6ee29474e5470944cf7122279c8213ecd91f57a4
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2
3 #include "anticheat.qh"
4 #include "antilag.qh"
5 #include "bot/api.qh"
6 #include "campaign.qh"
7 #include "cheats.qh"
8 #include "client.qh"
9 #include "command/common.qh"
10 #include "command/getreplies.qh"
11 #include "command/sv_cmd.qh"
12 #include "command/vote.qh"
13 #include "g_hook.qh"
14 #include "ipban.qh"
15 #include "mapvoting.qh"
16 #include <server/mutators/_mod.qh>
17 #include "race.qh"
18 #include "scores.qh"
19 #include "scores_rules.qh"
20 #include "teamplay.qh"
21 #include "weapons/weaponstats.qh"
22 #include "../common/constants.qh"
23 #include <common/net_linked.qh>
24 #include "../common/deathtypes/all.qh"
25 #include "../common/gamemodes/sv_rules.qh"
26 #include "../common/mapinfo.qh"
27 #include "../common/monsters/_mod.qh"
28 #include "../common/monsters/sv_monsters.qh"
29 #include "../common/vehicles/all.qh"
30 #include "../common/notifications/all.qh"
31 #include "../common/physics/player.qh"
32 #include "../common/playerstats.qh"
33 #include "../common/stats.qh"
34 #include "../common/teams.qh"
35 #include "../common/mapobjects/trigger/secret.qh"
36 #include "../common/mapobjects/target/music.qh"
37 #include "../common/util.qh"
38 #include "../common/items/_mod.qh"
39 #include <common/weapons/_all.qh>
40 #include "../common/state.qh"
41
42 const float LATENCY_THINKRATE = 10;
43 .float latency_sum;
44 .float latency_cnt;
45 .float latency_time;
46 entity pingplreport;
47 void PingPLReport_Think(entity this)
48 {
49         float delta;
50         entity e;
51
52         delta = 3 / maxclients;
53         if(delta < sys_frametime)
54                 delta = 0;
55         this.nextthink = time + delta;
56
57         e = edict_num(this.cnt + 1);
58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
59         {
60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
61                 WriteByte(MSG_BROADCAST, this.cnt);
62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
65
66                 // record latency times for clients throughout the match so we can report it to playerstats
67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
68                 {
69                         CS(e).latency_sum += CS(e).ping;
70                         CS(e).latency_cnt += 1;
71                         CS(e).latency_time = time;
72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
73                 }
74         }
75         else
76         {
77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
78                 WriteByte(MSG_BROADCAST, this.cnt);
79                 WriteShort(MSG_BROADCAST, 0);
80                 WriteByte(MSG_BROADCAST, 0);
81                 WriteByte(MSG_BROADCAST, 0);
82         }
83         this.cnt = (this.cnt + 1) % maxclients;
84 }
85 void PingPLReport_Spawn()
86 {
87         pingplreport = new_pure(pingplreport);
88         setthink(pingplreport, PingPLReport_Think);
89         pingplreport.nextthink = time;
90 }
91
92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
93 string redirection_target;
94 float world_initialized;
95
96 void SetDefaultAlpha()
97 {
98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
99         {
100                 default_player_alpha = autocvar_g_player_alpha;
101                 if(default_player_alpha == 0)
102                         default_player_alpha = 1;
103                 default_weapon_alpha = default_player_alpha;
104         }
105 }
106
107 void GotoFirstMap(entity this)
108 {
109         float n;
110         if(autocvar__sv_init)
111         {
112                 // cvar_set("_sv_init", "0");
113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
114                 // to this "init" map on a dedicated server will cause no permanent
115                 // harm
116                 if(autocvar_g_maplist_shuffle)
117                         ShuffleMaplist();
118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
120
121                 MapInfo_Enumerate();
122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
123
124                 if(!DoNextMapOverride(1))
125                         GotoNextMap(1);
126
127                 return;
128         }
129
130         if(time < 5)
131         {
132                 this.nextthink = time;
133         }
134         else
135         {
136                 this.nextthink = time + 1;
137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
138         }
139 }
140
141 void cvar_changes_init()
142 {
143         float h;
144         string k, v, d;
145         float n, i, adding, pureadding;
146
147         strfree(cvar_changes);
148         strfree(cvar_purechanges);
149         cvar_purechanges_count = 0;
150
151         h = buf_create();
152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
153         n = buf_getsize(h);
154
155         adding = true;
156         pureadding = true;
157
158         for(i = 0; i < n; ++i)
159         {
160                 k = bufstr_get(h, i);
161
162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
164 #define BADCVAR(p) if(k == p) continue
165
166                 // general excludes and namespaces for server admin used cvars
167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
168
169                 // internal
170                 BADPREFIX("csqc_");
171                 BADPREFIX("cvar_check_");
172                 BADCVAR("gamecfg");
173                 BADCVAR("g_configversion");
174                 BADCVAR("halflifebsp");
175                 BADCVAR("sv_mapformat_is_quake2");
176                 BADCVAR("sv_mapformat_is_quake3");
177                 BADPREFIX("sv_world");
178
179                 // client
180                 BADPREFIX("chase_");
181                 BADPREFIX("cl_");
182                 BADPREFIX("con_");
183                 BADPREFIX("scoreboard_");
184                 BADPREFIX("g_campaign");
185                 BADPREFIX("g_waypointsprite_");
186                 BADPREFIX("gl_");
187                 BADPREFIX("joy");
188                 BADPREFIX("hud_");
189                 BADPREFIX("m_");
190                 BADPREFIX("menu_");
191                 BADPREFIX("net_slist_");
192                 BADPREFIX("r_");
193                 BADPREFIX("sbar_");
194                 BADPREFIX("scr_");
195                 BADPREFIX("snd_");
196                 BADPREFIX("show");
197                 BADPREFIX("sensitivity");
198                 BADPREFIX("userbind");
199                 BADPREFIX("v_");
200                 BADPREFIX("vid_");
201                 BADPREFIX("crosshair");
202                 BADCVAR("mod_q3bsp_lightmapmergepower");
203                 BADCVAR("mod_q3bsp_nolightmaps");
204                 BADCVAR("fov");
205                 BADCVAR("mastervolume");
206                 BADCVAR("volume");
207                 BADCVAR("bgmvolume");
208                 BADCVAR("in_pitch_min");
209                 BADCVAR("in_pitch_max");
210
211                 // private
212                 BADCVAR("developer");
213                 BADCVAR("log_dest_udp");
214                 BADCVAR("net_address");
215                 BADCVAR("net_address_ipv6");
216                 BADCVAR("port");
217                 BADCVAR("savedgamecfg");
218                 BADCVAR("serverconfig");
219                 BADCVAR("sv_autoscreenshot");
220                 BADCVAR("sv_heartbeatperiod");
221                 BADCVAR("sv_vote_master_password");
222                 BADCVAR("sys_colortranslation");
223                 BADCVAR("sys_specialcharactertranslation");
224                 BADCVAR("timeformat");
225                 BADCVAR("timestamps");
226                 BADCVAR("g_require_stats");
227                 BADPREFIX("developer_");
228                 BADPREFIX("g_ban_");
229                 BADPREFIX("g_banned_list");
230                 BADPREFIX("g_require_stats_");
231                 BADPREFIX("g_chat_flood_");
232                 BADPREFIX("g_ghost_items");
233                 BADPREFIX("g_playerstats_");
234                 BADPREFIX("g_voice_flood_");
235                 BADPREFIX("log_file");
236                 BADPREFIX("quit_");
237                 BADPREFIX("rcon_");
238                 BADPREFIX("sv_allowdownloads");
239                 BADPREFIX("sv_autodemo");
240                 BADPREFIX("sv_curl_");
241                 BADPREFIX("sv_eventlog");
242                 BADPREFIX("sv_logscores_");
243                 BADPREFIX("sv_master");
244                 BADPREFIX("sv_weaponstats_");
245                 BADPREFIX("sv_waypointsprite_");
246                 BADCVAR("rescan_pending");
247
248                 // these can contain player IDs, so better hide
249                 BADPREFIX("g_forced_team_");
250                 BADCVAR("sv_muteban_list");
251                 BADCVAR("sv_voteban_list");
252                 BADCVAR("sv_allow_customplayermodels_idlist");
253                 BADCVAR("sv_allow_customplayermodels_speciallist");
254
255                 // mapinfo
256                 BADCVAR("fraglimit");
257                 BADCVAR("g_arena");
258                 BADCVAR("g_assault");
259                 BADCVAR("g_ca");
260                 BADCVAR("g_ca_teams");
261                 BADCVAR("g_conquest");
262                 BADCVAR("g_ctf");
263                 BADCVAR("g_cts");
264                 BADCVAR("g_dotc");
265                 BADCVAR("g_dm");
266                 BADCVAR("g_domination");
267                 BADCVAR("g_domination_default_teams");
268                 BADCVAR("g_duel");
269                 BADCVAR("g_duel_not_dm_maps");
270                 BADCVAR("g_freezetag");
271                 BADCVAR("g_freezetag_teams");
272                 BADCVAR("g_invasion_teams");
273                 BADCVAR("g_invasion_type");
274                 BADCVAR("g_jailbreak");
275                 BADCVAR("g_jailbreak_teams");
276                 BADCVAR("g_keepaway");
277                 BADCVAR("g_keyhunt");
278                 BADCVAR("g_keyhunt_teams");
279                 BADCVAR("g_lms");
280                 BADCVAR("g_nexball");
281                 BADCVAR("g_onslaught");
282                 BADCVAR("g_race");
283                 BADCVAR("g_race_laps_limit");
284                 BADCVAR("g_race_qualifying_timelimit");
285                 BADCVAR("g_race_qualifying_timelimit_override");
286                 BADCVAR("g_runematch");
287                 BADCVAR("g_shootfromeye");
288                 BADCVAR("g_snafu");
289                 BADCVAR("g_tdm");
290                 BADCVAR("g_tdm_on_dm_maps");
291                 BADCVAR("g_tdm_teams");
292                 BADCVAR("g_vip");
293                 BADCVAR("leadlimit");
294                 BADCVAR("nextmap");
295                 BADCVAR("teamplay");
296                 BADCVAR("timelimit");
297                 BADCVAR("g_mapinfo_ignore_warnings");
298                 BADCVAR("g_maplist_ignore_sizes");
299                 BADCVAR("g_maplist_sizes_count_bots");
300
301                 // long
302                 BADCVAR("hostname");
303                 BADCVAR("g_maplist");
304                 BADCVAR("g_maplist_mostrecent");
305                 BADCVAR("sv_motd");
306
307                 v = cvar_string(k);
308                 d = cvar_defstring(k);
309                 if(v == d)
310                         continue;
311
312                 if(adding)
313                 {
314                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
315                         if(strlen(cvar_changes) > 16384)
316                         {
317                                 cvar_changes = "// too many settings have been changed to show them here\n";
318                                 adding = 0;
319                         }
320                 }
321
322                 // now check if the changes are actually gameplay relevant
323
324                 // does nothing gameplay relevant
325                 BADCVAR("captureleadlimit_override");
326                 BADCVAR("condump_stripcolors");
327                 BADCVAR("gameversion");
328                 BADCVAR("fs_gamedir");
329                 BADCVAR("g_allow_oldvortexbeam");
330                 BADCVAR("g_balance_kill_delay");
331                 BADCVAR("g_buffs_pickup_anyway");
332                 BADCVAR("g_buffs_randomize");
333                 BADCVAR("g_campcheck_distance");
334                 BADCVAR("g_ca_point_leadlimit");
335                 BADCVAR("g_ca_point_limit");
336                 BADCVAR("g_ctf_captimerecord_always");
337                 BADCVAR("g_ctf_flag_glowtrails");
338                 BADCVAR("g_ctf_flag_pickup_verbosename");
339                 BADCVAR("g_domination_point_leadlimit");
340                 BADCVAR("g_forced_respawn");
341                 BADCVAR("g_freezetag_point_leadlimit");
342                 BADCVAR("g_freezetag_point_limit");
343                 BADCVAR("g_hats");
344                 BADCVAR("g_invasion_point_limit");
345                 BADCVAR("g_jump_grunt");
346                 BADCVAR("g_keyhunt_point_leadlimit");
347                 BADCVAR("g_nexball_goalleadlimit");
348                 BADCVAR("g_new_toys_autoreplace");
349                 BADCVAR("g_new_toys_use_pickupsound");
350                 BADCVAR("g_physics_predictall");
351                 BADCVAR("g_piggyback");
352                 BADCVAR("g_playerclip_collisions");
353                 BADCVAR("g_spawn_alloweffects");
354                 BADCVAR("g_tdm_point_leadlimit");
355                 BADCVAR("g_tdm_point_limit");
356                 BADCVAR("leadlimit_and_fraglimit");
357                 BADCVAR("leadlimit_override");
358                 BADCVAR("pausable");
359                 BADCVAR("sv_checkforpacketsduringsleep");
360                 BADCVAR("sv_damagetext");
361                 BADCVAR("sv_db_saveasdump");
362                 BADCVAR("sv_intermission_cdtrack");
363                 BADCVAR("sv_mapchange_delay");
364                 BADCVAR("sv_minigames");
365                 BADCVAR("sv_namechangetimer");
366                 BADCVAR("sv_precacheplayermodels");
367                 BADCVAR("sv_stepheight");
368                 BADCVAR("sv_timeout");
369                 BADCVAR("sv_weapons_modeloverride");
370                 BADCVAR("w_prop_interval");
371                 BADPREFIX("crypto_");
372                 BADPREFIX("gameversion_");
373                 BADPREFIX("g_chat_");
374                 BADPREFIX("g_ctf_captimerecord_");
375                 BADPREFIX("g_hats_");
376                 BADPREFIX("g_maplist_");
377                 BADPREFIX("g_mod_");
378                 BADPREFIX("g_respawn_");
379                 BADPREFIX("net_");
380                 BADPREFIX("notification_");
381                 BADPREFIX("prvm_");
382                 BADPREFIX("skill_");
383                 BADPREFIX("sv_allow_");
384                 BADPREFIX("sv_cullentities_");
385                 BADPREFIX("sv_maxidle_");
386                 BADPREFIX("sv_minigames_");
387                 BADPREFIX("sv_radio_");
388                 BADPREFIX("sv_timeout_");
389                 BADPREFIX("sv_vote_");
390                 BADPREFIX("timelimit_");
391
392                 // allowed changes to server admins (please sync this to server.cfg)
393                 // vi commands:
394                 //   :/"impure"/,$d
395                 //   :g!,^\/\/[^ /],d
396                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
397                 //   :%!sort
398                 // yes, this does contain some redundant stuff, don't really care
399                 BADCVAR("bot_config_file");
400                 BADCVAR("bot_number");
401                 BADCVAR("bot_prefix");
402                 BADCVAR("bot_suffix");
403                 BADCVAR("capturelimit_override");
404                 BADCVAR("fraglimit_override");
405                 BADCVAR("gametype");
406                 BADCVAR("g_antilag");
407                 BADCVAR("g_balance_teams");
408                 BADCVAR("g_balance_teams_prevent_imbalance");
409                 BADCVAR("g_balance_teams_scorefactor");
410                 BADCVAR("g_ban_sync_trusted_servers");
411                 BADCVAR("g_ban_sync_uri");
412                 BADCVAR("g_buffs");
413                 BADCVAR("g_ca_teams_override");
414                 BADCVAR("g_ctf_fullbrightflags");
415                 BADCVAR("g_ctf_ignore_frags");
416                 BADCVAR("g_ctf_leaderboard");
417                 BADCVAR("g_domination_point_limit");
418                 BADCVAR("g_domination_teams_override");
419                 BADCVAR("g_freezetag_teams_override");
420                 BADCVAR("g_friendlyfire");
421                 BADCVAR("g_fullbrightitems");
422                 BADCVAR("g_fullbrightplayers");
423                 BADCVAR("g_keyhunt_point_limit");
424                 BADCVAR("g_keyhunt_teams_override");
425                 BADCVAR("g_lms_lives_override");
426                 BADCVAR("g_maplist");
427                 BADCVAR("g_maxplayers");
428                 BADCVAR("g_mirrordamage");
429                 BADCVAR("g_nexball_goallimit");
430                 BADCVAR("g_norecoil");
431                 BADCVAR("g_physics_clientselect");
432                 BADCVAR("g_pinata");
433                 BADCVAR("g_powerups");
434                 BADCVAR("g_player_brightness");
435                 BADCVAR("g_rocket_flying");
436                 BADCVAR("g_rocket_flying_disabledelays");
437                 BADCVAR("g_spawnshieldtime");
438                 BADCVAR("g_start_delay");
439                 BADCVAR("g_superspectate");
440                 BADCVAR("g_tdm_teams_override");
441                 BADCVAR("g_warmup");
442                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
443                 BADCVAR("hostname");
444                 BADCVAR("log_file");
445                 BADCVAR("maxplayers");
446                 BADCVAR("minplayers");
447                 BADCVAR("minplayers_per_team");
448                 BADCVAR("net_address");
449                 BADCVAR("port");
450                 BADCVAR("rcon_password");
451                 BADCVAR("rcon_restricted_commands");
452                 BADCVAR("rcon_restricted_password");
453                 BADCVAR("skill");
454                 BADCVAR("sv_adminnick");
455                 BADCVAR("sv_autoscreenshot");
456                 BADCVAR("sv_autotaunt");
457                 BADCVAR("sv_curl_defaulturl");
458                 BADCVAR("sv_defaultcharacter");
459                 BADCVAR("sv_defaultcharacterskin");
460                 BADCVAR("sv_defaultplayercolors");
461                 BADCVAR("sv_defaultplayermodel");
462                 BADCVAR("sv_defaultplayerskin");
463                 BADCVAR("sv_maxidle");
464                 BADCVAR("sv_maxrate");
465                 BADCVAR("sv_motd");
466                 BADCVAR("sv_public");
467                 BADCVAR("sv_ready_restart");
468                 BADCVAR("sv_status_privacy");
469                 BADCVAR("sv_taunt");
470                 BADCVAR("sv_vote_call");
471                 BADCVAR("sv_vote_commands");
472                 BADCVAR("sv_vote_majority_factor");
473                 BADCVAR("sv_vote_master");
474                 BADCVAR("sv_vote_master_commands");
475                 BADCVAR("sv_vote_master_password");
476                 BADCVAR("sv_vote_simple_majority_factor");
477                 BADCVAR("teamplay_mode");
478                 BADCVAR("timelimit_override");
479                 BADPREFIX("g_warmup_");
480                 BADPREFIX("sv_info_");
481                 BADPREFIX("sv_ready_restart_");
482
483                 // mutators that announce themselves properly to the server browser
484                 BADCVAR("g_instagib");
485                 BADCVAR("g_new_toys");
486                 BADCVAR("g_nix");
487                 BADCVAR("g_grappling_hook");
488                 BADCVAR("g_jetpack");
489
490                 // temporary for testing
491                 // TODO remove before 0.8.3 release
492                 BADCVAR("g_ca_weaponarena");
493                 BADCVAR("g_freezetag_weaponarena");
494                 BADCVAR("g_lms_weaponarena");
495
496                 if(cvar_string("g_mod_balance") == "Testing")
497                 {
498                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
499                         BADPREFIX("g_balance_");
500                 }
501
502 #undef BADPRESUFFIX
503 #undef BADPREFIX
504 #undef BADCVAR
505
506                 if(pureadding)
507                 {
508                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
509                         if(strlen(cvar_purechanges) > 16384)
510                         {
511                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
512                                 pureadding = 0;
513                         }
514                 }
515                 ++cvar_purechanges_count;
516                 // WARNING: this variable is used for the server list
517                 // NEVER dare to skip this code!
518                 // Hacks to intentionally appearing as "pure server" even though you DO have
519                 // modified settings may be punished by removal from the server list.
520                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
521                 // though.
522         }
523         buf_del(h);
524         if(cvar_changes == "")
525                 cvar_changes = "// this server runs at default server settings\n";
526         else
527                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
528         cvar_changes = strzone(cvar_changes);
529         if(cvar_purechanges == "")
530                 cvar_purechanges = "// this server runs at default gameplay settings\n";
531         else
532                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
533         cvar_purechanges = strzone(cvar_purechanges);
534 }
535
536 entity randomseed;
537 bool RandomSeed_Send(entity this, entity to, int sf)
538 {
539         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
540         WriteShort(MSG_ENTITY, this.cnt);
541         return true;
542 }
543 void RandomSeed_Think(entity this)
544 {
545         this.cnt = bound(0, floor(random() * 65536), 65535);
546         this.nextthink = time + 5;
547
548         this.SendFlags |= 1;
549 }
550 void RandomSeed_Spawn()
551 {
552         randomseed = new_pure(randomseed);
553         setthink(randomseed, RandomSeed_Think);
554         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
555
556         getthink(randomseed)(randomseed); // sets random seed and nextthink
557 }
558
559 spawnfunc(__init_dedicated_server)
560 {
561         // handler for _init/_init map (only for dedicated server initialization)
562
563         world_initialized = -1; // don't complain
564         cvar = cvar_normal;
565         cvar_string = cvar_string_normal;
566         cvar_set = cvar_set_normal;
567
568         delete_fn = remove_unsafely;
569
570         entity e = spawn();
571         setthink(e, GotoFirstMap);
572         e.nextthink = time; // this is usually 1 at this point
573
574         e = new(info_player_deathmatch);  // safeguard against player joining
575
576     // assign reflectively to avoid "assignment to world" warning
577     for (int i = 0, n = numentityfields(); i < n; ++i) {
578         string k = entityfieldname(i);
579         if (k == "classname") {
580             // safeguard against various stuff ;)
581             putentityfieldstring(i, this, "worldspawn");
582             break;
583         }
584     }
585
586         // needs to be done so early because of the constants they create
587         static_init();
588         static_init_late();
589         static_init_precache();
590
591         IL_PUSH(g_spawnpoints, e); // just incase
592
593         MapInfo_Enumerate();
594         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
595 }
596
597 void __init_dedicated_server_shutdown() {
598         MapInfo_Shutdown();
599 }
600
601 STATIC_INIT_EARLY(maxclients)
602 {
603         maxclients = 0;
604         for (entity head = nextent(NULL); head; head = nextent(head)) {
605                 ++maxclients;
606         }
607 }
608
609 void default_delayedinit(entity this)
610 {
611         if(!scores_initialized)
612                 ScoreRules_generic();
613 }
614
615 void InitGameplayMode()
616 {
617         VoteReset();
618
619         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
620         get_mi_min_max(1);
621         // assign reflectively to avoid "assignment to world" warning
622         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
623             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
624             if (v) {
625             putentityfieldstring(i, world, sprintf("%v", v));
626             if (++done == 2) break;
627         }
628         }
629         // currently, NetRadiant's limit is 131072 qu for each side
630         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
631         // set the distance according to map size but don't go over the limit to avoid issues with float precision
632         // in case somebody makes extremely large maps
633         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
634
635         MapInfo_LoadMapSettings(mapname);
636         GameRules_teams(false);
637
638         if (!cvar_value_issafe(world.fog))
639         {
640                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
641                 world.fog = string_null;
642         }
643         if(MapInfo_Map_fog != "")
644         {
645                 if(MapInfo_Map_fog == "none")
646                         world.fog = string_null;
647                 else
648                         world.fog = strzone(MapInfo_Map_fog);
649         }
650         clientstuff = strzone(MapInfo_Map_clientstuff);
651
652         MapInfo_ClearTemps();
653
654         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
655
656         cache_mutatormsg = strzone("");
657         cache_lastmutatormsg = strzone("");
658
659         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
660 }
661
662 void Map_MarkAsRecent(string m);
663 float world_already_spawned;
664 spawnfunc(worldspawn)
665 {
666         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
667
668         bool wantrestart = false;
669         {
670                 if (!server_is_dedicated)
671                 {
672                         // force unloading of server pk3 files when starting a listen server
673                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
674                         // restore csqc_progname too
675                         string expect = "csprogs.dat";
676                         wantrestart = cvar_string_normal("csqc_progname") != expect;
677                         cvar_set_normal("csqc_progname", expect);
678                 }
679                 else
680                 {
681                         // Try to use versioned csprogs from pk3
682                         // Only ever use versioned csprogs.dat files on dedicated servers;
683                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
684                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
685                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
686                         string select = "csprogs.dat";
687                         if (fexists(pk3csprogs)) select = pk3csprogs;
688                         if (cvar_string_normal("csqc_progname") != select)
689                         {
690                                 cvar_set_normal("csqc_progname", select);
691                                 wantrestart = true;
692                         }
693                         // Check for updates on startup
694                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
695                         int sentinel = fopen("progs.txt", FILE_READ);
696                         if (sentinel >= 0)
697                         {
698                                 string switchversion = fgets(sentinel);
699                                 fclose(sentinel);
700                                 if (switchversion != "" && switchversion != WATERMARK)
701                                 {
702                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
703                                         // if it doesn't exist, assume either:
704                                         //   a) the current program was overwritten
705                                         //   b) this is a client only update
706                                         string newprogs = sprintf("progs-%s.dat", switchversion);
707                                         if (fexists(newprogs))
708                                         {
709                                                 cvar_set_normal("sv_progs", newprogs);
710                                                 wantrestart = true;
711                                         }
712                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
713                                         if (fexists(newcsprogs))
714                                         {
715                                                 cvar_set_normal("csqc_progname", newcsprogs);
716                                                 wantrestart = true;
717                                         }
718                                 }
719                         }
720                 }
721                 if (wantrestart)
722                 {
723                         LOG_INFO("Restart requested");
724                         changelevel(mapname);
725                         // let initialization continue, shutdown depends on it
726                 }
727         }
728
729         cvar = cvar_normal;
730         cvar_string = cvar_string_normal;
731         cvar_set = cvar_set_normal;
732
733         if(world_already_spawned)
734                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
735         world_already_spawned = true;
736
737         delete_fn = remove_safely; // during spawning, watch what you remove!
738
739         cvar_changes_init(); // do this very early now so it REALLY matches the server config
740
741         // needs to be done so early because of the constants they create
742         static_init();
743
744         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
745
746         TemporaryDB = db_create();
747
748         // 0 normal
749         lightstyle(0, "m");
750
751         // 1 FLICKER (first variety)
752         lightstyle(1, "mmnmmommommnonmmonqnmmo");
753
754         // 2 SLOW STRONG PULSE
755         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
756
757         // 3 CANDLE (first variety)
758         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
759
760         // 4 FAST STROBE
761         lightstyle(4, "mamamamamama");
762
763         // 5 GENTLE PULSE 1
764         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
765
766         // 6 FLICKER (second variety)
767         lightstyle(6, "nmonqnmomnmomomno");
768
769         // 7 CANDLE (second variety)
770         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
771
772         // 8 CANDLE (third variety)
773         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
774
775         // 9 SLOW STROBE (fourth variety)
776         lightstyle(9, "aaaaaaaazzzzzzzz");
777
778         // 10 FLUORESCENT FLICKER
779         lightstyle(10, "mmamammmmammamamaaamammma");
780
781         // 11 SLOW PULSE NOT FADE TO BLACK
782         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
783
784         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
785
786         // 63 testing
787         lightstyle(63, "a");
788
789         if(autocvar_g_campaign)
790                 CampaignPreInit();
791
792         Map_MarkAsRecent(mapname);
793
794         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
795
796         InitGameplayMode();
797         static_init_late();
798         static_init_precache();
799         readlevelcvars();
800         GrappleHookInit();
801
802         GameRules_limit_fallbacks();
803
804         if(warmup_limit == 0)
805                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
806
807         player_count = 0;
808         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
809         if(bot_waypoints_for_items == 1)
810                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
811                         bot_waypoints_for_items = 0;
812
813         precache();
814
815         WaypointSprite_Init();
816
817         GameLogInit(); // prepare everything
818         // NOTE for matchid:
819         // changing the logic generating it is okay. But:
820         // it HAS to stay <= 64 chars
821         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
822         if(autocvar_sv_eventlog)
823         {
824                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
825                 matchid = strzone(s);
826
827                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
828                 s = ":gameinfo:mutators:LIST";
829
830                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
831                 s = M_ARGV(0, string);
832
833                 // initialiation stuff, not good in the mutator system
834                 if(!autocvar_g_use_ammunition)
835                         s = strcat(s, ":no_use_ammunition");
836
837                 // initialiation stuff, not good in the mutator system
838                 if(autocvar_g_pickup_items == 0)
839                         s = strcat(s, ":no_pickup_items");
840                 if(autocvar_g_pickup_items > 0)
841                         s = strcat(s, ":pickup_items");
842
843                 // initialiation stuff, not good in the mutator system
844                 if(autocvar_g_weaponarena != "0")
845                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
846
847                 // TODO to mutator system
848                 if(autocvar_g_norecoil)
849                         s = strcat(s, ":norecoil");
850
851                 // TODO to mutator system
852                 if(autocvar_g_powerups == 0)
853                         s = strcat(s, ":no_powerups");
854                 if(autocvar_g_powerups > 0)
855                         s = strcat(s, ":powerups");
856
857                 GameLogEcho(s);
858                 GameLogEcho(":gameinfo:end");
859         }
860         else
861                 matchid = strzone(ftos(random()));
862
863         cvar_set("nextmap", "");
864
865         SetDefaultAlpha();
866
867         if(autocvar_g_campaign)
868                 CampaignPostInit();
869
870         Ban_LoadBans();
871
872         MapInfo_Enumerate();
873         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
874
875         if(fexists(strcat("scripts/", mapname, ".defi")))
876                 cvar_settemp("sv_q3defragcompat", "1");
877
878         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
879         {
880                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
881                 if(fd != -1)
882                 {
883                         string s;
884                         while((s = fgets(fd)))
885                         {
886                                 int l = tokenize_console(s);
887                                 if(l < 2)
888                                         continue;
889                                 if(argv(0) == "cd")
890                                 {
891                                         string trackname = argv(2);
892                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
893                                         LOG_INFO("  cdtrack ", trackname);
894                                         if (cvar_value_issafe(trackname))
895                                         {
896                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
897                                                 strcpy(clientstuff, newstuff);
898                                         }
899                                 }
900                                 else if(argv(0) == "fog")
901                                 {
902                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
903                                         LOG_INFO("  \"fog\" \"", s, "\"");
904                                 }
905                                 else if(argv(0) == "set")
906                                 {
907                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
908                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
909                                 }
910                                 else if(argv(0) != "//")
911                                 {
912                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
913                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
914                                 }
915                         }
916                         fclose(fd);
917                 }
918         }
919
920         WeaponStats_Init();
921
922         Nagger_Init();
923
924         next_pingtime = time + 5;
925
926         // set up information replies for clients and server to use
927         maplist_reply = strzone(getmaplist());
928         lsmaps_reply = strzone(getlsmaps());
929         monsterlist_reply = strzone(getmonsterlist());
930         for(int i = 0; i < 10; ++i)
931         {
932                 string s = getrecords(i);
933                 if (s)
934                         records_reply[i] = strzone(s);
935         }
936         ladder_reply = strzone(getladder());
937         rankings_reply = strzone(getrankings());
938
939         // begin other init
940         ClientInit_Spawn();
941         RandomSeed_Spawn();
942         PingPLReport_Spawn();
943
944         CheatInit();
945
946         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
947
948         // fill sv_curl_serverpackages from .serverpackage files
949         if (autocvar_sv_curl_serverpackages_auto)
950         {
951                 string s = "csprogs-" WATERMARK ".txt";
952                 // remove automatically managed files from the list to prevent duplicates
953                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
954                 {
955                         string pkg = argv(i);
956                         if (startsWith(pkg, "csprogs-")) continue;
957                         if (endsWith(pkg, "-serverpackage.txt")) continue;
958                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
959                         s = cons(s, pkg);
960                 }
961                 // add automatically managed files to the list
962                 #define X(match) MACRO_BEGIN \
963                         int fd = search_begin(match, true, false); \
964                         if (fd >= 0) \
965                         { \
966                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
967                                 { \
968                                         s = cons(s, search_getfilename(fd, i)); \
969                                 } \
970                                 search_end(fd); \
971                         } \
972                 MACRO_END
973                 X("*-serverpackage.txt");
974                 X("*.serverpackage");
975                 #undef X
976                 cvar_set("sv_curl_serverpackages", s);
977         }
978
979         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
980         modname = "Xonotic";
981         // physics/balance/config changes that count as mod
982         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
983                 modname = cvar_string("g_mod_physics");
984         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
985                 modname = cvar_string("g_mod_balance");
986         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
987                 modname = cvar_string("g_mod_config");
988         // extra mutators that deserve to count as mod
989         MUTATOR_CALLHOOK(SetModname, modname);
990         modname = M_ARGV(0, string);
991
992         // save it for later
993         modname = strzone(modname);
994
995         WinningConditionHelper(this); // set worldstatus
996
997         world_initialized = 1;
998         __spawnfunc_spawn_all();
999 }
1000
1001 spawnfunc(light)
1002 {
1003         //makestatic (this); // Who the f___ did that?
1004         delete(this);
1005 }
1006
1007 string GetGametype()
1008 {
1009         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1010 }
1011
1012 string GetMapname()
1013 {
1014         return mapname;
1015 }
1016
1017 float Map_Count, Map_Current;
1018 string Map_Current_Name;
1019
1020 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1021 int GetMaplistPosition()
1022 {
1023         string map = GetMapname();
1024         int idx = autocvar_g_maplist_index;
1025
1026         if(idx >= 0)
1027         {
1028                 if(idx < Map_Count)
1029                 {
1030                         if(map == argv(idx))
1031                         {
1032                                 return idx;
1033                         }
1034                 }
1035         }
1036
1037         for(int pos = 0; pos < Map_Count; ++pos)
1038         {
1039                 if(map == argv(pos))
1040                         return pos;
1041         }
1042
1043         // resume normal maplist rotation if current map is not in g_maplist
1044         return idx;
1045 }
1046
1047 bool MapHasRightSize(string map)
1048 {
1049         int minplayers = max(0, floor(autocvar_minplayers));
1050         if (teamplay)
1051                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1052         if (autocvar_g_maplist_check_waypoints
1053                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1054         {
1055                 string checkwp_msg = strcat("checkwp ", map);
1056                 if(!fexists(strcat("maps/", map, ".waypoints")))
1057                 {
1058                         LOG_TRACE(checkwp_msg, ": no waypoints");
1059                         return false;
1060                 }
1061                 LOG_TRACE(checkwp_msg, ": has waypoints");
1062         }
1063
1064         if(autocvar_g_maplist_ignore_sizes)
1065                 return true;
1066
1067         // open map size restriction file
1068         string opensize_msg = strcat("opensize ", map);
1069         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1070         int pcount = player_count;
1071         if(!autocvar_g_maplist_sizes_count_bots)
1072                 pcount -= currentbots;
1073         if(fh >= 0)
1074         {
1075                 opensize_msg = strcat(opensize_msg, ": ok, ");
1076                 int mapmin = stoi(fgets(fh));
1077                 int mapmax = stoi(fgets(fh));
1078                 fclose(fh);
1079                 if(pcount < mapmin)
1080                 {
1081                         LOG_TRACE(opensize_msg, "not enough");
1082                         return false;
1083                 }
1084                 if(mapmax && pcount > mapmax)
1085                 {
1086                         LOG_TRACE(opensize_msg, "too many");
1087                         return false;
1088                 }
1089                 LOG_TRACE(opensize_msg, "right size");
1090                 return true;
1091         }
1092         LOG_TRACE(opensize_msg, ": not found");
1093         return true;
1094 }
1095
1096 string Map_Filename(float position)
1097 {
1098         return strcat("maps/", argv(position), ".bsp");
1099 }
1100
1101 void Map_MarkAsRecent(string m)
1102 {
1103         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1104 }
1105
1106 float Map_IsRecent(string m)
1107 {
1108         return strhasword(autocvar_g_maplist_mostrecent, m);
1109 }
1110
1111 float Map_Check(float position, float pass)
1112 {
1113         string filename;
1114         string map_next;
1115         map_next = argv(position);
1116         if(pass <= 1)
1117         {
1118                 if(Map_IsRecent(map_next))
1119                         return 0;
1120         }
1121         filename = Map_Filename(position);
1122         if(MapInfo_CheckMap(map_next))
1123         {
1124                 if(pass == 2)
1125                         return 1;
1126                 if(MapHasRightSize(map_next))
1127                         return 1;
1128                 return 0;
1129         }
1130         else
1131                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1132
1133         return 0;
1134 }
1135
1136 void Map_Goto_SetStr(string nextmapname)
1137 {
1138         if(getmapname_stored != "")
1139                 strunzone(getmapname_stored);
1140         if(nextmapname == "")
1141                 getmapname_stored = "";
1142         else
1143                 getmapname_stored = strzone(nextmapname);
1144 }
1145
1146 void Map_Goto_SetFloat(float position)
1147 {
1148         cvar_set("g_maplist_index", ftos(position));
1149         Map_Goto_SetStr(argv(position));
1150 }
1151
1152 void Map_Goto(float reinit)
1153 {
1154         MapInfo_LoadMap(getmapname_stored, reinit);
1155 }
1156
1157 // return codes of map selectors:
1158 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1159 //   -2 = permanent failure
1160 float MaplistMethod_Iterate() // usual method
1161 {
1162         float pass, i;
1163
1164         LOG_TRACE("Trying MaplistMethod_Iterate");
1165
1166         for(pass = 1; pass <= 2; ++pass)
1167         {
1168                 for(i = 1; i < Map_Count; ++i)
1169                 {
1170                         float mapindex;
1171                         mapindex = (i + Map_Current) % Map_Count;
1172                         if(Map_Check(mapindex, pass))
1173                                 return mapindex;
1174                 }
1175         }
1176         return -1;
1177 }
1178
1179 float MaplistMethod_Repeat() // fallback method
1180 {
1181         LOG_TRACE("Trying MaplistMethod_Repeat");
1182
1183         if(Map_Check(Map_Current, 2))
1184                 return Map_Current;
1185         return -2;
1186 }
1187
1188 float MaplistMethod_Random() // random map selection
1189 {
1190         float i, imax;
1191
1192         LOG_TRACE("Trying MaplistMethod_Random");
1193
1194         imax = 42;
1195
1196         for(i = 0; i <= imax; ++i)
1197         {
1198                 float mapindex;
1199                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1200                 if(Map_Check(mapindex, 1))
1201                         return mapindex;
1202         }
1203         return -1;
1204 }
1205
1206 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1207 // the exponent sets a bias on the map selection:
1208 // the higher the exponent, the less likely "shortly repeated" same maps are
1209 {
1210         float i, j, imax, insertpos;
1211
1212         LOG_TRACE("Trying MaplistMethod_Shuffle");
1213
1214         imax = 42;
1215
1216         for(i = 0; i <= imax; ++i)
1217         {
1218                 string newlist;
1219
1220                 // now reinsert this at another position
1221                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1222                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1223                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1224                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1225
1226                 // insert the current map there
1227                 newlist = "";
1228                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1229                         newlist = strcat(newlist, " ", argv(j));
1230                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1231                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1232                         newlist = strcat(newlist, " ", argv(j));
1233                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1234                 cvar_set("g_maplist", newlist);
1235                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1236
1237                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1238                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1239                 if(Map_Check(Map_Current, 1))
1240                         return Map_Current;
1241         }
1242         return -1;
1243 }
1244
1245 void Maplist_Init()
1246 {
1247         float i = Map_Count = 0;
1248         if(autocvar_g_maplist != "")
1249         {
1250                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1251                 for (i = 0; i < Map_Count; ++i)
1252                 {
1253                         if (Map_Check(i, 2))
1254                                 break;
1255                 }
1256         }
1257         
1258         if (i == Map_Count)
1259         {
1260                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1261                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1262                 if(autocvar_g_maplist_shuffle)
1263                         ShuffleMaplist();
1264                 if(!server_is_dedicated)
1265                         localcmd("\nmenu_cmd sync\n");
1266                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1267         }
1268         if(Map_Count == 0)
1269                 error("empty maplist, cannot select a new map");
1270         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1271
1272         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1273         // this may or may not be correct, but who cares, in the worst case a map
1274         // isn't chosen in the first pass that should have been
1275 }
1276
1277 string GetNextMap()
1278 {
1279         Maplist_Init();
1280         float nextMap = -1;
1281
1282         if(nextMap == -1)
1283                 if(autocvar_g_maplist_shuffle > 0)
1284                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1285
1286         if(nextMap == -1)
1287                 if(autocvar_g_maplist_selectrandom)
1288                         nextMap = MaplistMethod_Random();
1289
1290         if(nextMap == -1)
1291                 nextMap = MaplistMethod_Iterate();
1292
1293         if(nextMap == -1)
1294                 nextMap = MaplistMethod_Repeat();
1295
1296         if(nextMap >= 0)
1297         {
1298                 Map_Goto_SetFloat(nextMap);
1299                 return getmapname_stored;
1300         }
1301
1302         return "";
1303 }
1304
1305 float DoNextMapOverride(float reinit)
1306 {
1307         if(autocvar_g_campaign)
1308         {
1309                 CampaignPostIntermission();
1310                 alreadychangedlevel = true;
1311                 return true;
1312         }
1313         if(autocvar_quit_when_empty)
1314         {
1315                 if(player_count <= currentbots)
1316                 {
1317                         localcmd("quit\n");
1318                         alreadychangedlevel = true;
1319                         return true;
1320                 }
1321         }
1322         if(autocvar_quit_and_redirect != "")
1323         {
1324                 redirection_target = strzone(autocvar_quit_and_redirect);
1325                 alreadychangedlevel = true;
1326                 return true;
1327         }
1328         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1329         {
1330                 localcmd("restart\n");
1331                 alreadychangedlevel = true;
1332                 return true;
1333         }
1334         if(autocvar_nextmap != "")
1335         {
1336                 string m;
1337                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1338                 cvar_set("nextmap",m);
1339
1340                 if(!m || gametypevote)
1341                         return false;
1342                 if(autocvar_sv_vote_gametype)
1343                 {
1344                         Map_Goto_SetStr(m);
1345                         return false;
1346                 }
1347
1348                 if(MapInfo_CheckMap(m))
1349                 {
1350                         Map_Goto_SetStr(m);
1351                         Map_Goto(reinit);
1352                         alreadychangedlevel = true;
1353                         return true;
1354                 }
1355         }
1356         if(!reinit && autocvar_lastlevel)
1357         {
1358                 cvar_settemp_restore();
1359                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1360                 alreadychangedlevel = true;
1361                 return true;
1362         }
1363         return false;
1364 }
1365
1366 void GotoNextMap(float reinit)
1367 {
1368         //string nextmap;
1369         //float n, nummaps;
1370         //string s;
1371         if (alreadychangedlevel)
1372                 return;
1373         alreadychangedlevel = true;
1374
1375         string nextMap = GetNextMap();
1376         if(nextMap == "")
1377                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1378         Map_Goto(reinit);
1379 }
1380
1381
1382 /*
1383 ============
1384 IntermissionThink
1385
1386 When the player presses attack or jump, change to the next level
1387 ============
1388 */
1389 .float autoscreenshot;
1390 void IntermissionThink(entity this)
1391 {
1392         FixIntermissionClient(this);
1393
1394         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1395         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1396
1397         if( (server_screenshot || client_screenshot)
1398                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1399         {
1400                 this.autoscreenshot = -1;
1401                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1402                 return;
1403         }
1404
1405         if (time < intermission_exittime)
1406                 return;
1407
1408         if(!mapvote_initialized)
1409                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1410                         return;
1411
1412         MapVote_Start();
1413 }
1414
1415 /*
1416 ============
1417 FindIntermission
1418
1419 Returns the entity to view from
1420 ============
1421 */
1422 /*
1423 entity FindIntermission()
1424 {
1425         local   entity spot;
1426         local   float cyc;
1427
1428 // look for info_intermission first
1429         spot = find(NULL, classname, "info_intermission");
1430         if (spot)
1431         {       // pick a random one
1432                 cyc = random() * 4;
1433                 while (cyc > 1)
1434                 {
1435                         spot = find(spot, classname, "info_intermission");
1436                         if (!spot)
1437                                 spot = find(spot, classname, "info_intermission");
1438                         cyc = cyc - 1;
1439                 }
1440                 return spot;
1441         }
1442
1443 // then look for the start position
1444         spot = find(NULL, classname, "info_player_start");
1445         if (spot)
1446                 return spot;
1447
1448 // testinfo_player_start is only found in regioned levels
1449         spot = find(NULL, classname, "testplayerstart");
1450         if (spot)
1451                 return spot;
1452
1453 // then look for the start position
1454         spot = find(NULL, classname, "info_player_deathmatch");
1455         if (spot)
1456                 return spot;
1457
1458         //objerror ("FindIntermission: no spot");
1459         return NULL;
1460 }
1461 */
1462
1463 /*
1464 ===============================================================================
1465
1466 RULES
1467
1468 ===============================================================================
1469 */
1470
1471 void DumpStats(float final)
1472 {
1473         float file;
1474         string s;
1475         float to_console;
1476         float to_eventlog;
1477         float to_file;
1478         float i;
1479
1480         to_console = autocvar_sv_logscores_console;
1481         to_eventlog = autocvar_sv_eventlog;
1482         to_file = autocvar_sv_logscores_file;
1483
1484         if(!final)
1485         {
1486                 to_console = true; // always print printstats replies
1487                 to_eventlog = false; // but never print them to the event log
1488         }
1489
1490         if(to_eventlog)
1491                 if(autocvar_sv_eventlog_console)
1492                         to_console = false; // otherwise we get the output twice
1493
1494         if(final)
1495                 s = ":scores:";
1496         else
1497                 s = ":status:";
1498         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1499
1500         if(to_console)
1501                 LOG_INFO(s);
1502         if(to_eventlog)
1503                 GameLogEcho(s);
1504
1505         file = -1;
1506         if(to_file)
1507         {
1508                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1509                 if(file == -1)
1510                         to_file = false;
1511                 else
1512                         fputs(file, strcat(s, "\n"));
1513         }
1514
1515         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1516         if(to_console)
1517                 LOG_INFO(s);
1518         if(to_eventlog)
1519                 GameLogEcho(s);
1520         if(to_file)
1521                 fputs(file, strcat(s, "\n"));
1522
1523         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1524                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1525                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1526                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1527                         s = strcat(s, ftos(it.team), ":");
1528                 else
1529                         s = strcat(s, "spectator:");
1530
1531                 if(to_console)
1532                         LOG_INFO(s, playername(it, false));
1533                 if(to_eventlog)
1534                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1535                 if(to_file)
1536                         fputs(file, strcat(s, playername(it, false), "\n"));
1537         });
1538
1539         if(teamplay)
1540         {
1541                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1542                 if(to_console)
1543                         LOG_INFO(s);
1544                 if(to_eventlog)
1545                         GameLogEcho(s);
1546                 if(to_file)
1547                         fputs(file, strcat(s, "\n"));
1548
1549                 for(i = 1; i < 16; ++i)
1550                 {
1551                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1552                         s = strcat(s, ":", ftos(i));
1553                         if(to_console)
1554                                 LOG_INFO(s);
1555                         if(to_eventlog)
1556                                 GameLogEcho(s);
1557                         if(to_file)
1558                                 fputs(file, strcat(s, "\n"));
1559                 }
1560         }
1561
1562         if(to_console)
1563                 LOG_INFO(":end");
1564         if(to_eventlog)
1565                 GameLogEcho(":end");
1566         if(to_file)
1567         {
1568                 fputs(file, ":end\n");
1569                 fclose(file);
1570         }
1571 }
1572
1573 void FixIntermissionClient(entity e)
1574 {
1575         if(!e.autoscreenshot) // initial call
1576         {
1577                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1578                 SetResourceExplicit(e, RES_HEALTH, -2342);
1579                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1580                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1581                 {
1582                     .entity weaponentity = weaponentities[slot];
1583                         if(e.(weaponentity))
1584                         {
1585                                 e.(weaponentity).effects = EF_NODRAW;
1586                                 if (e.(weaponentity).weaponchild)
1587                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1588                         }
1589                 }
1590                 if(IS_REAL_CLIENT(e))
1591                 {
1592                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1593                         RandomSelection_Init();
1594                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1595                                 RandomSelection_AddString(it, 1, 1);
1596                         });
1597                         if (RandomSelection_chosen_string != "")
1598                         {
1599                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1600                         }
1601                         msg_entity = e;
1602                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1603                 }
1604         }
1605 }
1606
1607 /*
1608 go to the next level for deathmatch
1609 only called if a time or frag limit has expired
1610 */
1611 void NextLevel()
1612 {
1613         game_stopped = true;
1614         intermission_running = 1; // game over
1615
1616         // enforce a wait time before allowing changelevel
1617         if(player_count > 0)
1618                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1619         else
1620                 intermission_exittime = -1;
1621
1622         /*
1623         WriteByte (MSG_ALL, SVC_CDTRACK);
1624         WriteByte (MSG_ALL, 3);
1625         WriteByte (MSG_ALL, 3);
1626         // done in FixIntermission
1627         */
1628
1629         //pos = FindIntermission ();
1630
1631         VoteReset();
1632
1633         DumpStats(true);
1634
1635         // send statistics
1636         PlayerStats_GameReport(true);
1637         WeaponStats_Shutdown();
1638
1639         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1640
1641         if(autocvar_sv_eventlog)
1642                 GameLogEcho(":gameover");
1643
1644         GameLogClose();
1645
1646         FOREACH_CLIENT(IS_PLAYER(it), {
1647                 FixIntermissionClient(it);
1648                 if(it.winning)
1649                         bprint(playername(it, false), " ^7wins.\n");
1650         });
1651
1652         target_music_kill();
1653
1654         if(autocvar_g_campaign)
1655                 CampaignPreIntermission();
1656
1657         MUTATOR_CALLHOOK(MatchEnd);
1658
1659         localcmd("\nsv_hook_gameend\n");
1660 }
1661
1662
1663 float InitiateSuddenDeath()
1664 {
1665         // Check first whether normal overtimes could be added before initiating suddendeath mode
1666         // - for this timelimit_overtime needs to be >0 of course
1667         // - also check the winning condition calculated in the previous frame and only add normal overtime
1668         //   again, if at the point at which timelimit would be extended again, still no winner was found
1669         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1670                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1671                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1672         {
1673                 return 1; // need to call InitiateOvertime later
1674         }
1675         else
1676         {
1677                 if(!checkrules_suddendeathend)
1678                 {
1679                         if(autocvar_g_campaign)
1680                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1681                         else
1682                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1683                         if(g_race && !g_race_qualifying)
1684                                 race_StartCompleting();
1685                 }
1686                 return 0;
1687         }
1688 }
1689
1690 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1691 {
1692         ++checkrules_overtimesadded;
1693         //add one more overtime by simply extending the timelimit
1694         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1695         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1696 }
1697
1698 float GetWinningCode(float fraglimitreached, float equality)
1699 {
1700         if(autocvar_g_campaign == 1)
1701         {
1702                 if(fraglimitreached)
1703                         return WINNING_YES;
1704                 else
1705                         return WINNING_NO;
1706         }
1707         else
1708         {
1709                 if(equality)
1710                 {
1711                         if(fraglimitreached)
1712                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1713                         else
1714                                 return WINNING_NEVER;
1715                 }
1716                 else
1717                 {
1718                         if(fraglimitreached)
1719                                 return WINNING_YES;
1720                         else
1721                                 return WINNING_NO;
1722                 }
1723         }
1724 }
1725
1726 // set the .winning flag for exactly those players with a given field value
1727 void SetWinners(.float field, float value)
1728 {
1729         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1730 }
1731
1732 // set the .winning flag for those players with a given field value
1733 void AddWinners(.float field, float value)
1734 {
1735         FOREACH_CLIENT(IS_PLAYER(it), {
1736                 if(it.(field) == value)
1737                         it.winning = 1;
1738         });
1739 }
1740
1741 // clear the .winning flags
1742 void ClearWinners()
1743 {
1744         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1745 }
1746
1747 void ShuffleMaplist()
1748 {
1749         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1750 }
1751
1752 float leaderfrags;
1753 float WinningCondition_Scores(float limit, float leadlimit)
1754 {
1755         float limitreached;
1756
1757         // TODO make everything use THIS winning condition (except LMS)
1758         WinningConditionHelper(NULL);
1759
1760         if(teamplay)
1761         {
1762                 for (int i = 1; i < 5; ++i)
1763                 {
1764                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1765                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1766                 }
1767         }
1768
1769         ClearWinners();
1770         if(WinningConditionHelper_winner)
1771                 WinningConditionHelper_winner.winning = 1;
1772         if(WinningConditionHelper_winnerteam >= 0)
1773                 SetWinners(team, WinningConditionHelper_winnerteam);
1774
1775         if(WinningConditionHelper_lowerisbetter)
1776         {
1777                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1778                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1779                 limit = -limit;
1780         }
1781
1782         if(WinningConditionHelper_zeroisworst)
1783                 leadlimit = 0; // not supported in this mode
1784
1785         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1786         // these modes always score in increments of 1, thus this makes sense
1787         {
1788                 if(leaderfrags != WinningConditionHelper_topscore)
1789                 {
1790                         leaderfrags = WinningConditionHelper_topscore;
1791
1792                         if (limit)
1793                         {
1794                                 if (leaderfrags == limit - 1)
1795                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1796                                 else if (leaderfrags == limit - 2)
1797                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1798                                 else if (leaderfrags == limit - 3)
1799                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1800                         }
1801                 }
1802         }
1803
1804         limitreached = false;
1805         if (limit && WinningConditionHelper_topscore >= limit)
1806                 limitreached = true;
1807         if(leadlimit)
1808         {
1809                 float leadlimitreached;
1810                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1811                 if(autocvar_leadlimit_and_fraglimit)
1812                         limitreached = (limitreached && leadlimitreached);
1813                 else
1814                         limitreached = (limitreached || leadlimitreached);
1815         }
1816
1817         if(limit)
1818                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1819
1820         return GetWinningCode(
1821                 WinningConditionHelper_topscore && limitreached,
1822                 WinningConditionHelper_equality
1823         );
1824 }
1825
1826 float WinningCondition_RanOutOfSpawns()
1827 {
1828         if(have_team_spawns <= 0)
1829                 return WINNING_NO;
1830
1831         if(!autocvar_g_spawn_useallspawns)
1832                 return WINNING_NO;
1833
1834         if(!some_spawn_has_been_used)
1835                 return WINNING_NO;
1836
1837         for (int i = 1; i < 5; ++i)
1838         {
1839                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1840         }
1841
1842         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1843         {
1844                 if (Team_IsValidTeam(it.team))
1845                 {
1846                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1847                 }
1848         });
1849
1850         IL_EACH(g_spawnpoints, true,
1851         {
1852                 if (Team_IsValidTeam(it.team))
1853                 {
1854                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1855                 }
1856         });
1857
1858         ClearWinners();
1859         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1860         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1861         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1862         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1863         if(team1_score + team2_score + team3_score + team4_score == 0)
1864         {
1865                 checkrules_equality = true;
1866                 return WINNING_YES;
1867         }
1868         else if(team1_score + team2_score + team3_score + team4_score == 1)
1869         {
1870                 float t, i;
1871                 if(team1_score)
1872                         t = 1;
1873                 else if(team2_score)
1874                         t = 2;
1875                 else if(team3_score)
1876                         t = 3;
1877                 else // if(team4_score)
1878                         t = 4;
1879                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1880                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1881                 {
1882                         for (int j = 1; j <= NUM_TEAMS; ++j)
1883                         {
1884                                 if (t == j)
1885                                 {
1886                                         continue;
1887                                 }
1888                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1889                                 {
1890                                         continue;
1891                                 }
1892                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1893                         }
1894                 }
1895
1896                 AddWinners(team, t);
1897                 return WINNING_YES;
1898         }
1899         else
1900                 return WINNING_NO;
1901 }
1902
1903 /*
1904 ============
1905 CheckRules_World
1906
1907 Exit deathmatch games upon conditions
1908 ============
1909 */
1910 void CheckRules_World()
1911 {
1912         float timelimit;
1913         float fraglimit;
1914         float leadlimit;
1915
1916         VoteThink();
1917         MapVote_Think();
1918
1919         SetDefaultAlpha();
1920
1921         if (intermission_running) // someone else quit the game already
1922         {
1923                 if(player_count == 0) // Nobody there? Then let's go to the next map
1924                         MapVote_Start();
1925                         // this will actually check the player count in the next frame
1926                         // again, but this shouldn't hurt
1927                 return;
1928         }
1929
1930         timelimit = autocvar_timelimit * 60;
1931         fraglimit = autocvar_fraglimit;
1932         leadlimit = autocvar_leadlimit;
1933
1934         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1935         {
1936                 if(timelimit > 0)
1937                         timelimit = 0; // timelimit is not made for warmup
1938                 if(fraglimit > 0)
1939                         fraglimit = 0; // no fraglimit for now
1940                 leadlimit = 0; // no leadlimit for now
1941         }
1942
1943         if(timelimit > 0)
1944         {
1945                 timelimit += game_starttime;
1946         }
1947         else if (timelimit < 0)
1948         {
1949                 // endmatch
1950                 NextLevel();
1951                 return;
1952         }
1953
1954         float wantovertime;
1955         wantovertime = 0;
1956
1957         if(timelimit > game_starttime)
1958                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1959         else
1960                 game_completion_ratio = 0;
1961
1962         if(checkrules_suddendeathend)
1963         {
1964                 if(!checkrules_suddendeathwarning)
1965                 {
1966                         checkrules_suddendeathwarning = true;
1967                         if(g_race && !g_race_qualifying)
1968                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1969                         else
1970                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1971                 }
1972         }
1973         else
1974         {
1975                 if (timelimit && time >= timelimit)
1976                 {
1977                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1978                         {
1979                                 float totalplayers;
1980                                 float playerswithlaps;
1981                                 float readyplayers;
1982                                 totalplayers = playerswithlaps = readyplayers = 0;
1983                                 FOREACH_CLIENT(IS_PLAYER(it), {
1984                                         ++totalplayers;
1985                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1986                                                 ++playerswithlaps;
1987                                         if(it.ready)
1988                                                 ++readyplayers;
1989                                 });
1990
1991                                 // at least 2 of the players have completed a lap: start the RACE
1992                                 // otherwise, the players should end the qualifying on their own
1993                                 if(readyplayers || playerswithlaps >= 2)
1994                                 {
1995                                         checkrules_suddendeathend = 0;
1996                                         ReadyRestart(); // go to race
1997                                         return;
1998                                 }
1999                                 else
2000                                         wantovertime |= InitiateSuddenDeath();
2001                         }
2002                         else
2003                                 wantovertime |= InitiateSuddenDeath();
2004                 }
2005         }
2006
2007         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2008         {
2009                 NextLevel();
2010                 return;
2011         }
2012
2013         int checkrules_status = WinningCondition_RanOutOfSpawns();
2014         if(checkrules_status == WINNING_YES)
2015                 bprint("Hey! Someone ran out of spawns!\n");
2016         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
2017                 checkrules_status = M_ARGV(0, float);
2018         else
2019                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2020
2021         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2022         {
2023                 checkrules_status = WINNING_NEVER;
2024                 checkrules_overtimesadded = -1;
2025                 wantovertime |= InitiateSuddenDeath();
2026         }
2027
2028         if(checkrules_status == WINNING_NEVER)
2029                 // equality cases! Nobody wins if the overtime ends in a draw.
2030                 ClearWinners();
2031
2032         if(wantovertime)
2033         {
2034                 if(checkrules_status == WINNING_NEVER)
2035                         InitiateOvertime();
2036                 else
2037                         checkrules_status = WINNING_YES;
2038         }
2039
2040         if(checkrules_suddendeathend)
2041                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2042                         checkrules_status = WINNING_YES;
2043
2044         if(checkrules_status == WINNING_YES)
2045         {
2046                 //print("WINNING\n");
2047                 NextLevel();
2048         }
2049 }
2050
2051 string GotoMap(string m)
2052 {
2053         m = GameTypeVote_MapInfo_FixName(m);
2054         if (!m)
2055                 return "The map you suggested is not available on this server.";
2056         if (!autocvar_sv_vote_gametype)
2057         if(!MapInfo_CheckMap(m))
2058                 return "The map you suggested does not support the current game mode.";
2059         cvar_set("nextmap", m);
2060         cvar_set("timelimit", "-1");
2061         if(mapvote_initialized || alreadychangedlevel)
2062         {
2063                 if(DoNextMapOverride(0))
2064                         return "Map switch initiated.";
2065                 else
2066                         return "Hm... no. For some reason I like THIS map more.";
2067         }
2068         else
2069                 return "Map switch will happen after scoreboard.";
2070 }
2071
2072 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2073 void RunThink(entity this)
2074 {
2075         // don't let things stay in the past.
2076         // it is possible to start that way by a trigger with a local time.
2077         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2078                 return;
2079
2080         float oldtime = time; // do we need to save this?
2081
2082         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2083         {
2084                 time = max(oldtime, this.nextthink);
2085                 this.nextthink = 0;
2086
2087                 if(getthink(this))
2088                         getthink(this)(this);
2089                 // mods often set nextthink to time to cause a think every frame,
2090                 // we don't want to loop in that case, so exit if the new nextthink is
2091                 // <= the time the qc was told, also exit if it is past the end of the
2092                 // frame
2093                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2094                         break;
2095         }
2096
2097         time = oldtime;
2098 }
2099
2100 bool autocvar_sv_freezenonclients;
2101 bool autocvar_sv_gameplayfix_delayprojectiles = false;
2102 void Physics_Frame()
2103 {
2104         if(autocvar_sv_freezenonclients)
2105                 return;
2106
2107         FOREACH_ENTITY_FLOAT(pure_data, false,
2108         {
2109                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2110                         continue;
2111
2112                 //set_movetype(it, it.move_movetype);
2113                 // inline the set_movetype function, since this is called a lot
2114                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2115
2116                 if(it.move_movetype == MOVETYPE_NONE)
2117                         continue;
2118
2119                 if(it.move_qcphysics)
2120                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2121
2122                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2123                 {
2124                         // handle thinking here
2125                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2126                                 RunThink(it);
2127                 }
2128         });
2129
2130         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2131                 return;
2132
2133         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2134         {
2135                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2136                         continue;
2137                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2138         });
2139 }
2140
2141 void systems_update();
2142 void EndFrame()
2143 {
2144         anticheat_endframe();
2145
2146         Physics_Frame();
2147
2148         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2149                 entity e = IS_SPEC(it) ? it.enemy : it;
2150                 if (e.typehitsound) {
2151                         STAT(TYPEHIT_TIME, it) = time;
2152                 } else if (e.killsound) {
2153                         STAT(KILL_TIME, it) = time;
2154                 } else if (e.damage_dealt) {
2155                         STAT(HIT_TIME, it) = time;
2156                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2157                 }
2158         });
2159         // add 1 frametime because after this, engine SV_Physics
2160         // increases time by a frametime and then networks the frame
2161         // add another frametime because client shows everything with
2162         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2163         // needed!
2164         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2165         FOREACH_CLIENT(true, {
2166                 it.typehitsound = false;
2167                 it.damage_dealt = 0;
2168                 it.killsound = false;
2169                 antilag_record(it, CS(it), altime);
2170         });
2171         IL_EACH(g_monsters, true,
2172         {
2173                 antilag_record(it, it, altime);
2174         });
2175         IL_EACH(g_projectiles, it.classname == "nade",
2176         {
2177                 antilag_record(it, it, altime);
2178         });
2179         systems_update();
2180         IL_ENDFRAME();
2181 }
2182
2183
2184 /*
2185  * RedirectionThink:
2186  * returns true if redirecting
2187  */
2188 float redirection_timeout;
2189 float redirection_nextthink;
2190 float RedirectionThink()
2191 {
2192         float clients_found;
2193
2194         if(redirection_target == "")
2195                 return false;
2196
2197         if(!redirection_timeout)
2198         {
2199                 cvar_set("sv_public", "-2");
2200                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2201                 if(redirection_target == "self")
2202                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2203                 else
2204                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2205         }
2206
2207         if(time < redirection_nextthink)
2208                 return true;
2209
2210         redirection_nextthink = time + 1;
2211
2212         clients_found = 0;
2213         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2214                 // TODO add timer
2215                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2216                 if(redirection_target == "self")
2217                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2218                 else
2219                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2220                 ++clients_found;
2221         });
2222
2223         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2224
2225         if(time > redirection_timeout || clients_found == 0)
2226                 localcmd("\nwait; wait; wait; quit\n");
2227
2228         return true;
2229 }
2230
2231 void RestoreGame()
2232 {
2233         // Loaded from a save game
2234         // some things then break, so let's work around them...
2235
2236         // Progs DB (capture records)
2237         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2238
2239         // Mapinfo
2240         MapInfo_Shutdown();
2241         MapInfo_Enumerate();
2242         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2243         WeaponStats_Init();
2244
2245         TargetMusic_RestoreGame();
2246 }
2247
2248 void Shutdown()
2249 {
2250         game_stopped = 2;
2251
2252         if(world_initialized > 0)
2253         {
2254                 world_initialized = 0;
2255                 LOG_TRACE("Saving persistent data...");
2256                 Ban_SaveBans();
2257
2258                 // playerstats with unfinished match
2259                 PlayerStats_GameReport(false);
2260
2261                 if(!cheatcount_total)
2262                 {
2263                         if(autocvar_sv_db_saveasdump)
2264                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2265                         else
2266                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2267                 }
2268                 if(autocvar_developer > 0)
2269                 {
2270                         if(autocvar_sv_db_saveasdump)
2271                                 db_dump(TemporaryDB, "server-temp.db");
2272                         else
2273                                 db_save(TemporaryDB, "server-temp.db");
2274                 }
2275                 CheatShutdown(); // must be after cheatcount check
2276                 db_close(ServerProgsDB);
2277                 db_close(TemporaryDB);
2278                 LOG_TRACE("Saving persistent data... done!");
2279                 // tell the bot system the game is ending now
2280                 bot_endgame();
2281
2282                 WeaponStats_Shutdown();
2283                 MapInfo_Shutdown();
2284         }
2285         else if(world_initialized == 0)
2286         {
2287                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2288         }
2289         else
2290         {
2291                 __init_dedicated_server_shutdown();
2292         }
2293 }