qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include <server/mutators/_mod.qh>
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "scores_rules.qh"
  20 #include "teamplay.qh"
  21 #include "weapons/weaponstats.qh"
  22 #include "../common/constants.qh"
  23 #include <common/net_linked.qh>
  24 #include "../common/deathtypes/all.qh"
  25 #include "../common/gamemodes/sv_rules.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/_mod.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/vehicles/all.qh"
  30 #include "../common/notifications/all.qh"
  31 #include "../common/physics/player.qh"
  32 #include "../common/playerstats.qh"
  33 #include "../common/stats.qh"
  34 #include "../common/teams.qh"
  35 #include "../common/mapobjects/trigger/secret.qh"
  36 #include "../common/mapobjects/target/music.qh"
  37 #include "../common/util.qh"
  38 #include "../common/items/_mod.qh"
  39 #include <common/weapons/_all.qh>
  40 #include "../common/state.qh"
  41
  42 const float LATENCY_THINKRATE = 10;
  43 .float latency_sum;
  44 .float latency_cnt;
  45 .float latency_time;
  46 entity pingplreport;
  47 void PingPLReport_Think(entity this)
  48 {
  49         float delta;
  50         entity e;
  51
  52         delta = 3 / maxclients;
  53         if(delta < sys_frametime)
  54                 delta = 0;
  55         this.nextthink = time + delta;
  56
  57         e = edict_num(this.cnt + 1);
  58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  59         {
  60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  61                 WriteByte(MSG_BROADCAST, this.cnt);
  62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  65
  66                 // record latency times for clients throughout the match so we can report it to playerstats
  67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  68                 {
  69                         CS(e).latency_sum += CS(e).ping;
  70                         CS(e).latency_cnt += 1;
  71                         CS(e).latency_time = time;
  72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  73                 }
  74         }
  75         else
  76         {
  77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  78                 WriteByte(MSG_BROADCAST, this.cnt);
  79                 WriteShort(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82         }
  83         this.cnt = (this.cnt + 1) % maxclients;
  84 }
  85 void PingPLReport_Spawn()
  86 {
  87         pingplreport = new_pure(pingplreport);
  88         setthink(pingplreport, PingPLReport_Think);
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         strfree(cvar_changes);
 148         strfree(cvar_purechanges);
 149         cvar_purechanges_count = 0;
 150
 151         h = buf_create();
 152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 153         n = buf_getsize(h);
 154
 155         adding = true;
 156         pureadding = true;
 157
 158         for(i = 0; i < n; ++i)
 159         {
 160                 k = bufstr_get(h, i);
 161
 162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 164 #define BADCVAR(p) if(k == p) continue
 165
 166                 // general excludes and namespaces for server admin used cvars
 167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 168
 169                 // internal
 170                 BADPREFIX("csqc_");
 171                 BADPREFIX("cvar_check_");
 172                 BADCVAR("gamecfg");
 173                 BADCVAR("g_configversion");
 174                 BADCVAR("halflifebsp");
 175                 BADCVAR("sv_mapformat_is_quake2");
 176                 BADCVAR("sv_mapformat_is_quake3");
 177                 BADPREFIX("sv_world");
 178
 179                 // client
 180                 BADPREFIX("chase_");
 181                 BADPREFIX("cl_");
 182                 BADPREFIX("con_");
 183                 BADPREFIX("scoreboard_");
 184                 BADPREFIX("g_campaign");
 185                 BADPREFIX("g_waypointsprite_");
 186                 BADPREFIX("gl_");
 187                 BADPREFIX("joy");
 188                 BADPREFIX("hud_");
 189                 BADPREFIX("m_");
 190                 BADPREFIX("menu_");
 191                 BADPREFIX("net_slist_");
 192                 BADPREFIX("r_");
 193                 BADPREFIX("sbar_");
 194                 BADPREFIX("scr_");
 195                 BADPREFIX("snd_");
 196                 BADPREFIX("show");
 197                 BADPREFIX("sensitivity");
 198                 BADPREFIX("userbind");
 199                 BADPREFIX("v_");
 200                 BADPREFIX("vid_");
 201                 BADPREFIX("crosshair");
 202                 BADCVAR("mod_q3bsp_lightmapmergepower");
 203                 BADCVAR("mod_q3bsp_nolightmaps");
 204                 BADCVAR("fov");
 205                 BADCVAR("mastervolume");
 206                 BADCVAR("volume");
 207                 BADCVAR("bgmvolume");
 208                 BADCVAR("in_pitch_min");
 209                 BADCVAR("in_pitch_max");
 210
 211                 // private
 212                 BADCVAR("developer");
 213                 BADCVAR("log_dest_udp");
 214                 BADCVAR("net_address");
 215                 BADCVAR("net_address_ipv6");
 216                 BADCVAR("port");
 217                 BADCVAR("savedgamecfg");
 218                 BADCVAR("serverconfig");
 219                 BADCVAR("sv_autoscreenshot");
 220                 BADCVAR("sv_heartbeatperiod");
 221                 BADCVAR("sv_vote_master_password");
 222                 BADCVAR("sys_colortranslation");
 223                 BADCVAR("sys_specialcharactertranslation");
 224                 BADCVAR("timeformat");
 225                 BADCVAR("timestamps");
 226                 BADCVAR("g_require_stats");
 227                 BADPREFIX("developer_");
 228                 BADPREFIX("g_ban_");
 229                 BADPREFIX("g_banned_list");
 230                 BADPREFIX("g_require_stats_");
 231                 BADPREFIX("g_chat_flood_");
 232                 BADPREFIX("g_ghost_items");
 233                 BADPREFIX("g_playerstats_");
 234                 BADPREFIX("g_voice_flood_");
 235                 BADPREFIX("log_file");
 236                 BADPREFIX("quit_");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250                 BADCVAR("sv_muteban_list");
 251                 BADCVAR("sv_voteban_list");
 252                 BADCVAR("sv_allow_customplayermodels_idlist");
 253                 BADCVAR("sv_allow_customplayermodels_speciallist");
 254
 255                 // mapinfo
 256                 BADCVAR("fraglimit");
 257                 BADCVAR("g_arena");
 258                 BADCVAR("g_assault");
 259                 BADCVAR("g_ca");
 260                 BADCVAR("g_ca_teams");
 261                 BADCVAR("g_conquest");
 262                 BADCVAR("g_ctf");
 263                 BADCVAR("g_cts");
 264                 BADCVAR("g_dotc");
 265                 BADCVAR("g_dm");
 266                 BADCVAR("g_domination");
 267                 BADCVAR("g_domination_default_teams");
 268                 BADCVAR("g_duel");
 269                 BADCVAR("g_freezetag");
 270                 BADCVAR("g_freezetag_teams");
 271                 BADCVAR("g_invasion_teams");
 272                 BADCVAR("g_invasion_type");
 273                 BADCVAR("g_jailbreak");
 274                 BADCVAR("g_jailbreak_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_laps_limit");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_race_qualifying_timelimit_override");
 285                 BADCVAR("g_runematch");
 286                 BADCVAR("g_snafu");
 287                 BADCVAR("g_tdm");
 288                 BADCVAR("g_tdm_teams");
 289                 BADCVAR("g_vip");
 290                 BADCVAR("leadlimit");
 291                 BADCVAR("nextmap");
 292                 BADCVAR("teamplay");
 293                 BADCVAR("timelimit");
 294                 BADCVAR("g_mapinfo_ignore_warnings");
 295
 296                 // long
 297                 BADCVAR("hostname");
 298                 BADCVAR("g_maplist");
 299                 BADCVAR("g_maplist_mostrecent");
 300                 BADCVAR("sv_motd");
 301
 302                 v = cvar_string(k);
 303                 d = cvar_defstring(k);
 304                 if(v == d)
 305                         continue;
 306
 307                 if(adding)
 308                 {
 309                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 310                         if(strlen(cvar_changes) > 16384)
 311                         {
 312                                 cvar_changes = "// too many settings have been changed to show them here\n";
 313                                 adding = 0;
 314                         }
 315                 }
 316
 317                 // now check if the changes are actually gameplay relevant
 318
 319                 // does nothing gameplay relevant
 320                 BADCVAR("captureleadlimit_override");
 321                 BADCVAR("condump_stripcolors");
 322                 BADCVAR("gameversion");
 323                 BADCVAR("g_allow_oldvortexbeam");
 324                 BADCVAR("g_balance_kill_delay");
 325                 BADCVAR("g_buffs_pickup_anyway");
 326                 BADCVAR("g_buffs_randomize");
 327                 BADCVAR("g_campcheck_distance");
 328                 BADCVAR("g_ca_point_leadlimit");
 329                 BADCVAR("g_ca_point_limit");
 330                 BADCVAR("g_ctf_captimerecord_always");
 331                 BADCVAR("g_ctf_flag_glowtrails");
 332                 BADCVAR("g_ctf_flag_pickup_verbosename");
 333                 BADCVAR("g_domination_point_leadlimit");
 334                 BADCVAR("g_forced_respawn");
 335                 BADCVAR("g_freezetag_point_leadlimit");
 336                 BADCVAR("g_freezetag_point_limit");
 337                 BADCVAR("g_hats");
 338                 BADCVAR("g_invasion_point_limit");
 339                 BADCVAR("g_jump_grunt");
 340                 BADCVAR("g_keyhunt_point_leadlimit");
 341                 BADCVAR("g_nexball_goalleadlimit");
 342                 BADCVAR("g_new_toys_use_pickupsound");
 343                 BADCVAR("g_physics_predictall");
 344                 BADCVAR("g_piggyback");
 345                 BADCVAR("g_playerclip_collisions");
 346                 BADCVAR("g_tdm_point_leadlimit");
 347                 BADCVAR("g_tdm_point_limit");
 348                 BADCVAR("leadlimit_and_fraglimit");
 349                 BADCVAR("leadlimit_override");
 350                 BADCVAR("pausable");
 351                 BADCVAR("sv_checkforpacketsduringsleep");
 352                 BADCVAR("sv_damagetext");
 353                 BADCVAR("sv_db_saveasdump");
 354                 BADCVAR("sv_intermission_cdtrack");
 355                 BADCVAR("sv_minigames");
 356                 BADCVAR("sv_namechangetimer");
 357                 BADCVAR("sv_precacheplayermodels");
 358                 BADCVAR("sv_stepheight");
 359                 BADCVAR("sv_timeout");
 360                 BADCVAR("sv_weapons_modeloverride");
 361                 BADCVAR("w_prop_interval");
 362                 BADPREFIX("crypto_");
 363                 BADPREFIX("gameversion_");
 364                 BADPREFIX("g_chat_");
 365                 BADPREFIX("g_ctf_captimerecord_");
 366                 BADPREFIX("g_hats_");
 367                 BADPREFIX("g_maplist_");
 368                 BADPREFIX("g_mod_");
 369                 BADPREFIX("g_respawn_");
 370                 BADPREFIX("net_");
 371                 BADPREFIX("notification_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("skill_");
 374                 BADPREFIX("sv_allow_");
 375                 BADPREFIX("sv_cullentities_");
 376                 BADPREFIX("sv_maxidle_");
 377                 BADPREFIX("sv_minigames_");
 378                 BADPREFIX("sv_radio_");
 379                 BADPREFIX("sv_timeout_");
 380                 BADPREFIX("sv_vote_");
 381                 BADPREFIX("timelimit_");
 382
 383                 // allowed changes to server admins (please sync this to server.cfg)
 384                 // vi commands:
 385                 //   :/"impure"/,$d
 386                 //   :g!,^\/\/[^ /],d
 387                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 388                 //   :%!sort
 389                 // yes, this does contain some redundant stuff, don't really care
 390                 BADCVAR("bot_config_file");
 391                 BADCVAR("bot_number");
 392                 BADCVAR("bot_prefix");
 393                 BADCVAR("bot_suffix");
 394                 BADCVAR("capturelimit_override");
 395                 BADCVAR("fraglimit_override");
 396                 BADCVAR("gametype");
 397                 BADCVAR("g_antilag");
 398                 BADCVAR("g_balance_teams");
 399                 BADCVAR("g_balance_teams_prevent_imbalance");
 400                 BADCVAR("g_balance_teams_scorefactor");
 401                 BADCVAR("g_ban_sync_trusted_servers");
 402                 BADCVAR("g_ban_sync_uri");
 403                 BADCVAR("g_buffs");
 404                 BADCVAR("g_ca_teams_override");
 405                 BADCVAR("g_ctf_ignore_frags");
 406                 BADCVAR("g_ctf_leaderboard");
 407                 BADCVAR("g_domination_point_limit");
 408                 BADCVAR("g_domination_teams_override");
 409                 BADCVAR("g_freezetag_teams_override");
 410                 BADCVAR("g_friendlyfire");
 411                 BADCVAR("g_fullbrightitems");
 412                 BADCVAR("g_fullbrightplayers");
 413                 BADCVAR("g_keyhunt_point_limit");
 414                 BADCVAR("g_keyhunt_teams_override");
 415                 BADCVAR("g_lms_lives_override");
 416                 BADCVAR("g_maplist");
 417                 BADCVAR("g_maxplayers");
 418                 BADCVAR("g_mirrordamage");
 419                 BADCVAR("g_nexball_goallimit");
 420                 BADCVAR("g_norecoil");
 421                 BADCVAR("g_physics_clientselect");
 422                 BADCVAR("g_pinata");
 423                 BADCVAR("g_powerups");
 424                 BADCVAR("g_spawnshieldtime");
 425                 BADCVAR("g_start_delay");
 426                 BADCVAR("g_superspectate");
 427                 BADCVAR("g_tdm_teams_override");
 428                 BADCVAR("g_warmup");
 429                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 430                 BADCVAR("hostname");
 431                 BADCVAR("log_file");
 432                 BADCVAR("maxplayers");
 433                 BADCVAR("minplayers");
 434                 BADCVAR("minplayers_per_team");
 435                 BADCVAR("net_address");
 436                 BADCVAR("port");
 437                 BADCVAR("rcon_password");
 438                 BADCVAR("rcon_restricted_commands");
 439                 BADCVAR("rcon_restricted_password");
 440                 BADCVAR("skill");
 441                 BADCVAR("sv_adminnick");
 442                 BADCVAR("sv_autoscreenshot");
 443                 BADCVAR("sv_autotaunt");
 444                 BADCVAR("sv_curl_defaulturl");
 445                 BADCVAR("sv_defaultcharacter");
 446                 BADCVAR("sv_defaultcharacterskin");
 447                 BADCVAR("sv_defaultplayercolors");
 448                 BADCVAR("sv_defaultplayermodel");
 449                 BADCVAR("sv_defaultplayerskin");
 450                 BADCVAR("sv_maxidle");
 451                 BADCVAR("sv_maxrate");
 452                 BADCVAR("sv_motd");
 453                 BADCVAR("sv_public");
 454                 BADCVAR("sv_ready_restart");
 455                 BADCVAR("sv_status_privacy");
 456                 BADCVAR("sv_taunt");
 457                 BADCVAR("sv_vote_call");
 458                 BADCVAR("sv_vote_commands");
 459                 BADCVAR("sv_vote_majority_factor");
 460                 BADCVAR("sv_vote_master");
 461                 BADCVAR("sv_vote_master_commands");
 462                 BADCVAR("sv_vote_master_password");
 463                 BADCVAR("sv_vote_simple_majority_factor");
 464                 BADCVAR("teamplay_mode");
 465                 BADCVAR("timelimit_override");
 466                 BADPREFIX("g_warmup_");
 467                 BADPREFIX("sv_info_");
 468                 BADPREFIX("sv_ready_restart_");
 469
 470                 // mutators that announce themselves properly to the server browser
 471                 BADCVAR("g_instagib");
 472                 BADCVAR("g_new_toys");
 473                 BADCVAR("g_nix");
 474                 BADCVAR("g_grappling_hook");
 475                 BADCVAR("g_jetpack");
 476
 477                 // temporary for testing
 478                 // TODO remove before 0.8.3 release
 479                 BADCVAR("g_ca_weaponarena");
 480                 BADCVAR("g_freezetag_weaponarena");
 481                 BADCVAR("g_lms_weaponarena");
 482
 483 #undef BADPRESUFFIX
 484 #undef BADPREFIX
 485 #undef BADCVAR
 486
 487                 if(pureadding)
 488                 {
 489                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 490                         if(strlen(cvar_purechanges) > 16384)
 491                         {
 492                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 493                                 pureadding = 0;
 494                         }
 495                 }
 496                 ++cvar_purechanges_count;
 497                 // WARNING: this variable is used for the server list
 498                 // NEVER dare to skip this code!
 499                 // Hacks to intentionally appearing as "pure server" even though you DO have
 500                 // modified settings may be punished by removal from the server list.
 501                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 502                 // though.
 503         }
 504         buf_del(h);
 505         if(cvar_changes == "")
 506                 cvar_changes = "// this server runs at default server settings\n";
 507         else
 508                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 509         cvar_changes = strzone(cvar_changes);
 510         if(cvar_purechanges == "")
 511                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 512         else
 513                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 514         cvar_purechanges = strzone(cvar_purechanges);
 515 }
 516
 517 entity randomseed;
 518 bool RandomSeed_Send(entity this, entity to, int sf)
 519 {
 520         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 521         WriteShort(MSG_ENTITY, this.cnt);
 522         return true;
 523 }
 524 void RandomSeed_Think(entity this)
 525 {
 526         this.cnt = bound(0, floor(random() * 65536), 65535);
 527         this.nextthink = time + 5;
 528
 529         this.SendFlags |= 1;
 530 }
 531 void RandomSeed_Spawn()
 532 {
 533         randomseed = new_pure(randomseed);
 534         setthink(randomseed, RandomSeed_Think);
 535         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 536
 537         getthink(randomseed)(randomseed); // sets random seed and nextthink
 538 }
 539
 540 spawnfunc(__init_dedicated_server)
 541 {
 542         // handler for _init/_init map (only for dedicated server initialization)
 543
 544         world_initialized = -1; // don't complain
 545         cvar = cvar_normal;
 546         cvar_string = cvar_string_normal;
 547         cvar_set = cvar_set_normal;
 548
 549         delete_fn = remove_unsafely;
 550
 551         entity e = spawn();
 552         setthink(e, GotoFirstMap);
 553         e.nextthink = time; // this is usually 1 at this point
 554
 555         e = new(info_player_deathmatch);  // safeguard against player joining
 556
 557     // assign reflectively to avoid "assignment to world" warning
 558     for (int i = 0, n = numentityfields(); i < n; ++i) {
 559         string k = entityfieldname(i);
 560         if (k == "classname") {
 561             // safeguard against various stuff ;)
 562             putentityfieldstring(i, this, "worldspawn");
 563             break;
 564         }
 565     }
 566
 567         // needs to be done so early because of the constants they create
 568         static_init();
 569         static_init_late();
 570         static_init_precache();
 571
 572         IL_PUSH(g_spawnpoints, e); // just incase
 573
 574         MapInfo_Enumerate();
 575         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 576 }
 577
 578 void __init_dedicated_server_shutdown() {
 579         MapInfo_Shutdown();
 580 }
 581
 582 STATIC_INIT_EARLY(maxclients)
 583 {
 584         maxclients = 0;
 585         for (entity head = nextent(NULL); head; head = nextent(head)) {
 586                 ++maxclients;
 587         }
 588 }
 589
 590 void default_delayedinit(entity this)
 591 {
 592         if(!scores_initialized)
 593                 ScoreRules_generic();
 594 }
 595
 596 void InitGameplayMode()
 597 {
 598         VoteReset();
 599
 600         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 601         get_mi_min_max(1);
 602         // assign reflectively to avoid "assignment to world" warning
 603         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 604             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 605             if (v) {
 606             putentityfieldstring(i, world, sprintf("%v", v));
 607             if (++done == 2) break;
 608         }
 609         }
 610         // currently, NetRadiant's limit is 131072 qu for each side
 611         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 612         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 613         // in case somebody makes extremely large maps
 614         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 615
 616         MapInfo_LoadMapSettings(mapname);
 617         GameRules_teams(false);
 618
 619         if (!cvar_value_issafe(world.fog))
 620         {
 621                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 622                 world.fog = string_null;
 623         }
 624         if(MapInfo_Map_fog != "")
 625         {
 626                 if(MapInfo_Map_fog == "none")
 627                         world.fog = string_null;
 628                 else
 629                         world.fog = strzone(MapInfo_Map_fog);
 630         }
 631         clientstuff = strzone(MapInfo_Map_clientstuff);
 632
 633         MapInfo_ClearTemps();
 634
 635         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 636
 637         cache_mutatormsg = strzone("");
 638         cache_lastmutatormsg = strzone("");
 639
 640         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 641 }
 642
 643 void Map_MarkAsRecent(string m);
 644 float world_already_spawned;
 645 spawnfunc(worldspawn)
 646 {
 647         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 648
 649         bool wantrestart = false;
 650         {
 651                 if (!server_is_dedicated)
 652                 {
 653                         // force unloading of server pk3 files when starting a listen server
 654                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 655                         // restore csqc_progname too
 656                         string expect = "csprogs.dat";
 657                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 658                         cvar_set_normal("csqc_progname", expect);
 659                 }
 660                 else
 661                 {
 662                         // Try to use versioned csprogs from pk3
 663                         // Only ever use versioned csprogs.dat files on dedicated servers;
 664                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 665                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 666                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 667                         string select = "csprogs.dat";
 668                         if (fexists(pk3csprogs)) select = pk3csprogs;
 669                         if (cvar_string_normal("csqc_progname") != select)
 670                         {
 671                                 cvar_set_normal("csqc_progname", select);
 672                                 wantrestart = true;
 673                         }
 674                         // Check for updates on startup
 675                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 676                         int sentinel = fopen("progs.txt", FILE_READ);
 677                         if (sentinel >= 0)
 678                         {
 679                                 string switchversion = fgets(sentinel);
 680                                 fclose(sentinel);
 681                                 if (switchversion != "" && switchversion != WATERMARK)
 682                                 {
 683                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 684                                         // if it doesn't exist, assume either:
 685                                         //   a) the current program was overwritten
 686                                         //   b) this is a client only update
 687                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 688                                         if (fexists(newprogs))
 689                                         {
 690                                                 cvar_set_normal("sv_progs", newprogs);
 691                                                 wantrestart = true;
 692                                         }
 693                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 694                                         if (fexists(newcsprogs))
 695                                         {
 696                                                 cvar_set_normal("csqc_progname", newcsprogs);
 697                                                 wantrestart = true;
 698                                         }
 699                                 }
 700                         }
 701                 }
 702                 if (wantrestart)
 703                 {
 704                         LOG_INFO("Restart requested");
 705                         changelevel(mapname);
 706                         // let initialization continue, shutdown depends on it
 707                 }
 708         }
 709
 710         cvar = cvar_normal;
 711         cvar_string = cvar_string_normal;
 712         cvar_set = cvar_set_normal;
 713
 714         if(world_already_spawned)
 715                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 716         world_already_spawned = true;
 717
 718         delete_fn = remove_safely; // during spawning, watch what you remove!
 719
 720         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 721
 722         // needs to be done so early because of the constants they create
 723         static_init();
 724
 725         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 726
 727         TemporaryDB = db_create();
 728
 729         // 0 normal
 730         lightstyle(0, "m");
 731
 732         // 1 FLICKER (first variety)
 733         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 734
 735         // 2 SLOW STRONG PULSE
 736         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 737
 738         // 3 CANDLE (first variety)
 739         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 740
 741         // 4 FAST STROBE
 742         lightstyle(4, "mamamamamama");
 743
 744         // 5 GENTLE PULSE 1
 745         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 746
 747         // 6 FLICKER (second variety)
 748         lightstyle(6, "nmonqnmomnmomomno");
 749
 750         // 7 CANDLE (second variety)
 751         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 752
 753         // 8 CANDLE (third variety)
 754         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 755
 756         // 9 SLOW STROBE (fourth variety)
 757         lightstyle(9, "aaaaaaaazzzzzzzz");
 758
 759         // 10 FLUORESCENT FLICKER
 760         lightstyle(10, "mmamammmmammamamaaamammma");
 761
 762         // 11 SLOW PULSE NOT FADE TO BLACK
 763         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 764
 765         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 766
 767         // 63 testing
 768         lightstyle(63, "a");
 769
 770         if(autocvar_g_campaign)
 771                 CampaignPreInit();
 772
 773         Map_MarkAsRecent(mapname);
 774
 775         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 776
 777         InitGameplayMode();
 778         static_init_late();
 779         static_init_precache();
 780         readlevelcvars();
 781         GrappleHookInit();
 782
 783         GameRules_limit_fallbacks();
 784
 785         if(warmup_limit == 0)
 786                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 787
 788         player_count = 0;
 789         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 790         if(bot_waypoints_for_items == 1)
 791                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 792                         bot_waypoints_for_items = 0;
 793
 794         precache();
 795
 796         WaypointSprite_Init();
 797
 798         GameLogInit(); // prepare everything
 799         // NOTE for matchid:
 800         // changing the logic generating it is okay. But:
 801         // it HAS to stay <= 64 chars
 802         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 803         if(autocvar_sv_eventlog)
 804         {
 805                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 806                 matchid = strzone(s);
 807
 808                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 809                 s = ":gameinfo:mutators:LIST";
 810
 811                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 812                 s = M_ARGV(0, string);
 813
 814                 // initialiation stuff, not good in the mutator system
 815                 if(!autocvar_g_use_ammunition)
 816                         s = strcat(s, ":no_use_ammunition");
 817
 818                 // initialiation stuff, not good in the mutator system
 819                 if(autocvar_g_pickup_items == 0)
 820                         s = strcat(s, ":no_pickup_items");
 821                 if(autocvar_g_pickup_items > 0)
 822                         s = strcat(s, ":pickup_items");
 823
 824                 // initialiation stuff, not good in the mutator system
 825                 if(autocvar_g_weaponarena != "0")
 826                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 827
 828                 // TODO to mutator system
 829                 if(autocvar_g_norecoil)
 830                         s = strcat(s, ":norecoil");
 831
 832                 // TODO to mutator system
 833                 if(autocvar_g_powerups == 0)
 834                         s = strcat(s, ":no_powerups");
 835                 if(autocvar_g_powerups > 0)
 836                         s = strcat(s, ":powerups");
 837
 838                 GameLogEcho(s);
 839                 GameLogEcho(":gameinfo:end");
 840         }
 841         else
 842                 matchid = strzone(ftos(random()));
 843
 844         cvar_set("nextmap", "");
 845
 846         SetDefaultAlpha();
 847
 848         if(autocvar_g_campaign)
 849                 CampaignPostInit();
 850
 851         Ban_LoadBans();
 852
 853         MapInfo_Enumerate();
 854         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 855
 856         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 857         {
 858                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 859                 if(fd != -1)
 860                 {
 861                         string s;
 862                         while((s = fgets(fd)))
 863                         {
 864                                 int l = tokenize_console(s);
 865                                 if(l < 2)
 866                                         continue;
 867                                 if(argv(0) == "cd")
 868                                 {
 869                                         string trackname = argv(2);
 870                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 871                                         LOG_INFO("  cdtrack ", trackname);
 872                                         if (cvar_value_issafe(trackname))
 873                                         {
 874                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 875                                                 strcpy(clientstuff, newstuff);
 876                                         }
 877                                 }
 878                                 else if(argv(0) == "fog")
 879                                 {
 880                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 881                                         LOG_INFO("  \"fog\" \"", s, "\"");
 882                                 }
 883                                 else if(argv(0) == "set")
 884                                 {
 885                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 886                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 887                                 }
 888                                 else if(argv(0) != "//")
 889                                 {
 890                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 891                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 892                                 }
 893                         }
 894                         fclose(fd);
 895                 }
 896         }
 897
 898         WeaponStats_Init();
 899
 900         Nagger_Init();
 901
 902         next_pingtime = time + 5;
 903
 904         // set up information replies for clients and server to use
 905         maplist_reply = strzone(getmaplist());
 906         lsmaps_reply = strzone(getlsmaps());
 907         monsterlist_reply = strzone(getmonsterlist());
 908         for(int i = 0; i < 10; ++i)
 909         {
 910                 string s = getrecords(i);
 911                 if (s)
 912                         records_reply[i] = strzone(s);
 913         }
 914         ladder_reply = strzone(getladder());
 915         rankings_reply = strzone(getrankings());
 916
 917         // begin other init
 918         ClientInit_Spawn();
 919         RandomSeed_Spawn();
 920         PingPLReport_Spawn();
 921
 922         CheatInit();
 923
 924         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 925
 926         // fill sv_curl_serverpackages from .serverpackage files
 927         if (autocvar_sv_curl_serverpackages_auto)
 928         {
 929                 string s = "csprogs-" WATERMARK ".txt";
 930                 // remove automatically managed files from the list to prevent duplicates
 931                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 932                 {
 933                         string pkg = argv(i);
 934                         if (startsWith(pkg, "csprogs-")) continue;
 935                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 936                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 937                         s = cons(s, pkg);
 938                 }
 939                 // add automatically managed files to the list
 940                 #define X(match) MACRO_BEGIN \
 941                         int fd = search_begin(match, true, false); \
 942                         if (fd >= 0) \
 943                         { \
 944                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 945                                 { \
 946                                         s = cons(s, search_getfilename(fd, i)); \
 947                                 } \
 948                                 search_end(fd); \
 949                         } \
 950                 MACRO_END
 951                 X("*-serverpackage.txt");
 952                 X("*.serverpackage");
 953                 #undef X
 954                 cvar_set("sv_curl_serverpackages", s);
 955         }
 956
 957         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 958         modname = "Xonotic";
 959         // physics/balance/config changes that count as mod
 960         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 961                 modname = cvar_string("g_mod_physics");
 962         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 963                 modname = cvar_string("g_mod_balance");
 964         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 965                 modname = cvar_string("g_mod_config");
 966         // extra mutators that deserve to count as mod
 967         MUTATOR_CALLHOOK(SetModname, modname);
 968         modname = M_ARGV(0, string);
 969
 970         // save it for later
 971         modname = strzone(modname);
 972
 973         WinningConditionHelper(this); // set worldstatus
 974
 975         world_initialized = 1;
 976         __spawnfunc_spawn_all();
 977 }
 978
 979 spawnfunc(light)
 980 {
 981         //makestatic (this); // Who the f___ did that?
 982         delete(this);
 983 }
 984
 985 string GetGametype()
 986 {
 987         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 988 }
 989
 990 string GetMapname()
 991 {
 992         return mapname;
 993 }
 994
 995 float Map_Count, Map_Current;
 996 string Map_Current_Name;
 997
 998 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 999 int GetMaplistPosition()
1000 {
1001         string map = GetMapname();
1002         int idx = autocvar_g_maplist_index;
1003
1004         if(idx >= 0)
1005         {
1006                 if(idx < Map_Count)
1007                 {
1008                         if(map == argv(idx))
1009                         {
1010                                 return idx;
1011                         }
1012                 }
1013         }
1014
1015         for(int pos = 0; pos < Map_Count; ++pos)
1016         {
1017                 if(map == argv(pos))
1018                         return pos;
1019         }
1020
1021         // resume normal maplist rotation if current map is not in g_maplist
1022         return idx;
1023 }
1024
1025 bool MapHasRightSize(string map)
1026 {
1027         int minplayers = max(0, floor(autocvar_minplayers));
1028         if (teamplay)
1029                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1030         if (autocvar_g_maplist_check_waypoints
1031                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1032         {
1033                 string checkwp_msg = strcat("checkwp ", map);
1034                 if(!fexists(strcat("maps/", map, ".waypoints")))
1035                 {
1036                         LOG_TRACE(checkwp_msg, ": no waypoints");
1037                         return false;
1038                 }
1039                 LOG_TRACE(checkwp_msg, ": has waypoints");
1040         }
1041
1042         if(autocvar_g_maplist_ignore_sizes)
1043                 return true;
1044
1045         // open map size restriction file
1046         string opensize_msg = strcat("opensize ", map);
1047         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1048         if(fh >= 0)
1049         {
1050                 opensize_msg = strcat(opensize_msg, ": ok, ");
1051                 int mapmin = stoi(fgets(fh));
1052                 int mapmax = stoi(fgets(fh));
1053                 fclose(fh);
1054                 if(player_count < mapmin)
1055                 {
1056                         LOG_TRACE(opensize_msg, "not enough");
1057                         return false;
1058                 }
1059                 if(mapmax && player_count > mapmax)
1060                 {
1061                         LOG_TRACE(opensize_msg, "too many");
1062                         return false;
1063                 }
1064                 LOG_TRACE(opensize_msg, "right size");
1065                 return true;
1066         }
1067         LOG_TRACE(opensize_msg, ": not found");
1068         return true;
1069 }
1070
1071 string Map_Filename(float position)
1072 {
1073         return strcat("maps/", argv(position), ".bsp");
1074 }
1075
1076 void Map_MarkAsRecent(string m)
1077 {
1078         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1079 }
1080
1081 float Map_IsRecent(string m)
1082 {
1083         return strhasword(autocvar_g_maplist_mostrecent, m);
1084 }
1085
1086 float Map_Check(float position, float pass)
1087 {
1088         string filename;
1089         string map_next;
1090         map_next = argv(position);
1091         if(pass <= 1)
1092         {
1093                 if(Map_IsRecent(map_next))
1094                         return 0;
1095         }
1096         filename = Map_Filename(position);
1097         if(MapInfo_CheckMap(map_next))
1098         {
1099                 if(pass == 2)
1100                         return 1;
1101                 if(MapHasRightSize(map_next))
1102                         return 1;
1103                 return 0;
1104         }
1105         else
1106                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1107
1108         return 0;
1109 }
1110
1111 void Map_Goto_SetStr(string nextmapname)
1112 {
1113         if(getmapname_stored != "")
1114                 strunzone(getmapname_stored);
1115         if(nextmapname == "")
1116                 getmapname_stored = "";
1117         else
1118                 getmapname_stored = strzone(nextmapname);
1119 }
1120
1121 void Map_Goto_SetFloat(float position)
1122 {
1123         cvar_set("g_maplist_index", ftos(position));
1124         Map_Goto_SetStr(argv(position));
1125 }
1126
1127 void Map_Goto(float reinit)
1128 {
1129         MapInfo_LoadMap(getmapname_stored, reinit);
1130 }
1131
1132 // return codes of map selectors:
1133 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1134 //   -2 = permanent failure
1135 float MaplistMethod_Iterate() // usual method
1136 {
1137         float pass, i;
1138
1139         LOG_TRACE("Trying MaplistMethod_Iterate");
1140
1141         for(pass = 1; pass <= 2; ++pass)
1142         {
1143                 for(i = 1; i < Map_Count; ++i)
1144                 {
1145                         float mapindex;
1146                         mapindex = (i + Map_Current) % Map_Count;
1147                         if(Map_Check(mapindex, pass))
1148                                 return mapindex;
1149                 }
1150         }
1151         return -1;
1152 }
1153
1154 float MaplistMethod_Repeat() // fallback method
1155 {
1156         LOG_TRACE("Trying MaplistMethod_Repeat");
1157
1158         if(Map_Check(Map_Current, 2))
1159                 return Map_Current;
1160         return -2;
1161 }
1162
1163 float MaplistMethod_Random() // random map selection
1164 {
1165         float i, imax;
1166
1167         LOG_TRACE("Trying MaplistMethod_Random");
1168
1169         imax = 42;
1170
1171         for(i = 0; i <= imax; ++i)
1172         {
1173                 float mapindex;
1174                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1175                 if(Map_Check(mapindex, 1))
1176                         return mapindex;
1177         }
1178         return -1;
1179 }
1180
1181 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1182 // the exponent sets a bias on the map selection:
1183 // the higher the exponent, the less likely "shortly repeated" same maps are
1184 {
1185         float i, j, imax, insertpos;
1186
1187         LOG_TRACE("Trying MaplistMethod_Shuffle");
1188
1189         imax = 42;
1190
1191         for(i = 0; i <= imax; ++i)
1192         {
1193                 string newlist;
1194
1195                 // now reinsert this at another position
1196                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1197                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1198                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1199                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1200
1201                 // insert the current map there
1202                 newlist = "";
1203                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1204                         newlist = strcat(newlist, " ", argv(j));
1205                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1206                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1207                         newlist = strcat(newlist, " ", argv(j));
1208                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1209                 cvar_set("g_maplist", newlist);
1210                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1211
1212                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1213                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1214                 if(Map_Check(Map_Current, 1))
1215                         return Map_Current;
1216         }
1217         return -1;
1218 }
1219
1220 void Maplist_Init()
1221 {
1222         float i = Map_Count = 0;
1223         if(autocvar_g_maplist != "")
1224         {
1225                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1226                 for (i = 0; i < Map_Count; ++i)
1227                 {
1228                         if (Map_Check(i, 2))
1229                                 break;
1230                 }
1231         }
1232
1233         if (i == Map_Count)
1234         {
1235                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1236                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1237                 if(autocvar_g_maplist_shuffle)
1238                         ShuffleMaplist();
1239                 if(!server_is_dedicated)
1240                         localcmd("\nmenu_cmd sync\n");
1241                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1242         }
1243         if(Map_Count == 0)
1244                 error("empty maplist, cannot select a new map");
1245         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1246
1247         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1248         // this may or may not be correct, but who cares, in the worst case a map
1249         // isn't chosen in the first pass that should have been
1250 }
1251
1252 string GetNextMap()
1253 {
1254         Maplist_Init();
1255         float nextMap = -1;
1256
1257         if(nextMap == -1)
1258                 if(autocvar_g_maplist_shuffle > 0)
1259                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1260
1261         if(nextMap == -1)
1262                 if(autocvar_g_maplist_selectrandom)
1263                         nextMap = MaplistMethod_Random();
1264
1265         if(nextMap == -1)
1266                 nextMap = MaplistMethod_Iterate();
1267
1268         if(nextMap == -1)
1269                 nextMap = MaplistMethod_Repeat();
1270
1271         if(nextMap >= 0)
1272         {
1273                 Map_Goto_SetFloat(nextMap);
1274                 return getmapname_stored;
1275         }
1276
1277         return "";
1278 }
1279
1280 float DoNextMapOverride(float reinit)
1281 {
1282         if(autocvar_g_campaign)
1283         {
1284                 CampaignPostIntermission();
1285                 alreadychangedlevel = true;
1286                 return true;
1287         }
1288         if(autocvar_quit_when_empty)
1289         {
1290                 if(player_count <= currentbots)
1291                 {
1292                         localcmd("quit\n");
1293                         alreadychangedlevel = true;
1294                         return true;
1295                 }
1296         }
1297         if(autocvar_quit_and_redirect != "")
1298         {
1299                 redirection_target = strzone(autocvar_quit_and_redirect);
1300                 alreadychangedlevel = true;
1301                 return true;
1302         }
1303         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1304         {
1305                 localcmd("restart\n");
1306                 alreadychangedlevel = true;
1307                 return true;
1308         }
1309         if(autocvar_nextmap != "")
1310         {
1311                 string m;
1312                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1313                 cvar_set("nextmap",m);
1314
1315                 if(!m || gametypevote)
1316                         return false;
1317                 if(autocvar_sv_vote_gametype)
1318                 {
1319                         Map_Goto_SetStr(m);
1320                         return false;
1321                 }
1322
1323                 if(MapInfo_CheckMap(m))
1324                 {
1325                         Map_Goto_SetStr(m);
1326                         Map_Goto(reinit);
1327                         alreadychangedlevel = true;
1328                         return true;
1329                 }
1330         }
1331         if(!reinit && autocvar_lastlevel)
1332         {
1333                 cvar_settemp_restore();
1334                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1335                 alreadychangedlevel = true;
1336                 return true;
1337         }
1338         return false;
1339 }
1340
1341 void GotoNextMap(float reinit)
1342 {
1343         //string nextmap;
1344         //float n, nummaps;
1345         //string s;
1346         if (alreadychangedlevel)
1347                 return;
1348         alreadychangedlevel = true;
1349
1350         string nextMap = GetNextMap();
1351         if(nextMap == "")
1352                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1353         Map_Goto(reinit);
1354 }
1355
1356
1357 /*
1358 ============
1359 IntermissionThink
1360
1361 When the player presses attack or jump, change to the next level
1362 ============
1363 */
1364 .float autoscreenshot;
1365 void IntermissionThink(entity this)
1366 {
1367         FixIntermissionClient(this);
1368
1369         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1370         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1371
1372         if( (server_screenshot || client_screenshot)
1373                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1374         {
1375                 this.autoscreenshot = -1;
1376                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1377                 return;
1378         }
1379
1380         if (time < intermission_exittime)
1381                 return;
1382
1383         if(!mapvote_initialized)
1384                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1385                         return;
1386
1387         MapVote_Start();
1388 }
1389
1390 /*
1391 ============
1392 FindIntermission
1393
1394 Returns the entity to view from
1395 ============
1396 */
1397 /*
1398 entity FindIntermission()
1399 {
1400         local   entity spot;
1401         local   float cyc;
1402
1403 // look for info_intermission first
1404         spot = find(NULL, classname, "info_intermission");
1405         if (spot)
1406         {       // pick a random one
1407                 cyc = random() * 4;
1408                 while (cyc > 1)
1409                 {
1410                         spot = find(spot, classname, "info_intermission");
1411                         if (!spot)
1412                                 spot = find(spot, classname, "info_intermission");
1413                         cyc = cyc - 1;
1414                 }
1415                 return spot;
1416         }
1417
1418 // then look for the start position
1419         spot = find(NULL, classname, "info_player_start");
1420         if (spot)
1421                 return spot;
1422
1423 // testinfo_player_start is only found in regioned levels
1424         spot = find(NULL, classname, "testplayerstart");
1425         if (spot)
1426                 return spot;
1427
1428 // then look for the start position
1429         spot = find(NULL, classname, "info_player_deathmatch");
1430         if (spot)
1431                 return spot;
1432
1433         //objerror ("FindIntermission: no spot");
1434         return NULL;
1435 }
1436 */
1437
1438 /*
1439 ===============================================================================
1440
1441 RULES
1442
1443 ===============================================================================
1444 */
1445
1446 void DumpStats(float final)
1447 {
1448         float file;
1449         string s;
1450         float to_console;
1451         float to_eventlog;
1452         float to_file;
1453         float i;
1454
1455         to_console = autocvar_sv_logscores_console;
1456         to_eventlog = autocvar_sv_eventlog;
1457         to_file = autocvar_sv_logscores_file;
1458
1459         if(!final)
1460         {
1461                 to_console = true; // always print printstats replies
1462                 to_eventlog = false; // but never print them to the event log
1463         }
1464
1465         if(to_eventlog)
1466                 if(autocvar_sv_eventlog_console)
1467                         to_console = false; // otherwise we get the output twice
1468
1469         if(final)
1470                 s = ":scores:";
1471         else
1472                 s = ":status:";
1473         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1474
1475         if(to_console)
1476                 LOG_INFO(s);
1477         if(to_eventlog)
1478                 GameLogEcho(s);
1479
1480         file = -1;
1481         if(to_file)
1482         {
1483                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1484                 if(file == -1)
1485                         to_file = false;
1486                 else
1487                         fputs(file, strcat(s, "\n"));
1488         }
1489
1490         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1491         if(to_console)
1492                 LOG_INFO(s);
1493         if(to_eventlog)
1494                 GameLogEcho(s);
1495         if(to_file)
1496                 fputs(file, strcat(s, "\n"));
1497
1498         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1499                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1500                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1501                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1502                         s = strcat(s, ftos(it.team), ":");
1503                 else
1504                         s = strcat(s, "spectator:");
1505
1506                 if(to_console)
1507                         LOG_INFO(s, playername(it, false));
1508                 if(to_eventlog)
1509                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1510                 if(to_file)
1511                         fputs(file, strcat(s, playername(it, false), "\n"));
1512         });
1513
1514         if(teamplay)
1515         {
1516                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1517                 if(to_console)
1518                         LOG_INFO(s);
1519                 if(to_eventlog)
1520                         GameLogEcho(s);
1521                 if(to_file)
1522                         fputs(file, strcat(s, "\n"));
1523
1524                 for(i = 1; i < 16; ++i)
1525                 {
1526                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1527                         s = strcat(s, ":", ftos(i));
1528                         if(to_console)
1529                                 LOG_INFO(s);
1530                         if(to_eventlog)
1531                                 GameLogEcho(s);
1532                         if(to_file)
1533                                 fputs(file, strcat(s, "\n"));
1534                 }
1535         }
1536
1537         if(to_console)
1538                 LOG_INFO(":end");
1539         if(to_eventlog)
1540                 GameLogEcho(":end");
1541         if(to_file)
1542         {
1543                 fputs(file, ":end\n");
1544                 fclose(file);
1545         }
1546 }
1547
1548 void FixIntermissionClient(entity e)
1549 {
1550         if(!e.autoscreenshot) // initial call
1551         {
1552                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1553                 SetResourceExplicit(e, RES_HEALTH, -2342);
1554                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1555                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1556                 {
1557                     .entity weaponentity = weaponentities[slot];
1558                         if(e.(weaponentity))
1559                         {
1560                                 e.(weaponentity).effects = EF_NODRAW;
1561                                 if (e.(weaponentity).weaponchild)
1562                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1563                         }
1564                 }
1565                 if(IS_REAL_CLIENT(e))
1566                 {
1567                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1568                         RandomSelection_Init();
1569                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1570                                 RandomSelection_AddString(it, 1, 1);
1571                         });
1572                         if (RandomSelection_chosen_string != "")
1573                         {
1574                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1575                         }
1576                         msg_entity = e;
1577                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1578                 }
1579         }
1580 }
1581
1582 /*
1583 go to the next level for deathmatch
1584 only called if a time or frag limit has expired
1585 */
1586 void NextLevel()
1587 {
1588         game_stopped = true;
1589         intermission_running = 1; // game over
1590
1591         // enforce a wait time before allowing changelevel
1592         if(player_count > 0)
1593                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1594         else
1595                 intermission_exittime = -1;
1596
1597         /*
1598         WriteByte (MSG_ALL, SVC_CDTRACK);
1599         WriteByte (MSG_ALL, 3);
1600         WriteByte (MSG_ALL, 3);
1601         // done in FixIntermission
1602         */
1603
1604         //pos = FindIntermission ();
1605
1606         VoteReset();
1607
1608         DumpStats(true);
1609
1610         // send statistics
1611         PlayerStats_GameReport(true);
1612         WeaponStats_Shutdown();
1613
1614         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1615
1616         if(autocvar_sv_eventlog)
1617                 GameLogEcho(":gameover");
1618
1619         GameLogClose();
1620
1621         FOREACH_CLIENT(IS_PLAYER(it), {
1622                 FixIntermissionClient(it);
1623                 if(it.winning)
1624                         bprint(playername(it, false), " ^7wins.\n");
1625         });
1626
1627         target_music_kill();
1628
1629         if(autocvar_g_campaign)
1630                 CampaignPreIntermission();
1631
1632         MUTATOR_CALLHOOK(MatchEnd);
1633
1634         localcmd("\nsv_hook_gameend\n");
1635 }
1636
1637
1638 float InitiateSuddenDeath()
1639 {
1640         // Check first whether normal overtimes could be added before initiating suddendeath mode
1641         // - for this timelimit_overtime needs to be >0 of course
1642         // - also check the winning condition calculated in the previous frame and only add normal overtime
1643         //   again, if at the point at which timelimit would be extended again, still no winner was found
1644         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1645                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1646                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1647         {
1648                 return 1; // need to call InitiateOvertime later
1649         }
1650         else
1651         {
1652                 if(!checkrules_suddendeathend)
1653                 {
1654                         if(autocvar_g_campaign)
1655                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1656                         else
1657                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1658                         if(g_race && !g_race_qualifying)
1659                                 race_StartCompleting();
1660                 }
1661                 return 0;
1662         }
1663 }
1664
1665 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1666 {
1667         ++checkrules_overtimesadded;
1668         //add one more overtime by simply extending the timelimit
1669         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1670         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1671 }
1672
1673 float GetWinningCode(float fraglimitreached, float equality)
1674 {
1675         if(autocvar_g_campaign == 1)
1676         {
1677                 if(fraglimitreached)
1678                         return WINNING_YES;
1679                 else
1680                         return WINNING_NO;
1681         }
1682         else
1683         {
1684                 if(equality)
1685                 {
1686                         if(fraglimitreached)
1687                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1688                         else
1689                                 return WINNING_NEVER;
1690                 }
1691                 else
1692                 {
1693                         if(fraglimitreached)
1694                                 return WINNING_YES;
1695                         else
1696                                 return WINNING_NO;
1697                 }
1698         }
1699 }
1700
1701 // set the .winning flag for exactly those players with a given field value
1702 void SetWinners(.float field, float value)
1703 {
1704         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1705 }
1706
1707 // set the .winning flag for those players with a given field value
1708 void AddWinners(.float field, float value)
1709 {
1710         FOREACH_CLIENT(IS_PLAYER(it), {
1711                 if(it.(field) == value)
1712                         it.winning = 1;
1713         });
1714 }
1715
1716 // clear the .winning flags
1717 void ClearWinners()
1718 {
1719         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1720 }
1721
1722 void ShuffleMaplist()
1723 {
1724         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1725 }
1726
1727 float leaderfrags;
1728 float WinningCondition_Scores(float limit, float leadlimit)
1729 {
1730         float limitreached;
1731
1732         // TODO make everything use THIS winning condition (except LMS)
1733         WinningConditionHelper(NULL);
1734
1735         if(teamplay)
1736         {
1737                 for (int i = 1; i < 5; ++i)
1738                 {
1739                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1740                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1741                 }
1742         }
1743
1744         ClearWinners();
1745         if(WinningConditionHelper_winner)
1746                 WinningConditionHelper_winner.winning = 1;
1747         if(WinningConditionHelper_winnerteam >= 0)
1748                 SetWinners(team, WinningConditionHelper_winnerteam);
1749
1750         if(WinningConditionHelper_lowerisbetter)
1751         {
1752                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1753                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1754                 limit = -limit;
1755         }
1756
1757         if(WinningConditionHelper_zeroisworst)
1758                 leadlimit = 0; // not supported in this mode
1759
1760         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1761         // these modes always score in increments of 1, thus this makes sense
1762         {
1763                 if(leaderfrags != WinningConditionHelper_topscore)
1764                 {
1765                         leaderfrags = WinningConditionHelper_topscore;
1766
1767                         if (limit)
1768                         {
1769                                 if (leaderfrags == limit - 1)
1770                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1771                                 else if (leaderfrags == limit - 2)
1772                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1773                                 else if (leaderfrags == limit - 3)
1774                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1775                         }
1776                 }
1777         }
1778
1779         limitreached = false;
1780         if (limit && WinningConditionHelper_topscore >= limit)
1781                 limitreached = true;
1782         if(leadlimit)
1783         {
1784                 float leadlimitreached;
1785                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1786                 if(autocvar_leadlimit_and_fraglimit)
1787                         limitreached = (limitreached && leadlimitreached);
1788                 else
1789                         limitreached = (limitreached || leadlimitreached);
1790         }
1791
1792         if(limit)
1793                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1794
1795         return GetWinningCode(
1796                 WinningConditionHelper_topscore && limitreached,
1797                 WinningConditionHelper_equality
1798         );
1799 }
1800
1801 float WinningCondition_RanOutOfSpawns()
1802 {
1803         if(have_team_spawns <= 0)
1804                 return WINNING_NO;
1805
1806         if(!autocvar_g_spawn_useallspawns)
1807                 return WINNING_NO;
1808
1809         if(!some_spawn_has_been_used)
1810                 return WINNING_NO;
1811
1812         for (int i = 1; i < 5; ++i)
1813         {
1814                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1815         }
1816
1817         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1818         {
1819                 if (Team_IsValidTeam(it.team))
1820                 {
1821                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1822                 }
1823         });
1824
1825         IL_EACH(g_spawnpoints, true,
1826         {
1827                 if (Team_IsValidTeam(it.team))
1828                 {
1829                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1830                 }
1831         });
1832
1833         ClearWinners();
1834         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1835         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1836         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1837         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1838         if(team1_score + team2_score + team3_score + team4_score == 0)
1839         {
1840                 checkrules_equality = true;
1841                 return WINNING_YES;
1842         }
1843         else if(team1_score + team2_score + team3_score + team4_score == 1)
1844         {
1845                 float t, i;
1846                 if(team1_score)
1847                         t = 1;
1848                 else if(team2_score)
1849                         t = 2;
1850                 else if(team3_score)
1851                         t = 3;
1852                 else // if(team4_score)
1853                         t = 4;
1854                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1855                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1856                 {
1857                         for (int j = 1; j <= NUM_TEAMS; ++j)
1858                         {
1859                                 if (t == j)
1860                                 {
1861                                         continue;
1862                                 }
1863                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1864                                 {
1865                                         continue;
1866                                 }
1867                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1868                         }
1869                 }
1870
1871                 AddWinners(team, t);
1872                 return WINNING_YES;
1873         }
1874         else
1875                 return WINNING_NO;
1876 }
1877
1878 /*
1879 ============
1880 CheckRules_World
1881
1882 Exit deathmatch games upon conditions
1883 ============
1884 */
1885 void CheckRules_World()
1886 {
1887         float timelimit;
1888         float fraglimit;
1889         float leadlimit;
1890
1891         VoteThink();
1892         MapVote_Think();
1893
1894         SetDefaultAlpha();
1895
1896         if (intermission_running) // someone else quit the game already
1897         {
1898                 if(player_count == 0) // Nobody there? Then let's go to the next map
1899                         MapVote_Start();
1900                         // this will actually check the player count in the next frame
1901                         // again, but this shouldn't hurt
1902                 return;
1903         }
1904
1905         timelimit = autocvar_timelimit * 60;
1906         fraglimit = autocvar_fraglimit;
1907         leadlimit = autocvar_leadlimit;
1908
1909         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1910         {
1911                 if(timelimit > 0)
1912                         timelimit = 0; // timelimit is not made for warmup
1913                 if(fraglimit > 0)
1914                         fraglimit = 0; // no fraglimit for now
1915                 leadlimit = 0; // no leadlimit for now
1916         }
1917
1918         if(timelimit > 0)
1919         {
1920                 timelimit += game_starttime;
1921         }
1922         else if (timelimit < 0)
1923         {
1924                 // endmatch
1925                 NextLevel();
1926                 return;
1927         }
1928
1929         float wantovertime;
1930         wantovertime = 0;
1931
1932         if(timelimit > game_starttime)
1933                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1934         else
1935                 game_completion_ratio = 0;
1936
1937         if(checkrules_suddendeathend)
1938         {
1939                 if(!checkrules_suddendeathwarning)
1940                 {
1941                         checkrules_suddendeathwarning = true;
1942                         if(g_race && !g_race_qualifying)
1943                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1944                         else
1945                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1946                 }
1947         }
1948         else
1949         {
1950                 if (timelimit && time >= timelimit)
1951                 {
1952                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1953                         {
1954                                 float totalplayers;
1955                                 float playerswithlaps;
1956                                 float readyplayers;
1957                                 totalplayers = playerswithlaps = readyplayers = 0;
1958                                 FOREACH_CLIENT(IS_PLAYER(it), {
1959                                         ++totalplayers;
1960                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1961                                                 ++playerswithlaps;
1962                                         if(it.ready)
1963                                                 ++readyplayers;
1964                                 });
1965
1966                                 // at least 2 of the players have completed a lap: start the RACE
1967                                 // otherwise, the players should end the qualifying on their own
1968                                 if(readyplayers || playerswithlaps >= 2)
1969                                 {
1970                                         checkrules_suddendeathend = 0;
1971                                         ReadyRestart(); // go to race
1972                                         return;
1973                                 }
1974                                 else
1975                                         wantovertime |= InitiateSuddenDeath();
1976                         }
1977                         else
1978                                 wantovertime |= InitiateSuddenDeath();
1979                 }
1980         }
1981
1982         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1983         {
1984                 NextLevel();
1985                 return;
1986         }
1987
1988         int checkrules_status = WinningCondition_RanOutOfSpawns();
1989         if(checkrules_status == WINNING_YES)
1990                 bprint("Hey! Someone ran out of spawns!\n");
1991         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1992                 checkrules_status = M_ARGV(0, float);
1993         else
1994                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1995
1996         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1997         {
1998                 checkrules_status = WINNING_NEVER;
1999                 checkrules_overtimesadded = -1;
2000                 wantovertime |= InitiateSuddenDeath();
2001         }
2002
2003         if(checkrules_status == WINNING_NEVER)
2004                 // equality cases! Nobody wins if the overtime ends in a draw.
2005                 ClearWinners();
2006
2007         if(wantovertime)
2008         {
2009                 if(checkrules_status == WINNING_NEVER)
2010                         InitiateOvertime();
2011                 else
2012                         checkrules_status = WINNING_YES;
2013         }
2014
2015         if(checkrules_suddendeathend)
2016                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2017                         checkrules_status = WINNING_YES;
2018
2019         if(checkrules_status == WINNING_YES)
2020         {
2021                 //print("WINNING\n");
2022                 NextLevel();
2023         }
2024 }
2025
2026 string GotoMap(string m)
2027 {
2028         m = GameTypeVote_MapInfo_FixName(m);
2029         if (!m)
2030                 return "The map you suggested is not available on this server.";
2031         if (!autocvar_sv_vote_gametype)
2032         if(!MapInfo_CheckMap(m))
2033                 return "The map you suggested does not support the current game mode.";
2034         cvar_set("nextmap", m);
2035         cvar_set("timelimit", "-1");
2036         if(mapvote_initialized || alreadychangedlevel)
2037         {
2038                 if(DoNextMapOverride(0))
2039                         return "Map switch initiated.";
2040                 else
2041                         return "Hm... no. For some reason I like THIS map more.";
2042         }
2043         else
2044                 return "Map switch will happen after scoreboard.";
2045 }
2046
2047 bool autocvar_sv_gameplayfix_multiplethinksperframe;
2048 void RunThink(entity this)
2049 {
2050         // don't let things stay in the past.
2051         // it is possible to start that way by a trigger with a local time.
2052         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2053                 return;
2054
2055         float oldtime = time; // do we need to save this?
2056
2057         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2058         {
2059                 time = max(oldtime, this.nextthink);
2060                 this.nextthink = 0;
2061
2062                 if(getthink(this))
2063                         getthink(this)(this);
2064                 // mods often set nextthink to time to cause a think every frame,
2065                 // we don't want to loop in that case, so exit if the new nextthink is
2066                 // <= the time the qc was told, also exit if it is past the end of the
2067                 // frame
2068                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2069                         break;
2070         }
2071
2072         time = oldtime;
2073 }
2074
2075 bool autocvar_sv_freezenonclients;
2076 bool autocvar_sv_gameplayfix_delayprojectiles;
2077 void Physics_Frame()
2078 {
2079         if(autocvar_sv_freezenonclients)
2080                 return;
2081
2082         FOREACH_ENTITY_FLOAT(pure_data, false,
2083         {
2084                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2085                         continue;
2086
2087                 //set_movetype(it, it.move_movetype);
2088                 // inline the set_movetype function, since this is called a lot
2089                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2090
2091                 if(it.move_movetype == MOVETYPE_NONE)
2092                         continue;
2093
2094                 if(it.move_qcphysics)
2095                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2096
2097                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2098                 {
2099                         // handle thinking here
2100                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2101                                 RunThink(it);
2102                 }
2103         });
2104
2105         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2106                 return;
2107
2108         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2109         {
2110                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2111                         continue;
2112                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2113         });
2114 }
2115
2116 void systems_update();
2117 void EndFrame()
2118 {
2119         anticheat_endframe();
2120
2121         Physics_Frame();
2122
2123         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2124                 entity e = IS_SPEC(it) ? it.enemy : it;
2125                 if (e.typehitsound) {
2126                         STAT(TYPEHIT_TIME, it) = time;
2127                 } else if (e.killsound) {
2128                         STAT(KILL_TIME, it) = time;
2129                 } else if (e.damage_dealt) {
2130                         STAT(HIT_TIME, it) = time;
2131                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2132                 }
2133         });
2134         // add 1 frametime because after this, engine SV_Physics
2135         // increases time by a frametime and then networks the frame
2136         // add another frametime because client shows everything with
2137         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2138         // needed!
2139         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2140         FOREACH_CLIENT(true, {
2141                 it.typehitsound = false;
2142                 it.damage_dealt = 0;
2143                 it.killsound = false;
2144                 antilag_record(it, CS(it), altime);
2145         });
2146         IL_EACH(g_monsters, true,
2147         {
2148                 antilag_record(it, it, altime);
2149         });
2150         IL_EACH(g_projectiles, it.classname == "nade",
2151         {
2152                 antilag_record(it, it, altime);
2153         });
2154         systems_update();
2155         IL_ENDFRAME();
2156 }
2157
2158
2159 /*
2160  * RedirectionThink:
2161  * returns true if redirecting
2162  */
2163 float redirection_timeout;
2164 float redirection_nextthink;
2165 float RedirectionThink()
2166 {
2167         float clients_found;
2168
2169         if(redirection_target == "")
2170                 return false;
2171
2172         if(!redirection_timeout)
2173         {
2174                 cvar_set("sv_public", "-2");
2175                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2176                 if(redirection_target == "self")
2177                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2178                 else
2179                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2180         }
2181
2182         if(time < redirection_nextthink)
2183                 return true;
2184
2185         redirection_nextthink = time + 1;
2186
2187         clients_found = 0;
2188         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2189                 // TODO add timer
2190                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2191                 if(redirection_target == "self")
2192                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2193                 else
2194                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2195                 ++clients_found;
2196         });
2197
2198         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2199
2200         if(time > redirection_timeout || clients_found == 0)
2201                 localcmd("\nwait; wait; wait; quit\n");
2202
2203         return true;
2204 }
2205
2206 void RestoreGame()
2207 {
2208         // Loaded from a save game
2209         // some things then break, so let's work around them...
2210
2211         // Progs DB (capture records)
2212         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2213
2214         // Mapinfo
2215         MapInfo_Shutdown();
2216         MapInfo_Enumerate();
2217         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2218         WeaponStats_Init();
2219
2220         TargetMusic_RestoreGame();
2221 }
2222
2223 void Shutdown()
2224 {
2225         game_stopped = 2;
2226
2227         if(world_initialized > 0)
2228         {
2229                 world_initialized = 0;
2230                 LOG_TRACE("Saving persistent data...");
2231                 Ban_SaveBans();
2232
2233                 // playerstats with unfinished match
2234                 PlayerStats_GameReport(false);
2235
2236                 if(!cheatcount_total)
2237                 {
2238                         if(autocvar_sv_db_saveasdump)
2239                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2240                         else
2241                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2242                 }
2243                 if(autocvar_developer)
2244                 {
2245                         if(autocvar_sv_db_saveasdump)
2246                                 db_dump(TemporaryDB, "server-temp.db");
2247                         else
2248                                 db_save(TemporaryDB, "server-temp.db");
2249                 }
2250                 CheatShutdown(); // must be after cheatcount check
2251                 db_close(ServerProgsDB);
2252                 db_close(TemporaryDB);
2253                 LOG_TRACE("Saving persistent data... done!");
2254                 // tell the bot system the game is ending now
2255                 bot_endgame();
2256
2257                 WeaponStats_Shutdown();
2258                 MapInfo_Shutdown();
2259         }
2260         else if(world_initialized == 0)
2261         {
2262                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2263         }
2264         else
2265         {
2266                 __init_dedicated_server_shutdown();
2267         }
2268 }