Revert "Merge branch 'TimePath/bot_api' into 'master'\r"
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2 #include "_all.qh"
3
4 #include "anticheat.qh"
5 #include "antilag.qh"
6 #include "bot/bot.qh"
7 #include "campaign.qh"
8 #include "cheats.qh"
9 #include "cl_client.qh"
10 #include "command/common.qh"
11 #include "command/getreplies.qh"
12 #include "command/sv_cmd.qh"
13 #include "command/vote.qh"
14 #include "g_hook.qh"
15 #include "ipban.qh"
16 #include "mapvoting.qh"
17 #include "mutators/mutators_include.qh"
18 #include "race.qh"
19 #include "scores.qh"
20 #include "teamplay.qh"
21 #include "weapons/weaponstats.qh"
22 #include "../common/buffs/all.qh"
23 #include "../common/constants.qh"
24 #include "../common/deathtypes.qh"
25 #include "../common/effects/effects.qh"
26 #include "../common/mapinfo.qh"
27 #include "../common/monsters/all.qh"
28 #include "../common/monsters/sv_monsters.qh"
29 #include "../common/vehicles/all.qh"
30 #include "../common/notifications.qh"
31 #include "../common/playerstats.qh"
32 #include "../common/stats.qh"
33 #include "../common/teams.qh"
34 #include "../common/util.qh"
35 #include "../common/items/all.qh"
36 #include "../common/weapons/all.qh"
37
38 const float LATENCY_THINKRATE = 10;
39 .float latency_sum;
40 .float latency_cnt;
41 .float latency_time;
42 entity pingplreport;
43 void PingPLReport_Think()
44 {SELFPARAM();
45         float delta;
46         entity e;
47
48         delta = 3 / maxclients;
49         if(delta < sys_frametime)
50                 delta = 0;
51         self.nextthink = time + delta;
52
53         e = edict_num(self.cnt + 1);
54         if(IS_REAL_CLIENT(e))
55         {
56                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
57                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
58                 WriteByte(MSG_BROADCAST, self.cnt);
59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
62
63                 // record latency times for clients throughout the match so we can report it to playerstats
64                 if(time > (e.latency_time + LATENCY_THINKRATE))
65                 {
66                         e.latency_sum += e.ping;
67                         e.latency_cnt += 1;
68                         e.latency_time = time;
69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
70                 }
71         }
72         else
73         {
74                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
75                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
76                 WriteByte(MSG_BROADCAST, self.cnt);
77                 WriteShort(MSG_BROADCAST, 0);
78                 WriteByte(MSG_BROADCAST, 0);
79                 WriteByte(MSG_BROADCAST, 0);
80         }
81         self.cnt = (self.cnt + 1) % maxclients;
82 }
83 void PingPLReport_Spawn()
84 {
85         pingplreport = spawn();
86         pingplreport.classname = "pingplreport";
87         pingplreport.think = PingPLReport_Think;
88         pingplreport.nextthink = time;
89 }
90
91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
92 string redirection_target;
93 float world_initialized;
94
95 string GetGametype();
96 void ShuffleMaplist();
97
98 void SetDefaultAlpha()
99 {
100         if(autocvar_g_running_guns)
101         {
102                 default_player_alpha = -1;
103                 default_weapon_alpha = +1;
104         }
105         else if(g_cloaked)
106         {
107                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
108                 default_weapon_alpha = default_player_alpha;
109         }
110         else
111         {
112                 default_player_alpha = autocvar_g_player_alpha;
113                 if(default_player_alpha == 0)
114                         default_player_alpha = 1;
115                 default_weapon_alpha = default_player_alpha;
116         }
117 }
118
119 void GotoFirstMap()
120 {SELFPARAM();
121         float n;
122         if(autocvar__sv_init)
123         {
124                 // cvar_set("_sv_init", "0");
125                 // we do NOT set this to 0 any more, so someone "accidentally" changing
126                 // to this "init" map on a dedicated server will cause no permanent
127                 // harm
128                 if(autocvar_g_maplist_shuffle)
129                         ShuffleMaplist();
130                 n = tokenizebyseparator(autocvar_g_maplist, " ");
131                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
132
133                 MapInfo_Enumerate();
134                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
135
136                 if(!DoNextMapOverride(1))
137                         GotoNextMap(1);
138
139                 return;
140         }
141
142         if(time < 5)
143         {
144                 self.nextthink = time;
145         }
146         else
147         {
148                 self.nextthink = time + 1;
149                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
150         }
151 }
152
153 void cvar_changes_init()
154 {
155         float h;
156         string k, v, d;
157         float n, i, adding, pureadding;
158
159         if(cvar_changes)
160                 strunzone(cvar_changes);
161         cvar_changes = string_null;
162         if(cvar_purechanges)
163                 strunzone(cvar_purechanges);
164         cvar_purechanges = string_null;
165         cvar_purechanges_count = 0;
166
167         h = buf_create();
168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
169         n = buf_getsize(h);
170
171         adding = true;
172         pureadding = true;
173
174         for(i = 0; i < n; ++i)
175         {
176                 k = bufstr_get(h, i);
177
178 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
179 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
180 #define BADCVAR(p) if(k == p) continue
181
182                 // general excludes and namespaces for server admin used cvars
183                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
184
185                 // internal
186                 BADPREFIX("csqc_");
187                 BADPREFIX("cvar_check_");
188                 BADCVAR("gamecfg");
189                 BADCVAR("g_configversion");
190                 BADCVAR("g_maplist_index");
191                 BADCVAR("halflifebsp");
192                 BADCVAR("sv_mapformat_is_quake2");
193                 BADCVAR("sv_mapformat_is_quake3");
194                 BADPREFIX("sv_world");
195
196                 // client
197                 BADPREFIX("chase_");
198                 BADPREFIX("cl_");
199                 BADPREFIX("con_");
200                 BADPREFIX("scoreboard_");
201                 BADPREFIX("g_campaign");
202                 BADPREFIX("g_waypointsprite_");
203                 BADPREFIX("gl_");
204                 BADPREFIX("joy");
205                 BADPREFIX("hud_");
206                 BADPREFIX("m_");
207                 BADPREFIX("menu_");
208                 BADPREFIX("net_slist_");
209                 BADPREFIX("r_");
210                 BADPREFIX("sbar_");
211                 BADPREFIX("scr_");
212                 BADPREFIX("snd_");
213                 BADPREFIX("show");
214                 BADPREFIX("sensitivity");
215                 BADPREFIX("userbind");
216                 BADPREFIX("v_");
217                 BADPREFIX("vid_");
218                 BADPREFIX("crosshair");
219                 BADCVAR("mod_q3bsp_lightmapmergepower");
220                 BADCVAR("mod_q3bsp_nolightmaps");
221                 BADCVAR("fov");
222                 BADCVAR("mastervolume");
223                 BADCVAR("volume");
224                 BADCVAR("bgmvolume");
225
226                 // private
227                 BADCVAR("developer");
228                 BADCVAR("log_dest_udp");
229                 BADCVAR("net_address");
230                 BADCVAR("net_address_ipv6");
231                 BADCVAR("port");
232                 BADCVAR("savedgamecfg");
233                 BADCVAR("serverconfig");
234                 BADCVAR("sv_autoscreenshot");
235                 BADCVAR("sv_heartbeatperiod");
236                 BADCVAR("sv_vote_master_password");
237                 BADCVAR("sys_colortranslation");
238                 BADCVAR("sys_specialcharactertranslation");
239                 BADCVAR("timeformat");
240                 BADCVAR("timestamps");
241                 BADPREFIX("developer_");
242                 BADPREFIX("g_ban_");
243                 BADPREFIX("g_banned_list");
244                 BADPREFIX("g_chat_flood_");
245                 BADPREFIX("g_ghost_items");
246                 BADPREFIX("g_playerstats_");
247                 BADPREFIX("g_respawn_ghosts");
248                 BADPREFIX("g_voice_flood_");
249                 BADPREFIX("log_file");
250                 BADPREFIX("rcon_");
251                 BADPREFIX("sv_allowdownloads");
252                 BADPREFIX("sv_autodemo");
253                 BADPREFIX("sv_curl_");
254                 BADPREFIX("sv_eventlog");
255                 BADPREFIX("sv_logscores_");
256                 BADPREFIX("sv_master");
257                 BADPREFIX("sv_weaponstats_");
258                 BADPREFIX("sv_waypointsprite_");
259                 BADCVAR("rescan_pending");
260
261                 // these can contain player IDs, so better hide
262                 BADPREFIX("g_forced_team_");
263
264                 // mapinfo
265                 BADCVAR("fraglimit");
266                 BADCVAR("g_assault");
267                 BADCVAR("g_ca");
268                 BADCVAR("g_ca_teams");
269                 BADCVAR("g_ctf");
270                 BADCVAR("g_cts");
271                 BADCVAR("g_dm");
272                 BADCVAR("g_domination");
273                 BADCVAR("g_domination_default_teams");
274                 BADCVAR("g_freezetag");
275                 BADCVAR("g_freezetag_teams");
276                 BADCVAR("g_invasion_teams");
277                 BADCVAR("g_keepaway");
278                 BADCVAR("g_keyhunt");
279                 BADCVAR("g_keyhunt_teams");
280                 BADCVAR("g_lms");
281                 BADCVAR("g_nexball");
282                 BADCVAR("g_onslaught");
283                 BADCVAR("g_race");
284                 BADCVAR("g_race_qualifying_timelimit");
285                 BADCVAR("g_tdm");
286                 BADCVAR("g_tdm_teams");
287                 BADCVAR("leadlimit");
288                 BADCVAR("nextmap");
289                 BADCVAR("teamplay");
290                 BADCVAR("timelimit");
291
292                 // long
293                 BADCVAR("hostname");
294                 BADCVAR("g_maplist");
295                 BADCVAR("g_maplist_mostrecent");
296                 BADCVAR("sv_motd");
297
298                 v = cvar_string(k);
299                 d = cvar_defstring(k);
300                 if(v == d)
301                         continue;
302
303                 if(adding)
304                 {
305                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
306                         if(strlen(cvar_changes) > 16384)
307                         {
308                                 cvar_changes = "// too many settings have been changed to show them here\n";
309                                 adding = 0;
310                         }
311                 }
312
313                 // now check if the changes are actually gameplay relevant
314
315                 // does nothing visible
316                 BADCVAR("captureleadlimit_override");
317                 BADCVAR("g_balance_kill_delay");
318                 BADCVAR("g_ca_point_limit");
319                 BADCVAR("g_ca_point_leadlimit");
320                 BADCVAR("g_ctf_captimerecord_always");
321                 BADCVAR("g_ctf_flag_glowtrails");
322                 BADCVAR("g_ctf_flag_pickup_verbosename");
323                 BADCVAR("g_domination_point_leadlimit");
324                 BADCVAR("g_forced_respawn");
325                 BADCVAR("g_freezetag_point_limit");
326                 BADCVAR("g_freezetag_point_leadlimit");
327                 BADCVAR("g_keyhunt_point_leadlimit");
328                 BADPREFIX("g_mod_");
329                 BADCVAR("g_invasion_point_limit");
330                 BADCVAR("g_nexball_goalleadlimit");
331                 BADCVAR("g_tdm_point_limit");
332                 BADCVAR("g_tdm_point_leadlimit");
333                 BADCVAR("leadlimit_and_fraglimit");
334                 BADCVAR("leadlimit_override");
335                 BADCVAR("pausable");
336                 BADCVAR("sv_allow_fullbright");
337                 BADCVAR("sv_checkforpacketsduringsleep");
338                 BADCVAR("sv_timeout");
339                 BADPREFIX("sv_timeout_");
340                 BADPREFIX("crypto_");
341                 BADPREFIX("g_chat_");
342                 BADPREFIX("g_ctf_captimerecord_");
343                 BADPREFIX("g_maplist_votable_");
344                 BADPREFIX("net_");
345                 BADPREFIX("prvm_");
346                 BADPREFIX("skill_");
347                 BADPREFIX("sv_cullentities_");
348                 BADPREFIX("sv_maxidle_");
349                 BADPREFIX("sv_vote_");
350                 BADPREFIX("timelimit_");
351                 BADCVAR("gameversion");
352                 BADPREFIX("gameversion_");
353                 BADCVAR("sv_minigames");
354                 BADPREFIX("sv_minigames_");
355                 BADCVAR("sv_namechangetimer");
356
357                 // allowed changes to server admins (please sync this to server.cfg)
358                 // vi commands:
359                 //   :/"impure"/,$d
360                 //   :g!,^\/\/[^ /],d
361                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
362                 //   :%!sort
363                 // yes, this does contain some redundant stuff, don't really care
364                 BADCVAR("bot_config_file");
365                 BADCVAR("bot_number");
366                 BADCVAR("bot_prefix");
367                 BADCVAR("bot_suffix");
368                 BADCVAR("capturelimit_override");
369                 BADCVAR("fraglimit_override");
370                 BADCVAR("gametype");
371                 BADCVAR("g_antilag");
372                 BADCVAR("g_balance_teams");
373                 BADCVAR("g_balance_teams_prevent_imbalance");
374                 BADCVAR("g_balance_teams_scorefactor");
375                 BADCVAR("g_ban_sync_trusted_servers");
376                 BADCVAR("g_ban_sync_uri");
377                 BADCVAR("g_ca_teams_override");
378                 BADCVAR("g_ctf_ignore_frags");
379                 BADCVAR("g_domination_point_limit");
380                 BADCVAR("g_domination_teams_override");
381                 BADCVAR("g_freezetag_teams_override");
382                 BADCVAR("g_friendlyfire");
383                 BADCVAR("g_fullbrightitems");
384                 BADCVAR("g_fullbrightplayers");
385                 BADCVAR("g_keyhunt_point_limit");
386                 BADCVAR("g_keyhunt_teams_override");
387                 BADCVAR("g_lms_lives_override");
388                 BADCVAR("g_maplist");
389                 BADCVAR("g_maplist_check_waypoints");
390                 BADCVAR("g_maplist_mostrecent_count");
391                 BADCVAR("g_maplist_shuffle");
392                 BADCVAR("g_maplist_votable");
393                 BADCVAR("g_maplist_votable_abstain");
394                 BADCVAR("g_maplist_votable_nodetail");
395                 BADCVAR("g_maplist_votable_suggestions");
396                 BADCVAR("g_maxplayers");
397                 BADCVAR("g_mirrordamage");
398                 BADCVAR("g_nexball_goallimit");
399                 BADCVAR("g_powerups");
400                 BADCVAR("g_start_delay");
401                 BADCVAR("g_tdm_teams_override");
402                 BADCVAR("g_warmup");
403                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
404                 BADCVAR("hostname");
405                 BADCVAR("log_file");
406                 BADCVAR("maxplayers");
407                 BADCVAR("minplayers");
408                 BADCVAR("net_address");
409                 BADCVAR("port");
410                 BADCVAR("rcon_password");
411                 BADCVAR("rcon_restricted_commands");
412                 BADCVAR("rcon_restricted_password");
413                 BADCVAR("skill");
414                 BADCVAR("sv_adminnick");
415                 BADCVAR("sv_autoscreenshot");
416                 BADCVAR("sv_autotaunt");
417                 BADCVAR("sv_curl_defaulturl");
418                 BADCVAR("sv_defaultcharacter");
419                 BADCVAR("sv_defaultplayercolors");
420                 BADCVAR("sv_defaultplayermodel");
421                 BADCVAR("sv_defaultplayerskin");
422                 BADCVAR("sv_maxidle");
423                 BADCVAR("sv_maxrate");
424                 BADCVAR("sv_motd");
425                 BADCVAR("sv_public");
426                 BADCVAR("sv_ready_restart");
427                 BADCVAR("sv_status_privacy");
428                 BADCVAR("sv_taunt");
429                 BADCVAR("sv_vote_call");
430                 BADCVAR("sv_vote_commands");
431                 BADCVAR("sv_vote_majority_factor");
432                 BADCVAR("sv_vote_master");
433                 BADCVAR("sv_vote_master_commands");
434                 BADCVAR("sv_vote_master_password");
435                 BADCVAR("sv_vote_simple_majority_factor");
436                 BADCVAR("teamplay_mode");
437                 BADCVAR("timelimit_override");
438                 BADCVAR("g_spawnshieldtime");
439                 BADPREFIX("g_warmup_");
440                 BADPREFIX("sv_ready_restart_");
441
442                 // mutators that announce themselves properly to the server browser
443                 BADCVAR("g_instagib");
444                 BADCVAR("g_new_toys");
445                 BADCVAR("g_nix");
446                 BADCVAR("g_grappling_hook");
447                 BADCVAR("g_jetpack");
448
449 #undef BADPREFIX
450 #undef BADCVAR
451
452                 if(pureadding)
453                 {
454                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
455                         if(strlen(cvar_purechanges) > 16384)
456                         {
457                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
458                                 pureadding = 0;
459                         }
460                 }
461                 ++cvar_purechanges_count;
462                 // WARNING: this variable is used for the server list
463                 // NEVER dare to skip this code!
464                 // Hacks to intentionally appearing as "pure server" even though you DO have
465                 // modified settings may be punished by removal from the server list.
466                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
467                 // though.
468         }
469         buf_del(h);
470         if(cvar_changes == "")
471                 cvar_changes = "// this server runs at default server settings\n";
472         else
473                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
474         cvar_changes = strzone(cvar_changes);
475         if(cvar_purechanges == "")
476                 cvar_purechanges = "// this server runs at default gameplay settings\n";
477         else
478                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
479         cvar_purechanges = strzone(cvar_purechanges);
480 }
481
482 void detect_maptype()
483 {
484 #if 0
485         vector o, v;
486         float i;
487
488         for (;;)
489         {
490                 o = world.mins;
491                 o.x += random() * (world.maxs.x - world.mins.x);
492                 o.y += random() * (world.maxs.y - world.mins.y);
493                 o.z += random() * (world.maxs.z - world.mins.z);
494
495                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
496                 if(trace_fraction == 1)
497                         continue;
498
499                 v = trace_endpos;
500
501                 for(i = 0; i < 64; i += 4)
502                 {
503                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
504         if(trace_fraction == 1)
505                 continue;
506                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
507                 }
508
509                 break;
510         }
511 #endif
512 }
513
514 entity randomseed;
515 bool RandomSeed_Send(entity this, entity to, int sf)
516 {
517         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
518         WriteShort(MSG_ENTITY, self.cnt);
519         return true;
520 }
521 void RandomSeed_Think()
522 {SELFPARAM();
523         self.cnt = bound(0, floor(random() * 65536), 65535);
524         self.nextthink = time + 5;
525
526         self.SendFlags |= 1;
527 }
528 void RandomSeed_Spawn()
529 {SELFPARAM();
530         randomseed = spawn();
531         randomseed.think = RandomSeed_Think;
532         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
533
534         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
535 }
536
537 spawnfunc(__init_dedicated_server)
538 {
539         // handler for _init/_init map (only for dedicated server initialization)
540
541         world_initialized = -1; // don't complain
542         cvar = cvar_normal;
543         cvar_string = cvar_string_normal;
544         cvar_set = cvar_set_normal;
545
546         remove = remove_unsafely;
547
548         entity e;
549         e = spawn();
550         e.think = GotoFirstMap;
551         e.nextthink = time; // this is usually 1 at this point
552
553         e = spawn();
554         e.classname = "info_player_deathmatch"; // safeguard against player joining
555
556         self.classname = "worldspawn"; // safeguard against various stuff ;)
557
558         // needs to be done so early because of the constants they create
559         static_init();
560         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
561         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
562
563         MapInfo_Enumerate();
564         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
565 }
566
567 void Map_MarkAsRecent(string m);
568 float world_already_spawned;
569 void Nagger_Init();
570 void ClientInit_Spawn();
571 void WeaponStats_Init();
572 void WeaponStats_Shutdown();
573 void Physics_AddStats();
574 spawnfunc(worldspawn)
575 {
576         float fd, l, j, n;
577         string s;
578
579         cvar = cvar_normal;
580         cvar_string = cvar_string_normal;
581         cvar_set = cvar_set_normal;
582
583         if(world_already_spawned)
584                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
585         world_already_spawned = true;
586
587         remove = remove_safely; // during spawning, watch what you remove!
588
589         cvar_changes_init(); // do this very early now so it REALLY matches the server config
590
591         compressShortVector_init();
592
593         entity head;
594         head = nextent(world);
595         maxclients = 0;
596         while(head)
597         {
598                 ++maxclients;
599                 head = nextent(head);
600         }
601
602         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
603
604         // needs to be done so early because of the constants they create
605         static_init();
606         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
607         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
608
609         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
610
611         TemporaryDB = db_create();
612
613         // 0 normal
614         lightstyle(0, "m");
615
616         // 1 FLICKER (first variety)
617         lightstyle(1, "mmnmmommommnonmmonqnmmo");
618
619         // 2 SLOW STRONG PULSE
620         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
621
622         // 3 CANDLE (first variety)
623         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
624
625         // 4 FAST STROBE
626         lightstyle(4, "mamamamamama");
627
628         // 5 GENTLE PULSE 1
629         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
630
631         // 6 FLICKER (second variety)
632         lightstyle(6, "nmonqnmomnmomomno");
633
634         // 7 CANDLE (second variety)
635         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
636
637         // 8 CANDLE (third variety)
638         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
639
640         // 9 SLOW STROBE (fourth variety)
641         lightstyle(9, "aaaaaaaazzzzzzzz");
642
643         // 10 FLUORESCENT FLICKER
644         lightstyle(10, "mmamammmmammamamaaamammma");
645
646         // 11 SLOW PULSE NOT FADE TO BLACK
647         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
648
649         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
650
651         // 63 testing
652         lightstyle(63, "a");
653
654         if(autocvar_g_campaign)
655                 CampaignPreInit();
656
657         Map_MarkAsRecent(mapname);
658
659         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
660
661         InitGameplayMode();
662         readlevelcvars();
663         GrappleHookInit();
664
665         player_count = 0;
666         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
667         if(bot_waypoints_for_items == 1)
668                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
669                         bot_waypoints_for_items = 0;
670
671         precache();
672
673         WaypointSprite_Init();
674
675         GameLogInit(); // prepare everything
676         // NOTE for matchid:
677         // changing the logic generating it is okay. But:
678         // it HAS to stay <= 64 chars
679         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
680         if(autocvar_sv_eventlog)
681         {
682                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
683                 matchid = strzone(s);
684
685                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
686                 s = ":gameinfo:mutators:LIST";
687
688                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
689                 s = ret_string;
690
691                 // initialiation stuff, not good in the mutator system
692                 if(!autocvar_g_use_ammunition)
693                         s = strcat(s, ":no_use_ammunition");
694
695                 // initialiation stuff, not good in the mutator system
696                 if(autocvar_g_pickup_items == 0)
697                         s = strcat(s, ":no_pickup_items");
698                 if(autocvar_g_pickup_items > 0)
699                         s = strcat(s, ":pickup_items");
700
701                 // initialiation stuff, not good in the mutator system
702                 if(autocvar_g_weaponarena != "0")
703                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
704
705                 // TODO to mutator system
706                 if(autocvar_g_norecoil)
707                         s = strcat(s, ":norecoil");
708
709                 // TODO to mutator system
710                 if(autocvar_g_powerups == 0)
711                         s = strcat(s, ":no_powerups");
712                 if(autocvar_g_powerups > 0)
713                         s = strcat(s, ":powerups");
714
715                 GameLogEcho(s);
716                 GameLogEcho(":gameinfo:end");
717         }
718         else
719                 matchid = strzone(ftos(random()));
720
721         cvar_set("nextmap", "");
722
723         SetDefaultAlpha();
724
725         if(autocvar_g_campaign)
726                 CampaignPostInit();
727
728         Ban_LoadBans();
729
730         MapInfo_Enumerate();
731         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
732
733         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
734         {
735                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
736                 if(fd != -1)
737                 {
738                         while((s = fgets(fd)))
739                         {
740                                 l = tokenize_console(s);
741                                 if(l < 2)
742                                         continue;
743                                 if(argv(0) == "cd")
744                                 {
745                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
746                                         LOG_INFO("  cdtrack ", argv(2), "\n");
747                                 }
748                                 else if(argv(0) == "fog")
749                                 {
750                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
751                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
752                                 }
753                                 else if(argv(0) == "set")
754                                 {
755                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
756                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
757                                 }
758                                 else if(argv(0) != "//")
759                                 {
760                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
761                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
762                                 }
763                         }
764                         fclose(fd);
765                 }
766         }
767
768         WeaponStats_Init();
769
770         WepSet_AddStat();
771         WepSet_AddStat_InMap();
772         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
773         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
774         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
775         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
776         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
777         Nagger_Init();
778
779         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
780         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
781         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
782         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
783         addstat(STAT_FUEL, AS_INT, ammo_fuel);
784         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
785         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
786         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
787         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
788         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
789         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
790         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
791         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
792         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
793         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
794
795         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
796         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
797
798         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
799
800         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
801
802         // freeze attacks
803         addstat(STAT_FROZEN, AS_INT, frozen);
804         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
805
806         // physics
807         Physics_AddStats();
808
809         // new properties
810         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
811         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
812         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
813         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
814         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
815         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
816         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
817         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
818         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
819         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
820         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
821         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
822         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
823         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
824         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
825         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
826         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
827         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
828         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
829
830         // secrets
831         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
832         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
833
834         // monsters
835         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
836         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
837
838         // misc
839         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
840
841         next_pingtime = time + 5;
842
843         detect_maptype();
844
845         // set up information replies for clients and server to use
846         maplist_reply = strzone(getmaplist());
847         lsmaps_reply = strzone(getlsmaps());
848         monsterlist_reply = strzone(getmonsterlist());
849         for(int i = 0; i < 10; ++i)
850         {
851                 s = getrecords(i);
852                 if (s)
853                         records_reply[i] = strzone(s);
854         }
855         ladder_reply = strzone(getladder());
856         rankings_reply = strzone(getrankings());
857
858         // begin other init
859         ClientInit_Spawn();
860         RandomSeed_Spawn();
861         PingPLReport_Spawn();
862
863         CheatInit();
864
865         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
866
867         // fill sv_curl_serverpackages from .serverpackage files
868         if(autocvar_sv_curl_serverpackages_auto)
869         {
870                 s = "";
871                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
872                 for(int i = 0; i < n; ++i)
873                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
874                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
875                                 s = strcat(s, " ", argv(i));
876                 fd = search_begin("*-serverpackage.txt", true, false);
877                 if(fd >= 0)
878                 {
879                         j = search_getsize(fd);
880                         for(int i = 0; i < j; ++i)
881                                 s = strcat(s, " ", search_getfilename(fd, i));
882                         search_end(fd);
883                 }
884                 fd = search_begin("*.serverpackage", true, false);
885                 if(fd >= 0)
886                 {
887                         j = search_getsize(fd);
888                         for(int i = 0; i < j; ++i)
889                                 s = strcat(s, " ", search_getfilename(fd, i));
890                         search_end(fd);
891                 }
892                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
893         }
894
895         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
896         modname = "Xonotic";
897         // physics/balance/config changes that count as mod
898         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
899                 modname = cvar_string("g_mod_physics");
900         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
901                 modname = cvar_string("g_mod_balance");
902         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
903                 modname = cvar_string("g_mod_config");
904         // extra mutators that deserve to count as mod
905         MUTATOR_CALLHOOK(SetModname);
906
907         // save it for later
908         modname = strzone(modname);
909
910         WinningConditionHelper(); // set worldstatus
911
912         world_initialized = 1;
913 }
914
915 spawnfunc(light)
916 {
917         //makestatic (self); // Who the f___ did that?
918         remove(self);
919 }
920
921 string GetGametype()
922 {
923         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
924 }
925
926 string GetMapname()
927 {
928         return mapname;
929 }
930
931 float Map_Count, Map_Current;
932 string Map_Current_Name;
933
934 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
935 float GetMaplistPosition()
936 {
937         float pos, idx;
938         string map;
939
940         map = GetMapname();
941         idx = autocvar_g_maplist_index;
942
943         if(idx >= 0)
944                 if(idx < Map_Count)
945                         if(map == argv(idx))
946                                 return idx;
947
948         for(pos = 0; pos < Map_Count; ++pos)
949                 if(map == argv(pos))
950                         return pos;
951
952         // resume normal maplist rotation if current map is not in g_maplist
953         return idx;
954 }
955
956 float MapHasRightSize(string map)
957 {
958         float fh;
959         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
960         if(autocvar_g_maplist_check_waypoints)
961         {
962                 LOG_TRACE("checkwp "); LOG_TRACE(map);
963                 if(!fexists(strcat("maps/", map, ".waypoints")))
964                 {
965                         LOG_TRACE(": no waypoints\n");
966                         return false;
967                 }
968                 LOG_TRACE(": has waypoints\n");
969         }
970
971         // open map size restriction file
972         LOG_TRACE("opensize "); LOG_TRACE(map);
973         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
974         if(fh >= 0)
975         {
976                 float mapmin, mapmax;
977                 LOG_TRACE(": ok, ");
978                 mapmin = stof(fgets(fh));
979                 mapmax = stof(fgets(fh));
980                 fclose(fh);
981                 if(player_count < mapmin)
982                 {
983                         LOG_TRACE("not enough\n");
984                         return false;
985                 }
986                 if(player_count > mapmax)
987                 {
988                         LOG_TRACE("too many\n");
989                         return false;
990                 }
991                 LOG_TRACE("right size\n");
992                 return true;
993         }
994         LOG_TRACE(": not found\n");
995         return true;
996 }
997
998 string Map_Filename(float position)
999 {
1000         return strcat("maps/", argv(position), ".bsp");
1001 }
1002
1003 void Map_MarkAsRecent(string m)
1004 {
1005         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1006 }
1007
1008 float Map_IsRecent(string m)
1009 {
1010         return strhasword(autocvar_g_maplist_mostrecent, m);
1011 }
1012
1013 float Map_Check(float position, float pass)
1014 {
1015         string filename;
1016         string map_next;
1017         map_next = argv(position);
1018         if(pass <= 1)
1019         {
1020                 if(Map_IsRecent(map_next))
1021                         return 0;
1022         }
1023         filename = Map_Filename(position);
1024         if(MapInfo_CheckMap(map_next))
1025         {
1026                 if(pass == 2)
1027                         return 1;
1028                 if(MapHasRightSize(map_next))
1029                         return 1;
1030                 return 0;
1031         }
1032         else
1033                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1034
1035         return 0;
1036 }
1037
1038 void Map_Goto_SetStr(string nextmapname)
1039 {
1040         if(getmapname_stored != "")
1041                 strunzone(getmapname_stored);
1042         if(nextmapname == "")
1043                 getmapname_stored = "";
1044         else
1045                 getmapname_stored = strzone(nextmapname);
1046 }
1047
1048 void Map_Goto_SetFloat(float position)
1049 {
1050         cvar_set("g_maplist_index", ftos(position));
1051         Map_Goto_SetStr(argv(position));
1052 }
1053
1054 void Map_Goto(float reinit)
1055 {
1056         MapInfo_LoadMap(getmapname_stored, reinit);
1057 }
1058
1059 // return codes of map selectors:
1060 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1061 //   -2 = permanent failure
1062 float() MaplistMethod_Iterate = // usual method
1063 {
1064         float pass, i;
1065
1066         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1067
1068         for(pass = 1; pass <= 2; ++pass)
1069         {
1070                 for(i = 1; i < Map_Count; ++i)
1071                 {
1072                         float mapindex;
1073                         mapindex = (i + Map_Current) % Map_Count;
1074                         if(Map_Check(mapindex, pass))
1075                                 return mapindex;
1076                 }
1077         }
1078         return -1;
1079 }
1080
1081 float() MaplistMethod_Repeat = // fallback method
1082 {
1083         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1084
1085         if(Map_Check(Map_Current, 2))
1086                 return Map_Current;
1087         return -2;
1088 }
1089
1090 float() MaplistMethod_Random = // random map selection
1091 {
1092         float i, imax;
1093
1094         LOG_TRACE("Trying MaplistMethod_Random\n");
1095
1096         imax = 42;
1097
1098         for(i = 0; i <= imax; ++i)
1099         {
1100                 float mapindex;
1101                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1102                 if(Map_Check(mapindex, 1))
1103                         return mapindex;
1104         }
1105         return -1;
1106 }
1107
1108 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1109 // the exponent sets a bias on the map selection:
1110 // the higher the exponent, the less likely "shortly repeated" same maps are
1111 {
1112         float i, j, imax, insertpos;
1113
1114         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1115
1116         imax = 42;
1117
1118         for(i = 0; i <= imax; ++i)
1119         {
1120                 string newlist;
1121
1122                 // now reinsert this at another position
1123                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1124                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1125                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1126                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1127
1128                 // insert the current map there
1129                 newlist = "";
1130                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1131                         newlist = strcat(newlist, " ", argv(j));
1132                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1133                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1134                         newlist = strcat(newlist, " ", argv(j));
1135                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1136                 cvar_set("g_maplist", newlist);
1137                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1138
1139                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1140                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1141                 if(Map_Check(Map_Current, 1))
1142                         return Map_Current;
1143         }
1144         return -1;
1145 }
1146
1147 void Maplist_Init()
1148 {
1149         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1150         float i;
1151         for (i = 0; i < Map_Count; ++i)
1152                 if (Map_Check(i, 2))
1153                         break;
1154         if (i == Map_Count)
1155         {
1156                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1157                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1158                 if(autocvar_g_maplist_shuffle)
1159                         ShuffleMaplist();
1160                 localcmd("\nmenu_cmd sync\n");
1161                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1162         }
1163         if(Map_Count == 0)
1164                 error("empty maplist, cannot select a new map");
1165         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1166
1167         if(Map_Current_Name)
1168                 strunzone(Map_Current_Name);
1169         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1170         // this may or may not be correct, but who cares, in the worst case a map
1171         // isn't chosen in the first pass that should have been
1172 }
1173
1174 string GetNextMap()
1175 {
1176         float nextMap;
1177
1178         Maplist_Init();
1179         nextMap = -1;
1180
1181         if(nextMap == -1)
1182                 if(autocvar_g_maplist_shuffle > 0)
1183                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1184
1185         if(nextMap == -1)
1186                 if(autocvar_g_maplist_selectrandom)
1187                         nextMap = MaplistMethod_Random();
1188
1189         if(nextMap == -1)
1190                 nextMap = MaplistMethod_Iterate();
1191
1192         if(nextMap == -1)
1193                 nextMap = MaplistMethod_Repeat();
1194
1195         if(nextMap >= 0)
1196         {
1197                 Map_Goto_SetFloat(nextMap);
1198                 return getmapname_stored;
1199         }
1200
1201         return "";
1202 }
1203
1204 float DoNextMapOverride(float reinit)
1205 {
1206         if(autocvar_g_campaign)
1207         {
1208                 CampaignPostIntermission();
1209                 alreadychangedlevel = true;
1210                 return true;
1211         }
1212         if(autocvar_quit_when_empty)
1213         {
1214                 if(player_count <= currentbots)
1215                 {
1216                         localcmd("quit\n");
1217                         alreadychangedlevel = true;
1218                         return true;
1219                 }
1220         }
1221         if(autocvar_quit_and_redirect != "")
1222         {
1223                 redirection_target = strzone(autocvar_quit_and_redirect);
1224                 alreadychangedlevel = true;
1225                 return true;
1226         }
1227         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1228         {
1229                 localcmd("restart\n");
1230                 alreadychangedlevel = true;
1231                 return true;
1232         }
1233         if(autocvar_nextmap != "")
1234         {
1235                 string m;
1236                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1237                 cvar_set("nextmap",m);
1238
1239                 if(!m || gametypevote)
1240                         return false;
1241                 if(autocvar_sv_vote_gametype)
1242                 {
1243                         Map_Goto_SetStr(m);
1244                         return false;
1245                 }
1246
1247                 if(MapInfo_CheckMap(m))
1248                 {
1249                         Map_Goto_SetStr(m);
1250                         Map_Goto(reinit);
1251                         alreadychangedlevel = true;
1252                         return true;
1253                 }
1254         }
1255         if(!reinit && autocvar_lastlevel)
1256         {
1257                 cvar_settemp_restore();
1258                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1259                 alreadychangedlevel = true;
1260                 return true;
1261         }
1262         return false;
1263 }
1264
1265 void GotoNextMap(float reinit)
1266 {
1267         //string nextmap;
1268         //float n, nummaps;
1269         //string s;
1270         if (alreadychangedlevel)
1271                 return;
1272         alreadychangedlevel = true;
1273
1274         string nextMap;
1275
1276         nextMap = GetNextMap();
1277         if(nextMap == "")
1278                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1279         Map_Goto(reinit);
1280 }
1281
1282
1283 /*
1284 ============
1285 IntermissionThink
1286
1287 When the player presses attack or jump, change to the next level
1288 ============
1289 */
1290 .float autoscreenshot;
1291 void IntermissionThink()
1292 {SELFPARAM();
1293         FixIntermissionClient(self);
1294
1295         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1296         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1297
1298         if( (server_screenshot || client_screenshot)
1299                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1300         {
1301                 self.autoscreenshot = -1;
1302                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1303                 return;
1304         }
1305
1306         if (time < intermission_exittime)
1307                 return;
1308
1309         if(!mapvote_initialized)
1310                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1311                         return;
1312
1313         MapVote_Start();
1314 }
1315
1316 /*
1317 ============
1318 FindIntermission
1319
1320 Returns the entity to view from
1321 ============
1322 */
1323 /*
1324 entity FindIntermission()
1325 {
1326         local   entity spot;
1327         local   float cyc;
1328
1329 // look for info_intermission first
1330         spot = find (world, classname, "info_intermission");
1331         if (spot)
1332         {       // pick a random one
1333                 cyc = random() * 4;
1334                 while (cyc > 1)
1335                 {
1336                         spot = find (spot, classname, "info_intermission");
1337                         if (!spot)
1338                                 spot = find (spot, classname, "info_intermission");
1339                         cyc = cyc - 1;
1340                 }
1341                 return spot;
1342         }
1343
1344 // then look for the start position
1345         spot = find (world, classname, "info_player_start");
1346         if (spot)
1347                 return spot;
1348
1349 // testinfo_player_start is only found in regioned levels
1350         spot = find (world, classname, "testplayerstart");
1351         if (spot)
1352                 return spot;
1353
1354 // then look for the start position
1355         spot = find (world, classname, "info_player_deathmatch");
1356         if (spot)
1357                 return spot;
1358
1359         //objerror ("FindIntermission: no spot");
1360         return world;
1361 }
1362 */
1363
1364 /*
1365 ===============================================================================
1366
1367 RULES
1368
1369 ===============================================================================
1370 */
1371
1372 void DumpStats(float final)
1373 {
1374         float file;
1375         string s;
1376         float to_console;
1377         float to_eventlog;
1378         float to_file;
1379         float i;
1380
1381         to_console = autocvar_sv_logscores_console;
1382         to_eventlog = autocvar_sv_eventlog;
1383         to_file = autocvar_sv_logscores_file;
1384
1385         if(!final)
1386         {
1387                 to_console = true; // always print printstats replies
1388                 to_eventlog = false; // but never print them to the event log
1389         }
1390
1391         if(to_eventlog)
1392                 if(autocvar_sv_eventlog_console)
1393                         to_console = false; // otherwise we get the output twice
1394
1395         if(final)
1396                 s = ":scores:";
1397         else
1398                 s = ":status:";
1399         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1400
1401         if(to_console)
1402                 LOG_INFO(s, "\n");
1403         if(to_eventlog)
1404                 GameLogEcho(s);
1405
1406         file = -1;
1407         if(to_file)
1408         {
1409                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1410                 if(file == -1)
1411                         to_file = false;
1412                 else
1413                         fputs(file, strcat(s, "\n"));
1414         }
1415
1416         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1417         if(to_console)
1418                 LOG_INFO(s, "\n");
1419         if(to_eventlog)
1420                 GameLogEcho(s);
1421         if(to_file)
1422                 fputs(file, strcat(s, "\n"));
1423
1424         FOR_EACH_CLIENT(other)
1425         {
1426                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1427                 {
1428                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1429                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1430                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1431                                 s = strcat(s, ftos(other.team), ":");
1432                         else
1433                                 s = strcat(s, "spectator:");
1434
1435                         if(to_console)
1436                                 LOG_INFO(s, other.netname, "\n");
1437                         if(to_eventlog)
1438                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1439                         if(to_file)
1440                                 fputs(file, strcat(s, other.netname, "\n"));
1441                 }
1442         }
1443
1444         if(teamplay)
1445         {
1446                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1447                 if(to_console)
1448                         LOG_INFO(s, "\n");
1449                 if(to_eventlog)
1450                         GameLogEcho(s);
1451                 if(to_file)
1452                         fputs(file, strcat(s, "\n"));
1453
1454                 for(i = 1; i < 16; ++i)
1455                 {
1456                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1457                         s = strcat(s, ":", ftos(i));
1458                         if(to_console)
1459                                 LOG_INFO(s, "\n");
1460                         if(to_eventlog)
1461                                 GameLogEcho(s);
1462                         if(to_file)
1463                                 fputs(file, strcat(s, "\n"));
1464                 }
1465         }
1466
1467         if(to_console)
1468                 LOG_INFO(":end\n");
1469         if(to_eventlog)
1470                 GameLogEcho(":end");
1471         if(to_file)
1472         {
1473                 fputs(file, ":end\n");
1474                 fclose(file);
1475         }
1476 }
1477
1478 void FixIntermissionClient(entity e)
1479 {
1480         string s;
1481         if(!e.autoscreenshot) // initial call
1482         {
1483                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1484                 e.health = -2342;
1485                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1486                 e.solid = SOLID_NOT;
1487                 e.movetype = MOVETYPE_NONE;
1488                 e.takedamage = DAMAGE_NO;
1489                 if(e.weaponentity)
1490                 {
1491                         e.weaponentity.effects = EF_NODRAW;
1492                         if (e.weaponentity.weaponentity)
1493                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1494                 }
1495                 if(IS_REAL_CLIENT(e))
1496                 {
1497                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1498                         s = autocvar_sv_intermission_cdtrack;
1499                         if(s != "")
1500                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1501                         msg_entity = e;
1502                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1503                 }
1504         }
1505 }
1506
1507 /*
1508 go to the next level for deathmatch
1509 only called if a time or frag limit has expired
1510 */
1511 void NextLevel()
1512 {
1513         gameover = true;
1514
1515         intermission_running = 1;
1516
1517 // enforce a wait time before allowing changelevel
1518         if(player_count > 0)
1519                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1520         else
1521                 intermission_exittime = -1;
1522
1523         /*
1524         WriteByte (MSG_ALL, SVC_CDTRACK);
1525         WriteByte (MSG_ALL, 3);
1526         WriteByte (MSG_ALL, 3);
1527         // done in FixIntermission
1528         */
1529
1530         //pos = FindIntermission ();
1531
1532         VoteReset();
1533
1534         DumpStats(true);
1535
1536         // send statistics
1537         PlayerStats_GameReport(true);
1538         WeaponStats_Shutdown();
1539
1540         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1541
1542         if(autocvar_sv_eventlog)
1543                 GameLogEcho(":gameover");
1544
1545         GameLogClose();
1546
1547         FOR_EACH_PLAYER(other) {
1548                 FixIntermissionClient(other);
1549                 if(other.winning)
1550                         bprint(other.netname, " ^7wins.\n");
1551         }
1552
1553         if(autocvar_g_campaign)
1554                 CampaignPreIntermission();
1555
1556         MUTATOR_CALLHOOK(MatchEnd);
1557
1558         localcmd("\nsv_hook_gameend\n");
1559 }
1560
1561 /*
1562 ============
1563 CheckRules_Player
1564
1565 Exit deathmatch games upon conditions
1566 ============
1567 */
1568 void CheckRules_Player()
1569 {SELFPARAM();
1570         if (gameover)   // someone else quit the game already
1571                 return;
1572
1573         if(self.deadflag == DEAD_NO)
1574                 self.play_time += frametime;
1575
1576         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1577         //   (div0: and that in CheckRules_World please)
1578 }
1579
1580
1581 float InitiateSuddenDeath()
1582 {
1583         // Check first whether normal overtimes could be added before initiating suddendeath mode
1584         // - for this timelimit_overtime needs to be >0 of course
1585         // - also check the winning condition calculated in the previous frame and only add normal overtime
1586         //   again, if at the point at which timelimit would be extended again, still no winner was found
1587         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1588         {
1589                 return 1; // need to call InitiateOvertime later
1590         }
1591         else
1592         {
1593                 if(!checkrules_suddendeathend)
1594                 {
1595                         if(autocvar_g_campaign)
1596                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1597                         else
1598                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1599                         if(g_race && !g_race_qualifying)
1600                                 race_StartCompleting();
1601                 }
1602                 return 0;
1603         }
1604 }
1605
1606 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1607 {
1608         ++checkrules_overtimesadded;
1609         //add one more overtime by simply extending the timelimit
1610         float tl;
1611         tl = autocvar_timelimit;
1612         tl += autocvar_timelimit_overtime;
1613         cvar_set("timelimit", ftos(tl));
1614
1615         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1616 }
1617
1618 float GetWinningCode(float fraglimitreached, float equality)
1619 {
1620         if(autocvar_g_campaign == 1)
1621                 if(fraglimitreached)
1622                         return WINNING_YES;
1623                 else
1624                         return WINNING_NO;
1625
1626         else
1627                 if(equality)
1628                         if(fraglimitreached)
1629                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1630                         else
1631                                 return WINNING_NEVER;
1632                 else
1633                         if(fraglimitreached)
1634                                 return WINNING_YES;
1635                         else
1636                                 return WINNING_NO;
1637 }
1638
1639 // set the .winning flag for exactly those players with a given field value
1640 void SetWinners(.float field, float value)
1641 {
1642         entity head;
1643         FOR_EACH_PLAYER(head)
1644                 head.winning = (head.(field) == value);
1645 }
1646
1647 // set the .winning flag for those players with a given field value
1648 void AddWinners(.float field, float value)
1649 {
1650         entity head;
1651         FOR_EACH_PLAYER(head)
1652                 if (head.(field) == value)
1653                         head.winning = 1;
1654 }
1655
1656 // clear the .winning flags
1657 void ClearWinners(void)
1658 {
1659         entity head;
1660         FOR_EACH_PLAYER(head)
1661                 head.winning = 0;
1662 }
1663
1664 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1665 // they win. Otherwise the defending team wins once the timelimit passes.
1666 void assault_new_round();
1667 float WinningCondition_Assault()
1668 {SELFPARAM();
1669         float status;
1670
1671         WinningConditionHelper(); // set worldstatus
1672
1673         status = WINNING_NO;
1674         // as the timelimit has not yet passed just assume the defending team will win
1675         if(assault_attacker_team == NUM_TEAM_1)
1676         {
1677                 SetWinners(team, NUM_TEAM_2);
1678         }
1679         else
1680         {
1681                 SetWinners(team, NUM_TEAM_1);
1682         }
1683
1684         entity ent;
1685         ent = find(world, classname, "target_assault_roundend");
1686         if(ent)
1687         {
1688                 if(ent.winning) // round end has been triggered by attacking team
1689                 {
1690                         bprint("ASSAULT: round completed...\n");
1691                         SetWinners(team, assault_attacker_team);
1692
1693                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1694
1695                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1696                         {
1697                                 status = WINNING_YES;
1698                         }
1699                         else
1700                         {
1701                                 WITH(entity, self, ent, assault_new_round());
1702                         }
1703                 }
1704         }
1705
1706         return status;
1707 }
1708
1709 // LMS winning condition: game terminates if and only if there's at most one
1710 // one player who's living lives. Top two scores being equal cancels the time
1711 // limit.
1712 float WinningCondition_LMS()
1713 {
1714         entity head, head2;
1715         float have_player;
1716         float have_players;
1717         float l;
1718
1719         have_player = false;
1720         have_players = false;
1721         l = LMS_NewPlayerLives();
1722
1723         head = find(world, classname, "player");
1724         if(head)
1725                 have_player = true;
1726         head2 = find(head, classname, "player");
1727         if(head2)
1728                 have_players = true;
1729
1730         if(have_player)
1731         {
1732                 // we have at least one player
1733                 if(have_players)
1734                 {
1735                         // two or more active players - continue with the game
1736                 }
1737                 else
1738                 {
1739                         // exactly one player?
1740
1741                         ClearWinners();
1742                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1743
1744                         if(l)
1745                         {
1746                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1747                                 return WINNING_NO;
1748                         }
1749                         else
1750                         {
1751                                 // a winner!
1752                                 // and assign him his first place
1753                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1754                                 return WINNING_YES;
1755                         }
1756                 }
1757         }
1758         else
1759         {
1760                 // nobody is playing at all...
1761                 if(l)
1762                 {
1763                         // wait for players...
1764                 }
1765                 else
1766                 {
1767                         // SNAFU (maybe a draw game?)
1768                         ClearWinners();
1769                         LOG_TRACE("No players, ending game.\n");
1770                         return WINNING_YES;
1771                 }
1772         }
1773
1774         // When we get here, we have at least two players who are actually LIVING,
1775         // now check if the top two players have equal score.
1776         WinningConditionHelper();
1777
1778         ClearWinners();
1779         if(WinningConditionHelper_winner)
1780                 WinningConditionHelper_winner.winning = true;
1781         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1782                 return WINNING_NEVER;
1783
1784         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1785         return WINNING_NO;
1786 }
1787
1788 void ShuffleMaplist()
1789 {
1790         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1791 }
1792
1793 float leaderfrags;
1794 float WinningCondition_Scores(float limit, float leadlimit)
1795 {
1796         float limitreached;
1797
1798         // TODO make everything use THIS winning condition (except LMS)
1799         WinningConditionHelper();
1800
1801         if(teamplay)
1802         {
1803                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1804                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1805                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1806                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1807         }
1808
1809         ClearWinners();
1810         if(WinningConditionHelper_winner)
1811                 WinningConditionHelper_winner.winning = 1;
1812         if(WinningConditionHelper_winnerteam >= 0)
1813                 SetWinners(team, WinningConditionHelper_winnerteam);
1814
1815         if(WinningConditionHelper_lowerisbetter)
1816         {
1817                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1818                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1819                 limit = -limit;
1820         }
1821
1822         if(WinningConditionHelper_zeroisworst)
1823                 leadlimit = 0; // not supported in this mode
1824
1825         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1826         // these modes always score in increments of 1, thus this makes sense
1827         {
1828                 if(leaderfrags != WinningConditionHelper_topscore)
1829                 {
1830                         leaderfrags = WinningConditionHelper_topscore;
1831
1832                         if (limit)
1833                         if (leaderfrags == limit - 1)
1834                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1835                         else if (leaderfrags == limit - 2)
1836                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1837                         else if (leaderfrags == limit - 3)
1838                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1839                 }
1840         }
1841
1842         limitreached = false;
1843         if(limit)
1844                 if(WinningConditionHelper_topscore >= limit)
1845                         limitreached = true;
1846         if(leadlimit)
1847         {
1848                 float leadlimitreached;
1849                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1850                 if(autocvar_leadlimit_and_fraglimit)
1851                         limitreached = (limitreached && leadlimitreached);
1852                 else
1853                         limitreached = (limitreached || leadlimitreached);
1854         }
1855
1856         if(limit)
1857                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1858
1859         return GetWinningCode(
1860                 WinningConditionHelper_topscore && limitreached,
1861                 WinningConditionHelper_equality
1862         );
1863 }
1864
1865 float WinningCondition_Race(float fraglimit)
1866 {
1867         float wc;
1868         entity p;
1869         float n, c;
1870
1871         n = 0;
1872         c = 0;
1873         FOR_EACH_PLAYER(p)
1874         {
1875                 ++n;
1876                 if(p.race_completed)
1877                         ++c;
1878         }
1879         if(n && (n == c))
1880                 return WINNING_YES;
1881         wc = WinningCondition_Scores(fraglimit, 0);
1882
1883         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1884         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1885         // do NOT support equality when the laps are all raced!
1886                 return WINNING_STARTSUDDENDEATHOVERTIME;
1887         else
1888                 return WINNING_NEVER;
1889 }
1890
1891 float WinningCondition_QualifyingThenRace(float limit)
1892 {
1893         float wc;
1894         wc = WinningCondition_Scores(limit, 0);
1895
1896         // NEVER initiate overtime
1897         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1898         {
1899                 return WINNING_YES;
1900         }
1901
1902         return wc;
1903 }
1904
1905 float WinningCondition_RanOutOfSpawns()
1906 {
1907         entity head;
1908
1909         if(have_team_spawns <= 0)
1910                 return WINNING_NO;
1911
1912         if(!autocvar_g_spawn_useallspawns)
1913                 return WINNING_NO;
1914
1915         if(!some_spawn_has_been_used)
1916                 return WINNING_NO;
1917
1918         team1_score = team2_score = team3_score = team4_score = 0;
1919
1920         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1921         {
1922                 if(head.team == NUM_TEAM_1)
1923                         team1_score = 1;
1924                 else if(head.team == NUM_TEAM_2)
1925                         team2_score = 1;
1926                 else if(head.team == NUM_TEAM_3)
1927                         team3_score = 1;
1928                 else if(head.team == NUM_TEAM_4)
1929                         team4_score = 1;
1930         }
1931
1932         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1933         {
1934                 if(head.team == NUM_TEAM_1)
1935                         team1_score = 1;
1936                 else if(head.team == NUM_TEAM_2)
1937                         team2_score = 1;
1938                 else if(head.team == NUM_TEAM_3)
1939                         team3_score = 1;
1940                 else if(head.team == NUM_TEAM_4)
1941                         team4_score = 1;
1942         }
1943
1944         ClearWinners();
1945         if(team1_score + team2_score + team3_score + team4_score == 0)
1946         {
1947                 checkrules_equality = true;
1948                 return WINNING_YES;
1949         }
1950         else if(team1_score + team2_score + team3_score + team4_score == 1)
1951         {
1952                 float t, i;
1953                 if(team1_score)
1954                         t = NUM_TEAM_1;
1955                 else if(team2_score)
1956                         t = NUM_TEAM_2;
1957                 else if(team3_score)
1958                         t = NUM_TEAM_3;
1959                 else // if(team4_score)
1960                         t = NUM_TEAM_4;
1961                 CheckAllowedTeams(world);
1962                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1963                 {
1964                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1965                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1966                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1967                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1968                 }
1969
1970                 AddWinners(team, t);
1971                 return WINNING_YES;
1972         }
1973         else
1974                 return WINNING_NO;
1975 }
1976
1977 /*
1978 ============
1979 CheckRules_World
1980
1981 Exit deathmatch games upon conditions
1982 ============
1983 */
1984 void CheckRules_World()
1985 {
1986         float timelimit;
1987         float fraglimit;
1988         float leadlimit;
1989
1990         VoteThink();
1991         MapVote_Think();
1992
1993         SetDefaultAlpha();
1994
1995         if (gameover)   // someone else quit the game already
1996         {
1997                 if(player_count == 0) // Nobody there? Then let's go to the next map
1998                         MapVote_Start();
1999                         // this will actually check the player count in the next frame
2000                         // again, but this shouldn't hurt
2001                 return;
2002         }
2003
2004         timelimit = autocvar_timelimit * 60;
2005         fraglimit = autocvar_fraglimit;
2006         leadlimit = autocvar_leadlimit;
2007
2008         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2009         {
2010                 if(timelimit > 0)
2011                         timelimit = 0; // timelimit is not made for warmup
2012                 if(fraglimit > 0)
2013                         fraglimit = 0; // no fraglimit for now
2014                 leadlimit = 0; // no leadlimit for now
2015         }
2016
2017         if(timelimit > 0)
2018         {
2019                 timelimit += game_starttime;
2020         }
2021         else if (timelimit < 0)
2022         {
2023                 // endmatch
2024                 NextLevel();
2025                 return;
2026         }
2027
2028         float wantovertime;
2029         wantovertime = 0;
2030
2031         if(timelimit > game_starttime)
2032                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2033         else
2034                 game_completion_ratio = 0;
2035
2036         if(checkrules_suddendeathend)
2037         {
2038                 if(!checkrules_suddendeathwarning)
2039                 {
2040                         checkrules_suddendeathwarning = true;
2041                         if(g_race && !g_race_qualifying)
2042                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2043                         else
2044                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2045                 }
2046         }
2047         else
2048         {
2049                 if (timelimit && time >= timelimit)
2050                 {
2051                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2052                         {
2053                                 float totalplayers;
2054                                 float playerswithlaps;
2055                                 float readyplayers;
2056                                 entity head;
2057                                 totalplayers = playerswithlaps = readyplayers = 0;
2058                                 FOR_EACH_PLAYER(head)
2059                                 {
2060                                         ++totalplayers;
2061                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2062                                                 ++playerswithlaps;
2063                                         if(head.ready)
2064                                                 ++readyplayers;
2065                                 }
2066
2067                                 // at least 2 of the players have completed a lap: start the RACE
2068                                 // otherwise, the players should end the qualifying on their own
2069                                 if(readyplayers || playerswithlaps >= 2)
2070                                 {
2071                                         checkrules_suddendeathend = 0;
2072                                         ReadyRestart(); // go to race
2073                                         return;
2074                                 }
2075                                 else
2076                                         wantovertime |= InitiateSuddenDeath();
2077                         }
2078                         else
2079                                 wantovertime |= InitiateSuddenDeath();
2080                 }
2081         }
2082
2083         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2084         {
2085                 NextLevel();
2086                 return;
2087         }
2088
2089         float checkrules_status;
2090         checkrules_status = WinningCondition_RanOutOfSpawns();
2091         if(checkrules_status == WINNING_YES)
2092         {
2093                 bprint("Hey! Someone ran out of spawns!\n");
2094         }
2095         else if(g_race && !g_race_qualifying && timelimit >= 0)
2096         {
2097                 checkrules_status = WinningCondition_Race(fraglimit);
2098                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2099         }
2100         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2101         {
2102                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2103                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2104         }
2105         else if(g_assault)
2106         {
2107                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2108         }
2109         else if(g_lms)
2110         {
2111                 checkrules_status = WinningCondition_LMS();
2112         }
2113         else
2114         {
2115                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2116                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2117         }
2118
2119         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2120         {
2121                 checkrules_status = WINNING_NEVER;
2122                 checkrules_overtimesadded = -1;
2123                 wantovertime |= InitiateSuddenDeath();
2124         }
2125
2126         if(checkrules_status == WINNING_NEVER)
2127                 // equality cases! Nobody wins if the overtime ends in a draw.
2128                 ClearWinners();
2129
2130         if(wantovertime)
2131         {
2132                 if(checkrules_status == WINNING_NEVER)
2133                         InitiateOvertime();
2134                 else
2135                         checkrules_status = WINNING_YES;
2136         }
2137
2138         if(checkrules_suddendeathend)
2139                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2140                         checkrules_status = WINNING_YES;
2141
2142         if(checkrules_status == WINNING_YES)
2143         {
2144                 //print("WINNING\n");
2145                 NextLevel();
2146         }
2147 }
2148
2149 string GotoMap(string m)
2150 {
2151         m = GameTypeVote_MapInfo_FixName(m);
2152         if (!m)
2153                 return "The map you suggested is not available on this server.";
2154         if (!autocvar_sv_vote_gametype)
2155         if(!MapInfo_CheckMap(m))
2156                 return "The map you suggested does not support the current game mode.";
2157         cvar_set("nextmap", m);
2158         cvar_set("timelimit", "-1");
2159         if(mapvote_initialized || alreadychangedlevel)
2160         {
2161                 if(DoNextMapOverride(0))
2162                         return "Map switch initiated.";
2163                 else
2164                         return "Hm... no. For some reason I like THIS map more.";
2165         }
2166         else
2167                 return "Map switch will happen after scoreboard.";
2168 }
2169
2170
2171 void EndFrame()
2172 {SELFPARAM();
2173         anticheat_endframe();
2174
2175         float altime;
2176         entity e_;
2177         FOR_EACH_REALCLIENT(e_)
2178         {
2179                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2180                 if(e.typehitsound)
2181                         e_.typehit_time = time;
2182                 else if(e.damage_dealt)
2183                 {
2184                         e_.hit_time = time;
2185                         e_.damage_dealt_total += ceil(e.damage_dealt);
2186                 }
2187         }
2188         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2189         // add 1 frametime because after this, engine SV_Physics
2190         // increases time by a frametime and then networks the frame
2191         // add another frametime because client shows everything with
2192         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2193         // needed!
2194         FOR_EACH_CLIENT(e_)
2195         {
2196                 e_.typehitsound = false;
2197                 e_.damage_dealt = 0;
2198                 setself(e_);
2199                 antilag_record(e_, altime);
2200         }
2201         FOR_EACH_MONSTER(e_)
2202         {
2203                 setself(e_);
2204                 antilag_record(e_, altime);
2205         }
2206 }
2207
2208
2209 /*
2210  * RedirectionThink:
2211  * returns true if redirecting
2212  */
2213 float redirection_timeout;
2214 float redirection_nextthink;
2215 float RedirectionThink()
2216 {SELFPARAM();
2217         float clients_found;
2218
2219         if(redirection_target == "")
2220                 return false;
2221
2222         if(!redirection_timeout)
2223         {
2224                 cvar_set("sv_public", "-2");
2225                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2226                 if(redirection_target == "self")
2227                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2228                 else
2229                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2230         }
2231
2232         if(time < redirection_nextthink)
2233                 return true;
2234
2235         redirection_nextthink = time + 1;
2236
2237         clients_found = 0;
2238         entity e;
2239         FOR_EACH_REALCLIENT(e)
2240         {
2241                 setself(e);
2242                 // TODO add timer
2243                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2244                 if(redirection_target == "self")
2245                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2246                 else
2247                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2248                 ++clients_found;
2249         }
2250
2251         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2252
2253         if(time > redirection_timeout || clients_found == 0)
2254                 localcmd("\nwait; wait; wait; quit\n");
2255
2256         return true;
2257 }
2258
2259 void TargetMusic_RestoreGame();
2260 void RestoreGame()
2261 {
2262         // Loaded from a save game
2263         // some things then break, so let's work around them...
2264
2265         // Progs DB (capture records)
2266         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2267
2268         // Mapinfo
2269         MapInfo_Shutdown();
2270         MapInfo_Enumerate();
2271         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2272         WeaponStats_Init();
2273
2274         TargetMusic_RestoreGame();
2275 }
2276
2277 void Shutdown()
2278 {
2279         gameover = 2;
2280
2281         if(world_initialized > 0)
2282         {
2283                 world_initialized = 0;
2284                 LOG_INFO("Saving persistent data...\n");
2285                 Ban_SaveBans();
2286
2287                 // playerstats with unfinished match
2288                 PlayerStats_GameReport(false);
2289
2290                 if(!cheatcount_total)
2291                 {
2292                         if(autocvar_sv_db_saveasdump)
2293                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2294                         else
2295                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2296                 }
2297                 if(autocvar_developer)
2298                 {
2299                         if(autocvar_sv_db_saveasdump)
2300                                 db_dump(TemporaryDB, "server-temp.db");
2301                         else
2302                                 db_save(TemporaryDB, "server-temp.db");
2303                 }
2304                 CheatShutdown(); // must be after cheatcount check
2305                 db_close(ServerProgsDB);
2306                 db_close(TemporaryDB);
2307                 LOG_INFO("done!\n");
2308                 // tell the bot system the game is ending now
2309                 bot_endgame();
2310
2311                 WeaponStats_Shutdown();
2312                 MapInfo_Shutdown();
2313         }
2314         else if(world_initialized == 0)
2315         {
2316                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2317         }
2318 }