qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("serverconfig");
 276                 BADPREFIX("g_ban_");
 277                 BADPREFIX("g_chat_flood_");
 278                 BADPREFIX("g_voice_flood_");
 279                 BADPREFIX("rcon_");
 280                 BADPREFIX("settemp_");
 281                 BADPREFIX("sv_allowdownloads_");
 282                 BADPREFIX("sv_autodemo");
 283                 BADPREFIX("sv_curl_");
 284                 BADPREFIX("sv_eventlog");
 285                 BADPREFIX("sv_logscores_");
 286                 BADPREFIX("sv_master");
 287                 BADCVAR("g_banned_list");
 288                 BADCVAR("log_dest_udp");
 289                 BADCVAR("log_file");
 290                 BADCVAR("net_address");
 291                 BADCVAR("port");
 292                 BADCVAR("savedgamecfg");
 293                 BADCVAR("sv_heartbeatperiod");
 294                 BADCVAR("sv_vote_master_password");
 295                 BADCVAR("sys_colortranslation");
 296                 BADCVAR("sys_specialcharactertranslation");
 297                 BADCVAR("timestamps");
 298                 BADCVAR("net_address");
 299                 BADCVAR("net_address_ipv6");
 300                 BADPREFIX("sv_weaponstats_");
 301                 BADCVAR("developer");
 302                 BADPREFIX("developer_");
 303
 304                 // mapinfo
 305                 BADCVAR("timelimit");
 306                 BADCVAR("fraglimit");
 307                 BADCVAR("leadlimit");
 308                 BADCVAR("g_tdm_teams");
 309                 BADCVAR("g_keyhunt_teams");
 310                 BADCVAR("g_domination_default_teams");
 311                 BADCVAR("g_race_qualifying_timelimit");
 312                 BADCVAR("g_lms");
 313                 BADCVAR("g_arena");
 314                 BADCVAR("g_ca");
 315                 BADCVAR("g_assault");
 316                 BADCVAR("g_ctf");
 317                 BADCVAR("g_dm");
 318                 BADCVAR("g_domination");
 319                 BADCVAR("g_keyhunt");
 320                 BADCVAR("g_keyhunt_teams");
 321                 BADCVAR("g_onslaught");
 322                 BADCVAR("g_race");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_runematch");
 325                 BADCVAR("g_tdm");
 326                 BADCVAR("g_nexball");
 327                 BADCVAR("teamplay");
 328
 329                 // long
 330                 BADCVAR("hostname");
 331                 BADCVAR("g_maplist");
 332                 BADCVAR("g_maplist_mostrecent");
 333                 BADCVAR("sv_motd");
 334
 335                 v = cvar_string(k);
 336                 d = cvar_defstring(k);
 337                 if(v == d)
 338                         continue;
 339
 340                 if(adding)
 341                 {
 342                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 343                         if(strlen(cvar_changes) > 16384)
 344                         {
 345                                 cvar_changes = "// too many settings have been changed to show them here\n";
 346                                 adding = 0;
 347                         }
 348                 }
 349
 350                 // now check if the changes are actually gameplay relevant
 351
 352                 // does nothing visible
 353                 BADCVAR("captureleadlimit_override");
 354                 BADCVAR("g_arena_point_leadlimit");
 355                 BADCVAR("g_ca_point_leadlimit");
 356                 BADCVAR("g_ctf_capture_leadlimit");
 357                 BADCVAR("g_domination_point_leadlimit");
 358                 BADCVAR("g_keyhunt_point_leadlimit");
 359                 BADCVAR("g_nexball_goalleadlimit");
 360                 BADCVAR("g_runematch_point_leadlimit");
 361                 BADCVAR("leadlimit_and_fraglimit");
 362                 BADCVAR("leadlimit_override");
 363                 BADCVAR("sv_checkforpacketsduringsleep");
 364                 BADPREFIX("crypto_");
 365                 BADPREFIX("g_chat_");
 366                 BADPREFIX("prvm_");
 367                 BADPREFIX("sv_fragmessage_");
 368                 BADPREFIX("sv_vote_");
 369                 BADPREFIX("timelimit_");
 370
 371                 // allowed changes to server admins (please sync this to server.cfg)
 372                 // vi commands:
 373                 //   :/"impure"/,$d
 374                 //   :g!,^\/\/[^ /],d
 375                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 376                 //   :%!sort
 377                 // yes, this does contain some redundant stuff, don't really care
 378                 BADCVAR("bot_number");
 379                 BADCVAR("bot_prefix");
 380                 BADCVAR("bot_suffix");
 381                 BADCVAR("capturelimit_override");
 382                 BADCVAR("fraglimit_override");
 383                 BADCVAR("gametype");
 384                 BADCVAR("g_antilag");
 385                 BADCVAR("g_balance_teams");
 386                 BADCVAR("g_balance_teams_force");
 387                 BADCVAR("g_ban_sync_trusted_servers");
 388                 BADCVAR("g_ban_sync_uri");
 389                 BADCVAR("g_ctf_capture_limit");
 390                 BADCVAR("g_ctf_ignore_frags");
 391                 BADCVAR("g_ctf_win_mode");
 392                 BADCVAR("g_domination_point_limit");
 393                 BADCVAR("g_fullbrightitems");
 394                 BADCVAR("g_fullbrightplayers");
 395                 BADCVAR("g_keyhunt_point_limit");
 396                 BADCVAR("g_keyhunt_teams_override");
 397                 BADCVAR("g_lms_lives_override");
 398                 BADCVAR("g_maplist");
 399                 BADCVAR("g_maplist_check_waypoints");
 400                 BADCVAR("g_maplist_mostrecent_count");
 401                 BADCVAR("g_maplist_shuffle");
 402                 BADCVAR("g_maplist_votable");
 403                 BADCVAR("g_maplist_votable_abstain");
 404                 BADCVAR("g_maplist_votable_nodetail");
 405                 BADCVAR("g_maplist_votable_suggestions");
 406                 BADCVAR("g_minstagib");
 407                 BADCVAR("g_nexball_goallimit");
 408                 BADCVAR("g_runematch_point_limit");
 409                 BADCVAR("g_start_delay");
 410                 BADCVAR("hostname");
 411                 BADCVAR("log_file");
 412                 BADCVAR("maxplayers");
 413                 BADCVAR("minplayers");
 414                 BADCVAR("net_address");
 415                 BADCVAR("port");
 416                 BADCVAR("rcon_password");
 417                 BADCVAR("rcon_restricted_commands");
 418                 BADCVAR("rcon_restricted_password");
 419                 BADCVAR("skill");
 420                 BADCVAR("sv_adminnick");
 421                 BADCVAR("sv_autoscreenshot");
 422                 BADCVAR("sv_curl_defaulturl");
 423                 BADCVAR("sv_defaultcharacter");
 424                 BADCVAR("sv_defaultplayermodel");
 425                 BADCVAR("sv_defaultplayerskin");
 426                 BADCVAR("sv_maxidle");
 427                 BADCVAR("sv_maxrate");
 428                 BADCVAR("sv_motd");
 429                 BADCVAR("sv_public");
 430                 BADCVAR("sv_ready_restart");
 431                 BADCVAR("sv_status_privacy");
 432                 BADCVAR("sv_vote_call");
 433                 BADCVAR("sv_vote_commands");
 434                 BADCVAR("sv_vote_majority_factor");
 435                 BADCVAR("sv_vote_master");
 436                 BADCVAR("sv_vote_master_commands");
 437                 BADCVAR("sv_vote_master_password");
 438                 BADCVAR("sv_vote_simple_majority_factor");
 439                 BADCVAR("timelimit_override");
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for(;;)
 480         {
 481                 o = world.mins;
 482                 o_x += random() * (world.maxs_x - world.mins_x);
 483                 o_y += random() * (world.maxs_y - world.mins_y);
 484                 o_z += random() * (world.maxs_z - world.mins_z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return TRUE;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         MapInfo_Enumerate();
 554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 555 }
 556
 557 void Map_MarkAsRecent(string m);
 558 float world_already_spawned;
 559 void RegisterWeapons();
 560 void Nagger_Init();
 561 void ClientInit_Spawn();
 562 void WeaponStats_Init();
 563 void WeaponStats_Shutdown();
 564 void spawnfunc_worldspawn (void)
 565 {
 566         float fd, l, i, j, n;
 567         string s, col;
 568
 569         cvar = cvar_normal;
 570         cvar_string = cvar_string_normal;
 571         cvar_set = cvar_set_normal;
 572
 573         if(world_already_spawned)
 574                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 575         world_already_spawned = TRUE;
 576
 577         remove = remove_safely; // during spawning, watch what you remove!
 578
 579         check_unacceptable_compiler_bugs();
 580
 581         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 582
 583         compressShortVector_init();
 584
 585         allowed_to_spawn = TRUE;
 586
 587         local entity head;
 588         head = nextent(world);
 589         maxclients = 0;
 590         while(head)
 591         {
 592                 ++maxclients;
 593                 head = nextent(head);
 594         }
 595
 596         // needs to be done so early as they would still spawn
 597         RegisterWeapons();
 598
 599         ServerProgsDB = db_load("server.db");
 600
 601         TemporaryDB = db_create();
 602
 603         /*
 604         TODO sound pack system
 605         // initialize sound pack system
 606         soundpack = cvar_string("g_soundpack");
 607         if(soundpack != "")
 608                 soundpack = strcat(soundpack, "/");
 609         soundpack = strzone(soundpack);
 610         */
 611
 612         // 0 normal
 613         lightstyle(0, "m");
 614
 615         // 1 FLICKER (first variety)
 616         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 617
 618         // 2 SLOW STRONG PULSE
 619         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 620
 621         // 3 CANDLE (first variety)
 622         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 623
 624         // 4 FAST STROBE
 625         lightstyle(4, "mamamamamama");
 626
 627         // 5 GENTLE PULSE 1
 628         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 629
 630         // 6 FLICKER (second variety)
 631         lightstyle(6, "nmonqnmomnmomomno");
 632
 633         // 7 CANDLE (second variety)
 634         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 635
 636         // 8 CANDLE (third variety)
 637         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 638
 639         // 9 SLOW STROBE (fourth variety)
 640         lightstyle(9, "aaaaaaaazzzzzzzz");
 641
 642         // 10 FLUORESCENT FLICKER
 643         lightstyle(10, "mmamammmmammamamaaamammma");
 644
 645         // 11 SLOW PULSE NOT FADE TO BLACK
 646         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 647
 648         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 649
 650         // 63 testing
 651         lightstyle(63, "a");
 652
 653         if(cvar("g_campaign"))
 654                 CampaignPreInit();
 655
 656         Map_MarkAsRecent(mapname);
 657
 658         precache_model ("null"); // we need this one before InitGameplayMode
 659         InitGameplayMode();
 660         readlevelcvars();
 661         GrappleHookInit();
 662         ElectroInit();
 663         LaserInit();
 664
 665         player_count = 0;
 666         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 667         if(bot_waypoints_for_items == 1)
 668                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 669                         bot_waypoints_for_items = 0;
 670
 671         // for setting by mapinfo
 672         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 673         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 674
 675         precache();
 676
 677         WaypointSprite_Init();
 678
 679         //if (g_domination)
 680         //      dom_init();
 681
 682         GameLogInit(); // prepare everything
 683         if(cvar("sv_eventlog"))
 684         {
 685                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 686                 s = strcat(s, ftos(random()));
 687                 matchid = strzone(s);
 688
 689                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 690                 s = ":gameinfo:mutators:LIST";
 691
 692                 ret_string = s;
 693                 MUTATOR_CALLHOOK(BuildMutatorsString);
 694                 s = ret_string;
 695
 696                 // simple, probably not good in the mutator system
 697                 if(cvar("g_grappling_hook"))
 698                         s = strcat(s, ":grappling_hook");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(!cvar("g_use_ammunition"))
 702                         s = strcat(s, ":no_use_ammunition");
 703
 704                 // initialiation stuff, not good in the mutator system
 705                 if(!cvar("g_pickup_items"))
 706                         s = strcat(s, ":no_pickup_items");
 707
 708                 // initialiation stuff, not good in the mutator system
 709                 if(cvar_string("g_weaponarena") != "0")
 710                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 711
 712                 // TODO to mutator system
 713                 if(cvar("g_vampire"))
 714                         s = strcat(s, ":vampire");
 715
 716                 // TODO to mutator system
 717                 if(cvar("g_norecoil"))
 718                         s = strcat(s, ":norecoil");
 719
 720                 // TODO to mutator system
 721                 if(cvar("g_midair"))
 722                         s = strcat(s, ":midair");
 723
 724                 // TODO to mutator system
 725                 if(cvar("g_minstagib"))
 726                         s = strcat(s, ":minstagib");
 727                 GameLogEcho(s);
 728                 GameLogEcho(":gameinfo:end");
 729         }
 730         else
 731                 matchid = strzone(ftos(random()));
 732
 733         cvar_set("nextmap", "");
 734
 735         SetDefaultAlpha();
 736
 737         if(cvar("g_campaign"))
 738                 CampaignPostInit();
 739
 740         fteqcc_testbugs();
 741
 742         Ban_LoadBans();
 743
 744         MapInfo_Enumerate();
 745         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 746
 747         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 748         {
 749                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 750                 if(fd != -1)
 751                 {
 752                         while((s = fgets(fd)))
 753                         {
 754                                 l = tokenize_console(s);
 755                                 if(l < 2)
 756                                         continue;
 757                                 if(argv(0) == "cd")
 758                                 {
 759                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 760                                         print("  cdtrack ", argv(2), "\n");
 761                                 }
 762                                 else if(argv(0) == "fog")
 763                                 {
 764                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 765                                         print("  \"fog\" \"", s, "\"\n");
 766                                 }
 767                                 else if(argv(0) == "set")
 768                                 {
 769                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 770                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 771                                 }
 772                                 else if(argv(0) != "//")
 773                                 {
 774                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 775                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 776                                 }
 777                         }
 778                         fclose(fd);
 779                 }
 780         }
 781
 782         WeaponStats_Init();
 783
 784         addstat(STAT_WEAPONS, AS_INT, weapons);
 785         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 786         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 787         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 788         Nagger_Init();
 789
 790         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 791         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 792         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 793         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 794         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 795         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 796         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 797         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 798         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 799         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 800
 801         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 802
 803         if(g_ca)
 804         {
 805                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 806                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 807         }
 808         // g_movementspeed hack
 809         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 810         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 811         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 812
 813         next_pingtime = time + 5;
 814
 815         detect_maptype();
 816
 817         lsmaps_reply = "^7Maps available: ";
 818         lsnewmaps_reply = "^7Maps without a record set: ";
 819         for(i = 0, j = 0; i < MapInfo_count; ++i)
 820         {
 821                 if(MapInfo_Get_ByID(i))
 822                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 823                         {
 824                                 if(mod(i, 2))
 825                                         col = "^2";
 826                                 else
 827                                         col = "^3";
 828                                 ++j;
 829                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 830                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 831                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 832                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 833                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 834                         }
 835         }
 836         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 837         if (!g_race && !g_cts)
 838                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 839         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 840
 841         maplist_reply = "^7Maps in list: ";
 842         n = tokenize_console(cvar_string("g_maplist"));
 843         for(i = 0, j = 0; i < n; ++i)
 844         {
 845                 if(MapInfo_CheckMap(argv(i)))
 846                 {
 847                         if(mod(j, 2))
 848                                 col = "^2";
 849                         else
 850                                 col = "^3";
 851                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 852                         ++j;
 853                 }
 854         }
 855         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 856         MapInfo_ClearTemps();
 857
 858         for(i = 0; i < 10; ++i)
 859         {
 860                 records_reply[i] = strzone(getrecords(i));
 861         }
 862         if(g_cts)
 863                 ladder_reply = strzone(getladder());
 864
 865         rankings_reply = strzone(getrankings());
 866
 867         ClientInit_Spawn();
 868         RandomSeed_Spawn();
 869         PingPLReport_Spawn();
 870
 871         CheatInit();
 872
 873         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 874
 875         // fill sv_curl_serverpackages from .serverpackage files
 876         if(cvar("sv_curl_serverpackages_auto"))
 877         {
 878                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 879                 s = "";
 880                 if(fd >= 0)
 881                 {
 882                         j = search_getsize(fd);
 883                         for(i = 0; i < j; ++i)
 884                                 s = strcat(s, " ", search_getfilename(fd, i));
 885                         search_end(fd);
 886                 }
 887                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 888         }
 889
 890         world_initialized = 1;
 891 }
 892
 893 void spawnfunc_light (void)
 894 {
 895         //makestatic (self); // Who the f___ did that?
 896         remove(self);
 897 }
 898
 899 float TryFile( string pFilename )
 900 {
 901         local float lHandle;
 902         dprint("TryFile(\"", pFilename, "\")\n");
 903         lHandle = fopen( pFilename, FILE_READ );
 904         if( lHandle != -1 ) {
 905                 fclose( lHandle );
 906                 return TRUE;
 907         } else {
 908                 return FALSE;
 909         }
 910 };
 911
 912 string GetGametype()
 913 {
 914         return GametypeNameFromType(game);
 915 }
 916
 917 string getmapname_stored;
 918 string GetMapname()
 919 {
 920         return mapname;
 921 }
 922
 923 float Map_Count, Map_Current;
 924 string Map_Current_Name;
 925
 926 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 927 float GetMaplistPosition()
 928 {
 929         float pos, idx;
 930         string map;
 931
 932         map = GetMapname();
 933         idx = cvar("g_maplist_index");
 934
 935         if(idx >= 0)
 936                 if(idx < Map_Count)
 937                         if(map == argv(idx))
 938                                 return idx;
 939
 940         for(pos = 0; pos < Map_Count; ++pos)
 941                 if(map == argv(pos))
 942                         return pos;
 943
 944         // resume normal maplist rotation if current map is not in g_maplist
 945         return idx;
 946 }
 947
 948 float MapHasRightSize(string map)
 949 {
 950         float fh;
 951         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 952         if(cvar("g_maplist_check_waypoints"))
 953         {
 954                 dprint("checkwp "); dprint(map);
 955                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 956                 if(fh < 0)
 957                 {
 958                         dprint(": no waypoints\n");
 959                         return FALSE;
 960                 }
 961                 dprint(": has waypoints\n");
 962                 fclose(fh);
 963         }
 964
 965         // open map size restriction file
 966         dprint("opensize "); dprint(map);
 967         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 968         if(fh >= 0)
 969         {
 970                 float mapmin, mapmax;
 971                 dprint(": ok, ");
 972                 mapmin = stof(fgets(fh));
 973                 mapmax = stof(fgets(fh));
 974                 fclose(fh);
 975                 if(player_count < mapmin)
 976                 {
 977                         dprint("not enough\n");
 978                         return FALSE;
 979                 }
 980                 if(player_count > mapmax)
 981                 {
 982                         dprint("too many\n");
 983                         return FALSE;
 984                 }
 985                 dprint("right size\n");
 986                 return TRUE;
 987         }
 988         dprint(": not found\n");
 989         return TRUE;
 990 }
 991
 992 string Map_Filename(float position)
 993 {
 994         return strcat("maps/", argv(position), ".bsp");
 995 }
 996
 997 string strwords(string s, float w)
 998 {
 999         float endpos;
1000         for(endpos = 0; w && endpos >= 0; --w)
1001                 endpos = strstrofs(s, " ", endpos + 1);
1002         if(endpos < 0)
1003                 return s;
1004         else
1005                 return substring(s, 0, endpos);
1006 }
1007
1008 float strhasword(string s, string w)
1009 {
1010         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1011 }
1012
1013 void Map_MarkAsRecent(string m)
1014 {
1015         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1016 }
1017
1018 float Map_IsRecent(string m)
1019 {
1020         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1021 }
1022
1023 float Map_Check(float position, float pass)
1024 {
1025         string filename;
1026         string map_next;
1027         map_next = argv(position);
1028         if(pass <= 1)
1029         {
1030                 if(Map_IsRecent(map_next))
1031                         return 0;
1032         }
1033         filename = Map_Filename(position);
1034         if(MapInfo_CheckMap(map_next))
1035         {
1036                 if(pass == 2)
1037                         return 1;
1038                 if(MapHasRightSize(map_next))
1039                         return 1;
1040                 return 0;
1041         }
1042         else
1043                 dprint( "Couldn't select '", filename, "'..\n" );
1044
1045         return 0;
1046 }
1047
1048 void Map_Goto_SetStr(string nextmapname)
1049 {
1050         if(getmapname_stored != "")
1051                 strunzone(getmapname_stored);
1052         if(nextmapname == "")
1053                 getmapname_stored = "";
1054         else
1055                 getmapname_stored = strzone(nextmapname);
1056 }
1057
1058 void Map_Goto_SetFloat(float position)
1059 {
1060         cvar_set("g_maplist_index", ftos(position));
1061         Map_Goto_SetStr(argv(position));
1062 }
1063
1064 void GameResetCfg()
1065 {
1066         // settings persist, except...
1067         localcmd("\nsettemp_restore\n");
1068 };
1069
1070 void Map_Goto()
1071 {
1072         GameResetCfg();
1073         MapInfo_LoadMap(getmapname_stored);
1074 }
1075
1076 // return codes of map selectors:
1077 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1078 //   -2 = permanent failure
1079 float() MaplistMethod_Iterate = // usual method
1080 {
1081         float pass, i;
1082
1083         for(pass = 1; pass <= 2; ++pass)
1084         {
1085                 for(i = 1; i < Map_Count; ++i)
1086                 {
1087                         float mapindex;
1088                         mapindex = mod(i + Map_Current, Map_Count);
1089                         if(Map_Check(mapindex, pass))
1090                                 return mapindex;
1091                 }
1092         }
1093         return -1;
1094 }
1095
1096 float() MaplistMethod_Repeat = // fallback method
1097 {
1098         if(Map_Check(Map_Current, 2))
1099                 return Map_Current;
1100         return -2;
1101 }
1102
1103 float() MaplistMethod_Random = // random map selection
1104 {
1105         float i, imax;
1106
1107         imax = 42;
1108
1109         for(i = 0; i <= imax; ++i)
1110         {
1111                 float mapindex;
1112                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1113                 if(Map_Check(mapindex, 1))
1114                         return mapindex;
1115         }
1116         return -1;
1117 }
1118
1119 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1120 // the exponent sets a bias on the map selection:
1121 // the higher the exponent, the less likely "shortly repeated" same maps are
1122 {
1123         float i, j, imax, insertpos;
1124
1125         imax = 42;
1126
1127         for(i = 0; i <= imax; ++i)
1128         {
1129                 string newlist;
1130
1131                 // now reinsert this at another position
1132                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1133                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1134                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1135                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1136
1137                 // insert the current map there
1138                 newlist = "";
1139                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1140                         newlist = strcat(newlist, " ", argv(j));
1141                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1142                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1143                         newlist = strcat(newlist, " ", argv(j));
1144                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1145                 cvar_set("g_maplist", newlist);
1146                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1147
1148                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1149                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1150                 if(Map_Check(Map_Current, 1))
1151                         return Map_Current;
1152         }
1153         return -1;
1154 }
1155
1156 void Maplist_Init()
1157 {
1158         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1159         if(Map_Count == 0)
1160         {
1161                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1162                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1163                 if(cvar("g_maplist_shuffle"))
1164                         ShuffleMaplist();
1165                 localcmd("\nmenu_cmd sync\n");
1166                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1167         }
1168         if(Map_Count == 0)
1169                 error("empty maplist, cannot select a new map");
1170         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1171
1172         if(Map_Current_Name)
1173                 strunzone(Map_Current_Name);
1174         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1175         // this may or may not be correct, but who cares, in the worst case a map
1176         // isn't chosen in the first pass that should have been
1177 }
1178
1179 string GetNextMap()
1180 {
1181         float nextMap;
1182
1183         Maplist_Init();
1184         nextMap = -1;
1185
1186         if(nextMap == -1)
1187                 if(cvar("g_maplist_shuffle") > 0)
1188                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1189
1190         if(nextMap == -1)
1191                 if(cvar("g_maplist_selectrandom"))
1192                         nextMap = MaplistMethod_Random();
1193
1194         if(nextMap == -1)
1195                 nextMap = MaplistMethod_Iterate();
1196
1197         if(nextMap == -1)
1198                 nextMap = MaplistMethod_Repeat();
1199
1200         if(nextMap >= 0)
1201         {
1202                 Map_Goto_SetFloat(nextMap);
1203                 return getmapname_stored;
1204         }
1205
1206         return "";
1207 };
1208
1209 float DoNextMapOverride()
1210 {
1211         if(cvar("g_campaign"))
1212         {
1213                 CampaignPostIntermission();
1214                 alreadychangedlevel = TRUE;
1215                 return TRUE;
1216         }
1217         if(cvar("quit_when_empty"))
1218         {
1219                 if(player_count <= currentbots)
1220                 {
1221                         localcmd("quit\n");
1222                         alreadychangedlevel = TRUE;
1223                         return TRUE;
1224                 }
1225         }
1226         if(cvar_string("quit_and_redirect") != "")
1227         {
1228                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1229                 alreadychangedlevel = TRUE;
1230                 return TRUE;
1231         }
1232         if (cvar("samelevel")) // if samelevel is set, stay on same level
1233         {
1234                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1235                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1236                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1237                 localcmd("restart\n");
1238                 //changelevel (mapname);
1239                 alreadychangedlevel = TRUE;
1240                 return TRUE;
1241         }
1242         if(cvar_string("nextmap") != "")
1243                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1244                 {
1245                         Map_Goto_SetStr(cvar_string("nextmap"));
1246                         Map_Goto();
1247                         alreadychangedlevel = TRUE;
1248                         return TRUE;
1249                 }
1250         if(cvar("lastlevel"))
1251         {
1252                 GameResetCfg();
1253                 localcmd("set lastlevel 0\ntogglemenu\n");
1254                 alreadychangedlevel = TRUE;
1255                 return TRUE;
1256         }
1257         return FALSE;
1258 };
1259
1260 void GotoNextMap()
1261 {
1262         //local string nextmap;
1263         //local float n, nummaps;
1264         //local string s;
1265         if (alreadychangedlevel)
1266                 return;
1267         alreadychangedlevel = TRUE;
1268
1269         {
1270                 string nextMap;
1271                 float allowReset;
1272
1273                 for(allowReset = 1; allowReset >= 0; --allowReset)
1274                 {
1275                         nextMap = GetNextMap();
1276                         if(nextMap != "")
1277                                 break;
1278
1279                         if(allowReset)
1280                         {
1281                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1282                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1283                                 if(cvar("g_maplist_shuffle"))
1284                                         ShuffleMaplist();
1285                                 localcmd("\nmenu_cmd sync\n");
1286                         }
1287                         else
1288                         {
1289                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1290                         }
1291                 }
1292                 Map_Goto();
1293         }
1294 };
1295
1296
1297 /*
1298 ============
1299 IntermissionThink
1300
1301 When the player presses attack or jump, change to the next level
1302 ============
1303 */
1304 .float autoscreenshot;
1305 void() MapVote_Start;
1306 void() MapVote_Think;
1307 float mapvote_initialized;
1308 void IntermissionThink()
1309 {
1310         FixIntermissionClient(self);
1311
1312         if(cvar("sv_autoscreenshot"))
1313         if(self.autoscreenshot > 0)
1314         if(time > self.autoscreenshot)
1315         {
1316                 self.autoscreenshot = -1;
1317                 if(clienttype(self) == CLIENTTYPE_REAL)
1318                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1319                 return;
1320         }
1321
1322         if (time < intermission_exittime)
1323                 return;
1324
1325         if(!mapvote_initialized)
1326                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1327                         return;
1328
1329         MapVote_Start();
1330 };
1331
1332 /*
1333 ============
1334 FindIntermission
1335
1336 Returns the entity to view from
1337 ============
1338 */
1339 /*
1340 entity FindIntermission()
1341 {
1342         local   entity spot;
1343         local   float cyc;
1344
1345 // look for info_intermission first
1346         spot = find (world, classname, "info_intermission");
1347         if (spot)
1348         {       // pick a random one
1349                 cyc = random() * 4;
1350                 while (cyc > 1)
1351                 {
1352                         spot = find (spot, classname, "info_intermission");
1353                         if (!spot)
1354                                 spot = find (spot, classname, "info_intermission");
1355                         cyc = cyc - 1;
1356                 }
1357                 return spot;
1358         }
1359
1360 // then look for the start position
1361         spot = find (world, classname, "info_player_start");
1362         if (spot)
1363                 return spot;
1364
1365 // testinfo_player_start is only found in regioned levels
1366         spot = find (world, classname, "testplayerstart");
1367         if (spot)
1368                 return spot;
1369
1370 // then look for the start position
1371         spot = find (world, classname, "info_player_deathmatch");
1372         if (spot)
1373                 return spot;
1374
1375         //objerror ("FindIntermission: no spot");
1376         return world;
1377 };
1378 */
1379
1380 /*
1381 ===============================================================================
1382
1383 RULES
1384
1385 ===============================================================================
1386 */
1387
1388 void DumpStats(float final)
1389 {
1390         local float file;
1391         local string s;
1392         local float to_console;
1393         local float to_eventlog;
1394         local float to_file;
1395         local float i;
1396
1397         to_console = cvar("sv_logscores_console");
1398         to_eventlog = cvar("sv_eventlog");
1399         to_file = cvar("sv_logscores_file");
1400
1401         if(!final)
1402         {
1403                 to_console = TRUE; // always print printstats replies
1404                 to_eventlog = FALSE; // but never print them to the event log
1405         }
1406
1407         if(to_eventlog)
1408                 if(cvar("sv_eventlog_console"))
1409                         to_console = FALSE; // otherwise we get the output twice
1410
1411         if(final)
1412                 s = ":scores:";
1413         else
1414                 s = ":status:";
1415         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1416
1417         if(to_console)
1418                 print(s, "\n");
1419         if(to_eventlog)
1420                 GameLogEcho(s);
1421         if(to_file)
1422         {
1423                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1424                 if(file == -1)
1425                         to_file = FALSE;
1426                 else
1427                         fputs(file, strcat(s, "\n"));
1428         }
1429
1430         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1431         if(to_console)
1432                 print(s, "\n");
1433         if(to_eventlog)
1434                 GameLogEcho(s);
1435         if(to_file)
1436                 fputs(file, strcat(s, "\n"));
1437
1438         FOR_EACH_CLIENT(other)
1439         {
1440                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1441                 {
1442                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1443                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1444                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1445                                 s = strcat(s, ftos(other.team), ":");
1446                         else
1447                                 s = strcat(s, "spectator:");
1448
1449                         if(to_console)
1450                                 print(s, other.netname, "\n");
1451                         if(to_eventlog)
1452                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1453                         if(to_file)
1454                                 fputs(file, strcat(s, other.netname, "\n"));
1455                 }
1456         }
1457
1458         if(teams_matter)
1459         {
1460                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1461                 if(to_console)
1462                         print(s, "\n");
1463                 if(to_eventlog)
1464                         GameLogEcho(s);
1465                 if(to_file)
1466                         fputs(file, strcat(s, "\n"));
1467
1468                 for(i = 1; i < 16; ++i)
1469                 {
1470                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1471                         s = strcat(s, ":", ftos(i));
1472                         if(to_console)
1473                                 print(s, "\n");
1474                         if(to_eventlog)
1475                                 GameLogEcho(s);
1476                         if(to_file)
1477                                 fputs(file, strcat(s, "\n"));
1478                 }
1479         }
1480
1481         if(to_console)
1482                 print(":end\n");
1483         if(to_eventlog)
1484                 GameLogEcho(":end");
1485         if(to_file)
1486         {
1487                 fputs(file, ":end\n");
1488                 fclose(file);
1489         }
1490 }
1491
1492 void FixIntermissionClient(entity e)
1493 {
1494         string s;
1495         if(!e.autoscreenshot) // initial call
1496         {
1497                 e.angles = e.v_angle;
1498                 e.angles_x = -e.angles_x;
1499                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1500                 e.health = -2342;
1501                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1502                 e.solid = SOLID_NOT;
1503                 e.movetype = MOVETYPE_NONE;
1504                 e.takedamage = DAMAGE_NO;
1505                 if(e.weaponentity)
1506                 {
1507                         e.weaponentity.effects = EF_NODRAW;
1508                         if (e.weaponentity.weaponentity)
1509                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1510                 }
1511                 if(clienttype(e) == CLIENTTYPE_REAL)
1512                 {
1513                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1514                         s = cvar_string("sv_intermission_cdtrack");
1515                         if(s != "")
1516                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1517                         msg_entity = e;
1518                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1519                 }
1520         }
1521
1522         //e.velocity = '0 0 0';
1523         //e.fixangle = TRUE;
1524
1525         // TODO halt weapon animation
1526 }
1527
1528
1529 /*
1530 go to the next level for deathmatch
1531 only called if a time or frag limit has expired
1532 */
1533 void NextLevel()
1534 {
1535         float i;
1536
1537         gameover = TRUE;
1538
1539         intermission_running = 1;
1540
1541 // enforce a wait time before allowing changelevel
1542         if(player_count > 0)
1543                 intermission_exittime = time + cvar("sv_mapchange_delay");
1544         else
1545                 intermission_exittime = -1;
1546
1547         /*
1548         WriteByte (MSG_ALL, SVC_CDTRACK);
1549         WriteByte (MSG_ALL, 3);
1550         WriteByte (MSG_ALL, 3);
1551         // done in FixIntermission
1552         */
1553
1554         //pos = FindIntermission ();
1555
1556         VoteReset();
1557
1558         DumpStats(TRUE);
1559
1560         if(cvar("sv_eventlog"))
1561                 GameLogEcho(":gameover");
1562
1563         GameLogClose();
1564
1565 // TO DO
1566
1567 // save the stats to a text file on the client
1568 // stuffcmd(other, log_stats "stats/file_name");
1569 // bprint stats
1570 // stuffcmd(other, log_stats "");
1571 // use a filename similar to the demo name
1572         // string file_name;
1573         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1574
1575 // write a stats parser for the menu
1576
1577         if(cvar("sv_accuracy_data_send")) {
1578                 string stats_to_send;
1579
1580                 FOR_EACH_CLIENT(other) {  // make the string to send
1581                         FixIntermissionClient(other);
1582
1583                         if(other.cvar_cl_accuracy_data_share) {
1584                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1585
1586                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1587                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1588
1589                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1590
1591                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1592                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1593
1594                                 stats_to_send = strcat(stats_to_send, "\n");
1595                         }
1596                 }
1597
1598                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1599                         Score_NicePrint(other);  // print the score
1600
1601                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1602                                 bprint(stats_to_send);
1603                 }
1604         } else { // ye olde message
1605                 FOR_EACH_PLAYER(other) {
1606                         FixIntermissionClient(other);
1607
1608                         if(other.winning)
1609                                 bprint(other.netname, " ^7wins.\n");
1610                 }
1611         }
1612
1613         if(cvar("g_campaign"))
1614                 CampaignPreIntermission();
1615
1616         localcmd("\nsv_hook_gameend\n");
1617 }
1618
1619 /*
1620 ============
1621 CheckRules_Player
1622
1623 Exit deathmatch games upon conditions
1624 ============
1625 */
1626 void CheckRules_Player()
1627 {
1628         if (gameover)   // someone else quit the game already
1629                 return;
1630
1631         if(self.deadflag == DEAD_NO)
1632                 self.play_time += frametime;
1633
1634         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1635         //   (div0: and that in CheckRules_World please)
1636 };
1637
1638 float checkrules_equality;
1639 float checkrules_suddendeathwarning;
1640 float checkrules_suddendeathend;
1641 float checkrules_overtimesadded; //how many overtimes have been already added
1642
1643 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1644 float WINNING_YES = 1; // winner found
1645 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1646 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1647
1648 float InitiateSuddenDeath()
1649 {
1650         // Check first whether normal overtimes could be added before initiating suddendeath mode
1651         // - for this timelimit_overtime needs to be >0 of course
1652         // - also check the winning condition calculated in the previous frame and only add normal overtime
1653         //   again, if at the point at which timelimit would be extended again, still no winner was found
1654         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1655         {
1656                 return 1; // need to call InitiateOvertime later
1657         }
1658         else
1659         {
1660                 if(!checkrules_suddendeathend)
1661                 {
1662                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1663                         if(g_race && !g_race_qualifying)
1664                                 race_StartCompleting();
1665                 }
1666                 return 0;
1667         }
1668 }
1669
1670 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1671 {
1672         ++checkrules_overtimesadded;
1673         //add one more overtime by simply extending the timelimit
1674         float tl;
1675         tl = cvar("timelimit");
1676         tl += cvar("timelimit_overtime");
1677         cvar_set("timelimit", ftos(tl));
1678         string minutesPlural;
1679         if (cvar("timelimit_overtime") == 1)
1680                 minutesPlural = " ^3minute";
1681         else
1682                 minutesPlural = " ^3minutes";
1683
1684         bcenterprint(
1685                 strcat(
1686                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1687                         ftos(cvar("timelimit_overtime")),
1688                         minutesPlural,
1689                         " to the game!"
1690                 )
1691         );
1692 }
1693
1694 float GetWinningCode(float fraglimitreached, float equality)
1695 {
1696         if(cvar("g_campaign") == 1)
1697                 if(fraglimitreached)
1698                         return WINNING_YES;
1699                 else
1700                         return WINNING_NO;
1701
1702         else
1703                 if(equality)
1704                         if(fraglimitreached)
1705                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1706                         else
1707                                 return WINNING_NEVER;
1708                 else
1709                         if(fraglimitreached)
1710                                 return WINNING_YES;
1711                         else
1712                                 return WINNING_NO;
1713 }
1714
1715 // set the .winning flag for exactly those players with a given field value
1716 void SetWinners(.float field, float value)
1717 {
1718         entity head;
1719         FOR_EACH_PLAYER(head)
1720                 head.winning = (head.field == value);
1721 }
1722
1723 // set the .winning flag for those players with a given field value
1724 void AddWinners(.float field, float value)
1725 {
1726         entity head;
1727         FOR_EACH_PLAYER(head)
1728                 if(head.field == value)
1729                         head.winning = 1;
1730 }
1731
1732 // clear the .winning flags
1733 void ClearWinners(void)
1734 {
1735         entity head;
1736         FOR_EACH_PLAYER(head)
1737                 head.winning = 0;
1738 }
1739
1740 // Onslaught winning condition:
1741 // game terminates if only one team has a working generator (or none)
1742 float WinningCondition_Onslaught()
1743 {
1744         entity head;
1745         local float t1, t2, t3, t4;
1746
1747         WinningConditionHelper(); // set worldstatus
1748
1749         if(inWarmupStage)
1750                 return WINNING_NO;
1751
1752         // first check if the game has ended
1753         t1 = t2 = t3 = t4 = 0;
1754         head = find(world, classname, "onslaught_generator");
1755         while (head)
1756         {
1757                 if (head.health > 0)
1758                 {
1759                         if (head.team == COLOR_TEAM1) t1 = 1;
1760                         if (head.team == COLOR_TEAM2) t2 = 1;
1761                         if (head.team == COLOR_TEAM3) t3 = 1;
1762                         if (head.team == COLOR_TEAM4) t4 = 1;
1763                 }
1764                 head = find(head, classname, "onslaught_generator");
1765         }
1766         if (t1 + t2 + t3 + t4 < 2)
1767         {
1768                 // game over, only one team remains (or none)
1769                 ClearWinners();
1770                 if (t1) SetWinners(team, COLOR_TEAM1);
1771                 if (t2) SetWinners(team, COLOR_TEAM2);
1772                 if (t3) SetWinners(team, COLOR_TEAM3);
1773                 if (t4) SetWinners(team, COLOR_TEAM4);
1774                 dprint("Have a winner, ending game.\n");
1775                 return WINNING_YES;
1776         }
1777
1778         // Two or more teams remain
1779         return WINNING_NO;
1780 }
1781
1782 float LMS_NewPlayerLives()
1783 {
1784         float fl;
1785         fl = cvar("fraglimit");
1786         if(fl == 0)
1787                 fl = 999;
1788
1789         // first player has left the game for dying too much? Nobody else can get in.
1790         if(lms_lowest_lives < 1)
1791                 return 0;
1792
1793         if(!cvar("g_lms_join_anytime"))
1794                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1795                         return 0;
1796
1797         return bound(1, lms_lowest_lives, fl);
1798 }
1799
1800 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1801 // they win. Otherwise the defending team wins once the timelimit passes.
1802 void assault_new_round();
1803 float WinningCondition_Assault()
1804 {
1805         local float status;
1806
1807         WinningConditionHelper(); // set worldstatus
1808
1809         status = WINNING_NO;
1810         // as the timelimit has not yet passed just assume the defending team will win
1811         if(assault_attacker_team == COLOR_TEAM1)
1812         {
1813                 SetWinners(team, COLOR_TEAM2);
1814         }
1815         else
1816         {
1817                 SetWinners(team, COLOR_TEAM1);
1818         }
1819
1820         local entity ent;
1821         ent = find(world, classname, "target_assault_roundend");
1822         if(ent)
1823         {
1824                 if(ent.winning) // round end has been triggered by attacking team
1825                 {
1826                         bprint("ASSAULT: round completed...\n");
1827                         SetWinners(team, assault_attacker_team);
1828
1829                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1830
1831                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1832                         {
1833                                 status = WINNING_YES;
1834                         }
1835                         else
1836                         {
1837                                 local entity oldself;
1838                                 oldself = self;
1839                                 self = ent;
1840                                 assault_new_round();
1841                                 self = oldself;
1842                         }
1843                 }
1844         }
1845
1846         return status;
1847 }
1848
1849 // LMS winning condition: game terminates if and only if there's at most one
1850 // one player who's living lives. Top two scores being equal cancels the time
1851 // limit.
1852 float WinningCondition_LMS()
1853 {
1854         entity head, head2;
1855         float have_player;
1856         float have_players;
1857         float l;
1858
1859         have_player = FALSE;
1860         have_players = FALSE;
1861         l = LMS_NewPlayerLives();
1862
1863         head = find(world, classname, "player");
1864         if(head)
1865                 have_player = TRUE;
1866         head2 = find(head, classname, "player");
1867         if(head2)
1868                 have_players = TRUE;
1869
1870         if(have_player)
1871         {
1872                 // we have at least one player
1873                 if(have_players)
1874                 {
1875                         // two or more active players - continue with the game
1876                 }
1877                 else
1878                 {
1879                         // exactly one player?
1880
1881                         ClearWinners();
1882                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1883
1884                         if(l)
1885                         {
1886                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1887                                 return WINNING_NO;
1888                         }
1889                         else
1890                         {
1891                                 // a winner!
1892                                 // and assign him his first place
1893                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1894                                 return WINNING_YES;
1895                         }
1896                 }
1897         }
1898         else
1899         {
1900                 // nobody is playing at all...
1901                 if(l)
1902                 {
1903                         // wait for players...
1904                 }
1905                 else
1906                 {
1907                         // SNAFU (maybe a draw game?)
1908                         ClearWinners();
1909                         dprint("No players, ending game.\n");
1910                         return WINNING_YES;
1911                 }
1912         }
1913
1914         // When we get here, we have at least two players who are actually LIVING,
1915         // now check if the top two players have equal score.
1916         WinningConditionHelper();
1917
1918         ClearWinners();
1919         if(WinningConditionHelper_winner)
1920                 WinningConditionHelper_winner.winning = TRUE;
1921         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1922                 return WINNING_NEVER;
1923
1924         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1925         return WINNING_NO;
1926 }
1927
1928 void ShuffleMaplist()
1929 {
1930         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1931 }
1932
1933 float leaderfrags;
1934 float WinningCondition_Scores(float limit, float leadlimit)
1935 {
1936         float limitreached;
1937
1938         // TODO make everything use THIS winning condition (except LMS)
1939         WinningConditionHelper();
1940
1941         if(teams_matter)
1942         {
1943                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1944                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1945                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1946                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1947         }
1948
1949         ClearWinners();
1950         if(WinningConditionHelper_winner)
1951                 WinningConditionHelper_winner.winning = 1;
1952         if(WinningConditionHelper_winnerteam >= 0)
1953                 SetWinners(team, WinningConditionHelper_winnerteam);
1954
1955         if(WinningConditionHelper_lowerisbetter)
1956         {
1957                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1958                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1959                 limit = -limit;
1960         }
1961
1962         if(WinningConditionHelper_zeroisworst)
1963                 leadlimit = 0; // not supported in this mode
1964
1965         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1966         // these modes always score in increments of 1, thus this makes sense
1967         {
1968                 if(leaderfrags != WinningConditionHelper_topscore)
1969                 {
1970                         leaderfrags = WinningConditionHelper_topscore;
1971
1972                         if (limit)
1973                         if (leaderfrags == limit - 1)
1974                                 Announce("1fragleft");
1975                         else if (leaderfrags == limit - 2)
1976                                 Announce("2fragsleft");
1977                         else if (leaderfrags == limit - 3)
1978                                 Announce("3fragsleft");
1979                 }
1980         }
1981
1982         limitreached = FALSE;
1983         if(limit)
1984                 if(WinningConditionHelper_topscore >= limit)
1985                         limitreached = TRUE;
1986         if(leadlimit)
1987         {
1988                 float leadlimitreached;
1989                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1990                 if(cvar("leadlimit_and_fraglimit"))
1991                         limitreached = (limitreached && leadlimitreached);
1992                 else
1993                         limitreached = (limitreached || leadlimitreached);
1994         }
1995
1996         return GetWinningCode(
1997                 WinningConditionHelper_topscore && limitreached,
1998                 WinningConditionHelper_equality
1999         );
2000 }
2001
2002 float WinningCondition_Race(float fraglimit)
2003 {
2004         float wc;
2005         entity p;
2006         float n, c;
2007
2008         n = 0;
2009         c = 0;
2010         FOR_EACH_PLAYER(p)
2011         {
2012                 ++n;
2013                 if(p.race_completed)
2014                         ++c;
2015         }
2016         if(n && (n == c))
2017                 return WINNING_YES;
2018         wc = WinningCondition_Scores(fraglimit, 0);
2019
2020         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2021         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2022         // do NOT support equality when the laps are all raced!
2023                 return WINNING_STARTSUDDENDEATHOVERTIME;
2024         else
2025                 return WINNING_NEVER;
2026         return wc;
2027 }
2028
2029 void ReadyRestart();
2030 float WinningCondition_QualifyingThenRace(float limit)
2031 {
2032         float wc;
2033         wc = WinningCondition_Scores(limit, 0);
2034
2035         // NEVER initiate overtime
2036         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2037         {
2038                 return WINNING_YES;
2039         }
2040
2041         return wc;
2042 }
2043
2044 float WinningCondition_RanOutOfSpawns()
2045 {
2046         entity head;
2047
2048         if(have_team_spawns <= 0)
2049                 return WINNING_NO;
2050
2051         if(!some_spawn_has_been_used)
2052                 return WINNING_NO;
2053
2054         team1_score = team2_score = team3_score = team4_score = 0;
2055
2056         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2057         {
2058                 if(head.team == COLOR_TEAM1)
2059                         team1_score = 1;
2060                 else if(head.team == COLOR_TEAM2)
2061                         team2_score = 1;
2062                 else if(head.team == COLOR_TEAM3)
2063                         team3_score = 1;
2064                 else if(head.team == COLOR_TEAM4)
2065                         team4_score = 1;
2066         }
2067
2068         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2069         {
2070                 if(head.team == COLOR_TEAM1)
2071                         team1_score = 1;
2072                 else if(head.team == COLOR_TEAM2)
2073                         team2_score = 1;
2074                 else if(head.team == COLOR_TEAM3)
2075                         team3_score = 1;
2076                 else if(head.team == COLOR_TEAM4)
2077                         team4_score = 1;
2078         }
2079
2080         ClearWinners();
2081         if(team1_score + team2_score + team3_score + team4_score == 0)
2082         {
2083                 checkrules_equality = TRUE;
2084                 return WINNING_YES;
2085         }
2086         else if(team1_score + team2_score + team3_score + team4_score == 1)
2087         {
2088                 float t, i;
2089                 if(team1_score) t = COLOR_TEAM1;
2090                 if(team2_score) t = COLOR_TEAM2;
2091                 if(team3_score) t = COLOR_TEAM3;
2092                 if(team4_score) t = COLOR_TEAM4;
2093                 CheckAllowedTeams(world);
2094                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2095                 {
2096                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2097                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2098                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2099                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2100                 }
2101
2102                 AddWinners(team, t);
2103                 return WINNING_YES;
2104         }
2105         else
2106                 return WINNING_NO;
2107 }
2108
2109 /*
2110 ============
2111 CheckRules_World
2112
2113 Exit deathmatch games upon conditions
2114 ============
2115 */
2116 void CheckRules_World()
2117 {
2118         float timelimit;
2119         float fraglimit;
2120         float leadlimit;
2121
2122         VoteThink();
2123         MapVote_Think();
2124
2125         SetDefaultAlpha();
2126
2127         /*
2128         MapVote_Think should now do that part
2129         if (intermission_running)
2130                 if (time >= intermission_exittime + 60)
2131                 {
2132                         if(!DoNextMapOverride())
2133                                 GotoNextMap();
2134                         return;
2135                 }
2136         */
2137
2138         if (gameover)   // someone else quit the game already
2139         {
2140                 if(player_count == 0) // Nobody there? Then let's go to the next map
2141                         MapVote_Start();
2142                         // this will actually check the player count in the next frame
2143                         // again, but this shouldn't hurt
2144                 return;
2145         }
2146
2147         timelimit = cvar("timelimit") * 60;
2148         fraglimit = cvar("fraglimit");
2149         leadlimit = cvar("leadlimit");
2150
2151         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2152         {
2153                 if(timelimit > 0)
2154                         timelimit = 0; // timelimit is not made for warmup
2155                 if(fraglimit > 0)
2156                         fraglimit = 0; // no fraglimit for now
2157                 leadlimit = 0; // no leadlimit for now
2158         }
2159
2160         if(g_onslaught)
2161                 timelimit = 0; // ONS has its own overtime rule
2162
2163         if(timelimit > 0)
2164         {
2165                 timelimit += game_starttime;
2166         }
2167         else if (timelimit < 0)
2168         {
2169                 // endmatch
2170                 NextLevel();
2171                 return;
2172         }
2173
2174         float wantovertime;
2175         wantovertime = 0;
2176
2177         if(checkrules_suddendeathend)
2178         {
2179                 if(!checkrules_suddendeathwarning)
2180                 {
2181                         checkrules_suddendeathwarning = TRUE;
2182                         if(g_race && !g_race_qualifying)
2183                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2184                         else
2185                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2186                 }
2187         }
2188         else
2189         {
2190                 if (timelimit && time >= timelimit)
2191                 {
2192                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2193                         {
2194                                 float totalplayers;
2195                                 float playerswithlaps;
2196                                 float readyplayers;
2197                                 entity head;
2198                                 totalplayers = playerswithlaps = readyplayers = 0;
2199                                 FOR_EACH_PLAYER(head)
2200                                 {
2201                                         ++totalplayers;
2202                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2203                                                 ++playerswithlaps;
2204                                         if(head.ready)
2205                                                 ++readyplayers;
2206                                 }
2207
2208                                 // at least 2 of the players have completed a lap: start the RACE
2209                                 // otherwise, the players should end the qualifying on their own
2210                                 if(readyplayers || playerswithlaps >= 2)
2211                                 {
2212                                         checkrules_suddendeathend = 0;
2213                                         ReadyRestart(); // go to race
2214                                         return;
2215                                 }
2216                                 else
2217                                         wantovertime |= InitiateSuddenDeath();
2218                         }
2219                         else
2220                                 wantovertime |= InitiateSuddenDeath();
2221                 }
2222         }
2223
2224         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2225         {
2226                 NextLevel();
2227                 return;
2228         }
2229
2230         float checkrules_status;
2231         checkrules_status = WinningCondition_RanOutOfSpawns();
2232         if(checkrules_status == WINNING_YES)
2233         {
2234                 bprint("Hey! Someone ran out of spawns!\n");
2235         }
2236         else if(g_race && !g_race_qualifying && timelimit >= 0)
2237         {
2238                 checkrules_status = WinningCondition_Race(fraglimit);
2239                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2240         }
2241         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2242         {
2243                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2244                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2245         }
2246         else if(g_assault)
2247         {
2248                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2249         }
2250         else if(g_lms)
2251         {
2252                 checkrules_status = WinningCondition_LMS();
2253         }
2254         else if (g_onslaught)
2255         {
2256                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2257         }
2258         else
2259         {
2260                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2261                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2262         }
2263
2264         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2265         {
2266                 checkrules_status = WINNING_NEVER;
2267                 checkrules_overtimesadded = -1;
2268                 wantovertime |= InitiateSuddenDeath();
2269         }
2270
2271         if(checkrules_status == WINNING_NEVER)
2272                 // equality cases! Nobody wins if the overtime ends in a draw.
2273                 ClearWinners();
2274
2275         if(wantovertime)
2276         {
2277                 if(checkrules_status == WINNING_NEVER)
2278                         InitiateOvertime();
2279                 else
2280                         checkrules_status = WINNING_YES;
2281         }
2282
2283         if(checkrules_suddendeathend)
2284                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2285                         checkrules_status = WINNING_YES;
2286
2287         if(checkrules_status == WINNING_YES)
2288         {
2289                 //print("WINNING\n");
2290                 NextLevel();
2291         }
2292 };
2293
2294 float mapvote_nextthink;
2295 float mapvote_initialized;
2296 float mapvote_keeptwotime;
2297 float mapvote_timeout;
2298 string mapvote_message;
2299 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2300 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2301 float mapvote_screenshot_dirs_count;
2302
2303 float mapvote_count;
2304 float mapvote_count_real;
2305 string mapvote_maps[MAPVOTE_COUNT];
2306 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2307 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2308 float mapvote_maps_suggested[MAPVOTE_COUNT];
2309 string mapvote_suggestions[MAPVOTE_COUNT];
2310 float mapvote_suggestion_ptr;
2311 float mapvote_maxlen;
2312 float mapvote_voters;
2313 float mapvote_votes[MAPVOTE_COUNT];
2314 float mapvote_run;
2315 float mapvote_detail;
2316 float mapvote_abstain;
2317 .float mapvote;
2318
2319 void MapVote_ClearAllVotes()
2320 {
2321         FOR_EACH_CLIENT(other)
2322                 other.mapvote = 0;
2323 }
2324
2325 string MapVote_Suggest(string m)
2326 {
2327         float i;
2328         if(m == "")
2329                 return "That's not how to use this command.";
2330         if(!cvar("g_maplist_votable_suggestions"))
2331                 return "Suggestions are not accepted on this server.";
2332         if(mapvote_initialized)
2333                 return "Can't suggest - voting is already in progress!";
2334         m = MapInfo_FixName(m);
2335         if(!m)
2336                 return "The map you suggested is not available on this server.";
2337         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2338                 if(Map_IsRecent(m))
2339                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2340
2341         if(!MapInfo_CheckMap(m))
2342                 return "The map you suggested does not support the current game mode.";
2343         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2344                 if(mapvote_suggestions[i] == m)
2345                         return "This map was already suggested.";
2346         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2347         {
2348                 i = floor(random() * mapvote_suggestion_ptr);
2349         }
2350         else
2351         {
2352                 i = mapvote_suggestion_ptr;
2353                 mapvote_suggestion_ptr += 1;
2354         }
2355         if(mapvote_suggestions[i] != "")
2356                 strunzone(mapvote_suggestions[i]);
2357         mapvote_suggestions[i] = strzone(m);
2358         if(cvar("sv_eventlog"))
2359                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2360         return strcat("Suggestion of ", m, " accepted.");
2361 }
2362
2363 void MapVote_AddVotable(string nextMap, float isSuggestion)
2364 {
2365         float j, i, o;
2366         string pakfile, mapfile;
2367
2368         if(nextMap == "")
2369                 return;
2370         for(j = 0; j < mapvote_count; ++j)
2371                 if(mapvote_maps[j] == nextMap)
2372                         return;
2373         if(strlen(nextMap) > mapvote_maxlen)
2374                 mapvote_maxlen = strlen(nextMap);
2375         mapvote_maps[mapvote_count] = strzone(nextMap);
2376         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2377
2378         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2379         {
2380                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2381                 pakfile = whichpack(strcat(mapfile, ".tga"));
2382                 if(pakfile == "")
2383                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2384                 if(pakfile == "")
2385                         pakfile = whichpack(strcat(mapfile, ".png"));
2386                 if(pakfile != "")
2387                         break;
2388         }
2389         if(i >= mapvote_screenshot_dirs_count)
2390                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2391         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2392                 pakfile = substring(pakfile, o, -1);
2393
2394         mapvote_maps_screenshot_dir[mapvote_count] = i;
2395         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2396
2397         mapvote_count += 1;
2398 }
2399
2400 void MapVote_Spawn();
2401 void MapVote_Init()
2402 {
2403         float i;
2404         float nmax, smax;
2405
2406         MapVote_ClearAllVotes();
2407
2408         mapvote_count = 0;
2409         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2410         mapvote_abstain = cvar("g_maplist_votable_abstain");
2411
2412         if(mapvote_abstain)
2413                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2414         else
2415                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2416         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2417
2418         // we need this for AddVotable, as that cycles through the screenshot dirs
2419         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2420         if(mapvote_screenshot_dirs_count == 0)
2421                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2422         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2423         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2424                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2425
2426         if(mapvote_suggestion_ptr)
2427                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2428                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2429
2430         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2431                 MapVote_AddVotable(GetNextMap(), FALSE);
2432
2433         if(mapvote_count == 0)
2434         {
2435                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2436                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2437                 if(cvar("g_maplist_shuffle"))
2438                         ShuffleMaplist();
2439                 localcmd("\nmenu_cmd sync\n");
2440                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2441                         MapVote_AddVotable(GetNextMap(), FALSE);
2442         }
2443
2444         mapvote_count_real = mapvote_count;
2445         if(mapvote_abstain)
2446                 MapVote_AddVotable("don't care", 0);
2447
2448         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2449
2450         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2451         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2452         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2453                 mapvote_keeptwotime = 0;
2454         mapvote_message = "Choose a map and press its key!";
2455
2456         MapVote_Spawn();
2457 }
2458
2459 void MapVote_SendPicture(float id)
2460 {
2461         msg_entity = self;
2462         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2463         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2464         WriteByte(MSG_ONE, id);
2465         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2466 }
2467
2468 float GameCommand_MapVote(string cmd)
2469 {
2470         if(!intermission_running)
2471                 return FALSE;
2472
2473         if(cmd == "mv_getpic")
2474         {
2475                 MapVote_SendPicture(stof(argv(1)));
2476                 return TRUE;
2477         }
2478
2479         return FALSE;
2480 }
2481
2482 float MapVote_GetMapMask()
2483 {
2484         float mask, i, power;
2485         mask = 0;
2486         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2487                 if(mapvote_maps[i] != "")
2488                         mask |= power;
2489         return mask;
2490 }
2491
2492 entity mapvote_ent;
2493 float MapVote_SendEntity(entity to, float sf)
2494 {
2495         float i;
2496
2497         if(sf & 1)
2498                 sf &~= 2; // if we send 1, we don't need to also send 2
2499
2500         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2501         WriteByte(MSG_ENTITY, sf);
2502
2503         if(sf & 1)
2504         {
2505                 // flag 1 == initialization
2506                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2507                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2508                 WriteString(MSG_ENTITY, "");
2509                 WriteByte(MSG_ENTITY, mapvote_count);
2510                 WriteByte(MSG_ENTITY, mapvote_abstain);
2511                 WriteByte(MSG_ENTITY, mapvote_detail);
2512                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2513                 if(mapvote_count <= 8)
2514                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2515                 else
2516                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2517                 for(i = 0; i < mapvote_count; ++i)
2518                         if(mapvote_maps[i] != "")
2519                         {
2520                                 if(mapvote_abstain && i == mapvote_count - 1)
2521                                 {
2522                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2523                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2524                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2525                                 }
2526                                 else
2527                                 {
2528                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2529                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2530                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2531                                 }
2532                         }
2533         }
2534
2535         if(sf & 2)
2536         {
2537                 // flag 2 == update of mask
2538                 if(mapvote_count <= 8)
2539                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2540                 else
2541                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2542         }
2543
2544         if(sf & 4)
2545         {
2546                 if(mapvote_detail)
2547                         for(i = 0; i < mapvote_count; ++i)
2548                                 if(mapvote_maps[i] != "")
2549                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2550
2551                 WriteByte(MSG_ENTITY, to.mapvote);
2552         }
2553
2554         return TRUE;
2555 }
2556
2557 void MapVote_Spawn()
2558 {
2559         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2560 }
2561
2562 void MapVote_TouchMask()
2563 {
2564         mapvote_ent.SendFlags |= 2;
2565 }
2566
2567 void MapVote_TouchVotes(entity voter)
2568 {
2569         mapvote_ent.SendFlags |= 4;
2570 }
2571
2572 float MapVote_Finished(float mappos)
2573 {
2574         string result;
2575         float i;
2576         float didntvote;
2577
2578         if(cvar("sv_eventlog"))
2579         {
2580                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2581                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2582                 didntvote = mapvote_voters;
2583                 for(i = 0; i < mapvote_count; ++i)
2584                         if(mapvote_maps[i] != "")
2585                         {
2586                                 didntvote -= mapvote_votes[i];
2587                                 if(i != mappos)
2588                                 {
2589                                         result = strcat(result, ":", mapvote_maps[i]);
2590                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2591                                 }
2592                         }
2593                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2594
2595                 GameLogEcho(result);
2596                 if(mapvote_maps_suggested[mappos])
2597                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2598         }
2599
2600         FOR_EACH_REALCLIENT(other)
2601                 FixClientCvars(other);
2602
2603         Map_Goto_SetStr(mapvote_maps[mappos]);
2604         Map_Goto();
2605         alreadychangedlevel = TRUE;
2606         return TRUE;
2607 }
2608 void MapVote_CheckRules_1()
2609 {
2610         float i;
2611
2612         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2613         {
2614                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2615                 mapvote_votes[i] = 0;
2616         }
2617
2618         mapvote_voters = 0;
2619         FOR_EACH_REALCLIENT(other)
2620         {
2621                 ++mapvote_voters;
2622                 if(other.mapvote)
2623                 {
2624                         i = other.mapvote - 1;
2625                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2626                         mapvote_votes[i] = mapvote_votes[i] + 1;
2627                 }
2628         }
2629 }
2630
2631 float MapVote_CheckRules_2()
2632 {
2633         float i;
2634         float firstPlace, secondPlace;
2635         float firstPlaceVotes, secondPlaceVotes;
2636         float mapvote_voters_real;
2637         string result;
2638
2639         if(mapvote_count_real == 1)
2640                 return MapVote_Finished(0);
2641
2642         mapvote_voters_real = mapvote_voters;
2643         if(mapvote_abstain)
2644                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2645
2646         RandomSelection_Init();
2647         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2648                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2649         firstPlace = RandomSelection_chosen_float;
2650         firstPlaceVotes = RandomSelection_best_priority;
2651         //dprint("First place: ", ftos(firstPlace), "\n");
2652         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2653
2654         RandomSelection_Init();
2655         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2656                 if(i != firstPlace)
2657                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2658         secondPlace = RandomSelection_chosen_float;
2659         secondPlaceVotes = RandomSelection_best_priority;
2660         //dprint("Second place: ", ftos(secondPlace), "\n");
2661         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2662
2663         if(firstPlace == -1)
2664                 error("No first place in map vote... WTF?");
2665
2666         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2667                 return MapVote_Finished(firstPlace);
2668
2669         if(mapvote_keeptwotime)
2670                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2671                 {
2672                         float didntvote;
2673                         MapVote_TouchMask();
2674                         mapvote_message = "Now decide between the TOP TWO!";
2675                         mapvote_keeptwotime = 0;
2676                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2677                         result = strcat(result, ":", ftos(firstPlaceVotes));
2678                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2679                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2680                         didntvote = mapvote_voters;
2681                         for(i = 0; i < mapvote_count; ++i)
2682                                 if(mapvote_maps[i] != "")
2683                                 {
2684                                         didntvote -= mapvote_votes[i];
2685                                         if(i != firstPlace)
2686                                                 if(i != secondPlace)
2687                                                 {
2688                                                         result = strcat(result, ":", mapvote_maps[i]);
2689                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2690                                                         if(i < mapvote_count_real)
2691                                                         {
2692                                                                 strunzone(mapvote_maps[i]);
2693                                                                 mapvote_maps[i] = "";
2694                                                                 strunzone(mapvote_maps_pakfile[i]);
2695                                                                 mapvote_maps_pakfile[i] = "";
2696                                                         }
2697                                                 }
2698                                 }
2699                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2700                         if(cvar("sv_eventlog"))
2701                                 GameLogEcho(result);
2702                 }
2703
2704         return FALSE;
2705 }
2706 void MapVote_Tick()
2707 {
2708         float keeptwo;
2709         float totalvotes;
2710
2711         keeptwo = mapvote_keeptwotime;
2712         MapVote_CheckRules_1(); // count
2713         if(MapVote_CheckRules_2()) // decide
2714                 return;
2715
2716         totalvotes = 0;
2717         FOR_EACH_REALCLIENT(other)
2718         {
2719                 // hide scoreboard again
2720                 if(other.health != 2342)
2721                 {
2722                         other.health = 2342;
2723                         other.impulse = 0;
2724                         if(clienttype(other) == CLIENTTYPE_REAL)
2725                         {
2726                                 msg_entity = other;
2727                                 WriteByte(MSG_ONE, SVC_FINALE);
2728                                 WriteString(MSG_ONE, "");
2729                         }
2730                 }
2731
2732                 // clear possibly invalid votes
2733                 if(mapvote_maps[other.mapvote - 1] == "")
2734                         other.mapvote = 0;
2735                 // use impulses as new vote
2736                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2737                         if(mapvote_maps[other.impulse - 1] != "")
2738                         {
2739                                 other.mapvote = other.impulse;
2740                                 MapVote_TouchVotes(other);
2741                         }
2742                 other.impulse = 0;
2743
2744                 if(other.mapvote)
2745                         ++totalvotes;
2746         }
2747
2748         MapVote_CheckRules_1(); // just count
2749 }
2750 void MapVote_Start()
2751 {
2752         if(mapvote_run)
2753                 return;
2754
2755         MapInfo_Enumerate();
2756         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2757                 mapvote_run = TRUE;
2758 }
2759 void MapVote_Think()
2760 {
2761         if(!mapvote_run)
2762                 return;
2763
2764         if(alreadychangedlevel)
2765                 return;
2766
2767         if(time < mapvote_nextthink)
2768                 return;
2769         //dprint("tick\n");
2770
2771         mapvote_nextthink = time + 0.5;
2772
2773         if(!mapvote_initialized)
2774         {
2775                 if(cvar("rescan_pending") == 1)
2776                 {
2777                         cvar_set("rescan_pending", "2");
2778                         localcmd("fs_rescan\nrescan_pending 3\n");
2779                         return;
2780                 }
2781                 else if(cvar("rescan_pending") == 2)
2782                 {
2783                         return;
2784                 }
2785                 else if(cvar("rescan_pending") == 3)
2786                 {
2787                         // now build missing mapinfo files
2788                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2789                                 return;
2790
2791                         // we're done, start the timer
2792                         cvar_set("rescan_pending", "0");
2793                 }
2794
2795                 mapvote_initialized = TRUE;
2796                 if(DoNextMapOverride())
2797                         return;
2798                 if(!cvar("g_maplist_votable") || player_count <= 0)
2799                 {
2800                         GotoNextMap();
2801                         return;
2802                 }
2803                 MapVote_Init();
2804         }
2805
2806         MapVote_Tick();
2807 };
2808
2809 string GotoMap(string m)
2810 {
2811         if(!MapInfo_CheckMap(m))
2812                 return "The map you chose is not available on this server.";
2813         cvar_set("nextmap", m);
2814         cvar_set("timelimit", "-1");
2815         if(mapvote_initialized || alreadychangedlevel)
2816         {
2817                 if(DoNextMapOverride())
2818                         return "Map switch initiated.";
2819                 else
2820                         return "Hm... no. For some reason I like THIS map more.";
2821         }
2822         else
2823                 return "Map switch will happen after scoreboard.";
2824 }
2825
2826
2827 void EndFrame()
2828 {
2829         float altime;
2830         FOR_EACH_REALCLIENT(self)
2831         {
2832                 if(self.classname == "spectator")
2833                 {
2834                         if(self.enemy.typehitsound)
2835                                 play2(self, "misc/typehit.wav");
2836                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2837                                 play2(self, "misc/hit.wav");
2838                 }
2839                 else
2840                 {
2841                         if(self.typehitsound)
2842                                 play2(self, "misc/typehit.wav");
2843                         else if(self.hitsound && self.cvar_cl_hitsound)
2844                                 play2(self, "misc/hit.wav");
2845                 }
2846         }
2847         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2848         // add 1 frametime because after this, engine SV_Physics
2849         // increases time by a frametime and then networks the frame
2850         // add another frametime because client shows everything with
2851         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2852         // needed!
2853         FOR_EACH_CLIENT(self)
2854         {
2855                 self.hitsound = FALSE;
2856                 self.typehitsound = FALSE;
2857                 antilag_record(self, altime);
2858         }
2859 }
2860
2861
2862 /*
2863  * RedirectionThink:
2864  * returns TRUE if redirecting
2865  */
2866 float redirection_timeout;
2867 float redirection_nextthink;
2868 float RedirectionThink()
2869 {
2870         float clients_found;
2871
2872         if(redirection_target == "")
2873                 return FALSE;
2874
2875         if(!redirection_timeout)
2876         {
2877                 cvar_set("sv_public", "-2");
2878                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2879                 if(redirection_target == "self")
2880                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2881                 else
2882                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2883         }
2884
2885         if(time < redirection_nextthink)
2886                 return TRUE;
2887
2888         redirection_nextthink = time + 1;
2889
2890         clients_found = 0;
2891         FOR_EACH_REALCLIENT(self)
2892         {
2893                 print("Redirecting: sending connect command to ", self.netname, "\n");
2894                 if(redirection_target == "self")
2895                         stuffcmd(self, "\ndisconnect; reconnect\n");
2896                 else
2897                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2898                 ++clients_found;
2899         }
2900
2901         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2902
2903         if(time > redirection_timeout || clients_found == 0)
2904                 localcmd("\nwait; wait; wait; quit\n");
2905
2906         return TRUE;
2907 }
2908
2909 void TargetMusic_RestoreGame();
2910 void RestoreGame()
2911 {
2912         // Loaded from a save game
2913         // some things then break, so let's work around them...
2914
2915         // Progs DB (capture records)
2916         ServerProgsDB = db_load("server.db");
2917
2918         // Mapinfo
2919         MapInfo_Shutdown();
2920         MapInfo_Enumerate();
2921         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2922         WeaponStats_Init();
2923
2924         TargetMusic_RestoreGame();
2925 }
2926
2927 void SV_Shutdown()
2928 {
2929         if(gameover > 1) // shutting down already?
2930                 return;
2931
2932         gameover = 2; // 2 = server shutting down
2933
2934         if(world_initialized > 0)
2935         {
2936                 world_initialized = 0;
2937                 print("Saving persistent data...\n");
2938                 Ban_SaveBans();
2939                 if(!cheatcount_total)
2940                 {
2941                         if(cvar("sv_db_saveasdump"))
2942                                 db_dump(ServerProgsDB, "server.db");
2943                         else
2944                                 db_save(ServerProgsDB, "server.db");
2945                 }
2946                 if(cvar("developer"))
2947                 {
2948                         if(cvar("sv_db_saveasdump"))
2949                                 db_dump(TemporaryDB, "server-temp.db");
2950                         else
2951                                 db_save(TemporaryDB, "server-temp.db");
2952                 }
2953                 CheatShutdown(); // must be after cheatcount check
2954                 db_close(ServerProgsDB);
2955                 db_close(TemporaryDB);
2956                 print("done!\n");
2957                 // tell the bot system the game is ending now
2958                 bot_endgame();
2959
2960                 WeaponStats_Shutdown();
2961                 MapInfo_Shutdown();
2962         }
2963         else if(world_initialized == 0)
2964         {
2965                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2966         }
2967 }