qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         return TRUE;
  18 }
  19
  20 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, entity dmgowner)
  21 {
  22         // TODO maybe call this from non-edgedamage too?
  23         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  24
  25         entity e;
  26
  27         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  28                 deathtype |= 0x8000;
  29
  30         e = spawn();
  31         setorigin(e, org);
  32         e.projectiledeathtype = deathtype;
  33         e.dmg = coredamage;
  34         e.dmg_edge = edgedamage;
  35         e.dmg_radius = rad;
  36         e.dmg_force = vlen(force);
  37         e.velocity = force;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  42 }
  43
  44 #define DAMAGE_CENTERPRINT_SPACER NEWLINES
  45
  46 float checkrules_firstblood;
  47
  48 float yoda;
  49 float damage_goodhits;
  50 float damage_gooddamage;
  51 float headshot;
  52 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  53
  54 .float dmg_team;
  55 .float teamkill_complain;
  56 .float teamkill_soundtime;
  57 .entity teamkill_soundsource;
  58 .entity pusher;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teams_matter)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 void GiveFrags (entity attacker, entity targ, float f)
 106 {
 107         float w;
 108
 109         // TODO route through PlayerScores instead
 110         if(gameover) return;
 111
 112         if(f < 0)
 113         {
 114                 if(targ == attacker)
 115                 {
 116                         // suicide
 117                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 118                 }
 119                 else
 120                 {
 121                         // teamkill
 122                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 123                         PlayerStats_Event(attacker, PLAYERSTATS_KILLS, -1);
 124                 }
 125         }
 126         else
 127         {
 128                 // regular frag
 129                 PlayerScore_Add(attacker, SP_KILLS, 1);
 130                 PlayerStats_Event(attacker, PLAYERSTATS_KILLS, 1);
 131         }
 132
 133         PlayerScore_Add(targ, SP_DEATHS, 1);
 134
 135         if(g_arena || g_ca)
 136                 if(autocvar_g_arena_roundbased)
 137                         return;
 138
 139         if(targ != attacker) // not for suicides
 140         if(g_weaponarena_random)
 141         {
 142                 // after a frag, choose another random weapon set
 143                 if(inWarmupStage)
 144                         w = warmup_start_weapons;
 145                 else
 146                         w = start_weapons;
 147
 148                 attacker.weapons = randombits(w - (w & W_WeaponBit(attacker.weapon)), g_weaponarena_random, TRUE);
 149                 if(attacker.weapons < 0)
 150                 {
 151                         // error from randombits: no weapon available
 152                         // this means we can just give ALL weapons
 153                         attacker.weapons = w;
 154                 }
 155                 if not(attacker.weapons & W_WeaponBit(attacker.weapon))
 156                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 157         }
 158
 159         // FIXME fix the mess this is (we have REAL points now!)
 160         entity oldself;
 161         oldself = self;
 162         self = attacker;
 163         frag_attacker = attacker;
 164         frag_target = targ;
 165         frag_score = f;
 166         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 167         {
 168                 f = frag_score;
 169                 self = oldself;
 170         }
 171         else
 172         {
 173                 self = oldself;
 174                 if(g_runematch)
 175                 {
 176                         f = RunematchHandleFrags(attacker, targ, f);
 177                 }
 178                 else if(g_lms)
 179                 {
 180                         // remove a life
 181                         float tl;
 182                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 183                         if(tl < lms_lowest_lives)
 184                                 lms_lowest_lives = tl;
 185                         if(tl <= 0)
 186                         {
 187                                 if(!lms_next_place)
 188                                         lms_next_place = player_count;
 189                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 190                                 --lms_next_place;
 191                         }
 192                         f = 0;
 193                 }
 194                 else if(g_ctf)
 195                 {
 196                         if(g_ctf_ignore_frags)
 197                                 f = 0;
 198                 }
 199         }
 200
 201         attacker.totalfrags += f;
 202
 203         if(f)
 204                 UpdateFrags(attacker, f);
 205 }
 206
 207 string AppendItemcodes(string s, entity player)
 208 {
 209         float w;
 210         w = player.weapon;
 211         //if(w == 0)
 212         //      w = player.switchweapon;
 213         if(w == 0)
 214                 w = player.cnt; // previous weapon!
 215         s = strcat(s, ftos(w));
 216         if(time < player.strength_finished)
 217                 s = strcat(s, "S");
 218         if(time < player.invincible_finished)
 219                 s = strcat(s, "I");
 220         if(player.flagcarried != world)
 221                 s = strcat(s, "F");
 222         if(player.BUTTON_CHAT)
 223                 s = strcat(s, "T");
 224         if(player.kh_next)
 225                 s = strcat(s, "K");
 226         if(player.runes)
 227                 s = strcat(s, "|", ftos(player.runes));
 228         return s;
 229 }
 230
 231 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 232 {
 233         string s;
 234         if(!autocvar_sv_eventlog)
 235                 return;
 236         s = strcat(":kill:", mode);
 237         s = strcat(s, ":", ftos(killer.playerid));
 238         s = strcat(s, ":", ftos(killed.playerid));
 239         s = strcat(s, ":type=", ftos(deathtype));
 240         s = strcat(s, ":items=");
 241         s = AppendItemcodes(s, killer);
 242         if(killed != killer)
 243         {
 244                 s = strcat(s, ":victimitems=");
 245                 s = AppendItemcodes(s, killed);
 246         }
 247         GameLogEcho(s);
 248 }
 249
 250 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 251 {
 252         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 253         WriteByte(MSG_ALL, TE_CSQC_NOTIFY);
 254         WriteByte(MSG_ALL, CSQC_KILLNOTIFY);
 255         WriteString(MSG_ALL, s1);
 256         WriteString(MSG_ALL, s2);
 257         WriteString(MSG_ALL, s3);
 258         WriteShort(MSG_ALL, msg);
 259         WriteByte(MSG_ALL, type);
 260 }
 261
 262 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 263 void Send_CSQC_Centerprint(entity e, string s1, string s2, float msg, float type)
 264 {
 265         if (clienttype(e) == CLIENTTYPE_REAL)
 266         {
 267                 msg_entity = e;
 268                 WRITESPECTATABLE_MSG_ONE({
 269                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 270                         WriteByte(MSG_ONE, TE_CSQC_NOTIFY);
 271                         WriteByte(MSG_ONE, CSQC_CENTERPRINT);
 272                         WriteString(MSG_ONE, s1);
 273                         WriteString(MSG_ONE, s2);
 274                         WriteShort(MSG_ONE, msg);
 275                         WriteByte(MSG_ONE, type);
 276                 });
 277         }
 278 }
 279
 280 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 281 {
 282         string  s, a, msg;
 283         float w, type;
 284
 285         if (targ.classname == "player" || targ.classname == "corpse")
 286         {
 287                 if (targ.classname == "corpse")
 288                         s = "A corpse";
 289                 else
 290                         s = targ.netname;
 291
 292                 a = attacker.netname;
 293
 294                 if (targ == attacker) // suicides
 295                 {
 296                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 297                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 298             if(!g_cts) // no "killed your own dumb self" message in CTS
 299                 Send_CSQC_Centerprint(targ, msg, "", deathtype, MSG_SUICIDE);
 300
 301                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 302                         {
 303                                 LogDeath("suicide", deathtype, targ, targ);
 304                                 GiveFrags(attacker, targ, -1);
 305                         }
 306
 307                         if (targ.killcount > 2)
 308                                 msg = ftos(targ.killcount);
 309                         if(teams_matter && deathtype == DEATH_MIRRORDAMAGE)
 310                         {
 311                                 if(attacker.team == COLOR_TEAM1)
 312                                         deathtype = KILL_TEAM_RED;
 313                                 else
 314                                         deathtype = KILL_TEAM_BLUE;
 315                         }
 316
 317                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 318                 }
 319                 else if (attacker.classname == "player" || attacker.classname == "gib")
 320                 {
 321                         if(teams_matter && attacker.team == targ.team)
 322                         {
 323                                 if(attacker.team == COLOR_TEAM1)
 324                                         type = KILL_TEAM_RED;
 325                                 else
 326                                         type = KILL_TEAM_BLUE;
 327
 328                                 GiveFrags(attacker, targ, -1);
 329
 330                                 Send_CSQC_Centerprint(attacker, s, "", type, MSG_KILL);
 331
 332                                 if (targ.killcount > 2) {
 333                                         msg = ftos(targ.killcount);
 334                                 }
 335
 336                                 if (attacker.killcount > 2) {
 337                                         msg = ftos(attacker.killcount);
 338                                         type = KILL_TEAM_SPREE;
 339                                 }
 340                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 341
 342                                 attacker.killcount = 0;
 343
 344                                 LogDeath("tk", deathtype, attacker, targ);
 345                         }
 346                         else
 347                         {
 348                                 if (!checkrules_firstblood)
 349                                 {
 350                                         checkrules_firstblood = TRUE;
 351                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 352                                         // TODO: make these print a newline if they dont
 353                                         Send_CSQC_Centerprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 354                                         Send_CSQC_Centerprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 355                                 }
 356
 357                                 if((autocvar_sv_fragmessage_information_typefrag) && (targ.BUTTON_CHAT)) {
 358                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_TYPEFRAG, MSG_KILL);
 359                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 360                                 } else {
 361                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_FRAG, MSG_KILL);
 362                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_FRAGGED, MSG_KILL);
 363                                 }
 364
 365                                 attacker.taunt_soundtime = time + 1;
 366
 367                                 // TODO: fix this?
 368                                 if (deathtype == DEATH_CUSTOM)
 369                                         msg = deathmessage;
 370                                 else
 371                                         msg = inflictor.message2;
 372
 373                                 if(strstrofs(msg, "%", 0) < 0)
 374                                         msg = strcat("%s ", msg, " by %s");
 375
 376                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 377
 378                                 if(g_ctf && targ.flagcarried)
 379                                 {
 380                                         UpdateFrags(attacker, ctf_score_value("score_kill"));
 381                                         PlayerScore_Add(attacker, SP_CTF_FCKILLS, 1);
 382                                         GiveFrags(attacker, targ, 0); // for logging
 383                                 }
 384                                 else
 385                                         GiveFrags(attacker, targ, 1);
 386
 387                                 if (targ.killcount > 2) {
 388                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 389                                 }
 390
 391                                 attacker.killcount = attacker.killcount + 1;
 392
 393                                 if (attacker.killcount > 2) {
 394                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 395                                 }
 396                                 else if (attacker.killcount == 3)
 397                                 {
 398                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 399                                         AnnounceTo(attacker, "03kills");
 400                                 }
 401                                 else if (attacker.killcount == 5)
 402                                 {
 403                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 404                                         AnnounceTo(attacker, "05kills");
 405                                 }
 406                                 else if (attacker.killcount == 10)
 407                                 {
 408                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 409                                         AnnounceTo(attacker, "10kills");
 410                                 }
 411                                 else if (attacker.killcount == 15)
 412                                 {
 413                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 414                                         AnnounceTo(attacker, "15kills");
 415                                 }
 416                                 else if (attacker.killcount == 20)
 417                                 {
 418                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 419                                         AnnounceTo(attacker, "20kills");
 420                                 }
 421                                 else if (attacker.killcount == 25)
 422                                 {
 423                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 424                                         AnnounceTo(attacker, "25kills");
 425                                 }
 426                                 else if (attacker.killcount == 30)
 427                                 {
 428                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 429                                         AnnounceTo(attacker, "30kills");
 430                                 }
 431                                 LogDeath("frag", deathtype, attacker, targ);
 432                         }
 433                 }
 434                 else
 435                 {
 436                         Send_CSQC_Centerprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 437                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 438                                 msg = inflictor.message;
 439                         else if (deathtype == DEATH_CUSTOM)
 440                                 msg = deathmessage;
 441                         if(strstrofs(msg, "%", 0) < 0)
 442                                 msg = strcat("%s ", msg);
 443
 444                         GiveFrags(targ, targ, -1);
 445                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 446                                 AnnounceTo(targ, "botlike");
 447                         }
 448                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 449
 450                         if (targ.killcount > 2)
 451                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 452
 453                         LogDeath("accident", deathtype, targ, targ);
 454                 }
 455
 456                 targ.death_origin = targ.origin;
 457                 if(targ != attacker)
 458                         targ.killer_origin = attacker.origin;
 459
 460                 // FIXME: this should go in PutClientInServer
 461                 if (targ.killcount)
 462                         targ.killcount = 0;
 463         }
 464 }
 465
 466 // these are updated by each Damage call for use in button triggering and such
 467 entity damage_targ;
 468 entity damage_inflictor;
 469 entity damage_attacker;
 470 .float prevhitsound;
 471
 472 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 473 {
 474         float mirrordamage;
 475         float mirrorforce;
 476         float teamdamage0;
 477         entity attacker_save;
 478         mirrordamage = 0;
 479         mirrorforce = 0;
 480
 481         if (gameover || targ.killcount == -666)
 482                 return;
 483
 484         local entity oldself;
 485         oldself = self;
 486         self = targ;
 487         damage_targ = targ;
 488         damage_inflictor = inflictor;
 489         damage_attacker = attacker;
 490                 attacker_save = attacker;
 491
 492         if(targ.classname == "player")
 493                 if(targ.hook)
 494                         if(targ.hook.aiment)
 495                                 if(targ.hook.aiment == attacker)
 496                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 497
 498         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 499         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 500         {
 501                 if(targ.classname == "player")
 502                         if not(IsDifferentTeam(targ, attacker))
 503                         {
 504                                 self = oldself;
 505                                 return;
 506                         }
 507         }
 508
 509         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 510         {
 511                 // These are ALWAYS lethal
 512                 // No damage modification here
 513                 // Instead, prepare the victim for his death...
 514                 targ.armorvalue = 0;
 515                 targ.spawnshieldtime = 0;
 516                 targ.health = 0.9; // this is < 1
 517                 targ.flags -= targ.flags & FL_GODMODE;
 518                 damage = 100000;
 519         }
 520         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 521         {
 522                 // no processing
 523         }
 524         else
 525         {
 526                 if (targ.classname == "player")
 527                 if (attacker.classname == "player")
 528                 if (!targ.isbot)
 529                 if (attacker.isbot)
 530                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 531
 532                 // nullify damage if teamplay is on
 533                 if(deathtype != DEATH_TELEFRAG)
 534                 if(attacker.classname == "player")
 535                 {
 536                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 537                         {
 538                                 damage = 0;
 539                                 force = '0 0 0';
 540                         }
 541                         else if(teams_matter && attacker.team == targ.team)
 542                         {
 543                                 if(autocvar_teamplay_mode == 1)
 544                                         damage = 0;
 545                                 else if(attacker != targ)
 546                                 {
 547                                         if(autocvar_teamplay_mode == 3)
 548                                                 damage = 0;
 549                                         else if(autocvar_teamplay_mode == 4)
 550                                         {
 551                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 552                                                 {
 553                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 554                                                         attacker.dmg_team = attacker.dmg_team + damage;
 555                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 556                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 557                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 558                                                         if(g_minstagib)
 559                                                         {
 560                                                                 if(autocvar_g_friendlyfire == 0)
 561                                                                         damage = 0;
 562                                                         }
 563                                                         else if(g_ca)
 564                                                                 damage = 0;
 565                                                         else
 566                                                                 damage = autocvar_g_friendlyfire * damage;
 567                                                         // mirrordamage will be used LATER
 568
 569                                                         if(autocvar_g_mirrordamage_virtual)
 570                                                         {
 571                                                                 vector v;
 572                                                                 v = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 573                                                                 attacker.dmg_take += v_x;
 574                                                                 attacker.dmg_save += v_y;
 575                                                                 attacker.dmg_inflictor = inflictor;
 576                                                                 mirrordamage = 0;
 577                                                                 mirrorforce = 0;
 578                                                         }
 579
 580                                                         if(autocvar_g_friendlyfire_virtual)
 581                                                         {
 582                                                                 vector v;
 583                                                                 v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 584                                                                 targ.dmg_take += v_x;
 585                                                                 targ.dmg_save += v_y;
 586                                                                 targ.dmg_inflictor = inflictor;
 587                                                                 damage = 0;
 588                                                                 force = '0 0 0';
 589                                                         }
 590                                                 }
 591                                                 else
 592                                                         damage = 0;
 593                                         }
 594                                 }
 595                         }
 596                 }
 597
 598                 if(targ.classname == "player")
 599                 if(attacker.classname == "player")
 600                 if(attacker != targ)
 601                 {
 602                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 603                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 604                 }
 605
 606                 if(targ.classname == "player")
 607                 if (g_minstagib)
 608                 {
 609                         if ((deathtype == DEATH_FALL)  ||
 610                                 (deathtype == DEATH_DROWN) ||
 611                                 (deathtype == DEATH_SLIME) ||
 612                                 (deathtype == DEATH_LAVA)  ||
 613                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 614                         {
 615                                 self = oldself;
 616                                 return;
 617                         }
 618                         if(damage > 0)
 619                             damage = 10000;
 620                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 621                         {
 622                                 targ.armorvalue -= 1;
 623                                 centerprint(targ, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(targ.armorvalue)));
 624                                 damage = 0;
 625                                 targ.hitsound += 1;
 626                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 627                         }
 628                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 629                         {
 630                                 damage = 0;
 631                                 mirrordamage = 0;
 632                                 if (targ != attacker)
 633                                 {
 634                                         if ((targ.health >= 1) && (targ.classname == "player"))
 635                                                 centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "Secondary fire inflicts no damage!"));
 636                                         force = '0 0 0';
 637                                         // keep mirrorforce
 638                                         attacker = targ;
 639                                 }
 640                         }
 641                 }
 642
 643                 if not(DEATH_ISSPECIAL(deathtype))
 644                 {
 645                         damage *= g_weapondamagefactor;
 646                         mirrordamage *= g_weapondamagefactor;
 647                         force = force * g_weaponforcefactor;
 648                         mirrorforce *= g_weaponforcefactor;
 649                 }
 650
 651                 // should this be changed at all? If so, in what way?
 652                 frag_attacker = attacker;
 653                 frag_target = targ;
 654                 frag_damage = damage;
 655                 frag_force = force;
 656         frag_deathtype = deathtype;
 657                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 658                 damage = frag_damage;
 659                 force = frag_force;
 660
 661                 // apply strength multiplier
 662                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 663                 {
 664                         if(targ == attacker)
 665                         {
 666                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 667                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 668                         }
 669                         else
 670                         {
 671                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 672                                 force = force * autocvar_g_balance_powerup_strength_force;
 673                         }
 674                 }
 675
 676                 // apply invincibility multiplier
 677                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 678                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 679
 680                 if (targ == attacker)
 681                 {
 682                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 683                                 damage = 0;
 684                         else
 685                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 686                 }
 687
 688                 // CTF: reduce damage/force
 689                 if(g_ctf)
 690                 if(targ == attacker)
 691                 if(targ.flagcarried)
 692                 {
 693                         damage = damage * autocvar_g_ctf_flagcarrier_selfdamage;
 694                         force = force * autocvar_g_ctf_flagcarrier_selfforce;
 695                 }
 696
 697                 if(g_runematch)
 698                 {
 699                         // apply strength rune
 700                         if (attacker.runes & RUNE_STRENGTH)
 701                         {
 702                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 703                                 {
 704                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 705                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 706                                 }
 707                                 else
 708                                 {
 709                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 710                                         force = force * autocvar_g_balance_rune_strength_force;
 711                                 }
 712                         }
 713                         else if (attacker.runes & CURSE_WEAK)
 714                         {
 715                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 716                                 force = force * autocvar_g_balance_curse_weak_force;
 717                         }
 718
 719                         // apply defense rune
 720                         if (targ.runes & RUNE_DEFENSE)
 721                         {
 722                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 723                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 724                                 else
 725                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 726                         }
 727                         else if (targ.runes & CURSE_VULNER)
 728                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 729                 }
 730
 731                 // count the damage
 732                 if(attacker)
 733                 if(!targ.deadflag)
 734                 if(targ.takedamage == DAMAGE_AIM)
 735                 if(targ != attacker)
 736                 {
 737                         if(targ.classname == "player")
 738                         {
 739                                 // HEAD SHOT:
 740                                 // find height of hit on player axis
 741                                 // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 742                                 vector headmins, headmaxs, org;
 743                                 org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 744                                 headmins = org + GetHeadshotMins(targ);
 745                                 headmaxs = org + GetHeadshotMaxs(targ);
 746                                 if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 747                                 {
 748                                         deathtype |= HITTYPE_HEADSHOT;
 749                                 }
 750                         }
 751                         else if(targ.classname == "turret_head")
 752                         {
 753                                 deathtype |= HITTYPE_HEADSHOT;
 754                         }
 755                         if(deathtype & HITTYPE_HEADSHOT)
 756                                 damage *= 1 + damage_headshotbonus;
 757
 758                         if(targ.classname == "player")
 759                         {
 760                                 if(IsDifferentTeam(targ, attacker))
 761                                 {
 762                                         if(damage > 0)
 763                                         {
 764                                                 if(attacker.weapon != WEP_ELECTRO && attacker.weapon != WEP_LASER || ((attacker.weapon == WEP_ELECTRO && autocvar_g_balance_electro_lightning || attacker.weapon == WEP_LASER) && attacker.prevhitsound + autocvar_sv_hitsound_antispam_time < time))
 765                                                 {
 766                                                         if(targ.BUTTON_CHAT)
 767                                                                 attacker.typehitsound += 1;
 768                                                         else
 769                                                                 attacker.hitsound += 1;
 770                                                         attacker.prevhitsound = time;
 771                                                 }
 772
 773                                                 damage_goodhits += 1;
 774                                                 damage_gooddamage += damage;
 775
 776                                                 if not(DEATH_ISSPECIAL(deathtype))
 777                                                 {
 778                                                         if(!g_minstagib)
 779                                                         if(IsFlying(targ))
 780                                                                 yoda = 1;
 781
 782                                                         if(g_minstagib)
 783                                                         if(targ.items & IT_STRENGTH)
 784                                                                 yoda = 1;
 785
 786                                                         if(deathtype & HITTYPE_HEADSHOT)
 787                                                                 headshot = 1;
 788                                                 }
 789                                                 if(g_ca)
 790                                                         PlayerScore_Add(attacker, SP_SCORE, damage * autocvar_g_ca_damage2score_multiplier);
 791                                         }
 792                                 }
 793                                 else
 794                                 {
 795                                         if(deathtype != DEATH_FIRE)
 796                                                 attacker.typehitsound += 1;
 797                                         if(mirrordamage > 0)
 798                                                 if(time > attacker.teamkill_complain)
 799                                                 {
 800                                                         attacker.teamkill_complain = time + 5;
 801                                                         attacker.teamkill_soundtime = time + 0.4;
 802                                                         attacker.teamkill_soundsource = targ;
 803                                                 }
 804                                 }
 805                         }
 806                 }
 807         }
 808
 809         // apply push
 810         if (self.damageforcescale)
 811         if (vlen(force))
 812         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 813         {
 814                 self.velocity = self.velocity + self.damageforcescale * force;
 815                 self.flags &~= FL_ONGROUND;
 816                 UpdateCSQCProjectile(self);
 817         }
 818         // apply damage
 819         if (damage != 0 || (self.damageforcescale && vlen(force)))
 820         if (self.event_damage)
 821                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 822         self = oldself;
 823
 824         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 825         {
 826                 if(g_runematch)
 827                 {
 828                         if (attacker.runes & RUNE_VAMPIRE)
 829                         {
 830                         // apply vampire rune
 831                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 832                                 {
 833                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 834                                         attacker.health = bound(
 835                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 836                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 837                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 838                                 }
 839                                 else
 840                                 {
 841                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 842                                         attacker.health = bound(
 843                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 844                                                                                         // empathy won't let you gain health in the same way...
 845                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 846                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 847                                         }
 848                         }
 849                         // apply empathy curse
 850                         else if (attacker.runes & CURSE_EMPATHY)
 851                         {
 852                                 attacker.health = bound(
 853                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 854                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 855                                         attacker.health);
 856                         }
 857                 }
 858         }
 859
 860         // apply mirror damage if any
 861         if(mirrordamage > 0 || mirrorforce > 0)
 862         {
 863                 attacker = attacker_save;
 864                 if(g_minstagib)
 865                 if(mirrordamage > 0)
 866                 {
 867                         // just lose extra LIVES, don't kill the player for mirror damage
 868                         if(attacker.armorvalue > 0)
 869                         {
 870                                 attacker.armorvalue = attacker.armorvalue - 1;
 871                                 centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 872                                 attacker.hitsound += 1;
 873                         }
 874                         mirrordamage = 0;
 875                 }
 876
 877                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 878                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 879         }
 880 }
 881
 882 float RadiusDamage_running;
 883 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 884 // Returns total damage applies to creatures
 885 {
 886         entity  targ;
 887         float   finaldmg;
 888         float   power;
 889         vector  blastorigin;
 890         vector  force;
 891         vector  diff;
 892         vector  center;
 893         vector  nearest;
 894         float   total_damage_to_creatures;
 895         entity  next;
 896         float   tfloordmg;
 897         float   tfloorforce;
 898
 899         float stat_damagedone;
 900
 901         if(RadiusDamage_running)
 902         {
 903                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 904                 return 0;
 905         }
 906
 907         RadiusDamage_running = 1;
 908
 909         tfloordmg = autocvar_g_throughfloor_damage;
 910         tfloorforce = autocvar_g_throughfloor_force;
 911
 912         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 913         total_damage_to_creatures = 0;
 914
 915         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 916         if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 917         {
 918                 force = inflictor.velocity;
 919                 if(vlen(force) == 0)
 920                         force = '0 0 -1';
 921                 else
 922                         force = normalize(force);
 923                 if(forceintensity >= 0)
 924                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, attacker);
 925                 else
 926                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, attacker);
 927         }
 928
 929         stat_damagedone = 0;
 930
 931         targ = WarpZone_FindRadius (blastorigin, rad, FALSE);
 932         while (targ)
 933         {
 934                 next = targ.chain;
 935                 if (targ != inflictor)
 936                         if (ignore != targ) if(targ.takedamage)
 937                         {
 938                                 // LordHavoc: measure distance to nearest point on target (not origin)
 939                                 // (this guarentees 100% damage on a touch impact)
 940                                 nearest = targ.WarpZone_findradius_nearest;
 941                                 diff = targ.WarpZone_findradius_dist;
 942                                 // round up a little on the damage to ensure full damage on impacts
 943                                 // and turn the distance into a fraction of the radius
 944                                 power = 1 - ((vlen (diff) - 2) / rad);
 945                                 //bprint(" ");
 946                                 //bprint(ftos(power));
 947                                 //if (targ == attacker)
 948                                 //      print(ftos(power), "\n");
 949                                 if (power > 0)
 950                                 {
 951                                         if (power > 1)
 952                                                 power = 1;
 953                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 954                                         if (finaldmg > 0)
 955                                         {
 956                                                 local float a;
 957                                                 local float c;
 958                                                 local float hits;
 959                                                 local float total;
 960                                                 local float hitratio;
 961                                                 local vector hitloc;
 962                                                 local vector myblastorigin;
 963                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 964                                                 center = targ.origin + (targ.mins + targ.maxs) * 0.5;
 965                                                 // if it's a player, use the view origin as reference
 966                                                 if (targ.classname == "player")
 967                                                         center = targ.origin + targ.view_ofs;
 968                                                 force = normalize(center - myblastorigin);
 969                                                 force = force * (finaldmg / coredamage) * forceintensity;
 970                                                 // test line of sight to multiple positions on box,
 971                                                 // and do damage if any of them hit
 972                                                 hits = 0;
 973                                                 if (targ.classname == "player")
 974                                                         total = ceil(bound(1, finaldmg, 50));
 975                                                 else
 976                                                         total = ceil(bound(1, finaldmg/10, 5));
 977                                                 hitloc = nearest;
 978                                                 c = 0;
 979                                                 while (c < total)
 980                                                 {
 981                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 982                                                         WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 983                                                         if (trace_fraction == 1 || trace_ent == targ)
 984                                                         {
 985                                                                 hits = hits + 1;
 986                                                                 if (hits > 1)
 987                                                                         hitloc = hitloc + nearest;
 988                                                                 else
 989                                                                         hitloc = nearest;
 990                                                         }
 991                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 992                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 993                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 994                                                         c = c + 1;
 995                                                 }
 996                                                 nearest = hitloc * (1 / max(1, hits));
 997                                                 hitratio = (hits / total);
 998                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 999                                                 finaldmg = finaldmg * a;
1000                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1001                                                 force = force * a;
1002
1003                                                 // laser force adjustments :P
1004                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1005                                                 {
1006                                                         vector vel;
1007
1008                                                         float force_zscale;
1009                                                         float force_velocitybiasramp;
1010                                                         float force_velocitybias;
1011
1012                                                         force_velocitybiasramp = autocvar_sv_maxspeed;
1013                                                         if(deathtype & HITTYPE_SECONDARY)
1014                                                         {
1015                                                                 force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1016                                                                 force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1017                                                         }
1018                                                         else
1019                                                         {
1020                                                                 force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1021                                                                 force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1022                                                         }
1023
1024                                                         vel = targ.velocity;
1025                                                         vel_z = 0;
1026                                                         vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1027                                                         force =
1028                                                                 vlen(force)
1029                                                                 *
1030                                                                 normalize(normalize(force) + vel);
1031
1032                                                         force_z *= force_zscale;
1033                                                 }
1034
1035                                                 //if (targ == attacker)
1036                                                 //{
1037                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1038                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1039                                                 //      print(" (", ftos(a), ")\n");
1040                                                 //}
1041                                                 if(hits || tfloordmg || tfloorforce)
1042                                                 {
1043                                                         if(targ.iscreature)
1044                                                         {
1045                                                                 total_damage_to_creatures += finaldmg;
1046
1047                                                                 if(accuracy_isgooddamage(attacker, targ))
1048                                                                         stat_damagedone += finaldmg;
1049                                                         }
1050
1051                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1052                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1053                                                         else
1054                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1055                                                 }
1056                                         }
1057                                 }
1058                         }
1059                 targ = next;
1060         }
1061
1062         RadiusDamage_running = 0;
1063
1064         if(!DEATH_ISSPECIAL(deathtype))
1065                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1066
1067         return total_damage_to_creatures;
1068 }
1069
1070 .float fire_damagepersec;
1071 .float fire_endtime;
1072 .float fire_deathtype;
1073 .entity fire_owner;
1074 .float fire_hitsound;
1075 .entity fire_burner;
1076
1077 void fireburner_think();
1078
1079 float Fire_IsBurning(entity e)
1080 {
1081         return (time < e.fire_endtime);
1082 }
1083
1084 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1085 {
1086         float dps;
1087         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1088
1089         if(e.classname == "player")
1090         {
1091                 if(e.deadflag)
1092                         return -1;
1093         }
1094         else
1095         {
1096                 if(!e.fire_burner)
1097                 {
1098                         // print("adding a fire burner to ", e.classname, "\n");
1099                         e.fire_burner = spawn();
1100                         e.fire_burner.classname = "fireburner";
1101                         e.fire_burner.think = fireburner_think;
1102                         e.fire_burner.nextthink = time;
1103                         e.fire_burner.owner = e;
1104                 }
1105         }
1106
1107         t = max(t, 0.1);
1108         dps = d / t;
1109         if(Fire_IsBurning(e))
1110         {
1111                 mintime = e.fire_endtime - time;
1112                 maxtime = max(mintime, t);
1113
1114                 mindps = e.fire_damagepersec;
1115                 maxdps = max(mindps, dps);
1116
1117                 if(maxtime > mintime || maxdps > mindps)
1118                 {
1119                         mindamage = mindps * mintime;
1120                         maxdamage = mindamage + d;
1121
1122                         // interval [mintime, maxtime] * [mindps, maxdps]
1123                         // intersected with
1124                         // [mindamage, maxdamage]
1125                         // maximum of this!
1126
1127                         if(maxdamage >= maxtime * maxdps)
1128                         {
1129                                 totaltime = maxtime;
1130                                 totaldamage = maxtime * maxdps;
1131
1132                                 // this branch increases totaldamage if either t > mintime, or dps > mindps
1133                         }
1134                         else
1135                         {
1136                                 // maxdamage is inside the interval!
1137                                 // first, try to use mindps; only if this fails, increase dps as needed
1138                                 totaltime = min(maxdamage / mindps, maxtime); // maxdamage / mindps >= mindamage / mindps = mintime
1139                                 totaldamage = maxdamage;
1140                                 // can totaldamage / totaltime be >= maxdps?
1141                                 // max(mindps, maxdamage / maxtime) >= maxdps?
1142                                 // we know maxdamage < maxtime * maxdps
1143                                 // so it cannot be
1144
1145                                 // this branch ALWAYS increases totaldamage, but requires maxdamage < maxtime * maxdps
1146                         }
1147
1148                         // total conditions for increasing:
1149                         //     maxtime > mintime OR maxdps > mindps OR maxtime * maxdps > maxdamage
1150                         // however:
1151                         //     if maxtime = mintime, maxdps = mindps
1152                         // then:
1153                         //     maxdamage = mindamage + d
1154                         //     mindamage = mindps * mintime = maxdps * maxtime < maxdamage!
1155                         // so the last condition is not needed
1156
1157                         e.fire_damagepersec = totaldamage / totaltime;
1158                         e.fire_endtime = time + totaltime;
1159                         if(totaldamage > 1.2 * mindamage)
1160                         {
1161                                 e.fire_deathtype = dt;
1162                                 if(e.fire_owner != o)
1163                                 {
1164                                         e.fire_owner = o;
1165                                         e.fire_hitsound = FALSE;
1166                                 }
1167                         }
1168                         if(accuracy_isgooddamage(o, e))
1169                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1170                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1171                 }
1172                 else
1173                         return 0;
1174         }
1175         else
1176         {
1177                 e.fire_damagepersec = dps;
1178                 e.fire_endtime = time + t;
1179                 e.fire_deathtype = dt;
1180                 e.fire_owner = o;
1181                 e.fire_hitsound = FALSE;
1182                 if(accuracy_isgooddamage(o, e))
1183                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1184                 return d;
1185         }
1186 }
1187
1188 void Fire_ApplyDamage(entity e)
1189 {
1190         float t, d, hi, ty;
1191         entity o;
1192
1193         if not(Fire_IsBurning(e))
1194                 return;
1195
1196         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1197         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1198                 o = e.fire_owner;
1199
1200         // water and slime stop fire
1201         if(e.waterlevel)
1202         if(e.watertype != CONTENT_LAVA)
1203                 e.fire_endtime = 0;
1204
1205         t = min(frametime, e.fire_endtime - time);
1206         d = e.fire_damagepersec * t;
1207
1208         hi = e.fire_owner.hitsound;
1209         ty = e.fire_owner.typehitsound;
1210         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1211         if(e.fire_hitsound && e.fire_owner)
1212         {
1213                 e.fire_owner.hitsound = hi;
1214                 e.fire_owner.typehitsound = ty;
1215         }
1216         e.fire_hitsound = TRUE;
1217
1218         if not(IS_INDEPENDENT_PLAYER(e))
1219         FOR_EACH_PLAYER(other) if(e != other)
1220         {
1221                 if(other.classname == "player")
1222                 if(other.deadflag == DEAD_NO)
1223                 if not(IS_INDEPENDENT_PLAYER(other))
1224                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1225                 {
1226                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1227                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1228                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1229                 }
1230         }
1231 }
1232
1233 void Fire_ApplyEffect(entity e)
1234 {
1235         if(Fire_IsBurning(e))
1236                 e.effects |= EF_FLAME;
1237         else
1238                 e.effects &~= EF_FLAME;
1239 }
1240
1241 void fireburner_think()
1242 {
1243         // for players, this is done in the regular loop
1244         if(wasfreed(self.owner))
1245         {
1246                 remove(self);
1247                 return;
1248         }
1249         Fire_ApplyEffect(self.owner);
1250         if(!Fire_IsBurning(self.owner))
1251         {
1252                 self.owner.fire_burner = world;
1253                 remove(self);
1254                 return;
1255         }
1256         Fire_ApplyDamage(self.owner);
1257         self.nextthink = time;
1258 }