Merge branch 'master' into Lyberta/TeamplayOverhaul
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2
3 #include "anticheat.qh"
4 #include "antilag.qh"
5 #include "bot/api.qh"
6 #include "campaign.qh"
7 #include "cheats.qh"
8 #include "client.qh"
9 #include "command/common.qh"
10 #include "command/getreplies.qh"
11 #include "command/sv_cmd.qh"
12 #include "command/vote.qh"
13 #include "g_hook.qh"
14 #include "ipban.qh"
15 #include "mapvoting.qh"
16 #include <server/mutators/_mod.qh>
17 #include "race.qh"
18 #include "scores.qh"
19 #include "scores_rules.qh"
20 #include "teamplay.qh"
21 #include "weapons/weaponstats.qh"
22 #include "../common/constants.qh"
23 #include <common/net_linked.qh>
24 #include "../common/deathtypes/all.qh"
25 #include "../common/gamemodes/sv_rules.qh"
26 #include "../common/mapinfo.qh"
27 #include "../common/monsters/_mod.qh"
28 #include "../common/monsters/sv_monsters.qh"
29 #include "../common/vehicles/all.qh"
30 #include "../common/notifications/all.qh"
31 #include "../common/physics/player.qh"
32 #include "../common/playerstats.qh"
33 #include "../common/stats.qh"
34 #include "../common/teams.qh"
35 #include "../common/mapobjects/trigger/secret.qh"
36 #include "../common/mapobjects/target/music.qh"
37 #include "../common/util.qh"
38 #include "../common/items/_mod.qh"
39 #include <common/weapons/_all.qh>
40 #include "../common/state.qh"
41
42 const float LATENCY_THINKRATE = 10;
43 .float latency_sum;
44 .float latency_cnt;
45 .float latency_time;
46 entity pingplreport;
47 void PingPLReport_Think(entity this)
48 {
49         float delta;
50         entity e;
51
52         delta = 3 / maxclients;
53         if(delta < sys_frametime)
54                 delta = 0;
55         this.nextthink = time + delta;
56
57         e = edict_num(this.cnt + 1);
58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
59         {
60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
61                 WriteByte(MSG_BROADCAST, this.cnt);
62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
65
66                 // record latency times for clients throughout the match so we can report it to playerstats
67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
68                 {
69                         CS(e).latency_sum += CS(e).ping;
70                         CS(e).latency_cnt += 1;
71                         CS(e).latency_time = time;
72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
73                 }
74         }
75         else
76         {
77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
78                 WriteByte(MSG_BROADCAST, this.cnt);
79                 WriteShort(MSG_BROADCAST, 0);
80                 WriteByte(MSG_BROADCAST, 0);
81                 WriteByte(MSG_BROADCAST, 0);
82         }
83         this.cnt = (this.cnt + 1) % maxclients;
84 }
85 void PingPLReport_Spawn()
86 {
87         pingplreport = new_pure(pingplreport);
88         setthink(pingplreport, PingPLReport_Think);
89         pingplreport.nextthink = time;
90 }
91
92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
93 string redirection_target;
94 float world_initialized;
95
96 void SetDefaultAlpha()
97 {
98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
99         {
100                 default_player_alpha = autocvar_g_player_alpha;
101                 if(default_player_alpha == 0)
102                         default_player_alpha = 1;
103                 default_weapon_alpha = default_player_alpha;
104         }
105 }
106
107 void GotoFirstMap(entity this)
108 {
109         float n;
110         if(autocvar__sv_init)
111         {
112                 // cvar_set("_sv_init", "0");
113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
114                 // to this "init" map on a dedicated server will cause no permanent
115                 // harm
116                 if(autocvar_g_maplist_shuffle)
117                         ShuffleMaplist();
118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
120
121                 MapInfo_Enumerate();
122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
123
124                 if(!DoNextMapOverride(1))
125                         GotoNextMap(1);
126
127                 return;
128         }
129
130         if(time < 5)
131         {
132                 this.nextthink = time;
133         }
134         else
135         {
136                 this.nextthink = time + 1;
137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
138         }
139 }
140
141 void cvar_changes_init()
142 {
143         float h;
144         string k, v, d;
145         float n, i, adding, pureadding;
146
147         strfree(cvar_changes);
148         strfree(cvar_purechanges);
149         cvar_purechanges_count = 0;
150
151         h = buf_create();
152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
153         n = buf_getsize(h);
154
155         adding = true;
156         pureadding = true;
157
158         for(i = 0; i < n; ++i)
159         {
160                 k = bufstr_get(h, i);
161
162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
164 #define BADCVAR(p) if(k == p) continue
165
166                 // general excludes and namespaces for server admin used cvars
167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
168
169                 // internal
170                 BADPREFIX("csqc_");
171                 BADPREFIX("cvar_check_");
172                 BADCVAR("gamecfg");
173                 BADCVAR("g_configversion");
174                 BADCVAR("halflifebsp");
175                 BADCVAR("sv_mapformat_is_quake2");
176                 BADCVAR("sv_mapformat_is_quake3");
177                 BADPREFIX("sv_world");
178
179                 // client
180                 BADPREFIX("chase_");
181                 BADPREFIX("cl_");
182                 BADPREFIX("con_");
183                 BADPREFIX("scoreboard_");
184                 BADPREFIX("g_campaign");
185                 BADPREFIX("g_waypointsprite_");
186                 BADPREFIX("gl_");
187                 BADPREFIX("joy");
188                 BADPREFIX("hud_");
189                 BADPREFIX("m_");
190                 BADPREFIX("menu_");
191                 BADPREFIX("net_slist_");
192                 BADPREFIX("r_");
193                 BADPREFIX("sbar_");
194                 BADPREFIX("scr_");
195                 BADPREFIX("snd_");
196                 BADPREFIX("show");
197                 BADPREFIX("sensitivity");
198                 BADPREFIX("userbind");
199                 BADPREFIX("v_");
200                 BADPREFIX("vid_");
201                 BADPREFIX("crosshair");
202                 BADCVAR("mod_q3bsp_lightmapmergepower");
203                 BADCVAR("mod_q3bsp_nolightmaps");
204                 BADCVAR("fov");
205                 BADCVAR("mastervolume");
206                 BADCVAR("volume");
207                 BADCVAR("bgmvolume");
208                 BADCVAR("in_pitch_min");
209                 BADCVAR("in_pitch_max");
210
211                 // private
212                 BADCVAR("developer");
213                 BADCVAR("log_dest_udp");
214                 BADCVAR("net_address");
215                 BADCVAR("net_address_ipv6");
216                 BADCVAR("port");
217                 BADCVAR("savedgamecfg");
218                 BADCVAR("serverconfig");
219                 BADCVAR("sv_autoscreenshot");
220                 BADCVAR("sv_heartbeatperiod");
221                 BADCVAR("sv_vote_master_password");
222                 BADCVAR("sys_colortranslation");
223                 BADCVAR("sys_specialcharactertranslation");
224                 BADCVAR("timeformat");
225                 BADCVAR("timestamps");
226                 BADCVAR("g_require_stats");
227                 BADPREFIX("developer_");
228                 BADPREFIX("g_ban_");
229                 BADPREFIX("g_banned_list");
230                 BADPREFIX("g_require_stats_");
231                 BADPREFIX("g_chat_flood_");
232                 BADPREFIX("g_ghost_items");
233                 BADPREFIX("g_playerstats_");
234                 BADPREFIX("g_voice_flood_");
235                 BADPREFIX("log_file");
236                 BADPREFIX("quit_");
237                 BADPREFIX("rcon_");
238                 BADPREFIX("sv_allowdownloads");
239                 BADPREFIX("sv_autodemo");
240                 BADPREFIX("sv_curl_");
241                 BADPREFIX("sv_eventlog");
242                 BADPREFIX("sv_logscores_");
243                 BADPREFIX("sv_master");
244                 BADPREFIX("sv_weaponstats_");
245                 BADPREFIX("sv_waypointsprite_");
246                 BADCVAR("rescan_pending");
247
248                 // these can contain player IDs, so better hide
249                 BADPREFIX("g_forced_team_");
250                 BADCVAR("sv_muteban_list");
251                 BADCVAR("sv_voteban_list");
252                 BADCVAR("sv_allow_customplayermodels_idlist");
253                 BADCVAR("sv_allow_customplayermodels_speciallist");
254
255                 // mapinfo
256                 BADCVAR("fraglimit");
257                 BADCVAR("g_arena");
258                 BADCVAR("g_assault");
259                 BADCVAR("g_ca");
260                 BADCVAR("g_ca_teams");
261                 BADCVAR("g_conquest");
262                 BADCVAR("g_ctf");
263                 BADCVAR("g_cts");
264                 BADCVAR("g_dotc");
265                 BADCVAR("g_dm");
266                 BADCVAR("g_domination");
267                 BADCVAR("g_domination_default_teams");
268                 BADCVAR("g_freezetag");
269                 BADCVAR("g_freezetag_teams");
270                 BADCVAR("g_invasion_teams");
271                 BADCVAR("g_invasion_type");
272                 BADCVAR("g_jailbreak");
273                 BADCVAR("g_jailbreak_teams");
274                 BADCVAR("g_keepaway");
275                 BADCVAR("g_keyhunt");
276                 BADCVAR("g_keyhunt_teams");
277                 BADCVAR("g_lms");
278                 BADCVAR("g_nexball");
279                 BADCVAR("g_onslaught");
280                 BADCVAR("g_race");
281                 BADCVAR("g_race_laps_limit");
282                 BADCVAR("g_race_qualifying_timelimit");
283                 BADCVAR("g_race_qualifying_timelimit_override");
284                 BADCVAR("g_runematch");
285                 BADCVAR("g_snafu");
286                 BADCVAR("g_tdm");
287                 BADCVAR("g_tdm_teams");
288                 BADCVAR("g_vip");
289                 BADCVAR("leadlimit");
290                 BADCVAR("nextmap");
291                 BADCVAR("teamplay");
292                 BADCVAR("timelimit");
293                 BADCVAR("g_mapinfo_ignore_warnings");
294
295                 // long
296                 BADCVAR("hostname");
297                 BADCVAR("g_maplist");
298                 BADCVAR("g_maplist_mostrecent");
299                 BADCVAR("sv_motd");
300
301                 v = cvar_string(k);
302                 d = cvar_defstring(k);
303                 if(v == d)
304                         continue;
305
306                 if(adding)
307                 {
308                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
309                         if(strlen(cvar_changes) > 16384)
310                         {
311                                 cvar_changes = "// too many settings have been changed to show them here\n";
312                                 adding = 0;
313                         }
314                 }
315
316                 // now check if the changes are actually gameplay relevant
317
318                 // does nothing gameplay relevant
319                 BADCVAR("captureleadlimit_override");
320                 BADCVAR("condump_stripcolors");
321                 BADCVAR("gameversion");
322                 BADCVAR("g_allow_oldvortexbeam");
323                 BADCVAR("g_balance_kill_delay");
324                 BADCVAR("g_buffs_pickup_anyway");
325                 BADCVAR("g_buffs_randomize");
326                 BADCVAR("g_campcheck_distance");
327                 BADCVAR("g_ca_point_leadlimit");
328                 BADCVAR("g_ca_point_limit");
329                 BADCVAR("g_ctf_captimerecord_always");
330                 BADCVAR("g_ctf_flag_glowtrails");
331                 BADCVAR("g_ctf_flag_pickup_verbosename");
332                 BADCVAR("g_domination_point_leadlimit");
333                 BADCVAR("g_forced_respawn");
334                 BADCVAR("g_freezetag_point_leadlimit");
335                 BADCVAR("g_freezetag_point_limit");
336                 BADCVAR("g_hats");
337                 BADCVAR("g_invasion_point_limit");
338                 BADCVAR("g_jump_grunt");
339                 BADCVAR("g_keyhunt_point_leadlimit");
340                 BADCVAR("g_nexball_goalleadlimit");
341                 BADCVAR("g_new_toys_use_pickupsound");
342                 BADCVAR("g_physics_predictall");
343                 BADCVAR("g_piggyback");
344                 BADCVAR("g_playerclip_collisions");
345                 BADCVAR("g_tdm_point_leadlimit");
346                 BADCVAR("g_tdm_point_limit");
347                 BADCVAR("leadlimit_and_fraglimit");
348                 BADCVAR("leadlimit_override");
349                 BADCVAR("pausable");
350                 BADCVAR("sv_checkforpacketsduringsleep");
351                 BADCVAR("sv_damagetext");
352                 BADCVAR("sv_db_saveasdump");
353                 BADCVAR("sv_intermission_cdtrack");
354                 BADCVAR("sv_minigames");
355                 BADCVAR("sv_namechangetimer");
356                 BADCVAR("sv_precacheplayermodels");
357                 BADCVAR("sv_stepheight");
358                 BADCVAR("sv_timeout");
359                 BADCVAR("sv_weapons_modeloverride");
360                 BADCVAR("w_prop_interval");
361                 BADPREFIX("crypto_");
362                 BADPREFIX("gameversion_");
363                 BADPREFIX("g_chat_");
364                 BADPREFIX("g_ctf_captimerecord_");
365                 BADPREFIX("g_hats_");
366                 BADPREFIX("g_maplist_");
367                 BADPREFIX("g_mod_");
368                 BADPREFIX("g_respawn_");
369                 BADPREFIX("net_");
370                 BADPREFIX("notification_");
371                 BADPREFIX("prvm_");
372                 BADPREFIX("skill_");
373                 BADPREFIX("sv_allow_");
374                 BADPREFIX("sv_cullentities_");
375                 BADPREFIX("sv_maxidle_");
376                 BADPREFIX("sv_minigames_");
377                 BADPREFIX("sv_radio_");
378                 BADPREFIX("sv_timeout_");
379                 BADPREFIX("sv_vote_");
380                 BADPREFIX("timelimit_");
381
382                 // allowed changes to server admins (please sync this to server.cfg)
383                 // vi commands:
384                 //   :/"impure"/,$d
385                 //   :g!,^\/\/[^ /],d
386                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
387                 //   :%!sort
388                 // yes, this does contain some redundant stuff, don't really care
389                 BADCVAR("bot_config_file");
390                 BADCVAR("bot_number");
391                 BADCVAR("bot_prefix");
392                 BADCVAR("bot_suffix");
393                 BADCVAR("capturelimit_override");
394                 BADCVAR("fraglimit_override");
395                 BADCVAR("gametype");
396                 BADCVAR("g_antilag");
397                 BADCVAR("g_balance_teams");
398                 BADCVAR("g_balance_teams_prevent_imbalance");
399                 BADCVAR("g_balance_teams_scorefactor");
400                 BADCVAR("g_ban_sync_trusted_servers");
401                 BADCVAR("g_ban_sync_uri");
402                 BADCVAR("g_buffs");
403                 BADCVAR("g_ca_teams_override");
404                 BADCVAR("g_ctf_ignore_frags");
405                 BADCVAR("g_ctf_leaderboard");
406                 BADCVAR("g_domination_point_limit");
407                 BADCVAR("g_domination_teams_override");
408                 BADCVAR("g_freezetag_teams_override");
409                 BADCVAR("g_friendlyfire");
410                 BADCVAR("g_fullbrightitems");
411                 BADCVAR("g_fullbrightplayers");
412                 BADCVAR("g_keyhunt_point_limit");
413                 BADCVAR("g_keyhunt_teams_override");
414                 BADCVAR("g_lms_lives_override");
415                 BADCVAR("g_maplist");
416                 BADCVAR("g_maxplayers");
417                 BADCVAR("g_mirrordamage");
418                 BADCVAR("g_nexball_goallimit");
419                 BADCVAR("g_norecoil");
420                 BADCVAR("g_physics_clientselect");
421                 BADCVAR("g_pinata");
422                 BADCVAR("g_powerups");
423                 BADCVAR("g_spawnshieldtime");
424                 BADCVAR("g_start_delay");
425                 BADCVAR("g_superspectate");
426                 BADCVAR("g_tdm_teams_override");
427                 BADCVAR("g_warmup");
428                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
429                 BADCVAR("hostname");
430                 BADCVAR("log_file");
431                 BADCVAR("maxplayers");
432                 BADCVAR("minplayers");
433                 BADCVAR("net_address");
434                 BADCVAR("port");
435                 BADCVAR("rcon_password");
436                 BADCVAR("rcon_restricted_commands");
437                 BADCVAR("rcon_restricted_password");
438                 BADCVAR("skill");
439                 BADCVAR("sv_adminnick");
440                 BADCVAR("sv_autoscreenshot");
441                 BADCVAR("sv_autotaunt");
442                 BADCVAR("sv_curl_defaulturl");
443                 BADCVAR("sv_defaultcharacter");
444                 BADCVAR("sv_defaultcharacterskin");
445                 BADCVAR("sv_defaultplayercolors");
446                 BADCVAR("sv_defaultplayermodel");
447                 BADCVAR("sv_defaultplayerskin");
448                 BADCVAR("sv_maxidle");
449                 BADCVAR("sv_maxrate");
450                 BADCVAR("sv_motd");
451                 BADCVAR("sv_public");
452                 BADCVAR("sv_ready_restart");
453                 BADCVAR("sv_status_privacy");
454                 BADCVAR("sv_taunt");
455                 BADCVAR("sv_vote_call");
456                 BADCVAR("sv_vote_commands");
457                 BADCVAR("sv_vote_majority_factor");
458                 BADCVAR("sv_vote_master");
459                 BADCVAR("sv_vote_master_commands");
460                 BADCVAR("sv_vote_master_password");
461                 BADCVAR("sv_vote_simple_majority_factor");
462                 BADCVAR("teamplay_mode");
463                 BADCVAR("timelimit_override");
464                 BADPREFIX("g_warmup_");
465                 BADPREFIX("sv_info_");
466                 BADPREFIX("sv_ready_restart_");
467
468                 // mutators that announce themselves properly to the server browser
469                 BADCVAR("g_instagib");
470                 BADCVAR("g_new_toys");
471                 BADCVAR("g_nix");
472                 BADCVAR("g_grappling_hook");
473                 BADCVAR("g_jetpack");
474
475 #undef BADPRESUFFIX
476 #undef BADPREFIX
477 #undef BADCVAR
478
479                 if(pureadding)
480                 {
481                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
482                         if(strlen(cvar_purechanges) > 16384)
483                         {
484                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
485                                 pureadding = 0;
486                         }
487                 }
488                 ++cvar_purechanges_count;
489                 // WARNING: this variable is used for the server list
490                 // NEVER dare to skip this code!
491                 // Hacks to intentionally appearing as "pure server" even though you DO have
492                 // modified settings may be punished by removal from the server list.
493                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
494                 // though.
495         }
496         buf_del(h);
497         if(cvar_changes == "")
498                 cvar_changes = "// this server runs at default server settings\n";
499         else
500                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
501         cvar_changes = strzone(cvar_changes);
502         if(cvar_purechanges == "")
503                 cvar_purechanges = "// this server runs at default gameplay settings\n";
504         else
505                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
506         cvar_purechanges = strzone(cvar_purechanges);
507 }
508
509 entity randomseed;
510 bool RandomSeed_Send(entity this, entity to, int sf)
511 {
512         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
513         WriteShort(MSG_ENTITY, this.cnt);
514         return true;
515 }
516 void RandomSeed_Think(entity this)
517 {
518         this.cnt = bound(0, floor(random() * 65536), 65535);
519         this.nextthink = time + 5;
520
521         this.SendFlags |= 1;
522 }
523 void RandomSeed_Spawn()
524 {
525         randomseed = new_pure(randomseed);
526         setthink(randomseed, RandomSeed_Think);
527         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
528
529         getthink(randomseed)(randomseed); // sets random seed and nextthink
530 }
531
532 spawnfunc(__init_dedicated_server)
533 {
534         // handler for _init/_init map (only for dedicated server initialization)
535
536         world_initialized = -1; // don't complain
537         cvar = cvar_normal;
538         cvar_string = cvar_string_normal;
539         cvar_set = cvar_set_normal;
540
541         delete_fn = remove_unsafely;
542
543         entity e = spawn();
544         setthink(e, GotoFirstMap);
545         e.nextthink = time; // this is usually 1 at this point
546
547         e = new(info_player_deathmatch);  // safeguard against player joining
548
549     // assign reflectively to avoid "assignment to world" warning
550     for (int i = 0, n = numentityfields(); i < n; ++i) {
551         string k = entityfieldname(i);
552         if (k == "classname") {
553             // safeguard against various stuff ;)
554             putentityfieldstring(i, this, "worldspawn");
555             break;
556         }
557     }
558
559         // needs to be done so early because of the constants they create
560         static_init();
561         static_init_late();
562         static_init_precache();
563
564         IL_PUSH(g_spawnpoints, e); // just incase
565
566         MapInfo_Enumerate();
567         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
568 }
569
570 void __init_dedicated_server_shutdown() {
571         MapInfo_Shutdown();
572 }
573
574 STATIC_INIT_EARLY(maxclients)
575 {
576         maxclients = 0;
577         for (entity head = nextent(NULL); head; head = nextent(head)) {
578                 ++maxclients;
579         }
580 }
581
582 void default_delayedinit(entity this)
583 {
584         if(!scores_initialized)
585                 ScoreRules_generic();
586 }
587
588 void InitGameplayMode()
589 {
590         VoteReset();
591
592         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
593         get_mi_min_max(1);
594         // assign reflectively to avoid "assignment to world" warning
595         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
596             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
597             if (v) {
598             putentityfieldstring(i, world, sprintf("%v", v));
599             if (++done == 2) break;
600         }
601         }
602         // currently, NetRadiant's limit is 131072 qu for each side
603         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
604         // set the distance according to map size but don't go over the limit to avoid issues with float precision
605         // in case somebody makes extremely large maps
606         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
607
608         MapInfo_LoadMapSettings(mapname);
609         GameRules_teams(false);
610
611         if (!cvar_value_issafe(world.fog))
612         {
613                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
614                 world.fog = string_null;
615         }
616         if(MapInfo_Map_fog != "")
617                 if(MapInfo_Map_fog == "none")
618                         world.fog = string_null;
619                 else
620                         world.fog = strzone(MapInfo_Map_fog);
621         clientstuff = strzone(MapInfo_Map_clientstuff);
622
623         MapInfo_ClearTemps();
624
625         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
626
627         cache_mutatormsg = strzone("");
628         cache_lastmutatormsg = strzone("");
629
630         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
631 }
632
633 void Map_MarkAsRecent(string m);
634 float world_already_spawned;
635 spawnfunc(worldspawn)
636 {
637         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
638
639     bool wantrestart = false;
640         {
641                 if (!server_is_dedicated)
642                 {
643                         // force unloading of server pk3 files when starting a listen server
644                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
645                         // restore csqc_progname too
646                         string expect = "csprogs.dat";
647                         wantrestart = cvar_string_normal("csqc_progname") != expect;
648                         cvar_set_normal("csqc_progname", expect);
649                 }
650                 else
651                 {
652                         // Try to use versioned csprogs from pk3
653                         // Only ever use versioned csprogs.dat files on dedicated servers;
654                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
655                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
656                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
657                         string select = "csprogs.dat";
658                         if (fexists(pk3csprogs)) select = pk3csprogs;
659                         if (cvar_string_normal("csqc_progname") != select)
660                         {
661                                 cvar_set_normal("csqc_progname", select);
662                                 wantrestart = true;
663                         }
664                         // Check for updates on startup
665                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
666                         int sentinel = fopen("progs.txt", FILE_READ);
667                         if (sentinel >= 0)
668                         {
669                                 string switchversion = fgets(sentinel);
670                                 fclose(sentinel);
671                                 if (switchversion != "" && switchversion != WATERMARK)
672                                 {
673                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
674                                         // if it doesn't exist, assume either:
675                                         //   a) the current program was overwritten
676                                         //   b) this is a client only update
677                                         string newprogs = sprintf("progs-%s.dat", switchversion);
678                                         if (fexists(newprogs))
679                                         {
680                                                 cvar_set_normal("sv_progs", newprogs);
681                                                 wantrestart = true;
682                                         }
683                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
684                                         if (fexists(newcsprogs))
685                                         {
686                                                 cvar_set_normal("csqc_progname", newcsprogs);
687                                                 wantrestart = true;
688                                         }
689                                 }
690                         }
691                 }
692                 if (wantrestart)
693                 {
694                         LOG_INFOF("Restart requested");
695                         changelevel(mapname);
696                         // let initialization continue, shutdown depends on it
697                 }
698         }
699
700         cvar = cvar_normal;
701         cvar_string = cvar_string_normal;
702         cvar_set = cvar_set_normal;
703
704         if(world_already_spawned)
705                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
706         world_already_spawned = true;
707
708         delete_fn = remove_safely; // during spawning, watch what you remove!
709
710         cvar_changes_init(); // do this very early now so it REALLY matches the server config
711
712         // needs to be done so early because of the constants they create
713         static_init();
714
715         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
716
717         TemporaryDB = db_create();
718
719         // 0 normal
720         lightstyle(0, "m");
721
722         // 1 FLICKER (first variety)
723         lightstyle(1, "mmnmmommommnonmmonqnmmo");
724
725         // 2 SLOW STRONG PULSE
726         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
727
728         // 3 CANDLE (first variety)
729         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
730
731         // 4 FAST STROBE
732         lightstyle(4, "mamamamamama");
733
734         // 5 GENTLE PULSE 1
735         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
736
737         // 6 FLICKER (second variety)
738         lightstyle(6, "nmonqnmomnmomomno");
739
740         // 7 CANDLE (second variety)
741         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
742
743         // 8 CANDLE (third variety)
744         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
745
746         // 9 SLOW STROBE (fourth variety)
747         lightstyle(9, "aaaaaaaazzzzzzzz");
748
749         // 10 FLUORESCENT FLICKER
750         lightstyle(10, "mmamammmmammamamaaamammma");
751
752         // 11 SLOW PULSE NOT FADE TO BLACK
753         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
754
755         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
756
757         // 63 testing
758         lightstyle(63, "a");
759
760         if(autocvar_g_campaign)
761                 CampaignPreInit();
762
763         Map_MarkAsRecent(mapname);
764
765         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
766
767         InitGameplayMode();
768         static_init_late();
769         static_init_precache();
770         readlevelcvars();
771         GrappleHookInit();
772
773     GameRules_limit_fallbacks();
774
775         if(warmup_limit == 0)
776                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
777
778         player_count = 0;
779         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
780         if(bot_waypoints_for_items == 1)
781                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
782                         bot_waypoints_for_items = 0;
783
784         precache();
785
786         WaypointSprite_Init();
787
788         GameLogInit(); // prepare everything
789         // NOTE for matchid:
790         // changing the logic generating it is okay. But:
791         // it HAS to stay <= 64 chars
792         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
793         if(autocvar_sv_eventlog)
794         {
795                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
796                 matchid = strzone(s);
797
798                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
799                 s = ":gameinfo:mutators:LIST";
800
801                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
802                 s = M_ARGV(0, string);
803
804                 // initialiation stuff, not good in the mutator system
805                 if(!autocvar_g_use_ammunition)
806                         s = strcat(s, ":no_use_ammunition");
807
808                 // initialiation stuff, not good in the mutator system
809                 if(autocvar_g_pickup_items == 0)
810                         s = strcat(s, ":no_pickup_items");
811                 if(autocvar_g_pickup_items > 0)
812                         s = strcat(s, ":pickup_items");
813
814                 // initialiation stuff, not good in the mutator system
815                 if(autocvar_g_weaponarena != "0")
816                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
817
818                 // TODO to mutator system
819                 if(autocvar_g_norecoil)
820                         s = strcat(s, ":norecoil");
821
822                 // TODO to mutator system
823                 if(autocvar_g_powerups == 0)
824                         s = strcat(s, ":no_powerups");
825                 if(autocvar_g_powerups > 0)
826                         s = strcat(s, ":powerups");
827
828                 GameLogEcho(s);
829                 GameLogEcho(":gameinfo:end");
830         }
831         else
832                 matchid = strzone(ftos(random()));
833
834         cvar_set("nextmap", "");
835
836         SetDefaultAlpha();
837
838         if(autocvar_g_campaign)
839                 CampaignPostInit();
840
841         Ban_LoadBans();
842
843         MapInfo_Enumerate();
844         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
845
846         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
847         {
848                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
849                 if(fd != -1)
850                 {
851                         string s;
852                         while((s = fgets(fd)))
853                         {
854                                 int l = tokenize_console(s);
855                                 if(l < 2)
856                                         continue;
857                                 if(argv(0) == "cd")
858                                 {
859                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
860                                         LOG_INFO("  cdtrack ", argv(2));
861                                 }
862                                 else if(argv(0) == "fog")
863                                 {
864                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
865                                         LOG_INFO("  \"fog\" \"", s, "\"");
866                                 }
867                                 else if(argv(0) == "set")
868                                 {
869                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
870                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
871                                 }
872                                 else if(argv(0) != "//")
873                                 {
874                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
875                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
876                                 }
877                         }
878                         fclose(fd);
879                 }
880         }
881
882         WeaponStats_Init();
883
884         Nagger_Init();
885
886         next_pingtime = time + 5;
887
888         // set up information replies for clients and server to use
889         maplist_reply = strzone(getmaplist());
890         lsmaps_reply = strzone(getlsmaps());
891         monsterlist_reply = strzone(getmonsterlist());
892         for(int i = 0; i < 10; ++i)
893         {
894                 string s = getrecords(i);
895                 if (s)
896                         records_reply[i] = strzone(s);
897         }
898         ladder_reply = strzone(getladder());
899         rankings_reply = strzone(getrankings());
900
901         // begin other init
902         ClientInit_Spawn();
903         RandomSeed_Spawn();
904         PingPLReport_Spawn();
905
906         CheatInit();
907
908         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
909
910         // fill sv_curl_serverpackages from .serverpackage files
911         if (autocvar_sv_curl_serverpackages_auto)
912         {
913                 string s = "csprogs-" WATERMARK ".txt";
914                 // remove automatically managed files from the list to prevent duplicates
915                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
916                 {
917                         string pkg = argv(i);
918                         if (startsWith(pkg, "csprogs-")) continue;
919                         if (endsWith(pkg, "-serverpackage.txt")) continue;
920                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
921                         s = cons(s, pkg);
922                 }
923                 // add automatically managed files to the list
924                 #define X(match) MACRO_BEGIN { \
925                         int fd = search_begin(match, true, false); \
926                         if (fd >= 0) \
927                         { \
928                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
929                                 { \
930                                         s = cons(s, search_getfilename(fd, i)); \
931                                 } \
932                                 search_end(fd); \
933                         } \
934                 } MACRO_END
935                 X("*-serverpackage.txt");
936                 X("*.serverpackage");
937                 #undef X
938                 cvar_set("sv_curl_serverpackages", s);
939         }
940
941         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
942         modname = "Xonotic";
943         // physics/balance/config changes that count as mod
944         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
945                 modname = cvar_string("g_mod_physics");
946         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
947                 modname = cvar_string("g_mod_balance");
948         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
949                 modname = cvar_string("g_mod_config");
950         // extra mutators that deserve to count as mod
951         MUTATOR_CALLHOOK(SetModname, modname);
952         modname = M_ARGV(0, string);
953
954         // save it for later
955         modname = strzone(modname);
956
957         WinningConditionHelper(this); // set worldstatus
958
959         world_initialized = 1;
960         __spawnfunc_spawn_all();
961 }
962
963 spawnfunc(light)
964 {
965         //makestatic (this); // Who the f___ did that?
966         delete(this);
967 }
968
969 string GetGametype()
970 {
971         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
972 }
973
974 string GetMapname()
975 {
976         return mapname;
977 }
978
979 float Map_Count, Map_Current;
980 string Map_Current_Name;
981
982 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
983 float GetMaplistPosition()
984 {
985         float pos, idx;
986         string map;
987
988         map = GetMapname();
989         idx = autocvar_g_maplist_index;
990
991         if(idx >= 0)
992                 if(idx < Map_Count)
993                         if(map == argv(idx))
994                                 return idx;
995
996         for(pos = 0; pos < Map_Count; ++pos)
997                 if(map == argv(pos))
998                         return pos;
999
1000         // resume normal maplist rotation if current map is not in g_maplist
1001         return idx;
1002 }
1003
1004 bool MapHasRightSize(string map)
1005 {
1006         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1007         if(autocvar_g_maplist_check_waypoints)
1008         {
1009                 string checkwp_msg = strcat("checkwp ", map);
1010                 if(!fexists(strcat("maps/", map, ".waypoints")))
1011                 {
1012                         LOG_TRACE(checkwp_msg, ": no waypoints");
1013                         return false;
1014                 }
1015                 LOG_TRACE(checkwp_msg, ": has waypoints");
1016         }
1017
1018         // open map size restriction file
1019         string opensize_msg = strcat("opensize ", map);
1020         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1021         if(fh >= 0)
1022         {
1023                 opensize_msg = strcat(opensize_msg, ": ok, ");
1024                 int mapmin = stoi(fgets(fh));
1025                 int mapmax = stoi(fgets(fh));
1026                 fclose(fh);
1027                 if(player_count < mapmin)
1028                 {
1029                         LOG_TRACE(opensize_msg, "not enough");
1030                         return false;
1031                 }
1032                 if(mapmax && player_count > mapmax)
1033                 {
1034                         LOG_TRACE(opensize_msg, "too many");
1035                         return false;
1036                 }
1037                 LOG_TRACE(opensize_msg, "right size");
1038                 return true;
1039         }
1040         LOG_TRACE(opensize_msg, ": not found");
1041         return true;
1042 }
1043
1044 string Map_Filename(float position)
1045 {
1046         return strcat("maps/", argv(position), ".bsp");
1047 }
1048
1049 void Map_MarkAsRecent(string m)
1050 {
1051         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1052 }
1053
1054 float Map_IsRecent(string m)
1055 {
1056         return strhasword(autocvar_g_maplist_mostrecent, m);
1057 }
1058
1059 float Map_Check(float position, float pass)
1060 {
1061         string filename;
1062         string map_next;
1063         map_next = argv(position);
1064         if(pass <= 1)
1065         {
1066                 if(Map_IsRecent(map_next))
1067                         return 0;
1068         }
1069         filename = Map_Filename(position);
1070         if(MapInfo_CheckMap(map_next))
1071         {
1072                 if(pass == 2)
1073                         return 1;
1074                 if(MapHasRightSize(map_next))
1075                         return 1;
1076                 return 0;
1077         }
1078         else
1079                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1080
1081         return 0;
1082 }
1083
1084 void Map_Goto_SetStr(string nextmapname)
1085 {
1086         if(getmapname_stored != "")
1087                 strunzone(getmapname_stored);
1088         if(nextmapname == "")
1089                 getmapname_stored = "";
1090         else
1091                 getmapname_stored = strzone(nextmapname);
1092 }
1093
1094 void Map_Goto_SetFloat(float position)
1095 {
1096         cvar_set("g_maplist_index", ftos(position));
1097         Map_Goto_SetStr(argv(position));
1098 }
1099
1100 void Map_Goto(float reinit)
1101 {
1102         MapInfo_LoadMap(getmapname_stored, reinit);
1103 }
1104
1105 // return codes of map selectors:
1106 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1107 //   -2 = permanent failure
1108 float MaplistMethod_Iterate() // usual method
1109 {
1110         float pass, i;
1111
1112         LOG_TRACE("Trying MaplistMethod_Iterate");
1113
1114         for(pass = 1; pass <= 2; ++pass)
1115         {
1116                 for(i = 1; i < Map_Count; ++i)
1117                 {
1118                         float mapindex;
1119                         mapindex = (i + Map_Current) % Map_Count;
1120                         if(Map_Check(mapindex, pass))
1121                                 return mapindex;
1122                 }
1123         }
1124         return -1;
1125 }
1126
1127 float MaplistMethod_Repeat() // fallback method
1128 {
1129         LOG_TRACE("Trying MaplistMethod_Repeat");
1130
1131         if(Map_Check(Map_Current, 2))
1132                 return Map_Current;
1133         return -2;
1134 }
1135
1136 float MaplistMethod_Random() // random map selection
1137 {
1138         float i, imax;
1139
1140         LOG_TRACE("Trying MaplistMethod_Random");
1141
1142         imax = 42;
1143
1144         for(i = 0; i <= imax; ++i)
1145         {
1146                 float mapindex;
1147                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1148                 if(Map_Check(mapindex, 1))
1149                         return mapindex;
1150         }
1151         return -1;
1152 }
1153
1154 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1155 // the exponent sets a bias on the map selection:
1156 // the higher the exponent, the less likely "shortly repeated" same maps are
1157 {
1158         float i, j, imax, insertpos;
1159
1160         LOG_TRACE("Trying MaplistMethod_Shuffle");
1161
1162         imax = 42;
1163
1164         for(i = 0; i <= imax; ++i)
1165         {
1166                 string newlist;
1167
1168                 // now reinsert this at another position
1169                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1170                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1171                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1172                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1173
1174                 // insert the current map there
1175                 newlist = "";
1176                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1177                         newlist = strcat(newlist, " ", argv(j));
1178                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1179                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1180                         newlist = strcat(newlist, " ", argv(j));
1181                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1182                 cvar_set("g_maplist", newlist);
1183                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1184
1185                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1186                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1187                 if(Map_Check(Map_Current, 1))
1188                         return Map_Current;
1189         }
1190         return -1;
1191 }
1192
1193 void Maplist_Init()
1194 {
1195         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1196         float i;
1197         for (i = 0; i < Map_Count; ++i)
1198                 if (Map_Check(i, 2))
1199                         break;
1200         if (i == Map_Count)
1201         {
1202                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1203                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1204                 if(autocvar_g_maplist_shuffle)
1205                         ShuffleMaplist();
1206                 localcmd("\nmenu_cmd sync\n");
1207                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1208         }
1209         if(Map_Count == 0)
1210                 error("empty maplist, cannot select a new map");
1211         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1212
1213         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1214         // this may or may not be correct, but who cares, in the worst case a map
1215         // isn't chosen in the first pass that should have been
1216 }
1217
1218 string GetNextMap()
1219 {
1220         float nextMap;
1221
1222         Maplist_Init();
1223         nextMap = -1;
1224
1225         if(nextMap == -1)
1226                 if(autocvar_g_maplist_shuffle > 0)
1227                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1228
1229         if(nextMap == -1)
1230                 if(autocvar_g_maplist_selectrandom)
1231                         nextMap = MaplistMethod_Random();
1232
1233         if(nextMap == -1)
1234                 nextMap = MaplistMethod_Iterate();
1235
1236         if(nextMap == -1)
1237                 nextMap = MaplistMethod_Repeat();
1238
1239         if(nextMap >= 0)
1240         {
1241                 Map_Goto_SetFloat(nextMap);
1242                 return getmapname_stored;
1243         }
1244
1245         return "";
1246 }
1247
1248 float DoNextMapOverride(float reinit)
1249 {
1250         if(autocvar_g_campaign)
1251         {
1252                 CampaignPostIntermission();
1253                 alreadychangedlevel = true;
1254                 return true;
1255         }
1256         if(autocvar_quit_when_empty)
1257         {
1258                 if(player_count <= currentbots)
1259                 {
1260                         localcmd("quit\n");
1261                         alreadychangedlevel = true;
1262                         return true;
1263                 }
1264         }
1265         if(autocvar_quit_and_redirect != "")
1266         {
1267                 redirection_target = strzone(autocvar_quit_and_redirect);
1268                 alreadychangedlevel = true;
1269                 return true;
1270         }
1271         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1272         {
1273                 localcmd("restart\n");
1274                 alreadychangedlevel = true;
1275                 return true;
1276         }
1277         if(autocvar_nextmap != "")
1278         {
1279                 string m;
1280                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1281                 cvar_set("nextmap",m);
1282
1283                 if(!m || gametypevote)
1284                         return false;
1285                 if(autocvar_sv_vote_gametype)
1286                 {
1287                         Map_Goto_SetStr(m);
1288                         return false;
1289                 }
1290
1291                 if(MapInfo_CheckMap(m))
1292                 {
1293                         Map_Goto_SetStr(m);
1294                         Map_Goto(reinit);
1295                         alreadychangedlevel = true;
1296                         return true;
1297                 }
1298         }
1299         if(!reinit && autocvar_lastlevel)
1300         {
1301                 cvar_settemp_restore();
1302                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1303                 alreadychangedlevel = true;
1304                 return true;
1305         }
1306         return false;
1307 }
1308
1309 void GotoNextMap(float reinit)
1310 {
1311         //string nextmap;
1312         //float n, nummaps;
1313         //string s;
1314         if (alreadychangedlevel)
1315                 return;
1316         alreadychangedlevel = true;
1317
1318         string nextMap;
1319
1320         nextMap = GetNextMap();
1321         if(nextMap == "")
1322                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1323         Map_Goto(reinit);
1324 }
1325
1326
1327 /*
1328 ============
1329 IntermissionThink
1330
1331 When the player presses attack or jump, change to the next level
1332 ============
1333 */
1334 .float autoscreenshot;
1335 void IntermissionThink(entity this)
1336 {
1337         FixIntermissionClient(this);
1338
1339         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1340         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1341
1342         if( (server_screenshot || client_screenshot)
1343                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1344         {
1345                 this.autoscreenshot = -1;
1346                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1347                 return;
1348         }
1349
1350         if (time < intermission_exittime)
1351                 return;
1352
1353         if(!mapvote_initialized)
1354                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1355                         return;
1356
1357         MapVote_Start();
1358 }
1359
1360 /*
1361 ============
1362 FindIntermission
1363
1364 Returns the entity to view from
1365 ============
1366 */
1367 /*
1368 entity FindIntermission()
1369 {
1370         local   entity spot;
1371         local   float cyc;
1372
1373 // look for info_intermission first
1374         spot = find(NULL, classname, "info_intermission");
1375         if (spot)
1376         {       // pick a random one
1377                 cyc = random() * 4;
1378                 while (cyc > 1)
1379                 {
1380                         spot = find(spot, classname, "info_intermission");
1381                         if (!spot)
1382                                 spot = find(spot, classname, "info_intermission");
1383                         cyc = cyc - 1;
1384                 }
1385                 return spot;
1386         }
1387
1388 // then look for the start position
1389         spot = find(NULL, classname, "info_player_start");
1390         if (spot)
1391                 return spot;
1392
1393 // testinfo_player_start is only found in regioned levels
1394         spot = find(NULL, classname, "testplayerstart");
1395         if (spot)
1396                 return spot;
1397
1398 // then look for the start position
1399         spot = find(NULL, classname, "info_player_deathmatch");
1400         if (spot)
1401                 return spot;
1402
1403         //objerror ("FindIntermission: no spot");
1404         return NULL;
1405 }
1406 */
1407
1408 /*
1409 ===============================================================================
1410
1411 RULES
1412
1413 ===============================================================================
1414 */
1415
1416 void DumpStats(float final)
1417 {
1418         float file;
1419         string s;
1420         float to_console;
1421         float to_eventlog;
1422         float to_file;
1423         float i;
1424
1425         to_console = autocvar_sv_logscores_console;
1426         to_eventlog = autocvar_sv_eventlog;
1427         to_file = autocvar_sv_logscores_file;
1428
1429         if(!final)
1430         {
1431                 to_console = true; // always print printstats replies
1432                 to_eventlog = false; // but never print them to the event log
1433         }
1434
1435         if(to_eventlog)
1436                 if(autocvar_sv_eventlog_console)
1437                         to_console = false; // otherwise we get the output twice
1438
1439         if(final)
1440                 s = ":scores:";
1441         else
1442                 s = ":status:";
1443         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1444
1445         if(to_console)
1446                 LOG_INFO(s);
1447         if(to_eventlog)
1448                 GameLogEcho(s);
1449
1450         file = -1;
1451         if(to_file)
1452         {
1453                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1454                 if(file == -1)
1455                         to_file = false;
1456                 else
1457                         fputs(file, strcat(s, "\n"));
1458         }
1459
1460         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1461         if(to_console)
1462                 LOG_INFO(s);
1463         if(to_eventlog)
1464                 GameLogEcho(s);
1465         if(to_file)
1466                 fputs(file, strcat(s, "\n"));
1467
1468         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1469                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1470                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1471                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1472                         s = strcat(s, ftos(it.team), ":");
1473                 else
1474                         s = strcat(s, "spectator:");
1475
1476                 if(to_console)
1477                         LOG_INFO(s, playername(it, false));
1478                 if(to_eventlog)
1479                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1480                 if(to_file)
1481                         fputs(file, strcat(s, playername(it, false), "\n"));
1482         });
1483
1484         if(teamplay)
1485         {
1486                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1487                 if(to_console)
1488                         LOG_INFO(s);
1489                 if(to_eventlog)
1490                         GameLogEcho(s);
1491                 if(to_file)
1492                         fputs(file, strcat(s, "\n"));
1493
1494                 for(i = 1; i < 16; ++i)
1495                 {
1496                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1497                         s = strcat(s, ":", ftos(i));
1498                         if(to_console)
1499                                 LOG_INFO(s);
1500                         if(to_eventlog)
1501                                 GameLogEcho(s);
1502                         if(to_file)
1503                                 fputs(file, strcat(s, "\n"));
1504                 }
1505         }
1506
1507         if(to_console)
1508                 LOG_INFO(":end");
1509         if(to_eventlog)
1510                 GameLogEcho(":end");
1511         if(to_file)
1512         {
1513                 fputs(file, ":end\n");
1514                 fclose(file);
1515         }
1516 }
1517
1518 void FixIntermissionClient(entity e)
1519 {
1520         if(!e.autoscreenshot) // initial call
1521         {
1522                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1523                 SetResourceAmountExplicit(e, RESOURCE_HEALTH, -2342);
1524                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1525                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1526                 {
1527                     .entity weaponentity = weaponentities[slot];
1528                         if(e.(weaponentity))
1529                         {
1530                                 e.(weaponentity).effects = EF_NODRAW;
1531                                 if (e.(weaponentity).weaponchild)
1532                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1533                         }
1534                 }
1535                 if(IS_REAL_CLIENT(e))
1536                 {
1537                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1538                         RandomSelection_Init();
1539                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1540                                 RandomSelection_AddString(it, 1, 1);
1541                         });
1542                         if (RandomSelection_chosen_string != "")
1543                         {
1544                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1545                         }
1546                         msg_entity = e;
1547                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1548                 }
1549         }
1550 }
1551
1552 /*
1553 go to the next level for deathmatch
1554 only called if a time or frag limit has expired
1555 */
1556 void NextLevel()
1557 {
1558         game_stopped = true;
1559         intermission_running = 1; // game over
1560
1561         // enforce a wait time before allowing changelevel
1562         if(player_count > 0)
1563                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1564         else
1565                 intermission_exittime = -1;
1566
1567         /*
1568         WriteByte (MSG_ALL, SVC_CDTRACK);
1569         WriteByte (MSG_ALL, 3);
1570         WriteByte (MSG_ALL, 3);
1571         // done in FixIntermission
1572         */
1573
1574         //pos = FindIntermission ();
1575
1576         VoteReset();
1577
1578         DumpStats(true);
1579
1580         // send statistics
1581         PlayerStats_GameReport(true);
1582         WeaponStats_Shutdown();
1583
1584         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1585
1586         if(autocvar_sv_eventlog)
1587                 GameLogEcho(":gameover");
1588
1589         GameLogClose();
1590
1591         FOREACH_CLIENT(IS_PLAYER(it), {
1592                 FixIntermissionClient(it);
1593                 if(it.winning)
1594                         bprint(playername(it, false), " ^7wins.\n");
1595         });
1596
1597         target_music_kill();
1598
1599         if(autocvar_g_campaign)
1600                 CampaignPreIntermission();
1601
1602         MUTATOR_CALLHOOK(MatchEnd);
1603
1604         localcmd("\nsv_hook_gameend\n");
1605 }
1606
1607
1608 float InitiateSuddenDeath()
1609 {
1610         // Check first whether normal overtimes could be added before initiating suddendeath mode
1611         // - for this timelimit_overtime needs to be >0 of course
1612         // - also check the winning condition calculated in the previous frame and only add normal overtime
1613         //   again, if at the point at which timelimit would be extended again, still no winner was found
1614         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1615         {
1616                 return 1; // need to call InitiateOvertime later
1617         }
1618         else
1619         {
1620                 if(!checkrules_suddendeathend)
1621                 {
1622                         if(autocvar_g_campaign)
1623                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1624                         else
1625                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1626                         if(g_race && !g_race_qualifying)
1627                                 race_StartCompleting();
1628                 }
1629                 return 0;
1630         }
1631 }
1632
1633 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1634 {
1635         ++checkrules_overtimesadded;
1636         //add one more overtime by simply extending the timelimit
1637         float tl;
1638         tl = autocvar_timelimit;
1639         tl += autocvar_timelimit_overtime;
1640         cvar_set("timelimit", ftos(tl));
1641
1642         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1643 }
1644
1645 float GetWinningCode(float fraglimitreached, float equality)
1646 {
1647         if(autocvar_g_campaign == 1)
1648                 if(fraglimitreached)
1649                         return WINNING_YES;
1650                 else
1651                         return WINNING_NO;
1652
1653         else
1654                 if(equality)
1655                         if(fraglimitreached)
1656                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1657                         else
1658                                 return WINNING_NEVER;
1659                 else
1660                         if(fraglimitreached)
1661                                 return WINNING_YES;
1662                         else
1663                                 return WINNING_NO;
1664 }
1665
1666 // set the .winning flag for exactly those players with a given field value
1667 void SetWinners(.float field, float value)
1668 {
1669         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1670 }
1671
1672 // set the .winning flag for those players with a given field value
1673 void AddWinners(.float field, float value)
1674 {
1675         FOREACH_CLIENT(IS_PLAYER(it), {
1676                 if(it.(field) == value)
1677                         it.winning = 1;
1678         });
1679 }
1680
1681 // clear the .winning flags
1682 void ClearWinners()
1683 {
1684         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1685 }
1686
1687 void ShuffleMaplist()
1688 {
1689         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1690 }
1691
1692 float leaderfrags;
1693 float WinningCondition_Scores(float limit, float leadlimit)
1694 {
1695         float limitreached;
1696
1697         // TODO make everything use THIS winning condition (except LMS)
1698         WinningConditionHelper(NULL);
1699
1700         if(teamplay)
1701         {
1702                 for (int i = 1; i < 5; ++i)
1703                 {
1704                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1705                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1706                 }
1707         }
1708
1709         ClearWinners();
1710         if(WinningConditionHelper_winner)
1711                 WinningConditionHelper_winner.winning = 1;
1712         if(WinningConditionHelper_winnerteam >= 0)
1713                 SetWinners(team, WinningConditionHelper_winnerteam);
1714
1715         if(WinningConditionHelper_lowerisbetter)
1716         {
1717                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1718                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1719                 limit = -limit;
1720         }
1721
1722         if(WinningConditionHelper_zeroisworst)
1723                 leadlimit = 0; // not supported in this mode
1724
1725         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1726         // these modes always score in increments of 1, thus this makes sense
1727         {
1728                 if(leaderfrags != WinningConditionHelper_topscore)
1729                 {
1730                         leaderfrags = WinningConditionHelper_topscore;
1731
1732                         if (limit)
1733                         if (leaderfrags == limit - 1)
1734                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1735                         else if (leaderfrags == limit - 2)
1736                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1737                         else if (leaderfrags == limit - 3)
1738                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1739                 }
1740         }
1741
1742         limitreached = false;
1743         if(limit)
1744                 if(WinningConditionHelper_topscore >= limit)
1745                         limitreached = true;
1746         if(leadlimit)
1747         {
1748                 float leadlimitreached;
1749                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1750                 if(autocvar_leadlimit_and_fraglimit)
1751                         limitreached = (limitreached && leadlimitreached);
1752                 else
1753                         limitreached = (limitreached || leadlimitreached);
1754         }
1755
1756         if(limit)
1757                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1758
1759         return GetWinningCode(
1760                 WinningConditionHelper_topscore && limitreached,
1761                 WinningConditionHelper_equality
1762         );
1763 }
1764
1765 float WinningCondition_RanOutOfSpawns()
1766 {
1767         if(have_team_spawns <= 0)
1768                 return WINNING_NO;
1769
1770         if(!autocvar_g_spawn_useallspawns)
1771                 return WINNING_NO;
1772
1773         if(!some_spawn_has_been_used)
1774                 return WINNING_NO;
1775
1776         for (int i = 1; i < 5; ++i)
1777         {
1778                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1779         }
1780         
1781         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1782         {
1783                 if (Team_IsValidTeam(it.team))
1784                 {
1785                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1786                 }
1787         });
1788
1789         IL_EACH(g_spawnpoints, true,
1790         {
1791                 if (Team_IsValidTeam(it.team))
1792                 {
1793                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1794                 }
1795         });
1796
1797         ClearWinners();
1798         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1799         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1800         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1801         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1802         if(team1_score + team2_score + team3_score + team4_score == 0)
1803         {
1804                 checkrules_equality = true;
1805                 return WINNING_YES;
1806         }
1807         else if(team1_score + team2_score + team3_score + team4_score == 1)
1808         {
1809                 float t, i;
1810                 if(team1_score)
1811                         t = 1;
1812                 else if(team2_score)
1813                         t = 2;
1814                 else if(team3_score)
1815                         t = 3;
1816                 else // if(team4_score)
1817                         t = 4;
1818                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1819                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1820                 {
1821                         for (int j = 1; j <= NUM_TEAMS; ++j)
1822                         {
1823                                 if (t == j)
1824                                 {
1825                                         continue;
1826                                 }
1827                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1828                                 {
1829                                         continue;
1830                                 }
1831                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1832                         }
1833                 }
1834
1835                 AddWinners(team, t);
1836                 return WINNING_YES;
1837         }
1838         else
1839                 return WINNING_NO;
1840 }
1841
1842 /*
1843 ============
1844 CheckRules_World
1845
1846 Exit deathmatch games upon conditions
1847 ============
1848 */
1849 void CheckRules_World()
1850 {
1851         float timelimit;
1852         float fraglimit;
1853         float leadlimit;
1854
1855         VoteThink();
1856         MapVote_Think();
1857
1858         SetDefaultAlpha();
1859
1860         if (intermission_running) // someone else quit the game already
1861         {
1862                 if(player_count == 0) // Nobody there? Then let's go to the next map
1863                         MapVote_Start();
1864                         // this will actually check the player count in the next frame
1865                         // again, but this shouldn't hurt
1866                 return;
1867         }
1868
1869         timelimit = autocvar_timelimit * 60;
1870         fraglimit = autocvar_fraglimit;
1871         leadlimit = autocvar_leadlimit;
1872
1873         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1874         {
1875                 if(timelimit > 0)
1876                         timelimit = 0; // timelimit is not made for warmup
1877                 if(fraglimit > 0)
1878                         fraglimit = 0; // no fraglimit for now
1879                 leadlimit = 0; // no leadlimit for now
1880         }
1881
1882         if(timelimit > 0)
1883         {
1884                 timelimit += game_starttime;
1885         }
1886         else if (timelimit < 0)
1887         {
1888                 // endmatch
1889                 NextLevel();
1890                 return;
1891         }
1892
1893         float wantovertime;
1894         wantovertime = 0;
1895
1896         if(timelimit > game_starttime)
1897                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1898         else
1899                 game_completion_ratio = 0;
1900
1901         if(checkrules_suddendeathend)
1902         {
1903                 if(!checkrules_suddendeathwarning)
1904                 {
1905                         checkrules_suddendeathwarning = true;
1906                         if(g_race && !g_race_qualifying)
1907                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1908                         else
1909                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1910                 }
1911         }
1912         else
1913         {
1914                 if (timelimit && time >= timelimit)
1915                 {
1916                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1917                         {
1918                                 float totalplayers;
1919                                 float playerswithlaps;
1920                                 float readyplayers;
1921                                 totalplayers = playerswithlaps = readyplayers = 0;
1922                                 FOREACH_CLIENT(IS_PLAYER(it), {
1923                                         ++totalplayers;
1924                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1925                                                 ++playerswithlaps;
1926                                         if(it.ready)
1927                                                 ++readyplayers;
1928                                 });
1929
1930                                 // at least 2 of the players have completed a lap: start the RACE
1931                                 // otherwise, the players should end the qualifying on their own
1932                                 if(readyplayers || playerswithlaps >= 2)
1933                                 {
1934                                         checkrules_suddendeathend = 0;
1935                                         ReadyRestart(); // go to race
1936                                         return;
1937                                 }
1938                                 else
1939                                         wantovertime |= InitiateSuddenDeath();
1940                         }
1941                         else
1942                                 wantovertime |= InitiateSuddenDeath();
1943                 }
1944         }
1945
1946         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1947         {
1948                 NextLevel();
1949                 return;
1950         }
1951
1952         int checkrules_status = WinningCondition_RanOutOfSpawns();
1953         if(checkrules_status == WINNING_YES)
1954                 bprint("Hey! Someone ran out of spawns!\n");
1955         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1956                 checkrules_status = M_ARGV(0, float);
1957         else
1958                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1959
1960         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1961         {
1962                 checkrules_status = WINNING_NEVER;
1963                 checkrules_overtimesadded = -1;
1964                 wantovertime |= InitiateSuddenDeath();
1965         }
1966
1967         if(checkrules_status == WINNING_NEVER)
1968                 // equality cases! Nobody wins if the overtime ends in a draw.
1969                 ClearWinners();
1970
1971         if(wantovertime)
1972         {
1973                 if(checkrules_status == WINNING_NEVER)
1974                         InitiateOvertime();
1975                 else
1976                         checkrules_status = WINNING_YES;
1977         }
1978
1979         if(checkrules_suddendeathend)
1980                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1981                         checkrules_status = WINNING_YES;
1982
1983         if(checkrules_status == WINNING_YES)
1984         {
1985                 //print("WINNING\n");
1986                 NextLevel();
1987         }
1988 }
1989
1990 string GotoMap(string m)
1991 {
1992         m = GameTypeVote_MapInfo_FixName(m);
1993         if (!m)
1994                 return "The map you suggested is not available on this server.";
1995         if (!autocvar_sv_vote_gametype)
1996         if(!MapInfo_CheckMap(m))
1997                 return "The map you suggested does not support the current game mode.";
1998         cvar_set("nextmap", m);
1999         cvar_set("timelimit", "-1");
2000         if(mapvote_initialized || alreadychangedlevel)
2001         {
2002                 if(DoNextMapOverride(0))
2003                         return "Map switch initiated.";
2004                 else
2005                         return "Hm... no. For some reason I like THIS map more.";
2006         }
2007         else
2008                 return "Map switch will happen after scoreboard.";
2009 }
2010
2011 bool autocvar_sv_gameplayfix_multiplethinksperframe;
2012 void RunThink(entity this)
2013 {
2014         // don't let things stay in the past.
2015         // it is possible to start that way by a trigger with a local time.
2016         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2017                 return;
2018
2019         float oldtime = time; // do we need to save this?
2020
2021         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2022         {
2023                 time = max(oldtime, this.nextthink);
2024                 this.nextthink = 0;
2025
2026                 if(getthink(this))
2027                         getthink(this)(this);
2028                 // mods often set nextthink to time to cause a think every frame,
2029                 // we don't want to loop in that case, so exit if the new nextthink is
2030                 // <= the time the qc was told, also exit if it is past the end of the
2031                 // frame
2032                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2033                         break;
2034         }
2035
2036         time = oldtime;
2037 }
2038
2039 bool autocvar_sv_freezenonclients;
2040 bool autocvar_sv_gameplayfix_delayprojectiles;
2041 void Physics_Frame()
2042 {
2043         if(autocvar_sv_freezenonclients)
2044                 return;
2045
2046         FOREACH_ENTITY_FLOAT(pure_data, false,
2047         {
2048                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2049                         continue;
2050
2051                 //set_movetype(it, it.move_movetype);
2052                 // inline the set_movetype function, since this is called a lot
2053                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2054
2055                 if(it.move_movetype == MOVETYPE_NONE)
2056                         continue;
2057
2058                 if(it.move_qcphysics)
2059                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2060
2061                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2062                 {
2063                         // handle thinking here
2064                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2065                                 RunThink(it);
2066                 }
2067         });
2068
2069         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2070                 return;
2071
2072         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2073         {
2074                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2075                         continue;
2076                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2077         });
2078 }
2079
2080 void systems_update();
2081 void EndFrame()
2082 {
2083         anticheat_endframe();
2084
2085         Physics_Frame();
2086
2087         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2088                 entity e = IS_SPEC(it) ? it.enemy : it;
2089                 if (e.typehitsound) {
2090                         STAT(TYPEHIT_TIME, it) = time;
2091                 } else if (e.killsound) {
2092                         STAT(KILL_TIME, it) = time;
2093                 } else if (e.damage_dealt) {
2094                         STAT(HIT_TIME, it) = time;
2095                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2096                 }
2097         });
2098         // add 1 frametime because after this, engine SV_Physics
2099         // increases time by a frametime and then networks the frame
2100         // add another frametime because client shows everything with
2101         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2102         // needed!
2103         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2104         FOREACH_CLIENT(true, {
2105                 it.typehitsound = false;
2106                 it.damage_dealt = 0;
2107                 it.killsound = false;
2108                 antilag_record(it, CS(it), altime);
2109         });
2110         IL_EACH(g_monsters, true,
2111         {
2112                 antilag_record(it, it, altime);
2113         });
2114         IL_EACH(g_projectiles, it.classname == "nade",
2115         {
2116                 antilag_record(it, it, altime);
2117         });
2118         systems_update();
2119         IL_ENDFRAME();
2120 }
2121
2122
2123 /*
2124  * RedirectionThink:
2125  * returns true if redirecting
2126  */
2127 float redirection_timeout;
2128 float redirection_nextthink;
2129 float RedirectionThink()
2130 {
2131         float clients_found;
2132
2133         if(redirection_target == "")
2134                 return false;
2135
2136         if(!redirection_timeout)
2137         {
2138                 cvar_set("sv_public", "-2");
2139                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2140                 if(redirection_target == "self")
2141                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2142                 else
2143                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2144         }
2145
2146         if(time < redirection_nextthink)
2147                 return true;
2148
2149         redirection_nextthink = time + 1;
2150
2151         clients_found = 0;
2152         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2153                 // TODO add timer
2154                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2155                 if(redirection_target == "self")
2156                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2157                 else
2158                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2159                 ++clients_found;
2160         });
2161
2162         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2163
2164         if(time > redirection_timeout || clients_found == 0)
2165                 localcmd("\nwait; wait; wait; quit\n");
2166
2167         return true;
2168 }
2169
2170 void RestoreGame()
2171 {
2172         // Loaded from a save game
2173         // some things then break, so let's work around them...
2174
2175         // Progs DB (capture records)
2176         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2177
2178         // Mapinfo
2179         MapInfo_Shutdown();
2180         MapInfo_Enumerate();
2181         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2182         WeaponStats_Init();
2183
2184         TargetMusic_RestoreGame();
2185 }
2186
2187 void Shutdown()
2188 {
2189         game_stopped = 2;
2190
2191         if(world_initialized > 0)
2192         {
2193                 world_initialized = 0;
2194                 LOG_TRACE("Saving persistent data...");
2195                 Ban_SaveBans();
2196
2197                 // playerstats with unfinished match
2198                 PlayerStats_GameReport(false);
2199
2200                 if(!cheatcount_total)
2201                 {
2202                         if(autocvar_sv_db_saveasdump)
2203                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2204                         else
2205                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2206                 }
2207                 if(autocvar_developer)
2208                 {
2209                         if(autocvar_sv_db_saveasdump)
2210                                 db_dump(TemporaryDB, "server-temp.db");
2211                         else
2212                                 db_save(TemporaryDB, "server-temp.db");
2213                 }
2214                 CheatShutdown(); // must be after cheatcount check
2215                 db_close(ServerProgsDB);
2216                 db_close(TemporaryDB);
2217                 LOG_TRACE("Saving persistent data... done!");
2218                 // tell the bot system the game is ending now
2219                 bot_endgame();
2220
2221                 WeaponStats_Shutdown();
2222                 MapInfo_Shutdown();
2223         }
2224         else if(world_initialized == 0)
2225         {
2226                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2227         }
2228         else
2229         {
2230                 __init_dedicated_server_shutdown();
2231         }
2232 }