qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_assault");
 257                 BADCVAR("g_ca");
 258                 BADCVAR("g_ca_teams");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_freezetag_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_leadlimit");
 308                 BADCVAR("g_ctf_captimerecord_always");
 309                 BADCVAR("g_ctf_flag_glowtrails");
 310                 BADCVAR("g_ctf_flag_pickup_verbosename");
 311                 BADCVAR("g_domination_point_leadlimit");
 312                 BADCVAR("g_forced_respawn");
 313                 BADCVAR("g_keyhunt_point_leadlimit");
 314                 BADPREFIX("g_mod_");
 315                 BADCVAR("g_nexball_goalleadlimit");
 316                 BADCVAR("leadlimit_and_fraglimit");
 317                 BADCVAR("leadlimit_override");
 318                 BADCVAR("pausable");
 319                 BADCVAR("sv_allow_fullbright");
 320                 BADCVAR("sv_checkforpacketsduringsleep");
 321                 BADCVAR("sv_fraginfo");
 322                 BADCVAR("sv_timeout");
 323                 BADPREFIX("sv_timeout_");
 324                 BADPREFIX("crypto_");
 325                 BADPREFIX("g_chat_");
 326                 BADPREFIX("g_ctf_captimerecord_");
 327                 BADPREFIX("g_maplist_votable_");
 328                 BADPREFIX("net_");
 329                 BADPREFIX("prvm_");
 330                 BADPREFIX("skill_");
 331                 BADPREFIX("sv_cullentities_");
 332                 BADPREFIX("sv_fraginfo_");
 333                 BADPREFIX("sv_maxidle_");
 334                 BADPREFIX("sv_vote_");
 335                 BADPREFIX("timelimit_");
 336                 BADCVAR("gameversion");
 337                 BADPREFIX("gameversion_");
 338                 BADCVAR("sv_namechangetimer");
 339
 340                 // allowed changes to server admins (please sync this to server.cfg)
 341                 // vi commands:
 342                 //   :/"impure"/,$d
 343                 //   :g!,^\/\/[^ /],d
 344                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 345                 //   :%!sort
 346                 // yes, this does contain some redundant stuff, don't really care
 347                 BADCVAR("bot_config_file");
 348                 BADCVAR("bot_number");
 349                 BADCVAR("bot_prefix");
 350                 BADCVAR("bot_suffix");
 351                 BADCVAR("capturelimit_override");
 352                 BADCVAR("fraglimit_override");
 353                 BADCVAR("gametype");
 354                 BADCVAR("g_antilag");
 355                 BADCVAR("g_balance_teams");
 356                 BADCVAR("g_balance_teams_prevent_imbalance");
 357                 BADCVAR("g_balance_teams_scorefactor");
 358                 BADCVAR("g_ban_sync_trusted_servers");
 359                 BADCVAR("g_ban_sync_uri");
 360                 BADCVAR("g_ca_teams_override");
 361                 BADCVAR("g_ctf_ignore_frags");
 362                 BADCVAR("g_domination_point_limit");
 363                 BADCVAR("g_freezetag_teams_override");
 364                 BADCVAR("g_friendlyfire");
 365                 BADCVAR("g_fullbrightitems");
 366                 BADCVAR("g_fullbrightplayers");
 367                 BADCVAR("g_keyhunt_point_limit");
 368                 BADCVAR("g_keyhunt_teams_override");
 369                 BADCVAR("g_lms_lives_override");
 370                 BADCVAR("g_maplist");
 371                 BADCVAR("g_maplist_check_waypoints");
 372                 BADCVAR("g_maplist_mostrecent_count");
 373                 BADCVAR("g_maplist_shuffle");
 374                 BADCVAR("g_maplist_votable");
 375                 BADCVAR("g_maplist_votable_abstain");
 376                 BADCVAR("g_maplist_votable_nodetail");
 377                 BADCVAR("g_maplist_votable_suggestions");
 378                 BADCVAR("g_maxplayers");
 379                 BADCVAR("g_mirrordamage");
 380                 BADCVAR("g_nexball_goallimit");
 381                 BADCVAR("g_powerups");
 382                 BADCVAR("g_start_delay");
 383                 BADCVAR("g_warmup");
 384                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 385                 BADCVAR("hostname");
 386                 BADCVAR("log_file");
 387                 BADCVAR("maxplayers");
 388                 BADCVAR("minplayers");
 389                 BADCVAR("net_address");
 390                 BADCVAR("port");
 391                 BADCVAR("rcon_password");
 392                 BADCVAR("rcon_restricted_commands");
 393                 BADCVAR("rcon_restricted_password");
 394                 BADCVAR("skill");
 395                 BADCVAR("sv_adminnick");
 396                 BADCVAR("sv_autoscreenshot");
 397                 BADCVAR("sv_autotaunt");
 398                 BADCVAR("sv_curl_defaulturl");
 399                 BADCVAR("sv_defaultcharacter");
 400                 BADCVAR("sv_defaultplayercolors");
 401                 BADCVAR("sv_defaultplayermodel");
 402                 BADCVAR("sv_defaultplayerskin");
 403                 BADCVAR("sv_maxidle");
 404                 BADCVAR("sv_maxrate");
 405                 BADCVAR("sv_motd");
 406                 BADCVAR("sv_public");
 407                 BADCVAR("sv_ready_restart");
 408                 BADCVAR("sv_status_privacy");
 409                 BADCVAR("sv_taunt");
 410                 BADCVAR("sv_vote_call");
 411                 BADCVAR("sv_vote_commands");
 412                 BADCVAR("sv_vote_majority_factor");
 413                 BADCVAR("sv_vote_master");
 414                 BADCVAR("sv_vote_master_commands");
 415                 BADCVAR("sv_vote_master_password");
 416                 BADCVAR("sv_vote_simple_majority_factor");
 417                 BADCVAR("teamplay_mode");
 418                 BADCVAR("timelimit_override");
 419                 BADCVAR("g_spawnshieldtime");
 420                 BADPREFIX("g_warmup_");
 421                 BADPREFIX("sv_ready_restart_");
 422
 423                 // mutators that announce themselves properly to the server browser
 424                 BADCVAR("g_minstagib");
 425                 BADCVAR("g_new_toys");
 426                 BADCVAR("g_nix");
 427                 BADCVAR("g_grappling_hook");
 428                 BADCVAR("g_jetpack");
 429
 430 #undef BADPREFIX
 431 #undef BADCVAR
 432
 433                 if(pureadding)
 434                 {
 435                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 436                         if(strlen(cvar_purechanges) > 16384)
 437                         {
 438                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 439                                 pureadding = 0;
 440                         }
 441                 }
 442                 ++cvar_purechanges_count;
 443                 // WARNING: this variable is used for the server list
 444                 // NEVER dare to skip this code!
 445                 // Hacks to intentionally appearing as "pure server" even though you DO have
 446                 // modified settings may be punished by removal from the server list.
 447                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 448                 // though.
 449         }
 450         buf_del(h);
 451         if(cvar_changes == "")
 452                 cvar_changes = "// this server runs at default server settings\n";
 453         else
 454                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 455         cvar_changes = strzone(cvar_changes);
 456         if(cvar_purechanges == "")
 457                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 458         else
 459                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 460         cvar_purechanges = strzone(cvar_purechanges);
 461 }
 462
 463 void detect_maptype()
 464 {
 465 #if 0
 466         vector o, v;
 467         float i;
 468
 469         for(;;)
 470         {
 471                 o = world.mins;
 472                 o_x += random() * (world.maxs_x - world.mins_x);
 473                 o_y += random() * (world.maxs_y - world.mins_y);
 474                 o_z += random() * (world.maxs_z - world.mins_z);
 475
 476                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 477                 if(trace_fraction == 1)
 478                         continue;
 479
 480                 v = trace_endpos;
 481
 482                 for(i = 0; i < 64; i += 4)
 483                 {
 484                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 485         if(trace_fraction == 1)
 486                 continue;
 487                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 488                 }
 489
 490                 break;
 491         }
 492 #endif
 493 }
 494
 495 entity randomseed;
 496 float RandomSeed_Send(entity to, float sf)
 497 {
 498         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 499         WriteShort(MSG_ENTITY, self.cnt);
 500         return TRUE;
 501 }
 502 void RandomSeed_Think()
 503 {
 504         self.cnt = bound(0, floor(random() * 65536), 65535);
 505         self.nextthink = time + 5;
 506
 507         self.SendFlags |= 1;
 508 }
 509 void RandomSeed_Spawn()
 510 {
 511         randomseed = spawn();
 512         randomseed.think = RandomSeed_Think;
 513         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 514
 515         entity oldself;
 516         oldself = self;
 517         self = randomseed;
 518         self.think(); // sets random seed and nextthink
 519         self = oldself;
 520 }
 521
 522 void spawnfunc___init_dedicated_server(void)
 523 {
 524         // handler for _init/_init map (only for dedicated server initialization)
 525
 526         world_initialized = -1; // don't complain
 527         cvar = cvar_normal;
 528         cvar_string = cvar_string_normal;
 529         cvar_set = cvar_set_normal;
 530
 531         remove = remove_unsafely;
 532
 533         entity e;
 534         e = spawn();
 535         e.think = GotoFirstMap;
 536         e.nextthink = time; // this is usually 1 at this point
 537
 538         e = spawn();
 539         e.classname = "info_player_deathmatch"; // safeguard against player joining
 540
 541         self.classname = "worldspawn"; // safeguard against various stuff ;)
 542
 543         // needs to be done so early because of the constants they create
 544         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 545         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 546         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 547         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 548         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 591
 592         // needs to be done so early because of the constants they create
 593         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 594         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 595         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 596         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 597         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 598
 599         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 600
 601         TemporaryDB = db_create();
 602
 603         // 0 normal
 604         lightstyle(0, "m");
 605
 606         // 1 FLICKER (first variety)
 607         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 608
 609         // 2 SLOW STRONG PULSE
 610         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 611
 612         // 3 CANDLE (first variety)
 613         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 614
 615         // 4 FAST STROBE
 616         lightstyle(4, "mamamamamama");
 617
 618         // 5 GENTLE PULSE 1
 619         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 620
 621         // 6 FLICKER (second variety)
 622         lightstyle(6, "nmonqnmomnmomomno");
 623
 624         // 7 CANDLE (second variety)
 625         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 626
 627         // 8 CANDLE (third variety)
 628         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 629
 630         // 9 SLOW STROBE (fourth variety)
 631         lightstyle(9, "aaaaaaaazzzzzzzz");
 632
 633         // 10 FLUORESCENT FLICKER
 634         lightstyle(10, "mmamammmmammamamaaamammma");
 635
 636         // 11 SLOW PULSE NOT FADE TO BLACK
 637         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 638
 639         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 640
 641         // 63 testing
 642         lightstyle(63, "a");
 643
 644         if(autocvar_g_campaign)
 645                 CampaignPreInit();
 646
 647         Map_MarkAsRecent(mapname);
 648
 649         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 650
 651         precache_model ("null"); // we need this one before InitGameplayMode
 652         InitGameplayMode();
 653         readlevelcvars();
 654         GrappleHookInit();
 655
 656         player_count = 0;
 657         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 658         if(bot_waypoints_for_items == 1)
 659                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 660                         bot_waypoints_for_items = 0;
 661
 662         precache();
 663
 664         WaypointSprite_Init();
 665
 666         GameLogInit(); // prepare everything
 667         // NOTE for matchid:
 668         // changing the logic generating it is okay. But:
 669         // it HAS to stay <= 64 chars
 670         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 671         if(autocvar_sv_eventlog)
 672         {
 673                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 674                 matchid = strzone(s);
 675
 676                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 677                 s = ":gameinfo:mutators:LIST";
 678
 679                 ret_string = s;
 680                 MUTATOR_CALLHOOK(BuildMutatorsString);
 681                 s = ret_string;
 682
 683                 // simple, probably not good in the mutator system
 684                 if(autocvar_g_grappling_hook)
 685                         s = strcat(s, ":grappling_hook");
 686
 687                 // initialiation stuff, not good in the mutator system
 688                 if(!autocvar_g_use_ammunition)
 689                         s = strcat(s, ":no_use_ammunition");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(autocvar_g_pickup_items == 0)
 693                         s = strcat(s, ":no_pickup_items");
 694                 if(autocvar_g_pickup_items > 0)
 695                         s = strcat(s, ":pickup_items");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(autocvar_g_weaponarena != "0")
 699                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 700
 701                 // TODO to mutator system
 702                 if(autocvar_g_norecoil)
 703                         s = strcat(s, ":norecoil");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_powerups == 0)
 707                         s = strcat(s, ":no_powerups");
 708                 if(autocvar_g_powerups > 0)
 709                         s = strcat(s, ":powerups");
 710
 711                 GameLogEcho(s);
 712                 GameLogEcho(":gameinfo:end");
 713         }
 714         else
 715                 matchid = strzone(ftos(random()));
 716
 717         cvar_set("nextmap", "");
 718
 719         SetDefaultAlpha();
 720
 721         if(autocvar_g_campaign)
 722                 CampaignPostInit();
 723
 724         fteqcc_testbugs();
 725
 726         Ban_LoadBans();
 727
 728         MapInfo_Enumerate();
 729         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 730
 731         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 732         {
 733                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 734                 if(fd != -1)
 735                 {
 736                         while((s = fgets(fd)))
 737                         {
 738                                 l = tokenize_console(s);
 739                                 if(l < 2)
 740                                         continue;
 741                                 if(argv(0) == "cd")
 742                                 {
 743                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 744                                         print("  cdtrack ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) == "fog")
 747                                 {
 748                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 749                                         print("  \"fog\" \"", s, "\"\n");
 750                                 }
 751                                 else if(argv(0) == "set")
 752                                 {
 753                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 754                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 755                                 }
 756                                 else if(argv(0) != "//")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 760                                 }
 761                         }
 762                         fclose(fd);
 763                 }
 764         }
 765
 766         WeaponStats_Init();
 767
 768         WepSet_AddStat();
 769         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 770         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 771         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 772         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 773         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 774         Nagger_Init();
 775
 776         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 777         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 778         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 779         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 780         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 781         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 782         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 783         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 784         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 785         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 786         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 787         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 788         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 789
 790         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 791         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 792
 793         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 794
 795         // g_movementspeed hack
 796         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 797         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 798         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 799         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 800
 801         // secrets
 802         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 803         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 804
 805         // monsters
 806         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 807         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 808
 809         // misc
 810         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 811
 812         next_pingtime = time + 5;
 813
 814         detect_maptype();
 815
 816         // set up information replies for clients and server to use
 817         maplist_reply = strzone(getmaplist());
 818         lsmaps_reply = strzone(getlsmaps());
 819         monsterlist_reply = strzone(getmonsterlist());
 820         for(i = 0; i < 10; ++i)
 821         {
 822                 s = getrecords(i);
 823                 if (s)
 824                         records_reply[i] = strzone(s);
 825         }
 826         ladder_reply = strzone(getladder());
 827         rankings_reply = strzone(getrankings());
 828
 829         // begin other init
 830         ClientInit_Spawn();
 831         RandomSeed_Spawn();
 832         PingPLReport_Spawn();
 833
 834         CheatInit();
 835
 836         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 837
 838         // fill sv_curl_serverpackages from .serverpackage files
 839         if(autocvar_sv_curl_serverpackages_auto)
 840         {
 841                 s = "";
 842                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 843                 for(i = 0; i < n; ++i)
 844                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 845                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 846                                 s = strcat(s, " ", argv(i));
 847                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 848                 if(fd >= 0)
 849                 {
 850                         j = search_getsize(fd);
 851                         for(i = 0; i < j; ++i)
 852                                 s = strcat(s, " ", search_getfilename(fd, i));
 853                         search_end(fd);
 854                 }
 855                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 856                 if(fd >= 0)
 857                 {
 858                         j = search_getsize(fd);
 859                         for(i = 0; i < j; ++i)
 860                                 s = strcat(s, " ", search_getfilename(fd, i));
 861                         search_end(fd);
 862                 }
 863                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 864         }
 865
 866         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 867         modname = "Xonotic";
 868         // physics/balance/config changes that count as mod
 869         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 870                 modname = cvar_string("g_mod_physics");
 871         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 872                 modname = cvar_string("g_mod_balance");
 873         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 874                 modname = cvar_string("g_mod_config");
 875         // extra mutators that deserve to count as mod
 876         MUTATOR_CALLHOOK(SetModname);
 877
 878         // save it for later
 879         modname = strzone(modname);
 880
 881         WinningConditionHelper(); // set worldstatus
 882
 883         world_initialized = 1;
 884 }
 885
 886 void spawnfunc_light (void)
 887 {
 888         //makestatic (self); // Who the f___ did that?
 889         remove(self);
 890 }
 891
 892 string GetGametype()
 893 {
 894         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 895 }
 896
 897 string getmapname_stored;
 898 string GetMapname()
 899 {
 900         return mapname;
 901 }
 902
 903 float Map_Count, Map_Current;
 904 string Map_Current_Name;
 905
 906 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 907 float GetMaplistPosition()
 908 {
 909         float pos, idx;
 910         string map;
 911
 912         map = GetMapname();
 913         idx = autocvar_g_maplist_index;
 914
 915         if(idx >= 0)
 916                 if(idx < Map_Count)
 917                         if(map == argv(idx))
 918                                 return idx;
 919
 920         for(pos = 0; pos < Map_Count; ++pos)
 921                 if(map == argv(pos))
 922                         return pos;
 923
 924         // resume normal maplist rotation if current map is not in g_maplist
 925         return idx;
 926 }
 927
 928 float MapHasRightSize(string map)
 929 {
 930         float fh;
 931         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 932         if(autocvar_g_maplist_check_waypoints)
 933         {
 934                 dprint("checkwp "); dprint(map);
 935                 if(!fexists(strcat("maps/", map, ".waypoints")))
 936                 {
 937                         dprint(": no waypoints\n");
 938                         return FALSE;
 939                 }
 940                 dprint(": has waypoints\n");
 941         }
 942
 943         // open map size restriction file
 944         dprint("opensize "); dprint(map);
 945         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 946         if(fh >= 0)
 947         {
 948                 float mapmin, mapmax;
 949                 dprint(": ok, ");
 950                 mapmin = stof(fgets(fh));
 951                 mapmax = stof(fgets(fh));
 952                 fclose(fh);
 953                 if(player_count < mapmin)
 954                 {
 955                         dprint("not enough\n");
 956                         return FALSE;
 957                 }
 958                 if(player_count > mapmax)
 959                 {
 960                         dprint("too many\n");
 961                         return FALSE;
 962                 }
 963                 dprint("right size\n");
 964                 return TRUE;
 965         }
 966         dprint(": not found\n");
 967         return TRUE;
 968 }
 969
 970 string Map_Filename(float position)
 971 {
 972         return strcat("maps/", argv(position), ".bsp");
 973 }
 974
 975 string strwords(string s, float w)
 976 {
 977         float endpos;
 978         for(endpos = 0; w && endpos >= 0; --w)
 979                 endpos = strstrofs(s, " ", endpos + 1);
 980         if(endpos < 0)
 981                 return s;
 982         else
 983                 return substring(s, 0, endpos);
 984 }
 985
 986 float strhasword(string s, string w)
 987 {
 988         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 989 }
 990
 991 void Map_MarkAsRecent(string m)
 992 {
 993         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 994 }
 995
 996 float Map_IsRecent(string m)
 997 {
 998         return strhasword(autocvar_g_maplist_mostrecent, m);
 999 }
