qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(autocvar__sv_init)
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(autocvar_g_maplist_shuffle)
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 239 #define BADCVAR(p) if(k == p) continue
 240
 241                 // general excludes and namespaces for server admin used cvars
 242                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 243
 244                 // internal
 245                 BADPREFIX("csqc_");
 246                 BADPREFIX("cvar_check_");
 247                 BADCVAR("gamecfg");
 248                 BADCVAR("g_configversion");
 249                 BADCVAR("g_maplist_index");
 250                 BADCVAR("halflifebsp");
 251                 BADPREFIX("sv_world");
 252
 253                 // client
 254                 BADPREFIX("chase_");
 255                 BADPREFIX("cl_");
 256                 BADPREFIX("con_");
 257                 BADPREFIX("scoreboard_");
 258                 BADPREFIX("g_campaign");
 259                 BADPREFIX("gl_");
 260                 BADPREFIX("joy");
 261                 BADPREFIX("hud_");
 262                 BADPREFIX("m_");
 263                 BADPREFIX("menu_");
 264                 BADPREFIX("net_slist_");
 265                 BADPREFIX("r_");
 266                 BADPREFIX("sbar_");
 267                 BADPREFIX("scr_");
 268                 BADPREFIX("snd_");
 269                 BADPREFIX("show");
 270                 BADPREFIX("sensitivity");
 271                 BADPREFIX("userbind");
 272                 BADPREFIX("v_");
 273                 BADPREFIX("vid_");
 274                 BADPREFIX("crosshair");
 275                 BADCVAR("mod_q3bsp_lightmapmergepower");
 276                 BADCVAR("mod_q3bsp_nolightmaps");
 277                 BADCVAR("fov");
 278                 BADCVAR("mastervolume");
 279                 BADCVAR("volume");
 280                 BADCVAR("bgmvolume");
 281
 282                 // private
 283                 BADCVAR("developer");
 284                 BADCVAR("g_banned_list");
 285                 BADCVAR("log_dest_udp");
 286                 BADCVAR("log_file");
 287                 BADCVAR("net_address");
 288                 BADCVAR("net_address_ipv6");
 289                 BADCVAR("port");
 290                 BADCVAR("savedgamecfg");
 291                 BADCVAR("serverconfig");
 292                 BADCVAR("sv_heartbeatperiod");
 293                 BADCVAR("sv_vote_master_password");
 294                 BADCVAR("sys_colortranslation");
 295                 BADCVAR("sys_specialcharactertranslation");
 296                 BADCVAR("timestamps");
 297                 BADPREFIX("developer_");
 298                 BADPREFIX("g_ban_");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_voice_flood_");
 301                 BADPREFIX("rcon_");
 302                 BADPREFIX("settemp_");
 303                 BADPREFIX("sv_allowdownloads_");
 304                 BADPREFIX("sv_autodemo");
 305                 BADPREFIX("sv_curl_");
 306                 BADPREFIX("sv_eventlog");
 307                 BADPREFIX("sv_logscores_");
 308                 BADPREFIX("sv_master");
 309                 BADPREFIX("sv_weaponstats_");
 310
 311                 // these can contain player IDs, so better hide
 312                 BADCVAR("g_forced_team_red");
 313                 BADCVAR("g_forced_team_blue");
 314                 BADCVAR("g_forced_team_yellow");
 315                 BADCVAR("g_forced_team_pink");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_checkforpacketsduringsleep");
 387                 BADCVAR("sv_timeout");
 388                 BADCVAR("welcome_message_time");
 389                 BADPREFIX("crypto_");
 390                 BADPREFIX("g_chat_");
 391                 BADPREFIX("g_ctf_captimerecord_");
 392                 BADPREFIX("g_maplist_votable_");
 393                 BADPREFIX("net_");
 394                 BADPREFIX("prvm_");
 395                 BADPREFIX("skill_");
 396                 BADPREFIX("sv_fragmessage_");
 397                 BADPREFIX("sv_maxidle_");
 398                 BADPREFIX("sv_vote_");
 399                 BADPREFIX("timelimit_");
 400
 401                 // allowed changes to server admins (please sync this to server.cfg)
 402                 // vi commands:
 403                 //   :/"impure"/,$d
 404                 //   :g!,^\/\/[^ /],d
 405                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 406                 //   :%!sort
 407                 // yes, this does contain some redundant stuff, don't really care
 408                 BADCVAR("bot_number");
 409                 BADCVAR("bot_prefix");
 410                 BADCVAR("bot_suffix");
 411                 BADCVAR("capturelimit_override");
 412                 BADCVAR("fraglimit_override");
 413                 BADCVAR("gametype");
 414                 BADCVAR("g_antilag");
 415                 BADCVAR("g_balance_teams");
 416                 BADCVAR("g_balance_teams_force");
 417                 BADCVAR("g_ban_sync_trusted_servers");
 418                 BADCVAR("g_ban_sync_uri");
 419                 BADCVAR("g_ctf_capture_limit");
 420                 BADCVAR("g_ctf_ignore_frags");
 421                 BADCVAR("g_ctf_win_mode");
 422                 BADCVAR("g_domination_point_limit");
 423                 BADCVAR("g_fullbrightitems");
 424                 BADCVAR("g_fullbrightplayers");
 425                 BADCVAR("g_keyhunt_point_limit");
 426                 BADCVAR("g_keyhunt_teams_override");
 427                 BADCVAR("g_lms_lives_override");
 428                 BADCVAR("g_maplist");
 429                 BADCVAR("g_maplist_check_waypoints");
 430                 BADCVAR("g_maplist_mostrecent_count");
 431                 BADCVAR("g_maplist_shuffle");
 432                 BADCVAR("g_maplist_votable");
 433                 BADCVAR("g_maplist_votable_abstain");
 434                 BADCVAR("g_maplist_votable_nodetail");
 435                 BADCVAR("g_maplist_votable_suggestions");
 436                 BADCVAR("g_minstagib");
 437                 BADCVAR("g_nexball_goallimit");
 438                 BADCVAR("g_runematch_point_limit");
 439                 BADCVAR("g_start_delay");
 440                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 441                 BADCVAR("hostname");
 442                 BADCVAR("log_file");
 443                 BADCVAR("maxplayers");
 444                 BADCVAR("g_maxplayers");
 445                 BADCVAR("minplayers");
 446                 BADCVAR("net_address");
 447                 BADCVAR("port");
 448                 BADCVAR("rcon_password");
 449                 BADCVAR("rcon_restricted_commands");
 450                 BADCVAR("rcon_restricted_password");
 451                 BADCVAR("skill");
 452                 BADCVAR("sv_adminnick");
 453                 BADCVAR("sv_autoscreenshot");
 454                 BADCVAR("sv_curl_defaulturl");
 455                 BADCVAR("sv_defaultcharacter");
 456                 BADCVAR("sv_defaultplayercolors");
 457                 BADCVAR("sv_defaultplayermodel");
 458                 BADCVAR("sv_defaultplayerskin");
 459                 BADCVAR("sv_maxidle");
 460                 BADCVAR("sv_maxrate");
 461                 BADCVAR("sv_motd");
 462                 BADCVAR("sv_public");
 463                 BADCVAR("sv_ready_restart");
 464                 BADCVAR("sv_status_privacy");
 465                 BADCVAR("sv_vote_call");
 466                 BADCVAR("sv_vote_commands");
 467                 BADCVAR("sv_vote_majority_factor");
 468                 BADCVAR("sv_vote_master");
 469                 BADCVAR("sv_vote_master_commands");
 470                 BADCVAR("sv_vote_master_password");
 471                 BADCVAR("sv_vote_simple_majority_factor");
 472                 BADCVAR("timelimit_override");
 473                 BADCVAR("g_warmup");
 474                 BADPREFIX("g_warmup_");
 475                 BADCVAR("teamplay_mode");
 476
 477                 if(autocvar_g_minstagib)
 478                 {
 479                         BADCVAR("g_grappling_hook");
 480                         BADCVAR("g_jetpack");
 481                 }
 482 #undef BADPREFIX
 483 #undef BADCVAR
 484
 485                 if(pureadding)
 486                 {
 487                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 488                         if(strlen(cvar_purechanges) > 16384)
 489                         {
 490                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 491                                 pureadding = 0;
 492                         }
 493                 }
 494                 ++cvar_purechanges_count;
 495                 // WARNING: this variable is used for the server list
 496                 // NEVER dare to skip this code!
 497                 // Hacks to intentionally appearing as "pure server" even though you DO have
 498                 // modified settings may be punished by removal from the server list.
 499                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 500                 // though.
 501         }
 502         buf_del(h);
 503         if(cvar_changes == "")
 504                 cvar_changes = "// this server runs at default server settings\n";
 505         else
 506                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 507         cvar_changes = strzone(cvar_changes);
 508         if(cvar_purechanges == "")
 509                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 510         else
 511                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 512         cvar_purechanges = strzone(cvar_purechanges);
 513 }
 514
 515 void detect_maptype()
 516 {
 517 #if 0
 518         vector o, v;
 519         float i;
 520
 521         for(;;)
 522         {
 523                 o = world.mins;
 524                 o_x += random() * (world.maxs_x - world.mins_x);
 525                 o_y += random() * (world.maxs_y - world.mins_y);
 526                 o_z += random() * (world.maxs_z - world.mins_z);
 527
 528                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 529                 if(trace_fraction == 1)
 530                         continue;
 531
 532                 v = trace_endpos;
 533
 534                 for(i = 0; i < 64; i += 4)
 535                 {
 536                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 537         if(trace_fraction == 1)
 538                 continue;
 539                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 540                 }
 541
 542                 break;
 543         }
 544 #endif
 545 }
 546
 547 entity randomseed;
 548 float RandomSeed_Send(entity to, float sf)
 549 {
 550         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 551         WriteShort(MSG_ENTITY, self.cnt);
 552         return TRUE;
 553 }
 554 void RandomSeed_Think()
 555 {
 556         self.cnt = bound(0, floor(random() * 65536), 65535);
 557         self.nextthink = time + 5;
 558
 559         self.SendFlags |= 1;
 560 }
 561 void RandomSeed_Spawn()
 562 {
 563         randomseed = spawn();
 564         randomseed.think = RandomSeed_Think;
 565         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 566
 567         entity oldself;
 568         oldself = self;
 569         self = randomseed;
 570         self.think(); // sets random seed and nextthink
 571         self = oldself;
 572 }
 573
 574 void spawnfunc___init_dedicated_server(void)
 575 {
 576         // handler for _init/_init map (only for dedicated server initialization)
 577
 578         world_initialized = -1; // don't complain
 579         cvar = cvar_normal;
 580         cvar_string = cvar_string_normal;
 581         cvar_set = cvar_set_normal;
 582
 583         remove = remove_unsafely;
 584
 585         entity e;
 586         e = spawn();
 587         e.think = GotoFirstMap;
 588         e.nextthink = time; // this is usually 1 at this point
 589
 590         e = spawn();
 591         e.classname = "info_player_deathmatch"; // safeguard against player joining
 592
 593         self.classname = "worldspawn"; // safeguard against various stuff ;)
 594
 595         MapInfo_Enumerate();
 596         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 597 }
 598
 599 void Map_MarkAsRecent(string m);
 600 float world_already_spawned;
 601 void RegisterWeapons();
 602 void Nagger_Init();
 603 void ClientInit_Spawn();
 604 void WeaponStats_Init();
 605 void WeaponStats_Shutdown();
 606 void spawnfunc_worldspawn (void)
 607 {
 608         float fd, l, i, j, n;
 609         string s, col;
 610
 611         cvar = cvar_normal;
 612         cvar_string = cvar_string_normal;
 613         cvar_set = cvar_set_normal;
 614
 615         if(world_already_spawned)
 616                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 617         world_already_spawned = TRUE;
 618
 619         remove = remove_safely; // during spawning, watch what you remove!
 620
 621         check_unacceptable_compiler_bugs();
 622
 623         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 624
 625         compressShortVector_init();
 626
 627         allowed_to_spawn = TRUE;
 628
 629         local entity head;
 630         head = nextent(world);
 631         maxclients = 0;
 632         while(head)
 633         {
 634                 ++maxclients;
 635                 head = nextent(head);
 636         }
 637
 638         // needs to be done so early as they would still spawn
 639         RegisterWeapons();
 640
 641         ServerProgsDB = db_load("server.db");
 642
 643         TemporaryDB = db_create();
 644
 645         // 0 normal
 646         lightstyle(0, "m");
 647
 648         // 1 FLICKER (first variety)
 649         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 650
 651         // 2 SLOW STRONG PULSE
 652         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 653
 654         // 3 CANDLE (first variety)
 655         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 656
 657         // 4 FAST STROBE
 658         lightstyle(4, "mamamamamama");
 659
 660         // 5 GENTLE PULSE 1
 661         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 662
 663         // 6 FLICKER (second variety)
 664         lightstyle(6, "nmonqnmomnmomomno");
 665
 666         // 7 CANDLE (second variety)
 667         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 668
 669         // 8 CANDLE (third variety)
 670         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 671
 672         // 9 SLOW STROBE (fourth variety)
 673         lightstyle(9, "aaaaaaaazzzzzzzz");
 674
 675         // 10 FLUORESCENT FLICKER
 676         lightstyle(10, "mmamammmmammamamaaamammma");
 677
 678         // 11 SLOW PULSE NOT FADE TO BLACK
 679         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 680
 681         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 682
 683         // 63 testing
 684         lightstyle(63, "a");
 685
 686         if(autocvar_g_campaign)
 687                 CampaignPreInit();
 688
 689         Map_MarkAsRecent(mapname);
 690
 691         precache_model ("null"); // we need this one before InitGameplayMode
 692         InitGameplayMode();
 693         readlevelcvars();
 694         GrappleHookInit();
 695         ElectroInit();
 696         LaserInit();
 697
 698         player_count = 0;
 699         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 700         if(bot_waypoints_for_items == 1)
 701                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 702                         bot_waypoints_for_items = 0;
 703
 704         // for setting by mapinfo
 705         q3acompat_machineshotgunswap = autocvar_sv_q3acompat_machineshotgunswap;
 706         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 707
 708         precache();
 709
 710         WaypointSprite_Init();
 711
 712         //if (g_domination)
 713         //      dom_init();
 714
 715         GameLogInit(); // prepare everything
 716         if(autocvar_sv_eventlog)
 717         {
 718                 s = strcat(ftos(autocvar_sv_eventlog_files_counter), ".");
 719                 s = strcat(s, ftos(random()));
 720                 matchid = strzone(s);
 721
 722                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 723                 s = ":gameinfo:mutators:LIST";
 724
 725                 ret_string = s;
 726                 MUTATOR_CALLHOOK(BuildMutatorsString);
 727                 s = ret_string;
 728
 729                 // simple, probably not good in the mutator system
 730                 if(autocvar_g_grappling_hook)
 731                         s = strcat(s, ":grappling_hook");
 732
 733                 // initialiation stuff, not good in the mutator system
 734                 if(!autocvar_g_use_ammunition)
 735                         s = strcat(s, ":no_use_ammunition");
 736
 737                 // initialiation stuff, not good in the mutator system
 738                 if(!autocvar_g_pickup_items)
 739                         s = strcat(s, ":no_pickup_items");
 740
 741                 // initialiation stuff, not good in the mutator system
 742                 if(autocvar_g_weaponarena != "0")
 743                         s = strcat(s, ":", autocvar_g_weaponarena, "_arena");
 744
 745                 // TODO to mutator system
 746                 if(autocvar_g_norecoil)
 747                         s = strcat(s, ":norecoil");
 748
 749                 // TODO to mutator system
 750                 if(autocvar_g_midair)
 751                         s = strcat(s, ":midair");
 752
 753                 // TODO to mutator system
 754                 if(autocvar_g_minstagib)
 755                         s = strcat(s, ":minstagib");
 756
 757                 GameLogEcho(s);
 758                 GameLogEcho(":gameinfo:end");
 759         }
 760         else
 761                 matchid = strzone(ftos(random()));
 762
 763         cvar_set("nextmap", "");
 764
 765         SetDefaultAlpha();
 766
 767         if(autocvar_g_campaign)
 768                 CampaignPostInit();
 769
 770         fteqcc_testbugs();
 771
 772         Ban_LoadBans();
 773
 774         MapInfo_Enumerate();
 775         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 776
 777         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 778         {
 779                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 780                 if(fd != -1)
 781                 {
 782                         while((s = fgets(fd)))
 783                         {
 784                                 l = tokenize_console(s);
 785                                 if(l < 2)
 786                                         continue;
 787                                 if(argv(0) == "cd")
 788                                 {
 789                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 790                                         print("  cdtrack ", argv(2), "\n");
 791                                 }
 792                                 else if(argv(0) == "fog")
 793                                 {
 794                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 795                                         print("  \"fog\" \"", s, "\"\n");
 796                                 }
 797                                 else if(argv(0) == "set")
 798                                 {
 799                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 800                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 801                                 }
 802                                 else if(argv(0) != "//")
 803                                 {
 804                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 805                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 806                                 }
 807                         }
 808                         fclose(fd);
 809                 }
 810         }
 811
 812         WeaponStats_Init();
 813
 814         addstat(STAT_WEAPONS, AS_INT, weapons);
 815         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 816         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 817         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 818         Nagger_Init();
 819
 820         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 821         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 822         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 823         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 824         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 825         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 826         addstat(STAT_BULLETS_LOADED, AS_INT, sniperrifle_bulletcounter);
 827         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 828         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 829         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 830         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 831
 832         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 833         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 834
 835         if(g_ca || g_freezetag)
 836         {
 837                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 838                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 839                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 840                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 841         }
 842         if(g_freezetag)
 843         {
 844                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 845                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 846         }
 847
 848         // g_movementspeed hack
 849         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 850         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 851         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 852         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 853
 854         next_pingtime = time + 5;
 855
 856         detect_maptype();
 857
 858         lsmaps_reply = "^7Maps available: ";
 859         lsnewmaps_reply = "^7Maps without a record set: ";
 860         for(i = 0, j = 0; i < MapInfo_count; ++i)
 861         {
 862                 if(MapInfo_Get_ByID(i))
 863                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 864                         {
 865                                 if(mod(i, 2))
 866                                         col = "^2";
 867                                 else
 868                                         col = "^3";
 869                                 ++j;
 870                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 871                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 872                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 873                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 874                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 875                         }
 876         }
 877         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 878         if (!g_race && !g_cts)
 879                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 880         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 881
 882         maplist_reply = "^7Maps in list: ";
 883         n = tokenize_console(autocvar_g_maplist);
 884         for(i = 0, j = 0; i < n; ++i)
 885         {
 886                 if(MapInfo_CheckMap(argv(i)))
 887                 {
 888                         if(mod(j, 2))
 889                                 col = "^2";
 890                         else
 891                                 col = "^3";
 892                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 893                         ++j;
 894                 }
 895         }
 896         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 897         MapInfo_ClearTemps();
 898
 899         for(i = 0; i < 10; ++i)
 900         {
 901                 records_reply[i] = strzone(getrecords(i));
 902         }
 903         if(g_cts)
 904                 ladder_reply = strzone(getladder());
 905
 906         rankings_reply = strzone(getrankings());
 907
 908         ClientInit_Spawn();
 909         RandomSeed_Spawn();
 910         PingPLReport_Spawn();
 911
 912         CheatInit();
 913
 914         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 915
 916         // fill sv_curl_serverpackages from .serverpackage files
 917         if(autocvar_sv_curl_serverpackages_auto)
 918         {
 919                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 920                 s = "";
 921                 if(fd >= 0)
 922                 {
 923                         j = search_getsize(fd);
 924                         for(i = 0; i < j; ++i)
 925                                 s = strcat(s, " ", search_getfilename(fd, i));
 926                         search_end(fd);
 927                 }
 928                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 929         }
 930
 931         PlayerStats_Init();
 932
 933         world_initialized = 1;
 934 }
 935
 936 void spawnfunc_light (void)
 937 {
 938         //makestatic (self); // Who the f___ did that?
 939         remove(self);
 940 }
 941
 942 float TryFile( string pFilename )
 943 {
 944         local float lHandle;
 945         dprint("TryFile(\"", pFilename, "\")\n");
 946         lHandle = fopen( pFilename, FILE_READ );
 947         if( lHandle != -1 ) {
 948                 fclose( lHandle );
 949                 return TRUE;
 950         } else {
 951                 return FALSE;
 952         }
 953 };
 954
 955 string GetGametype()
 956 {
 957         return GametypeNameFromType(game);
 958 }
 959
 960 string getmapname_stored;
 961 string GetMapname()
 962 {
 963         return mapname;
 964 }
 965
 966 float Map_Count, Map_Current;
 967 string Map_Current_Name;
 968
 969 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 970 float GetMaplistPosition()
 971 {
 972         float pos, idx;
 973         string map;
 974
 975         map = GetMapname();
 976         idx = autocvar_g_maplist_index;
 977
 978         if(idx >= 0)
 979                 if(idx < Map_Count)
 980                         if(map == argv(idx))
 981                                 return idx;
 982
 983         for(pos = 0; pos < Map_Count; ++pos)
 984                 if(map == argv(pos))
 985                         return pos;
 986
 987         // resume normal maplist rotation if current map is not in g_maplist
 988         return idx;
 989 }
 990
 991 float MapHasRightSize(string map)
 992 {
 993         float fh;
 994         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 995         if(autocvar_g_maplist_check_waypoints)
 996         {
 997                 dprint("checkwp "); dprint(map);
 998                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 999                 if(fh < 0)
1000                 {
1001                         dprint(": no waypoints\n");
1002                         return FALSE;
1003                 }
1004                 dprint(": has waypoints\n");
1005                 fclose(fh);
1006         }
1007
1008         // open map size restriction file
1009         dprint("opensize "); dprint(map);
1010         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1011         if(fh >= 0)
1012         {
1013                 float mapmin, mapmax;
1014                 dprint(": ok, ");
1015                 mapmin = stof(fgets(fh));
1016                 mapmax = stof(fgets(fh));
1017                 fclose(fh);
1018                 if(player_count < mapmin)
1019                 {
1020                         dprint("not enough\n");
1021                         return FALSE;
1022                 }
1023                 if(player_count > mapmax)
1024                 {
1025                         dprint("too many\n");
1026                         return FALSE;
1027                 }
1028                 dprint("right size\n");
1029                 return TRUE;
1030         }
1031         dprint(": not found\n");
1032         return TRUE;
1033 }
1034
1035 string Map_Filename(float position)
1036 {
1037         return strcat("maps/", argv(position), ".bsp");
1038 }
1039
1040 string strwords(string s, float w)
1041 {
1042         float endpos;
1043         for(endpos = 0; w && endpos >= 0; --w)
1044                 endpos = strstrofs(s, " ", endpos + 1);
1045         if(endpos < 0)
1046                 return s;
1047         else
1048                 return substring(s, 0, endpos);
1049 }
1050
1051 float strhasword(string s, string w)
1052 {
1053         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1054 }
1055
1056 void Map_MarkAsRecent(string m)
1057 {
1058         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1059 }
1060
1061 float Map_IsRecent(string m)
1062 {
1063         return strhasword(autocvar_g_maplist_mostrecent, m);
1064 }
1065
1066 float Map_Check(float position, float pass)
1067 {
1068         string filename;
1069         string map_next;
1070         map_next = argv(position);
1071         if(pass <= 1)
1072         {
1073                 if(Map_IsRecent(map_next))
1074                         return 0;
1075         }
1076         filename = Map_Filename(position);
1077         if(MapInfo_CheckMap(map_next))
1078         {
1079                 if(pass == 2)
1080                         return 1;
1081                 if(MapHasRightSize(map_next))
1082                         return 1;
1083                 return 0;
1084         }
1085         else
1086                 dprint( "Couldn't select '", filename, "'..\n" );
1087
1088         return 0;
1089 }
1090
1091 void Map_Goto_SetStr(string nextmapname)
1092 {
1093         if(getmapname_stored != "")
1094                 strunzone(getmapname_stored);
1095         if(nextmapname == "")
1096                 getmapname_stored = "";
1097         else
1098                 getmapname_stored = strzone(nextmapname);
1099 }
1100
1101 void Map_Goto_SetFloat(float position)
1102 {
1103         cvar_set("g_maplist_index", ftos(position));
1104         Map_Goto_SetStr(argv(position));
1105 }
1106
1107 void GameResetCfg()
1108 {
1109         // settings persist, except...
1110         localcmd("\nsettemp_restore\n");
1111 };
1112
1113 void Map_Goto()
1114 {
1115         GameResetCfg();
1116         MapInfo_LoadMap(getmapname_stored);
1117 }
1118
1119 // return codes of map selectors:
1120 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1121 //   -2 = permanent failure
1122 float() MaplistMethod_Iterate = // usual method
1123 {
1124         float pass, i;
1125
1126         for(pass = 1; pass <= 2; ++pass)
1127         {
1128                 for(i = 1; i < Map_Count; ++i)
1129                 {
1130                         float mapindex;
1131                         mapindex = mod(i + Map_Current, Map_Count);
1132                         if(Map_Check(mapindex, pass))
1133                                 return mapindex;
1134                 }
1135         }
1136         return -1;
1137 }
1138
1139 float() MaplistMethod_Repeat = // fallback method
1140 {
1141         if(Map_Check(Map_Current, 2))
1142                 return Map_Current;
1143         return -2;
1144 }
1145
1146 float() MaplistMethod_Random = // random map selection
1147 {
1148         float i, imax;
1149
1150         imax = 42;
1151
1152         for(i = 0; i <= imax; ++i)
1153         {
1154                 float mapindex;
1155                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1156                 if(Map_Check(mapindex, 1))
1157                         return mapindex;
1158         }
1159         return -1;
1160 }
1161
1162 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1163 // the exponent sets a bias on the map selection:
1164 // the higher the exponent, the less likely "shortly repeated" same maps are
1165 {
1166         float i, j, imax, insertpos;
1167
1168         imax = 42;
1169
1170         for(i = 0; i <= imax; ++i)
1171         {
1172                 string newlist;
1173
1174                 // now reinsert this at another position
1175                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1176                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1177                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1178                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1179
1180                 // insert the current map there
1181                 newlist = "";
1182                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1183                         newlist = strcat(newlist, " ", argv(j));
1184                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1185                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1186                         newlist = strcat(newlist, " ", argv(j));
1187                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1188                 cvar_set("g_maplist", newlist);
1189                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1190
1191                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1192                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1193                 if(Map_Check(Map_Current, 1))
1194                         return Map_Current;
1195         }
1196         return -1;
1197 }
1198
1199 void Maplist_Init()
1200 {
1201         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1202         if(Map_Count == 0)
1203         {
1204                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1205                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1206                 if(autocvar_g_maplist_shuffle)
1207                         ShuffleMaplist();
1208                 localcmd("\nmenu_cmd sync\n");
1209                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1210         }
1211         if(Map_Count == 0)
1212                 error("empty maplist, cannot select a new map");
1213         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1214
1215         if(Map_Current_Name)
1216                 strunzone(Map_Current_Name);
1217         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1218         // this may or may not be correct, but who cares, in the worst case a map
1219         // isn't chosen in the first pass that should have been
1220 }
1221
1222 string GetNextMap()
1223 {
1224         float nextMap;
1225
1226         Maplist_Init();
1227         nextMap = -1;
1228
1229         if(nextMap == -1)
1230                 if(autocvar_g_maplist_shuffle > 0)
1231                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1232
1233         if(nextMap == -1)
1234                 if(autocvar_g_maplist_selectrandom)
1235                         nextMap = MaplistMethod_Random();
1236
1237         if(nextMap == -1)
1238                 nextMap = MaplistMethod_Iterate();
1239
1240         if(nextMap == -1)
1241                 nextMap = MaplistMethod_Repeat();
1242
1243         if(nextMap >= 0)
1244         {
1245                 Map_Goto_SetFloat(nextMap);
1246                 return getmapname_stored;
1247         }
1248
1249         return "";
1250 };
1251
1252 float DoNextMapOverride()
1253 {
1254         if(autocvar_g_campaign)
1255         {
1256                 CampaignPostIntermission();
1257                 alreadychangedlevel = TRUE;
1258                 return TRUE;
1259         }
1260         if(autocvar_quit_when_empty)
1261         {
1262                 if(player_count <= currentbots)
1263                 {
1264                         localcmd("quit\n");
1265                         alreadychangedlevel = TRUE;
1266                         return TRUE;
1267                 }
1268         }
1269         if(autocvar_quit_and_redirect != "")
1270         {
1271                 redirection_target = strzone(autocvar_quit_and_redirect);
1272                 alreadychangedlevel = TRUE;
1273                 return TRUE;
1274         }
1275         if (autocvar_samelevel) // if samelevel is set, stay on same level
1276         {
1277                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1278                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1279                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1280                 localcmd("restart\n");
1281                 //changelevel (mapname);
1282                 alreadychangedlevel = TRUE;
1283                 return TRUE;
1284         }
1285         if(autocvar_nextmap != "")
1286                 if(MapInfo_CheckMap(autocvar_nextmap))
1287                 {
1288                         Map_Goto_SetStr(autocvar_nextmap);
1289                         Map_Goto();
1290                         alreadychangedlevel = TRUE;
1291                         return TRUE;
1292                 }
1293         if(autocvar_lastlevel)
1294         {
1295                 GameResetCfg();
1296                 localcmd("set lastlevel 0\ntogglemenu\n");
1297                 alreadychangedlevel = TRUE;
1298                 return TRUE;
1299         }
1300         return FALSE;
1301 };
1302
1303 void GotoNextMap()
1304 {
1305         //local string nextmap;
1306         //local float n, nummaps;
1307         //local string s;
1308         if (alreadychangedlevel)
1309                 return;
1310         alreadychangedlevel = TRUE;
1311
1312         {
1313                 string nextMap;
1314                 float allowReset;
1315
1316                 for(allowReset = 1; allowReset >= 0; --allowReset)
1317                 {
1318                         nextMap = GetNextMap();
1319                         if(nextMap != "")
1320                                 break;
1321
1322                         if(allowReset)
1323                         {
1324                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1325                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1326                                 if(autocvar_g_maplist_shuffle)
1327                                         ShuffleMaplist();
1328                                 localcmd("\nmenu_cmd sync\n");
1329                         }
1330                         else
1331                         {
1332                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1333                         }
1334                 }
1335                 Map_Goto();
1336         }
1337 };
1338
1339
1340 /*
1341 ============
1342 IntermissionThink
1343
1344 When the player presses attack or jump, change to the next level
1345 ============
1346 */
1347 .float autoscreenshot;
1348 void() MapVote_Start;
1349 void() MapVote_Think;
1350 float mapvote_initialized;
1351 void IntermissionThink()
1352 {
1353         FixIntermissionClient(self);
1354
1355         if(autocvar_sv_autoscreenshot)
1356         if(self.autoscreenshot > 0)
1357         if(time > self.autoscreenshot)
1358         {
1359                 self.autoscreenshot = -1;
1360                 if(clienttype(self) == CLIENTTYPE_REAL)
1361                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1362                 return;
1363         }
1364
1365         if (time < intermission_exittime)
1366                 return;
1367
1368         if(!mapvote_initialized)
1369                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1370                         return;
1371
1372         MapVote_Start();
1373 };
1374
1375 /*
1376 ============
1377 FindIntermission
1378
1379 Returns the entity to view from
1380 ============
1381 */
1382 /*
1383 entity FindIntermission()
1384 {
1385         local   entity spot;
1386         local   float cyc;
1387
1388 // look for info_intermission first
1389         spot = find (world, classname, "info_intermission");
1390         if (spot)
1391         {       // pick a random one
1392                 cyc = random() * 4;
1393                 while (cyc > 1)
1394                 {
1395                         spot = find (spot, classname, "info_intermission");
1396                         if (!spot)
1397                                 spot = find (spot, classname, "info_intermission");
1398                         cyc = cyc - 1;
1399                 }
1400                 return spot;
1401         }
1402
1403 // then look for the start position
1404         spot = find (world, classname, "info_player_start");
1405         if (spot)
1406                 return spot;
1407
1408 // testinfo_player_start is only found in regioned levels
1409         spot = find (world, classname, "testplayerstart");
1410         if (spot)
1411                 return spot;
1412
1413 // then look for the start position
1414         spot = find (world, classname, "info_player_deathmatch");
1415         if (spot)
1416                 return spot;
1417
1418         //objerror ("FindIntermission: no spot");
1419         return world;
1420 };
1421 */
1422
1423 /*
1424 ===============================================================================
1425
1426 RULES
1427
1428 ===============================================================================
1429 */
1430
1431 void DumpStats(float final)
1432 {
1433         float file;
1434         string s;
1435         float to_console;
1436         float to_eventlog;
1437         float to_file;
1438         float i;
1439         entity e;
1440
1441         to_console = autocvar_sv_logscores_console;
1442         to_eventlog = autocvar_sv_eventlog;
1443         to_file = autocvar_sv_logscores_file;
1444
1445         if(!final)
1446         {
1447                 to_console = TRUE; // always print printstats replies
1448                 to_eventlog = FALSE; // but never print them to the event log
1449         }
1450
1451         if(to_eventlog)
1452                 if(autocvar_sv_eventlog_console)
1453                         to_console = FALSE; // otherwise we get the output twice
1454
1455         if(final)
1456                 s = ":scores:";
1457         else
1458                 s = ":status:";
1459         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1460
1461         if(to_console)
1462                 print(s, "\n");
1463         if(to_eventlog)
1464                 GameLogEcho(s);
1465         if(to_file)
1466         {
1467                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1468                 if(file == -1)
1469                         to_file = FALSE;
1470                 else
1471                         fputs(file, strcat(s, "\n"));
1472         }
1473
1474         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1475         if(to_console)
1476                 print(s, "\n");
1477         if(to_eventlog)
1478                 GameLogEcho(s);
1479         if(to_file)
1480                 fputs(file, strcat(s, "\n"));
1481
1482         FOR_EACH_CLIENT(other)
1483         {
1484                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1485                 {
1486                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1487                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1488                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1489                                 s = strcat(s, ftos(other.team), ":");
1490                         else
1491                                 s = strcat(s, "spectator:");
1492
1493                         if(to_console)
1494                                 print(s, other.netname, "\n");
1495                         if(to_eventlog)
1496                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1497                         if(to_file)
1498                                 fputs(file, strcat(s, other.netname, "\n"));
1499                 }
1500         }
1501
1502         if(teams_matter)
1503         {
1504                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1505                 if(to_console)
1506                         print(s, "\n");
1507                 if(to_eventlog)
1508                         GameLogEcho(s);
1509                 if(to_file)
1510                         fputs(file, strcat(s, "\n"));
1511
1512                 for(i = 1; i < 16; ++i)
1513                 {
1514                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1515                         s = strcat(s, ":", ftos(i));
1516                         if(to_console)
1517                                 print(s, "\n");
1518                         if(to_eventlog)
1519                                 GameLogEcho(s);
1520                         if(to_file)
1521                                 fputs(file, strcat(s, "\n"));
1522                 }
1523         }
1524
1525         if(to_console)
1526                 print(":end\n");
1527         if(to_eventlog)
1528                 GameLogEcho(":end");
1529         if(to_file)
1530         {
1531                 fputs(file, ":end\n");
1532                 fclose(file);
1533         }
1534 }
1535
1536 void FixIntermissionClient(entity e)
1537 {
1538         string s;
1539         if(!e.autoscreenshot) // initial call
1540         {
1541                 e.angles = e.v_angle;
1542                 e.angles_x = -e.angles_x;
1543                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1544                 e.health = -2342;
1545                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1546                 e.solid = SOLID_NOT;
1547                 e.movetype = MOVETYPE_NONE;
1548                 e.takedamage = DAMAGE_NO;
1549                 if(e.weaponentity)
1550                 {
1551                         e.weaponentity.effects = EF_NODRAW;
1552                         if (e.weaponentity.weaponentity)
1553                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1554                 }
1555                 if(clienttype(e) == CLIENTTYPE_REAL)
1556                 {
1557                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1558                         s = autocvar_sv_intermission_cdtrack;
1559                         if(s != "")
1560                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1561                         msg_entity = e;
1562                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1563                 }
1564         }
1565
1566         //e.velocity = '0 0 0';
1567         //e.fixangle = TRUE;
1568
1569         // TODO halt weapon animation
1570 }
1571
1572
1573 /*
1574 go to the next level for deathmatch
1575 only called if a time or frag limit has expired
1576 */
1577 void NextLevel()
1578 {
1579         gameover = TRUE;
1580
1581         intermission_running = 1;
1582
1583 // enforce a wait time before allowing changelevel
1584         if(player_count > 0)
1585                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1586         else
1587                 intermission_exittime = -1;
1588
1589         /*
1590         WriteByte (MSG_ALL, SVC_CDTRACK);
1591         WriteByte (MSG_ALL, 3);
1592         WriteByte (MSG_ALL, 3);
1593         // done in FixIntermission
1594         */
1595
1596         //pos = FindIntermission ();
1597
1598         VoteReset();
1599
1600         DumpStats(TRUE);
1601
1602         // send statistics
1603         entity e;
1604         PlayerStats_EndMatch(1);
1605         FOR_EACH_CLIENT(e)
1606                 PlayerStats_AddGlobalInfo(e);
1607         PlayerStats_Shutdown();
1608
1609         if(autocvar_sv_eventlog)
1610                 GameLogEcho(":gameover");
1611
1612         GameLogClose();
1613
1614         FOR_EACH_PLAYER(other) {
1615                 FixIntermissionClient(other);
1616                 if(other.winning)
1617                         bprint(other.netname, " ^7wins.\n");
1618         }
1619
1620         if(autocvar_g_campaign)
1621                 CampaignPreIntermission();
1622
1623         localcmd("\nsv_hook_gameend\n");
1624 }
1625
1626 /*
1627 ============
1628 CheckRules_Player
1629
1630 Exit deathmatch games upon conditions
1631 ============
1632 */
1633 void CheckRules_Player()
1634 {
1635         if (gameover)   // someone else quit the game already
1636                 return;
1637
1638         if(self.deadflag == DEAD_NO)
1639                 self.play_time += frametime;
1640
1641         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1642         //   (div0: and that in CheckRules_World please)
1643 };
1644
1645 float checkrules_equality;
1646 float checkrules_suddendeathwarning;
1647 float checkrules_suddendeathend;
1648 float checkrules_overtimesadded; //how many overtimes have been already added
1649
1650 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1651 float WINNING_YES = 1; // winner found
1652 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1653 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1654
1655 float InitiateSuddenDeath()
1656 {
1657         // Check first whether normal overtimes could be added before initiating suddendeath mode
1658         // - for this timelimit_overtime needs to be >0 of course
1659         // - also check the winning condition calculated in the previous frame and only add normal overtime
1660         //   again, if at the point at which timelimit would be extended again, still no winner was found
1661         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1662         {
1663                 return 1; // need to call InitiateOvertime later
1664         }
1665         else
1666         {
1667                 if(!checkrules_suddendeathend)
1668                 {
1669                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1670                         if(g_race && !g_race_qualifying)
1671                                 race_StartCompleting();
1672                 }
1673                 return 0;
1674         }
1675 }
1676
1677 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1678 {
1679         ++checkrules_overtimesadded;
1680         //add one more overtime by simply extending the timelimit
1681         float tl;
1682         tl = autocvar_timelimit;
1683         tl += autocvar_timelimit_overtime;
1684         cvar_set("timelimit", ftos(tl));
1685         string minutesPlural;
1686         if (autocvar_timelimit_overtime == 1)
1687                 minutesPlural = " ^3minute";
1688         else
1689                 minutesPlural = " ^3minutes";
1690
1691         bcenterprint(
1692                 strcat(
1693                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1694                         ftos(autocvar_timelimit_overtime),
1695                         minutesPlural,
1696                         " to the game!"
1697                 )
1698         );
1699 }
1700
1701 float GetWinningCode(float fraglimitreached, float equality)
1702 {
1703         if(autocvar_g_campaign == 1)
1704                 if(fraglimitreached)
1705                         return WINNING_YES;
1706                 else
1707                         return WINNING_NO;
1708
1709         else
1710                 if(equality)
1711                         if(fraglimitreached)
1712                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1713                         else
1714                                 return WINNING_NEVER;
1715                 else
1716                         if(fraglimitreached)
1717                                 return WINNING_YES;
1718                         else
1719                                 return WINNING_NO;
1720 }
1721
1722 // set the .winning flag for exactly those players with a given field value
1723 void SetWinners(.float field, float value)
1724 {
1725         entity head;
1726         FOR_EACH_PLAYER(head)
1727                 head.winning = (head.field == value);
1728 }
1729
1730 // set the .winning flag for those players with a given field value
1731 void AddWinners(.float field, float value)
1732 {
1733         entity head;
1734         FOR_EACH_PLAYER(head)
1735                 if(head.field == value)
1736                         head.winning = 1;
1737 }
1738
1739 // clear the .winning flags
1740 void ClearWinners(void)
1741 {
1742         entity head;
1743         FOR_EACH_PLAYER(head)
1744                 head.winning = 0;
1745 }
1746
1747 // Onslaught winning condition:
1748 // game terminates if only one team has a working generator (or none)
1749 float WinningCondition_Onslaught()
1750 {
1751         entity head;
1752         local float t1, t2, t3, t4;
1753
1754         WinningConditionHelper(); // set worldstatus
1755
1756         if(inWarmupStage)
1757                 return WINNING_NO;
1758
1759         // first check if the game has ended
1760         t1 = t2 = t3 = t4 = 0;
1761         head = find(world, classname, "onslaught_generator");
1762         while (head)
1763         {
1764                 if (head.health > 0)
1765                 {
1766                         if (head.team == COLOR_TEAM1) t1 = 1;
1767                         if (head.team == COLOR_TEAM2) t2 = 1;
1768                         if (head.team == COLOR_TEAM3) t3 = 1;
1769                         if (head.team == COLOR_TEAM4) t4 = 1;
1770                 }
1771                 head = find(head, classname, "onslaught_generator");
1772         }
1773         if (t1 + t2 + t3 + t4 < 2)
1774         {
1775                 // game over, only one team remains (or none)
1776                 ClearWinners();
1777                 if (t1) SetWinners(team, COLOR_TEAM1);
1778                 if (t2) SetWinners(team, COLOR_TEAM2);
1779                 if (t3) SetWinners(team, COLOR_TEAM3);
1780                 if (t4) SetWinners(team, COLOR_TEAM4);
1781                 dprint("Have a winner, ending game.\n");
1782                 return WINNING_YES;
1783         }
1784
1785         // Two or more teams remain
1786         return WINNING_NO;
1787 }
1788
1789 float LMS_NewPlayerLives()
1790 {
1791         float fl;
1792         fl = autocvar_fraglimit;
1793         if(fl == 0)
1794                 fl = 999;
1795
1796         // first player has left the game for dying too much? Nobody else can get in.
1797         if(lms_lowest_lives < 1)
1798                 return 0;
1799
1800         if(!autocvar_g_lms_join_anytime)
1801                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1802                         return 0;
1803
1804         return bound(1, lms_lowest_lives, fl);
1805 }
1806
1807 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1808 // they win. Otherwise the defending team wins once the timelimit passes.
1809 void assault_new_round();
1810 float WinningCondition_Assault()
1811 {
1812         local float status;
1813
1814         WinningConditionHelper(); // set worldstatus
1815
1816         status = WINNING_NO;
1817         // as the timelimit has not yet passed just assume the defending team will win
1818         if(assault_attacker_team == COLOR_TEAM1)
1819         {
1820                 SetWinners(team, COLOR_TEAM2);
1821         }
1822         else
1823         {
1824                 SetWinners(team, COLOR_TEAM1);
1825         }
1826
1827         local entity ent;
1828         ent = find(world, classname, "target_assault_roundend");
1829         if(ent)
1830         {
1831                 if(ent.winning) // round end has been triggered by attacking team
1832                 {
1833                         bprint("ASSAULT: round completed...\n");
1834                         SetWinners(team, assault_attacker_team);
1835
1836                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1837
1838                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1839                         {
1840                                 status = WINNING_YES;
1841                         }
1842                         else
1843                         {
1844                                 local entity oldself;
1845                                 oldself = self;
1846                                 self = ent;
1847                                 assault_new_round();
1848                                 self = oldself;
1849                         }
1850                 }
1851         }
1852
1853         return status;
1854 }
1855
1856 // LMS winning condition: game terminates if and only if there's at most one
1857 // one player who's living lives. Top two scores being equal cancels the time
1858 // limit.
1859 float WinningCondition_LMS()
1860 {
1861         entity head, head2;
1862         float have_player;
1863         float have_players;
1864         float l;
1865
1866         have_player = FALSE;
1867         have_players = FALSE;
1868         l = LMS_NewPlayerLives();
1869
1870         head = find(world, classname, "player");
1871         if(head)
1872                 have_player = TRUE;
1873         head2 = find(head, classname, "player");
1874         if(head2)
1875                 have_players = TRUE;
1876
1877         if(have_player)
1878         {
1879                 // we have at least one player
1880                 if(have_players)
1881                 {
1882                         // two or more active players - continue with the game
1883                 }
1884                 else
1885                 {
1886                         // exactly one player?
1887
1888                         ClearWinners();
1889                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1890
1891                         if(l)
1892                         {
1893                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1894                                 return WINNING_NO;
1895                         }
1896                         else
1897                         {
1898                                 // a winner!
1899                                 // and assign him his first place
1900                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1901                                 return WINNING_YES;
1902                         }
1903                 }
1904         }
1905         else
1906         {
1907                 // nobody is playing at all...
1908                 if(l)
1909                 {
1910                         // wait for players...
1911                 }
1912                 else
1913                 {
1914                         // SNAFU (maybe a draw game?)
1915                         ClearWinners();
1916                         dprint("No players, ending game.\n");
1917                         return WINNING_YES;
1918                 }
1919         }
1920
1921         // When we get here, we have at least two players who are actually LIVING,
1922         // now check if the top two players have equal score.
1923         WinningConditionHelper();
1924
1925         ClearWinners();
1926         if(WinningConditionHelper_winner)
1927                 WinningConditionHelper_winner.winning = TRUE;
1928         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1929                 return WINNING_NEVER;
1930
1931         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1932         return WINNING_NO;
1933 }
1934
1935 void ShuffleMaplist()
1936 {
1937         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1938 }
1939
1940 float leaderfrags;
1941 float WinningCondition_Scores(float limit, float leadlimit)
1942 {
1943         float limitreached;
1944
1945         // TODO make everything use THIS winning condition (except LMS)
1946         WinningConditionHelper();
1947
1948         if(teams_matter)
1949         {
1950                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1951                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1952                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1953                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1954         }
1955
1956         ClearWinners();
1957         if(WinningConditionHelper_winner)
1958                 WinningConditionHelper_winner.winning = 1;
1959         if(WinningConditionHelper_winnerteam >= 0)
1960                 SetWinners(team, WinningConditionHelper_winnerteam);
1961
1962         if(WinningConditionHelper_lowerisbetter)
1963         {
1964                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1965                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1966                 limit = -limit;
1967         }
1968
1969         if(WinningConditionHelper_zeroisworst)
1970                 leadlimit = 0; // not supported in this mode
1971
1972         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1973         // these modes always score in increments of 1, thus this makes sense
1974         {
1975                 if(leaderfrags != WinningConditionHelper_topscore)
1976                 {
1977                         leaderfrags = WinningConditionHelper_topscore;
1978
1979                         if (limit)
1980                         if (leaderfrags == limit - 1)
1981                                 Announce("1fragleft");
1982                         else if (leaderfrags == limit - 2)
1983                                 Announce("2fragsleft");
1984                         else if (leaderfrags == limit - 3)
1985                                 Announce("3fragsleft");
1986                 }
1987         }
1988
1989         limitreached = FALSE;
1990         if(limit)
1991                 if(WinningConditionHelper_topscore >= limit)
1992                         limitreached = TRUE;
1993         if(leadlimit)
1994         {
1995                 float leadlimitreached;
1996                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1997                 if(autocvar_leadlimit_and_fraglimit)
1998                         limitreached = (limitreached && leadlimitreached);
1999                 else
2000                         limitreached = (limitreached || leadlimitreached);
2001         }
2002
2003         return GetWinningCode(
2004                 WinningConditionHelper_topscore && limitreached,
2005                 WinningConditionHelper_equality
2006         );
2007 }
2008
2009 float WinningCondition_Race(float fraglimit)
2010 {
2011         float wc;
2012         entity p;
2013         float n, c;
2014
2015         n = 0;
2016         c = 0;
2017         FOR_EACH_PLAYER(p)
2018         {
2019                 ++n;
2020                 if(p.race_completed)
2021                         ++c;
2022         }
2023         if(n && (n == c))
2024                 return WINNING_YES;
2025         wc = WinningCondition_Scores(fraglimit, 0);
2026
2027         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2028         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2029         // do NOT support equality when the laps are all raced!
2030                 return WINNING_STARTSUDDENDEATHOVERTIME;
2031         else
2032                 return WINNING_NEVER;
2033         return wc;
2034 }
2035
2036 void ReadyRestart();
2037 float WinningCondition_QualifyingThenRace(float limit)
2038 {
2039         float wc;
2040         wc = WinningCondition_Scores(limit, 0);
2041
2042         // NEVER initiate overtime
2043         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2044         {
2045                 return WINNING_YES;
2046         }
2047
2048         return wc;
2049 }
2050
2051 float WinningCondition_RanOutOfSpawns()
2052 {
2053         entity head;
2054
2055         if(have_team_spawns <= 0)
2056                 return WINNING_NO;
2057
2058         if(!some_spawn_has_been_used)
2059                 return WINNING_NO;
2060
2061         team1_score = team2_score = team3_score = team4_score = 0;
2062
2063         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2064         {
2065                 if(head.team == COLOR_TEAM1)
2066                         team1_score = 1;
2067                 else if(head.team == COLOR_TEAM2)
2068                         team2_score = 1;
2069                 else if(head.team == COLOR_TEAM3)
2070                         team3_score = 1;
2071                 else if(head.team == COLOR_TEAM4)
2072                         team4_score = 1;
2073         }
2074
2075         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2076         {
2077                 if(head.team == COLOR_TEAM1)
2078                         team1_score = 1;
2079                 else if(head.team == COLOR_TEAM2)
2080                         team2_score = 1;
2081                 else if(head.team == COLOR_TEAM3)
2082                         team3_score = 1;
2083                 else if(head.team == COLOR_TEAM4)
2084                         team4_score = 1;
2085         }
2086
2087         ClearWinners();
2088         if(team1_score + team2_score + team3_score + team4_score == 0)
2089         {
2090                 checkrules_equality = TRUE;
2091                 return WINNING_YES;
2092         }
2093         else if(team1_score + team2_score + team3_score + team4_score == 1)
2094         {
2095                 float t, i;
2096                 if(team1_score) t = COLOR_TEAM1;
2097                 if(team2_score) t = COLOR_TEAM2;
2098                 if(team3_score) t = COLOR_TEAM3;
2099                 if(team4_score) t = COLOR_TEAM4;
2100                 CheckAllowedTeams(world);
2101                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2102                 {
2103                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2104                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2105                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2106                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2107                 }
2108
2109                 AddWinners(team, t);
2110                 return WINNING_YES;
2111         }
2112         else
2113                 return WINNING_NO;
2114 }
2115
2116 /*
2117 ============
2118 CheckRules_World
2119
2120 Exit deathmatch games upon conditions
2121 ============
2122 */
2123 void CheckRules_World()
2124 {
2125         float timelimit;
2126         float fraglimit;
2127         float leadlimit;
2128
2129         VoteThink();
2130         MapVote_Think();
2131
2132         SetDefaultAlpha();
2133
2134         /*
2135         MapVote_Think should now do that part
2136         if (intermission_running)
2137                 if (time >= intermission_exittime + 60)
2138                 {
2139                         if(!DoNextMapOverride())
2140                                 GotoNextMap();
2141                         return;
2142                 }
2143         */
2144
2145         if (gameover)   // someone else quit the game already
2146         {
2147                 if(player_count == 0) // Nobody there? Then let's go to the next map
2148                         MapVote_Start();
2149                         // this will actually check the player count in the next frame
2150                         // again, but this shouldn't hurt
2151                 return;
2152         }
2153
2154         timelimit = autocvar_timelimit * 60;
2155         fraglimit = autocvar_fraglimit;
2156         leadlimit = autocvar_leadlimit;
2157
2158         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2159         {
2160                 if(timelimit > 0)
2161                         timelimit = 0; // timelimit is not made for warmup
2162                 if(fraglimit > 0)
2163                         fraglimit = 0; // no fraglimit for now
2164                 leadlimit = 0; // no leadlimit for now
2165         }
2166
2167         if(g_onslaught)
2168                 timelimit = 0; // ONS has its own overtime rule
2169
2170         if(timelimit > 0)
2171         {
2172                 timelimit += game_starttime;
2173         }
2174         else if (timelimit < 0)
2175         {
2176                 // endmatch
2177                 NextLevel();
2178                 return;
2179         }
2180
2181         float wantovertime;
2182         wantovertime = 0;
2183
2184         if(checkrules_suddendeathend)
2185         {
2186                 if(!checkrules_suddendeathwarning)
2187                 {
2188                         checkrules_suddendeathwarning = TRUE;
2189                         if(g_race && !g_race_qualifying)
2190                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2191                         else
2192                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2193                 }
2194         }
2195         else
2196         {
2197                 if (timelimit && time >= timelimit)
2198                 {
2199                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2200                         {
2201                                 float totalplayers;
2202                                 float playerswithlaps;
2203                                 float readyplayers;
2204                                 entity head;
2205                                 totalplayers = playerswithlaps = readyplayers = 0;
2206                                 FOR_EACH_PLAYER(head)
2207                                 {
2208                                         ++totalplayers;
2209                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2210                                                 ++playerswithlaps;
2211                                         if(head.ready)
2212                                                 ++readyplayers;
2213                                 }
2214
2215                                 // at least 2 of the players have completed a lap: start the RACE
2216                                 // otherwise, the players should end the qualifying on their own
2217                                 if(readyplayers || playerswithlaps >= 2)
2218                                 {
2219                                         checkrules_suddendeathend = 0;
2220                                         ReadyRestart(); // go to race
2221                                         return;
2222                                 }
2223                                 else
2224                                         wantovertime |= InitiateSuddenDeath();
2225                         }
2226                         else
2227                                 wantovertime |= InitiateSuddenDeath();
2228                 }
2229         }
2230
2231         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2232         {
2233                 NextLevel();
2234                 return;
2235         }
2236
2237         float checkrules_status;
2238         checkrules_status = WinningCondition_RanOutOfSpawns();
2239         if(checkrules_status == WINNING_YES)
2240         {
2241                 bprint("Hey! Someone ran out of spawns!\n");
2242         }
2243         else if(g_race && !g_race_qualifying && timelimit >= 0)
2244         {
2245                 checkrules_status = WinningCondition_Race(fraglimit);
2246                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2247         }
2248         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2249         {
2250                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2251                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2252         }
2253         else if(g_assault)
2254         {
2255                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2256         }
2257         else if(g_lms)
2258         {
2259                 checkrules_status = WinningCondition_LMS();
2260         }
2261         else if (g_onslaught)
2262         {
2263                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2264         }
2265         else
2266         {
2267                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2268                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2269         }
2270
2271         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2272         {
2273                 checkrules_status = WINNING_NEVER;
2274                 checkrules_overtimesadded = -1;
2275                 wantovertime |= InitiateSuddenDeath();
2276         }
2277
2278         if(checkrules_status == WINNING_NEVER)
2279                 // equality cases! Nobody wins if the overtime ends in a draw.
2280                 ClearWinners();
2281
2282         if(wantovertime)
2283         {
2284                 if(checkrules_status == WINNING_NEVER)
2285                         InitiateOvertime();
2286                 else
2287                         checkrules_status = WINNING_YES;
2288         }
2289
2290         if(checkrules_suddendeathend)
2291                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2292                         checkrules_status = WINNING_YES;
2293
2294         if(checkrules_status == WINNING_YES)
2295         {
2296                 //print("WINNING\n");
2297                 NextLevel();
2298         }
2299 };
2300
2301 float mapvote_nextthink;
2302 float mapvote_initialized;
2303 float mapvote_keeptwotime;
2304 float mapvote_timeout;
2305 string mapvote_message;
2306 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2307 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2308 float mapvote_screenshot_dirs_count;
2309
2310 float mapvote_count;
2311 float mapvote_count_real;
2312 string mapvote_maps[MAPVOTE_COUNT];
2313 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2314 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2315 float mapvote_maps_suggested[MAPVOTE_COUNT];
2316 string mapvote_suggestions[MAPVOTE_COUNT];
2317 float mapvote_suggestion_ptr;
2318 float mapvote_maxlen;
2319 float mapvote_voters;
2320 float mapvote_votes[MAPVOTE_COUNT];
2321 float mapvote_run;
2322 float mapvote_detail;
2323 float mapvote_abstain;
2324 .float mapvote;
2325
2326 void MapVote_ClearAllVotes()
2327 {
2328         FOR_EACH_CLIENT(other)
2329                 other.mapvote = 0;
2330 }
2331
2332 string MapVote_Suggest(string m)
2333 {
2334         float i;
2335         if(m == "")
2336                 return "That's not how to use this command.";
2337         if(!autocvar_g_maplist_votable_suggestions)
2338                 return "Suggestions are not accepted on this server.";
2339         if(mapvote_initialized)
2340                 return "Can't suggest - voting is already in progress!";
2341         m = MapInfo_FixName(m);
2342         if(!m)
2343                 return "The map you suggested is not available on this server.";
2344         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2345                 if(Map_IsRecent(m))
2346                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2347
2348         if(!MapInfo_CheckMap(m))
2349                 return "The map you suggested does not support the current game mode.";
2350         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2351                 if(mapvote_suggestions[i] == m)
2352                         return "This map was already suggested.";
2353         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2354         {
2355                 i = floor(random() * mapvote_suggestion_ptr);
2356         }
2357         else
2358         {
2359                 i = mapvote_suggestion_ptr;
2360                 mapvote_suggestion_ptr += 1;
2361         }
2362         if(mapvote_suggestions[i] != "")
2363                 strunzone(mapvote_suggestions[i]);
2364         mapvote_suggestions[i] = strzone(m);
2365         if(autocvar_sv_eventlog)
2366                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2367         return strcat("Suggestion of ", m, " accepted.");
2368 }
2369
2370 void MapVote_AddVotable(string nextMap, float isSuggestion)
2371 {
2372         float j, i, o;
2373         string pakfile, mapfile;
2374
2375         if(nextMap == "")
2376                 return;
2377         for(j = 0; j < mapvote_count; ++j)
2378                 if(mapvote_maps[j] == nextMap)
2379                         return;
2380         if(strlen(nextMap) > mapvote_maxlen)
2381                 mapvote_maxlen = strlen(nextMap);
2382         mapvote_maps[mapvote_count] = strzone(nextMap);
2383         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2384
2385         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2386         {
2387                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2388                 pakfile = whichpack(strcat(mapfile, ".tga"));
2389                 if(pakfile == "")
2390                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2391                 if(pakfile == "")
2392                         pakfile = whichpack(strcat(mapfile, ".png"));
2393                 if(pakfile != "")
2394                         break;
2395         }
2396         if(i >= mapvote_screenshot_dirs_count)
2397                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2398         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2399                 pakfile = substring(pakfile, o, -1);
2400
2401         mapvote_maps_screenshot_dir[mapvote_count] = i;
2402         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2403
2404         mapvote_count += 1;
2405 }
2406
2407 void MapVote_Spawn();
2408 void MapVote_Init()
2409 {
2410         float i;
2411         float nmax, smax;
2412
2413         MapVote_ClearAllVotes();
2414
2415         mapvote_count = 0;
2416         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2417         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2418
2419         if(mapvote_abstain)
2420                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2421         else
2422                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2423         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2424
2425         // we need this for AddVotable, as that cycles through the screenshot dirs
2426         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2427         if(mapvote_screenshot_dirs_count == 0)
2428                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2429         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2430         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2431                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2432
2433         if(mapvote_suggestion_ptr)
2434                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2435                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2436
2437         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2438                 MapVote_AddVotable(GetNextMap(), FALSE);
2439
2440         if(mapvote_count == 0)
2441         {
2442                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2443                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2444                 if(autocvar_g_maplist_shuffle)
2445                         ShuffleMaplist();
2446                 localcmd("\nmenu_cmd sync\n");
2447                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2448                         MapVote_AddVotable(GetNextMap(), FALSE);
2449         }
2450
2451         mapvote_count_real = mapvote_count;
2452         if(mapvote_abstain)
2453                 MapVote_AddVotable("don't care", 0);
2454
2455         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2456
2457         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2458         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2459         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2460                 mapvote_keeptwotime = 0;
2461         mapvote_message = "Choose a map and press its key!";
2462
2463         MapVote_Spawn();
2464 }
2465
2466 void MapVote_SendPicture(float id)
2467 {
2468         msg_entity = self;
2469         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2470         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2471         WriteByte(MSG_ONE, id);
2472         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2473 }
2474
2475 float GameCommand_MapVote(string cmd)
2476 {
2477         if(!intermission_running)
2478                 return FALSE;
2479
2480         if(cmd == "mv_getpic")
2481         {
2482                 MapVote_SendPicture(stof(argv(1)));
2483                 return TRUE;
2484         }
2485
2486         return FALSE;
2487 }
2488
2489 float MapVote_GetMapMask()
2490 {
2491         float mask, i, power;
2492         mask = 0;
2493         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2494                 if(mapvote_maps[i] != "")
2495                         mask |= power;
2496         return mask;
2497 }
2498
2499 entity mapvote_ent;
2500 float MapVote_SendEntity(entity to, float sf)
2501 {
2502         float i;
2503
2504         if(sf & 1)
2505                 sf &~= 2; // if we send 1, we don't need to also send 2
2506
2507         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2508         WriteByte(MSG_ENTITY, sf);
2509
2510         if(sf & 1)
2511         {
2512                 // flag 1 == initialization
2513                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2514                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2515                 WriteString(MSG_ENTITY, "");
2516                 WriteByte(MSG_ENTITY, mapvote_count);
2517                 WriteByte(MSG_ENTITY, mapvote_abstain);
2518                 WriteByte(MSG_ENTITY, mapvote_detail);
2519                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2520                 if(mapvote_count <= 8)
2521                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2522                 else
2523                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2524                 for(i = 0; i < mapvote_count; ++i)
2525                         if(mapvote_maps[i] != "")
2526                         {
2527                                 if(mapvote_abstain && i == mapvote_count - 1)
2528                                 {
2529                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2530                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2531                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2532                                 }
2533                                 else
2534                                 {
2535                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2536                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2537                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2538                                 }
2539                         }
2540         }
2541
2542         if(sf & 2)
2543         {
2544                 // flag 2 == update of mask
2545                 if(mapvote_count <= 8)
2546                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2547                 else
2548                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2549         }
2550
2551         if(sf & 4)
2552         {
2553                 if(mapvote_detail)
2554                         for(i = 0; i < mapvote_count; ++i)
2555                                 if(mapvote_maps[i] != "")
2556                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2557
2558                 WriteByte(MSG_ENTITY, to.mapvote);
2559         }
2560
2561         return TRUE;
2562 }
2563
2564 void MapVote_Spawn()
2565 {
2566         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2567 }
2568
2569 void MapVote_TouchMask()
2570 {
2571         mapvote_ent.SendFlags |= 2;
2572 }
2573
2574 void MapVote_TouchVotes(entity voter)
2575 {
2576         mapvote_ent.SendFlags |= 4;
2577 }
2578
2579 float MapVote_Finished(float mappos)
2580 {
2581         string result;
2582         float i;
2583         float didntvote;
2584
2585         if(autocvar_sv_eventlog)
2586         {
2587                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2588                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2589                 didntvote = mapvote_voters;
2590                 for(i = 0; i < mapvote_count; ++i)
2591                         if(mapvote_maps[i] != "")
2592                         {
2593                                 didntvote -= mapvote_votes[i];
2594                                 if(i != mappos)
2595                                 {
2596                                         result = strcat(result, ":", mapvote_maps[i]);
2597                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2598                                 }
2599                         }
2600                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2601
2602                 GameLogEcho(result);
2603                 if(mapvote_maps_suggested[mappos])
2604                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2605         }
2606
2607         FOR_EACH_REALCLIENT(other)
2608                 FixClientCvars(other);
2609
2610         Map_Goto_SetStr(mapvote_maps[mappos]);
2611         Map_Goto();
2612         alreadychangedlevel = TRUE;
2613         return TRUE;
2614 }
2615 void MapVote_CheckRules_1()
2616 {
2617         float i;
2618
2619         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2620         {
2621                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2622                 mapvote_votes[i] = 0;
2623         }
2624
2625         mapvote_voters = 0;
2626         FOR_EACH_REALCLIENT(other)
2627         {
2628                 ++mapvote_voters;
2629                 if(other.mapvote)
2630                 {
2631                         i = other.mapvote - 1;
2632                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2633                         mapvote_votes[i] = mapvote_votes[i] + 1;
2634                 }
2635         }
2636 }
2637
2638 float MapVote_CheckRules_2()
2639 {
2640         float i;
2641         float firstPlace, secondPlace;
2642         float firstPlaceVotes, secondPlaceVotes;
2643         float mapvote_voters_real;
2644         string result;
2645
2646         if(mapvote_count_real == 1)
2647                 return MapVote_Finished(0);
2648
2649         mapvote_voters_real = mapvote_voters;
2650         if(mapvote_abstain)
2651                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2652
2653         RandomSelection_Init();
2654         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2655                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2656         firstPlace = RandomSelection_chosen_float;
2657         firstPlaceVotes = RandomSelection_best_priority;
2658         //dprint("First place: ", ftos(firstPlace), "\n");
2659         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2660
2661         RandomSelection_Init();
2662         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2663                 if(i != firstPlace)
2664                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2665         secondPlace = RandomSelection_chosen_float;
2666         secondPlaceVotes = RandomSelection_best_priority;
2667         //dprint("Second place: ", ftos(secondPlace), "\n");
2668         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2669
2670         if(firstPlace == -1)
2671                 error("No first place in map vote... WTF?");
2672
2673         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2674                 return MapVote_Finished(firstPlace);
2675
2676         if(mapvote_keeptwotime)
2677                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2678                 {
2679                         float didntvote;
2680                         MapVote_TouchMask();
2681                         mapvote_message = "Now decide between the TOP TWO!";
2682                         mapvote_keeptwotime = 0;
2683                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2684                         result = strcat(result, ":", ftos(firstPlaceVotes));
2685                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2686                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2687                         didntvote = mapvote_voters;
2688                         for(i = 0; i < mapvote_count; ++i)
2689                                 if(mapvote_maps[i] != "")
2690                                 {
2691                                         didntvote -= mapvote_votes[i];
2692                                         if(i != firstPlace)
2693                                                 if(i != secondPlace)
2694                                                 {
2695                                                         result = strcat(result, ":", mapvote_maps[i]);
2696                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2697                                                         if(i < mapvote_count_real)
2698                                                         {
2699                                                                 strunzone(mapvote_maps[i]);
2700                                                                 mapvote_maps[i] = "";
2701                                                                 strunzone(mapvote_maps_pakfile[i]);
2702                                                                 mapvote_maps_pakfile[i] = "";
2703                                                         }
2704                                                 }
2705                                 }
2706                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2707                         if(autocvar_sv_eventlog)
2708                                 GameLogEcho(result);
2709                 }
2710
2711         return FALSE;
2712 }
2713 void MapVote_Tick()
2714 {
2715         float keeptwo;
2716         float totalvotes;
2717
2718         keeptwo = mapvote_keeptwotime;
2719         MapVote_CheckRules_1(); // count
2720         if(MapVote_CheckRules_2()) // decide
2721                 return;
2722
2723         totalvotes = 0;
2724         FOR_EACH_REALCLIENT(other)
2725         {
2726                 // hide scoreboard again
2727                 if(other.health != 2342)
2728                 {
2729                         other.health = 2342;
2730                         other.impulse = 0;
2731                         if(clienttype(other) == CLIENTTYPE_REAL)
2732                         {
2733                                 msg_entity = other;
2734                                 WriteByte(MSG_ONE, SVC_FINALE);
2735                                 WriteString(MSG_ONE, "");
2736                         }
2737                 }
2738
2739                 // clear possibly invalid votes
2740                 if(mapvote_maps[other.mapvote - 1] == "")
2741                         other.mapvote = 0;
2742                 // use impulses as new vote
2743                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2744                         if(mapvote_maps[other.impulse - 1] != "")
2745                         {
2746                                 other.mapvote = other.impulse;
2747                                 MapVote_TouchVotes(other);
2748                         }
2749                 other.impulse = 0;
2750
2751                 if(other.mapvote)
2752                         ++totalvotes;
2753         }
2754
2755         MapVote_CheckRules_1(); // just count
2756 }
2757 void MapVote_Start()
2758 {
2759         if(mapvote_run)
2760                 return;
2761
2762         // wait for stats to be sent first
2763         if(!playerstats_waitforme)
2764                 return;
2765
2766         MapInfo_Enumerate();
2767         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2768                 mapvote_run = TRUE;
2769 }
2770 void MapVote_Think()
2771 {
2772         if(!mapvote_run)
2773                 return;
2774
2775         if(alreadychangedlevel)
2776                 return;
2777
2778         if(time < mapvote_nextthink)
2779                 return;
2780         //dprint("tick\n");
2781
2782         mapvote_nextthink = time + 0.5;
2783
2784         if(!mapvote_initialized)
2785         {
2786                 if(autocvar_rescan_pending == 1)
2787                 {
2788                         cvar_set("rescan_pending", "2");
2789                         localcmd("fs_rescan\nrescan_pending 3\n");
2790                         return;
2791                 }
2792                 else if(autocvar_rescan_pending == 2)
2793                 {
2794                         return;
2795                 }
2796                 else if(autocvar_rescan_pending == 3)
2797                 {
2798                         // now build missing mapinfo files
2799                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2800                                 return;
2801
2802                         // we're done, start the timer
2803                         cvar_set("rescan_pending", "0");
2804                 }
2805
2806                 mapvote_initialized = TRUE;
2807                 if(DoNextMapOverride())
2808                         return;
2809                 if(!autocvar_g_maplist_votable || player_count <= 0)
2810                 {
2811                         GotoNextMap();
2812                         return;
2813                 }
2814                 MapVote_Init();
2815         }
2816
2817         MapVote_Tick();
2818 };
2819
2820 string GotoMap(string m)
2821 {
2822         if(!MapInfo_CheckMap(m))
2823                 return "The map you chose is not available on this server.";
2824         cvar_set("nextmap", m);
2825         cvar_set("timelimit", "-1");
2826         if(mapvote_initialized || alreadychangedlevel)
2827         {
2828                 if(DoNextMapOverride())
2829                         return "Map switch initiated.";
2830                 else
2831                         return "Hm... no. For some reason I like THIS map more.";
2832         }
2833         else
2834                 return "Map switch will happen after scoreboard.";
2835 }
2836
2837
2838 void EndFrame()
2839 {
2840         float altime;
2841         FOR_EACH_REALCLIENT(self)
2842         {
2843                 if(self.classname == "spectator")
2844                 {
2845                         if(self.enemy.typehitsound)
2846                                 self.typehit_time = time;
2847                         else if(self.enemy.hitsound)
2848                                 self.hit_time = time;
2849                 }
2850                 else
2851                 {
2852                         if(self.typehitsound)
2853                                 self.typehit_time = time;
2854                         else if(self.hitsound)
2855                                 self.hit_time = time;
2856                 }
2857         }
2858         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2859         // add 1 frametime because after this, engine SV_Physics
2860         // increases time by a frametime and then networks the frame
2861         // add another frametime because client shows everything with
2862         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2863         // needed!
2864         FOR_EACH_CLIENT(self)
2865         {
2866                 self.hitsound = FALSE;
2867                 self.typehitsound = FALSE;
2868                 antilag_record(self, altime);
2869         }
2870 }
2871
2872
2873 /*
2874  * RedirectionThink:
2875  * returns TRUE if redirecting
2876  */
2877 float redirection_timeout;
2878 float redirection_nextthink;
2879 float RedirectionThink()
2880 {
2881         float clients_found;
2882
2883         if(redirection_target == "")
2884                 return FALSE;
2885
2886         if(!redirection_timeout)
2887         {
2888                 cvar_set("sv_public", "-2");
2889                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2890                 if(redirection_target == "self")
2891                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2892                 else
2893                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2894         }
2895
2896         if(time < redirection_nextthink)
2897                 return TRUE;
2898
2899         redirection_nextthink = time + 1;
2900
2901         clients_found = 0;
2902         FOR_EACH_REALCLIENT(self)
2903         {
2904                 print("Redirecting: sending connect command to ", self.netname, "\n");
2905                 if(redirection_target == "self")
2906                         stuffcmd(self, "\ndisconnect; reconnect\n");
2907                 else
2908                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2909                 ++clients_found;
2910         }
2911
2912         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2913
2914         if(time > redirection_timeout || clients_found == 0)
2915                 localcmd("\nwait; wait; wait; quit\n");
2916
2917         return TRUE;
2918 }
2919
2920 void TargetMusic_RestoreGame();
2921 void RestoreGame()
2922 {
2923         // Loaded from a save game
2924         // some things then break, so let's work around them...
2925
2926         // Progs DB (capture records)
2927         ServerProgsDB = db_load("server.db");
2928
2929         // Mapinfo
2930         MapInfo_Shutdown();
2931         MapInfo_Enumerate();
2932         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2933         WeaponStats_Init();
2934
2935         TargetMusic_RestoreGame();
2936 }
2937
2938 void SV_Shutdown()
2939 {
2940         entity e;
2941
2942         if(gameover > 1) // shutting down already?
2943                 return;
2944
2945         gameover = 2; // 2 = server shutting down
2946
2947         if(world_initialized > 0)
2948         {
2949                 world_initialized = 0;
2950                 print("Saving persistent data...\n");
2951                 Ban_SaveBans();
2952
2953                 PlayerStats_EndMatch(0);
2954                 FOR_EACH_CLIENT(e)
2955                         PlayerStats_AddGlobalInfo(e);
2956                 PlayerStats_Shutdown();
2957
2958                 if(!cheatcount_total)
2959                 {
2960                         if(autocvar_sv_db_saveasdump)
2961                                 db_dump(ServerProgsDB, "server.db");
2962                         else
2963                                 db_save(ServerProgsDB, "server.db");
2964                 }
2965                 if(autocvar_developer)
2966                 {
2967                         if(autocvar_sv_db_saveasdump)
2968                                 db_dump(TemporaryDB, "server-temp.db");
2969                         else
2970                                 db_save(TemporaryDB, "server-temp.db");
2971                 }
2972                 CheatShutdown(); // must be after cheatcount check
2973                 db_close(ServerProgsDB);
2974                 db_close(TemporaryDB);
2975                 print("done!\n");
2976                 // tell the bot system the game is ending now
2977                 bot_endgame();
2978
2979                 WeaponStats_Shutdown();
2980                 MapInfo_Shutdown();
2981         }
2982         else if(world_initialized == 0)
2983         {
2984                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2985         }
2986 }