qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_assault");
 257                 BADCVAR("g_ca");
 258                 BADCVAR("g_ca_teams");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_freezetag_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_leadlimit");
 308                 BADCVAR("g_ctf_captimerecord_always");
 309                 BADCVAR("g_ctf_flag_glowtrails");
 310                 BADCVAR("g_ctf_flag_pickup_verbosename");
 311                 BADCVAR("g_domination_point_leadlimit");
 312                 BADCVAR("g_forced_respawn");
 313                 BADCVAR("g_keyhunt_point_leadlimit");
 314                 BADPREFIX("g_mod_");
 315                 BADCVAR("g_nexball_goalleadlimit");
 316                 BADCVAR("leadlimit_and_fraglimit");
 317                 BADCVAR("leadlimit_override");
 318                 BADCVAR("pausable");
 319                 BADCVAR("sv_allow_fullbright");
 320                 BADCVAR("sv_checkforpacketsduringsleep");
 321                 BADCVAR("sv_fraginfo");
 322                 BADCVAR("sv_timeout");
 323                 BADPREFIX("sv_timeout_");
 324                 BADPREFIX("crypto_");
 325                 BADPREFIX("g_chat_");
 326                 BADPREFIX("g_ctf_captimerecord_");
 327                 BADPREFIX("g_maplist_votable_");
 328                 BADPREFIX("net_");
 329                 BADPREFIX("prvm_");
 330                 BADPREFIX("skill_");
 331                 BADPREFIX("sv_cullentities_");
 332                 BADPREFIX("sv_fraginfo_");
 333                 BADPREFIX("sv_maxidle_");
 334                 BADPREFIX("sv_vote_");
 335                 BADPREFIX("timelimit_");
 336                 BADCVAR("gameversion");
 337                 BADPREFIX("gameversion_");
 338                 BADCVAR("sv_namechangetimer");
 339
 340                 // allowed changes to server admins (please sync this to server.cfg)
 341                 // vi commands:
 342                 //   :/"impure"/,$d
 343                 //   :g!,^\/\/[^ /],d
 344                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 345                 //   :%!sort
 346                 // yes, this does contain some redundant stuff, don't really care
 347                 BADCVAR("bot_config_file");
 348                 BADCVAR("bot_number");
 349                 BADCVAR("bot_prefix");
 350                 BADCVAR("bot_suffix");
 351                 BADCVAR("capturelimit_override");
 352                 BADCVAR("fraglimit_override");
 353                 BADCVAR("gametype");
 354                 BADCVAR("g_antilag");
 355                 BADCVAR("g_balance_teams");
 356                 BADCVAR("g_balance_teams_prevent_imbalance");
 357                 BADCVAR("g_balance_teams_scorefactor");
 358                 BADCVAR("g_ban_sync_trusted_servers");
 359                 BADCVAR("g_ban_sync_uri");
 360                 BADCVAR("g_ca_teams_override");
 361                 BADCVAR("g_ctf_ignore_frags");
 362                 BADCVAR("g_domination_point_limit");
 363                 BADCVAR("g_freezetag_teams_override");
 364                 BADCVAR("g_friendlyfire");
 365                 BADCVAR("g_fullbrightitems");
 366                 BADCVAR("g_fullbrightplayers");
 367                 BADCVAR("g_keyhunt_point_limit");
 368                 BADCVAR("g_keyhunt_teams_override");
 369                 BADCVAR("g_lms_lives_override");
 370                 BADCVAR("g_maplist");
 371                 BADCVAR("g_maplist_check_waypoints");
 372                 BADCVAR("g_maplist_mostrecent_count");
 373                 BADCVAR("g_maplist_shuffle");
 374                 BADCVAR("g_maplist_votable");
 375                 BADCVAR("g_maplist_votable_abstain");
 376                 BADCVAR("g_maplist_votable_nodetail");
 377                 BADCVAR("g_maplist_votable_suggestions");
 378                 BADCVAR("g_maxplayers");
 379                 BADCVAR("g_mirrordamage");
 380                 BADCVAR("g_nexball_goallimit");
 381                 BADCVAR("g_powerups");
 382                 BADCVAR("g_start_delay");
 383                 BADCVAR("g_warmup");
 384                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 385                 BADCVAR("hostname");
 386                 BADCVAR("log_file");
 387                 BADCVAR("maxplayers");
 388                 BADCVAR("minplayers");
 389                 BADCVAR("net_address");
 390                 BADCVAR("port");
 391                 BADCVAR("rcon_password");
 392                 BADCVAR("rcon_restricted_commands");
 393                 BADCVAR("rcon_restricted_password");
 394                 BADCVAR("skill");
 395                 BADCVAR("sv_adminnick");
 396                 BADCVAR("sv_autoscreenshot");
 397                 BADCVAR("sv_autotaunt");
 398                 BADCVAR("sv_curl_defaulturl");
 399                 BADCVAR("sv_defaultcharacter");
 400                 BADCVAR("sv_defaultplayercolors");
 401                 BADCVAR("sv_defaultplayermodel");
 402                 BADCVAR("sv_defaultplayerskin");
 403                 BADCVAR("sv_maxidle");
 404                 BADCVAR("sv_maxrate");
 405                 BADCVAR("sv_motd");
 406                 BADCVAR("sv_public");
 407                 BADCVAR("sv_ready_restart");
 408                 BADCVAR("sv_status_privacy");
 409                 BADCVAR("sv_taunt");
 410                 BADCVAR("sv_vote_call");
 411                 BADCVAR("sv_vote_commands");
 412                 BADCVAR("sv_vote_majority_factor");
 413                 BADCVAR("sv_vote_master");
 414                 BADCVAR("sv_vote_master_commands");
 415                 BADCVAR("sv_vote_master_password");
 416                 BADCVAR("sv_vote_simple_majority_factor");
 417                 BADCVAR("teamplay_mode");
 418                 BADCVAR("timelimit_override");
 419                 BADCVAR("g_spawnshieldtime");
 420                 BADPREFIX("g_warmup_");
 421                 BADPREFIX("sv_ready_restart_");
 422
 423                 // mutators that announce themselves properly to the server browser
 424                 BADCVAR("g_minstagib");
 425                 BADCVAR("g_new_toys");
 426                 BADCVAR("g_nix");
 427                 BADCVAR("g_grappling_hook");
 428                 BADCVAR("g_jetpack");
 429
 430 #undef BADPREFIX
 431 #undef BADCVAR
 432
 433                 if(pureadding)
 434                 {
 435                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 436                         if(strlen(cvar_purechanges) > 16384)
 437                         {
 438                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 439                                 pureadding = 0;
 440                         }
 441                 }
 442                 ++cvar_purechanges_count;
 443                 // WARNING: this variable is used for the server list
 444                 // NEVER dare to skip this code!
 445                 // Hacks to intentionally appearing as "pure server" even though you DO have
 446                 // modified settings may be punished by removal from the server list.
 447                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 448                 // though.
 449         }
 450         buf_del(h);
 451         if(cvar_changes == "")
 452                 cvar_changes = "// this server runs at default server settings\n";
 453         else
 454                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 455         cvar_changes = strzone(cvar_changes);
 456         if(cvar_purechanges == "")
 457                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 458         else
 459                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 460         cvar_purechanges = strzone(cvar_purechanges);
 461 }
 462
 463 void detect_maptype()
 464 {
 465 #if 0
 466         vector o, v;
 467         float i;
 468
 469         for(;;)
 470         {
 471                 o = world.mins;
 472                 o_x += random() * (world.maxs_x - world.mins_x);
 473                 o_y += random() * (world.maxs_y - world.mins_y);
 474                 o_z += random() * (world.maxs_z - world.mins_z);
 475
 476                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 477                 if(trace_fraction == 1)
 478                         continue;
 479
 480                 v = trace_endpos;
 481
 482                 for(i = 0; i < 64; i += 4)
 483                 {
 484                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 485         if(trace_fraction == 1)
 486                 continue;
 487                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 488                 }
 489
 490                 break;
 491         }
 492 #endif
 493 }
 494
 495 entity randomseed;
 496 float RandomSeed_Send(entity to, float sf)
 497 {
 498         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 499         WriteShort(MSG_ENTITY, self.cnt);
 500         return TRUE;
 501 }
 502 void RandomSeed_Think()
 503 {
 504         self.cnt = bound(0, floor(random() * 65536), 65535);
 505         self.nextthink = time + 5;
 506
 507         self.SendFlags |= 1;
 508 }
 509 void RandomSeed_Spawn()
 510 {
 511         randomseed = spawn();
 512         randomseed.think = RandomSeed_Think;
 513         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 514
 515         entity oldself;
 516         oldself = self;
 517         self = randomseed;
 518         self.think(); // sets random seed and nextthink
 519         self = oldself;
 520 }
 521
 522 void spawnfunc___init_dedicated_server(void)
 523 {
 524         // handler for _init/_init map (only for dedicated server initialization)
 525
 526         world_initialized = -1; // don't complain
 527         cvar = cvar_normal;
 528         cvar_string = cvar_string_normal;
 529         cvar_set = cvar_set_normal;
 530
 531         remove = remove_unsafely;
 532
 533         entity e;
 534         e = spawn();
 535         e.think = GotoFirstMap;
 536         e.nextthink = time; // this is usually 1 at this point
 537
 538         e = spawn();
 539         e.classname = "info_player_deathmatch"; // safeguard against player joining
 540
 541         self.classname = "worldspawn"; // safeguard against various stuff ;)
 542
 543         // needs to be done so early because of the constants they create
 544         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 545         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 546         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 547         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 548         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 591
 592         // needs to be done so early because of the constants they create
 593         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 594         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 595         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 596         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 597         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 598
 599         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 600
 601         TemporaryDB = db_create();
 602
 603         // 0 normal
 604         lightstyle(0, "m");
 605
 606         // 1 FLICKER (first variety)
 607         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 608
 609         // 2 SLOW STRONG PULSE
 610         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 611
 612         // 3 CANDLE (first variety)
 613         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 614
 615         // 4 FAST STROBE
 616         lightstyle(4, "mamamamamama");
 617
 618         // 5 GENTLE PULSE 1
 619         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 620
 621         // 6 FLICKER (second variety)
 622         lightstyle(6, "nmonqnmomnmomomno");
 623
 624         // 7 CANDLE (second variety)
 625         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 626
 627         // 8 CANDLE (third variety)
 628         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 629
 630         // 9 SLOW STROBE (fourth variety)
 631         lightstyle(9, "aaaaaaaazzzzzzzz");
 632
 633         // 10 FLUORESCENT FLICKER
 634         lightstyle(10, "mmamammmmammamamaaamammma");
 635
 636         // 11 SLOW PULSE NOT FADE TO BLACK
 637         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 638
 639         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 640
 641         // 63 testing
 642         lightstyle(63, "a");
 643
 644         if(autocvar_g_campaign)
 645                 CampaignPreInit();
 646
 647         Map_MarkAsRecent(mapname);
 648
 649         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 650
 651         precache_model ("null"); // we need this one before InitGameplayMode
 652         InitGameplayMode();
 653         readlevelcvars();
 654         GrappleHookInit();
 655         ElectroInit();
 656         LaserInit();
 657
 658         player_count = 0;
 659         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 660         if(bot_waypoints_for_items == 1)
 661                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 662                         bot_waypoints_for_items = 0;
 663
 664         precache();
 665
 666         WaypointSprite_Init();
 667
 668         GameLogInit(); // prepare everything
 669         // NOTE for matchid:
 670         // changing the logic generating it is okay. But:
 671         // it HAS to stay <= 64 chars
 672         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 673         if(autocvar_sv_eventlog)
 674         {
 675                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 676                 matchid = strzone(s);
 677
 678                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 679                 s = ":gameinfo:mutators:LIST";
 680
 681                 ret_string = s;
 682                 MUTATOR_CALLHOOK(BuildMutatorsString);
 683                 s = ret_string;
 684
 685                 // simple, probably not good in the mutator system
 686                 if(autocvar_g_grappling_hook)
 687                         s = strcat(s, ":grappling_hook");
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(!autocvar_g_use_ammunition)
 691                         s = strcat(s, ":no_use_ammunition");
 692
 693                 // initialiation stuff, not good in the mutator system
 694                 if(autocvar_g_pickup_items == 0)
 695                         s = strcat(s, ":no_pickup_items");
 696                 if(autocvar_g_pickup_items > 0)
 697                         s = strcat(s, ":pickup_items");
 698
 699                 // initialiation stuff, not good in the mutator system
 700                 if(autocvar_g_weaponarena != "0")
 701                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 702
 703                 // TODO to mutator system
 704                 if(autocvar_g_norecoil)
 705                         s = strcat(s, ":norecoil");
 706
 707                 // TODO to mutator system
 708                 if(autocvar_g_powerups == 0)
 709                         s = strcat(s, ":no_powerups");
 710                 if(autocvar_g_powerups > 0)
 711                         s = strcat(s, ":powerups");
 712
 713                 GameLogEcho(s);
 714                 GameLogEcho(":gameinfo:end");
 715         }
 716         else
 717                 matchid = strzone(ftos(random()));
 718
 719         cvar_set("nextmap", "");
 720
 721         SetDefaultAlpha();
 722
 723         if(autocvar_g_campaign)
 724                 CampaignPostInit();
 725
 726         fteqcc_testbugs();
 727
 728         Ban_LoadBans();
 729
 730         MapInfo_Enumerate();
 731         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 732
 733         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 734         {
 735                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 736                 if(fd != -1)
 737                 {
 738                         while((s = fgets(fd)))
 739                         {
 740                                 l = tokenize_console(s);
 741                                 if(l < 2)
 742                                         continue;
 743                                 if(argv(0) == "cd")
 744                                 {
 745                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 746                                         print("  cdtrack ", argv(2), "\n");
 747                                 }
 748                                 else if(argv(0) == "fog")
 749                                 {
 750                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 751                                         print("  \"fog\" \"", s, "\"\n");
 752                                 }
 753                                 else if(argv(0) == "set")
 754                                 {
 755                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 756                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 757                                 }
 758                                 else if(argv(0) != "//")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 761                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 762                                 }
 763                         }
 764                         fclose(fd);
 765                 }
 766         }
 767
 768         WeaponStats_Init();
 769
 770         WepSet_AddStat();
 771         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 772         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 773         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 774         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 775         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 776         Nagger_Init();
 777
 778         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 779         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 780         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 781         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 782         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 783         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 784         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 785         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 786         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 787         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 788         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 789         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 790         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 791
 792         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 793         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 794
 795         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 796
 797         // g_movementspeed hack
 798         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 799         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 800         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 801         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 802
 803         // secrets
 804         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 805         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 806
 807         // monsters
 808         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 809         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 810
 811         // misc
 812         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 813
 814         next_pingtime = time + 5;
 815
 816         detect_maptype();
 817
 818         // set up information replies for clients and server to use
 819         maplist_reply = strzone(getmaplist());
 820         lsmaps_reply = strzone(getlsmaps());
 821         monsterlist_reply = strzone(getmonsterlist());
 822         for(i = 0; i < 10; ++i)
 823         {
 824                 s = getrecords(i);
 825                 if (s)
 826                         records_reply[i] = strzone(s);
 827         }
 828         ladder_reply = strzone(getladder());
 829         rankings_reply = strzone(getrankings());
 830
 831         // begin other init
 832         ClientInit_Spawn();
 833         RandomSeed_Spawn();
 834         PingPLReport_Spawn();
 835
 836         CheatInit();
 837
 838         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 839
 840         // fill sv_curl_serverpackages from .serverpackage files
 841         if(autocvar_sv_curl_serverpackages_auto)
 842         {
 843                 s = "";
 844                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 845                 for(i = 0; i < n; ++i)
 846                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 847                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 848                                 s = strcat(s, " ", argv(i));
 849                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 850                 if(fd >= 0)
 851                 {
 852                         j = search_getsize(fd);
 853                         for(i = 0; i < j; ++i)
 854                                 s = strcat(s, " ", search_getfilename(fd, i));
 855                         search_end(fd);
 856                 }
 857                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 858                 if(fd >= 0)
 859                 {
 860                         j = search_getsize(fd);
 861                         for(i = 0; i < j; ++i)
 862                                 s = strcat(s, " ", search_getfilename(fd, i));
 863                         search_end(fd);
 864                 }
 865                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 866         }
 867
 868         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 869         modname = "Xonotic";
 870         // physics/balance/config changes that count as mod
 871         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 872                 modname = cvar_string("g_mod_physics");
 873         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 874                 modname = cvar_string("g_mod_balance");
 875         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 876                 modname = cvar_string("g_mod_config");
 877         // extra mutators that deserve to count as mod
 878         MUTATOR_CALLHOOK(SetModname);
 879
 880         // save it for later
 881         modname = strzone(modname);
 882
 883         WinningConditionHelper(); // set worldstatus
 884
 885         world_initialized = 1;
 886 }
 887
 888 void spawnfunc_light (void)
 889 {
 890         //makestatic (self); // Who the f___ did that?
 891         remove(self);
 892 }
 893
 894 string GetGametype()
 895 {
 896         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 897 }
 898
 899 string getmapname_stored;
 900 string GetMapname()
 901 {
 902         return mapname;
 903 }
 904
 905 float Map_Count, Map_Current;
 906 string Map_Current_Name;
 907
 908 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 909 float GetMaplistPosition()
 910 {
 911         float pos, idx;
 912         string map;
 913
 914         map = GetMapname();
 915         idx = autocvar_g_maplist_index;
 916
 917         if(idx >= 0)
 918                 if(idx < Map_Count)
 919                         if(map == argv(idx))
 920                                 return idx;
 921
 922         for(pos = 0; pos < Map_Count; ++pos)
 923                 if(map == argv(pos))
 924                         return pos;
 925
 926         // resume normal maplist rotation if current map is not in g_maplist
 927         return idx;
 928 }
 929
 930 float MapHasRightSize(string map)
 931 {
 932         float fh;
 933         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 934         if(autocvar_g_maplist_check_waypoints)
 935         {
 936                 dprint("checkwp "); dprint(map);
 937                 if(!fexists(strcat("maps/", map, ".waypoints")))
 938                 {
 939                         dprint(": no waypoints\n");
 940                         return FALSE;
 941                 }
 942                 dprint(": has waypoints\n");
 943         }
 944
 945         // open map size restriction file
 946         dprint("opensize "); dprint(map);
 947         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 948         if(fh >= 0)
 949         {
 950                 float mapmin, mapmax;
 951                 dprint(": ok, ");
 952                 mapmin = stof(fgets(fh));
 953                 mapmax = stof(fgets(fh));
 954                 fclose(fh);
 955                 if(player_count < mapmin)
 956                 {
 957                         dprint("not enough\n");
 958                         return FALSE;
 959                 }
 960                 if(player_count > mapmax)
 961                 {
 962                         dprint("too many\n");
 963                         return FALSE;
 964                 }
 965                 dprint("right size\n");
 966                 return TRUE;
 967         }
 968         dprint(": not found\n");
 969         return TRUE;
 970 }
 971
 972 string Map_Filename(float position)
 973 {
 974         return strcat("maps/", argv(position), ".bsp");
 975 }
 976
 977 string strwords(string s, float w)
 978 {
 979         float endpos;
 980         for(endpos = 0; w && endpos >= 0; --w)
 981                 endpos = strstrofs(s, " ", endpos + 1);
 982         if(endpos < 0)
 983                 return s;
 984         else
 985                 return substring(s, 0, endpos);
 986 }
 987
 988 float strhasword(string s, string w)
 989 {
 990         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 991 }
 992
 993 void Map_MarkAsRecent(string m)
 994 {
 995         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 996 }
 997
 998 float Map_IsRecent(string m)
 999 {
1000         return strhasword(autocvar_g_maplist_mostrecent, m);
1001 }
1002
1003 float Map_Check(float position, float pass)
1004 {
1005         string filename;
1006         string map_next;
1007         map_next = argv(position);
1008         if(pass <= 1)
1009         {
1010                 if(Map_IsRecent(map_next))
1011                         return 0;
1012         }
1013         filename = Map_Filename(position);
1014         if(MapInfo_CheckMap(map_next))
1015         {
1016                 if(pass == 2)
1017                         return 1;
1018                 if(MapHasRightSize(map_next))
1019                         return 1;
1020                 return 0;
1021         }
1022         else
1023                 dprint( "Couldn't select '", filename, "'..\n" );
1024
1025         return 0;
1026 }
1027
1028 void Map_Goto_SetStr(string nextmapname)
1029 {
1030         if(getmapname_stored != "")
1031                 strunzone(getmapname_stored);
1032         if(nextmapname == "")
1033                 getmapname_stored = "";
1034         else
1035                 getmapname_stored = strzone(nextmapname);
1036 }
1037
1038 void Map_Goto_SetFloat(float position)
1039 {
1040         cvar_set("g_maplist_index", ftos(position));
1041         Map_Goto_SetStr(argv(position));
1042 }
1043
1044 void Map_Goto(float reinit)
1045 {
1046         MapInfo_LoadMap(getmapname_stored, reinit);
1047 }
1048
1049 // return codes of map selectors:
1050 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1051 //   -2 = permanent failure
1052 float() MaplistMethod_Iterate = // usual method
1053 {
1054         float pass, i;
1055
1056         dprint("Trying MaplistMethod_Iterate\n");
1057
1058         for(pass = 1; pass <= 2; ++pass)
1059         {
1060                 for(i = 1; i < Map_Count; ++i)
1061                 {
1062                         float mapindex;
1063                         mapindex = mod(i + Map_Current, Map_Count);
1064                         if(Map_Check(mapindex, pass))
1065                                 return mapindex;
1066                 }
1067         }
1068         return -1;
1069 }
1070
1071 float() MaplistMethod_Repeat = // fallback method
1072 {
1073         dprint("Trying MaplistMethod_Repeat\n");
1074
1075         if(Map_Check(Map_Current, 2))
1076                 return Map_Current;
1077         return -2;
1078 }
1079
1080 float() MaplistMethod_Random = // random map selection
1081 {
1082         float i, imax;
1083
1084         dprint("Trying MaplistMethod_Random\n");
1085
1086         imax = 42;
1087
1088         for(i = 0; i <= imax; ++i)
1089         {
1090                 float mapindex;
1091                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1092                 if(Map_Check(mapindex, 1))
1093                         return mapindex;
1094         }
1095         return -1;
1096 }
1097
1098 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1099 // the exponent sets a bias on the map selection:
1100 // the higher the exponent, the less likely "shortly repeated" same maps are
1101 {
1102         float i, j, imax, insertpos;
1103
1104         dprint("Trying MaplistMethod_Shuffle\n");
1105
1106         imax = 42;
1107
1108         for(i = 0; i <= imax; ++i)
1109         {
1110                 string newlist;
1111
1112                 // now reinsert this at another position
1113                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1114                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1115                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1116                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1117
1118                 // insert the current map there
1119                 newlist = "";
1120                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1121                         newlist = strcat(newlist, " ", argv(j));
1122                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1123                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1124                         newlist = strcat(newlist, " ", argv(j));
1125                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1126                 cvar_set("g_maplist", newlist);
1127                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1128
1129                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1130                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1131                 if(Map_Check(Map_Current, 1))
1132                         return Map_Current;
1133         }
1134         return -1;
1135 }
1136
1137 void Maplist_Init()
1138 {
1139         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1140         float i;
1141         for (i = 0; i < Map_Count; ++i)
1142                 if (Map_Check(i, 2))
1143                         break;
1144         if (i == Map_Count)
1145         {
1146                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1147                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1148                 if(autocvar_g_maplist_shuffle)
1149                         ShuffleMaplist();
1150                 localcmd("\nmenu_cmd sync\n");
1151                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1152         }
1153         if(Map_Count == 0)
1154                 error("empty maplist, cannot select a new map");
1155         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1156
1157         if(Map_Current_Name)
1158                 strunzone(Map_Current_Name);
1159         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1160         // this may or may not be correct, but who cares, in the worst case a map
1161         // isn't chosen in the first pass that should have been
1162 }
1163
1164 string GetNextMap()
1165 {
1166         float nextMap;
1167
1168         Maplist_Init();
1169         nextMap = -1;
1170
1171         if(nextMap == -1)
1172                 if(autocvar_g_maplist_shuffle > 0)
1173                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1174
1175         if(nextMap == -1)
1176                 if(autocvar_g_maplist_selectrandom)
1177                         nextMap = MaplistMethod_Random();
1178
1179         if(nextMap == -1)
1180                 nextMap = MaplistMethod_Iterate();
1181
1182         if(nextMap == -1)
1183                 nextMap = MaplistMethod_Repeat();
1184
1185         if(nextMap >= 0)
1186         {
1187                 Map_Goto_SetFloat(nextMap);
1188                 return getmapname_stored;
1189         }
1190
1191         return "";
1192 }
1193
1194 float DoNextMapOverride(float reinit)
1195 {
1196         if(autocvar_g_campaign)
1197         {
1198                 CampaignPostIntermission();
1199                 alreadychangedlevel = TRUE;
1200                 return TRUE;
1201         }
1202         if(autocvar_quit_when_empty)
1203         {
1204                 if(player_count <= currentbots)
1205                 {
1206                         localcmd("quit\n");
1207                         alreadychangedlevel = TRUE;
1208                         return TRUE;
1209                 }
1210         }
1211         if(autocvar_quit_and_redirect != "")
1212         {
1213                 redirection_target = strzone(autocvar_quit_and_redirect);
1214                 alreadychangedlevel = TRUE;
1215                 return TRUE;
1216         }
1217         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1218         {
1219                 localcmd("restart\n");
1220                 alreadychangedlevel = TRUE;
1221                 return TRUE;
1222         }
1223         if(autocvar_nextmap != "")
1224                 if(MapInfo_CheckMap(autocvar_nextmap))
1225                 {
1226                         Map_Goto_SetStr(autocvar_nextmap);
1227                         Map_Goto(reinit);
1228                         alreadychangedlevel = TRUE;
1229                         return TRUE;
1230                 }
1231         if(!reinit && autocvar_lastlevel)
1232         {
1233                 cvar_settemp_restore();
1234                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1235                 alreadychangedlevel = TRUE;
1236                 return TRUE;
1237         }
1238         return FALSE;
1239 }
1240
1241 void GotoNextMap(float reinit)
1242 {
1243         //string nextmap;
1244         //float n, nummaps;
1245         //string s;
1246         if (alreadychangedlevel)
1247                 return;
1248         alreadychangedlevel = TRUE;
1249
1250         string nextMap;
1251
1252         nextMap = GetNextMap();
1253         if(nextMap == "")
1254                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1255         Map_Goto(reinit);
1256 }
1257
1258
1259 /*
1260 ============
1261 IntermissionThink
1262
1263 When the player presses attack or jump, change to the next level
1264 ============
1265 */
1266 .float autoscreenshot;
1267 void() MapVote_Start;
1268 void() MapVote_Think;
1269 float mapvote_initialized;
1270 void IntermissionThink()
1271 {
1272         FixIntermissionClient(self);
1273
1274         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1275         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1276
1277         if( (server_screenshot || client_screenshot)
1278                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1279         {
1280                 self.autoscreenshot = -1;
1281                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1282                 return;
1283         }
1284
1285         if (time < intermission_exittime)
1286                 return;
1287
1288         if(!mapvote_initialized)
1289                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1290                         return;
1291
1292         MapVote_Start();
1293 }
1294
1295 /*
1296 ============
1297 FindIntermission
1298
1299 Returns the entity to view from
1300 ============
1301 */
1302 /*
1303 entity FindIntermission()
1304 {
1305         local   entity spot;
1306         local   float cyc;
1307
1308 // look for info_intermission first
1309         spot = find (world, classname, "info_intermission");
1310         if (spot)
1311         {       // pick a random one
1312                 cyc = random() * 4;
1313                 while (cyc > 1)
1314                 {
1315                         spot = find (spot, classname, "info_intermission");
1316                         if (!spot)
1317                                 spot = find (spot, classname, "info_intermission");
1318                         cyc = cyc - 1;
1319                 }
1320                 return spot;
1321         }
1322
1323 // then look for the start position
1324         spot = find (world, classname, "info_player_start");
1325         if (spot)
1326                 return spot;
1327
1328 // testinfo_player_start is only found in regioned levels
1329         spot = find (world, classname, "testplayerstart");
1330         if (spot)
1331                 return spot;
1332
1333 // then look for the start position
1334         spot = find (world, classname, "info_player_deathmatch");
1335         if (spot)
1336                 return spot;
1337
1338         //objerror ("FindIntermission: no spot");
1339         return world;
1340 }
1341 */
1342
1343 /*
1344 ===============================================================================
1345
1346 RULES
1347
1348 ===============================================================================
1349 */
1350
1351 void DumpStats(float final)
1352 {
1353         float file;
1354         string s;
1355         float to_console;
1356         float to_eventlog;
1357         float to_file;
1358         float i;
1359
1360         to_console = autocvar_sv_logscores_console;
1361         to_eventlog = autocvar_sv_eventlog;
1362         to_file = autocvar_sv_logscores_file;
1363
1364         if(!final)
1365         {
1366                 to_console = TRUE; // always print printstats replies
1367                 to_eventlog = FALSE; // but never print them to the event log
1368         }
1369
1370         if(to_eventlog)
1371                 if(autocvar_sv_eventlog_console)
1372                         to_console = FALSE; // otherwise we get the output twice
1373
1374         if(final)
1375                 s = ":scores:";
1376         else
1377                 s = ":status:";
1378         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1379
1380         if(to_console)
1381                 print(s, "\n");
1382         if(to_eventlog)
1383                 GameLogEcho(s);
1384
1385         file = -1;
1386         if(to_file)
1387         {
1388                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1389                 if(file == -1)
1390                         to_file = FALSE;
1391                 else
1392                         fputs(file, strcat(s, "\n"));
1393         }
1394
1395         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1396         if(to_console)
1397                 print(s, "\n");
1398         if(to_eventlog)
1399                 GameLogEcho(s);
1400         if(to_file)
1401                 fputs(file, strcat(s, "\n"));
1402
1403         FOR_EACH_CLIENT(other)
1404         {
1405                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1406                 {
1407                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1408                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1409                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1410                                 s = strcat(s, ftos(other.team), ":");
1411                         else
1412                                 s = strcat(s, "spectator:");
1413
1414                         if(to_console)
1415                                 print(s, other.netname, "\n");
1416                         if(to_eventlog)
1417                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1418                         if(to_file)
1419                                 fputs(file, strcat(s, other.netname, "\n"));
1420                 }
1421         }
1422
1423         if(teamplay)
1424         {
1425                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1426                 if(to_console)
1427                         print(s, "\n");
1428                 if(to_eventlog)
1429                         GameLogEcho(s);
1430                 if(to_file)
1431                         fputs(file, strcat(s, "\n"));
1432
1433                 for(i = 1; i < 16; ++i)
1434                 {
1435                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1436                         s = strcat(s, ":", ftos(i));
1437                         if(to_console)
1438                                 print(s, "\n");
1439                         if(to_eventlog)
1440                                 GameLogEcho(s);
1441                         if(to_file)
1442                                 fputs(file, strcat(s, "\n"));
1443                 }
1444         }
1445
1446         if(to_console)
1447                 print(":end\n");
1448         if(to_eventlog)
1449                 GameLogEcho(":end");
1450         if(to_file)
1451         {
1452                 fputs(file, ":end\n");
1453                 fclose(file);
1454         }
1455 }
1456
1457 void FixIntermissionClient(entity e)
1458 {
1459         string s;
1460         if(!e.autoscreenshot) // initial call
1461         {
1462                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1463                 e.health = -2342;
1464                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1465                 e.solid = SOLID_NOT;
1466                 e.movetype = MOVETYPE_NONE;
1467                 e.takedamage = DAMAGE_NO;
1468                 if(e.weaponentity)
1469                 {
1470                         e.weaponentity.effects = EF_NODRAW;
1471                         if (e.weaponentity.weaponentity)
1472                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1473                 }
1474                 if(IS_REAL_CLIENT(e))
1475                 {
1476                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1477                         s = autocvar_sv_intermission_cdtrack;
1478                         if(s != "")
1479                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1480                         msg_entity = e;
1481                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1482                 }
1483         }
1484 }
1485
1486 /*
1487 go to the next level for deathmatch
1488 only called if a time or frag limit has expired
1489 */
1490 void NextLevel()
1491 {
1492         gameover = TRUE;
1493
1494         intermission_running = 1;
1495
1496 // enforce a wait time before allowing changelevel
1497         if(player_count > 0)
1498                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1499         else
1500                 intermission_exittime = -1;
1501
1502         /*
1503         WriteByte (MSG_ALL, SVC_CDTRACK);
1504         WriteByte (MSG_ALL, 3);
1505         WriteByte (MSG_ALL, 3);
1506         // done in FixIntermission
1507         */
1508
1509         //pos = FindIntermission ();
1510
1511         VoteReset();
1512
1513         DumpStats(TRUE);
1514
1515         // send statistics
1516         PlayerStats_GameReport(TRUE);
1517         WeaponStats_Shutdown();
1518
1519         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1520
1521         if(autocvar_sv_eventlog)
1522                 GameLogEcho(":gameover");
1523
1524         GameLogClose();
1525
1526         FOR_EACH_PLAYER(other) {
1527                 FixIntermissionClient(other);
1528                 if(other.winning)
1529                         bprint(other.netname, " ^7wins.\n");
1530         }
1531
1532         if(autocvar_g_campaign)
1533                 CampaignPreIntermission();
1534
1535         MUTATOR_CALLHOOK(MatchEnd);
1536
1537         localcmd("\nsv_hook_gameend\n");
1538 }
1539
1540 /*
1541 ============
1542 CheckRules_Player
1543
1544 Exit deathmatch games upon conditions
1545 ============
1546 */
1547 void CheckRules_Player()
1548 {
1549         if (gameover)   // someone else quit the game already
1550                 return;
1551
1552         if(self.deadflag == DEAD_NO)
1553                 self.play_time += frametime;
1554
1555         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1556         //   (div0: and that in CheckRules_World please)
1557 }
1558
1559 float checkrules_equality;
1560 float checkrules_suddendeathwarning;
1561 float checkrules_suddendeathend;
1562 float checkrules_overtimesadded; //how many overtimes have been already added
1563
1564 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1565 const float WINNING_YES = 1; // winner found
1566 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1567 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1568
1569 float InitiateSuddenDeath()
1570 {
1571         // Check first whether normal overtimes could be added before initiating suddendeath mode
1572         // - for this timelimit_overtime needs to be >0 of course
1573         // - also check the winning condition calculated in the previous frame and only add normal overtime
1574         //   again, if at the point at which timelimit would be extended again, still no winner was found
1575         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1576         {
1577                 return 1; // need to call InitiateOvertime later
1578         }
1579         else
1580         {
1581                 if(!checkrules_suddendeathend)
1582                 {
1583                         if(autocvar_g_campaign)
1584                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1585                         else
1586                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1587                         if(g_race && !g_race_qualifying)
1588                                 race_StartCompleting();
1589                 }
1590                 return 0;
1591         }
1592 }
1593
1594 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1595 {
1596         ++checkrules_overtimesadded;
1597         //add one more overtime by simply extending the timelimit
1598         float tl;
1599         tl = autocvar_timelimit;
1600         tl += autocvar_timelimit_overtime;
1601         cvar_set("timelimit", ftos(tl));
1602
1603         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1604 }
1605
1606 float GetWinningCode(float fraglimitreached, float equality)
1607 {
1608         if(autocvar_g_campaign == 1)
1609                 if(fraglimitreached)
1610                         return WINNING_YES;
1611                 else
1612                         return WINNING_NO;
1613
1614         else
1615                 if(equality)
1616                         if(fraglimitreached)
1617                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1618                         else
1619                                 return WINNING_NEVER;
1620                 else
1621                         if(fraglimitreached)
1622                                 return WINNING_YES;
1623                         else
1624                                 return WINNING_NO;
1625 }
1626
1627 // set the .winning flag for exactly those players with a given field value
1628 void SetWinners(.float field, float value)
1629 {
1630         entity head;
1631         FOR_EACH_PLAYER(head)
1632                 head.winning = (head.field == value);
1633 }
1634
1635 // set the .winning flag for those players with a given field value
1636 void AddWinners(.float field, float value)
1637 {
1638         entity head;
1639         FOR_EACH_PLAYER(head)
1640                 if(head.field == value)
1641                         head.winning = 1;
1642 }
1643
1644 // clear the .winning flags
1645 void ClearWinners(void)
1646 {
1647         entity head;
1648         FOR_EACH_PLAYER(head)
1649                 head.winning = 0;
1650 }
1651
1652 // Onslaught winning condition:
1653 // game terminates if only one team has a working generator (or none)
1654 float WinningCondition_Onslaught()
1655 {
1656         entity head;
1657         float t1, t2, t3, t4;
1658
1659         WinningConditionHelper(); // set worldstatus
1660
1661         if(warmup_stage)
1662                 return WINNING_NO;
1663
1664         // first check if the game has ended
1665         t1 = t2 = t3 = t4 = 0;
1666         head = find(world, classname, "onslaught_generator");
1667         while (head)
1668         {
1669                 if (head.health > 0)
1670                 {
1671                         if (head.team == NUM_TEAM_1) t1 = 1;
1672                         if (head.team == NUM_TEAM_2) t2 = 1;
1673                         if (head.team == NUM_TEAM_3) t3 = 1;
1674                         if (head.team == NUM_TEAM_4) t4 = 1;
1675                 }
1676                 head = find(head, classname, "onslaught_generator");
1677         }
1678         if (t1 + t2 + t3 + t4 < 2)
1679         {
1680                 // game over, only one team remains (or none)
1681                 ClearWinners();
1682                 if (t1) SetWinners(team, NUM_TEAM_1);
1683                 if (t2) SetWinners(team, NUM_TEAM_2);
1684                 if (t3) SetWinners(team, NUM_TEAM_3);
1685                 if (t4) SetWinners(team, NUM_TEAM_4);
1686                 dprint("Have a winner, ending game.\n");
1687                 return WINNING_YES;
1688         }
1689
1690         // Two or more teams remain
1691         return WINNING_NO;
1692 }
1693
1694 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1695 // they win. Otherwise the defending team wins once the timelimit passes.
1696 void assault_new_round();
1697 float WinningCondition_Assault()
1698 {
1699         float status;
1700
1701         WinningConditionHelper(); // set worldstatus
1702
1703         status = WINNING_NO;
1704         // as the timelimit has not yet passed just assume the defending team will win
1705         if(assault_attacker_team == NUM_TEAM_1)
1706         {
1707                 SetWinners(team, NUM_TEAM_2);
1708         }
1709         else
1710         {
1711                 SetWinners(team, NUM_TEAM_1);
1712         }
1713
1714         entity ent;
1715         ent = find(world, classname, "target_assault_roundend");
1716         if(ent)
1717         {
1718                 if(ent.winning) // round end has been triggered by attacking team
1719                 {
1720                         bprint("ASSAULT: round completed...\n");
1721                         SetWinners(team, assault_attacker_team);
1722
1723                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1724
1725                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1726                         {
1727                                 status = WINNING_YES;
1728                         }
1729                         else
1730                         {
1731                                 entity oldself;
1732                                 oldself = self;
1733                                 self = ent;
1734                                 assault_new_round();
1735                                 self = oldself;
1736                         }
1737                 }
1738         }
1739
1740         return status;
1741 }
1742
1743 // LMS winning condition: game terminates if and only if there's at most one
1744 // one player who's living lives. Top two scores being equal cancels the time
1745 // limit.
1746 float WinningCondition_LMS()
1747 {
1748         entity head, head2;
1749         float have_player;
1750         float have_players;
1751         float l;
1752
1753         have_player = FALSE;
1754         have_players = FALSE;
1755         l = LMS_NewPlayerLives();
1756
1757         head = find(world, classname, "player");
1758         if(head)
1759                 have_player = TRUE;
1760         head2 = find(head, classname, "player");
1761         if(head2)
1762                 have_players = TRUE;
1763
1764         if(have_player)
1765         {
1766                 // we have at least one player
1767                 if(have_players)
1768                 {
1769                         // two or more active players - continue with the game
1770                 }
1771                 else
1772                 {
1773                         // exactly one player?
1774
1775                         ClearWinners();
1776                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1777
1778                         if(l)
1779                         {
1780                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1781                                 return WINNING_NO;
1782                         }
1783                         else
1784                         {
1785                                 // a winner!
1786                                 // and assign him his first place
1787                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1788                                 return WINNING_YES;
1789                         }
1790                 }
1791         }
1792         else
1793         {
1794                 // nobody is playing at all...
1795                 if(l)
1796                 {
1797                         // wait for players...
1798                 }
1799                 else
1800                 {
1801                         // SNAFU (maybe a draw game?)
1802                         ClearWinners();
1803                         dprint("No players, ending game.\n");
1804                         return WINNING_YES;
1805                 }
1806         }
1807
1808         // When we get here, we have at least two players who are actually LIVING,
1809         // now check if the top two players have equal score.
1810         WinningConditionHelper();
1811
1812         ClearWinners();
1813         if(WinningConditionHelper_winner)
1814                 WinningConditionHelper_winner.winning = TRUE;
1815         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1816                 return WINNING_NEVER;
1817
1818         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1819         return WINNING_NO;
1820 }
1821
1822 void ShuffleMaplist()
1823 {
1824         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1825 }
1826
1827 float leaderfrags;
1828 float WinningCondition_Scores(float limit, float leadlimit)
1829 {
1830         float limitreached;
1831
1832         // TODO make everything use THIS winning condition (except LMS)
1833         WinningConditionHelper();
1834
1835         if(teamplay)
1836         {
1837                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1838                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1839                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1840                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1841         }
1842
1843         ClearWinners();
1844         if(WinningConditionHelper_winner)
1845                 WinningConditionHelper_winner.winning = 1;
1846         if(WinningConditionHelper_winnerteam >= 0)
1847                 SetWinners(team, WinningConditionHelper_winnerteam);
1848
1849         if(WinningConditionHelper_lowerisbetter)
1850         {
1851                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1852                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1853                 limit = -limit;
1854         }
1855
1856         if(WinningConditionHelper_zeroisworst)
1857                 leadlimit = 0; // not supported in this mode
1858
1859         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1860         // these modes always score in increments of 1, thus this makes sense
1861         {
1862                 if(leaderfrags != WinningConditionHelper_topscore)
1863                 {
1864                         leaderfrags = WinningConditionHelper_topscore;
1865
1866                         if (limit)
1867                         if (leaderfrags == limit - 1)
1868                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1869                         else if (leaderfrags == limit - 2)
1870                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1871                         else if (leaderfrags == limit - 3)
1872                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1873                 }
1874         }
1875
1876         limitreached = FALSE;
1877         if(limit)
1878                 if(WinningConditionHelper_topscore >= limit)
1879                         limitreached = TRUE;
1880         if(leadlimit)
1881         {
1882                 float leadlimitreached;
1883                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1884                 if(autocvar_leadlimit_and_fraglimit)
1885                         limitreached = (limitreached && leadlimitreached);
1886                 else
1887                         limitreached = (limitreached || leadlimitreached);
1888         }
1889
1890         if(limit)
1891                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1892
1893         return GetWinningCode(
1894                 WinningConditionHelper_topscore && limitreached,
1895                 WinningConditionHelper_equality
1896         );
1897 }
1898
1899 float WinningCondition_Race(float fraglimit)
1900 {
1901         float wc;
1902         entity p;
1903         float n, c;
1904
1905         n = 0;
1906         c = 0;
1907         FOR_EACH_PLAYER(p)
1908         {
1909                 ++n;
1910                 if(p.race_completed)
1911                         ++c;
1912         }
1913         if(n && (n == c))
1914                 return WINNING_YES;
1915         wc = WinningCondition_Scores(fraglimit, 0);
1916
1917         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1918         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1919         // do NOT support equality when the laps are all raced!
1920                 return WINNING_STARTSUDDENDEATHOVERTIME;
1921         else
1922                 return WINNING_NEVER;
1923 }
1924
1925 float WinningCondition_QualifyingThenRace(float limit)
1926 {
1927         float wc;
1928         wc = WinningCondition_Scores(limit, 0);
1929
1930         // NEVER initiate overtime
1931         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1932         {
1933                 return WINNING_YES;
1934         }
1935
1936         return wc;
1937 }
1938
1939 float WinningCondition_RanOutOfSpawns()
1940 {
1941         entity head;
1942
1943         if(have_team_spawns <= 0)
1944                 return WINNING_NO;
1945
1946         if(autocvar_g_spawn_useallspawns <= 0)
1947                 return WINNING_NO;
1948
1949         if(!some_spawn_has_been_used)
1950                 return WINNING_NO;
1951
1952         team1_score = team2_score = team3_score = team4_score = 0;
1953
1954         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1955         {
1956                 if(head.team == NUM_TEAM_1)
1957                         team1_score = 1;
1958                 else if(head.team == NUM_TEAM_2)
1959                         team2_score = 1;
1960                 else if(head.team == NUM_TEAM_3)
1961                         team3_score = 1;
1962                 else if(head.team == NUM_TEAM_4)
1963                         team4_score = 1;
1964         }
1965
1966         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1967         {
1968                 if(head.team == NUM_TEAM_1)
1969                         team1_score = 1;
1970                 else if(head.team == NUM_TEAM_2)
1971                         team2_score = 1;
1972                 else if(head.team == NUM_TEAM_3)
1973                         team3_score = 1;
1974                 else if(head.team == NUM_TEAM_4)
1975                         team4_score = 1;
1976         }
1977
1978         ClearWinners();
1979         if(team1_score + team2_score + team3_score + team4_score == 0)
1980         {
1981                 checkrules_equality = TRUE;
1982                 return WINNING_YES;
1983         }
1984         else if(team1_score + team2_score + team3_score + team4_score == 1)
1985         {
1986                 float t, i;
1987                 if(team1_score)
1988                         t = NUM_TEAM_1;
1989                 else if(team2_score)
1990                         t = NUM_TEAM_2;
1991                 else if(team3_score)
1992                         t = NUM_TEAM_3;
1993                 else // if(team4_score)
1994                         t = NUM_TEAM_4;
1995                 CheckAllowedTeams(world);
1996                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1997                 {
1998                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1999                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2000                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2001                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2002                 }
2003
2004                 AddWinners(team, t);
2005                 return WINNING_YES;
2006         }
2007         else
2008                 return WINNING_NO;
2009 }
2010
2011 /*
2012 ============
2013 CheckRules_World
2014
2015 Exit deathmatch games upon conditions
2016 ============
2017 */
2018 void ReadyRestart();
2019 void CheckRules_World()
2020 {
2021         float timelimit;
2022         float fraglimit;
2023         float leadlimit;
2024
2025         VoteThink();
2026         MapVote_Think();
2027
2028         SetDefaultAlpha();
2029
2030         /*
2031         MapVote_Think should now do that part
2032         if (intermission_running)
2033                 if (time >= intermission_exittime + 60)
2034                 {
2035                         if(!DoNextMapOverride())
2036                                 GotoNextMap();
2037                         return;
2038                 }
2039         */
2040
2041         if (gameover)   // someone else quit the game already
2042         {
2043                 if(player_count == 0) // Nobody there? Then let's go to the next map
2044                         MapVote_Start();
2045                         // this will actually check the player count in the next frame
2046                         // again, but this shouldn't hurt
2047                 return;
2048         }
2049
2050         timelimit = autocvar_timelimit * 60;
2051         fraglimit = autocvar_fraglimit;
2052         leadlimit = autocvar_leadlimit;
2053
2054         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2055         {
2056                 if(timelimit > 0)
2057                         timelimit = 0; // timelimit is not made for warmup
2058                 if(fraglimit > 0)
2059                         fraglimit = 0; // no fraglimit for now
2060                 leadlimit = 0; // no leadlimit for now
2061         }
2062
2063         if(timelimit > 0)
2064         {
2065                 timelimit += game_starttime;
2066         }
2067         else if (timelimit < 0)
2068         {
2069                 // endmatch
2070                 NextLevel();
2071                 return;
2072         }
2073
2074         if(g_onslaught)
2075                 timelimit = 0; // ONS has its own overtime rule
2076
2077         float wantovertime;
2078         wantovertime = 0;
2079
2080         if(timelimit > game_starttime)
2081                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2082         else
2083                 game_completion_ratio = 0;
2084
2085         if(checkrules_suddendeathend)
2086         {
2087                 if(!checkrules_suddendeathwarning)
2088                 {
2089                         checkrules_suddendeathwarning = TRUE;
2090                         if(g_race && !g_race_qualifying)
2091                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2092                         else
2093                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2094                 }
2095         }
2096         else
2097         {
2098                 if (timelimit && time >= timelimit)
2099                 {
2100                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2101                         {
2102                                 float totalplayers;
2103                                 float playerswithlaps;
2104                                 float readyplayers;
2105                                 entity head;
2106                                 totalplayers = playerswithlaps = readyplayers = 0;
2107                                 FOR_EACH_PLAYER(head)
2108                                 {
2109                                         ++totalplayers;
2110                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2111                                                 ++playerswithlaps;
2112                                         if(head.ready)
2113                                                 ++readyplayers;
2114                                 }
2115
2116                                 // at least 2 of the players have completed a lap: start the RACE
2117                                 // otherwise, the players should end the qualifying on their own
2118                                 if(readyplayers || playerswithlaps >= 2)
2119                                 {
2120                                         checkrules_suddendeathend = 0;
2121                                         ReadyRestart(); // go to race
2122                                         return;
2123                                 }
2124                                 else
2125                                         wantovertime |= InitiateSuddenDeath();
2126                         }
2127                         else
2128                                 wantovertime |= InitiateSuddenDeath();
2129                 }
2130         }
2131
2132         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2133         {
2134                 NextLevel();
2135                 return;
2136         }
2137
2138         float checkrules_status;
2139         checkrules_status = WinningCondition_RanOutOfSpawns();
2140         if(checkrules_status == WINNING_YES)
2141         {
2142                 bprint("Hey! Someone ran out of spawns!\n");
2143         }
2144         else if(g_race && !g_race_qualifying && timelimit >= 0)
2145         {
2146                 checkrules_status = WinningCondition_Race(fraglimit);
2147                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2148         }
2149         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2150         {
2151                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2152                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2153         }
2154         else if(g_assault)
2155         {
2156                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2157         }
2158         else if(g_lms)
2159         {
2160                 checkrules_status = WinningCondition_LMS();
2161         }
2162         else if (g_onslaught)
2163         {
2164                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2165         }
2166         else
2167         {
2168                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2169                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2170         }
2171
2172         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2173         {
2174                 checkrules_status = WINNING_NEVER;
2175                 checkrules_overtimesadded = -1;
2176                 wantovertime |= InitiateSuddenDeath();
2177         }
2178
2179         if(checkrules_status == WINNING_NEVER)
2180                 // equality cases! Nobody wins if the overtime ends in a draw.
2181                 ClearWinners();
2182
2183         if(wantovertime)
2184         {
2185                 if(checkrules_status == WINNING_NEVER)
2186                         InitiateOvertime();
2187                 else
2188                         checkrules_status = WINNING_YES;
2189         }
2190
2191         if(checkrules_suddendeathend)
2192                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2193                         checkrules_status = WINNING_YES;
2194
2195         if(checkrules_status == WINNING_YES)
2196         {
2197                 //print("WINNING\n");
2198                 NextLevel();
2199         }
2200 }
2201
2202 float mapvote_nextthink;
2203 float mapvote_initialized;
2204 float mapvote_keeptwotime;
2205 float mapvote_timeout;
2206 string mapvote_message;
2207 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2208 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2209 float mapvote_screenshot_dirs_count;
2210
2211 float mapvote_count;
2212 float mapvote_count_real;
2213 string mapvote_maps[MAPVOTE_COUNT];
2214 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2215 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2216 float mapvote_maps_suggested[MAPVOTE_COUNT];
2217 string mapvote_suggestions[MAPVOTE_COUNT];
2218 float mapvote_suggestion_ptr;
2219 float mapvote_voters;
2220 float mapvote_selections[MAPVOTE_COUNT];
2221 float mapvote_run;
2222 float mapvote_detail;
2223 float mapvote_abstain;
2224 .float mapvote;
2225
2226 void MapVote_ClearAllVotes()
2227 {
2228         FOR_EACH_CLIENT(other)
2229                 other.mapvote = 0;
2230 }
2231
2232 string MapVote_Suggest(string m)
2233 {
2234         float i;
2235         if(m == "")
2236                 return "That's not how to use this command.";
2237         if(!autocvar_g_maplist_votable_suggestions)
2238                 return "Suggestions are not accepted on this server.";
2239         if(mapvote_initialized)
2240                 return "Can't suggest - voting is already in progress!";
2241         m = MapInfo_FixName(m);
2242         if (!m)
2243                 return "The map you suggested is not available on this server.";
2244         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2245                 if(Map_IsRecent(m))
2246                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2247
2248         if(!MapInfo_CheckMap(m))
2249                 return "The map you suggested does not support the current game mode.";
2250         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2251                 if(mapvote_suggestions[i] == m)
2252                         return "This map was already suggested.";
2253         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2254         {
2255                 i = floor(random() * mapvote_suggestion_ptr);
2256         }
2257         else
2258         {
2259                 i = mapvote_suggestion_ptr;
2260                 mapvote_suggestion_ptr += 1;
2261         }
2262         if(mapvote_suggestions[i] != "")
2263                 strunzone(mapvote_suggestions[i]);
2264         mapvote_suggestions[i] = strzone(m);
2265         if(autocvar_sv_eventlog)
2266                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2267         return strcat("Suggestion of ", m, " accepted.");
2268 }
2269
2270 void MapVote_AddVotable(string nextMap, float isSuggestion)
2271 {
2272         float j, i, o;
2273         string pakfile, mapfile;
2274
2275         if(nextMap == "")
2276                 return;
2277         for(j = 0; j < mapvote_count; ++j)
2278                 if(mapvote_maps[j] == nextMap)
2279                         return;
2280         // suggestions might be no longer valid/allowed after gametype switch!
2281         if(isSuggestion)
2282                 if(!MapInfo_CheckMap(nextMap))
2283                         return;
2284         mapvote_maps[mapvote_count] = strzone(nextMap);
2285         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2286
2287         pakfile = string_null;
2288         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2289         {
2290                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2291                 pakfile = whichpack(strcat(mapfile, ".tga"));
2292                 if(pakfile == "")
2293                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2294                 if(pakfile == "")
2295                         pakfile = whichpack(strcat(mapfile, ".png"));
2296                 if(pakfile != "")
2297                         break;
2298         }
2299         if(i >= mapvote_screenshot_dirs_count)
2300                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2301         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2302                 pakfile = substring(pakfile, o, -1);
2303
2304         mapvote_maps_screenshot_dir[mapvote_count] = i;
2305         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2306
2307         mapvote_count += 1;
2308 }
2309
2310 void MapVote_Spawn();
2311 void MapVote_Init()
2312 {
2313         float i;
2314         float nmax, smax;
2315
2316         MapVote_ClearAllVotes();
2317
2318         mapvote_count = 0;
2319         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2320         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2321
2322         if(mapvote_abstain)
2323                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2324         else
2325                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2326         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2327
2328         // we need this for AddVotable, as that cycles through the screenshot dirs
2329         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2330         if(mapvote_screenshot_dirs_count == 0)
2331                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2332         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2333         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2334                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2335
2336         if(mapvote_suggestion_ptr)
2337                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2338                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2339
2340         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2341                 MapVote_AddVotable(GetNextMap(), FALSE);
2342
2343         if(mapvote_count == 0)
2344         {
2345                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2346                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2347                 if(autocvar_g_maplist_shuffle)
2348                         ShuffleMaplist();
2349                 localcmd("\nmenu_cmd sync\n");
2350                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2351                         MapVote_AddVotable(GetNextMap(), FALSE);
2352         }
2353
2354         mapvote_count_real = mapvote_count;
2355         if(mapvote_abstain)
2356                 MapVote_AddVotable("don't care", 0);
2357
2358         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2359
2360         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2361         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2362         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2363                 mapvote_keeptwotime = 0;
2364         mapvote_message = "Choose a map and press its key!";
2365
2366         MapVote_Spawn();
2367 }
2368
2369 void MapVote_SendPicture(float id)
2370 {
2371         msg_entity = self;
2372         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2373         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2374         WriteByte(MSG_ONE, id);
2375         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2376 }
2377
2378 float MapVote_GetMapMask()
2379 {
2380         float mask, i, power;
2381         mask = 0;
2382         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2383                 if(mapvote_maps[i] != "")
2384                         mask |= power;
2385         return mask;
2386 }
2387
2388 entity mapvote_ent;
2389 float MapVote_SendEntity(entity to, float sf)
2390 {
2391         float i;
2392
2393         if(sf & 1)
2394                 sf &= ~2; // if we send 1, we don't need to also send 2
2395
2396         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2397         WriteByte(MSG_ENTITY, sf);
2398
2399         if(sf & 1)
2400         {
2401                 // flag 1 == initialization
2402                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2403                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2404                 WriteString(MSG_ENTITY, "");
2405                 WriteByte(MSG_ENTITY, mapvote_count);
2406                 WriteByte(MSG_ENTITY, mapvote_abstain);
2407                 WriteByte(MSG_ENTITY, mapvote_detail);
2408                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2409                 if(mapvote_count <= 8)
2410                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2411                 else
2412                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2413                 for(i = 0; i < mapvote_count; ++i)
2414                         if(mapvote_maps[i] != "")
2415                         {
2416                                 if(mapvote_abstain && i == mapvote_count - 1)
2417                                 {
2418                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2419                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2420                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2421                                 }
2422                                 else
2423                                 {
2424                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2425                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2426                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2427                                 }
2428                         }
2429         }
2430
2431         if(sf & 2)
2432         {
2433                 // flag 2 == update of mask
2434                 if(mapvote_count <= 8)
2435                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2436                 else
2437                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2438         }
2439
2440         if(sf & 4)
2441         {
2442                 if(mapvote_detail)
2443                         for(i = 0; i < mapvote_count; ++i)
2444                                 if(mapvote_maps[i] != "")
2445                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2446
2447                 WriteByte(MSG_ENTITY, to.mapvote);
2448         }
2449
2450         return TRUE;
2451 }
2452
2453 void MapVote_Spawn()
2454 {
2455         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2456 }
2457
2458 void MapVote_TouchMask()
2459 {
2460         mapvote_ent.SendFlags |= 2;
2461 }
2462
2463 void MapVote_TouchVotes(entity voter)
2464 {
2465         mapvote_ent.SendFlags |= 4;
2466 }
2467
2468 float MapVote_Finished(float mappos)
2469 {
2470         string result;
2471         float i;
2472         float didntvote;
2473
2474         if(autocvar_sv_eventlog)
2475         {
2476                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2477                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2478                 didntvote = mapvote_voters;
2479                 for(i = 0; i < mapvote_count; ++i)
2480                         if(mapvote_maps[i] != "")
2481                         {
2482                                 didntvote -= mapvote_selections[i];
2483                                 if(i != mappos)
2484                                 {
2485                                         result = strcat(result, ":", mapvote_maps[i]);
2486                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2487                                 }
2488                         }
2489                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2490
2491                 GameLogEcho(result);
2492                 if(mapvote_maps_suggested[mappos])
2493                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2494         }
2495
2496         FOR_EACH_REALCLIENT(other)
2497                 FixClientCvars(other);
2498
2499         Map_Goto_SetStr(mapvote_maps[mappos]);
2500         Map_Goto(0);
2501         alreadychangedlevel = TRUE;
2502         return TRUE;
2503 }
2504 void MapVote_CheckRules_1()
2505 {
2506         float i;
2507
2508         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2509         {
2510                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2511                 mapvote_selections[i] = 0;
2512         }
2513
2514         mapvote_voters = 0;
2515         FOR_EACH_REALCLIENT(other)
2516         {
2517                 ++mapvote_voters;
2518                 if(other.mapvote)
2519                 {
2520                         i = other.mapvote - 1;
2521                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2522                         mapvote_selections[i] = mapvote_selections[i] + 1;
2523                 }
2524         }
2525 }
2526
2527 float MapVote_CheckRules_2()
2528 {
2529         float i;
2530         float firstPlace, secondPlace;
2531         float firstPlaceVotes, secondPlaceVotes;
2532         float mapvote_voters_real;
2533         string result;
2534
2535         if(mapvote_count_real == 1)
2536                 return MapVote_Finished(0);
2537
2538         mapvote_voters_real = mapvote_voters;
2539         if(mapvote_abstain)
2540                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2541
2542         RandomSelection_Init();
2543         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2544                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2545         firstPlace = RandomSelection_chosen_float;
2546         firstPlaceVotes = RandomSelection_best_priority;
2547         //dprint("First place: ", ftos(firstPlace), "\n");
2548         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2549
2550         RandomSelection_Init();
2551         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2552                 if(i != firstPlace)
2553                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2554         secondPlace = RandomSelection_chosen_float;
2555         secondPlaceVotes = RandomSelection_best_priority;
2556         //dprint("Second place: ", ftos(secondPlace), "\n");
2557         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2558
2559         if(firstPlace == -1)
2560                 error("No first place in map vote... WTF?");
2561
2562         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2563                 return MapVote_Finished(firstPlace);
2564
2565         if(mapvote_keeptwotime)
2566                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2567                 {
2568                         float didntvote;
2569                         MapVote_TouchMask();
2570                         mapvote_message = "Now decide between the TOP TWO!";
2571                         mapvote_keeptwotime = 0;
2572                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2573                         result = strcat(result, ":", ftos(firstPlaceVotes));
2574                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2575                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2576                         didntvote = mapvote_voters;
2577                         for(i = 0; i < mapvote_count; ++i)
2578                                 if(mapvote_maps[i] != "")
2579                                 {
2580                                         didntvote -= mapvote_selections[i];
2581                                         if(i != firstPlace)
2582                                                 if(i != secondPlace)
2583                                                 {
2584                                                         result = strcat(result, ":", mapvote_maps[i]);
2585                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2586                                                         if(i < mapvote_count_real)
2587                                                         {
2588                                                                 strunzone(mapvote_maps[i]);
2589                                                                 mapvote_maps[i] = "";
2590                                                                 strunzone(mapvote_maps_pakfile[i]);
2591                                                                 mapvote_maps_pakfile[i] = "";
2592                                                         }
2593                                                 }
2594                                 }
2595                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2596                         if(autocvar_sv_eventlog)
2597                                 GameLogEcho(result);
2598                 }
2599
2600         return FALSE;
2601 }
2602 void MapVote_Tick()
2603 {
2604         float keeptwo;
2605         float totalvotes;
2606
2607         keeptwo = mapvote_keeptwotime;
2608         MapVote_CheckRules_1(); // count
2609         if(MapVote_CheckRules_2()) // decide
2610                 return;
2611
2612         totalvotes = 0;
2613         FOR_EACH_REALCLIENT(other)
2614         {
2615                 // hide scoreboard again
2616                 if(other.health != 2342)
2617                 {
2618                         other.health = 2342;
2619                         other.impulse = 0;
2620                         if(IS_REAL_CLIENT(other))
2621                         {
2622                                 msg_entity = other;
2623                                 WriteByte(MSG_ONE, SVC_FINALE);
2624                                 WriteString(MSG_ONE, "");
2625                         }
2626                 }
2627
2628                 // clear possibly invalid votes
2629                 if(mapvote_maps[other.mapvote - 1] == "")
2630                         other.mapvote = 0;
2631                 // use impulses as new vote
2632                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2633                         if(mapvote_maps[other.impulse - 1] != "")
2634                         {
2635                                 other.mapvote = other.impulse;
2636                                 MapVote_TouchVotes(other);
2637                         }
2638                 other.impulse = 0;
2639
2640                 if(other.mapvote)
2641                         ++totalvotes;
2642         }
2643
2644         MapVote_CheckRules_1(); // just count
2645 }
2646 void MapVote_Start()
2647 {
2648         // if mapvote is already running, don't do this initialization again
2649         if(mapvote_run) { return; }
2650
2651         // don't start mapvote until after playerstats gamereport is sent
2652         if(PlayerStats_GameReport_DelayMapVote) { return; }
2653
2654         // set up map information for mapvote
2655         MapInfo_Enumerate();
2656         if
2657         (
2658                 MapInfo_FilterGametype
2659                 (
2660                         MapInfo_CurrentGametype(),
2661                         MapInfo_CurrentFeatures(),
2662                         MapInfo_RequiredFlags(),
2663                         MapInfo_ForbiddenFlags(),
2664                         1
2665                 )
2666         )
2667                 { mapvote_run = TRUE; }
2668 }
2669 void MapVote_Think()
2670 {
2671         if(!mapvote_run)
2672                 return;
2673
2674         if(alreadychangedlevel)
2675                 return;
2676
2677         if(time < mapvote_nextthink)
2678                 return;
2679         //dprint("tick\n");
2680
2681         mapvote_nextthink = time + 0.5;
2682
2683         if(!mapvote_initialized)
2684         {
2685                 if(autocvar_rescan_pending == 1)
2686                 {
2687                         cvar_set("rescan_pending", "2");
2688                         localcmd("fs_rescan\nrescan_pending 3\n");
2689                         return;
2690                 }
2691                 else if(autocvar_rescan_pending == 2)
2692                 {
2693                         return;
2694                 }
2695                 else if(autocvar_rescan_pending == 3)
2696                 {
2697                         // now build missing mapinfo files
2698                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2699                                 return;
2700
2701                         // we're done, start the timer
2702                         cvar_set("rescan_pending", "0");
2703                 }
2704
2705                 mapvote_initialized = TRUE;
2706                 if(DoNextMapOverride(0))
2707                         return;
2708                 if(!autocvar_g_maplist_votable || player_count <= 0)
2709                 {
2710                         GotoNextMap(0);
2711                         return;
2712                 }
2713                 MapVote_Init();
2714         }
2715
2716         MapVote_Tick();
2717 }
2718
2719 string GotoMap(string m)
2720 {
2721         if(!MapInfo_CheckMap(m))
2722                 return "The map you chose is not available on this server.";
2723         cvar_set("nextmap", m);
2724         cvar_set("timelimit", "-1");
2725         if(mapvote_initialized || alreadychangedlevel)
2726         {
2727                 if(DoNextMapOverride(0))
2728                         return "Map switch initiated.";
2729                 else
2730                         return "Hm... no. For some reason I like THIS map more.";
2731         }
2732         else
2733                 return "Map switch will happen after scoreboard.";
2734 }
2735
2736
2737 void EndFrame()
2738 {
2739         float altime;
2740         FOR_EACH_REALCLIENT(self)
2741         {
2742                 if(IS_SPEC(self))
2743                 {
2744                         if(self.enemy.typehitsound)
2745                                 self.typehit_time = time;
2746                         else if(self.enemy.hitsound)
2747                                 self.hit_time = time;
2748                 }
2749                 else
2750                 {
2751                         if(self.typehitsound)
2752                                 self.typehit_time = time;
2753                         else if(self.hitsound)
2754                                 self.hit_time = time;
2755                 }
2756         }
2757         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2758         // add 1 frametime because after this, engine SV_Physics
2759         // increases time by a frametime and then networks the frame
2760         // add another frametime because client shows everything with
2761         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2762         // needed!
2763         FOR_EACH_CLIENT(self)
2764         {
2765                 self.hitsound = FALSE;
2766                 self.typehitsound = FALSE;
2767                 antilag_record(self, altime);
2768         }
2769 }
2770
2771
2772 /*
2773  * RedirectionThink:
2774  * returns TRUE if redirecting
2775  */
2776 float redirection_timeout;
2777 float redirection_nextthink;
2778 float RedirectionThink()
2779 {
2780         float clients_found;
2781
2782         if(redirection_target == "")
2783                 return FALSE;
2784
2785         if(!redirection_timeout)
2786         {
2787                 cvar_set("sv_public", "-2");
2788                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2789                 if(redirection_target == "self")
2790                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2791                 else
2792                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2793         }
2794
2795         if(time < redirection_nextthink)
2796                 return TRUE;
2797
2798         redirection_nextthink = time + 1;
2799
2800         clients_found = 0;
2801         FOR_EACH_REALCLIENT(self)
2802         {
2803                 // TODO add timer
2804                 print("Redirecting: sending connect command to ", self.netname, "\n");
2805                 if(redirection_target == "self")
2806                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2807                 else
2808                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2809                 ++clients_found;
2810         }
2811
2812         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2813
2814         if(time > redirection_timeout || clients_found == 0)
2815                 localcmd("\nwait; wait; wait; quit\n");
2816
2817         return TRUE;
2818 }
2819
2820 void TargetMusic_RestoreGame();
2821 void RestoreGame()
2822 {
2823         // Loaded from a save game
2824         // some things then break, so let's work around them...
2825
2826         // Progs DB (capture records)
2827         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2828
2829         // Mapinfo
2830         MapInfo_Shutdown();
2831         MapInfo_Enumerate();
2832         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2833         WeaponStats_Init();
2834
2835         TargetMusic_RestoreGame();
2836 }
2837
2838 void Shutdown()
2839 {
2840         gameover = 2;
2841
2842         if(world_initialized > 0)
2843         {
2844                 world_initialized = 0;
2845                 print("Saving persistent data...\n");
2846                 Ban_SaveBans();
2847
2848                 // playerstats with unfinished match
2849                 PlayerStats_GameReport(FALSE);
2850
2851                 if(!cheatcount_total)
2852                 {
2853                         if(autocvar_sv_db_saveasdump)
2854                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2855                         else
2856                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2857                 }
2858                 if(autocvar_developer)
2859                 {
2860                         if(autocvar_sv_db_saveasdump)
2861                                 db_dump(TemporaryDB, "server-temp.db");
2862                         else
2863                                 db_save(TemporaryDB, "server-temp.db");
2864                 }
2865                 CheatShutdown(); // must be after cheatcount check
2866                 db_close(ServerProgsDB);
2867                 db_close(TemporaryDB);
2868                 print("done!\n");
2869                 // tell the bot system the game is ending now
2870                 bot_endgame();
2871
2872                 WeaponStats_Shutdown();
2873                 MapInfo_Shutdown();
2874         }
2875         else if(world_initialized == 0)
2876         {
2877                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2878         }
2879 }