qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void fteqcc_testbugs()
  85 {
  86         float a, b;
  87
  88         if(!autocvar_developer_fteqccbugs)
  89                 return;
  90
  91         dprint("*** fteqcc test: checking for bugs...\n");
  92
  93         a = 1;
  94         b = 5;
  95         if(sqrt(a) - sqrt(b - a) == 0)
  96                 dprint("*** fteqcc test: found same-function-twice bug\n");
  97         else
  98                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  99
 100         world.cnt = -10;
 101         world.enemy = world;
 102         world.enemy.cnt += 10;
 103         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 104                 dprint("*** fteqcc test: found += bug\n");
 105         else
 106                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 107         world.cnt = 0;
 108 }
 109
 110 void GotoFirstMap()
 111 {
 112         float n;
 113         if(autocvar__sv_init)
 114         {
 115                 // cvar_set("_sv_init", "0");
 116                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 117                 // to this "init" map on a dedicated server will cause no permanent
 118                 // harm
 119                 if(autocvar_g_maplist_shuffle)
 120                         ShuffleMaplist();
 121                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 122                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 123
 124                 MapInfo_Enumerate();
 125                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 126
 127                 if(!DoNextMapOverride(1))
 128                         GotoNextMap(1);
 129
 130                 return;
 131         }
 132
 133         if(time < 5)
 134         {
 135                 self.nextthink = time;
 136         }
 137         else
 138         {
 139                 self.nextthink = time + 1;
 140                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 141         }
 142 }
 143
 144 void cvar_changes_init()
 145 {
 146         float h;
 147         string k, v, d;
 148         float n, i, adding, pureadding;
 149
 150         if(cvar_changes)
 151                 strunzone(cvar_changes);
 152         cvar_changes = string_null;
 153         if(cvar_purechanges)
 154                 strunzone(cvar_purechanges);
 155         cvar_purechanges = string_null;
 156         cvar_purechanges_count = 0;
 157
 158         h = buf_create();
 159         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 160         n = buf_getsize(h);
 161
 162         adding = TRUE;
 163         pureadding = TRUE;
 164
 165         for(i = 0; i < n; ++i)
 166         {
 167                 k = bufstr_get(h, i);
 168
 169 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 170 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 171 #define BADCVAR(p) if(k == p) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("g_maplist_index");
 182                 BADCVAR("halflifebsp");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing visible
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("g_balance_kill_delay");
 306                 BADCVAR("g_ca_point_leadlimit");
 307                 BADCVAR("g_ctf_captimerecord_always");
 308                 BADCVAR("g_ctf_flag_glowtrails");
 309                 BADCVAR("g_ctf_flag_pickup_verbosename");
 310                 BADCVAR("g_domination_point_leadlimit");
 311                 BADCVAR("g_forced_respawn");
 312                 BADCVAR("g_keyhunt_point_leadlimit");
 313                 BADPREFIX("g_mod_");
 314                 BADCVAR("g_nexball_goalleadlimit");
 315                 BADCVAR("leadlimit_and_fraglimit");
 316                 BADCVAR("leadlimit_override");
 317                 BADCVAR("pausable");
 318                 BADCVAR("sv_allow_fullbright");
 319                 BADCVAR("sv_checkforpacketsduringsleep");
 320                 BADCVAR("sv_fraginfo");
 321                 BADCVAR("sv_timeout");
 322                 BADPREFIX("sv_timeout_");
 323                 BADPREFIX("crypto_");
 324                 BADPREFIX("g_chat_");
 325                 BADPREFIX("g_ctf_captimerecord_");
 326                 BADPREFIX("g_maplist_votable_");
 327                 BADPREFIX("net_");
 328                 BADPREFIX("prvm_");
 329                 BADPREFIX("skill_");
 330                 BADPREFIX("sv_cullentities_");
 331                 BADPREFIX("sv_fraginfo_");
 332                 BADPREFIX("sv_maxidle_");
 333                 BADPREFIX("sv_vote_");
 334                 BADPREFIX("timelimit_");
 335                 BADCVAR("gameversion");
 336                 BADPREFIX("gameversion_");
 337                 BADCVAR("sv_namechangetimer");
 338
 339                 // allowed changes to server admins (please sync this to server.cfg)
 340                 // vi commands:
 341                 //   :/"impure"/,$d
 342                 //   :g!,^\/\/[^ /],d
 343                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 344                 //   :%!sort
 345                 // yes, this does contain some redundant stuff, don't really care
 346                 BADCVAR("bot_config_file");
 347                 BADCVAR("bot_number");
 348                 BADCVAR("bot_prefix");
 349                 BADCVAR("bot_suffix");
 350                 BADCVAR("capturelimit_override");
 351                 BADCVAR("fraglimit_override");
 352                 BADCVAR("gametype");
 353                 BADCVAR("g_antilag");
 354                 BADCVAR("g_balance_teams");
 355                 BADCVAR("g_balance_teams_prevent_imbalance");
 356                 BADCVAR("g_balance_teams_scorefactor");
 357                 BADCVAR("g_ban_sync_trusted_servers");
 358                 BADCVAR("g_ban_sync_uri");
 359                 BADCVAR("g_ca_teams_override");
 360                 BADCVAR("g_ctf_ignore_frags");
 361                 BADCVAR("g_domination_point_limit");
 362                 BADCVAR("g_freezetag_teams_override");
 363                 BADCVAR("g_friendlyfire");
 364                 BADCVAR("g_fullbrightitems");
 365                 BADCVAR("g_fullbrightplayers");
 366                 BADCVAR("g_keyhunt_point_limit");
 367                 BADCVAR("g_keyhunt_teams_override");
 368                 BADCVAR("g_lms_lives_override");
 369                 BADCVAR("g_maplist");
 370                 BADCVAR("g_maplist_check_waypoints");
 371                 BADCVAR("g_maplist_mostrecent_count");
 372                 BADCVAR("g_maplist_shuffle");
 373                 BADCVAR("g_maplist_votable");
 374                 BADCVAR("g_maplist_votable_abstain");
 375                 BADCVAR("g_maplist_votable_nodetail");
 376                 BADCVAR("g_maplist_votable_suggestions");
 377                 BADCVAR("g_maxplayers");
 378                 BADCVAR("g_mirrordamage");
 379                 BADCVAR("g_nexball_goallimit");
 380                 BADCVAR("g_powerups");
 381                 BADCVAR("g_start_delay");
 382                 BADCVAR("g_warmup");
 383                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 384                 BADCVAR("hostname");
 385                 BADCVAR("log_file");
 386                 BADCVAR("maxplayers");
 387                 BADCVAR("minplayers");
 388                 BADCVAR("net_address");
 389                 BADCVAR("port");
 390                 BADCVAR("rcon_password");
 391                 BADCVAR("rcon_restricted_commands");
 392                 BADCVAR("rcon_restricted_password");
 393                 BADCVAR("skill");
 394                 BADCVAR("sv_adminnick");
 395                 BADCVAR("sv_autoscreenshot");
 396                 BADCVAR("sv_autotaunt");
 397                 BADCVAR("sv_curl_defaulturl");
 398                 BADCVAR("sv_defaultcharacter");
 399                 BADCVAR("sv_defaultplayercolors");
 400                 BADCVAR("sv_defaultplayermodel");
 401                 BADCVAR("sv_defaultplayerskin");
 402                 BADCVAR("sv_maxidle");
 403                 BADCVAR("sv_maxrate");
 404                 BADCVAR("sv_motd");
 405                 BADCVAR("sv_public");
 406                 BADCVAR("sv_ready_restart");
 407                 BADCVAR("sv_status_privacy");
 408                 BADCVAR("sv_taunt");
 409                 BADCVAR("sv_vote_call");
 410                 BADCVAR("sv_vote_commands");
 411                 BADCVAR("sv_vote_majority_factor");
 412                 BADCVAR("sv_vote_master");
 413                 BADCVAR("sv_vote_master_commands");
 414                 BADCVAR("sv_vote_master_password");
 415                 BADCVAR("sv_vote_simple_majority_factor");
 416                 BADCVAR("teamplay_mode");
 417                 BADCVAR("timelimit_override");
 418                 BADCVAR("g_spawnshieldtime");
 419                 BADPREFIX("g_warmup_");
 420                 BADPREFIX("sv_ready_restart_");
 421
 422                 // mutators that announce themselves properly to the server browser
 423                 BADCVAR("g_instagib");
 424                 BADCVAR("g_new_toys");
 425                 BADCVAR("g_nix");
 426                 BADCVAR("g_grappling_hook");
 427                 BADCVAR("g_jetpack");
 428
 429 #undef BADPREFIX
 430 #undef BADCVAR
 431
 432                 if(pureadding)
 433                 {
 434                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 435                         if(strlen(cvar_purechanges) > 16384)
 436                         {
 437                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 438                                 pureadding = 0;
 439                         }
 440                 }
 441                 ++cvar_purechanges_count;
 442                 // WARNING: this variable is used for the server list
 443                 // NEVER dare to skip this code!
 444                 // Hacks to intentionally appearing as "pure server" even though you DO have
 445                 // modified settings may be punished by removal from the server list.
 446                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 447                 // though.
 448         }
 449         buf_del(h);
 450         if(cvar_changes == "")
 451                 cvar_changes = "// this server runs at default server settings\n";
 452         else
 453                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 454         cvar_changes = strzone(cvar_changes);
 455         if(cvar_purechanges == "")
 456                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 457         else
 458                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 459         cvar_purechanges = strzone(cvar_purechanges);
 460 }
 461
 462 void detect_maptype()
 463 {
 464 #if 0
 465         vector o, v;
 466         float i;
 467
 468         for(;;)
 469         {
 470                 o = world.mins;
 471                 o_x += random() * (world.maxs_x - world.mins_x);
 472                 o_y += random() * (world.maxs_y - world.mins_y);
 473                 o_z += random() * (world.maxs_z - world.mins_z);
 474
 475                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 476                 if(trace_fraction == 1)
 477                         continue;
 478
 479                 v = trace_endpos;
 480
 481                 for(i = 0; i < 64; i += 4)
 482                 {
 483                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 484         if(trace_fraction == 1)
 485                 continue;
 486                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 487                 }
 488
 489                 break;
 490         }
 491 #endif
 492 }
 493
 494 entity randomseed;
 495 float RandomSeed_Send(entity to, float sf)
 496 {
 497         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 498         WriteShort(MSG_ENTITY, self.cnt);
 499         return TRUE;
 500 }
 501 void RandomSeed_Think()
 502 {
 503         self.cnt = bound(0, floor(random() * 65536), 65535);
 504         self.nextthink = time + 5;
 505
 506         self.SendFlags |= 1;
 507 }
 508 void RandomSeed_Spawn()
 509 {
 510         randomseed = spawn();
 511         randomseed.think = RandomSeed_Think;
 512         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 513
 514         entity oldself;
 515         oldself = self;
 516         self = randomseed;
 517         self.think(); // sets random seed and nextthink
 518         self = oldself;
 519 }
 520
 521 void spawnfunc___init_dedicated_server(void)
 522 {
 523         // handler for _init/_init map (only for dedicated server initialization)
 524
 525         world_initialized = -1; // don't complain
 526         cvar = cvar_normal;
 527         cvar_string = cvar_string_normal;
 528         cvar_set = cvar_set_normal;
 529
 530         remove = remove_unsafely;
 531
 532         entity e;
 533         e = spawn();
 534         e.think = GotoFirstMap;
 535         e.nextthink = time; // this is usually 1 at this point
 536
 537         e = spawn();
 538         e.classname = "info_player_deathmatch"; // safeguard against player joining
 539
 540         self.classname = "worldspawn"; // safeguard against various stuff ;)
 541
 542         // needs to be done so early because of the constants they create
 543         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 544         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 545         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 546         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 547         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 548         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 591
 592         // needs to be done so early because of the constants they create
 593         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 594         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 595         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 596         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 597         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 599
 600         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 601
 602         TemporaryDB = db_create();
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(autocvar_g_campaign)
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 651
 652         precache_model ("null"); // we need this one before InitGameplayMode
 653         InitGameplayMode();
 654         readlevelcvars();
 655         GrappleHookInit();
 656
 657         player_count = 0;
 658         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 659         if(bot_waypoints_for_items == 1)
 660                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 661                         bot_waypoints_for_items = 0;
 662
 663         precache();
 664
 665         WaypointSprite_Init();
 666
 667         GameLogInit(); // prepare everything
 668         // NOTE for matchid:
 669         // changing the logic generating it is okay. But:
 670         // it HAS to stay <= 64 chars
 671         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 672         if(autocvar_sv_eventlog)
 673         {
 674                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 675                 matchid = strzone(s);
 676
 677                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 678                 s = ":gameinfo:mutators:LIST";
 679
 680                 ret_string = s;
 681                 MUTATOR_CALLHOOK(BuildMutatorsString);
 682                 s = ret_string;
 683
 684                 // simple, probably not good in the mutator system
 685                 if(autocvar_g_grappling_hook)
 686                         s = strcat(s, ":grappling_hook");
 687
 688                 // initialiation stuff, not good in the mutator system
 689                 if(!autocvar_g_use_ammunition)
 690                         s = strcat(s, ":no_use_ammunition");
 691
 692                 // initialiation stuff, not good in the mutator system
 693                 if(autocvar_g_pickup_items == 0)
 694                         s = strcat(s, ":no_pickup_items");
 695                 if(autocvar_g_pickup_items > 0)
 696                         s = strcat(s, ":pickup_items");
 697
 698                 // initialiation stuff, not good in the mutator system
 699                 if(autocvar_g_weaponarena != "0")
 700                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 701
 702                 // TODO to mutator system
 703                 if(autocvar_g_norecoil)
 704                         s = strcat(s, ":norecoil");
 705
 706                 // TODO to mutator system
 707                 if(autocvar_g_powerups == 0)
 708                         s = strcat(s, ":no_powerups");
 709                 if(autocvar_g_powerups > 0)
 710                         s = strcat(s, ":powerups");
 711
 712                 GameLogEcho(s);
 713                 GameLogEcho(":gameinfo:end");
 714         }
 715         else
 716                 matchid = strzone(ftos(random()));
 717
 718         cvar_set("nextmap", "");
 719
 720         SetDefaultAlpha();
 721
 722         if(autocvar_g_campaign)
 723                 CampaignPostInit();
 724
 725         fteqcc_testbugs();
 726
 727         Ban_LoadBans();
 728
 729         MapInfo_Enumerate();
 730         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 731
 732         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 733         {
 734                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 735                 if(fd != -1)
 736                 {
 737                         while((s = fgets(fd)))
 738                         {
 739                                 l = tokenize_console(s);
 740                                 if(l < 2)
 741                                         continue;
 742                                 if(argv(0) == "cd")
 743                                 {
 744                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 745                                         print("  cdtrack ", argv(2), "\n");
 746                                 }
 747                                 else if(argv(0) == "fog")
 748                                 {
 749                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 750                                         print("  \"fog\" \"", s, "\"\n");
 751                                 }
 752                                 else if(argv(0) == "set")
 753                                 {
 754                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 755                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 756                                 }
 757                                 else if(argv(0) != "//")
 758                                 {
 759                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 760                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 761                                 }
 762                         }
 763                         fclose(fd);
 764                 }
 765         }
 766
 767         WeaponStats_Init();
 768
 769         WepSet_AddStat();
 770         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 771         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 772         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 773         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 774         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 775         Nagger_Init();
 776
 777         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 778         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 779         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 780         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 781         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 782         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 783         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 784         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 785         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 786         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 787         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 788         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 789         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 790         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 791
 792         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 793         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 794
 795         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 796
 797         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 798
 799         // freeze attacks
 800         addstat(STAT_FROZEN, AS_INT, frozen);
 801         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 802
 803         // g_movementspeed hack
 804         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 805         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 806         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 807         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 808
 809         // secrets
 810         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 811         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 812
 813         // monsters
 814         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 815         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 816
 817         // misc
 818         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 819
 820         next_pingtime = time + 5;
 821
 822         detect_maptype();
 823
 824         // set up information replies for clients and server to use
 825         maplist_reply = strzone(getmaplist());
 826         lsmaps_reply = strzone(getlsmaps());
 827         monsterlist_reply = strzone(getmonsterlist());
 828         for(i = 0; i < 10; ++i)
 829         {
 830                 s = getrecords(i);
 831                 if (s)
 832                         records_reply[i] = strzone(s);
 833         }
 834         ladder_reply = strzone(getladder());
 835         rankings_reply = strzone(getrankings());
 836
 837         // begin other init
 838         ClientInit_Spawn();
 839         RandomSeed_Spawn();
 840         PingPLReport_Spawn();
 841
 842         CheatInit();
 843
 844         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 845
 846         // fill sv_curl_serverpackages from .serverpackage files
 847         if(autocvar_sv_curl_serverpackages_auto)
 848         {
 849                 s = "";
 850                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 851                 for(i = 0; i < n; ++i)
 852                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 853                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 854                                 s = strcat(s, " ", argv(i));
 855                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 856                 if(fd >= 0)
 857                 {
 858                         j = search_getsize(fd);
 859                         for(i = 0; i < j; ++i)
 860                                 s = strcat(s, " ", search_getfilename(fd, i));
 861                         search_end(fd);
 862                 }
 863                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 864                 if(fd >= 0)
 865                 {
 866                         j = search_getsize(fd);
 867                         for(i = 0; i < j; ++i)
 868                                 s = strcat(s, " ", search_getfilename(fd, i));
 869                         search_end(fd);
 870                 }
 871                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 872         }
 873
 874         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 875         modname = "Xonotic";
 876         // physics/balance/config changes that count as mod
 877         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 878                 modname = cvar_string("g_mod_physics");
 879         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 880                 modname = cvar_string("g_mod_balance");
 881         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 882                 modname = cvar_string("g_mod_config");
 883         // extra mutators that deserve to count as mod
 884         MUTATOR_CALLHOOK(SetModname);
 885
 886         // save it for later
 887         modname = strzone(modname);
 888
 889         WinningConditionHelper(); // set worldstatus
 890
 891         world_initialized = 1;
 892 }
 893
 894 void spawnfunc_light (void)
 895 {
 896         //makestatic (self); // Who the f___ did that?
 897         remove(self);
 898 }
 899
 900 string GetGametype()
 901 {
 902         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 903 }
 904
 905 string GetMapname()
 906 {
 907         return mapname;
 908 }
 909
 910 float Map_Count, Map_Current;
 911 string Map_Current_Name;
 912
 913 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 914 float GetMaplistPosition()
 915 {
 916         float pos, idx;
 917         string map;
 918
 919         map = GetMapname();
 920         idx = autocvar_g_maplist_index;
 921
 922         if(idx >= 0)
 923                 if(idx < Map_Count)
 924                         if(map == argv(idx))
 925                                 return idx;
 926
 927         for(pos = 0; pos < Map_Count; ++pos)
 928                 if(map == argv(pos))
 929                         return pos;
 930
 931         // resume normal maplist rotation if current map is not in g_maplist
 932         return idx;
 933 }
 934
 935 float MapHasRightSize(string map)
 936 {
 937         float fh;
 938         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 939         if(autocvar_g_maplist_check_waypoints)
 940         {
 941                 dprint("checkwp "); dprint(map);
 942                 if(!fexists(strcat("maps/", map, ".waypoints")))
 943                 {
 944                         dprint(": no waypoints\n");
 945                         return FALSE;
 946                 }
 947                 dprint(": has waypoints\n");
 948         }
 949
 950         // open map size restriction file
 951         dprint("opensize "); dprint(map);
 952         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 953         if(fh >= 0)
 954         {
 955                 float mapmin, mapmax;
 956                 dprint(": ok, ");
 957                 mapmin = stof(fgets(fh));
 958                 mapmax = stof(fgets(fh));
 959                 fclose(fh);
 960                 if(player_count < mapmin)
 961                 {
 962                         dprint("not enough\n");
 963                         return FALSE;
 964                 }
 965                 if(player_count > mapmax)
 966                 {
 967                         dprint("too many\n");
 968                         return FALSE;
 969                 }
 970                 dprint("right size\n");
 971                 return TRUE;
 972         }
 973         dprint(": not found\n");
 974         return TRUE;
 975 }
 976
 977 string Map_Filename(float position)
 978 {
 979         return strcat("maps/", argv(position), ".bsp");
 980 }
 981
 982 string strwords(string s, float w)
 983 {
 984         float endpos;
 985         for(endpos = 0; w && endpos >= 0; --w)
 986                 endpos = strstrofs(s, " ", endpos + 1);
 987         if(endpos < 0)
 988                 return s;
 989         else
 990                 return substring(s, 0, endpos);
 991 }
 992
 993 float strhasword(string s, string w)
 994 {
 995         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 996 }
 997
 998 void Map_MarkAsRecent(string m)
 999 {
1000         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1001 }
1002
1003 float Map_IsRecent(string m)
1004 {
1005         return strhasword(autocvar_g_maplist_mostrecent, m);
1006 }
1007
1008 float Map_Check(float position, float pass)
1009 {
1010         string filename;
1011         string map_next;
1012         map_next = argv(position);
1013         if(pass <= 1)
1014         {
1015                 if(Map_IsRecent(map_next))
1016                         return 0;
1017         }
1018         filename = Map_Filename(position);
1019         if(MapInfo_CheckMap(map_next))
1020         {
1021                 if(pass == 2)
1022                         return 1;
1023                 if(MapHasRightSize(map_next))
1024                         return 1;
1025                 return 0;
1026         }
1027         else
1028                 dprint( "Couldn't select '", filename, "'..\n" );
1029
1030         return 0;
1031 }
1032
1033 void Map_Goto_SetStr(string nextmapname)
1034 {
1035         if(getmapname_stored != "")
1036                 strunzone(getmapname_stored);
1037         if(nextmapname == "")
1038                 getmapname_stored = "";
1039         else
1040                 getmapname_stored = strzone(nextmapname);
1041 }
1042
1043 void Map_Goto_SetFloat(float position)
1044 {
1045         cvar_set("g_maplist_index", ftos(position));
1046         Map_Goto_SetStr(argv(position));
1047 }
1048
1049 void Map_Goto(float reinit)
1050 {
1051         MapInfo_LoadMap(getmapname_stored, reinit);
1052 }
1053
1054 // return codes of map selectors:
1055 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1056 //   -2 = permanent failure
1057 float() MaplistMethod_Iterate = // usual method
1058 {
1059         float pass, i;
1060
1061         dprint("Trying MaplistMethod_Iterate\n");
1062
1063         for(pass = 1; pass <= 2; ++pass)
1064         {
1065                 for(i = 1; i < Map_Count; ++i)
1066                 {
1067                         float mapindex;
1068                         mapindex = mod(i + Map_Current, Map_Count);
1069                         if(Map_Check(mapindex, pass))
1070                                 return mapindex;
1071                 }
1072         }
1073         return -1;
1074 }
1075
1076 float() MaplistMethod_Repeat = // fallback method
1077 {
1078         dprint("Trying MaplistMethod_Repeat\n");
1079
1080         if(Map_Check(Map_Current, 2))
1081                 return Map_Current;
1082         return -2;
1083 }
1084
1085 float() MaplistMethod_Random = // random map selection
1086 {
1087         float i, imax;
1088
1089         dprint("Trying MaplistMethod_Random\n");
1090
1091         imax = 42;
1092
1093         for(i = 0; i <= imax; ++i)
1094         {
1095                 float mapindex;
1096                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1097                 if(Map_Check(mapindex, 1))
1098                         return mapindex;
1099         }
1100         return -1;
1101 }
1102
1103 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1104 // the exponent sets a bias on the map selection:
1105 // the higher the exponent, the less likely "shortly repeated" same maps are
1106 {
1107         float i, j, imax, insertpos;
1108
1109         dprint("Trying MaplistMethod_Shuffle\n");
1110
1111         imax = 42;
1112
1113         for(i = 0; i <= imax; ++i)
1114         {
1115                 string newlist;
1116
1117                 // now reinsert this at another position
1118                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1119                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1120                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1121                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1122
1123                 // insert the current map there
1124                 newlist = "";
1125                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1126                         newlist = strcat(newlist, " ", argv(j));
1127                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1128                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1129                         newlist = strcat(newlist, " ", argv(j));
1130                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1131                 cvar_set("g_maplist", newlist);
1132                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1133
1134                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1135                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1136                 if(Map_Check(Map_Current, 1))
1137                         return Map_Current;
1138         }
1139         return -1;
1140 }
1141
1142 void Maplist_Init()
1143 {
1144         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1145         float i;
1146         for (i = 0; i < Map_Count; ++i)
1147                 if (Map_Check(i, 2))
1148                         break;
1149         if (i == Map_Count)
1150         {
1151                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1152                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1153                 if(autocvar_g_maplist_shuffle)
1154                         ShuffleMaplist();
1155                 localcmd("\nmenu_cmd sync\n");
1156                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1157         }
1158         if(Map_Count == 0)
1159                 error("empty maplist, cannot select a new map");
1160         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1161
1162         if(Map_Current_Name)
1163                 strunzone(Map_Current_Name);
1164         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1165         // this may or may not be correct, but who cares, in the worst case a map
1166         // isn't chosen in the first pass that should have been
1167 }
1168
1169 string GetNextMap()
1170 {
1171         float nextMap;
1172
1173         Maplist_Init();
1174         nextMap = -1;
1175
1176         if(nextMap == -1)
1177                 if(autocvar_g_maplist_shuffle > 0)
1178                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1179
1180         if(nextMap == -1)
1181                 if(autocvar_g_maplist_selectrandom)
1182                         nextMap = MaplistMethod_Random();
1183
1184         if(nextMap == -1)
1185                 nextMap = MaplistMethod_Iterate();
1186
1187         if(nextMap == -1)
1188                 nextMap = MaplistMethod_Repeat();
1189
1190         if(nextMap >= 0)
1191         {
1192                 Map_Goto_SetFloat(nextMap);
1193                 return getmapname_stored;
1194         }
1195
1196         return "";
1197 }
1198
1199 float DoNextMapOverride(float reinit)
1200 {
1201         if(autocvar_g_campaign)
1202         {
1203                 CampaignPostIntermission();
1204                 alreadychangedlevel = TRUE;
1205                 return TRUE;
1206         }
1207         if(autocvar_quit_when_empty)
1208         {
1209                 if(player_count <= currentbots)
1210                 {
1211                         localcmd("quit\n");
1212                         alreadychangedlevel = TRUE;
1213                         return TRUE;
1214                 }
1215         }
1216         if(autocvar_quit_and_redirect != "")
1217         {
1218                 redirection_target = strzone(autocvar_quit_and_redirect);
1219                 alreadychangedlevel = TRUE;
1220                 return TRUE;
1221         }
1222         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1223         {
1224                 localcmd("restart\n");
1225                 alreadychangedlevel = TRUE;
1226                 return TRUE;
1227         }
1228         if(autocvar_nextmap != "")
1229         {
1230                 string m;
1231                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1232                 cvar_set("nextmap",m);
1233
1234                 if(!m || gametypevote)
1235                         return FALSE;
1236                 if(autocvar_sv_vote_gametype)
1237                 {
1238                         Map_Goto_SetStr(m);
1239                         return FALSE;
1240                 }
1241
1242                 if(MapInfo_CheckMap(m))
1243                 {
1244                         Map_Goto_SetStr(m);
1245                         Map_Goto(reinit);
1246                         alreadychangedlevel = TRUE;
1247                         return TRUE;
1248                 }
1249         }
1250         if(!reinit && autocvar_lastlevel)
1251         {
1252                 cvar_settemp_restore();
1253                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1254                 alreadychangedlevel = TRUE;
1255                 return TRUE;
1256         }
1257         return FALSE;
1258 }
1259
1260 void GotoNextMap(float reinit)
1261 {
1262         //string nextmap;
1263         //float n, nummaps;
1264         //string s;
1265         if (alreadychangedlevel)
1266                 return;
1267         alreadychangedlevel = TRUE;
1268
1269         string nextMap;
1270
1271         nextMap = GetNextMap();
1272         if(nextMap == "")
1273                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1274         Map_Goto(reinit);
1275 }
1276
1277
1278 /*
1279 ============
1280 IntermissionThink
1281
1282 When the player presses attack or jump, change to the next level
1283 ============
1284 */
1285 .float autoscreenshot;
1286 void IntermissionThink()
1287 {
1288         FixIntermissionClient(self);
1289
1290         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1291         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1292
1293         if( (server_screenshot || client_screenshot)
1294                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1295         {
1296                 self.autoscreenshot = -1;
1297                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1298                 return;
1299         }
1300
1301         if (time < intermission_exittime)
1302                 return;
1303
1304         if(!mapvote_initialized)
1305                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1306                         return;
1307
1308         MapVote_Start();
1309 }
1310
1311 /*
1312 ============
1313 FindIntermission
1314
1315 Returns the entity to view from
1316 ============
1317 */
1318 /*
1319 entity FindIntermission()
1320 {
1321         local   entity spot;
1322         local   float cyc;
1323
1324 // look for info_intermission first
1325         spot = find (world, classname, "info_intermission");
1326         if (spot)
1327         {       // pick a random one
1328                 cyc = random() * 4;
1329                 while (cyc > 1)
1330                 {
1331                         spot = find (spot, classname, "info_intermission");
1332                         if (!spot)
1333                                 spot = find (spot, classname, "info_intermission");
1334                         cyc = cyc - 1;
1335                 }
1336                 return spot;
1337         }
1338
1339 // then look for the start position
1340         spot = find (world, classname, "info_player_start");
1341         if (spot)
1342                 return spot;
1343
1344 // testinfo_player_start is only found in regioned levels
1345         spot = find (world, classname, "testplayerstart");
1346         if (spot)
1347                 return spot;
1348
1349 // then look for the start position
1350         spot = find (world, classname, "info_player_deathmatch");
1351         if (spot)
1352                 return spot;
1353
1354         //objerror ("FindIntermission: no spot");
1355         return world;
1356 }
1357 */
1358
1359 /*
1360 ===============================================================================
1361
1362 RULES
1363
1364 ===============================================================================
1365 */
1366
1367 void DumpStats(float final)
1368 {
1369         float file;
1370         string s;
1371         float to_console;
1372         float to_eventlog;
1373         float to_file;
1374         float i;
1375
1376         to_console = autocvar_sv_logscores_console;
1377         to_eventlog = autocvar_sv_eventlog;
1378         to_file = autocvar_sv_logscores_file;
1379
1380         if(!final)
1381         {
1382                 to_console = TRUE; // always print printstats replies
1383                 to_eventlog = FALSE; // but never print them to the event log
1384         }
1385
1386         if(to_eventlog)
1387                 if(autocvar_sv_eventlog_console)
1388                         to_console = FALSE; // otherwise we get the output twice
1389
1390         if(final)
1391                 s = ":scores:";
1392         else
1393                 s = ":status:";
1394         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1395
1396         if(to_console)
1397                 print(s, "\n");
1398         if(to_eventlog)
1399                 GameLogEcho(s);
1400
1401         file = -1;
1402         if(to_file)
1403         {
1404                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1405                 if(file == -1)
1406                         to_file = FALSE;
1407                 else
1408                         fputs(file, strcat(s, "\n"));
1409         }
1410
1411         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1412         if(to_console)
1413                 print(s, "\n");
1414         if(to_eventlog)
1415                 GameLogEcho(s);
1416         if(to_file)
1417                 fputs(file, strcat(s, "\n"));
1418
1419         FOR_EACH_CLIENT(other)
1420         {
1421                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1422                 {
1423                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1424                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1425                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1426                                 s = strcat(s, ftos(other.team), ":");
1427                         else
1428                                 s = strcat(s, "spectator:");
1429
1430                         if(to_console)
1431                                 print(s, other.netname, "\n");
1432                         if(to_eventlog)
1433                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1434                         if(to_file)
1435                                 fputs(file, strcat(s, other.netname, "\n"));
1436                 }
1437         }
1438
1439         if(teamplay)
1440         {
1441                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1442                 if(to_console)
1443                         print(s, "\n");
1444                 if(to_eventlog)
1445                         GameLogEcho(s);
1446                 if(to_file)
1447                         fputs(file, strcat(s, "\n"));
1448
1449                 for(i = 1; i < 16; ++i)
1450                 {
1451                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1452                         s = strcat(s, ":", ftos(i));
1453                         if(to_console)
1454                                 print(s, "\n");
1455                         if(to_eventlog)
1456                                 GameLogEcho(s);
1457                         if(to_file)
1458                                 fputs(file, strcat(s, "\n"));
1459                 }
1460         }
1461
1462         if(to_console)
1463                 print(":end\n");
1464         if(to_eventlog)
1465                 GameLogEcho(":end");
1466         if(to_file)
1467         {
1468                 fputs(file, ":end\n");
1469                 fclose(file);
1470         }
1471 }
1472
1473 void FixIntermissionClient(entity e)
1474 {
1475         string s;
1476         if(!e.autoscreenshot) // initial call
1477         {
1478                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1479                 e.health = -2342;
1480                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1481                 e.solid = SOLID_NOT;
1482                 e.movetype = MOVETYPE_NONE;
1483                 e.takedamage = DAMAGE_NO;
1484                 if(e.weaponentity)
1485                 {
1486                         e.weaponentity.effects = EF_NODRAW;
1487                         if (e.weaponentity.weaponentity)
1488                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1489                 }
1490                 if(IS_REAL_CLIENT(e))
1491                 {
1492                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1493                         s = autocvar_sv_intermission_cdtrack;
1494                         if(s != "")
1495                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1496                         msg_entity = e;
1497                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1498                 }
1499         }
1500 }
1501
1502 /*
1503 go to the next level for deathmatch
1504 only called if a time or frag limit has expired
1505 */
1506 void NextLevel()
1507 {
1508         gameover = TRUE;
1509
1510         intermission_running = 1;
1511
1512 // enforce a wait time before allowing changelevel
1513         if(player_count > 0)
1514                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1515         else
1516                 intermission_exittime = -1;
1517
1518         /*
1519         WriteByte (MSG_ALL, SVC_CDTRACK);
1520         WriteByte (MSG_ALL, 3);
1521         WriteByte (MSG_ALL, 3);
1522         // done in FixIntermission
1523         */
1524
1525         //pos = FindIntermission ();
1526
1527         VoteReset();
1528
1529         DumpStats(TRUE);
1530
1531         // send statistics
1532         entity e;
1533         PlayerStats_EndMatch(1);
1534         FOR_EACH_CLIENT(e)
1535                 PlayerStats_AddGlobalInfo(e);
1536         PlayerStats_Shutdown();
1537         WeaponStats_Shutdown();
1538
1539         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1540
1541         if(autocvar_sv_eventlog)
1542                 GameLogEcho(":gameover");
1543
1544         GameLogClose();
1545
1546         FOR_EACH_PLAYER(other) {
1547                 FixIntermissionClient(other);
1548                 if(other.winning)
1549                         bprint(other.netname, " ^7wins.\n");
1550         }
1551
1552         if(autocvar_g_campaign)
1553                 CampaignPreIntermission();
1554
1555         MUTATOR_CALLHOOK(MatchEnd);
1556
1557         localcmd("\nsv_hook_gameend\n");
1558 }
1559
1560 /*
1561 ============
1562 CheckRules_Player
1563
1564 Exit deathmatch games upon conditions
1565 ============
1566 */
1567 void CheckRules_Player()
1568 {
1569         if (gameover)   // someone else quit the game already
1570                 return;
1571
1572         if(self.deadflag == DEAD_NO)
1573                 self.play_time += frametime;
1574
1575         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1576         //   (div0: and that in CheckRules_World please)
1577 }
1578
1579 float checkrules_equality;
1580 float checkrules_suddendeathwarning;
1581 float checkrules_suddendeathend;
1582 float checkrules_overtimesadded; //how many overtimes have been already added
1583
1584 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1585 const float WINNING_YES = 1; // winner found
1586 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1587 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1588
1589 float InitiateSuddenDeath()
1590 {
1591         // Check first whether normal overtimes could be added before initiating suddendeath mode
1592         // - for this timelimit_overtime needs to be >0 of course
1593         // - also check the winning condition calculated in the previous frame and only add normal overtime
1594         //   again, if at the point at which timelimit would be extended again, still no winner was found
1595         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1596         {
1597                 return 1; // need to call InitiateOvertime later
1598         }
1599         else
1600         {
1601                 if(!checkrules_suddendeathend)
1602                 {
1603                         if(autocvar_g_campaign)
1604                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1605                         else
1606                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1607                         if(g_race && !g_race_qualifying)
1608                                 race_StartCompleting();
1609                 }
1610                 return 0;
1611         }
1612 }
1613
1614 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1615 {
1616         ++checkrules_overtimesadded;
1617         //add one more overtime by simply extending the timelimit
1618         float tl;
1619         tl = autocvar_timelimit;
1620         tl += autocvar_timelimit_overtime;
1621         cvar_set("timelimit", ftos(tl));
1622
1623         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1624 }
1625
1626 float GetWinningCode(float fraglimitreached, float equality)
1627 {
1628         if(autocvar_g_campaign == 1)
1629                 if(fraglimitreached)
1630                         return WINNING_YES;
1631                 else
1632                         return WINNING_NO;
1633
1634         else
1635                 if(equality)
1636                         if(fraglimitreached)
1637                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1638                         else
1639                                 return WINNING_NEVER;
1640                 else
1641                         if(fraglimitreached)
1642                                 return WINNING_YES;
1643                         else
1644                                 return WINNING_NO;
1645 }
1646
1647 // set the .winning flag for exactly those players with a given field value
1648 void SetWinners(.float field, float value)
1649 {
1650         entity head;
1651         FOR_EACH_PLAYER(head)
1652                 head.winning = (head.field == value);
1653 }
1654
1655 // set the .winning flag for those players with a given field value
1656 void AddWinners(.float field, float value)
1657 {
1658         entity head;
1659         FOR_EACH_PLAYER(head)
1660                 if(head.field == value)
1661                         head.winning = 1;
1662 }
1663
1664 // clear the .winning flags
1665 void ClearWinners(void)
1666 {
1667         entity head;
1668         FOR_EACH_PLAYER(head)
1669                 head.winning = 0;
1670 }
1671
1672 // Onslaught winning condition:
1673 // game terminates if only one team has a working generator (or none)
1674 float WinningCondition_Onslaught()
1675 {
1676         entity head;
1677         float t1, t2, t3, t4;
1678
1679         WinningConditionHelper(); // set worldstatus
1680
1681         if(warmup_stage)
1682                 return WINNING_NO;
1683
1684         // first check if the game has ended
1685         t1 = t2 = t3 = t4 = 0;
1686         head = find(world, classname, "onslaught_generator");
1687         while (head)
1688         {
1689                 if (head.health > 0)
1690                 {
1691                         if (head.team == NUM_TEAM_1) t1 = 1;
1692                         if (head.team == NUM_TEAM_2) t2 = 1;
1693                         if (head.team == NUM_TEAM_3) t3 = 1;
1694                         if (head.team == NUM_TEAM_4) t4 = 1;
1695                 }
1696                 head = find(head, classname, "onslaught_generator");
1697         }
1698         if (t1 + t2 + t3 + t4 < 2)
1699         {
1700                 // game over, only one team remains (or none)
1701                 ClearWinners();
1702                 if (t1) SetWinners(team, NUM_TEAM_1);
1703                 if (t2) SetWinners(team, NUM_TEAM_2);
1704                 if (t3) SetWinners(team, NUM_TEAM_3);
1705                 if (t4) SetWinners(team, NUM_TEAM_4);
1706                 dprint("Have a winner, ending game.\n");
1707                 return WINNING_YES;
1708         }
1709
1710         // Two or more teams remain
1711         return WINNING_NO;
1712 }
1713
1714 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1715 // they win. Otherwise the defending team wins once the timelimit passes.
1716 void assault_new_round();
1717 float WinningCondition_Assault()
1718 {
1719         float status;
1720
1721         WinningConditionHelper(); // set worldstatus
1722
1723         status = WINNING_NO;
1724         // as the timelimit has not yet passed just assume the defending team will win
1725         if(assault_attacker_team == NUM_TEAM_1)
1726         {
1727                 SetWinners(team, NUM_TEAM_2);
1728         }
1729         else
1730         {
1731                 SetWinners(team, NUM_TEAM_1);
1732         }
1733
1734         entity ent;
1735         ent = find(world, classname, "target_assault_roundend");
1736         if(ent)
1737         {
1738                 if(ent.winning) // round end has been triggered by attacking team
1739                 {
1740                         bprint("ASSAULT: round completed...\n");
1741                         SetWinners(team, assault_attacker_team);
1742
1743                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1744
1745                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1746                         {
1747                                 status = WINNING_YES;
1748                         }
1749                         else
1750                         {
1751                                 entity oldself;
1752                                 oldself = self;
1753                                 self = ent;
1754                                 assault_new_round();
1755                                 self = oldself;
1756                         }
1757                 }
1758         }
1759
1760         return status;
1761 }
1762
1763 // LMS winning condition: game terminates if and only if there's at most one
1764 // one player who's living lives. Top two scores being equal cancels the time
1765 // limit.
1766 float WinningCondition_LMS()
1767 {
1768         entity head, head2;
1769         float have_player;
1770         float have_players;
1771         float l;
1772
1773         have_player = FALSE;
1774         have_players = FALSE;
1775         l = LMS_NewPlayerLives();
1776
1777         head = find(world, classname, "player");
1778         if(head)
1779                 have_player = TRUE;
1780         head2 = find(head, classname, "player");
1781         if(head2)
1782                 have_players = TRUE;
1783
1784         if(have_player)
1785         {
1786                 // we have at least one player
1787                 if(have_players)
1788                 {
1789                         // two or more active players - continue with the game
1790                 }
1791                 else
1792                 {
1793                         // exactly one player?
1794
1795                         ClearWinners();
1796                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1797
1798                         if(l)
1799                         {
1800                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1801                                 return WINNING_NO;
1802                         }
1803                         else
1804                         {
1805                                 // a winner!
1806                                 // and assign him his first place
1807                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1808                                 return WINNING_YES;
1809                         }
1810                 }
1811         }
1812         else
1813         {
1814                 // nobody is playing at all...
1815                 if(l)
1816                 {
1817                         // wait for players...
1818                 }
1819                 else
1820                 {
1821                         // SNAFU (maybe a draw game?)
1822                         ClearWinners();
1823                         dprint("No players, ending game.\n");
1824                         return WINNING_YES;
1825                 }
1826         }
1827
1828         // When we get here, we have at least two players who are actually LIVING,
1829         // now check if the top two players have equal score.
1830         WinningConditionHelper();
1831
1832         ClearWinners();
1833         if(WinningConditionHelper_winner)
1834                 WinningConditionHelper_winner.winning = TRUE;
1835         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1836                 return WINNING_NEVER;
1837
1838         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1839         return WINNING_NO;
1840 }
1841
1842 void ShuffleMaplist()
1843 {
1844         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1845 }
1846
1847 float leaderfrags;
1848 float WinningCondition_Scores(float limit, float leadlimit)
1849 {
1850         float limitreached;
1851
1852         // TODO make everything use THIS winning condition (except LMS)
1853         WinningConditionHelper();
1854
1855         if(teamplay)
1856         {
1857                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1858                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1859                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1860                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1861         }
1862
1863         ClearWinners();
1864         if(WinningConditionHelper_winner)
1865                 WinningConditionHelper_winner.winning = 1;
1866         if(WinningConditionHelper_winnerteam >= 0)
1867                 SetWinners(team, WinningConditionHelper_winnerteam);
1868
1869         if(WinningConditionHelper_lowerisbetter)
1870         {
1871                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1872                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1873                 limit = -limit;
1874         }
1875
1876         if(WinningConditionHelper_zeroisworst)
1877                 leadlimit = 0; // not supported in this mode
1878
1879         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1880         // these modes always score in increments of 1, thus this makes sense
1881         {
1882                 if(leaderfrags != WinningConditionHelper_topscore)
1883                 {
1884                         leaderfrags = WinningConditionHelper_topscore;
1885
1886                         if (limit)
1887                         if (leaderfrags == limit - 1)
1888                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1889                         else if (leaderfrags == limit - 2)
1890                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1891                         else if (leaderfrags == limit - 3)
1892                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1893                 }
1894         }
1895
1896         limitreached = FALSE;
1897         if(limit)
1898                 if(WinningConditionHelper_topscore >= limit)
1899                         limitreached = TRUE;
1900         if(leadlimit)
1901         {
1902                 float leadlimitreached;
1903                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1904                 if(autocvar_leadlimit_and_fraglimit)
1905                         limitreached = (limitreached && leadlimitreached);
1906                 else
1907                         limitreached = (limitreached || leadlimitreached);
1908         }
1909
1910         if(limit)
1911                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1912
1913         return GetWinningCode(
1914                 WinningConditionHelper_topscore && limitreached,
1915                 WinningConditionHelper_equality
1916         );
1917 }
1918
1919 float WinningCondition_Race(float fraglimit)
1920 {
1921         float wc;
1922         entity p;
1923         float n, c;
1924
1925         n = 0;
1926         c = 0;
1927         FOR_EACH_PLAYER(p)
1928         {
1929                 ++n;
1930                 if(p.race_completed)
1931                         ++c;
1932         }
1933         if(n && (n == c))
1934                 return WINNING_YES;
1935         wc = WinningCondition_Scores(fraglimit, 0);
1936
1937         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1938         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1939         // do NOT support equality when the laps are all raced!
1940                 return WINNING_STARTSUDDENDEATHOVERTIME;
1941         else
1942                 return WINNING_NEVER;
1943 }
1944
1945 float WinningCondition_QualifyingThenRace(float limit)
1946 {
1947         float wc;
1948         wc = WinningCondition_Scores(limit, 0);
1949
1950         // NEVER initiate overtime
1951         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1952         {
1953                 return WINNING_YES;
1954         }
1955
1956         return wc;
1957 }
1958
1959 float WinningCondition_RanOutOfSpawns()
1960 {
1961         entity head;
1962
1963         if(have_team_spawns <= 0)
1964                 return WINNING_NO;
1965
1966         if(autocvar_g_spawn_useallspawns <= 0)
1967                 return WINNING_NO;
1968
1969         if(!some_spawn_has_been_used)
1970                 return WINNING_NO;
1971
1972         team1_score = team2_score = team3_score = team4_score = 0;
1973
1974         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1975         {
1976                 if(head.team == NUM_TEAM_1)
1977                         team1_score = 1;
1978                 else if(head.team == NUM_TEAM_2)
1979                         team2_score = 1;
1980                 else if(head.team == NUM_TEAM_3)
1981                         team3_score = 1;
1982                 else if(head.team == NUM_TEAM_4)
1983                         team4_score = 1;
1984         }
1985
1986         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1987         {
1988                 if(head.team == NUM_TEAM_1)
1989                         team1_score = 1;
1990                 else if(head.team == NUM_TEAM_2)
1991                         team2_score = 1;
1992                 else if(head.team == NUM_TEAM_3)
1993                         team3_score = 1;
1994                 else if(head.team == NUM_TEAM_4)
1995                         team4_score = 1;
1996         }
1997
1998         ClearWinners();
1999         if(team1_score + team2_score + team3_score + team4_score == 0)
2000         {
2001                 checkrules_equality = TRUE;
2002                 return WINNING_YES;
2003         }
2004         else if(team1_score + team2_score + team3_score + team4_score == 1)
2005         {
2006                 float t, i;
2007                 if(team1_score)
2008                         t = NUM_TEAM_1;
2009                 else if(team2_score)
2010                         t = NUM_TEAM_2;
2011                 else if(team3_score)
2012                         t = NUM_TEAM_3;
2013                 else // if(team4_score)
2014                         t = NUM_TEAM_4;
2015                 CheckAllowedTeams(world);
2016                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2017                 {
2018                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2019                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2020                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2021                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2022                 }
2023
2024                 AddWinners(team, t);
2025                 return WINNING_YES;
2026         }
2027         else
2028                 return WINNING_NO;
2029 }
2030
2031 /*
2032 ============
2033 CheckRules_World
2034
2035 Exit deathmatch games upon conditions
2036 ============
2037 */
2038 void ReadyRestart();
2039 void CheckRules_World()
2040 {
2041         float timelimit;
2042         float fraglimit;
2043         float leadlimit;
2044
2045         VoteThink();
2046         MapVote_Think();
2047
2048         SetDefaultAlpha();
2049
2050         if (gameover)   // someone else quit the game already
2051         {
2052                 if(player_count == 0) // Nobody there? Then let's go to the next map
2053                         MapVote_Start();
2054                         // this will actually check the player count in the next frame
2055                         // again, but this shouldn't hurt
2056                 return;
2057         }
2058
2059         timelimit = autocvar_timelimit * 60;
2060         fraglimit = autocvar_fraglimit;
2061         leadlimit = autocvar_leadlimit;
2062
2063         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2064         {
2065                 if(timelimit > 0)
2066                         timelimit = 0; // timelimit is not made for warmup
2067                 if(fraglimit > 0)
2068                         fraglimit = 0; // no fraglimit for now
2069                 leadlimit = 0; // no leadlimit for now
2070         }
2071
2072         if(timelimit > 0)
2073         {
2074                 timelimit += game_starttime;
2075         }
2076         else if (timelimit < 0)
2077         {
2078                 // endmatch
2079                 NextLevel();
2080                 return;
2081         }
2082
2083         if(g_onslaught)
2084                 timelimit = 0; // ONS has its own overtime rule
2085
2086         float wantovertime;
2087         wantovertime = 0;
2088
2089         if(timelimit > game_starttime)
2090                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2091         else
2092                 game_completion_ratio = 0;
2093
2094         if(checkrules_suddendeathend)
2095         {
2096                 if(!checkrules_suddendeathwarning)
2097                 {
2098                         checkrules_suddendeathwarning = TRUE;
2099                         if(g_race && !g_race_qualifying)
2100                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2101                         else
2102                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2103                 }
2104         }
2105         else
2106         {
2107                 if (timelimit && time >= timelimit)
2108                 {
2109                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2110                         {
2111                                 float totalplayers;
2112                                 float playerswithlaps;
2113                                 float readyplayers;
2114                                 entity head;
2115                                 totalplayers = playerswithlaps = readyplayers = 0;
2116                                 FOR_EACH_PLAYER(head)
2117                                 {
2118                                         ++totalplayers;
2119                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2120                                                 ++playerswithlaps;
2121                                         if(head.ready)
2122                                                 ++readyplayers;
2123                                 }
2124
2125                                 // at least 2 of the players have completed a lap: start the RACE
2126                                 // otherwise, the players should end the qualifying on their own
2127                                 if(readyplayers || playerswithlaps >= 2)
2128                                 {
2129                                         checkrules_suddendeathend = 0;
2130                                         ReadyRestart(); // go to race
2131                                         return;
2132                                 }
2133                                 else
2134                                         wantovertime |= InitiateSuddenDeath();
2135                         }
2136                         else
2137                                 wantovertime |= InitiateSuddenDeath();
2138                 }
2139         }
2140
2141         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2142         {
2143                 NextLevel();
2144                 return;
2145         }
2146
2147         float checkrules_status;
2148         checkrules_status = WinningCondition_RanOutOfSpawns();
2149         if(checkrules_status == WINNING_YES)
2150         {
2151                 bprint("Hey! Someone ran out of spawns!\n");
2152         }
2153         else if(g_race && !g_race_qualifying && timelimit >= 0)
2154         {
2155                 checkrules_status = WinningCondition_Race(fraglimit);
2156                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2157         }
2158         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2159         {
2160                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2161                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2162         }
2163         else if(g_assault)
2164         {
2165                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2166         }
2167         else if(g_lms)
2168         {
2169                 checkrules_status = WinningCondition_LMS();
2170         }
2171         else if (g_onslaught)
2172         {
2173                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2174         }
2175         else
2176         {
2177                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2178                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2179         }
2180
2181         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2182         {
2183                 checkrules_status = WINNING_NEVER;
2184                 checkrules_overtimesadded = -1;
2185                 wantovertime |= InitiateSuddenDeath();
2186         }
2187
2188         if(checkrules_status == WINNING_NEVER)
2189                 // equality cases! Nobody wins if the overtime ends in a draw.
2190                 ClearWinners();
2191
2192         if(wantovertime)
2193         {
2194                 if(checkrules_status == WINNING_NEVER)
2195                         InitiateOvertime();
2196                 else
2197                         checkrules_status = WINNING_YES;
2198         }
2199
2200         if(checkrules_suddendeathend)
2201                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2202                         checkrules_status = WINNING_YES;
2203
2204         if(checkrules_status == WINNING_YES)
2205         {
2206                 //print("WINNING\n");
2207                 NextLevel();
2208         }
2209 }
2210
2211 string GotoMap(string m)
2212 {
2213         m = GameTypeVote_MapInfo_FixName(m);
2214         if (!m)
2215                 return "The map you suggested is not available on this server.";
2216         if (!autocvar_sv_vote_gametype)
2217         if(!MapInfo_CheckMap(m))
2218                 return "The map you suggested does not support the current game mode.";
2219         cvar_set("nextmap", m);
2220         cvar_set("timelimit", "-1");
2221         if(mapvote_initialized || alreadychangedlevel)
2222         {
2223                 if(DoNextMapOverride(0))
2224                         return "Map switch initiated.";
2225                 else
2226                         return "Hm... no. For some reason I like THIS map more.";
2227         }
2228         else
2229                 return "Map switch will happen after scoreboard.";
2230 }
2231
2232
2233 void EndFrame()
2234 {
2235         anticheat_endframe();
2236
2237         float altime;
2238         FOR_EACH_REALCLIENT(self)
2239         {
2240                 self.damage_dealt_total = 0;
2241
2242                 if(IS_SPEC(self))
2243                 {
2244                         if(self.enemy.typehitsound)
2245                                 self.typehit_time = time;
2246                         else if(self.enemy.damage_dealt)
2247                                 self.damage_dealt_total = ceil(self.enemy.damage_dealt);
2248                 }
2249                 else
2250                 {
2251                         if(self.typehitsound)
2252                                 self.typehit_time = time;
2253                         else if(self.damage_dealt)
2254                                 self.damage_dealt_total = ceil(self.damage_dealt);
2255                 }
2256         }
2257         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2258         // add 1 frametime because after this, engine SV_Physics
2259         // increases time by a frametime and then networks the frame
2260         // add another frametime because client shows everything with
2261         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2262         // needed!
2263         FOR_EACH_CLIENT(self)
2264         {
2265                 self.typehitsound = FALSE;
2266                 self.damage_dealt = 0;
2267                 antilag_record(self, altime);
2268         }
2269         FOR_EACH_MONSTER(self)
2270                 antilag_record(self, altime);
2271 }
2272
2273
2274 /*
2275  * RedirectionThink:
2276  * returns TRUE if redirecting
2277  */
2278 float redirection_timeout;
2279 float redirection_nextthink;
2280 float RedirectionThink()
2281 {
2282         float clients_found;
2283
2284         if(redirection_target == "")
2285                 return FALSE;
2286
2287         if(!redirection_timeout)
2288         {
2289                 cvar_set("sv_public", "-2");
2290                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2291                 if(redirection_target == "self")
2292                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2293                 else
2294                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2295         }
2296
2297         if(time < redirection_nextthink)
2298                 return TRUE;
2299
2300         redirection_nextthink = time + 1;
2301
2302         clients_found = 0;
2303         FOR_EACH_REALCLIENT(self)
2304         {
2305                 // TODO add timer
2306                 print("Redirecting: sending connect command to ", self.netname, "\n");
2307                 if(redirection_target == "self")
2308                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2309                 else
2310                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2311                 ++clients_found;
2312         }
2313
2314         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2315
2316         if(time > redirection_timeout || clients_found == 0)
2317                 localcmd("\nwait; wait; wait; quit\n");
2318
2319         return TRUE;
2320 }
2321
2322 void TargetMusic_RestoreGame();
2323 void RestoreGame()
2324 {
2325         // Loaded from a save game
2326         // some things then break, so let's work around them...
2327
2328         // Progs DB (capture records)
2329         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2330
2331         // Mapinfo
2332         MapInfo_Shutdown();
2333         MapInfo_Enumerate();
2334         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2335         WeaponStats_Init();
2336
2337         TargetMusic_RestoreGame();
2338 }
2339
2340 void Shutdown()
2341 {
2342         entity e;
2343
2344         gameover = 2;
2345
2346         if(world_initialized > 0)
2347         {
2348                 world_initialized = 0;
2349                 print("Saving persistent data...\n");
2350                 Ban_SaveBans();
2351
2352                 PlayerStats_EndMatch(0);
2353                 FOR_EACH_CLIENT(e)
2354                         PlayerStats_AddGlobalInfo(e);
2355                 PlayerStats_Shutdown();
2356
2357                 if(!cheatcount_total)
2358                 {
2359                         if(autocvar_sv_db_saveasdump)
2360                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2361                         else
2362                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2363                 }
2364                 if(autocvar_developer)
2365                 {
2366                         if(autocvar_sv_db_saveasdump)
2367                                 db_dump(TemporaryDB, "server-temp.db");
2368                         else
2369                                 db_save(TemporaryDB, "server-temp.db");
2370                 }
2371                 CheatShutdown(); // must be after cheatcount check
2372                 db_close(ServerProgsDB);
2373                 db_close(TemporaryDB);
2374                 print("done!\n");
2375                 // tell the bot system the game is ending now
2376                 bot_endgame();
2377
2378                 WeaponStats_Shutdown();
2379                 MapInfo_Shutdown();
2380         }
2381         else if(world_initialized == 0)
2382         {
2383                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2384         }
2385 }