160be73891f73cac4aefa42b0a1baadbdc8aa3bc
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2
3 #include "anticheat.qh"
4 #include "antilag.qh"
5 #include "bot/bot.qh"
6 #include "campaign.qh"
7 #include "cheats.qh"
8 #include "cl_client.qh"
9 #include "command/common.qh"
10 #include "command/getreplies.qh"
11 #include "command/sv_cmd.qh"
12 #include "command/vote.qh"
13 #include "g_hook.qh"
14 #include "ipban.qh"
15 #include "mapvoting.qh"
16 #include "mutators/all.qh"
17 #include "race.qh"
18 #include "scores.qh"
19 #include "teamplay.qh"
20 #include "weapons/weaponstats.qh"
21 #include "../common/constants.qh"
22 #include "../common/deathtypes/all.qh"
23 #include "../common/mapinfo.qh"
24 #include "../common/monsters/all.qh"
25 #include "../common/monsters/sv_monsters.qh"
26 #include "../common/vehicles/all.qh"
27 #include "../common/notifications.qh"
28 #include "../common/physics/player.qh"
29 #include "../common/playerstats.qh"
30 #include "../common/stats.qh"
31 #include "../common/teams.qh"
32 #include "../common/triggers/trigger/secret.qh"
33 #include "../common/triggers/target/music.qh"
34 #include "../common/util.qh"
35 #include "../common/items/all.qh"
36 #include "../common/weapons/all.qh"
37
38 const float LATENCY_THINKRATE = 10;
39 .float latency_sum;
40 .float latency_cnt;
41 .float latency_time;
42 entity pingplreport;
43 void PingPLReport_Think()
44 {SELFPARAM();
45         float delta;
46         entity e;
47
48         delta = 3 / maxclients;
49         if(delta < sys_frametime)
50                 delta = 0;
51         self.nextthink = time + delta;
52
53         e = edict_num(self.cnt + 1);
54         if(IS_REAL_CLIENT(e))
55         {
56                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
57                 WriteByte(MSG_BROADCAST, self.cnt);
58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
61
62                 // record latency times for clients throughout the match so we can report it to playerstats
63                 if(time > (e.latency_time + LATENCY_THINKRATE))
64                 {
65                         e.latency_sum += e.ping;
66                         e.latency_cnt += 1;
67                         e.latency_time = time;
68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
69                 }
70         }
71         else
72         {
73                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
74                 WriteByte(MSG_BROADCAST, self.cnt);
75                 WriteShort(MSG_BROADCAST, 0);
76                 WriteByte(MSG_BROADCAST, 0);
77                 WriteByte(MSG_BROADCAST, 0);
78         }
79         self.cnt = (self.cnt + 1) % maxclients;
80 }
81 void PingPLReport_Spawn()
82 {
83         pingplreport = new(pingplreport);
84         make_pure(pingplreport);
85         pingplreport.think = PingPLReport_Think;
86         pingplreport.nextthink = time;
87 }
88
89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
90 string redirection_target;
91 float world_initialized;
92
93 string GetGametype();
94 void ShuffleMaplist();
95
96 void SetDefaultAlpha()
97 {
98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
99         {
100                 default_player_alpha = autocvar_g_player_alpha;
101                 if(default_player_alpha == 0)
102                         default_player_alpha = 1;
103                 default_weapon_alpha = default_player_alpha;
104         }
105 }
106
107 void GotoFirstMap()
108 {SELFPARAM();
109         float n;
110         if(autocvar__sv_init)
111         {
112                 // cvar_set("_sv_init", "0");
113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
114                 // to this "init" map on a dedicated server will cause no permanent
115                 // harm
116                 if(autocvar_g_maplist_shuffle)
117                         ShuffleMaplist();
118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
120
121                 MapInfo_Enumerate();
122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
123
124                 if(!DoNextMapOverride(1))
125                         GotoNextMap(1);
126
127                 return;
128         }
129
130         if(time < 5)
131         {
132                 self.nextthink = time;
133         }
134         else
135         {
136                 self.nextthink = time + 1;
137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
138         }
139 }
140
141 void cvar_changes_init()
142 {
143         float h;
144         string k, v, d;
145         float n, i, adding, pureadding;
146
147         if(cvar_changes)
148                 strunzone(cvar_changes);
149         cvar_changes = string_null;
150         if(cvar_purechanges)
151                 strunzone(cvar_purechanges);
152         cvar_purechanges = string_null;
153         cvar_purechanges_count = 0;
154
155         h = buf_create();
156         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
157         n = buf_getsize(h);
158
159         adding = true;
160         pureadding = true;
161
162         for(i = 0; i < n; ++i)
163         {
164                 k = bufstr_get(h, i);
165
166 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
167 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
168 #define BADCVAR(p) if(k == p) continue
169
170                 // general excludes and namespaces for server admin used cvars
171                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
172
173                 // internal
174                 BADPREFIX("csqc_");
175                 BADPREFIX("cvar_check_");
176                 BADCVAR("gamecfg");
177                 BADCVAR("g_configversion");
178                 BADCVAR("g_maplist_index");
179                 BADCVAR("halflifebsp");
180                 BADCVAR("sv_mapformat_is_quake2");
181                 BADCVAR("sv_mapformat_is_quake3");
182                 BADPREFIX("sv_world");
183
184                 // client
185                 BADPREFIX("chase_");
186                 BADPREFIX("cl_");
187                 BADPREFIX("con_");
188                 BADPREFIX("scoreboard_");
189                 BADPREFIX("g_campaign");
190                 BADPREFIX("g_waypointsprite_");
191                 BADPREFIX("gl_");
192                 BADPREFIX("joy");
193                 BADPREFIX("hud_");
194                 BADPREFIX("m_");
195                 BADPREFIX("menu_");
196                 BADPREFIX("net_slist_");
197                 BADPREFIX("r_");
198                 BADPREFIX("sbar_");
199                 BADPREFIX("scr_");
200                 BADPREFIX("snd_");
201                 BADPREFIX("show");
202                 BADPREFIX("sensitivity");
203                 BADPREFIX("userbind");
204                 BADPREFIX("v_");
205                 BADPREFIX("vid_");
206                 BADPREFIX("crosshair");
207                 BADCVAR("mod_q3bsp_lightmapmergepower");
208                 BADCVAR("mod_q3bsp_nolightmaps");
209                 BADCVAR("fov");
210                 BADCVAR("mastervolume");
211                 BADCVAR("volume");
212                 BADCVAR("bgmvolume");
213
214                 // private
215                 BADCVAR("developer");
216                 BADCVAR("log_dest_udp");
217                 BADCVAR("net_address");
218                 BADCVAR("net_address_ipv6");
219                 BADCVAR("port");
220                 BADCVAR("savedgamecfg");
221                 BADCVAR("serverconfig");
222                 BADCVAR("sv_autoscreenshot");
223                 BADCVAR("sv_heartbeatperiod");
224                 BADCVAR("sv_vote_master_password");
225                 BADCVAR("sys_colortranslation");
226                 BADCVAR("sys_specialcharactertranslation");
227                 BADCVAR("timeformat");
228                 BADCVAR("timestamps");
229                 BADPREFIX("developer_");
230                 BADPREFIX("g_ban_");
231                 BADPREFIX("g_banned_list");
232                 BADPREFIX("g_chat_flood_");
233                 BADPREFIX("g_ghost_items");
234                 BADPREFIX("g_playerstats_");
235                 BADPREFIX("g_respawn_ghosts");
236                 BADPREFIX("g_voice_flood_");
237                 BADPREFIX("log_file");
238                 BADPREFIX("rcon_");
239                 BADPREFIX("sv_allowdownloads");
240                 BADPREFIX("sv_autodemo");
241                 BADPREFIX("sv_curl_");
242                 BADPREFIX("sv_eventlog");
243                 BADPREFIX("sv_logscores_");
244                 BADPREFIX("sv_master");
245                 BADPREFIX("sv_weaponstats_");
246                 BADPREFIX("sv_waypointsprite_");
247                 BADCVAR("rescan_pending");
248
249                 // these can contain player IDs, so better hide
250                 BADPREFIX("g_forced_team_");
251
252                 // mapinfo
253                 BADCVAR("fraglimit");
254                 BADCVAR("g_assault");
255                 BADCVAR("g_ca");
256                 BADCVAR("g_ca_teams");
257                 BADCVAR("g_ctf");
258                 BADCVAR("g_cts");
259                 BADCVAR("g_dm");
260                 BADCVAR("g_domination");
261                 BADCVAR("g_domination_default_teams");
262                 BADCVAR("g_freezetag");
263                 BADCVAR("g_freezetag_teams");
264                 BADCVAR("g_invasion_teams");
265                 BADCVAR("g_keepaway");
266                 BADCVAR("g_keyhunt");
267                 BADCVAR("g_keyhunt_teams");
268                 BADCVAR("g_lms");
269                 BADCVAR("g_nexball");
270                 BADCVAR("g_onslaught");
271                 BADCVAR("g_race");
272                 BADCVAR("g_race_qualifying_timelimit");
273                 BADCVAR("g_tdm");
274                 BADCVAR("g_tdm_teams");
275                 BADCVAR("leadlimit");
276                 BADCVAR("nextmap");
277                 BADCVAR("teamplay");
278                 BADCVAR("timelimit");
279
280                 // long
281                 BADCVAR("hostname");
282                 BADCVAR("g_maplist");
283                 BADCVAR("g_maplist_mostrecent");
284                 BADCVAR("sv_motd");
285
286                 v = cvar_string(k);
287                 d = cvar_defstring(k);
288                 if(v == d)
289                         continue;
290
291                 if(adding)
292                 {
293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
294                         if(strlen(cvar_changes) > 16384)
295                         {
296                                 cvar_changes = "// too many settings have been changed to show them here\n";
297                                 adding = 0;
298                         }
299                 }
300
301                 // now check if the changes are actually gameplay relevant
302
303                 // does nothing visible
304                 BADCVAR("captureleadlimit_override");
305                 BADCVAR("g_balance_kill_delay");
306                 BADCVAR("g_ca_point_limit");
307                 BADCVAR("g_ca_point_leadlimit");
308                 BADCVAR("g_ctf_captimerecord_always");
309                 BADCVAR("g_ctf_flag_glowtrails");
310                 BADCVAR("g_ctf_flag_pickup_verbosename");
311                 BADCVAR("g_domination_point_leadlimit");
312                 BADCVAR("g_forced_respawn");
313                 BADCVAR("g_freezetag_point_limit");
314                 BADCVAR("g_freezetag_point_leadlimit");
315                 BADCVAR("g_keyhunt_point_leadlimit");
316                 BADPREFIX("g_mod_");
317                 BADCVAR("g_invasion_point_limit");
318                 BADCVAR("g_nexball_goalleadlimit");
319                 BADCVAR("g_tdm_point_limit");
320                 BADCVAR("g_tdm_point_leadlimit");
321                 BADCVAR("leadlimit_and_fraglimit");
322                 BADCVAR("leadlimit_override");
323                 BADCVAR("pausable");
324                 BADCVAR("sv_allow_fullbright");
325                 BADCVAR("sv_checkforpacketsduringsleep");
326                 BADCVAR("sv_timeout");
327                 BADPREFIX("sv_timeout_");
328                 BADPREFIX("crypto_");
329                 BADPREFIX("g_chat_");
330                 BADPREFIX("g_ctf_captimerecord_");
331                 BADPREFIX("g_maplist_votable_");
332                 BADPREFIX("net_");
333                 BADPREFIX("prvm_");
334                 BADPREFIX("skill_");
335                 BADPREFIX("sv_cullentities_");
336                 BADPREFIX("sv_maxidle_");
337                 BADPREFIX("sv_vote_");
338                 BADPREFIX("timelimit_");
339                 BADCVAR("gameversion");
340                 BADPREFIX("gameversion_");
341                 BADCVAR("sv_minigames");
342                 BADPREFIX("sv_minigames_");
343                 BADCVAR("sv_namechangetimer");
344
345                 // allowed changes to server admins (please sync this to server.cfg)
346                 // vi commands:
347                 //   :/"impure"/,$d
348                 //   :g!,^\/\/[^ /],d
349                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
350                 //   :%!sort
351                 // yes, this does contain some redundant stuff, don't really care
352                 BADCVAR("bot_config_file");
353                 BADCVAR("bot_number");
354                 BADCVAR("bot_prefix");
355                 BADCVAR("bot_suffix");
356                 BADCVAR("capturelimit_override");
357                 BADCVAR("fraglimit_override");
358                 BADCVAR("gametype");
359                 BADCVAR("g_antilag");
360                 BADCVAR("g_balance_teams");
361                 BADCVAR("g_balance_teams_prevent_imbalance");
362                 BADCVAR("g_balance_teams_scorefactor");
363                 BADCVAR("g_ban_sync_trusted_servers");
364                 BADCVAR("g_ban_sync_uri");
365                 BADCVAR("g_ca_teams_override");
366                 BADCVAR("g_ctf_ignore_frags");
367                 BADCVAR("g_domination_point_limit");
368                 BADCVAR("g_domination_teams_override");
369                 BADCVAR("g_freezetag_teams_override");
370                 BADCVAR("g_friendlyfire");
371                 BADCVAR("g_fullbrightitems");
372                 BADCVAR("g_fullbrightplayers");
373                 BADCVAR("g_keyhunt_point_limit");
374                 BADCVAR("g_keyhunt_teams_override");
375                 BADCVAR("g_lms_lives_override");
376                 BADCVAR("g_maplist");
377                 BADCVAR("g_maplist_check_waypoints");
378                 BADCVAR("g_maplist_mostrecent_count");
379                 BADCVAR("g_maplist_shuffle");
380                 BADCVAR("g_maplist_votable");
381                 BADCVAR("g_maplist_votable_abstain");
382                 BADCVAR("g_maplist_votable_nodetail");
383                 BADCVAR("g_maplist_votable_suggestions");
384                 BADCVAR("g_maxplayers");
385                 BADCVAR("g_mirrordamage");
386                 BADCVAR("g_nexball_goallimit");
387                 BADCVAR("g_powerups");
388                 BADCVAR("g_start_delay");
389                 BADCVAR("g_tdm_teams_override");
390                 BADCVAR("g_warmup");
391                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
392                 BADCVAR("hostname");
393                 BADCVAR("log_file");
394                 BADCVAR("maxplayers");
395                 BADCVAR("minplayers");
396                 BADCVAR("net_address");
397                 BADCVAR("port");
398                 BADCVAR("rcon_password");
399                 BADCVAR("rcon_restricted_commands");
400                 BADCVAR("rcon_restricted_password");
401                 BADCVAR("skill");
402                 BADCVAR("sv_adminnick");
403                 BADCVAR("sv_autoscreenshot");
404                 BADCVAR("sv_autotaunt");
405                 BADCVAR("sv_curl_defaulturl");
406                 BADCVAR("sv_defaultcharacter");
407                 BADCVAR("sv_defaultplayercolors");
408                 BADCVAR("sv_defaultplayermodel");
409                 BADCVAR("sv_defaultplayerskin");
410                 BADCVAR("sv_maxidle");
411                 BADCVAR("sv_maxrate");
412                 BADCVAR("sv_motd");
413                 BADCVAR("sv_public");
414                 BADCVAR("sv_ready_restart");
415                 BADCVAR("sv_status_privacy");
416                 BADCVAR("sv_taunt");
417                 BADCVAR("sv_vote_call");
418                 BADCVAR("sv_vote_commands");
419                 BADCVAR("sv_vote_majority_factor");
420                 BADCVAR("sv_vote_master");
421                 BADCVAR("sv_vote_master_commands");
422                 BADCVAR("sv_vote_master_password");
423                 BADCVAR("sv_vote_simple_majority_factor");
424                 BADCVAR("teamplay_mode");
425                 BADCVAR("timelimit_override");
426                 BADCVAR("g_spawnshieldtime");
427                 BADPREFIX("g_warmup_");
428                 BADPREFIX("sv_ready_restart_");
429
430                 // mutators that announce themselves properly to the server browser
431                 BADCVAR("g_instagib");
432                 BADCVAR("g_new_toys");
433                 BADCVAR("g_nix");
434                 BADCVAR("g_grappling_hook");
435                 BADCVAR("g_jetpack");
436
437 #undef BADPREFIX
438 #undef BADCVAR
439
440                 if(pureadding)
441                 {
442                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
443                         if(strlen(cvar_purechanges) > 16384)
444                         {
445                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
446                                 pureadding = 0;
447                         }
448                 }
449                 ++cvar_purechanges_count;
450                 // WARNING: this variable is used for the server list
451                 // NEVER dare to skip this code!
452                 // Hacks to intentionally appearing as "pure server" even though you DO have
453                 // modified settings may be punished by removal from the server list.
454                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
455                 // though.
456         }
457         buf_del(h);
458         if(cvar_changes == "")
459                 cvar_changes = "// this server runs at default server settings\n";
460         else
461                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
462         cvar_changes = strzone(cvar_changes);
463         if(cvar_purechanges == "")
464                 cvar_purechanges = "// this server runs at default gameplay settings\n";
465         else
466                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
467         cvar_purechanges = strzone(cvar_purechanges);
468 }
469
470 void detect_maptype()
471 {
472 #if 0
473         vector o, v;
474         float i;
475
476         for (;;)
477         {
478                 o = world.mins;
479                 o.x += random() * (world.maxs.x - world.mins.x);
480                 o.y += random() * (world.maxs.y - world.mins.y);
481                 o.z += random() * (world.maxs.z - world.mins.z);
482
483                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, world);
484                 if(trace_fraction == 1)
485                         continue;
486
487                 v = trace_endpos;
488
489                 for(i = 0; i < 64; i += 4)
490                 {
491                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
492         if(trace_fraction == 1)
493                 continue;
494                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
495                 }
496
497                 break;
498         }
499 #endif
500 }
501
502 entity randomseed;
503 bool RandomSeed_Send(entity this, entity to, int sf)
504 {
505         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
506         WriteShort(MSG_ENTITY, self.cnt);
507         return true;
508 }
509 void RandomSeed_Think()
510 {SELFPARAM();
511         self.cnt = bound(0, floor(random() * 65536), 65535);
512         self.nextthink = time + 5;
513
514         self.SendFlags |= 1;
515 }
516 void RandomSeed_Spawn()
517 {SELFPARAM();
518         randomseed = new(randomseed);
519         make_pure(randomseed);
520         randomseed.think = RandomSeed_Think;
521         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
522
523         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
524 }
525
526 spawnfunc(__init_dedicated_server)
527 {
528         // handler for _init/_init map (only for dedicated server initialization)
529
530         world_initialized = -1; // don't complain
531         cvar = cvar_normal;
532         cvar_string = cvar_string_normal;
533         cvar_set = cvar_set_normal;
534
535         remove = remove_unsafely;
536
537         entity e = spawn();
538         e.think = GotoFirstMap;
539         e.nextthink = time; // this is usually 1 at this point
540
541         e = new(info_player_deathmatch);  // safeguard against player joining
542
543         self.classname = "worldspawn"; // safeguard against various stuff ;)
544
545         // needs to be done so early because of the constants they create
546         static_init();
547         static_init_late();
548         static_init_precache();
549
550         MapInfo_Enumerate();
551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
552 }
553
554 void __init_dedicated_server_shutdown() {
555         MapInfo_Shutdown();
556 }
557
558 void Map_MarkAsRecent(string m);
559 float world_already_spawned;
560 void Nagger_Init();
561 void ClientInit_Spawn();
562 void WeaponStats_Init();
563 void WeaponStats_Shutdown();
564 spawnfunc(worldspawn)
565 {
566         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
567
568         {
569                 bool wantrestart = false;
570
571                 if (!server_is_dedicated)
572                 {
573                         // force unloading of server pk3 files when starting a listen server
574                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
575                         // restore csqc_progname too
576                         string expect = "csprogs.dat";
577                         wantrestart = cvar_string_normal("csqc_progname") != expect;
578                         cvar_set_normal("csqc_progname", expect);
579                 }
580                 else
581                 {
582                         // Try to use versioned csprogs from pk3
583                         // Only ever use versioned csprogs.dat files on dedicated servers;
584                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
585                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
586                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
587                         string select = "csprogs.dat";
588                         if (fexists(pk3csprogs)) select = pk3csprogs;
589                         if (cvar_string_normal("csqc_progname") != select)
590                         {
591                                 cvar_set_normal("csqc_progname", select);
592                                 wantrestart = true;
593                         }
594                         // Check for updates on startup
595                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
596                         int sentinel = fopen("progs.txt", FILE_READ);
597                         if (sentinel >= 0)
598                         {
599                                 string switchversion = fgets(sentinel);
600                                 fclose(sentinel);
601                                 if (switchversion != "" && switchversion != WATERMARK)
602                                 {
603                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
604                                         // if it doesn't exist, assume either:
605                                         //   a) the current program was overwritten
606                                         //   b) this is a client only update
607                                         string newprogs = sprintf("progs-%s.dat", switchversion);
608                                         if (fexists(newprogs))
609                                         {
610                                                 cvar_set_normal("sv_progs", newprogs);
611                                                 wantrestart = true;
612                                         }
613                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
614                                         if (fexists(newcsprogs))
615                                         {
616                                                 cvar_set_normal("csqc_progname", newcsprogs);
617                                                 wantrestart = true;
618                                         }
619                                 }
620                         }
621                 }
622                 if (wantrestart)
623                 {
624                         LOG_INFOF("Restart requested\n");
625                         changelevel(mapname);
626                         // let initialization continue, shutdown depends on it
627                 }
628         }
629
630         float fd, l;
631         string s;
632
633         cvar = cvar_normal;
634         cvar_string = cvar_string_normal;
635         cvar_set = cvar_set_normal;
636
637         if(world_already_spawned)
638                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
639         world_already_spawned = true;
640
641         remove = remove_safely; // during spawning, watch what you remove!
642
643         cvar_changes_init(); // do this very early now so it REALLY matches the server config
644
645         compressShortVector_init();
646
647         maxclients = 0;
648         for (entity head = nextent(world); head; head = nextent(head))
649         {
650                 ++maxclients;
651         }
652
653         // needs to be done so early because of the constants they create
654         static_init();
655
656         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
657
658         TemporaryDB = db_create();
659
660         // 0 normal
661         lightstyle(0, "m");
662
663         // 1 FLICKER (first variety)
664         lightstyle(1, "mmnmmommommnonmmonqnmmo");
665
666         // 2 SLOW STRONG PULSE
667         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
668
669         // 3 CANDLE (first variety)
670         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
671
672         // 4 FAST STROBE
673         lightstyle(4, "mamamamamama");
674
675         // 5 GENTLE PULSE 1
676         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
677
678         // 6 FLICKER (second variety)
679         lightstyle(6, "nmonqnmomnmomomno");
680
681         // 7 CANDLE (second variety)
682         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
683
684         // 8 CANDLE (third variety)
685         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
686
687         // 9 SLOW STROBE (fourth variety)
688         lightstyle(9, "aaaaaaaazzzzzzzz");
689
690         // 10 FLUORESCENT FLICKER
691         lightstyle(10, "mmamammmmammamamaaamammma");
692
693         // 11 SLOW PULSE NOT FADE TO BLACK
694         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
695
696         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
697
698         // 63 testing
699         lightstyle(63, "a");
700
701         if(autocvar_g_campaign)
702                 CampaignPreInit();
703
704         Map_MarkAsRecent(mapname);
705
706         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
707
708         InitGameplayMode();
709         static_init_late();
710         static_init_precache();
711         readlevelcvars();
712         GrappleHookInit();
713
714         player_count = 0;
715         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
716         if(bot_waypoints_for_items == 1)
717                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
718                         bot_waypoints_for_items = 0;
719
720         precache();
721
722         WaypointSprite_Init();
723
724         GameLogInit(); // prepare everything
725         // NOTE for matchid:
726         // changing the logic generating it is okay. But:
727         // it HAS to stay <= 64 chars
728         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
729         if(autocvar_sv_eventlog)
730         {
731                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
732                 matchid = strzone(s);
733
734                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
735                 s = ":gameinfo:mutators:LIST";
736
737                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
738                 s = ret_string;
739
740                 // initialiation stuff, not good in the mutator system
741                 if(!autocvar_g_use_ammunition)
742                         s = strcat(s, ":no_use_ammunition");
743
744                 // initialiation stuff, not good in the mutator system
745                 if(autocvar_g_pickup_items == 0)
746                         s = strcat(s, ":no_pickup_items");
747                 if(autocvar_g_pickup_items > 0)
748                         s = strcat(s, ":pickup_items");
749
750                 // initialiation stuff, not good in the mutator system
751                 if(autocvar_g_weaponarena != "0")
752                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
753
754                 // TODO to mutator system
755                 if(autocvar_g_norecoil)
756                         s = strcat(s, ":norecoil");
757
758                 // TODO to mutator system
759                 if(autocvar_g_powerups == 0)
760                         s = strcat(s, ":no_powerups");
761                 if(autocvar_g_powerups > 0)
762                         s = strcat(s, ":powerups");
763
764                 GameLogEcho(s);
765                 GameLogEcho(":gameinfo:end");
766         }
767         else
768                 matchid = strzone(ftos(random()));
769
770         cvar_set("nextmap", "");
771
772         SetDefaultAlpha();
773
774         if(autocvar_g_campaign)
775                 CampaignPostInit();
776
777         Ban_LoadBans();
778
779         MapInfo_Enumerate();
780         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
781
782         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
783         {
784                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
785                 if(fd != -1)
786                 {
787                         while((s = fgets(fd)))
788                         {
789                                 l = tokenize_console(s);
790                                 if(l < 2)
791                                         continue;
792                                 if(argv(0) == "cd")
793                                 {
794                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
795                                         LOG_INFO("  cdtrack ", argv(2), "\n");
796                                 }
797                                 else if(argv(0) == "fog")
798                                 {
799                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
800                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
801                                 }
802                                 else if(argv(0) == "set")
803                                 {
804                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
805                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
806                                 }
807                                 else if(argv(0) != "//")
808                                 {
809                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
810                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
811                                 }
812                         }
813                         fclose(fd);
814                 }
815         }
816
817         WeaponStats_Init();
818
819         Nagger_Init();
820
821         next_pingtime = time + 5;
822
823         detect_maptype();
824
825         // set up information replies for clients and server to use
826         maplist_reply = strzone(getmaplist());
827         lsmaps_reply = strzone(getlsmaps());
828         monsterlist_reply = strzone(getmonsterlist());
829         for(int i = 0; i < 10; ++i)
830         {
831                 s = getrecords(i);
832                 if (s)
833                         records_reply[i] = strzone(s);
834         }
835         ladder_reply = strzone(getladder());
836         rankings_reply = strzone(getrankings());
837
838         // begin other init
839         ClientInit_Spawn();
840         RandomSeed_Spawn();
841         PingPLReport_Spawn();
842
843         CheatInit();
844
845         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
846
847         // fill sv_curl_serverpackages from .serverpackage files
848         if (autocvar_sv_curl_serverpackages_auto)
849         {
850                 s = "csprogs-" WATERMARK ".txt";
851                 // remove automatically managed files from the list to prevent duplicates
852                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
853                 {
854                         string pkg = argv(i);
855                         if (startsWith(pkg, "csprogs-")) continue;
856                         if (endsWith(pkg, "-serverpackage.txt")) continue;
857                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
858                         s = cons(s, pkg);
859                 }
860                 // add automatically managed files to the list
861                 #define X(match) MACRO_BEGIN { \
862                         fd = search_begin(match, true, false); \
863                         if (fd >= 0) \
864                         { \
865                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
866                                 { \
867                                         s = cons(s, search_getfilename(fd, i)); \
868                                 } \
869                                 search_end(fd); \
870                         } \
871                 } MACRO_END
872                 X("*-serverpackage.txt");
873                 X("*.serverpackage");
874                 #undef X
875                 cvar_set("sv_curl_serverpackages", s);
876         }
877
878         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
879         modname = "Xonotic";
880         // physics/balance/config changes that count as mod
881         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
882                 modname = cvar_string("g_mod_physics");
883         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
884                 modname = cvar_string("g_mod_balance");
885         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
886                 modname = cvar_string("g_mod_config");
887         // extra mutators that deserve to count as mod
888         MUTATOR_CALLHOOK(SetModname);
889
890         // save it for later
891         modname = strzone(modname);
892
893         WinningConditionHelper(); // set worldstatus
894
895         world_initialized = 1;
896 }
897
898 spawnfunc(light)
899 {
900         //makestatic (self); // Who the f___ did that?
901         remove(self);
902 }
903
904 string GetGametype()
905 {
906         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
907 }
908
909 string GetMapname()
910 {
911         return mapname;
912 }
913
914 float Map_Count, Map_Current;
915 string Map_Current_Name;
916
917 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
918 float GetMaplistPosition()
919 {
920         float pos, idx;
921         string map;
922
923         map = GetMapname();
924         idx = autocvar_g_maplist_index;
925
926         if(idx >= 0)
927                 if(idx < Map_Count)
928                         if(map == argv(idx))
929                                 return idx;
930
931         for(pos = 0; pos < Map_Count; ++pos)
932                 if(map == argv(pos))
933                         return pos;
934
935         // resume normal maplist rotation if current map is not in g_maplist
936         return idx;
937 }
938
939 float MapHasRightSize(string map)
940 {
941         float fh;
942         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
943         if(autocvar_g_maplist_check_waypoints)
944         {
945                 LOG_TRACE("checkwp "); LOG_TRACE(map);
946                 if(!fexists(strcat("maps/", map, ".waypoints")))
947                 {
948                         LOG_TRACE(": no waypoints\n");
949                         return false;
950                 }
951                 LOG_TRACE(": has waypoints\n");
952         }
953
954         // open map size restriction file
955         LOG_TRACE("opensize "); LOG_TRACE(map);
956         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
957         if(fh >= 0)
958         {
959                 float mapmin, mapmax;
960                 LOG_TRACE(": ok, ");
961                 mapmin = stof(fgets(fh));
962                 mapmax = stof(fgets(fh));
963                 fclose(fh);
964                 if(player_count < mapmin)
965                 {
966                         LOG_TRACE("not enough\n");
967                         return false;
968                 }
969                 if(player_count > mapmax)
970                 {
971                         LOG_TRACE("too many\n");
972                         return false;
973                 }
974                 LOG_TRACE("right size\n");
975                 return true;
976         }
977         LOG_TRACE(": not found\n");
978         return true;
979 }
980
981 string Map_Filename(float position)
982 {
983         return strcat("maps/", argv(position), ".bsp");
984 }
985
986 void Map_MarkAsRecent(string m)
987 {
988         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
989 }
990
991 float Map_IsRecent(string m)
992 {
993         return strhasword(autocvar_g_maplist_mostrecent, m);
994 }
995
996 float Map_Check(float position, float pass)
997 {
998         string filename;
999         string map_next;
1000         map_next = argv(position);
1001         if(pass <= 1)
1002         {
1003                 if(Map_IsRecent(map_next))
1004                         return 0;
1005         }
1006         filename = Map_Filename(position);
1007         if(MapInfo_CheckMap(map_next))
1008         {
1009                 if(pass == 2)
1010                         return 1;
1011                 if(MapHasRightSize(map_next))
1012                         return 1;
1013                 return 0;
1014         }
1015         else
1016                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1017
1018         return 0;
1019 }
1020
1021 void Map_Goto_SetStr(string nextmapname)
1022 {
1023         if(getmapname_stored != "")
1024                 strunzone(getmapname_stored);
1025         if(nextmapname == "")
1026                 getmapname_stored = "";
1027         else
1028                 getmapname_stored = strzone(nextmapname);
1029 }
1030
1031 void Map_Goto_SetFloat(float position)
1032 {
1033         cvar_set("g_maplist_index", ftos(position));
1034         Map_Goto_SetStr(argv(position));
1035 }
1036
1037 void Map_Goto(float reinit)
1038 {
1039         MapInfo_LoadMap(getmapname_stored, reinit);
1040 }
1041
1042 // return codes of map selectors:
1043 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1044 //   -2 = permanent failure
1045 float() MaplistMethod_Iterate = // usual method
1046 {
1047         float pass, i;
1048
1049         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1050
1051         for(pass = 1; pass <= 2; ++pass)
1052         {
1053                 for(i = 1; i < Map_Count; ++i)
1054                 {
1055                         float mapindex;
1056                         mapindex = (i + Map_Current) % Map_Count;
1057                         if(Map_Check(mapindex, pass))
1058                                 return mapindex;
1059                 }
1060         }
1061         return -1;
1062 }
1063
1064 float() MaplistMethod_Repeat = // fallback method
1065 {
1066         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1067
1068         if(Map_Check(Map_Current, 2))
1069                 return Map_Current;
1070         return -2;
1071 }
1072
1073 float() MaplistMethod_Random = // random map selection
1074 {
1075         float i, imax;
1076
1077         LOG_TRACE("Trying MaplistMethod_Random\n");
1078
1079         imax = 42;
1080
1081         for(i = 0; i <= imax; ++i)
1082         {
1083                 float mapindex;
1084                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1085                 if(Map_Check(mapindex, 1))
1086                         return mapindex;
1087         }
1088         return -1;
1089 }
1090
1091 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1092 // the exponent sets a bias on the map selection:
1093 // the higher the exponent, the less likely "shortly repeated" same maps are
1094 {
1095         float i, j, imax, insertpos;
1096
1097         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1098
1099         imax = 42;
1100
1101         for(i = 0; i <= imax; ++i)
1102         {
1103                 string newlist;
1104
1105                 // now reinsert this at another position
1106                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1107                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1108                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1109                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1110
1111                 // insert the current map there
1112                 newlist = "";
1113                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1114                         newlist = strcat(newlist, " ", argv(j));
1115                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1116                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1117                         newlist = strcat(newlist, " ", argv(j));
1118                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1119                 cvar_set("g_maplist", newlist);
1120                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1121
1122                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1123                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1124                 if(Map_Check(Map_Current, 1))
1125                         return Map_Current;
1126         }
1127         return -1;
1128 }
1129
1130 void Maplist_Init()
1131 {
1132         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1133         float i;
1134         for (i = 0; i < Map_Count; ++i)
1135                 if (Map_Check(i, 2))
1136                         break;
1137         if (i == Map_Count)
1138         {
1139                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1140                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1141                 if(autocvar_g_maplist_shuffle)
1142                         ShuffleMaplist();
1143                 localcmd("\nmenu_cmd sync\n");
1144                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1145         }
1146         if(Map_Count == 0)
1147                 error("empty maplist, cannot select a new map");
1148         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1149
1150         if(Map_Current_Name)
1151                 strunzone(Map_Current_Name);
1152         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1153         // this may or may not be correct, but who cares, in the worst case a map
1154         // isn't chosen in the first pass that should have been
1155 }
1156
1157 string GetNextMap()
1158 {
1159         float nextMap;
1160
1161         Maplist_Init();
1162         nextMap = -1;
1163
1164         if(nextMap == -1)
1165                 if(autocvar_g_maplist_shuffle > 0)
1166                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1167
1168         if(nextMap == -1)
1169                 if(autocvar_g_maplist_selectrandom)
1170                         nextMap = MaplistMethod_Random();
1171
1172         if(nextMap == -1)
1173                 nextMap = MaplistMethod_Iterate();
1174
1175         if(nextMap == -1)
1176                 nextMap = MaplistMethod_Repeat();
1177
1178         if(nextMap >= 0)
1179         {
1180                 Map_Goto_SetFloat(nextMap);
1181                 return getmapname_stored;
1182         }
1183
1184         return "";
1185 }
1186
1187 float DoNextMapOverride(float reinit)
1188 {
1189         if(autocvar_g_campaign)
1190         {
1191                 CampaignPostIntermission();
1192                 alreadychangedlevel = true;
1193                 return true;
1194         }
1195         if(autocvar_quit_when_empty)
1196         {
1197                 if(player_count <= currentbots)
1198                 {
1199                         localcmd("quit\n");
1200                         alreadychangedlevel = true;
1201                         return true;
1202                 }
1203         }
1204         if(autocvar_quit_and_redirect != "")
1205         {
1206                 redirection_target = strzone(autocvar_quit_and_redirect);
1207                 alreadychangedlevel = true;
1208                 return true;
1209         }
1210         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1211         {
1212                 localcmd("restart\n");
1213                 alreadychangedlevel = true;
1214                 return true;
1215         }
1216         if(autocvar_nextmap != "")
1217         {
1218                 string m;
1219                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1220                 cvar_set("nextmap",m);
1221
1222                 if(!m || gametypevote)
1223                         return false;
1224                 if(autocvar_sv_vote_gametype)
1225                 {
1226                         Map_Goto_SetStr(m);
1227                         return false;
1228                 }
1229
1230                 if(MapInfo_CheckMap(m))
1231                 {
1232                         Map_Goto_SetStr(m);
1233                         Map_Goto(reinit);
1234                         alreadychangedlevel = true;
1235                         return true;
1236                 }
1237         }
1238         if(!reinit && autocvar_lastlevel)
1239         {
1240                 cvar_settemp_restore();
1241                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1242                 alreadychangedlevel = true;
1243                 return true;
1244         }
1245         return false;
1246 }
1247
1248 void GotoNextMap(float reinit)
1249 {
1250         //string nextmap;
1251         //float n, nummaps;
1252         //string s;
1253         if (alreadychangedlevel)
1254                 return;
1255         alreadychangedlevel = true;
1256
1257         string nextMap;
1258
1259         nextMap = GetNextMap();
1260         if(nextMap == "")
1261                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1262         Map_Goto(reinit);
1263 }
1264
1265
1266 /*
1267 ============
1268 IntermissionThink
1269
1270 When the player presses attack or jump, change to the next level
1271 ============
1272 */
1273 .float autoscreenshot;
1274 void IntermissionThink()
1275 {SELFPARAM();
1276         FixIntermissionClient(self);
1277
1278         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1279         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1280
1281         if( (server_screenshot || client_screenshot)
1282                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1283         {
1284                 self.autoscreenshot = -1;
1285                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1286                 return;
1287         }
1288
1289         if (time < intermission_exittime)
1290                 return;
1291
1292         if(!mapvote_initialized)
1293                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1294                         return;
1295
1296         MapVote_Start();
1297 }
1298
1299 /*
1300 ============
1301 FindIntermission
1302
1303 Returns the entity to view from
1304 ============
1305 */
1306 /*
1307 entity FindIntermission()
1308 {
1309         local   entity spot;
1310         local   float cyc;
1311
1312 // look for info_intermission first
1313         spot = find (world, classname, "info_intermission");
1314         if (spot)
1315         {       // pick a random one
1316                 cyc = random() * 4;
1317                 while (cyc > 1)
1318                 {
1319                         spot = find (spot, classname, "info_intermission");
1320                         if (!spot)
1321                                 spot = find (spot, classname, "info_intermission");
1322                         cyc = cyc - 1;
1323                 }
1324                 return spot;
1325         }
1326
1327 // then look for the start position
1328         spot = find (world, classname, "info_player_start");
1329         if (spot)
1330                 return spot;
1331
1332 // testinfo_player_start is only found in regioned levels
1333         spot = find (world, classname, "testplayerstart");
1334         if (spot)
1335                 return spot;
1336
1337 // then look for the start position
1338         spot = find (world, classname, "info_player_deathmatch");
1339         if (spot)
1340                 return spot;
1341
1342         //objerror ("FindIntermission: no spot");
1343         return world;
1344 }
1345 */
1346
1347 /*
1348 ===============================================================================
1349
1350 RULES
1351
1352 ===============================================================================
1353 */
1354
1355 void DumpStats(float final)
1356 {
1357         float file;
1358         string s;
1359         float to_console;
1360         float to_eventlog;
1361         float to_file;
1362         float i;
1363
1364         to_console = autocvar_sv_logscores_console;
1365         to_eventlog = autocvar_sv_eventlog;
1366         to_file = autocvar_sv_logscores_file;
1367
1368         if(!final)
1369         {
1370                 to_console = true; // always print printstats replies
1371                 to_eventlog = false; // but never print them to the event log
1372         }
1373
1374         if(to_eventlog)
1375                 if(autocvar_sv_eventlog_console)
1376                         to_console = false; // otherwise we get the output twice
1377
1378         if(final)
1379                 s = ":scores:";
1380         else
1381                 s = ":status:";
1382         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1383
1384         if(to_console)
1385                 LOG_INFO(s, "\n");
1386         if(to_eventlog)
1387                 GameLogEcho(s);
1388
1389         file = -1;
1390         if(to_file)
1391         {
1392                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1393                 if(file == -1)
1394                         to_file = false;
1395                 else
1396                         fputs(file, strcat(s, "\n"));
1397         }
1398
1399         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1400         if(to_console)
1401                 LOG_INFO(s, "\n");
1402         if(to_eventlog)
1403                 GameLogEcho(s);
1404         if(to_file)
1405                 fputs(file, strcat(s, "\n"));
1406
1407         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1408                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1409                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1410                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it, s))
1411                         s = strcat(s, ftos(it.team), ":");
1412                 else
1413                         s = strcat(s, "spectator:");
1414
1415                 if(to_console)
1416                         LOG_INFO(s, it.netname, "\n");
1417                 if(to_eventlog)
1418                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1419                 if(to_file)
1420                         fputs(file, strcat(s, it.netname, "\n"));
1421         ));
1422
1423         if(teamplay)
1424         {
1425                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1426                 if(to_console)
1427                         LOG_INFO(s, "\n");
1428                 if(to_eventlog)
1429                         GameLogEcho(s);
1430                 if(to_file)
1431                         fputs(file, strcat(s, "\n"));
1432
1433                 for(i = 1; i < 16; ++i)
1434                 {
1435                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1436                         s = strcat(s, ":", ftos(i));
1437                         if(to_console)
1438                                 LOG_INFO(s, "\n");
1439                         if(to_eventlog)
1440                                 GameLogEcho(s);
1441                         if(to_file)
1442                                 fputs(file, strcat(s, "\n"));
1443                 }
1444         }
1445
1446         if(to_console)
1447                 LOG_INFO(":end\n");
1448         if(to_eventlog)
1449                 GameLogEcho(":end");
1450         if(to_file)
1451         {
1452                 fputs(file, ":end\n");
1453                 fclose(file);
1454         }
1455 }
1456
1457 void FixIntermissionClient(entity e)
1458 {
1459         if(!e.autoscreenshot) // initial call
1460         {
1461                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1462                 e.health = -2342;
1463                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1464                 e.solid = SOLID_NOT;
1465                 e.movetype = MOVETYPE_NONE;
1466                 e.takedamage = DAMAGE_NO;
1467                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1468                 {
1469                     .entity weaponentity = weaponentities[slot];
1470                         if(e.(weaponentity))
1471                         {
1472                                 e.(weaponentity).effects = EF_NODRAW;
1473                                 if (e.(weaponentity).weaponchild)
1474                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1475                         }
1476                 }
1477                 if(IS_REAL_CLIENT(e))
1478                 {
1479                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1480                         RandomSelection_Init();
1481                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1482                                 RandomSelection_Add(NULL, 0, it, 1, 1);
1483                         ));
1484                         if (RandomSelection_chosen_string != "")
1485                         {
1486                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1487                         }
1488                         msg_entity = e;
1489                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1490                 }
1491         }
1492 }
1493
1494 /*
1495 go to the next level for deathmatch
1496 only called if a time or frag limit has expired
1497 */
1498 void NextLevel()
1499 {
1500         gameover = true;
1501
1502         intermission_running = 1;
1503
1504 // enforce a wait time before allowing changelevel
1505         if(player_count > 0)
1506                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1507         else
1508                 intermission_exittime = -1;
1509
1510         /*
1511         WriteByte (MSG_ALL, SVC_CDTRACK);
1512         WriteByte (MSG_ALL, 3);
1513         WriteByte (MSG_ALL, 3);
1514         // done in FixIntermission
1515         */
1516
1517         //pos = FindIntermission ();
1518
1519         VoteReset();
1520
1521         DumpStats(true);
1522
1523         // send statistics
1524         PlayerStats_GameReport(true);
1525         WeaponStats_Shutdown();
1526
1527         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1528
1529         if(autocvar_sv_eventlog)
1530                 GameLogEcho(":gameover");
1531
1532         GameLogClose();
1533
1534         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1535                 FixIntermissionClient(it);
1536                 if(it.winning)
1537                         bprint(it.netname, " ^7wins.\n");
1538         ));
1539
1540         entity oldself = self;
1541         target_music_kill();
1542         self = oldself;
1543
1544         if(autocvar_g_campaign)
1545                 CampaignPreIntermission();
1546
1547         MUTATOR_CALLHOOK(MatchEnd);
1548
1549         localcmd("\nsv_hook_gameend\n");
1550 }
1551
1552 /*
1553 ============
1554 CheckRules_Player
1555
1556 Exit deathmatch games upon conditions
1557 ============
1558 */
1559 void CheckRules_Player()
1560 {SELFPARAM();
1561         if (gameover)   // someone else quit the game already
1562                 return;
1563
1564         if(!IS_DEAD(self))
1565                 self.play_time += frametime;
1566
1567         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1568         //   (div0: and that in CheckRules_World please)
1569 }
1570
1571
1572 float InitiateSuddenDeath()
1573 {
1574         // Check first whether normal overtimes could be added before initiating suddendeath mode
1575         // - for this timelimit_overtime needs to be >0 of course
1576         // - also check the winning condition calculated in the previous frame and only add normal overtime
1577         //   again, if at the point at which timelimit would be extended again, still no winner was found
1578         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1579         {
1580                 return 1; // need to call InitiateOvertime later
1581         }
1582         else
1583         {
1584                 if(!checkrules_suddendeathend)
1585                 {
1586                         if(autocvar_g_campaign)
1587                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1588                         else
1589                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1590                         if(g_race && !g_race_qualifying)
1591                                 race_StartCompleting();
1592                 }
1593                 return 0;
1594         }
1595 }
1596
1597 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1598 {
1599         ++checkrules_overtimesadded;
1600         //add one more overtime by simply extending the timelimit
1601         float tl;
1602         tl = autocvar_timelimit;
1603         tl += autocvar_timelimit_overtime;
1604         cvar_set("timelimit", ftos(tl));
1605
1606         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1607 }
1608
1609 float GetWinningCode(float fraglimitreached, float equality)
1610 {
1611         if(autocvar_g_campaign == 1)
1612                 if(fraglimitreached)
1613                         return WINNING_YES;
1614                 else
1615                         return WINNING_NO;
1616
1617         else
1618                 if(equality)
1619                         if(fraglimitreached)
1620                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1621                         else
1622                                 return WINNING_NEVER;
1623                 else
1624                         if(fraglimitreached)
1625                                 return WINNING_YES;
1626                         else
1627                                 return WINNING_NO;
1628 }
1629
1630 // set the .winning flag for exactly those players with a given field value
1631 void SetWinners(.float field, float value)
1632 {
1633         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1634 }
1635
1636 // set the .winning flag for those players with a given field value
1637 void AddWinners(.float field, float value)
1638 {
1639         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1640                 if(it.(field) == value)
1641                         it.winning = 1;
1642         ));
1643 }
1644
1645 // clear the .winning flags
1646 void ClearWinners()
1647 {
1648         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1649 }
1650
1651 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1652 // they win. Otherwise the defending team wins once the timelimit passes.
1653 void assault_new_round();
1654 float WinningCondition_Assault()
1655 {SELFPARAM();
1656         float status;
1657
1658         WinningConditionHelper(); // set worldstatus
1659
1660         status = WINNING_NO;
1661         // as the timelimit has not yet passed just assume the defending team will win
1662         if(assault_attacker_team == NUM_TEAM_1)
1663         {
1664                 SetWinners(team, NUM_TEAM_2);
1665         }
1666         else
1667         {
1668                 SetWinners(team, NUM_TEAM_1);
1669         }
1670
1671         entity ent;
1672         ent = find(world, classname, "target_assault_roundend");
1673         if(ent)
1674         {
1675                 if(ent.winning) // round end has been triggered by attacking team
1676                 {
1677                         bprint("ASSAULT: round completed...\n");
1678                         SetWinners(team, assault_attacker_team);
1679
1680                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1681
1682                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1683                         {
1684                                 status = WINNING_YES;
1685                         }
1686                         else
1687                         {
1688                                 WITH(entity, self, ent, assault_new_round());
1689                         }
1690                 }
1691         }
1692
1693         return status;
1694 }
1695
1696 void ShuffleMaplist()
1697 {
1698         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1699 }
1700
1701 float leaderfrags;
1702 float WinningCondition_Scores(float limit, float leadlimit)
1703 {
1704         float limitreached;
1705
1706         // TODO make everything use THIS winning condition (except LMS)
1707         WinningConditionHelper();
1708
1709         if(teamplay)
1710         {
1711                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1712                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1713                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1714                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1715         }
1716
1717         ClearWinners();
1718         if(WinningConditionHelper_winner)
1719                 WinningConditionHelper_winner.winning = 1;
1720         if(WinningConditionHelper_winnerteam >= 0)
1721                 SetWinners(team, WinningConditionHelper_winnerteam);
1722
1723         if(WinningConditionHelper_lowerisbetter)
1724         {
1725                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1726                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1727                 limit = -limit;
1728         }
1729
1730         if(WinningConditionHelper_zeroisworst)
1731                 leadlimit = 0; // not supported in this mode
1732
1733         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1734         // these modes always score in increments of 1, thus this makes sense
1735         {
1736                 if(leaderfrags != WinningConditionHelper_topscore)
1737                 {
1738                         leaderfrags = WinningConditionHelper_topscore;
1739
1740                         if (limit)
1741                         if (leaderfrags == limit - 1)
1742                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1743                         else if (leaderfrags == limit - 2)
1744                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1745                         else if (leaderfrags == limit - 3)
1746                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1747                 }
1748         }
1749
1750         limitreached = false;
1751         if(limit)
1752                 if(WinningConditionHelper_topscore >= limit)
1753                         limitreached = true;
1754         if(leadlimit)
1755         {
1756                 float leadlimitreached;
1757                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1758                 if(autocvar_leadlimit_and_fraglimit)
1759                         limitreached = (limitreached && leadlimitreached);
1760                 else
1761                         limitreached = (limitreached || leadlimitreached);
1762         }
1763
1764         if(limit)
1765                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1766
1767         return GetWinningCode(
1768                 WinningConditionHelper_topscore && limitreached,
1769                 WinningConditionHelper_equality
1770         );
1771 }
1772
1773 float WinningCondition_RanOutOfSpawns()
1774 {
1775         if(have_team_spawns <= 0)
1776                 return WINNING_NO;
1777
1778         if(!autocvar_g_spawn_useallspawns)
1779                 return WINNING_NO;
1780
1781         if(!some_spawn_has_been_used)
1782                 return WINNING_NO;
1783
1784         team1_score = team2_score = team3_score = team4_score = 0;
1785
1786         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1787                 switch(it.team)
1788                 {
1789                         case NUM_TEAM_1: team1_score = 1; break;
1790                         case NUM_TEAM_2: team2_score = 1; break;
1791                         case NUM_TEAM_3: team3_score = 1; break;
1792                         case NUM_TEAM_4: team4_score = 1; break;
1793                 }
1794         ));
1795
1796         FOREACH_ENTITY_CLASS("info_player_deathmatch", true, LAMBDA(
1797                 switch(it.team)
1798                 {
1799                         case NUM_TEAM_1: team1_score = 1; break;
1800                         case NUM_TEAM_2: team2_score = 1; break;
1801                         case NUM_TEAM_3: team3_score = 1; break;
1802                         case NUM_TEAM_4: team4_score = 1; break;
1803                 }
1804         ));
1805
1806         ClearWinners();
1807         if(team1_score + team2_score + team3_score + team4_score == 0)
1808         {
1809                 checkrules_equality = true;
1810                 return WINNING_YES;
1811         }
1812         else if(team1_score + team2_score + team3_score + team4_score == 1)
1813         {
1814                 float t, i;
1815                 if(team1_score)
1816                         t = NUM_TEAM_1;
1817                 else if(team2_score)
1818                         t = NUM_TEAM_2;
1819                 else if(team3_score)
1820                         t = NUM_TEAM_3;
1821                 else // if(team4_score)
1822                         t = NUM_TEAM_4;
1823                 CheckAllowedTeams(world);
1824                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1825                 {
1826                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1827                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1828                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1829                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1830                 }
1831
1832                 AddWinners(team, t);
1833                 return WINNING_YES;
1834         }
1835         else
1836                 return WINNING_NO;
1837 }
1838
1839 /*
1840 ============
1841 CheckRules_World
1842
1843 Exit deathmatch games upon conditions
1844 ============
1845 */
1846 void CheckRules_World()
1847 {
1848         float timelimit;
1849         float fraglimit;
1850         float leadlimit;
1851
1852         VoteThink();
1853         MapVote_Think();
1854
1855         SetDefaultAlpha();
1856
1857         if (gameover)   // someone else quit the game already
1858         {
1859                 if(player_count == 0) // Nobody there? Then let's go to the next map
1860                         MapVote_Start();
1861                         // this will actually check the player count in the next frame
1862                         // again, but this shouldn't hurt
1863                 return;
1864         }
1865
1866         timelimit = autocvar_timelimit * 60;
1867         fraglimit = autocvar_fraglimit;
1868         leadlimit = autocvar_leadlimit;
1869
1870         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1871         {
1872                 if(timelimit > 0)
1873                         timelimit = 0; // timelimit is not made for warmup
1874                 if(fraglimit > 0)
1875                         fraglimit = 0; // no fraglimit for now
1876                 leadlimit = 0; // no leadlimit for now
1877         }
1878
1879         if(timelimit > 0)
1880         {
1881                 timelimit += game_starttime;
1882         }
1883         else if (timelimit < 0)
1884         {
1885                 // endmatch
1886                 NextLevel();
1887                 return;
1888         }
1889
1890         float wantovertime;
1891         wantovertime = 0;
1892
1893         if(timelimit > game_starttime)
1894                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1895         else
1896                 game_completion_ratio = 0;
1897
1898         if(checkrules_suddendeathend)
1899         {
1900                 if(!checkrules_suddendeathwarning)
1901                 {
1902                         checkrules_suddendeathwarning = true;
1903                         if(g_race && !g_race_qualifying)
1904                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1905                         else
1906                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1907                 }
1908         }
1909         else
1910         {
1911                 if (timelimit && time >= timelimit)
1912                 {
1913                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1914                         {
1915                                 float totalplayers;
1916                                 float playerswithlaps;
1917                                 float readyplayers;
1918                                 totalplayers = playerswithlaps = readyplayers = 0;
1919                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1920                                         ++totalplayers;
1921                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1922                                                 ++playerswithlaps;
1923                                         if(it.ready)
1924                                                 ++readyplayers;
1925                                 ));
1926
1927                                 // at least 2 of the players have completed a lap: start the RACE
1928                                 // otherwise, the players should end the qualifying on their own
1929                                 if(readyplayers || playerswithlaps >= 2)
1930                                 {
1931                                         checkrules_suddendeathend = 0;
1932                                         ReadyRestart(); // go to race
1933                                         return;
1934                                 }
1935                                 else
1936                                         wantovertime |= InitiateSuddenDeath();
1937                         }
1938                         else
1939                                 wantovertime |= InitiateSuddenDeath();
1940                 }
1941         }
1942
1943         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1944         {
1945                 NextLevel();
1946                 return;
1947         }
1948
1949         int checkrules_status = WinningCondition_RanOutOfSpawns();
1950         if(checkrules_status == WINNING_YES)
1951                 bprint("Hey! Someone ran out of spawns!\n");
1952         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1953                 checkrules_status = ret_float;
1954         else
1955                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1956
1957         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1958         {
1959                 checkrules_status = WINNING_NEVER;
1960                 checkrules_overtimesadded = -1;
1961                 wantovertime |= InitiateSuddenDeath();
1962         }
1963
1964         if(checkrules_status == WINNING_NEVER)
1965                 // equality cases! Nobody wins if the overtime ends in a draw.
1966                 ClearWinners();
1967
1968         if(wantovertime)
1969         {
1970                 if(checkrules_status == WINNING_NEVER)
1971                         InitiateOvertime();
1972                 else
1973                         checkrules_status = WINNING_YES;
1974         }
1975
1976         if(checkrules_suddendeathend)
1977                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1978                         checkrules_status = WINNING_YES;
1979
1980         if(checkrules_status == WINNING_YES)
1981         {
1982                 //print("WINNING\n");
1983                 NextLevel();
1984         }
1985 }
1986
1987 string GotoMap(string m)
1988 {
1989         m = GameTypeVote_MapInfo_FixName(m);
1990         if (!m)
1991                 return "The map you suggested is not available on this server.";
1992         if (!autocvar_sv_vote_gametype)
1993         if(!MapInfo_CheckMap(m))
1994                 return "The map you suggested does not support the current game mode.";
1995         cvar_set("nextmap", m);
1996         cvar_set("timelimit", "-1");
1997         if(mapvote_initialized || alreadychangedlevel)
1998         {
1999                 if(DoNextMapOverride(0))
2000                         return "Map switch initiated.";
2001                 else
2002                         return "Hm... no. For some reason I like THIS map more.";
2003         }
2004         else
2005                 return "Map switch will happen after scoreboard.";
2006 }
2007
2008
2009 void EndFrame()
2010 {SELFPARAM();
2011         anticheat_endframe();
2012
2013         float altime;
2014         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2015                 entity e = IS_SPEC(it) ? it.enemy : it;
2016                 if(e.typehitsound)
2017                         it.typehit_time = time;
2018                 else if(e.damage_dealt)
2019                 {
2020                         it.hit_time = time;
2021                         it.damage_dealt_total += ceil(e.damage_dealt);
2022                 }
2023         ));
2024         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2025         // add 1 frametime because after this, engine SV_Physics
2026         // increases time by a frametime and then networks the frame
2027         // add another frametime because client shows everything with
2028         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2029         // needed!
2030         FOREACH_CLIENT(true, LAMBDA(
2031                 it.typehitsound = false;
2032                 it.damage_dealt = 0;
2033                 setself(it);
2034                 antilag_record(it, altime);
2035         ));
2036         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
2037                 setself(it);
2038                 antilag_record(it, altime);
2039         ));
2040         FOREACH_CLIENT(PS(it), LAMBDA(
2041                 PlayerState s = PS(it);
2042                 s.ps_push(s, it);
2043         ));
2044 }
2045
2046
2047 /*
2048  * RedirectionThink:
2049  * returns true if redirecting
2050  */
2051 float redirection_timeout;
2052 float redirection_nextthink;
2053 float RedirectionThink()
2054 {SELFPARAM();
2055         float clients_found;
2056
2057         if(redirection_target == "")
2058                 return false;
2059
2060         if(!redirection_timeout)
2061         {
2062                 cvar_set("sv_public", "-2");
2063                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2064                 if(redirection_target == "self")
2065                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2066                 else
2067                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2068         }
2069
2070         if(time < redirection_nextthink)
2071                 return true;
2072
2073         redirection_nextthink = time + 1;
2074
2075         clients_found = 0;
2076         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2077                 setself(it);
2078                 // TODO add timer
2079                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2080                 if(redirection_target == "self")
2081                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2082                 else
2083                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2084                 ++clients_found;
2085         ));
2086
2087         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2088
2089         if(time > redirection_timeout || clients_found == 0)
2090                 localcmd("\nwait; wait; wait; quit\n");
2091
2092         return true;
2093 }
2094
2095 void TargetMusic_RestoreGame();
2096 void RestoreGame()
2097 {
2098         // Loaded from a save game
2099         // some things then break, so let's work around them...
2100
2101         // Progs DB (capture records)
2102         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2103
2104         // Mapinfo
2105         MapInfo_Shutdown();
2106         MapInfo_Enumerate();
2107         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2108         WeaponStats_Init();
2109
2110         TargetMusic_RestoreGame();
2111 }
2112
2113 void Shutdown()
2114 {
2115         gameover = 2;
2116
2117         if(world_initialized > 0)
2118         {
2119                 world_initialized = 0;
2120                 LOG_TRACE("Saving persistent data...\n");
2121                 Ban_SaveBans();
2122
2123                 // playerstats with unfinished match
2124                 PlayerStats_GameReport(false);
2125
2126                 if(!cheatcount_total)
2127                 {
2128                         if(autocvar_sv_db_saveasdump)
2129                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2130                         else
2131                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2132                 }
2133                 if(autocvar_developer)
2134                 {
2135                         if(autocvar_sv_db_saveasdump)
2136                                 db_dump(TemporaryDB, "server-temp.db");
2137                         else
2138                                 db_save(TemporaryDB, "server-temp.db");
2139                 }
2140                 CheatShutdown(); // must be after cheatcount check
2141                 db_close(ServerProgsDB);
2142                 db_close(TemporaryDB);
2143                 LOG_TRACE("Saving persistent data... done!\n");
2144                 // tell the bot system the game is ending now
2145                 bot_endgame();
2146
2147                 WeaponStats_Shutdown();
2148                 MapInfo_Shutdown();
2149         }
2150         else if(world_initialized == 0)
2151         {
2152                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2153         }
2154         else
2155         {
2156                 __init_dedicated_server_shutdown();
2157         }
2158 }