qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void fteqcc_testbugs()
  85 {
  86         float a, b;
  87
  88         if(!autocvar_developer_fteqccbugs)
  89                 return;
  90
  91         dprint("*** fteqcc test: checking for bugs...\n");
  92
  93         a = 1;
  94         b = 5;
  95         if(sqrt(a) - sqrt(b - a) == 0)
  96                 dprint("*** fteqcc test: found same-function-twice bug\n");
  97         else
  98                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  99
 100         world.cnt = -10;
 101         world.enemy = world;
 102         world.enemy.cnt += 10;
 103         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 104                 dprint("*** fteqcc test: found += bug\n");
 105         else
 106                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 107         world.cnt = 0;
 108 }
 109
 110 void GotoFirstMap()
 111 {
 112         float n;
 113         if(autocvar__sv_init)
 114         {
 115                 // cvar_set("_sv_init", "0");
 116                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 117                 // to this "init" map on a dedicated server will cause no permanent
 118                 // harm
 119                 if(autocvar_g_maplist_shuffle)
 120                         ShuffleMaplist();
 121                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 122                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 123
 124                 MapInfo_Enumerate();
 125                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 126
 127                 if(!DoNextMapOverride(1))
 128                         GotoNextMap(1);
 129
 130                 return;
 131         }
 132
 133         if(time < 5)
 134         {
 135                 self.nextthink = time;
 136         }
 137         else
 138         {
 139                 self.nextthink = time + 1;
 140                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 141         }
 142 }
 143
 144 void cvar_changes_init()
 145 {
 146         float h;
 147         string k, v, d;
 148         float n, i, adding, pureadding;
 149
 150         if(cvar_changes)
 151                 strunzone(cvar_changes);
 152         cvar_changes = string_null;
 153         if(cvar_purechanges)
 154                 strunzone(cvar_purechanges);
 155         cvar_purechanges = string_null;
 156         cvar_purechanges_count = 0;
 157
 158         h = buf_create();
 159         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 160         n = buf_getsize(h);
 161
 162         adding = TRUE;
 163         pureadding = TRUE;
 164
 165         for(i = 0; i < n; ++i)
 166         {
 167                 k = bufstr_get(h, i);
 168
 169 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 170 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 171 #define BADCVAR(p) if(k == p) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("g_maplist_index");
 182                 BADCVAR("halflifebsp");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("log_file");
 219                 BADCVAR("net_address");
 220                 BADCVAR("net_address_ipv6");
 221                 BADCVAR("port");
 222                 BADCVAR("savedgamecfg");
 223                 BADCVAR("serverconfig");
 224                 BADCVAR("sv_autoscreenshot");
 225                 BADCVAR("sv_heartbeatperiod");
 226                 BADCVAR("sv_vote_master_password");
 227                 BADCVAR("sys_colortranslation");
 228                 BADCVAR("sys_specialcharactertranslation");
 229                 BADCVAR("timeformat");
 230                 BADCVAR("timestamps");
 231                 BADPREFIX("developer_");
 232                 BADPREFIX("g_ban_");
 233                 BADPREFIX("g_banned_list");
 234                 BADPREFIX("g_chat_flood_");
 235                 BADPREFIX("g_ghost_items");
 236                 BADPREFIX("g_playerstats_");
 237                 BADPREFIX("g_respawn_ghosts");
 238                 BADPREFIX("g_voice_flood_");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing visible
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("g_balance_kill_delay");
 306                 BADCVAR("g_ca_point_leadlimit");
 307                 BADCVAR("g_ctf_captimerecord_always");
 308                 BADCVAR("g_ctf_flag_glowtrails");
 309                 BADCVAR("g_ctf_flag_pickup_verbosename");
 310                 BADCVAR("g_domination_point_leadlimit");
 311                 BADCVAR("g_forced_respawn");
 312                 BADCVAR("g_keyhunt_point_leadlimit");
 313                 BADPREFIX("g_mod_");
 314                 BADCVAR("g_nexball_goalleadlimit");
 315                 BADCVAR("leadlimit_and_fraglimit");
 316                 BADCVAR("leadlimit_override");
 317                 BADCVAR("pausable");
 318                 BADCVAR("sv_allow_fullbright");
 319                 BADCVAR("sv_checkforpacketsduringsleep");
 320                 BADCVAR("sv_fraginfo");
 321                 BADCVAR("sv_timeout");
 322                 BADPREFIX("sv_timeout_");
 323                 BADPREFIX("crypto_");
 324                 BADPREFIX("g_chat_");
 325                 BADPREFIX("g_ctf_captimerecord_");
 326                 BADPREFIX("g_maplist_votable_");
 327                 BADPREFIX("net_");
 328                 BADPREFIX("prvm_");
 329                 BADPREFIX("skill_");
 330                 BADPREFIX("sv_cullentities_");
 331                 BADPREFIX("sv_fraginfo_");
 332                 BADPREFIX("sv_maxidle_");
 333                 BADPREFIX("sv_vote_");
 334                 BADPREFIX("timelimit_");
 335                 BADCVAR("gameversion");
 336                 BADPREFIX("gameversion_");
 337                 BADCVAR("sv_namechangetimer");
 338
 339                 // allowed changes to server admins (please sync this to server.cfg)
 340                 // vi commands:
 341                 //   :/"impure"/,$d
 342                 //   :g!,^\/\/[^ /],d
 343                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 344                 //   :%!sort
 345                 // yes, this does contain some redundant stuff, don't really care
 346                 BADCVAR("bot_config_file");
 347                 BADCVAR("bot_number");
 348                 BADCVAR("bot_prefix");
 349                 BADCVAR("bot_suffix");
 350                 BADCVAR("capturelimit_override");
 351                 BADCVAR("fraglimit_override");
 352                 BADCVAR("gametype");
 353                 BADCVAR("g_antilag");
 354                 BADCVAR("g_balance_teams");
 355                 BADCVAR("g_balance_teams_prevent_imbalance");
 356                 BADCVAR("g_balance_teams_scorefactor");
 357                 BADCVAR("g_ban_sync_trusted_servers");
 358                 BADCVAR("g_ban_sync_uri");
 359                 BADCVAR("g_ca_teams_override");
 360                 BADCVAR("g_ctf_ignore_frags");
 361                 BADCVAR("g_domination_point_limit");
 362                 BADCVAR("g_freezetag_teams_override");
 363                 BADCVAR("g_friendlyfire");
 364                 BADCVAR("g_fullbrightitems");
 365                 BADCVAR("g_fullbrightplayers");
 366                 BADCVAR("g_keyhunt_point_limit");
 367                 BADCVAR("g_keyhunt_teams_override");
 368                 BADCVAR("g_lms_lives_override");
 369                 BADCVAR("g_maplist");
 370                 BADCVAR("g_maplist_check_waypoints");
 371                 BADCVAR("g_maplist_mostrecent_count");
 372                 BADCVAR("g_maplist_shuffle");
 373                 BADCVAR("g_maplist_votable");
 374                 BADCVAR("g_maplist_votable_abstain");
 375                 BADCVAR("g_maplist_votable_nodetail");
 376                 BADCVAR("g_maplist_votable_suggestions");
 377                 BADCVAR("g_maxplayers");
 378                 BADCVAR("g_mirrordamage");
 379                 BADCVAR("g_nexball_goallimit");
 380                 BADCVAR("g_powerups");
 381                 BADCVAR("g_start_delay");
 382                 BADCVAR("g_warmup");
 383                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 384                 BADCVAR("hostname");
 385                 BADCVAR("log_file");
 386                 BADCVAR("maxplayers");
 387                 BADCVAR("minplayers");
 388                 BADCVAR("net_address");
 389                 BADCVAR("port");
 390                 BADCVAR("rcon_password");
 391                 BADCVAR("rcon_restricted_commands");
 392                 BADCVAR("rcon_restricted_password");
 393                 BADCVAR("skill");
 394                 BADCVAR("sv_adminnick");
 395                 BADCVAR("sv_autoscreenshot");
 396                 BADCVAR("sv_autotaunt");
 397                 BADCVAR("sv_curl_defaulturl");
 398                 BADCVAR("sv_defaultcharacter");
 399                 BADCVAR("sv_defaultplayercolors");
 400                 BADCVAR("sv_defaultplayermodel");
 401                 BADCVAR("sv_defaultplayerskin");
 402                 BADCVAR("sv_maxidle");
 403                 BADCVAR("sv_maxrate");
 404                 BADCVAR("sv_motd");
 405                 BADCVAR("sv_public");
 406                 BADCVAR("sv_ready_restart");
 407                 BADCVAR("sv_status_privacy");
 408                 BADCVAR("sv_taunt");
 409                 BADCVAR("sv_vote_call");
 410                 BADCVAR("sv_vote_commands");
 411                 BADCVAR("sv_vote_majority_factor");
 412                 BADCVAR("sv_vote_master");
 413                 BADCVAR("sv_vote_master_commands");
 414                 BADCVAR("sv_vote_master_password");
 415                 BADCVAR("sv_vote_simple_majority_factor");
 416                 BADCVAR("teamplay_mode");
 417                 BADCVAR("timelimit_override");
 418                 BADCVAR("g_spawnshieldtime");
 419                 BADPREFIX("g_warmup_");
 420                 BADPREFIX("sv_ready_restart_");
 421
 422                 // mutators that announce themselves properly to the server browser
 423                 BADCVAR("g_minstagib");
 424                 BADCVAR("g_new_toys");
 425                 BADCVAR("g_nix");
 426                 BADCVAR("g_grappling_hook");
 427                 BADCVAR("g_jetpack");
 428
 429 #undef BADPREFIX
 430 #undef BADCVAR
 431
 432                 if(pureadding)
 433                 {
 434                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 435                         if(strlen(cvar_purechanges) > 16384)
 436                         {
 437                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 438                                 pureadding = 0;
 439                         }
 440                 }
 441                 ++cvar_purechanges_count;
 442                 // WARNING: this variable is used for the server list
 443                 // NEVER dare to skip this code!
 444                 // Hacks to intentionally appearing as "pure server" even though you DO have
 445                 // modified settings may be punished by removal from the server list.
 446                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 447                 // though.
 448         }
 449         buf_del(h);
 450         if(cvar_changes == "")
 451                 cvar_changes = "// this server runs at default server settings\n";
 452         else
 453                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 454         cvar_changes = strzone(cvar_changes);
 455         if(cvar_purechanges == "")
 456                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 457         else
 458                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 459         cvar_purechanges = strzone(cvar_purechanges);
 460 }
 461
 462 void detect_maptype()
 463 {
 464 #if 0
 465         vector o, v;
 466         float i;
 467
 468         for(;;)
 469         {
 470                 o = world.mins;
 471                 o_x += random() * (world.maxs_x - world.mins_x);
 472                 o_y += random() * (world.maxs_y - world.mins_y);
 473                 o_z += random() * (world.maxs_z - world.mins_z);
 474
 475                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 476                 if(trace_fraction == 1)
 477                         continue;
 478
 479                 v = trace_endpos;
 480
 481                 for(i = 0; i < 64; i += 4)
 482                 {
 483                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 484         if(trace_fraction == 1)
 485                 continue;
 486                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 487                 }
 488
 489                 break;
 490         }
 491 #endif
 492 }
 493
 494 entity randomseed;
 495 float RandomSeed_Send(entity to, float sf)
 496 {
 497         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 498         WriteShort(MSG_ENTITY, self.cnt);
 499         return TRUE;
 500 }
 501 void RandomSeed_Think()
 502 {
 503         self.cnt = bound(0, floor(random() * 65536), 65535);
 504         self.nextthink = time + 5;
 505
 506         self.SendFlags |= 1;
 507 }
 508 void RandomSeed_Spawn()
 509 {
 510         randomseed = spawn();
 511         randomseed.think = RandomSeed_Think;
 512         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 513
 514         entity oldself;
 515         oldself = self;
 516         self = randomseed;
 517         self.think(); // sets random seed and nextthink
 518         self = oldself;
 519 }
 520
 521 void spawnfunc___init_dedicated_server(void)
 522 {
 523         // handler for _init/_init map (only for dedicated server initialization)
 524
 525         world_initialized = -1; // don't complain
 526         cvar = cvar_normal;
 527         cvar_string = cvar_string_normal;
 528         cvar_set = cvar_set_normal;
 529
 530         remove = remove_unsafely;
 531
 532         entity e;
 533         e = spawn();
 534         e.think = GotoFirstMap;
 535         e.nextthink = time; // this is usually 1 at this point
 536
 537         e = spawn();
 538         e.classname = "info_player_deathmatch"; // safeguard against player joining
 539
 540         self.classname = "worldspawn"; // safeguard against various stuff ;)
 541
 542         // needs to be done so early because of the constants they create
 543         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 544         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 545         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 546         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 547         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 548         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 591
 592         // needs to be done so early because of the constants they create
 593         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 594         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 595         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 596         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 597         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 599
 600         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 601
 602         TemporaryDB = db_create();
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(autocvar_g_campaign)
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 651
 652         precache_model ("null"); // we need this one before InitGameplayMode
 653         InitGameplayMode();
 654         readlevelcvars();
 655         GrappleHookInit();
 656         ElectroInit();
 657         LaserInit();
 658
 659         player_count = 0;
 660         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 661         if(bot_waypoints_for_items == 1)
 662                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 663                         bot_waypoints_for_items = 0;
 664
 665         precache();
 666
 667         WaypointSprite_Init();
 668
 669         GameLogInit(); // prepare everything
 670         // NOTE for matchid:
 671         // changing the logic generating it is okay. But:
 672         // it HAS to stay <= 64 chars
 673         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 674         if(autocvar_sv_eventlog)
 675         {
 676                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 677                 matchid = strzone(s);
 678
 679                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 680                 s = ":gameinfo:mutators:LIST";
 681
 682                 ret_string = s;
 683                 MUTATOR_CALLHOOK(BuildMutatorsString);
 684                 s = ret_string;
 685
 686                 // simple, probably not good in the mutator system
 687                 if(autocvar_g_grappling_hook)
 688                         s = strcat(s, ":grappling_hook");
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(!autocvar_g_use_ammunition)
 692                         s = strcat(s, ":no_use_ammunition");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(autocvar_g_pickup_items == 0)
 696                         s = strcat(s, ":no_pickup_items");
 697                 if(autocvar_g_pickup_items > 0)
 698                         s = strcat(s, ":pickup_items");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_weaponarena != "0")
 702                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_norecoil)
 706                         s = strcat(s, ":norecoil");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_powerups == 0)
 710                         s = strcat(s, ":no_powerups");
 711                 if(autocvar_g_powerups > 0)
 712                         s = strcat(s, ":powerups");
 713
 714                 GameLogEcho(s);
 715                 GameLogEcho(":gameinfo:end");
 716         }
 717         else
 718                 matchid = strzone(ftos(random()));
 719
 720         cvar_set("nextmap", "");
 721
 722         SetDefaultAlpha();
 723
 724         if(autocvar_g_campaign)
 725                 CampaignPostInit();
 726
 727         fteqcc_testbugs();
 728
 729         Ban_LoadBans();
 730
 731         MapInfo_Enumerate();
 732         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 733
 734         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 735         {
 736                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 737                 if(fd != -1)
 738                 {
 739                         while((s = fgets(fd)))
 740                         {
 741                                 l = tokenize_console(s);
 742                                 if(l < 2)
 743                                         continue;
 744                                 if(argv(0) == "cd")
 745                                 {
 746                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 747                                         print("  cdtrack ", argv(2), "\n");
 748                                 }
 749                                 else if(argv(0) == "fog")
 750                                 {
 751                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 752                                         print("  \"fog\" \"", s, "\"\n");
 753                                 }
 754                                 else if(argv(0) == "set")
 755                                 {
 756                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 757                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 758                                 }
 759                                 else if(argv(0) != "//")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 763                                 }
 764                         }
 765                         fclose(fd);
 766                 }
 767         }
 768
 769         WeaponStats_Init();
 770
 771         WepSet_AddStat();
 772         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 773         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 774         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 775         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 776         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 777         Nagger_Init();
 778
 779         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 780         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 781         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 782         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 783         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 784         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 785         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 786         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 787         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 788         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 789         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 790         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 791         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 792
 793         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 794         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 795
 796         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 797
 798         // g_movementspeed hack
 799         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 800         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 801         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 802         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 803
 804         // secrets
 805         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 806         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 807
 808         // monsters
 809         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 810         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 811
 812         // misc
 813         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 814
 815         next_pingtime = time + 5;
 816
 817         detect_maptype();
 818
 819         // set up information replies for clients and server to use
 820         maplist_reply = strzone(getmaplist());
 821         lsmaps_reply = strzone(getlsmaps());
 822         monsterlist_reply = strzone(getmonsterlist());
 823         for(i = 0; i < 10; ++i)
 824         {
 825                 s = getrecords(i);
 826                 if (s)
 827                         records_reply[i] = strzone(s);
 828         }
 829         ladder_reply = strzone(getladder());
 830         rankings_reply = strzone(getrankings());
 831
 832         // begin other init
 833         ClientInit_Spawn();
 834         RandomSeed_Spawn();
 835         PingPLReport_Spawn();
 836
 837         CheatInit();
 838
 839         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 840
 841         // fill sv_curl_serverpackages from .serverpackage files
 842         if(autocvar_sv_curl_serverpackages_auto)
 843         {
 844                 s = "";
 845                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 846                 for(i = 0; i < n; ++i)
 847                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 848                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 849                                 s = strcat(s, " ", argv(i));
 850                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 851                 if(fd >= 0)
 852                 {
 853                         j = search_getsize(fd);
 854                         for(i = 0; i < j; ++i)
 855                                 s = strcat(s, " ", search_getfilename(fd, i));
 856                         search_end(fd);
 857                 }
 858                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 859                 if(fd >= 0)
 860                 {
 861                         j = search_getsize(fd);
 862                         for(i = 0; i < j; ++i)
 863                                 s = strcat(s, " ", search_getfilename(fd, i));
 864                         search_end(fd);
 865                 }
 866                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 867         }
 868
 869         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 870         modname = "Xonotic";
 871         // physics/balance/config changes that count as mod
 872         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 873                 modname = cvar_string("g_mod_physics");
 874         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 875                 modname = cvar_string("g_mod_balance");
 876         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 877                 modname = cvar_string("g_mod_config");
 878         // extra mutators that deserve to count as mod
 879         MUTATOR_CALLHOOK(SetModname);
 880
 881         // save it for later
 882         modname = strzone(modname);
 883
 884         WinningConditionHelper(); // set worldstatus
 885
 886         world_initialized = 1;
 887 }
 888
 889 void spawnfunc_light (void)
 890 {
 891         //makestatic (self); // Who the f___ did that?
 892         remove(self);
 893 }
 894
 895 string GetGametype()
 896 {
 897         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 898 }
 899
 900 string GetMapname()
 901 {
 902         return mapname;
 903 }
 904
 905 float Map_Count, Map_Current;
 906 string Map_Current_Name;
 907
 908 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 909 float GetMaplistPosition()
 910 {
 911         float pos, idx;
 912         string map;
 913
 914         map = GetMapname();
 915         idx = autocvar_g_maplist_index;
 916
 917         if(idx >= 0)
 918                 if(idx < Map_Count)
 919                         if(map == argv(idx))
 920                                 return idx;
 921
 922         for(pos = 0; pos < Map_Count; ++pos)
 923                 if(map == argv(pos))
 924                         return pos;
 925
 926         // resume normal maplist rotation if current map is not in g_maplist
 927         return idx;
 928 }
 929
 930 float MapHasRightSize(string map)
 931 {
 932         float fh;
 933         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 934         if(autocvar_g_maplist_check_waypoints)
 935         {
 936                 dprint("checkwp "); dprint(map);
 937                 if(!fexists(strcat("maps/", map, ".waypoints")))
 938                 {
 939                         dprint(": no waypoints\n");
 940                         return FALSE;
 941                 }
 942                 dprint(": has waypoints\n");
 943         }
 944
 945         // open map size restriction file
 946         dprint("opensize "); dprint(map);
 947         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 948         if(fh >= 0)
 949         {
 950                 float mapmin, mapmax;
 951                 dprint(": ok, ");
 952                 mapmin = stof(fgets(fh));
 953                 mapmax = stof(fgets(fh));
 954                 fclose(fh);
 955                 if(player_count < mapmin)
 956                 {
 957                         dprint("not enough\n");
 958                         return FALSE;
 959                 }
 960                 if(player_count > mapmax)
 961                 {
 962                         dprint("too many\n");
 963                         return FALSE;
 964                 }
 965                 dprint("right size\n");
 966                 return TRUE;
 967         }
 968         dprint(": not found\n");
 969         return TRUE;
 970 }
 971
 972 string Map_Filename(float position)
 973 {
 974         return strcat("maps/", argv(position), ".bsp");
 975 }
 976
 977 string strwords(string s, float w)
 978 {
 979         float endpos;
 980         for(endpos = 0; w && endpos >= 0; --w)
 981                 endpos = strstrofs(s, " ", endpos + 1);
 982         if(endpos < 0)
 983                 return s;
 984         else
 985                 return substring(s, 0, endpos);
 986 }
 987
 988 float strhasword(string s, string w)
 989 {
 990         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 991 }
 992
 993 void Map_MarkAsRecent(string m)
 994 {
 995         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 996 }
 997
 998 float Map_IsRecent(string m)
 999 {
1000         return strhasword(autocvar_g_maplist_mostrecent, m);
1001 }
1002
1003 float Map_Check(float position, float pass)
1004 {
1005         string filename;
1006         string map_next;
1007         map_next = argv(position);
1008         if(pass <= 1)
1009         {
1010                 if(Map_IsRecent(map_next))
1011                         return 0;
1012         }
1013         filename = Map_Filename(position);
1014         if(MapInfo_CheckMap(map_next))
1015         {
1016                 if(pass == 2)
1017                         return 1;
1018                 if(MapHasRightSize(map_next))
1019                         return 1;
1020                 return 0;
1021         }
1022         else
1023                 dprint( "Couldn't select '", filename, "'..\n" );
1024
1025         return 0;
1026 }
1027
1028 void Map_Goto_SetStr(string nextmapname)
1029 {
1030         if(getmapname_stored != "")
1031                 strunzone(getmapname_stored);
1032         if(nextmapname == "")
1033                 getmapname_stored = "";
1034         else
1035                 getmapname_stored = strzone(nextmapname);
1036 }
1037
1038 void Map_Goto_SetFloat(float position)
1039 {
1040         cvar_set("g_maplist_index", ftos(position));
1041         Map_Goto_SetStr(argv(position));
1042 }
1043
1044 void Map_Goto(float reinit)
1045 {
1046         MapInfo_LoadMap(getmapname_stored, reinit);
1047 }
1048
1049 // return codes of map selectors:
1050 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1051 //   -2 = permanent failure
1052 float() MaplistMethod_Iterate = // usual method
1053 {
1054         float pass, i;
1055
1056         dprint("Trying MaplistMethod_Iterate\n");
1057
1058         for(pass = 1; pass <= 2; ++pass)
1059         {
1060                 for(i = 1; i < Map_Count; ++i)
1061                 {
1062                         float mapindex;
1063                         mapindex = mod(i + Map_Current, Map_Count);
1064                         if(Map_Check(mapindex, pass))
1065                                 return mapindex;
1066                 }
1067         }
1068         return -1;
1069 }
1070
1071 float() MaplistMethod_Repeat = // fallback method
1072 {
1073         dprint("Trying MaplistMethod_Repeat\n");
1074
1075         if(Map_Check(Map_Current, 2))
1076                 return Map_Current;
1077         return -2;
1078 }
1079
1080 float() MaplistMethod_Random = // random map selection
1081 {
1082         float i, imax;
1083
1084         dprint("Trying MaplistMethod_Random\n");
1085
1086         imax = 42;
1087
1088         for(i = 0; i <= imax; ++i)
1089         {
1090                 float mapindex;
1091                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1092                 if(Map_Check(mapindex, 1))
1093                         return mapindex;
1094         }
1095         return -1;
1096 }
1097
1098 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1099 // the exponent sets a bias on the map selection:
1100 // the higher the exponent, the less likely "shortly repeated" same maps are
1101 {
1102         float i, j, imax, insertpos;
1103
1104         dprint("Trying MaplistMethod_Shuffle\n");
1105
1106         imax = 42;
1107
1108         for(i = 0; i <= imax; ++i)
1109         {
1110                 string newlist;
1111
1112                 // now reinsert this at another position
1113                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1114                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1115                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1116                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1117
1118                 // insert the current map there
1119                 newlist = "";
1120                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1121                         newlist = strcat(newlist, " ", argv(j));
1122                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1123                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1124                         newlist = strcat(newlist, " ", argv(j));
1125                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1126                 cvar_set("g_maplist", newlist);
1127                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1128
1129                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1130                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1131                 if(Map_Check(Map_Current, 1))
1132                         return Map_Current;
1133         }
1134         return -1;
1135 }
1136
1137 void Maplist_Init()
1138 {
1139         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1140         float i;
1141         for (i = 0; i < Map_Count; ++i)
1142                 if (Map_Check(i, 2))
1143                         break;
1144         if (i == Map_Count)
1145         {
1146                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1147                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1148                 if(autocvar_g_maplist_shuffle)
1149                         ShuffleMaplist();
1150                 localcmd("\nmenu_cmd sync\n");
1151                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1152         }
1153         if(Map_Count == 0)
1154                 error("empty maplist, cannot select a new map");
1155         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1156
1157         if(Map_Current_Name)
1158                 strunzone(Map_Current_Name);
1159         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1160         // this may or may not be correct, but who cares, in the worst case a map
1161         // isn't chosen in the first pass that should have been
1162 }
1163
1164 string GetNextMap()
1165 {
1166         float nextMap;
1167
1168         Maplist_Init();
1169         nextMap = -1;
1170
1171         if(nextMap == -1)
1172                 if(autocvar_g_maplist_shuffle > 0)
1173                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1174
1175         if(nextMap == -1)
1176                 if(autocvar_g_maplist_selectrandom)
1177                         nextMap = MaplistMethod_Random();
1178
1179         if(nextMap == -1)
1180                 nextMap = MaplistMethod_Iterate();
1181
1182         if(nextMap == -1)
1183                 nextMap = MaplistMethod_Repeat();
1184
1185         if(nextMap >= 0)
1186         {
1187                 Map_Goto_SetFloat(nextMap);
1188                 return getmapname_stored;
1189         }
1190
1191         return "";
1192 }
1193
1194 float DoNextMapOverride(float reinit)
1195 {
1196         if(autocvar_g_campaign)
1197         {
1198                 CampaignPostIntermission();
1199                 alreadychangedlevel = TRUE;
1200                 return TRUE;
1201         }
1202         if(autocvar_quit_when_empty)
1203         {
1204                 if(player_count <= currentbots)
1205                 {
1206                         localcmd("quit\n");
1207                         alreadychangedlevel = TRUE;
1208                         return TRUE;
1209                 }
1210         }
1211         if(autocvar_quit_and_redirect != "")
1212         {
1213                 redirection_target = strzone(autocvar_quit_and_redirect);
1214                 alreadychangedlevel = TRUE;
1215                 return TRUE;
1216         }
1217         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1218         {
1219                 localcmd("restart\n");
1220                 alreadychangedlevel = TRUE;
1221                 return TRUE;
1222         }
1223         if(autocvar_nextmap != "")
1224         {
1225                 string m;
1226                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1227                 cvar_set("nextmap",m);
1228
1229                 if(!m || gametypevote)
1230                         return FALSE;
1231                 if(autocvar_sv_vote_gametype)
1232                 {
1233                         Map_Goto_SetStr(m);
1234                         return FALSE;
1235                 }
1236
1237                 if(MapInfo_CheckMap(m))
1238                 {
1239                         Map_Goto_SetStr(m);
1240                         Map_Goto(reinit);
1241                         alreadychangedlevel = TRUE;
1242                         return TRUE;
1243                 }
1244         }
1245         if(!reinit && autocvar_lastlevel)
1246         {
1247                 cvar_settemp_restore();
1248                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1249                 alreadychangedlevel = TRUE;
1250                 return TRUE;
1251         }
1252         return FALSE;
1253 }
1254
1255 void GotoNextMap(float reinit)
1256 {
1257         //string nextmap;
1258         //float n, nummaps;
1259         //string s;
1260         if (alreadychangedlevel)
1261                 return;
1262         alreadychangedlevel = TRUE;
1263
1264         string nextMap;
1265
1266         nextMap = GetNextMap();
1267         if(nextMap == "")
1268                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1269         Map_Goto(reinit);
1270 }
1271
1272
1273 /*
1274 ============
1275 IntermissionThink
1276
1277 When the player presses attack or jump, change to the next level
1278 ============
1279 */
1280 .float autoscreenshot;
1281 void IntermissionThink()
1282 {
1283         FixIntermissionClient(self);
1284
1285         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1286         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1287
1288         if( (server_screenshot || client_screenshot)
1289                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1290         {
1291                 self.autoscreenshot = -1;
1292                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1293                 return;
1294         }
1295
1296         if (time < intermission_exittime)
1297                 return;
1298
1299         if(!mapvote_initialized)
1300                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1301                         return;
1302
1303         MapVote_Start();
1304 }
1305
1306 /*
1307 ============
1308 FindIntermission
1309
1310 Returns the entity to view from
1311 ============
1312 */
1313 /*
1314 entity FindIntermission()
1315 {
1316         local   entity spot;
1317         local   float cyc;
1318
1319 // look for info_intermission first
1320         spot = find (world, classname, "info_intermission");
1321         if (spot)
1322         {       // pick a random one
1323                 cyc = random() * 4;
1324                 while (cyc > 1)
1325                 {
1326                         spot = find (spot, classname, "info_intermission");
1327                         if (!spot)
1328                                 spot = find (spot, classname, "info_intermission");
1329                         cyc = cyc - 1;
1330                 }
1331                 return spot;
1332         }
1333
1334 // then look for the start position
1335         spot = find (world, classname, "info_player_start");
1336         if (spot)
1337                 return spot;
1338
1339 // testinfo_player_start is only found in regioned levels
1340         spot = find (world, classname, "testplayerstart");
1341         if (spot)
1342                 return spot;
1343
1344 // then look for the start position
1345         spot = find (world, classname, "info_player_deathmatch");
1346         if (spot)
1347                 return spot;
1348
1349         //objerror ("FindIntermission: no spot");
1350         return world;
1351 }
1352 */
1353
1354 /*
1355 ===============================================================================
1356
1357 RULES
1358
1359 ===============================================================================
1360 */
1361
1362 void DumpStats(float final)
1363 {
1364         float file;
1365         string s;
1366         float to_console;
1367         float to_eventlog;
1368         float to_file;
1369         float i;
1370
1371         to_console = autocvar_sv_logscores_console;
1372         to_eventlog = autocvar_sv_eventlog;
1373         to_file = autocvar_sv_logscores_file;
1374
1375         if(!final)
1376         {
1377                 to_console = TRUE; // always print printstats replies
1378                 to_eventlog = FALSE; // but never print them to the event log
1379         }
1380
1381         if(to_eventlog)
1382                 if(autocvar_sv_eventlog_console)
1383                         to_console = FALSE; // otherwise we get the output twice
1384
1385         if(final)
1386                 s = ":scores:";
1387         else
1388                 s = ":status:";
1389         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1390
1391         if(to_console)
1392                 print(s, "\n");
1393         if(to_eventlog)
1394                 GameLogEcho(s);
1395
1396         file = -1;
1397         if(to_file)
1398         {
1399                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1400                 if(file == -1)
1401                         to_file = FALSE;
1402                 else
1403                         fputs(file, strcat(s, "\n"));
1404         }
1405
1406         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1407         if(to_console)
1408                 print(s, "\n");
1409         if(to_eventlog)
1410                 GameLogEcho(s);
1411         if(to_file)
1412                 fputs(file, strcat(s, "\n"));
1413
1414         FOR_EACH_CLIENT(other)
1415         {
1416                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1417                 {
1418                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1419                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1420                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1421                                 s = strcat(s, ftos(other.team), ":");
1422                         else
1423                                 s = strcat(s, "spectator:");
1424
1425                         if(to_console)
1426                                 print(s, other.netname, "\n");
1427                         if(to_eventlog)
1428                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1429                         if(to_file)
1430                                 fputs(file, strcat(s, other.netname, "\n"));
1431                 }
1432         }
1433
1434         if(teamplay)
1435         {
1436                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1437                 if(to_console)
1438                         print(s, "\n");
1439                 if(to_eventlog)
1440                         GameLogEcho(s);
1441                 if(to_file)
1442                         fputs(file, strcat(s, "\n"));
1443
1444                 for(i = 1; i < 16; ++i)
1445                 {
1446                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1447                         s = strcat(s, ":", ftos(i));
1448                         if(to_console)
1449                                 print(s, "\n");
1450                         if(to_eventlog)
1451                                 GameLogEcho(s);
1452                         if(to_file)
1453                                 fputs(file, strcat(s, "\n"));
1454                 }
1455         }
1456
1457         if(to_console)
1458                 print(":end\n");
1459         if(to_eventlog)
1460                 GameLogEcho(":end");
1461         if(to_file)
1462         {
1463                 fputs(file, ":end\n");
1464                 fclose(file);
1465         }
1466 }
1467
1468 void FixIntermissionClient(entity e)
1469 {
1470         string s;
1471         if(!e.autoscreenshot) // initial call
1472         {
1473                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1474                 e.health = -2342;
1475                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1476                 e.solid = SOLID_NOT;
1477                 e.movetype = MOVETYPE_NONE;
1478                 e.takedamage = DAMAGE_NO;
1479                 if(e.weaponentity)
1480                 {
1481                         e.weaponentity.effects = EF_NODRAW;
1482                         if (e.weaponentity.weaponentity)
1483                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1484                 }
1485                 if(IS_REAL_CLIENT(e))
1486                 {
1487                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1488                         s = autocvar_sv_intermission_cdtrack;
1489                         if(s != "")
1490                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1491                         msg_entity = e;
1492                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1493                 }
1494         }
1495 }
1496
1497 /*
1498 go to the next level for deathmatch
1499 only called if a time or frag limit has expired
1500 */
1501 void NextLevel()
1502 {
1503         gameover = TRUE;
1504
1505         intermission_running = 1;
1506
1507 // enforce a wait time before allowing changelevel
1508         if(player_count > 0)
1509                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1510         else
1511                 intermission_exittime = -1;
1512
1513         /*
1514         WriteByte (MSG_ALL, SVC_CDTRACK);
1515         WriteByte (MSG_ALL, 3);
1516         WriteByte (MSG_ALL, 3);
1517         // done in FixIntermission
1518         */
1519
1520         //pos = FindIntermission ();
1521
1522         VoteReset();
1523
1524         DumpStats(TRUE);
1525
1526         // send statistics
1527         entity e;
1528         PlayerStats_EndMatch(1);
1529         FOR_EACH_CLIENT(e)
1530                 PlayerStats_AddGlobalInfo(e);
1531         PlayerStats_Shutdown();
1532         WeaponStats_Shutdown();
1533
1534         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1535
1536         if(autocvar_sv_eventlog)
1537                 GameLogEcho(":gameover");
1538
1539         GameLogClose();
1540
1541         FOR_EACH_PLAYER(other) {
1542                 FixIntermissionClient(other);
1543                 if(other.winning)
1544                         bprint(other.netname, " ^7wins.\n");
1545         }
1546
1547         if(autocvar_g_campaign)
1548                 CampaignPreIntermission();
1549
1550         MUTATOR_CALLHOOK(MatchEnd);
1551
1552         localcmd("\nsv_hook_gameend\n");
1553 }
1554
1555 /*
1556 ============
1557 CheckRules_Player
1558
1559 Exit deathmatch games upon conditions
1560 ============
1561 */
1562 void CheckRules_Player()
1563 {
1564         if (gameover)   // someone else quit the game already
1565                 return;
1566
1567         if(self.deadflag == DEAD_NO)
1568                 self.play_time += frametime;
1569
1570         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1571         //   (div0: and that in CheckRules_World please)
1572 }
1573
1574 float checkrules_equality;
1575 float checkrules_suddendeathwarning;
1576 float checkrules_suddendeathend;
1577 float checkrules_overtimesadded; //how many overtimes have been already added
1578
1579 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1580 const float WINNING_YES = 1; // winner found
1581 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1582 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1583
1584 float InitiateSuddenDeath()
1585 {
1586         // Check first whether normal overtimes could be added before initiating suddendeath mode
1587         // - for this timelimit_overtime needs to be >0 of course
1588         // - also check the winning condition calculated in the previous frame and only add normal overtime
1589         //   again, if at the point at which timelimit would be extended again, still no winner was found
1590         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1591         {
1592                 return 1; // need to call InitiateOvertime later
1593         }
1594         else
1595         {
1596                 if(!checkrules_suddendeathend)
1597                 {
1598                         if(autocvar_g_campaign)
1599                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1600                         else
1601                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1602                         if(g_race && !g_race_qualifying)
1603                                 race_StartCompleting();
1604                 }
1605                 return 0;
1606         }
1607 }
1608
1609 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1610 {
1611         ++checkrules_overtimesadded;
1612         //add one more overtime by simply extending the timelimit
1613         float tl;
1614         tl = autocvar_timelimit;
1615         tl += autocvar_timelimit_overtime;
1616         cvar_set("timelimit", ftos(tl));
1617
1618         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1619 }
1620
1621 float GetWinningCode(float fraglimitreached, float equality)
1622 {
1623         if(autocvar_g_campaign == 1)
1624                 if(fraglimitreached)
1625                         return WINNING_YES;
1626                 else
1627                         return WINNING_NO;
1628
1629         else
1630                 if(equality)
1631                         if(fraglimitreached)
1632                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1633                         else
1634                                 return WINNING_NEVER;
1635                 else
1636                         if(fraglimitreached)
1637                                 return WINNING_YES;
1638                         else
1639                                 return WINNING_NO;
1640 }
1641
1642 // set the .winning flag for exactly those players with a given field value
1643 void SetWinners(.float field, float value)
1644 {
1645         entity head;
1646         FOR_EACH_PLAYER(head)
1647                 head.winning = (head.field == value);
1648 }
1649
1650 // set the .winning flag for those players with a given field value
1651 void AddWinners(.float field, float value)
1652 {
1653         entity head;
1654         FOR_EACH_PLAYER(head)
1655                 if(head.field == value)
1656                         head.winning = 1;
1657 }
1658
1659 // clear the .winning flags
1660 void ClearWinners(void)
1661 {
1662         entity head;
1663         FOR_EACH_PLAYER(head)
1664                 head.winning = 0;
1665 }
1666
1667 // Onslaught winning condition:
1668 // game terminates if only one team has a working generator (or none)
1669 float WinningCondition_Onslaught()
1670 {
1671         entity head;
1672         float t1, t2, t3, t4;
1673
1674         WinningConditionHelper(); // set worldstatus
1675
1676         if(warmup_stage)
1677                 return WINNING_NO;
1678
1679         // first check if the game has ended
1680         t1 = t2 = t3 = t4 = 0;
1681         head = find(world, classname, "onslaught_generator");
1682         while (head)
1683         {
1684                 if (head.health > 0)
1685                 {
1686                         if (head.team == NUM_TEAM_1) t1 = 1;
1687                         if (head.team == NUM_TEAM_2) t2 = 1;
1688                         if (head.team == NUM_TEAM_3) t3 = 1;
1689                         if (head.team == NUM_TEAM_4) t4 = 1;
1690                 }
1691                 head = find(head, classname, "onslaught_generator");
1692         }
1693         if (t1 + t2 + t3 + t4 < 2)
1694         {
1695                 // game over, only one team remains (or none)
1696                 ClearWinners();
1697                 if (t1) SetWinners(team, NUM_TEAM_1);
1698                 if (t2) SetWinners(team, NUM_TEAM_2);
1699                 if (t3) SetWinners(team, NUM_TEAM_3);
1700                 if (t4) SetWinners(team, NUM_TEAM_4);
1701                 dprint("Have a winner, ending game.\n");
1702                 return WINNING_YES;
1703         }
1704
1705         // Two or more teams remain
1706         return WINNING_NO;
1707 }
1708
1709 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1710 // they win. Otherwise the defending team wins once the timelimit passes.
1711 void assault_new_round();
1712 float WinningCondition_Assault()
1713 {
1714         float status;
1715
1716         WinningConditionHelper(); // set worldstatus
1717
1718         status = WINNING_NO;
1719         // as the timelimit has not yet passed just assume the defending team will win
1720         if(assault_attacker_team == NUM_TEAM_1)
1721         {
1722                 SetWinners(team, NUM_TEAM_2);
1723         }
1724         else
1725         {
1726                 SetWinners(team, NUM_TEAM_1);
1727         }
1728
1729         entity ent;
1730         ent = find(world, classname, "target_assault_roundend");
1731         if(ent)
1732         {
1733                 if(ent.winning) // round end has been triggered by attacking team
1734                 {
1735                         bprint("ASSAULT: round completed...\n");
1736                         SetWinners(team, assault_attacker_team);
1737
1738                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1739
1740                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1741                         {
1742                                 status = WINNING_YES;
1743                         }
1744                         else
1745                         {
1746                                 entity oldself;
1747                                 oldself = self;
1748                                 self = ent;
1749                                 assault_new_round();
1750                                 self = oldself;
1751                         }
1752                 }
1753         }
1754
1755         return status;
1756 }
1757
1758 // LMS winning condition: game terminates if and only if there's at most one
1759 // one player who's living lives. Top two scores being equal cancels the time
1760 // limit.
1761 float WinningCondition_LMS()
1762 {
1763         entity head, head2;
1764         float have_player;
1765         float have_players;
1766         float l;
1767
1768         have_player = FALSE;
1769         have_players = FALSE;
1770         l = LMS_NewPlayerLives();
1771
1772         head = find(world, classname, "player");
1773         if(head)
1774                 have_player = TRUE;
1775         head2 = find(head, classname, "player");
1776         if(head2)
1777                 have_players = TRUE;
1778
1779         if(have_player)
1780         {
1781                 // we have at least one player
1782                 if(have_players)
1783                 {
1784                         // two or more active players - continue with the game
1785                 }
1786                 else
1787                 {
1788                         // exactly one player?
1789
1790                         ClearWinners();
1791                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1792
1793                         if(l)
1794                         {
1795                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1796                                 return WINNING_NO;
1797                         }
1798                         else
1799                         {
1800                                 // a winner!
1801                                 // and assign him his first place
1802                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1803                                 return WINNING_YES;
1804                         }
1805                 }
1806         }
1807         else
1808         {
1809                 // nobody is playing at all...
1810                 if(l)
1811                 {
1812                         // wait for players...
1813                 }
1814                 else
1815                 {
1816                         // SNAFU (maybe a draw game?)
1817                         ClearWinners();
1818                         dprint("No players, ending game.\n");
1819                         return WINNING_YES;
1820                 }
1821         }
1822
1823         // When we get here, we have at least two players who are actually LIVING,
1824         // now check if the top two players have equal score.
1825         WinningConditionHelper();
1826
1827         ClearWinners();
1828         if(WinningConditionHelper_winner)
1829                 WinningConditionHelper_winner.winning = TRUE;
1830         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1831                 return WINNING_NEVER;
1832
1833         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1834         return WINNING_NO;
1835 }
1836
1837 void ShuffleMaplist()
1838 {
1839         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1840 }
1841
1842 float leaderfrags;
1843 float WinningCondition_Scores(float limit, float leadlimit)
1844 {
1845         float limitreached;
1846
1847         // TODO make everything use THIS winning condition (except LMS)
1848         WinningConditionHelper();
1849
1850         if(teamplay)
1851         {
1852                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1853                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1854                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1855                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1856         }
1857
1858         ClearWinners();
1859         if(WinningConditionHelper_winner)
1860                 WinningConditionHelper_winner.winning = 1;
1861         if(WinningConditionHelper_winnerteam >= 0)
1862                 SetWinners(team, WinningConditionHelper_winnerteam);
1863
1864         if(WinningConditionHelper_lowerisbetter)
1865         {
1866                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1867                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1868                 limit = -limit;
1869         }
1870
1871         if(WinningConditionHelper_zeroisworst)
1872                 leadlimit = 0; // not supported in this mode
1873
1874         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1875         // these modes always score in increments of 1, thus this makes sense
1876         {
1877                 if(leaderfrags != WinningConditionHelper_topscore)
1878                 {
1879                         leaderfrags = WinningConditionHelper_topscore;
1880
1881                         if (limit)
1882                         if (leaderfrags == limit - 1)
1883                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1884                         else if (leaderfrags == limit - 2)
1885                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1886                         else if (leaderfrags == limit - 3)
1887                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1888                 }
1889         }
1890
1891         limitreached = FALSE;
1892         if(limit)
1893                 if(WinningConditionHelper_topscore >= limit)
1894                         limitreached = TRUE;
1895         if(leadlimit)
1896         {
1897                 float leadlimitreached;
1898                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1899                 if(autocvar_leadlimit_and_fraglimit)
1900                         limitreached = (limitreached && leadlimitreached);
1901                 else
1902                         limitreached = (limitreached || leadlimitreached);
1903         }
1904
1905         if(limit)
1906                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1907
1908         return GetWinningCode(
1909                 WinningConditionHelper_topscore && limitreached,
1910                 WinningConditionHelper_equality
1911         );
1912 }
1913
1914 float WinningCondition_Race(float fraglimit)
1915 {
1916         float wc;
1917         entity p;
1918         float n, c;
1919
1920         n = 0;
1921         c = 0;
1922         FOR_EACH_PLAYER(p)
1923         {
1924                 ++n;
1925                 if(p.race_completed)
1926                         ++c;
1927         }
1928         if(n && (n == c))
1929                 return WINNING_YES;
1930         wc = WinningCondition_Scores(fraglimit, 0);
1931
1932         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1933         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1934         // do NOT support equality when the laps are all raced!
1935                 return WINNING_STARTSUDDENDEATHOVERTIME;
1936         else
1937                 return WINNING_NEVER;
1938 }
1939
1940 float WinningCondition_QualifyingThenRace(float limit)
1941 {
1942         float wc;
1943         wc = WinningCondition_Scores(limit, 0);
1944
1945         // NEVER initiate overtime
1946         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1947         {
1948                 return WINNING_YES;
1949         }
1950
1951         return wc;
1952 }
1953
1954 float WinningCondition_RanOutOfSpawns()
1955 {
1956         entity head;
1957
1958         if(have_team_spawns <= 0)
1959                 return WINNING_NO;
1960
1961         if(autocvar_g_spawn_useallspawns <= 0)
1962                 return WINNING_NO;
1963
1964         if(!some_spawn_has_been_used)
1965                 return WINNING_NO;
1966
1967         team1_score = team2_score = team3_score = team4_score = 0;
1968
1969         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1970         {
1971                 if(head.team == NUM_TEAM_1)
1972                         team1_score = 1;
1973                 else if(head.team == NUM_TEAM_2)
1974                         team2_score = 1;
1975                 else if(head.team == NUM_TEAM_3)
1976                         team3_score = 1;
1977                 else if(head.team == NUM_TEAM_4)
1978                         team4_score = 1;
1979         }
1980
1981         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1982         {
1983                 if(head.team == NUM_TEAM_1)
1984                         team1_score = 1;
1985                 else if(head.team == NUM_TEAM_2)
1986                         team2_score = 1;
1987                 else if(head.team == NUM_TEAM_3)
1988                         team3_score = 1;
1989                 else if(head.team == NUM_TEAM_4)
1990                         team4_score = 1;
1991         }
1992
1993         ClearWinners();
1994         if(team1_score + team2_score + team3_score + team4_score == 0)
1995         {
1996                 checkrules_equality = TRUE;
1997                 return WINNING_YES;
1998         }
1999         else if(team1_score + team2_score + team3_score + team4_score == 1)
2000         {
2001                 float t, i;
2002                 if(team1_score)
2003                         t = NUM_TEAM_1;
2004                 else if(team2_score)
2005                         t = NUM_TEAM_2;
2006                 else if(team3_score)
2007                         t = NUM_TEAM_3;
2008                 else // if(team4_score)
2009                         t = NUM_TEAM_4;
2010                 CheckAllowedTeams(world);
2011                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2012                 {
2013                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2014                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2015                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2016                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2017                 }
2018
2019                 AddWinners(team, t);
2020                 return WINNING_YES;
2021         }
2022         else
2023                 return WINNING_NO;
2024 }
2025
2026 /*
2027 ============
2028 CheckRules_World
2029
2030 Exit deathmatch games upon conditions
2031 ============
2032 */
2033 void ReadyRestart();
2034 void CheckRules_World()
2035 {
2036         float timelimit;
2037         float fraglimit;
2038         float leadlimit;
2039
2040         VoteThink();
2041         MapVote_Think();
2042
2043         SetDefaultAlpha();
2044
2045         if (gameover)   // someone else quit the game already
2046         {
2047                 if(player_count == 0) // Nobody there? Then let's go to the next map
2048                         MapVote_Start();
2049                         // this will actually check the player count in the next frame
2050                         // again, but this shouldn't hurt
2051                 return;
2052         }
2053
2054         timelimit = autocvar_timelimit * 60;
2055         fraglimit = autocvar_fraglimit;
2056         leadlimit = autocvar_leadlimit;
2057
2058         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2059         {
2060                 if(timelimit > 0)
2061                         timelimit = 0; // timelimit is not made for warmup
2062                 if(fraglimit > 0)
2063                         fraglimit = 0; // no fraglimit for now
2064                 leadlimit = 0; // no leadlimit for now
2065         }
2066
2067         if(timelimit > 0)
2068         {
2069                 timelimit += game_starttime;
2070         }
2071         else if (timelimit < 0)
2072         {
2073                 // endmatch
2074                 NextLevel();
2075                 return;
2076         }
2077
2078         if(g_onslaught)
2079                 timelimit = 0; // ONS has its own overtime rule
2080
2081         float wantovertime;
2082         wantovertime = 0;
2083
2084         if(timelimit > game_starttime)
2085                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2086         else
2087                 game_completion_ratio = 0;
2088
2089         if(checkrules_suddendeathend)
2090         {
2091                 if(!checkrules_suddendeathwarning)
2092                 {
2093                         checkrules_suddendeathwarning = TRUE;
2094                         if(g_race && !g_race_qualifying)
2095                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2096                         else
2097                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2098                 }
2099         }
2100         else
2101         {
2102                 if (timelimit && time >= timelimit)
2103                 {
2104                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2105                         {
2106                                 float totalplayers;
2107                                 float playerswithlaps;
2108                                 float readyplayers;
2109                                 entity head;
2110                                 totalplayers = playerswithlaps = readyplayers = 0;
2111                                 FOR_EACH_PLAYER(head)
2112                                 {
2113                                         ++totalplayers;
2114                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2115                                                 ++playerswithlaps;
2116                                         if(head.ready)
2117                                                 ++readyplayers;
2118                                 }
2119
2120                                 // at least 2 of the players have completed a lap: start the RACE
2121                                 // otherwise, the players should end the qualifying on their own
2122                                 if(readyplayers || playerswithlaps >= 2)
2123                                 {
2124                                         checkrules_suddendeathend = 0;
2125                                         ReadyRestart(); // go to race
2126                                         return;
2127                                 }
2128                                 else
2129                                         wantovertime |= InitiateSuddenDeath();
2130                         }
2131                         else
2132                                 wantovertime |= InitiateSuddenDeath();
2133                 }
2134         }
2135
2136         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2137         {
2138                 NextLevel();
2139                 return;
2140         }
2141
2142         float checkrules_status;
2143         checkrules_status = WinningCondition_RanOutOfSpawns();
2144         if(checkrules_status == WINNING_YES)
2145         {
2146                 bprint("Hey! Someone ran out of spawns!\n");
2147         }
2148         else if(g_race && !g_race_qualifying && timelimit >= 0)
2149         {
2150                 checkrules_status = WinningCondition_Race(fraglimit);
2151                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2152         }
2153         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2154         {
2155                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2156                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2157         }
2158         else if(g_assault)
2159         {
2160                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2161         }
2162         else if(g_lms)
2163         {
2164                 checkrules_status = WinningCondition_LMS();
2165         }
2166         else if (g_onslaught)
2167         {
2168                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2169         }
2170         else
2171         {
2172                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2173                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2174         }
2175
2176         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2177         {
2178                 checkrules_status = WINNING_NEVER;
2179                 checkrules_overtimesadded = -1;
2180                 wantovertime |= InitiateSuddenDeath();
2181         }
2182
2183         if(checkrules_status == WINNING_NEVER)
2184                 // equality cases! Nobody wins if the overtime ends in a draw.
2185                 ClearWinners();
2186
2187         if(wantovertime)
2188         {
2189                 if(checkrules_status == WINNING_NEVER)
2190                         InitiateOvertime();
2191                 else
2192                         checkrules_status = WINNING_YES;
2193         }
2194
2195         if(checkrules_suddendeathend)
2196                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2197                         checkrules_status = WINNING_YES;
2198
2199         if(checkrules_status == WINNING_YES)
2200         {
2201                 //print("WINNING\n");
2202                 NextLevel();
2203         }
2204 }
2205
2206 string GotoMap(string m)
2207 {
2208         m = GameTypeVote_MapInfo_FixName(m);
2209         if (!m)
2210                 return "The map you suggested is not available on this server.";
2211         if (!autocvar_sv_vote_gametype)
2212         if(!MapInfo_CheckMap(m))
2213                 return "The map you suggested does not support the current game mode.";
2214         cvar_set("nextmap", m);
2215         cvar_set("timelimit", "-1");
2216         if(mapvote_initialized || alreadychangedlevel)
2217         {
2218                 if(DoNextMapOverride(0))
2219                         return "Map switch initiated.";
2220                 else
2221                         return "Hm... no. For some reason I like THIS map more.";
2222         }
2223         else
2224                 return "Map switch will happen after scoreboard.";
2225 }
2226
2227
2228 void EndFrame()
2229 {
2230         anticheat_endframe();
2231
2232         float altime;
2233         FOR_EACH_REALCLIENT(self)
2234         {
2235                 if(IS_SPEC(self))
2236                 {
2237                         if(self.enemy.typehitsound)
2238                                 self.typehit_time = time;
2239                         else if(self.enemy.hitsound)
2240                                 self.hit_time = time;
2241                 }
2242                 else
2243                 {
2244                         if(self.typehitsound)
2245                                 self.typehit_time = time;
2246                         else if(self.hitsound)
2247                                 self.hit_time = time;
2248                 }
2249         }
2250         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2251         // add 1 frametime because after this, engine SV_Physics
2252         // increases time by a frametime and then networks the frame
2253         // add another frametime because client shows everything with
2254         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2255         // needed!
2256         FOR_EACH_CLIENT(self)
2257         {
2258                 self.hitsound = FALSE;
2259                 self.typehitsound = FALSE;
2260                 antilag_record(self, altime);
2261         }
2262 }
2263
2264
2265 /*
2266  * RedirectionThink:
2267  * returns TRUE if redirecting
2268  */
2269 float redirection_timeout;
2270 float redirection_nextthink;
2271 float RedirectionThink()
2272 {
2273         float clients_found;
2274
2275         if(redirection_target == "")
2276                 return FALSE;
2277
2278         if(!redirection_timeout)
2279         {
2280                 cvar_set("sv_public", "-2");
2281                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2282                 if(redirection_target == "self")
2283                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2284                 else
2285                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2286         }
2287
2288         if(time < redirection_nextthink)
2289                 return TRUE;
2290
2291         redirection_nextthink = time + 1;
2292
2293         clients_found = 0;
2294         FOR_EACH_REALCLIENT(self)
2295         {
2296                 // TODO add timer
2297                 print("Redirecting: sending connect command to ", self.netname, "\n");
2298                 if(redirection_target == "self")
2299                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2300                 else
2301                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2302                 ++clients_found;
2303         }
2304
2305         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2306
2307         if(time > redirection_timeout || clients_found == 0)
2308                 localcmd("\nwait; wait; wait; quit\n");
2309
2310         return TRUE;
2311 }
2312
2313 void TargetMusic_RestoreGame();
2314 void RestoreGame()
2315 {
2316         // Loaded from a save game
2317         // some things then break, so let's work around them...
2318
2319         // Progs DB (capture records)
2320         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2321
2322         // Mapinfo
2323         MapInfo_Shutdown();
2324         MapInfo_Enumerate();
2325         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2326         WeaponStats_Init();
2327
2328         TargetMusic_RestoreGame();
2329 }
2330
2331 void Shutdown()
2332 {
2333         entity e;
2334
2335         gameover = 2;
2336
2337         if(world_initialized > 0)
2338         {
2339                 world_initialized = 0;
2340                 print("Saving persistent data...\n");
2341                 Ban_SaveBans();
2342
2343                 PlayerStats_EndMatch(0);
2344                 FOR_EACH_CLIENT(e)
2345                         PlayerStats_AddGlobalInfo(e);
2346                 PlayerStats_Shutdown();
2347
2348                 if(!cheatcount_total)
2349                 {
2350                         if(autocvar_sv_db_saveasdump)
2351                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2352                         else
2353                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2354                 }
2355                 if(autocvar_developer)
2356                 {
2357                         if(autocvar_sv_db_saveasdump)
2358                                 db_dump(TemporaryDB, "server-temp.db");
2359                         else
2360                                 db_save(TemporaryDB, "server-temp.db");
2361                 }
2362                 CheatShutdown(); // must be after cheatcount check
2363                 db_close(ServerProgsDB);
2364                 db_close(TemporaryDB);
2365                 print("done!\n");
2366                 // tell the bot system the game is ending now
2367                 bot_endgame();
2368
2369                 WeaponStats_Shutdown();
2370                 MapInfo_Shutdown();
2371         }
2372         else if(world_initialized == 0)
2373         {
2374                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2375         }
2376 }