qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include <server/mutators/_mod.qh>
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "scores_rules.qh"
  20 #include "teamplay.qh"
  21 #include "weapons/weaponstats.qh"
  22 #include "../common/constants.qh"
  23 #include <common/net_linked.qh>
  24 #include "../common/deathtypes/all.qh"
  25 #include "../common/gamemodes/sv_rules.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/_mod.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/vehicles/all.qh"
  30 #include "../common/notifications/all.qh"
  31 #include "../common/physics/player.qh"
  32 #include "../common/playerstats.qh"
  33 #include "../common/stats.qh"
  34 #include "../common/teams.qh"
  35 #include "../common/mapobjects/trigger/secret.qh"
  36 #include "../common/mapobjects/target/music.qh"
  37 #include "../common/util.qh"
  38 #include "../common/items/_mod.qh"
  39 #include <common/weapons/_all.qh>
  40 #include "../common/state.qh"
  41
  42 const float LATENCY_THINKRATE = 10;
  43 .float latency_sum;
  44 .float latency_cnt;
  45 .float latency_time;
  46 entity pingplreport;
  47 void PingPLReport_Think(entity this)
  48 {
  49         float delta;
  50         entity e;
  51
  52         delta = 3 / maxclients;
  53         if(delta < sys_frametime)
  54                 delta = 0;
  55         this.nextthink = time + delta;
  56
  57         e = edict_num(this.cnt + 1);
  58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  59         {
  60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  61                 WriteByte(MSG_BROADCAST, this.cnt);
  62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  65
  66                 // record latency times for clients throughout the match so we can report it to playerstats
  67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  68                 {
  69                         CS(e).latency_sum += CS(e).ping;
  70                         CS(e).latency_cnt += 1;
  71                         CS(e).latency_time = time;
  72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  73                 }
  74         }
  75         else
  76         {
  77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  78                 WriteByte(MSG_BROADCAST, this.cnt);
  79                 WriteShort(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82         }
  83         this.cnt = (this.cnt + 1) % maxclients;
  84 }
  85 void PingPLReport_Spawn()
  86 {
  87         pingplreport = new_pure(pingplreport);
  88         setthink(pingplreport, PingPLReport_Think);
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         strfree(cvar_changes);
 148         strfree(cvar_purechanges);
 149         cvar_purechanges_count = 0;
 150
 151         h = buf_create();
 152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 153         n = buf_getsize(h);
 154
 155         adding = true;
 156         pureadding = true;
 157
 158         for(i = 0; i < n; ++i)
 159         {
 160                 k = bufstr_get(h, i);
 161
 162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 164 #define BADCVAR(p) if(k == p) continue
 165
 166                 // general excludes and namespaces for server admin used cvars
 167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 168
 169                 // internal
 170                 BADPREFIX("csqc_");
 171                 BADPREFIX("cvar_check_");
 172                 BADCVAR("gamecfg");
 173                 BADCVAR("g_configversion");
 174                 BADCVAR("halflifebsp");
 175                 BADCVAR("sv_mapformat_is_quake2");
 176                 BADCVAR("sv_mapformat_is_quake3");
 177                 BADPREFIX("sv_world");
 178
 179                 // client
 180                 BADPREFIX("chase_");
 181                 BADPREFIX("cl_");
 182                 BADPREFIX("con_");
 183                 BADPREFIX("scoreboard_");
 184                 BADPREFIX("g_campaign");
 185                 BADPREFIX("g_waypointsprite_");
 186                 BADPREFIX("gl_");
 187                 BADPREFIX("joy");
 188                 BADPREFIX("hud_");
 189                 BADPREFIX("m_");
 190                 BADPREFIX("menu_");
 191                 BADPREFIX("net_slist_");
 192                 BADPREFIX("r_");
 193                 BADPREFIX("sbar_");
 194                 BADPREFIX("scr_");
 195                 BADPREFIX("snd_");
 196                 BADPREFIX("show");
 197                 BADPREFIX("sensitivity");
 198                 BADPREFIX("userbind");
 199                 BADPREFIX("v_");
 200                 BADPREFIX("vid_");
 201                 BADPREFIX("crosshair");
 202                 BADCVAR("mod_q3bsp_lightmapmergepower");
 203                 BADCVAR("mod_q3bsp_nolightmaps");
 204                 BADCVAR("fov");
 205                 BADCVAR("mastervolume");
 206                 BADCVAR("volume");
 207                 BADCVAR("bgmvolume");
 208                 BADCVAR("in_pitch_min");
 209                 BADCVAR("in_pitch_max");
 210
 211                 // private
 212                 BADCVAR("developer");
 213                 BADCVAR("log_dest_udp");
 214                 BADCVAR("net_address");
 215                 BADCVAR("net_address_ipv6");
 216                 BADCVAR("port");
 217                 BADCVAR("savedgamecfg");
 218                 BADCVAR("serverconfig");
 219                 BADCVAR("sv_autoscreenshot");
 220                 BADCVAR("sv_heartbeatperiod");
 221                 BADCVAR("sv_vote_master_password");
 222                 BADCVAR("sys_colortranslation");
 223                 BADCVAR("sys_specialcharactertranslation");
 224                 BADCVAR("timeformat");
 225                 BADCVAR("timestamps");
 226                 BADCVAR("g_require_stats");
 227                 BADPREFIX("developer_");
 228                 BADPREFIX("g_ban_");
 229                 BADPREFIX("g_banned_list");
 230                 BADPREFIX("g_require_stats_");
 231                 BADPREFIX("g_chat_flood_");
 232                 BADPREFIX("g_ghost_items");
 233                 BADPREFIX("g_playerstats_");
 234                 BADPREFIX("g_voice_flood_");
 235                 BADPREFIX("log_file");
 236                 BADPREFIX("quit_");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250                 BADCVAR("sv_muteban_list");
 251                 BADCVAR("sv_voteban_list");
 252                 BADCVAR("sv_allow_customplayermodels_idlist");
 253                 BADCVAR("sv_allow_customplayermodels_speciallist");
 254
 255                 // mapinfo
 256                 BADCVAR("fraglimit");
 257                 BADCVAR("g_arena");
 258                 BADCVAR("g_assault");
 259                 BADCVAR("g_ca");
 260                 BADCVAR("g_ca_teams");
 261                 BADCVAR("g_conquest");
 262                 BADCVAR("g_ctf");
 263                 BADCVAR("g_cts");
 264                 BADCVAR("g_dotc");
 265                 BADCVAR("g_dm");
 266                 BADCVAR("g_domination");
 267                 BADCVAR("g_domination_default_teams");
 268                 BADCVAR("g_duel");
 269                 BADCVAR("g_freezetag");
 270                 BADCVAR("g_freezetag_teams");
 271                 BADCVAR("g_invasion_teams");
 272                 BADCVAR("g_invasion_type");
 273                 BADCVAR("g_jailbreak");
 274                 BADCVAR("g_jailbreak_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_laps_limit");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_race_qualifying_timelimit_override");
 285                 BADCVAR("g_runematch");
 286                 BADCVAR("g_shootfromeye");
 287                 BADCVAR("g_snafu");
 288                 BADCVAR("g_tdm");
 289                 BADCVAR("g_tdm_teams");
 290                 BADCVAR("g_vip");
 291                 BADCVAR("leadlimit");
 292                 BADCVAR("nextmap");
 293                 BADCVAR("teamplay");
 294                 BADCVAR("timelimit");
 295                 BADCVAR("g_mapinfo_ignore_warnings");
 296                 BADCVAR("g_maplist_ignore_sizes");
 297                 BADCVAR("g_maplist_sizes_count_bots");
 298
 299                 // long
 300                 BADCVAR("hostname");
 301                 BADCVAR("g_maplist");
 302                 BADCVAR("g_maplist_mostrecent");
 303                 BADCVAR("sv_motd");
 304
 305                 v = cvar_string(k);
 306                 d = cvar_defstring(k);
 307                 if(v == d)
 308                         continue;
 309
 310                 if(adding)
 311                 {
 312                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 313                         if(strlen(cvar_changes) > 16384)
 314                         {
 315                                 cvar_changes = "// too many settings have been changed to show them here\n";
 316                                 adding = 0;
 317                         }
 318                 }
 319
 320                 // now check if the changes are actually gameplay relevant
 321
 322                 // does nothing gameplay relevant
 323                 BADCVAR("captureleadlimit_override");
 324                 BADCVAR("condump_stripcolors");
 325                 BADCVAR("gameversion");
 326                 BADCVAR("fs_gamedir");
 327                 BADCVAR("g_allow_oldvortexbeam");
 328                 BADCVAR("g_balance_kill_delay");
 329                 BADCVAR("g_buffs_pickup_anyway");
 330                 BADCVAR("g_buffs_randomize");
 331                 BADCVAR("g_campcheck_distance");
 332                 BADCVAR("g_ca_point_leadlimit");
 333                 BADCVAR("g_ca_point_limit");
 334                 BADCVAR("g_ctf_captimerecord_always");
 335                 BADCVAR("g_ctf_flag_glowtrails");
 336                 BADCVAR("g_ctf_flag_pickup_verbosename");
 337                 BADCVAR("g_domination_point_leadlimit");
 338                 BADCVAR("g_forced_respawn");
 339                 BADCVAR("g_freezetag_point_leadlimit");
 340                 BADCVAR("g_freezetag_point_limit");
 341                 BADCVAR("g_hats");
 342                 BADCVAR("g_invasion_point_limit");
 343                 BADCVAR("g_jump_grunt");
 344                 BADCVAR("g_keyhunt_point_leadlimit");
 345                 BADCVAR("g_nexball_goalleadlimit");
 346                 BADCVAR("g_new_toys_autoreplace");
 347                 BADCVAR("g_new_toys_use_pickupsound");
 348                 BADCVAR("g_physics_predictall");
 349                 BADCVAR("g_piggyback");
 350                 BADCVAR("g_playerclip_collisions");
 351                 BADCVAR("g_spawn_alloweffects");
 352                 BADCVAR("g_tdm_point_leadlimit");
 353                 BADCVAR("g_tdm_point_limit");
 354                 BADCVAR("leadlimit_and_fraglimit");
 355                 BADCVAR("leadlimit_override");
 356                 BADCVAR("pausable");
 357                 BADCVAR("sv_checkforpacketsduringsleep");
 358                 BADCVAR("sv_damagetext");
 359                 BADCVAR("sv_db_saveasdump");
 360                 BADCVAR("sv_intermission_cdtrack");
 361                 BADCVAR("sv_minigames");
 362                 BADCVAR("sv_namechangetimer");
 363                 BADCVAR("sv_precacheplayermodels");
 364                 BADCVAR("sv_stepheight");
 365                 BADCVAR("sv_timeout");
 366                 BADCVAR("sv_weapons_modeloverride");
 367                 BADCVAR("w_prop_interval");
 368                 BADPREFIX("crypto_");
 369                 BADPREFIX("gameversion_");
 370                 BADPREFIX("g_chat_");
 371                 BADPREFIX("g_ctf_captimerecord_");
 372                 BADPREFIX("g_hats_");
 373                 BADPREFIX("g_maplist_");
 374                 BADPREFIX("g_mod_");
 375                 BADPREFIX("g_respawn_");
 376                 BADPREFIX("net_");
 377                 BADPREFIX("notification_");
 378                 BADPREFIX("prvm_");
 379                 BADPREFIX("skill_");
 380                 BADPREFIX("sv_allow_");
 381                 BADPREFIX("sv_cullentities_");
 382                 BADPREFIX("sv_maxidle_");
 383                 BADPREFIX("sv_minigames_");
 384                 BADPREFIX("sv_radio_");
 385                 BADPREFIX("sv_timeout_");
 386                 BADPREFIX("sv_vote_");
 387                 BADPREFIX("timelimit_");
 388
 389                 // allowed changes to server admins (please sync this to server.cfg)
 390                 // vi commands:
 391                 //   :/"impure"/,$d
 392                 //   :g!,^\/\/[^ /],d
 393                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 394                 //   :%!sort
 395                 // yes, this does contain some redundant stuff, don't really care
 396                 BADCVAR("bot_config_file");
 397                 BADCVAR("bot_number");
 398                 BADCVAR("bot_prefix");
 399                 BADCVAR("bot_suffix");
 400                 BADCVAR("capturelimit_override");
 401                 BADCVAR("fraglimit_override");
 402                 BADCVAR("gametype");
 403                 BADCVAR("g_antilag");
 404                 BADCVAR("g_balance_teams");
 405                 BADCVAR("g_balance_teams_prevent_imbalance");
 406                 BADCVAR("g_balance_teams_scorefactor");
 407                 BADCVAR("g_ban_sync_trusted_servers");
 408                 BADCVAR("g_ban_sync_uri");
 409                 BADCVAR("g_buffs");
 410                 BADCVAR("g_ca_teams_override");
 411                 BADCVAR("g_ctf_fullbrightflags");
 412                 BADCVAR("g_ctf_ignore_frags");
 413                 BADCVAR("g_ctf_leaderboard");
 414                 BADCVAR("g_domination_point_limit");
 415                 BADCVAR("g_domination_teams_override");
 416                 BADCVAR("g_freezetag_teams_override");
 417                 BADCVAR("g_friendlyfire");
 418                 BADCVAR("g_fullbrightitems");
 419                 BADCVAR("g_fullbrightplayers");
 420                 BADCVAR("g_keyhunt_point_limit");
 421                 BADCVAR("g_keyhunt_teams_override");
 422                 BADCVAR("g_lms_lives_override");
 423                 BADCVAR("g_maplist");
 424                 BADCVAR("g_maxplayers");
 425                 BADCVAR("g_mirrordamage");
 426                 BADCVAR("g_nexball_goallimit");
 427                 BADCVAR("g_norecoil");
 428                 BADCVAR("g_physics_clientselect");
 429                 BADCVAR("g_pinata");
 430                 BADCVAR("g_powerups");
 431                 BADCVAR("g_spawnshieldtime");
 432                 BADCVAR("g_start_delay");
 433                 BADCVAR("g_superspectate");
 434                 BADCVAR("g_tdm_teams_override");
 435                 BADCVAR("g_warmup");
 436                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 437                 BADCVAR("hostname");
 438                 BADCVAR("log_file");
 439                 BADCVAR("maxplayers");
 440                 BADCVAR("minplayers");
 441                 BADCVAR("minplayers_per_team");
 442                 BADCVAR("net_address");
 443                 BADCVAR("port");
 444                 BADCVAR("rcon_password");
 445                 BADCVAR("rcon_restricted_commands");
 446                 BADCVAR("rcon_restricted_password");
 447                 BADCVAR("skill");
 448                 BADCVAR("sv_adminnick");
 449                 BADCVAR("sv_autoscreenshot");
 450                 BADCVAR("sv_autotaunt");
 451                 BADCVAR("sv_curl_defaulturl");
 452                 BADCVAR("sv_defaultcharacter");
 453                 BADCVAR("sv_defaultcharacterskin");
 454                 BADCVAR("sv_defaultplayercolors");
 455                 BADCVAR("sv_defaultplayermodel");
 456                 BADCVAR("sv_defaultplayerskin");
 457                 BADCVAR("sv_maxidle");
 458                 BADCVAR("sv_maxrate");
 459                 BADCVAR("sv_motd");
 460                 BADCVAR("sv_public");
 461                 BADCVAR("sv_ready_restart");
 462                 BADCVAR("sv_status_privacy");
 463                 BADCVAR("sv_taunt");
 464                 BADCVAR("sv_vote_call");
 465                 BADCVAR("sv_vote_commands");
 466                 BADCVAR("sv_vote_majority_factor");
 467                 BADCVAR("sv_vote_master");
 468                 BADCVAR("sv_vote_master_commands");
 469                 BADCVAR("sv_vote_master_password");
 470                 BADCVAR("sv_vote_simple_majority_factor");
 471                 BADCVAR("teamplay_mode");
 472                 BADCVAR("timelimit_override");
 473                 BADPREFIX("g_warmup_");
 474                 BADPREFIX("sv_info_");
 475                 BADPREFIX("sv_ready_restart_");
 476
 477                 // mutators that announce themselves properly to the server browser
 478                 BADCVAR("g_instagib");
 479                 BADCVAR("g_new_toys");
 480                 BADCVAR("g_nix");
 481                 BADCVAR("g_grappling_hook");
 482                 BADCVAR("g_jetpack");
 483
 484                 // temporary for testing
 485                 // TODO remove before 0.8.3 release
 486                 BADCVAR("g_ca_weaponarena");
 487                 BADCVAR("g_freezetag_weaponarena");
 488                 BADCVAR("g_lms_weaponarena");
 489
 490 #undef BADPRESUFFIX
 491 #undef BADPREFIX
 492 #undef BADCVAR
 493
 494                 if(pureadding)
 495                 {
 496                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 497                         if(strlen(cvar_purechanges) > 16384)
 498                         {
 499                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 500                                 pureadding = 0;
 501                         }
 502                 }
 503                 ++cvar_purechanges_count;
 504                 // WARNING: this variable is used for the server list
 505                 // NEVER dare to skip this code!
 506                 // Hacks to intentionally appearing as "pure server" even though you DO have
 507                 // modified settings may be punished by removal from the server list.
 508                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 509                 // though.
 510         }
 511         buf_del(h);
 512         if(cvar_changes == "")
 513                 cvar_changes = "// this server runs at default server settings\n";
 514         else
 515                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 516         cvar_changes = strzone(cvar_changes);
 517         if(cvar_purechanges == "")
 518                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 519         else
 520                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 521         cvar_purechanges = strzone(cvar_purechanges);
 522 }
 523
 524 entity randomseed;
 525 bool RandomSeed_Send(entity this, entity to, int sf)
 526 {
 527         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 528         WriteShort(MSG_ENTITY, this.cnt);
 529         return true;
 530 }
 531 void RandomSeed_Think(entity this)
 532 {
 533         this.cnt = bound(0, floor(random() * 65536), 65535);
 534         this.nextthink = time + 5;
 535
 536         this.SendFlags |= 1;
 537 }
 538 void RandomSeed_Spawn()
 539 {
 540         randomseed = new_pure(randomseed);
 541         setthink(randomseed, RandomSeed_Think);
 542         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 543
 544         getthink(randomseed)(randomseed); // sets random seed and nextthink
 545 }
 546
 547 spawnfunc(__init_dedicated_server)
 548 {
 549         // handler for _init/_init map (only for dedicated server initialization)
 550
 551         world_initialized = -1; // don't complain
 552         cvar = cvar_normal;
 553         cvar_string = cvar_string_normal;
 554         cvar_set = cvar_set_normal;
 555
 556         delete_fn = remove_unsafely;
 557
 558         entity e = spawn();
 559         setthink(e, GotoFirstMap);
 560         e.nextthink = time; // this is usually 1 at this point
 561
 562         e = new(info_player_deathmatch);  // safeguard against player joining
 563
 564     // assign reflectively to avoid "assignment to world" warning
 565     for (int i = 0, n = numentityfields(); i < n; ++i) {
 566         string k = entityfieldname(i);
 567         if (k == "classname") {
 568             // safeguard against various stuff ;)
 569             putentityfieldstring(i, this, "worldspawn");
 570             break;
 571         }
 572     }
 573
 574         // needs to be done so early because of the constants they create
 575         static_init();
 576         static_init_late();
 577         static_init_precache();
 578
 579         IL_PUSH(g_spawnpoints, e); // just incase
 580
 581         MapInfo_Enumerate();
 582         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 583 }
 584
 585 void __init_dedicated_server_shutdown() {
 586         MapInfo_Shutdown();
 587 }
 588
 589 STATIC_INIT_EARLY(maxclients)
 590 {
 591         maxclients = 0;
 592         for (entity head = nextent(NULL); head; head = nextent(head)) {
 593                 ++maxclients;
 594         }
 595 }
 596
 597 void default_delayedinit(entity this)
 598 {
 599         if(!scores_initialized)
 600                 ScoreRules_generic();
 601 }
 602
 603 void InitGameplayMode()
 604 {
 605         VoteReset();
 606
 607         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 608         get_mi_min_max(1);
 609         // assign reflectively to avoid "assignment to world" warning
 610         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 611             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 612             if (v) {
 613             putentityfieldstring(i, world, sprintf("%v", v));
 614             if (++done == 2) break;
 615         }
 616         }
 617         // currently, NetRadiant's limit is 131072 qu for each side
 618         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 619         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 620         // in case somebody makes extremely large maps
 621         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 622
 623         MapInfo_LoadMapSettings(mapname);
 624         GameRules_teams(false);
 625
 626         if (!cvar_value_issafe(world.fog))
 627         {
 628                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 629                 world.fog = string_null;
 630         }
 631         if(MapInfo_Map_fog != "")
 632         {
 633                 if(MapInfo_Map_fog == "none")
 634                         world.fog = string_null;
 635                 else
 636                         world.fog = strzone(MapInfo_Map_fog);
 637         }
 638         clientstuff = strzone(MapInfo_Map_clientstuff);
 639
 640         MapInfo_ClearTemps();
 641
 642         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 643
 644         cache_mutatormsg = strzone("");
 645         cache_lastmutatormsg = strzone("");
 646
 647         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 648 }
 649
 650 void Map_MarkAsRecent(string m);
 651 float world_already_spawned;
 652 spawnfunc(worldspawn)
 653 {
 654         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 655
 656         bool wantrestart = false;
 657         {
 658                 if (!server_is_dedicated)
 659                 {
 660                         // force unloading of server pk3 files when starting a listen server
 661                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 662                         // restore csqc_progname too
 663                         string expect = "csprogs.dat";
 664                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 665                         cvar_set_normal("csqc_progname", expect);
 666                 }
 667                 else
 668                 {
 669                         // Try to use versioned csprogs from pk3
 670                         // Only ever use versioned csprogs.dat files on dedicated servers;
 671                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 672                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 673                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 674                         string select = "csprogs.dat";
 675                         if (fexists(pk3csprogs)) select = pk3csprogs;
 676                         if (cvar_string_normal("csqc_progname") != select)
 677                         {
 678                                 cvar_set_normal("csqc_progname", select);
 679                                 wantrestart = true;
 680                         }
 681                         // Check for updates on startup
 682                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 683                         int sentinel = fopen("progs.txt", FILE_READ);
 684                         if (sentinel >= 0)
 685                         {
 686                                 string switchversion = fgets(sentinel);
 687                                 fclose(sentinel);
 688                                 if (switchversion != "" && switchversion != WATERMARK)
 689                                 {
 690                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 691                                         // if it doesn't exist, assume either:
 692                                         //   a) the current program was overwritten
 693                                         //   b) this is a client only update
 694                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 695                                         if (fexists(newprogs))
 696                                         {
 697                                                 cvar_set_normal("sv_progs", newprogs);
 698                                                 wantrestart = true;
 699                                         }
 700                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 701                                         if (fexists(newcsprogs))
 702                                         {
 703                                                 cvar_set_normal("csqc_progname", newcsprogs);
 704                                                 wantrestart = true;
 705                                         }
 706                                 }
 707                         }
 708                 }
 709                 if (wantrestart)
 710                 {
 711                         LOG_INFO("Restart requested");
 712                         changelevel(mapname);
 713                         // let initialization continue, shutdown depends on it
 714                 }
 715         }
 716
 717         cvar = cvar_normal;
 718         cvar_string = cvar_string_normal;
 719         cvar_set = cvar_set_normal;
 720
 721         if(world_already_spawned)
 722                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 723         world_already_spawned = true;
 724
 725         delete_fn = remove_safely; // during spawning, watch what you remove!
 726
 727         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 728
 729         // needs to be done so early because of the constants they create
 730         static_init();
 731
 732         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 733
 734         TemporaryDB = db_create();
 735
 736         // 0 normal
 737         lightstyle(0, "m");
 738
 739         // 1 FLICKER (first variety)
 740         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 741
 742         // 2 SLOW STRONG PULSE
 743         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 744
 745         // 3 CANDLE (first variety)
 746         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 747
 748         // 4 FAST STROBE
 749         lightstyle(4, "mamamamamama");
 750
 751         // 5 GENTLE PULSE 1
 752         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 753
 754         // 6 FLICKER (second variety)
 755         lightstyle(6, "nmonqnmomnmomomno");
 756
 757         // 7 CANDLE (second variety)
 758         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 759
 760         // 8 CANDLE (third variety)
 761         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 762
 763         // 9 SLOW STROBE (fourth variety)
 764         lightstyle(9, "aaaaaaaazzzzzzzz");
 765
 766         // 10 FLUORESCENT FLICKER
 767         lightstyle(10, "mmamammmmammamamaaamammma");
 768
 769         // 11 SLOW PULSE NOT FADE TO BLACK
 770         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 771
 772         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 773
 774         // 63 testing
 775         lightstyle(63, "a");
 776
 777         if(autocvar_g_campaign)
 778                 CampaignPreInit();
 779
 780         Map_MarkAsRecent(mapname);
 781
 782         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 783
 784         InitGameplayMode();
 785         static_init_late();
 786         static_init_precache();
 787         readlevelcvars();
 788         GrappleHookInit();
 789
 790         GameRules_limit_fallbacks();
 791
 792         if(warmup_limit == 0)
 793                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 794
 795         player_count = 0;
 796         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 797         if(bot_waypoints_for_items == 1)
 798                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 799                         bot_waypoints_for_items = 0;
 800
 801         precache();
 802
 803         WaypointSprite_Init();
 804
 805         GameLogInit(); // prepare everything
 806         // NOTE for matchid:
 807         // changing the logic generating it is okay. But:
 808         // it HAS to stay <= 64 chars
 809         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 810         if(autocvar_sv_eventlog)
 811         {
 812                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 813                 matchid = strzone(s);
 814
 815                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 816                 s = ":gameinfo:mutators:LIST";
 817
 818                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 819                 s = M_ARGV(0, string);
 820
 821                 // initialiation stuff, not good in the mutator system
 822                 if(!autocvar_g_use_ammunition)
 823                         s = strcat(s, ":no_use_ammunition");
 824
 825                 // initialiation stuff, not good in the mutator system
 826                 if(autocvar_g_pickup_items == 0)
 827                         s = strcat(s, ":no_pickup_items");
 828                 if(autocvar_g_pickup_items > 0)
 829                         s = strcat(s, ":pickup_items");
 830
 831                 // initialiation stuff, not good in the mutator system
 832                 if(autocvar_g_weaponarena != "0")
 833                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 834
 835                 // TODO to mutator system
 836                 if(autocvar_g_norecoil)
 837                         s = strcat(s, ":norecoil");
 838
 839                 // TODO to mutator system
 840                 if(autocvar_g_powerups == 0)
 841                         s = strcat(s, ":no_powerups");
 842                 if(autocvar_g_powerups > 0)
 843                         s = strcat(s, ":powerups");
 844
 845                 GameLogEcho(s);
 846                 GameLogEcho(":gameinfo:end");
 847         }
 848         else
 849                 matchid = strzone(ftos(random()));
 850
 851         cvar_set("nextmap", "");
 852
 853         SetDefaultAlpha();
 854
 855         if(autocvar_g_campaign)
 856                 CampaignPostInit();
 857
 858         Ban_LoadBans();
 859
 860         MapInfo_Enumerate();
 861         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 862
 863         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 864         {
 865                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 866                 if(fd != -1)
 867                 {
 868                         string s;
 869                         while((s = fgets(fd)))
 870                         {
 871                                 int l = tokenize_console(s);
 872                                 if(l < 2)
 873                                         continue;
 874                                 if(argv(0) == "cd")
 875                                 {
 876                                         string trackname = argv(2);
 877                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 878                                         LOG_INFO("  cdtrack ", trackname);
 879                                         if (cvar_value_issafe(trackname))
 880                                         {
 881                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 882                                                 strcpy(clientstuff, newstuff);
 883                                         }
 884                                 }
 885                                 else if(argv(0) == "fog")
 886                                 {
 887                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 888                                         LOG_INFO("  \"fog\" \"", s, "\"");
 889                                 }
 890                                 else if(argv(0) == "set")
 891                                 {
 892                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 893                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 894                                 }
 895                                 else if(argv(0) != "//")
 896                                 {
 897                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 898                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 899                                 }
 900                         }
 901                         fclose(fd);
 902                 }
 903         }
 904
 905         WeaponStats_Init();
 906
 907         Nagger_Init();
 908
 909         next_pingtime = time + 5;
 910
 911         // set up information replies for clients and server to use
 912         maplist_reply = strzone(getmaplist());
 913         lsmaps_reply = strzone(getlsmaps());
 914         monsterlist_reply = strzone(getmonsterlist());
 915         for(int i = 0; i < 10; ++i)
 916         {
 917                 string s = getrecords(i);
 918                 if (s)
 919                         records_reply[i] = strzone(s);
 920         }
 921         ladder_reply = strzone(getladder());
 922         rankings_reply = strzone(getrankings());
 923
 924         // begin other init
 925         ClientInit_Spawn();
 926         RandomSeed_Spawn();
 927         PingPLReport_Spawn();
 928
 929         CheatInit();
 930
 931         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 932
 933         // fill sv_curl_serverpackages from .serverpackage files
 934         if (autocvar_sv_curl_serverpackages_auto)
 935         {
 936                 string s = "csprogs-" WATERMARK ".txt";
 937                 // remove automatically managed files from the list to prevent duplicates
 938                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 939                 {
 940                         string pkg = argv(i);
 941                         if (startsWith(pkg, "csprogs-")) continue;
 942                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 943                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 944                         s = cons(s, pkg);
 945                 }
 946                 // add automatically managed files to the list
 947                 #define X(match) MACRO_BEGIN \
 948                         int fd = search_begin(match, true, false); \
 949                         if (fd >= 0) \
 950                         { \
 951                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 952                                 { \
 953                                         s = cons(s, search_getfilename(fd, i)); \
 954                                 } \
 955                                 search_end(fd); \
 956                         } \
 957                 MACRO_END
 958                 X("*-serverpackage.txt");
 959                 X("*.serverpackage");
 960                 #undef X
 961                 cvar_set("sv_curl_serverpackages", s);
 962         }
 963
 964         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 965         modname = "Xonotic";
 966         // physics/balance/config changes that count as mod
 967         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 968                 modname = cvar_string("g_mod_physics");
 969         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 970                 modname = cvar_string("g_mod_balance");
 971         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 972                 modname = cvar_string("g_mod_config");
 973         // extra mutators that deserve to count as mod
 974         MUTATOR_CALLHOOK(SetModname, modname);
 975         modname = M_ARGV(0, string);
 976
 977         // save it for later
 978         modname = strzone(modname);
 979
 980         WinningConditionHelper(this); // set worldstatus
 981
 982         world_initialized = 1;
 983         __spawnfunc_spawn_all();
 984 }
 985
 986 spawnfunc(light)
 987 {
 988         //makestatic (this); // Who the f___ did that?
 989         delete(this);
 990 }
 991
 992 string GetGametype()
 993 {
 994         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 995 }
 996
 997 string GetMapname()
 998 {
 999         return mapname;
1000 }
1001
1002 float Map_Count, Map_Current;
1003 string Map_Current_Name;
1004
1005 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1006 int GetMaplistPosition()
1007 {
1008         string map = GetMapname();
1009         int idx = autocvar_g_maplist_index;
1010
1011         if(idx >= 0)
1012         {
1013                 if(idx < Map_Count)
1014                 {
1015                         if(map == argv(idx))
1016                         {
1017                                 return idx;
1018                         }
1019                 }
1020         }
1021
1022         for(int pos = 0; pos < Map_Count; ++pos)
1023         {
1024                 if(map == argv(pos))
1025                         return pos;
1026         }
1027
1028         // resume normal maplist rotation if current map is not in g_maplist
1029         return idx;
1030 }
1031
1032 bool MapHasRightSize(string map)
1033 {
1034         int minplayers = max(0, floor(autocvar_minplayers));
1035         if (teamplay)
1036                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1037         if (autocvar_g_maplist_check_waypoints
1038                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1039         {
1040                 string checkwp_msg = strcat("checkwp ", map);
1041                 if(!fexists(strcat("maps/", map, ".waypoints")))
1042                 {
1043                         LOG_TRACE(checkwp_msg, ": no waypoints");
1044                         return false;
1045                 }
1046                 LOG_TRACE(checkwp_msg, ": has waypoints");
1047         }
1048
1049         if(autocvar_g_maplist_ignore_sizes)
1050                 return true;
1051
1052         // open map size restriction file
1053         string opensize_msg = strcat("opensize ", map);
1054         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1055         int pcount = player_count;
1056         if(!autocvar_g_maplist_sizes_count_bots)
1057                 pcount -= currentbots;
1058         if(fh >= 0)
1059         {
1060                 opensize_msg = strcat(opensize_msg, ": ok, ");
1061                 int mapmin = stoi(fgets(fh));
1062                 int mapmax = stoi(fgets(fh));
1063                 fclose(fh);
1064                 if(pcount < mapmin)
1065                 {
1066                         LOG_TRACE(opensize_msg, "not enough");
1067                         return false;
1068                 }
1069                 if(mapmax && pcount > mapmax)
1070                 {
1071                         LOG_TRACE(opensize_msg, "too many");
1072                         return false;
1073                 }
1074                 LOG_TRACE(opensize_msg, "right size");
1075                 return true;
1076         }
1077         LOG_TRACE(opensize_msg, ": not found");
1078         return true;
1079 }
1080
1081 string Map_Filename(float position)
1082 {
1083         return strcat("maps/", argv(position), ".bsp");
1084 }
1085
1086 void Map_MarkAsRecent(string m)
1087 {
1088         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1089 }
1090
1091 float Map_IsRecent(string m)
1092 {
1093         return strhasword(autocvar_g_maplist_mostrecent, m);
1094 }
1095
1096 float Map_Check(float position, float pass)
1097 {
1098         string filename;
1099         string map_next;
1100         map_next = argv(position);
1101         if(pass <= 1)
1102         {
1103                 if(Map_IsRecent(map_next))
1104                         return 0;
1105         }
1106         filename = Map_Filename(position);
1107         if(MapInfo_CheckMap(map_next))
1108         {
1109                 if(pass == 2)
1110                         return 1;
1111                 if(MapHasRightSize(map_next))
1112                         return 1;
1113                 return 0;
1114         }
1115         else
1116                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1117
1118         return 0;
1119 }
1120
1121 void Map_Goto_SetStr(string nextmapname)
1122 {
1123         if(getmapname_stored != "")
1124                 strunzone(getmapname_stored);
1125         if(nextmapname == "")
1126                 getmapname_stored = "";
1127         else
1128                 getmapname_stored = strzone(nextmapname);
1129 }
1130
1131 void Map_Goto_SetFloat(float position)
1132 {
1133         cvar_set("g_maplist_index", ftos(position));
1134         Map_Goto_SetStr(argv(position));
1135 }
1136
1137 void Map_Goto(float reinit)
1138 {
1139         MapInfo_LoadMap(getmapname_stored, reinit);
1140 }
1141
1142 // return codes of map selectors:
1143 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1144 //   -2 = permanent failure
1145 float MaplistMethod_Iterate() // usual method
1146 {
1147         float pass, i;
1148
1149         LOG_TRACE("Trying MaplistMethod_Iterate");
1150
1151         for(pass = 1; pass <= 2; ++pass)
1152         {
1153                 for(i = 1; i < Map_Count; ++i)
1154                 {
1155                         float mapindex;
1156                         mapindex = (i + Map_Current) % Map_Count;
1157                         if(Map_Check(mapindex, pass))
1158                                 return mapindex;
1159                 }
1160         }
1161         return -1;
1162 }
1163
1164 float MaplistMethod_Repeat() // fallback method
1165 {
1166         LOG_TRACE("Trying MaplistMethod_Repeat");
1167
1168         if(Map_Check(Map_Current, 2))
1169                 return Map_Current;
1170         return -2;
1171 }
1172
1173 float MaplistMethod_Random() // random map selection
1174 {
1175         float i, imax;
1176
1177         LOG_TRACE("Trying MaplistMethod_Random");
1178
1179         imax = 42;
1180
1181         for(i = 0; i <= imax; ++i)
1182         {
1183                 float mapindex;
1184                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1185                 if(Map_Check(mapindex, 1))
1186                         return mapindex;
1187         }
1188         return -1;
1189 }
1190
1191 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1192 // the exponent sets a bias on the map selection:
1193 // the higher the exponent, the less likely "shortly repeated" same maps are
1194 {
1195         float i, j, imax, insertpos;
1196
1197         LOG_TRACE("Trying MaplistMethod_Shuffle");
1198
1199         imax = 42;
1200
1201         for(i = 0; i <= imax; ++i)
1202         {
1203                 string newlist;
1204
1205                 // now reinsert this at another position
1206                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1207                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1208                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1209                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1210
1211                 // insert the current map there
1212                 newlist = "";
1213                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1214                         newlist = strcat(newlist, " ", argv(j));
1215                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1216                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1217                         newlist = strcat(newlist, " ", argv(j));
1218                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1219                 cvar_set("g_maplist", newlist);
1220                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1221
1222                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1223                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1224                 if(Map_Check(Map_Current, 1))
1225                         return Map_Current;
1226         }
1227         return -1;
1228 }
1229
1230 void Maplist_Init()
1231 {
1232         float i = Map_Count = 0;
1233         if(autocvar_g_maplist != "")
1234         {
1235                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1236                 for (i = 0; i < Map_Count; ++i)
1237                 {
1238                         if (Map_Check(i, 2))
1239                                 break;
1240                 }
1241         }
1242
1243         if (i == Map_Count)
1244         {
1245                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1246                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1247                 if(autocvar_g_maplist_shuffle)
1248                         ShuffleMaplist();
1249                 if(!server_is_dedicated)
1250                         localcmd("\nmenu_cmd sync\n");
1251                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1252         }
1253         if(Map_Count == 0)
1254                 error("empty maplist, cannot select a new map");
1255         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1256
1257         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1258         // this may or may not be correct, but who cares, in the worst case a map
1259         // isn't chosen in the first pass that should have been
1260 }
1261
1262 string GetNextMap()
1263 {
1264         Maplist_Init();
1265         float nextMap = -1;
1266
1267         if(nextMap == -1)
1268                 if(autocvar_g_maplist_shuffle > 0)
1269                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1270
1271         if(nextMap == -1)
1272                 if(autocvar_g_maplist_selectrandom)
1273                         nextMap = MaplistMethod_Random();
1274
1275         if(nextMap == -1)
1276                 nextMap = MaplistMethod_Iterate();
1277
1278         if(nextMap == -1)
1279                 nextMap = MaplistMethod_Repeat();
1280
1281         if(nextMap >= 0)
1282         {
1283                 Map_Goto_SetFloat(nextMap);
1284                 return getmapname_stored;
1285         }
1286
1287         return "";
1288 }
1289
1290 float DoNextMapOverride(float reinit)
1291 {
1292         if(autocvar_g_campaign)
1293         {
1294                 CampaignPostIntermission();
1295                 alreadychangedlevel = true;
1296                 return true;
1297         }
1298         if(autocvar_quit_when_empty)
1299         {
1300                 if(player_count <= currentbots)
1301                 {
1302                         localcmd("quit\n");
1303                         alreadychangedlevel = true;
1304                         return true;
1305                 }
1306         }
1307         if(autocvar_quit_and_redirect != "")
1308         {
1309                 redirection_target = strzone(autocvar_quit_and_redirect);
1310                 alreadychangedlevel = true;
1311                 return true;
1312         }
1313         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1314         {
1315                 localcmd("restart\n");
1316                 alreadychangedlevel = true;
1317                 return true;
1318         }
1319         if(autocvar_nextmap != "")
1320         {
1321                 string m;
1322                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1323                 cvar_set("nextmap",m);
1324
1325                 if(!m || gametypevote)
1326                         return false;
1327                 if(autocvar_sv_vote_gametype)
1328                 {
1329                         Map_Goto_SetStr(m);
1330                         return false;
1331                 }
1332
1333                 if(MapInfo_CheckMap(m))
1334                 {
1335                         Map_Goto_SetStr(m);
1336                         Map_Goto(reinit);
1337                         alreadychangedlevel = true;
1338                         return true;
1339                 }
1340         }
1341         if(!reinit && autocvar_lastlevel)
1342         {
1343                 cvar_settemp_restore();
1344                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1345                 alreadychangedlevel = true;
1346                 return true;
1347         }
1348         return false;
1349 }
1350
1351 void GotoNextMap(float reinit)
1352 {
1353         //string nextmap;
1354         //float n, nummaps;
1355         //string s;
1356         if (alreadychangedlevel)
1357                 return;
1358         alreadychangedlevel = true;
1359
1360         string nextMap = GetNextMap();
1361         if(nextMap == "")
1362                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1363         Map_Goto(reinit);
1364 }
1365
1366
1367 /*
1368 ============
1369 IntermissionThink
1370
1371 When the player presses attack or jump, change to the next level
1372 ============
1373 */
1374 .float autoscreenshot;
1375 void IntermissionThink(entity this)
1376 {
1377         FixIntermissionClient(this);
1378
1379         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1380         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1381
1382         if( (server_screenshot || client_screenshot)
1383                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1384         {
1385                 this.autoscreenshot = -1;
1386                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1387                 return;
1388         }
1389
1390         if (time < intermission_exittime)
1391                 return;
1392
1393         if(!mapvote_initialized)
1394                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1395                         return;
1396
1397         MapVote_Start();
1398 }
1399
1400 /*
1401 ============
1402 FindIntermission
1403
1404 Returns the entity to view from
1405 ============
1406 */
1407 /*
1408 entity FindIntermission()
1409 {
1410         local   entity spot;
1411         local   float cyc;
1412
1413 // look for info_intermission first
1414         spot = find(NULL, classname, "info_intermission");
1415         if (spot)
1416         {       // pick a random one
1417                 cyc = random() * 4;
1418                 while (cyc > 1)
1419                 {
1420                         spot = find(spot, classname, "info_intermission");
1421                         if (!spot)
1422                                 spot = find(spot, classname, "info_intermission");
1423                         cyc = cyc - 1;
1424                 }
1425                 return spot;
1426         }
1427
1428 // then look for the start position
1429         spot = find(NULL, classname, "info_player_start");
1430         if (spot)
1431                 return spot;
1432
1433 // testinfo_player_start is only found in regioned levels
1434         spot = find(NULL, classname, "testplayerstart");
1435         if (spot)
1436                 return spot;
1437
1438 // then look for the start position
1439         spot = find(NULL, classname, "info_player_deathmatch");
1440         if (spot)
1441                 return spot;
1442
1443         //objerror ("FindIntermission: no spot");
1444         return NULL;
1445 }
1446 */
1447
1448 /*
1449 ===============================================================================
1450
1451 RULES
1452
1453 ===============================================================================
1454 */
1455
1456 void DumpStats(float final)
1457 {
1458         float file;
1459         string s;
1460         float to_console;
1461         float to_eventlog;
1462         float to_file;
1463         float i;
1464
1465         to_console = autocvar_sv_logscores_console;
1466         to_eventlog = autocvar_sv_eventlog;
1467         to_file = autocvar_sv_logscores_file;
1468
1469         if(!final)
1470         {
1471                 to_console = true; // always print printstats replies
1472                 to_eventlog = false; // but never print them to the event log
1473         }
1474
1475         if(to_eventlog)
1476                 if(autocvar_sv_eventlog_console)
1477                         to_console = false; // otherwise we get the output twice
1478
1479         if(final)
1480                 s = ":scores:";
1481         else
1482                 s = ":status:";
1483         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1484
1485         if(to_console)
1486                 LOG_INFO(s);
1487         if(to_eventlog)
1488                 GameLogEcho(s);
1489
1490         file = -1;
1491         if(to_file)
1492         {
1493                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1494                 if(file == -1)
1495                         to_file = false;
1496                 else
1497                         fputs(file, strcat(s, "\n"));
1498         }
1499
1500         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1501         if(to_console)
1502                 LOG_INFO(s);
1503         if(to_eventlog)
1504                 GameLogEcho(s);
1505         if(to_file)
1506                 fputs(file, strcat(s, "\n"));
1507
1508         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1509                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1510                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1511                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1512                         s = strcat(s, ftos(it.team), ":");
1513                 else
1514                         s = strcat(s, "spectator:");
1515
1516                 if(to_console)
1517                         LOG_INFO(s, playername(it, false));
1518                 if(to_eventlog)
1519                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1520                 if(to_file)
1521                         fputs(file, strcat(s, playername(it, false), "\n"));
1522         });
1523
1524         if(teamplay)
1525         {
1526                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1527                 if(to_console)
1528                         LOG_INFO(s);
1529                 if(to_eventlog)
1530                         GameLogEcho(s);
1531                 if(to_file)
1532                         fputs(file, strcat(s, "\n"));
1533
1534                 for(i = 1; i < 16; ++i)
1535                 {
1536                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1537                         s = strcat(s, ":", ftos(i));
1538                         if(to_console)
1539                                 LOG_INFO(s);
1540                         if(to_eventlog)
1541                                 GameLogEcho(s);
1542                         if(to_file)
1543                                 fputs(file, strcat(s, "\n"));
1544                 }
1545         }
1546
1547         if(to_console)
1548                 LOG_INFO(":end");
1549         if(to_eventlog)
1550                 GameLogEcho(":end");
1551         if(to_file)
1552         {
1553                 fputs(file, ":end\n");
1554                 fclose(file);
1555         }
1556 }
1557
1558 void FixIntermissionClient(entity e)
1559 {
1560         if(!e.autoscreenshot) // initial call
1561         {
1562                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1563                 SetResourceExplicit(e, RES_HEALTH, -2342);
1564                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1565                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1566                 {
1567                     .entity weaponentity = weaponentities[slot];
1568                         if(e.(weaponentity))
1569                         {
1570                                 e.(weaponentity).effects = EF_NODRAW;
1571                                 if (e.(weaponentity).weaponchild)
1572                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1573                         }
1574                 }
1575                 if(IS_REAL_CLIENT(e))
1576                 {
1577                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1578                         RandomSelection_Init();
1579                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1580                                 RandomSelection_AddString(it, 1, 1);
1581                         });
1582                         if (RandomSelection_chosen_string != "")
1583                         {
1584                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1585                         }
1586                         msg_entity = e;
1587                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1588                 }
1589         }
1590 }
1591
1592 /*
1593 go to the next level for deathmatch
1594 only called if a time or frag limit has expired
1595 */
1596 void NextLevel()
1597 {
1598         game_stopped = true;
1599         intermission_running = 1; // game over
1600
1601         // enforce a wait time before allowing changelevel
1602         if(player_count > 0)
1603                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1604         else
1605                 intermission_exittime = -1;
1606
1607         /*
1608         WriteByte (MSG_ALL, SVC_CDTRACK);
1609         WriteByte (MSG_ALL, 3);
1610         WriteByte (MSG_ALL, 3);
1611         // done in FixIntermission
1612         */
1613
1614         //pos = FindIntermission ();
1615
1616         VoteReset();
1617
1618         DumpStats(true);
1619
1620         // send statistics
1621         PlayerStats_GameReport(true);
1622         WeaponStats_Shutdown();
1623
1624         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1625
1626         if(autocvar_sv_eventlog)
1627                 GameLogEcho(":gameover");
1628
1629         GameLogClose();
1630
1631         FOREACH_CLIENT(IS_PLAYER(it), {
1632                 FixIntermissionClient(it);
1633                 if(it.winning)
1634                         bprint(playername(it, false), " ^7wins.\n");
1635         });
1636
1637         target_music_kill();
1638
1639         if(autocvar_g_campaign)
1640                 CampaignPreIntermission();
1641
1642         MUTATOR_CALLHOOK(MatchEnd);
1643
1644         localcmd("\nsv_hook_gameend\n");
1645 }
1646
1647
1648 float InitiateSuddenDeath()
1649 {
1650         // Check first whether normal overtimes could be added before initiating suddendeath mode
1651         // - for this timelimit_overtime needs to be >0 of course
1652         // - also check the winning condition calculated in the previous frame and only add normal overtime
1653         //   again, if at the point at which timelimit would be extended again, still no winner was found
1654         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1655                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1656                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1657         {
1658                 return 1; // need to call InitiateOvertime later
1659         }
1660         else
1661         {
1662                 if(!checkrules_suddendeathend)
1663                 {
1664                         if(autocvar_g_campaign)
1665                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1666                         else
1667                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1668                         if(g_race && !g_race_qualifying)
1669                                 race_StartCompleting();
1670                 }
1671                 return 0;
1672         }
1673 }
1674
1675 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1676 {
1677         ++checkrules_overtimesadded;
1678         //add one more overtime by simply extending the timelimit
1679         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1680         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1681 }
1682
1683 float GetWinningCode(float fraglimitreached, float equality)
1684 {
1685         if(autocvar_g_campaign == 1)
1686         {
1687                 if(fraglimitreached)
1688                         return WINNING_YES;
1689                 else
1690                         return WINNING_NO;
1691         }
1692         else
1693         {
1694                 if(equality)
1695                 {
1696                         if(fraglimitreached)
1697                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1698                         else
1699                                 return WINNING_NEVER;
1700                 }
1701                 else
1702                 {
1703                         if(fraglimitreached)
1704                                 return WINNING_YES;
1705                         else
1706                                 return WINNING_NO;
1707                 }
1708         }
1709 }
1710
1711 // set the .winning flag for exactly those players with a given field value
1712 void SetWinners(.float field, float value)
1713 {
1714         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1715 }
1716
1717 // set the .winning flag for those players with a given field value
1718 void AddWinners(.float field, float value)
1719 {
1720         FOREACH_CLIENT(IS_PLAYER(it), {
1721                 if(it.(field) == value)
1722                         it.winning = 1;
1723         });
1724 }
1725
1726 // clear the .winning flags
1727 void ClearWinners()
1728 {
1729         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1730 }
1731
1732 void ShuffleMaplist()
1733 {
1734         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1735 }
1736
1737 float leaderfrags;
1738 float WinningCondition_Scores(float limit, float leadlimit)
1739 {
1740         float limitreached;
1741
1742         // TODO make everything use THIS winning condition (except LMS)
1743         WinningConditionHelper(NULL);
1744
1745         if(teamplay)
1746         {
1747                 for (int i = 1; i < 5; ++i)
1748                 {
1749                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1750                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1751                 }
1752         }
1753
1754         ClearWinners();
1755         if(WinningConditionHelper_winner)
1756                 WinningConditionHelper_winner.winning = 1;
1757         if(WinningConditionHelper_winnerteam >= 0)
1758                 SetWinners(team, WinningConditionHelper_winnerteam);
1759
1760         if(WinningConditionHelper_lowerisbetter)
1761         {
1762                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1763                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1764                 limit = -limit;
1765         }
1766
1767         if(WinningConditionHelper_zeroisworst)
1768                 leadlimit = 0; // not supported in this mode
1769
1770         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1771         // these modes always score in increments of 1, thus this makes sense
1772         {
1773                 if(leaderfrags != WinningConditionHelper_topscore)
1774                 {
1775                         leaderfrags = WinningConditionHelper_topscore;
1776
1777                         if (limit)
1778                         {
1779                                 if (leaderfrags == limit - 1)
1780                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1781                                 else if (leaderfrags == limit - 2)
1782                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1783                                 else if (leaderfrags == limit - 3)
1784                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1785                         }
1786                 }
1787         }
1788
1789         limitreached = false;
1790         if (limit && WinningConditionHelper_topscore >= limit)
1791                 limitreached = true;
1792         if(leadlimit)
1793         {
1794                 float leadlimitreached;
1795                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1796                 if(autocvar_leadlimit_and_fraglimit)
1797                         limitreached = (limitreached && leadlimitreached);
1798                 else
1799                         limitreached = (limitreached || leadlimitreached);
1800         }
1801
1802         if(limit)
1803                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1804
1805         return GetWinningCode(
1806                 WinningConditionHelper_topscore && limitreached,
1807                 WinningConditionHelper_equality
1808         );
1809 }
1810
1811 float WinningCondition_RanOutOfSpawns()
1812 {
1813         if(have_team_spawns <= 0)
1814                 return WINNING_NO;
1815
1816         if(!autocvar_g_spawn_useallspawns)
1817                 return WINNING_NO;
1818
1819         if(!some_spawn_has_been_used)
1820                 return WINNING_NO;
1821
1822         for (int i = 1; i < 5; ++i)
1823         {
1824                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1825         }
1826
1827         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1828         {
1829                 if (Team_IsValidTeam(it.team))
1830                 {
1831                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1832                 }
1833         });
1834
1835         IL_EACH(g_spawnpoints, true,
1836         {
1837                 if (Team_IsValidTeam(it.team))
1838                 {
1839                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1840                 }
1841         });
1842
1843         ClearWinners();
1844         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1845         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1846         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1847         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1848         if(team1_score + team2_score + team3_score + team4_score == 0)
1849         {
1850                 checkrules_equality = true;
1851                 return WINNING_YES;
1852         }
1853         else if(team1_score + team2_score + team3_score + team4_score == 1)
1854         {
1855                 float t, i;
1856                 if(team1_score)
1857                         t = 1;
1858                 else if(team2_score)
1859                         t = 2;
1860                 else if(team3_score)
1861                         t = 3;
1862                 else // if(team4_score)
1863                         t = 4;
1864                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1865                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1866                 {
1867                         for (int j = 1; j <= NUM_TEAMS; ++j)
1868                         {
1869                                 if (t == j)
1870                                 {
1871                                         continue;
1872                                 }
1873                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1874                                 {
1875                                         continue;
1876                                 }
1877                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1878                         }
1879                 }
1880
1881                 AddWinners(team, t);
1882                 return WINNING_YES;
1883         }
1884         else
1885                 return WINNING_NO;
1886 }
1887
1888 /*
1889 ============
1890 CheckRules_World
1891
1892 Exit deathmatch games upon conditions
1893 ============
1894 */
1895 void CheckRules_World()
1896 {
1897         float timelimit;
1898         float fraglimit;
1899         float leadlimit;
1900
1901         VoteThink();
1902         MapVote_Think();
1903
1904         SetDefaultAlpha();
1905
1906         if (intermission_running) // someone else quit the game already
1907         {
1908                 if(player_count == 0) // Nobody there? Then let's go to the next map
1909                         MapVote_Start();
1910                         // this will actually check the player count in the next frame
1911                         // again, but this shouldn't hurt
1912                 return;
1913         }
1914
1915         timelimit = autocvar_timelimit * 60;
1916         fraglimit = autocvar_fraglimit;
1917         leadlimit = autocvar_leadlimit;
1918
1919         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1920         {
1921                 if(timelimit > 0)
1922                         timelimit = 0; // timelimit is not made for warmup
1923                 if(fraglimit > 0)
1924                         fraglimit = 0; // no fraglimit for now
1925                 leadlimit = 0; // no leadlimit for now
1926         }
1927
1928         if(timelimit > 0)
1929         {
1930                 timelimit += game_starttime;
1931         }
1932         else if (timelimit < 0)
1933         {
1934                 // endmatch
1935                 NextLevel();
1936                 return;
1937         }
1938
1939         float wantovertime;
1940         wantovertime = 0;
1941
1942         if(timelimit > game_starttime)
1943                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1944         else
1945                 game_completion_ratio = 0;
1946
1947         if(checkrules_suddendeathend)
1948         {
1949                 if(!checkrules_suddendeathwarning)
1950                 {
1951                         checkrules_suddendeathwarning = true;
1952                         if(g_race && !g_race_qualifying)
1953                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1954                         else
1955                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1956                 }
1957         }
1958         else
1959         {
1960                 if (timelimit && time >= timelimit)
1961                 {
1962                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1963                         {
1964                                 float totalplayers;
1965                                 float playerswithlaps;
1966                                 float readyplayers;
1967                                 totalplayers = playerswithlaps = readyplayers = 0;
1968                                 FOREACH_CLIENT(IS_PLAYER(it), {
1969                                         ++totalplayers;
1970                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1971                                                 ++playerswithlaps;
1972                                         if(it.ready)
1973                                                 ++readyplayers;
1974                                 });
1975
1976                                 // at least 2 of the players have completed a lap: start the RACE
1977                                 // otherwise, the players should end the qualifying on their own
1978                                 if(readyplayers || playerswithlaps >= 2)
1979                                 {
1980                                         checkrules_suddendeathend = 0;
1981                                         ReadyRestart(); // go to race
1982                                         return;
1983                                 }
1984                                 else
1985                                         wantovertime |= InitiateSuddenDeath();
1986                         }
1987                         else
1988                                 wantovertime |= InitiateSuddenDeath();
1989                 }
1990         }
1991
1992         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1993         {
1994                 NextLevel();
1995                 return;
1996         }
1997
1998         int checkrules_status = WinningCondition_RanOutOfSpawns();
1999         if(checkrules_status == WINNING_YES)
2000                 bprint("Hey! Someone ran out of spawns!\n");
2001         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
2002                 checkrules_status = M_ARGV(0, float);
2003         else
2004                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2005
2006         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2007         {
2008                 checkrules_status = WINNING_NEVER;
2009                 checkrules_overtimesadded = -1;
2010                 wantovertime |= InitiateSuddenDeath();
2011         }
2012
2013         if(checkrules_status == WINNING_NEVER)
2014                 // equality cases! Nobody wins if the overtime ends in a draw.
2015                 ClearWinners();
2016
2017         if(wantovertime)
2018         {
2019                 if(checkrules_status == WINNING_NEVER)
2020                         InitiateOvertime();
2021                 else
2022                         checkrules_status = WINNING_YES;
2023         }
2024
2025         if(checkrules_suddendeathend)
2026                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2027                         checkrules_status = WINNING_YES;
2028
2029         if(checkrules_status == WINNING_YES)
2030         {
2031                 //print("WINNING\n");
2032                 NextLevel();
2033         }
2034 }
2035
2036 string GotoMap(string m)
2037 {
2038         m = GameTypeVote_MapInfo_FixName(m);
2039         if (!m)
2040                 return "The map you suggested is not available on this server.";
2041         if (!autocvar_sv_vote_gametype)
2042         if(!MapInfo_CheckMap(m))
2043                 return "The map you suggested does not support the current game mode.";
2044         cvar_set("nextmap", m);
2045         cvar_set("timelimit", "-1");
2046         if(mapvote_initialized || alreadychangedlevel)
2047         {
2048                 if(DoNextMapOverride(0))
2049                         return "Map switch initiated.";
2050                 else
2051                         return "Hm... no. For some reason I like THIS map more.";
2052         }
2053         else
2054                 return "Map switch will happen after scoreboard.";
2055 }
2056
2057 bool autocvar_sv_gameplayfix_multiplethinksperframe;
2058 void RunThink(entity this)
2059 {
2060         // don't let things stay in the past.
2061         // it is possible to start that way by a trigger with a local time.
2062         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2063                 return;
2064
2065         float oldtime = time; // do we need to save this?
2066
2067         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2068         {
2069                 time = max(oldtime, this.nextthink);
2070                 this.nextthink = 0;
2071
2072                 if(getthink(this))
2073                         getthink(this)(this);
2074                 // mods often set nextthink to time to cause a think every frame,
2075                 // we don't want to loop in that case, so exit if the new nextthink is
2076                 // <= the time the qc was told, also exit if it is past the end of the
2077                 // frame
2078                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2079                         break;
2080         }
2081
2082         time = oldtime;
2083 }
2084
2085 bool autocvar_sv_freezenonclients;
2086 bool autocvar_sv_gameplayfix_delayprojectiles;
2087 void Physics_Frame()
2088 {
2089         if(autocvar_sv_freezenonclients)
2090                 return;
2091
2092         FOREACH_ENTITY_FLOAT(pure_data, false,
2093         {
2094                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2095                         continue;
2096
2097                 //set_movetype(it, it.move_movetype);
2098                 // inline the set_movetype function, since this is called a lot
2099                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2100
2101                 if(it.move_movetype == MOVETYPE_NONE)
2102                         continue;
2103
2104                 if(it.move_qcphysics)
2105                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2106
2107                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2108                 {
2109                         // handle thinking here
2110                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2111                                 RunThink(it);
2112                 }
2113         });
2114
2115         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2116                 return;
2117
2118         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2119         {
2120                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2121                         continue;
2122                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2123         });
2124 }
2125
2126 void systems_update();
2127 void EndFrame()
2128 {
2129         anticheat_endframe();
2130
2131         Physics_Frame();
2132
2133         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2134                 entity e = IS_SPEC(it) ? it.enemy : it;
2135                 if (e.typehitsound) {
2136                         STAT(TYPEHIT_TIME, it) = time;
2137                 } else if (e.killsound) {
2138                         STAT(KILL_TIME, it) = time;
2139                 } else if (e.damage_dealt) {
2140                         STAT(HIT_TIME, it) = time;
2141                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2142                 }
2143         });
2144         // add 1 frametime because after this, engine SV_Physics
2145         // increases time by a frametime and then networks the frame
2146         // add another frametime because client shows everything with
2147         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2148         // needed!
2149         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2150         FOREACH_CLIENT(true, {
2151                 it.typehitsound = false;
2152                 it.damage_dealt = 0;
2153                 it.killsound = false;
2154                 antilag_record(it, CS(it), altime);
2155         });
2156         IL_EACH(g_monsters, true,
2157         {
2158                 antilag_record(it, it, altime);
2159         });
2160         IL_EACH(g_projectiles, it.classname == "nade",
2161         {
2162                 antilag_record(it, it, altime);
2163         });
2164         systems_update();
2165         IL_ENDFRAME();
2166 }
2167
2168
2169 /*
2170  * RedirectionThink:
2171  * returns true if redirecting
2172  */
2173 float redirection_timeout;
2174 float redirection_nextthink;
2175 float RedirectionThink()
2176 {
2177         float clients_found;
2178
2179         if(redirection_target == "")
2180                 return false;
2181
2182         if(!redirection_timeout)
2183         {
2184                 cvar_set("sv_public", "-2");
2185                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2186                 if(redirection_target == "self")
2187                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2188                 else
2189                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2190         }
2191
2192         if(time < redirection_nextthink)
2193                 return true;
2194
2195         redirection_nextthink = time + 1;
2196
2197         clients_found = 0;
2198         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2199                 // TODO add timer
2200                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2201                 if(redirection_target == "self")
2202                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2203                 else
2204                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2205                 ++clients_found;
2206         });
2207
2208         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2209
2210         if(time > redirection_timeout || clients_found == 0)
2211                 localcmd("\nwait; wait; wait; quit\n");
2212
2213         return true;
2214 }
2215
2216 void RestoreGame()
2217 {
2218         // Loaded from a save game
2219         // some things then break, so let's work around them...
2220
2221         // Progs DB (capture records)
2222         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2223
2224         // Mapinfo
2225         MapInfo_Shutdown();
2226         MapInfo_Enumerate();
2227         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2228         WeaponStats_Init();
2229
2230         TargetMusic_RestoreGame();
2231 }
2232
2233 void Shutdown()
2234 {
2235         game_stopped = 2;
2236
2237         if(world_initialized > 0)
2238         {
2239                 world_initialized = 0;
2240                 LOG_TRACE("Saving persistent data...");
2241                 Ban_SaveBans();
2242
2243                 // playerstats with unfinished match
2244                 PlayerStats_GameReport(false);
2245
2246                 if(!cheatcount_total)
2247                 {
2248                         if(autocvar_sv_db_saveasdump)
2249                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2250                         else
2251                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2252                 }
2253                 if(autocvar_developer)
2254                 {
2255                         if(autocvar_sv_db_saveasdump)
2256                                 db_dump(TemporaryDB, "server-temp.db");
2257                         else
2258                                 db_save(TemporaryDB, "server-temp.db");
2259                 }
2260                 CheatShutdown(); // must be after cheatcount check
2261                 db_close(ServerProgsDB);
2262                 db_close(TemporaryDB);
2263                 LOG_TRACE("Saving persistent data... done!");
2264                 // tell the bot system the game is ending now
2265                 bot_endgame();
2266
2267                 WeaponStats_Shutdown();
2268                 MapInfo_Shutdown();
2269         }
2270         else if(world_initialized == 0)
2271         {
2272                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2273         }
2274         else
2275         {
2276                 __init_dedicated_server_shutdown();
2277         }
2278 }