qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADCVAR("welcome_message_time");
 327                 BADPREFIX("crypto_");
 328                 BADPREFIX("g_chat_");
 329                 BADPREFIX("g_ctf_captimerecord_");
 330                 BADPREFIX("g_maplist_votable_");
 331                 BADPREFIX("net_");
 332                 BADPREFIX("prvm_");
 333                 BADPREFIX("skill_");
 334                 BADPREFIX("sv_cullentities_");
 335                 BADPREFIX("sv_fraginfo_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_namechangetimer");
 342
 343                 // allowed changes to server admins (please sync this to server.cfg)
 344                 // vi commands:
 345                 //   :/"impure"/,$d
 346                 //   :g!,^\/\/[^ /],d
 347                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 348                 //   :%!sort
 349                 // yes, this does contain some redundant stuff, don't really care
 350                 BADCVAR("bot_config_file");
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_prevent_imbalance");
 360                 BADCVAR("g_balance_teams_scorefactor");
 361                 BADCVAR("g_ban_sync_trusted_servers");
 362                 BADCVAR("g_ban_sync_uri");
 363                 BADCVAR("g_ca_teams_override");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_freezetag_teams_override");
 367                 BADCVAR("g_friendlyfire");
 368                 BADCVAR("g_fullbrightitems");
 369                 BADCVAR("g_fullbrightplayers");
 370                 BADCVAR("g_keyhunt_point_limit");
 371                 BADCVAR("g_keyhunt_teams_override");
 372                 BADCVAR("g_lms_lives_override");
 373                 BADCVAR("g_maplist");
 374                 BADCVAR("g_maplist_check_waypoints");
 375                 BADCVAR("g_maplist_mostrecent_count");
 376                 BADCVAR("g_maplist_shuffle");
 377                 BADCVAR("g_maplist_votable");
 378                 BADCVAR("g_maplist_votable_abstain");
 379                 BADCVAR("g_maplist_votable_nodetail");
 380                 BADCVAR("g_maplist_votable_suggestions");
 381                 BADCVAR("g_maxplayers");
 382                 BADCVAR("g_mirrordamage");
 383                 BADCVAR("g_nexball_goallimit");
 384                 BADCVAR("g_powerups");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("teamplay_mode");
 421                 BADCVAR("timelimit_override");
 422                 BADCVAR("g_spawnshieldtime");
 423                 BADPREFIX("g_warmup_");
 424                 BADPREFIX("sv_ready_restart_");
 425
 426                 // mutators that announce themselves properly to the server browser
 427                 BADCVAR("g_minstagib");
 428                 BADCVAR("g_new_toys");
 429                 BADCVAR("g_nix");
 430                 BADCVAR("g_grappling_hook");
 431                 BADCVAR("g_jetpack");
 432
 433 #undef BADPREFIX
 434 #undef BADCVAR
 435
 436                 if(pureadding)
 437                 {
 438                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 439                         if(strlen(cvar_purechanges) > 16384)
 440                         {
 441                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 442                                 pureadding = 0;
 443                         }
 444                 }
 445                 ++cvar_purechanges_count;
 446                 // WARNING: this variable is used for the server list
 447                 // NEVER dare to skip this code!
 448                 // Hacks to intentionally appearing as "pure server" even though you DO have
 449                 // modified settings may be punished by removal from the server list.
 450                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 451                 // though.
 452         }
 453         buf_del(h);
 454         if(cvar_changes == "")
 455                 cvar_changes = "// this server runs at default server settings\n";
 456         else
 457                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 458         cvar_changes = strzone(cvar_changes);
 459         if(cvar_purechanges == "")
 460                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 461         else
 462                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 463         cvar_purechanges = strzone(cvar_purechanges);
 464 }
 465
 466 void detect_maptype()
 467 {
 468 #if 0
 469         vector o, v;
 470         float i;
 471
 472         for(;;)
 473         {
 474                 o = world.mins;
 475                 o_x += random() * (world.maxs_x - world.mins_x);
 476                 o_y += random() * (world.maxs_y - world.mins_y);
 477                 o_z += random() * (world.maxs_z - world.mins_z);
 478
 479                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 480                 if(trace_fraction == 1)
 481                         continue;
 482
 483                 v = trace_endpos;
 484
 485                 for(i = 0; i < 64; i += 4)
 486                 {
 487                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 488         if(trace_fraction == 1)
 489                 continue;
 490                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 491                 }
 492
 493                 break;
 494         }
 495 #endif
 496 }
 497
 498 entity randomseed;
 499 float RandomSeed_Send(entity to, float sf)
 500 {
 501         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 502         WriteShort(MSG_ENTITY, self.cnt);
 503         return TRUE;
 504 }
 505 void RandomSeed_Think()
 506 {
 507         self.cnt = bound(0, floor(random() * 65536), 65535);
 508         self.nextthink = time + 5;
 509
 510         self.SendFlags |= 1;
 511 }
 512 void RandomSeed_Spawn()
 513 {
 514         randomseed = spawn();
 515         randomseed.think = RandomSeed_Think;
 516         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 517
 518         entity oldself;
 519         oldself = self;
 520         self = randomseed;
 521         self.think(); // sets random seed and nextthink
 522         self = oldself;
 523 }
 524
 525 void spawnfunc___init_dedicated_server(void)
 526 {
 527         // handler for _init/_init map (only for dedicated server initialization)
 528
 529         world_initialized = -1; // don't complain
 530         cvar = cvar_normal;
 531         cvar_string = cvar_string_normal;
 532         cvar_set = cvar_set_normal;
 533
 534         remove = remove_unsafely;
 535
 536         entity e;
 537         e = spawn();
 538         e.think = GotoFirstMap;
 539         e.nextthink = time; // this is usually 1 at this point
 540
 541         e = spawn();
 542         e.classname = "info_player_deathmatch"; // safeguard against player joining
 543
 544         self.classname = "worldspawn"; // safeguard against various stuff ;)
 545
 546         // needs to be done so early because of the constants they create
 547         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 548         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 549         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 550         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 551         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 552
 553         MapInfo_Enumerate();
 554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 555 }
 556
 557 void Map_MarkAsRecent(string m);
 558 float world_already_spawned;
 559 void Nagger_Init();
 560 void ClientInit_Spawn();
 561 void WeaponStats_Init();
 562 void WeaponStats_Shutdown();
 563 void spawnfunc_worldspawn (void)
 564 {
 565         float fd, l, i, j, n;
 566         string s;
 567
 568         cvar = cvar_normal;
 569         cvar_string = cvar_string_normal;
 570         cvar_set = cvar_set_normal;
 571
 572         if(world_already_spawned)
 573                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 574         world_already_spawned = TRUE;
 575
 576         remove = remove_safely; // during spawning, watch what you remove!
 577
 578         check_unacceptable_compiler_bugs();
 579
 580         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 581
 582         compressShortVector_init();
 583
 584         entity head;
 585         head = nextent(world);
 586         maxclients = 0;
 587         while(head)
 588         {
 589                 ++maxclients;
 590                 head = nextent(head);
 591         }
 592
 593         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 594
 595         // needs to be done so early because of the constants they create
 596         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 597         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 598         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 599         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 600         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 601
 602         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 603
 604         TemporaryDB = db_create();
 605
 606         // 0 normal
 607         lightstyle(0, "m");
 608
 609         // 1 FLICKER (first variety)
 610         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 611
 612         // 2 SLOW STRONG PULSE
 613         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 614
 615         // 3 CANDLE (first variety)
 616         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 617
 618         // 4 FAST STROBE
 619         lightstyle(4, "mamamamamama");
 620
 621         // 5 GENTLE PULSE 1
 622         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 623
 624         // 6 FLICKER (second variety)
 625         lightstyle(6, "nmonqnmomnmomomno");
 626
 627         // 7 CANDLE (second variety)
 628         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 629
 630         // 8 CANDLE (third variety)
 631         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 632
 633         // 9 SLOW STROBE (fourth variety)
 634         lightstyle(9, "aaaaaaaazzzzzzzz");
 635
 636         // 10 FLUORESCENT FLICKER
 637         lightstyle(10, "mmamammmmammamamaaamammma");
 638
 639         // 11 SLOW PULSE NOT FADE TO BLACK
 640         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 641
 642         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 643
 644         // 63 testing
 645         lightstyle(63, "a");
 646
 647         if(autocvar_g_campaign)
 648                 CampaignPreInit();
 649
 650         Map_MarkAsRecent(mapname);
 651
 652         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 653
 654         precache_model ("null"); // we need this one before InitGameplayMode
 655         InitGameplayMode();
 656         readlevelcvars();
 657         GrappleHookInit();
 658         ElectroInit();
 659         LaserInit();
 660
 661         player_count = 0;
 662         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 663         if(bot_waypoints_for_items == 1)
 664                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 665                         bot_waypoints_for_items = 0;
 666
 667         precache();
 668
 669         WaypointSprite_Init();
 670
 671         GameLogInit(); // prepare everything
 672         // NOTE for matchid:
 673         // changing the logic generating it is okay. But:
 674         // it HAS to stay <= 64 chars
 675         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 676         if(autocvar_sv_eventlog)
 677         {
 678                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 679                 matchid = strzone(s);
 680
 681                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 682                 s = ":gameinfo:mutators:LIST";
 683
 684                 ret_string = s;
 685                 MUTATOR_CALLHOOK(BuildMutatorsString);
 686                 s = ret_string;
 687
 688                 // simple, probably not good in the mutator system
 689                 if(autocvar_g_grappling_hook)
 690                         s = strcat(s, ":grappling_hook");
 691
 692                 // initialiation stuff, not good in the mutator system
 693                 if(!autocvar_g_use_ammunition)
 694                         s = strcat(s, ":no_use_ammunition");
 695
 696                 // initialiation stuff, not good in the mutator system
 697                 if(autocvar_g_pickup_items == 0)
 698                         s = strcat(s, ":no_pickup_items");
 699                 if(autocvar_g_pickup_items > 0)
 700                         s = strcat(s, ":pickup_items");
 701
 702                 // initialiation stuff, not good in the mutator system
 703                 if(autocvar_g_weaponarena != "0")
 704                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 705
 706                 // TODO to mutator system
 707                 if(autocvar_g_norecoil)
 708                         s = strcat(s, ":norecoil");
 709
 710                 // TODO to mutator system
 711                 if(autocvar_g_powerups == 0)
 712                         s = strcat(s, ":no_powerups");
 713                 if(autocvar_g_powerups > 0)
 714                         s = strcat(s, ":powerups");
 715
 716                 GameLogEcho(s);
 717                 GameLogEcho(":gameinfo:end");
 718         }
 719         else
 720                 matchid = strzone(ftos(random()));
 721
 722         cvar_set("nextmap", "");
 723
 724         SetDefaultAlpha();
 725
 726         if(autocvar_g_campaign)
 727                 CampaignPostInit();
 728
 729         fteqcc_testbugs();
 730
 731         Ban_LoadBans();
 732
 733         MapInfo_Enumerate();
 734         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 735
 736         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 737         {
 738                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 739                 if(fd != -1)
 740                 {
 741                         while((s = fgets(fd)))
 742                         {
 743                                 l = tokenize_console(s);
 744                                 if(l < 2)
 745                                         continue;
 746                                 if(argv(0) == "cd")
 747                                 {
 748                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 749                                         print("  cdtrack ", argv(2), "\n");
 750                                 }
 751                                 else if(argv(0) == "fog")
 752                                 {
 753                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 754                                         print("  \"fog\" \"", s, "\"\n");
 755                                 }
 756                                 else if(argv(0) == "set")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 760                                 }
 761                                 else if(argv(0) != "//")
 762                                 {
 763                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 764                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 765                                 }
 766                         }
 767                         fclose(fd);
 768                 }
 769         }
 770
 771         WeaponStats_Init();
 772
 773         WepSet_AddStat();
 774         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 775         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 776         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 777         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 778         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 779         Nagger_Init();
 780
 781         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 782         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 783         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 784         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 785         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 786         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 787         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 788         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 789         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 790         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 791         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 792         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 793         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 794
 795         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 796         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 797
 798         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 799
 800         // freeze attacks
 801         addstat(STAT_FROZEN, AS_INT, frozen);
 802         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 803
 804         // g_movementspeed hack
 805         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 806         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 807         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 808         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 809
 810         // secrets
 811         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 812         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 813
 814         // monsters
 815         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 816         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 817
 818         // misc
 819         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 820
 821         next_pingtime = time + 5;
 822
 823         detect_maptype();
 824
 825         // set up information replies for clients and server to use
 826         maplist_reply = strzone(getmaplist());
 827         lsmaps_reply = strzone(getlsmaps());
 828         for(i = 0; i < 10; ++i)
 829         {
 830                 s = getrecords(i);
 831                 if (s)
 832                         records_reply[i] = strzone(s);
 833         }
 834         ladder_reply = strzone(getladder());
 835         rankings_reply = strzone(getrankings());
 836
 837         // begin other init
 838         ClientInit_Spawn();
 839         RandomSeed_Spawn();
 840         PingPLReport_Spawn();
 841
 842         CheatInit();
 843
 844         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 845
 846         // fill sv_curl_serverpackages from .serverpackage files
 847         if(autocvar_sv_curl_serverpackages_auto)
 848         {
 849                 s = "";
 850                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 851                 for(i = 0; i < n; ++i)
 852                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 853                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 854                                 s = strcat(s, " ", argv(i));
 855                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 856                 if(fd >= 0)
 857                 {
 858                         j = search_getsize(fd);
 859                         for(i = 0; i < j; ++i)
 860                                 s = strcat(s, " ", search_getfilename(fd, i));
 861                         search_end(fd);
 862                 }
 863                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 864                 if(fd >= 0)
 865                 {
 866                         j = search_getsize(fd);
 867                         for(i = 0; i < j; ++i)
 868                                 s = strcat(s, " ", search_getfilename(fd, i));
 869                         search_end(fd);
 870                 }
 871                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 872         }
 873
 874         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 875         modname = "Xonotic";
 876         // physics/balance/config changes that count as mod
 877         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 878                 modname = cvar_string("g_mod_physics");
 879         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 880                 modname = cvar_string("g_mod_balance");
 881         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 882                 modname = cvar_string("g_mod_config");
 883         // extra mutators that deserve to count as mod
 884         MUTATOR_CALLHOOK(SetModname);
 885
 886         // save it for later
 887         modname = strzone(modname);
 888
 889         WinningConditionHelper(); // set worldstatus
 890
 891         world_initialized = 1;
 892 }
 893
 894 void spawnfunc_light (void)
 895 {
 896         //makestatic (self); // Who the f___ did that?
 897         remove(self);
 898 }
 899
 900 string GetGametype()
 901 {
 902         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 903 }
 904
 905 string getmapname_stored;
 906 string GetMapname()
 907 {
 908         return mapname;
 909 }
 910
 911 float Map_Count, Map_Current;
 912 string Map_Current_Name;
 913
 914 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 915 float GetMaplistPosition()
 916 {
 917         float pos, idx;
 918         string map;
 919
 920         map = GetMapname();
 921         idx = autocvar_g_maplist_index;
 922
 923         if(idx >= 0)
 924                 if(idx < Map_Count)
 925                         if(map == argv(idx))
 926                                 return idx;
 927
 928         for(pos = 0; pos < Map_Count; ++pos)
 929                 if(map == argv(pos))
 930                         return pos;
 931
 932         // resume normal maplist rotation if current map is not in g_maplist
 933         return idx;
 934 }
 935
 936 float MapHasRightSize(string map)
 937 {
 938         float fh;
 939         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 940         if(autocvar_g_maplist_check_waypoints)
 941         {
 942                 dprint("checkwp "); dprint(map);
 943                 if(!fexists(strcat("maps/", map, ".waypoints")))
 944                 {
 945                         dprint(": no waypoints\n");
 946                         return FALSE;
 947                 }
 948                 dprint(": has waypoints\n");
 949         }
 950
 951         // open map size restriction file
 952         dprint("opensize "); dprint(map);
 953         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 954         if(fh >= 0)
 955         {
 956                 float mapmin, mapmax;
 957                 dprint(": ok, ");
 958                 mapmin = stof(fgets(fh));
 959                 mapmax = stof(fgets(fh));
 960                 fclose(fh);
 961                 if(player_count < mapmin)
 962                 {
 963                         dprint("not enough\n");
 964                         return FALSE;
 965                 }
 966                 if(player_count > mapmax)
 967                 {
 968                         dprint("too many\n");
 969                         return FALSE;
 970                 }
 971                 dprint("right size\n");
 972                 return TRUE;
 973         }
 974         dprint(": not found\n");
 975         return TRUE;
 976 }
 977
 978 string Map_Filename(float position)
 979 {
 980         return strcat("maps/", argv(position), ".bsp");
 981 }
 982
 983 string strwords(string s, float w)
 984 {
 985         float endpos;
 986         for(endpos = 0; w && endpos >= 0; --w)
 987                 endpos = strstrofs(s, " ", endpos + 1);
 988         if(endpos < 0)
 989                 return s;
 990         else
 991                 return substring(s, 0, endpos);
 992 }
 993
 994 float strhasword(string s, string w)
 995 {
 996         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 997 }
 998
 999 void Map_MarkAsRecent(string m)
