qcsrc/server/g_world.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "../common/constants.qh"
   7     #include "../common/stats.qh"
   8     #include "../common/teams.qh"
   9     #include "../common/util.qh"
  10     #include "../common/monsters/sv_monsters.qh"
  11     #include "../common/weapons/weapons.qh"
  12     #include "weapons/weaponstats.qh"
  13     #include "autocvars.qh"
  14     #include "constants.qh"
  15     #include "defs.qh"
  16     #include "../common/notifications.qh"
  17     #include "mutators/mutators_include.qh"
  18     #include "campaign.qh"
  19     #include "../common/mapinfo.qh"
  20     #include "command/common.qh"
  21     #include "command/vote.qh"
  22     #include "command/getreplies.qh"
  23     #include "command/sv_cmd.qh"
  24     #include "anticheat.qh"
  25     #include "cheats.qh"
  26     #include "../common/playerstats.qh"
  27     #include "g_hook.qh"
  28     #include "scores.qh"
  29     #include "mapvoting.qh"
  30     #include "ipban.qh"
  31     #include "race.qh"
  32     #include "antilag.qh"
  33     #include "secret.qh"
  34 #endif
  35
  36 const float LATENCY_THINKRATE = 10;
  37 .float latency_sum;
  38 .float latency_cnt;
  39 .float latency_time;
  40 entity pingplreport;
  41 void PingPLReport_Think()
  42 {
  43         float delta;
  44         entity e;
  45
  46         delta = 3 / maxclients;
  47         if(delta < sys_frametime)
  48                 delta = 0;
  49         self.nextthink = time + delta;
  50
  51         e = edict_num(self.cnt + 1);
  52         if(IS_REAL_CLIENT(e))
  53         {
  54                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  55                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  56                 WriteByte(MSG_BROADCAST, self.cnt);
  57                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  58                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  60
  61                 // record latency times for clients throughout the match so we can report it to playerstats
  62                 if(time > (e.latency_time + LATENCY_THINKRATE))
  63                 {
  64                         e.latency_sum += e.ping;
  65                         e.latency_cnt += 1;
  66                         e.latency_time = time;
  67                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  68                 }
  69         }
  70         else
  71         {
  72                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  73                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  74                 WriteByte(MSG_BROADCAST, self.cnt);
  75                 WriteShort(MSG_BROADCAST, 0);
  76                 WriteByte(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78         }
  79         self.cnt = (self.cnt + 1) % maxclients;
  80 }
  81 void PingPLReport_Spawn()
  82 {
  83         pingplreport = spawn();
  84         pingplreport.classname = "pingplreport";
  85         pingplreport.think = PingPLReport_Think;
  86         pingplreport.nextthink = time;
  87 }
  88
  89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  90 string redirection_target;
  91 float world_initialized;
  92
  93 string GetGametype();
  94 void GotoNextMap(float reinit);
  95 void ShuffleMaplist();
  96 float(float reinit) DoNextMapOverride;
  97
  98 void SetDefaultAlpha()
  99 {
 100         if(autocvar_g_running_guns)
 101         {
 102                 default_player_alpha = -1;
 103                 default_weapon_alpha = +1;
 104         }
 105         else if(g_cloaked)
 106         {
 107                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 108                 default_weapon_alpha = default_player_alpha;
 109         }
 110         else
 111         {
 112                 default_player_alpha = autocvar_g_player_alpha;
 113                 if(default_player_alpha == 0)
 114                         default_player_alpha = 1;
 115                 default_weapon_alpha = default_player_alpha;
 116         }
 117 }
 118
 119 void GotoFirstMap()
 120 {
 121         float n;
 122         if(autocvar__sv_init)
 123         {
 124                 // cvar_set("_sv_init", "0");
 125                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 126                 // to this "init" map on a dedicated server will cause no permanent
 127                 // harm
 128                 if(autocvar_g_maplist_shuffle)
 129                         ShuffleMaplist();
 130                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 131                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 132
 133                 MapInfo_Enumerate();
 134                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 135
 136                 if(!DoNextMapOverride(1))
 137                         GotoNextMap(1);
 138
 139                 return;
 140         }
 141
 142         if(time < 5)
 143         {
 144                 self.nextthink = time;
 145         }
 146         else
 147         {
 148                 self.nextthink = time + 1;
 149                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 150         }
 151 }
 152
 153 void cvar_changes_init()
 154 {
 155         float h;
 156         string k, v, d;
 157         float n, i, adding, pureadding;
 158
 159         if(cvar_changes)
 160                 strunzone(cvar_changes);
 161         cvar_changes = string_null;
 162         if(cvar_purechanges)
 163                 strunzone(cvar_purechanges);
 164         cvar_purechanges = string_null;
 165         cvar_purechanges_count = 0;
 166
 167         h = buf_create();
 168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 169         n = buf_getsize(h);
 170
 171         adding = true;
 172         pureadding = true;
 173
 174         for(i = 0; i < n; ++i)
 175         {
 176                 k = bufstr_get(h, i);
 177
 178 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 179 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 180 #define BADCVAR(p) if(k == p) continue
 181
 182                 // general excludes and namespaces for server admin used cvars
 183                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 184
 185                 // internal
 186                 BADPREFIX("csqc_");
 187                 BADPREFIX("cvar_check_");
 188                 BADCVAR("gamecfg");
 189                 BADCVAR("g_configversion");
 190                 BADCVAR("g_maplist_index");
 191                 BADCVAR("halflifebsp");
 192                 BADPREFIX("sv_world");
 193
 194                 // client
 195                 BADPREFIX("chase_");
 196                 BADPREFIX("cl_");
 197                 BADPREFIX("con_");
 198                 BADPREFIX("scoreboard_");
 199                 BADPREFIX("g_campaign");
 200                 BADPREFIX("g_waypointsprite_");
 201                 BADPREFIX("gl_");
 202                 BADPREFIX("joy");
 203                 BADPREFIX("hud_");
 204                 BADPREFIX("m_");
 205                 BADPREFIX("menu_");
 206                 BADPREFIX("net_slist_");
 207                 BADPREFIX("r_");
 208                 BADPREFIX("sbar_");
 209                 BADPREFIX("scr_");
 210                 BADPREFIX("snd_");
 211                 BADPREFIX("show");
 212                 BADPREFIX("sensitivity");
 213                 BADPREFIX("userbind");
 214                 BADPREFIX("v_");
 215                 BADPREFIX("vid_");
 216                 BADPREFIX("crosshair");
 217                 BADCVAR("mod_q3bsp_lightmapmergepower");
 218                 BADCVAR("mod_q3bsp_nolightmaps");
 219                 BADCVAR("fov");
 220                 BADCVAR("mastervolume");
 221                 BADCVAR("volume");
 222                 BADCVAR("bgmvolume");
 223
 224                 // private
 225                 BADCVAR("developer");
 226                 BADCVAR("log_dest_udp");
 227                 BADCVAR("net_address");
 228                 BADCVAR("net_address_ipv6");
 229                 BADCVAR("port");
 230                 BADCVAR("savedgamecfg");
 231                 BADCVAR("serverconfig");
 232                 BADCVAR("sv_autoscreenshot");
 233                 BADCVAR("sv_heartbeatperiod");
 234                 BADCVAR("sv_vote_master_password");
 235                 BADCVAR("sys_colortranslation");
 236                 BADCVAR("sys_specialcharactertranslation");
 237                 BADCVAR("timeformat");
 238                 BADCVAR("timestamps");
 239                 BADPREFIX("developer_");
 240                 BADPREFIX("g_ban_");
 241                 BADPREFIX("g_banned_list");
 242                 BADPREFIX("g_chat_flood_");
 243                 BADPREFIX("g_ghost_items");
 244                 BADPREFIX("g_playerstats_");
 245                 BADPREFIX("g_respawn_ghosts");
 246                 BADPREFIX("g_voice_flood_");
 247                 BADPREFIX("log_file");
 248                 BADPREFIX("rcon_");
 249                 BADPREFIX("sv_allowdownloads");
 250                 BADPREFIX("sv_autodemo");
 251                 BADPREFIX("sv_curl_");
 252                 BADPREFIX("sv_eventlog");
 253                 BADPREFIX("sv_logscores_");
 254                 BADPREFIX("sv_master");
 255                 BADPREFIX("sv_weaponstats_");
 256                 BADPREFIX("sv_waypointsprite_");
 257                 BADCVAR("rescan_pending");
 258
 259                 // these can contain player IDs, so better hide
 260                 BADPREFIX("g_forced_team_");
 261
 262                 // mapinfo
 263                 BADCVAR("fraglimit");
 264                 BADCVAR("g_assault");
 265                 BADCVAR("g_ca");
 266                 BADCVAR("g_ca_teams");
 267                 BADCVAR("g_ctf");
 268                 BADCVAR("g_cts");
 269                 BADCVAR("g_dm");
 270                 BADCVAR("g_domination");
 271                 BADCVAR("g_domination_default_teams");
 272                 BADCVAR("g_freezetag");
 273                 BADCVAR("g_freezetag_teams");
 274                 BADCVAR("g_keepaway");
 275                 BADCVAR("g_keyhunt");
 276                 BADCVAR("g_keyhunt_teams");
 277                 BADCVAR("g_lms");
 278                 BADCVAR("g_nexball");
 279                 BADCVAR("g_onslaught");
 280                 BADCVAR("g_race");
 281                 BADCVAR("g_race_qualifying_timelimit");
 282                 BADCVAR("g_tdm");
 283                 BADCVAR("g_tdm_teams");
 284                 BADCVAR("leadlimit");
 285                 BADCVAR("nextmap");
 286                 BADCVAR("teamplay");
 287                 BADCVAR("timelimit");
 288
 289                 // long
 290                 BADCVAR("hostname");
 291                 BADCVAR("g_maplist");
 292                 BADCVAR("g_maplist_mostrecent");
 293                 BADCVAR("sv_motd");
 294
 295                 v = cvar_string(k);
 296                 d = cvar_defstring(k);
 297                 if(v == d)
 298                         continue;
 299
 300                 if(adding)
 301                 {
 302                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 303                         if(strlen(cvar_changes) > 16384)
 304                         {
 305                                 cvar_changes = "// too many settings have been changed to show them here\n";
 306                                 adding = 0;
 307                         }
 308                 }
 309
 310                 // now check if the changes are actually gameplay relevant
 311
 312                 // does nothing visible
 313                 BADCVAR("captureleadlimit_override");
 314                 BADCVAR("g_balance_kill_delay");
 315                 BADCVAR("g_ca_point_leadlimit");
 316                 BADCVAR("g_ctf_captimerecord_always");
 317                 BADCVAR("g_ctf_flag_glowtrails");
 318                 BADCVAR("g_ctf_flag_pickup_verbosename");
 319                 BADCVAR("g_domination_point_leadlimit");
 320                 BADCVAR("g_forced_respawn");
 321                 BADCVAR("g_keyhunt_point_leadlimit");
 322                 BADPREFIX("g_mod_");
 323                 BADCVAR("g_nexball_goalleadlimit");
 324                 BADCVAR("leadlimit_and_fraglimit");
 325                 BADCVAR("leadlimit_override");
 326                 BADCVAR("pausable");
 327                 BADCVAR("sv_allow_fullbright");
 328                 BADCVAR("sv_checkforpacketsduringsleep");
 329                 BADCVAR("sv_fraginfo");
 330                 BADCVAR("sv_timeout");
 331                 BADPREFIX("sv_timeout_");
 332                 BADPREFIX("crypto_");
 333                 BADPREFIX("g_chat_");
 334                 BADPREFIX("g_ctf_captimerecord_");
 335                 BADPREFIX("g_maplist_votable_");
 336                 BADPREFIX("net_");
 337                 BADPREFIX("prvm_");
 338                 BADPREFIX("skill_");
 339                 BADPREFIX("sv_cullentities_");
 340                 BADPREFIX("sv_fraginfo_");
 341                 BADPREFIX("sv_maxidle_");
 342                 BADPREFIX("sv_vote_");
 343                 BADPREFIX("timelimit_");
 344                 BADCVAR("gameversion");
 345                 BADPREFIX("gameversion_");
 346                 BADCVAR("sv_namechangetimer");
 347
 348                 // allowed changes to server admins (please sync this to server.cfg)
 349                 // vi commands:
 350                 //   :/"impure"/,$d
 351                 //   :g!,^\/\/[^ /],d
 352                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 353                 //   :%!sort
 354                 // yes, this does contain some redundant stuff, don't really care
 355                 BADCVAR("bot_config_file");
 356                 BADCVAR("bot_number");
 357                 BADCVAR("bot_prefix");
 358                 BADCVAR("bot_suffix");
 359                 BADCVAR("capturelimit_override");
 360                 BADCVAR("fraglimit_override");
 361                 BADCVAR("gametype");
 362                 BADCVAR("g_antilag");
 363                 BADCVAR("g_balance_teams");
 364                 BADCVAR("g_balance_teams_prevent_imbalance");
 365                 BADCVAR("g_balance_teams_scorefactor");
 366                 BADCVAR("g_ban_sync_trusted_servers");
 367                 BADCVAR("g_ban_sync_uri");
 368                 BADCVAR("g_ca_teams_override");
 369                 BADCVAR("g_ctf_ignore_frags");
 370                 BADCVAR("g_domination_point_limit");
 371                 BADCVAR("g_freezetag_teams_override");
 372                 BADCVAR("g_friendlyfire");
 373                 BADCVAR("g_fullbrightitems");
 374                 BADCVAR("g_fullbrightplayers");
 375                 BADCVAR("g_keyhunt_point_limit");
 376                 BADCVAR("g_keyhunt_teams_override");
 377                 BADCVAR("g_lms_lives_override");
 378                 BADCVAR("g_maplist");
 379                 BADCVAR("g_maplist_check_waypoints");
 380                 BADCVAR("g_maplist_mostrecent_count");
 381                 BADCVAR("g_maplist_shuffle");
 382                 BADCVAR("g_maplist_votable");
 383                 BADCVAR("g_maplist_votable_abstain");
 384                 BADCVAR("g_maplist_votable_nodetail");
 385                 BADCVAR("g_maplist_votable_suggestions");
 386                 BADCVAR("g_maxplayers");
 387                 BADCVAR("g_mirrordamage");
 388                 BADCVAR("g_nexball_goallimit");
 389                 BADCVAR("g_powerups");
 390                 BADCVAR("g_start_delay");
 391                 BADCVAR("g_warmup");
 392                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 393                 BADCVAR("hostname");
 394                 BADCVAR("log_file");
 395                 BADCVAR("maxplayers");
 396                 BADCVAR("minplayers");
 397                 BADCVAR("net_address");
 398                 BADCVAR("port");
 399                 BADCVAR("rcon_password");
 400                 BADCVAR("rcon_restricted_commands");
 401                 BADCVAR("rcon_restricted_password");
 402                 BADCVAR("skill");
 403                 BADCVAR("sv_adminnick");
 404                 BADCVAR("sv_autoscreenshot");
 405                 BADCVAR("sv_autotaunt");
 406                 BADCVAR("sv_curl_defaulturl");
 407                 BADCVAR("sv_defaultcharacter");
 408                 BADCVAR("sv_defaultplayercolors");
 409                 BADCVAR("sv_defaultplayermodel");
 410                 BADCVAR("sv_defaultplayerskin");
 411                 BADCVAR("sv_maxidle");
 412                 BADCVAR("sv_maxrate");
 413                 BADCVAR("sv_motd");
 414                 BADCVAR("sv_public");
 415                 BADCVAR("sv_ready_restart");
 416                 BADCVAR("sv_status_privacy");
 417                 BADCVAR("sv_taunt");
 418                 BADCVAR("sv_vote_call");
 419                 BADCVAR("sv_vote_commands");
 420                 BADCVAR("sv_vote_majority_factor");
 421                 BADCVAR("sv_vote_master");
 422                 BADCVAR("sv_vote_master_commands");
 423                 BADCVAR("sv_vote_master_password");
 424                 BADCVAR("sv_vote_simple_majority_factor");
 425                 BADCVAR("teamplay_mode");
 426                 BADCVAR("timelimit_override");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADPREFIX("g_warmup_");
 429                 BADPREFIX("sv_ready_restart_");
 430
 431                 // mutators that announce themselves properly to the server browser
 432                 BADCVAR("g_instagib");
 433                 BADCVAR("g_new_toys");
 434                 BADCVAR("g_nix");
 435                 BADCVAR("g_grappling_hook");
 436                 BADCVAR("g_jetpack");
 437
 438 #undef BADPREFIX
 439 #undef BADCVAR
 440
 441                 if(pureadding)
 442                 {
 443                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 444                         if(strlen(cvar_purechanges) > 16384)
 445                         {
 446                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 447                                 pureadding = 0;
 448                         }
 449                 }
 450                 ++cvar_purechanges_count;
 451                 // WARNING: this variable is used for the server list
 452                 // NEVER dare to skip this code!
 453                 // Hacks to intentionally appearing as "pure server" even though you DO have
 454                 // modified settings may be punished by removal from the server list.
 455                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 456                 // though.
 457         }
 458         buf_del(h);
 459         if(cvar_changes == "")
 460                 cvar_changes = "// this server runs at default server settings\n";
 461         else
 462                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 463         cvar_changes = strzone(cvar_changes);
 464         if(cvar_purechanges == "")
 465                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 466         else
 467                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 468         cvar_purechanges = strzone(cvar_purechanges);
 469 }
 470
 471 void detect_maptype()
 472 {
 473 #if 0
 474         vector o, v;
 475         float i;
 476
 477         for(0;;)
 478         {
 479                 o = world.mins;
 480                 o.x += random() * (world.maxs.x - world.mins.x);
 481                 o.y += random() * (world.maxs.y - world.mins.y);
 482                 o.z += random() * (world.maxs.z - world.mins.z);
 483
 484                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 485                 if(trace_fraction == 1)
 486                         continue;
 487
 488                 v = trace_endpos;
 489
 490                 for(i = 0; i < 64; i += 4)
 491                 {
 492                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 493         if(trace_fraction == 1)
 494                 continue;
 495                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 496                 }
 497
 498                 break;
 499         }
 500 #endif
 501 }
 502
 503 entity randomseed;
 504 float RandomSeed_Send(entity to, float sf)
 505 {
 506         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 507         WriteShort(MSG_ENTITY, self.cnt);
 508         return true;
 509 }
 510 void RandomSeed_Think()
 511 {
 512         self.cnt = bound(0, floor(random() * 65536), 65535);
 513         self.nextthink = time + 5;
 514
 515         self.SendFlags |= 1;
 516 }
 517 void RandomSeed_Spawn()
 518 {
 519         randomseed = spawn();
 520         randomseed.think = RandomSeed_Think;
 521         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 522
 523         entity oldself;
 524         oldself = self;
 525         self = randomseed;
 526         self.think(); // sets random seed and nextthink
 527         self = oldself;
 528 }
 529
 530 void spawnfunc___init_dedicated_server(void)
 531 {
 532         // handler for _init/_init map (only for dedicated server initialization)
 533
 534         world_initialized = -1; // don't complain
 535         cvar = cvar_normal;
 536         cvar_string = cvar_string_normal;
 537         cvar_set = cvar_set_normal;
 538
 539         remove = remove_unsafely;
 540
 541         entity e;
 542         e = spawn();
 543         e.think = GotoFirstMap;
 544         e.nextthink = time; // this is usually 1 at this point
 545
 546         e = spawn();
 547         e.classname = "info_player_deathmatch"; // safeguard against player joining
 548
 549         self.classname = "worldspawn"; // safeguard against various stuff ;)
 550
 551         // needs to be done so early because of the constants they create
 552         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 553         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 554         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 555         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 556         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 557         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 558
 559         MapInfo_Enumerate();
 560         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 561 }
 562
 563 void Map_MarkAsRecent(string m);
 564 float world_already_spawned;
 565 void Nagger_Init();
 566 void ClientInit_Spawn();
 567 void WeaponStats_Init();
 568 void WeaponStats_Shutdown();
 569 void spawnfunc_worldspawn (void)
 570 {
 571         float fd, l, i, j, n;
 572         string s;
 573
 574         cvar = cvar_normal;
 575         cvar_string = cvar_string_normal;
 576         cvar_set = cvar_set_normal;
 577
 578         if(world_already_spawned)
 579                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 580         world_already_spawned = true;
 581
 582         remove = remove_safely; // during spawning, watch what you remove!
 583
 584         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 585
 586         compressShortVector_init();
 587
 588         entity head;
 589         head = nextent(world);
 590         maxclients = 0;
 591         while(head)
 592         {
 593                 ++maxclients;
 594                 head = nextent(head);
 595         }
 596
 597         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 598
 599         // needs to be done so early because of the constants they create
 600         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 601         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 602         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 603         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 604         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 605         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 606
 607         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 608
 609         TemporaryDB = db_create();
 610
 611         // 0 normal
 612         lightstyle(0, "m");
 613
 614         // 1 FLICKER (first variety)
 615         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 616
 617         // 2 SLOW STRONG PULSE
 618         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 619
 620         // 3 CANDLE (first variety)
 621         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 622
 623         // 4 FAST STROBE
 624         lightstyle(4, "mamamamamama");
 625
 626         // 5 GENTLE PULSE 1
 627         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 628
 629         // 6 FLICKER (second variety)
 630         lightstyle(6, "nmonqnmomnmomomno");
 631
 632         // 7 CANDLE (second variety)
 633         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 634
 635         // 8 CANDLE (third variety)
 636         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 637
 638         // 9 SLOW STROBE (fourth variety)
 639         lightstyle(9, "aaaaaaaazzzzzzzz");
 640
 641         // 10 FLUORESCENT FLICKER
 642         lightstyle(10, "mmamammmmammamamaaamammma");
 643
 644         // 11 SLOW PULSE NOT FADE TO BLACK
 645         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 646
 647         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 648
 649         // 63 testing
 650         lightstyle(63, "a");
 651
 652         if(autocvar_g_campaign)
 653                 CampaignPreInit();
 654
 655         Map_MarkAsRecent(mapname);
 656
 657         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 658
 659         precache_model ("null"); // we need this one before InitGameplayMode
 660         InitGameplayMode();
 661         readlevelcvars();
 662         GrappleHookInit();
 663
 664         player_count = 0;
 665         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 666         if(bot_waypoints_for_items == 1)
 667                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 668                         bot_waypoints_for_items = 0;
 669
 670         precache();
 671
 672         WaypointSprite_Init();
 673
 674         GameLogInit(); // prepare everything
 675         // NOTE for matchid:
 676         // changing the logic generating it is okay. But:
 677         // it HAS to stay <= 64 chars
 678         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 679         if(autocvar_sv_eventlog)
 680         {
 681                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 682                 matchid = strzone(s);
 683
 684                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 685                 s = ":gameinfo:mutators:LIST";
 686
 687                 ret_string = s;
 688                 MUTATOR_CALLHOOK(BuildMutatorsString);
 689                 s = ret_string;
 690
 691                 // simple, probably not good in the mutator system
 692                 if(autocvar_g_grappling_hook)
 693                         s = strcat(s, ":grappling_hook");
 694
 695                 // initialiation stuff, not good in the mutator system
 696                 if(!autocvar_g_use_ammunition)
 697                         s = strcat(s, ":no_use_ammunition");
 698
 699                 // initialiation stuff, not good in the mutator system
 700                 if(autocvar_g_pickup_items == 0)
 701                         s = strcat(s, ":no_pickup_items");
 702                 if(autocvar_g_pickup_items > 0)
 703                         s = strcat(s, ":pickup_items");
 704
 705                 // initialiation stuff, not good in the mutator system
 706                 if(autocvar_g_weaponarena != "0")
 707                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 708
 709                 // TODO to mutator system
 710                 if(autocvar_g_norecoil)
 711                         s = strcat(s, ":norecoil");
 712
 713                 // TODO to mutator system
 714                 if(autocvar_g_powerups == 0)
 715                         s = strcat(s, ":no_powerups");
 716                 if(autocvar_g_powerups > 0)
 717                         s = strcat(s, ":powerups");
 718
 719                 GameLogEcho(s);
 720                 GameLogEcho(":gameinfo:end");
 721         }
 722         else
 723                 matchid = strzone(ftos(random()));
 724
 725         cvar_set("nextmap", "");
 726
 727         SetDefaultAlpha();
 728
 729         if(autocvar_g_campaign)
 730                 CampaignPostInit();
 731
 732         Ban_LoadBans();
 733
 734         MapInfo_Enumerate();
 735         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 736
 737         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 738         {
 739                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 740                 if(fd != -1)
 741                 {
 742                         while((s = fgets(fd)))
 743                         {
 744                                 l = tokenize_console(s);
 745                                 if(l < 2)
 746                                         continue;
 747                                 if(argv(0) == "cd")
 748                                 {
 749                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 750                                         print("  cdtrack ", argv(2), "\n");
 751                                 }
 752                                 else if(argv(0) == "fog")
 753                                 {
 754                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 755                                         print("  \"fog\" \"", s, "\"\n");
 756                                 }
 757                                 else if(argv(0) == "set")
 758                                 {
 759                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 760                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 761                                 }
 762                                 else if(argv(0) != "//")
 763                                 {
 764                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 765                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 766                                 }
 767                         }
 768                         fclose(fd);
 769                 }
 770         }
 771
 772         WeaponStats_Init();
 773
 774         WepSet_AddStat();
 775         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 776         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 777         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 778         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 779         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 780         Nagger_Init();
 781
 782         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 783         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 784         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 785         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 786         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 787         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 788         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 789         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 790         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 791         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 792         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 793         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 794         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 795         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 796         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 797
 798         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 799         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 800
 801         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 802
 803         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 804
 805         // freeze attacks
 806         addstat(STAT_FROZEN, AS_INT, frozen);
 807         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 808
 809         // g_movementspeed hack
 810         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 811         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 812         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 813         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 814
 815         // secrets
 816         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 817         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 818
 819         // monsters
 820         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 821         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 822
 823         // misc
 824         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 825
 826         next_pingtime = time + 5;
 827
 828         detect_maptype();
 829
 830         // set up information replies for clients and server to use
 831         maplist_reply = strzone(getmaplist());
 832         lsmaps_reply = strzone(getlsmaps());
 833         monsterlist_reply = strzone(getmonsterlist());
 834         for(i = 0; i < 10; ++i)
 835         {
 836                 s = getrecords(i);
 837                 if (s)
 838                         records_reply[i] = strzone(s);
 839         }
 840         ladder_reply = strzone(getladder());
 841         rankings_reply = strzone(getrankings());
 842
 843         // begin other init
 844         ClientInit_Spawn();
 845         RandomSeed_Spawn();
 846         PingPLReport_Spawn();
 847
 848         CheatInit();
 849
 850         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 851
 852         // fill sv_curl_serverpackages from .serverpackage files
 853         if(autocvar_sv_curl_serverpackages_auto)
 854         {
 855                 s = "";
 856                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 857                 for(i = 0; i < n; ++i)
 858                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 859                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 860                                 s = strcat(s, " ", argv(i));
 861                 fd = search_begin("*-serverpackage.txt", true, false);
 862                 if(fd >= 0)
 863                 {
 864                         j = search_getsize(fd);
 865                         for(i = 0; i < j; ++i)
 866                                 s = strcat(s, " ", search_getfilename(fd, i));
 867                         search_end(fd);
 868                 }
 869                 fd = search_begin("*.serverpackage", true, false);
 870                 if(fd >= 0)
 871                 {
 872                         j = search_getsize(fd);
 873                         for(i = 0; i < j; ++i)
 874                                 s = strcat(s, " ", search_getfilename(fd, i));
 875                         search_end(fd);
 876                 }
 877                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 878         }
 879
 880         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 881         modname = "Xonotic";
 882         // physics/balance/config changes that count as mod
 883         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 884                 modname = cvar_string("g_mod_physics");
 885         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 886                 modname = cvar_string("g_mod_balance");
 887         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 888                 modname = cvar_string("g_mod_config");
 889         // extra mutators that deserve to count as mod
 890         MUTATOR_CALLHOOK(SetModname);
 891
 892         // save it for later
 893         modname = strzone(modname);
 894
 895         WinningConditionHelper(); // set worldstatus
 896
 897         world_initialized = 1;
 898 }
 899
 900 void spawnfunc_light (void)
 901 {
 902         //makestatic (self); // Who the f___ did that?
 903         remove(self);
 904 }
 905
 906 string GetGametype()
 907 {
 908         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 909 }
 910
 911 string GetMapname()
 912 {
 913         return mapname;
 914 }
 915
 916 float Map_Count, Map_Current;
 917 string Map_Current_Name;
 918
 919 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 920 float GetMaplistPosition()
 921 {
 922         float pos, idx;
 923         string map;
 924
 925         map = GetMapname();
 926         idx = autocvar_g_maplist_index;
 927
 928         if(idx >= 0)
 929                 if(idx < Map_Count)
 930                         if(map == argv(idx))
 931                                 return idx;
 932
 933         for(pos = 0; pos < Map_Count; ++pos)
 934                 if(map == argv(pos))
 935                         return pos;
 936
 937         // resume normal maplist rotation if current map is not in g_maplist
 938         return idx;
 939 }
 940
 941 float MapHasRightSize(string map)
 942 {
 943         float fh;
 944         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 945         if(autocvar_g_maplist_check_waypoints)
 946         {
 947                 dprint("checkwp "); dprint(map);
 948                 if(!fexists(strcat("maps/", map, ".waypoints")))
 949                 {
 950                         dprint(": no waypoints\n");
 951                         return false;
 952                 }
 953                 dprint(": has waypoints\n");
 954         }
 955
 956         // open map size restriction file
 957         dprint("opensize "); dprint(map);
 958         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 959         if(fh >= 0)
 960         {
 961                 float mapmin, mapmax;
 962                 dprint(": ok, ");
 963                 mapmin = stof(fgets(fh));
 964                 mapmax = stof(fgets(fh));
 965                 fclose(fh);
 966                 if(player_count < mapmin)
 967                 {
 968                         dprint("not enough\n");
 969                         return false;
 970                 }
 971                 if(player_count > mapmax)
 972                 {
 973                         dprint("too many\n");
 974                         return false;
 975                 }
 976                 dprint("right size\n");
 977                 return true;
 978         }
 979         dprint(": not found\n");
 980         return true;
 981 }
 982
 983 string Map_Filename(float position)
 984 {
 985         return strcat("maps/", argv(position), ".bsp");
 986 }
 987
 988 string strwords(string s, float w)
 989 {
 990         float endpos;
 991         for(endpos = 0; w && endpos >= 0; --w)
 992                 endpos = strstrofs(s, " ", endpos + 1);
 993         if(endpos < 0)
 994                 return s;
 995         else
 996                 return substring(s, 0, endpos);
 997 }
 998
 999 float strhasword(string s, string w)
1000 {
1001         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1002 }
1003
1004 void Map_MarkAsRecent(string m)
1005 {
1006         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1007 }
1008
1009 float Map_IsRecent(string m)
1010 {
1011         return strhasword(autocvar_g_maplist_mostrecent, m);
1012 }
1013
1014 float Map_Check(float position, float pass)
1015 {
1016         string filename;
1017         string map_next;
1018         map_next = argv(position);
1019         if(pass <= 1)
1020         {
1021                 if(Map_IsRecent(map_next))
1022                         return 0;
1023         }
1024         filename = Map_Filename(position);
1025         if(MapInfo_CheckMap(map_next))
1026         {
1027                 if(pass == 2)
1028                         return 1;
1029                 if(MapHasRightSize(map_next))
1030                         return 1;
1031                 return 0;
1032         }
1033         else
1034                 dprint( "Couldn't select '", filename, "'..\n" );
1035
1036         return 0;
1037 }
1038
1039 void Map_Goto_SetStr(string nextmapname)
1040 {
1041         if(getmapname_stored != "")
1042                 strunzone(getmapname_stored);
1043         if(nextmapname == "")
1044                 getmapname_stored = "";
1045         else
1046                 getmapname_stored = strzone(nextmapname);
1047 }
1048
1049 void Map_Goto_SetFloat(float position)
1050 {
1051         cvar_set("g_maplist_index", ftos(position));
1052         Map_Goto_SetStr(argv(position));
1053 }
1054
1055 void Map_Goto(float reinit)
1056 {
1057         MapInfo_LoadMap(getmapname_stored, reinit);
1058 }
1059
1060 // return codes of map selectors:
1061 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1062 //   -2 = permanent failure
1063 float() MaplistMethod_Iterate = // usual method
1064 {
1065         float pass, i;
1066
1067         dprint("Trying MaplistMethod_Iterate\n");
1068
1069         for(pass = 1; pass <= 2; ++pass)
1070         {
1071                 for(i = 1; i < Map_Count; ++i)
1072                 {
1073                         float mapindex;
1074                         mapindex = (i + Map_Current) % Map_Count;
1075                         if(Map_Check(mapindex, pass))
1076                                 return mapindex;
1077                 }
1078         }
1079         return -1;
1080 }
1081
1082 float() MaplistMethod_Repeat = // fallback method
1083 {
1084         dprint("Trying MaplistMethod_Repeat\n");
1085
1086         if(Map_Check(Map_Current, 2))
1087                 return Map_Current;
1088         return -2;
1089 }
1090
1091 float() MaplistMethod_Random = // random map selection
1092 {
1093         float i, imax;
1094
1095         dprint("Trying MaplistMethod_Random\n");
1096
1097         imax = 42;
1098
1099         for(i = 0; i <= imax; ++i)
1100         {
1101                 float mapindex;
1102                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1103                 if(Map_Check(mapindex, 1))
1104                         return mapindex;
1105         }
1106         return -1;
1107 }
1108
1109 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1110 // the exponent sets a bias on the map selection:
1111 // the higher the exponent, the less likely "shortly repeated" same maps are
1112 {
1113         float i, j, imax, insertpos;
1114
1115         dprint("Trying MaplistMethod_Shuffle\n");
1116
1117         imax = 42;
1118
1119         for(i = 0; i <= imax; ++i)
1120         {
1121                 string newlist;
1122
1123                 // now reinsert this at another position
1124                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1125                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1126                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1127                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1128
1129                 // insert the current map there
1130                 newlist = "";
1131                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1132                         newlist = strcat(newlist, " ", argv(j));
1133                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1134                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1135                         newlist = strcat(newlist, " ", argv(j));
1136                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1137                 cvar_set("g_maplist", newlist);
1138                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1139
1140                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1141                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1142                 if(Map_Check(Map_Current, 1))
1143                         return Map_Current;
1144         }
1145         return -1;
1146 }
1147
1148 void Maplist_Init()
1149 {
1150         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1151         float i;
1152         for (i = 0; i < Map_Count; ++i)
1153                 if (Map_Check(i, 2))
1154                         break;
1155         if (i == Map_Count)
1156         {
1157                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1158                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1159                 if(autocvar_g_maplist_shuffle)
1160                         ShuffleMaplist();
1161                 localcmd("\nmenu_cmd sync\n");
1162                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1163         }
1164         if(Map_Count == 0)
1165                 error("empty maplist, cannot select a new map");
1166         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1167
1168         if(Map_Current_Name)
1169                 strunzone(Map_Current_Name);
1170         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1171         // this may or may not be correct, but who cares, in the worst case a map
1172         // isn't chosen in the first pass that should have been
1173 }
1174
1175 string GetNextMap()
1176 {
1177         float nextMap;
1178
1179         Maplist_Init();
1180         nextMap = -1;
1181
1182         if(nextMap == -1)
1183                 if(autocvar_g_maplist_shuffle > 0)
1184                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1185
1186         if(nextMap == -1)
1187                 if(autocvar_g_maplist_selectrandom)
1188                         nextMap = MaplistMethod_Random();
1189
1190         if(nextMap == -1)
1191                 nextMap = MaplistMethod_Iterate();
1192
1193         if(nextMap == -1)
1194                 nextMap = MaplistMethod_Repeat();
1195
1196         if(nextMap >= 0)
1197         {
1198                 Map_Goto_SetFloat(nextMap);
1199                 return getmapname_stored;
1200         }
1201
1202         return "";
1203 }
1204
1205 float DoNextMapOverride(float reinit)
1206 {
1207         if(autocvar_g_campaign)
1208         {
1209                 CampaignPostIntermission();
1210                 alreadychangedlevel = true;
1211                 return true;
1212         }
1213         if(autocvar_quit_when_empty)
1214         {
1215                 if(player_count <= currentbots)
1216                 {
1217                         localcmd("quit\n");
1218                         alreadychangedlevel = true;
1219                         return true;
1220                 }
1221         }
1222         if(autocvar_quit_and_redirect != "")
1223         {
1224                 redirection_target = strzone(autocvar_quit_and_redirect);
1225                 alreadychangedlevel = true;
1226                 return true;
1227         }
1228         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1229         {
1230                 localcmd("restart\n");
1231                 alreadychangedlevel = true;
1232                 return true;
1233         }
1234         if(autocvar_nextmap != "")
1235         {
1236                 string m;
1237                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1238                 cvar_set("nextmap",m);
1239
1240                 if(!m || gametypevote)
1241                         return false;
1242                 if(autocvar_sv_vote_gametype)
1243                 {
1244                         Map_Goto_SetStr(m);
1245                         return false;
1246                 }
1247
1248                 if(MapInfo_CheckMap(m))
1249                 {
1250                         Map_Goto_SetStr(m);
1251                         Map_Goto(reinit);
1252                         alreadychangedlevel = true;
1253                         return true;
1254                 }
1255         }
1256         if(!reinit && autocvar_lastlevel)
1257         {
1258                 cvar_settemp_restore();
1259                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1260                 alreadychangedlevel = true;
1261                 return true;
1262         }
1263         return false;
1264 }
1265
1266 void GotoNextMap(float reinit)
1267 {
1268         //string nextmap;
1269         //float n, nummaps;
1270         //string s;
1271         if (alreadychangedlevel)
1272                 return;
1273         alreadychangedlevel = true;
1274
1275         string nextMap;
1276
1277         nextMap = GetNextMap();
1278         if(nextMap == "")
1279                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1280         Map_Goto(reinit);
1281 }
1282
1283
1284 /*
1285 ============
1286 IntermissionThink
1287
1288 When the player presses attack or jump, change to the next level
1289 ============
1290 */
1291 .float autoscreenshot;
1292 void IntermissionThink()
1293 {
1294         FixIntermissionClient(self);
1295
1296         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1297         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1298
1299         if( (server_screenshot || client_screenshot)
1300                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1301         {
1302                 self.autoscreenshot = -1;
1303                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1304                 return;
1305         }
1306
1307         if (time < intermission_exittime)
1308                 return;
1309
1310         if(!mapvote_initialized)
1311                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1312                         return;
1313
1314         MapVote_Start();
1315 }
1316
1317 /*
1318 ============
1319 FindIntermission
1320
1321 Returns the entity to view from
1322 ============
1323 */
1324 /*
1325 entity FindIntermission()
1326 {
1327         local   entity spot;
1328         local   float cyc;
1329
1330 // look for info_intermission first
1331         spot = find (world, classname, "info_intermission");
1332         if (spot)
1333         {       // pick a random one
1334                 cyc = random() * 4;
1335                 while (cyc > 1)
1336                 {
1337                         spot = find (spot, classname, "info_intermission");
1338                         if (!spot)
1339                                 spot = find (spot, classname, "info_intermission");
1340                         cyc = cyc - 1;
1341                 }
1342                 return spot;
1343         }
1344
1345 // then look for the start position
1346         spot = find (world, classname, "info_player_start");
1347         if (spot)
1348                 return spot;
1349
1350 // testinfo_player_start is only found in regioned levels
1351         spot = find (world, classname, "testplayerstart");
1352         if (spot)
1353                 return spot;
1354
1355 // then look for the start position
1356         spot = find (world, classname, "info_player_deathmatch");
1357         if (spot)
1358                 return spot;
1359
1360         //objerror ("FindIntermission: no spot");
1361         return world;
1362 }
1363 */
1364
1365 /*
1366 ===============================================================================
1367
1368 RULES
1369
1370 ===============================================================================
1371 */
1372
1373 void DumpStats(float final)
1374 {
1375         float file;
1376         string s;
1377         float to_console;
1378         float to_eventlog;
1379         float to_file;
1380         float i;
1381
1382         to_console = autocvar_sv_logscores_console;
1383         to_eventlog = autocvar_sv_eventlog;
1384         to_file = autocvar_sv_logscores_file;
1385
1386         if(!final)
1387         {
1388                 to_console = true; // always print printstats replies
1389                 to_eventlog = false; // but never print them to the event log
1390         }
1391
1392         if(to_eventlog)
1393                 if(autocvar_sv_eventlog_console)
1394                         to_console = false; // otherwise we get the output twice
1395
1396         if(final)
1397                 s = ":scores:";
1398         else
1399                 s = ":status:";
1400         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1401
1402         if(to_console)
1403                 print(s, "\n");
1404         if(to_eventlog)
1405                 GameLogEcho(s);
1406
1407         file = -1;
1408         if(to_file)
1409         {
1410                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1411                 if(file == -1)
1412                         to_file = false;
1413                 else
1414                         fputs(file, strcat(s, "\n"));
1415         }
1416
1417         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1418         if(to_console)
1419                 print(s, "\n");
1420         if(to_eventlog)
1421                 GameLogEcho(s);
1422         if(to_file)
1423                 fputs(file, strcat(s, "\n"));
1424
1425         FOR_EACH_CLIENT(other)
1426         {
1427                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1428                 {
1429                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1430                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1431                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1432                                 s = strcat(s, ftos(other.team), ":");
1433                         else
1434                                 s = strcat(s, "spectator:");
1435
1436                         if(to_console)
1437                                 print(s, other.netname, "\n");
1438                         if(to_eventlog)
1439                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1440                         if(to_file)
1441                                 fputs(file, strcat(s, other.netname, "\n"));
1442                 }
1443         }
1444
1445         if(teamplay)
1446         {
1447                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1448                 if(to_console)
1449                         print(s, "\n");
1450                 if(to_eventlog)
1451                         GameLogEcho(s);
1452                 if(to_file)
1453                         fputs(file, strcat(s, "\n"));
1454
1455                 for(i = 1; i < 16; ++i)
1456                 {
1457                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1458                         s = strcat(s, ":", ftos(i));
1459                         if(to_console)
1460                                 print(s, "\n");
1461                         if(to_eventlog)
1462                                 GameLogEcho(s);
1463                         if(to_file)
1464                                 fputs(file, strcat(s, "\n"));
1465                 }
1466         }
1467
1468         if(to_console)
1469                 print(":end\n");
1470         if(to_eventlog)
1471                 GameLogEcho(":end");
1472         if(to_file)
1473         {
1474                 fputs(file, ":end\n");
1475                 fclose(file);
1476         }
1477 }
1478
1479 void FixIntermissionClient(entity e)
1480 {
1481         string s;
1482         if(!e.autoscreenshot) // initial call
1483         {
1484                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1485                 e.health = -2342;
1486                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1487                 e.solid = SOLID_NOT;
1488                 e.movetype = MOVETYPE_NONE;
1489                 e.takedamage = DAMAGE_NO;
1490                 if(e.weaponentity)
1491                 {
1492                         e.weaponentity.effects = EF_NODRAW;
1493                         if (e.weaponentity.weaponentity)
1494                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1495                 }
1496                 if(IS_REAL_CLIENT(e))
1497                 {
1498                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1499                         s = autocvar_sv_intermission_cdtrack;
1500                         if(s != "")
1501                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1502                         msg_entity = e;
1503                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1504                 }
1505         }
1506 }
1507
1508 /*
1509 go to the next level for deathmatch
1510 only called if a time or frag limit has expired
1511 */
1512 void NextLevel()
1513 {
1514         gameover = true;
1515
1516         intermission_running = 1;
1517
1518 // enforce a wait time before allowing changelevel
1519         if(player_count > 0)
1520                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1521         else
1522                 intermission_exittime = -1;
1523
1524         /*
1525         WriteByte (MSG_ALL, SVC_CDTRACK);
1526         WriteByte (MSG_ALL, 3);
1527         WriteByte (MSG_ALL, 3);
1528         // done in FixIntermission
1529         */
1530
1531         //pos = FindIntermission ();
1532
1533         VoteReset();
1534
1535         DumpStats(true);
1536
1537         // send statistics
1538         PlayerStats_GameReport(true);
1539         WeaponStats_Shutdown();
1540
1541         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1542
1543         if(autocvar_sv_eventlog)
1544                 GameLogEcho(":gameover");
1545
1546         GameLogClose();
1547
1548         FOR_EACH_PLAYER(other) {
1549                 FixIntermissionClient(other);
1550                 if(other.winning)
1551                         bprint(other.netname, " ^7wins.\n");
1552         }
1553
1554         if(autocvar_g_campaign)
1555                 CampaignPreIntermission();
1556
1557         MUTATOR_CALLHOOK(MatchEnd);
1558
1559         localcmd("\nsv_hook_gameend\n");
1560 }
1561
1562 /*
1563 ============
1564 CheckRules_Player
1565
1566 Exit deathmatch games upon conditions
1567 ============
1568 */
1569 void CheckRules_Player()
1570 {
1571         if (gameover)   // someone else quit the game already
1572                 return;
1573
1574         if(self.deadflag == DEAD_NO)
1575                 self.play_time += frametime;
1576
1577         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1578         //   (div0: and that in CheckRules_World please)
1579 }
1580
1581 float checkrules_equality;
1582 float checkrules_suddendeathwarning;
1583 float checkrules_suddendeathend;
1584 float checkrules_overtimesadded; //how many overtimes have been already added
1585
1586 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1587 const float WINNING_YES = 1; // winner found
1588 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1589 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1590
1591 float InitiateSuddenDeath()
1592 {
1593         // Check first whether normal overtimes could be added before initiating suddendeath mode
1594         // - for this timelimit_overtime needs to be >0 of course
1595         // - also check the winning condition calculated in the previous frame and only add normal overtime
1596         //   again, if at the point at which timelimit would be extended again, still no winner was found
1597         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1598         {
1599                 return 1; // need to call InitiateOvertime later
1600         }
1601         else
1602         {
1603                 if(!checkrules_suddendeathend)
1604                 {
1605                         if(autocvar_g_campaign)
1606                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1607                         else
1608                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1609                         if(g_race && !g_race_qualifying)
1610                                 race_StartCompleting();
1611                 }
1612                 return 0;
1613         }
1614 }
1615
1616 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1617 {
1618         ++checkrules_overtimesadded;
1619         //add one more overtime by simply extending the timelimit
1620         float tl;
1621         tl = autocvar_timelimit;
1622         tl += autocvar_timelimit_overtime;
1623         cvar_set("timelimit", ftos(tl));
1624
1625         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1626 }
1627
1628 float GetWinningCode(float fraglimitreached, float equality)
1629 {
1630         if(autocvar_g_campaign == 1)
1631                 if(fraglimitreached)
1632                         return WINNING_YES;
1633                 else
1634                         return WINNING_NO;
1635
1636         else
1637                 if(equality)
1638                         if(fraglimitreached)
1639                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1640                         else
1641                                 return WINNING_NEVER;
1642                 else
1643                         if(fraglimitreached)
1644                                 return WINNING_YES;
1645                         else
1646                                 return WINNING_NO;
1647 }
1648
1649 // set the .winning flag for exactly those players with a given field value
1650 void SetWinners(.float field, float value)
1651 {
1652         entity head;
1653         FOR_EACH_PLAYER(head)
1654                 head.winning = (head.field == value);
1655 }
1656
1657 // set the .winning flag for those players with a given field value
1658 void AddWinners(.float field, float value)
1659 {
1660         entity head;
1661         FOR_EACH_PLAYER(head)
1662                 if(head.field == value)
1663                         head.winning = 1;
1664 }
1665
1666 // clear the .winning flags
1667 void ClearWinners(void)
1668 {
1669         entity head;
1670         FOR_EACH_PLAYER(head)
1671                 head.winning = 0;
1672 }
1673
1674 // Onslaught winning condition:
1675 // game terminates if only one team has a working generator (or none)
1676 float WinningCondition_Onslaught()
1677 {
1678         entity head;
1679         float t1, t2, t3, t4;
1680
1681         WinningConditionHelper(); // set worldstatus
1682
1683         if(warmup_stage)
1684                 return WINNING_NO;
1685
1686         // first check if the game has ended
1687         t1 = t2 = t3 = t4 = 0;
1688         head = find(world, classname, "onslaught_generator");
1689         while (head)
1690         {
1691                 if (head.health > 0)
1692                 {
1693                         if (head.team == NUM_TEAM_1) t1 = 1;
1694                         if (head.team == NUM_TEAM_2) t2 = 1;
1695                         if (head.team == NUM_TEAM_3) t3 = 1;
1696                         if (head.team == NUM_TEAM_4) t4 = 1;
1697                 }
1698                 head = find(head, classname, "onslaught_generator");
1699         }
1700         if (t1 + t2 + t3 + t4 < 2)
1701         {
1702                 // game over, only one team remains (or none)
1703                 ClearWinners();
1704                 if (t1) SetWinners(team, NUM_TEAM_1);
1705                 if (t2) SetWinners(team, NUM_TEAM_2);
1706                 if (t3) SetWinners(team, NUM_TEAM_3);
1707                 if (t4) SetWinners(team, NUM_TEAM_4);
1708                 dprint("Have a winner, ending game.\n");
1709                 return WINNING_YES;
1710         }
1711
1712         // Two or more teams remain
1713         return WINNING_NO;
1714 }
1715
1716 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1717 // they win. Otherwise the defending team wins once the timelimit passes.
1718 void assault_new_round();
1719 float WinningCondition_Assault()
1720 {
1721         float status;
1722
1723         WinningConditionHelper(); // set worldstatus
1724
1725         status = WINNING_NO;
1726         // as the timelimit has not yet passed just assume the defending team will win
1727         if(assault_attacker_team == NUM_TEAM_1)
1728         {
1729                 SetWinners(team, NUM_TEAM_2);
1730         }
1731         else
1732         {
1733                 SetWinners(team, NUM_TEAM_1);
1734         }
1735
1736         entity ent;
1737         ent = find(world, classname, "target_assault_roundend");
1738         if(ent)
1739         {
1740                 if(ent.winning) // round end has been triggered by attacking team
1741                 {
1742                         bprint("ASSAULT: round completed...\n");
1743                         SetWinners(team, assault_attacker_team);
1744
1745                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1746
1747                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1748                         {
1749                                 status = WINNING_YES;
1750                         }
1751                         else
1752                         {
1753                                 entity oldself;
1754                                 oldself = self;
1755                                 self = ent;
1756                                 assault_new_round();
1757                                 self = oldself;
1758                         }
1759                 }
1760         }
1761
1762         return status;
1763 }
1764
1765 // LMS winning condition: game terminates if and only if there's at most one
1766 // one player who's living lives. Top two scores being equal cancels the time
1767 // limit.
1768 float WinningCondition_LMS()
1769 {
1770         entity head, head2;
1771         float have_player;
1772         float have_players;
1773         float l;
1774
1775         have_player = false;
1776         have_players = false;
1777         l = LMS_NewPlayerLives();
1778
1779         head = find(world, classname, "player");
1780         if(head)
1781                 have_player = true;
1782         head2 = find(head, classname, "player");
1783         if(head2)
1784                 have_players = true;
1785
1786         if(have_player)
1787         {
1788                 // we have at least one player
1789                 if(have_players)
1790                 {
1791                         // two or more active players - continue with the game
1792                 }
1793                 else
1794                 {
1795                         // exactly one player?
1796
1797                         ClearWinners();
1798                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1799
1800                         if(l)
1801                         {
1802                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1803                                 return WINNING_NO;
1804                         }
1805                         else
1806                         {
1807                                 // a winner!
1808                                 // and assign him his first place
1809                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1810                                 return WINNING_YES;
1811                         }
1812                 }
1813         }
1814         else
1815         {
1816                 // nobody is playing at all...
1817                 if(l)
1818                 {
1819                         // wait for players...
1820                 }
1821                 else
1822                 {
1823                         // SNAFU (maybe a draw game?)
1824                         ClearWinners();
1825                         dprint("No players, ending game.\n");
1826                         return WINNING_YES;
1827                 }
1828         }
1829
1830         // When we get here, we have at least two players who are actually LIVING,
1831         // now check if the top two players have equal score.
1832         WinningConditionHelper();
1833
1834         ClearWinners();
1835         if(WinningConditionHelper_winner)
1836                 WinningConditionHelper_winner.winning = true;
1837         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1838                 return WINNING_NEVER;
1839
1840         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1841         return WINNING_NO;
1842 }
1843
1844 void ShuffleMaplist()
1845 {
1846         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1847 }
1848
1849 float leaderfrags;
1850 float WinningCondition_Scores(float limit, float leadlimit)
1851 {
1852         float limitreached;
1853
1854         // TODO make everything use THIS winning condition (except LMS)
1855         WinningConditionHelper();
1856
1857         if(teamplay)
1858         {
1859                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1860                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1861                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1862                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1863         }
1864
1865         ClearWinners();
1866         if(WinningConditionHelper_winner)
1867                 WinningConditionHelper_winner.winning = 1;
1868         if(WinningConditionHelper_winnerteam >= 0)
1869                 SetWinners(team, WinningConditionHelper_winnerteam);
1870
1871         if(WinningConditionHelper_lowerisbetter)
1872         {
1873                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1874                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1875                 limit = -limit;
1876         }
1877
1878         if(WinningConditionHelper_zeroisworst)
1879                 leadlimit = 0; // not supported in this mode
1880
1881         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1882         // these modes always score in increments of 1, thus this makes sense
1883         {
1884                 if(leaderfrags != WinningConditionHelper_topscore)
1885                 {
1886                         leaderfrags = WinningConditionHelper_topscore;
1887
1888                         if (limit)
1889                         if (leaderfrags == limit - 1)
1890                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1891                         else if (leaderfrags == limit - 2)
1892                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1893                         else if (leaderfrags == limit - 3)
1894                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1895                 }
1896         }
1897
1898         limitreached = false;
1899         if(limit)
1900                 if(WinningConditionHelper_topscore >= limit)
1901                         limitreached = true;
1902         if(leadlimit)
1903         {
1904                 float leadlimitreached;
1905                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1906                 if(autocvar_leadlimit_and_fraglimit)
1907                         limitreached = (limitreached && leadlimitreached);
1908                 else
1909                         limitreached = (limitreached || leadlimitreached);
1910         }
1911
1912         if(limit)
1913                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1914
1915         return GetWinningCode(
1916                 WinningConditionHelper_topscore && limitreached,
1917                 WinningConditionHelper_equality
1918         );
1919 }
1920
1921 float WinningCondition_Race(float fraglimit)
1922 {
1923         float wc;
1924         entity p;
1925         float n, c;
1926
1927         n = 0;
1928         c = 0;
1929         FOR_EACH_PLAYER(p)
1930         {
1931                 ++n;
1932                 if(p.race_completed)
1933                         ++c;
1934         }
1935         if(n && (n == c))
1936                 return WINNING_YES;
1937         wc = WinningCondition_Scores(fraglimit, 0);
1938
1939         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1940         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1941         // do NOT support equality when the laps are all raced!
1942                 return WINNING_STARTSUDDENDEATHOVERTIME;
1943         else
1944                 return WINNING_NEVER;
1945 }
1946
1947 float WinningCondition_QualifyingThenRace(float limit)
1948 {
1949         float wc;
1950         wc = WinningCondition_Scores(limit, 0);
1951
1952         // NEVER initiate overtime
1953         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1954         {
1955                 return WINNING_YES;
1956         }
1957
1958         return wc;
1959 }
1960
1961 float WinningCondition_RanOutOfSpawns()
1962 {
1963         entity head;
1964
1965         if(have_team_spawns <= 0)
1966                 return WINNING_NO;
1967
1968         if(autocvar_g_spawn_useallspawns <= 0)
1969                 return WINNING_NO;
1970
1971         if(!some_spawn_has_been_used)
1972                 return WINNING_NO;
1973
1974         team1_score = team2_score = team3_score = team4_score = 0;
1975
1976         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1977         {
1978                 if(head.team == NUM_TEAM_1)
1979                         team1_score = 1;
1980                 else if(head.team == NUM_TEAM_2)
1981                         team2_score = 1;
1982                 else if(head.team == NUM_TEAM_3)
1983                         team3_score = 1;
1984                 else if(head.team == NUM_TEAM_4)
1985                         team4_score = 1;
1986         }
1987
1988         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1989         {
1990                 if(head.team == NUM_TEAM_1)
1991                         team1_score = 1;
1992                 else if(head.team == NUM_TEAM_2)
1993                         team2_score = 1;
1994                 else if(head.team == NUM_TEAM_3)
1995                         team3_score = 1;
1996                 else if(head.team == NUM_TEAM_4)
1997                         team4_score = 1;
1998         }
1999
2000         ClearWinners();
2001         if(team1_score + team2_score + team3_score + team4_score == 0)
2002         {
2003                 checkrules_equality = true;
2004                 return WINNING_YES;
2005         }
2006         else if(team1_score + team2_score + team3_score + team4_score == 1)
2007         {
2008                 float t, i;
2009                 if(team1_score)
2010                         t = NUM_TEAM_1;
2011                 else if(team2_score)
2012                         t = NUM_TEAM_2;
2013                 else if(team3_score)
2014                         t = NUM_TEAM_3;
2015                 else // if(team4_score)
2016                         t = NUM_TEAM_4;
2017                 CheckAllowedTeams(world);
2018                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2019                 {
2020                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2021                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2022                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2023                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2024                 }
2025
2026                 AddWinners(team, t);
2027                 return WINNING_YES;
2028         }
2029         else
2030                 return WINNING_NO;
2031 }
2032
2033 /*
2034 ============
2035 CheckRules_World
2036
2037 Exit deathmatch games upon conditions
2038 ============
2039 */
2040 void ReadyRestart();
2041 void CheckRules_World()
2042 {
2043         float timelimit;
2044         float fraglimit;
2045         float leadlimit;
2046
2047         VoteThink();
2048         MapVote_Think();
2049
2050         SetDefaultAlpha();
2051
2052         if (gameover)   // someone else quit the game already
2053         {
2054                 if(player_count == 0) // Nobody there? Then let's go to the next map
2055                         MapVote_Start();
2056                         // this will actually check the player count in the next frame
2057                         // again, but this shouldn't hurt
2058                 return;
2059         }
2060
2061         timelimit = autocvar_timelimit * 60;
2062         fraglimit = autocvar_fraglimit;
2063         leadlimit = autocvar_leadlimit;
2064
2065         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2066         {
2067                 if(timelimit > 0)
2068                         timelimit = 0; // timelimit is not made for warmup
2069                 if(fraglimit > 0)
2070                         fraglimit = 0; // no fraglimit for now
2071                 leadlimit = 0; // no leadlimit for now
2072         }
2073
2074         if(timelimit > 0)
2075         {
2076                 timelimit += game_starttime;
2077         }
2078         else if (timelimit < 0)
2079         {
2080                 // endmatch
2081                 NextLevel();
2082                 return;
2083         }
2084
2085         if(g_onslaught)
2086                 timelimit = 0; // ONS has its own overtime rule
2087
2088         float wantovertime;
2089         wantovertime = 0;
2090
2091         if(timelimit > game_starttime)
2092                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2093         else
2094                 game_completion_ratio = 0;
2095
2096         if(checkrules_suddendeathend)
2097         {
2098                 if(!checkrules_suddendeathwarning)
2099                 {
2100                         checkrules_suddendeathwarning = true;
2101                         if(g_race && !g_race_qualifying)
2102                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2103                         else
2104                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2105                 }
2106         }
2107         else
2108         {
2109                 if (timelimit && time >= timelimit)
2110                 {
2111                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2112                         {
2113                                 float totalplayers;
2114                                 float playerswithlaps;
2115                                 float readyplayers;
2116                                 entity head;
2117                                 totalplayers = playerswithlaps = readyplayers = 0;
2118                                 FOR_EACH_PLAYER(head)
2119                                 {
2120                                         ++totalplayers;
2121                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2122                                                 ++playerswithlaps;
2123                                         if(head.ready)
2124                                                 ++readyplayers;
2125                                 }
2126
2127                                 // at least 2 of the players have completed a lap: start the RACE
2128                                 // otherwise, the players should end the qualifying on their own
2129                                 if(readyplayers || playerswithlaps >= 2)
2130                                 {
2131                                         checkrules_suddendeathend = 0;
2132                                         ReadyRestart(); // go to race
2133                                         return;
2134                                 }
2135                                 else
2136                                         wantovertime |= InitiateSuddenDeath();
2137                         }
2138                         else
2139                                 wantovertime |= InitiateSuddenDeath();
2140                 }
2141         }
2142
2143         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2144         {
2145                 NextLevel();
2146                 return;
2147         }
2148
2149         float checkrules_status;
2150         checkrules_status = WinningCondition_RanOutOfSpawns();
2151         if(checkrules_status == WINNING_YES)
2152         {
2153                 bprint("Hey! Someone ran out of spawns!\n");
2154         }
2155         else if(g_race && !g_race_qualifying && timelimit >= 0)
2156         {
2157                 checkrules_status = WinningCondition_Race(fraglimit);
2158                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2159         }
2160         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2161         {
2162                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2163                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2164         }
2165         else if(g_assault)
2166         {
2167                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2168         }
2169         else if(g_lms)
2170         {
2171                 checkrules_status = WinningCondition_LMS();
2172         }
2173         else if (g_onslaught)
2174         {
2175                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2176         }
2177         else
2178         {
2179                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2180                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2181         }
2182
2183         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2184         {
2185                 checkrules_status = WINNING_NEVER;
2186                 checkrules_overtimesadded = -1;
2187                 wantovertime |= InitiateSuddenDeath();
2188         }
2189
2190         if(checkrules_status == WINNING_NEVER)
2191                 // equality cases! Nobody wins if the overtime ends in a draw.
2192                 ClearWinners();
2193
2194         if(wantovertime)
2195         {
2196                 if(checkrules_status == WINNING_NEVER)
2197                         InitiateOvertime();
2198                 else
2199                         checkrules_status = WINNING_YES;
2200         }
2201
2202         if(checkrules_suddendeathend)
2203                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2204                         checkrules_status = WINNING_YES;
2205
2206         if(checkrules_status == WINNING_YES)
2207         {
2208                 //print("WINNING\n");
2209                 NextLevel();
2210         }
2211 }
2212
2213 string GotoMap(string m)
2214 {
2215         m = GameTypeVote_MapInfo_FixName(m);
2216         if (!m)
2217                 return "The map you suggested is not available on this server.";
2218         if (!autocvar_sv_vote_gametype)
2219         if(!MapInfo_CheckMap(m))
2220                 return "The map you suggested does not support the current game mode.";
2221         cvar_set("nextmap", m);
2222         cvar_set("timelimit", "-1");
2223         if(mapvote_initialized || alreadychangedlevel)
2224         {
2225                 if(DoNextMapOverride(0))
2226                         return "Map switch initiated.";
2227                 else
2228                         return "Hm... no. For some reason I like THIS map more.";
2229         }
2230         else
2231                 return "Map switch will happen after scoreboard.";
2232 }
2233
2234
2235 void EndFrame()
2236 {
2237         anticheat_endframe();
2238
2239         float altime;
2240         FOR_EACH_REALCLIENT(self)
2241         {
2242                 entity e = IS_SPEC(self) ? self.enemy : self;
2243                 if(e.typehitsound)
2244                         self.typehit_time = time;
2245                 else if(e.damage_dealt)
2246                 {
2247                         self.hit_time = time;
2248                         self.damage_dealt_total += ceil(e.damage_dealt);
2249                 }
2250         }
2251         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2252         // add 1 frametime because after this, engine SV_Physics
2253         // increases time by a frametime and then networks the frame
2254         // add another frametime because client shows everything with
2255         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2256         // needed!
2257         FOR_EACH_CLIENT(self)
2258         {
2259                 self.typehitsound = false;
2260                 self.damage_dealt = 0;
2261                 antilag_record(self, altime);
2262         }
2263         FOR_EACH_MONSTER(self)
2264                 antilag_record(self, altime);
2265 }
2266
2267
2268 /*
2269  * RedirectionThink:
2270  * returns true if redirecting
2271  */
2272 float redirection_timeout;
2273 float redirection_nextthink;
2274 float RedirectionThink()
2275 {
2276         float clients_found;
2277
2278         if(redirection_target == "")
2279                 return false;
2280
2281         if(!redirection_timeout)
2282         {
2283                 cvar_set("sv_public", "-2");
2284                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2285                 if(redirection_target == "self")
2286                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2287                 else
2288                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2289         }
2290
2291         if(time < redirection_nextthink)
2292                 return true;
2293
2294         redirection_nextthink = time + 1;
2295
2296         clients_found = 0;
2297         FOR_EACH_REALCLIENT(self)
2298         {
2299                 // TODO add timer
2300                 print("Redirecting: sending connect command to ", self.netname, "\n");
2301                 if(redirection_target == "self")
2302                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2303                 else
2304                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2305                 ++clients_found;
2306         }
2307
2308         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2309
2310         if(time > redirection_timeout || clients_found == 0)
2311                 localcmd("\nwait; wait; wait; quit\n");
2312
2313         return true;
2314 }
2315
2316 void TargetMusic_RestoreGame();
2317 void RestoreGame()
2318 {
2319         // Loaded from a save game
2320         // some things then break, so let's work around them...
2321
2322         // Progs DB (capture records)
2323         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2324
2325         // Mapinfo
2326         MapInfo_Shutdown();
2327         MapInfo_Enumerate();
2328         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2329         WeaponStats_Init();
2330
2331         TargetMusic_RestoreGame();
2332 }
2333
2334 void Shutdown()
2335 {
2336         gameover = 2;
2337
2338         if(world_initialized > 0)
2339         {
2340                 world_initialized = 0;
2341                 print("Saving persistent data...\n");
2342                 Ban_SaveBans();
2343
2344                 // playerstats with unfinished match
2345                 PlayerStats_GameReport(false);
2346
2347                 if(!cheatcount_total)
2348                 {
2349                         if(autocvar_sv_db_saveasdump)
2350                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2351                         else
2352                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2353                 }
2354                 if(autocvar_developer)
2355                 {
2356                         if(autocvar_sv_db_saveasdump)
2357                                 db_dump(TemporaryDB, "server-temp.db");
2358                         else
2359                                 db_save(TemporaryDB, "server-temp.db");
2360                 }
2361                 CheatShutdown(); // must be after cheatcount check
2362                 db_close(ServerProgsDB);
2363                 db_close(TemporaryDB);
2364                 print("done!\n");
2365                 // tell the bot system the game is ending now
2366                 bot_endgame();
2367
2368                 WeaponStats_Shutdown();
2369                 MapInfo_Shutdown();
2370         }
2371         else if(world_initialized == 0)
2372         {
2373                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2374         }
2375 }