1000
1001 float Map_Check(float position, float pass)
1002 {
1003         string filename;
1004         string map_next;
1005         map_next = argv(position);
1006         if(pass <= 1)
1007         {
1008                 if(Map_IsRecent(map_next))
1009                         return 0;
1010         }
1011         filename = Map_Filename(position);
1012         if(MapInfo_CheckMap(map_next))
1013         {
1014                 if(pass == 2)
1015                         return 1;
1016                 if(MapHasRightSize(map_next))
1017                         return 1;
1018                 return 0;
1019         }
1020         else
1021                 dprint( "Couldn't select '", filename, "'..\n" );
1022
1023         return 0;
1024 }
1025
1026 void Map_Goto_SetStr(string nextmapname)
1027 {
1028         if(getmapname_stored != "")
1029                 strunzone(getmapname_stored);
1030         if(nextmapname == "")
1031                 getmapname_stored = "";
1032         else
1033                 getmapname_stored = strzone(nextmapname);
1034 }
1035
1036 void Map_Goto_SetFloat(float position)
1037 {
1038         cvar_set("g_maplist_index", ftos(position));
1039         Map_Goto_SetStr(argv(position));
1040 }
1041
1042 void Map_Goto(float reinit)
1043 {
1044         MapInfo_LoadMap(getmapname_stored, reinit);
1045 }
1046
1047 // return codes of map selectors:
1048 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1049 //   -2 = permanent failure
1050 float() MaplistMethod_Iterate = // usual method
1051 {
1052         float pass, i;
1053
1054         dprint("Trying MaplistMethod_Iterate\n");
1055
1056         for(pass = 1; pass <= 2; ++pass)
1057         {
1058                 for(i = 1; i < Map_Count; ++i)
1059                 {
1060                         float mapindex;
1061                         mapindex = mod(i + Map_Current, Map_Count);
1062                         if(Map_Check(mapindex, pass))
1063                                 return mapindex;
1064                 }
1065         }
1066         return -1;
1067 }
1068
1069 float() MaplistMethod_Repeat = // fallback method
1070 {
1071         dprint("Trying MaplistMethod_Repeat\n");
1072
1073         if(Map_Check(Map_Current, 2))
1074                 return Map_Current;
1075         return -2;
1076 }
1077
1078 float() MaplistMethod_Random = // random map selection
1079 {
1080         float i, imax;
1081
1082         dprint("Trying MaplistMethod_Random\n");
1083
1084         imax = 42;
1085
1086         for(i = 0; i <= imax; ++i)
1087         {
1088                 float mapindex;
1089                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1090                 if(Map_Check(mapindex, 1))
1091                         return mapindex;
1092         }
1093         return -1;
1094 }
1095
1096 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1097 // the exponent sets a bias on the map selection:
1098 // the higher the exponent, the less likely "shortly repeated" same maps are
1099 {
1100         float i, j, imax, insertpos;
1101
1102         dprint("Trying MaplistMethod_Shuffle\n");
1103
1104         imax = 42;
1105
1106         for(i = 0; i <= imax; ++i)
1107         {
1108                 string newlist;
1109
1110                 // now reinsert this at another position
1111                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1112                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1113                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1114                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1115
1116                 // insert the current map there
1117                 newlist = "";
1118                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1119                         newlist = strcat(newlist, " ", argv(j));
1120                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1121                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1122                         newlist = strcat(newlist, " ", argv(j));
1123                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1124                 cvar_set("g_maplist", newlist);
1125                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1126
1127                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1128                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1129                 if(Map_Check(Map_Current, 1))
1130                         return Map_Current;
1131         }
1132         return -1;
1133 }
1134
1135 void Maplist_Init()
1136 {
1137         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1138         float i;
1139         for (i = 0; i < Map_Count; ++i)
1140                 if (Map_Check(i, 2))
1141                         break;
1142         if (i == Map_Count)
1143         {
1144                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1145                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1146                 if(autocvar_g_maplist_shuffle)
1147                         ShuffleMaplist();
1148                 localcmd("\nmenu_cmd sync\n");
1149                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1150         }
1151         if(Map_Count == 0)
1152                 error("empty maplist, cannot select a new map");
1153         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1154
1155         if(Map_Current_Name)
1156                 strunzone(Map_Current_Name);
1157         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1158         // this may or may not be correct, but who cares, in the worst case a map
1159         // isn't chosen in the first pass that should have been
1160 }
1161
1162 string GetNextMap()
1163 {
1164         float nextMap;
1165
1166         Maplist_Init();
1167         nextMap = -1;
1168
1169         if(nextMap == -1)
1170                 if(autocvar_g_maplist_shuffle > 0)
1171                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1172
1173         if(nextMap == -1)
1174                 if(autocvar_g_maplist_selectrandom)
1175                         nextMap = MaplistMethod_Random();
1176
1177         if(nextMap == -1)
1178                 nextMap = MaplistMethod_Iterate();
1179
1180         if(nextMap == -1)
1181                 nextMap = MaplistMethod_Repeat();
1182
1183         if(nextMap >= 0)
1184         {
1185                 Map_Goto_SetFloat(nextMap);
1186                 return getmapname_stored;
1187         }
1188
1189         return "";
1190 }
1191
1192 float DoNextMapOverride(float reinit)
1193 {
1194         if(autocvar_g_campaign)
1195         {
1196                 CampaignPostIntermission();
1197                 alreadychangedlevel = TRUE;
1198                 return TRUE;
1199         }
1200         if(autocvar_quit_when_empty)
1201         {
1202                 if(player_count <= currentbots)
1203                 {
1204                         localcmd("quit\n");
1205                         alreadychangedlevel = TRUE;
1206                         return TRUE;
1207                 }
1208         }
1209         if(autocvar_quit_and_redirect != "")
1210         {
1211                 redirection_target = strzone(autocvar_quit_and_redirect);
1212                 alreadychangedlevel = TRUE;
1213                 return TRUE;
1214         }
1215         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1216         {
1217                 localcmd("restart\n");
1218                 alreadychangedlevel = TRUE;
1219                 return TRUE;
1220         }
1221         if(autocvar_nextmap != "")
1222                 if(MapInfo_CheckMap(autocvar_nextmap))
1223                 {
1224                         Map_Goto_SetStr(autocvar_nextmap);
1225                         Map_Goto(reinit);
1226                         alreadychangedlevel = TRUE;
1227                         return TRUE;
1228                 }
1229         if(!reinit && autocvar_lastlevel)
1230         {
1231                 cvar_settemp_restore();
1232                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1233                 alreadychangedlevel = TRUE;
1234                 return TRUE;
1235         }
1236         return FALSE;
1237 }
1238
1239 void GotoNextMap(float reinit)
1240 {
1241         //string nextmap;
1242         //float n, nummaps;
1243         //string s;
1244         if (alreadychangedlevel)
1245                 return;
1246         alreadychangedlevel = TRUE;
1247
1248         string nextMap;
1249
1250         nextMap = GetNextMap();
1251         if(nextMap == "")
1252                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1253         Map_Goto(reinit);
1254 }
1255
1256
1257 /*
1258 ============
1259 IntermissionThink
1260
1261 When the player presses attack or jump, change to the next level
1262 ============
1263 */
1264 .float autoscreenshot;
1265 void() MapVote_Start;
1266 void() MapVote_Think;
1267 float mapvote_initialized;
1268 void IntermissionThink()
1269 {
1270         FixIntermissionClient(self);
1271
1272         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1273         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1274
1275         if( (server_screenshot || client_screenshot)
1276                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1277         {
1278                 self.autoscreenshot = -1;
1279                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1280                 return;
1281         }
1282
1283         if (time < intermission_exittime)
1284                 return;
1285
1286         if(!mapvote_initialized)
1287                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1288                         return;
1289
1290         MapVote_Start();
1291 }
1292
1293 /*
1294 ============
1295 FindIntermission
1296
1297 Returns the entity to view from
1298 ============
1299 */
1300 /*
1301 entity FindIntermission()
1302 {
1303         local   entity spot;
1304         local   float cyc;
1305
1306 // look for info_intermission first
1307         spot = find (world, classname, "info_intermission");
1308         if (spot)
1309         {       // pick a random one
1310                 cyc = random() * 4;
1311                 while (cyc > 1)
1312                 {
1313                         spot = find (spot, classname, "info_intermission");
1314                         if (!spot)
1315                                 spot = find (spot, classname, "info_intermission");
1316                         cyc = cyc - 1;
1317                 }
1318                 return spot;
1319         }
1320
1321 // then look for the start position
1322         spot = find (world, classname, "info_player_start");
1323         if (spot)
1324                 return spot;
1325
1326 // testinfo_player_start is only found in regioned levels
1327         spot = find (world, classname, "testplayerstart");
1328         if (spot)
1329                 return spot;
1330
1331 // then look for the start position
1332         spot = find (world, classname, "info_player_deathmatch");
1333         if (spot)
1334                 return spot;
1335
1336         //objerror ("FindIntermission: no spot");
1337         return world;
1338 }
1339 */
1340
1341 /*
1342 ===============================================================================
1343
1344 RULES
1345
1346 ===============================================================================
1347 */
1348
1349 void DumpStats(float final)
1350 {
1351         float file;
1352         string s;
1353         float to_console;
1354         float to_eventlog;
1355         float to_file;
1356         float i;
1357
1358         to_console = autocvar_sv_logscores_console;
1359         to_eventlog = autocvar_sv_eventlog;
1360         to_file = autocvar_sv_logscores_file;
1361
1362         if(!final)
1363         {
1364                 to_console = TRUE; // always print printstats replies
1365                 to_eventlog = FALSE; // but never print them to the event log
1366         }
1367
1368         if(to_eventlog)
1369                 if(autocvar_sv_eventlog_console)
1370                         to_console = FALSE; // otherwise we get the output twice
1371
1372         if(final)
1373                 s = ":scores:";
1374         else
1375                 s = ":status:";
1376         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1377
1378         if(to_console)
1379                 print(s, "\n");
1380         if(to_eventlog)
1381                 GameLogEcho(s);
1382
1383         file = -1;
1384         if(to_file)
1385         {
1386                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1387                 if(file == -1)
1388                         to_file = FALSE;
1389                 else
1390                         fputs(file, strcat(s, "\n"));
1391         }
1392
1393         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1394         if(to_console)
1395                 print(s, "\n");
1396         if(to_eventlog)
1397                 GameLogEcho(s);
1398         if(to_file)
1399                 fputs(file, strcat(s, "\n"));
1400
1401         FOR_EACH_CLIENT(other)
1402         {
1403                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1404                 {
1405                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1406                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1407                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1408                                 s = strcat(s, ftos(other.team), ":");
1409                         else
1410                                 s = strcat(s, "spectator:");
1411
1412                         if(to_console)
1413                                 print(s, other.netname, "\n");
1414                         if(to_eventlog)
1415                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1416                         if(to_file)
1417                                 fputs(file, strcat(s, other.netname, "\n"));
1418                 }
1419         }
1420
1421         if(teamplay)
1422         {
1423                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1424                 if(to_console)
1425                         print(s, "\n");
1426                 if(to_eventlog)
1427                         GameLogEcho(s);
1428                 if(to_file)
1429                         fputs(file, strcat(s, "\n"));
1430
1431                 for(i = 1; i < 16; ++i)
1432                 {
1433                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1434                         s = strcat(s, ":", ftos(i));
1435                         if(to_console)
1436                                 print(s, "\n");
1437                         if(to_eventlog)
1438                                 GameLogEcho(s);
1439                         if(to_file)
1440                                 fputs(file, strcat(s, "\n"));
1441                 }
1442         }
1443
1444         if(to_console)
1445                 print(":end\n");
1446         if(to_eventlog)
1447                 GameLogEcho(":end");
1448         if(to_file)
1449         {
1450                 fputs(file, ":end\n");
1451                 fclose(file);
1452         }
1453 }
1454
1455 void FixIntermissionClient(entity e)
1456 {
1457         string s;
1458         if(!e.autoscreenshot) // initial call
1459         {
1460                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1461                 e.health = -2342;
1462                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1463                 e.solid = SOLID_NOT;
1464                 e.movetype = MOVETYPE_NONE;
1465                 e.takedamage = DAMAGE_NO;
1466                 if(e.weaponentity)
1467                 {
1468                         e.weaponentity.effects = EF_NODRAW;
1469                         if (e.weaponentity.weaponentity)
1470                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1471                 }
1472                 if(IS_REAL_CLIENT(e))
1473                 {
1474                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1475                         s = autocvar_sv_intermission_cdtrack;
1476                         if(s != "")
1477                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1478                         msg_entity = e;
1479                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1480                 }
1481         }
1482 }
1483
1484 /*
1485 go to the next level for deathmatch
1486 only called if a time or frag limit has expired
1487 */
1488 void NextLevel()
1489 {
1490         gameover = TRUE;
1491
1492         intermission_running = 1;
1493
1494 // enforce a wait time before allowing changelevel
1495         if(player_count > 0)
1496                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1497         else
1498                 intermission_exittime = -1;
1499
1500         /*
1501         WriteByte (MSG_ALL, SVC_CDTRACK);
1502         WriteByte (MSG_ALL, 3);
1503         WriteByte (MSG_ALL, 3);
1504         // done in FixIntermission
1505         */
1506
1507         //pos = FindIntermission ();
1508
1509         VoteReset();
1510
1511         DumpStats(TRUE);
1512
1513         // send statistics
1514         entity e;
1515         PlayerStats_EndMatch(1);
1516         FOR_EACH_CLIENT(e)
1517                 PlayerStats_AddGlobalInfo(e);
1518         PlayerStats_Shutdown();
1519         WeaponStats_Shutdown();
1520
1521         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1522
1523         if(autocvar_sv_eventlog)
1524                 GameLogEcho(":gameover");
1525
1526         GameLogClose();
1527
1528         FOR_EACH_PLAYER(other) {
1529                 FixIntermissionClient(other);
1530                 if(other.winning)
1531                         bprint(other.netname, " ^7wins.\n");
1532         }
1533
1534         if(autocvar_g_campaign)
1535                 CampaignPreIntermission();
1536
1537         MUTATOR_CALLHOOK(MatchEnd);
1538
1539         localcmd("\nsv_hook_gameend\n");
1540 }
1541
1542 /*
1543 ============
1544 CheckRules_Player
1545
1546 Exit deathmatch games upon conditions
1547 ============
1548 */
1549 void CheckRules_Player()
1550 {
1551         if (gameover)   // someone else quit the game already
1552                 return;
1553
1554         if(self.deadflag == DEAD_NO)
1555                 self.play_time += frametime;
1556
1557         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1558         //   (div0: and that in CheckRules_World please)
1559 }
1560
1561 float checkrules_equality;
1562 float checkrules_suddendeathwarning;
1563 float checkrules_suddendeathend;
1564 float checkrules_overtimesadded; //how many overtimes have been already added
1565
1566 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1567 const float WINNING_YES = 1; // winner found
1568 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1569 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1570
1571 float InitiateSuddenDeath()
1572 {
1573         // Check first whether normal overtimes could be added before initiating suddendeath mode
1574         // - for this timelimit_overtime needs to be >0 of course
1575         // - also check the winning condition calculated in the previous frame and only add normal overtime
1576         //   again, if at the point at which timelimit would be extended again, still no winner was found
1577         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1578         {
1579                 return 1; // need to call InitiateOvertime later
1580         }
1581         else
1582         {
1583                 if(!checkrules_suddendeathend)
1584                 {
1585                         if(autocvar_g_campaign)
1586                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1587                         else
1588                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1589                         if(g_race && !g_race_qualifying)
1590                                 race_StartCompleting();
1591                 }
1592                 return 0;
1593         }
1594 }
1595
1596 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1597 {
1598         ++checkrules_overtimesadded;
1599         //add one more overtime by simply extending the timelimit
1600         float tl;
1601         tl = autocvar_timelimit;
1602         tl += autocvar_timelimit_overtime;
1603         cvar_set("timelimit", ftos(tl));
1604
1605         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1606 }
1607
1608 float GetWinningCode(float fraglimitreached, float equality)
1609 {
1610         if(autocvar_g_campaign == 1)
1611                 if(fraglimitreached)
1612                         return WINNING_YES;
1613                 else
1614                         return WINNING_NO;
1615
1616         else
1617                 if(equality)
1618                         if(fraglimitreached)
1619                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1620                         else
1621                                 return WINNING_NEVER;
1622                 else
1623                         if(fraglimitreached)
1624                                 return WINNING_YES;
1625                         else
1626                                 return WINNING_NO;
1627 }
1628
1629 // set the .winning flag for exactly those players with a given field value
1630 void SetWinners(.float field, float value)
1631 {
1632         entity head;
1633         FOR_EACH_PLAYER(head)
1634                 head.winning = (head.field == value);
1635 }
1636
1637 // set the .winning flag for those players with a given field value
1638 void AddWinners(.float field, float value)
1639 {
1640         entity head;
1641         FOR_EACH_PLAYER(head)
1642                 if(head.field == value)
1643                         head.winning = 1;
1644 }
1645
1646 // clear the .winning flags
1647 void ClearWinners(void)
1648 {
1649         entity head;
1650         FOR_EACH_PLAYER(head)
1651                 head.winning = 0;
1652 }
1653
1654 // Onslaught winning condition:
1655 // game terminates if only one team has a working generator (or none)
1656 float WinningCondition_Onslaught()
1657 {
1658         entity head;
1659         float t1, t2, t3, t4;
1660
1661         WinningConditionHelper(); // set worldstatus
1662
1663         if(warmup_stage)
1664                 return WINNING_NO;
1665
1666         // first check if the game has ended
1667         t1 = t2 = t3 = t4 = 0;
1668         head = find(world, classname, "onslaught_generator");
1669         while (head)
1670         {
1671                 if (head.health > 0)
1672                 {
1673                         if (head.team == NUM_TEAM_1) t1 = 1;
1674                         if (head.team == NUM_TEAM_2) t2 = 1;
1675                         if (head.team == NUM_TEAM_3) t3 = 1;
1676                         if (head.team == NUM_TEAM_4) t4 = 1;
1677                 }
1678                 head = find(head, classname, "onslaught_generator");
1679         }
1680         if (t1 + t2 + t3 + t4 < 2)
1681         {
1682                 // game over, only one team remains (or none)
1683                 ClearWinners();
1684                 if (t1) SetWinners(team, NUM_TEAM_1);
1685                 if (t2) SetWinners(team, NUM_TEAM_2);
1686                 if (t3) SetWinners(team, NUM_TEAM_3);
1687                 if (t4) SetWinners(team, NUM_TEAM_4);
1688                 dprint("Have a winner, ending game.\n");
1689                 return WINNING_YES;
1690         }
1691
1692         // Two or more teams remain
1693         return WINNING_NO;
1694 }
1695
1696 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1697 // they win. Otherwise the defending team wins once the timelimit passes.
1698 void assault_new_round();
1699 float WinningCondition_Assault()
1700 {
1701         float status;
1702
1703         WinningConditionHelper(); // set worldstatus
1704
1705         status = WINNING_NO;
1706         // as the timelimit has not yet passed just assume the defending team will win
1707         if(assault_attacker_team == NUM_TEAM_1)
1708         {
1709                 SetWinners(team, NUM_TEAM_2);
1710         }
1711         else
1712         {
1713                 SetWinners(team, NUM_TEAM_1);
1714         }
1715
1716         entity ent;
1717         ent = find(world, classname, "target_assault_roundend");
1718         if(ent)
1719         {
1720                 if(ent.winning) // round end has been triggered by attacking team
1721                 {
1722                         bprint("ASSAULT: round completed...\n");
1723                         SetWinners(team, assault_attacker_team);
1724
1725                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1726
1727                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1728                         {
1729                                 status = WINNING_YES;
1730                         }
1731                         else
1732                         {
1733                                 entity oldself;
1734                                 oldself = self;
1735                                 self = ent;
1736                                 assault_new_round();
1737                                 self = oldself;
1738                         }
1739                 }
1740         }
1741
1742         return status;
1743 }
1744
1745 // LMS winning condition: game terminates if and only if there's at most one
1746 // one player who's living lives. Top two scores being equal cancels the time
1747 // limit.
1748 float WinningCondition_LMS()
1749 {
1750         entity head, head2;
1751         float have_player;
1752         float have_players;
1753         float l;
1754
1755         have_player = FALSE;
1756         have_players = FALSE;
1757         l = LMS_NewPlayerLives();
1758
1759         head = find(world, classname, "player");
1760         if(head)
1761                 have_player = TRUE;
1762         head2 = find(head, classname, "player");
1763         if(head2)
1764                 have_players = TRUE;
1765
1766         if(have_player)
1767         {
1768                 // we have at least one player
1769                 if(have_players)
1770                 {
1771                         // two or more active players - continue with the game
1772                 }
1773                 else
1774                 {
1775                         // exactly one player?
1776
1777                         ClearWinners();
1778                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1779
1780                         if(l)
1781                         {
1782                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1783                                 return WINNING_NO;
1784                         }
1785                         else
1786                         {
1787                                 // a winner!
1788                                 // and assign him his first place
1789                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1790                                 return WINNING_YES;
1791                         }
1792                 }
1793         }
1794         else
1795         {
1796                 // nobody is playing at all...
1797                 if(l)
1798                 {
1799                         // wait for players...
1800                 }
1801                 else
1802                 {
1803                         // SNAFU (maybe a draw game?)
1804                         ClearWinners();
1805                         dprint("No players, ending game.\n");
1806                         return WINNING_YES;
1807                 }
1808         }
1809
1810         // When we get here, we have at least two players who are actually LIVING,
1811         // now check if the top two players have equal score.
1812         WinningConditionHelper();
1813
1814         ClearWinners();
1815         if(WinningConditionHelper_winner)
1816                 WinningConditionHelper_winner.winning = TRUE;
1817         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1818                 return WINNING_NEVER;
1819
1820         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1821         return WINNING_NO;
1822 }
1823
1824 void ShuffleMaplist()
1825 {
1826         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1827 }
1828
1829 float leaderfrags;
1830 float WinningCondition_Scores(float limit, float leadlimit)
1831 {
1832         float limitreached;
1833
1834         // TODO make everything use THIS winning condition (except LMS)
1835         WinningConditionHelper();
1836
1837         if(teamplay)
1838         {
1839                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1840                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1841                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1842                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1843         }
1844
1845         ClearWinners();
1846         if(WinningConditionHelper_winner)
1847                 WinningConditionHelper_winner.winning = 1;
1848         if(WinningConditionHelper_winnerteam >= 0)
1849                 SetWinners(team, WinningConditionHelper_winnerteam);
1850
1851         if(WinningConditionHelper_lowerisbetter)
1852         {
1853                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1854                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1855                 limit = -limit;
1856         }
1857
1858         if(WinningConditionHelper_zeroisworst)
1859                 leadlimit = 0; // not supported in this mode
1860
1861         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1862         // these modes always score in increments of 1, thus this makes sense
1863         {
1864                 if(leaderfrags != WinningConditionHelper_topscore)
1865                 {
1866                         leaderfrags = WinningConditionHelper_topscore;
1867
1868                         if (limit)
1869                         if (leaderfrags == limit - 1)
1870                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1871                         else if (leaderfrags == limit - 2)
1872                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1873                         else if (leaderfrags == limit - 3)
1874                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1875                 }
1876         }
1877
1878         limitreached = FALSE;
1879         if(limit)
1880                 if(WinningConditionHelper_topscore >= limit)
1881                         limitreached = TRUE;
1882         if(leadlimit)
1883         {
1884                 float leadlimitreached;
1885                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1886                 if(autocvar_leadlimit_and_fraglimit)
1887                         limitreached = (limitreached && leadlimitreached);
1888                 else
1889                         limitreached = (limitreached || leadlimitreached);
1890         }
1891
1892         if(limit)
1893                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1894
1895         return GetWinningCode(
1896                 WinningConditionHelper_topscore && limitreached,
1897                 WinningConditionHelper_equality
1898         );
1899 }
1900
1901 float WinningCondition_Race(float fraglimit)
1902 {
1903         float wc;
1904         entity p;
1905         float n, c;
1906
1907         n = 0;
1908         c = 0;
1909         FOR_EACH_PLAYER(p)
1910         {
1911                 ++n;
1912                 if(p.race_completed)
1913                         ++c;
1914         }
1915         if(n && (n == c))
1916                 return WINNING_YES;
1917         wc = WinningCondition_Scores(fraglimit, 0);
1918
1919         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1920         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1921         // do NOT support equality when the laps are all raced!
1922                 return WINNING_STARTSUDDENDEATHOVERTIME;
1923         else
1924                 return WINNING_NEVER;
1925 }
1926
1927 float WinningCondition_QualifyingThenRace(float limit)
1928 {
1929         float wc;
1930         wc = WinningCondition_Scores(limit, 0);
1931
1932         // NEVER initiate overtime
1933         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1934         {
1935                 return WINNING_YES;
1936         }
1937
1938         return wc;
1939 }
1940
1941 float WinningCondition_RanOutOfSpawns()
1942 {
1943         entity head;
1944
1945         if(have_team_spawns <= 0)
1946                 return WINNING_NO;
1947
1948         if(autocvar_g_spawn_useallspawns <= 0)
1949                 return WINNING_NO;
1950
1951         if(!some_spawn_has_been_used)
1952                 return WINNING_NO;
1953
1954         team1_score = team2_score = team3_score = team4_score = 0;
1955
1956         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1957         {
1958                 if(head.team == NUM_TEAM_1)
1959                         team1_score = 1;
1960                 else if(head.team == NUM_TEAM_2)
1961                         team2_score = 1;
1962                 else if(head.team == NUM_TEAM_3)
1963                         team3_score = 1;
1964                 else if(head.team == NUM_TEAM_4)
1965                         team4_score = 1;
1966         }
1967
1968         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1969         {
1970                 if(head.team == NUM_TEAM_1)
1971                         team1_score = 1;
1972                 else if(head.team == NUM_TEAM_2)
1973                         team2_score = 1;
1974                 else if(head.team == NUM_TEAM_3)
1975                         team3_score = 1;
1976                 else if(head.team == NUM_TEAM_4)
1977                         team4_score = 1;
1978         }
1979
1980         ClearWinners();
1981         if(team1_score + team2_score + team3_score + team4_score == 0)
1982         {
1983                 checkrules_equality = TRUE;
1984                 return WINNING_YES;
1985         }
1986         else if(team1_score + team2_score + team3_score + team4_score == 1)
1987         {
1988                 float t, i;
1989                 if(team1_score)
1990                         t = NUM_TEAM_1;
1991                 else if(team2_score)
1992                         t = NUM_TEAM_2;
1993                 else if(team3_score)
1994                         t = NUM_TEAM_3;
1995                 else // if(team4_score)
1996                         t = NUM_TEAM_4;
1997                 CheckAllowedTeams(world);
1998                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1999                 {
2000                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2001                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2002                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2003                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2004                 }
2005
2006                 AddWinners(team, t);
2007                 return WINNING_YES;
2008         }
2009         else
2010                 return WINNING_NO;
2011 }
2012
2013 /*
2014 ============
2015 CheckRules_World
2016
2017 Exit deathmatch games upon conditions
2018 ============
2019 */
2020 void ReadyRestart();
2021 void CheckRules_World()
2022 {
2023         float timelimit;
2024         float fraglimit;
2025         float leadlimit;
2026
2027         VoteThink();
2028         MapVote_Think();
2029
2030         SetDefaultAlpha();
2031
2032         /*
2033         MapVote_Think should now do that part
2034         if (intermission_running)
2035                 if (time >= intermission_exittime + 60)
2036                 {
2037                         if(!DoNextMapOverride())
2038                                 GotoNextMap();
2039                         return;
2040                 }
2041         */
2042
2043         if (gameover)   // someone else quit the game already
2044         {
2045                 if(player_count == 0) // Nobody there? Then let's go to the next map
2046                         MapVote_Start();
2047                         // this will actually check the player count in the next frame
2048                         // again, but this shouldn't hurt
2049                 return;
2050         }
2051
2052         timelimit = autocvar_timelimit * 60;
2053         fraglimit = autocvar_fraglimit;
2054         leadlimit = autocvar_leadlimit;
2055
2056         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2057         {
2058                 if(timelimit > 0)
2059                         timelimit = 0; // timelimit is not made for warmup
2060                 if(fraglimit > 0)
2061                         fraglimit = 0; // no fraglimit for now
2062                 leadlimit = 0; // no leadlimit for now
2063         }
2064
2065         if(timelimit > 0)
2066         {
2067                 timelimit += game_starttime;
2068         }
2069         else if (timelimit < 0)
2070         {
2071                 // endmatch
2072                 NextLevel();
2073                 return;
2074         }
2075
2076         if(g_onslaught)
2077                 timelimit = 0; // ONS has its own overtime rule
2078
2079         float wantovertime;
2080         wantovertime = 0;
2081
2082         if(timelimit > game_starttime)
2083                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2084         else
2085                 game_completion_ratio = 0;
2086
2087         if(checkrules_suddendeathend)
2088         {
2089                 if(!checkrules_suddendeathwarning)
2090                 {
2091                         checkrules_suddendeathwarning = TRUE;
2092                         if(g_race && !g_race_qualifying)
2093                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2094                         else
2095                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2096                 }
2097         }
2098         else
2099         {
2100                 if (timelimit && time >= timelimit)
2101                 {
2102                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2103                         {
2104                                 float totalplayers;
2105                                 float playerswithlaps;
2106                                 float readyplayers;
2107                                 entity head;
2108                                 totalplayers = playerswithlaps = readyplayers = 0;
2109                                 FOR_EACH_PLAYER(head)
2110                                 {
2111                                         ++totalplayers;
2112                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2113                                                 ++playerswithlaps;
2114                                         if(head.ready)
2115                                                 ++readyplayers;
2116                                 }
2117
2118                                 // at least 2 of the players have completed a lap: start the RACE
2119                                 // otherwise, the players should end the qualifying on their own
2120                                 if(readyplayers || playerswithlaps >= 2)
2121                                 {
2122                                         checkrules_suddendeathend = 0;
2123                                         ReadyRestart(); // go to race
2124                                         return;
2125                                 }
2126                                 else
2127                                         wantovertime |= InitiateSuddenDeath();
2128                         }
2129                         else
2130                                 wantovertime |= InitiateSuddenDeath();
2131                 }
2132         }
2133
2134         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2135         {
2136                 NextLevel();
2137                 return;
2138         }
2139
2140         float checkrules_status;
2141         checkrules_status = WinningCondition_RanOutOfSpawns();
2142         if(checkrules_status == WINNING_YES)
2143         {
2144                 bprint("Hey! Someone ran out of spawns!\n");
2145         }
2146         else if(g_race && !g_race_qualifying && timelimit >= 0)
2147         {
2148                 checkrules_status = WinningCondition_Race(fraglimit);
2149                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2150         }
2151         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2152         {
2153                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2154                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2155         }
2156         else if(g_assault)
2157         {
2158                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2159         }
2160         else if(g_lms)
2161         {
2162                 checkrules_status = WinningCondition_LMS();
2163         }
2164         else if (g_onslaught)
2165         {
2166                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2167         }
2168         else
2169         {
2170                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2171                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2172         }
2173
2174         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2175         {
2176                 checkrules_status = WINNING_NEVER;
2177                 checkrules_overtimesadded = -1;
2178                 wantovertime |= InitiateSuddenDeath();
2179         }
2180
2181         if(checkrules_status == WINNING_NEVER)
2182                 // equality cases! Nobody wins if the overtime ends in a draw.
2183                 ClearWinners();
2184
2185         if(wantovertime)
2186         {
2187                 if(checkrules_status == WINNING_NEVER)
2188                         InitiateOvertime();
2189                 else
2190                         checkrules_status = WINNING_YES;
2191         }
2192
2193         if(checkrules_suddendeathend)
2194                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2195                         checkrules_status = WINNING_YES;
2196
2197         if(checkrules_status == WINNING_YES)
2198         {
2199                 //print("WINNING\n");
2200                 NextLevel();
2201         }
2202 }
2203
2204 float mapvote_nextthink;
2205 float mapvote_initialized;
2206 float mapvote_keeptwotime;
2207 float mapvote_timeout;
2208 string mapvote_message;
2209 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2210 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2211 float mapvote_screenshot_dirs_count;
2212
2213 float mapvote_count;
2214 float mapvote_count_real;
2215 string mapvote_maps[MAPVOTE_COUNT];
2216 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2217 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2218 float mapvote_maps_suggested[MAPVOTE_COUNT];
2219 string mapvote_suggestions[MAPVOTE_COUNT];
2220 float mapvote_suggestion_ptr;
2221 float mapvote_voters;
2222 float mapvote_selections[MAPVOTE_COUNT];
2223 float mapvote_run;
2224 float mapvote_detail;
2225 float mapvote_abstain;
2226 .float mapvote;
2227
2228 void MapVote_ClearAllVotes()
2229 {
2230         FOR_EACH_CLIENT(other)
2231                 other.mapvote = 0;
2232 }
2233
2234 string MapVote_Suggest(string m)
2235 {
2236         float i;
2237         if(m == "")
2238                 return "That's not how to use this command.";
2239         if(!autocvar_g_maplist_votable_suggestions)
2240                 return "Suggestions are not accepted on this server.";
2241         if(mapvote_initialized)
2242                 return "Can't suggest - voting is already in progress!";
2243         m = MapInfo_FixName(m);
2244         if (!m)
2245                 return "The map you suggested is not available on this server.";
2246         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2247                 if(Map_IsRecent(m))
2248                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2249
2250         if(!MapInfo_CheckMap(m))
2251                 return "The map you suggested does not support the current game mode.";
2252         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2253                 if(mapvote_suggestions[i] == m)
2254                         return "This map was already suggested.";
2255         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2256         {
2257                 i = floor(random() * mapvote_suggestion_ptr);
2258         }
2259         else
2260         {
2261                 i = mapvote_suggestion_ptr;
2262                 mapvote_suggestion_ptr += 1;
2263         }
2264         if(mapvote_suggestions[i] != "")
2265                 strunzone(mapvote_suggestions[i]);
2266         mapvote_suggestions[i] = strzone(m);
2267         if(autocvar_sv_eventlog)
2268                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2269         return strcat("Suggestion of ", m, " accepted.");
2270 }
2271
2272 void MapVote_AddVotable(string nextMap, float isSuggestion)
2273 {
2274         float j, i, o;
2275         string pakfile, mapfile;
2276
2277         if(nextMap == "")
2278                 return;
2279         for(j = 0; j < mapvote_count; ++j)
2280                 if(mapvote_maps[j] == nextMap)
2281                         return;
2282         // suggestions might be no longer valid/allowed after gametype switch!
2283         if(isSuggestion)
2284                 if(!MapInfo_CheckMap(nextMap))
2285                         return;
2286         mapvote_maps[mapvote_count] = strzone(nextMap);
2287         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2288
2289         pakfile = string_null;
2290         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2291         {
2292                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2293                 pakfile = whichpack(strcat(mapfile, ".tga"));
2294                 if(pakfile == "")
2295                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2296                 if(pakfile == "")
2297                         pakfile = whichpack(strcat(mapfile, ".png"));
2298                 if(pakfile != "")
2299                         break;
2300         }
2301         if(i >= mapvote_screenshot_dirs_count)
2302                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2303         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2304                 pakfile = substring(pakfile, o, -1);
2305
2306         mapvote_maps_screenshot_dir[mapvote_count] = i;
2307         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2308
2309         mapvote_count += 1;
2310 }
2311
2312 void MapVote_Spawn();
2313 void MapVote_Init()
2314 {
2315         float i;
2316         float nmax, smax;
2317
2318         MapVote_ClearAllVotes();
2319
2320         mapvote_count = 0;
2321         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2322         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2323
2324         if(mapvote_abstain)
2325                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2326         else
2327                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2328         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2329
2330         // we need this for AddVotable, as that cycles through the screenshot dirs
2331         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2332         if(mapvote_screenshot_dirs_count == 0)
2333                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2334         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2335         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2336                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2337
2338         if(mapvote_suggestion_ptr)
2339                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2340                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2341
2342         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2343                 MapVote_AddVotable(GetNextMap(), FALSE);
2344
2345         if(mapvote_count == 0)
2346         {
2347                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2348                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2349                 if(autocvar_g_maplist_shuffle)
2350                         ShuffleMaplist();
2351                 localcmd("\nmenu_cmd sync\n");
2352                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2353                         MapVote_AddVotable(GetNextMap(), FALSE);
2354         }
2355
2356         mapvote_count_real = mapvote_count;
2357         if(mapvote_abstain)
2358                 MapVote_AddVotable("don't care", 0);
2359
2360         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2361
2362         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2363         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2364         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2365                 mapvote_keeptwotime = 0;
2366         mapvote_message = "Choose a map and press its key!";
2367
2368         MapVote_Spawn();
2369 }
2370
2371 void MapVote_SendPicture(float id)
2372 {
2373         msg_entity = self;
2374         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2375         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2376         WriteByte(MSG_ONE, id);
2377         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2378 }
2379
2380 float MapVote_GetMapMask()
2381 {
2382         float mask, i, power;
2383         mask = 0;
2384         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2385                 if(mapvote_maps[i] != "")
2386                         mask |= power;
2387         return mask;
2388 }
2389
2390 entity mapvote_ent;
2391 float MapVote_SendEntity(entity to, float sf)
2392 {
2393         float i;
2394
2395         if(sf & 1)
2396                 sf &= ~2; // if we send 1, we don't need to also send 2
2397
2398         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2399         WriteByte(MSG_ENTITY, sf);
2400
2401         if(sf & 1)
2402         {
2403                 // flag 1 == initialization
2404                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2405                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2406                 WriteString(MSG_ENTITY, "");
2407                 WriteByte(MSG_ENTITY, mapvote_count);
2408                 WriteByte(MSG_ENTITY, mapvote_abstain);
2409                 WriteByte(MSG_ENTITY, mapvote_detail);
2410                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2411                 if(mapvote_count <= 8)
2412                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2413                 else
2414                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2415                 for(i = 0; i < mapvote_count; ++i)
2416                         if(mapvote_maps[i] != "")
2417                         {
2418                                 if(mapvote_abstain && i == mapvote_count - 1)
2419                                 {
2420                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2421                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2422                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2423                                 }
2424                                 else
2425                                 {
2426                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2427                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2428                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2429                                 }
2430                         }
2431         }
2432
2433         if(sf & 2)
2434         {
2435                 // flag 2 == update of mask
2436                 if(mapvote_count <= 8)
2437                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2438                 else
2439                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2440         }
2441
2442         if(sf & 4)
2443         {
2444                 if(mapvote_detail)
2445                         for(i = 0; i < mapvote_count; ++i)
2446                                 if(mapvote_maps[i] != "")
2447                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2448
2449                 WriteByte(MSG_ENTITY, to.mapvote);
2450         }
2451
2452         return TRUE;
2453 }
2454
2455 void MapVote_Spawn()
2456 {
2457         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2458 }
2459
2460 void MapVote_TouchMask()
2461 {
2462         mapvote_ent.SendFlags |= 2;
2463 }
2464
2465 void MapVote_TouchVotes(entity voter)
2466 {
2467         mapvote_ent.SendFlags |= 4;
2468 }
2469
2470 float MapVote_Finished(float mappos)
2471 {
2472         string result;
2473         float i;
2474         float didntvote;
2475
2476         if(autocvar_sv_eventlog)
2477         {
2478                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2479                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2480                 didntvote = mapvote_voters;
2481                 for(i = 0; i < mapvote_count; ++i)
2482                         if(mapvote_maps[i] != "")
2483                         {
2484                                 didntvote -= mapvote_selections[i];
2485                                 if(i != mappos)
2486                                 {
2487                                         result = strcat(result, ":", mapvote_maps[i]);
2488                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2489                                 }
2490                         }
2491                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2492
2493                 GameLogEcho(result);
2494                 if(mapvote_maps_suggested[mappos])
2495                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2496         }
2497
2498         FOR_EACH_REALCLIENT(other)
2499                 FixClientCvars(other);
2500
2501         Map_Goto_SetStr(mapvote_maps[mappos]);
2502         Map_Goto(0);
2503         alreadychangedlevel = TRUE;
2504         return TRUE;
2505 }
2506 void MapVote_CheckRules_1()
2507 {
2508         float i;
2509
2510         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2511         {
2512                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2513                 mapvote_selections[i] = 0;
2514         }
2515
2516         mapvote_voters = 0;
2517         FOR_EACH_REALCLIENT(other)
2518         {
2519                 ++mapvote_voters;
2520                 if(other.mapvote)
2521                 {
2522                         i = other.mapvote - 1;
2523                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2524                         mapvote_selections[i] = mapvote_selections[i] + 1;
2525                 }
2526         }
2527 }
2528
2529 float MapVote_CheckRules_2()
2530 {
2531         float i;
2532         float firstPlace, secondPlace;
2533         float firstPlaceVotes, secondPlaceVotes;
2534         float mapvote_voters_real;
2535         string result;
2536
2537         if(mapvote_count_real == 1)
2538                 return MapVote_Finished(0);
2539
2540         mapvote_voters_real = mapvote_voters;
2541         if(mapvote_abstain)
2542                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2543
2544         RandomSelection_Init();
2545         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2546                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2547         firstPlace = RandomSelection_chosen_float;
2548         firstPlaceVotes = RandomSelection_best_priority;
2549         //dprint("First place: ", ftos(firstPlace), "\n");
2550         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2551
2552         RandomSelection_Init();
2553         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2554                 if(i != firstPlace)
2555                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2556         secondPlace = RandomSelection_chosen_float;
2557         secondPlaceVotes = RandomSelection_best_priority;
2558         //dprint("Second place: ", ftos(secondPlace), "\n");
2559         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2560
2561         if(firstPlace == -1)
2562                 error("No first place in map vote... WTF?");
2563
2564         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2565                 return MapVote_Finished(firstPlace);
2566
2567         if(mapvote_keeptwotime)
2568                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2569                 {
2570                         float didntvote;
2571                         MapVote_TouchMask();
2572                         mapvote_message = "Now decide between the TOP TWO!";
2573                         mapvote_keeptwotime = 0;
2574                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2575                         result = strcat(result, ":", ftos(firstPlaceVotes));
2576                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2577                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2578                         didntvote = mapvote_voters;
2579                         for(i = 0; i < mapvote_count; ++i)
2580                                 if(mapvote_maps[i] != "")
2581                                 {
2582                                         didntvote -= mapvote_selections[i];
2583                                         if(i != firstPlace)
2584                                                 if(i != secondPlace)
2585                                                 {
2586                                                         result = strcat(result, ":", mapvote_maps[i]);
2587                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2588                                                         if(i < mapvote_count_real)
2589                                                         {
2590                                                                 strunzone(mapvote_maps[i]);
2591                                                                 mapvote_maps[i] = "";
2592                                                                 strunzone(mapvote_maps_pakfile[i]);
2593                                                                 mapvote_maps_pakfile[i] = "";
2594                                                         }
2595                                                 }
2596                                 }
2597                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2598                         if(autocvar_sv_eventlog)
2599                                 GameLogEcho(result);
2600                 }
2601
2602         return FALSE;
2603 }
2604 void MapVote_Tick()
2605 {
2606         float keeptwo;
2607         float totalvotes;
2608
2609         keeptwo = mapvote_keeptwotime;
2610         MapVote_CheckRules_1(); // count
2611         if(MapVote_CheckRules_2()) // decide
2612                 return;
2613
2614         totalvotes = 0;
2615         FOR_EACH_REALCLIENT(other)
2616         {
2617                 // hide scoreboard again
2618                 if(other.health != 2342)
2619                 {
2620                         other.health = 2342;
2621                         other.impulse = 0;
2622                         if(IS_REAL_CLIENT(other))
2623                         {
2624                                 msg_entity = other;
2625                                 WriteByte(MSG_ONE, SVC_FINALE);
2626                                 WriteString(MSG_ONE, "");
2627                         }
2628                 }
2629
2630                 // clear possibly invalid votes
2631                 if(mapvote_maps[other.mapvote - 1] == "")
2632                         other.mapvote = 0;
2633                 // use impulses as new vote
2634                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2635                         if(mapvote_maps[other.impulse - 1] != "")
2636                         {
2637                                 other.mapvote = other.impulse;
2638                                 MapVote_TouchVotes(other);
2639                         }
2640                 other.impulse = 0;
2641
2642                 if(other.mapvote)
2643                         ++totalvotes;
2644         }
2645
2646         MapVote_CheckRules_1(); // just count
2647 }
2648 void MapVote_Start()
2649 {
2650         if(mapvote_run)
2651                 return;
2652
2653         // wait for stats to be sent first
2654         if(!playerstats_waitforme)
2655                 return;
2656
2657         MapInfo_Enumerate();
2658         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2659                 mapvote_run = TRUE;
2660 }
2661 void MapVote_Think()
2662 {
2663         if(!mapvote_run)
2664                 return;
2665
2666         if(alreadychangedlevel)
2667                 return;
2668
2669         if(time < mapvote_nextthink)
2670                 return;
2671         //dprint("tick\n");
2672
2673         mapvote_nextthink = time + 0.5;
2674
2675         if(!mapvote_initialized)
2676         {
2677                 if(autocvar_rescan_pending == 1)
2678                 {
2679                         cvar_set("rescan_pending", "2");
2680                         localcmd("fs_rescan\nrescan_pending 3\n");
2681                         return;
2682                 }
2683                 else if(autocvar_rescan_pending == 2)
2684                 {
2685                         return;
2686                 }
2687                 else if(autocvar_rescan_pending == 3)
2688                 {
2689                         // now build missing mapinfo files
2690                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2691                                 return;
2692
2693                         // we're done, start the timer
2694                         cvar_set("rescan_pending", "0");
2695                 }
2696
2697                 mapvote_initialized = TRUE;
2698                 if(DoNextMapOverride(0))
2699                         return;
2700                 if(!autocvar_g_maplist_votable || player_count <= 0)
2701                 {
2702                         GotoNextMap(0);
2703                         return;
2704                 }
2705                 MapVote_Init();
2706         }
2707
2708         MapVote_Tick();
2709 }
2710
2711 string GotoMap(string m)
2712 {
2713         if(!MapInfo_CheckMap(m))
2714                 return "The map you chose is not available on this server.";
2715         cvar_set("nextmap", m);
2716         cvar_set("timelimit", "-1");
2717         if(mapvote_initialized || alreadychangedlevel)
2718         {
2719                 if(DoNextMapOverride(0))
2720                         return "Map switch initiated.";
2721                 else
2722                         return "Hm... no. For some reason I like THIS map more.";
2723         }
2724         else
2725                 return "Map switch will happen after scoreboard.";
2726 }
2727
2728
2729 void EndFrame()
2730 {
2731         anticheat_endframe();
2732
2733         float altime;
2734         FOR_EACH_REALCLIENT(self)
2735         {
2736                 if(IS_SPEC(self))
2737                 {
2738                         if(self.enemy.typehitsound)
2739                                 self.typehit_time = time;
2740                         else if(self.enemy.hitsound)
2741                                 self.hit_time = time;
2742                 }
2743                 else
2744                 {
2745                         if(self.typehitsound)
2746                                 self.typehit_time = time;
2747                         else if(self.hitsound)
2748                                 self.hit_time = time;
2749                 }
2750         }
2751         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2752         // add 1 frametime because after this, engine SV_Physics
2753         // increases time by a frametime and then networks the frame
2754         // add another frametime because client shows everything with
2755         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2756         // needed!
2757         FOR_EACH_CLIENT(self)
2758         {
2759                 self.hitsound = FALSE;
2760                 self.typehitsound = FALSE;
2761                 antilag_record(self, altime);
2762         }
2763 }
2764
2765
2766 /*
2767  * RedirectionThink:
2768  * returns TRUE if redirecting
2769  */
2770 float redirection_timeout;
2771 float redirection_nextthink;
2772 float RedirectionThink()
2773 {
2774         float clients_found;
2775
2776         if(redirection_target == "")
2777                 return FALSE;
2778
2779         if(!redirection_timeout)
2780         {
2781                 cvar_set("sv_public", "-2");
2782                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2783                 if(redirection_target == "self")
2784                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2785                 else
2786                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2787         }
2788
2789         if(time < redirection_nextthink)
2790                 return TRUE;
2791
2792         redirection_nextthink = time + 1;
2793
2794         clients_found = 0;
2795         FOR_EACH_REALCLIENT(self)
2796         {
2797                 // TODO add timer
2798                 print("Redirecting: sending connect command to ", self.netname, "\n");
2799                 if(redirection_target == "self")
2800                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2801                 else
2802                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2803                 ++clients_found;
2804         }
2805
2806         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2807
2808         if(time > redirection_timeout || clients_found == 0)
2809                 localcmd("\nwait; wait; wait; quit\n");
2810
2811         return TRUE;
2812 }
2813
2814 void TargetMusic_RestoreGame();
2815 void RestoreGame()
2816 {
2817         // Loaded from a save game
2818         // some things then break, so let's work around them...
2819
2820         // Progs DB (capture records)
2821         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2822
2823         // Mapinfo
2824         MapInfo_Shutdown();
2825         MapInfo_Enumerate();
2826         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2827         WeaponStats_Init();
2828
2829         TargetMusic_RestoreGame();
2830 }
2831
2832 void Shutdown()
2833 {
2834         entity e;
2835
2836         gameover = 2;
2837
2838         if(world_initialized > 0)
2839         {
2840                 world_initialized = 0;
2841                 print("Saving persistent data...\n");
2842                 Ban_SaveBans();
2843
2844                 PlayerStats_EndMatch(0);
2845                 FOR_EACH_CLIENT(e)
2846                         PlayerStats_AddGlobalInfo(e);
2847                 PlayerStats_Shutdown();
2848
2849                 if(!cheatcount_total)
2850                 {
2851                         if(autocvar_sv_db_saveasdump)
2852                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2853                         else
2854                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2855                 }
2856                 if(autocvar_developer)
2857                 {
2858                         if(autocvar_sv_db_saveasdump)
2859                                 db_dump(TemporaryDB, "server-temp.db");
2860                         else
2861                                 db_save(TemporaryDB, "server-temp.db");
2862                 }
2863                 CheatShutdown(); // must be after cheatcount check
2864                 db_close(ServerProgsDB);
2865                 db_close(TemporaryDB);
2866                 print("done!\n");
2867                 // tell the bot system the game is ending now
2868                 bot_endgame();
2869
2870                 WeaponStats_Shutdown();
2871                 MapInfo_Shutdown();
2872         }
2873         else if(world_initialized == 0)
2874         {
2875                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2876         }
2877 }