qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(targ != attacker) // not for suicides
 124         if(g_weaponarena_random)
 125         {
 126                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 127                 float culprit;
 128                 culprit = DEATH_WEAPONOF(deathtype);
 129                 if(!culprit)
 130                         culprit = attacker.weapon;
 131                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 132                         culprit = attacker.weapon;
 133
 134                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 135                 {
 136                         // no exchange
 137                 }
 138                 else
 139                 {
 140                         if(!GiveFrags_randomweapons)
 141                         {
 142                                 GiveFrags_randomweapons = spawn();
 143                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 144                         }
 145
 146                         if(inWarmupStage)
 147                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 148                         else
 149                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 150
 151                         // all others (including the culprit): remove
 152                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 153                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 154
 155                         // among the remaining ones, choose one by random
 156                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 157
 158                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 159                         {
 160                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 161                                 WEPSET_ANDNOT_EW(attacker, culprit);
 162                         }
 163                 }
 164
 165                 // after a frag, choose another random weapon set
 166                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 167                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 168         }
 169
 170         // FIXME fix the mess this is (we have REAL points now!)
 171         entity oldself;
 172         oldself = self;
 173         self = attacker;
 174         frag_attacker = attacker;
 175         frag_target = targ;
 176         frag_score = f;
 177         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 178         {
 179                 f = frag_score;
 180                 self = oldself;
 181         }
 182         else
 183         {
 184                 self = oldself;
 185         }
 186
 187         attacker.totalfrags += f;
 188
 189         if(f)
 190                 UpdateFrags(attacker, f);
 191 }
 192
 193 string AppendItemcodes(string s, entity player)
 194 {
 195         float w;
 196         w = player.weapon;
 197         //if(w == 0)
 198         //      w = player.switchweapon;
 199         if(w == 0)
 200                 w = player.cnt; // previous weapon!
 201         s = strcat(s, ftos(w));
 202         if(time < player.strength_finished)
 203                 s = strcat(s, "S");
 204         if(time < player.invincible_finished)
 205                 s = strcat(s, "I");
 206         if(player.flagcarried != world)
 207                 s = strcat(s, "F");
 208         if(player.BUTTON_CHAT)
 209                 s = strcat(s, "T");
 210         if(player.kh_next)
 211                 s = strcat(s, "K");
 212         return s;
 213 }
 214
 215 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 216 {
 217         string s;
 218         if(!autocvar_sv_eventlog)
 219                 return;
 220         s = strcat(":kill:", mode);
 221         s = strcat(s, ":", ftos(killer.playerid));
 222         s = strcat(s, ":", ftos(killed.playerid));
 223         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 224         s = strcat(s, ":items=");
 225         s = AppendItemcodes(s, killer);
 226         if(killed != killer)
 227         {
 228                 s = strcat(s, ":victimitems=");
 229                 s = AppendItemcodes(s, killed);
 230         }
 231         GameLogEcho(s);
 232 }
 233
 234 void Obituary_SpecialDeath(
 235         entity notif_target,
 236         float murder,
 237         float deathtype,
 238         string s1, string s2, string s3,
 239         float f1, float f2, float f3)
 240 {
 241         if(DEATH_ISSPECIAL(deathtype))
 242         {
 243                 entity deathent = deathtypes[(deathtype - DT_FIRST)];
 244                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 245
 246                 if(murder)
 247                 {
 248                         if(deathent.death_msgmurder)
 249                         {
 250                                 Send_Notification_WOVA(
 251                                         NOTIF_ONE,
 252                                         notif_target,
 253                                         MSG_MULTI,
 254                                         deathent.death_msgmurder.nent_id,
 255                                         s1, s2, s3, "",
 256                                         f1, f2, f3, 0
 257                                 );
 258                                 Send_Notification_WOVA(
 259                                         NOTIF_ALL_EXCEPT,
 260                                         notif_target,
 261                                         MSG_INFO,
 262                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 263                                         s1, s2, s3, "",
 264                                         f1, f2, f3, 0
 265                                 );
 266                         }
 267                 }
 268                 else
 269                 {
 270                         if(deathent.death_msgself)
 271                         {
 272                                 Send_Notification_WOVA(
 273                                         NOTIF_ONE,
 274                                         notif_target,
 275                                         MSG_MULTI,
 276                                         deathent.death_msgself.nent_id,
 277                                         s1, s2, s3, "",
 278                                         f1, f2, f3, 0
 279                                 );
 280                                 Send_Notification_WOVA(
 281                                         NOTIF_ALL_EXCEPT,
 282                                         notif_target,
 283                                         MSG_INFO,
 284                                         deathent.death_msgself.nent_msginfo.nent_id,
 285                                         s1, s2, s3, "",
 286                                         f1, f2, f3, 0
 287                                 );
 288                         }
 289                 }
 290         }
 291         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 292 }
 293
 294 float w_deathtype;
 295 float Obituary_WeaponDeath(
 296         entity notif_target,
 297         float murder,
 298         float deathtype,
 299         string s1, string s2, string s3,
 300         float f1, float f2)
 301 {
 302         float death_weapon = DEATH_WEAPONOF(deathtype);
 303         if(death_weapon)
 304         {
 305                 w_deathtype = deathtype;
 306                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 307                 w_deathtype = FALSE;
 308
 309                 if(death_message)
 310                 {
 311                         Send_Notification_WOVA(
 312                                 NOTIF_ONE,
 313                                 notif_target,
 314                                 MSG_MULTI,
 315                                 death_message,
 316                                 s1, s2, s3, "",
 317                                 f1, f2, 0, 0
 318                         );
 319                         Send_Notification_WOVA(
 320                                 NOTIF_ALL_EXCEPT,
 321                                 notif_target,
 322                                 MSG_INFO,
 323                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 324                                 s1, s2, s3, "",
 325                                 f1, f2, 0, 0
 326                         );
 327                 }
 328                 else
 329                 {
 330                         dprint(sprintf(
 331                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 332                                 deathtype,
 333                                 death_weapon
 334                         ));
 335                 }
 336
 337                 return TRUE;
 338         }
 339         return FALSE;
 340 }
 341
 342 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 343 {
 344         // Sanity check
 345         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 346
 347         // Declarations
 348         float notif_firstblood = FALSE;
 349         float kill_count_to_attacker, kill_count_to_target;
 350
 351         // Set final information for the death
 352         targ.death_origin = targ.origin;
 353         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 354         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 355
 356         #ifdef NOTIFICATIONS_DEBUG
 357         Debug_Notification(
 358                 sprintf(
 359                         "Obituary(%s, %s, %s, %s = %d);\n",
 360                         attacker.netname,
 361                         inflictor.netname,
 362                         targ.netname,
 363                         Deathtype_Name(deathtype),
 364                         deathtype
 365                 )
 366         );
 367         #endif
 368
 369         // =======
 370         // SUICIDE
 371         // =======
 372         if(targ == attacker)
 373         {
 374                 if(DEATH_ISSPECIAL(deathtype))
 375                 {
 376                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 377                         {
 378                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 379                         }
 380                         else
 381                         {
 382                                 switch(deathtype)
 383                                 {
 384                                         case DEATH_MIRRORDAMAGE:
 385                                         {
 386                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 387                                                 break;
 388                                         }
 389
 390                                         default:
 391                                         {
 392                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 393                                                 break;
 394                                         }
 395                                 }
 396                         }
 397                 }
 398                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 399                 {
 400                         backtrace("SUICIDE: what the hell happened here?\n");
 401                         return;
 402                 }
 403                 LogDeath("suicide", deathtype, targ, targ);
 404                 GiveFrags(attacker, targ, -1, deathtype);
 405         }
 406
 407         // ======
 408         // MURDER
 409         // ======
 410         else if(IS_PLAYER(attacker))
 411         {
 412                 if(!IsDifferentTeam(attacker, targ))
 413                 {
 414                         LogDeath("tk", deathtype, attacker, targ);
 415                         GiveFrags(attacker, targ, -1, deathtype);
 416
 417                         attacker.killcount = 0;
 418
 419                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 420                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 421                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
 422
 423                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 424                         // No need for specific death/weapon messages...
 425                 }
 426                 else
 427                 {
 428                         LogDeath("frag", deathtype, attacker, targ);
 429                         GiveFrags(attacker, targ, 1, deathtype);
 430
 431                         attacker.taunt_soundtime = time + 1;
 432                         attacker.killcount = attacker.killcount + 1;
 433
 434                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 435                                 case counta: \
 436                                 { \
 437                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
 438                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 439                                         break; \
 440                                 }
 441                         switch(attacker.killcount)
 442                         {
 443                                 KILL_SPREE_LIST
 444                                 default: break;
 445                         }
 446                         #undef SPREE_ITEM
 447
 448                         if(!checkrules_firstblood)
 449                         {
 450                                 checkrules_firstblood = TRUE;
 451                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 452                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 453                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 454
 455                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 456                                 kill_count_to_attacker = -1;
 457                                 kill_count_to_target = -2;
 458                         }
 459                         else
 460                         {
 461                                 kill_count_to_attacker = attacker.killcount;
 462                                 kill_count_to_target = 0;
 463                         }
 464
 465                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
 466                         if(targ.istypefrag)
 467                         {
 468                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 469                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 470                                 else
 471                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 472
 473                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 474                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 475                                 else
 476                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 477                         }
 478                         else
 479                         {
 480                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 481                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 482                                 else
 483                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 484
 485                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 486                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 487                                 else
 488                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 489                         }
 490
 491                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 492                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 493                 }
 494         }
 495
 496         // =============
 497         // ACCIDENT/TRAP
 498         // =============
 499         else
 500         {
 501                 switch(deathtype)
 502                 {
 503                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 504                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 505                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 506                         /*case DEATH_HURTTRIGGER:
 507                         {
 508                                 s1 = targ.netname;
 509                                 s2 = inflictor.message;
 510                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 511                                 break;
 512                         }*/
 513
 514                         case DEATH_CUSTOM:
 515                         {
 516                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 517                                         targ.netname,
 518                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 519                                         deathlocation,
 520                                         targ.killcount,
 521                                         0,
 522                                         0);
 523                                 break;
 524                         }
 525
 526                         default:
 527                         {
 528                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 529                                 break;
 530                         }
 531                 }
 532
 533                 LogDeath("accident", deathtype, targ, targ);
 534                 GiveFrags(targ, targ, -1, deathtype);
 535
 536                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 537                 {
 538                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
 539                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 540                 }
 541         }
 542
 543         // reset target kill count
 544         if(targ.killcount) { targ.killcount = 0; }
 545 }
 546
 547 // these are updated by each Damage call for use in button triggering and such
 548 entity damage_targ;
 549 entity damage_inflictor;
 550 entity damage_attacker;
 551
 552 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 553 {
 554         float mirrordamage;
 555         float mirrorforce;
 556         float complainteamdamage = 0;
 557         entity attacker_save;
 558         mirrordamage = 0;
 559         mirrorforce = 0;
 560
 561         if (gameover || targ.killcount == -666)
 562                 return;
 563
 564         entity oldself;
 565         oldself = self;
 566         self = targ;
 567         damage_targ = targ;
 568         damage_inflictor = inflictor;
 569         damage_attacker = attacker;
 570                 attacker_save = attacker;
 571
 572         if(IS_PLAYER(targ))
 573                 if(targ.hook)
 574                         if(targ.hook.aiment)
 575                                 if(targ.hook.aiment == attacker)
 576                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 577
 578         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 579         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 580         {
 581                 if(IS_PLAYER(targ))
 582                         if not(IsDifferentTeam(targ, attacker))
 583                         {
 584                                 self = oldself;
 585                                 return;
 586                         }
 587         }
 588
 589         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 590         {
 591                 // These are ALWAYS lethal
 592                 // No damage modification here
 593                 // Instead, prepare the victim for his death...
 594                 targ.armorvalue = 0;
 595                 targ.spawnshieldtime = 0;
 596                 targ.health = 0.9; // this is < 1
 597                 targ.flags -= targ.flags & FL_GODMODE;
 598                 damage = 100000;
 599         }
 600         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 601         {
 602                 // no processing
 603         }
 604         else
 605         {
 606                 // nullify damage if teamplay is on
 607                 if(deathtype != DEATH_TELEFRAG)
 608                 if(IS_PLAYER(attacker))
 609                 {
 610                         if(IS_PLAYER(targ) && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 611                         {
 612                                 damage = 0;
 613                                 force = '0 0 0';
 614                         }
 615                         else if(!IsDifferentTeam(attacker, targ))
 616                         {
 617                                 if(autocvar_teamplay_mode == 1)
 618                                         damage = 0;
 619                                 else if(attacker != targ)
 620                                 {
 621                                         if(autocvar_teamplay_mode == 3)
 622                                                 damage = 0;
 623                                         else if(autocvar_teamplay_mode == 4)
 624                                         {
 625                                                 if(IS_PLAYER(targ) && targ.deadflag == DEAD_NO)
 626                                                 {
 627                                                         attacker.dmg_team = attacker.dmg_team + damage;
 628                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 629                                                         if(complainteamdamage > 0)
 630                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 631                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 632                                                         damage = autocvar_g_friendlyfire * damage;
 633                                                         // mirrordamage will be used LATER
 634
 635                                                         if(autocvar_g_mirrordamage_virtual)
 636                                                         {
 637                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 638                                                                 attacker.dmg_take += v_x;
 639                                                                 attacker.dmg_save += v_y;
 640                                                                 attacker.dmg_inflictor = inflictor;
 641                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 642                                                                 mirrorforce = 0;
 643                                                         }
 644
 645                                                         if(autocvar_g_friendlyfire_virtual)
 646                                                         {
 647                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 648                                                                 targ.dmg_take += v_x;
 649                                                                 targ.dmg_save += v_y;
 650                                                                 targ.dmg_inflictor = inflictor;
 651                                                                 damage = 0;
 652                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 653                                                                         force = '0 0 0';
 654                                                         }
 655                                                 }
 656                                                 else
 657                                                         damage = 0;
 658                                         }
 659                                 }
 660                         }
 661                 }
 662
 663                 if not(DEATH_ISSPECIAL(deathtype))
 664                 {
 665                         damage *= g_weapondamagefactor;
 666                         mirrordamage *= g_weapondamagefactor;
 667                         complainteamdamage *= g_weapondamagefactor;
 668                         force = force * g_weaponforcefactor;
 669                         mirrorforce *= g_weaponforcefactor;
 670                 }
 671
 672                 // should this be changed at all? If so, in what way?
 673                 frag_attacker = attacker;
 674                 frag_target = targ;
 675                 frag_damage = damage;
 676                 frag_force = force;
 677         frag_deathtype = deathtype;
 678                 frag_mirrordamage = mirrordamage;
 679                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 680                 damage = frag_damage;
 681                 mirrordamage = frag_mirrordamage;
 682                 force = frag_force;
 683
 684                 if not(g_minstagib)
 685                 {
 686                         // apply strength multiplier
 687                         if (attacker.items & IT_STRENGTH)
 688                         {
 689                                 if(targ == attacker)
 690                                 {
 691                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 692                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
 693                                 }
 694                                 else
 695                                 {
 696                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
 697                                         force = force * autocvar_g_balance_powerup_strength_force;
 698                                 }
 699                         }
 700
 701                         // apply invincibility multiplier
 702                         if (targ.items & IT_INVINCIBLE)
 703                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 704                 }
 705
 706                 if (targ == attacker)
 707                 {
 708                         if(g_cts && !autocvar_g_cts_selfdamage)
 709                                 damage = 0;
 710                         else
 711                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 712                 }
 713
 714                 // count the damage
 715                 if(attacker)
 716                 if(!targ.deadflag)
 717                 if(targ.takedamage == DAMAGE_AIM)
 718                 if(targ != attacker)
 719                 {
 720                         entity victim;
 721                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 722                                 victim = targ.owner;
 723                         else
 724                                 victim = targ;
 725
 726                         if(IS_PLAYER(victim) || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 727                         {
 728                                 if(IsDifferentTeam(victim, attacker))
 729                                 {
 730                                         if(damage > 0)
 731                                         {
 732                                                 if(deathtype != DEATH_FIRE)
 733                                                 {
 734                                                         if(victim.BUTTON_CHAT)
 735                                                                 attacker.typehitsound += 1;
 736                                                         else
 737                                                                 attacker.hitsound += 1;
 738                                                 }
 739
 740                                                 damage_goodhits += 1;
 741                                                 damage_gooddamage += damage;
 742
 743                                                 if not(DEATH_ISSPECIAL(deathtype))
 744                                                 {
 745                                                         if(IS_PLAYER(targ)) // don't do this for vehicles
 746                                                         if(IsFlying(victim))
 747                                                                 yoda = 1;
 748                                                 }
 749                                         }
 750                                 }
 751                                 else
 752                                 {
 753                                         if(deathtype != DEATH_FIRE)
 754                                         {
 755                                                 attacker.typehitsound += 1;
 756                                         }
 757                                         if(complainteamdamage > 0)
 758                                                 if(time > attacker.teamkill_complain)
 759                                                 {
 760                                                         attacker.teamkill_complain = time + 5;
 761                                                         attacker.teamkill_soundtime = time + 0.4;
 762                                                         attacker.teamkill_soundsource = targ;
 763                                                 }
 764                                 }
 765                         }
 766                 }
 767         }
 768
 769         // apply push
 770         if (self.damageforcescale)
 771         if (vlen(force))
 772         if (!IS_PLAYER(self) || time >= self.spawnshieldtime)
 773         {
 774                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 775                 if(self.movetype == MOVETYPE_PHYSICS)
 776                 {
 777                         entity farcent;
 778                         farcent = spawn();
 779                         farcent.classname = "farce";
 780                         farcent.enemy = self;
 781                         farcent.movedir = farce * 10;
 782                         if(self.mass)
 783                                 farcent.movedir = farcent.movedir * self.mass;
 784                         farcent.origin = hitloc;
 785                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 786                         farcent.nextthink = time + 0.1;
 787                         farcent.think = SUB_Remove;
 788                 }
 789                 else
 790                         self.velocity = self.velocity + farce;
 791                 self.flags &~= FL_ONGROUND;
 792                 UpdateCSQCProjectile(self);
 793         }
 794         // apply damage
 795         if (damage != 0 || (self.damageforcescale && vlen(force)))
 796         if (self.event_damage)
 797                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 798         self = oldself;
 799
 800         // apply mirror damage if any
 801         if(mirrordamage > 0 || mirrorforce > 0)
 802         {
 803                 attacker = attacker_save;
 804
 805                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 806                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 807         }
 808 }
 809
 810 float RadiusDamage_running;
 811 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 812         // Returns total damage applies to creatures
 813 {
 814         entity  targ;
 815         vector  blastorigin;
 816         vector  force;
 817         float   total_damage_to_creatures;
 818         entity  next;
 819         float   tfloordmg;
 820         float   tfloorforce;
 821
 822         float stat_damagedone;
 823
 824         if(RadiusDamage_running)
 825         {
 826                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 827                 return 0;
 828         }
 829
 830         RadiusDamage_running = 1;
 831
 832         tfloordmg = autocvar_g_throughfloor_damage;
 833         tfloorforce = autocvar_g_throughfloor_force;
 834
 835         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 836         total_damage_to_creatures = 0;
 837
 838         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 839                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 840                 {
 841                         force = inflictor.velocity;
 842                         if(vlen(force) == 0)
 843                                 force = '0 0 -1';
 844                         else
 845                                 force = normalize(force);
 846                         if(forceintensity >= 0)
 847                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 848                         else
 849                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 850                 }
 851
 852         stat_damagedone = 0;
 853
 854         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 855         while (targ)
 856         {
 857                 next = targ.chain;
 858                 if (targ != inflictor)
 859                         if (ignore != targ) if(targ.takedamage)
 860                         {
 861                                 vector nearest;
 862                                 vector diff;
 863                                 float power;
 864
 865                                 // LordHavoc: measure distance to nearest point on target (not origin)
 866                                 // (this guarentees 100% damage on a touch impact)
 867                                 nearest = targ.WarpZone_findradius_nearest;
 868                                 diff = targ.WarpZone_findradius_dist;
 869                                 // round up a little on the damage to ensure full damage on impacts
 870                                 // and turn the distance into a fraction of the radius
 871                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 872                                 //bprint(" ");
 873                                 //bprint(ftos(power));
 874                                 //if (targ == attacker)
 875                                 //      print(ftos(power), "\n");
 876                                 if (power > 0)
 877                                 {
 878                                         float finaldmg;
 879                                         if (power > 1)
 880                                                 power = 1;
 881                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 882                                         if (finaldmg > 0)
 883                                         {
 884                                                 float a;
 885                                                 float c;
 886                                                 vector hitloc;
 887                                                 vector myblastorigin;
 888                                                 vector center;
 889
 890                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 891
 892                                                 // if it's a player, use the view origin as reference
 893                                                 center = CENTER_OR_VIEWOFS(targ);
 894
 895                                                 force = normalize(center - myblastorigin);
 896                                                 force = force * (finaldmg / coredamage) * forceintensity;
 897                                                 hitloc = nearest;
 898
 899                                                 if(targ != directhitentity)
 900                                                 {
 901                                                         float hits;
 902                                                         float total;
 903                                                         float hitratio;
 904                                                         float mininv_f, mininv_d;
 905
 906                                                         // test line of sight to multiple positions on box,
 907                                                         // and do damage if any of them hit
 908                                                         hits = 0;
 909
 910                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
 911                                                         // so for a given max stddev:
 912                                                         // n = (1 / (2 * max stddev of hitratio))^2
 913
 914                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
 915                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
 916
 917                                                         if(autocvar_g_throughfloor_debug)
 918                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
 919
 920                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
 921
 922                                                         if(autocvar_g_throughfloor_debug)
 923                                                                 print(sprintf(" steps=%f", total));
 924
 925                                                         if (IS_PLAYER(targ))
 926                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
 927                                                         else
 928                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
 929
 930                                                         if(autocvar_g_throughfloor_debug)
 931                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
 932
 933                                                         for(c = 0; c < total; ++c)
 934                                                         {
 935                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 936                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 937                                                                 if (trace_fraction == 1 || trace_ent == targ)
 938                                                                 {
 939                                                                         ++hits;
 940                                                                         if (hits > 1)
 941                                                                                 hitloc = hitloc + nearest;
 942                                                                         else
 943                                                                                 hitloc = nearest;
 944                                                                 }
 945                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 946                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 947                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 948                                                         }
 949
 950                                                         nearest = hitloc * (1 / max(1, hits));
 951                                                         hitratio = (hits / total);
 952                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 953                                                         finaldmg = finaldmg * a;
 954                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
 955                                                         force = force * a;
 956
 957                                                         if(autocvar_g_throughfloor_debug)
 958                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
 959                                                 }
 960
 961                                                 // laser force adjustments :P
 962                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
 963                                                 {
 964                                                         if (targ == attacker)
 965                                                         {
 966                                                                 vector vel;
 967
 968                                                                 float force_zscale;
 969                                                                 float force_velocitybiasramp;
 970                                                                 float force_velocitybias;
 971
 972                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
 973                                                                 if(deathtype & HITTYPE_SECONDARY)
 974                                                                 {
 975                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
 976                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
 977                                                                 }
 978                                                                 else
 979                                                                 {
 980                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
 981                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
 982                                                                 }
 983
 984                                                                 vel = targ.velocity;
 985                                                                 vel_z = 0;
 986                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
 987                                                                 force =
 988                                                                         vlen(force)
 989                                                                         *
 990                                                                         normalize(normalize(force) + vel);
 991
 992                                                                 force_z *= force_zscale;
 993                                                         }
 994                                                         else
 995                                                         {
 996                                                                 if(deathtype & HITTYPE_SECONDARY)
 997                                                                 {
 998                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
 999                                                                 }
1000                                                                 else
1001                                                                 {
1002                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1003                                                                 }
1004                                                         }
1005                                                 }
1006
1007                                                 //if (targ == attacker)
1008                                                 //{
1009                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1010                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1011                                                 //      print(" (", ftos(a), ")\n");
1012                                                 //}
1013                                                 if(finaldmg || vlen(force))
1014                                                 {
1015                                                         if(targ.iscreature)
1016                                                         {
1017                                                                 total_damage_to_creatures += finaldmg;
1018
1019                                                                 if(accuracy_isgooddamage(attacker, targ))
1020                                                                         stat_damagedone += finaldmg;
1021                                                         }
1022
1023                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1024                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1025                                                         else
1026                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1027                                                 }
1028                                         }
1029                                 }
1030                         }
1031                 targ = next;
1032         }
1033
1034         RadiusDamage_running = 0;
1035
1036         if(!DEATH_ISSPECIAL(deathtype))
1037                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1038
1039         return total_damage_to_creatures;
1040 }
1041
1042 .float fire_damagepersec;
1043 .float fire_endtime;
1044 .float fire_deathtype;
1045 .entity fire_owner;
1046 .float fire_hitsound;
1047 .entity fire_burner;
1048
1049 void fireburner_think();
1050
1051 float Fire_IsBurning(entity e)
1052 {
1053         return (time < e.fire_endtime);
1054 }
1055
1056 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1057 {
1058         float dps;
1059         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1060
1061         if(IS_PLAYER(e))
1062         {
1063                 if(e.deadflag)
1064                         return -1;
1065         }
1066         else
1067         {
1068                 if(!e.fire_burner)
1069                 {
1070                         // print("adding a fire burner to ", e.classname, "\n");
1071                         e.fire_burner = spawn();
1072                         e.fire_burner.classname = "fireburner";
1073                         e.fire_burner.think = fireburner_think;
1074                         e.fire_burner.nextthink = time;
1075                         e.fire_burner.owner = e;
1076                 }
1077         }
1078
1079         t = max(t, 0.1);
1080         dps = d / t;
1081         if(Fire_IsBurning(e))
1082         {
1083                 mintime = e.fire_endtime - time;
1084                 maxtime = max(mintime, t);
1085
1086                 mindps = e.fire_damagepersec;
1087                 maxdps = max(mindps, dps);
1088
1089                 if(maxtime > mintime || maxdps > mindps)
1090                 {
1091                         // Constraints:
1092
1093                         // damage we have right now
1094                         mindamage = mindps * mintime;
1095
1096                         // damage we want to get
1097                         maxdamage = mindamage + d;
1098
1099                         // but we can't exceed maxtime * maxdps!
1100                         totaldamage = min(maxdamage, maxtime * maxdps);
1101
1102                         // LEMMA:
1103                         // Look at:
1104                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1105                         // We see:
1106                         // totaldamage <= maxtime * maxdps
1107                         // ==> totaldamage / maxdps <= maxtime.
1108                         // We also see:
1109                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1110                         //                     >= min(mintime, maxtime)
1111                         // ==> totaldamage / maxdps >= mintime.
1112
1113                         /*
1114                         // how long do we damage then?
1115                         // at least as long as before
1116                         // but, never exceed maxdps
1117                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1118                         */
1119
1120                         // alternate:
1121                         // at most as long as maximum allowed
1122                         // but, never below mindps
1123                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1124
1125                         // assuming t > mintime, dps > mindps:
1126                         // we get d = t * dps = maxtime * maxdps
1127                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1128                         // totaldamage / maxdps = maxtime
1129                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1130                         // FROM THIS:
1131                         // a) totaltime = max(mintime, maxtime) = maxtime
1132                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1133
1134                         // assuming t <= mintime:
1135                         // we get maxtime = mintime
1136                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1137                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1138
1139                         // assuming dps <= mindps:
1140                         // we get mindps = maxdps.
1141                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1142                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1143                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1144
1145                         e.fire_damagepersec = totaldamage / totaltime;
1146                         e.fire_endtime = time + totaltime;
1147                         if(totaldamage > 1.2 * mindamage)
1148                         {
1149                                 e.fire_deathtype = dt;
1150                                 if(e.fire_owner != o)
1151                                 {
1152                                         e.fire_owner = o;
1153                                         e.fire_hitsound = FALSE;
1154                                 }
1155                         }
1156                         if(accuracy_isgooddamage(o, e))
1157                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1158                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1159                 }
1160                 else
1161                         return 0;
1162         }
1163         else
1164         {
1165                 e.fire_damagepersec = dps;
1166                 e.fire_endtime = time + t;
1167                 e.fire_deathtype = dt;
1168                 e.fire_owner = o;
1169                 e.fire_hitsound = FALSE;
1170                 if(accuracy_isgooddamage(o, e))
1171                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1172                 return d;
1173         }
1174 }
1175
1176 void Fire_ApplyDamage(entity e)
1177 {
1178         float t, d, hi, ty;
1179         entity o;
1180
1181         if not(Fire_IsBurning(e))
1182                 return;
1183
1184         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1185         if(IS_NOT_A_CLIENT(o))
1186                 o = e.fire_owner;
1187
1188         // water and slime stop fire
1189         if(e.waterlevel)
1190         if(e.watertype != CONTENT_LAVA)
1191                 e.fire_endtime = 0;
1192
1193         // ice stops fire
1194         if(e.freezetag_frozen)
1195                 e.fire_endtime = 0;
1196
1197         t = min(frametime, e.fire_endtime - time);
1198         d = e.fire_damagepersec * t;
1199
1200         hi = e.fire_owner.hitsound;
1201         ty = e.fire_owner.typehitsound;
1202         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1203         if(e.fire_hitsound && e.fire_owner)
1204         {
1205                 e.fire_owner.hitsound = hi;
1206                 e.fire_owner.typehitsound = ty;
1207         }
1208         e.fire_hitsound = TRUE;
1209
1210         if not(IS_INDEPENDENT_PLAYER(e))
1211         FOR_EACH_PLAYER(other) if(e != other)
1212         {
1213                 if(IS_PLAYER(other))
1214                 if(other.deadflag == DEAD_NO)
1215                 if not(IS_INDEPENDENT_PLAYER(other))
1216                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1217                 {
1218                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1219                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1220                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1221                 }
1222         }
1223 }
1224
1225 void Fire_ApplyEffect(entity e)
1226 {
1227         if(Fire_IsBurning(e))
1228                 e.effects |= EF_FLAME;
1229         else
1230                 e.effects &~= EF_FLAME;
1231 }
1232
1233 void fireburner_think()
1234 {
1235         // for players, this is done in the regular loop
1236         if(wasfreed(self.owner))
1237         {
1238                 remove(self);
1239                 return;
1240         }
1241         Fire_ApplyEffect(self.owner);
1242         if(!Fire_IsBurning(self.owner))
1243         {
1244                 self.owner.fire_burner = world;
1245                 remove(self);
1246                 return;
1247         }
1248         Fire_ApplyDamage(self.owner);
1249         self.nextthink = time;
1250 }