1000 {
1001         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1002 }
1003
1004 float Map_IsRecent(string m)
1005 {
1006         return strhasword(autocvar_g_maplist_mostrecent, m);
1007 }
1008
1009 float Map_Check(float position, float pass)
1010 {
1011         string filename;
1012         string map_next;
1013         map_next = argv(position);
1014         if(pass <= 1)
1015         {
1016                 if(Map_IsRecent(map_next))
1017                         return 0;
1018         }
1019         filename = Map_Filename(position);
1020         if(MapInfo_CheckMap(map_next))
1021         {
1022                 if(pass == 2)
1023                         return 1;
1024                 if(MapHasRightSize(map_next))
1025                         return 1;
1026                 return 0;
1027         }
1028         else
1029                 dprint( "Couldn't select '", filename, "'..\n" );
1030
1031         return 0;
1032 }
1033
1034 void Map_Goto_SetStr(string nextmapname)
1035 {
1036         if(getmapname_stored != "")
1037                 strunzone(getmapname_stored);
1038         if(nextmapname == "")
1039                 getmapname_stored = "";
1040         else
1041                 getmapname_stored = strzone(nextmapname);
1042 }
1043
1044 void Map_Goto_SetFloat(float position)
1045 {
1046         cvar_set("g_maplist_index", ftos(position));
1047         Map_Goto_SetStr(argv(position));
1048 }
1049
1050 void Map_Goto(float reinit)
1051 {
1052         MapInfo_LoadMap(getmapname_stored, reinit);
1053 }
1054
1055 // return codes of map selectors:
1056 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1057 //   -2 = permanent failure
1058 float() MaplistMethod_Iterate = // usual method
1059 {
1060         float pass, i;
1061
1062         for(pass = 1; pass <= 2; ++pass)
1063         {
1064                 for(i = 1; i < Map_Count; ++i)
1065                 {
1066                         float mapindex;
1067                         mapindex = mod(i + Map_Current, Map_Count);
1068                         if(Map_Check(mapindex, pass))
1069                                 return mapindex;
1070                 }
1071         }
1072         return -1;
1073 }
1074
1075 float() MaplistMethod_Repeat = // fallback method
1076 {
1077         if(Map_Check(Map_Current, 2))
1078                 return Map_Current;
1079         return -2;
1080 }
1081
1082 float() MaplistMethod_Random = // random map selection
1083 {
1084         float i, imax;
1085
1086         imax = 42;
1087
1088         for(i = 0; i <= imax; ++i)
1089         {
1090                 float mapindex;
1091                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1092                 if(Map_Check(mapindex, 1))
1093                         return mapindex;
1094         }
1095         return -1;
1096 }
1097
1098 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1099 // the exponent sets a bias on the map selection:
1100 // the higher the exponent, the less likely "shortly repeated" same maps are
1101 {
1102         float i, j, imax, insertpos;
1103
1104         imax = 42;
1105
1106         for(i = 0; i <= imax; ++i)
1107         {
1108                 string newlist;
1109
1110                 // now reinsert this at another position
1111                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1112                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1113                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1114                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1115
1116                 // insert the current map there
1117                 newlist = "";
1118                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1119                         newlist = strcat(newlist, " ", argv(j));
1120                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1121                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1122                         newlist = strcat(newlist, " ", argv(j));
1123                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1124                 cvar_set("g_maplist", newlist);
1125                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1126
1127                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1128                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1129                 if(Map_Check(Map_Current, 1))
1130                         return Map_Current;
1131         }
1132         return -1;
1133 }
1134
1135 void Maplist_Init()
1136 {
1137         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1138         if(Map_Count == 0)
1139         {
1140                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1141                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1142                 if(autocvar_g_maplist_shuffle)
1143                         ShuffleMaplist();
1144                 localcmd("\nmenu_cmd sync\n");
1145                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1146         }
1147         if(Map_Count == 0)
1148                 error("empty maplist, cannot select a new map");
1149         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1150
1151         if(Map_Current_Name)
1152                 strunzone(Map_Current_Name);
1153         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1154         // this may or may not be correct, but who cares, in the worst case a map
1155         // isn't chosen in the first pass that should have been
1156 }
1157
1158 string GetNextMap()
1159 {
1160         float nextMap;
1161
1162         Maplist_Init();
1163         nextMap = -1;
1164
1165         if(nextMap == -1)
1166                 if(autocvar_g_maplist_shuffle > 0)
1167                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1168
1169         if(nextMap == -1)
1170                 if(autocvar_g_maplist_selectrandom)
1171                         nextMap = MaplistMethod_Random();
1172
1173         if(nextMap == -1)
1174                 nextMap = MaplistMethod_Iterate();
1175
1176         if(nextMap == -1)
1177                 nextMap = MaplistMethod_Repeat();
1178
1179         if(nextMap >= 0)
1180         {
1181                 Map_Goto_SetFloat(nextMap);
1182                 return getmapname_stored;
1183         }
1184
1185         return "";
1186 }
1187
1188 float DoNextMapOverride(float reinit)
1189 {
1190         if(autocvar_g_campaign)
1191         {
1192                 CampaignPostIntermission();
1193                 alreadychangedlevel = TRUE;
1194                 return TRUE;
1195         }
1196         if(autocvar_quit_when_empty)
1197         {
1198                 if(player_count <= currentbots)
1199                 {
1200                         localcmd("quit\n");
1201                         alreadychangedlevel = TRUE;
1202                         return TRUE;
1203                 }
1204         }
1205         if(autocvar_quit_and_redirect != "")
1206         {
1207                 redirection_target = strzone(autocvar_quit_and_redirect);
1208                 alreadychangedlevel = TRUE;
1209                 return TRUE;
1210         }
1211         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1212         {
1213                 localcmd("restart\n");
1214                 alreadychangedlevel = TRUE;
1215                 return TRUE;
1216         }
1217         if(autocvar_nextmap != "")
1218                 if(MapInfo_CheckMap(autocvar_nextmap))
1219                 {
1220                         Map_Goto_SetStr(autocvar_nextmap);
1221                         Map_Goto(reinit);
1222                         alreadychangedlevel = TRUE;
1223                         return TRUE;
1224                 }
1225         if(!reinit && autocvar_lastlevel)
1226         {
1227                 cvar_settemp_restore();
1228                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1229                 alreadychangedlevel = TRUE;
1230                 return TRUE;
1231         }
1232         return FALSE;
1233 }
1234
1235 void GotoNextMap(float reinit)
1236 {
1237         //string nextmap;
1238         //float n, nummaps;
1239         //string s;
1240         if (alreadychangedlevel)
1241                 return;
1242         alreadychangedlevel = TRUE;
1243
1244         {
1245                 string nextMap;
1246                 float allowReset;
1247
1248                 for(allowReset = 1; allowReset >= 0; --allowReset)
1249                 {
1250                         nextMap = GetNextMap();
1251                         if(nextMap != "")
1252                                 break;
1253
1254                         if(allowReset)
1255                         {
1256                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1257                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1258                                 if(autocvar_g_maplist_shuffle)
1259                                         ShuffleMaplist();
1260                                 localcmd("\nmenu_cmd sync\n");
1261                         }
1262                         else
1263                         {
1264                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1265                         }
1266                 }
1267                 Map_Goto(reinit);
1268         }
1269 }
1270
1271
1272 /*
1273 ============
1274 IntermissionThink
1275
1276 When the player presses attack or jump, change to the next level
1277 ============
1278 */
1279 .float autoscreenshot;
1280 void() MapVote_Start;
1281 void() MapVote_Think;
1282 float mapvote_initialized;
1283 void IntermissionThink()
1284 {
1285         FixIntermissionClient(self);
1286
1287         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1288         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1289
1290         if( (server_screenshot || client_screenshot)
1291                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1292         {
1293                 self.autoscreenshot = -1;
1294                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1295                 return;
1296         }
1297
1298         if (time < intermission_exittime)
1299                 return;
1300
1301         if(!mapvote_initialized)
1302                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1303                         return;
1304
1305         MapVote_Start();
1306 }
1307
1308 /*
1309 ============
1310 FindIntermission
1311
1312 Returns the entity to view from
1313 ============
1314 */
1315 /*
1316 entity FindIntermission()
1317 {
1318         local   entity spot;
1319         local   float cyc;
1320
1321 // look for info_intermission first
1322         spot = find (world, classname, "info_intermission");
1323         if (spot)
1324         {       // pick a random one
1325                 cyc = random() * 4;
1326                 while (cyc > 1)
1327                 {
1328                         spot = find (spot, classname, "info_intermission");
1329                         if (!spot)
1330                                 spot = find (spot, classname, "info_intermission");
1331                         cyc = cyc - 1;
1332                 }
1333                 return spot;
1334         }
1335
1336 // then look for the start position
1337         spot = find (world, classname, "info_player_start");
1338         if (spot)
1339                 return spot;
1340
1341 // testinfo_player_start is only found in regioned levels
1342         spot = find (world, classname, "testplayerstart");
1343         if (spot)
1344                 return spot;
1345
1346 // then look for the start position
1347         spot = find (world, classname, "info_player_deathmatch");
1348         if (spot)
1349                 return spot;
1350
1351         //objerror ("FindIntermission: no spot");
1352         return world;
1353 }
1354 */
1355
1356 /*
1357 ===============================================================================
1358
1359 RULES
1360
1361 ===============================================================================
1362 */
1363
1364 void DumpStats(float final)
1365 {
1366         float file;
1367         string s;
1368         float to_console;
1369         float to_eventlog;
1370         float to_file;
1371         float i;
1372
1373         to_console = autocvar_sv_logscores_console;
1374         to_eventlog = autocvar_sv_eventlog;
1375         to_file = autocvar_sv_logscores_file;
1376
1377         if(!final)
1378         {
1379                 to_console = TRUE; // always print printstats replies
1380                 to_eventlog = FALSE; // but never print them to the event log
1381         }
1382
1383         if(to_eventlog)
1384                 if(autocvar_sv_eventlog_console)
1385                         to_console = FALSE; // otherwise we get the output twice
1386
1387         if(final)
1388                 s = ":scores:";
1389         else
1390                 s = ":status:";
1391         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1392
1393         if(to_console)
1394                 print(s, "\n");
1395         if(to_eventlog)
1396                 GameLogEcho(s);
1397
1398         file = -1;
1399         if(to_file)
1400         {
1401                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1402                 if(file == -1)
1403                         to_file = FALSE;
1404                 else
1405                         fputs(file, strcat(s, "\n"));
1406         }
1407
1408         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1409         if(to_console)
1410                 print(s, "\n");
1411         if(to_eventlog)
1412                 GameLogEcho(s);
1413         if(to_file)
1414                 fputs(file, strcat(s, "\n"));
1415
1416         FOR_EACH_CLIENT(other)
1417         {
1418                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1419                 {
1420                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1421                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1422                         if(IS_PLAYER(other) || g_arena || other.caplayer == 1 || g_lms)
1423                                 s = strcat(s, ftos(other.team), ":");
1424                         else
1425                                 s = strcat(s, "spectator:");
1426
1427                         if(to_console)
1428                                 print(s, other.netname, "\n");
1429                         if(to_eventlog)
1430                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1431                         if(to_file)
1432                                 fputs(file, strcat(s, other.netname, "\n"));
1433                 }
1434         }
1435
1436         if(teamplay)
1437         {
1438                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1439                 if(to_console)
1440                         print(s, "\n");
1441                 if(to_eventlog)
1442                         GameLogEcho(s);
1443                 if(to_file)
1444                         fputs(file, strcat(s, "\n"));
1445
1446                 for(i = 1; i < 16; ++i)
1447                 {
1448                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1449                         s = strcat(s, ":", ftos(i));
1450                         if(to_console)
1451                                 print(s, "\n");
1452                         if(to_eventlog)
1453                                 GameLogEcho(s);
1454                         if(to_file)
1455                                 fputs(file, strcat(s, "\n"));
1456                 }
1457         }
1458
1459         if(to_console)
1460                 print(":end\n");
1461         if(to_eventlog)
1462                 GameLogEcho(":end");
1463         if(to_file)
1464         {
1465                 fputs(file, ":end\n");
1466                 fclose(file);
1467         }
1468 }
1469
1470 void FixIntermissionClient(entity e)
1471 {
1472         string s;
1473         if(!e.autoscreenshot) // initial call
1474         {
1475                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1476                 e.health = -2342;
1477                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1478                 e.solid = SOLID_NOT;
1479                 e.movetype = MOVETYPE_NONE;
1480                 e.takedamage = DAMAGE_NO;
1481                 if(e.weaponentity)
1482                 {
1483                         e.weaponentity.effects = EF_NODRAW;
1484                         if (e.weaponentity.weaponentity)
1485                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1486                 }
1487                 if(IS_REAL_CLIENT(e))
1488                 {
1489                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1490                         s = autocvar_sv_intermission_cdtrack;
1491                         if(s != "")
1492                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1493                         msg_entity = e;
1494                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1495                 }
1496         }
1497 }
1498
1499 /*
1500 go to the next level for deathmatch
1501 only called if a time or frag limit has expired
1502 */
1503 void NextLevel()
1504 {
1505         gameover = TRUE;
1506
1507         intermission_running = 1;
1508
1509 // enforce a wait time before allowing changelevel
1510         if(player_count > 0)
1511                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1512         else
1513                 intermission_exittime = -1;
1514
1515         /*
1516         WriteByte (MSG_ALL, SVC_CDTRACK);
1517         WriteByte (MSG_ALL, 3);
1518         WriteByte (MSG_ALL, 3);
1519         // done in FixIntermission
1520         */
1521
1522         //pos = FindIntermission ();
1523
1524         VoteReset();
1525
1526         DumpStats(TRUE);
1527
1528         // send statistics
1529         entity e;
1530         PlayerStats_EndMatch(1);
1531         FOR_EACH_CLIENT(e)
1532                 PlayerStats_AddGlobalInfo(e);
1533         PlayerStats_Shutdown();
1534         WeaponStats_Shutdown();
1535
1536         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1537
1538         if(autocvar_sv_eventlog)
1539                 GameLogEcho(":gameover");
1540
1541         GameLogClose();
1542
1543         FOR_EACH_PLAYER(other) {
1544                 FixIntermissionClient(other);
1545                 if(other.winning)
1546                         bprint(other.netname, " ^7wins.\n");
1547         }
1548
1549         if(autocvar_g_campaign)
1550                 CampaignPreIntermission();
1551
1552         MUTATOR_CALLHOOK(MatchEnd);
1553
1554         localcmd("\nsv_hook_gameend\n");
1555 }
1556
1557 /*
1558 ============
1559 CheckRules_Player
1560
1561 Exit deathmatch games upon conditions
1562 ============
1563 */
1564 void CheckRules_Player()
1565 {
1566         if (gameover)   // someone else quit the game already
1567                 return;
1568
1569         if(self.deadflag == DEAD_NO)
1570                 self.play_time += frametime;
1571
1572         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1573         //   (div0: and that in CheckRules_World please)
1574 }
1575
1576 float checkrules_equality;
1577 float checkrules_suddendeathwarning;
1578 float checkrules_suddendeathend;
1579 float checkrules_overtimesadded; //how many overtimes have been already added
1580
1581 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1582 const float WINNING_YES = 1; // winner found
1583 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1584 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1585
1586 float InitiateSuddenDeath()
1587 {
1588         // Check first whether normal overtimes could be added before initiating suddendeath mode
1589         // - for this timelimit_overtime needs to be >0 of course
1590         // - also check the winning condition calculated in the previous frame and only add normal overtime
1591         //   again, if at the point at which timelimit would be extended again, still no winner was found
1592         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1593         {
1594                 return 1; // need to call InitiateOvertime later
1595         }
1596         else
1597         {
1598                 if(!checkrules_suddendeathend)
1599                 {
1600                         if(autocvar_g_campaign)
1601                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1602                         else
1603                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1604                         if(g_race && !g_race_qualifying)
1605                                 race_StartCompleting();
1606                 }
1607                 return 0;
1608         }
1609 }
1610
1611 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1612 {
1613         ++checkrules_overtimesadded;
1614         //add one more overtime by simply extending the timelimit
1615         float tl;
1616         tl = autocvar_timelimit;
1617         tl += autocvar_timelimit_overtime;
1618         cvar_set("timelimit", ftos(tl));
1619
1620         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1621 }
1622
1623 float GetWinningCode(float fraglimitreached, float equality)
1624 {
1625         if(autocvar_g_campaign == 1)
1626                 if(fraglimitreached)
1627                         return WINNING_YES;
1628                 else
1629                         return WINNING_NO;
1630
1631         else
1632                 if(equality)
1633                         if(fraglimitreached)
1634                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1635                         else
1636                                 return WINNING_NEVER;
1637                 else
1638                         if(fraglimitreached)
1639                                 return WINNING_YES;
1640                         else
1641                                 return WINNING_NO;
1642 }
1643
1644 // set the .winning flag for exactly those players with a given field value
1645 void SetWinners(.float field, float value)
1646 {
1647         entity head;
1648         FOR_EACH_PLAYER(head)
1649                 head.winning = (head.field == value);
1650 }
1651
1652 // set the .winning flag for those players with a given field value
1653 void AddWinners(.float field, float value)
1654 {
1655         entity head;
1656         FOR_EACH_PLAYER(head)
1657                 if(head.field == value)
1658                         head.winning = 1;
1659 }
1660
1661 // clear the .winning flags
1662 void ClearWinners(void)
1663 {
1664         entity head;
1665         FOR_EACH_PLAYER(head)
1666                 head.winning = 0;
1667 }
1668
1669 // Onslaught winning condition:
1670 // game terminates if only one team has a working generator (or none)
1671 float WinningCondition_Onslaught()
1672 {
1673         entity head;
1674         float t1, t2, t3, t4;
1675
1676         WinningConditionHelper(); // set worldstatus
1677
1678         if(warmup_stage)
1679                 return WINNING_NO;
1680
1681         // first check if the game has ended
1682         t1 = t2 = t3 = t4 = 0;
1683         head = find(world, classname, "onslaught_generator");
1684         while (head)
1685         {
1686                 if (head.health > 0)
1687                 {
1688                         if (head.team == NUM_TEAM_1) t1 = 1;
1689                         if (head.team == NUM_TEAM_2) t2 = 1;
1690                         if (head.team == NUM_TEAM_3) t3 = 1;
1691                         if (head.team == NUM_TEAM_4) t4 = 1;
1692                 }
1693                 head = find(head, classname, "onslaught_generator");
1694         }
1695         if (t1 + t2 + t3 + t4 < 2)
1696         {
1697                 // game over, only one team remains (or none)
1698                 ClearWinners();
1699                 if (t1) SetWinners(team, NUM_TEAM_1);
1700                 if (t2) SetWinners(team, NUM_TEAM_2);
1701                 if (t3) SetWinners(team, NUM_TEAM_3);
1702                 if (t4) SetWinners(team, NUM_TEAM_4);
1703                 dprint("Have a winner, ending game.\n");
1704                 return WINNING_YES;
1705         }
1706
1707         // Two or more teams remain
1708         return WINNING_NO;
1709 }
1710
1711 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1712 // they win. Otherwise the defending team wins once the timelimit passes.
1713 void assault_new_round();
1714 float WinningCondition_Assault()
1715 {
1716         float status;
1717
1718         WinningConditionHelper(); // set worldstatus
1719
1720         status = WINNING_NO;
1721         // as the timelimit has not yet passed just assume the defending team will win
1722         if(assault_attacker_team == NUM_TEAM_1)
1723         {
1724                 SetWinners(team, NUM_TEAM_2);
1725         }
1726         else
1727         {
1728                 SetWinners(team, NUM_TEAM_1);
1729         }
1730
1731         entity ent;
1732         ent = find(world, classname, "target_assault_roundend");
1733         if(ent)
1734         {
1735                 if(ent.winning) // round end has been triggered by attacking team
1736                 {
1737                         bprint("ASSAULT: round completed...\n");
1738                         SetWinners(team, assault_attacker_team);
1739
1740                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1741
1742                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1743                         {
1744                                 status = WINNING_YES;
1745                         }
1746                         else
1747                         {
1748                                 entity oldself;
1749                                 oldself = self;
1750                                 self = ent;
1751                                 assault_new_round();
1752                                 self = oldself;
1753                         }
1754                 }
1755         }
1756
1757         return status;
1758 }
1759
1760 // LMS winning condition: game terminates if and only if there's at most one
1761 // one player who's living lives. Top two scores being equal cancels the time
1762 // limit.
1763 float WinningCondition_LMS()
1764 {
1765         entity head, head2;
1766         float have_player;
1767         float have_players;
1768         float l;
1769
1770         have_player = FALSE;
1771         have_players = FALSE;
1772         l = LMS_NewPlayerLives();
1773
1774         head = find(world, classname, "player");
1775         if(head)
1776                 have_player = TRUE;
1777         head2 = find(head, classname, "player");
1778         if(head2)
1779                 have_players = TRUE;
1780
1781         if(have_player)
1782         {
1783                 // we have at least one player
1784                 if(have_players)
1785                 {
1786                         // two or more active players - continue with the game
1787                 }
1788                 else
1789                 {
1790                         // exactly one player?
1791
1792                         ClearWinners();
1793                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1794
1795                         if(l)
1796                         {
1797                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1798                                 return WINNING_NO;
1799                         }
1800                         else
1801                         {
1802                                 // a winner!
1803                                 // and assign him his first place
1804                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1805                                 return WINNING_YES;
1806                         }
1807                 }
1808         }
1809         else
1810         {
1811                 // nobody is playing at all...
1812                 if(l)
1813                 {
1814                         // wait for players...
1815                 }
1816                 else
1817                 {
1818                         // SNAFU (maybe a draw game?)
1819                         ClearWinners();
1820                         dprint("No players, ending game.\n");
1821                         return WINNING_YES;
1822                 }
1823         }
1824
1825         // When we get here, we have at least two players who are actually LIVING,
1826         // now check if the top two players have equal score.
1827         WinningConditionHelper();
1828
1829         ClearWinners();
1830         if(WinningConditionHelper_winner)
1831                 WinningConditionHelper_winner.winning = TRUE;
1832         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1833                 return WINNING_NEVER;
1834
1835         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1836         return WINNING_NO;
1837 }
1838
1839 void ShuffleMaplist()
1840 {
1841         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1842 }
1843
1844 float leaderfrags;
1845 float WinningCondition_Scores(float limit, float leadlimit)
1846 {
1847         float limitreached;
1848
1849         // TODO make everything use THIS winning condition (except LMS)
1850         WinningConditionHelper();
1851
1852         if(teamplay)
1853         {
1854                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1855                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1856                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1857                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1858         }
1859
1860         ClearWinners();
1861         if(WinningConditionHelper_winner)
1862                 WinningConditionHelper_winner.winning = 1;
1863         if(WinningConditionHelper_winnerteam >= 0)
1864                 SetWinners(team, WinningConditionHelper_winnerteam);
1865
1866         if(WinningConditionHelper_lowerisbetter)
1867         {
1868                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1869                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1870                 limit = -limit;
1871         }
1872
1873         if(WinningConditionHelper_zeroisworst)
1874                 leadlimit = 0; // not supported in this mode
1875
1876         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1877         // these modes always score in increments of 1, thus this makes sense
1878         {
1879                 if(leaderfrags != WinningConditionHelper_topscore)
1880                 {
1881                         leaderfrags = WinningConditionHelper_topscore;
1882
1883                         if (limit)
1884                         if (leaderfrags == limit - 1)
1885                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1886                         else if (leaderfrags == limit - 2)
1887                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1888                         else if (leaderfrags == limit - 3)
1889                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1890                 }
1891         }
1892
1893         limitreached = FALSE;
1894         if(limit)
1895                 if(WinningConditionHelper_topscore >= limit)
1896                         limitreached = TRUE;
1897         if(leadlimit)
1898         {
1899                 float leadlimitreached;
1900                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1901                 if(autocvar_leadlimit_and_fraglimit)
1902                         limitreached = (limitreached && leadlimitreached);
1903                 else
1904                         limitreached = (limitreached || leadlimitreached);
1905         }
1906
1907         if(limit)
1908                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1909
1910         return GetWinningCode(
1911                 WinningConditionHelper_topscore && limitreached,
1912                 WinningConditionHelper_equality
1913         );
1914 }
1915
1916 float WinningCondition_Race(float fraglimit)
1917 {
1918         float wc;
1919         entity p;
1920         float n, c;
1921
1922         n = 0;
1923         c = 0;
1924         FOR_EACH_PLAYER(p)
1925         {
1926                 ++n;
1927                 if(p.race_completed)
1928                         ++c;
1929         }
1930         if(n && (n == c))
1931                 return WINNING_YES;
1932         wc = WinningCondition_Scores(fraglimit, 0);
1933
1934         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1935         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1936         // do NOT support equality when the laps are all raced!
1937                 return WINNING_STARTSUDDENDEATHOVERTIME;
1938         else
1939                 return WINNING_NEVER;
1940 }
1941
1942 float WinningCondition_QualifyingThenRace(float limit)
1943 {
1944         float wc;
1945         wc = WinningCondition_Scores(limit, 0);
1946
1947         // NEVER initiate overtime
1948         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1949         {
1950                 return WINNING_YES;
1951         }
1952
1953         return wc;
1954 }
1955
1956 float WinningCondition_RanOutOfSpawns()
1957 {
1958         entity head;
1959
1960         if(have_team_spawns <= 0)
1961                 return WINNING_NO;
1962
1963         if(autocvar_g_spawn_useallspawns <= 0)
1964                 return WINNING_NO;
1965
1966         if(!some_spawn_has_been_used)
1967                 return WINNING_NO;
1968
1969         team1_score = team2_score = team3_score = team4_score = 0;
1970
1971         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1972         {
1973                 if(head.team == NUM_TEAM_1)
1974                         team1_score = 1;
1975                 else if(head.team == NUM_TEAM_2)
1976                         team2_score = 1;
1977                 else if(head.team == NUM_TEAM_3)
1978                         team3_score = 1;
1979                 else if(head.team == NUM_TEAM_4)
1980                         team4_score = 1;
1981         }
1982
1983         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1984         {
1985                 if(head.team == NUM_TEAM_1)
1986                         team1_score = 1;
1987                 else if(head.team == NUM_TEAM_2)
1988                         team2_score = 1;
1989                 else if(head.team == NUM_TEAM_3)
1990                         team3_score = 1;
1991                 else if(head.team == NUM_TEAM_4)
1992                         team4_score = 1;
1993         }
1994
1995         ClearWinners();
1996         if(team1_score + team2_score + team3_score + team4_score == 0)
1997         {
1998                 checkrules_equality = TRUE;
1999                 return WINNING_YES;
2000         }
2001         else if(team1_score + team2_score + team3_score + team4_score == 1)
2002         {
2003                 float t, i;
2004                 if(team1_score)
2005                         t = NUM_TEAM_1;
2006                 else if(team2_score)
2007                         t = NUM_TEAM_2;
2008                 else if(team3_score)
2009                         t = NUM_TEAM_3;
2010                 else // if(team4_score)
2011                         t = NUM_TEAM_4;
2012                 CheckAllowedTeams(world);
2013                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2014                 {
2015                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2016                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2017                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2018                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2019                 }
2020
2021                 AddWinners(team, t);
2022                 return WINNING_YES;
2023         }
2024         else
2025                 return WINNING_NO;
2026 }
2027
2028 /*
2029 ============
2030 CheckRules_World
2031
2032 Exit deathmatch games upon conditions
2033 ============
2034 */
2035 void ReadyRestart();
2036 void CheckRules_World()
2037 {
2038         float timelimit;
2039         float fraglimit;
2040         float leadlimit;
2041
2042         VoteThink();
2043         MapVote_Think();
2044
2045         SetDefaultAlpha();
2046
2047         /*
2048         MapVote_Think should now do that part
2049         if (intermission_running)
2050                 if (time >= intermission_exittime + 60)
2051                 {
2052                         if(!DoNextMapOverride())
2053                                 GotoNextMap();
2054                         return;
2055                 }
2056         */
2057
2058         if (gameover)   // someone else quit the game already
2059         {
2060                 if(player_count == 0) // Nobody there? Then let's go to the next map
2061                         MapVote_Start();
2062                         // this will actually check the player count in the next frame
2063                         // again, but this shouldn't hurt
2064                 return;
2065         }
2066
2067         timelimit = autocvar_timelimit * 60;
2068         fraglimit = autocvar_fraglimit;
2069         leadlimit = autocvar_leadlimit;
2070
2071         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2072         {
2073                 if(timelimit > 0)
2074                         timelimit = 0; // timelimit is not made for warmup
2075                 if(fraglimit > 0)
2076                         fraglimit = 0; // no fraglimit for now
2077                 leadlimit = 0; // no leadlimit for now
2078         }
2079
2080         if(timelimit > 0)
2081         {
2082                 timelimit += game_starttime;
2083         }
2084         else if (timelimit < 0)
2085         {
2086                 // endmatch
2087                 NextLevel();
2088                 return;
2089         }
2090
2091         if(g_onslaught)
2092                 timelimit = 0; // ONS has its own overtime rule
2093
2094         float wantovertime;
2095         wantovertime = 0;
2096
2097         if(timelimit > game_starttime)
2098                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2099         else
2100                 game_completion_ratio = 0;
2101
2102         if(checkrules_suddendeathend)
2103         {
2104                 if(!checkrules_suddendeathwarning)
2105                 {
2106                         checkrules_suddendeathwarning = TRUE;
2107                         if(g_race && !g_race_qualifying)
2108                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2109                         else
2110                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2111                 }
2112         }
2113         else
2114         {
2115                 if (timelimit && time >= timelimit)
2116                 {
2117                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2118                         {
2119                                 float totalplayers;
2120                                 float playerswithlaps;
2121                                 float readyplayers;
2122                                 entity head;
2123                                 totalplayers = playerswithlaps = readyplayers = 0;
2124                                 FOR_EACH_PLAYER(head)
2125                                 {
2126                                         ++totalplayers;
2127                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2128                                                 ++playerswithlaps;
2129                                         if(head.ready)
2130                                                 ++readyplayers;
2131                                 }
2132
2133                                 // at least 2 of the players have completed a lap: start the RACE
2134                                 // otherwise, the players should end the qualifying on their own
2135                                 if(readyplayers || playerswithlaps >= 2)
2136                                 {
2137                                         checkrules_suddendeathend = 0;
2138                                         ReadyRestart(); // go to race
2139                                         return;
2140                                 }
2141                                 else
2142                                         wantovertime |= InitiateSuddenDeath();
2143                         }
2144                         else
2145                                 wantovertime |= InitiateSuddenDeath();
2146                 }
2147         }
2148
2149         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2150         {
2151                 NextLevel();
2152                 return;
2153         }
2154
2155         float checkrules_status;
2156         checkrules_status = WinningCondition_RanOutOfSpawns();
2157         if(checkrules_status == WINNING_YES)
2158         {
2159                 bprint("Hey! Someone ran out of spawns!\n");
2160         }
2161         else if(g_race && !g_race_qualifying && timelimit >= 0)
2162         {
2163                 checkrules_status = WinningCondition_Race(fraglimit);
2164                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2165         }
2166         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2167         {
2168                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2169                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2170         }
2171         else if(g_assault)
2172         {
2173                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2174         }
2175         else if(g_lms)
2176         {
2177                 checkrules_status = WinningCondition_LMS();
2178         }
2179         else if (g_onslaught)
2180         {
2181                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2182         }
2183         else
2184         {
2185                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2186                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2187         }
2188
2189         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2190         {
2191                 checkrules_status = WINNING_NEVER;
2192                 checkrules_overtimesadded = -1;
2193                 wantovertime |= InitiateSuddenDeath();
2194         }
2195
2196         if(checkrules_status == WINNING_NEVER)
2197                 // equality cases! Nobody wins if the overtime ends in a draw.
2198                 ClearWinners();
2199
2200         if(wantovertime)
2201         {
2202                 if(checkrules_status == WINNING_NEVER)
2203                         InitiateOvertime();
2204                 else
2205                         checkrules_status = WINNING_YES;
2206         }
2207
2208         if(checkrules_suddendeathend)
2209                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2210                         checkrules_status = WINNING_YES;
2211
2212         if(checkrules_status == WINNING_YES)
2213         {
2214                 //print("WINNING\n");
2215                 NextLevel();
2216         }
2217 }
2218
2219 float mapvote_nextthink;
2220 float mapvote_initialized;
2221 float mapvote_keeptwotime;
2222 float mapvote_timeout;
2223 string mapvote_message;
2224 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2225 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2226 float mapvote_screenshot_dirs_count;
2227
2228 float mapvote_count;
2229 float mapvote_count_real;
2230 string mapvote_maps[MAPVOTE_COUNT];
2231 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2232 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2233 float mapvote_maps_suggested[MAPVOTE_COUNT];
2234 string mapvote_suggestions[MAPVOTE_COUNT];
2235 float mapvote_suggestion_ptr;
2236 float mapvote_voters;
2237 float mapvote_selections[MAPVOTE_COUNT];
2238 float mapvote_run;
2239 float mapvote_detail;
2240 float mapvote_abstain;
2241 .float mapvote;
2242
2243 void MapVote_ClearAllVotes()
2244 {
2245         FOR_EACH_CLIENT(other)
2246                 other.mapvote = 0;
2247 }
2248
2249 string MapVote_Suggest(string m)
2250 {
2251         float i;
2252         if(m == "")
2253                 return "That's not how to use this command.";
2254         if(!autocvar_g_maplist_votable_suggestions)
2255                 return "Suggestions are not accepted on this server.";
2256         if(mapvote_initialized)
2257                 return "Can't suggest - voting is already in progress!";
2258         m = MapInfo_FixName(m);
2259         if not(m)
2260                 return "The map you suggested is not available on this server.";
2261         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2262                 if(Map_IsRecent(m))
2263                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2264
2265         if(!MapInfo_CheckMap(m))
2266                 return "The map you suggested does not support the current game mode.";
2267         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2268                 if(mapvote_suggestions[i] == m)
2269                         return "This map was already suggested.";
2270         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2271         {
2272                 i = floor(random() * mapvote_suggestion_ptr);
2273         }
2274         else
2275         {
2276                 i = mapvote_suggestion_ptr;
2277                 mapvote_suggestion_ptr += 1;
2278         }
2279         if(mapvote_suggestions[i] != "")
2280                 strunzone(mapvote_suggestions[i]);
2281         mapvote_suggestions[i] = strzone(m);
2282         if(autocvar_sv_eventlog)
2283                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2284         return strcat("Suggestion of ", m, " accepted.");
2285 }
2286
2287 void MapVote_AddVotable(string nextMap, float isSuggestion)
2288 {
2289         float j, i, o;
2290         string pakfile, mapfile;
2291
2292         if(nextMap == "")
2293                 return;
2294         for(j = 0; j < mapvote_count; ++j)
2295                 if(mapvote_maps[j] == nextMap)
2296                         return;
2297         // suggestions might be no longer valid/allowed after gametype switch!
2298         if(isSuggestion)
2299                 if(!MapInfo_CheckMap(nextMap))
2300                         return;
2301         mapvote_maps[mapvote_count] = strzone(nextMap);
2302         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2303
2304         pakfile = string_null;
2305         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2306         {
2307                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2308                 pakfile = whichpack(strcat(mapfile, ".tga"));
2309                 if(pakfile == "")
2310                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2311                 if(pakfile == "")
2312                         pakfile = whichpack(strcat(mapfile, ".png"));
2313                 if(pakfile != "")
2314                         break;
2315         }
2316         if(i >= mapvote_screenshot_dirs_count)
2317                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2318         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2319                 pakfile = substring(pakfile, o, -1);
2320
2321         mapvote_maps_screenshot_dir[mapvote_count] = i;
2322         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2323
2324         mapvote_count += 1;
2325 }
2326
2327 void MapVote_Spawn();
2328 void MapVote_Init()
2329 {
2330         float i;
2331         float nmax, smax;
2332
2333         MapVote_ClearAllVotes();
2334
2335         mapvote_count = 0;
2336         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2337         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2338
2339         if(mapvote_abstain)
2340                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2341         else
2342                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2343         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2344
2345         // we need this for AddVotable, as that cycles through the screenshot dirs
2346         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2347         if(mapvote_screenshot_dirs_count == 0)
2348                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2349         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2350         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2351                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2352
2353         if(mapvote_suggestion_ptr)
2354                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2355                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2356
2357         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2358                 MapVote_AddVotable(GetNextMap(), FALSE);
2359
2360         if(mapvote_count == 0)
2361         {
2362                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2363                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2364                 if(autocvar_g_maplist_shuffle)
2365                         ShuffleMaplist();
2366                 localcmd("\nmenu_cmd sync\n");
2367                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2368                         MapVote_AddVotable(GetNextMap(), FALSE);
2369         }
2370
2371         mapvote_count_real = mapvote_count;
2372         if(mapvote_abstain)
2373                 MapVote_AddVotable("don't care", 0);
2374
2375         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2376
2377         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2378         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2379         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2380                 mapvote_keeptwotime = 0;
2381         mapvote_message = "Choose a map and press its key!";
2382
2383         MapVote_Spawn();
2384 }
2385
2386 void MapVote_SendPicture(float id)
2387 {
2388         msg_entity = self;
2389         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2390         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2391         WriteByte(MSG_ONE, id);
2392         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2393 }
2394
2395 float MapVote_GetMapMask()
2396 {
2397         float mask, i, power;
2398         mask = 0;
2399         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2400                 if(mapvote_maps[i] != "")
2401                         mask |= power;
2402         return mask;
2403 }
2404
2405 entity mapvote_ent;
2406 float MapVote_SendEntity(entity to, float sf)
2407 {
2408         float i;
2409
2410         if(sf & 1)
2411                 sf &= ~2; // if we send 1, we don't need to also send 2
2412
2413         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2414         WriteByte(MSG_ENTITY, sf);
2415
2416         if(sf & 1)
2417         {
2418                 // flag 1 == initialization
2419                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2420                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2421                 WriteString(MSG_ENTITY, "");
2422                 WriteByte(MSG_ENTITY, mapvote_count);
2423                 WriteByte(MSG_ENTITY, mapvote_abstain);
2424                 WriteByte(MSG_ENTITY, mapvote_detail);
2425                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2426                 if(mapvote_count <= 8)
2427                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2428                 else
2429                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2430                 for(i = 0; i < mapvote_count; ++i)
2431                         if(mapvote_maps[i] != "")
2432                         {
2433                                 if(mapvote_abstain && i == mapvote_count - 1)
2434                                 {
2435                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2436                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2437                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2438                                 }
2439                                 else
2440                                 {
2441                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2442                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2443                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2444                                 }
2445                         }
2446         }
2447
2448         if(sf & 2)
2449         {
2450                 // flag 2 == update of mask
2451                 if(mapvote_count <= 8)
2452                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2453                 else
2454                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2455         }
2456
2457         if(sf & 4)
2458         {
2459                 if(mapvote_detail)
2460                         for(i = 0; i < mapvote_count; ++i)
2461                                 if(mapvote_maps[i] != "")
2462                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2463
2464                 WriteByte(MSG_ENTITY, to.mapvote);
2465         }
2466
2467         return TRUE;
2468 }
2469
2470 void MapVote_Spawn()
2471 {
2472         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2473 }
2474
2475 void MapVote_TouchMask()
2476 {
2477         mapvote_ent.SendFlags |= 2;
2478 }
2479
2480 void MapVote_TouchVotes(entity voter)
2481 {
2482         mapvote_ent.SendFlags |= 4;
2483 }
2484
2485 float MapVote_Finished(float mappos)
2486 {
2487         string result;
2488         float i;
2489         float didntvote;
2490
2491         if(autocvar_sv_eventlog)
2492         {
2493                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2494                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2495                 didntvote = mapvote_voters;
2496                 for(i = 0; i < mapvote_count; ++i)
2497                         if(mapvote_maps[i] != "")
2498                         {
2499                                 didntvote -= mapvote_selections[i];
2500                                 if(i != mappos)
2501                                 {
2502                                         result = strcat(result, ":", mapvote_maps[i]);
2503                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2504                                 }
2505                         }
2506                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2507
2508                 GameLogEcho(result);
2509                 if(mapvote_maps_suggested[mappos])
2510                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2511         }
2512
2513         FOR_EACH_REALCLIENT(other)
2514                 FixClientCvars(other);
2515
2516         Map_Goto_SetStr(mapvote_maps[mappos]);
2517         Map_Goto(0);
2518         alreadychangedlevel = TRUE;
2519         return TRUE;
2520 }
2521 void MapVote_CheckRules_1()
2522 {
2523         float i;
2524
2525         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2526         {
2527                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2528                 mapvote_selections[i] = 0;
2529         }
2530
2531         mapvote_voters = 0;
2532         FOR_EACH_REALCLIENT(other)
2533         {
2534                 ++mapvote_voters;
2535                 if(other.mapvote)
2536                 {
2537                         i = other.mapvote - 1;
2538                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2539                         mapvote_selections[i] = mapvote_selections[i] + 1;
2540                 }
2541         }
2542 }
2543
2544 float MapVote_CheckRules_2()
2545 {
2546         float i;
2547         float firstPlace, secondPlace;
2548         float firstPlaceVotes, secondPlaceVotes;
2549         float mapvote_voters_real;
2550         string result;
2551
2552         if(mapvote_count_real == 1)
2553                 return MapVote_Finished(0);
2554
2555         mapvote_voters_real = mapvote_voters;
2556         if(mapvote_abstain)
2557                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2558
2559         RandomSelection_Init();
2560         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2561                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2562         firstPlace = RandomSelection_chosen_float;
2563         firstPlaceVotes = RandomSelection_best_priority;
2564         //dprint("First place: ", ftos(firstPlace), "\n");
2565         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2566
2567         RandomSelection_Init();
2568         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2569                 if(i != firstPlace)
2570                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2571         secondPlace = RandomSelection_chosen_float;
2572         secondPlaceVotes = RandomSelection_best_priority;
2573         //dprint("Second place: ", ftos(secondPlace), "\n");
2574         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2575
2576         if(firstPlace == -1)
2577                 error("No first place in map vote... WTF?");
2578
2579         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2580                 return MapVote_Finished(firstPlace);
2581
2582         if(mapvote_keeptwotime)
2583                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2584                 {
2585                         float didntvote;
2586                         MapVote_TouchMask();
2587                         mapvote_message = "Now decide between the TOP TWO!";
2588                         mapvote_keeptwotime = 0;
2589                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2590                         result = strcat(result, ":", ftos(firstPlaceVotes));
2591                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2592                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2593                         didntvote = mapvote_voters;
2594                         for(i = 0; i < mapvote_count; ++i)
2595                                 if(mapvote_maps[i] != "")
2596                                 {
2597                                         didntvote -= mapvote_selections[i];
2598                                         if(i != firstPlace)
2599                                                 if(i != secondPlace)
2600                                                 {
2601                                                         result = strcat(result, ":", mapvote_maps[i]);
2602                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2603                                                         if(i < mapvote_count_real)
2604                                                         {
2605                                                                 strunzone(mapvote_maps[i]);
2606                                                                 mapvote_maps[i] = "";
2607                                                                 strunzone(mapvote_maps_pakfile[i]);
2608                                                                 mapvote_maps_pakfile[i] = "";
2609                                                         }
2610                                                 }
2611                                 }
2612                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2613                         if(autocvar_sv_eventlog)
2614                                 GameLogEcho(result);
2615                 }
2616
2617         return FALSE;
2618 }
2619 void MapVote_Tick()
2620 {
2621         float keeptwo;
2622         float totalvotes;
2623
2624         keeptwo = mapvote_keeptwotime;
2625         MapVote_CheckRules_1(); // count
2626         if(MapVote_CheckRules_2()) // decide
2627                 return;
2628
2629         totalvotes = 0;
2630         FOR_EACH_REALCLIENT(other)
2631         {
2632                 // hide scoreboard again
2633                 if(other.health != 2342)
2634                 {
2635                         other.health = 2342;
2636                         other.impulse = 0;
2637                         if(IS_REAL_CLIENT(other))
2638                         {
2639                                 msg_entity = other;
2640                                 WriteByte(MSG_ONE, SVC_FINALE);
2641                                 WriteString(MSG_ONE, "");
2642                         }
2643                 }
2644
2645                 // clear possibly invalid votes
2646                 if(mapvote_maps[other.mapvote - 1] == "")
2647                         other.mapvote = 0;
2648                 // use impulses as new vote
2649                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2650                         if(mapvote_maps[other.impulse - 1] != "")
2651                         {
2652                                 other.mapvote = other.impulse;
2653                                 MapVote_TouchVotes(other);
2654                         }
2655                 other.impulse = 0;
2656
2657                 if(other.mapvote)
2658                         ++totalvotes;
2659         }
2660
2661         MapVote_CheckRules_1(); // just count
2662 }
2663 void MapVote_Start()
2664 {
2665         if(mapvote_run)
2666                 return;
2667
2668         // wait for stats to be sent first
2669         if(!playerstats_waitforme)
2670                 return;
2671
2672         MapInfo_Enumerate();
2673         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2674                 mapvote_run = TRUE;
2675 }
2676 void MapVote_Think()
2677 {
2678         if(!mapvote_run)
2679                 return;
2680
2681         if(alreadychangedlevel)
2682                 return;
2683
2684         if(time < mapvote_nextthink)
2685                 return;
2686         //dprint("tick\n");
2687
2688         mapvote_nextthink = time + 0.5;
2689
2690         if(!mapvote_initialized)
2691         {
2692                 if(autocvar_rescan_pending == 1)
2693                 {
2694                         cvar_set("rescan_pending", "2");
2695                         localcmd("fs_rescan\nrescan_pending 3\n");
2696                         return;
2697                 }
2698                 else if(autocvar_rescan_pending == 2)
2699                 {
2700                         return;
2701                 }
2702                 else if(autocvar_rescan_pending == 3)
2703                 {
2704                         // now build missing mapinfo files
2705                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2706                                 return;
2707
2708                         // we're done, start the timer
2709                         cvar_set("rescan_pending", "0");
2710                 }
2711
2712                 mapvote_initialized = TRUE;
2713                 if(DoNextMapOverride(0))
2714                         return;
2715                 if(!autocvar_g_maplist_votable || player_count <= 0)
2716                 {
2717                         GotoNextMap(0);
2718                         return;
2719                 }
2720                 MapVote_Init();
2721         }
2722
2723         MapVote_Tick();
2724 }
2725
2726 string GotoMap(string m)
2727 {
2728         if(!MapInfo_CheckMap(m))
2729                 return "The map you chose is not available on this server.";
2730         cvar_set("nextmap", m);
2731         cvar_set("timelimit", "-1");
2732         if(mapvote_initialized || alreadychangedlevel)
2733         {
2734                 if(DoNextMapOverride(0))
2735                         return "Map switch initiated.";
2736                 else
2737                         return "Hm... no. For some reason I like THIS map more.";
2738         }
2739         else
2740                 return "Map switch will happen after scoreboard.";
2741 }
2742
2743
2744 void EndFrame()
2745 {
2746         float altime;
2747         FOR_EACH_REALCLIENT(self)
2748         {
2749                 if(IS_SPEC(self))
2750                 {
2751                         if(self.enemy.typehitsound)
2752                                 self.typehit_time = time;
2753                         else if(self.enemy.hitsound)
2754                                 self.hit_time = time;
2755                 }
2756                 else
2757                 {
2758                         if(self.typehitsound)
2759                                 self.typehit_time = time;
2760                         else if(self.hitsound)
2761                                 self.hit_time = time;
2762                 }
2763         }
2764         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2765         // add 1 frametime because after this, engine SV_Physics
2766         // increases time by a frametime and then networks the frame
2767         // add another frametime because client shows everything with
2768         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2769         // needed!
2770         FOR_EACH_CLIENT(self)
2771         {
2772                 self.hitsound = FALSE;
2773                 self.typehitsound = FALSE;
2774                 antilag_record(self, altime);
2775         }
2776 }
2777
2778
2779 /*
2780  * RedirectionThink:
2781  * returns TRUE if redirecting
2782  */
2783 float redirection_timeout;
2784 float redirection_nextthink;
2785 float RedirectionThink()
2786 {
2787         float clients_found;
2788
2789         if(redirection_target == "")
2790                 return FALSE;
2791
2792         if(!redirection_timeout)
2793         {
2794                 cvar_set("sv_public", "-2");
2795                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2796                 if(redirection_target == "self")
2797                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2798                 else
2799                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2800         }
2801
2802         if(time < redirection_nextthink)
2803                 return TRUE;
2804
2805         redirection_nextthink = time + 1;
2806
2807         clients_found = 0;
2808         FOR_EACH_REALCLIENT(self)
2809         {
2810                 // TODO add timer
2811                 print("Redirecting: sending connect command to ", self.netname, "\n");
2812                 if(redirection_target == "self")
2813                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2814                 else
2815                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2816                 ++clients_found;
2817         }
2818
2819         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2820
2821         if(time > redirection_timeout || clients_found == 0)
2822                 localcmd("\nwait; wait; wait; quit\n");
2823
2824         return TRUE;
2825 }
2826
2827 void TargetMusic_RestoreGame();
2828 void RestoreGame()
2829 {
2830         // Loaded from a save game
2831         // some things then break, so let's work around them...
2832
2833         // Progs DB (capture records)
2834         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2835
2836         // Mapinfo
2837         MapInfo_Shutdown();
2838         MapInfo_Enumerate();
2839         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2840         WeaponStats_Init();
2841
2842         TargetMusic_RestoreGame();
2843 }
2844
2845 void Shutdown()
2846 {
2847         entity e;
2848
2849         gameover = 2;
2850
2851         if(world_initialized > 0)
2852         {
2853                 world_initialized = 0;
2854                 print("Saving persistent data...\n");
2855                 Ban_SaveBans();
2856
2857                 PlayerStats_EndMatch(0);
2858                 FOR_EACH_CLIENT(e)
2859                         PlayerStats_AddGlobalInfo(e);
2860                 PlayerStats_Shutdown();
2861
2862                 if(!cheatcount_total)
2863                 {
2864                         if(autocvar_sv_db_saveasdump)
2865                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2866                         else
2867                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2868                 }
2869                 if(autocvar_developer)
2870                 {
2871                         if(autocvar_sv_db_saveasdump)
2872                                 db_dump(TemporaryDB, "server-temp.db");
2873                         else
2874                                 db_save(TemporaryDB, "server-temp.db");
2875                 }
2876                 CheatShutdown(); // must be after cheatcount check
2877                 db_close(ServerProgsDB);
2878                 db_close(TemporaryDB);
2879                 print("done!\n");
2880                 // tell the bot system the game is ending now
2881                 bot_endgame();
2882
2883                 WeaponStats_Shutdown();
2884                 MapInfo_Shutdown();
2885         }
2886         else if(world_initialized == 0)
2887         {
2888                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2889         }
2890 }