39d8acdfc2796b06c202e9f03703cee05b2f529d
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2
3 #include "anticheat.qh"
4 #include "antilag.qh"
5 #include "bot/api.qh"
6 #include "campaign.qh"
7 #include "cheats.qh"
8 #include "cl_client.qh"
9 #include "command/common.qh"
10 #include "command/getreplies.qh"
11 #include "command/sv_cmd.qh"
12 #include "command/vote.qh"
13 #include "g_hook.qh"
14 #include "ipban.qh"
15 #include "mapvoting.qh"
16 #include "mutators/all.qh"
17 #include "race.qh"
18 #include "scores.qh"
19 #include "teamplay.qh"
20 #include "weapons/weaponstats.qh"
21 #include "../common/constants.qh"
22 #include "../common/deathtypes/all.qh"
23 #include "../common/mapinfo.qh"
24 #include "../common/monsters/all.qh"
25 #include "../common/monsters/sv_monsters.qh"
26 #include "../common/vehicles/all.qh"
27 #include "../common/notifications/all.qh"
28 #include "../common/physics/player.qh"
29 #include "../common/playerstats.qh"
30 #include "../common/stats.qh"
31 #include "../common/teams.qh"
32 #include "../common/triggers/trigger/secret.qh"
33 #include "../common/triggers/target/music.qh"
34 #include "../common/util.qh"
35 #include "../common/items/all.qh"
36 #include "../common/weapons/all.qh"
37 #include "../common/state.qh"
38
39 const float LATENCY_THINKRATE = 10;
40 .float latency_sum;
41 .float latency_cnt;
42 .float latency_time;
43 entity pingplreport;
44 void PingPLReport_Think(entity this)
45 {
46         float delta;
47         entity e;
48
49         delta = 3 / maxclients;
50         if(delta < sys_frametime)
51                 delta = 0;
52         this.nextthink = time + delta;
53
54         e = edict_num(this.cnt + 1);
55         if(IS_REAL_CLIENT(e))
56         {
57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
58                 WriteByte(MSG_BROADCAST, this.cnt);
59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
62
63                 // record latency times for clients throughout the match so we can report it to playerstats
64                 if(time > (e.latency_time + LATENCY_THINKRATE))
65                 {
66                         e.latency_sum += e.ping;
67                         e.latency_cnt += 1;
68                         e.latency_time = time;
69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
70                 }
71         }
72         else
73         {
74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
75                 WriteByte(MSG_BROADCAST, this.cnt);
76                 WriteShort(MSG_BROADCAST, 0);
77                 WriteByte(MSG_BROADCAST, 0);
78                 WriteByte(MSG_BROADCAST, 0);
79         }
80         this.cnt = (this.cnt + 1) % maxclients;
81 }
82 void PingPLReport_Spawn()
83 {
84         pingplreport = new_pure(pingplreport);
85         setthink(pingplreport, PingPLReport_Think);
86         pingplreport.nextthink = time;
87 }
88
89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
90 string redirection_target;
91 float world_initialized;
92
93 string GetGametype();
94 void ShuffleMaplist();
95
96 void SetDefaultAlpha()
97 {
98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
99         {
100                 default_player_alpha = autocvar_g_player_alpha;
101                 if(default_player_alpha == 0)
102                         default_player_alpha = 1;
103                 default_weapon_alpha = default_player_alpha;
104         }
105 }
106
107 void GotoFirstMap(entity this)
108 {
109         float n;
110         if(autocvar__sv_init)
111         {
112                 // cvar_set("_sv_init", "0");
113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
114                 // to this "init" map on a dedicated server will cause no permanent
115                 // harm
116                 if(autocvar_g_maplist_shuffle)
117                         ShuffleMaplist();
118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
120
121                 MapInfo_Enumerate();
122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
123
124                 if(!DoNextMapOverride(1))
125                         GotoNextMap(1);
126
127                 return;
128         }
129
130         if(time < 5)
131         {
132                 this.nextthink = time;
133         }
134         else
135         {
136                 this.nextthink = time + 1;
137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
138         }
139 }
140
141 void cvar_changes_init()
142 {
143         float h;
144         string k, v, d;
145         float n, i, adding, pureadding;
146
147         if(cvar_changes)
148                 strunzone(cvar_changes);
149         cvar_changes = string_null;
150         if(cvar_purechanges)
151                 strunzone(cvar_purechanges);
152         cvar_purechanges = string_null;
153         cvar_purechanges_count = 0;
154
155         h = buf_create();
156         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
157         n = buf_getsize(h);
158
159         adding = true;
160         pureadding = true;
161
162         for(i = 0; i < n; ++i)
163         {
164                 k = bufstr_get(h, i);
165
166 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
167 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
168 #define BADCVAR(p) if(k == p) continue
169
170                 // general excludes and namespaces for server admin used cvars
171                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
172
173                 // internal
174                 BADPREFIX("csqc_");
175                 BADPREFIX("cvar_check_");
176                 BADCVAR("gamecfg");
177                 BADCVAR("g_configversion");
178                 BADCVAR("g_maplist_index");
179                 BADCVAR("halflifebsp");
180                 BADCVAR("sv_mapformat_is_quake2");
181                 BADCVAR("sv_mapformat_is_quake3");
182                 BADPREFIX("sv_world");
183
184                 // client
185                 BADPREFIX("chase_");
186                 BADPREFIX("cl_");
187                 BADPREFIX("con_");
188                 BADPREFIX("scoreboard_");
189                 BADPREFIX("g_campaign");
190                 BADPREFIX("g_waypointsprite_");
191                 BADPREFIX("gl_");
192                 BADPREFIX("joy");
193                 BADPREFIX("hud_");
194                 BADPREFIX("m_");
195                 BADPREFIX("menu_");
196                 BADPREFIX("net_slist_");
197                 BADPREFIX("r_");
198                 BADPREFIX("sbar_");
199                 BADPREFIX("scr_");
200                 BADPREFIX("snd_");
201                 BADPREFIX("show");
202                 BADPREFIX("sensitivity");
203                 BADPREFIX("userbind");
204                 BADPREFIX("v_");
205                 BADPREFIX("vid_");
206                 BADPREFIX("crosshair");
207                 BADCVAR("mod_q3bsp_lightmapmergepower");
208                 BADCVAR("mod_q3bsp_nolightmaps");
209                 BADCVAR("fov");
210                 BADCVAR("mastervolume");
211                 BADCVAR("volume");
212                 BADCVAR("bgmvolume");
213
214                 // private
215                 BADCVAR("developer");
216                 BADCVAR("log_dest_udp");
217                 BADCVAR("net_address");
218                 BADCVAR("net_address_ipv6");
219                 BADCVAR("port");
220                 BADCVAR("savedgamecfg");
221                 BADCVAR("serverconfig");
222                 BADCVAR("sv_autoscreenshot");
223                 BADCVAR("sv_heartbeatperiod");
224                 BADCVAR("sv_vote_master_password");
225                 BADCVAR("sys_colortranslation");
226                 BADCVAR("sys_specialcharactertranslation");
227                 BADCVAR("timeformat");
228                 BADCVAR("timestamps");
229                 BADPREFIX("developer_");
230                 BADPREFIX("g_ban_");
231                 BADPREFIX("g_banned_list");
232                 BADPREFIX("g_chat_flood_");
233                 BADPREFIX("g_ghost_items");
234                 BADPREFIX("g_playerstats_");
235                 BADPREFIX("g_voice_flood_");
236                 BADPREFIX("log_file");
237                 BADPREFIX("rcon_");
238                 BADPREFIX("sv_allowdownloads");
239                 BADPREFIX("sv_autodemo");
240                 BADPREFIX("sv_curl_");
241                 BADPREFIX("sv_eventlog");
242                 BADPREFIX("sv_logscores_");
243                 BADPREFIX("sv_master");
244                 BADPREFIX("sv_weaponstats_");
245                 BADPREFIX("sv_waypointsprite_");
246                 BADCVAR("rescan_pending");
247
248                 // these can contain player IDs, so better hide
249                 BADPREFIX("g_forced_team_");
250
251                 // mapinfo
252                 BADCVAR("fraglimit");
253                 BADCVAR("g_assault");
254                 BADCVAR("g_ca");
255                 BADCVAR("g_ca_teams");
256                 BADCVAR("g_ctf");
257                 BADCVAR("g_cts");
258                 BADCVAR("g_dm");
259                 BADCVAR("g_domination");
260                 BADCVAR("g_domination_default_teams");
261                 BADCVAR("g_freezetag");
262                 BADCVAR("g_freezetag_teams");
263                 BADCVAR("g_invasion_teams");
264                 BADCVAR("g_keepaway");
265                 BADCVAR("g_keyhunt");
266                 BADCVAR("g_keyhunt_teams");
267                 BADCVAR("g_lms");
268                 BADCVAR("g_nexball");
269                 BADCVAR("g_onslaught");
270                 BADCVAR("g_race");
271                 BADCVAR("g_race_laps_limit");
272                 BADCVAR("g_race_qualifying_timelimit");
273                 BADCVAR("g_race_qualifying_timelimit_override");
274                 BADCVAR("g_tdm");
275                 BADCVAR("g_tdm_teams");
276                 BADCVAR("leadlimit");
277                 BADCVAR("nextmap");
278                 BADCVAR("teamplay");
279                 BADCVAR("timelimit");
280
281                 // long
282                 BADCVAR("hostname");
283                 BADCVAR("g_maplist");
284                 BADCVAR("g_maplist_mostrecent");
285                 BADCVAR("sv_motd");
286
287                 v = cvar_string(k);
288                 d = cvar_defstring(k);
289                 if(v == d)
290                         continue;
291
292                 if(adding)
293                 {
294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
295                         if(strlen(cvar_changes) > 16384)
296                         {
297                                 cvar_changes = "// too many settings have been changed to show them here\n";
298                                 adding = 0;
299                         }
300                 }
301
302                 // now check if the changes are actually gameplay relevant
303
304                 // does nothing gameplay relevant
305                 BADCVAR("captureleadlimit_override");
306                 BADCVAR("gameversion");
307                 BADCVAR("g_allow_oldvortexbeam");
308                 BADCVAR("g_balance_kill_delay");
309                 BADCVAR("g_campcheck_distance");
310                 BADCVAR("g_ca_point_leadlimit");
311                 BADCVAR("g_ca_point_limit");
312                 BADCVAR("g_ctf_captimerecord_always");
313                 BADCVAR("g_ctf_flag_glowtrails");
314                 BADCVAR("g_ctf_flag_pickup_verbosename");
315                 BADCVAR("g_domination_point_leadlimit");
316                 BADCVAR("g_forced_respawn");
317                 BADCVAR("g_freezetag_point_leadlimit");
318                 BADCVAR("g_freezetag_point_limit");
319                 BADCVAR("g_hats");
320                 BADCVAR("g_invasion_point_limit");
321                 BADCVAR("g_keyhunt_point_leadlimit");
322                 BADCVAR("g_nexball_goalleadlimit");
323                 BADCVAR("g_tdm_point_leadlimit");
324                 BADCVAR("g_tdm_point_limit");
325                 BADCVAR("leadlimit_and_fraglimit");
326                 BADCVAR("leadlimit_override");
327                 BADCVAR("pausable");
328                 BADCVAR("sv_allow_fullbright");
329                 BADCVAR("sv_checkforpacketsduringsleep");
330                 BADCVAR("sv_intermission_cdtrack");
331                 BADCVAR("sv_minigames");
332                 BADCVAR("sv_namechangetimer");
333                 BADCVAR("sv_precacheplayermodels");
334                 BADCVAR("sv_timeout");
335                 BADPREFIX("crypto_");
336                 BADPREFIX("gameversion_");
337                 BADPREFIX("g_chat_");
338                 BADPREFIX("g_ctf_captimerecord_");
339                 BADPREFIX("g_maplist_votable_");
340                 BADPREFIX("g_mod_");
341                 BADPREFIX("g_respawn_");
342                 BADPREFIX("net_");
343                 BADPREFIX("prvm_");
344                 BADPREFIX("skill_");
345                 BADPREFIX("sv_cullentities_");
346                 BADPREFIX("sv_maxidle_");
347                 BADPREFIX("sv_minigames_");
348                 BADPREFIX("sv_timeout_");
349                 BADPREFIX("sv_vote_");
350                 BADPREFIX("timelimit_");
351
352                 // allowed changes to server admins (please sync this to server.cfg)
353                 // vi commands:
354                 //   :/"impure"/,$d
355                 //   :g!,^\/\/[^ /],d
356                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
357                 //   :%!sort
358                 // yes, this does contain some redundant stuff, don't really care
359                 BADCVAR("bot_config_file");
360                 BADCVAR("bot_number");
361                 BADCVAR("bot_prefix");
362                 BADCVAR("bot_suffix");
363                 BADCVAR("capturelimit_override");
364                 BADCVAR("fraglimit_override");
365                 BADCVAR("gametype");
366                 BADCVAR("g_antilag");
367                 BADCVAR("g_balance_teams");
368                 BADCVAR("g_balance_teams_prevent_imbalance");
369                 BADCVAR("g_balance_teams_scorefactor");
370                 BADCVAR("g_ban_sync_trusted_servers");
371                 BADCVAR("g_ban_sync_uri");
372                 BADCVAR("g_ca_teams_override");
373                 BADCVAR("g_ctf_ignore_frags");
374                 BADCVAR("g_domination_point_limit");
375                 BADCVAR("g_domination_teams_override");
376                 BADCVAR("g_freezetag_teams_override");
377                 BADCVAR("g_friendlyfire");
378                 BADCVAR("g_fullbrightitems");
379                 BADCVAR("g_fullbrightplayers");
380                 BADCVAR("g_keyhunt_point_limit");
381                 BADCVAR("g_keyhunt_teams_override");
382                 BADCVAR("g_lms_lives_override");
383                 BADCVAR("g_maplist");
384                 BADCVAR("g_maplist_check_waypoints");
385                 BADCVAR("g_maplist_mostrecent_count");
386                 BADCVAR("g_maplist_shuffle");
387                 BADCVAR("g_maplist_votable");
388                 BADCVAR("g_maplist_votable_abstain");
389                 BADCVAR("g_maplist_votable_nodetail");
390                 BADCVAR("g_maplist_votable_suggestions");
391                 BADCVAR("g_maxplayers");
392                 BADCVAR("g_mirrordamage");
393                 BADCVAR("g_nexball_goallimit");
394                 BADCVAR("g_powerups");
395                 BADCVAR("g_spawnshieldtime");
396                 BADCVAR("g_start_delay");
397                 BADCVAR("g_superspectate");
398                 BADCVAR("g_tdm_teams_override");
399                 BADCVAR("g_warmup");
400                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
401                 BADCVAR("hostname");
402                 BADCVAR("log_file");
403                 BADCVAR("maxplayers");
404                 BADCVAR("minplayers");
405                 BADCVAR("net_address");
406                 BADCVAR("port");
407                 BADCVAR("rcon_password");
408                 BADCVAR("rcon_restricted_commands");
409                 BADCVAR("rcon_restricted_password");
410                 BADCVAR("skill");
411                 BADCVAR("sv_adminnick");
412                 BADCVAR("sv_autoscreenshot");
413                 BADCVAR("sv_autotaunt");
414                 BADCVAR("sv_curl_defaulturl");
415                 BADCVAR("sv_defaultcharacter");
416                 BADCVAR("sv_defaultcharacterskin");
417                 BADCVAR("sv_defaultplayercolors");
418                 BADCVAR("sv_defaultplayermodel");
419                 BADCVAR("sv_defaultplayerskin");
420                 BADCVAR("sv_maxidle");
421                 BADCVAR("sv_maxrate");
422                 BADCVAR("sv_motd");
423                 BADCVAR("sv_public");
424                 BADCVAR("sv_ready_restart");
425                 BADCVAR("sv_status_privacy");
426                 BADCVAR("sv_taunt");
427                 BADCVAR("sv_vote_call");
428                 BADCVAR("sv_vote_commands");
429                 BADCVAR("sv_vote_majority_factor");
430                 BADCVAR("sv_vote_master");
431                 BADCVAR("sv_vote_master_commands");
432                 BADCVAR("sv_vote_master_password");
433                 BADCVAR("sv_vote_simple_majority_factor");
434                 BADCVAR("teamplay_mode");
435                 BADCVAR("timelimit_override");
436                 BADPREFIX("g_warmup_");
437                 BADPREFIX("sv_ready_restart_");
438
439                 // mutators that announce themselves properly to the server browser
440                 BADCVAR("g_instagib");
441                 BADCVAR("g_new_toys");
442                 BADCVAR("g_nix");
443                 BADCVAR("g_grappling_hook");
444                 BADCVAR("g_jetpack");
445
446 #undef BADPREFIX
447 #undef BADCVAR
448
449                 if(pureadding)
450                 {
451                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
452                         if(strlen(cvar_purechanges) > 16384)
453                         {
454                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
455                                 pureadding = 0;
456                         }
457                 }
458                 ++cvar_purechanges_count;
459                 // WARNING: this variable is used for the server list
460                 // NEVER dare to skip this code!
461                 // Hacks to intentionally appearing as "pure server" even though you DO have
462                 // modified settings may be punished by removal from the server list.
463                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
464                 // though.
465         }
466         buf_del(h);
467         if(cvar_changes == "")
468                 cvar_changes = "// this server runs at default server settings\n";
469         else
470                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
471         cvar_changes = strzone(cvar_changes);
472         if(cvar_purechanges == "")
473                 cvar_purechanges = "// this server runs at default gameplay settings\n";
474         else
475                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
476         cvar_purechanges = strzone(cvar_purechanges);
477 }
478
479 void detect_maptype()
480 {
481 #if 0
482         vector o, v;
483         float i;
484
485         for (;;)
486         {
487                 o = world.mins;
488                 o.x += random() * (world.maxs.x - world.mins.x);
489                 o.y += random() * (world.maxs.y - world.mins.y);
490                 o.z += random() * (world.maxs.z - world.mins.z);
491
492                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, NULL);
493                 if(trace_fraction == 1)
494                         continue;
495
496                 v = trace_endpos;
497
498                 for(i = 0; i < 64; i += 4)
499                 {
500                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
501         if(trace_fraction == 1)
502                 continue;
503                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
504                 }
505
506                 break;
507         }
508 #endif
509 }
510
511 entity randomseed;
512 bool RandomSeed_Send(entity this, entity to, int sf)
513 {
514         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
515         WriteShort(MSG_ENTITY, this.cnt);
516         return true;
517 }
518 void RandomSeed_Think(entity this)
519 {
520         this.cnt = bound(0, floor(random() * 65536), 65535);
521         this.nextthink = time + 5;
522
523         this.SendFlags |= 1;
524 }
525 void RandomSeed_Spawn()
526 {
527         randomseed = new_pure(randomseed);
528         setthink(randomseed, RandomSeed_Think);
529         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
530
531         getthink(randomseed)(randomseed); // sets random seed and nextthink
532 }
533
534 spawnfunc(__init_dedicated_server)
535 {
536         // handler for _init/_init map (only for dedicated server initialization)
537
538         world_initialized = -1; // don't complain
539         cvar = cvar_normal;
540         cvar_string = cvar_string_normal;
541         cvar_set = cvar_set_normal;
542
543         delete_fn = remove_unsafely;
544
545         entity e = spawn();
546         setthink(e, GotoFirstMap);
547         e.nextthink = time; // this is usually 1 at this point
548
549         e = new(info_player_deathmatch);  // safeguard against player joining
550
551         this.classname = "worldspawn"; // safeguard against various stuff ;)
552
553         // needs to be done so early because of the constants they create
554         static_init();
555         static_init_late();
556         static_init_precache();
557
558         MapInfo_Enumerate();
559         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
560 }
561
562 void __init_dedicated_server_shutdown() {
563         MapInfo_Shutdown();
564 }
565
566 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override)
567 {
568         if(!autocvar_g_campaign)
569         {
570                 if(fraglimit_override >= 0) cvar_set("fraglimit", ftos(fraglimit_override));
571                 if(timelimit_override >= 0) cvar_set("timelimit", ftos(timelimit_override));
572                 if(leadlimit_override >= 0) cvar_set("leadlimit", ftos(leadlimit_override));
573                 if(qualifying_override >= 0) cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
574         }
575         limits_are_set = true;
576 }
577
578 void Map_MarkAsRecent(string m);
579 float world_already_spawned;
580 void Nagger_Init();
581 void ClientInit_Spawn();
582 void WeaponStats_Init();
583 void WeaponStats_Shutdown();
584 spawnfunc(worldspawn)
585 {
586         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
587
588     bool wantrestart = false;
589         {
590                 if (!server_is_dedicated)
591                 {
592                         // force unloading of server pk3 files when starting a listen server
593                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
594                         // restore csqc_progname too
595                         string expect = "csprogs.dat";
596                         wantrestart = cvar_string_normal("csqc_progname") != expect;
597                         cvar_set_normal("csqc_progname", expect);
598                 }
599                 else
600                 {
601                         // Try to use versioned csprogs from pk3
602                         // Only ever use versioned csprogs.dat files on dedicated servers;
603                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
604                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
605                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
606                         string select = "csprogs.dat";
607                         if (fexists(pk3csprogs)) select = pk3csprogs;
608                         if (cvar_string_normal("csqc_progname") != select)
609                         {
610                                 cvar_set_normal("csqc_progname", select);
611                                 wantrestart = true;
612                         }
613                         // Check for updates on startup
614                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
615                         int sentinel = fopen("progs.txt", FILE_READ);
616                         if (sentinel >= 0)
617                         {
618                                 string switchversion = fgets(sentinel);
619                                 fclose(sentinel);
620                                 if (switchversion != "" && switchversion != WATERMARK)
621                                 {
622                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
623                                         // if it doesn't exist, assume either:
624                                         //   a) the current program was overwritten
625                                         //   b) this is a client only update
626                                         string newprogs = sprintf("progs-%s.dat", switchversion);
627                                         if (fexists(newprogs))
628                                         {
629                                                 cvar_set_normal("sv_progs", newprogs);
630                                                 wantrestart = true;
631                                         }
632                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
633                                         if (fexists(newcsprogs))
634                                         {
635                                                 cvar_set_normal("csqc_progname", newcsprogs);
636                                                 wantrestart = true;
637                                         }
638                                 }
639                         }
640                 }
641                 if (wantrestart)
642                 {
643                         LOG_INFOF("Restart requested\n");
644                         changelevel(mapname);
645                         // let initialization continue, shutdown depends on it
646                 }
647         }
648
649         float fd, l;
650         string s;
651
652         cvar = cvar_normal;
653         cvar_string = cvar_string_normal;
654         cvar_set = cvar_set_normal;
655
656         if(world_already_spawned)
657                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
658         world_already_spawned = true;
659
660         delete_fn = remove_safely; // during spawning, watch what you remove!
661
662         cvar_changes_init(); // do this very early now so it REALLY matches the server config
663
664         compressShortVector_init();
665
666         maxclients = 0;
667         for (entity head = nextent(NULL); head; head = nextent(head))
668         {
669                 ++maxclients;
670         }
671
672         // needs to be done so early because of the constants they create
673         static_init();
674
675         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
676
677         TemporaryDB = db_create();
678
679         // 0 normal
680         lightstyle(0, "m");
681
682         // 1 FLICKER (first variety)
683         lightstyle(1, "mmnmmommommnonmmonqnmmo");
684
685         // 2 SLOW STRONG PULSE
686         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
687
688         // 3 CANDLE (first variety)
689         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
690
691         // 4 FAST STROBE
692         lightstyle(4, "mamamamamama");
693
694         // 5 GENTLE PULSE 1
695         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
696
697         // 6 FLICKER (second variety)
698         lightstyle(6, "nmonqnmomnmomomno");
699
700         // 7 CANDLE (second variety)
701         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
702
703         // 8 CANDLE (third variety)
704         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
705
706         // 9 SLOW STROBE (fourth variety)
707         lightstyle(9, "aaaaaaaazzzzzzzz");
708
709         // 10 FLUORESCENT FLICKER
710         lightstyle(10, "mmamammmmammamamaaamammma");
711
712         // 11 SLOW PULSE NOT FADE TO BLACK
713         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
714
715         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
716
717         // 63 testing
718         lightstyle(63, "a");
719
720         if(autocvar_g_campaign)
721                 CampaignPreInit();
722
723         Map_MarkAsRecent(mapname);
724
725         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
726
727         InitGameplayMode();
728         static_init_late();
729         static_init_precache();
730         readlevelcvars();
731         GrappleHookInit();
732
733         if(!limits_are_set)
734                 SetLimits(autocvar_fraglimit_override, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
735
736         if(warmup_limit == 0)
737                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
738
739         player_count = 0;
740         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
741         if(bot_waypoints_for_items == 1)
742                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
743                         bot_waypoints_for_items = 0;
744
745         precache();
746
747         WaypointSprite_Init();
748
749         GameLogInit(); // prepare everything
750         // NOTE for matchid:
751         // changing the logic generating it is okay. But:
752         // it HAS to stay <= 64 chars
753         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
754         if(autocvar_sv_eventlog)
755         {
756                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
757                 matchid = strzone(s);
758
759                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
760                 s = ":gameinfo:mutators:LIST";
761
762                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
763                 s = M_ARGV(0, string);
764
765                 // initialiation stuff, not good in the mutator system
766                 if(!autocvar_g_use_ammunition)
767                         s = strcat(s, ":no_use_ammunition");
768
769                 // initialiation stuff, not good in the mutator system
770                 if(autocvar_g_pickup_items == 0)
771                         s = strcat(s, ":no_pickup_items");
772                 if(autocvar_g_pickup_items > 0)
773                         s = strcat(s, ":pickup_items");
774
775                 // initialiation stuff, not good in the mutator system
776                 if(autocvar_g_weaponarena != "0")
777                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
778
779                 // TODO to mutator system
780                 if(autocvar_g_norecoil)
781                         s = strcat(s, ":norecoil");
782
783                 // TODO to mutator system
784                 if(autocvar_g_powerups == 0)
785                         s = strcat(s, ":no_powerups");
786                 if(autocvar_g_powerups > 0)
787                         s = strcat(s, ":powerups");
788
789                 GameLogEcho(s);
790                 GameLogEcho(":gameinfo:end");
791         }
792         else
793                 matchid = strzone(ftos(random()));
794
795         cvar_set("nextmap", "");
796
797         SetDefaultAlpha();
798
799         if(autocvar_g_campaign)
800                 CampaignPostInit();
801
802         Ban_LoadBans();
803
804         MapInfo_Enumerate();
805         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
806
807         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
808         {
809                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
810                 if(fd != -1)
811                 {
812                         while((s = fgets(fd)))
813                         {
814                                 l = tokenize_console(s);
815                                 if(l < 2)
816                                         continue;
817                                 if(argv(0) == "cd")
818                                 {
819                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
820                                         LOG_INFO("  cdtrack ", argv(2), "\n");
821                                 }
822                                 else if(argv(0) == "fog")
823                                 {
824                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
825                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
826                                 }
827                                 else if(argv(0) == "set")
828                                 {
829                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
830                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
831                                 }
832                                 else if(argv(0) != "//")
833                                 {
834                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
835                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
836                                 }
837                         }
838                         fclose(fd);
839                 }
840         }
841
842         WeaponStats_Init();
843
844         Nagger_Init();
845
846         next_pingtime = time + 5;
847
848         detect_maptype();
849
850         // set up information replies for clients and server to use
851         maplist_reply = strzone(getmaplist());
852         lsmaps_reply = strzone(getlsmaps());
853         monsterlist_reply = strzone(getmonsterlist());
854         for(int i = 0; i < 10; ++i)
855         {
856                 s = getrecords(i);
857                 if (s)
858                         records_reply[i] = strzone(s);
859         }
860         ladder_reply = strzone(getladder());
861         rankings_reply = strzone(getrankings());
862
863         // begin other init
864         ClientInit_Spawn();
865         RandomSeed_Spawn();
866         PingPLReport_Spawn();
867
868         CheatInit();
869
870         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
871
872         // fill sv_curl_serverpackages from .serverpackage files
873         if (autocvar_sv_curl_serverpackages_auto)
874         {
875                 s = "csprogs-" WATERMARK ".txt";
876                 // remove automatically managed files from the list to prevent duplicates
877                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
878                 {
879                         string pkg = argv(i);
880                         if (startsWith(pkg, "csprogs-")) continue;
881                         if (endsWith(pkg, "-serverpackage.txt")) continue;
882                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
883                         s = cons(s, pkg);
884                 }
885                 // add automatically managed files to the list
886                 #define X(match) MACRO_BEGIN { \
887                         fd = search_begin(match, true, false); \
888                         if (fd >= 0) \
889                         { \
890                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
891                                 { \
892                                         s = cons(s, search_getfilename(fd, i)); \
893                                 } \
894                                 search_end(fd); \
895                         } \
896                 } MACRO_END
897                 X("*-serverpackage.txt");
898                 X("*.serverpackage");
899                 #undef X
900                 cvar_set("sv_curl_serverpackages", s);
901         }
902
903         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
904         modname = "Xonotic";
905         // physics/balance/config changes that count as mod
906         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
907                 modname = cvar_string("g_mod_physics");
908         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
909                 modname = cvar_string("g_mod_balance");
910         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
911                 modname = cvar_string("g_mod_config");
912         // extra mutators that deserve to count as mod
913         MUTATOR_CALLHOOK(SetModname);
914
915         // save it for later
916         modname = strzone(modname);
917
918         WinningConditionHelper(this); // set worldstatus
919
920         world_initialized = 1;
921 }
922
923 spawnfunc(light)
924 {
925         //makestatic (this); // Who the f___ did that?
926         delete(this);
927 }
928
929 string GetGametype()
930 {
931         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
932 }
933
934 string GetMapname()
935 {
936         return mapname;
937 }
938
939 float Map_Count, Map_Current;
940 string Map_Current_Name;
941
942 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
943 float GetMaplistPosition()
944 {
945         float pos, idx;
946         string map;
947
948         map = GetMapname();
949         idx = autocvar_g_maplist_index;
950
951         if(idx >= 0)
952                 if(idx < Map_Count)
953                         if(map == argv(idx))
954                                 return idx;
955
956         for(pos = 0; pos < Map_Count; ++pos)
957                 if(map == argv(pos))
958                         return pos;
959
960         // resume normal maplist rotation if current map is not in g_maplist
961         return idx;
962 }
963
964 float MapHasRightSize(string map)
965 {
966         float fh;
967         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
968         if(autocvar_g_maplist_check_waypoints)
969         {
970                 LOG_TRACE("checkwp "); LOG_TRACE(map);
971                 if(!fexists(strcat("maps/", map, ".waypoints")))
972                 {
973                         LOG_TRACE(": no waypoints\n");
974                         return false;
975                 }
976                 LOG_TRACE(": has waypoints\n");
977         }
978
979         // open map size restriction file
980         LOG_TRACE("opensize "); LOG_TRACE(map);
981         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
982         if(fh >= 0)
983         {
984                 float mapmin, mapmax;
985                 LOG_TRACE(": ok, ");
986                 mapmin = stof(fgets(fh));
987                 mapmax = stof(fgets(fh));
988                 fclose(fh);
989                 if(player_count < mapmin)
990                 {
991                         LOG_TRACE("not enough\n");
992                         return false;
993                 }
994                 if(player_count > mapmax)
995                 {
996                         LOG_TRACE("too many\n");
997                         return false;
998                 }
999                 LOG_TRACE("right size\n");
1000                 return true;
1001         }
1002         LOG_TRACE(": not found\n");
1003         return true;
1004 }
1005
1006 string Map_Filename(float position)
1007 {
1008         return strcat("maps/", argv(position), ".bsp");
1009 }
1010
1011 void Map_MarkAsRecent(string m)
1012 {
1013         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1014 }
1015
1016 float Map_IsRecent(string m)
1017 {
1018         return strhasword(autocvar_g_maplist_mostrecent, m);
1019 }
1020
1021 float Map_Check(float position, float pass)
1022 {
1023         string filename;
1024         string map_next;
1025         map_next = argv(position);
1026         if(pass <= 1)
1027         {
1028                 if(Map_IsRecent(map_next))
1029                         return 0;
1030         }
1031         filename = Map_Filename(position);
1032         if(MapInfo_CheckMap(map_next))
1033         {
1034                 if(pass == 2)
1035                         return 1;
1036                 if(MapHasRightSize(map_next))
1037                         return 1;
1038                 return 0;
1039         }
1040         else
1041                 LOG_DEBUG( "Couldn't select '", filename, "'...\n" );
1042
1043         return 0;
1044 }
1045
1046 void Map_Goto_SetStr(string nextmapname)
1047 {
1048         if(getmapname_stored != "")
1049                 strunzone(getmapname_stored);
1050         if(nextmapname == "")
1051                 getmapname_stored = "";
1052         else
1053                 getmapname_stored = strzone(nextmapname);
1054 }
1055
1056 void Map_Goto_SetFloat(float position)
1057 {
1058         cvar_set("g_maplist_index", ftos(position));
1059         Map_Goto_SetStr(argv(position));
1060 }
1061
1062 void Map_Goto(float reinit)
1063 {
1064         MapInfo_LoadMap(getmapname_stored, reinit);
1065 }
1066
1067 // return codes of map selectors:
1068 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1069 //   -2 = permanent failure
1070 float() MaplistMethod_Iterate = // usual method
1071 {
1072         float pass, i;
1073
1074         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1075
1076         for(pass = 1; pass <= 2; ++pass)
1077         {
1078                 for(i = 1; i < Map_Count; ++i)
1079                 {
1080                         float mapindex;
1081                         mapindex = (i + Map_Current) % Map_Count;
1082                         if(Map_Check(mapindex, pass))
1083                                 return mapindex;
1084                 }
1085         }
1086         return -1;
1087 }
1088
1089 float() MaplistMethod_Repeat = // fallback method
1090 {
1091         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1092
1093         if(Map_Check(Map_Current, 2))
1094                 return Map_Current;
1095         return -2;
1096 }
1097
1098 float() MaplistMethod_Random = // random map selection
1099 {
1100         float i, imax;
1101
1102         LOG_TRACE("Trying MaplistMethod_Random\n");
1103
1104         imax = 42;
1105
1106         for(i = 0; i <= imax; ++i)
1107         {
1108                 float mapindex;
1109                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1110                 if(Map_Check(mapindex, 1))
1111                         return mapindex;
1112         }
1113         return -1;
1114 }
1115
1116 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1117 // the exponent sets a bias on the map selection:
1118 // the higher the exponent, the less likely "shortly repeated" same maps are
1119 {
1120         float i, j, imax, insertpos;
1121
1122         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1123
1124         imax = 42;
1125
1126         for(i = 0; i <= imax; ++i)
1127         {
1128                 string newlist;
1129
1130                 // now reinsert this at another position
1131                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1132                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1133                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1134                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1135
1136                 // insert the current map there
1137                 newlist = "";
1138                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1139                         newlist = strcat(newlist, " ", argv(j));
1140                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1141                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1142                         newlist = strcat(newlist, " ", argv(j));
1143                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1144                 cvar_set("g_maplist", newlist);
1145                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1146
1147                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1148                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1149                 if(Map_Check(Map_Current, 1))
1150                         return Map_Current;
1151         }
1152         return -1;
1153 }
1154
1155 void Maplist_Init()
1156 {
1157         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1158         float i;
1159         for (i = 0; i < Map_Count; ++i)
1160                 if (Map_Check(i, 2))
1161                         break;
1162         if (i == Map_Count)
1163         {
1164                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1165                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1166                 if(autocvar_g_maplist_shuffle)
1167                         ShuffleMaplist();
1168                 localcmd("\nmenu_cmd sync\n");
1169                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1170         }
1171         if(Map_Count == 0)
1172                 error("empty maplist, cannot select a new map");
1173         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1174
1175         if(Map_Current_Name)
1176                 strunzone(Map_Current_Name);
1177         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1178         // this may or may not be correct, but who cares, in the worst case a map
1179         // isn't chosen in the first pass that should have been
1180 }
1181
1182 string GetNextMap()
1183 {
1184         float nextMap;
1185
1186         Maplist_Init();
1187         nextMap = -1;
1188
1189         if(nextMap == -1)
1190                 if(autocvar_g_maplist_shuffle > 0)
1191                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1192
1193         if(nextMap == -1)
1194                 if(autocvar_g_maplist_selectrandom)
1195                         nextMap = MaplistMethod_Random();
1196
1197         if(nextMap == -1)
1198                 nextMap = MaplistMethod_Iterate();
1199
1200         if(nextMap == -1)
1201                 nextMap = MaplistMethod_Repeat();
1202
1203         if(nextMap >= 0)
1204         {
1205                 Map_Goto_SetFloat(nextMap);
1206                 return getmapname_stored;
1207         }
1208
1209         return "";
1210 }
1211
1212 float DoNextMapOverride(float reinit)
1213 {
1214         if(autocvar_g_campaign)
1215         {
1216                 CampaignPostIntermission();
1217                 alreadychangedlevel = true;
1218                 return true;
1219         }
1220         if(autocvar_quit_when_empty)
1221         {
1222                 if(player_count <= currentbots)
1223                 {
1224                         localcmd("quit\n");
1225                         alreadychangedlevel = true;
1226                         return true;
1227                 }
1228         }
1229         if(autocvar_quit_and_redirect != "")
1230         {
1231                 redirection_target = strzone(autocvar_quit_and_redirect);
1232                 alreadychangedlevel = true;
1233                 return true;
1234         }
1235         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1236         {
1237                 localcmd("restart\n");
1238                 alreadychangedlevel = true;
1239                 return true;
1240         }
1241         if(autocvar_nextmap != "")
1242         {
1243                 string m;
1244                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1245                 cvar_set("nextmap",m);
1246
1247                 if(!m || gametypevote)
1248                         return false;
1249                 if(autocvar_sv_vote_gametype)
1250                 {
1251                         Map_Goto_SetStr(m);
1252                         return false;
1253                 }
1254
1255                 if(MapInfo_CheckMap(m))
1256                 {
1257                         Map_Goto_SetStr(m);
1258                         Map_Goto(reinit);
1259                         alreadychangedlevel = true;
1260                         return true;
1261                 }
1262         }
1263         if(!reinit && autocvar_lastlevel)
1264         {
1265                 cvar_settemp_restore();
1266                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1267                 alreadychangedlevel = true;
1268                 return true;
1269         }
1270         return false;
1271 }
1272
1273 void GotoNextMap(float reinit)
1274 {
1275         //string nextmap;
1276         //float n, nummaps;
1277         //string s;
1278         if (alreadychangedlevel)
1279                 return;
1280         alreadychangedlevel = true;
1281
1282         string nextMap;
1283
1284         nextMap = GetNextMap();
1285         if(nextMap == "")
1286                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1287         Map_Goto(reinit);
1288 }
1289
1290
1291 /*
1292 ============
1293 IntermissionThink
1294
1295 When the player presses attack or jump, change to the next level
1296 ============
1297 */
1298 .float autoscreenshot;
1299 void IntermissionThink(entity this)
1300 {
1301         FixIntermissionClient(this);
1302         CSQCMODEL_AUTOUPDATE(this); // PlayerPostThink returns before calling this during intermission, so run it here
1303
1304         float server_screenshot = (autocvar_sv_autoscreenshot && this.cvar_cl_autoscreenshot);
1305         float client_screenshot = (this.cvar_cl_autoscreenshot == 2);
1306
1307         if( (server_screenshot || client_screenshot)
1308                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1309         {
1310                 this.autoscreenshot = -1;
1311                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1312                 return;
1313         }
1314
1315         if (time < intermission_exittime)
1316                 return;
1317
1318         if(!mapvote_initialized)
1319                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1320                         return;
1321
1322         MapVote_Start();
1323 }
1324
1325 /*
1326 ============
1327 FindIntermission
1328
1329 Returns the entity to view from
1330 ============
1331 */
1332 /*
1333 entity FindIntermission()
1334 {
1335         local   entity spot;
1336         local   float cyc;
1337
1338 // look for info_intermission first
1339         spot = find (NULL, classname, "info_intermission");
1340         if (spot)
1341         {       // pick a random one
1342                 cyc = random() * 4;
1343                 while (cyc > 1)
1344                 {
1345                         spot = find (spot, classname, "info_intermission");
1346                         if (!spot)
1347                                 spot = find (spot, classname, "info_intermission");
1348                         cyc = cyc - 1;
1349                 }
1350                 return spot;
1351         }
1352
1353 // then look for the start position
1354         spot = find (NULL, classname, "info_player_start");
1355         if (spot)
1356                 return spot;
1357
1358 // testinfo_player_start is only found in regioned levels
1359         spot = find (NULL, classname, "testplayerstart");
1360         if (spot)
1361                 return spot;
1362
1363 // then look for the start position
1364         spot = find (NULL, classname, "info_player_deathmatch");
1365         if (spot)
1366                 return spot;
1367
1368         //objerror ("FindIntermission: no spot");
1369         return NULL;
1370 }
1371 */
1372
1373 /*
1374 ===============================================================================
1375
1376 RULES
1377
1378 ===============================================================================
1379 */
1380
1381 void DumpStats(float final)
1382 {
1383         float file;
1384         string s;
1385         float to_console;
1386         float to_eventlog;
1387         float to_file;
1388         float i;
1389
1390         to_console = autocvar_sv_logscores_console;
1391         to_eventlog = autocvar_sv_eventlog;
1392         to_file = autocvar_sv_logscores_file;
1393
1394         if(!final)
1395         {
1396                 to_console = true; // always print printstats replies
1397                 to_eventlog = false; // but never print them to the event log
1398         }
1399
1400         if(to_eventlog)
1401                 if(autocvar_sv_eventlog_console)
1402                         to_console = false; // otherwise we get the output twice
1403
1404         if(final)
1405                 s = ":scores:";
1406         else
1407                 s = ":status:";
1408         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1409
1410         if(to_console)
1411                 LOG_INFO(s, "\n");
1412         if(to_eventlog)
1413                 GameLogEcho(s);
1414
1415         file = -1;
1416         if(to_file)
1417         {
1418                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1419                 if(file == -1)
1420                         to_file = false;
1421                 else
1422                         fputs(file, strcat(s, "\n"));
1423         }
1424
1425         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1426         if(to_console)
1427                 LOG_INFO(s, "\n");
1428         if(to_eventlog)
1429                 GameLogEcho(s);
1430         if(to_file)
1431                 fputs(file, strcat(s, "\n"));
1432
1433         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1434                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1435                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1436                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1437                         s = strcat(s, ftos(it.team), ":");
1438                 else
1439                         s = strcat(s, "spectator:");
1440
1441                 if(to_console)
1442                         LOG_INFO(s, it.netname, "\n");
1443                 if(to_eventlog)
1444                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1445                 if(to_file)
1446                         fputs(file, strcat(s, it.netname, "\n"));
1447         ));
1448
1449         if(teamplay)
1450         {
1451                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1452                 if(to_console)
1453                         LOG_INFO(s, "\n");
1454                 if(to_eventlog)
1455                         GameLogEcho(s);
1456                 if(to_file)
1457                         fputs(file, strcat(s, "\n"));
1458
1459                 for(i = 1; i < 16; ++i)
1460                 {
1461                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1462                         s = strcat(s, ":", ftos(i));
1463                         if(to_console)
1464                                 LOG_INFO(s, "\n");
1465                         if(to_eventlog)
1466                                 GameLogEcho(s);
1467                         if(to_file)
1468                                 fputs(file, strcat(s, "\n"));
1469                 }
1470         }
1471
1472         if(to_console)
1473                 LOG_INFO(":end\n");
1474         if(to_eventlog)
1475                 GameLogEcho(":end");
1476         if(to_file)
1477         {
1478                 fputs(file, ":end\n");
1479                 fclose(file);
1480         }
1481 }
1482
1483 void FixIntermissionClient(entity e)
1484 {
1485         if(!e.autoscreenshot) // initial call
1486         {
1487                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1488                 e.health = -2342;
1489                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1490                 e.solid = SOLID_NOT;
1491                 set_movetype(e, MOVETYPE_NONE);
1492                 e.takedamage = DAMAGE_NO;
1493                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1494                 {
1495                     .entity weaponentity = weaponentities[slot];
1496                         if(e.(weaponentity))
1497                         {
1498                                 e.(weaponentity).effects = EF_NODRAW;
1499                                 if (e.(weaponentity).weaponchild)
1500                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1501                         }
1502                 }
1503                 if(IS_REAL_CLIENT(e))
1504                 {
1505                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1506                         RandomSelection_Init();
1507                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1508                                 RandomSelection_Add(NULL, 0, it, 1, 1);
1509                         ));
1510                         if (RandomSelection_chosen_string != "")
1511                         {
1512                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1513                         }
1514                         msg_entity = e;
1515                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1516                 }
1517         }
1518 }
1519
1520 /*
1521 go to the next level for deathmatch
1522 only called if a time or frag limit has expired
1523 */
1524 void NextLevel()
1525 {
1526         gameover = true;
1527
1528         intermission_running = 1;
1529
1530 // enforce a wait time before allowing changelevel
1531         if(player_count > 0)
1532                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1533         else
1534                 intermission_exittime = -1;
1535
1536         /*
1537         WriteByte (MSG_ALL, SVC_CDTRACK);
1538         WriteByte (MSG_ALL, 3);
1539         WriteByte (MSG_ALL, 3);
1540         // done in FixIntermission
1541         */
1542
1543         //pos = FindIntermission ();
1544
1545         VoteReset();
1546
1547         DumpStats(true);
1548
1549         // send statistics
1550         PlayerStats_GameReport(true);
1551         WeaponStats_Shutdown();
1552
1553         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1554
1555         if(autocvar_sv_eventlog)
1556                 GameLogEcho(":gameover");
1557
1558         GameLogClose();
1559
1560         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1561                 FixIntermissionClient(it);
1562                 if(it.winning)
1563                         bprint(it.netname, " ^7wins.\n");
1564         ));
1565
1566         target_music_kill();
1567
1568         if(autocvar_g_campaign)
1569                 CampaignPreIntermission();
1570
1571         MUTATOR_CALLHOOK(MatchEnd);
1572
1573         localcmd("\nsv_hook_gameend\n");
1574 }
1575
1576 /*
1577 ============
1578 CheckRules_Player
1579
1580 Exit deathmatch games upon conditions
1581 ============
1582 */
1583 void CheckRules_Player(entity this)
1584 {
1585         if (gameover)   // someone else quit the game already
1586                 return;
1587
1588         if(!IS_DEAD(this))
1589                 this.play_time += frametime;
1590
1591         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1592         //   (div0: and that in CheckRules_World please)
1593 }
1594
1595
1596 float InitiateSuddenDeath()
1597 {
1598         // Check first whether normal overtimes could be added before initiating suddendeath mode
1599         // - for this timelimit_overtime needs to be >0 of course
1600         // - also check the winning condition calculated in the previous frame and only add normal overtime
1601         //   again, if at the point at which timelimit would be extended again, still no winner was found
1602         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1603         {
1604                 return 1; // need to call InitiateOvertime later
1605         }
1606         else
1607         {
1608                 if(!checkrules_suddendeathend)
1609                 {
1610                         if(autocvar_g_campaign)
1611                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1612                         else
1613                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1614                         if(g_race && !g_race_qualifying)
1615                                 race_StartCompleting();
1616                 }
1617                 return 0;
1618         }
1619 }
1620
1621 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1622 {
1623         ++checkrules_overtimesadded;
1624         //add one more overtime by simply extending the timelimit
1625         float tl;
1626         tl = autocvar_timelimit;
1627         tl += autocvar_timelimit_overtime;
1628         cvar_set("timelimit", ftos(tl));
1629
1630         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1631 }
1632
1633 float GetWinningCode(float fraglimitreached, float equality)
1634 {
1635         if(autocvar_g_campaign == 1)
1636                 if(fraglimitreached)
1637                         return WINNING_YES;
1638                 else
1639                         return WINNING_NO;
1640
1641         else
1642                 if(equality)
1643                         if(fraglimitreached)
1644                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1645                         else
1646                                 return WINNING_NEVER;
1647                 else
1648                         if(fraglimitreached)
1649                                 return WINNING_YES;
1650                         else
1651                                 return WINNING_NO;
1652 }
1653
1654 // set the .winning flag for exactly those players with a given field value
1655 void SetWinners(.float field, float value)
1656 {
1657         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1658 }
1659
1660 // set the .winning flag for those players with a given field value
1661 void AddWinners(.float field, float value)
1662 {
1663         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1664                 if(it.(field) == value)
1665                         it.winning = 1;
1666         ));
1667 }
1668
1669 // clear the .winning flags
1670 void ClearWinners()
1671 {
1672         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1673 }
1674
1675 void ShuffleMaplist()
1676 {
1677         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1678 }
1679
1680 float leaderfrags;
1681 float WinningCondition_Scores(float limit, float leadlimit)
1682 {
1683         float limitreached;
1684
1685         // TODO make everything use THIS winning condition (except LMS)
1686         WinningConditionHelper(NULL);
1687
1688         if(teamplay)
1689         {
1690                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1691                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1692                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1693                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1694         }
1695
1696         ClearWinners();
1697         if(WinningConditionHelper_winner)
1698                 WinningConditionHelper_winner.winning = 1;
1699         if(WinningConditionHelper_winnerteam >= 0)
1700                 SetWinners(team, WinningConditionHelper_winnerteam);
1701
1702         if(WinningConditionHelper_lowerisbetter)
1703         {
1704                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1705                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1706                 limit = -limit;
1707         }
1708
1709         if(WinningConditionHelper_zeroisworst)
1710                 leadlimit = 0; // not supported in this mode
1711
1712         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1713         // these modes always score in increments of 1, thus this makes sense
1714         {
1715                 if(leaderfrags != WinningConditionHelper_topscore)
1716                 {
1717                         leaderfrags = WinningConditionHelper_topscore;
1718
1719                         if (limit)
1720                         if (leaderfrags == limit - 1)
1721                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1722                         else if (leaderfrags == limit - 2)
1723                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1724                         else if (leaderfrags == limit - 3)
1725                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1726                 }
1727         }
1728
1729         limitreached = false;
1730         if(limit)
1731                 if(WinningConditionHelper_topscore >= limit)
1732                         limitreached = true;
1733         if(leadlimit)
1734         {
1735                 float leadlimitreached;
1736                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1737                 if(autocvar_leadlimit_and_fraglimit)
1738                         limitreached = (limitreached && leadlimitreached);
1739                 else
1740                         limitreached = (limitreached || leadlimitreached);
1741         }
1742
1743         if(limit)
1744                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1745
1746         return GetWinningCode(
1747                 WinningConditionHelper_topscore && limitreached,
1748                 WinningConditionHelper_equality
1749         );
1750 }
1751
1752 float WinningCondition_RanOutOfSpawns()
1753 {
1754         if(have_team_spawns <= 0)
1755                 return WINNING_NO;
1756
1757         if(!autocvar_g_spawn_useallspawns)
1758                 return WINNING_NO;
1759
1760         if(!some_spawn_has_been_used)
1761                 return WINNING_NO;
1762
1763         team1_score = team2_score = team3_score = team4_score = 0;
1764
1765         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1766                 switch(it.team)
1767                 {
1768                         case NUM_TEAM_1: team1_score = 1; break;
1769                         case NUM_TEAM_2: team2_score = 1; break;
1770                         case NUM_TEAM_3: team3_score = 1; break;
1771                         case NUM_TEAM_4: team4_score = 1; break;
1772                 }
1773         ));
1774
1775         FOREACH_ENTITY_CLASS("info_player_deathmatch", true, LAMBDA(
1776                 switch(it.team)
1777                 {
1778                         case NUM_TEAM_1: team1_score = 1; break;
1779                         case NUM_TEAM_2: team2_score = 1; break;
1780                         case NUM_TEAM_3: team3_score = 1; break;
1781                         case NUM_TEAM_4: team4_score = 1; break;
1782                 }
1783         ));
1784
1785         ClearWinners();
1786         if(team1_score + team2_score + team3_score + team4_score == 0)
1787         {
1788                 checkrules_equality = true;
1789                 return WINNING_YES;
1790         }
1791         else if(team1_score + team2_score + team3_score + team4_score == 1)
1792         {
1793                 float t, i;
1794                 if(team1_score)
1795                         t = NUM_TEAM_1;
1796                 else if(team2_score)
1797                         t = NUM_TEAM_2;
1798                 else if(team3_score)
1799                         t = NUM_TEAM_3;
1800                 else // if(team4_score)
1801                         t = NUM_TEAM_4;
1802                 CheckAllowedTeams(NULL);
1803                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1804                 {
1805                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1806                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1807                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1808                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1809                 }
1810
1811                 AddWinners(team, t);
1812                 return WINNING_YES;
1813         }
1814         else
1815                 return WINNING_NO;
1816 }
1817
1818 /*
1819 ============
1820 CheckRules_World
1821
1822 Exit deathmatch games upon conditions
1823 ============
1824 */
1825 void CheckRules_World()
1826 {
1827         float timelimit;
1828         float fraglimit;
1829         float leadlimit;
1830
1831         VoteThink();
1832         MapVote_Think();
1833
1834         SetDefaultAlpha();
1835
1836         if (gameover)   // someone else quit the game already
1837         {
1838                 if(player_count == 0) // Nobody there? Then let's go to the next map
1839                         MapVote_Start();
1840                         // this will actually check the player count in the next frame
1841                         // again, but this shouldn't hurt
1842                 return;
1843         }
1844
1845         timelimit = autocvar_timelimit * 60;
1846         fraglimit = autocvar_fraglimit;
1847         leadlimit = autocvar_leadlimit;
1848
1849         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1850         {
1851                 if(timelimit > 0)
1852                         timelimit = 0; // timelimit is not made for warmup
1853                 if(fraglimit > 0)
1854                         fraglimit = 0; // no fraglimit for now
1855                 leadlimit = 0; // no leadlimit for now
1856         }
1857
1858         if(timelimit > 0)
1859         {
1860                 timelimit += game_starttime;
1861         }
1862         else if (timelimit < 0)
1863         {
1864                 // endmatch
1865                 NextLevel();
1866                 return;
1867         }
1868
1869         float wantovertime;
1870         wantovertime = 0;
1871
1872         if(timelimit > game_starttime)
1873                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1874         else
1875                 game_completion_ratio = 0;
1876
1877         if(checkrules_suddendeathend)
1878         {
1879                 if(!checkrules_suddendeathwarning)
1880                 {
1881                         checkrules_suddendeathwarning = true;
1882                         if(g_race && !g_race_qualifying)
1883                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1884                         else
1885                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1886                 }
1887         }
1888         else
1889         {
1890                 if (timelimit && time >= timelimit)
1891                 {
1892                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1893                         {
1894                                 float totalplayers;
1895                                 float playerswithlaps;
1896                                 float readyplayers;
1897                                 totalplayers = playerswithlaps = readyplayers = 0;
1898                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1899                                         ++totalplayers;
1900                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1901                                                 ++playerswithlaps;
1902                                         if(it.ready)
1903                                                 ++readyplayers;
1904                                 ));
1905
1906                                 // at least 2 of the players have completed a lap: start the RACE
1907                                 // otherwise, the players should end the qualifying on their own
1908                                 if(readyplayers || playerswithlaps >= 2)
1909                                 {
1910                                         checkrules_suddendeathend = 0;
1911                                         ReadyRestart(); // go to race
1912                                         return;
1913                                 }
1914                                 else
1915                                         wantovertime |= InitiateSuddenDeath();
1916                         }
1917                         else
1918                                 wantovertime |= InitiateSuddenDeath();
1919                 }
1920         }
1921
1922         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1923         {
1924                 NextLevel();
1925                 return;
1926         }
1927
1928         int checkrules_status = WinningCondition_RanOutOfSpawns();
1929         if(checkrules_status == WINNING_YES)
1930                 bprint("Hey! Someone ran out of spawns!\n");
1931         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1932                 checkrules_status = M_ARGV(0, float);
1933         else
1934                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1935
1936         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1937         {
1938                 checkrules_status = WINNING_NEVER;
1939                 checkrules_overtimesadded = -1;
1940                 wantovertime |= InitiateSuddenDeath();
1941         }
1942
1943         if(checkrules_status == WINNING_NEVER)
1944                 // equality cases! Nobody wins if the overtime ends in a draw.
1945                 ClearWinners();
1946
1947         if(wantovertime)
1948         {
1949                 if(checkrules_status == WINNING_NEVER)
1950                         InitiateOvertime();
1951                 else
1952                         checkrules_status = WINNING_YES;
1953         }
1954
1955         if(checkrules_suddendeathend)
1956                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1957                         checkrules_status = WINNING_YES;
1958
1959         if(checkrules_status == WINNING_YES)
1960         {
1961                 //print("WINNING\n");
1962                 NextLevel();
1963         }
1964 }
1965
1966 string GotoMap(string m)
1967 {
1968         m = GameTypeVote_MapInfo_FixName(m);
1969         if (!m)
1970                 return "The map you suggested is not available on this server.";
1971         if (!autocvar_sv_vote_gametype)
1972         if(!MapInfo_CheckMap(m))
1973                 return "The map you suggested does not support the current game mode.";
1974         cvar_set("nextmap", m);
1975         cvar_set("timelimit", "-1");
1976         if(mapvote_initialized || alreadychangedlevel)
1977         {
1978                 if(DoNextMapOverride(0))
1979                         return "Map switch initiated.";
1980                 else
1981                         return "Hm... no. For some reason I like THIS map more.";
1982         }
1983         else
1984                 return "Map switch will happen after scoreboard.";
1985 }
1986
1987 bool autocvar_sv_freezenonclients;
1988 bool autocvar_sv_gameplayfix_delayprojectiles;
1989 void Physics_Frame()
1990 {
1991         if(autocvar_sv_freezenonclients)
1992                 return;
1993
1994         FOREACH_ENTITY_FLOAT(pure_data, false,
1995         {
1996                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
1997                         continue;
1998
1999                 int mt = it.move_movetype;
2000
2001                 if(mt == MOVETYPE_PUSH || mt == MOVETYPE_FAKEPUSH || mt == MOVETYPE_PHYSICS)
2002                 {
2003                         it.move_qcphysics = false;
2004                         set_movetype(it, mt);
2005                         continue;
2006                 }
2007
2008                 set_movetype(it, ((it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype));
2009
2010                 if(it.move_movetype == MOVETYPE_NONE)
2011                         continue;
2012
2013                 if(it.move_qcphysics)
2014                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2015         });
2016
2017         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2018                 return;
2019
2020         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2021         {
2022                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2023                         continue;
2024                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2025         });
2026 }
2027
2028 void systems_update();
2029 void EndFrame()
2030 {
2031         anticheat_endframe();
2032
2033         Physics_Frame();
2034
2035         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2036                 entity e = IS_SPEC(it) ? it.enemy : it;
2037                 if (e.typehitsound) {
2038                         it.typehit_time = time;
2039                 } else if (e.damage_dealt) {
2040                         it.hit_time = time;
2041                         it.damage_dealt_total += ceil(e.damage_dealt);
2042                 }
2043         });
2044         // add 1 frametime because after this, engine SV_Physics
2045         // increases time by a frametime and then networks the frame
2046         // add another frametime because client shows everything with
2047         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2048         // needed!
2049         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2050         FOREACH_CLIENT(true, {
2051                 it.typehitsound = false;
2052                 it.damage_dealt = 0;
2053                 antilag_record(it, CS(it), altime);
2054         });
2055         IL_EACH(g_monsters, true,
2056         {
2057                 antilag_record(it, it, altime);
2058         });
2059         FOREACH_CLIENT(PS(it), {
2060                 PlayerState s = PS(it);
2061                 s.ps_push(s, it);
2062         });
2063         systems_update();
2064         IL_ENDFRAME();
2065 }
2066
2067
2068 /*
2069  * RedirectionThink:
2070  * returns true if redirecting
2071  */
2072 float redirection_timeout;
2073 float redirection_nextthink;
2074 float RedirectionThink()
2075 {
2076         float clients_found;
2077
2078         if(redirection_target == "")
2079                 return false;
2080
2081         if(!redirection_timeout)
2082         {
2083                 cvar_set("sv_public", "-2");
2084                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2085                 if(redirection_target == "self")
2086                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2087                 else
2088                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2089         }
2090
2091         if(time < redirection_nextthink)
2092                 return true;
2093
2094         redirection_nextthink = time + 1;
2095
2096         clients_found = 0;
2097         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2098                 // TODO add timer
2099                 LOG_INFO("Redirecting: sending connect command to ", it.netname, "\n");
2100                 if(redirection_target == "self")
2101                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2102                 else
2103                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2104                 ++clients_found;
2105         ));
2106
2107         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2108
2109         if(time > redirection_timeout || clients_found == 0)
2110                 localcmd("\nwait; wait; wait; quit\n");
2111
2112         return true;
2113 }
2114
2115 void TargetMusic_RestoreGame();
2116 void RestoreGame()
2117 {
2118         // Loaded from a save game
2119         // some things then break, so let's work around them...
2120
2121         // Progs DB (capture records)
2122         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2123
2124         // Mapinfo
2125         MapInfo_Shutdown();
2126         MapInfo_Enumerate();
2127         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2128         WeaponStats_Init();
2129
2130         TargetMusic_RestoreGame();
2131 }
2132
2133 void Shutdown()
2134 {
2135         gameover = 2;
2136
2137         if(world_initialized > 0)
2138         {
2139                 world_initialized = 0;
2140                 LOG_TRACE("Saving persistent data...\n");
2141                 Ban_SaveBans();
2142
2143                 // playerstats with unfinished match
2144                 PlayerStats_GameReport(false);
2145
2146                 if(!cheatcount_total)
2147                 {
2148                         if(autocvar_sv_db_saveasdump)
2149                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2150                         else
2151                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2152                 }
2153                 if(autocvar_developer)
2154                 {
2155                         if(autocvar_sv_db_saveasdump)
2156                                 db_dump(TemporaryDB, "server-temp.db");
2157                         else
2158                                 db_save(TemporaryDB, "server-temp.db");
2159                 }
2160                 CheatShutdown(); // must be after cheatcount check
2161                 db_close(ServerProgsDB);
2162                 db_close(TemporaryDB);
2163                 LOG_TRACE("Saving persistent data... done!\n");
2164                 // tell the bot system the game is ending now
2165                 bot_endgame();
2166
2167                 WeaponStats_Shutdown();
2168                 MapInfo_Shutdown();
2169         }
2170         else if(world_initialized == 0)
2171         {
2172                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2173         }
2174         else
2175         {
2176                 __init_dedicated_server_shutdown();
2177         }
2178 }