qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 /*string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }*/
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 #define INFO_NO_MSG 0
 312
 313 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2, float f3)
 314 {
 315         float handled = 0, hits = 0;
 316         if(DEATH_ISSPECIAL(deathtype))
 317         {
 318                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 319                         { if(deathtype == max(0, name)) \
 320                         { \
 321                                 #if msg_death != NO_MSG \
 322                                         if not(murder) \
 323                                         { \
 324                                                 Send_Notification_Legacy_Wrapper(NOTIF_ONE, notif_target, MSG_DEATH, msg_death, s1, s2, f1, f2, f3); \
 325                                                 Send_Notification_Legacy_Wrapper(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, f1, f2, f3); \
 326                                                 ++handled; \
 327                                         } \
 328                                 #endif \
 329                                 #if msg_death_by != NO_MSG \
 330                                         if(murder) \
 331                                         { \
 332                                                 Send_Notification_Legacy_Wrapper(NOTIF_ONE, notif_target, MSG_DEATH, msg_death_by, s1, s2, f1, f2, f3); \
 333                                                 Send_Notification_Legacy_Wrapper(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, f1, f2, f3); \
 334                                                 ++handled; \
 335                                         } \
 336                                 #endif \
 337                                 ++hits; \
 338                         } }
 339
 340                 DEATHTYPES
 341                 #undef DEATHTYPE
 342
 343                 if not(hits)
 344                 {
 345                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 346                 }
 347                 if not(handled)
 348                 {
 349                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 350                         return;
 351                 }
 352         }
 353 }
 354
 355 float w_deathtype;
 356 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1)
 357 {
 358         float death_weapon = DEATH_WEAPONOF(deathtype);
 359
 360         if(death_weapon)
 361         {
 362                 w_deathtype = deathtype;
 363                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 364                 w_deathtype = FALSE;
 365
 366                 if(death_message)
 367                 {
 368                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, notif_target, MSG_WEAPON, death_message, s1, s2, f1, NO_FL_ARG, NO_FL_ARG);
 369                         Send_Notification_Legacy_Wrapper(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, Get_Notif_Infval(MSG_WEAPON, death_message), s1, s2, f1, NO_FL_ARG, NO_FL_ARG);
 370                         //print(Get_Field_Value(F_INFVAL, MSG_WEAPON, death_message), "\n");
 371                 }
 372                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 373
 374                 return TRUE;
 375         }
 376         return FALSE;
 377 }
 378
 379 .float FRAG_VERBOSE;
 380 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 381 {
 382         // Sanity check
 383         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 384
 385         // Declarations
 386         string s1 = NO_STR_ARG, s2 = NO_STR_ARG;
 387         float f1 = NO_FL_ARG, f2 = NO_FL_ARG, f3 = NO_FL_ARG;
 388         float notif_firstblood = FALSE;
 389
 390         //dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 391
 392         // =======
 393         // SUICIDE
 394         // =======
 395         if(targ == attacker)
 396         {
 397                 if(DEATH_ISSPECIAL(deathtype))
 398                 {
 399                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 400                         {
 401                                 s1 = targ.netname;
 402                                 f1 = targ.team;
 403                         }
 404                         else
 405                         {
 406                                 switch(deathtype)
 407                                 {
 408                                         case DEATH_MIRRORDAMAGE:
 409                                         {
 410                                                 s1 = targ.netname;
 411                                                 f1 = targ.killcount;
 412                                                 break;
 413                                         }
 414
 415                                         default:
 416                                         {
 417                                                 s1 = targ.netname;
 418                                                 f1 = targ.killcount;
 419                                                 s2 = NO_STR_ARG;
 420                                                 f2 = f3 = NO_FL_ARG;
 421                                                 break;
 422                                         }
 423                                 }
 424                                 LogDeath("suicide", deathtype, targ, targ);
 425                                 GiveFrags(attacker, targ, -1, deathtype);
 426                         }
 427
 428                         Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, NO_FL_ARG);
 429                 }
 430                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, NO_STR_ARG, targ.killcount))
 431                 {
 432                         backtrace("SUICIDE: what the hell happened here?\n");
 433                 }
 434         }
 435
 436         // ======
 437         // MURDER
 438         // ======
 439         else if(attacker.classname == "player")
 440         {
 441                 s1 = attacker.netname;
 442                 s2 = targ.netname;
 443
 444                 // TODO: ADD REAL CHECK HERE!
 445                 attacker.FRAG_VERBOSE = TRUE;
 446                 targ.FRAG_VERBOSE = TRUE;
 447
 448                 if(!IsDifferentTeam(attacker, targ))
 449                 {
 450                         LogDeath("tk", deathtype, attacker, targ);
 451                         GiveFrags(attacker, targ, -1, deathtype);
 452
 453                         attacker.killcount = 0;
 454
 455                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, attacker, MSG_DEATH, DEATH_TEAMKILL_FRAG, s2, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 456                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, targ, MSG_DEATH, DEATH_TEAMKILL_FRAGGED, s1, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 457                         Send_Notification_Legacy_Wrapper(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG);
 458
 459                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 460                         // No need for specific death/weapon messages...
 461                 }
 462                 else
 463                 {
 464                         LogDeath("frag", deathtype, attacker, targ);
 465                         GiveFrags(attacker, targ, 1, deathtype);
 466
 467                         attacker.taunt_soundtime = time + 1;
 468                         attacker.killcount = attacker.killcount + 1;
 469
 470                         #define ADD_ACHIEVEMENT_CASE(numa,numb) \
 471                                 case numa: \
 472                                 { \
 473                                         AnnounceTo(attacker, strcat(#numb, "kills")); \
 474                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##numa, 1); \
 475                                         break; \
 476                                 }
 477                         switch(attacker.killcount)
 478                         {
 479                                 ADD_ACHIEVEMENT_CASE(3, 03)
 480                                 ADD_ACHIEVEMENT_CASE(5, 05)
 481                                 ADD_ACHIEVEMENT_CASE(10, 10)
 482                                 ADD_ACHIEVEMENT_CASE(15, 15)
 483                                 ADD_ACHIEVEMENT_CASE(20, 20)
 484                                 ADD_ACHIEVEMENT_CASE(25, 25)
 485                                 ADD_ACHIEVEMENT_CASE(30, 30)
 486                                 default: break;
 487                         }
 488                         #undef ADD_ACHIEVEMENT_CASE
 489
 490                         if(!checkrules_firstblood)
 491                         {
 492                                 checkrules_firstblood = TRUE;
 493                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 494                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 495                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 496                         }
 497
 498                         if(notif_firstblood) // first blood, no kill sprees yet
 499                         {
 500                                 if(targ.istypefrag)
 501                                 {
 502                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, attacker, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAG_FIRST),
 503                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 504
 505                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, targ, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAGGED_FIRST),
 506                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 507                                 }
 508                                 else
 509                                 {
 510                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, attacker, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_FIRST_VERBOSE : DEATH_MURDER_FRAG_FIRST),
 511                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 512
 513                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, targ, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_FIRST_VERBOSE : DEATH_MURDER_FRAGGED_FIRST),
 514                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 515                                 }
 516                         }
 517                         else // normal frags, kill sprees listed
 518                         {
 519                                 if(targ.istypefrag)
 520                                 {
 521                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, attacker, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_VERBOSE : DEATH_MURDER_TYPEFRAG),
 522                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 523
 524                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, targ, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_VERBOSE : DEATH_MURDER_TYPEFRAGGED),
 525                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 526                                 }
 527                                 else
 528                                 {
 529                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, attacker, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_VERBOSE : DEATH_MURDER_FRAG),
 530                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 531
 532                                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, targ, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_VERBOSE : DEATH_MURDER_FRAGGED),
 533                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 534                                 }
 535                         }
 536
 537                         //print("targ_killcount = ", ftos(targ.killcount), ", attacker_killcount = ", ftos(attacker.killcount), ".\n");
 538                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, targ.killcount))
 539                                 Obituary_SpecialDeath(targ, TRUE, deathtype, s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG);
 540                 }
 541         }
 542
 543         // =============
 544         // ACCIDENT/TRAP
 545         // =============
 546         else
 547         {
 548                 switch(deathtype)
 549                 {
 550                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 551                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 552                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 553                         /*case DEATH_HURTTRIGGER:
 554                         {
 555                                 s1 = targ.netname;
 556                                 s2 = inflictor.message;
 557                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 558                                 break;
 559                         }*/
 560
 561                         case DEATH_CUSTOM:
 562                         {
 563                                 s1 = targ.netname;
 564                                 s2 = deathmessage;
 565                                 f1 = targ.killcount;
 566                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 567                                 f2 = f3 = NO_FL_ARG;
 568                                 break;
 569                         }
 570
 571                         default:
 572                         {
 573                                 s1 = targ.netname;
 574                                 f1 = targ.killcount;
 575                                 s2 = NO_STR_ARG;
 576                                 f2 = f3 = NO_FL_ARG;
 577                                 break;
 578                         }
 579                 }
 580
 581                 LogDeath("accident", deathtype, targ, targ);
 582                 GiveFrags(targ, targ, -1, deathtype);
 583
 584                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 585                 {
 586                         AnnounceTo(targ, "botlike");
 587                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 588                 }
 589
 590                 Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, f3);
 591         }
 592
 593         // Set final information for the death
 594         targ.death_origin = targ.origin;
 595         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 596         if(targ.killcount) { targ.killcount = 0; }
 597 }
 598
 599 // these are updated by each Damage call for use in button triggering and such
 600 entity damage_targ;
 601 entity damage_inflictor;
 602 entity damage_attacker;
 603
 604 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 605 {
 606         float mirrordamage;
 607         float mirrorforce;
 608         float teamdamage0;
 609         entity attacker_save;
 610         mirrordamage = 0;
 611         mirrorforce = 0;
 612
 613         if (gameover || targ.killcount == -666)
 614                 return;
 615
 616         entity oldself;
 617         oldself = self;
 618         self = targ;
 619         damage_targ = targ;
 620         damage_inflictor = inflictor;
 621         damage_attacker = attacker;
 622                 attacker_save = attacker;
 623
 624         if(targ.classname == "player")
 625                 if(targ.hook)
 626                         if(targ.hook.aiment)
 627                                 if(targ.hook.aiment == attacker)
 628                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 629
 630         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 631         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 632         {
 633                 if(targ.classname == "player")
 634                         if not(IsDifferentTeam(targ, attacker))
 635                         {
 636                                 self = oldself;
 637                                 return;
 638                         }
 639         }
 640
 641         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 642         {
 643                 // These are ALWAYS lethal
 644                 // No damage modification here
 645                 // Instead, prepare the victim for his death...
 646                 targ.armorvalue = 0;
 647                 targ.spawnshieldtime = 0;
 648                 targ.health = 0.9; // this is < 1
 649                 targ.flags -= targ.flags & FL_GODMODE;
 650                 damage = 100000;
 651         }
 652         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 653         {
 654                 // no processing
 655         }
 656         else
 657         {
 658                 /*
 659                 skill based bot damage? gtfo. (tZork)
 660                 if (targ.classname == "player")
 661                 if (attacker.classname == "player")
 662                 if (!targ.isbot)
 663                 if (attacker.isbot)
 664                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 665         */
 666
 667                 // nullify damage if teamplay is on
 668                 if(deathtype != DEATH_TELEFRAG)
 669                 if(attacker.classname == "player")
 670                 {
 671                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 672                         {
 673                                 damage = 0;
 674                                 force = '0 0 0';
 675                         }
 676                         else if(!IsDifferentTeam(attacker, targ))
 677                         {
 678                                 if(autocvar_teamplay_mode == 1)
 679                                         damage = 0;
 680                                 else if(attacker != targ)
 681                                 {
 682                                         if(autocvar_teamplay_mode == 3)
 683                                                 damage = 0;
 684                                         else if(autocvar_teamplay_mode == 4)
 685                                         {
 686                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 687                                                 {
 688                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 689                                                         attacker.dmg_team = attacker.dmg_team + damage;
 690                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 691                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 692                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 693                                                         if(g_minstagib)
 694                                                         {
 695                                                                 if(autocvar_g_friendlyfire == 0)
 696                                                                         damage = 0;
 697                                                         }
 698                                                         else if(g_ca)
 699                                                                 damage = 0;
 700                                                         else
 701                                                                 damage = autocvar_g_friendlyfire * damage;
 702                                                         // mirrordamage will be used LATER
 703
 704                                                         if(autocvar_g_mirrordamage_virtual)
 705                                                         {
 706                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 707                                                                 attacker.dmg_take += v_x;
 708                                                                 attacker.dmg_save += v_y;
 709                                                                 attacker.dmg_inflictor = inflictor;
 710                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 711                                                                 mirrorforce = 0;
 712                                                         }
 713
 714                                                         if(autocvar_g_friendlyfire_virtual)
 715                                                         {
 716                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 717                                                                 targ.dmg_take += v_x;
 718                                                                 targ.dmg_save += v_y;
 719                                                                 targ.dmg_inflictor = inflictor;
 720                                                                 damage = 0;
 721                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 722                                                                         force = '0 0 0';
 723                                                         }
 724                                                 }
 725                                                 else
 726                                                         damage = 0;
 727                                         }
 728                                 }
 729                         }
 730                 }
 731
 732                 if(targ.classname == "player")
 733                 if(attacker.classname == "player")
 734                 if(attacker != targ)
 735                 {
 736                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 737                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 738                 }
 739
 740                 if(targ.classname == "player")
 741                 if (g_minstagib)
 742                 {
 743                         if ((deathtype == DEATH_FALL)  ||
 744                                 (deathtype == DEATH_DROWN) ||
 745                                 (deathtype == DEATH_SLIME) ||
 746                                 (deathtype == DEATH_LAVA)  ||
 747                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 748                         {
 749                                 self = oldself;
 750                                 return;
 751                         }
 752                         if(damage > 0)
 753                             damage = 10000;
 754                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 755                         {
 756                                 targ.armorvalue -= 1;
 757                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 758                                 damage = 0;
 759                                 targ.hitsound += 1;
 760                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 761                         }
 762                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 763                         {
 764                                 damage = 0;
 765                                 mirrordamage = 0;
 766                                 if (targ != attacker)
 767                                 {
 768                                         if ((targ.health >= 1) && (targ.classname == "player"))
 769                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 770                                         force = '0 0 0';
 771                                         // keep mirrorforce
 772                                         attacker = targ;
 773                                 }
 774                         }
 775                 }
 776
 777                 if not(DEATH_ISSPECIAL(deathtype))
 778                 {
 779                         damage *= g_weapondamagefactor;
 780                         mirrordamage *= g_weapondamagefactor;
 781                         force = force * g_weaponforcefactor;
 782                         mirrorforce *= g_weaponforcefactor;
 783                 }
 784
 785                 // should this be changed at all? If so, in what way?
 786                 frag_attacker = attacker;
 787                 frag_target = targ;
 788                 frag_damage = damage;
 789                 frag_force = force;
 790         frag_deathtype = deathtype;
 791                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 792                 damage = frag_damage;
 793                 force = frag_force;
 794
 795                 // apply strength multiplier
 796                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 797                 {
 798                         if(targ == attacker)
 799                         {
 800                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 801                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 802                         }
 803                         else
 804                         {
 805                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 806                                 force = force * autocvar_g_balance_powerup_strength_force;
 807                         }
 808                 }
 809
 810                 // apply invincibility multiplier
 811                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 812                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 813
 814                 if (targ == attacker)
 815                 {
 816                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 817                                 damage = 0;
 818                         else
 819                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 820                 }
 821
 822                 if(g_runematch)
 823                 {
 824                         // apply strength rune
 825                         if (attacker.runes & RUNE_STRENGTH)
 826                         {
 827                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 828                                 {
 829                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 830                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 831                                 }
 832                                 else
 833                                 {
 834                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 835                                         force = force * autocvar_g_balance_rune_strength_force;
 836                                 }
 837                         }
 838                         else if (attacker.runes & CURSE_WEAK)
 839                         {
 840                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 841                                 force = force * autocvar_g_balance_curse_weak_force;
 842                         }
 843
 844                         // apply defense rune
 845                         if (targ.runes & RUNE_DEFENSE)
 846                         {
 847                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 848                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 849                                 else
 850                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 851                         }
 852                         else if (targ.runes & CURSE_VULNER)
 853                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 854                 }
 855
 856                 // count the damage
 857                 if(attacker)
 858                 if(!targ.deadflag)
 859                 if(targ.takedamage == DAMAGE_AIM)
 860                 if(targ != attacker)
 861                 {
 862                         if(damage_headshotbonus)
 863                         {
 864                                 if(targ.classname == "player")
 865                                 {
 866                                         // HEAD SHOT:
 867                                         // find height of hit on player axis
 868                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 869                                         vector headmins, headmaxs, org;
 870                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 871                                         headmins = org + GetHeadshotMins(targ);
 872                                         headmaxs = org + GetHeadshotMaxs(targ);
 873                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 874                                         {
 875                                                 deathtype |= HITTYPE_HEADSHOT;
 876                                         }
 877                                 }
 878                                 else if(targ.classname == "turret_head")
 879                                 {
 880                                         deathtype |= HITTYPE_HEADSHOT;
 881                                 }
 882                                 if(deathtype & HITTYPE_HEADSHOT)
 883                                         if(damage_headshotbonus > 0)
 884                                                 damage *= 1 + damage_headshotbonus;
 885                         }
 886
 887                         entity victim;
 888                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 889                                 victim = targ.owner;
 890                         else
 891                                 victim = targ;
 892
 893                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 894                         {
 895                                 if(IsDifferentTeam(victim, attacker))
 896                                 {
 897                                         if(damage > 0)
 898                                         {
 899                                                 if(deathtype != DEATH_FIRE)
 900                                                 {
 901                                                         if(victim.BUTTON_CHAT)
 902                                                                 attacker.typehitsound += 1;
 903                                                         else
 904                                                                 attacker.hitsound += 1;
 905                                                 }
 906
 907                                                 damage_goodhits += 1;
 908                                                 damage_gooddamage += damage;
 909
 910                                                 if not(DEATH_ISSPECIAL(deathtype))
 911                                                 {
 912                                                         if(targ.classname == "player") // don't do this for vehicles
 913                                                         if(!g_minstagib)
 914                                                         if(IsFlying(victim))
 915                                                                 yoda = 1;
 916
 917                                                         if(g_minstagib)
 918                                                         if(victim.items & IT_STRENGTH)
 919                                                                 yoda = 1;
 920
 921                                                         if(deathtype & HITTYPE_HEADSHOT)
 922                                                                 headshot = 1;
 923                                                 }
 924                                         }
 925                                 }
 926                                 else
 927                                 {
 928                                         if(deathtype != DEATH_FIRE)
 929                                         {
 930                                                 attacker.typehitsound += 1;
 931                                         }
 932                                         if(mirrordamage > 0)
 933                                                 if(time > attacker.teamkill_complain)
 934                                                 {
 935                                                         attacker.teamkill_complain = time + 5;
 936                                                         attacker.teamkill_soundtime = time + 0.4;
 937                                                         attacker.teamkill_soundsource = targ;
 938                                                 }
 939                                 }
 940                         }
 941                 }
 942         }
 943
 944         // apply push
 945         if (self.damageforcescale)
 946         if (vlen(force))
 947         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 948         {
 949                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 950                 if(self.movetype == MOVETYPE_PHYSICS)
 951                 {
 952                         entity farcent;
 953                         farcent = spawn();
 954                         farcent.classname = "farce";
 955                         farcent.enemy = self;
 956                         farcent.movedir = farce * 10;
 957                         if(self.mass)
 958                                 farcent.movedir = farcent.movedir * self.mass;
 959                         farcent.origin = hitloc;
 960                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 961                         farcent.nextthink = time + 0.1;
 962                         farcent.think = SUB_Remove;
 963                 }
 964                 else
 965                         self.velocity = self.velocity + farce;
 966                 self.flags &~= FL_ONGROUND;
 967                 UpdateCSQCProjectile(self);
 968         }
 969         // apply damage
 970         if (damage != 0 || (self.damageforcescale && vlen(force)))
 971         if (self.event_damage)
 972                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 973         self = oldself;
 974
 975         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 976         {
 977                 if(g_runematch)
 978                 {
 979                         if (attacker.runes & RUNE_VAMPIRE)
 980                         {
 981                         // apply vampire rune
 982                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 983                                 {
 984                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 985                                         attacker.health = bound(
 986                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 987                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 988                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 989                                 }
 990                                 else
 991                                 {
 992                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 993                                         attacker.health = bound(
 994                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 995                                                                                         // empathy won't let you gain health in the same way...
 996                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 997                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 998                                         }
 999                         }
1000                         // apply empathy curse
1001                         else if (attacker.runes & CURSE_EMPATHY)
1002                         {
1003                                 attacker.health = bound(
1004                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
1005                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
1006                                         attacker.health);
1007                         }
1008                 }
1009         }
1010
1011         // apply mirror damage if any
1012         if(mirrordamage > 0 || mirrorforce > 0)
1013         {
1014                 attacker = attacker_save;
1015                 if(g_minstagib)
1016                 if(mirrordamage > 0)
1017                 {
1018                         // just lose extra LIVES, don't kill the player for mirror damage
1019                         if(attacker.armorvalue > 0)
1020                         {
1021                                 attacker.armorvalue = attacker.armorvalue - 1;
1022                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
1023                                 attacker.hitsound += 1;
1024                         }
1025                         mirrordamage = 0;
1026                 }
1027
1028                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
1029                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
1030         }
1031 }
1032
1033 float RadiusDamage_running;
1034 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
1035         // Returns total damage applies to creatures
1036 {
1037         entity  targ;
1038         vector  blastorigin;
1039         vector  force;
1040         float   total_damage_to_creatures;
1041         entity  next;
1042         float   tfloordmg;
1043         float   tfloorforce;
1044
1045         float stat_damagedone;
1046
1047         if(RadiusDamage_running)
1048         {
1049                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
1050                 return 0;
1051         }
1052
1053         RadiusDamage_running = 1;
1054
1055         tfloordmg = autocvar_g_throughfloor_damage;
1056         tfloorforce = autocvar_g_throughfloor_force;
1057
1058         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1059         total_damage_to_creatures = 0;
1060
1061         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1062                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1063                 {
1064                         force = inflictor.velocity;
1065                         if(vlen(force) == 0)
1066                                 force = '0 0 -1';
1067                         else
1068                                 force = normalize(force);
1069                         if(forceintensity >= 0)
1070                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1071                         else
1072                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1073                 }
1074
1075         stat_damagedone = 0;
1076
1077         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1078         while (targ)
1079         {
1080                 next = targ.chain;
1081                 if (targ != inflictor)
1082                         if (ignore != targ) if(targ.takedamage)
1083                         {
1084                                 vector nearest;
1085                                 vector diff;
1086                                 float power;
1087
1088                                 // LordHavoc: measure distance to nearest point on target (not origin)
1089                                 // (this guarentees 100% damage on a touch impact)
1090                                 nearest = targ.WarpZone_findradius_nearest;
1091                                 diff = targ.WarpZone_findradius_dist;
1092                                 // round up a little on the damage to ensure full damage on impacts
1093                                 // and turn the distance into a fraction of the radius
1094                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1095                                 //bprint(" ");
1096                                 //bprint(ftos(power));
1097                                 //if (targ == attacker)
1098                                 //      print(ftos(power), "\n");
1099                                 if (power > 0)
1100                                 {
1101                                         float finaldmg;
1102                                         if (power > 1)
1103                                                 power = 1;
1104                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1105                                         if (finaldmg > 0)
1106                                         {
1107                                                 float a;
1108                                                 float c;
1109                                                 vector hitloc;
1110                                                 vector myblastorigin;
1111                                                 vector center;
1112
1113                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1114
1115                                                 // if it's a player, use the view origin as reference
1116                                                 center = CENTER_OR_VIEWOFS(targ);
1117
1118                                                 force = normalize(center - myblastorigin);
1119                                                 force = force * (finaldmg / coredamage) * forceintensity;
1120                                                 hitloc = nearest;
1121
1122                                                 if(targ != directhitentity)
1123                                                 {
1124                                                         float hits;
1125                                                         float total;
1126                                                         float hitratio;
1127                                                         float mininv_f, mininv_d;
1128
1129                                                         // test line of sight to multiple positions on box,
1130                                                         // and do damage if any of them hit
1131                                                         hits = 0;
1132
1133                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1134                                                         // so for a given max stddev:
1135                                                         // n = (1 / (2 * max stddev of hitratio))^2
1136
1137                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1138                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1139
1140                                                         if(autocvar_g_throughfloor_debug)
1141                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1142
1143                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1144
1145                                                         if(autocvar_g_throughfloor_debug)
1146                                                                 print(sprintf(" steps=%f", total));
1147
1148                                                         if (targ.classname == "player")
1149                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1150                                                         else
1151                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1152
1153                                                         if(autocvar_g_throughfloor_debug)
1154                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1155
1156                                                         for(c = 0; c < total; ++c)
1157                                                         {
1158                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1159                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1160                                                                 if (trace_fraction == 1 || trace_ent == targ)
1161                                                                 {
1162                                                                         ++hits;
1163                                                                         if (hits > 1)
1164                                                                                 hitloc = hitloc + nearest;
1165                                                                         else
1166                                                                                 hitloc = nearest;
1167                                                                 }
1168                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1169                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1170                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1171                                                         }
1172
1173                                                         nearest = hitloc * (1 / max(1, hits));
1174                                                         hitratio = (hits / total);
1175                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1176                                                         finaldmg = finaldmg * a;
1177                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1178                                                         force = force * a;
1179
1180                                                         if(autocvar_g_throughfloor_debug)
1181                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1182                                                 }
1183
1184                                                 // laser force adjustments :P
1185                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1186                                                 {
1187                                                         if (targ == attacker)
1188                                                         {
1189                                                                 vector vel;
1190
1191                                                                 float force_zscale;
1192                                                                 float force_velocitybiasramp;
1193                                                                 float force_velocitybias;
1194
1195                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1196                                                                 if(deathtype & HITTYPE_SECONDARY)
1197                                                                 {
1198                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1199                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1200                                                                 }
1201                                                                 else
1202                                                                 {
1203                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1204                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1205                                                                 }
1206
1207                                                                 vel = targ.velocity;
1208                                                                 vel_z = 0;
1209                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1210                                                                 force =
1211                                                                         vlen(force)
1212                                                                         *
1213                                                                         normalize(normalize(force) + vel);
1214
1215                                                                 force_z *= force_zscale;
1216                                                         }
1217                                                         else
1218                                                         {
1219                                                                 if(deathtype & HITTYPE_SECONDARY)
1220                                                                 {
1221                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1222                                                                 }
1223                                                                 else
1224                                                                 {
1225                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1226                                                                 }
1227                                                         }
1228                                                 }
1229
1230                                                 //if (targ == attacker)
1231                                                 //{
1232                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1233                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1234                                                 //      print(" (", ftos(a), ")\n");
1235                                                 //}
1236                                                 if(finaldmg || vlen(force))
1237                                                 {
1238                                                         if(targ.iscreature)
1239                                                         {
1240                                                                 total_damage_to_creatures += finaldmg;
1241
1242                                                                 if(accuracy_isgooddamage(attacker, targ))
1243                                                                         stat_damagedone += finaldmg;
1244                                                         }
1245
1246                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1247                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1248                                                         else
1249                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1250                                                 }
1251                                         }
1252                                 }
1253                         }
1254                 targ = next;
1255         }
1256
1257         RadiusDamage_running = 0;
1258
1259         if(!DEATH_ISSPECIAL(deathtype))
1260                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1261
1262         return total_damage_to_creatures;
1263 }
1264
1265 .float fire_damagepersec;
1266 .float fire_endtime;
1267 .float fire_deathtype;
1268 .entity fire_owner;
1269 .float fire_hitsound;
1270 .entity fire_burner;
1271
1272 void fireburner_think();
1273
1274 float Fire_IsBurning(entity e)
1275 {
1276         return (time < e.fire_endtime);
1277 }
1278
1279 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1280 {
1281         float dps;
1282         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1283
1284         if(e.classname == "player")
1285         {
1286                 if(e.deadflag)
1287                         return -1;
1288         }
1289         else
1290         {
1291                 if(!e.fire_burner)
1292                 {
1293                         // print("adding a fire burner to ", e.classname, "\n");
1294                         e.fire_burner = spawn();
1295                         e.fire_burner.classname = "fireburner";
1296                         e.fire_burner.think = fireburner_think;
1297                         e.fire_burner.nextthink = time;
1298                         e.fire_burner.owner = e;
1299                 }
1300         }
1301
1302         t = max(t, 0.1);
1303         dps = d / t;
1304         if(Fire_IsBurning(e))
1305         {
1306                 mintime = e.fire_endtime - time;
1307                 maxtime = max(mintime, t);
1308
1309                 mindps = e.fire_damagepersec;
1310                 maxdps = max(mindps, dps);
1311
1312                 if(maxtime > mintime || maxdps > mindps)
1313                 {
1314                         // Constraints:
1315
1316                         // damage we have right now
1317                         mindamage = mindps * mintime;
1318
1319                         // damage we want to get
1320                         maxdamage = mindamage + d;
1321
1322                         // but we can't exceed maxtime * maxdps!
1323                         totaldamage = min(maxdamage, maxtime * maxdps);
1324
1325                         // LEMMA:
1326                         // Look at:
1327                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1328                         // We see:
1329                         // totaldamage <= maxtime * maxdps
1330                         // ==> totaldamage / maxdps <= maxtime.
1331                         // We also see:
1332                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1333                         //                     >= min(mintime, maxtime)
1334                         // ==> totaldamage / maxdps >= mintime.
1335
1336                         /*
1337                         // how long do we damage then?
1338                         // at least as long as before
1339                         // but, never exceed maxdps
1340                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1341                         */
1342
1343                         // alternate:
1344                         // at most as long as maximum allowed
1345                         // but, never below mindps
1346                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1347
1348                         // assuming t > mintime, dps > mindps:
1349                         // we get d = t * dps = maxtime * maxdps
1350                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1351                         // totaldamage / maxdps = maxtime
1352                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1353                         // FROM THIS:
1354                         // a) totaltime = max(mintime, maxtime) = maxtime
1355                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1356
1357                         // assuming t <= mintime:
1358                         // we get maxtime = mintime
1359                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1360                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1361
1362                         // assuming dps <= mindps:
1363                         // we get mindps = maxdps.
1364                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1365                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1366                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1367
1368                         e.fire_damagepersec = totaldamage / totaltime;
1369                         e.fire_endtime = time + totaltime;
1370                         if(totaldamage > 1.2 * mindamage)
1371                         {
1372                                 e.fire_deathtype = dt;
1373                                 if(e.fire_owner != o)
1374                                 {
1375                                         e.fire_owner = o;
1376                                         e.fire_hitsound = FALSE;
1377                                 }
1378                         }
1379                         if(accuracy_isgooddamage(o, e))
1380                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1381                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1382                 }
1383                 else
1384                         return 0;
1385         }
1386         else
1387         {
1388                 e.fire_damagepersec = dps;
1389                 e.fire_endtime = time + t;
1390                 e.fire_deathtype = dt;
1391                 e.fire_owner = o;
1392                 e.fire_hitsound = FALSE;
1393                 if(accuracy_isgooddamage(o, e))
1394                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1395                 return d;
1396         }
1397 }
1398
1399 void Fire_ApplyDamage(entity e)
1400 {
1401         float t, d, hi, ty;
1402         entity o;
1403
1404         if not(Fire_IsBurning(e))
1405                 return;
1406
1407         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1408         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1409                 o = e.fire_owner;
1410
1411         // water and slime stop fire
1412         if(e.waterlevel)
1413         if(e.watertype != CONTENT_LAVA)
1414                 e.fire_endtime = 0;
1415
1416         // ice stops fire
1417         if(e.freezetag_frozen)
1418                 e.fire_endtime = 0;
1419
1420         t = min(frametime, e.fire_endtime - time);
1421         d = e.fire_damagepersec * t;
1422
1423         hi = e.fire_owner.hitsound;
1424         ty = e.fire_owner.typehitsound;
1425         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1426         if(e.fire_hitsound && e.fire_owner)
1427         {
1428                 e.fire_owner.hitsound = hi;
1429                 e.fire_owner.typehitsound = ty;
1430         }
1431         e.fire_hitsound = TRUE;
1432
1433         if not(IS_INDEPENDENT_PLAYER(e))
1434         FOR_EACH_PLAYER(other) if(e != other)
1435         {
1436                 if(other.classname == "player")
1437                 if(other.deadflag == DEAD_NO)
1438                 if not(IS_INDEPENDENT_PLAYER(other))
1439                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1440                 {
1441                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1442                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1443                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1444                 }
1445         }
1446 }
1447
1448 void Fire_ApplyEffect(entity e)
1449 {
1450         if(Fire_IsBurning(e))
1451                 e.effects |= EF_FLAME;
1452         else
1453                 e.effects &~= EF_FLAME;
1454 }
1455
1456 void fireburner_think()
1457 {
1458         // for players, this is done in the regular loop
1459         if(wasfreed(self.owner))
1460         {
1461                 remove(self);
1462                 return;
1463         }
1464         Fire_ApplyEffect(self.owner);
1465         if(!Fire_IsBurning(self.owner))
1466         {
1467                 self.owner.fire_burner = world;
1468                 remove(self);
1469                 return;
1470         }
1471         Fire_ApplyDamage(self.owner);
1472         self.nextthink = time;
1473 }