qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_assault");
 257                 BADCVAR("g_ca");
 258                 BADCVAR("g_ca_teams");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_freezetag_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_leadlimit");
 308                 BADCVAR("g_ctf_captimerecord_always");
 309                 BADCVAR("g_ctf_flag_glowtrails");
 310                 BADCVAR("g_ctf_flag_pickup_verbosename");
 311                 BADCVAR("g_domination_point_leadlimit");
 312                 BADCVAR("g_forced_respawn");
 313                 BADCVAR("g_keyhunt_point_leadlimit");
 314                 BADPREFIX("g_mod_");
 315                 BADCVAR("g_nexball_goalleadlimit");
 316                 BADCVAR("leadlimit_and_fraglimit");
 317                 BADCVAR("leadlimit_override");
 318                 BADCVAR("pausable");
 319                 BADCVAR("sv_allow_fullbright");
 320                 BADCVAR("sv_checkforpacketsduringsleep");
 321                 BADCVAR("sv_fraginfo");
 322                 BADCVAR("sv_timeout");
 323                 BADPREFIX("sv_timeout_");
 324                 BADPREFIX("crypto_");
 325                 BADPREFIX("g_chat_");
 326                 BADPREFIX("g_ctf_captimerecord_");
 327                 BADPREFIX("g_maplist_votable_");
 328                 BADPREFIX("net_");
 329                 BADPREFIX("prvm_");
 330                 BADPREFIX("skill_");
 331                 BADPREFIX("sv_cullentities_");
 332                 BADPREFIX("sv_fraginfo_");
 333                 BADPREFIX("sv_maxidle_");
 334                 BADPREFIX("sv_vote_");
 335                 BADPREFIX("timelimit_");
 336                 BADCVAR("gameversion");
 337                 BADPREFIX("gameversion_");
 338                 BADCVAR("sv_namechangetimer");
 339
 340                 // allowed changes to server admins (please sync this to server.cfg)
 341                 // vi commands:
 342                 //   :/"impure"/,$d
 343                 //   :g!,^\/\/[^ /],d
 344                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 345                 //   :%!sort
 346                 // yes, this does contain some redundant stuff, don't really care
 347                 BADCVAR("bot_config_file");
 348                 BADCVAR("bot_number");
 349                 BADCVAR("bot_prefix");
 350                 BADCVAR("bot_suffix");
 351                 BADCVAR("capturelimit_override");
 352                 BADCVAR("fraglimit_override");
 353                 BADCVAR("gametype");
 354                 BADCVAR("g_antilag");
 355                 BADCVAR("g_balance_teams");
 356                 BADCVAR("g_balance_teams_prevent_imbalance");
 357                 BADCVAR("g_balance_teams_scorefactor");
 358                 BADCVAR("g_ban_sync_trusted_servers");
 359                 BADCVAR("g_ban_sync_uri");
 360                 BADCVAR("g_ca_teams_override");
 361                 BADCVAR("g_ctf_ignore_frags");
 362                 BADCVAR("g_domination_point_limit");
 363                 BADCVAR("g_freezetag_teams_override");
 364                 BADCVAR("g_friendlyfire");
 365                 BADCVAR("g_fullbrightitems");
 366                 BADCVAR("g_fullbrightplayers");
 367                 BADCVAR("g_keyhunt_point_limit");
 368                 BADCVAR("g_keyhunt_teams_override");
 369                 BADCVAR("g_lms_lives_override");
 370                 BADCVAR("g_maplist");
 371                 BADCVAR("g_maplist_check_waypoints");
 372                 BADCVAR("g_maplist_mostrecent_count");
 373                 BADCVAR("g_maplist_shuffle");
 374                 BADCVAR("g_maplist_votable");
 375                 BADCVAR("g_maplist_votable_abstain");
 376                 BADCVAR("g_maplist_votable_nodetail");
 377                 BADCVAR("g_maplist_votable_suggestions");
 378                 BADCVAR("g_maxplayers");
 379                 BADCVAR("g_mirrordamage");
 380                 BADCVAR("g_nexball_goallimit");
 381                 BADCVAR("g_powerups");
 382                 BADCVAR("g_start_delay");
 383                 BADCVAR("g_warmup");
 384                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 385                 BADCVAR("hostname");
 386                 BADCVAR("log_file");
 387                 BADCVAR("maxplayers");
 388                 BADCVAR("minplayers");
 389                 BADCVAR("net_address");
 390                 BADCVAR("port");
 391                 BADCVAR("rcon_password");
 392                 BADCVAR("rcon_restricted_commands");
 393                 BADCVAR("rcon_restricted_password");
 394                 BADCVAR("skill");
 395                 BADCVAR("sv_adminnick");
 396                 BADCVAR("sv_autoscreenshot");
 397                 BADCVAR("sv_autotaunt");
 398                 BADCVAR("sv_curl_defaulturl");
 399                 BADCVAR("sv_defaultcharacter");
 400                 BADCVAR("sv_defaultplayercolors");
 401                 BADCVAR("sv_defaultplayermodel");
 402                 BADCVAR("sv_defaultplayerskin");
 403                 BADCVAR("sv_maxidle");
 404                 BADCVAR("sv_maxrate");
 405                 BADCVAR("sv_motd");
 406                 BADCVAR("sv_public");
 407                 BADCVAR("sv_ready_restart");
 408                 BADCVAR("sv_status_privacy");
 409                 BADCVAR("sv_taunt");
 410                 BADCVAR("sv_vote_call");
 411                 BADCVAR("sv_vote_commands");
 412                 BADCVAR("sv_vote_majority_factor");
 413                 BADCVAR("sv_vote_master");
 414                 BADCVAR("sv_vote_master_commands");
 415                 BADCVAR("sv_vote_master_password");
 416                 BADCVAR("sv_vote_simple_majority_factor");
 417                 BADCVAR("teamplay_mode");
 418                 BADCVAR("timelimit_override");
 419                 BADCVAR("g_spawnshieldtime");
 420                 BADPREFIX("g_warmup_");
 421                 BADPREFIX("sv_ready_restart_");
 422
 423                 // mutators that announce themselves properly to the server browser
 424                 BADCVAR("g_minstagib");
 425                 BADCVAR("g_new_toys");
 426                 BADCVAR("g_nix");
 427                 BADCVAR("g_grappling_hook");
 428                 BADCVAR("g_jetpack");
 429
 430 #undef BADPREFIX
 431 #undef BADCVAR
 432
 433                 if(pureadding)
 434                 {
 435                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 436                         if(strlen(cvar_purechanges) > 16384)
 437                         {
 438                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 439                                 pureadding = 0;
 440                         }
 441                 }
 442                 ++cvar_purechanges_count;
 443                 // WARNING: this variable is used for the server list
 444                 // NEVER dare to skip this code!
 445                 // Hacks to intentionally appearing as "pure server" even though you DO have
 446                 // modified settings may be punished by removal from the server list.
 447                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 448                 // though.
 449         }
 450         buf_del(h);
 451         if(cvar_changes == "")
 452                 cvar_changes = "// this server runs at default server settings\n";
 453         else
 454                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 455         cvar_changes = strzone(cvar_changes);
 456         if(cvar_purechanges == "")
 457                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 458         else
 459                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 460         cvar_purechanges = strzone(cvar_purechanges);
 461 }
 462
 463 void detect_maptype()
 464 {
 465 #if 0
 466         vector o, v;
 467         float i;
 468
 469         for(;;)
 470         {
 471                 o = world.mins;
 472                 o_x += random() * (world.maxs_x - world.mins_x);
 473                 o_y += random() * (world.maxs_y - world.mins_y);
 474                 o_z += random() * (world.maxs_z - world.mins_z);
 475
 476                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 477                 if(trace_fraction == 1)
 478                         continue;
 479
 480                 v = trace_endpos;
 481
 482                 for(i = 0; i < 64; i += 4)
 483                 {
 484                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 485         if(trace_fraction == 1)
 486                 continue;
 487                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 488                 }
 489
 490                 break;
 491         }
 492 #endif
 493 }
 494
 495 entity randomseed;
 496 float RandomSeed_Send(entity to, float sf)
 497 {
 498         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 499         WriteShort(MSG_ENTITY, self.cnt);
 500         return TRUE;
 501 }
 502 void RandomSeed_Think()
 503 {
 504         self.cnt = bound(0, floor(random() * 65536), 65535);
 505         self.nextthink = time + 5;
 506
 507         self.SendFlags |= 1;
 508 }
 509 void RandomSeed_Spawn()
 510 {
 511         randomseed = spawn();
 512         randomseed.think = RandomSeed_Think;
 513         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 514
 515         entity oldself;
 516         oldself = self;
 517         self = randomseed;
 518         self.think(); // sets random seed and nextthink
 519         self = oldself;
 520 }
 521
 522 void spawnfunc___init_dedicated_server(void)
 523 {
 524         // handler for _init/_init map (only for dedicated server initialization)
 525
 526         world_initialized = -1; // don't complain
 527         cvar = cvar_normal;
 528         cvar_string = cvar_string_normal;
 529         cvar_set = cvar_set_normal;
 530
 531         remove = remove_unsafely;
 532
 533         entity e;
 534         e = spawn();
 535         e.think = GotoFirstMap;
 536         e.nextthink = time; // this is usually 1 at this point
 537
 538         e = spawn();
 539         e.classname = "info_player_deathmatch"; // safeguard against player joining
 540
 541         self.classname = "worldspawn"; // safeguard against various stuff ;)
 542
 543         // needs to be done so early because of the constants they create
 544         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 545         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 546         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 547         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 548         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 591
 592         // needs to be done so early because of the constants they create
 593         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 594         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 595         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 596         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 597         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 598
 599         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 600
 601         TemporaryDB = db_create();
 602
 603         // 0 normal
 604         lightstyle(0, "m");
 605
 606         // 1 FLICKER (first variety)
 607         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 608
 609         // 2 SLOW STRONG PULSE
 610         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 611
 612         // 3 CANDLE (first variety)
 613         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 614
 615         // 4 FAST STROBE
 616         lightstyle(4, "mamamamamama");
 617
 618         // 5 GENTLE PULSE 1
 619         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 620
 621         // 6 FLICKER (second variety)
 622         lightstyle(6, "nmonqnmomnmomomno");
 623
 624         // 7 CANDLE (second variety)
 625         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 626
 627         // 8 CANDLE (third variety)
 628         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 629
 630         // 9 SLOW STROBE (fourth variety)
 631         lightstyle(9, "aaaaaaaazzzzzzzz");
 632
 633         // 10 FLUORESCENT FLICKER
 634         lightstyle(10, "mmamammmmammamamaaamammma");
 635
 636         // 11 SLOW PULSE NOT FADE TO BLACK
 637         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 638
 639         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 640
 641         // 63 testing
 642         lightstyle(63, "a");
 643
 644         if(autocvar_g_campaign)
 645                 CampaignPreInit();
 646
 647         Map_MarkAsRecent(mapname);
 648
 649         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 650
 651         precache_model ("null"); // we need this one before InitGameplayMode
 652         InitGameplayMode();
 653         readlevelcvars();
 654         GrappleHookInit();
 655
 656         player_count = 0;
 657         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 658         if(bot_waypoints_for_items == 1)
 659                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 660                         bot_waypoints_for_items = 0;
 661
 662         precache();
 663
 664         WaypointSprite_Init();
 665
 666         GameLogInit(); // prepare everything
 667         // NOTE for matchid:
 668         // changing the logic generating it is okay. But:
 669         // it HAS to stay <= 64 chars
 670         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 671         if(autocvar_sv_eventlog)
 672         {
 673                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 674                 matchid = strzone(s);
 675
 676                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 677                 s = ":gameinfo:mutators:LIST";
 678
 679                 ret_string = s;
 680                 MUTATOR_CALLHOOK(BuildMutatorsString);
 681                 s = ret_string;
 682
 683                 // simple, probably not good in the mutator system
 684                 if(autocvar_g_grappling_hook)
 685                         s = strcat(s, ":grappling_hook");
 686
 687                 // initialiation stuff, not good in the mutator system
 688                 if(!autocvar_g_use_ammunition)
 689                         s = strcat(s, ":no_use_ammunition");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(autocvar_g_pickup_items == 0)
 693                         s = strcat(s, ":no_pickup_items");
 694                 if(autocvar_g_pickup_items > 0)
 695                         s = strcat(s, ":pickup_items");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(autocvar_g_weaponarena != "0")
 699                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 700
 701                 // TODO to mutator system
 702                 if(autocvar_g_norecoil)
 703                         s = strcat(s, ":norecoil");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_powerups == 0)
 707                         s = strcat(s, ":no_powerups");
 708                 if(autocvar_g_powerups > 0)
 709                         s = strcat(s, ":powerups");
 710
 711                 GameLogEcho(s);
 712                 GameLogEcho(":gameinfo:end");
 713         }
 714         else
 715                 matchid = strzone(ftos(random()));
 716
 717         cvar_set("nextmap", "");
 718
 719         SetDefaultAlpha();
 720
 721         if(autocvar_g_campaign)
 722                 CampaignPostInit();
 723
 724         fteqcc_testbugs();
 725
 726         Ban_LoadBans();
 727
 728         MapInfo_Enumerate();
 729         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 730
 731         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 732         {
 733                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 734                 if(fd != -1)
 735                 {
 736                         while((s = fgets(fd)))
 737                         {
 738                                 l = tokenize_console(s);
 739                                 if(l < 2)
 740                                         continue;
 741                                 if(argv(0) == "cd")
 742                                 {
 743                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 744                                         print("  cdtrack ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) == "fog")
 747                                 {
 748                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 749                                         print("  \"fog\" \"", s, "\"\n");
 750                                 }
 751                                 else if(argv(0) == "set")
 752                                 {
 753                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 754                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 755                                 }
 756                                 else if(argv(0) != "//")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 760                                 }
 761                         }
 762                         fclose(fd);
 763                 }
 764         }
 765
 766         WeaponStats_Init();
 767
 768         WepSet_AddStat();
 769         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 770         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 771         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 772         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 773         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 774         Nagger_Init();
 775
 776         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 777         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 778         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 779         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 780         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 781         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 782         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 783         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 784         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 785         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 786         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 787         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 788         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 789         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 790
 791         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 792         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 793
 794         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 795
 796         // g_movementspeed hack
 797         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 798         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 799         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 800         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 801
 802         // secrets
 803         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 804         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 805
 806         // monsters
 807         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 808         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 809
 810         // misc
 811         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 812
 813         next_pingtime = time + 5;
 814
 815         detect_maptype();
 816
 817         // set up information replies for clients and server to use
 818         maplist_reply = strzone(getmaplist());
 819         lsmaps_reply = strzone(getlsmaps());
 820         monsterlist_reply = strzone(getmonsterlist());
 821         for(i = 0; i < 10; ++i)
 822         {
 823                 s = getrecords(i);
 824                 if (s)
 825                         records_reply[i] = strzone(s);
 826         }
 827         ladder_reply = strzone(getladder());
 828         rankings_reply = strzone(getrankings());
 829
 830         // begin other init
 831         ClientInit_Spawn();
 832         RandomSeed_Spawn();
 833         PingPLReport_Spawn();
 834
 835         CheatInit();
 836
 837         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 838
 839         // fill sv_curl_serverpackages from .serverpackage files
 840         if(autocvar_sv_curl_serverpackages_auto)
 841         {
 842                 s = "";
 843                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 844                 for(i = 0; i < n; ++i)
 845                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 846                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 847                                 s = strcat(s, " ", argv(i));
 848                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 849                 if(fd >= 0)
 850                 {
 851                         j = search_getsize(fd);
 852                         for(i = 0; i < j; ++i)
 853                                 s = strcat(s, " ", search_getfilename(fd, i));
 854                         search_end(fd);
 855                 }
 856                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 857                 if(fd >= 0)
 858                 {
 859                         j = search_getsize(fd);
 860                         for(i = 0; i < j; ++i)
 861                                 s = strcat(s, " ", search_getfilename(fd, i));
 862                         search_end(fd);
 863                 }
 864                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 865         }
 866
 867         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 868         modname = "Xonotic";
 869         // physics/balance/config changes that count as mod
 870         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 871                 modname = cvar_string("g_mod_physics");
 872         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 873                 modname = cvar_string("g_mod_balance");
 874         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 875                 modname = cvar_string("g_mod_config");
 876         // extra mutators that deserve to count as mod
 877         MUTATOR_CALLHOOK(SetModname);
 878
 879         // save it for later
 880         modname = strzone(modname);
 881
 882         WinningConditionHelper(); // set worldstatus
 883
 884         world_initialized = 1;
 885 }
 886
 887 void spawnfunc_light (void)
 888 {
 889         //makestatic (self); // Who the f___ did that?
 890         remove(self);
 891 }
 892
 893 string GetGametype()
 894 {
 895         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 896 }
 897
 898 string getmapname_stored;
 899 string GetMapname()
 900 {
 901         return mapname;
 902 }
 903
 904 float Map_Count, Map_Current;
 905 string Map_Current_Name;
 906
 907 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 908 float GetMaplistPosition()
 909 {
 910         float pos, idx;
 911         string map;
 912
 913         map = GetMapname();
 914         idx = autocvar_g_maplist_index;
 915
 916         if(idx >= 0)
 917                 if(idx < Map_Count)
 918                         if(map == argv(idx))
 919                                 return idx;
 920
 921         for(pos = 0; pos < Map_Count; ++pos)
 922                 if(map == argv(pos))
 923                         return pos;
 924
 925         // resume normal maplist rotation if current map is not in g_maplist
 926         return idx;
 927 }
 928
 929 float MapHasRightSize(string map)
 930 {
 931         float fh;
 932         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 933         if(autocvar_g_maplist_check_waypoints)
 934         {
 935                 dprint("checkwp "); dprint(map);
 936                 if(!fexists(strcat("maps/", map, ".waypoints")))
 937                 {
 938                         dprint(": no waypoints\n");
 939                         return FALSE;
 940                 }
 941                 dprint(": has waypoints\n");
 942         }
 943
 944         // open map size restriction file
 945         dprint("opensize "); dprint(map);
 946         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 947         if(fh >= 0)
 948         {
 949                 float mapmin, mapmax;
 950                 dprint(": ok, ");
 951                 mapmin = stof(fgets(fh));
 952                 mapmax = stof(fgets(fh));
 953                 fclose(fh);
 954                 if(player_count < mapmin)
 955                 {
 956                         dprint("not enough\n");
 957                         return FALSE;
 958                 }
 959                 if(player_count > mapmax)
 960                 {
 961                         dprint("too many\n");
 962                         return FALSE;
 963                 }
 964                 dprint("right size\n");
 965                 return TRUE;
 966         }
 967         dprint(": not found\n");
 968         return TRUE;
 969 }
 970
 971 string Map_Filename(float position)
 972 {
 973         return strcat("maps/", argv(position), ".bsp");
 974 }
 975
 976 string strwords(string s, float w)
 977 {
 978         float endpos;
 979         for(endpos = 0; w && endpos >= 0; --w)
 980                 endpos = strstrofs(s, " ", endpos + 1);
 981         if(endpos < 0)
 982                 return s;
 983         else
 984                 return substring(s, 0, endpos);
 985 }
 986
 987 float strhasword(string s, string w)
 988 {
 989         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 990 }
 991
 992 void Map_MarkAsRecent(string m)
 993 {
 994         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 995 }
 996
 997 float Map_IsRecent(string m)
 998 {
 999         return strhasword(autocvar_g_maplist_mostrecent, m);
1000 }
1001
1002 float Map_Check(float position, float pass)
1003 {
1004         string filename;
1005         string map_next;
1006         map_next = argv(position);
1007         if(pass <= 1)
1008         {
1009                 if(Map_IsRecent(map_next))
1010                         return 0;
1011         }
1012         filename = Map_Filename(position);
1013         if(MapInfo_CheckMap(map_next))
1014         {
1015                 if(pass == 2)
1016                         return 1;
1017                 if(MapHasRightSize(map_next))
1018                         return 1;
1019                 return 0;
1020         }
1021         else
1022                 dprint( "Couldn't select '", filename, "'..\n" );
1023
1024         return 0;
1025 }
1026
1027 void Map_Goto_SetStr(string nextmapname)
1028 {
1029         if(getmapname_stored != "")
1030                 strunzone(getmapname_stored);
1031         if(nextmapname == "")
1032                 getmapname_stored = "";
1033         else
1034                 getmapname_stored = strzone(nextmapname);
1035 }
1036
1037 void Map_Goto_SetFloat(float position)
1038 {
1039         cvar_set("g_maplist_index", ftos(position));
1040         Map_Goto_SetStr(argv(position));
1041 }
1042
1043 void Map_Goto(float reinit)
1044 {
1045         MapInfo_LoadMap(getmapname_stored, reinit);
1046 }
1047
1048 // return codes of map selectors:
1049 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1050 //   -2 = permanent failure
1051 float() MaplistMethod_Iterate = // usual method
1052 {
1053         float pass, i;
1054
1055         dprint("Trying MaplistMethod_Iterate\n");
1056
1057         for(pass = 1; pass <= 2; ++pass)
1058         {
1059                 for(i = 1; i < Map_Count; ++i)
1060                 {
1061                         float mapindex;
1062                         mapindex = mod(i + Map_Current, Map_Count);
1063                         if(Map_Check(mapindex, pass))
1064                                 return mapindex;
1065                 }
1066         }
1067         return -1;
1068 }
1069
1070 float() MaplistMethod_Repeat = // fallback method
1071 {
1072         dprint("Trying MaplistMethod_Repeat\n");
1073
1074         if(Map_Check(Map_Current, 2))
1075                 return Map_Current;
1076         return -2;
1077 }
1078
1079 float() MaplistMethod_Random = // random map selection
1080 {
1081         float i, imax;
1082
1083         dprint("Trying MaplistMethod_Random\n");
1084
1085         imax = 42;
1086
1087         for(i = 0; i <= imax; ++i)
1088         {
1089                 float mapindex;
1090                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1091                 if(Map_Check(mapindex, 1))
1092                         return mapindex;
1093         }
1094         return -1;
1095 }
1096
1097 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1098 // the exponent sets a bias on the map selection:
1099 // the higher the exponent, the less likely "shortly repeated" same maps are
1100 {
1101         float i, j, imax, insertpos;
1102
1103         dprint("Trying MaplistMethod_Shuffle\n");
1104
1105         imax = 42;
1106
1107         for(i = 0; i <= imax; ++i)
1108         {
1109                 string newlist;
1110
1111                 // now reinsert this at another position
1112                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1113                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1114                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1115                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1116
1117                 // insert the current map there
1118                 newlist = "";
1119                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1120                         newlist = strcat(newlist, " ", argv(j));
1121                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1122                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1123                         newlist = strcat(newlist, " ", argv(j));
1124                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1125                 cvar_set("g_maplist", newlist);
1126                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1127
1128                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1129                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1130                 if(Map_Check(Map_Current, 1))
1131                         return Map_Current;
1132         }
1133         return -1;
1134 }
1135
1136 void Maplist_Init()
1137 {
1138         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1139         float i;
1140         for (i = 0; i < Map_Count; ++i)
1141                 if (Map_Check(i, 2))
1142                         break;
1143         if (i == Map_Count)
1144         {
1145                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1146                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1147                 if(autocvar_g_maplist_shuffle)
1148                         ShuffleMaplist();
1149                 localcmd("\nmenu_cmd sync\n");
1150                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1151         }
1152         if(Map_Count == 0)
1153                 error("empty maplist, cannot select a new map");
1154         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1155
1156         if(Map_Current_Name)
1157                 strunzone(Map_Current_Name);
1158         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1159         // this may or may not be correct, but who cares, in the worst case a map
1160         // isn't chosen in the first pass that should have been
1161 }
1162
1163 string GetNextMap()
1164 {
1165         float nextMap;
1166
1167         Maplist_Init();
1168         nextMap = -1;
1169
1170         if(nextMap == -1)
1171                 if(autocvar_g_maplist_shuffle > 0)
1172                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1173
1174         if(nextMap == -1)
1175                 if(autocvar_g_maplist_selectrandom)
1176                         nextMap = MaplistMethod_Random();
1177
1178         if(nextMap == -1)
1179                 nextMap = MaplistMethod_Iterate();
1180
1181         if(nextMap == -1)
1182                 nextMap = MaplistMethod_Repeat();
1183
1184         if(nextMap >= 0)
1185         {
1186                 Map_Goto_SetFloat(nextMap);
1187                 return getmapname_stored;
1188         }
1189
1190         return "";
1191 }
1192
1193 float DoNextMapOverride(float reinit)
1194 {
1195         if(autocvar_g_campaign)
1196         {
1197                 CampaignPostIntermission();
1198                 alreadychangedlevel = TRUE;
1199                 return TRUE;
1200         }
1201         if(autocvar_quit_when_empty)
1202         {
1203                 if(player_count <= currentbots)
1204                 {
1205                         localcmd("quit\n");
1206                         alreadychangedlevel = TRUE;
1207                         return TRUE;
1208                 }
1209         }
1210         if(autocvar_quit_and_redirect != "")
1211         {
1212                 redirection_target = strzone(autocvar_quit_and_redirect);
1213                 alreadychangedlevel = TRUE;
1214                 return TRUE;
1215         }
1216         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1217         {
1218                 localcmd("restart\n");
1219                 alreadychangedlevel = TRUE;
1220                 return TRUE;
1221         }
1222         if(autocvar_nextmap != "")
1223                 if(MapInfo_CheckMap(autocvar_nextmap))
1224                 {
1225                         Map_Goto_SetStr(autocvar_nextmap);
1226                         Map_Goto(reinit);
1227                         alreadychangedlevel = TRUE;
1228                         return TRUE;
1229                 }
1230         if(!reinit && autocvar_lastlevel)
1231         {
1232                 cvar_settemp_restore();
1233                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1234                 alreadychangedlevel = TRUE;
1235                 return TRUE;
1236         }
1237         return FALSE;
1238 }
1239
1240 void GotoNextMap(float reinit)
1241 {
1242         //string nextmap;
1243         //float n, nummaps;
1244         //string s;
1245         if (alreadychangedlevel)
1246                 return;
1247         alreadychangedlevel = TRUE;
1248
1249         string nextMap;
1250
1251         nextMap = GetNextMap();
1252         if(nextMap == "")
1253                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1254         Map_Goto(reinit);
1255 }
1256
1257
1258 /*
1259 ============
1260 IntermissionThink
1261
1262 When the player presses attack or jump, change to the next level
1263 ============
1264 */
1265 .float autoscreenshot;
1266 void() MapVote_Start;
1267 void() MapVote_Think;
1268 float mapvote_initialized;
1269 void IntermissionThink()
1270 {
1271         FixIntermissionClient(self);
1272
1273         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1274         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1275
1276         if( (server_screenshot || client_screenshot)
1277                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1278         {
1279                 self.autoscreenshot = -1;
1280                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1281                 return;
1282         }
1283
1284         if (time < intermission_exittime)
1285                 return;
1286
1287         if(!mapvote_initialized)
1288                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1289                         return;
1290
1291         MapVote_Start();
1292 }
1293
1294 /*
1295 ============
1296 FindIntermission
1297
1298 Returns the entity to view from
1299 ============
1300 */
1301 /*
1302 entity FindIntermission()
1303 {
1304         local   entity spot;
1305         local   float cyc;
1306
1307 // look for info_intermission first
1308         spot = find (world, classname, "info_intermission");
1309         if (spot)
1310         {       // pick a random one
1311                 cyc = random() * 4;
1312                 while (cyc > 1)
1313                 {
1314                         spot = find (spot, classname, "info_intermission");
1315                         if (!spot)
1316                                 spot = find (spot, classname, "info_intermission");
1317                         cyc = cyc - 1;
1318                 }
1319                 return spot;
1320         }
1321
1322 // then look for the start position
1323         spot = find (world, classname, "info_player_start");
1324         if (spot)
1325                 return spot;
1326
1327 // testinfo_player_start is only found in regioned levels
1328         spot = find (world, classname, "testplayerstart");
1329         if (spot)
1330                 return spot;
1331
1332 // then look for the start position
1333         spot = find (world, classname, "info_player_deathmatch");
1334         if (spot)
1335                 return spot;
1336
1337         //objerror ("FindIntermission: no spot");
1338         return world;
1339 }
1340 */
1341
1342 /*
1343 ===============================================================================
1344
1345 RULES
1346
1347 ===============================================================================
1348 */
1349
1350 void DumpStats(float final)
1351 {
1352         float file;
1353         string s;
1354         float to_console;
1355         float to_eventlog;
1356         float to_file;
1357         float i;
1358
1359         to_console = autocvar_sv_logscores_console;
1360         to_eventlog = autocvar_sv_eventlog;
1361         to_file = autocvar_sv_logscores_file;
1362
1363         if(!final)
1364         {
1365                 to_console = TRUE; // always print printstats replies
1366                 to_eventlog = FALSE; // but never print them to the event log
1367         }
1368
1369         if(to_eventlog)
1370                 if(autocvar_sv_eventlog_console)
1371                         to_console = FALSE; // otherwise we get the output twice
1372
1373         if(final)
1374                 s = ":scores:";
1375         else
1376                 s = ":status:";
1377         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1378
1379         if(to_console)
1380                 print(s, "\n");
1381         if(to_eventlog)
1382                 GameLogEcho(s);
1383
1384         file = -1;
1385         if(to_file)
1386         {
1387                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1388                 if(file == -1)
1389                         to_file = FALSE;
1390                 else
1391                         fputs(file, strcat(s, "\n"));
1392         }
1393
1394         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1395         if(to_console)
1396                 print(s, "\n");
1397         if(to_eventlog)
1398                 GameLogEcho(s);
1399         if(to_file)
1400                 fputs(file, strcat(s, "\n"));
1401
1402         FOR_EACH_CLIENT(other)
1403         {
1404                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1405                 {
1406                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1407                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1408                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1409                                 s = strcat(s, ftos(other.team), ":");
1410                         else
1411                                 s = strcat(s, "spectator:");
1412
1413                         if(to_console)
1414                                 print(s, other.netname, "\n");
1415                         if(to_eventlog)
1416                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1417                         if(to_file)
1418                                 fputs(file, strcat(s, other.netname, "\n"));
1419                 }
1420         }
1421
1422         if(teamplay)
1423         {
1424                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1425                 if(to_console)
1426                         print(s, "\n");
1427                 if(to_eventlog)
1428                         GameLogEcho(s);
1429                 if(to_file)
1430                         fputs(file, strcat(s, "\n"));
1431
1432                 for(i = 1; i < 16; ++i)
1433                 {
1434                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1435                         s = strcat(s, ":", ftos(i));
1436                         if(to_console)
1437                                 print(s, "\n");
1438                         if(to_eventlog)
1439                                 GameLogEcho(s);
1440                         if(to_file)
1441                                 fputs(file, strcat(s, "\n"));
1442                 }
1443         }
1444
1445         if(to_console)
1446                 print(":end\n");
1447         if(to_eventlog)
1448                 GameLogEcho(":end");
1449         if(to_file)
1450         {
1451                 fputs(file, ":end\n");
1452                 fclose(file);
1453         }
1454 }
1455
1456 void FixIntermissionClient(entity e)
1457 {
1458         string s;
1459         if(!e.autoscreenshot) // initial call
1460         {
1461                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1462                 e.health = -2342;
1463                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1464                 e.solid = SOLID_NOT;
1465                 e.movetype = MOVETYPE_NONE;
1466                 e.takedamage = DAMAGE_NO;
1467                 if(e.weaponentity)
1468                 {
1469                         e.weaponentity.effects = EF_NODRAW;
1470                         if (e.weaponentity.weaponentity)
1471                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1472                 }
1473                 if(IS_REAL_CLIENT(e))
1474                 {
1475                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1476                         s = autocvar_sv_intermission_cdtrack;
1477                         if(s != "")
1478                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1479                         msg_entity = e;
1480                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1481                 }
1482         }
1483 }
1484
1485 /*
1486 go to the next level for deathmatch
1487 only called if a time or frag limit has expired
1488 */
1489 void NextLevel()
1490 {
1491         gameover = TRUE;
1492
1493         intermission_running = 1;
1494
1495 // enforce a wait time before allowing changelevel
1496         if(player_count > 0)
1497                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1498         else
1499                 intermission_exittime = -1;
1500
1501         /*
1502         WriteByte (MSG_ALL, SVC_CDTRACK);
1503         WriteByte (MSG_ALL, 3);
1504         WriteByte (MSG_ALL, 3);
1505         // done in FixIntermission
1506         */
1507
1508         //pos = FindIntermission ();
1509
1510         VoteReset();
1511
1512         DumpStats(TRUE);
1513
1514         // send statistics
1515         entity e;
1516         PlayerStats_EndMatch(1);
1517         FOR_EACH_CLIENT(e)
1518                 PlayerStats_AddGlobalInfo(e);
1519         PlayerStats_Shutdown();
1520         WeaponStats_Shutdown();
1521
1522         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1523
1524         if(autocvar_sv_eventlog)
1525                 GameLogEcho(":gameover");
1526
1527         GameLogClose();
1528
1529         FOR_EACH_PLAYER(other) {
1530                 FixIntermissionClient(other);
1531                 if(other.winning)
1532                         bprint(other.netname, " ^7wins.\n");
1533         }
1534
1535         if(autocvar_g_campaign)
1536                 CampaignPreIntermission();
1537
1538         MUTATOR_CALLHOOK(MatchEnd);
1539
1540         localcmd("\nsv_hook_gameend\n");
1541 }
1542
1543 /*
1544 ============
1545 CheckRules_Player
1546
1547 Exit deathmatch games upon conditions
1548 ============
1549 */
1550 void CheckRules_Player()
1551 {
1552         if (gameover)   // someone else quit the game already
1553                 return;
1554
1555         if(self.deadflag == DEAD_NO)
1556                 self.play_time += frametime;
1557
1558         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1559         //   (div0: and that in CheckRules_World please)
1560 }
1561
1562 float checkrules_equality;
1563 float checkrules_suddendeathwarning;
1564 float checkrules_suddendeathend;
1565 float checkrules_overtimesadded; //how many overtimes have been already added
1566
1567 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1568 const float WINNING_YES = 1; // winner found
1569 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1570 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1571
1572 float InitiateSuddenDeath()
1573 {
1574         // Check first whether normal overtimes could be added before initiating suddendeath mode
1575         // - for this timelimit_overtime needs to be >0 of course
1576         // - also check the winning condition calculated in the previous frame and only add normal overtime
1577         //   again, if at the point at which timelimit would be extended again, still no winner was found
1578         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1579         {
1580                 return 1; // need to call InitiateOvertime later
1581         }
1582         else
1583         {
1584                 if(!checkrules_suddendeathend)
1585                 {
1586                         if(autocvar_g_campaign)
1587                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1588                         else
1589                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1590                         if(g_race && !g_race_qualifying)
1591                                 race_StartCompleting();
1592                 }
1593                 return 0;
1594         }
1595 }
1596
1597 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1598 {
1599         ++checkrules_overtimesadded;
1600         //add one more overtime by simply extending the timelimit
1601         float tl;
1602         tl = autocvar_timelimit;
1603         tl += autocvar_timelimit_overtime;
1604         cvar_set("timelimit", ftos(tl));
1605
1606         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1607 }
1608
1609 float GetWinningCode(float fraglimitreached, float equality)
1610 {
1611         if(autocvar_g_campaign == 1)
1612                 if(fraglimitreached)
1613                         return WINNING_YES;
1614                 else
1615                         return WINNING_NO;
1616
1617         else
1618                 if(equality)
1619                         if(fraglimitreached)
1620                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1621                         else
1622                                 return WINNING_NEVER;
1623                 else
1624                         if(fraglimitreached)
1625                                 return WINNING_YES;
1626                         else
1627                                 return WINNING_NO;
1628 }
1629
1630 // set the .winning flag for exactly those players with a given field value
1631 void SetWinners(.float field, float value)
1632 {
1633         entity head;
1634         FOR_EACH_PLAYER(head)
1635                 head.winning = (head.field == value);
1636 }
1637
1638 // set the .winning flag for those players with a given field value
1639 void AddWinners(.float field, float value)
1640 {
1641         entity head;
1642         FOR_EACH_PLAYER(head)
1643                 if(head.field == value)
1644                         head.winning = 1;
1645 }
1646
1647 // clear the .winning flags
1648 void ClearWinners(void)
1649 {
1650         entity head;
1651         FOR_EACH_PLAYER(head)
1652                 head.winning = 0;
1653 }
1654
1655 // Onslaught winning condition:
1656 // game terminates if only one team has a working generator (or none)
1657 float WinningCondition_Onslaught()
1658 {
1659         entity head;
1660         float t1, t2, t3, t4;
1661
1662         WinningConditionHelper(); // set worldstatus
1663
1664         if(warmup_stage)
1665                 return WINNING_NO;
1666
1667         // first check if the game has ended
1668         t1 = t2 = t3 = t4 = 0;
1669         head = find(world, classname, "onslaught_generator");
1670         while (head)
1671         {
1672                 if (head.health > 0)
1673                 {
1674                         if (head.team == NUM_TEAM_1) t1 = 1;
1675                         if (head.team == NUM_TEAM_2) t2 = 1;
1676                         if (head.team == NUM_TEAM_3) t3 = 1;
1677                         if (head.team == NUM_TEAM_4) t4 = 1;
1678                 }
1679                 head = find(head, classname, "onslaught_generator");
1680         }
1681         if (t1 + t2 + t3 + t4 < 2)
1682         {
1683                 // game over, only one team remains (or none)
1684                 ClearWinners();
1685                 if (t1) SetWinners(team, NUM_TEAM_1);
1686                 if (t2) SetWinners(team, NUM_TEAM_2);
1687                 if (t3) SetWinners(team, NUM_TEAM_3);
1688                 if (t4) SetWinners(team, NUM_TEAM_4);
1689                 dprint("Have a winner, ending game.\n");
1690                 return WINNING_YES;
1691         }
1692
1693         // Two or more teams remain
1694         return WINNING_NO;
1695 }
1696
1697 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1698 // they win. Otherwise the defending team wins once the timelimit passes.
1699 void assault_new_round();
1700 float WinningCondition_Assault()
1701 {
1702         float status;
1703
1704         WinningConditionHelper(); // set worldstatus
1705
1706         status = WINNING_NO;
1707         // as the timelimit has not yet passed just assume the defending team will win
1708         if(assault_attacker_team == NUM_TEAM_1)
1709         {
1710                 SetWinners(team, NUM_TEAM_2);
1711         }
1712         else
1713         {
1714                 SetWinners(team, NUM_TEAM_1);
1715         }
1716
1717         entity ent;
1718         ent = find(world, classname, "target_assault_roundend");
1719         if(ent)
1720         {
1721                 if(ent.winning) // round end has been triggered by attacking team
1722                 {
1723                         bprint("ASSAULT: round completed...\n");
1724                         SetWinners(team, assault_attacker_team);
1725
1726                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1727
1728                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1729                         {
1730                                 status = WINNING_YES;
1731                         }
1732                         else
1733                         {
1734                                 entity oldself;
1735                                 oldself = self;
1736                                 self = ent;
1737                                 assault_new_round();
1738                                 self = oldself;
1739                         }
1740                 }
1741         }
1742
1743         return status;
1744 }
1745
1746 // LMS winning condition: game terminates if and only if there's at most one
1747 // one player who's living lives. Top two scores being equal cancels the time
1748 // limit.
1749 float WinningCondition_LMS()
1750 {
1751         entity head, head2;
1752         float have_player;
1753         float have_players;
1754         float l;
1755
1756         have_player = FALSE;
1757         have_players = FALSE;
1758         l = LMS_NewPlayerLives();
1759
1760         head = find(world, classname, "player");
1761         if(head)
1762                 have_player = TRUE;
1763         head2 = find(head, classname, "player");
1764         if(head2)
1765                 have_players = TRUE;
1766
1767         if(have_player)
1768         {
1769                 // we have at least one player
1770                 if(have_players)
1771                 {
1772                         // two or more active players - continue with the game
1773                 }
1774                 else
1775                 {
1776                         // exactly one player?
1777
1778                         ClearWinners();
1779                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1780
1781                         if(l)
1782                         {
1783                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1784                                 return WINNING_NO;
1785                         }
1786                         else
1787                         {
1788                                 // a winner!
1789                                 // and assign him his first place
1790                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1791                                 return WINNING_YES;
1792                         }
1793                 }
1794         }
1795         else
1796         {
1797                 // nobody is playing at all...
1798                 if(l)
1799                 {
1800                         // wait for players...
1801                 }
1802                 else
1803                 {
1804                         // SNAFU (maybe a draw game?)
1805                         ClearWinners();
1806                         dprint("No players, ending game.\n");
1807                         return WINNING_YES;
1808                 }
1809         }
1810
1811         // When we get here, we have at least two players who are actually LIVING,
1812         // now check if the top two players have equal score.
1813         WinningConditionHelper();
1814
1815         ClearWinners();
1816         if(WinningConditionHelper_winner)
1817                 WinningConditionHelper_winner.winning = TRUE;
1818         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1819                 return WINNING_NEVER;
1820
1821         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1822         return WINNING_NO;
1823 }
1824
1825 void ShuffleMaplist()
1826 {
1827         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1828 }
1829
1830 float leaderfrags;
1831 float WinningCondition_Scores(float limit, float leadlimit)
1832 {
1833         float limitreached;
1834
1835         // TODO make everything use THIS winning condition (except LMS)
1836         WinningConditionHelper();
1837
1838         if(teamplay)
1839         {
1840                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1841                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1842                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1843                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1844         }
1845
1846         ClearWinners();
1847         if(WinningConditionHelper_winner)
1848                 WinningConditionHelper_winner.winning = 1;
1849         if(WinningConditionHelper_winnerteam >= 0)
1850                 SetWinners(team, WinningConditionHelper_winnerteam);
1851
1852         if(WinningConditionHelper_lowerisbetter)
1853         {
1854                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1855                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1856                 limit = -limit;
1857         }
1858
1859         if(WinningConditionHelper_zeroisworst)
1860                 leadlimit = 0; // not supported in this mode
1861
1862         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1863         // these modes always score in increments of 1, thus this makes sense
1864         {
1865                 if(leaderfrags != WinningConditionHelper_topscore)
1866                 {
1867                         leaderfrags = WinningConditionHelper_topscore;
1868
1869                         if (limit)
1870                         if (leaderfrags == limit - 1)
1871                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1872                         else if (leaderfrags == limit - 2)
1873                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1874                         else if (leaderfrags == limit - 3)
1875                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1876                 }
1877         }
1878
1879         limitreached = FALSE;
1880         if(limit)
1881                 if(WinningConditionHelper_topscore >= limit)
1882                         limitreached = TRUE;
1883         if(leadlimit)
1884         {
1885                 float leadlimitreached;
1886                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1887                 if(autocvar_leadlimit_and_fraglimit)
1888                         limitreached = (limitreached && leadlimitreached);
1889                 else
1890                         limitreached = (limitreached || leadlimitreached);
1891         }
1892
1893         if(limit)
1894                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1895
1896         return GetWinningCode(
1897                 WinningConditionHelper_topscore && limitreached,
1898                 WinningConditionHelper_equality
1899         );
1900 }
1901
1902 float WinningCondition_Race(float fraglimit)
1903 {
1904         float wc;
1905         entity p;
1906         float n, c;
1907
1908         n = 0;
1909         c = 0;
1910         FOR_EACH_PLAYER(p)
1911         {
1912                 ++n;
1913                 if(p.race_completed)
1914                         ++c;
1915         }
1916         if(n && (n == c))
1917                 return WINNING_YES;
1918         wc = WinningCondition_Scores(fraglimit, 0);
1919
1920         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1921         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1922         // do NOT support equality when the laps are all raced!
1923                 return WINNING_STARTSUDDENDEATHOVERTIME;
1924         else
1925                 return WINNING_NEVER;
1926 }
1927
1928 float WinningCondition_QualifyingThenRace(float limit)
1929 {
1930         float wc;
1931         wc = WinningCondition_Scores(limit, 0);
1932
1933         // NEVER initiate overtime
1934         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1935         {
1936                 return WINNING_YES;
1937         }
1938
1939         return wc;
1940 }
1941
1942 float WinningCondition_RanOutOfSpawns()
1943 {
1944         entity head;
1945
1946         if(have_team_spawns <= 0)
1947                 return WINNING_NO;
1948
1949         if(autocvar_g_spawn_useallspawns <= 0)
1950                 return WINNING_NO;
1951
1952         if(!some_spawn_has_been_used)
1953                 return WINNING_NO;
1954
1955         team1_score = team2_score = team3_score = team4_score = 0;
1956
1957         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1958         {
1959                 if(head.team == NUM_TEAM_1)
1960                         team1_score = 1;
1961                 else if(head.team == NUM_TEAM_2)
1962                         team2_score = 1;
1963                 else if(head.team == NUM_TEAM_3)
1964                         team3_score = 1;
1965                 else if(head.team == NUM_TEAM_4)
1966                         team4_score = 1;
1967         }
1968
1969         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1970         {
1971                 if(head.team == NUM_TEAM_1)
1972                         team1_score = 1;
1973                 else if(head.team == NUM_TEAM_2)
1974                         team2_score = 1;
1975                 else if(head.team == NUM_TEAM_3)
1976                         team3_score = 1;
1977                 else if(head.team == NUM_TEAM_4)
1978                         team4_score = 1;
1979         }
1980
1981         ClearWinners();
1982         if(team1_score + team2_score + team3_score + team4_score == 0)
1983         {
1984                 checkrules_equality = TRUE;
1985                 return WINNING_YES;
1986         }
1987         else if(team1_score + team2_score + team3_score + team4_score == 1)
1988         {
1989                 float t, i;
1990                 if(team1_score)
1991                         t = NUM_TEAM_1;
1992                 else if(team2_score)
1993                         t = NUM_TEAM_2;
1994                 else if(team3_score)
1995                         t = NUM_TEAM_3;
1996                 else // if(team4_score)
1997                         t = NUM_TEAM_4;
1998                 CheckAllowedTeams(world);
1999                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2000                 {
2001                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2002                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2003                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2004                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2005                 }
2006
2007                 AddWinners(team, t);
2008                 return WINNING_YES;
2009         }
2010         else
2011                 return WINNING_NO;
2012 }
2013
2014 /*
2015 ============
2016 CheckRules_World
2017
2018 Exit deathmatch games upon conditions
2019 ============
2020 */
2021 void ReadyRestart();
2022 void CheckRules_World()
2023 {
2024         float timelimit;
2025         float fraglimit;
2026         float leadlimit;
2027
2028         VoteThink();
2029         MapVote_Think();
2030
2031         SetDefaultAlpha();
2032
2033         /*
2034         MapVote_Think should now do that part
2035         if (intermission_running)
2036                 if (time >= intermission_exittime + 60)
2037                 {
2038                         if(!DoNextMapOverride())
2039                                 GotoNextMap();
2040                         return;
2041                 }
2042         */
2043
2044         if (gameover)   // someone else quit the game already
2045         {
2046                 if(player_count == 0) // Nobody there? Then let's go to the next map
2047                         MapVote_Start();
2048                         // this will actually check the player count in the next frame
2049                         // again, but this shouldn't hurt
2050                 return;
2051         }
2052
2053         timelimit = autocvar_timelimit * 60;
2054         fraglimit = autocvar_fraglimit;
2055         leadlimit = autocvar_leadlimit;
2056
2057         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2058         {
2059                 if(timelimit > 0)
2060                         timelimit = 0; // timelimit is not made for warmup
2061                 if(fraglimit > 0)
2062                         fraglimit = 0; // no fraglimit for now
2063                 leadlimit = 0; // no leadlimit for now
2064         }
2065
2066         if(timelimit > 0)
2067         {
2068                 timelimit += game_starttime;
2069         }
2070         else if (timelimit < 0)
2071         {
2072                 // endmatch
2073                 NextLevel();
2074                 return;
2075         }
2076
2077         if(g_onslaught)
2078                 timelimit = 0; // ONS has its own overtime rule
2079
2080         float wantovertime;
2081         wantovertime = 0;
2082
2083         if(timelimit > game_starttime)
2084                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2085         else
2086                 game_completion_ratio = 0;
2087
2088         if(checkrules_suddendeathend)
2089         {
2090                 if(!checkrules_suddendeathwarning)
2091                 {
2092                         checkrules_suddendeathwarning = TRUE;
2093                         if(g_race && !g_race_qualifying)
2094                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2095                         else
2096                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2097                 }
2098         }
2099         else
2100         {
2101                 if (timelimit && time >= timelimit)
2102                 {
2103                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2104                         {
2105                                 float totalplayers;
2106                                 float playerswithlaps;
2107                                 float readyplayers;
2108                                 entity head;
2109                                 totalplayers = playerswithlaps = readyplayers = 0;
2110                                 FOR_EACH_PLAYER(head)
2111                                 {
2112                                         ++totalplayers;
2113                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2114                                                 ++playerswithlaps;
2115                                         if(head.ready)
2116                                                 ++readyplayers;
2117                                 }
2118
2119                                 // at least 2 of the players have completed a lap: start the RACE
2120                                 // otherwise, the players should end the qualifying on their own
2121                                 if(readyplayers || playerswithlaps >= 2)
2122                                 {
2123                                         checkrules_suddendeathend = 0;
2124                                         ReadyRestart(); // go to race
2125                                         return;
2126                                 }
2127                                 else
2128                                         wantovertime |= InitiateSuddenDeath();
2129                         }
2130                         else
2131                                 wantovertime |= InitiateSuddenDeath();
2132                 }
2133         }
2134
2135         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2136         {
2137                 NextLevel();
2138                 return;
2139         }
2140
2141         float checkrules_status;
2142         checkrules_status = WinningCondition_RanOutOfSpawns();
2143         if(checkrules_status == WINNING_YES)
2144         {
2145                 bprint("Hey! Someone ran out of spawns!\n");
2146         }
2147         else if(g_race && !g_race_qualifying && timelimit >= 0)
2148         {
2149                 checkrules_status = WinningCondition_Race(fraglimit);
2150                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2151         }
2152         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2153         {
2154                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2155                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2156         }
2157         else if(g_assault)
2158         {
2159                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2160         }
2161         else if(g_lms)
2162         {
2163                 checkrules_status = WinningCondition_LMS();
2164         }
2165         else if (g_onslaught)
2166         {
2167                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2168         }
2169         else
2170         {
2171                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2172                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2173         }
2174
2175         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2176         {
2177                 checkrules_status = WINNING_NEVER;
2178                 checkrules_overtimesadded = -1;
2179                 wantovertime |= InitiateSuddenDeath();
2180         }
2181
2182         if(checkrules_status == WINNING_NEVER)
2183                 // equality cases! Nobody wins if the overtime ends in a draw.
2184                 ClearWinners();
2185
2186         if(wantovertime)
2187         {
2188                 if(checkrules_status == WINNING_NEVER)
2189                         InitiateOvertime();
2190                 else
2191                         checkrules_status = WINNING_YES;
2192         }
2193
2194         if(checkrules_suddendeathend)
2195                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2196                         checkrules_status = WINNING_YES;
2197
2198         if(checkrules_status == WINNING_YES)
2199         {
2200                 //print("WINNING\n");
2201                 NextLevel();
2202         }
2203 }
2204
2205 float mapvote_nextthink;
2206 float mapvote_initialized;
2207 float mapvote_keeptwotime;
2208 float mapvote_timeout;
2209 string mapvote_message;
2210 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2211 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2212 float mapvote_screenshot_dirs_count;
2213
2214 float mapvote_count;
2215 float mapvote_count_real;
2216 string mapvote_maps[MAPVOTE_COUNT];
2217 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2218 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2219 float mapvote_maps_suggested[MAPVOTE_COUNT];
2220 string mapvote_suggestions[MAPVOTE_COUNT];
2221 float mapvote_suggestion_ptr;
2222 float mapvote_voters;
2223 float mapvote_selections[MAPVOTE_COUNT];
2224 float mapvote_run;
2225 float mapvote_detail;
2226 float mapvote_abstain;
2227 .float mapvote;
2228
2229 void MapVote_ClearAllVotes()
2230 {
2231         FOR_EACH_CLIENT(other)
2232                 other.mapvote = 0;
2233 }
2234
2235 string MapVote_Suggest(string m)
2236 {
2237         float i;
2238         if(m == "")
2239                 return "That's not how to use this command.";
2240         if(!autocvar_g_maplist_votable_suggestions)
2241                 return "Suggestions are not accepted on this server.";
2242         if(mapvote_initialized)
2243                 return "Can't suggest - voting is already in progress!";
2244         m = MapInfo_FixName(m);
2245         if (!m)
2246                 return "The map you suggested is not available on this server.";
2247         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2248                 if(Map_IsRecent(m))
2249                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2250
2251         if(!MapInfo_CheckMap(m))
2252                 return "The map you suggested does not support the current game mode.";
2253         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2254                 if(mapvote_suggestions[i] == m)
2255                         return "This map was already suggested.";
2256         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2257         {
2258                 i = floor(random() * mapvote_suggestion_ptr);
2259         }
2260         else
2261         {
2262                 i = mapvote_suggestion_ptr;
2263                 mapvote_suggestion_ptr += 1;
2264         }
2265         if(mapvote_suggestions[i] != "")
2266                 strunzone(mapvote_suggestions[i]);
2267         mapvote_suggestions[i] = strzone(m);
2268         if(autocvar_sv_eventlog)
2269                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2270         return strcat("Suggestion of ", m, " accepted.");
2271 }
2272
2273 void MapVote_AddVotable(string nextMap, float isSuggestion)
2274 {
2275         float j, i, o;
2276         string pakfile, mapfile;
2277
2278         if(nextMap == "")
2279                 return;
2280         for(j = 0; j < mapvote_count; ++j)
2281                 if(mapvote_maps[j] == nextMap)
2282                         return;
2283         // suggestions might be no longer valid/allowed after gametype switch!
2284         if(isSuggestion)
2285                 if(!MapInfo_CheckMap(nextMap))
2286                         return;
2287         mapvote_maps[mapvote_count] = strzone(nextMap);
2288         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2289
2290         pakfile = string_null;
2291         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2292         {
2293                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2294                 pakfile = whichpack(strcat(mapfile, ".tga"));
2295                 if(pakfile == "")
2296                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2297                 if(pakfile == "")
2298                         pakfile = whichpack(strcat(mapfile, ".png"));
2299                 if(pakfile != "")
2300                         break;
2301         }
2302         if(i >= mapvote_screenshot_dirs_count)
2303                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2304         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2305                 pakfile = substring(pakfile, o, -1);
2306
2307         mapvote_maps_screenshot_dir[mapvote_count] = i;
2308         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2309
2310         mapvote_count += 1;
2311 }
2312
2313 void MapVote_Spawn();
2314 void MapVote_Init()
2315 {
2316         float i;
2317         float nmax, smax;
2318
2319         MapVote_ClearAllVotes();
2320
2321         mapvote_count = 0;
2322         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2323         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2324
2325         if(mapvote_abstain)
2326                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2327         else
2328                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2329         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2330
2331         // we need this for AddVotable, as that cycles through the screenshot dirs
2332         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2333         if(mapvote_screenshot_dirs_count == 0)
2334                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2335         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2336         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2337                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2338
2339         if(mapvote_suggestion_ptr)
2340                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2341                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2342
2343         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2344                 MapVote_AddVotable(GetNextMap(), FALSE);
2345
2346         if(mapvote_count == 0)
2347         {
2348                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2349                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2350                 if(autocvar_g_maplist_shuffle)
2351                         ShuffleMaplist();
2352                 localcmd("\nmenu_cmd sync\n");
2353                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2354                         MapVote_AddVotable(GetNextMap(), FALSE);
2355         }
2356
2357         mapvote_count_real = mapvote_count;
2358         if(mapvote_abstain)
2359                 MapVote_AddVotable("don't care", 0);
2360
2361         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2362
2363         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2364         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2365         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2366                 mapvote_keeptwotime = 0;
2367         mapvote_message = "Choose a map and press its key!";
2368
2369         MapVote_Spawn();
2370 }
2371
2372 void MapVote_SendPicture(float id)
2373 {
2374         msg_entity = self;
2375         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2376         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2377         WriteByte(MSG_ONE, id);
2378         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2379 }
2380
2381 float MapVote_GetMapMask()
2382 {
2383         float mask, i, power;
2384         mask = 0;
2385         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2386                 if(mapvote_maps[i] != "")
2387                         mask |= power;
2388         return mask;
2389 }
2390
2391 entity mapvote_ent;
2392 float MapVote_SendEntity(entity to, float sf)
2393 {
2394         float i;
2395
2396         if(sf & 1)
2397                 sf &= ~2; // if we send 1, we don't need to also send 2
2398
2399         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2400         WriteByte(MSG_ENTITY, sf);
2401
2402         if(sf & 1)
2403         {
2404                 // flag 1 == initialization
2405                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2406                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2407                 WriteString(MSG_ENTITY, "");
2408                 WriteByte(MSG_ENTITY, mapvote_count);
2409                 WriteByte(MSG_ENTITY, mapvote_abstain);
2410                 WriteByte(MSG_ENTITY, mapvote_detail);
2411                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2412                 if(mapvote_count <= 8)
2413                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2414                 else
2415                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2416                 for(i = 0; i < mapvote_count; ++i)
2417                         if(mapvote_maps[i] != "")
2418                         {
2419                                 if(mapvote_abstain && i == mapvote_count - 1)
2420                                 {
2421                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2422                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2423                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2424                                 }
2425                                 else
2426                                 {
2427                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2428                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2429                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2430                                 }
2431                         }
2432         }
2433
2434         if(sf & 2)
2435         {
2436                 // flag 2 == update of mask
2437                 if(mapvote_count <= 8)
2438                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2439                 else
2440                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2441         }
2442
2443         if(sf & 4)
2444         {
2445                 if(mapvote_detail)
2446                         for(i = 0; i < mapvote_count; ++i)
2447                                 if(mapvote_maps[i] != "")
2448                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2449
2450                 WriteByte(MSG_ENTITY, to.mapvote);
2451         }
2452
2453         return TRUE;
2454 }
2455
2456 void MapVote_Spawn()
2457 {
2458         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2459 }
2460
2461 void MapVote_TouchMask()
2462 {
2463         mapvote_ent.SendFlags |= 2;
2464 }
2465
2466 void MapVote_TouchVotes(entity voter)
2467 {
2468         mapvote_ent.SendFlags |= 4;
2469 }
2470
2471 float MapVote_Finished(float mappos)
2472 {
2473         string result;
2474         float i;
2475         float didntvote;
2476
2477         if(autocvar_sv_eventlog)
2478         {
2479                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2480                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2481                 didntvote = mapvote_voters;
2482                 for(i = 0; i < mapvote_count; ++i)
2483                         if(mapvote_maps[i] != "")
2484                         {
2485                                 didntvote -= mapvote_selections[i];
2486                                 if(i != mappos)
2487                                 {
2488                                         result = strcat(result, ":", mapvote_maps[i]);
2489                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2490                                 }
2491                         }
2492                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2493
2494                 GameLogEcho(result);
2495                 if(mapvote_maps_suggested[mappos])
2496                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2497         }
2498
2499         FOR_EACH_REALCLIENT(other)
2500                 FixClientCvars(other);
2501
2502         Map_Goto_SetStr(mapvote_maps[mappos]);
2503         Map_Goto(0);
2504         alreadychangedlevel = TRUE;
2505         return TRUE;
2506 }
2507 void MapVote_CheckRules_1()
2508 {
2509         float i;
2510
2511         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2512         {
2513                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2514                 mapvote_selections[i] = 0;
2515         }
2516
2517         mapvote_voters = 0;
2518         FOR_EACH_REALCLIENT(other)
2519         {
2520                 ++mapvote_voters;
2521                 if(other.mapvote)
2522                 {
2523                         i = other.mapvote - 1;
2524                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2525                         mapvote_selections[i] = mapvote_selections[i] + 1;
2526                 }
2527         }
2528 }
2529
2530 float MapVote_CheckRules_2()
2531 {
2532         float i;
2533         float firstPlace, secondPlace;
2534         float firstPlaceVotes, secondPlaceVotes;
2535         float mapvote_voters_real;
2536         string result;
2537
2538         if(mapvote_count_real == 1)
2539                 return MapVote_Finished(0);
2540
2541         mapvote_voters_real = mapvote_voters;
2542         if(mapvote_abstain)
2543                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2544
2545         RandomSelection_Init();
2546         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2547                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2548         firstPlace = RandomSelection_chosen_float;
2549         firstPlaceVotes = RandomSelection_best_priority;
2550         //dprint("First place: ", ftos(firstPlace), "\n");
2551         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2552
2553         RandomSelection_Init();
2554         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2555                 if(i != firstPlace)
2556                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2557         secondPlace = RandomSelection_chosen_float;
2558         secondPlaceVotes = RandomSelection_best_priority;
2559         //dprint("Second place: ", ftos(secondPlace), "\n");
2560         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2561
2562         if(firstPlace == -1)
2563                 error("No first place in map vote... WTF?");
2564
2565         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2566                 return MapVote_Finished(firstPlace);
2567
2568         if(mapvote_keeptwotime)
2569                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2570                 {
2571                         float didntvote;
2572                         MapVote_TouchMask();
2573                         mapvote_message = "Now decide between the TOP TWO!";
2574                         mapvote_keeptwotime = 0;
2575                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2576                         result = strcat(result, ":", ftos(firstPlaceVotes));
2577                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2578                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2579                         didntvote = mapvote_voters;
2580                         for(i = 0; i < mapvote_count; ++i)
2581                                 if(mapvote_maps[i] != "")
2582                                 {
2583                                         didntvote -= mapvote_selections[i];
2584                                         if(i != firstPlace)
2585                                                 if(i != secondPlace)
2586                                                 {
2587                                                         result = strcat(result, ":", mapvote_maps[i]);
2588                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2589                                                         if(i < mapvote_count_real)
2590                                                         {
2591                                                                 strunzone(mapvote_maps[i]);
2592                                                                 mapvote_maps[i] = "";
2593                                                                 strunzone(mapvote_maps_pakfile[i]);
2594                                                                 mapvote_maps_pakfile[i] = "";
2595                                                         }
2596                                                 }
2597                                 }
2598                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2599                         if(autocvar_sv_eventlog)
2600                                 GameLogEcho(result);
2601                 }
2602
2603         return FALSE;
2604 }
2605 void MapVote_Tick()
2606 {
2607         float keeptwo;
2608         float totalvotes;
2609
2610         keeptwo = mapvote_keeptwotime;
2611         MapVote_CheckRules_1(); // count
2612         if(MapVote_CheckRules_2()) // decide
2613                 return;
2614
2615         totalvotes = 0;
2616         FOR_EACH_REALCLIENT(other)
2617         {
2618                 // hide scoreboard again
2619                 if(other.health != 2342)
2620                 {
2621                         other.health = 2342;
2622                         other.impulse = 0;
2623                         if(IS_REAL_CLIENT(other))
2624                         {
2625                                 msg_entity = other;
2626                                 WriteByte(MSG_ONE, SVC_FINALE);
2627                                 WriteString(MSG_ONE, "");
2628                         }
2629                 }
2630
2631                 // clear possibly invalid votes
2632                 if(mapvote_maps[other.mapvote - 1] == "")
2633                         other.mapvote = 0;
2634                 // use impulses as new vote
2635                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2636                         if(mapvote_maps[other.impulse - 1] != "")
2637                         {
2638                                 other.mapvote = other.impulse;
2639                                 MapVote_TouchVotes(other);
2640                         }
2641                 other.impulse = 0;
2642
2643                 if(other.mapvote)
2644                         ++totalvotes;
2645         }
2646
2647         MapVote_CheckRules_1(); // just count
2648 }
2649 void MapVote_Start()
2650 {
2651         if(mapvote_run)
2652                 return;
2653
2654         // wait for stats to be sent first
2655         if(!playerstats_waitforme)
2656                 return;
2657
2658         MapInfo_Enumerate();
2659         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2660                 mapvote_run = TRUE;
2661 }
2662 void MapVote_Think()
2663 {
2664         if(!mapvote_run)
2665                 return;
2666
2667         if(alreadychangedlevel)
2668                 return;
2669
2670         if(time < mapvote_nextthink)
2671                 return;
2672         //dprint("tick\n");
2673
2674         mapvote_nextthink = time + 0.5;
2675
2676         if(!mapvote_initialized)
2677         {
2678                 if(autocvar_rescan_pending == 1)
2679                 {
2680                         cvar_set("rescan_pending", "2");
2681                         localcmd("fs_rescan\nrescan_pending 3\n");
2682                         return;
2683                 }
2684                 else if(autocvar_rescan_pending == 2)
2685                 {
2686                         return;
2687                 }
2688                 else if(autocvar_rescan_pending == 3)
2689                 {
2690                         // now build missing mapinfo files
2691                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2692                                 return;
2693
2694                         // we're done, start the timer
2695                         cvar_set("rescan_pending", "0");
2696                 }
2697
2698                 mapvote_initialized = TRUE;
2699                 if(DoNextMapOverride(0))
2700                         return;
2701                 if(!autocvar_g_maplist_votable || player_count <= 0)
2702                 {
2703                         GotoNextMap(0);
2704                         return;
2705                 }
2706                 MapVote_Init();
2707         }
2708
2709         MapVote_Tick();
2710 }
2711
2712 string GotoMap(string m)
2713 {
2714         if(!MapInfo_CheckMap(m))
2715                 return "The map you chose is not available on this server.";
2716         cvar_set("nextmap", m);
2717         cvar_set("timelimit", "-1");
2718         if(mapvote_initialized || alreadychangedlevel)
2719         {
2720                 if(DoNextMapOverride(0))
2721                         return "Map switch initiated.";
2722                 else
2723                         return "Hm... no. For some reason I like THIS map more.";
2724         }
2725         else
2726                 return "Map switch will happen after scoreboard.";
2727 }
2728
2729
2730 void EndFrame()
2731 {
2732         anticheat_endframe();
2733
2734         float altime;
2735         FOR_EACH_REALCLIENT(self)
2736         {
2737                 if(IS_SPEC(self))
2738                 {
2739                         if(self.enemy.typehitsound)
2740                                 self.typehit_time = time;
2741                         else if(self.enemy.hitsound)
2742                                 self.hit_time = time;
2743                 }
2744                 else
2745                 {
2746                         if(self.typehitsound)
2747                                 self.typehit_time = time;
2748                         else if(self.hitsound)
2749                                 self.hit_time = time;
2750                 }
2751         }
2752         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2753         // add 1 frametime because after this, engine SV_Physics
2754         // increases time by a frametime and then networks the frame
2755         // add another frametime because client shows everything with
2756         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2757         // needed!
2758         FOR_EACH_CLIENT(self)
2759         {
2760                 self.hitsound = FALSE;
2761                 self.typehitsound = FALSE;
2762                 antilag_record(self, altime);
2763         }
2764 }
2765
2766
2767 /*
2768  * RedirectionThink:
2769  * returns TRUE if redirecting
2770  */
2771 float redirection_timeout;
2772 float redirection_nextthink;
2773 float RedirectionThink()
2774 {
2775         float clients_found;
2776
2777         if(redirection_target == "")
2778                 return FALSE;
2779
2780         if(!redirection_timeout)
2781         {
2782                 cvar_set("sv_public", "-2");
2783                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2784                 if(redirection_target == "self")
2785                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2786                 else
2787                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2788         }
2789
2790         if(time < redirection_nextthink)
2791                 return TRUE;
2792
2793         redirection_nextthink = time + 1;
2794
2795         clients_found = 0;
2796         FOR_EACH_REALCLIENT(self)
2797         {
2798                 // TODO add timer
2799                 print("Redirecting: sending connect command to ", self.netname, "\n");
2800                 if(redirection_target == "self")
2801                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2802                 else
2803                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2804                 ++clients_found;
2805         }
2806
2807         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2808
2809         if(time > redirection_timeout || clients_found == 0)
2810                 localcmd("\nwait; wait; wait; quit\n");
2811
2812         return TRUE;
2813 }
2814
2815 void TargetMusic_RestoreGame();
2816 void RestoreGame()
2817 {
2818         // Loaded from a save game
2819         // some things then break, so let's work around them...
2820
2821         // Progs DB (capture records)
2822         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2823
2824         // Mapinfo
2825         MapInfo_Shutdown();
2826         MapInfo_Enumerate();
2827         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2828         WeaponStats_Init();
2829
2830         TargetMusic_RestoreGame();
2831 }
2832
2833 void Shutdown()
2834 {
2835         entity e;
2836
2837         gameover = 2;
2838
2839         if(world_initialized > 0)
2840         {
2841                 world_initialized = 0;
2842                 print("Saving persistent data...\n");
2843                 Ban_SaveBans();
2844
2845                 PlayerStats_EndMatch(0);
2846                 FOR_EACH_CLIENT(e)
2847                         PlayerStats_AddGlobalInfo(e);
2848                 PlayerStats_Shutdown();
2849
2850                 if(!cheatcount_total)
2851                 {
2852                         if(autocvar_sv_db_saveasdump)
2853                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2854                         else
2855                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2856                 }
2857                 if(autocvar_developer)
2858                 {
2859                         if(autocvar_sv_db_saveasdump)
2860                                 db_dump(TemporaryDB, "server-temp.db");
2861                         else
2862                                 db_save(TemporaryDB, "server-temp.db");
2863                 }
2864                 CheatShutdown(); // must be after cheatcount check
2865                 db_close(ServerProgsDB);
2866                 db_close(TemporaryDB);
2867                 print("done!\n");
2868                 // tell the bot system the game is ending now
2869                 bot_endgame();
2870
2871                 WeaponStats_Shutdown();
2872                 MapInfo_Shutdown();
2873         }
2874         else if(world_initialized == 0)
2875         {
2876                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2877         }
2878 }