Whitelist sv_mapchange_delay
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2
3 #include "anticheat.qh"
4 #include "antilag.qh"
5 #include "bot/api.qh"
6 #include "campaign.qh"
7 #include "cheats.qh"
8 #include "client.qh"
9 #include "command/common.qh"
10 #include "command/getreplies.qh"
11 #include "command/sv_cmd.qh"
12 #include "command/vote.qh"
13 #include "g_hook.qh"
14 #include "ipban.qh"
15 #include "mapvoting.qh"
16 #include <server/mutators/_mod.qh>
17 #include "race.qh"
18 #include "scores.qh"
19 #include "scores_rules.qh"
20 #include "teamplay.qh"
21 #include "weapons/weaponstats.qh"
22 #include "../common/constants.qh"
23 #include <common/net_linked.qh>
24 #include "../common/deathtypes/all.qh"
25 #include "../common/gamemodes/sv_rules.qh"
26 #include "../common/mapinfo.qh"
27 #include "../common/monsters/_mod.qh"
28 #include "../common/monsters/sv_monsters.qh"
29 #include "../common/vehicles/all.qh"
30 #include "../common/notifications/all.qh"
31 #include "../common/physics/player.qh"
32 #include "../common/playerstats.qh"
33 #include "../common/stats.qh"
34 #include "../common/teams.qh"
35 #include "../common/mapobjects/trigger/secret.qh"
36 #include "../common/mapobjects/target/music.qh"
37 #include "../common/util.qh"
38 #include "../common/items/_mod.qh"
39 #include <common/weapons/_all.qh>
40 #include "../common/state.qh"
41
42 const float LATENCY_THINKRATE = 10;
43 .float latency_sum;
44 .float latency_cnt;
45 .float latency_time;
46 entity pingplreport;
47 void PingPLReport_Think(entity this)
48 {
49         float delta;
50         entity e;
51
52         delta = 3 / maxclients;
53         if(delta < sys_frametime)
54                 delta = 0;
55         this.nextthink = time + delta;
56
57         e = edict_num(this.cnt + 1);
58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
59         {
60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
61                 WriteByte(MSG_BROADCAST, this.cnt);
62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
65
66                 // record latency times for clients throughout the match so we can report it to playerstats
67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
68                 {
69                         CS(e).latency_sum += CS(e).ping;
70                         CS(e).latency_cnt += 1;
71                         CS(e).latency_time = time;
72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
73                 }
74         }
75         else
76         {
77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
78                 WriteByte(MSG_BROADCAST, this.cnt);
79                 WriteShort(MSG_BROADCAST, 0);
80                 WriteByte(MSG_BROADCAST, 0);
81                 WriteByte(MSG_BROADCAST, 0);
82         }
83         this.cnt = (this.cnt + 1) % maxclients;
84 }
85 void PingPLReport_Spawn()
86 {
87         pingplreport = new_pure(pingplreport);
88         setthink(pingplreport, PingPLReport_Think);
89         pingplreport.nextthink = time;
90 }
91
92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
93 string redirection_target;
94 float world_initialized;
95
96 void SetDefaultAlpha()
97 {
98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
99         {
100                 default_player_alpha = autocvar_g_player_alpha;
101                 if(default_player_alpha == 0)
102                         default_player_alpha = 1;
103                 default_weapon_alpha = default_player_alpha;
104         }
105 }
106
107 void GotoFirstMap(entity this)
108 {
109         float n;
110         if(autocvar__sv_init)
111         {
112                 // cvar_set("_sv_init", "0");
113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
114                 // to this "init" map on a dedicated server will cause no permanent
115                 // harm
116                 if(autocvar_g_maplist_shuffle)
117                         ShuffleMaplist();
118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
120
121                 MapInfo_Enumerate();
122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
123
124                 if(!DoNextMapOverride(1))
125                         GotoNextMap(1);
126
127                 return;
128         }
129
130         if(time < 5)
131         {
132                 this.nextthink = time;
133         }
134         else
135         {
136                 this.nextthink = time + 1;
137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
138         }
139 }
140
141 void cvar_changes_init()
142 {
143         float h;
144         string k, v, d;
145         float n, i, adding, pureadding;
146
147         strfree(cvar_changes);
148         strfree(cvar_purechanges);
149         cvar_purechanges_count = 0;
150
151         h = buf_create();
152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
153         n = buf_getsize(h);
154
155         adding = true;
156         pureadding = true;
157
158         for(i = 0; i < n; ++i)
159         {
160                 k = bufstr_get(h, i);
161
162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
164 #define BADCVAR(p) if(k == p) continue
165
166                 // general excludes and namespaces for server admin used cvars
167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
168
169                 // internal
170                 BADPREFIX("csqc_");
171                 BADPREFIX("cvar_check_");
172                 BADCVAR("gamecfg");
173                 BADCVAR("g_configversion");
174                 BADCVAR("halflifebsp");
175                 BADCVAR("sv_mapformat_is_quake2");
176                 BADCVAR("sv_mapformat_is_quake3");
177                 BADPREFIX("sv_world");
178
179                 // client
180                 BADPREFIX("chase_");
181                 BADPREFIX("cl_");
182                 BADPREFIX("con_");
183                 BADPREFIX("scoreboard_");
184                 BADPREFIX("g_campaign");
185                 BADPREFIX("g_waypointsprite_");
186                 BADPREFIX("gl_");
187                 BADPREFIX("joy");
188                 BADPREFIX("hud_");
189                 BADPREFIX("m_");
190                 BADPREFIX("menu_");
191                 BADPREFIX("net_slist_");
192                 BADPREFIX("r_");
193                 BADPREFIX("sbar_");
194                 BADPREFIX("scr_");
195                 BADPREFIX("snd_");
196                 BADPREFIX("show");
197                 BADPREFIX("sensitivity");
198                 BADPREFIX("userbind");
199                 BADPREFIX("v_");
200                 BADPREFIX("vid_");
201                 BADPREFIX("crosshair");
202                 BADCVAR("mod_q3bsp_lightmapmergepower");
203                 BADCVAR("mod_q3bsp_nolightmaps");
204                 BADCVAR("fov");
205                 BADCVAR("mastervolume");
206                 BADCVAR("volume");
207                 BADCVAR("bgmvolume");
208                 BADCVAR("in_pitch_min");
209                 BADCVAR("in_pitch_max");
210
211                 // private
212                 BADCVAR("developer");
213                 BADCVAR("log_dest_udp");
214                 BADCVAR("net_address");
215                 BADCVAR("net_address_ipv6");
216                 BADCVAR("port");
217                 BADCVAR("savedgamecfg");
218                 BADCVAR("serverconfig");
219                 BADCVAR("sv_autoscreenshot");
220                 BADCVAR("sv_heartbeatperiod");
221                 BADCVAR("sv_vote_master_password");
222                 BADCVAR("sys_colortranslation");
223                 BADCVAR("sys_specialcharactertranslation");
224                 BADCVAR("timeformat");
225                 BADCVAR("timestamps");
226                 BADCVAR("g_require_stats");
227                 BADPREFIX("developer_");
228                 BADPREFIX("g_ban_");
229                 BADPREFIX("g_banned_list");
230                 BADPREFIX("g_require_stats_");
231                 BADPREFIX("g_chat_flood_");
232                 BADPREFIX("g_ghost_items");
233                 BADPREFIX("g_playerstats_");
234                 BADPREFIX("g_voice_flood_");
235                 BADPREFIX("log_file");
236                 BADPREFIX("quit_");
237                 BADPREFIX("rcon_");
238                 BADPREFIX("sv_allowdownloads");
239                 BADPREFIX("sv_autodemo");
240                 BADPREFIX("sv_curl_");
241                 BADPREFIX("sv_eventlog");
242                 BADPREFIX("sv_logscores_");
243                 BADPREFIX("sv_master");
244                 BADPREFIX("sv_weaponstats_");
245                 BADPREFIX("sv_waypointsprite_");
246                 BADCVAR("rescan_pending");
247
248                 // these can contain player IDs, so better hide
249                 BADPREFIX("g_forced_team_");
250                 BADCVAR("sv_muteban_list");
251                 BADCVAR("sv_voteban_list");
252                 BADCVAR("sv_allow_customplayermodels_idlist");
253                 BADCVAR("sv_allow_customplayermodels_speciallist");
254
255                 // mapinfo
256                 BADCVAR("fraglimit");
257                 BADCVAR("g_arena");
258                 BADCVAR("g_assault");
259                 BADCVAR("g_ca");
260                 BADCVAR("g_ca_teams");
261                 BADCVAR("g_conquest");
262                 BADCVAR("g_ctf");
263                 BADCVAR("g_cts");
264                 BADCVAR("g_dotc");
265                 BADCVAR("g_dm");
266                 BADCVAR("g_domination");
267                 BADCVAR("g_domination_default_teams");
268                 BADCVAR("g_duel");
269                 BADCVAR("g_duel_not_dm_maps");
270                 BADCVAR("g_freezetag");
271                 BADCVAR("g_freezetag_teams");
272                 BADCVAR("g_invasion_teams");
273                 BADCVAR("g_invasion_type");
274                 BADCVAR("g_jailbreak");
275                 BADCVAR("g_jailbreak_teams");
276                 BADCVAR("g_keepaway");
277                 BADCVAR("g_keyhunt");
278                 BADCVAR("g_keyhunt_teams");
279                 BADCVAR("g_lms");
280                 BADCVAR("g_nexball");
281                 BADCVAR("g_onslaught");
282                 BADCVAR("g_race");
283                 BADCVAR("g_race_laps_limit");
284                 BADCVAR("g_race_qualifying_timelimit");
285                 BADCVAR("g_race_qualifying_timelimit_override");
286                 BADCVAR("g_runematch");
287                 BADCVAR("g_shootfromeye");
288                 BADCVAR("g_snafu");
289                 BADCVAR("g_tdm");
290                 BADCVAR("g_tdm_on_dm_maps");
291                 BADCVAR("g_tdm_teams");
292                 BADCVAR("g_vip");
293                 BADCVAR("leadlimit");
294                 BADCVAR("nextmap");
295                 BADCVAR("teamplay");
296                 BADCVAR("timelimit");
297                 BADCVAR("g_mapinfo_ignore_warnings");
298                 BADCVAR("g_maplist_ignore_sizes");
299                 BADCVAR("g_maplist_sizes_count_bots");
300
301                 // long
302                 BADCVAR("hostname");
303                 BADCVAR("g_maplist");
304                 BADCVAR("g_maplist_mostrecent");
305                 BADCVAR("sv_motd");
306
307                 v = cvar_string(k);
308                 d = cvar_defstring(k);
309                 if(v == d)
310                         continue;
311
312                 if(adding)
313                 {
314                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
315                         if(strlen(cvar_changes) > 16384)
316                         {
317                                 cvar_changes = "// too many settings have been changed to show them here\n";
318                                 adding = 0;
319                         }
320                 }
321
322                 // now check if the changes are actually gameplay relevant
323
324                 // does nothing gameplay relevant
325                 BADCVAR("captureleadlimit_override");
326                 BADCVAR("condump_stripcolors");
327                 BADCVAR("gameversion");
328                 BADCVAR("fs_gamedir");
329                 BADCVAR("g_allow_oldvortexbeam");
330                 BADCVAR("g_balance_kill_delay");
331                 BADCVAR("g_buffs_pickup_anyway");
332                 BADCVAR("g_buffs_randomize");
333                 BADCVAR("g_campcheck_distance");
334                 BADCVAR("g_ca_point_leadlimit");
335                 BADCVAR("g_ca_point_limit");
336                 BADCVAR("g_ctf_captimerecord_always");
337                 BADCVAR("g_ctf_flag_glowtrails");
338                 BADCVAR("g_ctf_flag_pickup_verbosename");
339                 BADCVAR("g_domination_point_leadlimit");
340                 BADCVAR("g_forced_respawn");
341                 BADCVAR("g_freezetag_point_leadlimit");
342                 BADCVAR("g_freezetag_point_limit");
343                 BADCVAR("g_hats");
344                 BADCVAR("g_invasion_point_limit");
345                 BADCVAR("g_jump_grunt");
346                 BADCVAR("g_keyhunt_point_leadlimit");
347                 BADCVAR("g_nexball_goalleadlimit");
348                 BADCVAR("g_new_toys_autoreplace");
349                 BADCVAR("g_new_toys_use_pickupsound");
350                 BADCVAR("g_physics_predictall");
351                 BADCVAR("g_piggyback");
352                 BADCVAR("g_playerclip_collisions");
353                 BADCVAR("g_spawn_alloweffects");
354                 BADCVAR("g_tdm_point_leadlimit");
355                 BADCVAR("g_tdm_point_limit");
356                 BADCVAR("leadlimit_and_fraglimit");
357                 BADCVAR("leadlimit_override");
358                 BADCVAR("pausable");
359                 BADCVAR("sv_checkforpacketsduringsleep");
360                 BADCVAR("sv_damagetext");
361                 BADCVAR("sv_db_saveasdump");
362                 BADCVAR("sv_intermission_cdtrack");
363                 BADCVAR("sv_mapchange_delay");
364                 BADCVAR("sv_minigames");
365                 BADCVAR("sv_namechangetimer");
366                 BADCVAR("sv_precacheplayermodels");
367                 BADCVAR("sv_stepheight");
368                 BADCVAR("sv_timeout");
369                 BADCVAR("sv_weapons_modeloverride");
370                 BADCVAR("w_prop_interval");
371                 BADPREFIX("crypto_");
372                 BADPREFIX("gameversion_");
373                 BADPREFIX("g_chat_");
374                 BADPREFIX("g_ctf_captimerecord_");
375                 BADPREFIX("g_hats_");
376                 BADPREFIX("g_maplist_");
377                 BADPREFIX("g_mod_");
378                 BADPREFIX("g_respawn_");
379                 BADPREFIX("net_");
380                 BADPREFIX("notification_");
381                 BADPREFIX("prvm_");
382                 BADPREFIX("skill_");
383                 BADPREFIX("sv_allow_");
384                 BADPREFIX("sv_cullentities_");
385                 BADPREFIX("sv_maxidle_");
386                 BADPREFIX("sv_minigames_");
387                 BADPREFIX("sv_radio_");
388                 BADPREFIX("sv_timeout_");
389                 BADPREFIX("sv_vote_");
390                 BADPREFIX("timelimit_");
391
392                 // allowed changes to server admins (please sync this to server.cfg)
393                 // vi commands:
394                 //   :/"impure"/,$d
395                 //   :g!,^\/\/[^ /],d
396                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
397                 //   :%!sort
398                 // yes, this does contain some redundant stuff, don't really care
399                 BADCVAR("bot_config_file");
400                 BADCVAR("bot_number");
401                 BADCVAR("bot_prefix");
402                 BADCVAR("bot_suffix");
403                 BADCVAR("capturelimit_override");
404                 BADCVAR("fraglimit_override");
405                 BADCVAR("gametype");
406                 BADCVAR("g_antilag");
407                 BADCVAR("g_balance_teams");
408                 BADCVAR("g_balance_teams_prevent_imbalance");
409                 BADCVAR("g_balance_teams_scorefactor");
410                 BADCVAR("g_ban_sync_trusted_servers");
411                 BADCVAR("g_ban_sync_uri");
412                 BADCVAR("g_buffs");
413                 BADCVAR("g_ca_teams_override");
414                 BADCVAR("g_ctf_fullbrightflags");
415                 BADCVAR("g_ctf_ignore_frags");
416                 BADCVAR("g_ctf_leaderboard");
417                 BADCVAR("g_domination_point_limit");
418                 BADCVAR("g_domination_teams_override");
419                 BADCVAR("g_freezetag_teams_override");
420                 BADCVAR("g_friendlyfire");
421                 BADCVAR("g_fullbrightitems");
422                 BADCVAR("g_fullbrightplayers");
423                 BADCVAR("g_keyhunt_point_limit");
424                 BADCVAR("g_keyhunt_teams_override");
425                 BADCVAR("g_lms_lives_override");
426                 BADCVAR("g_maplist");
427                 BADCVAR("g_maxplayers");
428                 BADCVAR("g_mirrordamage");
429                 BADCVAR("g_nexball_goallimit");
430                 BADCVAR("g_norecoil");
431                 BADCVAR("g_physics_clientselect");
432                 BADCVAR("g_pinata");
433                 BADCVAR("g_powerups");
434                 BADCVAR("g_player_brightness");
435                 BADCVAR("g_rocket_flying");
436                 BADCVAR("g_rocket_flying_disabledelays");
437                 BADCVAR("g_spawnshieldtime");
438                 BADCVAR("g_start_delay");
439                 BADCVAR("g_superspectate");
440                 BADCVAR("g_tdm_teams_override");
441                 BADCVAR("g_warmup");
442                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
443                 BADCVAR("hostname");
444                 BADCVAR("log_file");
445                 BADCVAR("maxplayers");
446                 BADCVAR("minplayers");
447                 BADCVAR("minplayers_per_team");
448                 BADCVAR("net_address");
449                 BADCVAR("port");
450                 BADCVAR("rcon_password");
451                 BADCVAR("rcon_restricted_commands");
452                 BADCVAR("rcon_restricted_password");
453                 BADCVAR("skill");
454                 BADCVAR("sv_adminnick");
455                 BADCVAR("sv_autoscreenshot");
456                 BADCVAR("sv_autotaunt");
457                 BADCVAR("sv_curl_defaulturl");
458                 BADCVAR("sv_defaultcharacter");
459                 BADCVAR("sv_defaultcharacterskin");
460                 BADCVAR("sv_defaultplayercolors");
461                 BADCVAR("sv_defaultplayermodel");
462                 BADCVAR("sv_defaultplayerskin");
463                 BADCVAR("sv_maxidle");
464                 BADCVAR("sv_maxrate");
465                 BADCVAR("sv_motd");
466                 BADCVAR("sv_public");
467                 BADCVAR("sv_ready_restart");
468                 BADCVAR("sv_status_privacy");
469                 BADCVAR("sv_taunt");
470                 BADCVAR("sv_vote_call");
471                 BADCVAR("sv_vote_commands");
472                 BADCVAR("sv_vote_majority_factor");
473                 BADCVAR("sv_vote_master");
474                 BADCVAR("sv_vote_master_commands");
475                 BADCVAR("sv_vote_master_password");
476                 BADCVAR("sv_vote_simple_majority_factor");
477                 BADCVAR("teamplay_mode");
478                 BADCVAR("timelimit_override");
479                 BADPREFIX("g_warmup_");
480                 BADPREFIX("sv_info_");
481                 BADPREFIX("sv_ready_restart_");
482
483                 // mutators that announce themselves properly to the server browser
484                 BADCVAR("g_instagib");
485                 BADCVAR("g_new_toys");
486                 BADCVAR("g_nix");
487                 BADCVAR("g_grappling_hook");
488                 BADCVAR("g_jetpack");
489
490                 // temporary for testing
491                 // TODO remove before 0.8.3 release
492                 BADCVAR("g_ca_weaponarena");
493                 BADCVAR("g_freezetag_weaponarena");
494                 BADCVAR("g_lms_weaponarena");
495
496                 if(cvar_string("g_mod_balance") == "Testing")
497                 {
498                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
499                         BADPREFIX("g_balance_");
500                 }
501
502 #undef BADPRESUFFIX
503 #undef BADPREFIX
504 #undef BADCVAR
505
506                 if(pureadding)
507                 {
508                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
509                         if(strlen(cvar_purechanges) > 16384)
510                         {
511                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
512                                 pureadding = 0;
513                         }
514                 }
515                 ++cvar_purechanges_count;
516                 // WARNING: this variable is used for the server list
517                 // NEVER dare to skip this code!
518                 // Hacks to intentionally appearing as "pure server" even though you DO have
519                 // modified settings may be punished by removal from the server list.
520                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
521                 // though.
522         }
523         buf_del(h);
524         if(cvar_changes == "")
525                 cvar_changes = "// this server runs at default server settings\n";
526         else
527                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
528         cvar_changes = strzone(cvar_changes);
529         if(cvar_purechanges == "")
530                 cvar_purechanges = "// this server runs at default gameplay settings\n";
531         else
532                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
533         cvar_purechanges = strzone(cvar_purechanges);
534 }
535
536 entity randomseed;
537 bool RandomSeed_Send(entity this, entity to, int sf)
538 {
539         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
540         WriteShort(MSG_ENTITY, this.cnt);
541         return true;
542 }
543 void RandomSeed_Think(entity this)
544 {
545         this.cnt = bound(0, floor(random() * 65536), 65535);
546         this.nextthink = time + 5;
547
548         this.SendFlags |= 1;
549 }
550 void RandomSeed_Spawn()
551 {
552         randomseed = new_pure(randomseed);
553         setthink(randomseed, RandomSeed_Think);
554         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
555
556         getthink(randomseed)(randomseed); // sets random seed and nextthink
557 }
558
559 spawnfunc(__init_dedicated_server)
560 {
561         // handler for _init/_init map (only for dedicated server initialization)
562
563         world_initialized = -1; // don't complain
564         cvar = cvar_normal;
565         cvar_string = cvar_string_normal;
566         cvar_set = cvar_set_normal;
567
568         delete_fn = remove_unsafely;
569
570         entity e = spawn();
571         setthink(e, GotoFirstMap);
572         e.nextthink = time; // this is usually 1 at this point
573
574         e = new(info_player_deathmatch);  // safeguard against player joining
575
576     // assign reflectively to avoid "assignment to world" warning
577     for (int i = 0, n = numentityfields(); i < n; ++i) {
578         string k = entityfieldname(i);
579         if (k == "classname") {
580             // safeguard against various stuff ;)
581             putentityfieldstring(i, this, "worldspawn");
582             break;
583         }
584     }
585
586         // needs to be done so early because of the constants they create
587         static_init();
588         static_init_late();
589         static_init_precache();
590
591         IL_PUSH(g_spawnpoints, e); // just incase
592
593         MapInfo_Enumerate();
594         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
595 }
596
597 void __init_dedicated_server_shutdown() {
598         MapInfo_Shutdown();
599 }
600
601 STATIC_INIT_EARLY(maxclients)
602 {
603         maxclients = 0;
604         for (entity head = nextent(NULL); head; head = nextent(head)) {
605                 ++maxclients;
606         }
607 }
608
609 void default_delayedinit(entity this)
610 {
611         if(!scores_initialized)
612                 ScoreRules_generic();
613 }
614
615 void InitGameplayMode()
616 {
617         VoteReset();
618
619         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
620         get_mi_min_max(1);
621         // assign reflectively to avoid "assignment to world" warning
622         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
623             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
624             if (v) {
625             putentityfieldstring(i, world, sprintf("%v", v));
626             if (++done == 2) break;
627         }
628         }
629         // currently, NetRadiant's limit is 131072 qu for each side
630         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
631         // set the distance according to map size but don't go over the limit to avoid issues with float precision
632         // in case somebody makes extremely large maps
633         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
634
635         MapInfo_LoadMapSettings(mapname);
636         GameRules_teams(false);
637
638         if (!cvar_value_issafe(world.fog))
639         {
640                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
641                 world.fog = string_null;
642         }
643         if(MapInfo_Map_fog != "")
644         {
645                 if(MapInfo_Map_fog == "none")
646                         world.fog = string_null;
647                 else
648                         world.fog = strzone(MapInfo_Map_fog);
649         }
650         clientstuff = strzone(MapInfo_Map_clientstuff);
651
652         MapInfo_ClearTemps();
653
654         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
655
656         cache_mutatormsg = strzone("");
657         cache_lastmutatormsg = strzone("");
658
659         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
660 }
661
662 void Map_MarkAsRecent(string m);
663 float world_already_spawned;
664 spawnfunc(worldspawn)
665 {
666         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
667
668         bool wantrestart = false;
669         {
670                 if (!server_is_dedicated)
671                 {
672                         // force unloading of server pk3 files when starting a listen server
673                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
674                         // restore csqc_progname too
675                         string expect = "csprogs.dat";
676                         wantrestart = cvar_string_normal("csqc_progname") != expect;
677                         cvar_set_normal("csqc_progname", expect);
678                 }
679                 else
680                 {
681                         // Try to use versioned csprogs from pk3
682                         // Only ever use versioned csprogs.dat files on dedicated servers;
683                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
684                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
685                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
686                         string select = "csprogs.dat";
687                         if (fexists(pk3csprogs)) select = pk3csprogs;
688                         if (cvar_string_normal("csqc_progname") != select)
689                         {
690                                 cvar_set_normal("csqc_progname", select);
691                                 wantrestart = true;
692                         }
693                         // Check for updates on startup
694                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
695                         int sentinel = fopen("progs.txt", FILE_READ);
696                         if (sentinel >= 0)
697                         {
698                                 string switchversion = fgets(sentinel);
699                                 fclose(sentinel);
700                                 if (switchversion != "" && switchversion != WATERMARK)
701                                 {
702                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
703                                         // if it doesn't exist, assume either:
704                                         //   a) the current program was overwritten
705                                         //   b) this is a client only update
706                                         string newprogs = sprintf("progs-%s.dat", switchversion);
707                                         if (fexists(newprogs))
708                                         {
709                                                 cvar_set_normal("sv_progs", newprogs);
710                                                 wantrestart = true;
711                                         }
712                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
713                                         if (fexists(newcsprogs))
714                                         {
715                                                 cvar_set_normal("csqc_progname", newcsprogs);
716                                                 wantrestart = true;
717                                         }
718                                 }
719                         }
720                 }
721                 if (wantrestart)
722                 {
723                         LOG_INFO("Restart requested");
724                         changelevel(mapname);
725                         // let initialization continue, shutdown depends on it
726                 }
727         }
728
729         cvar = cvar_normal;
730         cvar_string = cvar_string_normal;
731         cvar_set = cvar_set_normal;
732
733         if(world_already_spawned)
734                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
735         world_already_spawned = true;
736
737         delete_fn = remove_safely; // during spawning, watch what you remove!
738
739         cvar_changes_init(); // do this very early now so it REALLY matches the server config
740
741         // needs to be done so early because of the constants they create
742         static_init();
743
744         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
745
746         TemporaryDB = db_create();
747
748         // 0 normal
749         lightstyle(0, "m");
750
751         // 1 FLICKER (first variety)
752         lightstyle(1, "mmnmmommommnonmmonqnmmo");
753
754         // 2 SLOW STRONG PULSE
755         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
756
757         // 3 CANDLE (first variety)
758         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
759
760         // 4 FAST STROBE
761         lightstyle(4, "mamamamamama");
762
763         // 5 GENTLE PULSE 1
764         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
765
766         // 6 FLICKER (second variety)
767         lightstyle(6, "nmonqnmomnmomomno");
768
769         // 7 CANDLE (second variety)
770         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
771
772         // 8 CANDLE (third variety)
773         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
774
775         // 9 SLOW STROBE (fourth variety)
776         lightstyle(9, "aaaaaaaazzzzzzzz");
777
778         // 10 FLUORESCENT FLICKER
779         lightstyle(10, "mmamammmmammamamaaamammma");
780
781         // 11 SLOW PULSE NOT FADE TO BLACK
782         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
783
784         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
785
786         // 63 testing
787         lightstyle(63, "a");
788
789         if(autocvar_g_campaign)
790                 CampaignPreInit();
791
792         Map_MarkAsRecent(mapname);
793
794         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
795
796         InitGameplayMode();
797         static_init_late();
798         static_init_precache();
799         readlevelcvars();
800         GrappleHookInit();
801
802         GameRules_limit_fallbacks();
803
804         if(warmup_limit == 0)
805                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
806
807         player_count = 0;
808         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
809         if(bot_waypoints_for_items == 1)
810                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
811                         bot_waypoints_for_items = 0;
812
813         precache();
814
815         WaypointSprite_Init();
816
817         GameLogInit(); // prepare everything
818         // NOTE for matchid:
819         // changing the logic generating it is okay. But:
820         // it HAS to stay <= 64 chars
821         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
822         if(autocvar_sv_eventlog)
823         {
824                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
825                 matchid = strzone(s);
826
827                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
828                 s = ":gameinfo:mutators:LIST";
829
830                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
831                 s = M_ARGV(0, string);
832
833                 // initialiation stuff, not good in the mutator system
834                 if(!autocvar_g_use_ammunition)
835                         s = strcat(s, ":no_use_ammunition");
836
837                 // initialiation stuff, not good in the mutator system
838                 if(autocvar_g_pickup_items == 0)
839                         s = strcat(s, ":no_pickup_items");
840                 if(autocvar_g_pickup_items > 0)
841                         s = strcat(s, ":pickup_items");
842
843                 // initialiation stuff, not good in the mutator system
844                 if(autocvar_g_weaponarena != "0")
845                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
846
847                 // TODO to mutator system
848                 if(autocvar_g_norecoil)
849                         s = strcat(s, ":norecoil");
850
851                 // TODO to mutator system
852                 if(autocvar_g_powerups == 0)
853                         s = strcat(s, ":no_powerups");
854                 if(autocvar_g_powerups > 0)
855                         s = strcat(s, ":powerups");
856
857                 GameLogEcho(s);
858                 GameLogEcho(":gameinfo:end");
859         }
860         else
861                 matchid = strzone(ftos(random()));
862
863         cvar_set("nextmap", "");
864
865         SetDefaultAlpha();
866
867         if(autocvar_g_campaign)
868                 CampaignPostInit();
869
870         Ban_LoadBans();
871
872         MapInfo_Enumerate();
873         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
874
875         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
876         {
877                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
878                 if(fd != -1)
879                 {
880                         string s;
881                         while((s = fgets(fd)))
882                         {
883                                 int l = tokenize_console(s);
884                                 if(l < 2)
885                                         continue;
886                                 if(argv(0) == "cd")
887                                 {
888                                         string trackname = argv(2);
889                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
890                                         LOG_INFO("  cdtrack ", trackname);
891                                         if (cvar_value_issafe(trackname))
892                                         {
893                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
894                                                 strcpy(clientstuff, newstuff);
895                                         }
896                                 }
897                                 else if(argv(0) == "fog")
898                                 {
899                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
900                                         LOG_INFO("  \"fog\" \"", s, "\"");
901                                 }
902                                 else if(argv(0) == "set")
903                                 {
904                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
905                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
906                                 }
907                                 else if(argv(0) != "//")
908                                 {
909                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
910                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
911                                 }
912                         }
913                         fclose(fd);
914                 }
915         }
916
917         WeaponStats_Init();
918
919         Nagger_Init();
920
921         next_pingtime = time + 5;
922
923         // set up information replies for clients and server to use
924         maplist_reply = strzone(getmaplist());
925         lsmaps_reply = strzone(getlsmaps());
926         monsterlist_reply = strzone(getmonsterlist());
927         for(int i = 0; i < 10; ++i)
928         {
929                 string s = getrecords(i);
930                 if (s)
931                         records_reply[i] = strzone(s);
932         }
933         ladder_reply = strzone(getladder());
934         rankings_reply = strzone(getrankings());
935
936         // begin other init
937         ClientInit_Spawn();
938         RandomSeed_Spawn();
939         PingPLReport_Spawn();
940
941         CheatInit();
942
943         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
944
945         // fill sv_curl_serverpackages from .serverpackage files
946         if (autocvar_sv_curl_serverpackages_auto)
947         {
948                 string s = "csprogs-" WATERMARK ".txt";
949                 // remove automatically managed files from the list to prevent duplicates
950                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
951                 {
952                         string pkg = argv(i);
953                         if (startsWith(pkg, "csprogs-")) continue;
954                         if (endsWith(pkg, "-serverpackage.txt")) continue;
955                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
956                         s = cons(s, pkg);
957                 }
958                 // add automatically managed files to the list
959                 #define X(match) MACRO_BEGIN \
960                         int fd = search_begin(match, true, false); \
961                         if (fd >= 0) \
962                         { \
963                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
964                                 { \
965                                         s = cons(s, search_getfilename(fd, i)); \
966                                 } \
967                                 search_end(fd); \
968                         } \
969                 MACRO_END
970                 X("*-serverpackage.txt");
971                 X("*.serverpackage");
972                 #undef X
973                 cvar_set("sv_curl_serverpackages", s);
974         }
975
976         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
977         modname = "Xonotic";
978         // physics/balance/config changes that count as mod
979         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
980                 modname = cvar_string("g_mod_physics");
981         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
982                 modname = cvar_string("g_mod_balance");
983         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
984                 modname = cvar_string("g_mod_config");
985         // extra mutators that deserve to count as mod
986         MUTATOR_CALLHOOK(SetModname, modname);
987         modname = M_ARGV(0, string);
988
989         // save it for later
990         modname = strzone(modname);
991
992         WinningConditionHelper(this); // set worldstatus
993
994         world_initialized = 1;
995         __spawnfunc_spawn_all();
996 }
997
998 spawnfunc(light)
999 {
1000         //makestatic (this); // Who the f___ did that?
1001         delete(this);
1002 }
1003
1004 string GetGametype()
1005 {
1006         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1007 }
1008
1009 string GetMapname()
1010 {
1011         return mapname;
1012 }
1013
1014 float Map_Count, Map_Current;
1015 string Map_Current_Name;
1016
1017 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1018 int GetMaplistPosition()
1019 {
1020         string map = GetMapname();
1021         int idx = autocvar_g_maplist_index;
1022
1023         if(idx >= 0)
1024         {
1025                 if(idx < Map_Count)
1026                 {
1027                         if(map == argv(idx))
1028                         {
1029                                 return idx;
1030                         }
1031                 }
1032         }
1033
1034         for(int pos = 0; pos < Map_Count; ++pos)
1035         {
1036                 if(map == argv(pos))
1037                         return pos;
1038         }
1039
1040         // resume normal maplist rotation if current map is not in g_maplist
1041         return idx;
1042 }
1043
1044 bool MapHasRightSize(string map)
1045 {
1046         int minplayers = max(0, floor(autocvar_minplayers));
1047         if (teamplay)
1048                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1049         if (autocvar_g_maplist_check_waypoints
1050                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1051         {
1052                 string checkwp_msg = strcat("checkwp ", map);
1053                 if(!fexists(strcat("maps/", map, ".waypoints")))
1054                 {
1055                         LOG_TRACE(checkwp_msg, ": no waypoints");
1056                         return false;
1057                 }
1058                 LOG_TRACE(checkwp_msg, ": has waypoints");
1059         }
1060
1061         if(autocvar_g_maplist_ignore_sizes)
1062                 return true;
1063
1064         // open map size restriction file
1065         string opensize_msg = strcat("opensize ", map);
1066         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1067         int pcount = player_count;
1068         if(!autocvar_g_maplist_sizes_count_bots)
1069                 pcount -= currentbots;
1070         if(fh >= 0)
1071         {
1072                 opensize_msg = strcat(opensize_msg, ": ok, ");
1073                 int mapmin = stoi(fgets(fh));
1074                 int mapmax = stoi(fgets(fh));
1075                 fclose(fh);
1076                 if(pcount < mapmin)
1077                 {
1078                         LOG_TRACE(opensize_msg, "not enough");
1079                         return false;
1080                 }
1081                 if(mapmax && pcount > mapmax)
1082                 {
1083                         LOG_TRACE(opensize_msg, "too many");
1084                         return false;
1085                 }
1086                 LOG_TRACE(opensize_msg, "right size");
1087                 return true;
1088         }
1089         LOG_TRACE(opensize_msg, ": not found");
1090         return true;
1091 }
1092
1093 string Map_Filename(float position)
1094 {
1095         return strcat("maps/", argv(position), ".bsp");
1096 }
1097
1098 void Map_MarkAsRecent(string m)
1099 {
1100         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1101 }
1102
1103 float Map_IsRecent(string m)
1104 {
1105         return strhasword(autocvar_g_maplist_mostrecent, m);
1106 }
1107
1108 float Map_Check(float position, float pass)
1109 {
1110         string filename;
1111         string map_next;
1112         map_next = argv(position);
1113         if(pass <= 1)
1114         {
1115                 if(Map_IsRecent(map_next))
1116                         return 0;
1117         }
1118         filename = Map_Filename(position);
1119         if(MapInfo_CheckMap(map_next))
1120         {
1121                 if(pass == 2)
1122                         return 1;
1123                 if(MapHasRightSize(map_next))
1124                         return 1;
1125                 return 0;
1126         }
1127         else
1128                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1129
1130         return 0;
1131 }
1132
1133 void Map_Goto_SetStr(string nextmapname)
1134 {
1135         if(getmapname_stored != "")
1136                 strunzone(getmapname_stored);
1137         if(nextmapname == "")
1138                 getmapname_stored = "";
1139         else
1140                 getmapname_stored = strzone(nextmapname);
1141 }
1142
1143 void Map_Goto_SetFloat(float position)
1144 {
1145         cvar_set("g_maplist_index", ftos(position));
1146         Map_Goto_SetStr(argv(position));
1147 }
1148
1149 void Map_Goto(float reinit)
1150 {
1151         MapInfo_LoadMap(getmapname_stored, reinit);
1152 }
1153
1154 // return codes of map selectors:
1155 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1156 //   -2 = permanent failure
1157 float MaplistMethod_Iterate() // usual method
1158 {
1159         float pass, i;
1160
1161         LOG_TRACE("Trying MaplistMethod_Iterate");
1162
1163         for(pass = 1; pass <= 2; ++pass)
1164         {
1165                 for(i = 1; i < Map_Count; ++i)
1166                 {
1167                         float mapindex;
1168                         mapindex = (i + Map_Current) % Map_Count;
1169                         if(Map_Check(mapindex, pass))
1170                                 return mapindex;
1171                 }
1172         }
1173         return -1;
1174 }
1175
1176 float MaplistMethod_Repeat() // fallback method
1177 {
1178         LOG_TRACE("Trying MaplistMethod_Repeat");
1179
1180         if(Map_Check(Map_Current, 2))
1181                 return Map_Current;
1182         return -2;
1183 }
1184
1185 float MaplistMethod_Random() // random map selection
1186 {
1187         float i, imax;
1188
1189         LOG_TRACE("Trying MaplistMethod_Random");
1190
1191         imax = 42;
1192
1193         for(i = 0; i <= imax; ++i)
1194         {
1195                 float mapindex;
1196                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1197                 if(Map_Check(mapindex, 1))
1198                         return mapindex;
1199         }
1200         return -1;
1201 }
1202
1203 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1204 // the exponent sets a bias on the map selection:
1205 // the higher the exponent, the less likely "shortly repeated" same maps are
1206 {
1207         float i, j, imax, insertpos;
1208
1209         LOG_TRACE("Trying MaplistMethod_Shuffle");
1210
1211         imax = 42;
1212
1213         for(i = 0; i <= imax; ++i)
1214         {
1215                 string newlist;
1216
1217                 // now reinsert this at another position
1218                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1219                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1220                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1221                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1222
1223                 // insert the current map there
1224                 newlist = "";
1225                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1226                         newlist = strcat(newlist, " ", argv(j));
1227                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1228                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1229                         newlist = strcat(newlist, " ", argv(j));
1230                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1231                 cvar_set("g_maplist", newlist);
1232                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1233
1234                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1235                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1236                 if(Map_Check(Map_Current, 1))
1237                         return Map_Current;
1238         }
1239         return -1;
1240 }
1241
1242 void Maplist_Init()
1243 {
1244         float i = Map_Count = 0;
1245         if(autocvar_g_maplist != "")
1246         {
1247                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1248                 for (i = 0; i < Map_Count; ++i)
1249                 {
1250                         if (Map_Check(i, 2))
1251                                 break;
1252                 }
1253         }
1254         
1255         if (i == Map_Count)
1256         {
1257                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1258                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1259                 if(autocvar_g_maplist_shuffle)
1260                         ShuffleMaplist();
1261                 if(!server_is_dedicated)
1262                         localcmd("\nmenu_cmd sync\n");
1263                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1264         }
1265         if(Map_Count == 0)
1266                 error("empty maplist, cannot select a new map");
1267         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1268
1269         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1270         // this may or may not be correct, but who cares, in the worst case a map
1271         // isn't chosen in the first pass that should have been
1272 }
1273
1274 string GetNextMap()
1275 {
1276         Maplist_Init();
1277         float nextMap = -1;
1278
1279         if(nextMap == -1)
1280                 if(autocvar_g_maplist_shuffle > 0)
1281                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1282
1283         if(nextMap == -1)
1284                 if(autocvar_g_maplist_selectrandom)
1285                         nextMap = MaplistMethod_Random();
1286
1287         if(nextMap == -1)
1288                 nextMap = MaplistMethod_Iterate();
1289
1290         if(nextMap == -1)
1291                 nextMap = MaplistMethod_Repeat();
1292
1293         if(nextMap >= 0)
1294         {
1295                 Map_Goto_SetFloat(nextMap);
1296                 return getmapname_stored;
1297         }
1298
1299         return "";
1300 }
1301
1302 float DoNextMapOverride(float reinit)
1303 {
1304         if(autocvar_g_campaign)
1305         {
1306                 CampaignPostIntermission();
1307                 alreadychangedlevel = true;
1308                 return true;
1309         }
1310         if(autocvar_quit_when_empty)
1311         {
1312                 if(player_count <= currentbots)
1313                 {
1314                         localcmd("quit\n");
1315                         alreadychangedlevel = true;
1316                         return true;
1317                 }
1318         }
1319         if(autocvar_quit_and_redirect != "")
1320         {
1321                 redirection_target = strzone(autocvar_quit_and_redirect);
1322                 alreadychangedlevel = true;
1323                 return true;
1324         }
1325         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1326         {
1327                 localcmd("restart\n");
1328                 alreadychangedlevel = true;
1329                 return true;
1330         }
1331         if(autocvar_nextmap != "")
1332         {
1333                 string m;
1334                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1335                 cvar_set("nextmap",m);
1336
1337                 if(!m || gametypevote)
1338                         return false;
1339                 if(autocvar_sv_vote_gametype)
1340                 {
1341                         Map_Goto_SetStr(m);
1342                         return false;
1343                 }
1344
1345                 if(MapInfo_CheckMap(m))
1346                 {
1347                         Map_Goto_SetStr(m);
1348                         Map_Goto(reinit);
1349                         alreadychangedlevel = true;
1350                         return true;
1351                 }
1352         }
1353         if(!reinit && autocvar_lastlevel)
1354         {
1355                 cvar_settemp_restore();
1356                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1357                 alreadychangedlevel = true;
1358                 return true;
1359         }
1360         return false;
1361 }
1362
1363 void GotoNextMap(float reinit)
1364 {
1365         //string nextmap;
1366         //float n, nummaps;
1367         //string s;
1368         if (alreadychangedlevel)
1369                 return;
1370         alreadychangedlevel = true;
1371
1372         string nextMap = GetNextMap();
1373         if(nextMap == "")
1374                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1375         Map_Goto(reinit);
1376 }
1377
1378
1379 /*
1380 ============
1381 IntermissionThink
1382
1383 When the player presses attack or jump, change to the next level
1384 ============
1385 */
1386 .float autoscreenshot;
1387 void IntermissionThink(entity this)
1388 {
1389         FixIntermissionClient(this);
1390
1391         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1392         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1393
1394         if( (server_screenshot || client_screenshot)
1395                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1396         {
1397                 this.autoscreenshot = -1;
1398                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1399                 return;
1400         }
1401
1402         if (time < intermission_exittime)
1403                 return;
1404
1405         if(!mapvote_initialized)
1406                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1407                         return;
1408
1409         MapVote_Start();
1410 }
1411
1412 /*
1413 ============
1414 FindIntermission
1415
1416 Returns the entity to view from
1417 ============
1418 */
1419 /*
1420 entity FindIntermission()
1421 {
1422         local   entity spot;
1423         local   float cyc;
1424
1425 // look for info_intermission first
1426         spot = find(NULL, classname, "info_intermission");
1427         if (spot)
1428         {       // pick a random one
1429                 cyc = random() * 4;
1430                 while (cyc > 1)
1431                 {
1432                         spot = find(spot, classname, "info_intermission");
1433                         if (!spot)
1434                                 spot = find(spot, classname, "info_intermission");
1435                         cyc = cyc - 1;
1436                 }
1437                 return spot;
1438         }
1439
1440 // then look for the start position
1441         spot = find(NULL, classname, "info_player_start");
1442         if (spot)
1443                 return spot;
1444
1445 // testinfo_player_start is only found in regioned levels
1446         spot = find(NULL, classname, "testplayerstart");
1447         if (spot)
1448                 return spot;
1449
1450 // then look for the start position
1451         spot = find(NULL, classname, "info_player_deathmatch");
1452         if (spot)
1453                 return spot;
1454
1455         //objerror ("FindIntermission: no spot");
1456         return NULL;
1457 }
1458 */
1459
1460 /*
1461 ===============================================================================
1462
1463 RULES
1464
1465 ===============================================================================
1466 */
1467
1468 void DumpStats(float final)
1469 {
1470         float file;
1471         string s;
1472         float to_console;
1473         float to_eventlog;
1474         float to_file;
1475         float i;
1476
1477         to_console = autocvar_sv_logscores_console;
1478         to_eventlog = autocvar_sv_eventlog;
1479         to_file = autocvar_sv_logscores_file;
1480
1481         if(!final)
1482         {
1483                 to_console = true; // always print printstats replies
1484                 to_eventlog = false; // but never print them to the event log
1485         }
1486
1487         if(to_eventlog)
1488                 if(autocvar_sv_eventlog_console)
1489                         to_console = false; // otherwise we get the output twice
1490
1491         if(final)
1492                 s = ":scores:";
1493         else
1494                 s = ":status:";
1495         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1496
1497         if(to_console)
1498                 LOG_INFO(s);
1499         if(to_eventlog)
1500                 GameLogEcho(s);
1501
1502         file = -1;
1503         if(to_file)
1504         {
1505                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1506                 if(file == -1)
1507                         to_file = false;
1508                 else
1509                         fputs(file, strcat(s, "\n"));
1510         }
1511
1512         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1513         if(to_console)
1514                 LOG_INFO(s);
1515         if(to_eventlog)
1516                 GameLogEcho(s);
1517         if(to_file)
1518                 fputs(file, strcat(s, "\n"));
1519
1520         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1521                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1522                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1523                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1524                         s = strcat(s, ftos(it.team), ":");
1525                 else
1526                         s = strcat(s, "spectator:");
1527
1528                 if(to_console)
1529                         LOG_INFO(s, playername(it, false));
1530                 if(to_eventlog)
1531                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1532                 if(to_file)
1533                         fputs(file, strcat(s, playername(it, false), "\n"));
1534         });
1535
1536         if(teamplay)
1537         {
1538                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1539                 if(to_console)
1540                         LOG_INFO(s);
1541                 if(to_eventlog)
1542                         GameLogEcho(s);
1543                 if(to_file)
1544                         fputs(file, strcat(s, "\n"));
1545
1546                 for(i = 1; i < 16; ++i)
1547                 {
1548                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1549                         s = strcat(s, ":", ftos(i));
1550                         if(to_console)
1551                                 LOG_INFO(s);
1552                         if(to_eventlog)
1553                                 GameLogEcho(s);
1554                         if(to_file)
1555                                 fputs(file, strcat(s, "\n"));
1556                 }
1557         }
1558
1559         if(to_console)
1560                 LOG_INFO(":end");
1561         if(to_eventlog)
1562                 GameLogEcho(":end");
1563         if(to_file)
1564         {
1565                 fputs(file, ":end\n");
1566                 fclose(file);
1567         }
1568 }
1569
1570 void FixIntermissionClient(entity e)
1571 {
1572         if(!e.autoscreenshot) // initial call
1573         {
1574                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1575                 SetResourceExplicit(e, RES_HEALTH, -2342);
1576                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1577                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1578                 {
1579                     .entity weaponentity = weaponentities[slot];
1580                         if(e.(weaponentity))
1581                         {
1582                                 e.(weaponentity).effects = EF_NODRAW;
1583                                 if (e.(weaponentity).weaponchild)
1584                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1585                         }
1586                 }
1587                 if(IS_REAL_CLIENT(e))
1588                 {
1589                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1590                         RandomSelection_Init();
1591                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1592                                 RandomSelection_AddString(it, 1, 1);
1593                         });
1594                         if (RandomSelection_chosen_string != "")
1595                         {
1596                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1597                         }
1598                         msg_entity = e;
1599                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1600                 }
1601         }
1602 }
1603
1604 /*
1605 go to the next level for deathmatch
1606 only called if a time or frag limit has expired
1607 */
1608 void NextLevel()
1609 {
1610         game_stopped = true;
1611         intermission_running = 1; // game over
1612
1613         // enforce a wait time before allowing changelevel
1614         if(player_count > 0)
1615                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1616         else
1617                 intermission_exittime = -1;
1618
1619         /*
1620         WriteByte (MSG_ALL, SVC_CDTRACK);
1621         WriteByte (MSG_ALL, 3);
1622         WriteByte (MSG_ALL, 3);
1623         // done in FixIntermission
1624         */
1625
1626         //pos = FindIntermission ();
1627
1628         VoteReset();
1629
1630         DumpStats(true);
1631
1632         // send statistics
1633         PlayerStats_GameReport(true);
1634         WeaponStats_Shutdown();
1635
1636         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1637
1638         if(autocvar_sv_eventlog)
1639                 GameLogEcho(":gameover");
1640
1641         GameLogClose();
1642
1643         FOREACH_CLIENT(IS_PLAYER(it), {
1644                 FixIntermissionClient(it);
1645                 if(it.winning)
1646                         bprint(playername(it, false), " ^7wins.\n");
1647         });
1648
1649         target_music_kill();
1650
1651         if(autocvar_g_campaign)
1652                 CampaignPreIntermission();
1653
1654         MUTATOR_CALLHOOK(MatchEnd);
1655
1656         localcmd("\nsv_hook_gameend\n");
1657 }
1658
1659
1660 float InitiateSuddenDeath()
1661 {
1662         // Check first whether normal overtimes could be added before initiating suddendeath mode
1663         // - for this timelimit_overtime needs to be >0 of course
1664         // - also check the winning condition calculated in the previous frame and only add normal overtime
1665         //   again, if at the point at which timelimit would be extended again, still no winner was found
1666         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1667                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1668                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1669         {
1670                 return 1; // need to call InitiateOvertime later
1671         }
1672         else
1673         {
1674                 if(!checkrules_suddendeathend)
1675                 {
1676                         if(autocvar_g_campaign)
1677                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1678                         else
1679                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1680                         if(g_race && !g_race_qualifying)
1681                                 race_StartCompleting();
1682                 }
1683                 return 0;
1684         }
1685 }
1686
1687 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1688 {
1689         ++checkrules_overtimesadded;
1690         //add one more overtime by simply extending the timelimit
1691         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1692         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1693 }
1694
1695 float GetWinningCode(float fraglimitreached, float equality)
1696 {
1697         if(autocvar_g_campaign == 1)
1698         {
1699                 if(fraglimitreached)
1700                         return WINNING_YES;
1701                 else
1702                         return WINNING_NO;
1703         }
1704         else
1705         {
1706                 if(equality)
1707                 {
1708                         if(fraglimitreached)
1709                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1710                         else
1711                                 return WINNING_NEVER;
1712                 }
1713                 else
1714                 {
1715                         if(fraglimitreached)
1716                                 return WINNING_YES;
1717                         else
1718                                 return WINNING_NO;
1719                 }
1720         }
1721 }
1722
1723 // set the .winning flag for exactly those players with a given field value
1724 void SetWinners(.float field, float value)
1725 {
1726         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1727 }
1728
1729 // set the .winning flag for those players with a given field value
1730 void AddWinners(.float field, float value)
1731 {
1732         FOREACH_CLIENT(IS_PLAYER(it), {
1733                 if(it.(field) == value)
1734                         it.winning = 1;
1735         });
1736 }
1737
1738 // clear the .winning flags
1739 void ClearWinners()
1740 {
1741         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1742 }
1743
1744 void ShuffleMaplist()
1745 {
1746         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1747 }
1748
1749 float leaderfrags;
1750 float WinningCondition_Scores(float limit, float leadlimit)
1751 {
1752         float limitreached;
1753
1754         // TODO make everything use THIS winning condition (except LMS)
1755         WinningConditionHelper(NULL);
1756
1757         if(teamplay)
1758         {
1759                 for (int i = 1; i < 5; ++i)
1760                 {
1761                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1762                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1763                 }
1764         }
1765
1766         ClearWinners();
1767         if(WinningConditionHelper_winner)
1768                 WinningConditionHelper_winner.winning = 1;
1769         if(WinningConditionHelper_winnerteam >= 0)
1770                 SetWinners(team, WinningConditionHelper_winnerteam);
1771
1772         if(WinningConditionHelper_lowerisbetter)
1773         {
1774                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1775                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1776                 limit = -limit;
1777         }
1778
1779         if(WinningConditionHelper_zeroisworst)
1780                 leadlimit = 0; // not supported in this mode
1781
1782         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1783         // these modes always score in increments of 1, thus this makes sense
1784         {
1785                 if(leaderfrags != WinningConditionHelper_topscore)
1786                 {
1787                         leaderfrags = WinningConditionHelper_topscore;
1788
1789                         if (limit)
1790                         {
1791                                 if (leaderfrags == limit - 1)
1792                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1793                                 else if (leaderfrags == limit - 2)
1794                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1795                                 else if (leaderfrags == limit - 3)
1796                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1797                         }
1798                 }
1799         }
1800
1801         limitreached = false;
1802         if (limit && WinningConditionHelper_topscore >= limit)
1803                 limitreached = true;
1804         if(leadlimit)
1805         {
1806                 float leadlimitreached;
1807                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1808                 if(autocvar_leadlimit_and_fraglimit)
1809                         limitreached = (limitreached && leadlimitreached);
1810                 else
1811                         limitreached = (limitreached || leadlimitreached);
1812         }
1813
1814         if(limit)
1815                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1816
1817         return GetWinningCode(
1818                 WinningConditionHelper_topscore && limitreached,
1819                 WinningConditionHelper_equality
1820         );
1821 }
1822
1823 float WinningCondition_RanOutOfSpawns()
1824 {
1825         if(have_team_spawns <= 0)
1826                 return WINNING_NO;
1827
1828         if(!autocvar_g_spawn_useallspawns)
1829                 return WINNING_NO;
1830
1831         if(!some_spawn_has_been_used)
1832                 return WINNING_NO;
1833
1834         for (int i = 1; i < 5; ++i)
1835         {
1836                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1837         }
1838
1839         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1840         {
1841                 if (Team_IsValidTeam(it.team))
1842                 {
1843                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1844                 }
1845         });
1846
1847         IL_EACH(g_spawnpoints, true,
1848         {
1849                 if (Team_IsValidTeam(it.team))
1850                 {
1851                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1852                 }
1853         });
1854
1855         ClearWinners();
1856         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1857         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1858         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1859         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1860         if(team1_score + team2_score + team3_score + team4_score == 0)
1861         {
1862                 checkrules_equality = true;
1863                 return WINNING_YES;
1864         }
1865         else if(team1_score + team2_score + team3_score + team4_score == 1)
1866         {
1867                 float t, i;
1868                 if(team1_score)
1869                         t = 1;
1870                 else if(team2_score)
1871                         t = 2;
1872                 else if(team3_score)
1873                         t = 3;
1874                 else // if(team4_score)
1875                         t = 4;
1876                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1877                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1878                 {
1879                         for (int j = 1; j <= NUM_TEAMS; ++j)
1880                         {
1881                                 if (t == j)
1882                                 {
1883                                         continue;
1884                                 }
1885                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1886                                 {
1887                                         continue;
1888                                 }
1889                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1890                         }
1891                 }
1892
1893                 AddWinners(team, t);
1894                 return WINNING_YES;
1895         }
1896         else
1897                 return WINNING_NO;
1898 }
1899
1900 /*
1901 ============
1902 CheckRules_World
1903
1904 Exit deathmatch games upon conditions
1905 ============
1906 */
1907 void CheckRules_World()
1908 {
1909         float timelimit;
1910         float fraglimit;
1911         float leadlimit;
1912
1913         VoteThink();
1914         MapVote_Think();
1915
1916         SetDefaultAlpha();
1917
1918         if (intermission_running) // someone else quit the game already
1919         {
1920                 if(player_count == 0) // Nobody there? Then let's go to the next map
1921                         MapVote_Start();
1922                         // this will actually check the player count in the next frame
1923                         // again, but this shouldn't hurt
1924                 return;
1925         }
1926
1927         timelimit = autocvar_timelimit * 60;
1928         fraglimit = autocvar_fraglimit;
1929         leadlimit = autocvar_leadlimit;
1930
1931         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1932         {
1933                 if(timelimit > 0)
1934                         timelimit = 0; // timelimit is not made for warmup
1935                 if(fraglimit > 0)
1936                         fraglimit = 0; // no fraglimit for now
1937                 leadlimit = 0; // no leadlimit for now
1938         }
1939
1940         if(timelimit > 0)
1941         {
1942                 timelimit += game_starttime;
1943         }
1944         else if (timelimit < 0)
1945         {
1946                 // endmatch
1947                 NextLevel();
1948                 return;
1949         }
1950
1951         float wantovertime;
1952         wantovertime = 0;
1953
1954         if(timelimit > game_starttime)
1955                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1956         else
1957                 game_completion_ratio = 0;
1958
1959         if(checkrules_suddendeathend)
1960         {
1961                 if(!checkrules_suddendeathwarning)
1962                 {
1963                         checkrules_suddendeathwarning = true;
1964                         if(g_race && !g_race_qualifying)
1965                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1966                         else
1967                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1968                 }
1969         }
1970         else
1971         {
1972                 if (timelimit && time >= timelimit)
1973                 {
1974                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1975                         {
1976                                 float totalplayers;
1977                                 float playerswithlaps;
1978                                 float readyplayers;
1979                                 totalplayers = playerswithlaps = readyplayers = 0;
1980                                 FOREACH_CLIENT(IS_PLAYER(it), {
1981                                         ++totalplayers;
1982                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1983                                                 ++playerswithlaps;
1984                                         if(it.ready)
1985                                                 ++readyplayers;
1986                                 });
1987
1988                                 // at least 2 of the players have completed a lap: start the RACE
1989                                 // otherwise, the players should end the qualifying on their own
1990                                 if(readyplayers || playerswithlaps >= 2)
1991                                 {
1992                                         checkrules_suddendeathend = 0;
1993                                         ReadyRestart(); // go to race
1994                                         return;
1995                                 }
1996                                 else
1997                                         wantovertime |= InitiateSuddenDeath();
1998                         }
1999                         else
2000                                 wantovertime |= InitiateSuddenDeath();
2001                 }
2002         }
2003
2004         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2005         {
2006                 NextLevel();
2007                 return;
2008         }
2009
2010         int checkrules_status = WinningCondition_RanOutOfSpawns();
2011         if(checkrules_status == WINNING_YES)
2012                 bprint("Hey! Someone ran out of spawns!\n");
2013         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
2014                 checkrules_status = M_ARGV(0, float);
2015         else
2016                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2017
2018         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2019         {
2020                 checkrules_status = WINNING_NEVER;
2021                 checkrules_overtimesadded = -1;
2022                 wantovertime |= InitiateSuddenDeath();
2023         }
2024
2025         if(checkrules_status == WINNING_NEVER)
2026                 // equality cases! Nobody wins if the overtime ends in a draw.
2027                 ClearWinners();
2028
2029         if(wantovertime)
2030         {
2031                 if(checkrules_status == WINNING_NEVER)
2032                         InitiateOvertime();
2033                 else
2034                         checkrules_status = WINNING_YES;
2035         }
2036
2037         if(checkrules_suddendeathend)
2038                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2039                         checkrules_status = WINNING_YES;
2040
2041         if(checkrules_status == WINNING_YES)
2042         {
2043                 //print("WINNING\n");
2044                 NextLevel();
2045         }
2046 }
2047
2048 string GotoMap(string m)
2049 {
2050         m = GameTypeVote_MapInfo_FixName(m);
2051         if (!m)
2052                 return "The map you suggested is not available on this server.";
2053         if (!autocvar_sv_vote_gametype)
2054         if(!MapInfo_CheckMap(m))
2055                 return "The map you suggested does not support the current game mode.";
2056         cvar_set("nextmap", m);
2057         cvar_set("timelimit", "-1");
2058         if(mapvote_initialized || alreadychangedlevel)
2059         {
2060                 if(DoNextMapOverride(0))
2061                         return "Map switch initiated.";
2062                 else
2063                         return "Hm... no. For some reason I like THIS map more.";
2064         }
2065         else
2066                 return "Map switch will happen after scoreboard.";
2067 }
2068
2069 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2070 void RunThink(entity this)
2071 {
2072         // don't let things stay in the past.
2073         // it is possible to start that way by a trigger with a local time.
2074         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2075                 return;
2076
2077         float oldtime = time; // do we need to save this?
2078
2079         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2080         {
2081                 time = max(oldtime, this.nextthink);
2082                 this.nextthink = 0;
2083
2084                 if(getthink(this))
2085                         getthink(this)(this);
2086                 // mods often set nextthink to time to cause a think every frame,
2087                 // we don't want to loop in that case, so exit if the new nextthink is
2088                 // <= the time the qc was told, also exit if it is past the end of the
2089                 // frame
2090                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2091                         break;
2092         }
2093
2094         time = oldtime;
2095 }
2096
2097 bool autocvar_sv_freezenonclients;
2098 bool autocvar_sv_gameplayfix_delayprojectiles = false;
2099 void Physics_Frame()
2100 {
2101         if(autocvar_sv_freezenonclients)
2102                 return;
2103
2104         FOREACH_ENTITY_FLOAT(pure_data, false,
2105         {
2106                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2107                         continue;
2108
2109                 //set_movetype(it, it.move_movetype);
2110                 // inline the set_movetype function, since this is called a lot
2111                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2112
2113                 if(it.move_movetype == MOVETYPE_NONE)
2114                         continue;
2115
2116                 if(it.move_qcphysics)
2117                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2118
2119                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2120                 {
2121                         // handle thinking here
2122                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2123                                 RunThink(it);
2124                 }
2125         });
2126
2127         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2128                 return;
2129
2130         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2131         {
2132                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2133                         continue;
2134                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2135         });
2136 }
2137
2138 void systems_update();
2139 void EndFrame()
2140 {
2141         anticheat_endframe();
2142
2143         Physics_Frame();
2144
2145         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2146                 entity e = IS_SPEC(it) ? it.enemy : it;
2147                 if (e.typehitsound) {
2148                         STAT(TYPEHIT_TIME, it) = time;
2149                 } else if (e.killsound) {
2150                         STAT(KILL_TIME, it) = time;
2151                 } else if (e.damage_dealt) {
2152                         STAT(HIT_TIME, it) = time;
2153                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2154                 }
2155         });
2156         // add 1 frametime because after this, engine SV_Physics
2157         // increases time by a frametime and then networks the frame
2158         // add another frametime because client shows everything with
2159         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2160         // needed!
2161         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2162         FOREACH_CLIENT(true, {
2163                 it.typehitsound = false;
2164                 it.damage_dealt = 0;
2165                 it.killsound = false;
2166                 antilag_record(it, CS(it), altime);
2167         });
2168         IL_EACH(g_monsters, true,
2169         {
2170                 antilag_record(it, it, altime);
2171         });
2172         IL_EACH(g_projectiles, it.classname == "nade",
2173         {
2174                 antilag_record(it, it, altime);
2175         });
2176         systems_update();
2177         IL_ENDFRAME();
2178 }
2179
2180
2181 /*
2182  * RedirectionThink:
2183  * returns true if redirecting
2184  */
2185 float redirection_timeout;
2186 float redirection_nextthink;
2187 float RedirectionThink()
2188 {
2189         float clients_found;
2190
2191         if(redirection_target == "")
2192                 return false;
2193
2194         if(!redirection_timeout)
2195         {
2196                 cvar_set("sv_public", "-2");
2197                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2198                 if(redirection_target == "self")
2199                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2200                 else
2201                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2202         }
2203
2204         if(time < redirection_nextthink)
2205                 return true;
2206
2207         redirection_nextthink = time + 1;
2208
2209         clients_found = 0;
2210         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2211                 // TODO add timer
2212                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2213                 if(redirection_target == "self")
2214                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2215                 else
2216                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2217                 ++clients_found;
2218         });
2219
2220         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2221
2222         if(time > redirection_timeout || clients_found == 0)
2223                 localcmd("\nwait; wait; wait; quit\n");
2224
2225         return true;
2226 }
2227
2228 void RestoreGame()
2229 {
2230         // Loaded from a save game
2231         // some things then break, so let's work around them...
2232
2233         // Progs DB (capture records)
2234         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2235
2236         // Mapinfo
2237         MapInfo_Shutdown();
2238         MapInfo_Enumerate();
2239         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2240         WeaponStats_Init();
2241
2242         TargetMusic_RestoreGame();
2243 }
2244
2245 void Shutdown()
2246 {
2247         game_stopped = 2;
2248
2249         if(world_initialized > 0)
2250         {
2251                 world_initialized = 0;
2252                 LOG_TRACE("Saving persistent data...");
2253                 Ban_SaveBans();
2254
2255                 // playerstats with unfinished match
2256                 PlayerStats_GameReport(false);
2257
2258                 if(!cheatcount_total)
2259                 {
2260                         if(autocvar_sv_db_saveasdump)
2261                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2262                         else
2263                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2264                 }
2265                 if(autocvar_developer)
2266                 {
2267                         if(autocvar_sv_db_saveasdump)
2268                                 db_dump(TemporaryDB, "server-temp.db");
2269                         else
2270                                 db_save(TemporaryDB, "server-temp.db");
2271                 }
2272                 CheatShutdown(); // must be after cheatcount check
2273                 db_close(ServerProgsDB);
2274                 db_close(TemporaryDB);
2275                 LOG_TRACE("Saving persistent data... done!");
2276                 // tell the bot system the game is ending now
2277                 bot_endgame();
2278
2279                 WeaponStats_Shutdown();
2280                 MapInfo_Shutdown();
2281         }
2282         else if(world_initialized == 0)
2283         {
2284                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2285         }
2286         else
2287         {
2288                 __init_dedicated_server_shutdown();
2289         }
2290 }