qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include <server/mutators/_mod.qh>
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "scores_rules.qh"
  20 #include "teamplay.qh"
  21 #include "weapons/weaponstats.qh"
  22 #include "../common/constants.qh"
  23 #include <common/net_linked.qh>
  24 #include "../common/deathtypes/all.qh"
  25 #include "../common/gamemodes/sv_rules.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/_mod.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/vehicles/all.qh"
  30 #include "../common/notifications/all.qh"
  31 #include "../common/physics/player.qh"
  32 #include "../common/playerstats.qh"
  33 #include "../common/stats.qh"
  34 #include "../common/teams.qh"
  35 #include "../common/mapobjects/trigger/secret.qh"
  36 #include "../common/mapobjects/target/music.qh"
  37 #include "../common/util.qh"
  38 #include "../common/items/_mod.qh"
  39 #include <common/weapons/_all.qh>
  40 #include "../common/state.qh"
  41
  42 const float LATENCY_THINKRATE = 10;
  43 .float latency_sum;
  44 .float latency_cnt;
  45 .float latency_time;
  46 entity pingplreport;
  47 void PingPLReport_Think(entity this)
  48 {
  49         float delta;
  50         entity e;
  51
  52         delta = 3 / maxclients;
  53         if(delta < sys_frametime)
  54                 delta = 0;
  55         this.nextthink = time + delta;
  56
  57         e = edict_num(this.cnt + 1);
  58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  59         {
  60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  61                 WriteByte(MSG_BROADCAST, this.cnt);
  62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  65
  66                 // record latency times for clients throughout the match so we can report it to playerstats
  67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  68                 {
  69                         CS(e).latency_sum += CS(e).ping;
  70                         CS(e).latency_cnt += 1;
  71                         CS(e).latency_time = time;
  72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  73                 }
  74         }
  75         else
  76         {
  77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  78                 WriteByte(MSG_BROADCAST, this.cnt);
  79                 WriteShort(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82         }
  83         this.cnt = (this.cnt + 1) % maxclients;
  84 }
  85 void PingPLReport_Spawn()
  86 {
  87         pingplreport = new_pure(pingplreport);
  88         setthink(pingplreport, PingPLReport_Think);
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         strfree(cvar_changes);
 148         strfree(cvar_purechanges);
 149         cvar_purechanges_count = 0;
 150
 151         h = buf_create();
 152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 153         n = buf_getsize(h);
 154
 155         adding = true;
 156         pureadding = true;
 157
 158         for(i = 0; i < n; ++i)
 159         {
 160                 k = bufstr_get(h, i);
 161
 162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 164 #define BADCVAR(p) if(k == p) continue
 165
 166                 // general excludes and namespaces for server admin used cvars
 167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 168
 169                 // internal
 170                 BADPREFIX("csqc_");
 171                 BADPREFIX("cvar_check_");
 172                 BADCVAR("gamecfg");
 173                 BADCVAR("g_configversion");
 174                 BADCVAR("halflifebsp");
 175                 BADCVAR("sv_mapformat_is_quake2");
 176                 BADCVAR("sv_mapformat_is_quake3");
 177                 BADPREFIX("sv_world");
 178
 179                 // client
 180                 BADPREFIX("chase_");
 181                 BADPREFIX("cl_");
 182                 BADPREFIX("con_");
 183                 BADPREFIX("scoreboard_");
 184                 BADPREFIX("g_campaign");
 185                 BADPREFIX("g_waypointsprite_");
 186                 BADPREFIX("gl_");
 187                 BADPREFIX("joy");
 188                 BADPREFIX("hud_");
 189                 BADPREFIX("m_");
 190                 BADPREFIX("menu_");
 191                 BADPREFIX("net_slist_");
 192                 BADPREFIX("r_");
 193                 BADPREFIX("sbar_");
 194                 BADPREFIX("scr_");
 195                 BADPREFIX("snd_");
 196                 BADPREFIX("show");
 197                 BADPREFIX("sensitivity");
 198                 BADPREFIX("userbind");
 199                 BADPREFIX("v_");
 200                 BADPREFIX("vid_");
 201                 BADPREFIX("crosshair");
 202                 BADCVAR("mod_q3bsp_lightmapmergepower");
 203                 BADCVAR("mod_q3bsp_nolightmaps");
 204                 BADCVAR("fov");
 205                 BADCVAR("mastervolume");
 206                 BADCVAR("volume");
 207                 BADCVAR("bgmvolume");
 208                 BADCVAR("in_pitch_min");
 209                 BADCVAR("in_pitch_max");
 210
 211                 // private
 212                 BADCVAR("developer");
 213                 BADCVAR("log_dest_udp");
 214                 BADCVAR("net_address");
 215                 BADCVAR("net_address_ipv6");
 216                 BADCVAR("port");
 217                 BADCVAR("savedgamecfg");
 218                 BADCVAR("serverconfig");
 219                 BADCVAR("sv_autoscreenshot");
 220                 BADCVAR("sv_heartbeatperiod");
 221                 BADCVAR("sv_vote_master_password");
 222                 BADCVAR("sys_colortranslation");
 223                 BADCVAR("sys_specialcharactertranslation");
 224                 BADCVAR("timeformat");
 225                 BADCVAR("timestamps");
 226                 BADCVAR("g_require_stats");
 227                 BADPREFIX("developer_");
 228                 BADPREFIX("g_ban_");
 229                 BADPREFIX("g_banned_list");
 230                 BADPREFIX("g_require_stats_");
 231                 BADPREFIX("g_chat_flood_");
 232                 BADPREFIX("g_ghost_items");
 233                 BADPREFIX("g_playerstats_");
 234                 BADPREFIX("g_voice_flood_");
 235                 BADPREFIX("log_file");
 236                 BADPREFIX("quit_");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250                 BADCVAR("sv_muteban_list");
 251                 BADCVAR("sv_voteban_list");
 252                 BADCVAR("sv_allow_customplayermodels_idlist");
 253                 BADCVAR("sv_allow_customplayermodels_speciallist");
 254
 255                 // mapinfo
 256                 BADCVAR("fraglimit");
 257                 BADCVAR("g_arena");
 258                 BADCVAR("g_assault");
 259                 BADCVAR("g_ca");
 260                 BADCVAR("g_ca_teams");
 261                 BADCVAR("g_conquest");
 262                 BADCVAR("g_ctf");
 263                 BADCVAR("g_cts");
 264                 BADCVAR("g_dotc");
 265                 BADCVAR("g_dm");
 266                 BADCVAR("g_domination");
 267                 BADCVAR("g_domination_default_teams");
 268                 BADCVAR("g_duel");
 269                 BADCVAR("g_freezetag");
 270                 BADCVAR("g_freezetag_teams");
 271                 BADCVAR("g_invasion_teams");
 272                 BADCVAR("g_invasion_type");
 273                 BADCVAR("g_jailbreak");
 274                 BADCVAR("g_jailbreak_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_laps_limit");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_race_qualifying_timelimit_override");
 285                 BADCVAR("g_runematch");
 286                 BADCVAR("g_snafu");
 287                 BADCVAR("g_tdm");
 288                 BADCVAR("g_tdm_teams");
 289                 BADCVAR("g_vip");
 290                 BADCVAR("leadlimit");
 291                 BADCVAR("nextmap");
 292                 BADCVAR("teamplay");
 293                 BADCVAR("timelimit");
 294                 BADCVAR("g_mapinfo_ignore_warnings");
 295
 296                 // long
 297                 BADCVAR("hostname");
 298                 BADCVAR("g_maplist");
 299                 BADCVAR("g_maplist_mostrecent");
 300                 BADCVAR("sv_motd");
 301
 302                 v = cvar_string(k);
 303                 d = cvar_defstring(k);
 304                 if(v == d)
 305                         continue;
 306
 307                 if(adding)
 308                 {
 309                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 310                         if(strlen(cvar_changes) > 16384)
 311                         {
 312                                 cvar_changes = "// too many settings have been changed to show them here\n";
 313                                 adding = 0;
 314                         }
 315                 }
 316
 317                 // now check if the changes are actually gameplay relevant
 318
 319                 // does nothing gameplay relevant
 320                 BADCVAR("captureleadlimit_override");
 321                 BADCVAR("condump_stripcolors");
 322                 BADCVAR("gameversion");
 323                 BADCVAR("g_allow_oldvortexbeam");
 324                 BADCVAR("g_balance_kill_delay");
 325                 BADCVAR("g_buffs_pickup_anyway");
 326                 BADCVAR("g_buffs_randomize");
 327                 BADCVAR("g_campcheck_distance");
 328                 BADCVAR("g_ca_point_leadlimit");
 329                 BADCVAR("g_ca_point_limit");
 330                 BADCVAR("g_ctf_captimerecord_always");
 331                 BADCVAR("g_ctf_flag_glowtrails");
 332                 BADCVAR("g_ctf_flag_pickup_verbosename");
 333                 BADCVAR("g_domination_point_leadlimit");
 334                 BADCVAR("g_forced_respawn");
 335                 BADCVAR("g_freezetag_point_leadlimit");
 336                 BADCVAR("g_freezetag_point_limit");
 337                 BADCVAR("g_hats");
 338                 BADCVAR("g_invasion_point_limit");
 339                 BADCVAR("g_jump_grunt");
 340                 BADCVAR("g_keyhunt_point_leadlimit");
 341                 BADCVAR("g_nexball_goalleadlimit");
 342                 BADCVAR("g_new_toys_use_pickupsound");
 343                 BADCVAR("g_physics_predictall");
 344                 BADCVAR("g_piggyback");
 345                 BADCVAR("g_playerclip_collisions");
 346                 BADCVAR("g_tdm_point_leadlimit");
 347                 BADCVAR("g_tdm_point_limit");
 348                 BADCVAR("leadlimit_and_fraglimit");
 349                 BADCVAR("leadlimit_override");
 350                 BADCVAR("pausable");
 351                 BADCVAR("sv_checkforpacketsduringsleep");
 352                 BADCVAR("sv_damagetext");
 353                 BADCVAR("sv_db_saveasdump");
 354                 BADCVAR("sv_intermission_cdtrack");
 355                 BADCVAR("sv_minigames");
 356                 BADCVAR("sv_namechangetimer");
 357                 BADCVAR("sv_precacheplayermodels");
 358                 BADCVAR("sv_stepheight");
 359                 BADCVAR("sv_timeout");
 360                 BADCVAR("sv_weapons_modeloverride");
 361                 BADCVAR("w_prop_interval");
 362                 BADPREFIX("crypto_");
 363                 BADPREFIX("gameversion_");
 364                 BADPREFIX("g_chat_");
 365                 BADPREFIX("g_ctf_captimerecord_");
 366                 BADPREFIX("g_hats_");
 367                 BADPREFIX("g_maplist_");
 368                 BADPREFIX("g_mod_");
 369                 BADPREFIX("g_respawn_");
 370                 BADPREFIX("net_");
 371                 BADPREFIX("notification_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("skill_");
 374                 BADPREFIX("sv_allow_");
 375                 BADPREFIX("sv_cullentities_");
 376                 BADPREFIX("sv_maxidle_");
 377                 BADPREFIX("sv_minigames_");
 378                 BADPREFIX("sv_radio_");
 379                 BADPREFIX("sv_timeout_");
 380                 BADPREFIX("sv_vote_");
 381                 BADPREFIX("timelimit_");
 382
 383                 // allowed changes to server admins (please sync this to server.cfg)
 384                 // vi commands:
 385                 //   :/"impure"/,$d
 386                 //   :g!,^\/\/[^ /],d
 387                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 388                 //   :%!sort
 389                 // yes, this does contain some redundant stuff, don't really care
 390                 BADCVAR("bot_config_file");
 391                 BADCVAR("bot_number");
 392                 BADCVAR("bot_prefix");
 393                 BADCVAR("bot_suffix");
 394                 BADCVAR("capturelimit_override");
 395                 BADCVAR("fraglimit_override");
 396                 BADCVAR("gametype");
 397                 BADCVAR("g_antilag");
 398                 BADCVAR("g_balance_teams");
 399                 BADCVAR("g_balance_teams_prevent_imbalance");
 400                 BADCVAR("g_balance_teams_scorefactor");
 401                 BADCVAR("g_ban_sync_trusted_servers");
 402                 BADCVAR("g_ban_sync_uri");
 403                 BADCVAR("g_buffs");
 404                 BADCVAR("g_ca_teams_override");
 405                 BADCVAR("g_ctf_ignore_frags");
 406                 BADCVAR("g_ctf_leaderboard");
 407                 BADCVAR("g_domination_point_limit");
 408                 BADCVAR("g_domination_teams_override");
 409                 BADCVAR("g_freezetag_teams_override");
 410                 BADCVAR("g_friendlyfire");
 411                 BADCVAR("g_fullbrightitems");
 412                 BADCVAR("g_fullbrightplayers");
 413                 BADCVAR("g_keyhunt_point_limit");
 414                 BADCVAR("g_keyhunt_teams_override");
 415                 BADCVAR("g_lms_lives_override");
 416                 BADCVAR("g_maplist");
 417                 BADCVAR("g_maxplayers");
 418                 BADCVAR("g_mirrordamage");
 419                 BADCVAR("g_nexball_goallimit");
 420                 BADCVAR("g_norecoil");
 421                 BADCVAR("g_physics_clientselect");
 422                 BADCVAR("g_pinata");
 423                 BADCVAR("g_powerups");
 424                 BADCVAR("g_spawnshieldtime");
 425                 BADCVAR("g_start_delay");
 426                 BADCVAR("g_superspectate");
 427                 BADCVAR("g_tdm_teams_override");
 428                 BADCVAR("g_warmup");
 429                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 430                 BADCVAR("hostname");
 431                 BADCVAR("log_file");
 432                 BADCVAR("maxplayers");
 433                 BADCVAR("minplayers");
 434                 BADCVAR("minplayers_per_team");
 435                 BADCVAR("net_address");
 436                 BADCVAR("port");
 437                 BADCVAR("rcon_password");
 438                 BADCVAR("rcon_restricted_commands");
 439                 BADCVAR("rcon_restricted_password");
 440                 BADCVAR("skill");
 441                 BADCVAR("sv_adminnick");
 442                 BADCVAR("sv_autoscreenshot");
 443                 BADCVAR("sv_autotaunt");
 444                 BADCVAR("sv_curl_defaulturl");
 445                 BADCVAR("sv_defaultcharacter");
 446                 BADCVAR("sv_defaultcharacterskin");
 447                 BADCVAR("sv_defaultplayercolors");
 448                 BADCVAR("sv_defaultplayermodel");
 449                 BADCVAR("sv_defaultplayerskin");
 450                 BADCVAR("sv_maxidle");
 451                 BADCVAR("sv_maxrate");
 452                 BADCVAR("sv_motd");
 453                 BADCVAR("sv_public");
 454                 BADCVAR("sv_ready_restart");
 455                 BADCVAR("sv_status_privacy");
 456                 BADCVAR("sv_taunt");
 457                 BADCVAR("sv_vote_call");
 458                 BADCVAR("sv_vote_commands");
 459                 BADCVAR("sv_vote_majority_factor");
 460                 BADCVAR("sv_vote_master");
 461                 BADCVAR("sv_vote_master_commands");
 462                 BADCVAR("sv_vote_master_password");
 463                 BADCVAR("sv_vote_simple_majority_factor");
 464                 BADCVAR("teamplay_mode");
 465                 BADCVAR("timelimit_override");
 466                 BADPREFIX("g_warmup_");
 467                 BADPREFIX("sv_info_");
 468                 BADPREFIX("sv_ready_restart_");
 469
 470                 // mutators that announce themselves properly to the server browser
 471                 BADCVAR("g_instagib");
 472                 BADCVAR("g_new_toys");
 473                 BADCVAR("g_nix");
 474                 BADCVAR("g_grappling_hook");
 475                 BADCVAR("g_jetpack");
 476
 477 #undef BADPRESUFFIX
 478 #undef BADPREFIX
 479 #undef BADCVAR
 480
 481                 if(pureadding)
 482                 {
 483                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 484                         if(strlen(cvar_purechanges) > 16384)
 485                         {
 486                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 487                                 pureadding = 0;
 488                         }
 489                 }
 490                 ++cvar_purechanges_count;
 491                 // WARNING: this variable is used for the server list
 492                 // NEVER dare to skip this code!
 493                 // Hacks to intentionally appearing as "pure server" even though you DO have
 494                 // modified settings may be punished by removal from the server list.
 495                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 496                 // though.
 497         }
 498         buf_del(h);
 499         if(cvar_changes == "")
 500                 cvar_changes = "// this server runs at default server settings\n";
 501         else
 502                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 503         cvar_changes = strzone(cvar_changes);
 504         if(cvar_purechanges == "")
 505                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 506         else
 507                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 508         cvar_purechanges = strzone(cvar_purechanges);
 509 }
 510
 511 entity randomseed;
 512 bool RandomSeed_Send(entity this, entity to, int sf)
 513 {
 514         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 515         WriteShort(MSG_ENTITY, this.cnt);
 516         return true;
 517 }
 518 void RandomSeed_Think(entity this)
 519 {
 520         this.cnt = bound(0, floor(random() * 65536), 65535);
 521         this.nextthink = time + 5;
 522
 523         this.SendFlags |= 1;
 524 }
 525 void RandomSeed_Spawn()
 526 {
 527         randomseed = new_pure(randomseed);
 528         setthink(randomseed, RandomSeed_Think);
 529         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 530
 531         getthink(randomseed)(randomseed); // sets random seed and nextthink
 532 }
 533
 534 spawnfunc(__init_dedicated_server)
 535 {
 536         // handler for _init/_init map (only for dedicated server initialization)
 537
 538         world_initialized = -1; // don't complain
 539         cvar = cvar_normal;
 540         cvar_string = cvar_string_normal;
 541         cvar_set = cvar_set_normal;
 542
 543         delete_fn = remove_unsafely;
 544
 545         entity e = spawn();
 546         setthink(e, GotoFirstMap);
 547         e.nextthink = time; // this is usually 1 at this point
 548
 549         e = new(info_player_deathmatch);  // safeguard against player joining
 550
 551     // assign reflectively to avoid "assignment to world" warning
 552     for (int i = 0, n = numentityfields(); i < n; ++i) {
 553         string k = entityfieldname(i);
 554         if (k == "classname") {
 555             // safeguard against various stuff ;)
 556             putentityfieldstring(i, this, "worldspawn");
 557             break;
 558         }
 559     }
 560
 561         // needs to be done so early because of the constants they create
 562         static_init();
 563         static_init_late();
 564         static_init_precache();
 565
 566         IL_PUSH(g_spawnpoints, e); // just incase
 567
 568         MapInfo_Enumerate();
 569         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 570 }
 571
 572 void __init_dedicated_server_shutdown() {
 573         MapInfo_Shutdown();
 574 }
 575
 576 STATIC_INIT_EARLY(maxclients)
 577 {
 578         maxclients = 0;
 579         for (entity head = nextent(NULL); head; head = nextent(head)) {
 580                 ++maxclients;
 581         }
 582 }
 583
 584 void default_delayedinit(entity this)
 585 {
 586         if(!scores_initialized)
 587                 ScoreRules_generic();
 588 }
 589
 590 void InitGameplayMode()
 591 {
 592         VoteReset();
 593
 594         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 595         get_mi_min_max(1);
 596         // assign reflectively to avoid "assignment to world" warning
 597         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 598             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 599             if (v) {
 600             putentityfieldstring(i, world, sprintf("%v", v));
 601             if (++done == 2) break;
 602         }
 603         }
 604         // currently, NetRadiant's limit is 131072 qu for each side
 605         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 606         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 607         // in case somebody makes extremely large maps
 608         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 609
 610         MapInfo_LoadMapSettings(mapname);
 611         GameRules_teams(false);
 612
 613         if (!cvar_value_issafe(world.fog))
 614         {
 615                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 616                 world.fog = string_null;
 617         }
 618         if(MapInfo_Map_fog != "")
 619                 if(MapInfo_Map_fog == "none")
 620                         world.fog = string_null;
 621                 else
 622                         world.fog = strzone(MapInfo_Map_fog);
 623         clientstuff = strzone(MapInfo_Map_clientstuff);
 624
 625         MapInfo_ClearTemps();
 626
 627         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 628
 629         cache_mutatormsg = strzone("");
 630         cache_lastmutatormsg = strzone("");
 631
 632         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 633 }
 634
 635 void Map_MarkAsRecent(string m);
 636 float world_already_spawned;
 637 spawnfunc(worldspawn)
 638 {
 639         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 640
 641     bool wantrestart = false;
 642         {
 643                 if (!server_is_dedicated)
 644                 {
 645                         // force unloading of server pk3 files when starting a listen server
 646                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 647                         // restore csqc_progname too
 648                         string expect = "csprogs.dat";
 649                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 650                         cvar_set_normal("csqc_progname", expect);
 651                 }
 652                 else
 653                 {
 654                         // Try to use versioned csprogs from pk3
 655                         // Only ever use versioned csprogs.dat files on dedicated servers;
 656                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 657                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 658                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 659                         string select = "csprogs.dat";
 660                         if (fexists(pk3csprogs)) select = pk3csprogs;
 661                         if (cvar_string_normal("csqc_progname") != select)
 662                         {
 663                                 cvar_set_normal("csqc_progname", select);
 664                                 wantrestart = true;
 665                         }
 666                         // Check for updates on startup
 667                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 668                         int sentinel = fopen("progs.txt", FILE_READ);
 669                         if (sentinel >= 0)
 670                         {
 671                                 string switchversion = fgets(sentinel);
 672                                 fclose(sentinel);
 673                                 if (switchversion != "" && switchversion != WATERMARK)
 674                                 {
 675                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 676                                         // if it doesn't exist, assume either:
 677                                         //   a) the current program was overwritten
 678                                         //   b) this is a client only update
 679                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 680                                         if (fexists(newprogs))
 681                                         {
 682                                                 cvar_set_normal("sv_progs", newprogs);
 683                                                 wantrestart = true;
 684                                         }
 685                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 686                                         if (fexists(newcsprogs))
 687                                         {
 688                                                 cvar_set_normal("csqc_progname", newcsprogs);
 689                                                 wantrestart = true;
 690                                         }
 691                                 }
 692                         }
 693                 }
 694                 if (wantrestart)
 695                 {
 696                         LOG_INFOF("Restart requested");
 697                         changelevel(mapname);
 698                         // let initialization continue, shutdown depends on it
 699                 }
 700         }
 701
 702         cvar = cvar_normal;
 703         cvar_string = cvar_string_normal;
 704         cvar_set = cvar_set_normal;
 705
 706         if(world_already_spawned)
 707                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 708         world_already_spawned = true;
 709
 710         delete_fn = remove_safely; // during spawning, watch what you remove!
 711
 712         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 713
 714         // needs to be done so early because of the constants they create
 715         static_init();
 716
 717         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 718
 719         TemporaryDB = db_create();
 720
 721         // 0 normal
 722         lightstyle(0, "m");
 723
 724         // 1 FLICKER (first variety)
 725         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 726
 727         // 2 SLOW STRONG PULSE
 728         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 729
 730         // 3 CANDLE (first variety)
 731         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 732
 733         // 4 FAST STROBE
 734         lightstyle(4, "mamamamamama");
 735
 736         // 5 GENTLE PULSE 1
 737         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 738
 739         // 6 FLICKER (second variety)
 740         lightstyle(6, "nmonqnmomnmomomno");
 741
 742         // 7 CANDLE (second variety)
 743         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 744
 745         // 8 CANDLE (third variety)
 746         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 747
 748         // 9 SLOW STROBE (fourth variety)
 749         lightstyle(9, "aaaaaaaazzzzzzzz");
 750
 751         // 10 FLUORESCENT FLICKER
 752         lightstyle(10, "mmamammmmammamamaaamammma");
 753
 754         // 11 SLOW PULSE NOT FADE TO BLACK
 755         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 756
 757         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 758
 759         // 63 testing
 760         lightstyle(63, "a");
 761
 762         if(autocvar_g_campaign)
 763                 CampaignPreInit();
 764
 765         Map_MarkAsRecent(mapname);
 766
 767         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 768
 769         InitGameplayMode();
 770         static_init_late();
 771         static_init_precache();
 772         readlevelcvars();
 773         GrappleHookInit();
 774
 775     GameRules_limit_fallbacks();
 776
 777         if(warmup_limit == 0)
 778                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 779
 780         player_count = 0;
 781         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 782         if(bot_waypoints_for_items == 1)
 783                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 784                         bot_waypoints_for_items = 0;
 785
 786         precache();
 787
 788         WaypointSprite_Init();
 789
 790         GameLogInit(); // prepare everything
 791         // NOTE for matchid:
 792         // changing the logic generating it is okay. But:
 793         // it HAS to stay <= 64 chars
 794         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 795         if(autocvar_sv_eventlog)
 796         {
 797                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 798                 matchid = strzone(s);
 799
 800                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 801                 s = ":gameinfo:mutators:LIST";
 802
 803                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 804                 s = M_ARGV(0, string);
 805
 806                 // initialiation stuff, not good in the mutator system
 807                 if(!autocvar_g_use_ammunition)
 808                         s = strcat(s, ":no_use_ammunition");
 809
 810                 // initialiation stuff, not good in the mutator system
 811                 if(autocvar_g_pickup_items == 0)
 812                         s = strcat(s, ":no_pickup_items");
 813                 if(autocvar_g_pickup_items > 0)
 814                         s = strcat(s, ":pickup_items");
 815
 816                 // initialiation stuff, not good in the mutator system
 817                 if(autocvar_g_weaponarena != "0")
 818                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 819
 820                 // TODO to mutator system
 821                 if(autocvar_g_norecoil)
 822                         s = strcat(s, ":norecoil");
 823
 824                 // TODO to mutator system
 825                 if(autocvar_g_powerups == 0)
 826                         s = strcat(s, ":no_powerups");
 827                 if(autocvar_g_powerups > 0)
 828                         s = strcat(s, ":powerups");
 829
 830                 GameLogEcho(s);
 831                 GameLogEcho(":gameinfo:end");
 832         }
 833         else
 834                 matchid = strzone(ftos(random()));
 835
 836         cvar_set("nextmap", "");
 837
 838         SetDefaultAlpha();
 839
 840         if(autocvar_g_campaign)
 841                 CampaignPostInit();
 842
 843         Ban_LoadBans();
 844
 845         MapInfo_Enumerate();
 846         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 847
 848         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 849         {
 850                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 851                 if(fd != -1)
 852                 {
 853                         string s;
 854                         while((s = fgets(fd)))
 855                         {
 856                                 int l = tokenize_console(s);
 857                                 if(l < 2)
 858                                         continue;
 859                                 if(argv(0) == "cd")
 860                                 {
 861                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 862                                         LOG_INFO("  cdtrack ", argv(2));
 863                                 }
 864                                 else if(argv(0) == "fog")
 865                                 {
 866                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 867                                         LOG_INFO("  \"fog\" \"", s, "\"");
 868                                 }
 869                                 else if(argv(0) == "set")
 870                                 {
 871                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 872                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 873                                 }
 874                                 else if(argv(0) != "//")
 875                                 {
 876                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 877                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 878                                 }
 879                         }
 880                         fclose(fd);
 881                 }
 882         }
 883
 884         WeaponStats_Init();
 885
 886         Nagger_Init();
 887
 888         next_pingtime = time + 5;
 889
 890         // set up information replies for clients and server to use
 891         maplist_reply = strzone(getmaplist());
 892         lsmaps_reply = strzone(getlsmaps());
 893         monsterlist_reply = strzone(getmonsterlist());
 894         for(int i = 0; i < 10; ++i)
 895         {
 896                 string s = getrecords(i);
 897                 if (s)
 898                         records_reply[i] = strzone(s);
 899         }
 900         ladder_reply = strzone(getladder());
 901         rankings_reply = strzone(getrankings());
 902
 903         // begin other init
 904         ClientInit_Spawn();
 905         RandomSeed_Spawn();
 906         PingPLReport_Spawn();
 907
 908         CheatInit();
 909
 910         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 911
 912         // fill sv_curl_serverpackages from .serverpackage files
 913         if (autocvar_sv_curl_serverpackages_auto)
 914         {
 915                 string s = "csprogs-" WATERMARK ".txt";
 916                 // remove automatically managed files from the list to prevent duplicates
 917                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 918                 {
 919                         string pkg = argv(i);
 920                         if (startsWith(pkg, "csprogs-")) continue;
 921                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 922                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 923                         s = cons(s, pkg);
 924                 }
 925                 // add automatically managed files to the list
 926                 #define X(match) MACRO_BEGIN { \
 927                         int fd = search_begin(match, true, false); \
 928                         if (fd >= 0) \
 929                         { \
 930                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 931                                 { \
 932                                         s = cons(s, search_getfilename(fd, i)); \
 933                                 } \
 934                                 search_end(fd); \
 935                         } \
 936                 } MACRO_END
 937                 X("*-serverpackage.txt");
 938                 X("*.serverpackage");
 939                 #undef X
 940                 cvar_set("sv_curl_serverpackages", s);
 941         }
 942
 943         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 944         modname = "Xonotic";
 945         // physics/balance/config changes that count as mod
 946         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 947                 modname = cvar_string("g_mod_physics");
 948         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 949                 modname = cvar_string("g_mod_balance");
 950         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 951                 modname = cvar_string("g_mod_config");
 952         // extra mutators that deserve to count as mod
 953         MUTATOR_CALLHOOK(SetModname, modname);
 954         modname = M_ARGV(0, string);
 955
 956         // save it for later
 957         modname = strzone(modname);
 958
 959         WinningConditionHelper(this); // set worldstatus
 960
 961         world_initialized = 1;
 962         __spawnfunc_spawn_all();
 963 }
 964
 965 spawnfunc(light)
 966 {
 967         //makestatic (this); // Who the f___ did that?
 968         delete(this);
 969 }
 970
 971 string GetGametype()
 972 {
 973         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 974 }
 975
 976 string GetMapname()
 977 {
 978         return mapname;
 979 }
 980
 981 float Map_Count, Map_Current;
 982 string Map_Current_Name;
 983
 984 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 985 float GetMaplistPosition()
 986 {
 987         float pos, idx;
 988         string map;
 989
 990         map = GetMapname();
 991         idx = autocvar_g_maplist_index;
 992
 993         if(idx >= 0)
 994                 if(idx < Map_Count)
 995                         if(map == argv(idx))
 996                                 return idx;
 997
 998         for(pos = 0; pos < Map_Count; ++pos)
 999                 if(map == argv(pos))
1000                         return pos;
1001
1002         // resume normal maplist rotation if current map is not in g_maplist
1003         return idx;
1004 }
1005
1006 bool MapHasRightSize(string map)
1007 {
1008         int minplayers = max(0, floor(autocvar_minplayers));
1009         if (teamplay)
1010                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1011         if (autocvar_g_maplist_check_waypoints
1012                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1013         {
1014                 string checkwp_msg = strcat("checkwp ", map);
1015                 if(!fexists(strcat("maps/", map, ".waypoints")))
1016                 {
1017                         LOG_TRACE(checkwp_msg, ": no waypoints");
1018                         return false;
1019                 }
1020                 LOG_TRACE(checkwp_msg, ": has waypoints");
1021         }
1022
1023         // open map size restriction file
1024         string opensize_msg = strcat("opensize ", map);
1025         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1026         if(fh >= 0)
1027         {
1028                 opensize_msg = strcat(opensize_msg, ": ok, ");
1029                 int mapmin = stoi(fgets(fh));
1030                 int mapmax = stoi(fgets(fh));
1031                 fclose(fh);
1032                 if(player_count < mapmin)
1033                 {
1034                         LOG_TRACE(opensize_msg, "not enough");
1035                         return false;
1036                 }
1037                 if(mapmax && player_count > mapmax)
1038                 {
1039                         LOG_TRACE(opensize_msg, "too many");
1040                         return false;
1041                 }
1042                 LOG_TRACE(opensize_msg, "right size");
1043                 return true;
1044         }
1045         LOG_TRACE(opensize_msg, ": not found");
1046         return true;
1047 }
1048
1049 string Map_Filename(float position)
1050 {
1051         return strcat("maps/", argv(position), ".bsp");
1052 }
1053
1054 void Map_MarkAsRecent(string m)
1055 {
1056         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1057 }
1058
1059 float Map_IsRecent(string m)
1060 {
1061         return strhasword(autocvar_g_maplist_mostrecent, m);
1062 }
1063
1064 float Map_Check(float position, float pass)
1065 {
1066         string filename;
1067         string map_next;
1068         map_next = argv(position);
1069         if(pass <= 1)
1070         {
1071                 if(Map_IsRecent(map_next))
1072                         return 0;
1073         }
1074         filename = Map_Filename(position);
1075         if(MapInfo_CheckMap(map_next))
1076         {
1077                 if(pass == 2)
1078                         return 1;
1079                 if(MapHasRightSize(map_next))
1080                         return 1;
1081                 return 0;
1082         }
1083         else
1084                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1085
1086         return 0;
1087 }
1088
1089 void Map_Goto_SetStr(string nextmapname)
1090 {
1091         if(getmapname_stored != "")
1092                 strunzone(getmapname_stored);
1093         if(nextmapname == "")
1094                 getmapname_stored = "";
1095         else
1096                 getmapname_stored = strzone(nextmapname);
1097 }
1098
1099 void Map_Goto_SetFloat(float position)
1100 {
1101         cvar_set("g_maplist_index", ftos(position));
1102         Map_Goto_SetStr(argv(position));
1103 }
1104
1105 void Map_Goto(float reinit)
1106 {
1107         MapInfo_LoadMap(getmapname_stored, reinit);
1108 }
1109
1110 // return codes of map selectors:
1111 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1112 //   -2 = permanent failure
1113 float MaplistMethod_Iterate() // usual method
1114 {
1115         float pass, i;
1116
1117         LOG_TRACE("Trying MaplistMethod_Iterate");
1118
1119         for(pass = 1; pass <= 2; ++pass)
1120         {
1121                 for(i = 1; i < Map_Count; ++i)
1122                 {
1123                         float mapindex;
1124                         mapindex = (i + Map_Current) % Map_Count;
1125                         if(Map_Check(mapindex, pass))
1126                                 return mapindex;
1127                 }
1128         }
1129         return -1;
1130 }
1131
1132 float MaplistMethod_Repeat() // fallback method
1133 {
1134         LOG_TRACE("Trying MaplistMethod_Repeat");
1135
1136         if(Map_Check(Map_Current, 2))
1137                 return Map_Current;
1138         return -2;
1139 }
1140
1141 float MaplistMethod_Random() // random map selection
1142 {
1143         float i, imax;
1144
1145         LOG_TRACE("Trying MaplistMethod_Random");
1146
1147         imax = 42;
1148
1149         for(i = 0; i <= imax; ++i)
1150         {
1151                 float mapindex;
1152                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1153                 if(Map_Check(mapindex, 1))
1154                         return mapindex;
1155         }
1156         return -1;
1157 }
1158
1159 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1160 // the exponent sets a bias on the map selection:
1161 // the higher the exponent, the less likely "shortly repeated" same maps are
1162 {
1163         float i, j, imax, insertpos;
1164
1165         LOG_TRACE("Trying MaplistMethod_Shuffle");
1166
1167         imax = 42;
1168
1169         for(i = 0; i <= imax; ++i)
1170         {
1171                 string newlist;
1172
1173                 // now reinsert this at another position
1174                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1175                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1176                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1177                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1178
1179                 // insert the current map there
1180                 newlist = "";
1181                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1182                         newlist = strcat(newlist, " ", argv(j));
1183                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1184                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1185                         newlist = strcat(newlist, " ", argv(j));
1186                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1187                 cvar_set("g_maplist", newlist);
1188                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1189
1190                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1191                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1192                 if(Map_Check(Map_Current, 1))
1193                         return Map_Current;
1194         }
1195         return -1;
1196 }
1197
1198 void Maplist_Init()
1199 {
1200         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1201         float i;
1202         for (i = 0; i < Map_Count; ++i)
1203                 if (Map_Check(i, 2))
1204                         break;
1205         if (i == Map_Count)
1206         {
1207                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1208                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1209                 if(autocvar_g_maplist_shuffle)
1210                         ShuffleMaplist();
1211                 localcmd("\nmenu_cmd sync\n");
1212                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1213         }
1214         if(Map_Count == 0)
1215                 error("empty maplist, cannot select a new map");
1216         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1217
1218         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1219         // this may or may not be correct, but who cares, in the worst case a map
1220         // isn't chosen in the first pass that should have been
1221 }
1222
1223 string GetNextMap()
1224 {
1225         float nextMap;
1226
1227         Maplist_Init();
1228         nextMap = -1;
1229
1230         if(nextMap == -1)
1231                 if(autocvar_g_maplist_shuffle > 0)
1232                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1233
1234         if(nextMap == -1)
1235                 if(autocvar_g_maplist_selectrandom)
1236                         nextMap = MaplistMethod_Random();
1237
1238         if(nextMap == -1)
1239                 nextMap = MaplistMethod_Iterate();
1240
1241         if(nextMap == -1)
1242                 nextMap = MaplistMethod_Repeat();
1243
1244         if(nextMap >= 0)
1245         {
1246                 Map_Goto_SetFloat(nextMap);
1247                 return getmapname_stored;
1248         }
1249
1250         return "";
1251 }
1252
1253 float DoNextMapOverride(float reinit)
1254 {
1255         if(autocvar_g_campaign)
1256         {
1257                 CampaignPostIntermission();
1258                 alreadychangedlevel = true;
1259                 return true;
1260         }
1261         if(autocvar_quit_when_empty)
1262         {
1263                 if(player_count <= currentbots)
1264                 {
1265                         localcmd("quit\n");
1266                         alreadychangedlevel = true;
1267                         return true;
1268                 }
1269         }
1270         if(autocvar_quit_and_redirect != "")
1271         {
1272                 redirection_target = strzone(autocvar_quit_and_redirect);
1273                 alreadychangedlevel = true;
1274                 return true;
1275         }
1276         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1277         {
1278                 localcmd("restart\n");
1279                 alreadychangedlevel = true;
1280                 return true;
1281         }
1282         if(autocvar_nextmap != "")
1283         {
1284                 string m;
1285                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1286                 cvar_set("nextmap",m);
1287
1288                 if(!m || gametypevote)
1289                         return false;
1290                 if(autocvar_sv_vote_gametype)
1291                 {
1292                         Map_Goto_SetStr(m);
1293                         return false;
1294                 }
1295
1296                 if(MapInfo_CheckMap(m))
1297                 {
1298                         Map_Goto_SetStr(m);
1299                         Map_Goto(reinit);
1300                         alreadychangedlevel = true;
1301                         return true;
1302                 }
1303         }
1304         if(!reinit && autocvar_lastlevel)
1305         {
1306                 cvar_settemp_restore();
1307                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1308                 alreadychangedlevel = true;
1309                 return true;
1310         }
1311         return false;
1312 }
1313
1314 void GotoNextMap(float reinit)
1315 {
1316         //string nextmap;
1317         //float n, nummaps;
1318         //string s;
1319         if (alreadychangedlevel)
1320                 return;
1321         alreadychangedlevel = true;
1322
1323         string nextMap;
1324
1325         nextMap = GetNextMap();
1326         if(nextMap == "")
1327                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1328         Map_Goto(reinit);
1329 }
1330
1331
1332 /*
1333 ============
1334 IntermissionThink
1335
1336 When the player presses attack or jump, change to the next level
1337 ============
1338 */
1339 .float autoscreenshot;
1340 void IntermissionThink(entity this)
1341 {
1342         FixIntermissionClient(this);
1343
1344         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1345         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1346
1347         if( (server_screenshot || client_screenshot)
1348                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1349         {
1350                 this.autoscreenshot = -1;
1351                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1352                 return;
1353         }
1354
1355         if (time < intermission_exittime)
1356                 return;
1357
1358         if(!mapvote_initialized)
1359                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1360                         return;
1361
1362         MapVote_Start();
1363 }
1364
1365 /*
1366 ============
1367 FindIntermission
1368
1369 Returns the entity to view from
1370 ============
1371 */
1372 /*
1373 entity FindIntermission()
1374 {
1375         local   entity spot;
1376         local   float cyc;
1377
1378 // look for info_intermission first
1379         spot = find(NULL, classname, "info_intermission");
1380         if (spot)
1381         {       // pick a random one
1382                 cyc = random() * 4;
1383                 while (cyc > 1)
1384                 {
1385                         spot = find(spot, classname, "info_intermission");
1386                         if (!spot)
1387                                 spot = find(spot, classname, "info_intermission");
1388                         cyc = cyc - 1;
1389                 }
1390                 return spot;
1391         }
1392
1393 // then look for the start position
1394         spot = find(NULL, classname, "info_player_start");
1395         if (spot)
1396                 return spot;
1397
1398 // testinfo_player_start is only found in regioned levels
1399         spot = find(NULL, classname, "testplayerstart");
1400         if (spot)
1401                 return spot;
1402
1403 // then look for the start position
1404         spot = find(NULL, classname, "info_player_deathmatch");
1405         if (spot)
1406                 return spot;
1407
1408         //objerror ("FindIntermission: no spot");
1409         return NULL;
1410 }
1411 */
1412
1413 /*
1414 ===============================================================================
1415
1416 RULES
1417
1418 ===============================================================================
1419 */
1420
1421 void DumpStats(float final)
1422 {
1423         float file;
1424         string s;
1425         float to_console;
1426         float to_eventlog;
1427         float to_file;
1428         float i;
1429
1430         to_console = autocvar_sv_logscores_console;
1431         to_eventlog = autocvar_sv_eventlog;
1432         to_file = autocvar_sv_logscores_file;
1433
1434         if(!final)
1435         {
1436                 to_console = true; // always print printstats replies
1437                 to_eventlog = false; // but never print them to the event log
1438         }
1439
1440         if(to_eventlog)
1441                 if(autocvar_sv_eventlog_console)
1442                         to_console = false; // otherwise we get the output twice
1443
1444         if(final)
1445                 s = ":scores:";
1446         else
1447                 s = ":status:";
1448         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1449
1450         if(to_console)
1451                 LOG_INFO(s);
1452         if(to_eventlog)
1453                 GameLogEcho(s);
1454
1455         file = -1;
1456         if(to_file)
1457         {
1458                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1459                 if(file == -1)
1460                         to_file = false;
1461                 else
1462                         fputs(file, strcat(s, "\n"));
1463         }
1464
1465         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1466         if(to_console)
1467                 LOG_INFO(s);
1468         if(to_eventlog)
1469                 GameLogEcho(s);
1470         if(to_file)
1471                 fputs(file, strcat(s, "\n"));
1472
1473         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1474                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1475                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1476                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1477                         s = strcat(s, ftos(it.team), ":");
1478                 else
1479                         s = strcat(s, "spectator:");
1480
1481                 if(to_console)
1482                         LOG_INFO(s, playername(it, false));
1483                 if(to_eventlog)
1484                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1485                 if(to_file)
1486                         fputs(file, strcat(s, playername(it, false), "\n"));
1487         });
1488
1489         if(teamplay)
1490         {
1491                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1492                 if(to_console)
1493                         LOG_INFO(s);
1494                 if(to_eventlog)
1495                         GameLogEcho(s);
1496                 if(to_file)
1497                         fputs(file, strcat(s, "\n"));
1498
1499                 for(i = 1; i < 16; ++i)
1500                 {
1501                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1502                         s = strcat(s, ":", ftos(i));
1503                         if(to_console)
1504                                 LOG_INFO(s);
1505                         if(to_eventlog)
1506                                 GameLogEcho(s);
1507                         if(to_file)
1508                                 fputs(file, strcat(s, "\n"));
1509                 }
1510         }
1511
1512         if(to_console)
1513                 LOG_INFO(":end");
1514         if(to_eventlog)
1515                 GameLogEcho(":end");
1516         if(to_file)
1517         {
1518                 fputs(file, ":end\n");
1519                 fclose(file);
1520         }
1521 }
1522
1523 void FixIntermissionClient(entity e)
1524 {
1525         if(!e.autoscreenshot) // initial call
1526         {
1527                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1528                 SetResourceAmountExplicit(e, RESOURCE_HEALTH, -2342);
1529                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1530                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1531                 {
1532                     .entity weaponentity = weaponentities[slot];
1533                         if(e.(weaponentity))
1534                         {
1535                                 e.(weaponentity).effects = EF_NODRAW;
1536                                 if (e.(weaponentity).weaponchild)
1537                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1538                         }
1539                 }
1540                 if(IS_REAL_CLIENT(e))
1541                 {
1542                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1543                         RandomSelection_Init();
1544                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1545                                 RandomSelection_AddString(it, 1, 1);
1546                         });
1547                         if (RandomSelection_chosen_string != "")
1548                         {
1549                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1550                         }
1551                         msg_entity = e;
1552                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1553                 }
1554         }
1555 }
1556
1557 /*
1558 go to the next level for deathmatch
1559 only called if a time or frag limit has expired
1560 */
1561 void NextLevel()
1562 {
1563         game_stopped = true;
1564         intermission_running = 1; // game over
1565
1566         // enforce a wait time before allowing changelevel
1567         if(player_count > 0)
1568                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1569         else
1570                 intermission_exittime = -1;
1571
1572         /*
1573         WriteByte (MSG_ALL, SVC_CDTRACK);
1574         WriteByte (MSG_ALL, 3);
1575         WriteByte (MSG_ALL, 3);
1576         // done in FixIntermission
1577         */
1578
1579         //pos = FindIntermission ();
1580
1581         VoteReset();
1582
1583         DumpStats(true);
1584
1585         // send statistics
1586         PlayerStats_GameReport(true);
1587         WeaponStats_Shutdown();
1588
1589         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1590
1591         if(autocvar_sv_eventlog)
1592                 GameLogEcho(":gameover");
1593
1594         GameLogClose();
1595
1596         FOREACH_CLIENT(IS_PLAYER(it), {
1597                 FixIntermissionClient(it);
1598                 if(it.winning)
1599                         bprint(playername(it, false), " ^7wins.\n");
1600         });
1601
1602         target_music_kill();
1603
1604         if(autocvar_g_campaign)
1605                 CampaignPreIntermission();
1606
1607         MUTATOR_CALLHOOK(MatchEnd);
1608
1609         localcmd("\nsv_hook_gameend\n");
1610 }
1611
1612
1613 float InitiateSuddenDeath()
1614 {
1615         // Check first whether normal overtimes could be added before initiating suddendeath mode
1616         // - for this timelimit_overtime needs to be >0 of course
1617         // - also check the winning condition calculated in the previous frame and only add normal overtime
1618         //   again, if at the point at which timelimit would be extended again, still no winner was found
1619         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1620                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1621                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1622         {
1623                 return 1; // need to call InitiateOvertime later
1624         }
1625         else
1626         {
1627                 if(!checkrules_suddendeathend)
1628                 {
1629                         if(autocvar_g_campaign)
1630                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1631                         else
1632                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1633                         if(g_race && !g_race_qualifying)
1634                                 race_StartCompleting();
1635                 }
1636                 return 0;
1637         }
1638 }
1639
1640 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1641 {
1642         ++checkrules_overtimesadded;
1643         //add one more overtime by simply extending the timelimit
1644         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1645         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1646 }
1647
1648 float GetWinningCode(float fraglimitreached, float equality)
1649 {
1650         if(autocvar_g_campaign == 1)
1651                 if(fraglimitreached)
1652                         return WINNING_YES;
1653                 else
1654                         return WINNING_NO;
1655
1656         else
1657                 if(equality)
1658                         if(fraglimitreached)
1659                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1660                         else
1661                                 return WINNING_NEVER;
1662                 else
1663                         if(fraglimitreached)
1664                                 return WINNING_YES;
1665                         else
1666                                 return WINNING_NO;
1667 }
1668
1669 // set the .winning flag for exactly those players with a given field value
1670 void SetWinners(.float field, float value)
1671 {
1672         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1673 }
1674
1675 // set the .winning flag for those players with a given field value
1676 void AddWinners(.float field, float value)
1677 {
1678         FOREACH_CLIENT(IS_PLAYER(it), {
1679                 if(it.(field) == value)
1680                         it.winning = 1;
1681         });
1682 }
1683
1684 // clear the .winning flags
1685 void ClearWinners()
1686 {
1687         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1688 }
1689
1690 void ShuffleMaplist()
1691 {
1692         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1693 }
1694
1695 float leaderfrags;
1696 float WinningCondition_Scores(float limit, float leadlimit)
1697 {
1698         float limitreached;
1699
1700         // TODO make everything use THIS winning condition (except LMS)
1701         WinningConditionHelper(NULL);
1702
1703         if(teamplay)
1704         {
1705                 for (int i = 1; i < 5; ++i)
1706                 {
1707                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1708                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1709                 }
1710         }
1711
1712         ClearWinners();
1713         if(WinningConditionHelper_winner)
1714                 WinningConditionHelper_winner.winning = 1;
1715         if(WinningConditionHelper_winnerteam >= 0)
1716                 SetWinners(team, WinningConditionHelper_winnerteam);
1717
1718         if(WinningConditionHelper_lowerisbetter)
1719         {
1720                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1721                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1722                 limit = -limit;
1723         }
1724
1725         if(WinningConditionHelper_zeroisworst)
1726                 leadlimit = 0; // not supported in this mode
1727
1728         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1729         // these modes always score in increments of 1, thus this makes sense
1730         {
1731                 if(leaderfrags != WinningConditionHelper_topscore)
1732                 {
1733                         leaderfrags = WinningConditionHelper_topscore;
1734
1735                         if (limit)
1736                         if (leaderfrags == limit - 1)
1737                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1738                         else if (leaderfrags == limit - 2)
1739                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1740                         else if (leaderfrags == limit - 3)
1741                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1742                 }
1743         }
1744
1745         limitreached = false;
1746         if(limit)
1747                 if(WinningConditionHelper_topscore >= limit)
1748                         limitreached = true;
1749         if(leadlimit)
1750         {
1751                 float leadlimitreached;
1752                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1753                 if(autocvar_leadlimit_and_fraglimit)
1754                         limitreached = (limitreached && leadlimitreached);
1755                 else
1756                         limitreached = (limitreached || leadlimitreached);
1757         }
1758
1759         if(limit)
1760                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1761
1762         return GetWinningCode(
1763                 WinningConditionHelper_topscore && limitreached,
1764                 WinningConditionHelper_equality
1765         );
1766 }
1767
1768 float WinningCondition_RanOutOfSpawns()
1769 {
1770         if(have_team_spawns <= 0)
1771                 return WINNING_NO;
1772
1773         if(!autocvar_g_spawn_useallspawns)
1774                 return WINNING_NO;
1775
1776         if(!some_spawn_has_been_used)
1777                 return WINNING_NO;
1778
1779         for (int i = 1; i < 5; ++i)
1780         {
1781                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1782         }
1783
1784         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1785         {
1786                 if (Team_IsValidTeam(it.team))
1787                 {
1788                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1789                 }
1790         });
1791
1792         IL_EACH(g_spawnpoints, true,
1793         {
1794                 if (Team_IsValidTeam(it.team))
1795                 {
1796                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1797                 }
1798         });
1799
1800         ClearWinners();
1801         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1802         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1803         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1804         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1805         if(team1_score + team2_score + team3_score + team4_score == 0)
1806         {
1807                 checkrules_equality = true;
1808                 return WINNING_YES;
1809         }
1810         else if(team1_score + team2_score + team3_score + team4_score == 1)
1811         {
1812                 float t, i;
1813                 if(team1_score)
1814                         t = 1;
1815                 else if(team2_score)
1816                         t = 2;
1817                 else if(team3_score)
1818                         t = 3;
1819                 else // if(team4_score)
1820                         t = 4;
1821                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1822                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1823                 {
1824                         for (int j = 1; j <= NUM_TEAMS; ++j)
1825                         {
1826                                 if (t == j)
1827                                 {
1828                                         continue;
1829                                 }
1830                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1831                                 {
1832                                         continue;
1833                                 }
1834                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1835                         }
1836                 }
1837
1838                 AddWinners(team, t);
1839                 return WINNING_YES;
1840         }
1841         else
1842                 return WINNING_NO;
1843 }
1844
1845 /*
1846 ============
1847 CheckRules_World
1848
1849 Exit deathmatch games upon conditions
1850 ============
1851 */
1852 void CheckRules_World()
1853 {
1854         float timelimit;
1855         float fraglimit;
1856         float leadlimit;
1857
1858         VoteThink();
1859         MapVote_Think();
1860
1861         SetDefaultAlpha();
1862
1863         if (intermission_running) // someone else quit the game already
1864         {
1865                 if(player_count == 0) // Nobody there? Then let's go to the next map
1866                         MapVote_Start();
1867                         // this will actually check the player count in the next frame
1868                         // again, but this shouldn't hurt
1869                 return;
1870         }
1871
1872         timelimit = autocvar_timelimit * 60;
1873         fraglimit = autocvar_fraglimit;
1874         leadlimit = autocvar_leadlimit;
1875
1876         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1877         {
1878                 if(timelimit > 0)
1879                         timelimit = 0; // timelimit is not made for warmup
1880                 if(fraglimit > 0)
1881                         fraglimit = 0; // no fraglimit for now
1882                 leadlimit = 0; // no leadlimit for now
1883         }
1884
1885         if(timelimit > 0)
1886         {
1887                 timelimit += game_starttime;
1888         }
1889         else if (timelimit < 0)
1890         {
1891                 // endmatch
1892                 NextLevel();
1893                 return;
1894         }
1895
1896         float wantovertime;
1897         wantovertime = 0;
1898
1899         if(timelimit > game_starttime)
1900                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1901         else
1902                 game_completion_ratio = 0;
1903
1904         if(checkrules_suddendeathend)
1905         {
1906                 if(!checkrules_suddendeathwarning)
1907                 {
1908                         checkrules_suddendeathwarning = true;
1909                         if(g_race && !g_race_qualifying)
1910                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1911                         else
1912                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1913                 }
1914         }
1915         else
1916         {
1917                 if (timelimit && time >= timelimit)
1918                 {
1919                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1920                         {
1921                                 float totalplayers;
1922                                 float playerswithlaps;
1923                                 float readyplayers;
1924                                 totalplayers = playerswithlaps = readyplayers = 0;
1925                                 FOREACH_CLIENT(IS_PLAYER(it), {
1926                                         ++totalplayers;
1927                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1928                                                 ++playerswithlaps;
1929                                         if(it.ready)
1930                                                 ++readyplayers;
1931                                 });
1932
1933                                 // at least 2 of the players have completed a lap: start the RACE
1934                                 // otherwise, the players should end the qualifying on their own
1935                                 if(readyplayers || playerswithlaps >= 2)
1936                                 {
1937                                         checkrules_suddendeathend = 0;
1938                                         ReadyRestart(); // go to race
1939                                         return;
1940                                 }
1941                                 else
1942                                         wantovertime |= InitiateSuddenDeath();
1943                         }
1944                         else
1945                                 wantovertime |= InitiateSuddenDeath();
1946                 }
1947         }
1948
1949         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1950         {
1951                 NextLevel();
1952                 return;
1953         }
1954
1955         int checkrules_status = WinningCondition_RanOutOfSpawns();
1956         if(checkrules_status == WINNING_YES)
1957                 bprint("Hey! Someone ran out of spawns!\n");
1958         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1959                 checkrules_status = M_ARGV(0, float);
1960         else
1961                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1962
1963         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1964         {
1965                 checkrules_status = WINNING_NEVER;
1966                 checkrules_overtimesadded = -1;
1967                 wantovertime |= InitiateSuddenDeath();
1968         }
1969
1970         if(checkrules_status == WINNING_NEVER)
1971                 // equality cases! Nobody wins if the overtime ends in a draw.
1972                 ClearWinners();
1973
1974         if(wantovertime)
1975         {
1976                 if(checkrules_status == WINNING_NEVER)
1977                         InitiateOvertime();
1978                 else
1979                         checkrules_status = WINNING_YES;
1980         }
1981
1982         if(checkrules_suddendeathend)
1983                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1984                         checkrules_status = WINNING_YES;
1985
1986         if(checkrules_status == WINNING_YES)
1987         {
1988                 //print("WINNING\n");
1989                 NextLevel();
1990         }
1991 }
1992
1993 string GotoMap(string m)
1994 {
1995         m = GameTypeVote_MapInfo_FixName(m);
1996         if (!m)
1997                 return "The map you suggested is not available on this server.";
1998         if (!autocvar_sv_vote_gametype)
1999         if(!MapInfo_CheckMap(m))
2000                 return "The map you suggested does not support the current game mode.";
2001         cvar_set("nextmap", m);
2002         cvar_set("timelimit", "-1");
2003         if(mapvote_initialized || alreadychangedlevel)
2004         {
2005                 if(DoNextMapOverride(0))
2006                         return "Map switch initiated.";
2007                 else
2008                         return "Hm... no. For some reason I like THIS map more.";
2009         }
2010         else
2011                 return "Map switch will happen after scoreboard.";
2012 }
2013
2014 bool autocvar_sv_gameplayfix_multiplethinksperframe;
2015 void RunThink(entity this)
2016 {
2017         // don't let things stay in the past.
2018         // it is possible to start that way by a trigger with a local time.
2019         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2020                 return;
2021
2022         float oldtime = time; // do we need to save this?
2023
2024         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2025         {
2026                 time = max(oldtime, this.nextthink);
2027                 this.nextthink = 0;
2028
2029                 if(getthink(this))
2030                         getthink(this)(this);
2031                 // mods often set nextthink to time to cause a think every frame,
2032                 // we don't want to loop in that case, so exit if the new nextthink is
2033                 // <= the time the qc was told, also exit if it is past the end of the
2034                 // frame
2035                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2036                         break;
2037         }
2038
2039         time = oldtime;
2040 }
2041
2042 bool autocvar_sv_freezenonclients;
2043 bool autocvar_sv_gameplayfix_delayprojectiles;
2044 void Physics_Frame()
2045 {
2046         if(autocvar_sv_freezenonclients)
2047                 return;
2048
2049         FOREACH_ENTITY_FLOAT(pure_data, false,
2050         {
2051                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2052                         continue;
2053
2054                 //set_movetype(it, it.move_movetype);
2055                 // inline the set_movetype function, since this is called a lot
2056                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2057
2058                 if(it.move_movetype == MOVETYPE_NONE)
2059                         continue;
2060
2061                 if(it.move_qcphysics)
2062                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2063
2064                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2065                 {
2066                         // handle thinking here
2067                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2068                                 RunThink(it);
2069                 }
2070         });
2071
2072         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2073                 return;
2074
2075         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2076         {
2077                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2078                         continue;
2079                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2080         });
2081 }
2082
2083 void systems_update();
2084 void EndFrame()
2085 {
2086         anticheat_endframe();
2087
2088         Physics_Frame();
2089
2090         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2091                 entity e = IS_SPEC(it) ? it.enemy : it;
2092                 if (e.typehitsound) {
2093                         STAT(TYPEHIT_TIME, it) = time;
2094                 } else if (e.killsound) {
2095                         STAT(KILL_TIME, it) = time;
2096                 } else if (e.damage_dealt) {
2097                         STAT(HIT_TIME, it) = time;
2098                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2099                 }
2100         });
2101         // add 1 frametime because after this, engine SV_Physics
2102         // increases time by a frametime and then networks the frame
2103         // add another frametime because client shows everything with
2104         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2105         // needed!
2106         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2107         FOREACH_CLIENT(true, {
2108                 it.typehitsound = false;
2109                 it.damage_dealt = 0;
2110                 it.killsound = false;
2111                 antilag_record(it, CS(it), altime);
2112         });
2113         IL_EACH(g_monsters, true,
2114         {
2115                 antilag_record(it, it, altime);
2116         });
2117         IL_EACH(g_projectiles, it.classname == "nade",
2118         {
2119                 antilag_record(it, it, altime);
2120         });
2121         systems_update();
2122         IL_ENDFRAME();
2123 }
2124
2125
2126 /*
2127  * RedirectionThink:
2128  * returns true if redirecting
2129  */
2130 float redirection_timeout;
2131 float redirection_nextthink;
2132 float RedirectionThink()
2133 {
2134         float clients_found;
2135
2136         if(redirection_target == "")
2137                 return false;
2138
2139         if(!redirection_timeout)
2140         {
2141                 cvar_set("sv_public", "-2");
2142                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2143                 if(redirection_target == "self")
2144                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2145                 else
2146                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2147         }
2148
2149         if(time < redirection_nextthink)
2150                 return true;
2151
2152         redirection_nextthink = time + 1;
2153
2154         clients_found = 0;
2155         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2156                 // TODO add timer
2157                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2158                 if(redirection_target == "self")
2159                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2160                 else
2161                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2162                 ++clients_found;
2163         });
2164
2165         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2166
2167         if(time > redirection_timeout || clients_found == 0)
2168                 localcmd("\nwait; wait; wait; quit\n");
2169
2170         return true;
2171 }
2172
2173 void RestoreGame()
2174 {
2175         // Loaded from a save game
2176         // some things then break, so let's work around them...
2177
2178         // Progs DB (capture records)
2179         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2180
2181         // Mapinfo
2182         MapInfo_Shutdown();
2183         MapInfo_Enumerate();
2184         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2185         WeaponStats_Init();
2186
2187         TargetMusic_RestoreGame();
2188 }
2189
2190 void Shutdown()
2191 {
2192         game_stopped = 2;
2193
2194         if(world_initialized > 0)
2195         {
2196                 world_initialized = 0;
2197                 LOG_TRACE("Saving persistent data...");
2198                 Ban_SaveBans();
2199
2200                 // playerstats with unfinished match
2201                 PlayerStats_GameReport(false);
2202
2203                 if(!cheatcount_total)
2204                 {
2205                         if(autocvar_sv_db_saveasdump)
2206                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2207                         else
2208                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2209                 }
2210                 if(autocvar_developer)
2211                 {
2212                         if(autocvar_sv_db_saveasdump)
2213                                 db_dump(TemporaryDB, "server-temp.db");
2214                         else
2215                                 db_save(TemporaryDB, "server-temp.db");
2216                 }
2217                 CheatShutdown(); // must be after cheatcount check
2218                 db_close(ServerProgsDB);
2219                 db_close(TemporaryDB);
2220                 LOG_TRACE("Saving persistent data... done!");
2221                 // tell the bot system the game is ending now
2222                 bot_endgame();
2223
2224                 WeaponStats_Shutdown();
2225                 MapInfo_Shutdown();
2226         }
2227         else if(world_initialized == 0)
2228         {
2229                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2230         }
2231         else
2232         {
2233                 __init_dedicated_server_shutdown();
2234         }
2235 }