Buffs: rename registry globals
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2 #include "_all.qh"
3
4 #include "anticheat.qh"
5 #include "antilag.qh"
6 #include "bot/bot.qh"
7 #include "campaign.qh"
8 #include "cheats.qh"
9 #include "cl_client.qh"
10 #include "command/common.qh"
11 #include "command/getreplies.qh"
12 #include "command/sv_cmd.qh"
13 #include "command/vote.qh"
14 #include "g_hook.qh"
15 #include "ipban.qh"
16 #include "mapvoting.qh"
17 #include "mutators/mutators_include.qh"
18 #include "race.qh"
19 #include "scores.qh"
20 #include "teamplay.qh"
21 #include "weapons/weaponstats.qh"
22 #include "../common/buffs/all.qh"
23 #include "../common/constants.qh"
24 #include "../common/deathtypes.qh"
25 #include "../common/effects/effects.qh"
26 #include "../common/mapinfo.qh"
27 #include "../common/monsters/all.qh"
28 #include "../common/monsters/sv_monsters.qh"
29 #include "../common/vehicles/all.qh"
30 #include "../common/notifications.qh"
31 #include "../common/playerstats.qh"
32 #include "../common/stats.qh"
33 #include "../common/teams.qh"
34 #include "../common/util.qh"
35 #include "../common/items/all.qh"
36 #include "../common/weapons/all.qh"
37
38 const float LATENCY_THINKRATE = 10;
39 .float latency_sum;
40 .float latency_cnt;
41 .float latency_time;
42 entity pingplreport;
43 void PingPLReport_Think()
44 {SELFPARAM();
45         float delta;
46         entity e;
47
48         delta = 3 / maxclients;
49         if(delta < sys_frametime)
50                 delta = 0;
51         self.nextthink = time + delta;
52
53         e = edict_num(self.cnt + 1);
54         if(IS_REAL_CLIENT(e))
55         {
56                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
57                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
58                 WriteByte(MSG_BROADCAST, self.cnt);
59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
62
63                 // record latency times for clients throughout the match so we can report it to playerstats
64                 if(time > (e.latency_time + LATENCY_THINKRATE))
65                 {
66                         e.latency_sum += e.ping;
67                         e.latency_cnt += 1;
68                         e.latency_time = time;
69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
70                 }
71         }
72         else
73         {
74                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
75                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
76                 WriteByte(MSG_BROADCAST, self.cnt);
77                 WriteShort(MSG_BROADCAST, 0);
78                 WriteByte(MSG_BROADCAST, 0);
79                 WriteByte(MSG_BROADCAST, 0);
80         }
81         self.cnt = (self.cnt + 1) % maxclients;
82 }
83 void PingPLReport_Spawn()
84 {
85         pingplreport = spawn();
86         pingplreport.classname = "pingplreport";
87         pingplreport.think = PingPLReport_Think;
88         pingplreport.nextthink = time;
89 }
90
91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
92 string redirection_target;
93 float world_initialized;
94
95 string GetGametype();
96 void ShuffleMaplist();
97
98 void SetDefaultAlpha()
99 {
100         if(autocvar_g_running_guns)
101         {
102                 default_player_alpha = -1;
103                 default_weapon_alpha = +1;
104         }
105         else if(g_cloaked)
106         {
107                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
108                 default_weapon_alpha = default_player_alpha;
109         }
110         else
111         {
112                 default_player_alpha = autocvar_g_player_alpha;
113                 if(default_player_alpha == 0)
114                         default_player_alpha = 1;
115                 default_weapon_alpha = default_player_alpha;
116         }
117 }
118
119 void GotoFirstMap()
120 {SELFPARAM();
121         float n;
122         if(autocvar__sv_init)
123         {
124                 // cvar_set("_sv_init", "0");
125                 // we do NOT set this to 0 any more, so someone "accidentally" changing
126                 // to this "init" map on a dedicated server will cause no permanent
127                 // harm
128                 if(autocvar_g_maplist_shuffle)
129                         ShuffleMaplist();
130                 n = tokenizebyseparator(autocvar_g_maplist, " ");
131                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
132
133                 MapInfo_Enumerate();
134                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
135
136                 if(!DoNextMapOverride(1))
137                         GotoNextMap(1);
138
139                 return;
140         }
141
142         if(time < 5)
143         {
144                 self.nextthink = time;
145         }
146         else
147         {
148                 self.nextthink = time + 1;
149                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
150         }
151 }
152
153 void cvar_changes_init()
154 {
155         float h;
156         string k, v, d;
157         float n, i, adding, pureadding;
158
159         if(cvar_changes)
160                 strunzone(cvar_changes);
161         cvar_changes = string_null;
162         if(cvar_purechanges)
163                 strunzone(cvar_purechanges);
164         cvar_purechanges = string_null;
165         cvar_purechanges_count = 0;
166
167         h = buf_create();
168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
169         n = buf_getsize(h);
170
171         adding = true;
172         pureadding = true;
173
174         for(i = 0; i < n; ++i)
175         {
176                 k = bufstr_get(h, i);
177
178 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
179 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
180 #define BADCVAR(p) if(k == p) continue
181
182                 // general excludes and namespaces for server admin used cvars
183                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
184
185                 // internal
186                 BADPREFIX("csqc_");
187                 BADPREFIX("cvar_check_");
188                 BADCVAR("gamecfg");
189                 BADCVAR("g_configversion");
190                 BADCVAR("g_maplist_index");
191                 BADCVAR("halflifebsp");
192                 BADCVAR("sv_mapformat_is_quake2");
193                 BADCVAR("sv_mapformat_is_quake3");
194                 BADPREFIX("sv_world");
195
196                 // client
197                 BADPREFIX("chase_");
198                 BADPREFIX("cl_");
199                 BADPREFIX("con_");
200                 BADPREFIX("scoreboard_");
201                 BADPREFIX("g_campaign");
202                 BADPREFIX("g_waypointsprite_");
203                 BADPREFIX("gl_");
204                 BADPREFIX("joy");
205                 BADPREFIX("hud_");
206                 BADPREFIX("m_");
207                 BADPREFIX("menu_");
208                 BADPREFIX("net_slist_");
209                 BADPREFIX("r_");
210                 BADPREFIX("sbar_");
211                 BADPREFIX("scr_");
212                 BADPREFIX("snd_");
213                 BADPREFIX("show");
214                 BADPREFIX("sensitivity");
215                 BADPREFIX("userbind");
216                 BADPREFIX("v_");
217                 BADPREFIX("vid_");
218                 BADPREFIX("crosshair");
219                 BADCVAR("mod_q3bsp_lightmapmergepower");
220                 BADCVAR("mod_q3bsp_nolightmaps");
221                 BADCVAR("fov");
222                 BADCVAR("mastervolume");
223                 BADCVAR("volume");
224                 BADCVAR("bgmvolume");
225
226                 // private
227                 BADCVAR("developer");
228                 BADCVAR("log_dest_udp");
229                 BADCVAR("net_address");
230                 BADCVAR("net_address_ipv6");
231                 BADCVAR("port");
232                 BADCVAR("savedgamecfg");
233                 BADCVAR("serverconfig");
234                 BADCVAR("sv_autoscreenshot");
235                 BADCVAR("sv_heartbeatperiod");
236                 BADCVAR("sv_vote_master_password");
237                 BADCVAR("sys_colortranslation");
238                 BADCVAR("sys_specialcharactertranslation");
239                 BADCVAR("timeformat");
240                 BADCVAR("timestamps");
241                 BADPREFIX("developer_");
242                 BADPREFIX("g_ban_");
243                 BADPREFIX("g_banned_list");
244                 BADPREFIX("g_chat_flood_");
245                 BADPREFIX("g_ghost_items");
246                 BADPREFIX("g_playerstats_");
247                 BADPREFIX("g_respawn_ghosts");
248                 BADPREFIX("g_voice_flood_");
249                 BADPREFIX("log_file");
250                 BADPREFIX("rcon_");
251                 BADPREFIX("sv_allowdownloads");
252                 BADPREFIX("sv_autodemo");
253                 BADPREFIX("sv_curl_");
254                 BADPREFIX("sv_eventlog");
255                 BADPREFIX("sv_logscores_");
256                 BADPREFIX("sv_master");
257                 BADPREFIX("sv_weaponstats_");
258                 BADPREFIX("sv_waypointsprite_");
259                 BADCVAR("rescan_pending");
260
261                 // these can contain player IDs, so better hide
262                 BADPREFIX("g_forced_team_");
263
264                 // mapinfo
265                 BADCVAR("fraglimit");
266                 BADCVAR("g_assault");
267                 BADCVAR("g_ca");
268                 BADCVAR("g_ca_teams");
269                 BADCVAR("g_ctf");
270                 BADCVAR("g_cts");
271                 BADCVAR("g_dm");
272                 BADCVAR("g_domination");
273                 BADCVAR("g_domination_default_teams");
274                 BADCVAR("g_freezetag");
275                 BADCVAR("g_freezetag_teams");
276                 BADCVAR("g_invasion_teams");
277                 BADCVAR("g_keepaway");
278                 BADCVAR("g_keyhunt");
279                 BADCVAR("g_keyhunt_teams");
280                 BADCVAR("g_lms");
281                 BADCVAR("g_nexball");
282                 BADCVAR("g_onslaught");
283                 BADCVAR("g_race");
284                 BADCVAR("g_race_qualifying_timelimit");
285                 BADCVAR("g_tdm");
286                 BADCVAR("g_tdm_teams");
287                 BADCVAR("leadlimit");
288                 BADCVAR("nextmap");
289                 BADCVAR("teamplay");
290                 BADCVAR("timelimit");
291
292                 // long
293                 BADCVAR("hostname");
294                 BADCVAR("g_maplist");
295                 BADCVAR("g_maplist_mostrecent");
296                 BADCVAR("sv_motd");
297
298                 v = cvar_string(k);
299                 d = cvar_defstring(k);
300                 if(v == d)
301                         continue;
302
303                 if(adding)
304                 {
305                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
306                         if(strlen(cvar_changes) > 16384)
307                         {
308                                 cvar_changes = "// too many settings have been changed to show them here\n";
309                                 adding = 0;
310                         }
311                 }
312
313                 // now check if the changes are actually gameplay relevant
314
315                 // does nothing visible
316                 BADCVAR("captureleadlimit_override");
317                 BADCVAR("g_balance_kill_delay");
318                 BADCVAR("g_ca_point_limit");
319                 BADCVAR("g_ca_point_leadlimit");
320                 BADCVAR("g_ctf_captimerecord_always");
321                 BADCVAR("g_ctf_flag_glowtrails");
322                 BADCVAR("g_ctf_flag_pickup_verbosename");
323                 BADCVAR("g_domination_point_leadlimit");
324                 BADCVAR("g_forced_respawn");
325                 BADCVAR("g_freezetag_point_limit");
326                 BADCVAR("g_freezetag_point_leadlimit");
327                 BADCVAR("g_keyhunt_point_leadlimit");
328                 BADPREFIX("g_mod_");
329                 BADCVAR("g_invasion_point_limit");
330                 BADCVAR("g_nexball_goalleadlimit");
331                 BADCVAR("g_tdm_point_limit");
332                 BADCVAR("g_tdm_point_leadlimit");
333                 BADCVAR("leadlimit_and_fraglimit");
334                 BADCVAR("leadlimit_override");
335                 BADCVAR("pausable");
336                 BADCVAR("sv_allow_fullbright");
337                 BADCVAR("sv_checkforpacketsduringsleep");
338                 BADCVAR("sv_timeout");
339                 BADPREFIX("sv_timeout_");
340                 BADPREFIX("crypto_");
341                 BADPREFIX("g_chat_");
342                 BADPREFIX("g_ctf_captimerecord_");
343                 BADPREFIX("g_maplist_votable_");
344                 BADPREFIX("net_");
345                 BADPREFIX("prvm_");
346                 BADPREFIX("skill_");
347                 BADPREFIX("sv_cullentities_");
348                 BADPREFIX("sv_maxidle_");
349                 BADPREFIX("sv_vote_");
350                 BADPREFIX("timelimit_");
351                 BADCVAR("gameversion");
352                 BADPREFIX("gameversion_");
353                 BADCVAR("sv_minigames");
354                 BADPREFIX("sv_minigames_");
355                 BADCVAR("sv_namechangetimer");
356
357                 // allowed changes to server admins (please sync this to server.cfg)
358                 // vi commands:
359                 //   :/"impure"/,$d
360                 //   :g!,^\/\/[^ /],d
361                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
362                 //   :%!sort
363                 // yes, this does contain some redundant stuff, don't really care
364                 BADCVAR("bot_config_file");
365                 BADCVAR("bot_number");
366                 BADCVAR("bot_prefix");
367                 BADCVAR("bot_suffix");
368                 BADCVAR("capturelimit_override");
369                 BADCVAR("fraglimit_override");
370                 BADCVAR("gametype");
371                 BADCVAR("g_antilag");
372                 BADCVAR("g_balance_teams");
373                 BADCVAR("g_balance_teams_prevent_imbalance");
374                 BADCVAR("g_balance_teams_scorefactor");
375                 BADCVAR("g_ban_sync_trusted_servers");
376                 BADCVAR("g_ban_sync_uri");
377                 BADCVAR("g_ca_teams_override");
378                 BADCVAR("g_ctf_ignore_frags");
379                 BADCVAR("g_domination_point_limit");
380                 BADCVAR("g_domination_teams_override");
381                 BADCVAR("g_freezetag_teams_override");
382                 BADCVAR("g_friendlyfire");
383                 BADCVAR("g_fullbrightitems");
384                 BADCVAR("g_fullbrightplayers");
385                 BADCVAR("g_keyhunt_point_limit");
386                 BADCVAR("g_keyhunt_teams_override");
387                 BADCVAR("g_lms_lives_override");
388                 BADCVAR("g_maplist");
389                 BADCVAR("g_maplist_check_waypoints");
390                 BADCVAR("g_maplist_mostrecent_count");
391                 BADCVAR("g_maplist_shuffle");
392                 BADCVAR("g_maplist_votable");
393                 BADCVAR("g_maplist_votable_abstain");
394                 BADCVAR("g_maplist_votable_nodetail");
395                 BADCVAR("g_maplist_votable_suggestions");
396                 BADCVAR("g_maxplayers");
397                 BADCVAR("g_mirrordamage");
398                 BADCVAR("g_nexball_goallimit");
399                 BADCVAR("g_powerups");
400                 BADCVAR("g_start_delay");
401                 BADCVAR("g_tdm_teams_override");
402                 BADCVAR("g_warmup");
403                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
404                 BADCVAR("hostname");
405                 BADCVAR("log_file");
406                 BADCVAR("maxplayers");
407                 BADCVAR("minplayers");
408                 BADCVAR("net_address");
409                 BADCVAR("port");
410                 BADCVAR("rcon_password");
411                 BADCVAR("rcon_restricted_commands");
412                 BADCVAR("rcon_restricted_password");
413                 BADCVAR("skill");
414                 BADCVAR("sv_adminnick");
415                 BADCVAR("sv_autoscreenshot");
416                 BADCVAR("sv_autotaunt");
417                 BADCVAR("sv_curl_defaulturl");
418                 BADCVAR("sv_defaultcharacter");
419                 BADCVAR("sv_defaultplayercolors");
420                 BADCVAR("sv_defaultplayermodel");
421                 BADCVAR("sv_defaultplayerskin");
422                 BADCVAR("sv_maxidle");
423                 BADCVAR("sv_maxrate");
424                 BADCVAR("sv_motd");
425                 BADCVAR("sv_public");
426                 BADCVAR("sv_ready_restart");
427                 BADCVAR("sv_status_privacy");
428                 BADCVAR("sv_taunt");
429                 BADCVAR("sv_vote_call");
430                 BADCVAR("sv_vote_commands");
431                 BADCVAR("sv_vote_majority_factor");
432                 BADCVAR("sv_vote_master");
433                 BADCVAR("sv_vote_master_commands");
434                 BADCVAR("sv_vote_master_password");
435                 BADCVAR("sv_vote_simple_majority_factor");
436                 BADCVAR("teamplay_mode");
437                 BADCVAR("timelimit_override");
438                 BADCVAR("g_spawnshieldtime");
439                 BADPREFIX("g_warmup_");
440                 BADPREFIX("sv_ready_restart_");
441
442                 // mutators that announce themselves properly to the server browser
443                 BADCVAR("g_instagib");
444                 BADCVAR("g_new_toys");
445                 BADCVAR("g_nix");
446                 BADCVAR("g_grappling_hook");
447                 BADCVAR("g_jetpack");
448
449 #undef BADPREFIX
450 #undef BADCVAR
451
452                 if(pureadding)
453                 {
454                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
455                         if(strlen(cvar_purechanges) > 16384)
456                         {
457                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
458                                 pureadding = 0;
459                         }
460                 }
461                 ++cvar_purechanges_count;
462                 // WARNING: this variable is used for the server list
463                 // NEVER dare to skip this code!
464                 // Hacks to intentionally appearing as "pure server" even though you DO have
465                 // modified settings may be punished by removal from the server list.
466                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
467                 // though.
468         }
469         buf_del(h);
470         if(cvar_changes == "")
471                 cvar_changes = "// this server runs at default server settings\n";
472         else
473                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
474         cvar_changes = strzone(cvar_changes);
475         if(cvar_purechanges == "")
476                 cvar_purechanges = "// this server runs at default gameplay settings\n";
477         else
478                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
479         cvar_purechanges = strzone(cvar_purechanges);
480 }
481
482 void detect_maptype()
483 {
484 #if 0
485         vector o, v;
486         float i;
487
488         for (;;)
489         {
490                 o = world.mins;
491                 o.x += random() * (world.maxs.x - world.mins.x);
492                 o.y += random() * (world.maxs.y - world.mins.y);
493                 o.z += random() * (world.maxs.z - world.mins.z);
494
495                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
496                 if(trace_fraction == 1)
497                         continue;
498
499                 v = trace_endpos;
500
501                 for(i = 0; i < 64; i += 4)
502                 {
503                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
504         if(trace_fraction == 1)
505                 continue;
506                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
507                 }
508
509                 break;
510         }
511 #endif
512 }
513
514 entity randomseed;
515 float RandomSeed_Send(entity to, int sf)
516 {SELFPARAM();
517         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
518         WriteShort(MSG_ENTITY, self.cnt);
519         return true;
520 }
521 void RandomSeed_Think()
522 {SELFPARAM();
523         self.cnt = bound(0, floor(random() * 65536), 65535);
524         self.nextthink = time + 5;
525
526         self.SendFlags |= 1;
527 }
528 void RandomSeed_Spawn()
529 {SELFPARAM();
530         randomseed = spawn();
531         randomseed.think = RandomSeed_Think;
532         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
533
534         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
535 }
536
537 spawnfunc(__init_dedicated_server)
538 {
539         // handler for _init/_init map (only for dedicated server initialization)
540
541         world_initialized = -1; // don't complain
542         cvar = cvar_normal;
543         cvar_string = cvar_string_normal;
544         cvar_set = cvar_set_normal;
545
546         remove = remove_unsafely;
547
548         entity e;
549         e = spawn();
550         e.think = GotoFirstMap;
551         e.nextthink = time; // this is usually 1 at this point
552
553         e = spawn();
554         e.classname = "info_player_deathmatch"; // safeguard against player joining
555
556         self.classname = "worldspawn"; // safeguard against various stuff ;)
557
558         // needs to be done so early because of the constants they create
559         static_init();
560         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
561         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
562
563         MapInfo_Enumerate();
564         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
565 }
566
567 void Map_MarkAsRecent(string m);
568 float world_already_spawned;
569 void Nagger_Init();
570 void ClientInit_Spawn();
571 void WeaponStats_Init();
572 void WeaponStats_Shutdown();
573 void Physics_AddStats();
574 spawnfunc(worldspawn)
575 {
576         float fd, l, j, n;
577         string s;
578
579         cvar = cvar_normal;
580         cvar_string = cvar_string_normal;
581         cvar_set = cvar_set_normal;
582
583         if(world_already_spawned)
584                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
585         world_already_spawned = true;
586
587         remove = remove_safely; // during spawning, watch what you remove!
588
589         cvar_changes_init(); // do this very early now so it REALLY matches the server config
590
591         compressShortVector_init();
592
593         entity head;
594         head = nextent(world);
595         maxclients = 0;
596         while(head)
597         {
598                 ++maxclients;
599                 head = nextent(head);
600         }
601
602         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
603
604         // needs to be done so early because of the constants they create
605         static_init();
606         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
607         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
608
609         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
610
611         TemporaryDB = db_create();
612
613         // 0 normal
614         lightstyle(0, "m");
615
616         // 1 FLICKER (first variety)
617         lightstyle(1, "mmnmmommommnonmmonqnmmo");
618
619         // 2 SLOW STRONG PULSE
620         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
621
622         // 3 CANDLE (first variety)
623         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
624
625         // 4 FAST STROBE
626         lightstyle(4, "mamamamamama");
627
628         // 5 GENTLE PULSE 1
629         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
630
631         // 6 FLICKER (second variety)
632         lightstyle(6, "nmonqnmomnmomomno");
633
634         // 7 CANDLE (second variety)
635         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
636
637         // 8 CANDLE (third variety)
638         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
639
640         // 9 SLOW STROBE (fourth variety)
641         lightstyle(9, "aaaaaaaazzzzzzzz");
642
643         // 10 FLUORESCENT FLICKER
644         lightstyle(10, "mmamammmmammamamaaamammma");
645
646         // 11 SLOW PULSE NOT FADE TO BLACK
647         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
648
649         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
650
651         // 63 testing
652         lightstyle(63, "a");
653
654         if(autocvar_g_campaign)
655                 CampaignPreInit();
656
657         Map_MarkAsRecent(mapname);
658
659         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
660
661         InitGameplayMode();
662         readlevelcvars();
663         GrappleHookInit();
664
665         player_count = 0;
666         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
667         if(bot_waypoints_for_items == 1)
668                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
669                         bot_waypoints_for_items = 0;
670
671         precache();
672
673         WaypointSprite_Init();
674
675         GameLogInit(); // prepare everything
676         // NOTE for matchid:
677         // changing the logic generating it is okay. But:
678         // it HAS to stay <= 64 chars
679         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
680         if(autocvar_sv_eventlog)
681         {
682                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
683                 matchid = strzone(s);
684
685                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
686                 s = ":gameinfo:mutators:LIST";
687
688                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
689                 s = ret_string;
690
691                 // initialiation stuff, not good in the mutator system
692                 if(!autocvar_g_use_ammunition)
693                         s = strcat(s, ":no_use_ammunition");
694
695                 // initialiation stuff, not good in the mutator system
696                 if(autocvar_g_pickup_items == 0)
697                         s = strcat(s, ":no_pickup_items");
698                 if(autocvar_g_pickup_items > 0)
699                         s = strcat(s, ":pickup_items");
700
701                 // initialiation stuff, not good in the mutator system
702                 if(autocvar_g_weaponarena != "0")
703                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
704
705                 // TODO to mutator system
706                 if(autocvar_g_norecoil)
707                         s = strcat(s, ":norecoil");
708
709                 // TODO to mutator system
710                 if(autocvar_g_powerups == 0)
711                         s = strcat(s, ":no_powerups");
712                 if(autocvar_g_powerups > 0)
713                         s = strcat(s, ":powerups");
714
715                 GameLogEcho(s);
716                 GameLogEcho(":gameinfo:end");
717         }
718         else
719                 matchid = strzone(ftos(random()));
720
721         cvar_set("nextmap", "");
722
723         SetDefaultAlpha();
724
725         if(autocvar_g_campaign)
726                 CampaignPostInit();
727
728         Ban_LoadBans();
729
730         MapInfo_Enumerate();
731         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
732
733         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
734         {
735                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
736                 if(fd != -1)
737                 {
738                         while((s = fgets(fd)))
739                         {
740                                 l = tokenize_console(s);
741                                 if(l < 2)
742                                         continue;
743                                 if(argv(0) == "cd")
744                                 {
745                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
746                                         LOG_INFO("  cdtrack ", argv(2), "\n");
747                                 }
748                                 else if(argv(0) == "fog")
749                                 {
750                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
751                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
752                                 }
753                                 else if(argv(0) == "set")
754                                 {
755                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
756                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
757                                 }
758                                 else if(argv(0) != "//")
759                                 {
760                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
761                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
762                                 }
763                         }
764                         fclose(fd);
765                 }
766         }
767
768         WeaponStats_Init();
769
770         WepSet_AddStat();
771         WepSet_AddStat_InMap();
772         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
773         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
774         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
775         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
776         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
777         Nagger_Init();
778
779         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
780         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
781         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
782         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
783         addstat(STAT_FUEL, AS_INT, ammo_fuel);
784         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
785         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
786         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
787         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
788         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
789         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
790         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
791         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
792         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
793         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
794
795         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
796         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
797
798         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
799
800         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
801
802         // freeze attacks
803         addstat(STAT_FROZEN, AS_INT, frozen);
804         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
805
806         // physics
807         Physics_AddStats();
808
809         // new properties
810         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
811         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
812         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
813         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
814         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
815         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
816         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
817         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
818         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
819         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
820         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
821         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
822         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
823         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
824         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
825         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
826         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
827         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
828         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
829
830         // secrets
831         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
832         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
833
834         // monsters
835         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
836         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
837
838         // misc
839         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
840
841         next_pingtime = time + 5;
842
843         detect_maptype();
844
845         // set up information replies for clients and server to use
846         maplist_reply = strzone(getmaplist());
847         lsmaps_reply = strzone(getlsmaps());
848         monsterlist_reply = strzone(getmonsterlist());
849         for(int i = 0; i < 10; ++i)
850         {
851                 s = getrecords(i);
852                 if (s)
853                         records_reply[i] = strzone(s);
854         }
855         ladder_reply = strzone(getladder());
856         rankings_reply = strzone(getrankings());
857
858         // begin other init
859         ClientInit_Spawn();
860         RandomSeed_Spawn();
861         PingPLReport_Spawn();
862
863         CheatInit();
864
865         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
866
867         // fill sv_curl_serverpackages from .serverpackage files
868         if(autocvar_sv_curl_serverpackages_auto)
869         {
870                 s = "";
871                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
872                 for(int i = 0; i < n; ++i)
873                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
874                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
875                                 s = strcat(s, " ", argv(i));
876                 fd = search_begin("*-serverpackage.txt", true, false);
877                 if(fd >= 0)
878                 {
879                         j = search_getsize(fd);
880                         for(int i = 0; i < j; ++i)
881                                 s = strcat(s, " ", search_getfilename(fd, i));
882                         search_end(fd);
883                 }
884                 fd = search_begin("*.serverpackage", true, false);
885                 if(fd >= 0)
886                 {
887                         j = search_getsize(fd);
888                         for(int i = 0; i < j; ++i)
889                                 s = strcat(s, " ", search_getfilename(fd, i));
890                         search_end(fd);
891                 }
892                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
893         }
894
895         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
896         modname = "Xonotic";
897         // physics/balance/config changes that count as mod
898         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
899                 modname = cvar_string("g_mod_physics");
900         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
901                 modname = cvar_string("g_mod_balance");
902         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
903                 modname = cvar_string("g_mod_config");
904         // extra mutators that deserve to count as mod
905         MUTATOR_CALLHOOK(SetModname);
906
907         // save it for later
908         modname = strzone(modname);
909
910         WinningConditionHelper(); // set worldstatus
911
912         world_initialized = 1;
913 }
914
915 spawnfunc(light)
916 {
917         //makestatic (self); // Who the f___ did that?
918         remove(self);
919 }
920
921 string GetGametype()
922 {
923         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
924 }
925
926 string GetMapname()
927 {
928         return mapname;
929 }
930
931 float Map_Count, Map_Current;
932 string Map_Current_Name;
933
934 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
935 float GetMaplistPosition()
936 {
937         float pos, idx;
938         string map;
939
940         map = GetMapname();
941         idx = autocvar_g_maplist_index;
942
943         if(idx >= 0)
944                 if(idx < Map_Count)
945                         if(map == argv(idx))
946                                 return idx;
947
948         for(pos = 0; pos < Map_Count; ++pos)
949                 if(map == argv(pos))
950                         return pos;
951
952         // resume normal maplist rotation if current map is not in g_maplist
953         return idx;
954 }
955
956 float MapHasRightSize(string map)
957 {
958         float fh;
959         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
960         if(autocvar_g_maplist_check_waypoints)
961         {
962                 LOG_TRACE("checkwp "); LOG_TRACE(map);
963                 if(!fexists(strcat("maps/", map, ".waypoints")))
964                 {
965                         LOG_TRACE(": no waypoints\n");
966                         return false;
967                 }
968                 LOG_TRACE(": has waypoints\n");
969         }
970
971         // open map size restriction file
972         LOG_TRACE("opensize "); LOG_TRACE(map);
973         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
974         if(fh >= 0)
975         {
976                 float mapmin, mapmax;
977                 LOG_TRACE(": ok, ");
978                 mapmin = stof(fgets(fh));
979                 mapmax = stof(fgets(fh));
980                 fclose(fh);
981                 if(player_count < mapmin)
982                 {
983                         LOG_TRACE("not enough\n");
984                         return false;
985                 }
986                 if(player_count > mapmax)
987                 {
988                         LOG_TRACE("too many\n");
989                         return false;
990                 }
991                 LOG_TRACE("right size\n");
992                 return true;
993         }
994         LOG_TRACE(": not found\n");
995         return true;
996 }
997
998 string Map_Filename(float position)
999 {
1000         return strcat("maps/", argv(position), ".bsp");
1001 }
1002
1003 string strwords(string s, float w)
1004 {
1005         float endpos;
1006         for(endpos = 0; w && endpos >= 0; --w)
1007                 endpos = strstrofs(s, " ", endpos + 1);
1008         if(endpos < 0)
1009                 return s;
1010         else
1011                 return substring(s, 0, endpos);
1012 }
1013
1014 float strhasword(string s, string w)
1015 {
1016         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1017 }
1018
1019 void Map_MarkAsRecent(string m)
1020 {
1021         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1022 }
1023
1024 float Map_IsRecent(string m)
1025 {
1026         return strhasword(autocvar_g_maplist_mostrecent, m);
1027 }
1028
1029 float Map_Check(float position, float pass)
1030 {
1031         string filename;
1032         string map_next;
1033         map_next = argv(position);
1034         if(pass <= 1)
1035         {
1036                 if(Map_IsRecent(map_next))
1037                         return 0;
1038         }
1039         filename = Map_Filename(position);
1040         if(MapInfo_CheckMap(map_next))
1041         {
1042                 if(pass == 2)
1043                         return 1;
1044                 if(MapHasRightSize(map_next))
1045                         return 1;
1046                 return 0;
1047         }
1048         else
1049                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1050
1051         return 0;
1052 }
1053
1054 void Map_Goto_SetStr(string nextmapname)
1055 {
1056         if(getmapname_stored != "")
1057                 strunzone(getmapname_stored);
1058         if(nextmapname == "")
1059                 getmapname_stored = "";
1060         else
1061                 getmapname_stored = strzone(nextmapname);
1062 }
1063
1064 void Map_Goto_SetFloat(float position)
1065 {
1066         cvar_set("g_maplist_index", ftos(position));
1067         Map_Goto_SetStr(argv(position));
1068 }
1069
1070 void Map_Goto(float reinit)
1071 {
1072         MapInfo_LoadMap(getmapname_stored, reinit);
1073 }
1074
1075 // return codes of map selectors:
1076 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1077 //   -2 = permanent failure
1078 float() MaplistMethod_Iterate = // usual method
1079 {
1080         float pass, i;
1081
1082         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1083
1084         for(pass = 1; pass <= 2; ++pass)
1085         {
1086                 for(i = 1; i < Map_Count; ++i)
1087                 {
1088                         float mapindex;
1089                         mapindex = (i + Map_Current) % Map_Count;
1090                         if(Map_Check(mapindex, pass))
1091                                 return mapindex;
1092                 }
1093         }
1094         return -1;
1095 }
1096
1097 float() MaplistMethod_Repeat = // fallback method
1098 {
1099         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1100
1101         if(Map_Check(Map_Current, 2))
1102                 return Map_Current;
1103         return -2;
1104 }
1105
1106 float() MaplistMethod_Random = // random map selection
1107 {
1108         float i, imax;
1109
1110         LOG_TRACE("Trying MaplistMethod_Random\n");
1111
1112         imax = 42;
1113
1114         for(i = 0; i <= imax; ++i)
1115         {
1116                 float mapindex;
1117                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1118                 if(Map_Check(mapindex, 1))
1119                         return mapindex;
1120         }
1121         return -1;
1122 }
1123
1124 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1125 // the exponent sets a bias on the map selection:
1126 // the higher the exponent, the less likely "shortly repeated" same maps are
1127 {
1128         float i, j, imax, insertpos;
1129
1130         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1131
1132         imax = 42;
1133
1134         for(i = 0; i <= imax; ++i)
1135         {
1136                 string newlist;
1137
1138                 // now reinsert this at another position
1139                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1140                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1141                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1142                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1143
1144                 // insert the current map there
1145                 newlist = "";
1146                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1147                         newlist = strcat(newlist, " ", argv(j));
1148                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1149                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1150                         newlist = strcat(newlist, " ", argv(j));
1151                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1152                 cvar_set("g_maplist", newlist);
1153                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1154
1155                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1156                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1157                 if(Map_Check(Map_Current, 1))
1158                         return Map_Current;
1159         }
1160         return -1;
1161 }
1162
1163 void Maplist_Init()
1164 {
1165         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1166         float i;
1167         for (i = 0; i < Map_Count; ++i)
1168                 if (Map_Check(i, 2))
1169                         break;
1170         if (i == Map_Count)
1171         {
1172                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1173                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1174                 if(autocvar_g_maplist_shuffle)
1175                         ShuffleMaplist();
1176                 localcmd("\nmenu_cmd sync\n");
1177                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1178         }
1179         if(Map_Count == 0)
1180                 error("empty maplist, cannot select a new map");
1181         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1182
1183         if(Map_Current_Name)
1184                 strunzone(Map_Current_Name);
1185         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1186         // this may or may not be correct, but who cares, in the worst case a map
1187         // isn't chosen in the first pass that should have been
1188 }
1189
1190 string GetNextMap()
1191 {
1192         float nextMap;
1193
1194         Maplist_Init();
1195         nextMap = -1;
1196
1197         if(nextMap == -1)
1198                 if(autocvar_g_maplist_shuffle > 0)
1199                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1200
1201         if(nextMap == -1)
1202                 if(autocvar_g_maplist_selectrandom)
1203                         nextMap = MaplistMethod_Random();
1204
1205         if(nextMap == -1)
1206                 nextMap = MaplistMethod_Iterate();
1207
1208         if(nextMap == -1)
1209                 nextMap = MaplistMethod_Repeat();
1210
1211         if(nextMap >= 0)
1212         {
1213                 Map_Goto_SetFloat(nextMap);
1214                 return getmapname_stored;
1215         }
1216
1217         return "";
1218 }
1219
1220 float DoNextMapOverride(float reinit)
1221 {
1222         if(autocvar_g_campaign)
1223         {
1224                 CampaignPostIntermission();
1225                 alreadychangedlevel = true;
1226                 return true;
1227         }
1228         if(autocvar_quit_when_empty)
1229         {
1230                 if(player_count <= currentbots)
1231                 {
1232                         localcmd("quit\n");
1233                         alreadychangedlevel = true;
1234                         return true;
1235                 }
1236         }
1237         if(autocvar_quit_and_redirect != "")
1238         {
1239                 redirection_target = strzone(autocvar_quit_and_redirect);
1240                 alreadychangedlevel = true;
1241                 return true;
1242         }
1243         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1244         {
1245                 localcmd("restart\n");
1246                 alreadychangedlevel = true;
1247                 return true;
1248         }
1249         if(autocvar_nextmap != "")
1250         {
1251                 string m;
1252                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1253                 cvar_set("nextmap",m);
1254
1255                 if(!m || gametypevote)
1256                         return false;
1257                 if(autocvar_sv_vote_gametype)
1258                 {
1259                         Map_Goto_SetStr(m);
1260                         return false;
1261                 }
1262
1263                 if(MapInfo_CheckMap(m))
1264                 {
1265                         Map_Goto_SetStr(m);
1266                         Map_Goto(reinit);
1267                         alreadychangedlevel = true;
1268                         return true;
1269                 }
1270         }
1271         if(!reinit && autocvar_lastlevel)
1272         {
1273                 cvar_settemp_restore();
1274                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1275                 alreadychangedlevel = true;
1276                 return true;
1277         }
1278         return false;
1279 }
1280
1281 void GotoNextMap(float reinit)
1282 {
1283         //string nextmap;
1284         //float n, nummaps;
1285         //string s;
1286         if (alreadychangedlevel)
1287                 return;
1288         alreadychangedlevel = true;
1289
1290         string nextMap;
1291
1292         nextMap = GetNextMap();
1293         if(nextMap == "")
1294                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1295         Map_Goto(reinit);
1296 }
1297
1298
1299 /*
1300 ============
1301 IntermissionThink
1302
1303 When the player presses attack or jump, change to the next level
1304 ============
1305 */
1306 .float autoscreenshot;
1307 void IntermissionThink()
1308 {SELFPARAM();
1309         FixIntermissionClient(self);
1310
1311         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1312         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1313
1314         if( (server_screenshot || client_screenshot)
1315                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1316         {
1317                 self.autoscreenshot = -1;
1318                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1319                 return;
1320         }
1321
1322         if (time < intermission_exittime)
1323                 return;
1324
1325         if(!mapvote_initialized)
1326                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1327                         return;
1328
1329         MapVote_Start();
1330 }
1331
1332 /*
1333 ============
1334 FindIntermission
1335
1336 Returns the entity to view from
1337 ============
1338 */
1339 /*
1340 entity FindIntermission()
1341 {
1342         local   entity spot;
1343         local   float cyc;
1344
1345 // look for info_intermission first
1346         spot = find (world, classname, "info_intermission");
1347         if (spot)
1348         {       // pick a random one
1349                 cyc = random() * 4;
1350                 while (cyc > 1)
1351                 {
1352                         spot = find (spot, classname, "info_intermission");
1353                         if (!spot)
1354                                 spot = find (spot, classname, "info_intermission");
1355                         cyc = cyc - 1;
1356                 }
1357                 return spot;
1358         }
1359
1360 // then look for the start position
1361         spot = find (world, classname, "info_player_start");
1362         if (spot)
1363                 return spot;
1364
1365 // testinfo_player_start is only found in regioned levels
1366         spot = find (world, classname, "testplayerstart");
1367         if (spot)
1368                 return spot;
1369
1370 // then look for the start position
1371         spot = find (world, classname, "info_player_deathmatch");
1372         if (spot)
1373                 return spot;
1374
1375         //objerror ("FindIntermission: no spot");
1376         return world;
1377 }
1378 */
1379
1380 /*
1381 ===============================================================================
1382
1383 RULES
1384
1385 ===============================================================================
1386 */
1387
1388 void DumpStats(float final)
1389 {
1390         float file;
1391         string s;
1392         float to_console;
1393         float to_eventlog;
1394         float to_file;
1395         float i;
1396
1397         to_console = autocvar_sv_logscores_console;
1398         to_eventlog = autocvar_sv_eventlog;
1399         to_file = autocvar_sv_logscores_file;
1400
1401         if(!final)
1402         {
1403                 to_console = true; // always print printstats replies
1404                 to_eventlog = false; // but never print them to the event log
1405         }
1406
1407         if(to_eventlog)
1408                 if(autocvar_sv_eventlog_console)
1409                         to_console = false; // otherwise we get the output twice
1410
1411         if(final)
1412                 s = ":scores:";
1413         else
1414                 s = ":status:";
1415         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1416
1417         if(to_console)
1418                 LOG_INFO(s, "\n");
1419         if(to_eventlog)
1420                 GameLogEcho(s);
1421
1422         file = -1;
1423         if(to_file)
1424         {
1425                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1426                 if(file == -1)
1427                         to_file = false;
1428                 else
1429                         fputs(file, strcat(s, "\n"));
1430         }
1431
1432         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1433         if(to_console)
1434                 LOG_INFO(s, "\n");
1435         if(to_eventlog)
1436                 GameLogEcho(s);
1437         if(to_file)
1438                 fputs(file, strcat(s, "\n"));
1439
1440         FOR_EACH_CLIENT(other)
1441         {
1442                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1443                 {
1444                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1445                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1446                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1447                                 s = strcat(s, ftos(other.team), ":");
1448                         else
1449                                 s = strcat(s, "spectator:");
1450
1451                         if(to_console)
1452                                 LOG_INFO(s, other.netname, "\n");
1453                         if(to_eventlog)
1454                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1455                         if(to_file)
1456                                 fputs(file, strcat(s, other.netname, "\n"));
1457                 }
1458         }
1459
1460         if(teamplay)
1461         {
1462                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1463                 if(to_console)
1464                         LOG_INFO(s, "\n");
1465                 if(to_eventlog)
1466                         GameLogEcho(s);
1467                 if(to_file)
1468                         fputs(file, strcat(s, "\n"));
1469
1470                 for(i = 1; i < 16; ++i)
1471                 {
1472                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1473                         s = strcat(s, ":", ftos(i));
1474                         if(to_console)
1475                                 LOG_INFO(s, "\n");
1476                         if(to_eventlog)
1477                                 GameLogEcho(s);
1478                         if(to_file)
1479                                 fputs(file, strcat(s, "\n"));
1480                 }
1481         }
1482
1483         if(to_console)
1484                 LOG_INFO(":end\n");
1485         if(to_eventlog)
1486                 GameLogEcho(":end");
1487         if(to_file)
1488         {
1489                 fputs(file, ":end\n");
1490                 fclose(file);
1491         }
1492 }
1493
1494 void FixIntermissionClient(entity e)
1495 {
1496         string s;
1497         if(!e.autoscreenshot) // initial call
1498         {
1499                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1500                 e.health = -2342;
1501                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1502                 e.solid = SOLID_NOT;
1503                 e.movetype = MOVETYPE_NONE;
1504                 e.takedamage = DAMAGE_NO;
1505                 if(e.weaponentity)
1506                 {
1507                         e.weaponentity.effects = EF_NODRAW;
1508                         if (e.weaponentity.weaponentity)
1509                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1510                 }
1511                 if(IS_REAL_CLIENT(e))
1512                 {
1513                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1514                         s = autocvar_sv_intermission_cdtrack;
1515                         if(s != "")
1516                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1517                         msg_entity = e;
1518                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1519                 }
1520         }
1521 }
1522
1523 /*
1524 go to the next level for deathmatch
1525 only called if a time or frag limit has expired
1526 */
1527 void NextLevel()
1528 {
1529         gameover = true;
1530
1531         intermission_running = 1;
1532
1533 // enforce a wait time before allowing changelevel
1534         if(player_count > 0)
1535                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1536         else
1537                 intermission_exittime = -1;
1538
1539         /*
1540         WriteByte (MSG_ALL, SVC_CDTRACK);
1541         WriteByte (MSG_ALL, 3);
1542         WriteByte (MSG_ALL, 3);
1543         // done in FixIntermission
1544         */
1545
1546         //pos = FindIntermission ();
1547
1548         VoteReset();
1549
1550         DumpStats(true);
1551
1552         // send statistics
1553         PlayerStats_GameReport(true);
1554         WeaponStats_Shutdown();
1555
1556         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1557
1558         if(autocvar_sv_eventlog)
1559                 GameLogEcho(":gameover");
1560
1561         GameLogClose();
1562
1563         FOR_EACH_PLAYER(other) {
1564                 FixIntermissionClient(other);
1565                 if(other.winning)
1566                         bprint(other.netname, " ^7wins.\n");
1567         }
1568
1569         if(autocvar_g_campaign)
1570                 CampaignPreIntermission();
1571
1572         MUTATOR_CALLHOOK(MatchEnd);
1573
1574         localcmd("\nsv_hook_gameend\n");
1575 }
1576
1577 /*
1578 ============
1579 CheckRules_Player
1580
1581 Exit deathmatch games upon conditions
1582 ============
1583 */
1584 void CheckRules_Player()
1585 {SELFPARAM();
1586         if (gameover)   // someone else quit the game already
1587                 return;
1588
1589         if(self.deadflag == DEAD_NO)
1590                 self.play_time += frametime;
1591
1592         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1593         //   (div0: and that in CheckRules_World please)
1594 }
1595
1596
1597 float InitiateSuddenDeath()
1598 {
1599         // Check first whether normal overtimes could be added before initiating suddendeath mode
1600         // - for this timelimit_overtime needs to be >0 of course
1601         // - also check the winning condition calculated in the previous frame and only add normal overtime
1602         //   again, if at the point at which timelimit would be extended again, still no winner was found
1603         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1604         {
1605                 return 1; // need to call InitiateOvertime later
1606         }
1607         else
1608         {
1609                 if(!checkrules_suddendeathend)
1610                 {
1611                         if(autocvar_g_campaign)
1612                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1613                         else
1614                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1615                         if(g_race && !g_race_qualifying)
1616                                 race_StartCompleting();
1617                 }
1618                 return 0;
1619         }
1620 }
1621
1622 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1623 {
1624         ++checkrules_overtimesadded;
1625         //add one more overtime by simply extending the timelimit
1626         float tl;
1627         tl = autocvar_timelimit;
1628         tl += autocvar_timelimit_overtime;
1629         cvar_set("timelimit", ftos(tl));
1630
1631         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1632 }
1633
1634 float GetWinningCode(float fraglimitreached, float equality)
1635 {
1636         if(autocvar_g_campaign == 1)
1637                 if(fraglimitreached)
1638                         return WINNING_YES;
1639                 else
1640                         return WINNING_NO;
1641
1642         else
1643                 if(equality)
1644                         if(fraglimitreached)
1645                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1646                         else
1647                                 return WINNING_NEVER;
1648                 else
1649                         if(fraglimitreached)
1650                                 return WINNING_YES;
1651                         else
1652                                 return WINNING_NO;
1653 }
1654
1655 // set the .winning flag for exactly those players with a given field value
1656 void SetWinners(.float field, float value)
1657 {
1658         entity head;
1659         FOR_EACH_PLAYER(head)
1660                 head.winning = (head.(field) == value);
1661 }
1662
1663 // set the .winning flag for those players with a given field value
1664 void AddWinners(.float field, float value)
1665 {
1666         entity head;
1667         FOR_EACH_PLAYER(head)
1668                 if (head.(field) == value)
1669                         head.winning = 1;
1670 }
1671
1672 // clear the .winning flags
1673 void ClearWinners(void)
1674 {
1675         entity head;
1676         FOR_EACH_PLAYER(head)
1677                 head.winning = 0;
1678 }
1679
1680 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1681 // they win. Otherwise the defending team wins once the timelimit passes.
1682 void assault_new_round();
1683 float WinningCondition_Assault()
1684 {SELFPARAM();
1685         float status;
1686
1687         WinningConditionHelper(); // set worldstatus
1688
1689         status = WINNING_NO;
1690         // as the timelimit has not yet passed just assume the defending team will win
1691         if(assault_attacker_team == NUM_TEAM_1)
1692         {
1693                 SetWinners(team, NUM_TEAM_2);
1694         }
1695         else
1696         {
1697                 SetWinners(team, NUM_TEAM_1);
1698         }
1699
1700         entity ent;
1701         ent = find(world, classname, "target_assault_roundend");
1702         if(ent)
1703         {
1704                 if(ent.winning) // round end has been triggered by attacking team
1705                 {
1706                         bprint("ASSAULT: round completed...\n");
1707                         SetWinners(team, assault_attacker_team);
1708
1709                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1710
1711                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1712                         {
1713                                 status = WINNING_YES;
1714                         }
1715                         else
1716                         {
1717                                 WITH(entity, self, ent, assault_new_round());
1718                         }
1719                 }
1720         }
1721
1722         return status;
1723 }
1724
1725 // LMS winning condition: game terminates if and only if there's at most one
1726 // one player who's living lives. Top two scores being equal cancels the time
1727 // limit.
1728 float WinningCondition_LMS()
1729 {
1730         entity head, head2;
1731         float have_player;
1732         float have_players;
1733         float l;
1734
1735         have_player = false;
1736         have_players = false;
1737         l = LMS_NewPlayerLives();
1738
1739         head = find(world, classname, "player");
1740         if(head)
1741                 have_player = true;
1742         head2 = find(head, classname, "player");
1743         if(head2)
1744                 have_players = true;
1745
1746         if(have_player)
1747         {
1748                 // we have at least one player
1749                 if(have_players)
1750                 {
1751                         // two or more active players - continue with the game
1752                 }
1753                 else
1754                 {
1755                         // exactly one player?
1756
1757                         ClearWinners();
1758                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1759
1760                         if(l)
1761                         {
1762                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1763                                 return WINNING_NO;
1764                         }
1765                         else
1766                         {
1767                                 // a winner!
1768                                 // and assign him his first place
1769                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1770                                 return WINNING_YES;
1771                         }
1772                 }
1773         }
1774         else
1775         {
1776                 // nobody is playing at all...
1777                 if(l)
1778                 {
1779                         // wait for players...
1780                 }
1781                 else
1782                 {
1783                         // SNAFU (maybe a draw game?)
1784                         ClearWinners();
1785                         LOG_TRACE("No players, ending game.\n");
1786                         return WINNING_YES;
1787                 }
1788         }
1789
1790         // When we get here, we have at least two players who are actually LIVING,
1791         // now check if the top two players have equal score.
1792         WinningConditionHelper();
1793
1794         ClearWinners();
1795         if(WinningConditionHelper_winner)
1796                 WinningConditionHelper_winner.winning = true;
1797         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1798                 return WINNING_NEVER;
1799
1800         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1801         return WINNING_NO;
1802 }
1803
1804 void ShuffleMaplist()
1805 {
1806         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1807 }
1808
1809 float leaderfrags;
1810 float WinningCondition_Scores(float limit, float leadlimit)
1811 {
1812         float limitreached;
1813
1814         // TODO make everything use THIS winning condition (except LMS)
1815         WinningConditionHelper();
1816
1817         if(teamplay)
1818         {
1819                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1820                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1821                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1822                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1823         }
1824
1825         ClearWinners();
1826         if(WinningConditionHelper_winner)
1827                 WinningConditionHelper_winner.winning = 1;
1828         if(WinningConditionHelper_winnerteam >= 0)
1829                 SetWinners(team, WinningConditionHelper_winnerteam);
1830
1831         if(WinningConditionHelper_lowerisbetter)
1832         {
1833                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1834                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1835                 limit = -limit;
1836         }
1837
1838         if(WinningConditionHelper_zeroisworst)
1839                 leadlimit = 0; // not supported in this mode
1840
1841         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1842         // these modes always score in increments of 1, thus this makes sense
1843         {
1844                 if(leaderfrags != WinningConditionHelper_topscore)
1845                 {
1846                         leaderfrags = WinningConditionHelper_topscore;
1847
1848                         if (limit)
1849                         if (leaderfrags == limit - 1)
1850                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1851                         else if (leaderfrags == limit - 2)
1852                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1853                         else if (leaderfrags == limit - 3)
1854                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1855                 }
1856         }
1857
1858         limitreached = false;
1859         if(limit)
1860                 if(WinningConditionHelper_topscore >= limit)
1861                         limitreached = true;
1862         if(leadlimit)
1863         {
1864                 float leadlimitreached;
1865                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1866                 if(autocvar_leadlimit_and_fraglimit)
1867                         limitreached = (limitreached && leadlimitreached);
1868                 else
1869                         limitreached = (limitreached || leadlimitreached);
1870         }
1871
1872         if(limit)
1873                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1874
1875         return GetWinningCode(
1876                 WinningConditionHelper_topscore && limitreached,
1877                 WinningConditionHelper_equality
1878         );
1879 }
1880
1881 float WinningCondition_Race(float fraglimit)
1882 {
1883         float wc;
1884         entity p;
1885         float n, c;
1886
1887         n = 0;
1888         c = 0;
1889         FOR_EACH_PLAYER(p)
1890         {
1891                 ++n;
1892                 if(p.race_completed)
1893                         ++c;
1894         }
1895         if(n && (n == c))
1896                 return WINNING_YES;
1897         wc = WinningCondition_Scores(fraglimit, 0);
1898
1899         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1900         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1901         // do NOT support equality when the laps are all raced!
1902                 return WINNING_STARTSUDDENDEATHOVERTIME;
1903         else
1904                 return WINNING_NEVER;
1905 }
1906
1907 float WinningCondition_QualifyingThenRace(float limit)
1908 {
1909         float wc;
1910         wc = WinningCondition_Scores(limit, 0);
1911
1912         // NEVER initiate overtime
1913         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1914         {
1915                 return WINNING_YES;
1916         }
1917
1918         return wc;
1919 }
1920
1921 float WinningCondition_RanOutOfSpawns()
1922 {
1923         entity head;
1924
1925         if(have_team_spawns <= 0)
1926                 return WINNING_NO;
1927
1928         if(!autocvar_g_spawn_useallspawns)
1929                 return WINNING_NO;
1930
1931         if(!some_spawn_has_been_used)
1932                 return WINNING_NO;
1933
1934         team1_score = team2_score = team3_score = team4_score = 0;
1935
1936         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1937         {
1938                 if(head.team == NUM_TEAM_1)
1939                         team1_score = 1;
1940                 else if(head.team == NUM_TEAM_2)
1941                         team2_score = 1;
1942                 else if(head.team == NUM_TEAM_3)
1943                         team3_score = 1;
1944                 else if(head.team == NUM_TEAM_4)
1945                         team4_score = 1;
1946         }
1947
1948         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1949         {
1950                 if(head.team == NUM_TEAM_1)
1951                         team1_score = 1;
1952                 else if(head.team == NUM_TEAM_2)
1953                         team2_score = 1;
1954                 else if(head.team == NUM_TEAM_3)
1955                         team3_score = 1;
1956                 else if(head.team == NUM_TEAM_4)
1957                         team4_score = 1;
1958         }
1959
1960         ClearWinners();
1961         if(team1_score + team2_score + team3_score + team4_score == 0)
1962         {
1963                 checkrules_equality = true;
1964                 return WINNING_YES;
1965         }
1966         else if(team1_score + team2_score + team3_score + team4_score == 1)
1967         {
1968                 float t, i;
1969                 if(team1_score)
1970                         t = NUM_TEAM_1;
1971                 else if(team2_score)
1972                         t = NUM_TEAM_2;
1973                 else if(team3_score)
1974                         t = NUM_TEAM_3;
1975                 else // if(team4_score)
1976                         t = NUM_TEAM_4;
1977                 CheckAllowedTeams(world);
1978                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1979                 {
1980                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1981                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1982                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1983                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1984                 }
1985
1986                 AddWinners(team, t);
1987                 return WINNING_YES;
1988         }
1989         else
1990                 return WINNING_NO;
1991 }
1992
1993 /*
1994 ============
1995 CheckRules_World
1996
1997 Exit deathmatch games upon conditions
1998 ============
1999 */
2000 void CheckRules_World()
2001 {
2002         float timelimit;
2003         float fraglimit;
2004         float leadlimit;
2005
2006         VoteThink();
2007         MapVote_Think();
2008
2009         SetDefaultAlpha();
2010
2011         if (gameover)   // someone else quit the game already
2012         {
2013                 if(player_count == 0) // Nobody there? Then let's go to the next map
2014                         MapVote_Start();
2015                         // this will actually check the player count in the next frame
2016                         // again, but this shouldn't hurt
2017                 return;
2018         }
2019
2020         timelimit = autocvar_timelimit * 60;
2021         fraglimit = autocvar_fraglimit;
2022         leadlimit = autocvar_leadlimit;
2023
2024         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2025         {
2026                 if(timelimit > 0)
2027                         timelimit = 0; // timelimit is not made for warmup
2028                 if(fraglimit > 0)
2029                         fraglimit = 0; // no fraglimit for now
2030                 leadlimit = 0; // no leadlimit for now
2031         }
2032
2033         if(timelimit > 0)
2034         {
2035                 timelimit += game_starttime;
2036         }
2037         else if (timelimit < 0)
2038         {
2039                 // endmatch
2040                 NextLevel();
2041                 return;
2042         }
2043
2044         float wantovertime;
2045         wantovertime = 0;
2046
2047         if(timelimit > game_starttime)
2048                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2049         else
2050                 game_completion_ratio = 0;
2051
2052         if(checkrules_suddendeathend)
2053         {
2054                 if(!checkrules_suddendeathwarning)
2055                 {
2056                         checkrules_suddendeathwarning = true;
2057                         if(g_race && !g_race_qualifying)
2058                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2059                         else
2060                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2061                 }
2062         }
2063         else
2064         {
2065                 if (timelimit && time >= timelimit)
2066                 {
2067                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2068                         {
2069                                 float totalplayers;
2070                                 float playerswithlaps;
2071                                 float readyplayers;
2072                                 entity head;
2073                                 totalplayers = playerswithlaps = readyplayers = 0;
2074                                 FOR_EACH_PLAYER(head)
2075                                 {
2076                                         ++totalplayers;
2077                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2078                                                 ++playerswithlaps;
2079                                         if(head.ready)
2080                                                 ++readyplayers;
2081                                 }
2082
2083                                 // at least 2 of the players have completed a lap: start the RACE
2084                                 // otherwise, the players should end the qualifying on their own
2085                                 if(readyplayers || playerswithlaps >= 2)
2086                                 {
2087                                         checkrules_suddendeathend = 0;
2088                                         ReadyRestart(); // go to race
2089                                         return;
2090                                 }
2091                                 else
2092                                         wantovertime |= InitiateSuddenDeath();
2093                         }
2094                         else
2095                                 wantovertime |= InitiateSuddenDeath();
2096                 }
2097         }
2098
2099         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2100         {
2101                 NextLevel();
2102                 return;
2103         }
2104
2105         float checkrules_status;
2106         checkrules_status = WinningCondition_RanOutOfSpawns();
2107         if(checkrules_status == WINNING_YES)
2108         {
2109                 bprint("Hey! Someone ran out of spawns!\n");
2110         }
2111         else if(g_race && !g_race_qualifying && timelimit >= 0)
2112         {
2113                 checkrules_status = WinningCondition_Race(fraglimit);
2114                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2115         }
2116         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2117         {
2118                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2119                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2120         }
2121         else if(g_assault)
2122         {
2123                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2124         }
2125         else if(g_lms)
2126         {
2127                 checkrules_status = WinningCondition_LMS();
2128         }
2129         else
2130         {
2131                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2132                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2133         }
2134
2135         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2136         {
2137                 checkrules_status = WINNING_NEVER;
2138                 checkrules_overtimesadded = -1;
2139                 wantovertime |= InitiateSuddenDeath();
2140         }
2141
2142         if(checkrules_status == WINNING_NEVER)
2143                 // equality cases! Nobody wins if the overtime ends in a draw.
2144                 ClearWinners();
2145
2146         if(wantovertime)
2147         {
2148                 if(checkrules_status == WINNING_NEVER)
2149                         InitiateOvertime();
2150                 else
2151                         checkrules_status = WINNING_YES;
2152         }
2153
2154         if(checkrules_suddendeathend)
2155                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2156                         checkrules_status = WINNING_YES;
2157
2158         if(checkrules_status == WINNING_YES)
2159         {
2160                 //print("WINNING\n");
2161                 NextLevel();
2162         }
2163 }
2164
2165 string GotoMap(string m)
2166 {
2167         m = GameTypeVote_MapInfo_FixName(m);
2168         if (!m)
2169                 return "The map you suggested is not available on this server.";
2170         if (!autocvar_sv_vote_gametype)
2171         if(!MapInfo_CheckMap(m))
2172                 return "The map you suggested does not support the current game mode.";
2173         cvar_set("nextmap", m);
2174         cvar_set("timelimit", "-1");
2175         if(mapvote_initialized || alreadychangedlevel)
2176         {
2177                 if(DoNextMapOverride(0))
2178                         return "Map switch initiated.";
2179                 else
2180                         return "Hm... no. For some reason I like THIS map more.";
2181         }
2182         else
2183                 return "Map switch will happen after scoreboard.";
2184 }
2185
2186
2187 void EndFrame()
2188 {SELFPARAM();
2189         anticheat_endframe();
2190
2191         float altime;
2192         entity e_;
2193         FOR_EACH_REALCLIENT(e_)
2194         {
2195                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2196                 if(e.typehitsound)
2197                         e_.typehit_time = time;
2198                 else if(e.damage_dealt)
2199                 {
2200                         e_.hit_time = time;
2201                         e_.damage_dealt_total += ceil(e.damage_dealt);
2202                 }
2203         }
2204         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2205         // add 1 frametime because after this, engine SV_Physics
2206         // increases time by a frametime and then networks the frame
2207         // add another frametime because client shows everything with
2208         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2209         // needed!
2210         FOR_EACH_CLIENT(e_)
2211         {
2212                 e_.typehitsound = false;
2213                 e_.damage_dealt = 0;
2214                 setself(e_);
2215                 antilag_record(e_, altime);
2216         }
2217         FOR_EACH_MONSTER(e_)
2218         {
2219                 setself(e_);
2220                 antilag_record(e_, altime);
2221         }
2222 }
2223
2224
2225 /*
2226  * RedirectionThink:
2227  * returns true if redirecting
2228  */
2229 float redirection_timeout;
2230 float redirection_nextthink;
2231 float RedirectionThink()
2232 {SELFPARAM();
2233         float clients_found;
2234
2235         if(redirection_target == "")
2236                 return false;
2237
2238         if(!redirection_timeout)
2239         {
2240                 cvar_set("sv_public", "-2");
2241                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2242                 if(redirection_target == "self")
2243                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2244                 else
2245                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2246         }
2247
2248         if(time < redirection_nextthink)
2249                 return true;
2250
2251         redirection_nextthink = time + 1;
2252
2253         clients_found = 0;
2254         entity e;
2255         FOR_EACH_REALCLIENT(e)
2256         {
2257                 setself(e);
2258                 // TODO add timer
2259                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2260                 if(redirection_target == "self")
2261                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2262                 else
2263                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2264                 ++clients_found;
2265         }
2266
2267         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2268
2269         if(time > redirection_timeout || clients_found == 0)
2270                 localcmd("\nwait; wait; wait; quit\n");
2271
2272         return true;
2273 }
2274
2275 void TargetMusic_RestoreGame();
2276 void RestoreGame()
2277 {
2278         // Loaded from a save game
2279         // some things then break, so let's work around them...
2280
2281         // Progs DB (capture records)
2282         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2283
2284         // Mapinfo
2285         MapInfo_Shutdown();
2286         MapInfo_Enumerate();
2287         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2288         WeaponStats_Init();
2289
2290         TargetMusic_RestoreGame();
2291 }
2292
2293 void Shutdown()
2294 {
2295         gameover = 2;
2296
2297         if(world_initialized > 0)
2298         {
2299                 world_initialized = 0;
2300                 LOG_INFO("Saving persistent data...\n");
2301                 Ban_SaveBans();
2302
2303                 // playerstats with unfinished match
2304                 PlayerStats_GameReport(false);
2305
2306                 if(!cheatcount_total)
2307                 {
2308                         if(autocvar_sv_db_saveasdump)
2309                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2310                         else
2311                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2312                 }
2313                 if(autocvar_developer)
2314                 {
2315                         if(autocvar_sv_db_saveasdump)
2316                                 db_dump(TemporaryDB, "server-temp.db");
2317                         else
2318                                 db_save(TemporaryDB, "server-temp.db");
2319                 }
2320                 CheatShutdown(); // must be after cheatcount check
2321                 db_close(ServerProgsDB);
2322                 db_close(TemporaryDB);
2323                 LOG_INFO("done!\n");
2324                 // tell the bot system the game is ending now
2325                 bot_endgame();
2326
2327                 WeaponStats_Shutdown();
2328                 MapInfo_Shutdown();
2329         }
2330         else if(world_initialized == 0)
2331         {
2332                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2333         }
2334 }