qcsrc/server/g_hook.qc

   1 /*============================================
   2
   3       Wazat's Xonotic Grappling Hook
   4
   5         Contact: Wazat1@gmail.com
   6
   7
   8 Installation instructions:
   9 --------------------------
  10
  11 1. Place hook.c in your gamec source directory with the other source files.
  12
  13 2. Add this line to the bottom of progs.src:
  14
  15 gamec/hook.c
  16
  17 3. Open defs.h and add these lines to the very bottom:
  18
  19 // Wazat's grappling hook
  20 .entity         hook;
  21 void GrapplingHookFrame();
  22 void RemoveGrapplingHook(entity pl);
  23 void SetGrappleHookBindings();
  24 // hook impulses
  25 float GRAPHOOK_FIRE             = 20;
  26 float GRAPHOOK_RELEASE          = 21;
  27 // (note: you can change the hook impulse #'s to whatever you please)
  28
  29 4. Open client.c and add this to the top of PutClientInServer():
  30
  31         RemoveGrapplingHook(self); // Wazat's Grappling Hook
  32
  33 5. Find ClientConnect() (in client.c) and add these lines to the bottom:
  34
  35         // Wazat's grappling hook
  36         SetGrappleHookBindings();
  37
  38 6. Still in client.c, find PlayerPreThink and add this line just above the call to W_WeaponFrame:
  39
  40         GrapplingHookFrame();
  41
  42 7. Build and test the mod.  You'll want to bind a key to "+hook" like this:
  43 bind ctrl "+hook"
  44
  45 And you should be done!
  46
  47
  48 ============================================*/
  49
  50 .float hook_length;
  51 .float hook_switchweapon;
  52
  53 void RemoveGrapplingHook(entity pl)
  54 {
  55         if(pl.hook == world)
  56                 return;
  57         remove(pl.hook);
  58         pl.hook = world;
  59         if(pl.movetype == MOVETYPE_FLY)
  60                 pl.movetype = MOVETYPE_WALK;
  61
  62         //pl.disableclientprediction = FALSE;
  63 }
  64
  65 void GrapplingHookReset(void)
  66 {
  67         if(self.realowner.hook == self)
  68                 RemoveGrapplingHook(self.owner);
  69         else // in any case:
  70                 remove(self);
  71 }
  72
  73 void GrapplingHookThink();
  74 void GrapplingHook_Stop()
  75 {
  76         pointparticles(particleeffectnum("grapple_impact"), self.origin, '0 0 0', 1);
  77         sound (self, CH_SHOTS, "weapons/hook_impact.wav", VOL_BASE, ATTN_NORM);
  78
  79         self.state = 1;
  80         self.think = GrapplingHookThink;
  81         self.nextthink = time;
  82         self.touch = SUB_Null;
  83         self.velocity = '0 0 0';
  84         self.movetype = MOVETYPE_NONE;
  85         self.hook_length = -1;
  86 }
  87
  88 .vector hook_start, hook_end;
  89 float GrapplingHookSend(entity to, float sf)
  90 {
  91         WriteByte(MSG_ENTITY, ENT_CLIENT_HOOK);
  92         sf = sf & 0x7F;
  93         if(sound_allowed(MSG_BROADCAST, self.realowner))
  94                 sf |= 0x80;
  95         WriteByte(MSG_ENTITY, sf);
  96         if(sf & 1)
  97         {
  98                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
  99         }
 100         if(sf & 2)
 101         {
 102                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 103                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 104                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 105         }
 106         if(sf & 4)
 107         {
 108                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 109                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 110                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 111         }
 112         return TRUE;
 113 }
 114
 115 void GrapplingHookThink()
 116 {
 117         float spd, dist, minlength, pullspeed, ropestretch, ropeairfriction, rubberforce, newlength, rubberforce_overstretch, s;
 118         vector dir, org, end, v0, dv, v, myorg, vs;
 119         if(self.realowner.hook != self) // how did that happen?
 120         {
 121                 error("Owner lost the hook!\n");
 122                 return;
 123         }
 124         if(LostMovetypeFollow(self) || intermission_running)
 125         {
 126                 RemoveGrapplingHook(self.realowner);
 127                 return;
 128         }
 129         if(self.aiment)
 130                 WarpZone_RefSys_AddIncrementally(self, self.aiment);
 131
 132         self.nextthink = time;
 133
 134         s = self.realowner.cvar_cl_gunalign;
 135         if(s != 1 && s != 2 && s != 4)
 136                 s = 3; // default value
 137         --s;
 138         vs = hook_shotorigin[s];
 139
 140         makevectors(self.realowner.v_angle);
 141         org = self.realowner.origin + self.realowner.view_ofs + v_forward * vs_x + v_right * -vs_y + v_up * vs_z;
 142         myorg = WarpZone_RefSys_TransformOrigin(self.realowner, self, org);
 143
 144         if(self.hook_length < 0)
 145                 self.hook_length = vlen(myorg - self.origin);
 146
 147         if(self.state == 1)
 148         {
 149                 pullspeed = autocvar_g_balance_grapplehook_speed_pull;//2000;
 150                 // speed the rope is pulled with
 151
 152                 rubberforce = autocvar_g_balance_grapplehook_force_rubber;//2000;
 153                 // force the rope will use if it is stretched
 154
 155                 rubberforce_overstretch = autocvar_g_balance_grapplehook_force_rubber_overstretch;//1000;
 156                 // force the rope will use if it is stretched
 157
 158                 minlength = autocvar_g_balance_grapplehook_length_min;//100;
 159                 // minimal rope length
 160                 // if the rope goes below this length, it isn't pulled any more
 161
 162                 ropestretch = autocvar_g_balance_grapplehook_stretch;//400;
 163                 // if the rope is stretched by more than this amount, more rope is
 164                 // given to you again
 165
 166                 ropeairfriction = autocvar_g_balance_grapplehook_airfriction;//0.2
 167                 // while hanging on the rope, this friction component will help you a
 168                 // bit to control the rope
 169
 170                 dir = self.origin - myorg;
 171                 dist = vlen(dir);
 172                 dir = normalize(dir);
 173
 174                 if(autocvar_g_grappling_hook_tarzan)
 175                 {
 176                         v = v0 = WarpZone_RefSys_TransformVelocity(self.realowner, self, self.realowner.velocity);
 177
 178                         // first pull the rope...
 179                         if(self.realowner.hook_state & HOOK_PULLING)
 180                         {
 181                                 newlength = self.hook_length;
 182                                 newlength = max(newlength - pullspeed * frametime, minlength);
 183
 184                                 if(newlength < dist - ropestretch) // overstretched?
 185                                 {
 186                                         newlength = dist - ropestretch;
 187                                         if(v * dir < 0) // only if not already moving in hook direction
 188                                                 v = v + frametime * dir * rubberforce_overstretch;
 189                                 }
 190
 191                                 self.hook_length = newlength;
 192                         }
 193
 194                         if(self.realowner.hook_state & HOOK_RELEASING)
 195                         {
 196                                 newlength = dist;
 197                                 self.hook_length = newlength;
 198                         }
 199                         else
 200                         {
 201                                 // then pull the player
 202                                 spd = bound(0, (dist - self.hook_length) / ropestretch, 1);
 203                                 v = v * (1 - frametime * ropeairfriction);
 204                                 v = v + frametime * dir * spd * rubberforce;
 205
 206                                 dv = ((v - v0) * dir) * dir;
 207                                 if(autocvar_g_grappling_hook_tarzan >= 2)
 208                                 {
 209                                         if(self.aiment.movetype == MOVETYPE_WALK)
 210                                         {
 211                                                 v = v - dv * 0.5;
 212                                                 self.aiment.velocity = self.aiment.velocity - dv * 0.5;
 213                                                 self.aiment.flags &~= FL_ONGROUND;
 214                                                 self.aiment.pusher = self.realowner;
 215                                                 self.aiment.pushltime = time + autocvar_g_maxpushtime;
 216                                         }
 217                                 }
 218
 219                                 self.realowner.flags &~= FL_ONGROUND;
 220                         }
 221
 222                         self.realowner.velocity = WarpZone_RefSys_TransformVelocity(self, self.realowner, v);
 223                 }
 224                 else
 225                 {
 226                         end = self.origin - dir*50;
 227                         dist = vlen(end - myorg);
 228                         if(dist < 200)
 229                                 spd = dist * (pullspeed / 200);
 230                         else
 231                                 spd = pullspeed;
 232                         if(spd < 50)
 233                                 spd = 0;
 234                         self.realowner.velocity = dir*spd;
 235                         self.realowner.movetype = MOVETYPE_FLY;
 236
 237                         self.realowner.flags &~= FL_ONGROUND;
 238                 }
 239         }
 240
 241         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 242         myorg = WarpZone_RefSys_TransformOrigin(self, self.realowner, self.origin); // + v_forward * (-9);
 243
 244         if(myorg != self.hook_start)
 245         {
 246                 self.SendFlags |= 2;
 247                 self.hook_start = myorg;
 248         }
 249         if(org != self.hook_end)
 250         {
 251                 self.SendFlags |= 4;
 252                 self.hook_end = org;
 253         }
 254 }
 255
 256 void GrapplingHookTouch (void)
 257 {
 258         PROJECTILE_TOUCH;
 259
 260         GrapplingHook_Stop();
 261
 262         if(other)
 263                 if(other.movetype != MOVETYPE_NONE)
 264                 {
 265                         SetMovetypeFollow(self, other);
 266                         WarpZone_RefSys_BeginAddingIncrementally(self, self.aiment);
 267                 }
 268
 269         //self.realowner.disableclientprediction = TRUE;
 270 }
 271
 272 void GrapplingHook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 273 {
 274         if(self.health <= 0)
 275                 return;
 276
 277         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 278                 return; // g_balance_projectiledamage says to halt
 279
 280         self.health = self.health - damage;
 281
 282         if (self.health <= 0)
 283         {
 284                 if(attacker != self.realowner)
 285                 {
 286                         self.realowner.pusher = attacker;
 287                         self.realowner.pushltime = time + autocvar_g_maxpushtime;
 288                 }
 289                 RemoveGrapplingHook(self.realowner);
 290         }
 291 }
 292
 293 void FireGrapplingHook (void)
 294 {
 295         entity missile;
 296         vector org;
 297         float s;
 298         vector vs;
 299
 300         if((arena_roundbased && time < warmup) || (time < game_starttime))
 301                 return;
 302
 303   if(self.freezetag_frozen)
 304                 return;
 305
 306         if(self.vehicle)
 307                 return;
 308
 309         makevectors(self.v_angle);
 310
 311         s = self.cvar_cl_gunalign;
 312         if(s != 1 && s != 2 && s != 4)
 313                 s = 3; // default value
 314         --s;
 315         vs = hook_shotorigin[s];
 316
 317         // UGLY WORKAROUND: play this on CH_WEAPON_B so it can't cut off fire sounds
 318         sound (self, CH_WEAPON_B, "weapons/hook_fire.wav", VOL_BASE, ATTN_NORM);
 319         org = self.origin + self.view_ofs + v_forward * vs_x + v_right * -vs_y + v_up * vs_z;
 320
 321         tracebox(self.origin + self.view_ofs, '-3 -3 -3', '3 3 3', org, MOVE_NORMAL, self);
 322         org = trace_endpos;
 323
 324         pointparticles(particleeffectnum("grapple_muzzleflash"), org, '0 0 0', 1);
 325
 326         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 327         missile.owner = missile.realowner = self;
 328         self.hook = missile;
 329         missile.reset = GrapplingHookReset;
 330         missile.classname = "grapplinghook";
 331         missile.flags = FL_PROJECTILE;
 332
 333         missile.movetype = MOVETYPE_FLY;
 334         PROJECTILE_MAKETRIGGER(missile);
 335
 336         //setmodel (missile, "models/hook.md3"); // precision set below
 337         setsize (missile, '-3 -3 -3', '3 3 3');
 338         setorigin (missile, org);
 339
 340         missile.state = 0; // not latched onto anything
 341
 342         W_SetupProjectileVelocityEx(missile, v_forward, v_up, autocvar_g_balance_grapplehook_speed_fly, 0, 0, 0, FALSE);
 343
 344         missile.angles = vectoangles (missile.velocity);
 345         //missile.glow_color = 250; // 244, 250
 346         //missile.glow_size = 120;
 347         missile.touch = GrapplingHookTouch;
 348         missile.think = GrapplingHookThink;
 349         missile.nextthink = time;
 350
 351         missile.effects = /*EF_FULLBRIGHT | EF_ADDITIVE |*/ EF_LOWPRECISION;
 352
 353         missile.health = autocvar_g_balance_grapplehook_health;//120
 354         missile.event_damage = GrapplingHook_Damage;
 355         missile.takedamage = DAMAGE_AIM;
 356         missile.damageforcescale = 0;
 357         missile.damagedbycontents = (autocvar_g_balance_grapplehook_damagedbycontents);
 358
 359         missile.hook_start = missile.hook_end = missile.origin;
 360
 361         Net_LinkEntity(missile, FALSE, 0, GrapplingHookSend);
 362 }
 363
 364 //  void GrapplingHookFrame()
 365 //  {
 366 //         // this function has been modified for Xonotic
 367 // -       if (self.BUTTON_HOOK && g_grappling_hook)
 368 //         {
 369 // -               if (!self.hook && self.hook_time <= time && !self.button6_pressed_before)
 370 // -                       if (timeoutStatus != 2) //only allow the player to fire the grappling hook if the game is not paused (timeout)
 371 // -                               FireGrapplingHook();
 372 //         }
 373 // -       else
 374 //         {
 375 //                 if (self.hook)
 376 //                         RemoveGrapplingHook(self);
 377 //         }
 378 // -       self.button6_pressed_before = self.BUTTON_HOOK;
 379 //         /*
 380 //         // if I have no hook or it's not pulling yet, make sure I'm not flying!
 381 //         if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 382
 383 void GrapplingHookFrame()
 384 {
 385         if(g_grappling_hook && timeout_status != TIMEOUT_ACTIVE && self.weapon != WEP_HOOK)
 386         {
 387                 // offhand hook controls
 388                 if(self.BUTTON_HOOK)
 389                 {
 390                         if not(self.hook || (self.hook_state & HOOK_WAITING_FOR_RELEASE))
 391                         {
 392                                 self.hook_state |= HOOK_FIRING;
 393                                 self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 394                         }
 395                 }
 396                 else
 397                 {
 398                         self.hook_state |= HOOK_REMOVING;
 399                         self.hook_state &~= HOOK_WAITING_FOR_RELEASE;
 400                 }
 401
 402                 self.hook_state &~= HOOK_RELEASING;
 403                 if(self.BUTTON_CROUCH)
 404                 {
 405                         self.hook_state &~= HOOK_PULLING;
 406                         //self.hook_state |= HOOK_RELEASING;
 407                 }
 408                 else
 409                 {
 410                         self.hook_state |= HOOK_PULLING;
 411                         //self.hook_state &~= HOOK_RELEASING;
 412                 }
 413         }
 414         else if(!(self.items & IT_JETPACK) && !g_grappling_hook && self.switchweapon != WEP_HOOK)
 415         {
 416                 if(self.BUTTON_HOOK && !self.hook_switchweapon)
 417                         W_SwitchWeapon(WEP_HOOK);
 418         }
 419         self.hook_switchweapon = self.BUTTON_HOOK;
 420
 421         if(!g_grappling_hook && self.weapon != WEP_HOOK)
 422         {
 423                 self.hook_state &~= HOOK_FIRING;
 424                 self.hook_state |= HOOK_REMOVING;
 425         }
 426
 427         if (self.hook_state & HOOK_FIRING)
 428         {
 429                 if (self.hook)
 430                         RemoveGrapplingHook(self);
 431                 FireGrapplingHook();
 432                 self.hook_state &~= HOOK_FIRING;
 433         }
 434         else if(self.hook_state & HOOK_REMOVING)
 435         {
 436                 if (self.hook)
 437                         RemoveGrapplingHook(self);
 438                 self.hook_state &~= HOOK_REMOVING;
 439         }
 440
 441         /*
 442         // if I have no hook or it's not pulling yet, make sure I'm not flying!
 443         if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 444         {
 445                 self.movetype = MOVETYPE_WALK;
 446         }
 447         if(self.impulse == GRAPHOOK_FIRE && self.hook_time <= time && g_grappling_hook)
 448         {
 449                 // fire hook
 450                 FireGrapplingHook();
 451                 return;
 452         }
 453         else if(self.hookimpulse == GRAPHOOK_RELEASE)
 454         {
 455                 // remove hook, reset movement type
 456                 RemoveGrapplingHook(self);
 457                 return;
 458         }
 459         */
 460         /*else // make sure the player's movetype is correct
 461         {
 462                 //if(self.hook == world && self.movetype == MOVETYPE_FLY)
 463                 if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 464                 {
 465                         self.movetype = MOVETYPE_WALK;
 466                 }
 467         }*/
 468         // note: The hook entity does the actual pulling
 469 }
 470
 471 void GrappleHookInit()
 472 {
 473         if(g_grappling_hook)
 474         {
 475                 hook_shotorigin[0] = '8 8 -12';
 476                 hook_shotorigin[1] = '8 8 -12';
 477                 hook_shotorigin[2] = '8 8 -12';
 478                 hook_shotorigin[3] = '8 8 -12';
 479         }
 480         else
 481         {
 482                 weapon_action(WEP_HOOK, WR_PRECACHE);
 483                 hook_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK), FALSE, FALSE, 1);
 484                 hook_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK), FALSE, FALSE, 2);
 485                 hook_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK), FALSE, FALSE, 3);
 486                 hook_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK), FALSE, FALSE, 4);
 487         }
 488 }
 489
 490 void SetGrappleHookBindings()
 491 {
 492         // this function has been modified for Xonotic
 493         // don't remove these lines! old server or demos coud overwrite the new aliases
 494         stuffcmd(self, "alias +hook +button6\n");
 495         stuffcmd(self, "alias -hook -button6\n");
 496 }