qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312                 BADCVAR("rescan_pending");
 313
 314                 // these can contain player IDs, so better hide
 315                 BADPREFIX("g_forced_team_");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_allow_fullbright");
 387                 BADCVAR("sv_checkforpacketsduringsleep");
 388                 BADCVAR("sv_timeout");
 389                 BADCVAR("welcome_message_time");
 390                 BADPREFIX("crypto_");
 391                 BADPREFIX("g_chat_");
 392                 BADPREFIX("g_ctf_captimerecord_");
 393                 BADPREFIX("g_maplist_votable_");
 394                 BADPREFIX("net_");
 395                 BADPREFIX("prvm_");
 396                 BADPREFIX("skill_");
 397                 BADPREFIX("sv_cullentities_");
 398                 BADPREFIX("sv_fraginfo_");
 399                 BADPREFIX("sv_maxidle_");
 400                 BADPREFIX("sv_vote_");
 401                 BADPREFIX("timelimit_");
 402                 BADCVAR("gameversion");
 403                 BADPREFIX("gameversion_");
 404                 BADCVAR("sv_namechangetimer");
 405
 406                 // allowed changes to server admins (please sync this to server.cfg)
 407                 // vi commands:
 408                 //   :/"impure"/,$d
 409                 //   :g!,^\/\/[^ /],d
 410                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 411                 //   :%!sort
 412                 // yes, this does contain some redundant stuff, don't really care
 413                 BADCVAR("bot_number");
 414                 BADCVAR("bot_prefix");
 415                 BADCVAR("bot_suffix");
 416                 BADCVAR("bot_config_file");
 417                 BADCVAR("capturelimit_override");
 418                 BADCVAR("fraglimit_override");
 419                 BADCVAR("gametype");
 420                 BADCVAR("g_antilag");
 421                 BADCVAR("g_balance_teams");
 422                 BADCVAR("g_balance_teams_force");
 423                 BADCVAR("g_ban_sync_trusted_servers");
 424                 BADCVAR("g_ban_sync_uri");
 425                 BADCVAR("g_ctf_capture_limit");
 426                 BADCVAR("g_ctf_ignore_frags");
 427                 BADCVAR("g_ctf_win_mode");
 428                 BADCVAR("g_domination_point_limit");
 429                 BADCVAR("g_friendlyfire");
 430                 BADCVAR("g_fullbrightitems");
 431                 BADCVAR("g_fullbrightplayers");
 432                 BADCVAR("g_keyhunt_point_limit");
 433                 BADCVAR("g_keyhunt_teams_override");
 434                 BADCVAR("g_lms_lives_override");
 435                 BADCVAR("g_maplist");
 436                 BADCVAR("g_maplist_check_waypoints");
 437                 BADCVAR("g_maplist_mostrecent_count");
 438                 BADCVAR("g_maplist_shuffle");
 439                 BADCVAR("g_maplist_votable");
 440                 BADCVAR("g_maplist_votable_abstain");
 441                 BADCVAR("g_maplist_votable_nodetail");
 442                 BADCVAR("g_maplist_votable_suggestions");
 443                 BADCVAR("g_maxplayers");
 444                 BADCVAR("g_minstagib");
 445                 BADCVAR("g_mirrordamage");
 446                 BADCVAR("g_nexball_goallimit");
 447                 BADCVAR("g_runematch_point_limit");
 448                 BADCVAR("g_start_delay");
 449                 BADCVAR("g_warmup");
 450                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 451                 BADCVAR("hostname");
 452                 BADCVAR("log_file");
 453                 BADCVAR("maxplayers");
 454                 BADCVAR("minplayers");
 455                 BADCVAR("net_address");
 456                 BADCVAR("port");
 457                 BADCVAR("rcon_password");
 458                 BADCVAR("rcon_restricted_commands");
 459                 BADCVAR("rcon_restricted_password");
 460                 BADCVAR("skill");
 461                 BADCVAR("sv_adminnick");
 462                 BADCVAR("sv_autoscreenshot");
 463                 BADCVAR("sv_curl_defaulturl");
 464                 BADCVAR("sv_defaultcharacter");
 465                 BADCVAR("sv_defaultplayercolors");
 466                 BADCVAR("sv_defaultplayermodel");
 467                 BADCVAR("sv_defaultplayerskin");
 468                 BADCVAR("sv_maxidle");
 469                 BADCVAR("sv_maxrate");
 470                 BADCVAR("sv_motd");
 471                 BADCVAR("sv_public");
 472                 BADCVAR("sv_ready_restart");
 473                 BADCVAR("sv_status_privacy");
 474                 BADCVAR("sv_vote_call");
 475                 BADCVAR("sv_vote_commands");
 476                 BADCVAR("sv_vote_majority_factor");
 477                 BADCVAR("sv_vote_master");
 478                 BADCVAR("sv_vote_master_commands");
 479                 BADCVAR("sv_vote_master_password");
 480                 BADCVAR("sv_vote_simple_majority_factor");
 481                 BADCVAR("sys_ticrate");
 482                 BADCVAR("teamplay_mode");
 483                 BADCVAR("timelimit_override");
 484                 BADPREFIX("g_warmup_");
 485
 486                 if(autocvar_g_minstagib)
 487                 {
 488                         BADCVAR("g_grappling_hook");
 489                         BADCVAR("g_jetpack");
 490                 }
 491 #undef BADPREFIX
 492 #undef BADCVAR
 493
 494                 if(pureadding)
 495                 {
 496                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 497                         if(strlen(cvar_purechanges) > 16384)
 498                         {
 499                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 500                                 pureadding = 0;
 501                         }
 502                 }
 503                 ++cvar_purechanges_count;
 504                 // WARNING: this variable is used for the server list
 505                 // NEVER dare to skip this code!
 506                 // Hacks to intentionally appearing as "pure server" even though you DO have
 507                 // modified settings may be punished by removal from the server list.
 508                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 509                 // though.
 510         }
 511         buf_del(h);
 512         if(cvar_changes == "")
 513                 cvar_changes = "// this server runs at default server settings\n";
 514         else
 515                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 516         cvar_changes = strzone(cvar_changes);
 517         if(cvar_purechanges == "")
 518                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 519         else
 520                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 521         cvar_purechanges = strzone(cvar_purechanges);
 522 }
 523
 524 void detect_maptype()
 525 {
 526 #if 0
 527         vector o, v;
 528         float i;
 529
 530         for(;;)
 531         {
 532                 o = world.mins;
 533                 o_x += random() * (world.maxs_x - world.mins_x);
 534                 o_y += random() * (world.maxs_y - world.mins_y);
 535                 o_z += random() * (world.maxs_z - world.mins_z);
 536
 537                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 538                 if(trace_fraction == 1)
 539                         continue;
 540
 541                 v = trace_endpos;
 542
 543                 for(i = 0; i < 64; i += 4)
 544                 {
 545                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 546         if(trace_fraction == 1)
 547                 continue;
 548                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 549                 }
 550
 551                 break;
 552         }
 553 #endif
 554 }
 555
 556 entity randomseed;
 557 float RandomSeed_Send(entity to, float sf)
 558 {
 559         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 560         WriteShort(MSG_ENTITY, self.cnt);
 561         return TRUE;
 562 }
 563 void RandomSeed_Think()
 564 {
 565         self.cnt = bound(0, floor(random() * 65536), 65535);
 566         self.nextthink = time + 5;
 567
 568         self.SendFlags |= 1;
 569 }
 570 void RandomSeed_Spawn()
 571 {
 572         randomseed = spawn();
 573         randomseed.think = RandomSeed_Think;
 574         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 575
 576         entity oldself;
 577         oldself = self;
 578         self = randomseed;
 579         self.think(); // sets random seed and nextthink
 580         self = oldself;
 581 }
 582
 583 void spawnfunc___init_dedicated_server(void)
 584 {
 585         // handler for _init/_init map (only for dedicated server initialization)
 586
 587         world_initialized = -1; // don't complain
 588         cvar = cvar_normal;
 589         cvar_string = cvar_string_normal;
 590         cvar_set = cvar_set_normal;
 591
 592         remove = remove_unsafely;
 593
 594         entity e;
 595         e = spawn();
 596         e.think = GotoFirstMap;
 597         e.nextthink = time; // this is usually 1 at this point
 598
 599         e = spawn();
 600         e.classname = "info_player_deathmatch"; // safeguard against player joining
 601
 602         self.classname = "worldspawn"; // safeguard against various stuff ;)
 603
 604         MapInfo_Enumerate();
 605         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 606 }
 607
 608 void Map_MarkAsRecent(string m);
 609 float world_already_spawned;
 610 void RegisterWeapons();
 611 void Nagger_Init();
 612 void ClientInit_Spawn();
 613 void WeaponStats_Init();
 614 void WeaponStats_Shutdown();
 615 void spawnfunc_worldspawn (void)
 616 {
 617         float fd, l, i, j, n;
 618         string s, col;
 619
 620         cvar = cvar_normal;
 621         cvar_string = cvar_string_normal;
 622         cvar_set = cvar_set_normal;
 623
 624         if(world_already_spawned)
 625                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 626         world_already_spawned = TRUE;
 627
 628         remove = remove_safely; // during spawning, watch what you remove!
 629
 630         check_unacceptable_compiler_bugs();
 631
 632         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 633
 634         compressShortVector_init();
 635
 636         allowed_to_spawn = TRUE;
 637
 638         entity head;
 639         head = nextent(world);
 640         maxclients = 0;
 641         while(head)
 642         {
 643                 ++maxclients;
 644                 head = nextent(head);
 645         }
 646
 647         // needs to be done so early as they would still spawn
 648         RegisterWeapons();
 649
 650         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 651
 652         TemporaryDB = db_create();
 653
 654         // 0 normal
 655         lightstyle(0, "m");
 656
 657         // 1 FLICKER (first variety)
 658         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 659
 660         // 2 SLOW STRONG PULSE
 661         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 662
 663         // 3 CANDLE (first variety)
 664         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 665
 666         // 4 FAST STROBE
 667         lightstyle(4, "mamamamamama");
 668
 669         // 5 GENTLE PULSE 1
 670         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 671
 672         // 6 FLICKER (second variety)
 673         lightstyle(6, "nmonqnmomnmomomno");
 674
 675         // 7 CANDLE (second variety)
 676         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 677
 678         // 8 CANDLE (third variety)
 679         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 680
 681         // 9 SLOW STROBE (fourth variety)
 682         lightstyle(9, "aaaaaaaazzzzzzzz");
 683
 684         // 10 FLUORESCENT FLICKER
 685         lightstyle(10, "mmamammmmammamamaaamammma");
 686
 687         // 11 SLOW PULSE NOT FADE TO BLACK
 688         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 689
 690         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 691
 692         // 63 testing
 693         lightstyle(63, "a");
 694
 695         if(autocvar_g_campaign)
 696                 CampaignPreInit();
 697
 698         Map_MarkAsRecent(mapname);
 699
 700         precache_model ("null"); // we need this one before InitGameplayMode
 701         InitGameplayMode();
 702         readlevelcvars();
 703         GrappleHookInit();
 704         ElectroInit();
 705         LaserInit();
 706
 707         player_count = 0;
 708         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 709         if(bot_waypoints_for_items == 1)
 710                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 711                         bot_waypoints_for_items = 0;
 712
 713         precache();
 714
 715         WaypointSprite_Init();
 716
 717         //if (g_domination)
 718         //      dom_init();
 719
 720         GameLogInit(); // prepare everything
 721         if(autocvar_sv_eventlog)
 722         {
 723                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 724                 matchid = strzone(s);
 725
 726                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 727                 s = ":gameinfo:mutators:LIST";
 728
 729                 ret_string = s;
 730                 MUTATOR_CALLHOOK(BuildMutatorsString);
 731                 s = ret_string;
 732
 733                 // simple, probably not good in the mutator system
 734                 if(autocvar_g_grappling_hook)
 735                         s = strcat(s, ":grappling_hook");
 736
 737                 // initialiation stuff, not good in the mutator system
 738                 if(!autocvar_g_use_ammunition)
 739                         s = strcat(s, ":no_use_ammunition");
 740
 741                 // initialiation stuff, not good in the mutator system
 742                 if(!autocvar_g_pickup_items)
 743                         s = strcat(s, ":no_pickup_items");
 744
 745                 // initialiation stuff, not good in the mutator system
 746                 if(autocvar_g_weaponarena != "0")
 747                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 748
 749                 // TODO to mutator system
 750                 if(autocvar_g_norecoil)
 751                         s = strcat(s, ":norecoil");
 752
 753                 // TODO to mutator system
 754                 if(autocvar_g_midair)
 755                         s = strcat(s, ":midair");
 756
 757                 // TODO to mutator system
 758                 if(autocvar_g_minstagib)
 759                         s = strcat(s, ":minstagib");
 760
 761                 GameLogEcho(s);
 762                 GameLogEcho(":gameinfo:end");
 763         }
 764         else
 765                 matchid = strzone(ftos(random()));
 766
 767         cvar_set("nextmap", "");
 768
 769         SetDefaultAlpha();
 770
 771         if(autocvar_g_campaign)
 772                 CampaignPostInit();
 773
 774         fteqcc_testbugs();
 775
 776         Ban_LoadBans();
 777
 778         MapInfo_Enumerate();
 779         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 780
 781         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 782         {
 783                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 784                 if(fd != -1)
 785                 {
 786                         while((s = fgets(fd)))
 787                         {
 788                                 l = tokenize_console(s);
 789                                 if(l < 2)
 790                                         continue;
 791                                 if(argv(0) == "cd")
 792                                 {
 793                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 794                                         print("  cdtrack ", argv(2), "\n");
 795                                 }
 796                                 else if(argv(0) == "fog")
 797                                 {
 798                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 799                                         print("  \"fog\" \"", s, "\"\n");
 800                                 }
 801                                 else if(argv(0) == "set")
 802                                 {
 803                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 804                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 805                                 }
 806                                 else if(argv(0) != "//")
 807                                 {
 808                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 809                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 810                                 }
 811                         }
 812                         fclose(fd);
 813                 }
 814         }
 815
 816         WeaponStats_Init();
 817
 818         addstat(STAT_WEAPONS, AS_INT, weapons);
 819         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 820         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 821         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 822         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 823         Nagger_Init();
 824
 825         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 826         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 827         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 828         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 829         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 830         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 831         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 832         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 833         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 834         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 835         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 836         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 837
 838         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 839         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 840
 841         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 842
 843         if(g_ca || g_freezetag)
 844         {
 845                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 846                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 847                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 848                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 849         }
 850         if(g_freezetag)
 851         {
 852                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 853                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 854         }
 855
 856         // g_movementspeed hack
 857         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 858         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 859         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 860         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 861
 862         // secrets
 863         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 864         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 865
 866         next_pingtime = time + 5;
 867
 868         detect_maptype();
 869
 870         lsmaps_reply = "^7Maps available: ";
 871         lsnewmaps_reply = "^7Maps without a record set: ";
 872         for(i = 0, j = 0; i < MapInfo_count; ++i)
 873         {
 874                 if(MapInfo_Get_ByID(i))
 875                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 876                         {
 877                                 if(mod(i, 2))
 878                                         col = "^2";
 879                                 else
 880                                         col = "^3";
 881                                 ++j;
 882                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 883                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 884                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 885                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 886                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 887                         }
 888         }
 889         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 890         if (!g_race && !g_cts)
 891                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 892         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 893
 894         maplist_reply = "^7Maps in list: ";
 895         n = tokenize_console(autocvar_g_maplist);
 896         for(i = 0, j = 0; i < n; ++i)
 897         {
 898                 if(MapInfo_CheckMap(argv(i)))
 899                 {
 900                         if(mod(j, 2))
 901                                 col = "^2";
 902                         else
 903                                 col = "^3";
 904                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 905                         ++j;
 906                 }
 907         }
 908         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 909         MapInfo_ClearTemps();
 910
 911         for(i = 0; i < 10; ++i)
 912         {
 913                 records_reply[i] = strzone(getrecords(i));
 914         }
 915         if(g_cts)
 916                 ladder_reply = strzone(getladder());
 917
 918         rankings_reply = strzone(getrankings());
 919
 920         ClientInit_Spawn();
 921         RandomSeed_Spawn();
 922         PingPLReport_Spawn();
 923
 924         CheatInit();
 925
 926         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 927
 928         // fill sv_curl_serverpackages from .serverpackage files
 929         if(autocvar_sv_curl_serverpackages_auto)
 930         {
 931                 s = "";
 932                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 933                 for(i = 0; i < n; ++i)
 934                         if(substring(argv(i), -14, -1) != ".serverpackage")
 935                                 s = strcat(s, " ", argv(i));
 936                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 937                 if(fd >= 0)
 938                 {
 939                         j = search_getsize(fd);
 940                         for(i = 0; i < j; ++i)
 941                                 s = strcat(s, " ", search_getfilename(fd, i));
 942                         search_end(fd);
 943                 }
 944                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 945         }
 946
 947         PlayerStats_Init();
 948
 949         world_initialized = 1;
 950 }
 951
 952 void spawnfunc_light (void)
 953 {
 954         //makestatic (self); // Who the f___ did that?
 955         remove(self);
 956 }
 957
 958 string GetGametype()
 959 {
 960         return GametypeNameFromType(game);
 961 }
 962
 963 string getmapname_stored;
 964 string GetMapname()
 965 {
 966         return mapname;
 967 }
 968
 969 float Map_Count, Map_Current;
 970 string Map_Current_Name;
 971
 972 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 973 float GetMaplistPosition()
 974 {
 975         float pos, idx;
 976         string map;
 977
 978         map = GetMapname();
 979         idx = autocvar_g_maplist_index;
 980
 981         if(idx >= 0)
 982                 if(idx < Map_Count)
 983                         if(map == argv(idx))
 984                                 return idx;
 985
 986         for(pos = 0; pos < Map_Count; ++pos)
 987                 if(map == argv(pos))
 988                         return pos;
 989
 990         // resume normal maplist rotation if current map is not in g_maplist
 991         return idx;
 992 }
 993
 994 float MapHasRightSize(string map)
 995 {
 996         float fh;
 997         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 998         if(autocvar_g_maplist_check_waypoints)
 999         {
1000                 dprint("checkwp "); dprint(map);
1001                 if(!fexists(strcat("maps/", map, ".waypoints")))
1002                 {
1003                         dprint(": no waypoints\n");
1004                         return FALSE;
1005                 }
1006                 dprint(": has waypoints\n");
1007         }
1008
1009         // open map size restriction file
1010         dprint("opensize "); dprint(map);
1011         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1012         if(fh >= 0)
1013         {
1014                 float mapmin, mapmax;
1015                 dprint(": ok, ");
1016                 mapmin = stof(fgets(fh));
1017                 mapmax = stof(fgets(fh));
1018                 fclose(fh);
1019                 if(player_count < mapmin)
1020                 {
1021                         dprint("not enough\n");
1022                         return FALSE;
1023                 }
1024                 if(player_count > mapmax)
1025                 {
1026                         dprint("too many\n");
1027                         return FALSE;
1028                 }
1029                 dprint("right size\n");
1030                 return TRUE;
1031         }
1032         dprint(": not found\n");
1033         return TRUE;
1034 }
1035
1036 string Map_Filename(float position)
1037 {
1038         return strcat("maps/", argv(position), ".bsp");
1039 }
1040
1041 string strwords(string s, float w)
1042 {
1043         float endpos;
1044         for(endpos = 0; w && endpos >= 0; --w)
1045                 endpos = strstrofs(s, " ", endpos + 1);
1046         if(endpos < 0)
1047                 return s;
1048         else
1049                 return substring(s, 0, endpos);
1050 }
1051
1052 float strhasword(string s, string w)
1053 {
1054         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1055 }
1056
1057 void Map_MarkAsRecent(string m)
1058 {
1059         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1060 }
1061
1062 float Map_IsRecent(string m)
1063 {
1064         return strhasword(autocvar_g_maplist_mostrecent, m);
1065 }
1066
1067 float Map_Check(float position, float pass)
1068 {
1069         string filename;
1070         string map_next;
1071         map_next = argv(position);
1072         if(pass <= 1)
1073         {
1074                 if(Map_IsRecent(map_next))
1075                         return 0;
1076         }
1077         filename = Map_Filename(position);
1078         if(MapInfo_CheckMap(map_next))
1079         {
1080                 if(pass == 2)
1081                         return 1;
1082                 if(MapHasRightSize(map_next))
1083                         return 1;
1084                 return 0;
1085         }
1086         else
1087                 dprint( "Couldn't select '", filename, "'..\n" );
1088
1089         return 0;
1090 }
1091
1092 void Map_Goto_SetStr(string nextmapname)
1093 {
1094         if(getmapname_stored != "")
1095                 strunzone(getmapname_stored);
1096         if(nextmapname == "")
1097                 getmapname_stored = "";
1098         else
1099                 getmapname_stored = strzone(nextmapname);
1100 }
1101
1102 void Map_Goto_SetFloat(float position)
1103 {
1104         cvar_set("g_maplist_index", ftos(position));
1105         Map_Goto_SetStr(argv(position));
1106 }
1107
1108 void GameResetCfg()
1109 {
1110         // settings persist, except...
1111         localcmd("\nsettemp_restore\n");
1112 }
1113
1114 void Map_Goto()
1115 {
1116         GameResetCfg();
1117         MapInfo_LoadMap(getmapname_stored);
1118 }
1119
1120 // return codes of map selectors:
1121 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1122 //   -2 = permanent failure
1123 float() MaplistMethod_Iterate = // usual method
1124 {
1125         float pass, i;
1126
1127         for(pass = 1; pass <= 2; ++pass)
1128         {
1129                 for(i = 1; i < Map_Count; ++i)
1130                 {
1131                         float mapindex;
1132                         mapindex = mod(i + Map_Current, Map_Count);
1133                         if(Map_Check(mapindex, pass))
1134                                 return mapindex;
1135                 }
1136         }
1137         return -1;
1138 }
1139
1140 float() MaplistMethod_Repeat = // fallback method
1141 {
1142         if(Map_Check(Map_Current, 2))
1143                 return Map_Current;
1144         return -2;
1145 }
1146
1147 float() MaplistMethod_Random = // random map selection
1148 {
1149         float i, imax;
1150
1151         imax = 42;
1152
1153         for(i = 0; i <= imax; ++i)
1154         {
1155                 float mapindex;
1156                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1157                 if(Map_Check(mapindex, 1))
1158                         return mapindex;
1159         }
1160         return -1;
1161 }
1162
1163 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1164 // the exponent sets a bias on the map selection:
1165 // the higher the exponent, the less likely "shortly repeated" same maps are
1166 {
1167         float i, j, imax, insertpos;
1168
1169         imax = 42;
1170
1171         for(i = 0; i <= imax; ++i)
1172         {
1173                 string newlist;
1174
1175                 // now reinsert this at another position
1176                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1177                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1178                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1179                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1180
1181                 // insert the current map there
1182                 newlist = "";
1183                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1184                         newlist = strcat(newlist, " ", argv(j));
1185                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1186                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1187                         newlist = strcat(newlist, " ", argv(j));
1188                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1189                 cvar_set("g_maplist", newlist);
1190                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1191
1192                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1193                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1194                 if(Map_Check(Map_Current, 1))
1195                         return Map_Current;
1196         }
1197         return -1;
1198 }
1199
1200 void Maplist_Init()
1201 {
1202         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1203         if(Map_Count == 0)
1204         {
1205                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1206                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1207                 if(autocvar_g_maplist_shuffle)
1208                         ShuffleMaplist();
1209                 localcmd("\nmenu_cmd sync\n");
1210                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1211         }
1212         if(Map_Count == 0)
1213                 error("empty maplist, cannot select a new map");
1214         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1215
1216         if(Map_Current_Name)
1217                 strunzone(Map_Current_Name);
1218         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1219         // this may or may not be correct, but who cares, in the worst case a map
1220         // isn't chosen in the first pass that should have been
1221 }
1222
1223 string GetNextMap()
1224 {
1225         float nextMap;
1226
1227         Maplist_Init();
1228         nextMap = -1;
1229
1230         if(nextMap == -1)
1231                 if(autocvar_g_maplist_shuffle > 0)
1232                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1233
1234         if(nextMap == -1)
1235                 if(autocvar_g_maplist_selectrandom)
1236                         nextMap = MaplistMethod_Random();
1237
1238         if(nextMap == -1)
1239                 nextMap = MaplistMethod_Iterate();
1240
1241         if(nextMap == -1)
1242                 nextMap = MaplistMethod_Repeat();
1243
1244         if(nextMap >= 0)
1245         {
1246                 Map_Goto_SetFloat(nextMap);
1247                 return getmapname_stored;
1248         }
1249
1250         return "";
1251 }
1252
1253 float DoNextMapOverride()
1254 {
1255         if(autocvar_g_campaign)
1256         {
1257                 CampaignPostIntermission();
1258                 alreadychangedlevel = TRUE;
1259                 return TRUE;
1260         }
1261         if(autocvar_quit_when_empty)
1262         {
1263                 if(player_count <= currentbots)
1264                 {
1265                         localcmd("quit\n");
1266                         alreadychangedlevel = TRUE;
1267                         return TRUE;
1268                 }
1269         }
1270         if(autocvar_quit_and_redirect != "")
1271         {
1272                 redirection_target = strzone(autocvar_quit_and_redirect);
1273                 alreadychangedlevel = TRUE;
1274                 return TRUE;
1275         }
1276         if (autocvar_samelevel) // if samelevel is set, stay on same level
1277         {
1278                 localcmd("restart\n");
1279                 alreadychangedlevel = TRUE;
1280                 return TRUE;
1281         }
1282         if(autocvar_nextmap != "")
1283                 if(MapInfo_CheckMap(autocvar_nextmap))
1284                 {
1285                         Map_Goto_SetStr(autocvar_nextmap);
1286                         Map_Goto();
1287                         alreadychangedlevel = TRUE;
1288                         return TRUE;
1289                 }
1290         if(autocvar_lastlevel)
1291         {
1292                 GameResetCfg();
1293                 localcmd("set lastlevel 0\ntogglemenu\n");
1294                 alreadychangedlevel = TRUE;
1295                 return TRUE;
1296         }
1297         return FALSE;
1298 }
1299
1300 void GotoNextMap()
1301 {
1302         //string nextmap;
1303         //float n, nummaps;
1304         //string s;
1305         if (alreadychangedlevel)
1306                 return;
1307         alreadychangedlevel = TRUE;
1308
1309         {
1310                 string nextMap;
1311                 float allowReset;
1312
1313                 for(allowReset = 1; allowReset >= 0; --allowReset)
1314                 {
1315                         nextMap = GetNextMap();
1316                         if(nextMap != "")
1317                                 break;
1318
1319                         if(allowReset)
1320                         {
1321                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1322                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1323                                 if(autocvar_g_maplist_shuffle)
1324                                         ShuffleMaplist();
1325                                 localcmd("\nmenu_cmd sync\n");
1326                         }
1327                         else
1328                         {
1329                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1330                         }
1331                 }
1332                 Map_Goto();
1333         }
1334 }
1335
1336
1337 /*
1338 ============
1339 IntermissionThink
1340
1341 When the player presses attack or jump, change to the next level
1342 ============
1343 */
1344 .float autoscreenshot;
1345 void() MapVote_Start;
1346 void() MapVote_Think;
1347 float mapvote_initialized;
1348 void IntermissionThink()
1349 {
1350         FixIntermissionClient(self);
1351
1352         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1353                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1354         {
1355                 self.autoscreenshot = -1;
1356                 if(clienttype(self) == CLIENTTYPE_REAL)
1357                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1358                 return;
1359         }
1360
1361         if (time < intermission_exittime)
1362                 return;
1363
1364         if(!mapvote_initialized)
1365                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1366                         return;
1367
1368         MapVote_Start();
1369 }
1370
1371 /*
1372 ============
1373 FindIntermission
1374
1375 Returns the entity to view from
1376 ============
1377 */
1378 /*
1379 entity FindIntermission()
1380 {
1381         local   entity spot;
1382         local   float cyc;
1383
1384 // look for info_intermission first
1385         spot = find (world, classname, "info_intermission");
1386         if (spot)
1387         {       // pick a random one
1388                 cyc = random() * 4;
1389                 while (cyc > 1)
1390                 {
1391                         spot = find (spot, classname, "info_intermission");
1392                         if (!spot)
1393                                 spot = find (spot, classname, "info_intermission");
1394                         cyc = cyc - 1;
1395                 }
1396                 return spot;
1397         }
1398
1399 // then look for the start position
1400         spot = find (world, classname, "info_player_start");
1401         if (spot)
1402                 return spot;
1403
1404 // testinfo_player_start is only found in regioned levels
1405         spot = find (world, classname, "testplayerstart");
1406         if (spot)
1407                 return spot;
1408
1409 // then look for the start position
1410         spot = find (world, classname, "info_player_deathmatch");
1411         if (spot)
1412                 return spot;
1413
1414         //objerror ("FindIntermission: no spot");
1415         return world;
1416 }
1417 */
1418
1419 /*
1420 ===============================================================================
1421
1422 RULES
1423
1424 ===============================================================================
1425 */
1426
1427 void DumpStats(float final)
1428 {
1429         float file;
1430         string s;
1431         float to_console;
1432         float to_eventlog;
1433         float to_file;
1434         float i;
1435
1436         to_console = autocvar_sv_logscores_console;
1437         to_eventlog = autocvar_sv_eventlog;
1438         to_file = autocvar_sv_logscores_file;
1439
1440         if(!final)
1441         {
1442                 to_console = TRUE; // always print printstats replies
1443                 to_eventlog = FALSE; // but never print them to the event log
1444         }
1445
1446         if(to_eventlog)
1447                 if(autocvar_sv_eventlog_console)
1448                         to_console = FALSE; // otherwise we get the output twice
1449
1450         if(final)
1451                 s = ":scores:";
1452         else
1453                 s = ":status:";
1454         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1455
1456         if(to_console)
1457                 print(s, "\n");
1458         if(to_eventlog)
1459                 GameLogEcho(s);
1460         if(to_file)
1461         {
1462                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1463                 if(file == -1)
1464                         to_file = FALSE;
1465                 else
1466                         fputs(file, strcat(s, "\n"));
1467         }
1468
1469         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1470         if(to_console)
1471                 print(s, "\n");
1472         if(to_eventlog)
1473                 GameLogEcho(s);
1474         if(to_file)
1475                 fputs(file, strcat(s, "\n"));
1476
1477         FOR_EACH_CLIENT(other)
1478         {
1479                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1480                 {
1481                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1482                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1483                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1484                                 s = strcat(s, ftos(other.team), ":");
1485                         else
1486                                 s = strcat(s, "spectator:");
1487
1488                         if(to_console)
1489                                 print(s, other.netname, "\n");
1490                         if(to_eventlog)
1491                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1492                         if(to_file)
1493                                 fputs(file, strcat(s, other.netname, "\n"));
1494                 }
1495         }
1496
1497         if(teamplay)
1498         {
1499                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1500                 if(to_console)
1501                         print(s, "\n");
1502                 if(to_eventlog)
1503                         GameLogEcho(s);
1504                 if(to_file)
1505                         fputs(file, strcat(s, "\n"));
1506
1507                 for(i = 1; i < 16; ++i)
1508                 {
1509                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1510                         s = strcat(s, ":", ftos(i));
1511                         if(to_console)
1512                                 print(s, "\n");
1513                         if(to_eventlog)
1514                                 GameLogEcho(s);
1515                         if(to_file)
1516                                 fputs(file, strcat(s, "\n"));
1517                 }
1518         }
1519
1520         if(to_console)
1521                 print(":end\n");
1522         if(to_eventlog)
1523                 GameLogEcho(":end");
1524         if(to_file)
1525         {
1526                 fputs(file, ":end\n");
1527                 fclose(file);
1528         }
1529 }
1530
1531 void FixIntermissionClient(entity e)
1532 {
1533         string s;
1534         if(!e.autoscreenshot) // initial call
1535         {
1536                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1537                 e.health = -2342;
1538                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1539                 e.solid = SOLID_NOT;
1540                 e.movetype = MOVETYPE_NONE;
1541                 e.takedamage = DAMAGE_NO;
1542                 if(e.weaponentity)
1543                 {
1544                         e.weaponentity.effects = EF_NODRAW;
1545                         if (e.weaponentity.weaponentity)
1546                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1547                 }
1548                 if(clienttype(e) == CLIENTTYPE_REAL)
1549                 {
1550                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1551                         s = autocvar_sv_intermission_cdtrack;
1552                         if(s != "")
1553                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1554                         msg_entity = e;
1555                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1556                 }
1557         }
1558 }
1559
1560
1561 /*
1562 go to the next level for deathmatch
1563 only called if a time or frag limit has expired
1564 */
1565 void NextLevel()
1566 {
1567         gameover = TRUE;
1568
1569         intermission_running = 1;
1570
1571 // enforce a wait time before allowing changelevel
1572         if(player_count > 0)
1573                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1574         else
1575                 intermission_exittime = -1;
1576
1577         /*
1578         WriteByte (MSG_ALL, SVC_CDTRACK);
1579         WriteByte (MSG_ALL, 3);
1580         WriteByte (MSG_ALL, 3);
1581         // done in FixIntermission
1582         */
1583
1584         //pos = FindIntermission ();
1585
1586         VoteReset();
1587
1588         DumpStats(TRUE);
1589
1590         // send statistics
1591         entity e;
1592         PlayerStats_EndMatch(1);
1593         FOR_EACH_CLIENT(e)
1594                 PlayerStats_AddGlobalInfo(e);
1595         PlayerStats_Shutdown();
1596         WeaponStats_Shutdown();
1597
1598         if(autocvar_sv_eventlog)
1599                 GameLogEcho(":gameover");
1600
1601         GameLogClose();
1602
1603         FOR_EACH_PLAYER(other) {
1604                 FixIntermissionClient(other);
1605                 if(other.winning)
1606                         bprint(other.netname, " ^7wins.\n");
1607         }
1608
1609         if(autocvar_g_campaign)
1610                 CampaignPreIntermission();
1611
1612         localcmd("\nsv_hook_gameend\n");
1613 }
1614
1615 /*
1616 ============
1617 CheckRules_Player
1618
1619 Exit deathmatch games upon conditions
1620 ============
1621 */
1622 void CheckRules_Player()
1623 {
1624         if (gameover)   // someone else quit the game already
1625                 return;
1626
1627         if(self.deadflag == DEAD_NO)
1628                 self.play_time += frametime;
1629
1630         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1631         //   (div0: and that in CheckRules_World please)
1632 }
1633
1634 float checkrules_equality;
1635 float checkrules_suddendeathwarning;
1636 float checkrules_suddendeathend;
1637 float checkrules_overtimesadded; //how many overtimes have been already added
1638
1639 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1640 float WINNING_YES = 1; // winner found
1641 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1642 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1643
1644 float InitiateSuddenDeath()
1645 {
1646         // Check first whether normal overtimes could be added before initiating suddendeath mode
1647         // - for this timelimit_overtime needs to be >0 of course
1648         // - also check the winning condition calculated in the previous frame and only add normal overtime
1649         //   again, if at the point at which timelimit would be extended again, still no winner was found
1650         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1651         {
1652                 return 1; // need to call InitiateOvertime later
1653         }
1654         else
1655         {
1656                 if(!checkrules_suddendeathend)
1657                 {
1658                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1659                         if(g_race && !g_race_qualifying)
1660                                 race_StartCompleting();
1661                 }
1662                 return 0;
1663         }
1664 }
1665
1666 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1667 {
1668         ++checkrules_overtimesadded;
1669         //add one more overtime by simply extending the timelimit
1670         float tl;
1671         tl = autocvar_timelimit;
1672         tl += autocvar_timelimit_overtime;
1673         cvar_set("timelimit", ftos(tl));
1674         string minutesPlural;
1675         if (autocvar_timelimit_overtime == 1)
1676                 minutesPlural = " ^3minute";
1677         else
1678                 minutesPlural = " ^3minutes";
1679
1680         bcenterprint(
1681                 strcat(
1682                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1683                         ftos(autocvar_timelimit_overtime),
1684                         minutesPlural,
1685                         " to the game!"
1686                 )
1687         );
1688 }
1689
1690 float GetWinningCode(float fraglimitreached, float equality)
1691 {
1692         if(autocvar_g_campaign == 1)
1693                 if(fraglimitreached)
1694                         return WINNING_YES;
1695                 else
1696                         return WINNING_NO;
1697
1698         else
1699                 if(equality)
1700                         if(fraglimitreached)
1701                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1702                         else
1703                                 return WINNING_NEVER;
1704                 else
1705                         if(fraglimitreached)
1706                                 return WINNING_YES;
1707                         else
1708                                 return WINNING_NO;
1709 }
1710
1711 // set the .winning flag for exactly those players with a given field value
1712 void SetWinners(.float field, float value)
1713 {
1714         entity head;
1715         FOR_EACH_PLAYER(head)
1716                 head.winning = (head.field == value);
1717 }
1718
1719 // set the .winning flag for those players with a given field value
1720 void AddWinners(.float field, float value)
1721 {
1722         entity head;
1723         FOR_EACH_PLAYER(head)
1724                 if(head.field == value)
1725                         head.winning = 1;
1726 }
1727
1728 // clear the .winning flags
1729 void ClearWinners(void)
1730 {
1731         entity head;
1732         FOR_EACH_PLAYER(head)
1733                 head.winning = 0;
1734 }
1735
1736 // Onslaught winning condition:
1737 // game terminates if only one team has a working generator (or none)
1738 float WinningCondition_Onslaught()
1739 {
1740         entity head;
1741         float t1, t2, t3, t4;
1742
1743         WinningConditionHelper(); // set worldstatus
1744
1745         if(inWarmupStage)
1746                 return WINNING_NO;
1747
1748         // first check if the game has ended
1749         t1 = t2 = t3 = t4 = 0;
1750         head = find(world, classname, "onslaught_generator");
1751         while (head)
1752         {
1753                 if (head.health > 0)
1754                 {
1755                         if (head.team == COLOR_TEAM1) t1 = 1;
1756                         if (head.team == COLOR_TEAM2) t2 = 1;
1757                         if (head.team == COLOR_TEAM3) t3 = 1;
1758                         if (head.team == COLOR_TEAM4) t4 = 1;
1759                 }
1760                 head = find(head, classname, "onslaught_generator");
1761         }
1762         if (t1 + t2 + t3 + t4 < 2)
1763         {
1764                 // game over, only one team remains (or none)
1765                 ClearWinners();
1766                 if (t1) SetWinners(team, COLOR_TEAM1);
1767                 if (t2) SetWinners(team, COLOR_TEAM2);
1768                 if (t3) SetWinners(team, COLOR_TEAM3);
1769                 if (t4) SetWinners(team, COLOR_TEAM4);
1770                 dprint("Have a winner, ending game.\n");
1771                 return WINNING_YES;
1772         }
1773
1774         // Two or more teams remain
1775         return WINNING_NO;
1776 }
1777
1778 float LMS_NewPlayerLives()
1779 {
1780         float fl;
1781         fl = autocvar_fraglimit;
1782         if(fl == 0)
1783                 fl = 999;
1784
1785         // first player has left the game for dying too much? Nobody else can get in.
1786         if(lms_lowest_lives < 1)
1787                 return 0;
1788
1789         if(!autocvar_g_lms_join_anytime)
1790                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1791                         return 0;
1792
1793         return bound(1, lms_lowest_lives, fl);
1794 }
1795
1796 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1797 // they win. Otherwise the defending team wins once the timelimit passes.
1798 void assault_new_round();
1799 float WinningCondition_Assault()
1800 {
1801         float status;
1802
1803         WinningConditionHelper(); // set worldstatus
1804
1805         status = WINNING_NO;
1806         // as the timelimit has not yet passed just assume the defending team will win
1807         if(assault_attacker_team == COLOR_TEAM1)
1808         {
1809                 SetWinners(team, COLOR_TEAM2);
1810         }
1811         else
1812         {
1813                 SetWinners(team, COLOR_TEAM1);
1814         }
1815
1816         entity ent;
1817         ent = find(world, classname, "target_assault_roundend");
1818         if(ent)
1819         {
1820                 if(ent.winning) // round end has been triggered by attacking team
1821                 {
1822                         bprint("ASSAULT: round completed...\n");
1823                         SetWinners(team, assault_attacker_team);
1824
1825                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1826
1827                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1828                         {
1829                                 status = WINNING_YES;
1830                         }
1831                         else
1832                         {
1833                                 entity oldself;
1834                                 oldself = self;
1835                                 self = ent;
1836                                 assault_new_round();
1837                                 self = oldself;
1838                         }
1839                 }
1840         }
1841
1842         return status;
1843 }
1844
1845 // LMS winning condition: game terminates if and only if there's at most one
1846 // one player who's living lives. Top two scores being equal cancels the time
1847 // limit.
1848 float WinningCondition_LMS()
1849 {
1850         entity head, head2;
1851         float have_player;
1852         float have_players;
1853         float l;
1854
1855         have_player = FALSE;
1856         have_players = FALSE;
1857         l = LMS_NewPlayerLives();
1858
1859         head = find(world, classname, "player");
1860         if(head)
1861                 have_player = TRUE;
1862         head2 = find(head, classname, "player");
1863         if(head2)
1864                 have_players = TRUE;
1865
1866         if(have_player)
1867         {
1868                 // we have at least one player
1869                 if(have_players)
1870                 {
1871                         // two or more active players - continue with the game
1872                 }
1873                 else
1874                 {
1875                         // exactly one player?
1876
1877                         ClearWinners();
1878                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1879
1880                         if(l)
1881                         {
1882                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1883                                 return WINNING_NO;
1884                         }
1885                         else
1886                         {
1887                                 // a winner!
1888                                 // and assign him his first place
1889                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1890                                 return WINNING_YES;
1891                         }
1892                 }
1893         }
1894         else
1895         {
1896                 // nobody is playing at all...
1897                 if(l)
1898                 {
1899                         // wait for players...
1900                 }
1901                 else
1902                 {
1903                         // SNAFU (maybe a draw game?)
1904                         ClearWinners();
1905                         dprint("No players, ending game.\n");
1906                         return WINNING_YES;
1907                 }
1908         }
1909
1910         // When we get here, we have at least two players who are actually LIVING,
1911         // now check if the top two players have equal score.
1912         WinningConditionHelper();
1913
1914         ClearWinners();
1915         if(WinningConditionHelper_winner)
1916                 WinningConditionHelper_winner.winning = TRUE;
1917         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1918                 return WINNING_NEVER;
1919
1920         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1921         return WINNING_NO;
1922 }
1923
1924 void ShuffleMaplist()
1925 {
1926         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1927 }
1928
1929 float leaderfrags;
1930 float WinningCondition_Scores(float limit, float leadlimit)
1931 {
1932         float limitreached;
1933
1934         // TODO make everything use THIS winning condition (except LMS)
1935         WinningConditionHelper();
1936
1937         if(teamplay)
1938         {
1939                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1940                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1941                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1942                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1943         }
1944
1945         ClearWinners();
1946         if(WinningConditionHelper_winner)
1947                 WinningConditionHelper_winner.winning = 1;
1948         if(WinningConditionHelper_winnerteam >= 0)
1949                 SetWinners(team, WinningConditionHelper_winnerteam);
1950
1951         if(WinningConditionHelper_lowerisbetter)
1952         {
1953                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1954                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1955                 limit = -limit;
1956         }
1957
1958         if(WinningConditionHelper_zeroisworst)
1959                 leadlimit = 0; // not supported in this mode
1960
1961         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1962         // these modes always score in increments of 1, thus this makes sense
1963         {
1964                 if(leaderfrags != WinningConditionHelper_topscore)
1965                 {
1966                         leaderfrags = WinningConditionHelper_topscore;
1967
1968                         if (limit)
1969                         if (leaderfrags == limit - 1)
1970                                 Announce("1fragleft");
1971                         else if (leaderfrags == limit - 2)
1972                                 Announce("2fragsleft");
1973                         else if (leaderfrags == limit - 3)
1974                                 Announce("3fragsleft");
1975                 }
1976         }
1977
1978         limitreached = FALSE;
1979         if(limit)
1980                 if(WinningConditionHelper_topscore >= limit)
1981                         limitreached = TRUE;
1982         if(leadlimit)
1983         {
1984                 float leadlimitreached;
1985                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1986                 if(autocvar_leadlimit_and_fraglimit)
1987                         limitreached = (limitreached && leadlimitreached);
1988                 else
1989                         limitreached = (limitreached || leadlimitreached);
1990         }
1991
1992         return GetWinningCode(
1993                 WinningConditionHelper_topscore && limitreached,
1994                 WinningConditionHelper_equality
1995         );
1996 }
1997
1998 float WinningCondition_Race(float fraglimit)
1999 {
2000         float wc;
2001         entity p;
2002         float n, c;
2003
2004         n = 0;
2005         c = 0;
2006         FOR_EACH_PLAYER(p)
2007         {
2008                 ++n;
2009                 if(p.race_completed)
2010                         ++c;
2011         }
2012         if(n && (n == c))
2013                 return WINNING_YES;
2014         wc = WinningCondition_Scores(fraglimit, 0);
2015
2016         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2017         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2018         // do NOT support equality when the laps are all raced!
2019                 return WINNING_STARTSUDDENDEATHOVERTIME;
2020         else
2021                 return WINNING_NEVER;
2022         return wc;
2023 }
2024
2025 void ReadyRestart();
2026 float WinningCondition_QualifyingThenRace(float limit)
2027 {
2028         float wc;
2029         wc = WinningCondition_Scores(limit, 0);
2030
2031         // NEVER initiate overtime
2032         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2033         {
2034                 return WINNING_YES;
2035         }
2036
2037         return wc;
2038 }
2039
2040 float WinningCondition_RanOutOfSpawns()
2041 {
2042         entity head;
2043
2044         if(have_team_spawns <= 0)
2045                 return WINNING_NO;
2046
2047         if(autocvar_g_spawn_useallspawns <= 0)
2048                 return WINNING_NO;
2049
2050         if(!some_spawn_has_been_used)
2051                 return WINNING_NO;
2052
2053         team1_score = team2_score = team3_score = team4_score = 0;
2054
2055         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2056         {
2057                 if(head.team == COLOR_TEAM1)
2058                         team1_score = 1;
2059                 else if(head.team == COLOR_TEAM2)
2060                         team2_score = 1;
2061                 else if(head.team == COLOR_TEAM3)
2062                         team3_score = 1;
2063                 else if(head.team == COLOR_TEAM4)
2064                         team4_score = 1;
2065         }
2066
2067         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2068         {
2069                 if(head.team == COLOR_TEAM1)
2070                         team1_score = 1;
2071                 else if(head.team == COLOR_TEAM2)
2072                         team2_score = 1;
2073                 else if(head.team == COLOR_TEAM3)
2074                         team3_score = 1;
2075                 else if(head.team == COLOR_TEAM4)
2076                         team4_score = 1;
2077         }
2078
2079         ClearWinners();
2080         if(team1_score + team2_score + team3_score + team4_score == 0)
2081         {
2082                 checkrules_equality = TRUE;
2083                 return WINNING_YES;
2084         }
2085         else if(team1_score + team2_score + team3_score + team4_score == 1)
2086         {
2087                 float t, i;
2088                 if(team1_score) t = COLOR_TEAM1;
2089                 if(team2_score) t = COLOR_TEAM2;
2090                 if(team3_score) t = COLOR_TEAM3;
2091                 if(team4_score) t = COLOR_TEAM4;
2092                 CheckAllowedTeams(world);
2093                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2094                 {
2095                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2096                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2097                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2098                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2099                 }
2100
2101                 AddWinners(team, t);
2102                 return WINNING_YES;
2103         }
2104         else
2105                 return WINNING_NO;
2106 }
2107
2108 /*
2109 ============
2110 CheckRules_World
2111
2112 Exit deathmatch games upon conditions
2113 ============
2114 */
2115 void CheckRules_World()
2116 {
2117         float timelimit;
2118         float fraglimit;
2119         float leadlimit;
2120
2121         VoteThink();
2122         MapVote_Think();
2123
2124         SetDefaultAlpha();
2125
2126         /*
2127         MapVote_Think should now do that part
2128         if (intermission_running)
2129                 if (time >= intermission_exittime + 60)
2130                 {
2131                         if(!DoNextMapOverride())
2132                                 GotoNextMap();
2133                         return;
2134                 }
2135         */
2136
2137         if (gameover)   // someone else quit the game already
2138         {
2139                 if(player_count == 0) // Nobody there? Then let's go to the next map
2140                         MapVote_Start();
2141                         // this will actually check the player count in the next frame
2142                         // again, but this shouldn't hurt
2143                 return;
2144         }
2145
2146         timelimit = autocvar_timelimit * 60;
2147         fraglimit = autocvar_fraglimit;
2148         leadlimit = autocvar_leadlimit;
2149
2150         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2151         {
2152                 if(timelimit > 0)
2153                         timelimit = 0; // timelimit is not made for warmup
2154                 if(fraglimit > 0)
2155                         fraglimit = 0; // no fraglimit for now
2156                 leadlimit = 0; // no leadlimit for now
2157         }
2158
2159         if(g_onslaught)
2160                 timelimit = 0; // ONS has its own overtime rule
2161
2162         if(timelimit > 0)
2163         {
2164                 timelimit += game_starttime;
2165         }
2166         else if (timelimit < 0)
2167         {
2168                 // endmatch
2169                 NextLevel();
2170                 return;
2171         }
2172
2173         float wantovertime;
2174         wantovertime = 0;
2175
2176         if(checkrules_suddendeathend)
2177         {
2178                 if(!checkrules_suddendeathwarning)
2179                 {
2180                         checkrules_suddendeathwarning = TRUE;
2181                         if(g_race && !g_race_qualifying)
2182                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2183                         else
2184                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2185                 }
2186         }
2187         else
2188         {
2189                 if (timelimit && time >= timelimit)
2190                 {
2191                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2192                         {
2193                                 float totalplayers;
2194                                 float playerswithlaps;
2195                                 float readyplayers;
2196                                 entity head;
2197                                 totalplayers = playerswithlaps = readyplayers = 0;
2198                                 FOR_EACH_PLAYER(head)
2199                                 {
2200                                         ++totalplayers;
2201                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2202                                                 ++playerswithlaps;
2203                                         if(head.ready)
2204                                                 ++readyplayers;
2205                                 }
2206
2207                                 // at least 2 of the players have completed a lap: start the RACE
2208                                 // otherwise, the players should end the qualifying on their own
2209                                 if(readyplayers || playerswithlaps >= 2)
2210                                 {
2211                                         checkrules_suddendeathend = 0;
2212                                         ReadyRestart(); // go to race
2213                                         return;
2214                                 }
2215                                 else
2216                                         wantovertime |= InitiateSuddenDeath();
2217                         }
2218                         else
2219                                 wantovertime |= InitiateSuddenDeath();
2220                 }
2221         }
2222
2223         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2224         {
2225                 NextLevel();
2226                 return;
2227         }
2228
2229         float checkrules_status;
2230         checkrules_status = WinningCondition_RanOutOfSpawns();
2231         if(checkrules_status == WINNING_YES)
2232         {
2233                 bprint("Hey! Someone ran out of spawns!\n");
2234         }
2235         else if(g_race && !g_race_qualifying && timelimit >= 0)
2236         {
2237                 checkrules_status = WinningCondition_Race(fraglimit);
2238                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2239         }
2240         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2241         {
2242                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2243                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2244         }
2245         else if(g_assault)
2246         {
2247                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2248         }
2249         else if(g_lms)
2250         {
2251                 checkrules_status = WinningCondition_LMS();
2252         }
2253         else if (g_onslaught)
2254         {
2255                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2256         }
2257         else
2258         {
2259                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2260                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2261         }
2262
2263         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2264         {
2265                 checkrules_status = WINNING_NEVER;
2266                 checkrules_overtimesadded = -1;
2267                 wantovertime |= InitiateSuddenDeath();
2268         }
2269
2270         if(checkrules_status == WINNING_NEVER)
2271                 // equality cases! Nobody wins if the overtime ends in a draw.
2272                 ClearWinners();
2273
2274         if(wantovertime)
2275         {
2276                 if(checkrules_status == WINNING_NEVER)
2277                         InitiateOvertime();
2278                 else
2279                         checkrules_status = WINNING_YES;
2280         }
2281
2282         if(checkrules_suddendeathend)
2283                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2284                         checkrules_status = WINNING_YES;
2285
2286         if(checkrules_status == WINNING_YES)
2287         {
2288                 //print("WINNING\n");
2289                 NextLevel();
2290         }
2291 }
2292
2293 float mapvote_nextthink;
2294 float mapvote_initialized;
2295 float mapvote_keeptwotime;
2296 float mapvote_timeout;
2297 string mapvote_message;
2298 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2299 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2300 float mapvote_screenshot_dirs_count;
2301
2302 float mapvote_count;
2303 float mapvote_count_real;
2304 string mapvote_maps[MAPVOTE_COUNT];
2305 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2306 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2307 float mapvote_maps_suggested[MAPVOTE_COUNT];
2308 string mapvote_suggestions[MAPVOTE_COUNT];
2309 float mapvote_suggestion_ptr;
2310 float mapvote_voters;
2311 float mapvote_votes[MAPVOTE_COUNT];
2312 float mapvote_run;
2313 float mapvote_detail;
2314 float mapvote_abstain;
2315 .float mapvote;
2316
2317 void MapVote_ClearAllVotes()
2318 {
2319         FOR_EACH_CLIENT(other)
2320                 other.mapvote = 0;
2321 }
2322
2323 string MapVote_Suggest(string m)
2324 {
2325         float i;
2326         if(m == "")
2327                 return "That's not how to use this command.";
2328         if(!autocvar_g_maplist_votable_suggestions)
2329                 return "Suggestions are not accepted on this server.";
2330         if(mapvote_initialized)
2331                 return "Can't suggest - voting is already in progress!";
2332         m = MapInfo_FixName(m);
2333         if(!m)
2334                 return "The map you suggested is not available on this server.";
2335         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2336                 if(Map_IsRecent(m))
2337                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2338
2339         if(!MapInfo_CheckMap(m))
2340                 return "The map you suggested does not support the current game mode.";
2341         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2342                 if(mapvote_suggestions[i] == m)
2343                         return "This map was already suggested.";
2344         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2345         {
2346                 i = floor(random() * mapvote_suggestion_ptr);
2347         }
2348         else
2349         {
2350                 i = mapvote_suggestion_ptr;
2351                 mapvote_suggestion_ptr += 1;
2352         }
2353         if(mapvote_suggestions[i] != "")
2354                 strunzone(mapvote_suggestions[i]);
2355         mapvote_suggestions[i] = strzone(m);
2356         if(autocvar_sv_eventlog)
2357                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2358         return strcat("Suggestion of ", m, " accepted.");
2359 }
2360
2361 void MapVote_AddVotable(string nextMap, float isSuggestion)
2362 {
2363         float j, i, o;
2364         string pakfile, mapfile;
2365
2366         if(nextMap == "")
2367                 return;
2368         for(j = 0; j < mapvote_count; ++j)
2369                 if(mapvote_maps[j] == nextMap)
2370                         return;
2371         // suggestions might be no longer valid/allowed after gametype switch!
2372         if(isSuggestion)
2373                 if(!MapInfo_CheckMap(nextMap))
2374                         return;
2375         mapvote_maps[mapvote_count] = strzone(nextMap);
2376         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2377
2378         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2379         {
2380                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2381                 pakfile = whichpack(strcat(mapfile, ".tga"));
2382                 if(pakfile == "")
2383                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2384                 if(pakfile == "")
2385                         pakfile = whichpack(strcat(mapfile, ".png"));
2386                 if(pakfile != "")
2387                         break;
2388         }
2389         if(i >= mapvote_screenshot_dirs_count)
2390                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2391         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2392                 pakfile = substring(pakfile, o, -1);
2393
2394         mapvote_maps_screenshot_dir[mapvote_count] = i;
2395         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2396
2397         mapvote_count += 1;
2398 }
2399
2400 void MapVote_Spawn();
2401 void MapVote_Init()
2402 {
2403         float i;
2404         float nmax, smax;
2405
2406         MapVote_ClearAllVotes();
2407
2408         mapvote_count = 0;
2409         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2410         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2411
2412         if(mapvote_abstain)
2413                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2414         else
2415                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2416         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2417
2418         // we need this for AddVotable, as that cycles through the screenshot dirs
2419         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2420         if(mapvote_screenshot_dirs_count == 0)
2421                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2422         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2423         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2424                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2425
2426         if(mapvote_suggestion_ptr)
2427                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2428                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2429
2430         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2431                 MapVote_AddVotable(GetNextMap(), FALSE);
2432
2433         if(mapvote_count == 0)
2434         {
2435                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2436                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2437                 if(autocvar_g_maplist_shuffle)
2438                         ShuffleMaplist();
2439                 localcmd("\nmenu_cmd sync\n");
2440                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2441                         MapVote_AddVotable(GetNextMap(), FALSE);
2442         }
2443
2444         mapvote_count_real = mapvote_count;
2445         if(mapvote_abstain)
2446                 MapVote_AddVotable("don't care", 0);
2447
2448         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2449
2450         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2451         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2452         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2453                 mapvote_keeptwotime = 0;
2454         mapvote_message = "Choose a map and press its key!";
2455
2456         MapVote_Spawn();
2457 }
2458
2459 void MapVote_SendPicture(float id)
2460 {
2461         msg_entity = self;
2462         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2463         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2464         WriteByte(MSG_ONE, id);
2465         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2466 }
2467
2468 float GameCommand_MapVote(string cmd)
2469 {
2470         if(!intermission_running)
2471                 return FALSE;
2472
2473         if(cmd == "mv_getpic")
2474         {
2475                 MapVote_SendPicture(stof(argv(1)));
2476                 return TRUE;
2477         }
2478
2479         return FALSE;
2480 }
2481
2482 float MapVote_GetMapMask()
2483 {
2484         float mask, i, power;
2485         mask = 0;
2486         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2487                 if(mapvote_maps[i] != "")
2488                         mask |= power;
2489         return mask;
2490 }
2491
2492 entity mapvote_ent;
2493 float MapVote_SendEntity(entity to, float sf)
2494 {
2495         float i;
2496
2497         if(sf & 1)
2498                 sf &~= 2; // if we send 1, we don't need to also send 2
2499
2500         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2501         WriteByte(MSG_ENTITY, sf);
2502
2503         if(sf & 1)
2504         {
2505                 // flag 1 == initialization
2506                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2507                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2508                 WriteString(MSG_ENTITY, "");
2509                 WriteByte(MSG_ENTITY, mapvote_count);
2510                 WriteByte(MSG_ENTITY, mapvote_abstain);
2511                 WriteByte(MSG_ENTITY, mapvote_detail);
2512                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2513                 if(mapvote_count <= 8)
2514                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2515                 else
2516                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2517                 for(i = 0; i < mapvote_count; ++i)
2518                         if(mapvote_maps[i] != "")
2519                         {
2520                                 if(mapvote_abstain && i == mapvote_count - 1)
2521                                 {
2522                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2523                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2524                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2525                                 }
2526                                 else
2527                                 {
2528                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2529                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2530                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2531                                 }
2532                         }
2533         }
2534
2535         if(sf & 2)
2536         {
2537                 // flag 2 == update of mask
2538                 if(mapvote_count <= 8)
2539                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2540                 else
2541                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2542         }
2543
2544         if(sf & 4)
2545         {
2546                 if(mapvote_detail)
2547                         for(i = 0; i < mapvote_count; ++i)
2548                                 if(mapvote_maps[i] != "")
2549                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2550
2551                 WriteByte(MSG_ENTITY, to.mapvote);
2552         }
2553
2554         return TRUE;
2555 }
2556
2557 void MapVote_Spawn()
2558 {
2559         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2560 }
2561
2562 void MapVote_TouchMask()
2563 {
2564         mapvote_ent.SendFlags |= 2;
2565 }
2566
2567 void MapVote_TouchVotes(entity voter)
2568 {
2569         mapvote_ent.SendFlags |= 4;
2570 }
2571
2572 float MapVote_Finished(float mappos)
2573 {
2574         string result;
2575         float i;
2576         float didntvote;
2577
2578         if(autocvar_sv_eventlog)
2579         {
2580                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2581                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2582                 didntvote = mapvote_voters;
2583                 for(i = 0; i < mapvote_count; ++i)
2584                         if(mapvote_maps[i] != "")
2585                         {
2586                                 didntvote -= mapvote_votes[i];
2587                                 if(i != mappos)
2588                                 {
2589                                         result = strcat(result, ":", mapvote_maps[i]);
2590                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2591                                 }
2592                         }
2593                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2594
2595                 GameLogEcho(result);
2596                 if(mapvote_maps_suggested[mappos])
2597                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2598         }
2599
2600         FOR_EACH_REALCLIENT(other)
2601                 FixClientCvars(other);
2602
2603         Map_Goto_SetStr(mapvote_maps[mappos]);
2604         Map_Goto();
2605         alreadychangedlevel = TRUE;
2606         return TRUE;
2607 }
2608 void MapVote_CheckRules_1()
2609 {
2610         float i;
2611
2612         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2613         {
2614                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2615                 mapvote_votes[i] = 0;
2616         }
2617
2618         mapvote_voters = 0;
2619         FOR_EACH_REALCLIENT(other)
2620         {
2621                 ++mapvote_voters;
2622                 if(other.mapvote)
2623                 {
2624                         i = other.mapvote - 1;
2625                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2626                         mapvote_votes[i] = mapvote_votes[i] + 1;
2627                 }
2628         }
2629 }
2630
2631 float MapVote_CheckRules_2()
2632 {
2633         float i;
2634         float firstPlace, secondPlace;
2635         float firstPlaceVotes, secondPlaceVotes;
2636         float mapvote_voters_real;
2637         string result;
2638
2639         if(mapvote_count_real == 1)
2640                 return MapVote_Finished(0);
2641
2642         mapvote_voters_real = mapvote_voters;
2643         if(mapvote_abstain)
2644                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2645
2646         RandomSelection_Init();
2647         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2648                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2649         firstPlace = RandomSelection_chosen_float;
2650         firstPlaceVotes = RandomSelection_best_priority;
2651         //dprint("First place: ", ftos(firstPlace), "\n");
2652         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2653
2654         RandomSelection_Init();
2655         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2656                 if(i != firstPlace)
2657                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2658         secondPlace = RandomSelection_chosen_float;
2659         secondPlaceVotes = RandomSelection_best_priority;
2660         //dprint("Second place: ", ftos(secondPlace), "\n");
2661         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2662
2663         if(firstPlace == -1)
2664                 error("No first place in map vote... WTF?");
2665
2666         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2667                 return MapVote_Finished(firstPlace);
2668
2669         if(mapvote_keeptwotime)
2670                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2671                 {
2672                         float didntvote;
2673                         MapVote_TouchMask();
2674                         mapvote_message = "Now decide between the TOP TWO!";
2675                         mapvote_keeptwotime = 0;
2676                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2677                         result = strcat(result, ":", ftos(firstPlaceVotes));
2678                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2679                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2680                         didntvote = mapvote_voters;
2681                         for(i = 0; i < mapvote_count; ++i)
2682                                 if(mapvote_maps[i] != "")
2683                                 {
2684                                         didntvote -= mapvote_votes[i];
2685                                         if(i != firstPlace)
2686                                                 if(i != secondPlace)
2687                                                 {
2688                                                         result = strcat(result, ":", mapvote_maps[i]);
2689                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2690                                                         if(i < mapvote_count_real)
2691                                                         {
2692                                                                 strunzone(mapvote_maps[i]);
2693                                                                 mapvote_maps[i] = "";
2694                                                                 strunzone(mapvote_maps_pakfile[i]);
2695                                                                 mapvote_maps_pakfile[i] = "";
2696                                                         }
2697                                                 }
2698                                 }
2699                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2700                         if(autocvar_sv_eventlog)
2701                                 GameLogEcho(result);
2702                 }
2703
2704         return FALSE;
2705 }
2706 void MapVote_Tick()
2707 {
2708         float keeptwo;
2709         float totalvotes;
2710
2711         keeptwo = mapvote_keeptwotime;
2712         MapVote_CheckRules_1(); // count
2713         if(MapVote_CheckRules_2()) // decide
2714                 return;
2715
2716         totalvotes = 0;
2717         FOR_EACH_REALCLIENT(other)
2718         {
2719                 // hide scoreboard again
2720                 if(other.health != 2342)
2721                 {
2722                         other.health = 2342;
2723                         other.impulse = 0;
2724                         if(clienttype(other) == CLIENTTYPE_REAL)
2725                         {
2726                                 msg_entity = other;
2727                                 WriteByte(MSG_ONE, SVC_FINALE);
2728                                 WriteString(MSG_ONE, "");
2729                         }
2730                 }
2731
2732                 // clear possibly invalid votes
2733                 if(mapvote_maps[other.mapvote - 1] == "")
2734                         other.mapvote = 0;
2735                 // use impulses as new vote
2736                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2737                         if(mapvote_maps[other.impulse - 1] != "")
2738                         {
2739                                 other.mapvote = other.impulse;
2740                                 MapVote_TouchVotes(other);
2741                         }
2742                 other.impulse = 0;
2743
2744                 if(other.mapvote)
2745                         ++totalvotes;
2746         }
2747
2748         MapVote_CheckRules_1(); // just count
2749 }
2750 void MapVote_Start()
2751 {
2752         if(mapvote_run)
2753                 return;
2754
2755         // wait for stats to be sent first
2756         if(!playerstats_waitforme)
2757                 return;
2758
2759         MapInfo_Enumerate();
2760         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2761                 mapvote_run = TRUE;
2762 }
2763 void MapVote_Think()
2764 {
2765         if(!mapvote_run)
2766                 return;
2767
2768         if(alreadychangedlevel)
2769                 return;
2770
2771         if(time < mapvote_nextthink)
2772                 return;
2773         //dprint("tick\n");
2774
2775         mapvote_nextthink = time + 0.5;
2776
2777         if(!mapvote_initialized)
2778         {
2779                 if(autocvar_rescan_pending == 1)
2780                 {
2781                         cvar_set("rescan_pending", "2");
2782                         localcmd("fs_rescan\nrescan_pending 3\n");
2783                         return;
2784                 }
2785                 else if(autocvar_rescan_pending == 2)
2786                 {
2787                         return;
2788                 }
2789                 else if(autocvar_rescan_pending == 3)
2790                 {
2791                         // now build missing mapinfo files
2792                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2793                                 return;
2794
2795                         // we're done, start the timer
2796                         cvar_set("rescan_pending", "0");
2797                 }
2798
2799                 mapvote_initialized = TRUE;
2800                 if(DoNextMapOverride())
2801                         return;
2802                 if(!autocvar_g_maplist_votable || player_count <= 0)
2803                 {
2804                         GotoNextMap();
2805                         return;
2806                 }
2807                 MapVote_Init();
2808         }
2809
2810         MapVote_Tick();
2811 }
2812
2813 string GotoMap(string m)
2814 {
2815         if(!MapInfo_CheckMap(m))
2816                 return "The map you chose is not available on this server.";
2817         cvar_set("nextmap", m);
2818         cvar_set("timelimit", "-1");
2819         if(mapvote_initialized || alreadychangedlevel)
2820         {
2821                 if(DoNextMapOverride())
2822                         return "Map switch initiated.";
2823                 else
2824                         return "Hm... no. For some reason I like THIS map more.";
2825         }
2826         else
2827                 return "Map switch will happen after scoreboard.";
2828 }
2829
2830
2831 void EndFrame()
2832 {
2833         float altime;
2834         FOR_EACH_REALCLIENT(self)
2835         {
2836                 if(self.classname == "spectator")
2837                 {
2838                         if(self.enemy.typehitsound)
2839                                 self.typehit_time = time;
2840                         else if(self.enemy.hitsound)
2841                                 self.hit_time = time;
2842                 }
2843                 else
2844                 {
2845                         if(self.typehitsound)
2846                                 self.typehit_time = time;
2847                         else if(self.hitsound)
2848                                 self.hit_time = time;
2849                 }
2850         }
2851         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2852         // add 1 frametime because after this, engine SV_Physics
2853         // increases time by a frametime and then networks the frame
2854         // add another frametime because client shows everything with
2855         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2856         // needed!
2857         FOR_EACH_CLIENT(self)
2858         {
2859                 self.hitsound = FALSE;
2860                 self.typehitsound = FALSE;
2861                 antilag_record(self, altime);
2862         }
2863 }
2864
2865
2866 /*
2867  * RedirectionThink:
2868  * returns TRUE if redirecting
2869  */
2870 float redirection_timeout;
2871 float redirection_nextthink;
2872 float RedirectionThink()
2873 {
2874         float clients_found;
2875
2876         if(redirection_target == "")
2877                 return FALSE;
2878
2879         if(!redirection_timeout)
2880         {
2881                 cvar_set("sv_public", "-2");
2882                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2883                 if(redirection_target == "self")
2884                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2885                 else
2886                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2887         }
2888
2889         if(time < redirection_nextthink)
2890                 return TRUE;
2891
2892         redirection_nextthink = time + 1;
2893
2894         clients_found = 0;
2895         FOR_EACH_REALCLIENT(self)
2896         {
2897                 print("Redirecting: sending connect command to ", self.netname, "\n");
2898                 if(redirection_target == "self")
2899                         stuffcmd(self, "\ndisconnect; reconnect\n");
2900                 else
2901                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2902                 ++clients_found;
2903         }
2904
2905         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2906
2907         if(time > redirection_timeout || clients_found == 0)
2908                 localcmd("\nwait; wait; wait; quit\n");
2909
2910         return TRUE;
2911 }
2912
2913 void TargetMusic_RestoreGame();
2914 void RestoreGame()
2915 {
2916         // Loaded from a save game
2917         // some things then break, so let's work around them...
2918
2919         // Progs DB (capture records)
2920         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2921
2922         // Mapinfo
2923         MapInfo_Shutdown();
2924         MapInfo_Enumerate();
2925         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2926         WeaponStats_Init();
2927
2928         TargetMusic_RestoreGame();
2929 }
2930
2931 void SV_Shutdown()
2932 {
2933         entity e;
2934
2935         if(gameover > 1) // shutting down already?
2936                 return;
2937
2938         gameover = 2; // 2 = server shutting down
2939
2940         if(world_initialized > 0)
2941         {
2942                 world_initialized = 0;
2943                 print("Saving persistent data...\n");
2944                 Ban_SaveBans();
2945
2946                 PlayerStats_EndMatch(0);
2947                 FOR_EACH_CLIENT(e)
2948                         PlayerStats_AddGlobalInfo(e);
2949                 PlayerStats_Shutdown();
2950
2951                 if(!cheatcount_total)
2952                 {
2953                         if(autocvar_sv_db_saveasdump)
2954                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2955                         else
2956                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2957                 }
2958                 if(autocvar_developer)
2959                 {
2960                         if(autocvar_sv_db_saveasdump)
2961                                 db_dump(TemporaryDB, "server-temp.db");
2962                         else
2963                                 db_save(TemporaryDB, "server-temp.db");
2964                 }
2965                 CheatShutdown(); // must be after cheatcount check
2966                 db_close(ServerProgsDB);
2967                 db_close(TemporaryDB);
2968                 print("done!\n");
2969                 // tell the bot system the game is ending now
2970                 bot_endgame();
2971
2972                 WeaponStats_Shutdown();
2973                 MapInfo_Shutdown();
2974         }
2975         else if(world_initialized == 0)
2976         {
2977                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2978         }
2979 }