qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/mutators_include.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/all.qh"
  36 #include "../common/weapons/all.qh"
  37
  38 const float LATENCY_THINKRATE = 10;
  39 .float latency_sum;
  40 .float latency_cnt;
  41 .float latency_time;
  42 entity pingplreport;
  43 void PingPLReport_Think()
  44 {SELFPARAM();
  45         float delta;
  46         entity e;
  47
  48         delta = 3 / maxclients;
  49         if(delta < sys_frametime)
  50                 delta = 0;
  51         self.nextthink = time + delta;
  52
  53         e = edict_num(self.cnt + 1);
  54         if(IS_REAL_CLIENT(e))
  55         {
  56                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  57                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  75                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, self.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         self.cnt = (self.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = spawn();
  86         pingplreport.classname = "pingplreport";
  87         pingplreport.think = PingPLReport_Think;
  88         pingplreport.nextthink = time;
  89 }
  90
  91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  92 string redirection_target;
  93 float world_initialized;
  94
  95 string GetGametype();
  96 void ShuffleMaplist();
  97
  98 void SetDefaultAlpha()
  99 {
 100         if(autocvar_g_running_guns)
 101         {
 102                 default_player_alpha = -1;
 103                 default_weapon_alpha = +1;
 104         }
 105         else if(g_cloaked)
 106         {
 107                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 108                 default_weapon_alpha = default_player_alpha;
 109         }
 110         else
 111         {
 112                 default_player_alpha = autocvar_g_player_alpha;
 113                 if(default_player_alpha == 0)
 114                         default_player_alpha = 1;
 115                 default_weapon_alpha = default_player_alpha;
 116         }
 117 }
 118
 119 void GotoFirstMap()
 120 {SELFPARAM();
 121         float n;
 122         if(autocvar__sv_init)
 123         {
 124                 // cvar_set("_sv_init", "0");
 125                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 126                 // to this "init" map on a dedicated server will cause no permanent
 127                 // harm
 128                 if(autocvar_g_maplist_shuffle)
 129                         ShuffleMaplist();
 130                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 131                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 132
 133                 MapInfo_Enumerate();
 134                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 135
 136                 if(!DoNextMapOverride(1))
 137                         GotoNextMap(1);
 138
 139                 return;
 140         }
 141
 142         if(time < 5)
 143         {
 144                 self.nextthink = time;
 145         }
 146         else
 147         {
 148                 self.nextthink = time + 1;
 149                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 150         }
 151 }
 152
 153 void cvar_changes_init()
 154 {
 155         float h;
 156         string k, v, d;
 157         float n, i, adding, pureadding;
 158
 159         if(cvar_changes)
 160                 strunzone(cvar_changes);
 161         cvar_changes = string_null;
 162         if(cvar_purechanges)
 163                 strunzone(cvar_purechanges);
 164         cvar_purechanges = string_null;
 165         cvar_purechanges_count = 0;
 166
 167         h = buf_create();
 168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 169         n = buf_getsize(h);
 170
 171         adding = true;
 172         pureadding = true;
 173
 174         for(i = 0; i < n; ++i)
 175         {
 176                 k = bufstr_get(h, i);
 177
 178 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 179 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 180 #define BADCVAR(p) if(k == p) continue
 181
 182                 // general excludes and namespaces for server admin used cvars
 183                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 184
 185                 // internal
 186                 BADPREFIX("csqc_");
 187                 BADPREFIX("cvar_check_");
 188                 BADCVAR("gamecfg");
 189                 BADCVAR("g_configversion");
 190                 BADCVAR("g_maplist_index");
 191                 BADCVAR("halflifebsp");
 192                 BADCVAR("sv_mapformat_is_quake2");
 193                 BADCVAR("sv_mapformat_is_quake3");
 194                 BADPREFIX("sv_world");
 195
 196                 // client
 197                 BADPREFIX("chase_");
 198                 BADPREFIX("cl_");
 199                 BADPREFIX("con_");
 200                 BADPREFIX("scoreboard_");
 201                 BADPREFIX("g_campaign");
 202                 BADPREFIX("g_waypointsprite_");
 203                 BADPREFIX("gl_");
 204                 BADPREFIX("joy");
 205                 BADPREFIX("hud_");
 206                 BADPREFIX("m_");
 207                 BADPREFIX("menu_");
 208                 BADPREFIX("net_slist_");
 209                 BADPREFIX("r_");
 210                 BADPREFIX("sbar_");
 211                 BADPREFIX("scr_");
 212                 BADPREFIX("snd_");
 213                 BADPREFIX("show");
 214                 BADPREFIX("sensitivity");
 215                 BADPREFIX("userbind");
 216                 BADPREFIX("v_");
 217                 BADPREFIX("vid_");
 218                 BADPREFIX("crosshair");
 219                 BADCVAR("mod_q3bsp_lightmapmergepower");
 220                 BADCVAR("mod_q3bsp_nolightmaps");
 221                 BADCVAR("fov");
 222                 BADCVAR("mastervolume");
 223                 BADCVAR("volume");
 224                 BADCVAR("bgmvolume");
 225
 226                 // private
 227                 BADCVAR("developer");
 228                 BADCVAR("log_dest_udp");
 229                 BADCVAR("net_address");
 230                 BADCVAR("net_address_ipv6");
 231                 BADCVAR("port");
 232                 BADCVAR("savedgamecfg");
 233                 BADCVAR("serverconfig");
 234                 BADCVAR("sv_autoscreenshot");
 235                 BADCVAR("sv_heartbeatperiod");
 236                 BADCVAR("sv_vote_master_password");
 237                 BADCVAR("sys_colortranslation");
 238                 BADCVAR("sys_specialcharactertranslation");
 239                 BADCVAR("timeformat");
 240                 BADCVAR("timestamps");
 241                 BADPREFIX("developer_");
 242                 BADPREFIX("g_ban_");
 243                 BADPREFIX("g_banned_list");
 244                 BADPREFIX("g_chat_flood_");
 245                 BADPREFIX("g_ghost_items");
 246                 BADPREFIX("g_playerstats_");
 247                 BADPREFIX("g_respawn_ghosts");
 248                 BADPREFIX("g_voice_flood_");
 249                 BADPREFIX("log_file");
 250                 BADPREFIX("rcon_");
 251                 BADPREFIX("sv_allowdownloads");
 252                 BADPREFIX("sv_autodemo");
 253                 BADPREFIX("sv_curl_");
 254                 BADPREFIX("sv_eventlog");
 255                 BADPREFIX("sv_logscores_");
 256                 BADPREFIX("sv_master");
 257                 BADPREFIX("sv_weaponstats_");
 258                 BADPREFIX("sv_waypointsprite_");
 259                 BADCVAR("rescan_pending");
 260
 261                 // these can contain player IDs, so better hide
 262                 BADPREFIX("g_forced_team_");
 263
 264                 // mapinfo
 265                 BADCVAR("fraglimit");
 266                 BADCVAR("g_assault");
 267                 BADCVAR("g_ca");
 268                 BADCVAR("g_ca_teams");
 269                 BADCVAR("g_ctf");
 270                 BADCVAR("g_cts");
 271                 BADCVAR("g_dm");
 272                 BADCVAR("g_domination");
 273                 BADCVAR("g_domination_default_teams");
 274                 BADCVAR("g_freezetag");
 275                 BADCVAR("g_freezetag_teams");
 276                 BADCVAR("g_invasion_teams");
 277                 BADCVAR("g_keepaway");
 278                 BADCVAR("g_keyhunt");
 279                 BADCVAR("g_keyhunt_teams");
 280                 BADCVAR("g_lms");
 281                 BADCVAR("g_nexball");
 282                 BADCVAR("g_onslaught");
 283                 BADCVAR("g_race");
 284                 BADCVAR("g_race_qualifying_timelimit");
 285                 BADCVAR("g_tdm");
 286                 BADCVAR("g_tdm_teams");
 287                 BADCVAR("leadlimit");
 288                 BADCVAR("nextmap");
 289                 BADCVAR("teamplay");
 290                 BADCVAR("timelimit");
 291
 292                 // long
 293                 BADCVAR("hostname");
 294                 BADCVAR("g_maplist");
 295                 BADCVAR("g_maplist_mostrecent");
 296                 BADCVAR("sv_motd");
 297
 298                 v = cvar_string(k);
 299                 d = cvar_defstring(k);
 300                 if(v == d)
 301                         continue;
 302
 303                 if(adding)
 304                 {
 305                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 306                         if(strlen(cvar_changes) > 16384)
 307                         {
 308                                 cvar_changes = "// too many settings have been changed to show them here\n";
 309                                 adding = 0;
 310                         }
 311                 }
 312
 313                 // now check if the changes are actually gameplay relevant
 314
 315                 // does nothing visible
 316                 BADCVAR("captureleadlimit_override");
 317                 BADCVAR("g_balance_kill_delay");
 318                 BADCVAR("g_ca_point_limit");
 319                 BADCVAR("g_ca_point_leadlimit");
 320                 BADCVAR("g_ctf_captimerecord_always");
 321                 BADCVAR("g_ctf_flag_glowtrails");
 322                 BADCVAR("g_ctf_flag_pickup_verbosename");
 323                 BADCVAR("g_domination_point_leadlimit");
 324                 BADCVAR("g_forced_respawn");
 325                 BADCVAR("g_freezetag_point_limit");
 326                 BADCVAR("g_freezetag_point_leadlimit");
 327                 BADCVAR("g_keyhunt_point_leadlimit");
 328                 BADPREFIX("g_mod_");
 329                 BADCVAR("g_invasion_point_limit");
 330                 BADCVAR("g_nexball_goalleadlimit");
 331                 BADCVAR("g_tdm_point_limit");
 332                 BADCVAR("g_tdm_point_leadlimit");
 333                 BADCVAR("leadlimit_and_fraglimit");
 334                 BADCVAR("leadlimit_override");
 335                 BADCVAR("pausable");
 336                 BADCVAR("sv_allow_fullbright");
 337                 BADCVAR("sv_checkforpacketsduringsleep");
 338                 BADCVAR("sv_timeout");
 339                 BADPREFIX("sv_timeout_");
 340                 BADPREFIX("crypto_");
 341                 BADPREFIX("g_chat_");
 342                 BADPREFIX("g_ctf_captimerecord_");
 343                 BADPREFIX("g_maplist_votable_");
 344                 BADPREFIX("net_");
 345                 BADPREFIX("prvm_");
 346                 BADPREFIX("skill_");
 347                 BADPREFIX("sv_cullentities_");
 348                 BADPREFIX("sv_maxidle_");
 349                 BADPREFIX("sv_vote_");
 350                 BADPREFIX("timelimit_");
 351                 BADCVAR("gameversion");
 352                 BADPREFIX("gameversion_");
 353                 BADCVAR("sv_minigames");
 354                 BADPREFIX("sv_minigames_");
 355                 BADCVAR("sv_namechangetimer");
 356
 357                 // allowed changes to server admins (please sync this to server.cfg)
 358                 // vi commands:
 359                 //   :/"impure"/,$d
 360                 //   :g!,^\/\/[^ /],d
 361                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 362                 //   :%!sort
 363                 // yes, this does contain some redundant stuff, don't really care
 364                 BADCVAR("bot_config_file");
 365                 BADCVAR("bot_number");
 366                 BADCVAR("bot_prefix");
 367                 BADCVAR("bot_suffix");
 368                 BADCVAR("capturelimit_override");
 369                 BADCVAR("fraglimit_override");
 370                 BADCVAR("gametype");
 371                 BADCVAR("g_antilag");
 372                 BADCVAR("g_balance_teams");
 373                 BADCVAR("g_balance_teams_prevent_imbalance");
 374                 BADCVAR("g_balance_teams_scorefactor");
 375                 BADCVAR("g_ban_sync_trusted_servers");
 376                 BADCVAR("g_ban_sync_uri");
 377                 BADCVAR("g_ca_teams_override");
 378                 BADCVAR("g_ctf_ignore_frags");
 379                 BADCVAR("g_domination_point_limit");
 380                 BADCVAR("g_domination_teams_override");
 381                 BADCVAR("g_freezetag_teams_override");
 382                 BADCVAR("g_friendlyfire");
 383                 BADCVAR("g_fullbrightitems");
 384                 BADCVAR("g_fullbrightplayers");
 385                 BADCVAR("g_keyhunt_point_limit");
 386                 BADCVAR("g_keyhunt_teams_override");
 387                 BADCVAR("g_lms_lives_override");
 388                 BADCVAR("g_maplist");
 389                 BADCVAR("g_maplist_check_waypoints");
 390                 BADCVAR("g_maplist_mostrecent_count");
 391                 BADCVAR("g_maplist_shuffle");
 392                 BADCVAR("g_maplist_votable");
 393                 BADCVAR("g_maplist_votable_abstain");
 394                 BADCVAR("g_maplist_votable_nodetail");
 395                 BADCVAR("g_maplist_votable_suggestions");
 396                 BADCVAR("g_maxplayers");
 397                 BADCVAR("g_mirrordamage");
 398                 BADCVAR("g_nexball_goallimit");
 399                 BADCVAR("g_powerups");
 400                 BADCVAR("g_start_delay");
 401                 BADCVAR("g_tdm_teams_override");
 402                 BADCVAR("g_warmup");
 403                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 404                 BADCVAR("hostname");
 405                 BADCVAR("log_file");
 406                 BADCVAR("maxplayers");
 407                 BADCVAR("minplayers");
 408                 BADCVAR("net_address");
 409                 BADCVAR("port");
 410                 BADCVAR("rcon_password");
 411                 BADCVAR("rcon_restricted_commands");
 412                 BADCVAR("rcon_restricted_password");
 413                 BADCVAR("skill");
 414                 BADCVAR("sv_adminnick");
 415                 BADCVAR("sv_autoscreenshot");
 416                 BADCVAR("sv_autotaunt");
 417                 BADCVAR("sv_curl_defaulturl");
 418                 BADCVAR("sv_defaultcharacter");
 419                 BADCVAR("sv_defaultplayercolors");
 420                 BADCVAR("sv_defaultplayermodel");
 421                 BADCVAR("sv_defaultplayerskin");
 422                 BADCVAR("sv_maxidle");
 423                 BADCVAR("sv_maxrate");
 424                 BADCVAR("sv_motd");
 425                 BADCVAR("sv_public");
 426                 BADCVAR("sv_ready_restart");
 427                 BADCVAR("sv_status_privacy");
 428                 BADCVAR("sv_taunt");
 429                 BADCVAR("sv_vote_call");
 430                 BADCVAR("sv_vote_commands");
 431                 BADCVAR("sv_vote_majority_factor");
 432                 BADCVAR("sv_vote_master");
 433                 BADCVAR("sv_vote_master_commands");
 434                 BADCVAR("sv_vote_master_password");
 435                 BADCVAR("sv_vote_simple_majority_factor");
 436                 BADCVAR("teamplay_mode");
 437                 BADCVAR("timelimit_override");
 438                 BADCVAR("g_spawnshieldtime");
 439                 BADPREFIX("g_warmup_");
 440                 BADPREFIX("sv_ready_restart_");
 441
 442                 // mutators that announce themselves properly to the server browser
 443                 BADCVAR("g_instagib");
 444                 BADCVAR("g_new_toys");
 445                 BADCVAR("g_nix");
 446                 BADCVAR("g_grappling_hook");
 447                 BADCVAR("g_jetpack");
 448
 449 #undef BADPREFIX
 450 #undef BADCVAR
 451
 452                 if(pureadding)
 453                 {
 454                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 455                         if(strlen(cvar_purechanges) > 16384)
 456                         {
 457                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 458                                 pureadding = 0;
 459                         }
 460                 }
 461                 ++cvar_purechanges_count;
 462                 // WARNING: this variable is used for the server list
 463                 // NEVER dare to skip this code!
 464                 // Hacks to intentionally appearing as "pure server" even though you DO have
 465                 // modified settings may be punished by removal from the server list.
 466                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 467                 // though.
 468         }
 469         buf_del(h);
 470         if(cvar_changes == "")
 471                 cvar_changes = "// this server runs at default server settings\n";
 472         else
 473                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 474         cvar_changes = strzone(cvar_changes);
 475         if(cvar_purechanges == "")
 476                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 477         else
 478                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 479         cvar_purechanges = strzone(cvar_purechanges);
 480 }
 481
 482 void detect_maptype()
 483 {
 484 #if 0
 485         vector o, v;
 486         float i;
 487
 488         for (;;)
 489         {
 490                 o = world.mins;
 491                 o.x += random() * (world.maxs.x - world.mins.x);
 492                 o.y += random() * (world.maxs.y - world.mins.y);
 493                 o.z += random() * (world.maxs.z - world.mins.z);
 494
 495                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 496                 if(trace_fraction == 1)
 497                         continue;
 498
 499                 v = trace_endpos;
 500
 501                 for(i = 0; i < 64; i += 4)
 502                 {
 503                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 504         if(trace_fraction == 1)
 505                 continue;
 506                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 507                 }
 508
 509                 break;
 510         }
 511 #endif
 512 }
 513
 514 entity randomseed;
 515 bool RandomSeed_Send(entity this, entity to, int sf)
 516 {
 517         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 518         WriteShort(MSG_ENTITY, self.cnt);
 519         return true;
 520 }
 521 void RandomSeed_Think()
 522 {SELFPARAM();
 523         self.cnt = bound(0, floor(random() * 65536), 65535);
 524         self.nextthink = time + 5;
 525
 526         self.SendFlags |= 1;
 527 }
 528 void RandomSeed_Spawn()
 529 {SELFPARAM();
 530         randomseed = spawn();
 531         randomseed.think = RandomSeed_Think;
 532         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 533
 534         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 535 }
 536
 537 spawnfunc(__init_dedicated_server)
 538 {
 539         // handler for _init/_init map (only for dedicated server initialization)
 540
 541         world_initialized = -1; // don't complain
 542         cvar = cvar_normal;
 543         cvar_string = cvar_string_normal;
 544         cvar_set = cvar_set_normal;
 545
 546         remove = remove_unsafely;
 547
 548         entity e;
 549         e = spawn();
 550         e.think = GotoFirstMap;
 551         e.nextthink = time; // this is usually 1 at this point
 552
 553         e = spawn();
 554         e.classname = "info_player_deathmatch"; // safeguard against player joining
 555
 556         self.classname = "worldspawn"; // safeguard against various stuff ;)
 557
 558         // needs to be done so early because of the constants they create
 559         static_init();
 560         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 561
 562         MapInfo_Enumerate();
 563         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 564 }
 565
 566 void Map_MarkAsRecent(string m);
 567 float world_already_spawned;
 568 void Nagger_Init();
 569 void ClientInit_Spawn();
 570 void WeaponStats_Init();
 571 void WeaponStats_Shutdown();
 572 void Physics_AddStats();
 573 spawnfunc(worldspawn)
 574 {
 575         float fd, l, j, n;
 576         string s;
 577
 578         cvar = cvar_normal;
 579         cvar_string = cvar_string_normal;
 580         cvar_set = cvar_set_normal;
 581
 582         if(world_already_spawned)
 583                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 584         world_already_spawned = true;
 585
 586         remove = remove_safely; // during spawning, watch what you remove!
 587
 588         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 589
 590         compressShortVector_init();
 591
 592         entity head;
 593         head = nextent(world);
 594         maxclients = 0;
 595         while(head)
 596         {
 597                 ++maxclients;
 598                 head = nextent(head);
 599         }
 600
 601         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 602
 603         // needs to be done so early because of the constants they create
 604         static_init();
 605         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 606
 607         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 608
 609         TemporaryDB = db_create();
 610
 611         // 0 normal
 612         lightstyle(0, "m");
 613
 614         // 1 FLICKER (first variety)
 615         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 616
 617         // 2 SLOW STRONG PULSE
 618         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 619
 620         // 3 CANDLE (first variety)
 621         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 622
 623         // 4 FAST STROBE
 624         lightstyle(4, "mamamamamama");
 625
 626         // 5 GENTLE PULSE 1
 627         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 628
 629         // 6 FLICKER (second variety)
 630         lightstyle(6, "nmonqnmomnmomomno");
 631
 632         // 7 CANDLE (second variety)
 633         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 634
 635         // 8 CANDLE (third variety)
 636         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 637
 638         // 9 SLOW STROBE (fourth variety)
 639         lightstyle(9, "aaaaaaaazzzzzzzz");
 640
 641         // 10 FLUORESCENT FLICKER
 642         lightstyle(10, "mmamammmmammamamaaamammma");
 643
 644         // 11 SLOW PULSE NOT FADE TO BLACK
 645         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 646
 647         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 648
 649         // 63 testing
 650         lightstyle(63, "a");
 651
 652         if(autocvar_g_campaign)
 653                 CampaignPreInit();
 654
 655         Map_MarkAsRecent(mapname);
 656
 657         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 658
 659         InitGameplayMode();
 660         readlevelcvars();
 661         GrappleHookInit();
 662
 663         player_count = 0;
 664         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 665         if(bot_waypoints_for_items == 1)
 666                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 667                         bot_waypoints_for_items = 0;
 668
 669         precache();
 670
 671         WaypointSprite_Init();
 672
 673         GameLogInit(); // prepare everything
 674         // NOTE for matchid:
 675         // changing the logic generating it is okay. But:
 676         // it HAS to stay <= 64 chars
 677         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 678         if(autocvar_sv_eventlog)
 679         {
 680                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 681                 matchid = strzone(s);
 682
 683                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 684                 s = ":gameinfo:mutators:LIST";
 685
 686                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 687                 s = ret_string;
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(!autocvar_g_use_ammunition)
 691                         s = strcat(s, ":no_use_ammunition");
 692
 693                 // initialiation stuff, not good in the mutator system
 694                 if(autocvar_g_pickup_items == 0)
 695                         s = strcat(s, ":no_pickup_items");
 696                 if(autocvar_g_pickup_items > 0)
 697                         s = strcat(s, ":pickup_items");
 698
 699                 // initialiation stuff, not good in the mutator system
 700                 if(autocvar_g_weaponarena != "0")
 701                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 702
 703                 // TODO to mutator system
 704                 if(autocvar_g_norecoil)
 705                         s = strcat(s, ":norecoil");
 706
 707                 // TODO to mutator system
 708                 if(autocvar_g_powerups == 0)
 709                         s = strcat(s, ":no_powerups");
 710                 if(autocvar_g_powerups > 0)
 711                         s = strcat(s, ":powerups");
 712
 713                 GameLogEcho(s);
 714                 GameLogEcho(":gameinfo:end");
 715         }
 716         else
 717                 matchid = strzone(ftos(random()));
 718
 719         cvar_set("nextmap", "");
 720
 721         SetDefaultAlpha();
 722
 723         if(autocvar_g_campaign)
 724                 CampaignPostInit();
 725
 726         Ban_LoadBans();
 727
 728         MapInfo_Enumerate();
 729         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 730
 731         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 732         {
 733                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 734                 if(fd != -1)
 735                 {
 736                         while((s = fgets(fd)))
 737                         {
 738                                 l = tokenize_console(s);
 739                                 if(l < 2)
 740                                         continue;
 741                                 if(argv(0) == "cd")
 742                                 {
 743                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 744                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) == "fog")
 747                                 {
 748                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 749                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 750                                 }
 751                                 else if(argv(0) == "set")
 752                                 {
 753                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 754                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 755                                 }
 756                                 else if(argv(0) != "//")
 757                                 {
 758                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 759                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 760                                 }
 761                         }
 762                         fclose(fd);
 763                 }
 764         }
 765
 766         WeaponStats_Init();
 767
 768         WepSet_AddStat();
 769         WepSet_AddStat_InMap();
 770         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 771         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 772         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 773         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 774         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 775         Nagger_Init();
 776
 777         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 778         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 779         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 780         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 781         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 782         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 783         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 784         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 785         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 786         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 787         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 788         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 789         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 790         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 791         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 792
 793         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 794         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 795
 796         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 797
 798         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 799
 800         // freeze attacks
 801         addstat(STAT_FROZEN, AS_INT, frozen);
 802         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 803
 804         // physics
 805         Physics_AddStats();
 806
 807         // new properties
 808         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 809         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 810         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 811         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 812         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 813         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 814         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 815         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 816         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 817         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 818         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 819         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 820         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 821         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 822         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 823         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 824         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 825         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 826         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 827
 828         // secrets
 829         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 830         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 831
 832         // monsters
 833         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 834         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 835
 836         // misc
 837         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 838
 839         next_pingtime = time + 5;
 840
 841         detect_maptype();
 842
 843         // set up information replies for clients and server to use
 844         maplist_reply = strzone(getmaplist());
 845         lsmaps_reply = strzone(getlsmaps());
 846         monsterlist_reply = strzone(getmonsterlist());
 847         for(int i = 0; i < 10; ++i)
 848         {
 849                 s = getrecords(i);
 850                 if (s)
 851                         records_reply[i] = strzone(s);
 852         }
 853         ladder_reply = strzone(getladder());
 854         rankings_reply = strzone(getrankings());
 855
 856         // begin other init
 857         ClientInit_Spawn();
 858         RandomSeed_Spawn();
 859         PingPLReport_Spawn();
 860
 861         CheatInit();
 862
 863         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 864
 865         // fill sv_curl_serverpackages from .serverpackage files
 866         if(autocvar_sv_curl_serverpackages_auto)
 867         {
 868                 s = "";
 869                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 870                 for(int i = 0; i < n; ++i)
 871                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 872                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 873                                 s = strcat(s, " ", argv(i));
 874                 fd = search_begin("*-serverpackage.txt", true, false);
 875                 if(fd >= 0)
 876                 {
 877                         j = search_getsize(fd);
 878                         for(int i = 0; i < j; ++i)
 879                                 s = strcat(s, " ", search_getfilename(fd, i));
 880                         search_end(fd);
 881                 }
 882                 fd = search_begin("*.serverpackage", true, false);
 883                 if(fd >= 0)
 884                 {
 885                         j = search_getsize(fd);
 886                         for(int i = 0; i < j; ++i)
 887                                 s = strcat(s, " ", search_getfilename(fd, i));
 888                         search_end(fd);
 889                 }
 890                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 891         }
 892
 893         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 894         modname = "Xonotic";
 895         // physics/balance/config changes that count as mod
 896         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 897                 modname = cvar_string("g_mod_physics");
 898         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 899                 modname = cvar_string("g_mod_balance");
 900         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 901                 modname = cvar_string("g_mod_config");
 902         // extra mutators that deserve to count as mod
 903         MUTATOR_CALLHOOK(SetModname);
 904
 905         // save it for later
 906         modname = strzone(modname);
 907
 908         WinningConditionHelper(); // set worldstatus
 909
 910         world_initialized = 1;
 911 }
 912
 913 spawnfunc(light)
 914 {
 915         //makestatic (self); // Who the f___ did that?
 916         remove(self);
 917 }
 918
 919 string GetGametype()
 920 {
 921         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 922 }
 923
 924 string GetMapname()
 925 {
 926         return mapname;
 927 }
 928
 929 float Map_Count, Map_Current;
 930 string Map_Current_Name;
 931
 932 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 933 float GetMaplistPosition()
 934 {
 935         float pos, idx;
 936         string map;
 937
 938         map = GetMapname();
 939         idx = autocvar_g_maplist_index;
 940
 941         if(idx >= 0)
 942                 if(idx < Map_Count)
 943                         if(map == argv(idx))
 944                                 return idx;
 945
 946         for(pos = 0; pos < Map_Count; ++pos)
 947                 if(map == argv(pos))
 948                         return pos;
 949
 950         // resume normal maplist rotation if current map is not in g_maplist
 951         return idx;
 952 }
 953
 954 float MapHasRightSize(string map)
 955 {
 956         float fh;
 957         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 958         if(autocvar_g_maplist_check_waypoints)
 959         {
 960                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 961                 if(!fexists(strcat("maps/", map, ".waypoints")))
 962                 {
 963                         LOG_TRACE(": no waypoints\n");
 964                         return false;
 965                 }
 966                 LOG_TRACE(": has waypoints\n");
 967         }
 968
 969         // open map size restriction file
 970         LOG_TRACE("opensize "); LOG_TRACE(map);
 971         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 972         if(fh >= 0)
 973         {
 974                 float mapmin, mapmax;
 975                 LOG_TRACE(": ok, ");
 976                 mapmin = stof(fgets(fh));
 977                 mapmax = stof(fgets(fh));
 978                 fclose(fh);
 979                 if(player_count < mapmin)
 980                 {
 981                         LOG_TRACE("not enough\n");
 982                         return false;
 983                 }
 984                 if(player_count > mapmax)
 985                 {
 986                         LOG_TRACE("too many\n");
 987                         return false;
 988                 }
 989                 LOG_TRACE("right size\n");
 990                 return true;
 991         }
 992         LOG_TRACE(": not found\n");
 993         return true;
 994 }
 995
 996 string Map_Filename(float position)
 997 {
 998         return strcat("maps/", argv(position), ".bsp");
 999 }
1000
1001 void Map_MarkAsRecent(string m)
1002 {
1003         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1004 }
1005
1006 float Map_IsRecent(string m)
1007 {
1008         return strhasword(autocvar_g_maplist_mostrecent, m);
1009 }
1010
1011 float Map_Check(float position, float pass)
1012 {
1013         string filename;
1014         string map_next;
1015         map_next = argv(position);
1016         if(pass <= 1)
1017         {
1018                 if(Map_IsRecent(map_next))
1019                         return 0;
1020         }
1021         filename = Map_Filename(position);
1022         if(MapInfo_CheckMap(map_next))
1023         {
1024                 if(pass == 2)
1025                         return 1;
1026                 if(MapHasRightSize(map_next))
1027                         return 1;
1028                 return 0;
1029         }
1030         else
1031                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1032
1033         return 0;
1034 }
1035
1036 void Map_Goto_SetStr(string nextmapname)
1037 {
1038         if(getmapname_stored != "")
1039                 strunzone(getmapname_stored);
1040         if(nextmapname == "")
1041                 getmapname_stored = "";
1042         else
1043                 getmapname_stored = strzone(nextmapname);
1044 }
1045
1046 void Map_Goto_SetFloat(float position)
1047 {
1048         cvar_set("g_maplist_index", ftos(position));
1049         Map_Goto_SetStr(argv(position));
1050 }
1051
1052 void Map_Goto(float reinit)
1053 {
1054         MapInfo_LoadMap(getmapname_stored, reinit);
1055 }
1056
1057 // return codes of map selectors:
1058 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1059 //   -2 = permanent failure
1060 float() MaplistMethod_Iterate = // usual method
1061 {
1062         float pass, i;
1063
1064         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1065
1066         for(pass = 1; pass <= 2; ++pass)
1067         {
1068                 for(i = 1; i < Map_Count; ++i)
1069                 {
1070                         float mapindex;
1071                         mapindex = (i + Map_Current) % Map_Count;
1072                         if(Map_Check(mapindex, pass))
1073                                 return mapindex;
1074                 }
1075         }
1076         return -1;
1077 }
1078
1079 float() MaplistMethod_Repeat = // fallback method
1080 {
1081         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1082
1083         if(Map_Check(Map_Current, 2))
1084                 return Map_Current;
1085         return -2;
1086 }
1087
1088 float() MaplistMethod_Random = // random map selection
1089 {
1090         float i, imax;
1091
1092         LOG_TRACE("Trying MaplistMethod_Random\n");
1093
1094         imax = 42;
1095
1096         for(i = 0; i <= imax; ++i)
1097         {
1098                 float mapindex;
1099                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1100                 if(Map_Check(mapindex, 1))
1101                         return mapindex;
1102         }
1103         return -1;
1104 }
1105
1106 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1107 // the exponent sets a bias on the map selection:
1108 // the higher the exponent, the less likely "shortly repeated" same maps are
1109 {
1110         float i, j, imax, insertpos;
1111
1112         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1113
1114         imax = 42;
1115
1116         for(i = 0; i <= imax; ++i)
1117         {
1118                 string newlist;
1119
1120                 // now reinsert this at another position
1121                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1122                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1123                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1124                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1125
1126                 // insert the current map there
1127                 newlist = "";
1128                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1129                         newlist = strcat(newlist, " ", argv(j));
1130                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1131                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1132                         newlist = strcat(newlist, " ", argv(j));
1133                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1134                 cvar_set("g_maplist", newlist);
1135                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1136
1137                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1138                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1139                 if(Map_Check(Map_Current, 1))
1140                         return Map_Current;
1141         }
1142         return -1;
1143 }
1144
1145 void Maplist_Init()
1146 {
1147         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1148         float i;
1149         for (i = 0; i < Map_Count; ++i)
1150                 if (Map_Check(i, 2))
1151                         break;
1152         if (i == Map_Count)
1153         {
1154                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1155                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1156                 if(autocvar_g_maplist_shuffle)
1157                         ShuffleMaplist();
1158                 localcmd("\nmenu_cmd sync\n");
1159                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1160         }
1161         if(Map_Count == 0)
1162                 error("empty maplist, cannot select a new map");
1163         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1164
1165         if(Map_Current_Name)
1166                 strunzone(Map_Current_Name);
1167         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1168         // this may or may not be correct, but who cares, in the worst case a map
1169         // isn't chosen in the first pass that should have been
1170 }
1171
1172 string GetNextMap()
1173 {
1174         float nextMap;
1175
1176         Maplist_Init();
1177         nextMap = -1;
1178
1179         if(nextMap == -1)
1180                 if(autocvar_g_maplist_shuffle > 0)
1181                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1182
1183         if(nextMap == -1)
1184                 if(autocvar_g_maplist_selectrandom)
1185                         nextMap = MaplistMethod_Random();
1186
1187         if(nextMap == -1)
1188                 nextMap = MaplistMethod_Iterate();
1189
1190         if(nextMap == -1)
1191                 nextMap = MaplistMethod_Repeat();
1192
1193         if(nextMap >= 0)
1194         {
1195                 Map_Goto_SetFloat(nextMap);
1196                 return getmapname_stored;
1197         }
1198
1199         return "";
1200 }
1201
1202 float DoNextMapOverride(float reinit)
1203 {
1204         if(autocvar_g_campaign)
1205         {
1206                 CampaignPostIntermission();
1207                 alreadychangedlevel = true;
1208                 return true;
1209         }
1210         if(autocvar_quit_when_empty)
1211         {
1212                 if(player_count <= currentbots)
1213                 {
1214                         localcmd("quit\n");
1215                         alreadychangedlevel = true;
1216                         return true;
1217                 }
1218         }
1219         if(autocvar_quit_and_redirect != "")
1220         {
1221                 redirection_target = strzone(autocvar_quit_and_redirect);
1222                 alreadychangedlevel = true;
1223                 return true;
1224         }
1225         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1226         {
1227                 localcmd("restart\n");
1228                 alreadychangedlevel = true;
1229                 return true;
1230         }
1231         if(autocvar_nextmap != "")
1232         {
1233                 string m;
1234                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1235                 cvar_set("nextmap",m);
1236
1237                 if(!m || gametypevote)
1238                         return false;
1239                 if(autocvar_sv_vote_gametype)
1240                 {
1241                         Map_Goto_SetStr(m);
1242                         return false;
1243                 }
1244
1245                 if(MapInfo_CheckMap(m))
1246                 {
1247                         Map_Goto_SetStr(m);
1248                         Map_Goto(reinit);
1249                         alreadychangedlevel = true;
1250                         return true;
1251                 }
1252         }
1253         if(!reinit && autocvar_lastlevel)
1254         {
1255                 cvar_settemp_restore();
1256                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1257                 alreadychangedlevel = true;
1258                 return true;
1259         }
1260         return false;
1261 }
1262
1263 void GotoNextMap(float reinit)
1264 {
1265         //string nextmap;
1266         //float n, nummaps;
1267         //string s;
1268         if (alreadychangedlevel)
1269                 return;
1270         alreadychangedlevel = true;
1271
1272         string nextMap;
1273
1274         nextMap = GetNextMap();
1275         if(nextMap == "")
1276                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1277         Map_Goto(reinit);
1278 }
1279
1280
1281 /*
1282 ============
1283 IntermissionThink
1284
1285 When the player presses attack or jump, change to the next level
1286 ============
1287 */
1288 .float autoscreenshot;
1289 void IntermissionThink()
1290 {SELFPARAM();
1291         FixIntermissionClient(self);
1292
1293         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1294         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1295
1296         if( (server_screenshot || client_screenshot)
1297                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1298         {
1299                 self.autoscreenshot = -1;
1300                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1301                 return;
1302         }
1303
1304         if (time < intermission_exittime)
1305                 return;
1306
1307         if(!mapvote_initialized)
1308                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1309                         return;
1310
1311         MapVote_Start();
1312 }
1313
1314 /*
1315 ============
1316 FindIntermission
1317
1318 Returns the entity to view from
1319 ============
1320 */
1321 /*
1322 entity FindIntermission()
1323 {
1324         local   entity spot;
1325         local   float cyc;
1326
1327 // look for info_intermission first
1328         spot = find (world, classname, "info_intermission");
1329         if (spot)
1330         {       // pick a random one
1331                 cyc = random() * 4;
1332                 while (cyc > 1)
1333                 {
1334                         spot = find (spot, classname, "info_intermission");
1335                         if (!spot)
1336                                 spot = find (spot, classname, "info_intermission");
1337                         cyc = cyc - 1;
1338                 }
1339                 return spot;
1340         }
1341
1342 // then look for the start position
1343         spot = find (world, classname, "info_player_start");
1344         if (spot)
1345                 return spot;
1346
1347 // testinfo_player_start is only found in regioned levels
1348         spot = find (world, classname, "testplayerstart");
1349         if (spot)
1350                 return spot;
1351
1352 // then look for the start position
1353         spot = find (world, classname, "info_player_deathmatch");
1354         if (spot)
1355                 return spot;
1356
1357         //objerror ("FindIntermission: no spot");
1358         return world;
1359 }
1360 */
1361
1362 /*
1363 ===============================================================================
1364
1365 RULES
1366
1367 ===============================================================================
1368 */
1369
1370 void DumpStats(float final)
1371 {
1372         float file;
1373         string s;
1374         float to_console;
1375         float to_eventlog;
1376         float to_file;
1377         float i;
1378
1379         to_console = autocvar_sv_logscores_console;
1380         to_eventlog = autocvar_sv_eventlog;
1381         to_file = autocvar_sv_logscores_file;
1382
1383         if(!final)
1384         {
1385                 to_console = true; // always print printstats replies
1386                 to_eventlog = false; // but never print them to the event log
1387         }
1388
1389         if(to_eventlog)
1390                 if(autocvar_sv_eventlog_console)
1391                         to_console = false; // otherwise we get the output twice
1392
1393         if(final)
1394                 s = ":scores:";
1395         else
1396                 s = ":status:";
1397         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1398
1399         if(to_console)
1400                 LOG_INFO(s, "\n");
1401         if(to_eventlog)
1402                 GameLogEcho(s);
1403
1404         file = -1;
1405         if(to_file)
1406         {
1407                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1408                 if(file == -1)
1409                         to_file = false;
1410                 else
1411                         fputs(file, strcat(s, "\n"));
1412         }
1413
1414         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1415         if(to_console)
1416                 LOG_INFO(s, "\n");
1417         if(to_eventlog)
1418                 GameLogEcho(s);
1419         if(to_file)
1420                 fputs(file, strcat(s, "\n"));
1421
1422         FOR_EACH_CLIENT(other)
1423         {
1424                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1425                 {
1426                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1427                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1428                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1429                                 s = strcat(s, ftos(other.team), ":");
1430                         else
1431                                 s = strcat(s, "spectator:");
1432
1433                         if(to_console)
1434                                 LOG_INFO(s, other.netname, "\n");
1435                         if(to_eventlog)
1436                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1437                         if(to_file)
1438                                 fputs(file, strcat(s, other.netname, "\n"));
1439                 }
1440         }
1441
1442         if(teamplay)
1443         {
1444                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1445                 if(to_console)
1446                         LOG_INFO(s, "\n");
1447                 if(to_eventlog)
1448                         GameLogEcho(s);
1449                 if(to_file)
1450                         fputs(file, strcat(s, "\n"));
1451
1452                 for(i = 1; i < 16; ++i)
1453                 {
1454                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1455                         s = strcat(s, ":", ftos(i));
1456                         if(to_console)
1457                                 LOG_INFO(s, "\n");
1458                         if(to_eventlog)
1459                                 GameLogEcho(s);
1460                         if(to_file)
1461                                 fputs(file, strcat(s, "\n"));
1462                 }
1463         }
1464
1465         if(to_console)
1466                 LOG_INFO(":end\n");
1467         if(to_eventlog)
1468                 GameLogEcho(":end");
1469         if(to_file)
1470         {
1471                 fputs(file, ":end\n");
1472                 fclose(file);
1473         }
1474 }
1475
1476 void FixIntermissionClient(entity e)
1477 {
1478         string s;
1479         if(!e.autoscreenshot) // initial call
1480         {
1481                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1482                 e.health = -2342;
1483                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1484                 e.solid = SOLID_NOT;
1485                 e.movetype = MOVETYPE_NONE;
1486                 e.takedamage = DAMAGE_NO;
1487                 if(e.weaponentity)
1488                 {
1489                         e.weaponentity.effects = EF_NODRAW;
1490                         if (e.weaponentity.weaponentity)
1491                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1492                 }
1493                 if(IS_REAL_CLIENT(e))
1494                 {
1495                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1496                         s = autocvar_sv_intermission_cdtrack;
1497                         if(s != "")
1498                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1499                         msg_entity = e;
1500                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1501                 }
1502         }
1503 }
1504
1505 /*
1506 go to the next level for deathmatch
1507 only called if a time or frag limit has expired
1508 */
1509 void NextLevel()
1510 {
1511         gameover = true;
1512
1513         intermission_running = 1;
1514
1515 // enforce a wait time before allowing changelevel
1516         if(player_count > 0)
1517                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1518         else
1519                 intermission_exittime = -1;
1520
1521         /*
1522         WriteByte (MSG_ALL, SVC_CDTRACK);
1523         WriteByte (MSG_ALL, 3);
1524         WriteByte (MSG_ALL, 3);
1525         // done in FixIntermission
1526         */
1527
1528         //pos = FindIntermission ();
1529
1530         VoteReset();
1531
1532         DumpStats(true);
1533
1534         // send statistics
1535         PlayerStats_GameReport(true);
1536         WeaponStats_Shutdown();
1537
1538         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1539
1540         if(autocvar_sv_eventlog)
1541                 GameLogEcho(":gameover");
1542
1543         GameLogClose();
1544
1545         FOR_EACH_PLAYER(other) {
1546                 FixIntermissionClient(other);
1547                 if(other.winning)
1548                         bprint(other.netname, " ^7wins.\n");
1549         }
1550
1551         if(autocvar_g_campaign)
1552                 CampaignPreIntermission();
1553
1554         MUTATOR_CALLHOOK(MatchEnd);
1555
1556         localcmd("\nsv_hook_gameend\n");
1557 }
1558
1559 /*
1560 ============
1561 CheckRules_Player
1562
1563 Exit deathmatch games upon conditions
1564 ============
1565 */
1566 void CheckRules_Player()
1567 {SELFPARAM();
1568         if (gameover)   // someone else quit the game already
1569                 return;
1570
1571         if(self.deadflag == DEAD_NO)
1572                 self.play_time += frametime;
1573
1574         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1575         //   (div0: and that in CheckRules_World please)
1576 }
1577
1578
1579 float InitiateSuddenDeath()
1580 {
1581         // Check first whether normal overtimes could be added before initiating suddendeath mode
1582         // - for this timelimit_overtime needs to be >0 of course
1583         // - also check the winning condition calculated in the previous frame and only add normal overtime
1584         //   again, if at the point at which timelimit would be extended again, still no winner was found
1585         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1586         {
1587                 return 1; // need to call InitiateOvertime later
1588         }
1589         else
1590         {
1591                 if(!checkrules_suddendeathend)
1592                 {
1593                         if(autocvar_g_campaign)
1594                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1595                         else
1596                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1597                         if(g_race && !g_race_qualifying)
1598                                 race_StartCompleting();
1599                 }
1600                 return 0;
1601         }
1602 }
1603
1604 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1605 {
1606         ++checkrules_overtimesadded;
1607         //add one more overtime by simply extending the timelimit
1608         float tl;
1609         tl = autocvar_timelimit;
1610         tl += autocvar_timelimit_overtime;
1611         cvar_set("timelimit", ftos(tl));
1612
1613         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1614 }
1615
1616 float GetWinningCode(float fraglimitreached, float equality)
1617 {
1618         if(autocvar_g_campaign == 1)
1619                 if(fraglimitreached)
1620                         return WINNING_YES;
1621                 else
1622                         return WINNING_NO;
1623
1624         else
1625                 if(equality)
1626                         if(fraglimitreached)
1627                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1628                         else
1629                                 return WINNING_NEVER;
1630                 else
1631                         if(fraglimitreached)
1632                                 return WINNING_YES;
1633                         else
1634                                 return WINNING_NO;
1635 }
1636
1637 // set the .winning flag for exactly those players with a given field value
1638 void SetWinners(.float field, float value)
1639 {
1640         entity head;
1641         FOR_EACH_PLAYER(head)
1642                 head.winning = (head.(field) == value);
1643 }
1644
1645 // set the .winning flag for those players with a given field value
1646 void AddWinners(.float field, float value)
1647 {
1648         entity head;
1649         FOR_EACH_PLAYER(head)
1650                 if (head.(field) == value)
1651                         head.winning = 1;
1652 }
1653
1654 // clear the .winning flags
1655 void ClearWinners(void)
1656 {
1657         entity head;
1658         FOR_EACH_PLAYER(head)
1659                 head.winning = 0;
1660 }
1661
1662 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1663 // they win. Otherwise the defending team wins once the timelimit passes.
1664 void assault_new_round();
1665 float WinningCondition_Assault()
1666 {SELFPARAM();
1667         float status;
1668
1669         WinningConditionHelper(); // set worldstatus
1670
1671         status = WINNING_NO;
1672         // as the timelimit has not yet passed just assume the defending team will win
1673         if(assault_attacker_team == NUM_TEAM_1)
1674         {
1675                 SetWinners(team, NUM_TEAM_2);
1676         }
1677         else
1678         {
1679                 SetWinners(team, NUM_TEAM_1);
1680         }
1681
1682         entity ent;
1683         ent = find(world, classname, "target_assault_roundend");
1684         if(ent)
1685         {
1686                 if(ent.winning) // round end has been triggered by attacking team
1687                 {
1688                         bprint("ASSAULT: round completed...\n");
1689                         SetWinners(team, assault_attacker_team);
1690
1691                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1692
1693                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1694                         {
1695                                 status = WINNING_YES;
1696                         }
1697                         else
1698                         {
1699                                 WITH(entity, self, ent, assault_new_round());
1700                         }
1701                 }
1702         }
1703
1704         return status;
1705 }
1706
1707 // LMS winning condition: game terminates if and only if there's at most one
1708 // one player who's living lives. Top two scores being equal cancels the time
1709 // limit.
1710 float WinningCondition_LMS()
1711 {
1712         entity head, head2;
1713         float have_player;
1714         float have_players;
1715         float l;
1716
1717         have_player = false;
1718         have_players = false;
1719         l = LMS_NewPlayerLives();
1720
1721         head = find(world, classname, "player");
1722         if(head)
1723                 have_player = true;
1724         head2 = find(head, classname, "player");
1725         if(head2)
1726                 have_players = true;
1727
1728         if(have_player)
1729         {
1730                 // we have at least one player
1731                 if(have_players)
1732                 {
1733                         // two or more active players - continue with the game
1734                 }
1735                 else
1736                 {
1737                         // exactly one player?
1738
1739                         ClearWinners();
1740                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1741
1742                         if(l)
1743                         {
1744                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1745                                 return WINNING_NO;
1746                         }
1747                         else
1748                         {
1749                                 // a winner!
1750                                 // and assign him his first place
1751                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1752                                 return WINNING_YES;
1753                         }
1754                 }
1755         }
1756         else
1757         {
1758                 // nobody is playing at all...
1759                 if(l)
1760                 {
1761                         // wait for players...
1762                 }
1763                 else
1764                 {
1765                         // SNAFU (maybe a draw game?)
1766                         ClearWinners();
1767                         LOG_TRACE("No players, ending game.\n");
1768                         return WINNING_YES;
1769                 }
1770         }
1771
1772         // When we get here, we have at least two players who are actually LIVING,
1773         // now check if the top two players have equal score.
1774         WinningConditionHelper();
1775
1776         ClearWinners();
1777         if(WinningConditionHelper_winner)
1778                 WinningConditionHelper_winner.winning = true;
1779         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1780                 return WINNING_NEVER;
1781
1782         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1783         return WINNING_NO;
1784 }
1785
1786 void ShuffleMaplist()
1787 {
1788         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1789 }
1790
1791 float leaderfrags;
1792 float WinningCondition_Scores(float limit, float leadlimit)
1793 {
1794         float limitreached;
1795
1796         // TODO make everything use THIS winning condition (except LMS)
1797         WinningConditionHelper();
1798
1799         if(teamplay)
1800         {
1801                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1802                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1803                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1804                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1805         }
1806
1807         ClearWinners();
1808         if(WinningConditionHelper_winner)
1809                 WinningConditionHelper_winner.winning = 1;
1810         if(WinningConditionHelper_winnerteam >= 0)
1811                 SetWinners(team, WinningConditionHelper_winnerteam);
1812
1813         if(WinningConditionHelper_lowerisbetter)
1814         {
1815                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1816                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1817                 limit = -limit;
1818         }
1819
1820         if(WinningConditionHelper_zeroisworst)
1821                 leadlimit = 0; // not supported in this mode
1822
1823         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1824         // these modes always score in increments of 1, thus this makes sense
1825         {
1826                 if(leaderfrags != WinningConditionHelper_topscore)
1827                 {
1828                         leaderfrags = WinningConditionHelper_topscore;
1829
1830                         if (limit)
1831                         if (leaderfrags == limit - 1)
1832                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1833                         else if (leaderfrags == limit - 2)
1834                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1835                         else if (leaderfrags == limit - 3)
1836                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1837                 }
1838         }
1839
1840         limitreached = false;
1841         if(limit)
1842                 if(WinningConditionHelper_topscore >= limit)
1843                         limitreached = true;
1844         if(leadlimit)
1845         {
1846                 float leadlimitreached;
1847                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1848                 if(autocvar_leadlimit_and_fraglimit)
1849                         limitreached = (limitreached && leadlimitreached);
1850                 else
1851                         limitreached = (limitreached || leadlimitreached);
1852         }
1853
1854         if(limit)
1855                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1856
1857         return GetWinningCode(
1858                 WinningConditionHelper_topscore && limitreached,
1859                 WinningConditionHelper_equality
1860         );
1861 }
1862
1863 float WinningCondition_Race(float fraglimit)
1864 {
1865         float wc;
1866         entity p;
1867         float n, c;
1868
1869         n = 0;
1870         c = 0;
1871         FOR_EACH_PLAYER(p)
1872         {
1873                 ++n;
1874                 if(p.race_completed)
1875                         ++c;
1876         }
1877         if(n && (n == c))
1878                 return WINNING_YES;
1879         wc = WinningCondition_Scores(fraglimit, 0);
1880
1881         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1882         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1883         // do NOT support equality when the laps are all raced!
1884                 return WINNING_STARTSUDDENDEATHOVERTIME;
1885         else
1886                 return WINNING_NEVER;
1887 }
1888
1889 float WinningCondition_QualifyingThenRace(float limit)
1890 {
1891         float wc;
1892         wc = WinningCondition_Scores(limit, 0);
1893
1894         // NEVER initiate overtime
1895         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1896         {
1897                 return WINNING_YES;
1898         }
1899
1900         return wc;
1901 }
1902
1903 float WinningCondition_RanOutOfSpawns()
1904 {
1905         entity head;
1906
1907         if(have_team_spawns <= 0)
1908                 return WINNING_NO;
1909
1910         if(!autocvar_g_spawn_useallspawns)
1911                 return WINNING_NO;
1912
1913         if(!some_spawn_has_been_used)
1914                 return WINNING_NO;
1915
1916         team1_score = team2_score = team3_score = team4_score = 0;
1917
1918         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1919         {
1920                 if(head.team == NUM_TEAM_1)
1921                         team1_score = 1;
1922                 else if(head.team == NUM_TEAM_2)
1923                         team2_score = 1;
1924                 else if(head.team == NUM_TEAM_3)
1925                         team3_score = 1;
1926                 else if(head.team == NUM_TEAM_4)
1927                         team4_score = 1;
1928         }
1929
1930         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1931         {
1932                 if(head.team == NUM_TEAM_1)
1933                         team1_score = 1;
1934                 else if(head.team == NUM_TEAM_2)
1935                         team2_score = 1;
1936                 else if(head.team == NUM_TEAM_3)
1937                         team3_score = 1;
1938                 else if(head.team == NUM_TEAM_4)
1939                         team4_score = 1;
1940         }
1941
1942         ClearWinners();
1943         if(team1_score + team2_score + team3_score + team4_score == 0)
1944         {
1945                 checkrules_equality = true;
1946                 return WINNING_YES;
1947         }
1948         else if(team1_score + team2_score + team3_score + team4_score == 1)
1949         {
1950                 float t, i;
1951                 if(team1_score)
1952                         t = NUM_TEAM_1;
1953                 else if(team2_score)
1954                         t = NUM_TEAM_2;
1955                 else if(team3_score)
1956                         t = NUM_TEAM_3;
1957                 else // if(team4_score)
1958                         t = NUM_TEAM_4;
1959                 CheckAllowedTeams(world);
1960                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1961                 {
1962                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1963                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1964                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1965                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1966                 }
1967
1968                 AddWinners(team, t);
1969                 return WINNING_YES;
1970         }
1971         else
1972                 return WINNING_NO;
1973 }
1974
1975 /*
1976 ============
1977 CheckRules_World
1978
1979 Exit deathmatch games upon conditions
1980 ============
1981 */
1982 void CheckRules_World()
1983 {
1984         float timelimit;
1985         float fraglimit;
1986         float leadlimit;
1987
1988         VoteThink();
1989         MapVote_Think();
1990
1991         SetDefaultAlpha();
1992
1993         if (gameover)   // someone else quit the game already
1994         {
1995                 if(player_count == 0) // Nobody there? Then let's go to the next map
1996                         MapVote_Start();
1997                         // this will actually check the player count in the next frame
1998                         // again, but this shouldn't hurt
1999                 return;
2000         }
2001
2002         timelimit = autocvar_timelimit * 60;
2003         fraglimit = autocvar_fraglimit;
2004         leadlimit = autocvar_leadlimit;
2005
2006         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2007         {
2008                 if(timelimit > 0)
2009                         timelimit = 0; // timelimit is not made for warmup
2010                 if(fraglimit > 0)
2011                         fraglimit = 0; // no fraglimit for now
2012                 leadlimit = 0; // no leadlimit for now
2013         }
2014
2015         if(timelimit > 0)
2016         {
2017                 timelimit += game_starttime;
2018         }
2019         else if (timelimit < 0)
2020         {
2021                 // endmatch
2022                 NextLevel();
2023                 return;
2024         }
2025
2026         float wantovertime;
2027         wantovertime = 0;
2028
2029         if(timelimit > game_starttime)
2030                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2031         else
2032                 game_completion_ratio = 0;
2033
2034         if(checkrules_suddendeathend)
2035         {
2036                 if(!checkrules_suddendeathwarning)
2037                 {
2038                         checkrules_suddendeathwarning = true;
2039                         if(g_race && !g_race_qualifying)
2040                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2041                         else
2042                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2043                 }
2044         }
2045         else
2046         {
2047                 if (timelimit && time >= timelimit)
2048                 {
2049                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2050                         {
2051                                 float totalplayers;
2052                                 float playerswithlaps;
2053                                 float readyplayers;
2054                                 entity head;
2055                                 totalplayers = playerswithlaps = readyplayers = 0;
2056                                 FOR_EACH_PLAYER(head)
2057                                 {
2058                                         ++totalplayers;
2059                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2060                                                 ++playerswithlaps;
2061                                         if(head.ready)
2062                                                 ++readyplayers;
2063                                 }
2064
2065                                 // at least 2 of the players have completed a lap: start the RACE
2066                                 // otherwise, the players should end the qualifying on their own
2067                                 if(readyplayers || playerswithlaps >= 2)
2068                                 {
2069                                         checkrules_suddendeathend = 0;
2070                                         ReadyRestart(); // go to race
2071                                         return;
2072                                 }
2073                                 else
2074                                         wantovertime |= InitiateSuddenDeath();
2075                         }
2076                         else
2077                                 wantovertime |= InitiateSuddenDeath();
2078                 }
2079         }
2080
2081         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2082         {
2083                 NextLevel();
2084                 return;
2085         }
2086
2087         float checkrules_status;
2088         checkrules_status = WinningCondition_RanOutOfSpawns();
2089         if(checkrules_status == WINNING_YES)
2090         {
2091                 bprint("Hey! Someone ran out of spawns!\n");
2092         }
2093         else if(g_race && !g_race_qualifying && timelimit >= 0)
2094         {
2095                 checkrules_status = WinningCondition_Race(fraglimit);
2096                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2097         }
2098         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2099         {
2100                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2101                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2102         }
2103         else if(g_assault)
2104         {
2105                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2106         }
2107         else if(g_lms)
2108         {
2109                 checkrules_status = WinningCondition_LMS();
2110         }
2111         else
2112         {
2113                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2114                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2115         }
2116
2117         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2118         {
2119                 checkrules_status = WINNING_NEVER;
2120                 checkrules_overtimesadded = -1;
2121                 wantovertime |= InitiateSuddenDeath();
2122         }
2123
2124         if(checkrules_status == WINNING_NEVER)
2125                 // equality cases! Nobody wins if the overtime ends in a draw.
2126                 ClearWinners();
2127
2128         if(wantovertime)
2129         {
2130                 if(checkrules_status == WINNING_NEVER)
2131                         InitiateOvertime();
2132                 else
2133                         checkrules_status = WINNING_YES;
2134         }
2135
2136         if(checkrules_suddendeathend)
2137                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2138                         checkrules_status = WINNING_YES;
2139
2140         if(checkrules_status == WINNING_YES)
2141         {
2142                 //print("WINNING\n");
2143                 NextLevel();
2144         }
2145 }
2146
2147 string GotoMap(string m)
2148 {
2149         m = GameTypeVote_MapInfo_FixName(m);
2150         if (!m)
2151                 return "The map you suggested is not available on this server.";
2152         if (!autocvar_sv_vote_gametype)
2153         if(!MapInfo_CheckMap(m))
2154                 return "The map you suggested does not support the current game mode.";
2155         cvar_set("nextmap", m);
2156         cvar_set("timelimit", "-1");
2157         if(mapvote_initialized || alreadychangedlevel)
2158         {
2159                 if(DoNextMapOverride(0))
2160                         return "Map switch initiated.";
2161                 else
2162                         return "Hm... no. For some reason I like THIS map more.";
2163         }
2164         else
2165                 return "Map switch will happen after scoreboard.";
2166 }
2167
2168
2169 void EndFrame()
2170 {SELFPARAM();
2171         anticheat_endframe();
2172
2173         float altime;
2174         entity e_;
2175         FOR_EACH_REALCLIENT(e_)
2176         {
2177                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2178                 if(e.typehitsound)
2179                         e_.typehit_time = time;
2180                 else if(e.damage_dealt)
2181                 {
2182                         e_.hit_time = time;
2183                         e_.damage_dealt_total += ceil(e.damage_dealt);
2184                 }
2185         }
2186         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2187         // add 1 frametime because after this, engine SV_Physics
2188         // increases time by a frametime and then networks the frame
2189         // add another frametime because client shows everything with
2190         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2191         // needed!
2192         FOR_EACH_CLIENT(e_)
2193         {
2194                 e_.typehitsound = false;
2195                 e_.damage_dealt = 0;
2196                 setself(e_);
2197                 antilag_record(e_, altime);
2198         }
2199         FOR_EACH_MONSTER(e_)
2200         {
2201                 setself(e_);
2202                 antilag_record(e_, altime);
2203         }
2204 }
2205
2206
2207 /*
2208  * RedirectionThink:
2209  * returns true if redirecting
2210  */
2211 float redirection_timeout;
2212 float redirection_nextthink;
2213 float RedirectionThink()
2214 {SELFPARAM();
2215         float clients_found;
2216
2217         if(redirection_target == "")
2218                 return false;
2219
2220         if(!redirection_timeout)
2221         {
2222                 cvar_set("sv_public", "-2");
2223                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2224                 if(redirection_target == "self")
2225                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2226                 else
2227                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2228         }
2229
2230         if(time < redirection_nextthink)
2231                 return true;
2232
2233         redirection_nextthink = time + 1;
2234
2235         clients_found = 0;
2236         entity e;
2237         FOR_EACH_REALCLIENT(e)
2238         {
2239                 setself(e);
2240                 // TODO add timer
2241                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2242                 if(redirection_target == "self")
2243                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2244                 else
2245                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2246                 ++clients_found;
2247         }
2248
2249         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2250
2251         if(time > redirection_timeout || clients_found == 0)
2252                 localcmd("\nwait; wait; wait; quit\n");
2253
2254         return true;
2255 }
2256
2257 void TargetMusic_RestoreGame();
2258 void RestoreGame()
2259 {
2260         // Loaded from a save game
2261         // some things then break, so let's work around them...
2262
2263         // Progs DB (capture records)
2264         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2265
2266         // Mapinfo
2267         MapInfo_Shutdown();
2268         MapInfo_Enumerate();
2269         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2270         WeaponStats_Init();
2271
2272         TargetMusic_RestoreGame();
2273 }
2274
2275 void Shutdown()
2276 {
2277         gameover = 2;
2278
2279         if(world_initialized > 0)
2280         {
2281                 world_initialized = 0;
2282                 LOG_INFO("Saving persistent data...\n");
2283                 Ban_SaveBans();
2284
2285                 // playerstats with unfinished match
2286                 PlayerStats_GameReport(false);
2287
2288                 if(!cheatcount_total)
2289                 {
2290                         if(autocvar_sv_db_saveasdump)
2291                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2292                         else
2293                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2294                 }
2295                 if(autocvar_developer)
2296                 {
2297                         if(autocvar_sv_db_saveasdump)
2298                                 db_dump(TemporaryDB, "server-temp.db");
2299                         else
2300                                 db_save(TemporaryDB, "server-temp.db");
2301                 }
2302                 CheatShutdown(); // must be after cheatcount check
2303                 db_close(ServerProgsDB);
2304                 db_close(TemporaryDB);
2305                 LOG_INFO("done!\n");
2306                 // tell the bot system the game is ending now
2307                 bot_endgame();
2308
2309                 WeaponStats_Shutdown();
2310                 MapInfo_Shutdown();
2311         }
2312         else if(world_initialized == 0)
2313         {
2314                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2315         }
2316 }