Allow admins to change the announcer and CTF flag models without affecting purity
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2
3 #include "anticheat.qh"
4 #include "antilag.qh"
5 #include "bot/api.qh"
6 #include "campaign.qh"
7 #include "cheats.qh"
8 #include "client.qh"
9 #include "command/common.qh"
10 #include "command/getreplies.qh"
11 #include "command/sv_cmd.qh"
12 #include "command/vote.qh"
13 #include "g_hook.qh"
14 #include "ipban.qh"
15 #include "mapvoting.qh"
16 #include <server/mutators/_mod.qh>
17 #include "race.qh"
18 #include "scores.qh"
19 #include "scores_rules.qh"
20 #include "teamplay.qh"
21 #include "weapons/weaponstats.qh"
22 #include "../common/constants.qh"
23 #include <common/net_linked.qh>
24 #include "../common/deathtypes/all.qh"
25 #include "../common/gamemodes/sv_rules.qh"
26 #include "../common/mapinfo.qh"
27 #include "../common/monsters/_mod.qh"
28 #include "../common/monsters/sv_monsters.qh"
29 #include "../common/vehicles/all.qh"
30 #include "../common/notifications/all.qh"
31 #include "../common/physics/player.qh"
32 #include "../common/playerstats.qh"
33 #include "../common/stats.qh"
34 #include "../common/teams.qh"
35 #include "../common/mapobjects/trigger/secret.qh"
36 #include "../common/mapobjects/target/music.qh"
37 #include "../common/util.qh"
38 #include "../common/items/_mod.qh"
39 #include <common/weapons/_all.qh>
40 #include "../common/state.qh"
41
42 const float LATENCY_THINKRATE = 10;
43 .float latency_sum;
44 .float latency_cnt;
45 .float latency_time;
46 entity pingplreport;
47 void PingPLReport_Think(entity this)
48 {
49         float delta;
50         entity e;
51
52         delta = 3 / maxclients;
53         if(delta < sys_frametime)
54                 delta = 0;
55         this.nextthink = time + delta;
56
57         e = edict_num(this.cnt + 1);
58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
59         {
60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
61                 WriteByte(MSG_BROADCAST, this.cnt);
62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
65
66                 // record latency times for clients throughout the match so we can report it to playerstats
67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
68                 {
69                         CS(e).latency_sum += CS(e).ping;
70                         CS(e).latency_cnt += 1;
71                         CS(e).latency_time = time;
72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
73                 }
74         }
75         else
76         {
77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
78                 WriteByte(MSG_BROADCAST, this.cnt);
79                 WriteShort(MSG_BROADCAST, 0);
80                 WriteByte(MSG_BROADCAST, 0);
81                 WriteByte(MSG_BROADCAST, 0);
82         }
83         this.cnt = (this.cnt + 1) % maxclients;
84 }
85 void PingPLReport_Spawn()
86 {
87         pingplreport = new_pure(pingplreport);
88         setthink(pingplreport, PingPLReport_Think);
89         pingplreport.nextthink = time;
90 }
91
92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
93 string redirection_target;
94 float world_initialized;
95
96 void SetDefaultAlpha()
97 {
98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
99         {
100                 default_player_alpha = autocvar_g_player_alpha;
101                 if(default_player_alpha == 0)
102                         default_player_alpha = 1;
103                 default_weapon_alpha = default_player_alpha;
104         }
105 }
106
107 void GotoFirstMap(entity this)
108 {
109         float n;
110         if(autocvar__sv_init)
111         {
112                 // cvar_set("_sv_init", "0");
113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
114                 // to this "init" map on a dedicated server will cause no permanent
115                 // harm
116                 if(autocvar_g_maplist_shuffle)
117                         ShuffleMaplist();
118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
120
121                 MapInfo_Enumerate();
122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
123
124                 if(!DoNextMapOverride(1))
125                         GotoNextMap(1);
126
127                 return;
128         }
129
130         if(time < 5)
131         {
132                 this.nextthink = time;
133         }
134         else
135         {
136                 this.nextthink = time + 1;
137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
138         }
139 }
140
141 void cvar_changes_init()
142 {
143         float h;
144         string k, v, d;
145         float n, i, adding, pureadding;
146
147         strfree(cvar_changes);
148         strfree(cvar_purechanges);
149         cvar_purechanges_count = 0;
150
151         h = buf_create();
152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
153         n = buf_getsize(h);
154
155         adding = true;
156         pureadding = true;
157
158         for(i = 0; i < n; ++i)
159         {
160                 k = bufstr_get(h, i);
161
162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
164 #define BADCVAR(p) if(k == p) continue
165
166                 // general excludes and namespaces for server admin used cvars
167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
168
169                 // internal
170                 BADPREFIX("csqc_");
171                 BADPREFIX("cvar_check_");
172                 BADCVAR("gamecfg");
173                 BADCVAR("g_configversion");
174                 BADCVAR("halflifebsp");
175                 BADCVAR("sv_mapformat_is_quake2");
176                 BADCVAR("sv_mapformat_is_quake3");
177                 BADPREFIX("sv_world");
178
179                 // client
180                 BADPREFIX("chase_");
181                 BADPREFIX("cl_");
182                 BADPREFIX("con_");
183                 BADPREFIX("scoreboard_");
184                 BADPREFIX("g_campaign");
185                 BADPREFIX("g_waypointsprite_");
186                 BADPREFIX("gl_");
187                 BADPREFIX("joy");
188                 BADPREFIX("hud_");
189                 BADPREFIX("m_");
190                 BADPREFIX("menu_");
191                 BADPREFIX("net_slist_");
192                 BADPREFIX("r_");
193                 BADPREFIX("sbar_");
194                 BADPREFIX("scr_");
195                 BADPREFIX("snd_");
196                 BADPREFIX("show");
197                 BADPREFIX("sensitivity");
198                 BADPREFIX("userbind");
199                 BADPREFIX("v_");
200                 BADPREFIX("vid_");
201                 BADPREFIX("crosshair");
202                 BADCVAR("mod_q3bsp_lightmapmergepower");
203                 BADCVAR("mod_q3bsp_nolightmaps");
204                 BADCVAR("fov");
205                 BADCVAR("mastervolume");
206                 BADCVAR("volume");
207                 BADCVAR("bgmvolume");
208                 BADCVAR("in_pitch_min");
209                 BADCVAR("in_pitch_max");
210
211                 // private
212                 BADCVAR("developer");
213                 BADCVAR("log_dest_udp");
214                 BADCVAR("net_address");
215                 BADCVAR("net_address_ipv6");
216                 BADCVAR("port");
217                 BADCVAR("savedgamecfg");
218                 BADCVAR("serverconfig");
219                 BADCVAR("sv_autoscreenshot");
220                 BADCVAR("sv_heartbeatperiod");
221                 BADCVAR("sv_vote_master_password");
222                 BADCVAR("sys_colortranslation");
223                 BADCVAR("sys_specialcharactertranslation");
224                 BADCVAR("timeformat");
225                 BADCVAR("timestamps");
226                 BADCVAR("g_require_stats");
227                 BADPREFIX("developer_");
228                 BADPREFIX("g_ban_");
229                 BADPREFIX("g_banned_list");
230                 BADPREFIX("g_require_stats_");
231                 BADPREFIX("g_chat_flood_");
232                 BADPREFIX("g_ghost_items");
233                 BADPREFIX("g_playerstats_");
234                 BADPREFIX("g_voice_flood_");
235                 BADPREFIX("log_file");
236                 BADPREFIX("quit_");
237                 BADPREFIX("rcon_");
238                 BADPREFIX("sv_allowdownloads");
239                 BADPREFIX("sv_autodemo");
240                 BADPREFIX("sv_curl_");
241                 BADPREFIX("sv_eventlog");
242                 BADPREFIX("sv_logscores_");
243                 BADPREFIX("sv_master");
244                 BADPREFIX("sv_weaponstats_");
245                 BADPREFIX("sv_waypointsprite_");
246                 BADCVAR("rescan_pending");
247
248                 // these can contain player IDs, so better hide
249                 BADPREFIX("g_forced_team_");
250                 BADCVAR("sv_muteban_list");
251                 BADCVAR("sv_voteban_list");
252                 BADCVAR("sv_allow_customplayermodels_idlist");
253                 BADCVAR("sv_allow_customplayermodels_speciallist");
254
255                 // mapinfo
256                 BADCVAR("fraglimit");
257                 BADCVAR("g_arena");
258                 BADCVAR("g_assault");
259                 BADCVAR("g_ca");
260                 BADCVAR("g_ca_teams");
261                 BADCVAR("g_conquest");
262                 BADCVAR("g_ctf");
263                 BADCVAR("g_cts");
264                 BADCVAR("g_dotc");
265                 BADCVAR("g_dm");
266                 BADCVAR("g_domination");
267                 BADCVAR("g_domination_default_teams");
268                 BADCVAR("g_duel");
269                 BADCVAR("g_duel_not_dm_maps");
270                 BADCVAR("g_freezetag");
271                 BADCVAR("g_freezetag_teams");
272                 BADCVAR("g_invasion_teams");
273                 BADCVAR("g_invasion_type");
274                 BADCVAR("g_jailbreak");
275                 BADCVAR("g_jailbreak_teams");
276                 BADCVAR("g_keepaway");
277                 BADCVAR("g_keyhunt");
278                 BADCVAR("g_keyhunt_teams");
279                 BADCVAR("g_lms");
280                 BADCVAR("g_nexball");
281                 BADCVAR("g_onslaught");
282                 BADCVAR("g_race");
283                 BADCVAR("g_race_laps_limit");
284                 BADCVAR("g_race_qualifying_timelimit");
285                 BADCVAR("g_race_qualifying_timelimit_override");
286                 BADCVAR("g_runematch");
287                 BADCVAR("g_shootfromeye");
288                 BADCVAR("g_snafu");
289                 BADCVAR("g_tdm");
290                 BADCVAR("g_tdm_on_dm_maps");
291                 BADCVAR("g_tdm_teams");
292                 BADCVAR("g_vip");
293                 BADCVAR("leadlimit");
294                 BADCVAR("nextmap");
295                 BADCVAR("teamplay");
296                 BADCVAR("timelimit");
297                 BADCVAR("g_mapinfo_ignore_warnings");
298                 BADCVAR("g_maplist_ignore_sizes");
299                 BADCVAR("g_maplist_sizes_count_bots");
300
301                 // long
302                 BADCVAR("hostname");
303                 BADCVAR("g_maplist");
304                 BADCVAR("g_maplist_mostrecent");
305                 BADCVAR("sv_motd");
306
307                 v = cvar_string(k);
308                 d = cvar_defstring(k);
309                 if(v == d)
310                         continue;
311
312                 if(adding)
313                 {
314                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
315                         if(strlen(cvar_changes) > 16384)
316                         {
317                                 cvar_changes = "// too many settings have been changed to show them here\n";
318                                 adding = 0;
319                         }
320                 }
321
322                 // now check if the changes are actually gameplay relevant
323
324                 // does nothing gameplay relevant
325                 BADCVAR("captureleadlimit_override");
326                 BADCVAR("condump_stripcolors");
327                 BADCVAR("gameversion");
328                 BADCVAR("fs_gamedir");
329                 BADCVAR("g_allow_oldvortexbeam");
330                 BADCVAR("g_balance_kill_delay");
331                 BADCVAR("g_buffs_pickup_anyway");
332                 BADCVAR("g_buffs_randomize");
333                 BADCVAR("g_buffs_randomize_teamplay");
334                 BADCVAR("g_campcheck_distance");
335                 BADCVAR("g_ca_point_leadlimit");
336                 BADCVAR("g_ca_point_limit");
337                 BADCVAR("g_ctf_captimerecord_always");
338                 BADCVAR("g_ctf_flag_glowtrails");
339                 BADCVAR("g_ctf_dynamiclights");
340                 BADCVAR("g_ctf_flag_pickup_verbosename");
341                 BADPRESUFFIX("g_ctf_flag_", "_model");
342                 BADPRESUFFIX("g_ctf_flag_", "_skin");
343                 BADCVAR("g_domination_point_leadlimit");
344                 BADCVAR("g_forced_respawn");
345                 BADCVAR("g_freezetag_point_leadlimit");
346                 BADCVAR("g_freezetag_point_limit");
347                 BADCVAR("g_hats");
348                 BADCVAR("g_invasion_point_limit");
349                 BADCVAR("g_jump_grunt");
350                 BADCVAR("g_keyhunt_point_leadlimit");
351                 BADCVAR("g_nexball_goalleadlimit");
352                 BADCVAR("g_new_toys_autoreplace");
353                 BADCVAR("g_new_toys_use_pickupsound");
354                 BADCVAR("g_physics_predictall");
355                 BADCVAR("g_piggyback");
356                 BADCVAR("g_playerclip_collisions");
357                 BADCVAR("g_spawn_alloweffects");
358                 BADCVAR("g_tdm_point_leadlimit");
359                 BADCVAR("g_tdm_point_limit");
360                 BADCVAR("leadlimit_and_fraglimit");
361                 BADCVAR("leadlimit_override");
362                 BADCVAR("pausable");
363                 BADCVAR("sv_announcer");
364                 BADCVAR("sv_checkforpacketsduringsleep");
365                 BADCVAR("sv_damagetext");
366                 BADCVAR("sv_db_saveasdump");
367                 BADCVAR("sv_intermission_cdtrack");
368                 BADCVAR("sv_mapchange_delay");
369                 BADCVAR("sv_minigames");
370                 BADCVAR("sv_namechangetimer");
371                 BADCVAR("sv_precacheplayermodels");
372                 BADCVAR("sv_stepheight");
373                 BADCVAR("sv_timeout");
374                 BADCVAR("sv_weapons_modeloverride");
375                 BADCVAR("w_prop_interval");
376                 BADPREFIX("crypto_");
377                 BADPREFIX("gameversion_");
378                 BADPREFIX("g_chat_");
379                 BADPREFIX("g_ctf_captimerecord_");
380                 BADPREFIX("g_hats_");
381                 BADPREFIX("g_maplist_");
382                 BADPREFIX("g_mod_");
383                 BADPREFIX("g_respawn_");
384                 BADPREFIX("net_");
385                 BADPREFIX("notification_");
386                 BADPREFIX("prvm_");
387                 BADPREFIX("skill_");
388                 BADPREFIX("sv_allow_");
389                 BADPREFIX("sv_cullentities_");
390                 BADPREFIX("sv_maxidle_");
391                 BADPREFIX("sv_minigames_");
392                 BADPREFIX("sv_radio_");
393                 BADPREFIX("sv_timeout_");
394                 BADPREFIX("sv_vote_");
395                 BADPREFIX("timelimit_");
396
397                 // allowed changes to server admins (please sync this to server.cfg)
398                 // vi commands:
399                 //   :/"impure"/,$d
400                 //   :g!,^\/\/[^ /],d
401                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
402                 //   :%!sort
403                 // yes, this does contain some redundant stuff, don't really care
404                 BADPREFIX("bot_ai_");
405                 BADCVAR("bot_config_file");
406                 BADCVAR("bot_number");
407                 BADCVAR("bot_prefix");
408                 BADCVAR("bot_suffix");
409                 BADCVAR("capturelimit_override");
410                 BADCVAR("fraglimit_override");
411                 BADCVAR("gametype");
412                 BADCVAR("g_antilag");
413                 BADCVAR("g_balance_teams");
414                 BADCVAR("g_balance_teams_prevent_imbalance");
415                 BADCVAR("g_balance_teams_scorefactor");
416                 BADCVAR("g_ban_sync_trusted_servers");
417                 BADCVAR("g_ban_sync_uri");
418                 BADCVAR("g_buffs");
419                 BADCVAR("g_ca_teams_override");
420                 BADCVAR("g_ctf_fullbrightflags");
421                 BADCVAR("g_ctf_ignore_frags");
422                 BADCVAR("g_ctf_leaderboard");
423                 BADCVAR("g_domination_point_limit");
424                 BADCVAR("g_domination_teams_override");
425                 BADCVAR("g_freezetag_teams_override");
426                 BADCVAR("g_friendlyfire");
427                 BADCVAR("g_fullbrightitems");
428                 BADCVAR("g_fullbrightplayers");
429                 BADCVAR("g_keyhunt_point_limit");
430                 BADCVAR("g_keyhunt_teams_override");
431                 BADCVAR("g_lms_lives_override");
432                 BADCVAR("g_maplist");
433                 BADCVAR("g_maxplayers");
434                 BADCVAR("g_mirrordamage");
435                 BADCVAR("g_nexball_goallimit");
436                 BADCVAR("g_norecoil");
437                 BADCVAR("g_physics_clientselect");
438                 BADCVAR("g_pinata");
439                 BADCVAR("g_powerups");
440                 BADCVAR("g_player_brightness");
441                 BADCVAR("g_rocket_flying");
442                 BADCVAR("g_rocket_flying_disabledelays");
443                 BADCVAR("g_spawnshieldtime");
444                 BADCVAR("g_start_delay");
445                 BADCVAR("g_superspectate");
446                 BADCVAR("g_tdm_teams_override");
447                 BADCVAR("g_warmup");
448                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
449                 BADCVAR("hostname");
450                 BADCVAR("log_file");
451                 BADCVAR("maxplayers");
452                 BADCVAR("minplayers");
453                 BADCVAR("minplayers_per_team");
454                 BADCVAR("net_address");
455                 BADCVAR("port");
456                 BADCVAR("rcon_password");
457                 BADCVAR("rcon_restricted_commands");
458                 BADCVAR("rcon_restricted_password");
459                 BADCVAR("skill");
460                 BADCVAR("sv_adminnick");
461                 BADCVAR("sv_autoscreenshot");
462                 BADCVAR("sv_autotaunt");
463                 BADCVAR("sv_curl_defaulturl");
464                 BADCVAR("sv_defaultcharacter");
465                 BADCVAR("sv_defaultcharacterskin");
466                 BADCVAR("sv_defaultplayercolors");
467                 BADCVAR("sv_defaultplayermodel");
468                 BADCVAR("sv_defaultplayerskin");
469                 BADCVAR("sv_maxidle");
470                 BADCVAR("sv_maxrate");
471                 BADCVAR("sv_motd");
472                 BADCVAR("sv_public");
473                 BADCVAR("sv_ready_restart");
474                 BADCVAR("sv_status_privacy");
475                 BADCVAR("sv_taunt");
476                 BADCVAR("sv_vote_call");
477                 BADCVAR("sv_vote_commands");
478                 BADCVAR("sv_vote_majority_factor");
479                 BADCVAR("sv_vote_master");
480                 BADCVAR("sv_vote_master_commands");
481                 BADCVAR("sv_vote_master_password");
482                 BADCVAR("sv_vote_simple_majority_factor");
483                 BADCVAR("teamplay_mode");
484                 BADCVAR("timelimit_override");
485                 BADPREFIX("g_warmup_");
486                 BADPREFIX("sv_info_");
487                 BADPREFIX("sv_ready_restart_");
488
489                 // mutators that announce themselves properly to the server browser
490                 BADCVAR("g_instagib");
491                 BADCVAR("g_new_toys");
492                 BADCVAR("g_nix");
493                 BADCVAR("g_grappling_hook");
494                 BADCVAR("g_jetpack");
495
496                 // temporary for testing
497                 // TODO remove before 0.8.3 release
498                 BADCVAR("g_ca_weaponarena");
499                 BADCVAR("g_freezetag_weaponarena");
500                 BADCVAR("g_lms_weaponarena");
501                 BADCVAR("g_ctf_stalemate_time");
502
503                 if(cvar_string("g_mod_balance") == "Testing")
504                 {
505                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
506                         BADPREFIX("g_balance_");
507                 }
508
509 #undef BADPRESUFFIX
510 #undef BADPREFIX
511 #undef BADCVAR
512
513                 if(pureadding)
514                 {
515                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
516                         if(strlen(cvar_purechanges) > 16384)
517                         {
518                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
519                                 pureadding = 0;
520                         }
521                 }
522                 ++cvar_purechanges_count;
523                 // WARNING: this variable is used for the server list
524                 // NEVER dare to skip this code!
525                 // Hacks to intentionally appearing as "pure server" even though you DO have
526                 // modified settings may be punished by removal from the server list.
527                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
528                 // though.
529         }
530         buf_del(h);
531         if(cvar_changes == "")
532                 cvar_changes = "// this server runs at default server settings\n";
533         else
534                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
535         cvar_changes = strzone(cvar_changes);
536         if(cvar_purechanges == "")
537                 cvar_purechanges = "// this server runs at default gameplay settings\n";
538         else
539                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
540         cvar_purechanges = strzone(cvar_purechanges);
541 }
542
543 entity randomseed;
544 bool RandomSeed_Send(entity this, entity to, int sf)
545 {
546         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
547         WriteShort(MSG_ENTITY, this.cnt);
548         return true;
549 }
550 void RandomSeed_Think(entity this)
551 {
552         this.cnt = bound(0, floor(random() * 65536), 65535);
553         this.nextthink = time + 5;
554
555         this.SendFlags |= 1;
556 }
557 void RandomSeed_Spawn()
558 {
559         randomseed = new_pure(randomseed);
560         setthink(randomseed, RandomSeed_Think);
561         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
562
563         getthink(randomseed)(randomseed); // sets random seed and nextthink
564 }
565
566 spawnfunc(__init_dedicated_server)
567 {
568         // handler for _init/_init map (only for dedicated server initialization)
569
570         world_initialized = -1; // don't complain
571         cvar = cvar_normal;
572         cvar_string = cvar_string_normal;
573         cvar_set = cvar_set_normal;
574
575         delete_fn = remove_unsafely;
576
577         entity e = spawn();
578         setthink(e, GotoFirstMap);
579         e.nextthink = time; // this is usually 1 at this point
580
581         e = new(info_player_deathmatch);  // safeguard against player joining
582
583     // assign reflectively to avoid "assignment to world" warning
584     for (int i = 0, n = numentityfields(); i < n; ++i) {
585         string k = entityfieldname(i);
586         if (k == "classname") {
587             // safeguard against various stuff ;)
588             putentityfieldstring(i, this, "worldspawn");
589             break;
590         }
591     }
592
593         // needs to be done so early because of the constants they create
594         static_init();
595         static_init_late();
596         static_init_precache();
597
598         IL_PUSH(g_spawnpoints, e); // just incase
599
600         MapInfo_Enumerate();
601         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
602 }
603
604 void __init_dedicated_server_shutdown() {
605         MapInfo_Shutdown();
606 }
607
608 STATIC_INIT_EARLY(maxclients)
609 {
610         maxclients = 0;
611         for (entity head = nextent(NULL); head; head = nextent(head)) {
612                 ++maxclients;
613         }
614 }
615
616 void default_delayedinit(entity this)
617 {
618         if(!scores_initialized)
619                 ScoreRules_generic();
620 }
621
622 void InitGameplayMode()
623 {
624         VoteReset();
625
626         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
627         get_mi_min_max(1);
628         // assign reflectively to avoid "assignment to world" warning
629         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
630             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
631             if (v) {
632             putentityfieldstring(i, world, sprintf("%v", v));
633             if (++done == 2) break;
634         }
635         }
636         // currently, NetRadiant's limit is 131072 qu for each side
637         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
638         // set the distance according to map size but don't go over the limit to avoid issues with float precision
639         // in case somebody makes extremely large maps
640         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
641
642         MapInfo_LoadMapSettings(mapname);
643         GameRules_teams(false);
644
645         if (!cvar_value_issafe(world.fog))
646         {
647                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
648                 world.fog = string_null;
649         }
650         if(MapInfo_Map_fog != "")
651         {
652                 if(MapInfo_Map_fog == "none")
653                         world.fog = string_null;
654                 else
655                         world.fog = strzone(MapInfo_Map_fog);
656         }
657         clientstuff = strzone(MapInfo_Map_clientstuff);
658
659         MapInfo_ClearTemps();
660
661         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
662
663         cache_mutatormsg = strzone("");
664         cache_lastmutatormsg = strzone("");
665
666         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
667 }
668
669 void Map_MarkAsRecent(string m);
670 float world_already_spawned;
671 spawnfunc(worldspawn)
672 {
673         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
674
675         bool wantrestart = false;
676         {
677                 if (!server_is_dedicated)
678                 {
679                         // force unloading of server pk3 files when starting a listen server
680                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
681                         // restore csqc_progname too
682                         string expect = "csprogs.dat";
683                         wantrestart = cvar_string_normal("csqc_progname") != expect;
684                         cvar_set_normal("csqc_progname", expect);
685                 }
686                 else
687                 {
688                         // Try to use versioned csprogs from pk3
689                         // Only ever use versioned csprogs.dat files on dedicated servers;
690                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
691                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
692                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
693                         string select = "csprogs.dat";
694                         if (fexists(pk3csprogs)) select = pk3csprogs;
695                         if (cvar_string_normal("csqc_progname") != select)
696                         {
697                                 cvar_set_normal("csqc_progname", select);
698                                 wantrestart = true;
699                         }
700                         // Check for updates on startup
701                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
702                         int sentinel = fopen("progs.txt", FILE_READ);
703                         if (sentinel >= 0)
704                         {
705                                 string switchversion = fgets(sentinel);
706                                 fclose(sentinel);
707                                 if (switchversion != "" && switchversion != WATERMARK)
708                                 {
709                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
710                                         // if it doesn't exist, assume either:
711                                         //   a) the current program was overwritten
712                                         //   b) this is a client only update
713                                         string newprogs = sprintf("progs-%s.dat", switchversion);
714                                         if (fexists(newprogs))
715                                         {
716                                                 cvar_set_normal("sv_progs", newprogs);
717                                                 wantrestart = true;
718                                         }
719                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
720                                         if (fexists(newcsprogs))
721                                         {
722                                                 cvar_set_normal("csqc_progname", newcsprogs);
723                                                 wantrestart = true;
724                                         }
725                                 }
726                         }
727                 }
728                 if (wantrestart)
729                 {
730                         LOG_INFO("Restart requested");
731                         changelevel(mapname);
732                         // let initialization continue, shutdown depends on it
733                 }
734         }
735
736         cvar = cvar_normal;
737         cvar_string = cvar_string_normal;
738         cvar_set = cvar_set_normal;
739
740         if(world_already_spawned)
741                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
742         world_already_spawned = true;
743
744         delete_fn = remove_safely; // during spawning, watch what you remove!
745
746         cvar_changes_init(); // do this very early now so it REALLY matches the server config
747
748         // needs to be done so early because of the constants they create
749         static_init();
750
751         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
752
753         TemporaryDB = db_create();
754
755         // 0 normal
756         lightstyle(0, "m");
757
758         // 1 FLICKER (first variety)
759         lightstyle(1, "mmnmmommommnonmmonqnmmo");
760
761         // 2 SLOW STRONG PULSE
762         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
763
764         // 3 CANDLE (first variety)
765         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
766
767         // 4 FAST STROBE
768         lightstyle(4, "mamamamamama");
769
770         // 5 GENTLE PULSE 1
771         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
772
773         // 6 FLICKER (second variety)
774         lightstyle(6, "nmonqnmomnmomomno");
775
776         // 7 CANDLE (second variety)
777         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
778
779         // 8 CANDLE (third variety)
780         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
781
782         // 9 SLOW STROBE (fourth variety)
783         lightstyle(9, "aaaaaaaazzzzzzzz");
784
785         // 10 FLUORESCENT FLICKER
786         lightstyle(10, "mmamammmmammamamaaamammma");
787
788         // 11 SLOW PULSE NOT FADE TO BLACK
789         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
790
791         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
792
793         // 63 testing
794         lightstyle(63, "a");
795
796         if(autocvar_g_campaign)
797                 CampaignPreInit();
798
799         Map_MarkAsRecent(mapname);
800
801         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
802
803         InitGameplayMode();
804         static_init_late();
805         static_init_precache();
806         readlevelcvars();
807         GrappleHookInit();
808
809         GameRules_limit_fallbacks();
810
811         if(warmup_limit == 0)
812                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
813
814         player_count = 0;
815         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
816         if(bot_waypoints_for_items == 1)
817                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
818                         bot_waypoints_for_items = 0;
819
820         WaypointSprite_Init();
821
822         GameLogInit(); // prepare everything
823         // NOTE for matchid:
824         // changing the logic generating it is okay. But:
825         // it HAS to stay <= 64 chars
826         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
827         if(autocvar_sv_eventlog)
828         {
829                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
830                 matchid = strzone(s);
831
832                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
833                 s = ":gameinfo:mutators:LIST";
834
835                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
836                 s = M_ARGV(0, string);
837
838                 // initialiation stuff, not good in the mutator system
839                 if(!autocvar_g_use_ammunition)
840                         s = strcat(s, ":no_use_ammunition");
841
842                 // initialiation stuff, not good in the mutator system
843                 if(autocvar_g_pickup_items == 0)
844                         s = strcat(s, ":no_pickup_items");
845                 if(autocvar_g_pickup_items > 0)
846                         s = strcat(s, ":pickup_items");
847
848                 // initialiation stuff, not good in the mutator system
849                 if(autocvar_g_weaponarena != "0")
850                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
851
852                 // TODO to mutator system
853                 if(autocvar_g_norecoil)
854                         s = strcat(s, ":norecoil");
855
856                 // TODO to mutator system
857                 if(autocvar_g_powerups == 0)
858                         s = strcat(s, ":no_powerups");
859                 if(autocvar_g_powerups > 0)
860                         s = strcat(s, ":powerups");
861
862                 GameLogEcho(s);
863                 GameLogEcho(":gameinfo:end");
864         }
865         else
866                 matchid = strzone(ftos(random()));
867
868         cvar_set("nextmap", "");
869
870         SetDefaultAlpha();
871
872         if(autocvar_g_campaign)
873                 CampaignPostInit();
874
875         Ban_LoadBans();
876
877         MapInfo_Enumerate();
878         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
879
880         if(fexists(strcat("scripts/", mapname, ".arena")))
881                 cvar_settemp("sv_q3acompat_machineshotgunswap", "1");
882
883         if(fexists(strcat("scripts/", mapname, ".defi")))
884                 cvar_settemp("sv_q3defragcompat", "1");
885
886         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
887         {
888                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
889                 if(fd != -1)
890                 {
891                         string s;
892                         while((s = fgets(fd)))
893                         {
894                                 int l = tokenize_console(s);
895                                 if(l < 2)
896                                         continue;
897                                 if(argv(0) == "cd")
898                                 {
899                                         string trackname = argv(2);
900                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
901                                         LOG_INFO("  cdtrack ", trackname);
902                                         if (cvar_value_issafe(trackname))
903                                         {
904                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
905                                                 strcpy(clientstuff, newstuff);
906                                         }
907                                 }
908                                 else if(argv(0) == "fog")
909                                 {
910                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
911                                         LOG_INFO("  \"fog\" \"", s, "\"");
912                                 }
913                                 else if(argv(0) == "set")
914                                 {
915                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
916                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
917                                 }
918                                 else if(argv(0) != "//")
919                                 {
920                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
921                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
922                                 }
923                         }
924                         fclose(fd);
925                 }
926         }
927
928         WeaponStats_Init();
929
930         Nagger_Init();
931
932         next_pingtime = time + 5;
933
934         // set up information replies for clients and server to use
935         maplist_reply = strzone(getmaplist());
936         lsmaps_reply = strzone(getlsmaps());
937         monsterlist_reply = strzone(getmonsterlist());
938         for(int i = 0; i < 10; ++i)
939         {
940                 string s = getrecords(i);
941                 if (s)
942                         records_reply[i] = strzone(s);
943         }
944         ladder_reply = strzone(getladder());
945         rankings_reply = strzone(getrankings());
946
947         // begin other init
948         ClientInit_Spawn();
949         RandomSeed_Spawn();
950         PingPLReport_Spawn();
951
952         CheatInit();
953
954         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
955
956         // fill sv_curl_serverpackages from .serverpackage files
957         if (autocvar_sv_curl_serverpackages_auto)
958         {
959                 string s = "csprogs-" WATERMARK ".txt";
960                 // remove automatically managed files from the list to prevent duplicates
961                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
962                 {
963                         string pkg = argv(i);
964                         if (startsWith(pkg, "csprogs-")) continue;
965                         if (endsWith(pkg, "-serverpackage.txt")) continue;
966                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
967                         s = cons(s, pkg);
968                 }
969                 // add automatically managed files to the list
970                 #define X(match) MACRO_BEGIN \
971                         int fd = search_begin(match, true, false); \
972                         if (fd >= 0) \
973                         { \
974                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
975                                 { \
976                                         s = cons(s, search_getfilename(fd, i)); \
977                                 } \
978                                 search_end(fd); \
979                         } \
980                 MACRO_END
981                 X("*-serverpackage.txt");
982                 X("*.serverpackage");
983                 #undef X
984                 cvar_set("sv_curl_serverpackages", s);
985         }
986
987         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
988         modname = "Xonotic";
989         // physics/balance/config changes that count as mod
990         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
991                 modname = cvar_string("g_mod_physics");
992         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
993                 modname = cvar_string("g_mod_balance");
994         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
995                 modname = cvar_string("g_mod_config");
996         // extra mutators that deserve to count as mod
997         MUTATOR_CALLHOOK(SetModname, modname);
998         modname = M_ARGV(0, string);
999
1000         // save it for later
1001         modname = strzone(modname);
1002
1003         WinningConditionHelper(this); // set worldstatus
1004
1005         world_initialized = 1;
1006         __spawnfunc_spawn_all();
1007 }
1008
1009 spawnfunc(light)
1010 {
1011         //makestatic (this); // Who the f___ did that?
1012         delete(this);
1013 }
1014
1015 string GetGametype()
1016 {
1017         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1018 }
1019
1020 string GetMapname()
1021 {
1022         return mapname;
1023 }
1024
1025 float Map_Count, Map_Current;
1026 string Map_Current_Name;
1027
1028 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1029 int GetMaplistPosition()
1030 {
1031         string map = GetMapname();
1032         int idx = autocvar_g_maplist_index;
1033
1034         if(idx >= 0)
1035         {
1036                 if(idx < Map_Count)
1037                 {
1038                         if(map == argv(idx))
1039                         {
1040                                 return idx;
1041                         }
1042                 }
1043         }
1044
1045         for(int pos = 0; pos < Map_Count; ++pos)
1046         {
1047                 if(map == argv(pos))
1048                         return pos;
1049         }
1050
1051         // resume normal maplist rotation if current map is not in g_maplist
1052         return idx;
1053 }
1054
1055 bool MapHasRightSize(string map)
1056 {
1057         int minplayers = max(0, floor(autocvar_minplayers));
1058         if (teamplay)
1059                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1060         if (autocvar_g_maplist_check_waypoints
1061                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1062         {
1063                 string checkwp_msg = strcat("checkwp ", map);
1064                 if(!fexists(strcat("maps/", map, ".waypoints")))
1065                 {
1066                         LOG_TRACE(checkwp_msg, ": no waypoints");
1067                         return false;
1068                 }
1069                 LOG_TRACE(checkwp_msg, ": has waypoints");
1070         }
1071
1072         if(autocvar_g_maplist_ignore_sizes)
1073                 return true;
1074
1075         // open map size restriction file
1076         string opensize_msg = strcat("opensize ", map);
1077         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1078         int player_limit = ((autocvar_g_maplist_sizes_count_maxplayers) ? GetPlayerLimit() : 0);
1079         int pcount = ((player_limit > 0) ? min(player_count, player_limit) : player_count); // bind it to the player limit so that forced spectators don't influence the limits
1080         if(!autocvar_g_maplist_sizes_count_bots)
1081                 pcount -= currentbots;
1082         if(fh >= 0)
1083         {
1084                 opensize_msg = strcat(opensize_msg, ": ok, ");
1085                 int mapmin = stoi(fgets(fh));
1086                 int mapmax = stoi(fgets(fh));
1087                 fclose(fh);
1088                 if(pcount < mapmin)
1089                 {
1090                         LOG_TRACE(opensize_msg, "not enough");
1091                         return false;
1092                 }
1093                 if(mapmax && pcount > mapmax)
1094                 {
1095                         LOG_TRACE(opensize_msg, "too many");
1096                         return false;
1097                 }
1098                 LOG_TRACE(opensize_msg, "right size");
1099                 return true;
1100         }
1101         LOG_TRACE(opensize_msg, ": not found");
1102         return true;
1103 }
1104
1105 string Map_Filename(float position)
1106 {
1107         return strcat("maps/", argv(position), ".bsp");
1108 }
1109
1110 void Map_MarkAsRecent(string m)
1111 {
1112         cvar_set("g_maplist_mostrecent", strwords(cons(m, autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1113 }
1114
1115 float Map_IsRecent(string m)
1116 {
1117         return strhasword(autocvar_g_maplist_mostrecent, m);
1118 }
1119
1120 float Map_Check(float position, float pass)
1121 {
1122         string filename;
1123         string map_next;
1124         map_next = argv(position);
1125         if(pass <= 1)
1126         {
1127                 if(Map_IsRecent(map_next))
1128                         return 0;
1129         }
1130         filename = Map_Filename(position);
1131         if(MapInfo_CheckMap(map_next))
1132         {
1133                 if(pass == 2)
1134                         return 1;
1135                 if(MapHasRightSize(map_next))
1136                         return 1;
1137                 return 0;
1138         }
1139         else
1140                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1141
1142         return 0;
1143 }
1144
1145 void Map_Goto_SetStr(string nextmapname)
1146 {
1147         if(getmapname_stored != "")
1148                 strunzone(getmapname_stored);
1149         if(nextmapname == "")
1150                 getmapname_stored = "";
1151         else
1152                 getmapname_stored = strzone(nextmapname);
1153 }
1154
1155 void Map_Goto_SetFloat(float position)
1156 {
1157         cvar_set("g_maplist_index", ftos(position));
1158         Map_Goto_SetStr(argv(position));
1159 }
1160
1161 void Map_Goto(float reinit)
1162 {
1163         MapInfo_LoadMap(getmapname_stored, reinit);
1164 }
1165
1166 // return codes of map selectors:
1167 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1168 //   -2 = permanent failure
1169 float MaplistMethod_Iterate() // usual method
1170 {
1171         float pass, i;
1172
1173         LOG_TRACE("Trying MaplistMethod_Iterate");
1174
1175         for(pass = 1; pass <= 2; ++pass)
1176         {
1177                 for(i = 1; i < Map_Count; ++i)
1178                 {
1179                         float mapindex;
1180                         mapindex = (i + Map_Current) % Map_Count;
1181                         if(Map_Check(mapindex, pass))
1182                                 return mapindex;
1183                 }
1184         }
1185         return -1;
1186 }
1187
1188 float MaplistMethod_Repeat() // fallback method
1189 {
1190         LOG_TRACE("Trying MaplistMethod_Repeat");
1191
1192         if(Map_Check(Map_Current, 2))
1193                 return Map_Current;
1194         return -2;
1195 }
1196
1197 float MaplistMethod_Random() // random map selection
1198 {
1199         float i, imax;
1200
1201         LOG_TRACE("Trying MaplistMethod_Random");
1202
1203         imax = 42;
1204
1205         for(i = 0; i <= imax; ++i)
1206         {
1207                 float mapindex;
1208                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1209                 if(Map_Check(mapindex, 1))
1210                         return mapindex;
1211         }
1212         return -1;
1213 }
1214
1215 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1216 // the exponent sets a bias on the map selection:
1217 // the higher the exponent, the less likely "shortly repeated" same maps are
1218 {
1219         float i, j, imax, insertpos;
1220
1221         LOG_TRACE("Trying MaplistMethod_Shuffle");
1222
1223         imax = 42;
1224
1225         for(i = 0; i <= imax; ++i)
1226         {
1227                 string newlist;
1228
1229                 // now reinsert this at another position
1230                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1231                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1232                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1233                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1234
1235                 // insert the current map there
1236                 newlist = "";
1237                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1238                         newlist = strcat(newlist, " ", argv(j));
1239                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1240                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1241                         newlist = strcat(newlist, " ", argv(j));
1242                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1243                 cvar_set("g_maplist", newlist);
1244                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1245
1246                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1247                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1248                 if(Map_Check(Map_Current, 1))
1249                         return Map_Current;
1250         }
1251         return -1;
1252 }
1253
1254 void Maplist_Init()
1255 {
1256         float i = Map_Count = 0;
1257         if(autocvar_g_maplist != "")
1258         {
1259                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1260                 for (i = 0; i < Map_Count; ++i)
1261                 {
1262                         if (Map_Check(i, 2))
1263                                 break;
1264                 }
1265         }
1266
1267         if (i == Map_Count)
1268         {
1269                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1270                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1271                 if(autocvar_g_maplist_shuffle)
1272                         ShuffleMaplist();
1273                 if(!server_is_dedicated)
1274                         localcmd("\nmenu_cmd sync\n");
1275                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1276         }
1277         if(Map_Count == 0)
1278                 error("empty maplist, cannot select a new map");
1279         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1280
1281         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1282         // this may or may not be correct, but who cares, in the worst case a map
1283         // isn't chosen in the first pass that should have been
1284 }
1285
1286 string GetNextMap()
1287 {
1288         Maplist_Init();
1289         float nextMap = -1;
1290
1291         if(nextMap == -1)
1292                 if(autocvar_g_maplist_shuffle > 0)
1293                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1294
1295         if(nextMap == -1)
1296                 if(autocvar_g_maplist_selectrandom)
1297                         nextMap = MaplistMethod_Random();
1298
1299         if(nextMap == -1)
1300                 nextMap = MaplistMethod_Iterate();
1301
1302         if(nextMap == -1)
1303                 nextMap = MaplistMethod_Repeat();
1304
1305         if(nextMap >= 0)
1306         {
1307                 Map_Goto_SetFloat(nextMap);
1308                 return getmapname_stored;
1309         }
1310
1311         return "";
1312 }
1313
1314 float DoNextMapOverride(float reinit)
1315 {
1316         if(autocvar_g_campaign)
1317         {
1318                 CampaignPostIntermission();
1319                 alreadychangedlevel = true;
1320                 return true;
1321         }
1322         if(autocvar_quit_when_empty)
1323         {
1324                 if(player_count <= currentbots)
1325                 {
1326                         localcmd("quit\n");
1327                         alreadychangedlevel = true;
1328                         return true;
1329                 }
1330         }
1331         if(autocvar_quit_and_redirect != "")
1332         {
1333                 redirection_target = strzone(autocvar_quit_and_redirect);
1334                 alreadychangedlevel = true;
1335                 return true;
1336         }
1337         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1338         {
1339                 localcmd("restart\n");
1340                 alreadychangedlevel = true;
1341                 return true;
1342         }
1343         if(autocvar_nextmap != "")
1344         {
1345                 string m;
1346                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1347                 cvar_set("nextmap",m);
1348
1349                 if(!m || gametypevote)
1350                         return false;
1351                 if(autocvar_sv_vote_gametype)
1352                 {
1353                         Map_Goto_SetStr(m);
1354                         return false;
1355                 }
1356
1357                 if(MapInfo_CheckMap(m))
1358                 {
1359                         Map_Goto_SetStr(m);
1360                         Map_Goto(reinit);
1361                         alreadychangedlevel = true;
1362                         return true;
1363                 }
1364         }
1365         if(!reinit && autocvar_lastlevel)
1366         {
1367                 cvar_settemp_restore();
1368                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1369                 alreadychangedlevel = true;
1370                 return true;
1371         }
1372         return false;
1373 }
1374
1375 void GotoNextMap(float reinit)
1376 {
1377         //string nextmap;
1378         //float n, nummaps;
1379         //string s;
1380         if (alreadychangedlevel)
1381                 return;
1382         alreadychangedlevel = true;
1383
1384         string nextMap = GetNextMap();
1385         if(nextMap == "")
1386                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1387         Map_Goto(reinit);
1388 }
1389
1390
1391 /*
1392 ============
1393 IntermissionThink
1394
1395 When the player presses attack or jump, change to the next level
1396 ============
1397 */
1398 .float autoscreenshot;
1399 void IntermissionThink(entity this)
1400 {
1401         FixIntermissionClient(this);
1402
1403         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1404         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1405
1406         if( (server_screenshot || client_screenshot)
1407                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1408         {
1409                 this.autoscreenshot = -1;
1410                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1411                 return;
1412         }
1413
1414         if (time < intermission_exittime)
1415                 return;
1416
1417         if(!mapvote_initialized)
1418                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1419                         return;
1420
1421         MapVote_Start();
1422 }
1423
1424 /*
1425 ===============================================================================
1426
1427 RULES
1428
1429 ===============================================================================
1430 */
1431
1432 void DumpStats(float final)
1433 {
1434         float file;
1435         string s;
1436         float to_console;
1437         float to_eventlog;
1438         float to_file;
1439         float i;
1440
1441         to_console = autocvar_sv_logscores_console;
1442         to_eventlog = autocvar_sv_eventlog;
1443         to_file = autocvar_sv_logscores_file;
1444
1445         if(!final)
1446         {
1447                 to_console = true; // always print printstats replies
1448                 to_eventlog = false; // but never print them to the event log
1449         }
1450
1451         if(to_eventlog)
1452                 if(autocvar_sv_eventlog_console)
1453                         to_console = false; // otherwise we get the output twice
1454
1455         if(final)
1456                 s = ":scores:";
1457         else
1458                 s = ":status:";
1459         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1460
1461         if(to_console)
1462                 LOG_INFO(s);
1463         if(to_eventlog)
1464                 GameLogEcho(s);
1465
1466         file = -1;
1467         if(to_file)
1468         {
1469                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1470                 if(file == -1)
1471                         to_file = false;
1472                 else
1473                         fputs(file, strcat(s, "\n"));
1474         }
1475
1476         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1477         if(to_console)
1478                 LOG_INFO(s);
1479         if(to_eventlog)
1480                 GameLogEcho(s);
1481         if(to_file)
1482                 fputs(file, strcat(s, "\n"));
1483
1484         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1485                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1486                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1487                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1488                         s = strcat(s, ftos(it.team), ":");
1489                 else
1490                         s = strcat(s, "spectator:");
1491
1492                 if(to_console)
1493                         LOG_INFO(s, playername(it, false));
1494                 if(to_eventlog)
1495                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1496                 if(to_file)
1497                         fputs(file, strcat(s, playername(it, false), "\n"));
1498         });
1499
1500         if(teamplay)
1501         {
1502                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1503                 if(to_console)
1504                         LOG_INFO(s);
1505                 if(to_eventlog)
1506                         GameLogEcho(s);
1507                 if(to_file)
1508                         fputs(file, strcat(s, "\n"));
1509
1510                 for(i = 1; i < 16; ++i)
1511                 {
1512                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1513                         s = strcat(s, ":", ftos(i));
1514                         if(to_console)
1515                                 LOG_INFO(s);
1516                         if(to_eventlog)
1517                                 GameLogEcho(s);
1518                         if(to_file)
1519                                 fputs(file, strcat(s, "\n"));
1520                 }
1521         }
1522
1523         if(to_console)
1524                 LOG_INFO(":end");
1525         if(to_eventlog)
1526                 GameLogEcho(":end");
1527         if(to_file)
1528         {
1529                 fputs(file, ":end\n");
1530                 fclose(file);
1531         }
1532 }
1533
1534 void FixIntermissionClient(entity e)
1535 {
1536         if(!e.autoscreenshot) // initial call
1537         {
1538                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1539                 SetResourceExplicit(e, RES_HEALTH, -2342);
1540                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1541                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1542                 {
1543                     .entity weaponentity = weaponentities[slot];
1544                         if(e.(weaponentity))
1545                         {
1546                                 e.(weaponentity).effects = EF_NODRAW;
1547                                 if (e.(weaponentity).weaponchild)
1548                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1549                         }
1550                 }
1551                 if(IS_REAL_CLIENT(e))
1552                 {
1553                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1554                         RandomSelection_Init();
1555                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1556                                 RandomSelection_AddString(it, 1, 1);
1557                         });
1558                         if (RandomSelection_chosen_string != "")
1559                         {
1560                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1561                         }
1562                         msg_entity = e;
1563                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1564                 }
1565         }
1566 }
1567
1568 /*
1569 go to the next level for deathmatch
1570 only called if a time or frag limit has expired
1571 */
1572 void NextLevel()
1573 {
1574         game_stopped = true;
1575         intermission_running = 1; // game over
1576
1577         // enforce a wait time before allowing changelevel
1578         if(player_count > 0)
1579                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1580         else
1581                 intermission_exittime = -1;
1582
1583         /*
1584         WriteByte (MSG_ALL, SVC_CDTRACK);
1585         WriteByte (MSG_ALL, 3);
1586         WriteByte (MSG_ALL, 3);
1587         // done in FixIntermission
1588         */
1589
1590         //pos = FindIntermission ();
1591
1592         VoteReset();
1593
1594         DumpStats(true);
1595
1596         // send statistics
1597         PlayerStats_GameReport(true);
1598         WeaponStats_Shutdown();
1599
1600         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1601
1602         if(autocvar_sv_eventlog)
1603                 GameLogEcho(":gameover");
1604
1605         GameLogClose();
1606
1607         FOREACH_CLIENT(IS_PLAYER(it), {
1608                 FixIntermissionClient(it);
1609                 if(it.winning)
1610                         bprint(playername(it, false), " ^7wins.\n");
1611         });
1612
1613         target_music_kill();
1614
1615         if(autocvar_g_campaign)
1616                 CampaignPreIntermission();
1617
1618         MUTATOR_CALLHOOK(MatchEnd);
1619
1620         localcmd("\nsv_hook_gameend\n");
1621 }
1622
1623
1624 float InitiateSuddenDeath()
1625 {
1626         // Check first whether normal overtimes could be added before initiating suddendeath mode
1627         // - for this timelimit_overtime needs to be >0 of course
1628         // - also check the winning condition calculated in the previous frame and only add normal overtime
1629         //   again, if at the point at which timelimit would be extended again, still no winner was found
1630         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1631                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1632                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1633         {
1634                 return 1; // need to call InitiateOvertime later
1635         }
1636         else
1637         {
1638                 if(!checkrules_suddendeathend)
1639                 {
1640                         if(autocvar_g_campaign)
1641                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1642                         else
1643                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1644                         if(g_race && !g_race_qualifying)
1645                                 race_StartCompleting();
1646                 }
1647                 return 0;
1648         }
1649 }
1650
1651 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1652 {
1653         ++checkrules_overtimesadded;
1654         //add one more overtime by simply extending the timelimit
1655         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1656         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1657 }
1658
1659 float GetWinningCode(float fraglimitreached, float equality)
1660 {
1661         if(autocvar_g_campaign == 1)
1662         {
1663                 if(fraglimitreached)
1664                         return WINNING_YES;
1665                 else
1666                         return WINNING_NO;
1667         }
1668         else
1669         {
1670                 if(equality)
1671                 {
1672                         if(fraglimitreached)
1673                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1674                         else
1675                                 return WINNING_NEVER;
1676                 }
1677                 else
1678                 {
1679                         if(fraglimitreached)
1680                                 return WINNING_YES;
1681                         else
1682                                 return WINNING_NO;
1683                 }
1684         }
1685 }
1686
1687 // set the .winning flag for exactly those players with a given field value
1688 void SetWinners(.float field, float value)
1689 {
1690         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1691 }
1692
1693 // set the .winning flag for those players with a given field value
1694 void AddWinners(.float field, float value)
1695 {
1696         FOREACH_CLIENT(IS_PLAYER(it), {
1697                 if(it.(field) == value)
1698                         it.winning = 1;
1699         });
1700 }
1701
1702 // clear the .winning flags
1703 void ClearWinners()
1704 {
1705         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1706 }
1707
1708 void ShuffleMaplist()
1709 {
1710         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1711 }
1712
1713 int fragsleft_last;
1714 float WinningCondition_Scores(float limit, float leadlimit)
1715 {
1716         // TODO make everything use THIS winning condition (except LMS)
1717         WinningConditionHelper(NULL);
1718
1719         if(teamplay)
1720         {
1721                 for (int i = 1; i < 5; ++i)
1722                 {
1723                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1724                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1725                 }
1726         }
1727
1728         ClearWinners();
1729         if(WinningConditionHelper_winner)
1730                 WinningConditionHelper_winner.winning = 1;
1731         if(WinningConditionHelper_winnerteam >= 0)
1732                 SetWinners(team, WinningConditionHelper_winnerteam);
1733
1734         if(WinningConditionHelper_lowerisbetter)
1735         {
1736                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1737                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1738                 limit = -limit;
1739         }
1740
1741         if(WinningConditionHelper_zeroisworst)
1742                 leadlimit = 0; // not supported in this mode
1743
1744         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1745         {
1746                 float fragsleft = FLOAT_MAX, leadingfragsleft = FLOAT_MAX;
1747                 if (limit)
1748                         fragsleft = limit - WinningConditionHelper_topscore;
1749                 if (leadlimit)
1750                         leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1751
1752                 if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1753                         fragsleft = max(fragsleft, leadingfragsleft);
1754                 else
1755                         fragsleft = min(fragsleft, leadingfragsleft);
1756
1757                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1758                 {
1759                         if (fragsleft == 1)
1760                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1761                         else if (fragsleft == 2)
1762                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1763                         else if (fragsleft == 3)
1764                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1765
1766                         fragsleft_last = fragsleft;
1767                 }
1768         }
1769
1770         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1771         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1772
1773         bool limit_reached;
1774         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1775         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1776                 limit_reached = (fraglimit_reached && leadlimit_reached);
1777         else
1778                 limit_reached = (fraglimit_reached || leadlimit_reached);
1779
1780         return GetWinningCode(
1781                 WinningConditionHelper_topscore && limit_reached,
1782                 WinningConditionHelper_equality
1783         );
1784 }
1785
1786 float WinningCondition_RanOutOfSpawns()
1787 {
1788         if(have_team_spawns <= 0)
1789                 return WINNING_NO;
1790
1791         if(!autocvar_g_spawn_useallspawns)
1792                 return WINNING_NO;
1793
1794         if(!some_spawn_has_been_used)
1795                 return WINNING_NO;
1796
1797         for (int i = 1; i < 5; ++i)
1798         {
1799                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1800         }
1801
1802         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1803         {
1804                 if (Team_IsValidTeam(it.team))
1805                 {
1806                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1807                 }
1808         });
1809
1810         IL_EACH(g_spawnpoints, true,
1811         {
1812                 if (Team_IsValidTeam(it.team))
1813                 {
1814                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1815                 }
1816         });
1817
1818         ClearWinners();
1819         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1820         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1821         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1822         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1823         if(team1_score + team2_score + team3_score + team4_score == 0)
1824         {
1825                 checkrules_equality = true;
1826                 return WINNING_YES;
1827         }
1828         else if(team1_score + team2_score + team3_score + team4_score == 1)
1829         {
1830                 float t, i;
1831                 if(team1_score)
1832                         t = 1;
1833                 else if(team2_score)
1834                         t = 2;
1835                 else if(team3_score)
1836                         t = 3;
1837                 else // if(team4_score)
1838                         t = 4;
1839                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1840                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1841                 {
1842                         for (int j = 1; j <= NUM_TEAMS; ++j)
1843                         {
1844                                 if (t == j)
1845                                 {
1846                                         continue;
1847                                 }
1848                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1849                                 {
1850                                         continue;
1851                                 }
1852                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1853                         }
1854                 }
1855
1856                 AddWinners(team, t);
1857                 return WINNING_YES;
1858         }
1859         else
1860                 return WINNING_NO;
1861 }
1862
1863 /*
1864 ============
1865 CheckRules_World
1866
1867 Exit deathmatch games upon conditions
1868 ============
1869 */
1870 void CheckRules_World()
1871 {
1872         VoteThink();
1873         MapVote_Think();
1874
1875         SetDefaultAlpha();
1876
1877         if (intermission_running) // someone else quit the game already
1878         {
1879                 if(player_count == 0) // Nobody there? Then let's go to the next map
1880                         MapVote_Start();
1881                         // this will actually check the player count in the next frame
1882                         // again, but this shouldn't hurt
1883                 return;
1884         }
1885
1886         float timelimit = autocvar_timelimit * 60;
1887         float fraglimit = autocvar_fraglimit;
1888         float leadlimit = autocvar_leadlimit;
1889         if (leadlimit < 0) leadlimit = 0;
1890
1891         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1892         {
1893                 if(timelimit > 0)
1894                         timelimit = 0; // timelimit is not made for warmup
1895                 if(fraglimit > 0)
1896                         fraglimit = 0; // no fraglimit for now
1897                 leadlimit = 0; // no leadlimit for now
1898         }
1899
1900         if(timelimit > 0)
1901         {
1902                 timelimit += game_starttime;
1903         }
1904         else if (timelimit < 0)
1905         {
1906                 // endmatch
1907                 NextLevel();
1908                 return;
1909         }
1910
1911         float wantovertime;
1912         wantovertime = 0;
1913
1914         if(checkrules_suddendeathend)
1915         {
1916                 if(!checkrules_suddendeathwarning)
1917                 {
1918                         checkrules_suddendeathwarning = true;
1919                         if(g_race && !g_race_qualifying)
1920                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1921                         else
1922                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1923                 }
1924         }
1925         else
1926         {
1927                 if (timelimit && time >= timelimit)
1928                 {
1929                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1930                         {
1931                                 float totalplayers;
1932                                 float playerswithlaps;
1933                                 float readyplayers;
1934                                 totalplayers = playerswithlaps = readyplayers = 0;
1935                                 FOREACH_CLIENT(IS_PLAYER(it), {
1936                                         ++totalplayers;
1937                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1938                                                 ++playerswithlaps;
1939                                         if(it.ready)
1940                                                 ++readyplayers;
1941                                 });
1942
1943                                 // at least 2 of the players have completed a lap: start the RACE
1944                                 // otherwise, the players should end the qualifying on their own
1945                                 if(readyplayers || playerswithlaps >= 2)
1946                                 {
1947                                         checkrules_suddendeathend = 0;
1948                                         ReadyRestart(); // go to race
1949                                         return;
1950                                 }
1951                                 else
1952                                         wantovertime |= InitiateSuddenDeath();
1953                         }
1954                         else
1955                                 wantovertime |= InitiateSuddenDeath();
1956                 }
1957         }
1958
1959         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1960         {
1961                 NextLevel();
1962                 return;
1963         }
1964
1965         int checkrules_status = WinningCondition_RanOutOfSpawns();
1966         if(checkrules_status == WINNING_YES)
1967                 bprint("Hey! Someone ran out of spawns!\n");
1968         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1969                 checkrules_status = M_ARGV(0, float);
1970         else
1971                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1972
1973         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1974         {
1975                 checkrules_status = WINNING_NEVER;
1976                 checkrules_overtimesadded = -1;
1977                 wantovertime |= InitiateSuddenDeath();
1978         }
1979
1980         if(checkrules_status == WINNING_NEVER)
1981                 // equality cases! Nobody wins if the overtime ends in a draw.
1982                 ClearWinners();
1983
1984         if(wantovertime)
1985         {
1986                 if(checkrules_status == WINNING_NEVER)
1987                         InitiateOvertime();
1988                 else
1989                         checkrules_status = WINNING_YES;
1990         }
1991
1992         if(checkrules_suddendeathend)
1993                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1994                         checkrules_status = WINNING_YES;
1995
1996         if(checkrules_status == WINNING_YES)
1997         {
1998                 //print("WINNING\n");
1999                 NextLevel();
2000         }
2001 }
2002
2003 string GotoMap(string m)
2004 {
2005         m = GameTypeVote_MapInfo_FixName(m);
2006         if (!m)
2007                 return "The map you suggested is not available on this server.";
2008         if (!autocvar_sv_vote_gametype)
2009         if(!MapInfo_CheckMap(m))
2010                 return "The map you suggested does not support the current game mode.";
2011         cvar_set("nextmap", m);
2012         cvar_set("timelimit", "-1");
2013         if(mapvote_initialized || alreadychangedlevel)
2014         {
2015                 if(DoNextMapOverride(0))
2016                         return "Map switch initiated.";
2017                 else
2018                         return "Hm... no. For some reason I like THIS map more.";
2019         }
2020         else
2021                 return "Map switch will happen after scoreboard.";
2022 }
2023
2024 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2025 void RunThink(entity this)
2026 {
2027         // don't let things stay in the past.
2028         // it is possible to start that way by a trigger with a local time.
2029         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2030                 return;
2031
2032         float oldtime = time; // do we need to save this?
2033
2034         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2035         {
2036                 time = max(oldtime, this.nextthink);
2037                 this.nextthink = 0;
2038
2039                 if(getthink(this))
2040                         getthink(this)(this);
2041                 // mods often set nextthink to time to cause a think every frame,
2042                 // we don't want to loop in that case, so exit if the new nextthink is
2043                 // <= the time the qc was told, also exit if it is past the end of the
2044                 // frame
2045                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2046                         break;
2047         }
2048
2049         time = oldtime;
2050 }
2051
2052 bool autocvar_sv_freezenonclients;
2053 bool autocvar_sv_gameplayfix_delayprojectiles = false;
2054 void Physics_Frame()
2055 {
2056         if(autocvar_sv_freezenonclients)
2057                 return;
2058
2059         IL_EACH(g_moveables, true,
2060         {
2061                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2062                         continue;
2063
2064                 //set_movetype(it, it.move_movetype);
2065                 // inline the set_movetype function, since this is called a lot
2066                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2067
2068                 if(it.move_movetype == MOVETYPE_NONE)
2069                         continue;
2070
2071                 if(it.move_qcphysics)
2072                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2073
2074                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2075                 {
2076                         // handle thinking here
2077                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2078                                 RunThink(it);
2079                 }
2080         });
2081
2082         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2083                 return;
2084
2085         IL_EACH(g_moveables, it.move_qcphysics,
2086         {
2087                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2088                         continue;
2089                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2090         });
2091 }
2092
2093 void systems_update();
2094 void EndFrame()
2095 {
2096         anticheat_endframe();
2097
2098         Physics_Frame();
2099
2100         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2101                 entity e = IS_SPEC(it) ? it.enemy : it;
2102                 if (e.typehitsound) {
2103                         STAT(TYPEHIT_TIME, it) = time;
2104                 } else if (e.killsound) {
2105                         STAT(KILL_TIME, it) = time;
2106                 } else if (e.damage_dealt) {
2107                         STAT(HIT_TIME, it) = time;
2108                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2109                 }
2110         });
2111         // add 1 frametime because after this, engine SV_Physics
2112         // increases time by a frametime and then networks the frame
2113         // add another frametime because client shows everything with
2114         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2115         // needed!
2116         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2117         FOREACH_CLIENT(true, {
2118                 it.typehitsound = false;
2119                 it.damage_dealt = 0;
2120                 it.killsound = false;
2121                 antilag_record(it, CS(it), altime);
2122         });
2123         IL_EACH(g_monsters, true,
2124         {
2125                 antilag_record(it, it, altime);
2126         });
2127         IL_EACH(g_projectiles, it.classname == "nade",
2128         {
2129                 antilag_record(it, it, altime);
2130         });
2131         systems_update();
2132         IL_ENDFRAME();
2133 }
2134
2135
2136 /*
2137  * RedirectionThink:
2138  * returns true if redirecting
2139  */
2140 float redirection_timeout;
2141 float redirection_nextthink;
2142 float RedirectionThink()
2143 {
2144         float clients_found;
2145
2146         if(redirection_target == "")
2147                 return false;
2148
2149         if(!redirection_timeout)
2150         {
2151                 cvar_set("sv_public", "-2");
2152                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2153                 if(redirection_target == "self")
2154                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2155                 else
2156                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2157         }
2158
2159         if(time < redirection_nextthink)
2160                 return true;
2161
2162         redirection_nextthink = time + 1;
2163
2164         clients_found = 0;
2165         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2166                 // TODO add timer
2167                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2168                 if(redirection_target == "self")
2169                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2170                 else
2171                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2172                 ++clients_found;
2173         });
2174
2175         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2176
2177         if(time > redirection_timeout || clients_found == 0)
2178                 localcmd("\nwait; wait; wait; quit\n");
2179
2180         return true;
2181 }
2182
2183 void RestoreGame()
2184 {
2185         // Loaded from a save game
2186         // some things then break, so let's work around them...
2187
2188         // Progs DB (capture records)
2189         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2190
2191         // Mapinfo
2192         MapInfo_Shutdown();
2193         MapInfo_Enumerate();
2194         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2195         WeaponStats_Init();
2196
2197         TargetMusic_RestoreGame();
2198 }
2199
2200 void Shutdown()
2201 {
2202         game_stopped = 2;
2203
2204         if(world_initialized > 0)
2205         {
2206                 world_initialized = 0;
2207                 LOG_TRACE("Saving persistent data...");
2208                 Ban_SaveBans();
2209
2210                 // playerstats with unfinished match
2211                 PlayerStats_GameReport(false);
2212
2213                 if(!cheatcount_total)
2214                 {
2215                         if(autocvar_sv_db_saveasdump)
2216                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2217                         else
2218                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2219                 }
2220                 if(autocvar_developer > 0)
2221                 {
2222                         if(autocvar_sv_db_saveasdump)
2223                                 db_dump(TemporaryDB, "server-temp.db");
2224                         else
2225                                 db_save(TemporaryDB, "server-temp.db");
2226                 }
2227                 CheatShutdown(); // must be after cheatcount check
2228                 db_close(ServerProgsDB);
2229                 db_close(TemporaryDB);
2230                 LOG_TRACE("Saving persistent data... done!");
2231                 // tell the bot system the game is ending now
2232                 bot_endgame();
2233
2234                 WeaponStats_Shutdown();
2235                 MapInfo_Shutdown();
2236         }
2237         else if(world_initialized == 0)
2238         {
2239                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2240         }
2241         else
2242         {
2243                 __init_dedicated_server_shutdown();
2244         }
2245 }