qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(autocvar__sv_init)
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(autocvar_g_maplist_shuffle)
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 239 #define BADCVAR(p) if(k == p) continue
 240
 241                 // general excludes and namespaces for server admin used cvars
 242                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 243
 244                 // internal
 245                 BADPREFIX("csqc_");
 246                 BADPREFIX("cvar_check_");
 247                 BADCVAR("gamecfg");
 248                 BADCVAR("g_configversion");
 249                 BADCVAR("g_maplist_index");
 250                 BADCVAR("halflifebsp");
 251                 BADPREFIX("sv_world");
 252
 253                 // client
 254                 BADPREFIX("chase_");
 255                 BADPREFIX("cl_");
 256                 BADPREFIX("con_");
 257                 BADPREFIX("scoreboard_");
 258                 BADPREFIX("g_campaign");
 259                 BADPREFIX("gl_");
 260                 BADPREFIX("joy");
 261                 BADPREFIX("hud_");
 262                 BADPREFIX("m_");
 263                 BADPREFIX("menu_");
 264                 BADPREFIX("net_slist_");
 265                 BADPREFIX("r_");
 266                 BADPREFIX("sbar_");
 267                 BADPREFIX("scr_");
 268                 BADPREFIX("snd_");
 269                 BADPREFIX("show");
 270                 BADPREFIX("sensitivity");
 271                 BADPREFIX("userbind");
 272                 BADPREFIX("v_");
 273                 BADPREFIX("vid_");
 274                 BADPREFIX("crosshair");
 275                 BADCVAR("mod_q3bsp_lightmapmergepower");
 276                 BADCVAR("mod_q3bsp_nolightmaps");
 277                 BADCVAR("fov");
 278                 BADCVAR("mastervolume");
 279                 BADCVAR("volume");
 280                 BADCVAR("bgmvolume");
 281
 282                 // private
 283                 BADCVAR("developer");
 284                 BADCVAR("g_banned_list");
 285                 BADCVAR("log_dest_udp");
 286                 BADCVAR("log_file");
 287                 BADCVAR("net_address");
 288                 BADCVAR("net_address_ipv6");
 289                 BADCVAR("port");
 290                 BADCVAR("savedgamecfg");
 291                 BADCVAR("serverconfig");
 292                 BADCVAR("sv_heartbeatperiod");
 293                 BADCVAR("sv_vote_master_password");
 294                 BADCVAR("sys_colortranslation");
 295                 BADCVAR("sys_specialcharactertranslation");
 296                 BADCVAR("timestamps");
 297                 BADPREFIX("developer_");
 298                 BADPREFIX("g_ban_");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_voice_flood_");
 301                 BADPREFIX("rcon_");
 302                 BADPREFIX("settemp_");
 303                 BADPREFIX("sv_allowdownloads_");
 304                 BADPREFIX("sv_autodemo");
 305                 BADPREFIX("sv_curl_");
 306                 BADPREFIX("sv_eventlog");
 307                 BADPREFIX("sv_logscores_");
 308                 BADPREFIX("sv_master");
 309                 BADPREFIX("sv_weaponstats_");
 310
 311                 // these can contain player IDs, so better hide
 312                 BADCVAR("g_forced_team_red");
 313                 BADCVAR("g_forced_team_blue");
 314                 BADCVAR("g_forced_team_yellow");
 315                 BADCVAR("g_forced_team_pink");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_checkforpacketsduringsleep");
 387                 BADCVAR("sv_timeout");
 388                 BADCVAR("welcome_message_time");
 389                 BADPREFIX("crypto_");
 390                 BADPREFIX("g_chat_");
 391                 BADPREFIX("g_ctf_captimerecord_");
 392                 BADPREFIX("g_maplist_votable_");
 393                 BADPREFIX("net_");
 394                 BADPREFIX("prvm_");
 395                 BADPREFIX("skill_");
 396                 BADPREFIX("sv_fragmessage_");
 397                 BADPREFIX("sv_maxidle_");
 398                 BADPREFIX("sv_vote_");
 399                 BADPREFIX("timelimit_");
 400
 401                 // allowed changes to server admins (please sync this to server.cfg)
 402                 // vi commands:
 403                 //   :/"impure"/,$d
 404                 //   :g!,^\/\/[^ /],d
 405                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 406                 //   :%!sort
 407                 // yes, this does contain some redundant stuff, don't really care
 408                 BADCVAR("bot_number");
 409                 BADCVAR("bot_prefix");
 410                 BADCVAR("bot_suffix");
 411                 BADCVAR("capturelimit_override");
 412                 BADCVAR("fraglimit_override");
 413                 BADCVAR("gametype");
 414                 BADCVAR("g_antilag");
 415                 BADCVAR("g_balance_teams");
 416                 BADCVAR("g_balance_teams_force");
 417                 BADCVAR("g_ban_sync_trusted_servers");
 418                 BADCVAR("g_ban_sync_uri");
 419                 BADCVAR("g_ctf_capture_limit");
 420                 BADCVAR("g_ctf_ignore_frags");
 421                 BADCVAR("g_ctf_win_mode");
 422                 BADCVAR("g_domination_point_limit");
 423                 BADCVAR("g_fullbrightitems");
 424                 BADCVAR("g_fullbrightplayers");
 425                 BADCVAR("g_keyhunt_point_limit");
 426                 BADCVAR("g_keyhunt_teams_override");
 427                 BADCVAR("g_lms_lives_override");
 428                 BADCVAR("g_maplist");
 429                 BADCVAR("g_maplist_check_waypoints");
 430                 BADCVAR("g_maplist_mostrecent_count");
 431                 BADCVAR("g_maplist_shuffle");
 432                 BADCVAR("g_maplist_votable");
 433                 BADCVAR("g_maplist_votable_abstain");
 434                 BADCVAR("g_maplist_votable_nodetail");
 435                 BADCVAR("g_maplist_votable_suggestions");
 436                 BADCVAR("g_minstagib");
 437                 BADCVAR("g_nexball_goallimit");
 438                 BADCVAR("g_runematch_point_limit");
 439                 BADCVAR("g_start_delay");
 440                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 441                 BADCVAR("hostname");
 442                 BADCVAR("log_file");
 443                 BADCVAR("maxplayers");
 444                 BADCVAR("g_maxplayers");
 445                 BADCVAR("minplayers");
 446                 BADCVAR("net_address");
 447                 BADCVAR("port");
 448                 BADCVAR("rcon_password");
 449                 BADCVAR("rcon_restricted_commands");
 450                 BADCVAR("rcon_restricted_password");
 451                 BADCVAR("skill");
 452                 BADCVAR("sv_adminnick");
 453                 BADCVAR("sv_autoscreenshot");
 454                 BADCVAR("sv_curl_defaulturl");
 455                 BADCVAR("sv_defaultcharacter");
 456                 BADCVAR("sv_defaultplayercolors");
 457                 BADCVAR("sv_defaultplayermodel");
 458                 BADCVAR("sv_defaultplayerskin");
 459                 BADCVAR("sv_maxidle");
 460                 BADCVAR("sv_maxrate");
 461                 BADCVAR("sv_motd");
 462                 BADCVAR("sv_public");
 463                 BADCVAR("sv_ready_restart");
 464                 BADCVAR("sv_status_privacy");
 465                 BADCVAR("sv_vote_call");
 466                 BADCVAR("sv_vote_commands");
 467                 BADCVAR("sv_vote_majority_factor");
 468                 BADCVAR("sv_vote_master");
 469                 BADCVAR("sv_vote_master_commands");
 470                 BADCVAR("sv_vote_master_password");
 471                 BADCVAR("sv_vote_simple_majority_factor");
 472                 BADCVAR("timelimit_override");
 473                 BADCVAR("g_warmup");
 474                 BADPREFIX("g_warmup_");
 475                 BADCVAR("teamplay_mode");
 476
 477                 if(autocvar_g_minstagib)
 478                 {
 479                         BADCVAR("g_grappling_hook");
 480                         BADCVAR("g_jetpack");
 481                 }
 482 #undef BADPREFIX
 483 #undef BADCVAR
 484
 485                 if(pureadding)
 486                 {
 487                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 488                         if(strlen(cvar_purechanges) > 16384)
 489                         {
 490                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 491                                 pureadding = 0;
 492                         }
 493                 }
 494                 ++cvar_purechanges_count;
 495                 // WARNING: this variable is used for the server list
 496                 // NEVER dare to skip this code!
 497                 // Hacks to intentionally appearing as "pure server" even though you DO have
 498                 // modified settings may be punished by removal from the server list.
 499                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 500                 // though.
 501         }
 502         buf_del(h);
 503         if(cvar_changes == "")
 504                 cvar_changes = "// this server runs at default server settings\n";
 505         else
 506                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 507         cvar_changes = strzone(cvar_changes);
 508         if(cvar_purechanges == "")
 509                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 510         else
 511                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 512         cvar_purechanges = strzone(cvar_purechanges);
 513 }
 514
 515 void detect_maptype()
 516 {
 517 #if 0
 518         vector o, v;
 519         float i;
 520
 521         for(;;)
 522         {
 523                 o = world.mins;
 524                 o_x += random() * (world.maxs_x - world.mins_x);
 525                 o_y += random() * (world.maxs_y - world.mins_y);
 526                 o_z += random() * (world.maxs_z - world.mins_z);
 527
 528                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 529                 if(trace_fraction == 1)
 530                         continue;
 531
 532                 v = trace_endpos;
 533
 534                 for(i = 0; i < 64; i += 4)
 535                 {
 536                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 537         if(trace_fraction == 1)
 538                 continue;
 539                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 540                 }
 541
 542                 break;
 543         }
 544 #endif
 545 }
 546
 547 entity randomseed;
 548 float RandomSeed_Send(entity to, float sf)
 549 {
 550         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 551         WriteShort(MSG_ENTITY, self.cnt);
 552         return TRUE;
 553 }
 554 void RandomSeed_Think()
 555 {
 556         self.cnt = bound(0, floor(random() * 65536), 65535);
 557         self.nextthink = time + 5;
 558
 559         self.SendFlags |= 1;
 560 }
 561 void RandomSeed_Spawn()
 562 {
 563         randomseed = spawn();
 564         randomseed.think = RandomSeed_Think;
 565         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 566
 567         entity oldself;
 568         oldself = self;
 569         self = randomseed;
 570         self.think(); // sets random seed and nextthink
 571         self = oldself;
 572 }
 573
 574 void spawnfunc___init_dedicated_server(void)
 575 {
 576         // handler for _init/_init map (only for dedicated server initialization)
 577
 578         world_initialized = -1; // don't complain
 579         cvar = cvar_normal;
 580         cvar_string = cvar_string_normal;
 581         cvar_set = cvar_set_normal;
 582
 583         remove = remove_unsafely;
 584
 585         entity e;
 586         e = spawn();
 587         e.think = GotoFirstMap;
 588         e.nextthink = time; // this is usually 1 at this point
 589
 590         e = spawn();
 591         e.classname = "info_player_deathmatch"; // safeguard against player joining
 592
 593         self.classname = "worldspawn"; // safeguard against various stuff ;)
 594
 595         MapInfo_Enumerate();
 596         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 597 }
 598
 599 void Map_MarkAsRecent(string m);
 600 float world_already_spawned;
 601 void RegisterWeapons();
 602 void Nagger_Init();
 603 void ClientInit_Spawn();
 604 void WeaponStats_Init();
 605 void WeaponStats_Shutdown();
 606 void spawnfunc_worldspawn (void)
 607 {
 608         float fd, l, i, j, n;
 609         string s, col;
 610
 611         cvar = cvar_normal;
 612         cvar_string = cvar_string_normal;
 613         cvar_set = cvar_set_normal;
 614
 615         if(world_already_spawned)
 616                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 617         world_already_spawned = TRUE;
 618
 619         remove = remove_safely; // during spawning, watch what you remove!
 620
 621         check_unacceptable_compiler_bugs();
 622
 623         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 624
 625         compressShortVector_init();
 626
 627         allowed_to_spawn = TRUE;
 628
 629         local entity head;
 630         head = nextent(world);
 631         maxclients = 0;
 632         while(head)
 633         {
 634                 ++maxclients;
 635                 head = nextent(head);
 636         }
 637
 638         // needs to be done so early as they would still spawn
 639         RegisterWeapons();
 640
 641         ServerProgsDB = db_load("server.db");
 642
 643         TemporaryDB = db_create();
 644
 645         // 0 normal
 646         lightstyle(0, "m");
 647
 648         // 1 FLICKER (first variety)
 649         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 650
 651         // 2 SLOW STRONG PULSE
 652         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 653
 654         // 3 CANDLE (first variety)
 655         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 656
 657         // 4 FAST STROBE
 658         lightstyle(4, "mamamamamama");
 659
 660         // 5 GENTLE PULSE 1
 661         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 662
 663         // 6 FLICKER (second variety)
 664         lightstyle(6, "nmonqnmomnmomomno");
 665
 666         // 7 CANDLE (second variety)
 667         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 668
 669         // 8 CANDLE (third variety)
 670         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 671
 672         // 9 SLOW STROBE (fourth variety)
 673         lightstyle(9, "aaaaaaaazzzzzzzz");
 674
 675         // 10 FLUORESCENT FLICKER
 676         lightstyle(10, "mmamammmmammamamaaamammma");
 677
 678         // 11 SLOW PULSE NOT FADE TO BLACK
 679         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 680
 681         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 682
 683         // 63 testing
 684         lightstyle(63, "a");
 685
 686         if(autocvar_g_campaign)
 687                 CampaignPreInit();
 688
 689         Map_MarkAsRecent(mapname);
 690
 691         precache_model ("null"); // we need this one before InitGameplayMode
 692         InitGameplayMode();
 693         readlevelcvars();
 694         GrappleHookInit();
 695         ElectroInit();
 696         LaserInit();
 697
 698         player_count = 0;
 699         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 700         if(bot_waypoints_for_items == 1)
 701                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 702                         bot_waypoints_for_items = 0;
 703
 704         // for setting by mapinfo
 705         q3acompat_machineshotgunswap = autocvar_sv_q3acompat_machineshotgunswap;
 706         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 707
 708         precache();
 709
 710         WaypointSprite_Init();
 711
 712         //if (g_domination)
 713         //      dom_init();
 714
 715         GameLogInit(); // prepare everything
 716         if(autocvar_sv_eventlog)
 717         {
 718                 s = strcat(ftos(autocvar_sv_eventlog_files_counter), ".");
 719                 s = strcat(s, ftos(random()));
 720                 matchid = strzone(s);
 721
 722                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 723                 s = ":gameinfo:mutators:LIST";
 724
 725                 ret_string = s;
 726                 MUTATOR_CALLHOOK(BuildMutatorsString);
 727                 s = ret_string;
 728
 729                 // simple, probably not good in the mutator system
 730                 if(autocvar_g_grappling_hook)
 731                         s = strcat(s, ":grappling_hook");
 732
 733                 // initialiation stuff, not good in the mutator system
 734                 if(!autocvar_g_use_ammunition)
 735                         s = strcat(s, ":no_use_ammunition");
 736
 737                 // initialiation stuff, not good in the mutator system
 738                 if(!autocvar_g_pickup_items)
 739                         s = strcat(s, ":no_pickup_items");
 740
 741                 // initialiation stuff, not good in the mutator system
 742                 if(autocvar_g_weaponarena != "0")
 743                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 744
 745                 // TODO to mutator system
 746                 if(autocvar_g_norecoil)
 747                         s = strcat(s, ":norecoil");
 748
 749                 // TODO to mutator system
 750                 if(autocvar_g_midair)
 751                         s = strcat(s, ":midair");
 752
 753                 // TODO to mutator system
 754                 if(autocvar_g_minstagib)
 755                         s = strcat(s, ":minstagib");
 756
 757                 GameLogEcho(s);
 758                 GameLogEcho(":gameinfo:end");
 759         }
 760         else
 761                 matchid = strzone(ftos(random()));
 762
 763         cvar_set("nextmap", "");
 764
 765         SetDefaultAlpha();
 766
 767         if(autocvar_g_campaign)
 768                 CampaignPostInit();
 769
 770         fteqcc_testbugs();
 771
 772         Ban_LoadBans();
 773
 774         MapInfo_Enumerate();
 775         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 776
 777         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 778         {
 779                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 780                 if(fd != -1)
 781                 {
 782                         while((s = fgets(fd)))
 783                         {
 784                                 l = tokenize_console(s);
 785                                 if(l < 2)
 786                                         continue;
 787                                 if(argv(0) == "cd")
 788                                 {
 789                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 790                                         print("  cdtrack ", argv(2), "\n");
 791                                 }
 792                                 else if(argv(0) == "fog")
 793                                 {
 794                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 795                                         print("  \"fog\" \"", s, "\"\n");
 796                                 }
 797                                 else if(argv(0) == "set")
 798                                 {
 799                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 800                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 801                                 }
 802                                 else if(argv(0) != "//")
 803                                 {
 804                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 805                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 806                                 }
 807                         }
 808                         fclose(fd);
 809                 }
 810         }
 811
 812         WeaponStats_Init();
 813
 814         addstat(STAT_WEAPONS, AS_INT, weapons);
 815         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 816         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 817         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 818         Nagger_Init();
 819
 820         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 821         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 822         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 823         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 824         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 825         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 826         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 827         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 828         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 829         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 830         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 831         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 832
 833         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 834         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 835
 836         if(g_ca || g_freezetag)
 837         {
 838                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 839                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 840                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 841                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 842         }
 843         if(g_freezetag)
 844         {
 845                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 846                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 847         }
 848
 849         // g_movementspeed hack
 850         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 851         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 852         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 853         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 854
 855         next_pingtime = time + 5;
 856
 857         detect_maptype();
 858
 859         lsmaps_reply = "^7Maps available: ";
 860         lsnewmaps_reply = "^7Maps without a record set: ";
 861         for(i = 0, j = 0; i < MapInfo_count; ++i)
 862         {
 863                 if(MapInfo_Get_ByID(i))
 864                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 865                         {
 866                                 if(mod(i, 2))
 867                                         col = "^2";
 868                                 else
 869                                         col = "^3";
 870                                 ++j;
 871                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 872                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 873                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 874                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 875                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 876                         }
 877         }
 878         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 879         if (!g_race && !g_cts)
 880                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 881         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 882
 883         maplist_reply = "^7Maps in list: ";
 884         n = tokenize_console(autocvar_g_maplist);
 885         for(i = 0, j = 0; i < n; ++i)
 886         {
 887                 if(MapInfo_CheckMap(argv(i)))
 888                 {
 889                         if(mod(j, 2))
 890                                 col = "^2";
 891                         else
 892                                 col = "^3";
 893                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 894                         ++j;
 895                 }
 896         }
 897         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 898         MapInfo_ClearTemps();
 899
 900         for(i = 0; i < 10; ++i)
 901         {
 902                 records_reply[i] = strzone(getrecords(i));
 903         }
 904         if(g_cts)
 905                 ladder_reply = strzone(getladder());
 906
 907         rankings_reply = strzone(getrankings());
 908
 909         ClientInit_Spawn();
 910         RandomSeed_Spawn();
 911         PingPLReport_Spawn();
 912
 913         CheatInit();
 914
 915         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 916
 917         // fill sv_curl_serverpackages from .serverpackage files
 918         if(autocvar_sv_curl_serverpackages_auto)
 919         {
 920                 s = "";
 921                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 922                 for(i = 0; i < n; ++i)
 923                         if(substring(argv(i), -14, -1) != ".serverpackage")
 924                                 s = strcat(s, " ", argv(i));
 925                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 926                 if(fd >= 0)
 927                 {
 928                         j = search_getsize(fd);
 929                         for(i = 0; i < j; ++i)
 930                                 s = strcat(s, " ", search_getfilename(fd, i));
 931                         search_end(fd);
 932                 }
 933                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 934         }
 935
 936         PlayerStats_Init();
 937
 938         world_initialized = 1;
 939 }
 940
 941 void spawnfunc_light (void)
 942 {
 943         //makestatic (self); // Who the f___ did that?
 944         remove(self);
 945 }
 946
 947 float TryFile( string pFilename )
 948 {
 949         local float lHandle;
 950         dprint("TryFile(\"", pFilename, "\")\n");
 951         lHandle = fopen( pFilename, FILE_READ );
 952         if( lHandle != -1 ) {
 953                 fclose( lHandle );
 954                 return TRUE;
 955         } else {
 956                 return FALSE;
 957         }
 958 };
 959
 960 string GetGametype()
 961 {
 962         return GametypeNameFromType(game);
 963 }
 964
 965 string getmapname_stored;
 966 string GetMapname()
 967 {
 968         return mapname;
 969 }
 970
 971 float Map_Count, Map_Current;
 972 string Map_Current_Name;
 973
 974 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 975 float GetMaplistPosition()
 976 {
 977         float pos, idx;
 978         string map;
 979
 980         map = GetMapname();
 981         idx = autocvar_g_maplist_index;
 982
 983         if(idx >= 0)
 984                 if(idx < Map_Count)
 985                         if(map == argv(idx))
 986                                 return idx;
 987
 988         for(pos = 0; pos < Map_Count; ++pos)
 989                 if(map == argv(pos))
 990                         return pos;
 991
 992         // resume normal maplist rotation if current map is not in g_maplist
 993         return idx;
 994 }
 995
 996 float MapHasRightSize(string map)
 997 {
 998         float fh;
 999         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1000         if(autocvar_g_maplist_check_waypoints)
1001         {
1002                 dprint("checkwp "); dprint(map);
1003                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
1004                 if(fh < 0)
1005                 {
1006                         dprint(": no waypoints\n");
1007                         return FALSE;
1008                 }
1009                 dprint(": has waypoints\n");
1010                 fclose(fh);
1011         }
1012
1013         // open map size restriction file
1014         dprint("opensize "); dprint(map);
1015         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1016         if(fh >= 0)
1017         {
1018                 float mapmin, mapmax;
1019                 dprint(": ok, ");
1020                 mapmin = stof(fgets(fh));
1021                 mapmax = stof(fgets(fh));
1022                 fclose(fh);
1023                 if(player_count < mapmin)
1024                 {
1025                         dprint("not enough\n");
1026                         return FALSE;
1027                 }
1028                 if(player_count > mapmax)
1029                 {
1030                         dprint("too many\n");
1031                         return FALSE;
1032                 }
1033                 dprint("right size\n");
1034                 return TRUE;
1035         }
1036         dprint(": not found\n");
1037         return TRUE;
1038 }
1039
1040 string Map_Filename(float position)
1041 {
1042         return strcat("maps/", argv(position), ".bsp");
1043 }
1044
1045 string strwords(string s, float w)
1046 {
1047         float endpos;
1048         for(endpos = 0; w && endpos >= 0; --w)
1049                 endpos = strstrofs(s, " ", endpos + 1);
1050         if(endpos < 0)
1051                 return s;
1052         else
1053                 return substring(s, 0, endpos);
1054 }
1055
1056 float strhasword(string s, string w)
1057 {
1058         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1059 }
1060
1061 void Map_MarkAsRecent(string m)
1062 {
1063         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1064 }
1065
1066 float Map_IsRecent(string m)
1067 {
1068         return strhasword(autocvar_g_maplist_mostrecent, m);
1069 }
1070
1071 float Map_Check(float position, float pass)
1072 {
1073         string filename;
1074         string map_next;
1075         map_next = argv(position);
1076         if(pass <= 1)
1077         {
1078                 if(Map_IsRecent(map_next))
1079                         return 0;
1080         }
1081         filename = Map_Filename(position);
1082         if(MapInfo_CheckMap(map_next))
1083         {
1084                 if(pass == 2)
1085                         return 1;
1086                 if(MapHasRightSize(map_next))
1087                         return 1;
1088                 return 0;
1089         }
1090         else
1091                 dprint( "Couldn't select '", filename, "'..\n" );
1092
1093         return 0;
1094 }
1095
1096 void Map_Goto_SetStr(string nextmapname)
1097 {
1098         if(getmapname_stored != "")
1099                 strunzone(getmapname_stored);
1100         if(nextmapname == "")
1101                 getmapname_stored = "";
1102         else
1103                 getmapname_stored = strzone(nextmapname);
1104 }
1105
1106 void Map_Goto_SetFloat(float position)
1107 {
1108         cvar_set("g_maplist_index", ftos(position));
1109         Map_Goto_SetStr(argv(position));
1110 }
1111
1112 void GameResetCfg()
1113 {
1114         // settings persist, except...
1115         localcmd("\nsettemp_restore\n");
1116 };
1117
1118 void Map_Goto()
1119 {
1120         GameResetCfg();
1121         MapInfo_LoadMap(getmapname_stored);
1122 }
1123
1124 // return codes of map selectors:
1125 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1126 //   -2 = permanent failure
1127 float() MaplistMethod_Iterate = // usual method
1128 {
1129         float pass, i;
1130
1131         for(pass = 1; pass <= 2; ++pass)
1132         {
1133                 for(i = 1; i < Map_Count; ++i)
1134                 {
1135                         float mapindex;
1136                         mapindex = mod(i + Map_Current, Map_Count);
1137                         if(Map_Check(mapindex, pass))
1138                                 return mapindex;
1139                 }
1140         }
1141         return -1;
1142 }
1143
1144 float() MaplistMethod_Repeat = // fallback method
1145 {
1146         if(Map_Check(Map_Current, 2))
1147                 return Map_Current;
1148         return -2;
1149 }
1150
1151 float() MaplistMethod_Random = // random map selection
1152 {
1153         float i, imax;
1154
1155         imax = 42;
1156
1157         for(i = 0; i <= imax; ++i)
1158         {
1159                 float mapindex;
1160                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1161                 if(Map_Check(mapindex, 1))
1162                         return mapindex;
1163         }
1164         return -1;
1165 }
1166
1167 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1168 // the exponent sets a bias on the map selection:
1169 // the higher the exponent, the less likely "shortly repeated" same maps are
1170 {
1171         float i, j, imax, insertpos;
1172
1173         imax = 42;
1174
1175         for(i = 0; i <= imax; ++i)
1176         {
1177                 string newlist;
1178
1179                 // now reinsert this at another position
1180                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1181                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1182                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1183                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1184
1185                 // insert the current map there
1186                 newlist = "";
1187                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1188                         newlist = strcat(newlist, " ", argv(j));
1189                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1190                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1191                         newlist = strcat(newlist, " ", argv(j));
1192                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1193                 cvar_set("g_maplist", newlist);
1194                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1195
1196                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1197                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1198                 if(Map_Check(Map_Current, 1))
1199                         return Map_Current;
1200         }
1201         return -1;
1202 }
1203
1204 void Maplist_Init()
1205 {
1206         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1207         if(Map_Count == 0)
1208         {
1209                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1210                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1211                 if(autocvar_g_maplist_shuffle)
1212                         ShuffleMaplist();
1213                 localcmd("\nmenu_cmd sync\n");
1214                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1215         }
1216         if(Map_Count == 0)
1217                 error("empty maplist, cannot select a new map");
1218         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1219
1220         if(Map_Current_Name)
1221                 strunzone(Map_Current_Name);
1222         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1223         // this may or may not be correct, but who cares, in the worst case a map
1224         // isn't chosen in the first pass that should have been
1225 }
1226
1227 string GetNextMap()
1228 {
1229         float nextMap;
1230
1231         Maplist_Init();
1232         nextMap = -1;
1233
1234         if(nextMap == -1)
1235                 if(autocvar_g_maplist_shuffle > 0)
1236                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1237
1238         if(nextMap == -1)
1239                 if(autocvar_g_maplist_selectrandom)
1240                         nextMap = MaplistMethod_Random();
1241
1242         if(nextMap == -1)
1243                 nextMap = MaplistMethod_Iterate();
1244
1245         if(nextMap == -1)
1246                 nextMap = MaplistMethod_Repeat();
1247
1248         if(nextMap >= 0)
1249         {
1250                 Map_Goto_SetFloat(nextMap);
1251                 return getmapname_stored;
1252         }
1253
1254         return "";
1255 };
1256
1257 float DoNextMapOverride()
1258 {
1259         if(autocvar_g_campaign)
1260         {
1261                 CampaignPostIntermission();
1262                 alreadychangedlevel = TRUE;
1263                 return TRUE;
1264         }
1265         if(autocvar_quit_when_empty)
1266         {
1267                 if(player_count <= currentbots)
1268                 {
1269                         localcmd("quit\n");
1270                         alreadychangedlevel = TRUE;
1271                         return TRUE;
1272                 }
1273         }
1274         if(autocvar_quit_and_redirect != "")
1275         {
1276                 redirection_target = strzone(autocvar_quit_and_redirect);
1277                 alreadychangedlevel = TRUE;
1278                 return TRUE;
1279         }
1280         if (autocvar_samelevel) // if samelevel is set, stay on same level
1281         {
1282                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1283                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1284                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1285                 localcmd("restart\n");
1286                 //changelevel (mapname);
1287                 alreadychangedlevel = TRUE;
1288                 return TRUE;
1289         }
1290         if(autocvar_nextmap != "")
1291                 if(MapInfo_CheckMap(autocvar_nextmap))
1292                 {
1293                         Map_Goto_SetStr(autocvar_nextmap);
1294                         Map_Goto();
1295                         alreadychangedlevel = TRUE;
1296                         return TRUE;
1297                 }
1298         if(autocvar_lastlevel)
1299         {
1300                 GameResetCfg();
1301                 localcmd("set lastlevel 0\ntogglemenu\n");
1302                 alreadychangedlevel = TRUE;
1303                 return TRUE;
1304         }
1305         return FALSE;
1306 };
1307
1308 void GotoNextMap()
1309 {
1310         //local string nextmap;
1311         //local float n, nummaps;
1312         //local string s;
1313         if (alreadychangedlevel)
1314                 return;
1315         alreadychangedlevel = TRUE;
1316
1317         {
1318                 string nextMap;
1319                 float allowReset;
1320
1321                 for(allowReset = 1; allowReset >= 0; --allowReset)
1322                 {
1323                         nextMap = GetNextMap();
1324                         if(nextMap != "")
1325                                 break;
1326
1327                         if(allowReset)
1328                         {
1329                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1330                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1331                                 if(autocvar_g_maplist_shuffle)
1332                                         ShuffleMaplist();
1333                                 localcmd("\nmenu_cmd sync\n");
1334                         }
1335                         else
1336                         {
1337                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1338                         }
1339                 }
1340                 Map_Goto();
1341         }
1342 };
1343
1344
1345 /*
1346 ============
1347 IntermissionThink
1348
1349 When the player presses attack or jump, change to the next level
1350 ============
1351 */
1352 .float autoscreenshot;
1353 void() MapVote_Start;
1354 void() MapVote_Think;
1355 float mapvote_initialized;
1356 void IntermissionThink()
1357 {
1358         FixIntermissionClient(self);
1359
1360         if(autocvar_sv_autoscreenshot)
1361         if(self.autoscreenshot > 0)
1362         if(time > self.autoscreenshot)
1363         {
1364                 self.autoscreenshot = -1;
1365                 if(clienttype(self) == CLIENTTYPE_REAL)
1366                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1367                 return;
1368         }
1369
1370         if (time < intermission_exittime)
1371                 return;
1372
1373         if(!mapvote_initialized)
1374                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1375                         return;
1376
1377         MapVote_Start();
1378 };
1379
1380 /*
1381 ============
1382 FindIntermission
1383
1384 Returns the entity to view from
1385 ============
1386 */
1387 /*
1388 entity FindIntermission()
1389 {
1390         local   entity spot;
1391         local   float cyc;
1392
1393 // look for info_intermission first
1394         spot = find (world, classname, "info_intermission");
1395         if (spot)
1396         {       // pick a random one
1397                 cyc = random() * 4;
1398                 while (cyc > 1)
1399                 {
1400                         spot = find (spot, classname, "info_intermission");
1401                         if (!spot)
1402                                 spot = find (spot, classname, "info_intermission");
1403                         cyc = cyc - 1;
1404                 }
1405                 return spot;
1406         }
1407
1408 // then look for the start position
1409         spot = find (world, classname, "info_player_start");
1410         if (spot)
1411                 return spot;
1412
1413 // testinfo_player_start is only found in regioned levels
1414         spot = find (world, classname, "testplayerstart");
1415         if (spot)
1416                 return spot;
1417
1418 // then look for the start position
1419         spot = find (world, classname, "info_player_deathmatch");
1420         if (spot)
1421                 return spot;
1422
1423         //objerror ("FindIntermission: no spot");
1424         return world;
1425 };
1426 */
1427
1428 /*
1429 ===============================================================================
1430
1431 RULES
1432
1433 ===============================================================================
1434 */
1435
1436 void DumpStats(float final)
1437 {
1438         float file;
1439         string s;
1440         float to_console;
1441         float to_eventlog;
1442         float to_file;
1443         float i;
1444
1445         to_console = autocvar_sv_logscores_console;
1446         to_eventlog = autocvar_sv_eventlog;
1447         to_file = autocvar_sv_logscores_file;
1448
1449         if(!final)
1450         {
1451                 to_console = TRUE; // always print printstats replies
1452                 to_eventlog = FALSE; // but never print them to the event log
1453         }
1454
1455         if(to_eventlog)
1456                 if(autocvar_sv_eventlog_console)
1457                         to_console = FALSE; // otherwise we get the output twice
1458
1459         if(final)
1460                 s = ":scores:";
1461         else
1462                 s = ":status:";
1463         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1464
1465         if(to_console)
1466                 print(s, "\n");
1467         if(to_eventlog)
1468                 GameLogEcho(s);
1469         if(to_file)
1470         {
1471                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1472                 if(file == -1)
1473                         to_file = FALSE;
1474                 else
1475                         fputs(file, strcat(s, "\n"));
1476         }
1477
1478         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1479         if(to_console)
1480                 print(s, "\n");
1481         if(to_eventlog)
1482                 GameLogEcho(s);
1483         if(to_file)
1484                 fputs(file, strcat(s, "\n"));
1485
1486         FOR_EACH_CLIENT(other)
1487         {
1488                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1489                 {
1490                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1491                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1492                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1493                                 s = strcat(s, ftos(other.team), ":");
1494                         else
1495                                 s = strcat(s, "spectator:");
1496
1497                         if(to_console)
1498                                 print(s, other.netname, "\n");
1499                         if(to_eventlog)
1500                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1501                         if(to_file)
1502                                 fputs(file, strcat(s, other.netname, "\n"));
1503                 }
1504         }
1505
1506         if(teams_matter)
1507         {
1508                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1509                 if(to_console)
1510                         print(s, "\n");
1511                 if(to_eventlog)
1512                         GameLogEcho(s);
1513                 if(to_file)
1514                         fputs(file, strcat(s, "\n"));
1515
1516                 for(i = 1; i < 16; ++i)
1517                 {
1518                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1519                         s = strcat(s, ":", ftos(i));
1520                         if(to_console)
1521                                 print(s, "\n");
1522                         if(to_eventlog)
1523                                 GameLogEcho(s);
1524                         if(to_file)
1525                                 fputs(file, strcat(s, "\n"));
1526                 }
1527         }
1528
1529         if(to_console)
1530                 print(":end\n");
1531         if(to_eventlog)
1532                 GameLogEcho(":end");
1533         if(to_file)
1534         {
1535                 fputs(file, ":end\n");
1536                 fclose(file);
1537         }
1538 }
1539
1540 void FixIntermissionClient(entity e)
1541 {
1542         string s;
1543         if(!e.autoscreenshot) // initial call
1544         {
1545                 e.angles = e.v_angle;
1546                 e.angles_x = -e.angles_x;
1547                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1548                 e.health = -2342;
1549                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1550                 e.solid = SOLID_NOT;
1551                 e.movetype = MOVETYPE_NONE;
1552                 e.takedamage = DAMAGE_NO;
1553                 if(e.weaponentity)
1554                 {
1555                         e.weaponentity.effects = EF_NODRAW;
1556                         if (e.weaponentity.weaponentity)
1557                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1558                 }
1559                 if(clienttype(e) == CLIENTTYPE_REAL)
1560                 {
1561                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1562                         s = autocvar_sv_intermission_cdtrack;
1563                         if(s != "")
1564                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1565                         msg_entity = e;
1566                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1567                 }
1568         }
1569
1570         //e.velocity = '0 0 0';
1571         //e.fixangle = TRUE;
1572
1573         // TODO halt weapon animation
1574 }
1575
1576
1577 /*
1578 go to the next level for deathmatch
1579 only called if a time or frag limit has expired
1580 */
1581 void NextLevel()
1582 {
1583         gameover = TRUE;
1584
1585         intermission_running = 1;
1586
1587 // enforce a wait time before allowing changelevel
1588         if(player_count > 0)
1589                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1590         else
1591                 intermission_exittime = -1;
1592
1593         /*
1594         WriteByte (MSG_ALL, SVC_CDTRACK);
1595         WriteByte (MSG_ALL, 3);
1596         WriteByte (MSG_ALL, 3);
1597         // done in FixIntermission
1598         */
1599
1600         //pos = FindIntermission ();
1601
1602         VoteReset();
1603
1604         DumpStats(TRUE);
1605
1606         // send statistics
1607         entity e;
1608         PlayerStats_EndMatch(1);
1609         FOR_EACH_CLIENT(e)
1610                 PlayerStats_AddGlobalInfo(e);
1611         PlayerStats_Shutdown();
1612
1613         if(autocvar_sv_eventlog)
1614                 GameLogEcho(":gameover");
1615
1616         GameLogClose();
1617
1618         FOR_EACH_PLAYER(other) {
1619                 FixIntermissionClient(other);
1620                 if(other.winning)
1621                         bprint(other.netname, " ^7wins.\n");
1622         }
1623
1624         if(autocvar_g_campaign)
1625                 CampaignPreIntermission();
1626
1627         localcmd("\nsv_hook_gameend\n");
1628 }
1629
1630 /*
1631 ============
1632 CheckRules_Player
1633
1634 Exit deathmatch games upon conditions
1635 ============
1636 */
1637 void CheckRules_Player()
1638 {
1639         if (gameover)   // someone else quit the game already
1640                 return;
1641
1642         if(self.deadflag == DEAD_NO)
1643                 self.play_time += frametime;
1644
1645         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1646         //   (div0: and that in CheckRules_World please)
1647 };
1648
1649 float checkrules_equality;
1650 float checkrules_suddendeathwarning;
1651 float checkrules_suddendeathend;
1652 float checkrules_overtimesadded; //how many overtimes have been already added
1653
1654 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1655 float WINNING_YES = 1; // winner found
1656 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1657 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1658
1659 float InitiateSuddenDeath()
1660 {
1661         // Check first whether normal overtimes could be added before initiating suddendeath mode
1662         // - for this timelimit_overtime needs to be >0 of course
1663         // - also check the winning condition calculated in the previous frame and only add normal overtime
1664         //   again, if at the point at which timelimit would be extended again, still no winner was found
1665         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1666         {
1667                 return 1; // need to call InitiateOvertime later
1668         }
1669         else
1670         {
1671                 if(!checkrules_suddendeathend)
1672                 {
1673                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1674                         if(g_race && !g_race_qualifying)
1675                                 race_StartCompleting();
1676                 }
1677                 return 0;
1678         }
1679 }
1680
1681 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1682 {
1683         ++checkrules_overtimesadded;
1684         //add one more overtime by simply extending the timelimit
1685         float tl;
1686         tl = autocvar_timelimit;
1687         tl += autocvar_timelimit_overtime;
1688         cvar_set("timelimit", ftos(tl));
1689         string minutesPlural;
1690         if (autocvar_timelimit_overtime == 1)
1691                 minutesPlural = " ^3minute";
1692         else
1693                 minutesPlural = " ^3minutes";
1694
1695         bcenterprint(
1696                 strcat(
1697                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1698                         ftos(autocvar_timelimit_overtime),
1699                         minutesPlural,
1700                         " to the game!"
1701                 )
1702         );
1703 }
1704
1705 float GetWinningCode(float fraglimitreached, float equality)
1706 {
1707         if(autocvar_g_campaign == 1)
1708                 if(fraglimitreached)
1709                         return WINNING_YES;
1710                 else
1711                         return WINNING_NO;
1712
1713         else
1714                 if(equality)
1715                         if(fraglimitreached)
1716                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1717                         else
1718                                 return WINNING_NEVER;
1719                 else
1720                         if(fraglimitreached)
1721                                 return WINNING_YES;
1722                         else
1723                                 return WINNING_NO;
1724 }
1725
1726 // set the .winning flag for exactly those players with a given field value
1727 void SetWinners(.float field, float value)
1728 {
1729         entity head;
1730         FOR_EACH_PLAYER(head)
1731                 head.winning = (head.field == value);
1732 }
1733
1734 // set the .winning flag for those players with a given field value
1735 void AddWinners(.float field, float value)
1736 {
1737         entity head;
1738         FOR_EACH_PLAYER(head)
1739                 if(head.field == value)
1740                         head.winning = 1;
1741 }
1742
1743 // clear the .winning flags
1744 void ClearWinners(void)
1745 {
1746         entity head;
1747         FOR_EACH_PLAYER(head)
1748                 head.winning = 0;
1749 }
1750
1751 // Onslaught winning condition:
1752 // game terminates if only one team has a working generator (or none)
1753 float WinningCondition_Onslaught()
1754 {
1755         entity head;
1756         local float t1, t2, t3, t4;
1757
1758         WinningConditionHelper(); // set worldstatus
1759
1760         if(inWarmupStage)
1761                 return WINNING_NO;
1762
1763         // first check if the game has ended
1764         t1 = t2 = t3 = t4 = 0;
1765         head = find(world, classname, "onslaught_generator");
1766         while (head)
1767         {
1768                 if (head.health > 0)
1769                 {
1770                         if (head.team == COLOR_TEAM1) t1 = 1;
1771                         if (head.team == COLOR_TEAM2) t2 = 1;
1772                         if (head.team == COLOR_TEAM3) t3 = 1;
1773                         if (head.team == COLOR_TEAM4) t4 = 1;
1774                 }
1775                 head = find(head, classname, "onslaught_generator");
1776         }
1777         if (t1 + t2 + t3 + t4 < 2)
1778         {
1779                 // game over, only one team remains (or none)
1780                 ClearWinners();
1781                 if (t1) SetWinners(team, COLOR_TEAM1);
1782                 if (t2) SetWinners(team, COLOR_TEAM2);
1783                 if (t3) SetWinners(team, COLOR_TEAM3);
1784                 if (t4) SetWinners(team, COLOR_TEAM4);
1785                 dprint("Have a winner, ending game.\n");
1786                 return WINNING_YES;
1787         }
1788
1789         // Two or more teams remain
1790         return WINNING_NO;
1791 }
1792
1793 float LMS_NewPlayerLives()
1794 {
1795         float fl;
1796         fl = autocvar_fraglimit;
1797         if(fl == 0)
1798                 fl = 999;
1799
1800         // first player has left the game for dying too much? Nobody else can get in.
1801         if(lms_lowest_lives < 1)
1802                 return 0;
1803
1804         if(!autocvar_g_lms_join_anytime)
1805                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1806                         return 0;
1807
1808         return bound(1, lms_lowest_lives, fl);
1809 }
1810
1811 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1812 // they win. Otherwise the defending team wins once the timelimit passes.
1813 void assault_new_round();
1814 float WinningCondition_Assault()
1815 {
1816         local float status;
1817
1818         WinningConditionHelper(); // set worldstatus
1819
1820         status = WINNING_NO;
1821         // as the timelimit has not yet passed just assume the defending team will win
1822         if(assault_attacker_team == COLOR_TEAM1)
1823         {
1824                 SetWinners(team, COLOR_TEAM2);
1825         }
1826         else
1827         {
1828                 SetWinners(team, COLOR_TEAM1);
1829         }
1830
1831         local entity ent;
1832         ent = find(world, classname, "target_assault_roundend");
1833         if(ent)
1834         {
1835                 if(ent.winning) // round end has been triggered by attacking team
1836                 {
1837                         bprint("ASSAULT: round completed...\n");
1838                         SetWinners(team, assault_attacker_team);
1839
1840                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1841
1842                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1843                         {
1844                                 status = WINNING_YES;
1845                         }
1846                         else
1847                         {
1848                                 local entity oldself;
1849                                 oldself = self;
1850                                 self = ent;
1851                                 assault_new_round();
1852                                 self = oldself;
1853                         }
1854                 }
1855         }
1856
1857         return status;
1858 }
1859
1860 // LMS winning condition: game terminates if and only if there's at most one
1861 // one player who's living lives. Top two scores being equal cancels the time
1862 // limit.
1863 float WinningCondition_LMS()
1864 {
1865         entity head, head2;
1866         float have_player;
1867         float have_players;
1868         float l;
1869
1870         have_player = FALSE;
1871         have_players = FALSE;
1872         l = LMS_NewPlayerLives();
1873
1874         head = find(world, classname, "player");
1875         if(head)
1876                 have_player = TRUE;
1877         head2 = find(head, classname, "player");
1878         if(head2)
1879                 have_players = TRUE;
1880
1881         if(have_player)
1882         {
1883                 // we have at least one player
1884                 if(have_players)
1885                 {
1886                         // two or more active players - continue with the game
1887                 }
1888                 else
1889                 {
1890                         // exactly one player?
1891
1892                         ClearWinners();
1893                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1894
1895                         if(l)
1896                         {
1897                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1898                                 return WINNING_NO;
1899                         }
1900                         else
1901                         {
1902                                 // a winner!
1903                                 // and assign him his first place
1904                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1905                                 return WINNING_YES;
1906                         }
1907                 }
1908         }
1909         else
1910         {
1911                 // nobody is playing at all...
1912                 if(l)
1913                 {
1914                         // wait for players...
1915                 }
1916                 else
1917                 {
1918                         // SNAFU (maybe a draw game?)
1919                         ClearWinners();
1920                         dprint("No players, ending game.\n");
1921                         return WINNING_YES;
1922                 }
1923         }
1924
1925         // When we get here, we have at least two players who are actually LIVING,
1926         // now check if the top two players have equal score.
1927         WinningConditionHelper();
1928
1929         ClearWinners();
1930         if(WinningConditionHelper_winner)
1931                 WinningConditionHelper_winner.winning = TRUE;
1932         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1933                 return WINNING_NEVER;
1934
1935         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1936         return WINNING_NO;
1937 }
1938
1939 void ShuffleMaplist()
1940 {
1941         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1942 }
1943
1944 float leaderfrags;
1945 float WinningCondition_Scores(float limit, float leadlimit)
1946 {
1947         float limitreached;
1948
1949         // TODO make everything use THIS winning condition (except LMS)
1950         WinningConditionHelper();
1951
1952         if(teams_matter)
1953         {
1954                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1955                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1956                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1957                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1958         }
1959
1960         ClearWinners();
1961         if(WinningConditionHelper_winner)
1962                 WinningConditionHelper_winner.winning = 1;
1963         if(WinningConditionHelper_winnerteam >= 0)
1964                 SetWinners(team, WinningConditionHelper_winnerteam);
1965
1966         if(WinningConditionHelper_lowerisbetter)
1967         {
1968                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1969                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1970                 limit = -limit;
1971         }
1972
1973         if(WinningConditionHelper_zeroisworst)
1974                 leadlimit = 0; // not supported in this mode
1975
1976         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1977         // these modes always score in increments of 1, thus this makes sense
1978         {
1979                 if(leaderfrags != WinningConditionHelper_topscore)
1980                 {
1981                         leaderfrags = WinningConditionHelper_topscore;
1982
1983                         if (limit)
1984                         if (leaderfrags == limit - 1)
1985                                 Announce("1fragleft");
1986                         else if (leaderfrags == limit - 2)
1987                                 Announce("2fragsleft");
1988                         else if (leaderfrags == limit - 3)
1989                                 Announce("3fragsleft");
1990                 }
1991         }
1992
1993         limitreached = FALSE;
1994         if(limit)
1995                 if(WinningConditionHelper_topscore >= limit)
1996                         limitreached = TRUE;
1997         if(leadlimit)
1998         {
1999                 float leadlimitreached;
2000                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2001                 if(autocvar_leadlimit_and_fraglimit)
2002                         limitreached = (limitreached && leadlimitreached);
2003                 else
2004                         limitreached = (limitreached || leadlimitreached);
2005         }
2006
2007         return GetWinningCode(
2008                 WinningConditionHelper_topscore && limitreached,
2009                 WinningConditionHelper_equality
2010         );
2011 }
2012
2013 float WinningCondition_Race(float fraglimit)
2014 {
2015         float wc;
2016         entity p;
2017         float n, c;
2018
2019         n = 0;
2020         c = 0;
2021         FOR_EACH_PLAYER(p)
2022         {
2023                 ++n;
2024                 if(p.race_completed)
2025                         ++c;
2026         }
2027         if(n && (n == c))
2028                 return WINNING_YES;
2029         wc = WinningCondition_Scores(fraglimit, 0);
2030
2031         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2032         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2033         // do NOT support equality when the laps are all raced!
2034                 return WINNING_STARTSUDDENDEATHOVERTIME;
2035         else
2036                 return WINNING_NEVER;
2037         return wc;
2038 }
2039
2040 void ReadyRestart();
2041 float WinningCondition_QualifyingThenRace(float limit)
2042 {
2043         float wc;
2044         wc = WinningCondition_Scores(limit, 0);
2045
2046         // NEVER initiate overtime
2047         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2048         {
2049                 return WINNING_YES;
2050         }
2051
2052         return wc;
2053 }
2054
2055 float WinningCondition_RanOutOfSpawns()
2056 {
2057         entity head;
2058
2059         if(have_team_spawns <= 0)
2060                 return WINNING_NO;
2061
2062         if(!some_spawn_has_been_used)
2063                 return WINNING_NO;
2064
2065         team1_score = team2_score = team3_score = team4_score = 0;
2066
2067         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2068         {
2069                 if(head.team == COLOR_TEAM1)
2070                         team1_score = 1;
2071                 else if(head.team == COLOR_TEAM2)
2072                         team2_score = 1;
2073                 else if(head.team == COLOR_TEAM3)
2074                         team3_score = 1;
2075                 else if(head.team == COLOR_TEAM4)
2076                         team4_score = 1;
2077         }
2078
2079         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2080         {
2081                 if(head.team == COLOR_TEAM1)
2082                         team1_score = 1;
2083                 else if(head.team == COLOR_TEAM2)
2084                         team2_score = 1;
2085                 else if(head.team == COLOR_TEAM3)
2086                         team3_score = 1;
2087                 else if(head.team == COLOR_TEAM4)
2088                         team4_score = 1;
2089         }
2090
2091         ClearWinners();
2092         if(team1_score + team2_score + team3_score + team4_score == 0)
2093         {
2094                 checkrules_equality = TRUE;
2095                 return WINNING_YES;
2096         }
2097         else if(team1_score + team2_score + team3_score + team4_score == 1)
2098         {
2099                 float t, i;
2100                 if(team1_score) t = COLOR_TEAM1;
2101                 if(team2_score) t = COLOR_TEAM2;
2102                 if(team3_score) t = COLOR_TEAM3;
2103                 if(team4_score) t = COLOR_TEAM4;
2104                 CheckAllowedTeams(world);
2105                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2106                 {
2107                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2108                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2109                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2110                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2111                 }
2112
2113                 AddWinners(team, t);
2114                 return WINNING_YES;
2115         }
2116         else
2117                 return WINNING_NO;
2118 }
2119
2120 /*
2121 ============
2122 CheckRules_World
2123
2124 Exit deathmatch games upon conditions
2125 ============
2126 */
2127 void CheckRules_World()
2128 {
2129         float timelimit;
2130         float fraglimit;
2131         float leadlimit;
2132
2133         VoteThink();
2134         MapVote_Think();
2135
2136         SetDefaultAlpha();
2137
2138         /*
2139         MapVote_Think should now do that part
2140         if (intermission_running)
2141                 if (time >= intermission_exittime + 60)
2142                 {
2143                         if(!DoNextMapOverride())
2144                                 GotoNextMap();
2145                         return;
2146                 }
2147         */
2148
2149         if (gameover)   // someone else quit the game already
2150         {
2151                 if(player_count == 0) // Nobody there? Then let's go to the next map
2152                         MapVote_Start();
2153                         // this will actually check the player count in the next frame
2154                         // again, but this shouldn't hurt
2155                 return;
2156         }
2157
2158         timelimit = autocvar_timelimit * 60;
2159         fraglimit = autocvar_fraglimit;
2160         leadlimit = autocvar_leadlimit;
2161
2162         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2163         {
2164                 if(timelimit > 0)
2165                         timelimit = 0; // timelimit is not made for warmup
2166                 if(fraglimit > 0)
2167                         fraglimit = 0; // no fraglimit for now
2168                 leadlimit = 0; // no leadlimit for now
2169         }
2170
2171         if(g_onslaught)
2172                 timelimit = 0; // ONS has its own overtime rule
2173
2174         if(timelimit > 0)
2175         {
2176                 timelimit += game_starttime;
2177         }
2178         else if (timelimit < 0)
2179         {
2180                 // endmatch
2181                 NextLevel();
2182                 return;
2183         }
2184
2185         float wantovertime;
2186         wantovertime = 0;
2187
2188         if(checkrules_suddendeathend)
2189         {
2190                 if(!checkrules_suddendeathwarning)
2191                 {
2192                         checkrules_suddendeathwarning = TRUE;
2193                         if(g_race && !g_race_qualifying)
2194                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2195                         else
2196                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2197                 }
2198         }
2199         else
2200         {
2201                 if (timelimit && time >= timelimit)
2202                 {
2203                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2204                         {
2205                                 float totalplayers;
2206                                 float playerswithlaps;
2207                                 float readyplayers;
2208                                 entity head;
2209                                 totalplayers = playerswithlaps = readyplayers = 0;
2210                                 FOR_EACH_PLAYER(head)
2211                                 {
2212                                         ++totalplayers;
2213                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2214                                                 ++playerswithlaps;
2215                                         if(head.ready)
2216                                                 ++readyplayers;
2217                                 }
2218
2219                                 // at least 2 of the players have completed a lap: start the RACE
2220                                 // otherwise, the players should end the qualifying on their own
2221                                 if(readyplayers || playerswithlaps >= 2)
2222                                 {
2223                                         checkrules_suddendeathend = 0;
2224                                         ReadyRestart(); // go to race
2225                                         return;
2226                                 }
2227                                 else
2228                                         wantovertime |= InitiateSuddenDeath();
2229                         }
2230                         else
2231                                 wantovertime |= InitiateSuddenDeath();
2232                 }
2233         }
2234
2235         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2236         {
2237                 NextLevel();
2238                 return;
2239         }
2240
2241         float checkrules_status;
2242         checkrules_status = WinningCondition_RanOutOfSpawns();
2243         if(checkrules_status == WINNING_YES)
2244         {
2245                 bprint("Hey! Someone ran out of spawns!\n");
2246         }
2247         else if(g_race && !g_race_qualifying && timelimit >= 0)
2248         {
2249                 checkrules_status = WinningCondition_Race(fraglimit);
2250                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2251         }
2252         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2253         {
2254                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2255                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2256         }
2257         else if(g_assault)
2258         {
2259                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2260         }
2261         else if(g_lms)
2262         {
2263                 checkrules_status = WinningCondition_LMS();
2264         }
2265         else if (g_onslaught)
2266         {
2267                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2268         }
2269         else
2270         {
2271                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2272                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2273         }
2274
2275         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2276         {
2277                 checkrules_status = WINNING_NEVER;
2278                 checkrules_overtimesadded = -1;
2279                 wantovertime |= InitiateSuddenDeath();
2280         }
2281
2282         if(checkrules_status == WINNING_NEVER)
2283                 // equality cases! Nobody wins if the overtime ends in a draw.
2284                 ClearWinners();
2285
2286         if(wantovertime)
2287         {
2288                 if(checkrules_status == WINNING_NEVER)
2289                         InitiateOvertime();
2290                 else
2291                         checkrules_status = WINNING_YES;
2292         }
2293
2294         if(checkrules_suddendeathend)
2295                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2296                         checkrules_status = WINNING_YES;
2297
2298         if(checkrules_status == WINNING_YES)
2299         {
2300                 //print("WINNING\n");
2301                 NextLevel();
2302         }
2303 };
2304
2305 float mapvote_nextthink;
2306 float mapvote_initialized;
2307 float mapvote_keeptwotime;
2308 float mapvote_timeout;
2309 string mapvote_message;
2310 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2311 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2312 float mapvote_screenshot_dirs_count;
2313
2314 float mapvote_count;
2315 float mapvote_count_real;
2316 string mapvote_maps[MAPVOTE_COUNT];
2317 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2318 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2319 float mapvote_maps_suggested[MAPVOTE_COUNT];
2320 string mapvote_suggestions[MAPVOTE_COUNT];
2321 float mapvote_suggestion_ptr;
2322 float mapvote_maxlen;
2323 float mapvote_voters;
2324 float mapvote_votes[MAPVOTE_COUNT];
2325 float mapvote_run;
2326 float mapvote_detail;
2327 float mapvote_abstain;
2328 .float mapvote;
2329
2330 void MapVote_ClearAllVotes()
2331 {
2332         FOR_EACH_CLIENT(other)
2333                 other.mapvote = 0;
2334 }
2335
2336 string MapVote_Suggest(string m)
2337 {
2338         float i;
2339         if(m == "")
2340                 return "That's not how to use this command.";
2341         if(!autocvar_g_maplist_votable_suggestions)
2342                 return "Suggestions are not accepted on this server.";
2343         if(mapvote_initialized)
2344                 return "Can't suggest - voting is already in progress!";
2345         m = MapInfo_FixName(m);
2346         if(!m)
2347                 return "The map you suggested is not available on this server.";
2348         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2349                 if(Map_IsRecent(m))
2350                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2351
2352         if(!MapInfo_CheckMap(m))
2353                 return "The map you suggested does not support the current game mode.";
2354         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2355                 if(mapvote_suggestions[i] == m)
2356                         return "This map was already suggested.";
2357         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2358         {
2359                 i = floor(random() * mapvote_suggestion_ptr);
2360         }
2361         else
2362         {
2363                 i = mapvote_suggestion_ptr;
2364                 mapvote_suggestion_ptr += 1;
2365         }
2366         if(mapvote_suggestions[i] != "")
2367                 strunzone(mapvote_suggestions[i]);
2368         mapvote_suggestions[i] = strzone(m);
2369         if(autocvar_sv_eventlog)
2370                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2371         return strcat("Suggestion of ", m, " accepted.");
2372 }
2373
2374 void MapVote_AddVotable(string nextMap, float isSuggestion)
2375 {
2376         float j, i, o;
2377         string pakfile, mapfile;
2378
2379         if(nextMap == "")
2380                 return;
2381         for(j = 0; j < mapvote_count; ++j)
2382                 if(mapvote_maps[j] == nextMap)
2383                         return;
2384         if(strlen(nextMap) > mapvote_maxlen)
2385                 mapvote_maxlen = strlen(nextMap);
2386         mapvote_maps[mapvote_count] = strzone(nextMap);
2387         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2388
2389         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2390         {
2391                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2392                 pakfile = whichpack(strcat(mapfile, ".tga"));
2393                 if(pakfile == "")
2394                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2395                 if(pakfile == "")
2396                         pakfile = whichpack(strcat(mapfile, ".png"));
2397                 if(pakfile != "")
2398                         break;
2399         }
2400         if(i >= mapvote_screenshot_dirs_count)
2401                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2402         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2403                 pakfile = substring(pakfile, o, -1);
2404
2405         mapvote_maps_screenshot_dir[mapvote_count] = i;
2406         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2407
2408         mapvote_count += 1;
2409 }
2410
2411 void MapVote_Spawn();
2412 void MapVote_Init()
2413 {
2414         float i;
2415         float nmax, smax;
2416
2417         MapVote_ClearAllVotes();
2418
2419         mapvote_count = 0;
2420         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2421         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2422
2423         if(mapvote_abstain)
2424                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2425         else
2426                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2427         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2428
2429         // we need this for AddVotable, as that cycles through the screenshot dirs
2430         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2431         if(mapvote_screenshot_dirs_count == 0)
2432                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2433         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2434         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2435                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2436
2437         if(mapvote_suggestion_ptr)
2438                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2439                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2440
2441         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2442                 MapVote_AddVotable(GetNextMap(), FALSE);
2443
2444         if(mapvote_count == 0)
2445         {
2446                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2447                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2448                 if(autocvar_g_maplist_shuffle)
2449                         ShuffleMaplist();
2450                 localcmd("\nmenu_cmd sync\n");
2451                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2452                         MapVote_AddVotable(GetNextMap(), FALSE);
2453         }
2454
2455         mapvote_count_real = mapvote_count;
2456         if(mapvote_abstain)
2457                 MapVote_AddVotable("don't care", 0);
2458
2459         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2460
2461         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2462         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2463         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2464                 mapvote_keeptwotime = 0;
2465         mapvote_message = "Choose a map and press its key!";
2466
2467         MapVote_Spawn();
2468 }
2469
2470 void MapVote_SendPicture(float id)
2471 {
2472         msg_entity = self;
2473         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2474         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2475         WriteByte(MSG_ONE, id);
2476         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2477 }
2478
2479 float GameCommand_MapVote(string cmd)
2480 {
2481         if(!intermission_running)
2482                 return FALSE;
2483
2484         if(cmd == "mv_getpic")
2485         {
2486                 MapVote_SendPicture(stof(argv(1)));
2487                 return TRUE;
2488         }
2489
2490         return FALSE;
2491 }
2492
2493 float MapVote_GetMapMask()
2494 {
2495         float mask, i, power;
2496         mask = 0;
2497         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2498                 if(mapvote_maps[i] != "")
2499                         mask |= power;
2500         return mask;
2501 }
2502
2503 entity mapvote_ent;
2504 float MapVote_SendEntity(entity to, float sf)
2505 {
2506         float i;
2507
2508         if(sf & 1)
2509                 sf &~= 2; // if we send 1, we don't need to also send 2
2510
2511         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2512         WriteByte(MSG_ENTITY, sf);
2513
2514         if(sf & 1)
2515         {
2516                 // flag 1 == initialization
2517                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2518                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2519                 WriteString(MSG_ENTITY, "");
2520                 WriteByte(MSG_ENTITY, mapvote_count);
2521                 WriteByte(MSG_ENTITY, mapvote_abstain);
2522                 WriteByte(MSG_ENTITY, mapvote_detail);
2523                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2524                 if(mapvote_count <= 8)
2525                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2526                 else
2527                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2528                 for(i = 0; i < mapvote_count; ++i)
2529                         if(mapvote_maps[i] != "")
2530                         {
2531                                 if(mapvote_abstain && i == mapvote_count - 1)
2532                                 {
2533                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2534                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2535                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2536                                 }
2537                                 else
2538                                 {
2539                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2540                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2541                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2542                                 }
2543                         }
2544         }
2545
2546         if(sf & 2)
2547         {
2548                 // flag 2 == update of mask
2549                 if(mapvote_count <= 8)
2550                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2551                 else
2552                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2553         }
2554
2555         if(sf & 4)
2556         {
2557                 if(mapvote_detail)
2558                         for(i = 0; i < mapvote_count; ++i)
2559                                 if(mapvote_maps[i] != "")
2560                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2561
2562                 WriteByte(MSG_ENTITY, to.mapvote);
2563         }
2564
2565         return TRUE;
2566 }
2567
2568 void MapVote_Spawn()
2569 {
2570         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2571 }
2572
2573 void MapVote_TouchMask()
2574 {
2575         mapvote_ent.SendFlags |= 2;
2576 }
2577
2578 void MapVote_TouchVotes(entity voter)
2579 {
2580         mapvote_ent.SendFlags |= 4;
2581 }
2582
2583 float MapVote_Finished(float mappos)
2584 {
2585         string result;
2586         float i;
2587         float didntvote;
2588
2589         if(autocvar_sv_eventlog)
2590         {
2591                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2592                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2593                 didntvote = mapvote_voters;
2594                 for(i = 0; i < mapvote_count; ++i)
2595                         if(mapvote_maps[i] != "")
2596                         {
2597                                 didntvote -= mapvote_votes[i];
2598                                 if(i != mappos)
2599                                 {
2600                                         result = strcat(result, ":", mapvote_maps[i]);
2601                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2602                                 }
2603                         }
2604                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2605
2606                 GameLogEcho(result);
2607                 if(mapvote_maps_suggested[mappos])
2608                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2609         }
2610
2611         FOR_EACH_REALCLIENT(other)
2612                 FixClientCvars(other);
2613
2614         Map_Goto_SetStr(mapvote_maps[mappos]);
2615         Map_Goto();
2616         alreadychangedlevel = TRUE;
2617         return TRUE;
2618 }
2619 void MapVote_CheckRules_1()
2620 {
2621         float i;
2622
2623         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2624         {
2625                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2626                 mapvote_votes[i] = 0;
2627         }
2628
2629         mapvote_voters = 0;
2630         FOR_EACH_REALCLIENT(other)
2631         {
2632                 ++mapvote_voters;
2633                 if(other.mapvote)
2634                 {
2635                         i = other.mapvote - 1;
2636                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2637                         mapvote_votes[i] = mapvote_votes[i] + 1;
2638                 }
2639         }
2640 }
2641
2642 float MapVote_CheckRules_2()
2643 {
2644         float i;
2645         float firstPlace, secondPlace;
2646         float firstPlaceVotes, secondPlaceVotes;
2647         float mapvote_voters_real;
2648         string result;
2649
2650         if(mapvote_count_real == 1)
2651                 return MapVote_Finished(0);
2652
2653         mapvote_voters_real = mapvote_voters;
2654         if(mapvote_abstain)
2655                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2656
2657         RandomSelection_Init();
2658         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2659                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2660         firstPlace = RandomSelection_chosen_float;
2661         firstPlaceVotes = RandomSelection_best_priority;
2662         //dprint("First place: ", ftos(firstPlace), "\n");
2663         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2664
2665         RandomSelection_Init();
2666         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2667                 if(i != firstPlace)
2668                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2669         secondPlace = RandomSelection_chosen_float;
2670         secondPlaceVotes = RandomSelection_best_priority;
2671         //dprint("Second place: ", ftos(secondPlace), "\n");
2672         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2673
2674         if(firstPlace == -1)
2675                 error("No first place in map vote... WTF?");
2676
2677         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2678                 return MapVote_Finished(firstPlace);
2679
2680         if(mapvote_keeptwotime)
2681                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2682                 {
2683                         float didntvote;
2684                         MapVote_TouchMask();
2685                         mapvote_message = "Now decide between the TOP TWO!";
2686                         mapvote_keeptwotime = 0;
2687                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2688                         result = strcat(result, ":", ftos(firstPlaceVotes));
2689                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2690                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2691                         didntvote = mapvote_voters;
2692                         for(i = 0; i < mapvote_count; ++i)
2693                                 if(mapvote_maps[i] != "")
2694                                 {
2695                                         didntvote -= mapvote_votes[i];
2696                                         if(i != firstPlace)
2697                                                 if(i != secondPlace)
2698                                                 {
2699                                                         result = strcat(result, ":", mapvote_maps[i]);
2700                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2701                                                         if(i < mapvote_count_real)
2702                                                         {
2703                                                                 strunzone(mapvote_maps[i]);
2704                                                                 mapvote_maps[i] = "";
2705                                                                 strunzone(mapvote_maps_pakfile[i]);
2706                                                                 mapvote_maps_pakfile[i] = "";
2707                                                         }
2708                                                 }
2709                                 }
2710                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2711                         if(autocvar_sv_eventlog)
2712                                 GameLogEcho(result);
2713                 }
2714
2715         return FALSE;
2716 }
2717 void MapVote_Tick()
2718 {
2719         float keeptwo;
2720         float totalvotes;
2721
2722         keeptwo = mapvote_keeptwotime;
2723         MapVote_CheckRules_1(); // count
2724         if(MapVote_CheckRules_2()) // decide
2725                 return;
2726
2727         totalvotes = 0;
2728         FOR_EACH_REALCLIENT(other)
2729         {
2730                 // hide scoreboard again
2731                 if(other.health != 2342)
2732                 {
2733                         other.health = 2342;
2734                         other.impulse = 0;
2735                         if(clienttype(other) == CLIENTTYPE_REAL)
2736                         {
2737                                 msg_entity = other;
2738                                 WriteByte(MSG_ONE, SVC_FINALE);
2739                                 WriteString(MSG_ONE, "");
2740                         }
2741                 }
2742
2743                 // clear possibly invalid votes
2744                 if(mapvote_maps[other.mapvote - 1] == "")
2745                         other.mapvote = 0;
2746                 // use impulses as new vote
2747                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2748                         if(mapvote_maps[other.impulse - 1] != "")
2749                         {
2750                                 other.mapvote = other.impulse;
2751                                 MapVote_TouchVotes(other);
2752                         }
2753                 other.impulse = 0;
2754
2755                 if(other.mapvote)
2756                         ++totalvotes;
2757         }
2758
2759         MapVote_CheckRules_1(); // just count
2760 }
2761 void MapVote_Start()
2762 {
2763         if(mapvote_run)
2764                 return;
2765
2766         // wait for stats to be sent first
2767         if(!playerstats_waitforme)
2768                 return;
2769
2770         MapInfo_Enumerate();
2771         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2772                 mapvote_run = TRUE;
2773 }
2774 void MapVote_Think()
2775 {
2776         if(!mapvote_run)
2777                 return;
2778
2779         if(alreadychangedlevel)
2780                 return;
2781
2782         if(time < mapvote_nextthink)
2783                 return;
2784         //dprint("tick\n");
2785
2786         mapvote_nextthink = time + 0.5;
2787
2788         if(!mapvote_initialized)
2789         {
2790                 if(autocvar_rescan_pending == 1)
2791                 {
2792                         cvar_set("rescan_pending", "2");
2793                         localcmd("fs_rescan\nrescan_pending 3\n");
2794                         return;
2795                 }
2796                 else if(autocvar_rescan_pending == 2)
2797                 {
2798                         return;
2799                 }
2800                 else if(autocvar_rescan_pending == 3)
2801                 {
2802                         // now build missing mapinfo files
2803                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2804                                 return;
2805
2806                         // we're done, start the timer
2807                         cvar_set("rescan_pending", "0");
2808                 }
2809
2810                 mapvote_initialized = TRUE;
2811                 if(DoNextMapOverride())
2812                         return;
2813                 if(!autocvar_g_maplist_votable || player_count <= 0)
2814                 {
2815                         GotoNextMap();
2816                         return;
2817                 }
2818                 MapVote_Init();
2819         }
2820
2821         MapVote_Tick();
2822 };
2823
2824 string GotoMap(string m)
2825 {
2826         if(!MapInfo_CheckMap(m))
2827                 return "The map you chose is not available on this server.";
2828         cvar_set("nextmap", m);
2829         cvar_set("timelimit", "-1");
2830         if(mapvote_initialized || alreadychangedlevel)
2831         {
2832                 if(DoNextMapOverride())
2833                         return "Map switch initiated.";
2834                 else
2835                         return "Hm... no. For some reason I like THIS map more.";
2836         }
2837         else
2838                 return "Map switch will happen after scoreboard.";
2839 }
2840
2841
2842 void EndFrame()
2843 {
2844         float altime;
2845         FOR_EACH_REALCLIENT(self)
2846         {
2847                 if(self.classname == "spectator")
2848                 {
2849                         if(self.enemy.typehitsound)
2850                                 self.typehit_time = time;
2851                         else if(self.enemy.hitsound)
2852                                 self.hit_time = time;
2853                 }
2854                 else
2855                 {
2856                         if(self.typehitsound)
2857                                 self.typehit_time = time;
2858                         else if(self.hitsound)
2859                                 self.hit_time = time;
2860                 }
2861         }
2862         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2863         // add 1 frametime because after this, engine SV_Physics
2864         // increases time by a frametime and then networks the frame
2865         // add another frametime because client shows everything with
2866         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2867         // needed!
2868         FOR_EACH_CLIENT(self)
2869         {
2870                 self.hitsound = FALSE;
2871                 self.typehitsound = FALSE;
2872                 antilag_record(self, altime);
2873         }
2874 }
2875
2876
2877 /*
2878  * RedirectionThink:
2879  * returns TRUE if redirecting
2880  */
2881 float redirection_timeout;
2882 float redirection_nextthink;
2883 float RedirectionThink()
2884 {
2885         float clients_found;
2886
2887         if(redirection_target == "")
2888                 return FALSE;
2889
2890         if(!redirection_timeout)
2891         {
2892                 cvar_set("sv_public", "-2");
2893                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2894                 if(redirection_target == "self")
2895                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2896                 else
2897                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2898         }
2899
2900         if(time < redirection_nextthink)
2901                 return TRUE;
2902
2903         redirection_nextthink = time + 1;
2904
2905         clients_found = 0;
2906         FOR_EACH_REALCLIENT(self)
2907         {
2908                 print("Redirecting: sending connect command to ", self.netname, "\n");
2909                 if(redirection_target == "self")
2910                         stuffcmd(self, "\ndisconnect; reconnect\n");
2911                 else
2912                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2913                 ++clients_found;
2914         }
2915
2916         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2917
2918         if(time > redirection_timeout || clients_found == 0)
2919                 localcmd("\nwait; wait; wait; quit\n");
2920
2921         return TRUE;
2922 }
2923
2924 void TargetMusic_RestoreGame();
2925 void RestoreGame()
2926 {
2927         // Loaded from a save game
2928         // some things then break, so let's work around them...
2929
2930         // Progs DB (capture records)
2931         ServerProgsDB = db_load("server.db");
2932
2933         // Mapinfo
2934         MapInfo_Shutdown();
2935         MapInfo_Enumerate();
2936         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2937         WeaponStats_Init();
2938
2939         TargetMusic_RestoreGame();
2940 }
2941
2942 void SV_Shutdown()
2943 {
2944         entity e;
2945
2946         if(gameover > 1) // shutting down already?
2947                 return;
2948
2949         gameover = 2; // 2 = server shutting down
2950
2951         if(world_initialized > 0)
2952         {
2953                 world_initialized = 0;
2954                 print("Saving persistent data...\n");
2955                 Ban_SaveBans();
2956
2957                 PlayerStats_EndMatch(0);
2958                 FOR_EACH_CLIENT(e)
2959                         PlayerStats_AddGlobalInfo(e);
2960                 PlayerStats_Shutdown();
2961
2962                 if(!cheatcount_total)
2963                 {
2964                         if(autocvar_sv_db_saveasdump)
2965                                 db_dump(ServerProgsDB, "server.db");
2966                         else
2967                                 db_save(ServerProgsDB, "server.db");
2968                 }
2969                 if(autocvar_developer)
2970                 {
2971                         if(autocvar_sv_db_saveasdump)
2972                                 db_dump(TemporaryDB, "server-temp.db");
2973                         else
2974                                 db_save(TemporaryDB, "server-temp.db");
2975                 }
2976                 CheatShutdown(); // must be after cheatcount check
2977                 db_close(ServerProgsDB);
2978                 db_close(TemporaryDB);
2979                 print("done!\n");
2980                 // tell the bot system the game is ending now
2981                 bot_endgame();
2982
2983                 WeaponStats_Shutdown();
2984                 MapInfo_Shutdown();
2985         }
2986         else if(world_initialized == 0)
2987         {
2988                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2989         }
2990 }