qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("developer");
 276                 BADCVAR("g_banned_list");
 277                 BADCVAR("log_dest_udp");
 278                 BADCVAR("log_file");
 279                 BADCVAR("net_address");
 280                 BADCVAR("net_address_ipv6");
 281                 BADCVAR("port");
 282                 BADCVAR("savedgamecfg");
 283                 BADCVAR("serverconfig");
 284                 BADCVAR("sv_heartbeatperiod");
 285                 BADCVAR("sv_vote_master_password");
 286                 BADCVAR("sys_colortranslation");
 287                 BADCVAR("sys_specialcharactertranslation");
 288                 BADCVAR("timestamps");
 289                 BADPREFIX("developer_");
 290                 BADPREFIX("g_ban_");
 291                 BADPREFIX("g_chat_flood_");
 292                 BADPREFIX("g_voice_flood_");
 293                 BADPREFIX("rcon_");
 294                 BADPREFIX("settemp_");
 295                 BADPREFIX("sv_allowdownloads_");
 296                 BADPREFIX("sv_autodemo");
 297                 BADPREFIX("sv_curl_");
 298                 BADPREFIX("sv_eventlog");
 299                 BADPREFIX("sv_logscores_");
 300                 BADPREFIX("sv_master");
 301                 BADPREFIX("sv_weaponstats_");
 302
 303                 // these can contain player IDs, so better hide
 304                 BADCVAR("g_forced_team_red");
 305                 BADCVAR("g_forced_team_blue");
 306                 BADCVAR("g_forced_team_yellow");
 307                 BADCVAR("g_forced_team_pink");
 308
 309                 // mapinfo
 310                 BADCVAR("timelimit");
 311                 BADCVAR("fraglimit");
 312                 BADCVAR("leadlimit");
 313                 BADCVAR("g_tdm_teams");
 314                 BADCVAR("g_keyhunt_teams");
 315                 BADCVAR("g_domination_default_teams");
 316                 BADCVAR("g_race_qualifying_timelimit");
 317                 BADCVAR("g_lms");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_ca");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_dm");
 323                 BADCVAR("g_domination");
 324                 BADCVAR("g_keyhunt");
 325                 BADCVAR("g_keyhunt_teams");
 326                 BADCVAR("g_onslaught");
 327                 BADCVAR("g_race");
 328                 BADCVAR("g_cts");
 329                 BADCVAR("g_runematch");
 330                 BADCVAR("g_tdm");
 331                 BADCVAR("g_nexball");
 332                 BADCVAR("teamplay");
 333
 334                 // long
 335                 BADCVAR("hostname");
 336                 BADCVAR("g_maplist");
 337                 BADCVAR("g_maplist_mostrecent");
 338                 BADCVAR("sv_motd");
 339
 340                 v = cvar_string(k);
 341                 d = cvar_defstring(k);
 342                 if(v == d)
 343                         continue;
 344
 345                 if(adding)
 346                 {
 347                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 348                         if(strlen(cvar_changes) > 16384)
 349                         {
 350                                 cvar_changes = "// too many settings have been changed to show them here\n";
 351                                 adding = 0;
 352                         }
 353                 }
 354
 355                 // now check if the changes are actually gameplay relevant
 356
 357                 // does nothing visible
 358                 BADCVAR("captureleadlimit_override");
 359                 BADCVAR("g_arena_point_leadlimit");
 360                 BADCVAR("g_ca_point_leadlimit");
 361                 BADCVAR("g_ctf_capture_leadlimit");
 362                 BADCVAR("g_domination_point_leadlimit");
 363                 BADCVAR("g_keyhunt_point_leadlimit");
 364                 BADCVAR("g_nexball_goalleadlimit");
 365                 BADCVAR("g_runematch_point_leadlimit");
 366                 BADCVAR("leadlimit_and_fraglimit");
 367                 BADCVAR("leadlimit_override");
 368                 BADCVAR("sv_checkforpacketsduringsleep");
 369                 BADPREFIX("crypto_");
 370                 BADPREFIX("g_chat_");
 371                 BADPREFIX("net_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("sv_fragmessage_");
 374                 BADPREFIX("sv_vote_");
 375                 BADPREFIX("timelimit_");
 376
 377                 // allowed changes to server admins (please sync this to server.cfg)
 378                 // vi commands:
 379                 //   :/"impure"/,$d
 380                 //   :g!,^\/\/[^ /],d
 381                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 382                 //   :%!sort
 383                 // yes, this does contain some redundant stuff, don't really care
 384                 BADCVAR("bot_number");
 385                 BADCVAR("bot_prefix");
 386                 BADCVAR("bot_suffix");
 387                 BADCVAR("capturelimit_override");
 388                 BADCVAR("fraglimit_override");
 389                 BADCVAR("gametype");
 390                 BADCVAR("g_antilag");
 391                 BADCVAR("g_balance_teams");
 392                 BADCVAR("g_balance_teams_force");
 393                 BADCVAR("g_ban_sync_trusted_servers");
 394                 BADCVAR("g_ban_sync_uri");
 395                 BADCVAR("g_ctf_capture_limit");
 396                 BADCVAR("g_ctf_ignore_frags");
 397                 BADCVAR("g_ctf_win_mode");
 398                 BADCVAR("g_domination_point_limit");
 399                 BADCVAR("g_fullbrightitems");
 400                 BADCVAR("g_fullbrightplayers");
 401                 BADCVAR("g_keyhunt_point_limit");
 402                 BADCVAR("g_keyhunt_teams_override");
 403                 BADCVAR("g_lms_lives_override");
 404                 BADCVAR("g_maplist");
 405                 BADCVAR("g_maplist_check_waypoints");
 406                 BADCVAR("g_maplist_mostrecent_count");
 407                 BADCVAR("g_maplist_shuffle");
 408                 BADCVAR("g_maplist_votable");
 409                 BADCVAR("g_maplist_votable_abstain");
 410                 BADCVAR("g_maplist_votable_nodetail");
 411                 BADCVAR("g_maplist_votable_suggestions");
 412                 BADCVAR("g_minstagib");
 413                 BADCVAR("g_nexball_goallimit");
 414                 BADCVAR("g_runematch_point_limit");
 415                 BADCVAR("g_start_delay");
 416                 BADCVAR("hostname");
 417                 BADCVAR("log_file");
 418                 BADCVAR("maxplayers");
 419                 BADCVAR("minplayers");
 420                 BADCVAR("net_address");
 421                 BADCVAR("port");
 422                 BADCVAR("rcon_password");
 423                 BADCVAR("rcon_restricted_commands");
 424                 BADCVAR("rcon_restricted_password");
 425                 BADCVAR("skill");
 426                 BADCVAR("sv_adminnick");
 427                 BADCVAR("sv_autoscreenshot");
 428                 BADCVAR("sv_curl_defaulturl");
 429                 BADCVAR("sv_defaultcharacter");
 430                 BADCVAR("sv_defaultplayermodel");
 431                 BADCVAR("sv_defaultplayerskin");
 432                 BADCVAR("sv_maxidle");
 433                 BADCVAR("sv_maxrate");
 434                 BADCVAR("sv_motd");
 435                 BADCVAR("sv_public");
 436                 BADCVAR("sv_ready_restart");
 437                 BADCVAR("sv_status_privacy");
 438                 BADCVAR("sv_vote_call");
 439                 BADCVAR("sv_vote_commands");
 440                 BADCVAR("sv_vote_majority_factor");
 441                 BADCVAR("sv_vote_master");
 442                 BADCVAR("sv_vote_master_commands");
 443                 BADCVAR("sv_vote_master_password");
 444                 BADCVAR("sv_vote_simple_majority_factor");
 445                 BADCVAR("timelimit_override");
 446
 447                 if(cvar("g_minstagib"))
 448                 {
 449                         BADCVAR("g_grappling_hook");
 450                         BADCVAR("g_jetpack");
 451                 }
 452 #undef BADPREFIX
 453 #undef BADCVAR
 454
 455                 if(pureadding)
 456                 {
 457                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 458                         if(strlen(cvar_purechanges) > 16384)
 459                         {
 460                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 461                                 pureadding = 0;
 462                         }
 463                 }
 464                 ++cvar_purechanges_count;
 465                 // WARNING: this variable is used for the server list
 466                 // NEVER dare to skip this code!
 467                 // Hacks to intentionally appearing as "pure server" even though you DO have
 468                 // modified settings may be punished by removal from the server list.
 469                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 470                 // though.
 471         }
 472         buf_del(h);
 473         if(cvar_changes == "")
 474                 cvar_changes = "// this server runs at default server settings\n";
 475         else
 476                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 477         cvar_changes = strzone(cvar_changes);
 478         if(cvar_purechanges == "")
 479                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 480         else
 481                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 482         cvar_purechanges = strzone(cvar_purechanges);
 483 }
 484
 485 void detect_maptype()
 486 {
 487 #if 0
 488         vector o, v;
 489         float i;
 490
 491         for(;;)
 492         {
 493                 o = world.mins;
 494                 o_x += random() * (world.maxs_x - world.mins_x);
 495                 o_y += random() * (world.maxs_y - world.mins_y);
 496                 o_z += random() * (world.maxs_z - world.mins_z);
 497
 498                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 499                 if(trace_fraction == 1)
 500                         continue;
 501
 502                 v = trace_endpos;
 503
 504                 for(i = 0; i < 64; i += 4)
 505                 {
 506                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 507         if(trace_fraction == 1)
 508                 continue;
 509                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 510                 }
 511
 512                 break;
 513         }
 514 #endif
 515 }
 516
 517 entity randomseed;
 518 float RandomSeed_Send(entity to, float sf)
 519 {
 520         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 521         WriteShort(MSG_ENTITY, self.cnt);
 522         return TRUE;
 523 }
 524 void RandomSeed_Think()
 525 {
 526         self.cnt = bound(0, floor(random() * 65536), 65535);
 527         self.nextthink = time + 5;
 528
 529         self.SendFlags |= 1;
 530 }
 531 void RandomSeed_Spawn()
 532 {
 533         randomseed = spawn();
 534         randomseed.think = RandomSeed_Think;
 535         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 536
 537         entity oldself;
 538         oldself = self;
 539         self = randomseed;
 540         self.think(); // sets random seed and nextthink
 541         self = oldself;
 542 }
 543
 544 void spawnfunc___init_dedicated_server(void)
 545 {
 546         // handler for _init/_init map (only for dedicated server initialization)
 547
 548         world_initialized = -1; // don't complain
 549         cvar = cvar_normal;
 550         cvar_string = cvar_string_normal;
 551         cvar_set = cvar_set_normal;
 552
 553         remove = remove_unsafely;
 554
 555         entity e;
 556         e = spawn();
 557         e.think = GotoFirstMap;
 558         e.nextthink = time; // this is usually 1 at this point
 559
 560         e = spawn();
 561         e.classname = "info_player_deathmatch"; // safeguard against player joining
 562
 563         self.classname = "worldspawn"; // safeguard against various stuff ;)
 564
 565         MapInfo_Enumerate();
 566         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 567 }
 568
 569 void Map_MarkAsRecent(string m);
 570 float world_already_spawned;
 571 void RegisterWeapons();
 572 void Nagger_Init();
 573 void ClientInit_Spawn();
 574 void WeaponStats_Init();
 575 void WeaponStats_Shutdown();
 576 void spawnfunc_worldspawn (void)
 577 {
 578         float fd, l, i, j, n;
 579         string s, col;
 580
 581         cvar = cvar_normal;
 582         cvar_string = cvar_string_normal;
 583         cvar_set = cvar_set_normal;
 584
 585         if(world_already_spawned)
 586                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 587         world_already_spawned = TRUE;
 588
 589         remove = remove_safely; // during spawning, watch what you remove!
 590
 591         check_unacceptable_compiler_bugs();
 592
 593         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 594
 595         compressShortVector_init();
 596
 597         allowed_to_spawn = TRUE;
 598
 599         local entity head;
 600         head = nextent(world);
 601         maxclients = 0;
 602         while(head)
 603         {
 604                 ++maxclients;
 605                 head = nextent(head);
 606         }
 607
 608         // needs to be done so early as they would still spawn
 609         RegisterWeapons();
 610
 611         ServerProgsDB = db_load("server.db");
 612
 613         TemporaryDB = db_create();
 614
 615         /*
 616         TODO sound pack system
 617         // initialize sound pack system
 618         soundpack = cvar_string("g_soundpack");
 619         if(soundpack != "")
 620                 soundpack = strcat(soundpack, "/");
 621         soundpack = strzone(soundpack);
 622         */
 623
 624         // 0 normal
 625         lightstyle(0, "m");
 626
 627         // 1 FLICKER (first variety)
 628         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 629
 630         // 2 SLOW STRONG PULSE
 631         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 632
 633         // 3 CANDLE (first variety)
 634         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 635
 636         // 4 FAST STROBE
 637         lightstyle(4, "mamamamamama");
 638
 639         // 5 GENTLE PULSE 1
 640         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 641
 642         // 6 FLICKER (second variety)
 643         lightstyle(6, "nmonqnmomnmomomno");
 644
 645         // 7 CANDLE (second variety)
 646         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 647
 648         // 8 CANDLE (third variety)
 649         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 650
 651         // 9 SLOW STROBE (fourth variety)
 652         lightstyle(9, "aaaaaaaazzzzzzzz");
 653
 654         // 10 FLUORESCENT FLICKER
 655         lightstyle(10, "mmamammmmammamamaaamammma");
 656
 657         // 11 SLOW PULSE NOT FADE TO BLACK
 658         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 659
 660         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 661
 662         // 63 testing
 663         lightstyle(63, "a");
 664
 665         if(cvar("g_campaign"))
 666                 CampaignPreInit();
 667
 668         Map_MarkAsRecent(mapname);
 669
 670         precache_model ("null"); // we need this one before InitGameplayMode
 671         InitGameplayMode();
 672         readlevelcvars();
 673         GrappleHookInit();
 674         ElectroInit();
 675         LaserInit();
 676
 677         player_count = 0;
 678         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 679         if(bot_waypoints_for_items == 1)
 680                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 681                         bot_waypoints_for_items = 0;
 682
 683         // for setting by mapinfo
 684         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 685         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 686
 687         precache();
 688
 689         WaypointSprite_Init();
 690
 691         //if (g_domination)
 692         //      dom_init();
 693
 694         GameLogInit(); // prepare everything
 695         if(cvar("sv_eventlog"))
 696         {
 697                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 698                 s = strcat(s, ftos(random()));
 699                 matchid = strzone(s);
 700
 701                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 702                 s = ":gameinfo:mutators:LIST";
 703
 704                 ret_string = s;
 705                 MUTATOR_CALLHOOK(BuildMutatorsString);
 706                 s = ret_string;
 707
 708                 // simple, probably not good in the mutator system
 709                 if(cvar("g_grappling_hook"))
 710                         s = strcat(s, ":grappling_hook");
 711
 712                 // initialiation stuff, not good in the mutator system
 713                 if(!cvar("g_use_ammunition"))
 714                         s = strcat(s, ":no_use_ammunition");
 715
 716                 // initialiation stuff, not good in the mutator system
 717                 if(!cvar("g_pickup_items"))
 718                         s = strcat(s, ":no_pickup_items");
 719
 720                 // initialiation stuff, not good in the mutator system
 721                 if(cvar_string("g_weaponarena") != "0")
 722                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 723
 724                 // TODO to mutator system
 725                 if(cvar("g_norecoil"))
 726                         s = strcat(s, ":norecoil");
 727
 728                 // TODO to mutator system
 729                 if(cvar("g_midair"))
 730                         s = strcat(s, ":midair");
 731
 732                 // TODO to mutator system
 733                 if(cvar("g_minstagib"))
 734                         s = strcat(s, ":minstagib");
 735
 736                 GameLogEcho(s);
 737                 GameLogEcho(":gameinfo:end");
 738         }
 739         else
 740                 matchid = strzone(ftos(random()));
 741
 742         cvar_set("nextmap", "");
 743
 744         SetDefaultAlpha();
 745
 746         if(cvar("g_campaign"))
 747                 CampaignPostInit();
 748
 749         fteqcc_testbugs();
 750
 751         Ban_LoadBans();
 752
 753         MapInfo_Enumerate();
 754         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 755
 756         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 757         {
 758                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 759                 if(fd != -1)
 760                 {
 761                         while((s = fgets(fd)))
 762                         {
 763                                 l = tokenize_console(s);
 764                                 if(l < 2)
 765                                         continue;
 766                                 if(argv(0) == "cd")
 767                                 {
 768                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 769                                         print("  cdtrack ", argv(2), "\n");
 770                                 }
 771                                 else if(argv(0) == "fog")
 772                                 {
 773                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 774                                         print("  \"fog\" \"", s, "\"\n");
 775                                 }
 776                                 else if(argv(0) == "set")
 777                                 {
 778                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 779                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 780                                 }
 781                                 else if(argv(0) != "//")
 782                                 {
 783                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 784                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 785                                 }
 786                         }
 787                         fclose(fd);
 788                 }
 789         }
 790
 791         WeaponStats_Init();
 792
 793         addstat(STAT_WEAPONS, AS_INT, weapons);
 794         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 795         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 796         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 797         Nagger_Init();
 798
 799         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 800         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 801         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 802         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 803         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 804         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 805         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 806         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 807         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 808         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 809
 810         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 811         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_charge_pool_ammo);
 812
 813         if(g_ca)
 814         {
 815                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 816                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 817         }
 818         // g_movementspeed hack
 819         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 820         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 821         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 822         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 823
 824         next_pingtime = time + 5;
 825
 826         detect_maptype();
 827
 828         lsmaps_reply = "^7Maps available: ";
 829         lsnewmaps_reply = "^7Maps without a record set: ";
 830         for(i = 0, j = 0; i < MapInfo_count; ++i)
 831         {
 832                 if(MapInfo_Get_ByID(i))
 833                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 834                         {
 835                                 if(mod(i, 2))
 836                                         col = "^2";
 837                                 else
 838                                         col = "^3";
 839                                 ++j;
 840                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 841                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 842                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 843                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 844                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 845                         }
 846         }
 847         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 848         if (!g_race && !g_cts)
 849                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 850         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 851
 852         maplist_reply = "^7Maps in list: ";
 853         n = tokenize_console(cvar_string("g_maplist"));
 854         for(i = 0, j = 0; i < n; ++i)
 855         {
 856                 if(MapInfo_CheckMap(argv(i)))
 857                 {
 858                         if(mod(j, 2))
 859                                 col = "^2";
 860                         else
 861                                 col = "^3";
 862                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 863                         ++j;
 864                 }
 865         }
 866         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 867         MapInfo_ClearTemps();
 868
 869         for(i = 0; i < 10; ++i)
 870         {
 871                 records_reply[i] = strzone(getrecords(i));
 872         }
 873         if(g_cts)
 874                 ladder_reply = strzone(getladder());
 875
 876         rankings_reply = strzone(getrankings());
 877
 878         ClientInit_Spawn();
 879         RandomSeed_Spawn();
 880         PingPLReport_Spawn();
 881
 882         CheatInit();
 883
 884         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 885
 886         // fill sv_curl_serverpackages from .serverpackage files
 887         if(cvar("sv_curl_serverpackages_auto"))
 888         {
 889                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 890                 s = "";
 891                 if(fd >= 0)
 892                 {
 893                         j = search_getsize(fd);
 894                         for(i = 0; i < j; ++i)
 895                                 s = strcat(s, " ", search_getfilename(fd, i));
 896                         search_end(fd);
 897                 }
 898                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 899         }
 900
 901         world_initialized = 1;
 902 }
 903
 904 void spawnfunc_light (void)
 905 {
 906         //makestatic (self); // Who the f___ did that?
 907         remove(self);
 908 }
 909
 910 float TryFile( string pFilename )
 911 {
 912         local float lHandle;
 913         dprint("TryFile(\"", pFilename, "\")\n");
 914         lHandle = fopen( pFilename, FILE_READ );
 915         if( lHandle != -1 ) {
 916                 fclose( lHandle );
 917                 return TRUE;
 918         } else {
 919                 return FALSE;
 920         }
 921 };
 922
 923 string GetGametype()
 924 {
 925         return GametypeNameFromType(game);
 926 }
 927
 928 string getmapname_stored;
 929 string GetMapname()
 930 {
 931         return mapname;
 932 }
 933
 934 float Map_Count, Map_Current;
 935 string Map_Current_Name;
 936
 937 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 938 float GetMaplistPosition()
 939 {
 940         float pos, idx;
 941         string map;
 942
 943         map = GetMapname();
 944         idx = cvar("g_maplist_index");
 945
 946         if(idx >= 0)
 947                 if(idx < Map_Count)
 948                         if(map == argv(idx))
 949                                 return idx;
 950
 951         for(pos = 0; pos < Map_Count; ++pos)
 952                 if(map == argv(pos))
 953                         return pos;
 954
 955         // resume normal maplist rotation if current map is not in g_maplist
 956         return idx;
 957 }
 958
 959 float MapHasRightSize(string map)
 960 {
 961         float fh;
 962         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 963         if(cvar("g_maplist_check_waypoints"))
 964         {
 965                 dprint("checkwp "); dprint(map);
 966                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 967                 if(fh < 0)
 968                 {
 969                         dprint(": no waypoints\n");
 970                         return FALSE;
 971                 }
 972                 dprint(": has waypoints\n");
 973                 fclose(fh);
 974         }
 975
 976         // open map size restriction file
 977         dprint("opensize "); dprint(map);
 978         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 979         if(fh >= 0)
 980         {
 981                 float mapmin, mapmax;
 982                 dprint(": ok, ");
 983                 mapmin = stof(fgets(fh));
 984                 mapmax = stof(fgets(fh));
 985                 fclose(fh);
 986                 if(player_count < mapmin)
 987                 {
 988                         dprint("not enough\n");
 989                         return FALSE;
 990                 }
 991                 if(player_count > mapmax)
 992                 {
 993                         dprint("too many\n");
 994                         return FALSE;
 995                 }
 996                 dprint("right size\n");
 997                 return TRUE;
 998         }
 999         dprint(": not found\n");
1000         return TRUE;
1001 }
1002
1003 string Map_Filename(float position)
1004 {
1005         return strcat("maps/", argv(position), ".bsp");
1006 }
1007
1008 string strwords(string s, float w)
1009 {
1010         float endpos;
1011         for(endpos = 0; w && endpos >= 0; --w)
1012                 endpos = strstrofs(s, " ", endpos + 1);
1013         if(endpos < 0)
1014                 return s;
1015         else
1016                 return substring(s, 0, endpos);
1017 }
1018
1019 float strhasword(string s, string w)
1020 {
1021         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1022 }
1023
1024 void Map_MarkAsRecent(string m)
1025 {
1026         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1027 }
1028
1029 float Map_IsRecent(string m)
1030 {
1031         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1032 }
1033
1034 float Map_Check(float position, float pass)
1035 {
1036         string filename;
1037         string map_next;
1038         map_next = argv(position);
1039         if(pass <= 1)
1040         {
1041                 if(Map_IsRecent(map_next))
1042                         return 0;
1043         }
1044         filename = Map_Filename(position);
1045         if(MapInfo_CheckMap(map_next))
1046         {
1047                 if(pass == 2)
1048                         return 1;
1049                 if(MapHasRightSize(map_next))
1050                         return 1;
1051                 return 0;
1052         }
1053         else
1054                 dprint( "Couldn't select '", filename, "'..\n" );
1055
1056         return 0;
1057 }
1058
1059 void Map_Goto_SetStr(string nextmapname)
1060 {
1061         if(getmapname_stored != "")
1062                 strunzone(getmapname_stored);
1063         if(nextmapname == "")
1064                 getmapname_stored = "";
1065         else
1066                 getmapname_stored = strzone(nextmapname);
1067 }
1068
1069 void Map_Goto_SetFloat(float position)
1070 {
1071         cvar_set("g_maplist_index", ftos(position));
1072         Map_Goto_SetStr(argv(position));
1073 }
1074
1075 void GameResetCfg()
1076 {
1077         // settings persist, except...
1078         localcmd("\nsettemp_restore\n");
1079 };
1080
1081 void Map_Goto()
1082 {
1083         GameResetCfg();
1084         MapInfo_LoadMap(getmapname_stored);
1085 }
1086
1087 // return codes of map selectors:
1088 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1089 //   -2 = permanent failure
1090 float() MaplistMethod_Iterate = // usual method
1091 {
1092         float pass, i;
1093
1094         for(pass = 1; pass <= 2; ++pass)
1095         {
1096                 for(i = 1; i < Map_Count; ++i)
1097                 {
1098                         float mapindex;
1099                         mapindex = mod(i + Map_Current, Map_Count);
1100                         if(Map_Check(mapindex, pass))
1101                                 return mapindex;
1102                 }
1103         }
1104         return -1;
1105 }
1106
1107 float() MaplistMethod_Repeat = // fallback method
1108 {
1109         if(Map_Check(Map_Current, 2))
1110                 return Map_Current;
1111         return -2;
1112 }
1113
1114 float() MaplistMethod_Random = // random map selection
1115 {
1116         float i, imax;
1117
1118         imax = 42;
1119
1120         for(i = 0; i <= imax; ++i)
1121         {
1122                 float mapindex;
1123                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1124                 if(Map_Check(mapindex, 1))
1125                         return mapindex;
1126         }
1127         return -1;
1128 }
1129
1130 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1131 // the exponent sets a bias on the map selection:
1132 // the higher the exponent, the less likely "shortly repeated" same maps are
1133 {
1134         float i, j, imax, insertpos;
1135
1136         imax = 42;
1137
1138         for(i = 0; i <= imax; ++i)
1139         {
1140                 string newlist;
1141
1142                 // now reinsert this at another position
1143                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1144                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1145                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1146                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1147
1148                 // insert the current map there
1149                 newlist = "";
1150                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1151                         newlist = strcat(newlist, " ", argv(j));
1152                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1153                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1154                         newlist = strcat(newlist, " ", argv(j));
1155                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1156                 cvar_set("g_maplist", newlist);
1157                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1158
1159                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1160                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1161                 if(Map_Check(Map_Current, 1))
1162                         return Map_Current;
1163         }
1164         return -1;
1165 }
1166
1167 void Maplist_Init()
1168 {
1169         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1170         if(Map_Count == 0)
1171         {
1172                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1173                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1174                 if(cvar("g_maplist_shuffle"))
1175                         ShuffleMaplist();
1176                 localcmd("\nmenu_cmd sync\n");
1177                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1178         }
1179         if(Map_Count == 0)
1180                 error("empty maplist, cannot select a new map");
1181         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1182
1183         if(Map_Current_Name)
1184                 strunzone(Map_Current_Name);
1185         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1186         // this may or may not be correct, but who cares, in the worst case a map
1187         // isn't chosen in the first pass that should have been
1188 }
1189
1190 string GetNextMap()
1191 {
1192         float nextMap;
1193
1194         Maplist_Init();
1195         nextMap = -1;
1196
1197         if(nextMap == -1)
1198                 if(cvar("g_maplist_shuffle") > 0)
1199                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1200
1201         if(nextMap == -1)
1202                 if(cvar("g_maplist_selectrandom"))
1203                         nextMap = MaplistMethod_Random();
1204
1205         if(nextMap == -1)
1206                 nextMap = MaplistMethod_Iterate();
1207
1208         if(nextMap == -1)
1209                 nextMap = MaplistMethod_Repeat();
1210
1211         if(nextMap >= 0)
1212         {
1213                 Map_Goto_SetFloat(nextMap);
1214                 return getmapname_stored;
1215         }
1216
1217         return "";
1218 };
1219
1220 float DoNextMapOverride()
1221 {
1222         if(cvar("g_campaign"))
1223         {
1224                 CampaignPostIntermission();
1225                 alreadychangedlevel = TRUE;
1226                 return TRUE;
1227         }
1228         if(cvar("quit_when_empty"))
1229         {
1230                 if(player_count <= currentbots)
1231                 {
1232                         localcmd("quit\n");
1233                         alreadychangedlevel = TRUE;
1234                         return TRUE;
1235                 }
1236         }
1237         if(cvar_string("quit_and_redirect") != "")
1238         {
1239                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1240                 alreadychangedlevel = TRUE;
1241                 return TRUE;
1242         }
1243         if (cvar("samelevel")) // if samelevel is set, stay on same level
1244         {
1245                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1246                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1247                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1248                 localcmd("restart\n");
1249                 //changelevel (mapname);
1250                 alreadychangedlevel = TRUE;
1251                 return TRUE;
1252         }
1253         if(cvar_string("nextmap") != "")
1254                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1255                 {
1256                         Map_Goto_SetStr(cvar_string("nextmap"));
1257                         Map_Goto();
1258                         alreadychangedlevel = TRUE;
1259                         return TRUE;
1260                 }
1261         if(cvar("lastlevel"))
1262         {
1263                 GameResetCfg();
1264                 localcmd("set lastlevel 0\ntogglemenu\n");
1265                 alreadychangedlevel = TRUE;
1266                 return TRUE;
1267         }
1268         return FALSE;
1269 };
1270
1271 void GotoNextMap()
1272 {
1273         //local string nextmap;
1274         //local float n, nummaps;
1275         //local string s;
1276         if (alreadychangedlevel)
1277                 return;
1278         alreadychangedlevel = TRUE;
1279
1280         {
1281                 string nextMap;
1282                 float allowReset;
1283
1284                 for(allowReset = 1; allowReset >= 0; --allowReset)
1285                 {
1286                         nextMap = GetNextMap();
1287                         if(nextMap != "")
1288                                 break;
1289
1290                         if(allowReset)
1291                         {
1292                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1293                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1294                                 if(cvar("g_maplist_shuffle"))
1295                                         ShuffleMaplist();
1296                                 localcmd("\nmenu_cmd sync\n");
1297                         }
1298                         else
1299                         {
1300                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1301                         }
1302                 }
1303                 Map_Goto();
1304         }
1305 };
1306
1307
1308 /*
1309 ============
1310 IntermissionThink
1311
1312 When the player presses attack or jump, change to the next level
1313 ============
1314 */
1315 .float autoscreenshot;
1316 void() MapVote_Start;
1317 void() MapVote_Think;
1318 float mapvote_initialized;
1319 void IntermissionThink()
1320 {
1321         FixIntermissionClient(self);
1322
1323         if(cvar("sv_autoscreenshot"))
1324         if(self.autoscreenshot > 0)
1325         if(time > self.autoscreenshot)
1326         {
1327                 self.autoscreenshot = -1;
1328                 if(clienttype(self) == CLIENTTYPE_REAL)
1329                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1330                 return;
1331         }
1332
1333         if (time < intermission_exittime)
1334                 return;
1335
1336         if(!mapvote_initialized)
1337                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1338                         return;
1339
1340         MapVote_Start();
1341 };
1342
1343 /*
1344 ============
1345 FindIntermission
1346
1347 Returns the entity to view from
1348 ============
1349 */
1350 /*
1351 entity FindIntermission()
1352 {
1353         local   entity spot;
1354         local   float cyc;
1355
1356 // look for info_intermission first
1357         spot = find (world, classname, "info_intermission");
1358         if (spot)
1359         {       // pick a random one
1360                 cyc = random() * 4;
1361                 while (cyc > 1)
1362                 {
1363                         spot = find (spot, classname, "info_intermission");
1364                         if (!spot)
1365                                 spot = find (spot, classname, "info_intermission");
1366                         cyc = cyc - 1;
1367                 }
1368                 return spot;
1369         }
1370
1371 // then look for the start position
1372         spot = find (world, classname, "info_player_start");
1373         if (spot)
1374                 return spot;
1375
1376 // testinfo_player_start is only found in regioned levels
1377         spot = find (world, classname, "testplayerstart");
1378         if (spot)
1379                 return spot;
1380
1381 // then look for the start position
1382         spot = find (world, classname, "info_player_deathmatch");
1383         if (spot)
1384                 return spot;
1385
1386         //objerror ("FindIntermission: no spot");
1387         return world;
1388 };
1389 */
1390
1391 /*
1392 ===============================================================================
1393
1394 RULES
1395
1396 ===============================================================================
1397 */
1398
1399 void DumpStats(float final)
1400 {
1401         local float file;
1402         local string s;
1403         local float to_console;
1404         local float to_eventlog;
1405         local float to_file;
1406         local float i;
1407
1408         to_console = cvar("sv_logscores_console");
1409         to_eventlog = cvar("sv_eventlog");
1410         to_file = cvar("sv_logscores_file");
1411
1412         if(!final)
1413         {
1414                 to_console = TRUE; // always print printstats replies
1415                 to_eventlog = FALSE; // but never print them to the event log
1416         }
1417
1418         if(to_eventlog)
1419                 if(cvar("sv_eventlog_console"))
1420                         to_console = FALSE; // otherwise we get the output twice
1421
1422         if(final)
1423                 s = ":scores:";
1424         else
1425                 s = ":status:";
1426         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1427
1428         if(to_console)
1429                 print(s, "\n");
1430         if(to_eventlog)
1431                 GameLogEcho(s);
1432         if(to_file)
1433         {
1434                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1435                 if(file == -1)
1436                         to_file = FALSE;
1437                 else
1438                         fputs(file, strcat(s, "\n"));
1439         }
1440
1441         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1442         if(to_console)
1443                 print(s, "\n");
1444         if(to_eventlog)
1445                 GameLogEcho(s);
1446         if(to_file)
1447                 fputs(file, strcat(s, "\n"));
1448
1449         FOR_EACH_CLIENT(other)
1450         {
1451                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1452                 {
1453                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1454                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1455                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1456                                 s = strcat(s, ftos(other.team), ":");
1457                         else
1458                                 s = strcat(s, "spectator:");
1459
1460                         if(to_console)
1461                                 print(s, other.netname, "\n");
1462                         if(to_eventlog)
1463                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1464                         if(to_file)
1465                                 fputs(file, strcat(s, other.netname, "\n"));
1466                 }
1467         }
1468
1469         if(teams_matter)
1470         {
1471                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1472                 if(to_console)
1473                         print(s, "\n");
1474                 if(to_eventlog)
1475                         GameLogEcho(s);
1476                 if(to_file)
1477                         fputs(file, strcat(s, "\n"));
1478
1479                 for(i = 1; i < 16; ++i)
1480                 {
1481                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1482                         s = strcat(s, ":", ftos(i));
1483                         if(to_console)
1484                                 print(s, "\n");
1485                         if(to_eventlog)
1486                                 GameLogEcho(s);
1487                         if(to_file)
1488                                 fputs(file, strcat(s, "\n"));
1489                 }
1490         }
1491
1492         if(to_console)
1493                 print(":end\n");
1494         if(to_eventlog)
1495                 GameLogEcho(":end");
1496         if(to_file)
1497         {
1498                 fputs(file, ":end\n");
1499                 fclose(file);
1500         }
1501 }
1502
1503 void FixIntermissionClient(entity e)
1504 {
1505         string s;
1506         if(!e.autoscreenshot) // initial call
1507         {
1508                 e.angles = e.v_angle;
1509                 e.angles_x = -e.angles_x;
1510                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1511                 e.health = -2342;
1512                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1513                 e.solid = SOLID_NOT;
1514                 e.movetype = MOVETYPE_NONE;
1515                 e.takedamage = DAMAGE_NO;
1516                 if(e.weaponentity)
1517                 {
1518                         e.weaponentity.effects = EF_NODRAW;
1519                         if (e.weaponentity.weaponentity)
1520                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1521                 }
1522                 if(clienttype(e) == CLIENTTYPE_REAL)
1523                 {
1524                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1525                         s = cvar_string("sv_intermission_cdtrack");
1526                         if(s != "")
1527                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1528                         msg_entity = e;
1529                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1530                 }
1531         }
1532
1533         //e.velocity = '0 0 0';
1534         //e.fixangle = TRUE;
1535
1536         // TODO halt weapon animation
1537 }
1538
1539
1540 /*
1541 go to the next level for deathmatch
1542 only called if a time or frag limit has expired
1543 */
1544 void NextLevel()
1545 {
1546         float i;
1547
1548         gameover = TRUE;
1549
1550         intermission_running = 1;
1551
1552 // enforce a wait time before allowing changelevel
1553         if(player_count > 0)
1554                 intermission_exittime = time + cvar("sv_mapchange_delay");
1555         else
1556                 intermission_exittime = -1;
1557
1558         /*
1559         WriteByte (MSG_ALL, SVC_CDTRACK);
1560         WriteByte (MSG_ALL, 3);
1561         WriteByte (MSG_ALL, 3);
1562         // done in FixIntermission
1563         */
1564
1565         //pos = FindIntermission ();
1566
1567         VoteReset();
1568
1569         DumpStats(TRUE);
1570
1571         if(cvar("sv_eventlog"))
1572                 GameLogEcho(":gameover");
1573
1574         GameLogClose();
1575
1576 // TO DO
1577
1578 // save the stats to a text file on the client
1579 // stuffcmd(other, log_stats "stats/file_name");
1580 // bprint stats
1581 // stuffcmd(other, log_stats "");
1582 // use a filename similar to the demo name
1583         // string file_name;
1584         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1585
1586 // write a stats parser for the menu
1587
1588         if(cvar("sv_accuracy_data_send")) {
1589                 string stats_to_send;
1590
1591                 FOR_EACH_CLIENT(other) {  // make the string to send
1592                         FixIntermissionClient(other);
1593
1594                         if(other.cvar_cl_accuracy_data_share) {
1595                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1596
1597                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1598                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1599
1600                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1601
1602                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1603                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1604
1605                                 stats_to_send = strcat(stats_to_send, "\n");
1606                         }
1607                 }
1608
1609                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1610                         Score_NicePrint(other);  // print the score
1611
1612                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1613                                 bprint(stats_to_send);
1614                 }
1615         } else { // ye olde message
1616                 FOR_EACH_PLAYER(other) {
1617                         FixIntermissionClient(other);
1618
1619                         if(other.winning)
1620                                 bprint(other.netname, " ^7wins.\n");
1621                 }
1622         }
1623
1624         if(cvar("g_campaign"))
1625                 CampaignPreIntermission();
1626
1627         localcmd("\nsv_hook_gameend\n");
1628 }
1629
1630 /*
1631 ============
1632 CheckRules_Player
1633
1634 Exit deathmatch games upon conditions
1635 ============
1636 */
1637 void CheckRules_Player()
1638 {
1639         if (gameover)   // someone else quit the game already
1640                 return;
1641
1642         if(self.deadflag == DEAD_NO)
1643                 self.play_time += frametime;
1644
1645         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1646         //   (div0: and that in CheckRules_World please)
1647 };
1648
1649 float checkrules_equality;
1650 float checkrules_suddendeathwarning;
1651 float checkrules_suddendeathend;
1652 float checkrules_overtimesadded; //how many overtimes have been already added
1653
1654 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1655 float WINNING_YES = 1; // winner found
1656 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1657 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1658
1659 float InitiateSuddenDeath()
1660 {
1661         // Check first whether normal overtimes could be added before initiating suddendeath mode
1662         // - for this timelimit_overtime needs to be >0 of course
1663         // - also check the winning condition calculated in the previous frame and only add normal overtime
1664         //   again, if at the point at which timelimit would be extended again, still no winner was found
1665         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1666         {
1667                 return 1; // need to call InitiateOvertime later
1668         }
1669         else
1670         {
1671                 if(!checkrules_suddendeathend)
1672                 {
1673                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1674                         if(g_race && !g_race_qualifying)
1675                                 race_StartCompleting();
1676                 }
1677                 return 0;
1678         }
1679 }
1680
1681 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1682 {
1683         ++checkrules_overtimesadded;
1684         //add one more overtime by simply extending the timelimit
1685         float tl;
1686         tl = cvar("timelimit");
1687         tl += cvar("timelimit_overtime");
1688         cvar_set("timelimit", ftos(tl));
1689         string minutesPlural;
1690         if (cvar("timelimit_overtime") == 1)
1691                 minutesPlural = " ^3minute";
1692         else
1693                 minutesPlural = " ^3minutes";
1694
1695         bcenterprint(
1696                 strcat(
1697                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1698                         ftos(cvar("timelimit_overtime")),
1699                         minutesPlural,
1700                         " to the game!"
1701                 )
1702         );
1703 }
1704
1705 float GetWinningCode(float fraglimitreached, float equality)
1706 {
1707         if(cvar("g_campaign") == 1)
1708                 if(fraglimitreached)
1709                         return WINNING_YES;
1710                 else
1711                         return WINNING_NO;
1712
1713         else
1714                 if(equality)
1715                         if(fraglimitreached)
1716                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1717                         else
1718                                 return WINNING_NEVER;
1719                 else
1720                         if(fraglimitreached)
1721                                 return WINNING_YES;
1722                         else
1723                                 return WINNING_NO;
1724 }
1725
1726 // set the .winning flag for exactly those players with a given field value
1727 void SetWinners(.float field, float value)
1728 {
1729         entity head;
1730         FOR_EACH_PLAYER(head)
1731                 head.winning = (head.field == value);
1732 }
1733
1734 // set the .winning flag for those players with a given field value
1735 void AddWinners(.float field, float value)
1736 {
1737         entity head;
1738         FOR_EACH_PLAYER(head)
1739                 if(head.field == value)
1740                         head.winning = 1;
1741 }
1742
1743 // clear the .winning flags
1744 void ClearWinners(void)
1745 {
1746         entity head;
1747         FOR_EACH_PLAYER(head)
1748                 head.winning = 0;
1749 }
1750
1751 // Onslaught winning condition:
1752 // game terminates if only one team has a working generator (or none)
1753 float WinningCondition_Onslaught()
1754 {
1755         entity head;
1756         local float t1, t2, t3, t4;
1757
1758         WinningConditionHelper(); // set worldstatus
1759
1760         if(inWarmupStage)
1761                 return WINNING_NO;
1762
1763         // first check if the game has ended
1764         t1 = t2 = t3 = t4 = 0;
1765         head = find(world, classname, "onslaught_generator");
1766         while (head)
1767         {
1768                 if (head.health > 0)
1769                 {
1770                         if (head.team == COLOR_TEAM1) t1 = 1;
1771                         if (head.team == COLOR_TEAM2) t2 = 1;
1772                         if (head.team == COLOR_TEAM3) t3 = 1;
1773                         if (head.team == COLOR_TEAM4) t4 = 1;
1774                 }
1775                 head = find(head, classname, "onslaught_generator");
1776         }
1777         if (t1 + t2 + t3 + t4 < 2)
1778         {
1779                 // game over, only one team remains (or none)
1780                 ClearWinners();
1781                 if (t1) SetWinners(team, COLOR_TEAM1);
1782                 if (t2) SetWinners(team, COLOR_TEAM2);
1783                 if (t3) SetWinners(team, COLOR_TEAM3);
1784                 if (t4) SetWinners(team, COLOR_TEAM4);
1785                 dprint("Have a winner, ending game.\n");
1786                 return WINNING_YES;
1787         }
1788
1789         // Two or more teams remain
1790         return WINNING_NO;
1791 }
1792
1793 float LMS_NewPlayerLives()
1794 {
1795         float fl;
1796         fl = cvar("fraglimit");
1797         if(fl == 0)
1798                 fl = 999;
1799
1800         // first player has left the game for dying too much? Nobody else can get in.
1801         if(lms_lowest_lives < 1)
1802                 return 0;
1803
1804         if(!cvar("g_lms_join_anytime"))
1805                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1806                         return 0;
1807
1808         return bound(1, lms_lowest_lives, fl);
1809 }
1810
1811 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1812 // they win. Otherwise the defending team wins once the timelimit passes.
1813 void assault_new_round();
1814 float WinningCondition_Assault()
1815 {
1816         local float status;
1817
1818         WinningConditionHelper(); // set worldstatus
1819
1820         status = WINNING_NO;
1821         // as the timelimit has not yet passed just assume the defending team will win
1822         if(assault_attacker_team == COLOR_TEAM1)
1823         {
1824                 SetWinners(team, COLOR_TEAM2);
1825         }
1826         else
1827         {
1828                 SetWinners(team, COLOR_TEAM1);
1829         }
1830
1831         local entity ent;
1832         ent = find(world, classname, "target_assault_roundend");
1833         if(ent)
1834         {
1835                 if(ent.winning) // round end has been triggered by attacking team
1836                 {
1837                         bprint("ASSAULT: round completed...\n");
1838                         SetWinners(team, assault_attacker_team);
1839
1840                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1841
1842                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1843                         {
1844                                 status = WINNING_YES;
1845                         }
1846                         else
1847                         {
1848                                 local entity oldself;
1849                                 oldself = self;
1850                                 self = ent;
1851                                 assault_new_round();
1852                                 self = oldself;
1853                         }
1854                 }
1855         }
1856
1857         return status;
1858 }
1859
1860 // LMS winning condition: game terminates if and only if there's at most one
1861 // one player who's living lives. Top two scores being equal cancels the time
1862 // limit.
1863 float WinningCondition_LMS()
1864 {
1865         entity head, head2;
1866         float have_player;
1867         float have_players;
1868         float l;
1869
1870         have_player = FALSE;
1871         have_players = FALSE;
1872         l = LMS_NewPlayerLives();
1873
1874         head = find(world, classname, "player");
1875         if(head)
1876                 have_player = TRUE;
1877         head2 = find(head, classname, "player");
1878         if(head2)
1879                 have_players = TRUE;
1880
1881         if(have_player)
1882         {
1883                 // we have at least one player
1884                 if(have_players)
1885                 {
1886                         // two or more active players - continue with the game
1887                 }
1888                 else
1889                 {
1890                         // exactly one player?
1891
1892                         ClearWinners();
1893                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1894
1895                         if(l)
1896                         {
1897                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1898                                 return WINNING_NO;
1899                         }
1900                         else
1901                         {
1902                                 // a winner!
1903                                 // and assign him his first place
1904                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1905                                 return WINNING_YES;
1906                         }
1907                 }
1908         }
1909         else
1910         {
1911                 // nobody is playing at all...
1912                 if(l)
1913                 {
1914                         // wait for players...
1915                 }
1916                 else
1917                 {
1918                         // SNAFU (maybe a draw game?)
1919                         ClearWinners();
1920                         dprint("No players, ending game.\n");
1921                         return WINNING_YES;
1922                 }
1923         }
1924
1925         // When we get here, we have at least two players who are actually LIVING,
1926         // now check if the top two players have equal score.
1927         WinningConditionHelper();
1928
1929         ClearWinners();
1930         if(WinningConditionHelper_winner)
1931                 WinningConditionHelper_winner.winning = TRUE;
1932         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1933                 return WINNING_NEVER;
1934
1935         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1936         return WINNING_NO;
1937 }
1938
1939 void ShuffleMaplist()
1940 {
1941         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1942 }
1943
1944 float leaderfrags;
1945 float WinningCondition_Scores(float limit, float leadlimit)
1946 {
1947         float limitreached;
1948
1949         // TODO make everything use THIS winning condition (except LMS)
1950         WinningConditionHelper();
1951
1952         if(teams_matter)
1953         {
1954                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1955                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1956                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1957                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1958         }
1959
1960         ClearWinners();
1961         if(WinningConditionHelper_winner)
1962                 WinningConditionHelper_winner.winning = 1;
1963         if(WinningConditionHelper_winnerteam >= 0)
1964                 SetWinners(team, WinningConditionHelper_winnerteam);
1965
1966         if(WinningConditionHelper_lowerisbetter)
1967         {
1968                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1969                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1970                 limit = -limit;
1971         }
1972
1973         if(WinningConditionHelper_zeroisworst)
1974                 leadlimit = 0; // not supported in this mode
1975
1976         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1977         // these modes always score in increments of 1, thus this makes sense
1978         {
1979                 if(leaderfrags != WinningConditionHelper_topscore)
1980                 {
1981                         leaderfrags = WinningConditionHelper_topscore;
1982
1983                         if (limit)
1984                         if (leaderfrags == limit - 1)
1985                                 Announce("1fragleft");
1986                         else if (leaderfrags == limit - 2)
1987                                 Announce("2fragsleft");
1988                         else if (leaderfrags == limit - 3)
1989                                 Announce("3fragsleft");
1990                 }
1991         }
1992
1993         limitreached = FALSE;
1994         if(limit)
1995                 if(WinningConditionHelper_topscore >= limit)
1996                         limitreached = TRUE;
1997         if(leadlimit)
1998         {
1999                 float leadlimitreached;
2000                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2001                 if(cvar("leadlimit_and_fraglimit"))
2002                         limitreached = (limitreached && leadlimitreached);
2003                 else
2004                         limitreached = (limitreached || leadlimitreached);
2005         }
2006
2007         return GetWinningCode(
2008                 WinningConditionHelper_topscore && limitreached,
2009                 WinningConditionHelper_equality
2010         );
2011 }
2012
2013 float WinningCondition_Race(float fraglimit)
2014 {
2015         float wc;
2016         entity p;
2017         float n, c;
2018
2019         n = 0;
2020         c = 0;
2021         FOR_EACH_PLAYER(p)
2022         {
2023                 ++n;
2024                 if(p.race_completed)
2025                         ++c;
2026         }
2027         if(n && (n == c))
2028                 return WINNING_YES;
2029         wc = WinningCondition_Scores(fraglimit, 0);
2030
2031         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2032         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2033         // do NOT support equality when the laps are all raced!
2034                 return WINNING_STARTSUDDENDEATHOVERTIME;
2035         else
2036                 return WINNING_NEVER;
2037         return wc;
2038 }
2039
2040 void ReadyRestart();
2041 float WinningCondition_QualifyingThenRace(float limit)
2042 {
2043         float wc;
2044         wc = WinningCondition_Scores(limit, 0);
2045
2046         // NEVER initiate overtime
2047         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2048         {
2049                 return WINNING_YES;
2050         }
2051
2052         return wc;
2053 }
2054
2055 float WinningCondition_RanOutOfSpawns()
2056 {
2057         entity head;
2058
2059         if(have_team_spawns <= 0)
2060                 return WINNING_NO;
2061
2062         if(!some_spawn_has_been_used)
2063                 return WINNING_NO;
2064
2065         team1_score = team2_score = team3_score = team4_score = 0;
2066
2067         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2068         {
2069                 if(head.team == COLOR_TEAM1)
2070                         team1_score = 1;
2071                 else if(head.team == COLOR_TEAM2)
2072                         team2_score = 1;
2073                 else if(head.team == COLOR_TEAM3)
2074                         team3_score = 1;
2075                 else if(head.team == COLOR_TEAM4)
2076                         team4_score = 1;
2077         }
2078
2079         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2080         {
2081                 if(head.team == COLOR_TEAM1)
2082                         team1_score = 1;
2083                 else if(head.team == COLOR_TEAM2)
2084                         team2_score = 1;
2085                 else if(head.team == COLOR_TEAM3)
2086                         team3_score = 1;
2087                 else if(head.team == COLOR_TEAM4)
2088                         team4_score = 1;
2089         }
2090
2091         ClearWinners();
2092         if(team1_score + team2_score + team3_score + team4_score == 0)
2093         {
2094                 checkrules_equality = TRUE;
2095                 return WINNING_YES;
2096         }
2097         else if(team1_score + team2_score + team3_score + team4_score == 1)
2098         {
2099                 float t, i;
2100                 if(team1_score) t = COLOR_TEAM1;
2101                 if(team2_score) t = COLOR_TEAM2;
2102                 if(team3_score) t = COLOR_TEAM3;
2103                 if(team4_score) t = COLOR_TEAM4;
2104                 CheckAllowedTeams(world);
2105                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2106                 {
2107                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2108                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2109                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2110                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2111                 }
2112
2113                 AddWinners(team, t);
2114                 return WINNING_YES;
2115         }
2116         else
2117                 return WINNING_NO;
2118 }
2119
2120 /*
2121 ============
2122 CheckRules_World
2123
2124 Exit deathmatch games upon conditions
2125 ============
2126 */
2127 void CheckRules_World()
2128 {
2129         float timelimit;
2130         float fraglimit;
2131         float leadlimit;
2132
2133         VoteThink();
2134         MapVote_Think();
2135
2136         SetDefaultAlpha();
2137
2138         /*
2139         MapVote_Think should now do that part
2140         if (intermission_running)
2141                 if (time >= intermission_exittime + 60)
2142                 {
2143                         if(!DoNextMapOverride())
2144                                 GotoNextMap();
2145                         return;
2146                 }
2147         */
2148
2149         if (gameover)   // someone else quit the game already
2150         {
2151                 if(player_count == 0) // Nobody there? Then let's go to the next map
2152                         MapVote_Start();
2153                         // this will actually check the player count in the next frame
2154                         // again, but this shouldn't hurt
2155                 return;
2156         }
2157
2158         timelimit = cvar("timelimit") * 60;
2159         fraglimit = cvar("fraglimit");
2160         leadlimit = cvar("leadlimit");
2161
2162         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2163         {
2164                 if(timelimit > 0)
2165                         timelimit = 0; // timelimit is not made for warmup
2166                 if(fraglimit > 0)
2167                         fraglimit = 0; // no fraglimit for now
2168                 leadlimit = 0; // no leadlimit for now
2169         }
2170
2171         if(g_onslaught)
2172                 timelimit = 0; // ONS has its own overtime rule
2173
2174         if(timelimit > 0)
2175         {
2176                 timelimit += game_starttime;
2177         }
2178         else if (timelimit < 0)
2179         {
2180                 // endmatch
2181                 NextLevel();
2182                 return;
2183         }
2184
2185         float wantovertime;
2186         wantovertime = 0;
2187
2188         if(checkrules_suddendeathend)
2189         {
2190                 if(!checkrules_suddendeathwarning)
2191                 {
2192                         checkrules_suddendeathwarning = TRUE;
2193                         if(g_race && !g_race_qualifying)
2194                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2195                         else
2196                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2197                 }
2198         }
2199         else
2200         {
2201                 if (timelimit && time >= timelimit)
2202                 {
2203                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2204                         {
2205                                 float totalplayers;
2206                                 float playerswithlaps;
2207                                 float readyplayers;
2208                                 entity head;
2209                                 totalplayers = playerswithlaps = readyplayers = 0;
2210                                 FOR_EACH_PLAYER(head)
2211                                 {
2212                                         ++totalplayers;
2213                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2214                                                 ++playerswithlaps;
2215                                         if(head.ready)
2216                                                 ++readyplayers;
2217                                 }
2218
2219                                 // at least 2 of the players have completed a lap: start the RACE
2220                                 // otherwise, the players should end the qualifying on their own
2221                                 if(readyplayers || playerswithlaps >= 2)
2222                                 {
2223                                         checkrules_suddendeathend = 0;
2224                                         ReadyRestart(); // go to race
2225                                         return;
2226                                 }
2227                                 else
2228                                         wantovertime |= InitiateSuddenDeath();
2229                         }
2230                         else
2231                                 wantovertime |= InitiateSuddenDeath();
2232                 }
2233         }
2234
2235         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2236         {
2237                 NextLevel();
2238                 return;
2239         }
2240
2241         float checkrules_status;
2242         checkrules_status = WinningCondition_RanOutOfSpawns();
2243         if(checkrules_status == WINNING_YES)
2244         {
2245                 bprint("Hey! Someone ran out of spawns!\n");
2246         }
2247         else if(g_race && !g_race_qualifying && timelimit >= 0)
2248         {
2249                 checkrules_status = WinningCondition_Race(fraglimit);
2250                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2251         }
2252         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2253         {
2254                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2255                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2256         }
2257         else if(g_assault)
2258         {
2259                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2260         }
2261         else if(g_lms)
2262         {
2263                 checkrules_status = WinningCondition_LMS();
2264         }
2265         else if (g_onslaught)
2266         {
2267                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2268         }
2269         else
2270         {
2271                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2272                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2273         }
2274
2275         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2276         {
2277                 checkrules_status = WINNING_NEVER;
2278                 checkrules_overtimesadded = -1;
2279                 wantovertime |= InitiateSuddenDeath();
2280         }
2281
2282         if(checkrules_status == WINNING_NEVER)
2283                 // equality cases! Nobody wins if the overtime ends in a draw.
2284                 ClearWinners();
2285
2286         if(wantovertime)
2287         {
2288                 if(checkrules_status == WINNING_NEVER)
2289                         InitiateOvertime();
2290                 else
2291                         checkrules_status = WINNING_YES;
2292         }
2293
2294         if(checkrules_suddendeathend)
2295                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2296                         checkrules_status = WINNING_YES;
2297
2298         if(checkrules_status == WINNING_YES)
2299         {
2300                 //print("WINNING\n");
2301                 NextLevel();
2302         }
2303 };
2304
2305 float mapvote_nextthink;
2306 float mapvote_initialized;
2307 float mapvote_keeptwotime;
2308 float mapvote_timeout;
2309 string mapvote_message;
2310 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2311 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2312 float mapvote_screenshot_dirs_count;
2313
2314 float mapvote_count;
2315 float mapvote_count_real;
2316 string mapvote_maps[MAPVOTE_COUNT];
2317 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2318 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2319 float mapvote_maps_suggested[MAPVOTE_COUNT];
2320 string mapvote_suggestions[MAPVOTE_COUNT];
2321 float mapvote_suggestion_ptr;
2322 float mapvote_maxlen;
2323 float mapvote_voters;
2324 float mapvote_votes[MAPVOTE_COUNT];
2325 float mapvote_run;
2326 float mapvote_detail;
2327 float mapvote_abstain;
2328 .float mapvote;
2329
2330 void MapVote_ClearAllVotes()
2331 {
2332         FOR_EACH_CLIENT(other)
2333                 other.mapvote = 0;
2334 }
2335
2336 string MapVote_Suggest(string m)
2337 {
2338         float i;
2339         if(m == "")
2340                 return "That's not how to use this command.";
2341         if(!cvar("g_maplist_votable_suggestions"))
2342                 return "Suggestions are not accepted on this server.";
2343         if(mapvote_initialized)
2344                 return "Can't suggest - voting is already in progress!";
2345         m = MapInfo_FixName(m);
2346         if(!m)
2347                 return "The map you suggested is not available on this server.";
2348         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2349                 if(Map_IsRecent(m))
2350                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2351
2352         if(!MapInfo_CheckMap(m))
2353                 return "The map you suggested does not support the current game mode.";
2354         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2355                 if(mapvote_suggestions[i] == m)
2356                         return "This map was already suggested.";
2357         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2358         {
2359                 i = floor(random() * mapvote_suggestion_ptr);
2360         }
2361         else
2362         {
2363                 i = mapvote_suggestion_ptr;
2364                 mapvote_suggestion_ptr += 1;
2365         }
2366         if(mapvote_suggestions[i] != "")
2367                 strunzone(mapvote_suggestions[i]);
2368         mapvote_suggestions[i] = strzone(m);
2369         if(cvar("sv_eventlog"))
2370                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2371         return strcat("Suggestion of ", m, " accepted.");
2372 }
2373
2374 void MapVote_AddVotable(string nextMap, float isSuggestion)
2375 {
2376         float j, i, o;
2377         string pakfile, mapfile;
2378
2379         if(nextMap == "")
2380                 return;
2381         for(j = 0; j < mapvote_count; ++j)
2382                 if(mapvote_maps[j] == nextMap)
2383                         return;
2384         if(strlen(nextMap) > mapvote_maxlen)
2385                 mapvote_maxlen = strlen(nextMap);
2386         mapvote_maps[mapvote_count] = strzone(nextMap);
2387         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2388
2389         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2390         {
2391                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2392                 pakfile = whichpack(strcat(mapfile, ".tga"));
2393                 if(pakfile == "")
2394                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2395                 if(pakfile == "")
2396                         pakfile = whichpack(strcat(mapfile, ".png"));
2397                 if(pakfile != "")
2398                         break;
2399         }
2400         if(i >= mapvote_screenshot_dirs_count)
2401                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2402         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2403                 pakfile = substring(pakfile, o, -1);
2404
2405         mapvote_maps_screenshot_dir[mapvote_count] = i;
2406         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2407
2408         mapvote_count += 1;
2409 }
2410
2411 void MapVote_Spawn();
2412 void MapVote_Init()
2413 {
2414         float i;
2415         float nmax, smax;
2416
2417         MapVote_ClearAllVotes();
2418
2419         mapvote_count = 0;
2420         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2421         mapvote_abstain = cvar("g_maplist_votable_abstain");
2422
2423         if(mapvote_abstain)
2424                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2425         else
2426                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2427         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2428
2429         // we need this for AddVotable, as that cycles through the screenshot dirs
2430         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2431         if(mapvote_screenshot_dirs_count == 0)
2432                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2433         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2434         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2435                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2436
2437         if(mapvote_suggestion_ptr)
2438                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2439                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2440
2441         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2442                 MapVote_AddVotable(GetNextMap(), FALSE);
2443
2444         if(mapvote_count == 0)
2445         {
2446                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2447                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2448                 if(cvar("g_maplist_shuffle"))
2449                         ShuffleMaplist();
2450                 localcmd("\nmenu_cmd sync\n");
2451                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2452                         MapVote_AddVotable(GetNextMap(), FALSE);
2453         }
2454
2455         mapvote_count_real = mapvote_count;
2456         if(mapvote_abstain)
2457                 MapVote_AddVotable("don't care", 0);
2458
2459         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2460
2461         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2462         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2463         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2464                 mapvote_keeptwotime = 0;
2465         mapvote_message = "Choose a map and press its key!";
2466
2467         MapVote_Spawn();
2468 }
2469
2470 void MapVote_SendPicture(float id)
2471 {
2472         msg_entity = self;
2473         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2474         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2475         WriteByte(MSG_ONE, id);
2476         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2477 }
2478
2479 float GameCommand_MapVote(string cmd)
2480 {
2481         if(!intermission_running)
2482                 return FALSE;
2483
2484         if(cmd == "mv_getpic")
2485         {
2486                 MapVote_SendPicture(stof(argv(1)));
2487                 return TRUE;
2488         }
2489
2490         return FALSE;
2491 }
2492
2493 float MapVote_GetMapMask()
2494 {
2495         float mask, i, power;
2496         mask = 0;
2497         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2498                 if(mapvote_maps[i] != "")
2499                         mask |= power;
2500         return mask;
2501 }
2502
2503 entity mapvote_ent;
2504 float MapVote_SendEntity(entity to, float sf)
2505 {
2506         float i;
2507
2508         if(sf & 1)
2509                 sf &~= 2; // if we send 1, we don't need to also send 2
2510
2511         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2512         WriteByte(MSG_ENTITY, sf);
2513
2514         if(sf & 1)
2515         {
2516                 // flag 1 == initialization
2517                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2518                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2519                 WriteString(MSG_ENTITY, "");
2520                 WriteByte(MSG_ENTITY, mapvote_count);
2521                 WriteByte(MSG_ENTITY, mapvote_abstain);
2522                 WriteByte(MSG_ENTITY, mapvote_detail);
2523                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2524                 if(mapvote_count <= 8)
2525                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2526                 else
2527                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2528                 for(i = 0; i < mapvote_count; ++i)
2529                         if(mapvote_maps[i] != "")
2530                         {
2531                                 if(mapvote_abstain && i == mapvote_count - 1)
2532                                 {
2533                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2534                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2535                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2536                                 }
2537                                 else
2538                                 {
2539                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2540                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2541                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2542                                 }
2543                         }
2544         }
2545
2546         if(sf & 2)
2547         {
2548                 // flag 2 == update of mask
2549                 if(mapvote_count <= 8)
2550                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2551                 else
2552                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2553         }
2554
2555         if(sf & 4)
2556         {
2557                 if(mapvote_detail)
2558                         for(i = 0; i < mapvote_count; ++i)
2559                                 if(mapvote_maps[i] != "")
2560                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2561
2562                 WriteByte(MSG_ENTITY, to.mapvote);
2563         }
2564
2565         return TRUE;
2566 }
2567
2568 void MapVote_Spawn()
2569 {
2570         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2571 }
2572
2573 void MapVote_TouchMask()
2574 {
2575         mapvote_ent.SendFlags |= 2;
2576 }
2577
2578 void MapVote_TouchVotes(entity voter)
2579 {
2580         mapvote_ent.SendFlags |= 4;
2581 }
2582
2583 float MapVote_Finished(float mappos)
2584 {
2585         string result;
2586         float i;
2587         float didntvote;
2588
2589         if(cvar("sv_eventlog"))
2590         {
2591                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2592                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2593                 didntvote = mapvote_voters;
2594                 for(i = 0; i < mapvote_count; ++i)
2595                         if(mapvote_maps[i] != "")
2596                         {
2597                                 didntvote -= mapvote_votes[i];
2598                                 if(i != mappos)
2599                                 {
2600                                         result = strcat(result, ":", mapvote_maps[i]);
2601                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2602                                 }
2603                         }
2604                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2605
2606                 GameLogEcho(result);
2607                 if(mapvote_maps_suggested[mappos])
2608                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2609         }
2610
2611         FOR_EACH_REALCLIENT(other)
2612                 FixClientCvars(other);
2613
2614         Map_Goto_SetStr(mapvote_maps[mappos]);
2615         Map_Goto();
2616         alreadychangedlevel = TRUE;
2617         return TRUE;
2618 }
2619 void MapVote_CheckRules_1()
2620 {
2621         float i;
2622
2623         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2624         {
2625                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2626                 mapvote_votes[i] = 0;
2627         }
2628
2629         mapvote_voters = 0;
2630         FOR_EACH_REALCLIENT(other)
2631         {
2632                 ++mapvote_voters;
2633                 if(other.mapvote)
2634                 {
2635                         i = other.mapvote - 1;
2636                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2637                         mapvote_votes[i] = mapvote_votes[i] + 1;
2638                 }
2639         }
2640 }
2641
2642 float MapVote_CheckRules_2()
2643 {
2644         float i;
2645         float firstPlace, secondPlace;
2646         float firstPlaceVotes, secondPlaceVotes;
2647         float mapvote_voters_real;
2648         string result;
2649
2650         if(mapvote_count_real == 1)
2651                 return MapVote_Finished(0);
2652
2653         mapvote_voters_real = mapvote_voters;
2654         if(mapvote_abstain)
2655                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2656
2657         RandomSelection_Init();
2658         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2659                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2660         firstPlace = RandomSelection_chosen_float;
2661         firstPlaceVotes = RandomSelection_best_priority;
2662         //dprint("First place: ", ftos(firstPlace), "\n");
2663         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2664
2665         RandomSelection_Init();
2666         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2667                 if(i != firstPlace)
2668                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2669         secondPlace = RandomSelection_chosen_float;
2670         secondPlaceVotes = RandomSelection_best_priority;
2671         //dprint("Second place: ", ftos(secondPlace), "\n");
2672         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2673
2674         if(firstPlace == -1)
2675                 error("No first place in map vote... WTF?");
2676
2677         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2678                 return MapVote_Finished(firstPlace);
2679
2680         if(mapvote_keeptwotime)
2681                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2682                 {
2683                         float didntvote;
2684                         MapVote_TouchMask();
2685                         mapvote_message = "Now decide between the TOP TWO!";
2686                         mapvote_keeptwotime = 0;
2687                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2688                         result = strcat(result, ":", ftos(firstPlaceVotes));
2689                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2690                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2691                         didntvote = mapvote_voters;
2692                         for(i = 0; i < mapvote_count; ++i)
2693                                 if(mapvote_maps[i] != "")
2694                                 {
2695                                         didntvote -= mapvote_votes[i];
2696                                         if(i != firstPlace)
2697                                                 if(i != secondPlace)
2698                                                 {
2699                                                         result = strcat(result, ":", mapvote_maps[i]);
2700                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2701                                                         if(i < mapvote_count_real)
2702                                                         {
2703                                                                 strunzone(mapvote_maps[i]);
2704                                                                 mapvote_maps[i] = "";
2705                                                                 strunzone(mapvote_maps_pakfile[i]);
2706                                                                 mapvote_maps_pakfile[i] = "";
2707                                                         }
2708                                                 }
2709                                 }
2710                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2711                         if(cvar("sv_eventlog"))
2712                                 GameLogEcho(result);
2713                 }
2714
2715         return FALSE;
2716 }
2717 void MapVote_Tick()
2718 {
2719         float keeptwo;
2720         float totalvotes;
2721
2722         keeptwo = mapvote_keeptwotime;
2723         MapVote_CheckRules_1(); // count
2724         if(MapVote_CheckRules_2()) // decide
2725                 return;
2726
2727         totalvotes = 0;
2728         FOR_EACH_REALCLIENT(other)
2729         {
2730                 // hide scoreboard again
2731                 if(other.health != 2342)
2732                 {
2733                         other.health = 2342;
2734                         other.impulse = 0;
2735                         if(clienttype(other) == CLIENTTYPE_REAL)
2736                         {
2737                                 msg_entity = other;
2738                                 WriteByte(MSG_ONE, SVC_FINALE);
2739                                 WriteString(MSG_ONE, "");
2740                         }
2741                 }
2742
2743                 // clear possibly invalid votes
2744                 if(mapvote_maps[other.mapvote - 1] == "")
2745                         other.mapvote = 0;
2746                 // use impulses as new vote
2747                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2748                         if(mapvote_maps[other.impulse - 1] != "")
2749                         {
2750                                 other.mapvote = other.impulse;
2751                                 MapVote_TouchVotes(other);
2752                         }
2753                 other.impulse = 0;
2754
2755                 if(other.mapvote)
2756                         ++totalvotes;
2757         }
2758
2759         MapVote_CheckRules_1(); // just count
2760 }
2761 void MapVote_Start()
2762 {
2763         if(mapvote_run)
2764                 return;
2765
2766         MapInfo_Enumerate();
2767         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2768                 mapvote_run = TRUE;
2769 }
2770 void MapVote_Think()
2771 {
2772         if(!mapvote_run)
2773                 return;
2774
2775         if(alreadychangedlevel)
2776                 return;
2777
2778         if(time < mapvote_nextthink)
2779                 return;
2780         //dprint("tick\n");
2781
2782         mapvote_nextthink = time + 0.5;
2783
2784         if(!mapvote_initialized)
2785         {
2786                 if(cvar("rescan_pending") == 1)
2787                 {
2788                         cvar_set("rescan_pending", "2");
2789                         localcmd("fs_rescan\nrescan_pending 3\n");
2790                         return;
2791                 }
2792                 else if(cvar("rescan_pending") == 2)
2793                 {
2794                         return;
2795                 }
2796                 else if(cvar("rescan_pending") == 3)
2797                 {
2798                         // now build missing mapinfo files
2799                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2800                                 return;
2801
2802                         // we're done, start the timer
2803                         cvar_set("rescan_pending", "0");
2804                 }
2805
2806                 mapvote_initialized = TRUE;
2807                 if(DoNextMapOverride())
2808                         return;
2809                 if(!cvar("g_maplist_votable") || player_count <= 0)
2810                 {
2811                         GotoNextMap();
2812                         return;
2813                 }
2814                 MapVote_Init();
2815         }
2816
2817         MapVote_Tick();
2818 };
2819
2820 string GotoMap(string m)
2821 {
2822         if(!MapInfo_CheckMap(m))
2823                 return "The map you chose is not available on this server.";
2824         cvar_set("nextmap", m);
2825         cvar_set("timelimit", "-1");
2826         if(mapvote_initialized || alreadychangedlevel)
2827         {
2828                 if(DoNextMapOverride())
2829                         return "Map switch initiated.";
2830                 else
2831                         return "Hm... no. For some reason I like THIS map more.";
2832         }
2833         else
2834                 return "Map switch will happen after scoreboard.";
2835 }
2836
2837
2838 void EndFrame()
2839 {
2840         float altime;
2841         FOR_EACH_REALCLIENT(self)
2842         {
2843                 if(self.classname == "spectator")
2844                 {
2845                         if(self.enemy.typehitsound)
2846                                 play2(self, "misc/typehit.wav");
2847                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2848                                 play2(self, "misc/hit.wav");
2849                 }
2850                 else
2851                 {
2852                         if(self.typehitsound)
2853                                 play2(self, "misc/typehit.wav");
2854                         else if(self.hitsound && self.cvar_cl_hitsound)
2855                                 play2(self, "misc/hit.wav");
2856                 }
2857         }
2858         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2859         // add 1 frametime because after this, engine SV_Physics
2860         // increases time by a frametime and then networks the frame
2861         // add another frametime because client shows everything with
2862         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2863         // needed!
2864         FOR_EACH_CLIENT(self)
2865         {
2866                 self.hitsound = FALSE;
2867                 self.typehitsound = FALSE;
2868                 antilag_record(self, altime);
2869         }
2870 }
2871
2872
2873 /*
2874  * RedirectionThink:
2875  * returns TRUE if redirecting
2876  */
2877 float redirection_timeout;
2878 float redirection_nextthink;
2879 float RedirectionThink()
2880 {
2881         float clients_found;
2882
2883         if(redirection_target == "")
2884                 return FALSE;
2885
2886         if(!redirection_timeout)
2887         {
2888                 cvar_set("sv_public", "-2");
2889                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2890                 if(redirection_target == "self")
2891                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2892                 else
2893                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2894         }
2895
2896         if(time < redirection_nextthink)
2897                 return TRUE;
2898
2899         redirection_nextthink = time + 1;
2900
2901         clients_found = 0;
2902         FOR_EACH_REALCLIENT(self)
2903         {
2904                 print("Redirecting: sending connect command to ", self.netname, "\n");
2905                 if(redirection_target == "self")
2906                         stuffcmd(self, "\ndisconnect; reconnect\n");
2907                 else
2908                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2909                 ++clients_found;
2910         }
2911
2912         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2913
2914         if(time > redirection_timeout || clients_found == 0)
2915                 localcmd("\nwait; wait; wait; quit\n");
2916
2917         return TRUE;
2918 }
2919
2920 void TargetMusic_RestoreGame();
2921 void RestoreGame()
2922 {
2923         // Loaded from a save game
2924         // some things then break, so let's work around them...
2925
2926         // Progs DB (capture records)
2927         ServerProgsDB = db_load("server.db");
2928
2929         // Mapinfo
2930         MapInfo_Shutdown();
2931         MapInfo_Enumerate();
2932         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2933         WeaponStats_Init();
2934
2935         TargetMusic_RestoreGame();
2936 }
2937
2938 void SV_Shutdown()
2939 {
2940         if(gameover > 1) // shutting down already?
2941                 return;
2942
2943         gameover = 2; // 2 = server shutting down
2944
2945         if(world_initialized > 0)
2946         {
2947                 world_initialized = 0;
2948                 print("Saving persistent data...\n");
2949                 Ban_SaveBans();
2950                 if(!cheatcount_total)
2951                 {
2952                         if(cvar("sv_db_saveasdump"))
2953                                 db_dump(ServerProgsDB, "server.db");
2954                         else
2955                                 db_save(ServerProgsDB, "server.db");
2956                 }
2957                 if(cvar("developer"))
2958                 {
2959                         if(cvar("sv_db_saveasdump"))
2960                                 db_dump(TemporaryDB, "server-temp.db");
2961                         else
2962                                 db_save(TemporaryDB, "server-temp.db");
2963                 }
2964                 CheatShutdown(); // must be after cheatcount check
2965                 db_close(ServerProgsDB);
2966                 db_close(TemporaryDB);
2967                 print("done!\n");
2968                 // tell the bot system the game is ending now
2969                 bot_endgame();
2970
2971                 WeaponStats_Shutdown();
2972                 MapInfo_Shutdown();
2973         }
2974         else if(world_initialized == 0)
2975         {
2976                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2977         }
2978 }