Merge branch 'master' into Mario/vehicles
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2 #include "_all.qh"
3
4 #include "anticheat.qh"
5 #include "antilag.qh"
6 #include "bot/bot.qh"
7 #include "campaign.qh"
8 #include "cheats.qh"
9 #include "cl_client.qh"
10 #include "command/common.qh"
11 #include "command/getreplies.qh"
12 #include "command/sv_cmd.qh"
13 #include "command/vote.qh"
14 #include "g_hook.qh"
15 #include "ipban.qh"
16 #include "mapvoting.qh"
17 #include "mutators/mutators_include.qh"
18 #include "race.qh"
19 #include "scores.qh"
20 #include "teamplay.qh"
21 #include "waypointsprites.qh"
22 #include "weapons/weaponstats.qh"
23 #include "../common/buffs.qh"
24 #include "../common/constants.qh"
25 #include "../common/deathtypes.qh"
26 #include "../common/effects.qh"
27 #include "../common/mapinfo.qh"
28 #include "../common/monsters/all.qh"
29 #include "../common/monsters/sv_monsters.qh"
30 #include "../common/vehicles/vehicles.qh"
31 #include "../common/notifications.qh"
32 #include "../common/playerstats.qh"
33 #include "../common/stats.qh"
34 #include "../common/teams.qh"
35 #include "../common/util.qh"
36 #include "../common/items/all.qh"
37 #include "../common/weapons/all.qh"
38
39 const float LATENCY_THINKRATE = 10;
40 .float latency_sum;
41 .float latency_cnt;
42 .float latency_time;
43 entity pingplreport;
44 void PingPLReport_Think()
45 {
46         float delta;
47         entity e;
48
49         delta = 3 / maxclients;
50         if(delta < sys_frametime)
51                 delta = 0;
52         self.nextthink = time + delta;
53
54         e = edict_num(self.cnt + 1);
55         if(IS_REAL_CLIENT(e))
56         {
57                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
58                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
59                 WriteByte(MSG_BROADCAST, self.cnt);
60                 WriteShort(MSG_BROADCAST, max(1, e.ping));
61                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
62                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
63
64                 // record latency times for clients throughout the match so we can report it to playerstats
65                 if(time > (e.latency_time + LATENCY_THINKRATE))
66                 {
67                         e.latency_sum += e.ping;
68                         e.latency_cnt += 1;
69                         e.latency_time = time;
70                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
71                 }
72         }
73         else
74         {
75                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
76                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
77                 WriteByte(MSG_BROADCAST, self.cnt);
78                 WriteShort(MSG_BROADCAST, 0);
79                 WriteByte(MSG_BROADCAST, 0);
80                 WriteByte(MSG_BROADCAST, 0);
81         }
82         self.cnt = (self.cnt + 1) % maxclients;
83 }
84 void PingPLReport_Spawn()
85 {
86         pingplreport = spawn();
87         pingplreport.classname = "pingplreport";
88         pingplreport.think = PingPLReport_Think;
89         pingplreport.nextthink = time;
90 }
91
92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
93 string redirection_target;
94 float world_initialized;
95
96 string GetGametype();
97 void ShuffleMaplist();
98
99 void SetDefaultAlpha()
100 {
101         if(autocvar_g_running_guns)
102         {
103                 default_player_alpha = -1;
104                 default_weapon_alpha = +1;
105         }
106         else if(g_cloaked)
107         {
108                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
109                 default_weapon_alpha = default_player_alpha;
110         }
111         else
112         {
113                 default_player_alpha = autocvar_g_player_alpha;
114                 if(default_player_alpha == 0)
115                         default_player_alpha = 1;
116                 default_weapon_alpha = default_player_alpha;
117         }
118 }
119
120 void GotoFirstMap()
121 {
122         float n;
123         if(autocvar__sv_init)
124         {
125                 // cvar_set("_sv_init", "0");
126                 // we do NOT set this to 0 any more, so someone "accidentally" changing
127                 // to this "init" map on a dedicated server will cause no permanent
128                 // harm
129                 if(autocvar_g_maplist_shuffle)
130                         ShuffleMaplist();
131                 n = tokenizebyseparator(autocvar_g_maplist, " ");
132                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
133
134                 MapInfo_Enumerate();
135                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
136
137                 if(!DoNextMapOverride(1))
138                         GotoNextMap(1);
139
140                 return;
141         }
142
143         if(time < 5)
144         {
145                 self.nextthink = time;
146         }
147         else
148         {
149                 self.nextthink = time + 1;
150                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
151         }
152 }
153
154 void cvar_changes_init()
155 {
156         float h;
157         string k, v, d;
158         float n, i, adding, pureadding;
159
160         if(cvar_changes)
161                 strunzone(cvar_changes);
162         cvar_changes = string_null;
163         if(cvar_purechanges)
164                 strunzone(cvar_purechanges);
165         cvar_purechanges = string_null;
166         cvar_purechanges_count = 0;
167
168         h = buf_create();
169         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
170         n = buf_getsize(h);
171
172         adding = true;
173         pureadding = true;
174
175         for(i = 0; i < n; ++i)
176         {
177                 k = bufstr_get(h, i);
178
179 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
180 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
181 #define BADCVAR(p) if(k == p) continue
182
183                 // general excludes and namespaces for server admin used cvars
184                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
185
186                 // internal
187                 BADPREFIX("csqc_");
188                 BADPREFIX("cvar_check_");
189                 BADCVAR("gamecfg");
190                 BADCVAR("g_configversion");
191                 BADCVAR("g_maplist_index");
192                 BADCVAR("halflifebsp");
193                 BADCVAR("sv_mapformat_is_quake2");
194                 BADCVAR("sv_mapformat_is_quake3");
195                 BADPREFIX("sv_world");
196
197                 // client
198                 BADPREFIX("chase_");
199                 BADPREFIX("cl_");
200                 BADPREFIX("con_");
201                 BADPREFIX("scoreboard_");
202                 BADPREFIX("g_campaign");
203                 BADPREFIX("g_waypointsprite_");
204                 BADPREFIX("gl_");
205                 BADPREFIX("joy");
206                 BADPREFIX("hud_");
207                 BADPREFIX("m_");
208                 BADPREFIX("menu_");
209                 BADPREFIX("net_slist_");
210                 BADPREFIX("r_");
211                 BADPREFIX("sbar_");
212                 BADPREFIX("scr_");
213                 BADPREFIX("snd_");
214                 BADPREFIX("show");
215                 BADPREFIX("sensitivity");
216                 BADPREFIX("userbind");
217                 BADPREFIX("v_");
218                 BADPREFIX("vid_");
219                 BADPREFIX("crosshair");
220                 BADCVAR("mod_q3bsp_lightmapmergepower");
221                 BADCVAR("mod_q3bsp_nolightmaps");
222                 BADCVAR("fov");
223                 BADCVAR("mastervolume");
224                 BADCVAR("volume");
225                 BADCVAR("bgmvolume");
226
227                 // private
228                 BADCVAR("developer");
229                 BADCVAR("log_dest_udp");
230                 BADCVAR("net_address");
231                 BADCVAR("net_address_ipv6");
232                 BADCVAR("port");
233                 BADCVAR("savedgamecfg");
234                 BADCVAR("serverconfig");
235                 BADCVAR("sv_autoscreenshot");
236                 BADCVAR("sv_heartbeatperiod");
237                 BADCVAR("sv_vote_master_password");
238                 BADCVAR("sys_colortranslation");
239                 BADCVAR("sys_specialcharactertranslation");
240                 BADCVAR("timeformat");
241                 BADCVAR("timestamps");
242                 BADPREFIX("developer_");
243                 BADPREFIX("g_ban_");
244                 BADPREFIX("g_banned_list");
245                 BADPREFIX("g_chat_flood_");
246                 BADPREFIX("g_ghost_items");
247                 BADPREFIX("g_playerstats_");
248                 BADPREFIX("g_respawn_ghosts");
249                 BADPREFIX("g_voice_flood_");
250                 BADPREFIX("log_file");
251                 BADPREFIX("rcon_");
252                 BADPREFIX("sv_allowdownloads");
253                 BADPREFIX("sv_autodemo");
254                 BADPREFIX("sv_curl_");
255                 BADPREFIX("sv_eventlog");
256                 BADPREFIX("sv_logscores_");
257                 BADPREFIX("sv_master");
258                 BADPREFIX("sv_weaponstats_");
259                 BADPREFIX("sv_waypointsprite_");
260                 BADCVAR("rescan_pending");
261
262                 // these can contain player IDs, so better hide
263                 BADPREFIX("g_forced_team_");
264
265                 // mapinfo
266                 BADCVAR("fraglimit");
267                 BADCVAR("g_assault");
268                 BADCVAR("g_ca");
269                 BADCVAR("g_ca_teams");
270                 BADCVAR("g_ctf");
271                 BADCVAR("g_cts");
272                 BADCVAR("g_dm");
273                 BADCVAR("g_domination");
274                 BADCVAR("g_domination_default_teams");
275                 BADCVAR("g_freezetag");
276                 BADCVAR("g_freezetag_teams");
277                 BADCVAR("g_invasion_teams");
278                 BADCVAR("g_keepaway");
279                 BADCVAR("g_keyhunt");
280                 BADCVAR("g_keyhunt_teams");
281                 BADCVAR("g_lms");
282                 BADCVAR("g_nexball");
283                 BADCVAR("g_onslaught");
284                 BADCVAR("g_race");
285                 BADCVAR("g_race_qualifying_timelimit");
286                 BADCVAR("g_tdm");
287                 BADCVAR("g_tdm_teams");
288                 BADCVAR("leadlimit");
289                 BADCVAR("nextmap");
290                 BADCVAR("teamplay");
291                 BADCVAR("timelimit");
292
293                 // long
294                 BADCVAR("hostname");
295                 BADCVAR("g_maplist");
296                 BADCVAR("g_maplist_mostrecent");
297                 BADCVAR("sv_motd");
298
299                 v = cvar_string(k);
300                 d = cvar_defstring(k);
301                 if(v == d)
302                         continue;
303
304                 if(adding)
305                 {
306                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
307                         if(strlen(cvar_changes) > 16384)
308                         {
309                                 cvar_changes = "// too many settings have been changed to show them here\n";
310                                 adding = 0;
311                         }
312                 }
313
314                 // now check if the changes are actually gameplay relevant
315
316                 // does nothing visible
317                 BADCVAR("captureleadlimit_override");
318                 BADCVAR("g_balance_kill_delay");
319                 BADCVAR("g_ca_point_limit");
320                 BADCVAR("g_ca_point_leadlimit");
321                 BADCVAR("g_ctf_captimerecord_always");
322                 BADCVAR("g_ctf_flag_glowtrails");
323                 BADCVAR("g_ctf_flag_pickup_verbosename");
324                 BADCVAR("g_domination_point_leadlimit");
325                 BADCVAR("g_forced_respawn");
326                 BADCVAR("g_freezetag_point_limit");
327                 BADCVAR("g_freezetag_point_leadlimit");
328                 BADCVAR("g_keyhunt_point_leadlimit");
329                 BADPREFIX("g_mod_");
330                 BADCVAR("g_invasion_point_limit");
331                 BADCVAR("g_nexball_goalleadlimit");
332                 BADCVAR("g_tdm_point_limit");
333                 BADCVAR("g_tdm_point_leadlimit");
334                 BADCVAR("leadlimit_and_fraglimit");
335                 BADCVAR("leadlimit_override");
336                 BADCVAR("pausable");
337                 BADCVAR("sv_allow_fullbright");
338                 BADCVAR("sv_checkforpacketsduringsleep");
339                 BADCVAR("sv_fraginfo");
340                 BADCVAR("sv_timeout");
341                 BADPREFIX("sv_timeout_");
342                 BADPREFIX("crypto_");
343                 BADPREFIX("g_chat_");
344                 BADPREFIX("g_ctf_captimerecord_");
345                 BADPREFIX("g_maplist_votable_");
346                 BADPREFIX("net_");
347                 BADPREFIX("prvm_");
348                 BADPREFIX("skill_");
349                 BADPREFIX("sv_cullentities_");
350                 BADPREFIX("sv_fraginfo_");
351                 BADPREFIX("sv_maxidle_");
352                 BADPREFIX("sv_vote_");
353                 BADPREFIX("timelimit_");
354                 BADCVAR("gameversion");
355                 BADPREFIX("gameversion_");
356                 BADCVAR("sv_namechangetimer");
357
358                 // allowed changes to server admins (please sync this to server.cfg)
359                 // vi commands:
360                 //   :/"impure"/,$d
361                 //   :g!,^\/\/[^ /],d
362                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
363                 //   :%!sort
364                 // yes, this does contain some redundant stuff, don't really care
365                 BADCVAR("bot_config_file");
366                 BADCVAR("bot_number");
367                 BADCVAR("bot_prefix");
368                 BADCVAR("bot_suffix");
369                 BADCVAR("capturelimit_override");
370                 BADCVAR("fraglimit_override");
371                 BADCVAR("gametype");
372                 BADCVAR("g_antilag");
373                 BADCVAR("g_balance_teams");
374                 BADCVAR("g_balance_teams_prevent_imbalance");
375                 BADCVAR("g_balance_teams_scorefactor");
376                 BADCVAR("g_ban_sync_trusted_servers");
377                 BADCVAR("g_ban_sync_uri");
378                 BADCVAR("g_ca_teams_override");
379                 BADCVAR("g_ctf_ignore_frags");
380                 BADCVAR("g_domination_point_limit");
381                 BADCVAR("g_domination_teams_override");
382                 BADCVAR("g_freezetag_teams_override");
383                 BADCVAR("g_friendlyfire");
384                 BADCVAR("g_fullbrightitems");
385                 BADCVAR("g_fullbrightplayers");
386                 BADCVAR("g_keyhunt_point_limit");
387                 BADCVAR("g_keyhunt_teams_override");
388                 BADCVAR("g_lms_lives_override");
389                 BADCVAR("g_maplist");
390                 BADCVAR("g_maplist_check_waypoints");
391                 BADCVAR("g_maplist_mostrecent_count");
392                 BADCVAR("g_maplist_shuffle");
393                 BADCVAR("g_maplist_votable");
394                 BADCVAR("g_maplist_votable_abstain");
395                 BADCVAR("g_maplist_votable_nodetail");
396                 BADCVAR("g_maplist_votable_suggestions");
397                 BADCVAR("g_maxplayers");
398                 BADCVAR("g_mirrordamage");
399                 BADCVAR("g_nexball_goallimit");
400                 BADCVAR("g_powerups");
401                 BADCVAR("g_start_delay");
402                 BADCVAR("g_tdm_teams_override");
403                 BADCVAR("g_warmup");
404                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
405                 BADCVAR("hostname");
406                 BADCVAR("log_file");
407                 BADCVAR("maxplayers");
408                 BADCVAR("minplayers");
409                 BADCVAR("net_address");
410                 BADCVAR("port");
411                 BADCVAR("rcon_password");
412                 BADCVAR("rcon_restricted_commands");
413                 BADCVAR("rcon_restricted_password");
414                 BADCVAR("skill");
415                 BADCVAR("sv_adminnick");
416                 BADCVAR("sv_autoscreenshot");
417                 BADCVAR("sv_autotaunt");
418                 BADCVAR("sv_curl_defaulturl");
419                 BADCVAR("sv_defaultcharacter");
420                 BADCVAR("sv_defaultplayercolors");
421                 BADCVAR("sv_defaultplayermodel");
422                 BADCVAR("sv_defaultplayerskin");
423                 BADCVAR("sv_maxidle");
424                 BADCVAR("sv_maxrate");
425                 BADCVAR("sv_motd");
426                 BADCVAR("sv_public");
427                 BADCVAR("sv_ready_restart");
428                 BADCVAR("sv_status_privacy");
429                 BADCVAR("sv_taunt");
430                 BADCVAR("sv_vote_call");
431                 BADCVAR("sv_vote_commands");
432                 BADCVAR("sv_vote_majority_factor");
433                 BADCVAR("sv_vote_master");
434                 BADCVAR("sv_vote_master_commands");
435                 BADCVAR("sv_vote_master_password");
436                 BADCVAR("sv_vote_simple_majority_factor");
437                 BADCVAR("teamplay_mode");
438                 BADCVAR("timelimit_override");
439                 BADCVAR("g_spawnshieldtime");
440                 BADPREFIX("g_warmup_");
441                 BADPREFIX("sv_ready_restart_");
442
443                 // mutators that announce themselves properly to the server browser
444                 BADCVAR("g_instagib");
445                 BADCVAR("g_new_toys");
446                 BADCVAR("g_nix");
447                 BADCVAR("g_grappling_hook");
448                 BADCVAR("g_jetpack");
449
450 #undef BADPREFIX
451 #undef BADCVAR
452
453                 if(pureadding)
454                 {
455                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
456                         if(strlen(cvar_purechanges) > 16384)
457                         {
458                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
459                                 pureadding = 0;
460                         }
461                 }
462                 ++cvar_purechanges_count;
463                 // WARNING: this variable is used for the server list
464                 // NEVER dare to skip this code!
465                 // Hacks to intentionally appearing as "pure server" even though you DO have
466                 // modified settings may be punished by removal from the server list.
467                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
468                 // though.
469         }
470         buf_del(h);
471         if(cvar_changes == "")
472                 cvar_changes = "// this server runs at default server settings\n";
473         else
474                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
475         cvar_changes = strzone(cvar_changes);
476         if(cvar_purechanges == "")
477                 cvar_purechanges = "// this server runs at default gameplay settings\n";
478         else
479                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
480         cvar_purechanges = strzone(cvar_purechanges);
481 }
482
483 void detect_maptype()
484 {
485 #if 0
486         vector o, v;
487         float i;
488
489         for (;;)
490         {
491                 o = world.mins;
492                 o.x += random() * (world.maxs.x - world.mins.x);
493                 o.y += random() * (world.maxs.y - world.mins.y);
494                 o.z += random() * (world.maxs.z - world.mins.z);
495
496                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
497                 if(trace_fraction == 1)
498                         continue;
499
500                 v = trace_endpos;
501
502                 for(i = 0; i < 64; i += 4)
503                 {
504                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
505         if(trace_fraction == 1)
506                 continue;
507                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
508                 }
509
510                 break;
511         }
512 #endif
513 }
514
515 entity randomseed;
516 float RandomSeed_Send(entity to, int sf)
517 {
518         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
519         WriteShort(MSG_ENTITY, self.cnt);
520         return true;
521 }
522 void RandomSeed_Think()
523 {
524         self.cnt = bound(0, floor(random() * 65536), 65535);
525         self.nextthink = time + 5;
526
527         self.SendFlags |= 1;
528 }
529 void RandomSeed_Spawn()
530 {
531         randomseed = spawn();
532         randomseed.think = RandomSeed_Think;
533         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
534
535         entity oldself;
536         oldself = self;
537         self = randomseed;
538         self.think(); // sets random seed and nextthink
539         self = oldself;
540 }
541
542 void spawnfunc___init_dedicated_server(void)
543 {
544         // handler for _init/_init map (only for dedicated server initialization)
545
546         world_initialized = -1; // don't complain
547         cvar = cvar_normal;
548         cvar_string = cvar_string_normal;
549         cvar_set = cvar_set_normal;
550
551         remove = remove_unsafely;
552
553         entity e;
554         e = spawn();
555         e.think = GotoFirstMap;
556         e.nextthink = time; // this is usually 1 at this point
557
558         e = spawn();
559         e.classname = "info_player_deathmatch"; // safeguard against player joining
560
561         self.classname = "worldspawn"; // safeguard against various stuff ;)
562
563         // needs to be done so early because of the constants they create
564         static_init();
565         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
566         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
567         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
568         CALL_ACCUMULATED_FUNCTION(RegisterVehicles);
569
570         MapInfo_Enumerate();
571         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
572 }
573
574 void Map_MarkAsRecent(string m);
575 float world_already_spawned;
576 void Nagger_Init();
577 void Item_ItemsTime_Init();
578 void ClientInit_Spawn();
579 void WeaponStats_Init();
580 void WeaponStats_Shutdown();
581 void Physics_AddStats();
582 void spawnfunc_worldspawn (void)
583 {
584         float fd, l, j, n;
585         string s;
586
587         cvar = cvar_normal;
588         cvar_string = cvar_string_normal;
589         cvar_set = cvar_set_normal;
590
591         if(world_already_spawned)
592                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
593         world_already_spawned = true;
594
595         remove = remove_safely; // during spawning, watch what you remove!
596
597         cvar_changes_init(); // do this very early now so it REALLY matches the server config
598
599         compressShortVector_init();
600
601         entity head;
602         head = nextent(world);
603         maxclients = 0;
604         while(head)
605         {
606                 ++maxclients;
607                 head = nextent(head);
608         }
609
610         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
611
612         // needs to be done so early because of the constants they create
613         static_init();
614         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
615         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
616         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
617         CALL_ACCUMULATED_FUNCTION(RegisterVehicles);
618
619         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
620
621         TemporaryDB = db_create();
622
623         // 0 normal
624         lightstyle(0, "m");
625
626         // 1 FLICKER (first variety)
627         lightstyle(1, "mmnmmommommnonmmonqnmmo");
628
629         // 2 SLOW STRONG PULSE
630         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
631
632         // 3 CANDLE (first variety)
633         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
634
635         // 4 FAST STROBE
636         lightstyle(4, "mamamamamama");
637
638         // 5 GENTLE PULSE 1
639         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
640
641         // 6 FLICKER (second variety)
642         lightstyle(6, "nmonqnmomnmomomno");
643
644         // 7 CANDLE (second variety)
645         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
646
647         // 8 CANDLE (third variety)
648         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
649
650         // 9 SLOW STROBE (fourth variety)
651         lightstyle(9, "aaaaaaaazzzzzzzz");
652
653         // 10 FLUORESCENT FLICKER
654         lightstyle(10, "mmamammmmammamamaaamammma");
655
656         // 11 SLOW PULSE NOT FADE TO BLACK
657         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
658
659         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
660
661         // 63 testing
662         lightstyle(63, "a");
663
664         if(autocvar_g_campaign)
665                 CampaignPreInit();
666
667         Map_MarkAsRecent(mapname);
668
669         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
670
671         precache_model ("null"); // we need this one before InitGameplayMode
672         InitGameplayMode();
673         readlevelcvars();
674         GrappleHookInit();
675
676         player_count = 0;
677         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
678         if(bot_waypoints_for_items == 1)
679                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
680                         bot_waypoints_for_items = 0;
681
682         precache();
683
684         WaypointSprite_Init();
685
686         GameLogInit(); // prepare everything
687         // NOTE for matchid:
688         // changing the logic generating it is okay. But:
689         // it HAS to stay <= 64 chars
690         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
691         if(autocvar_sv_eventlog)
692         {
693                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
694                 matchid = strzone(s);
695
696                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
697                 s = ":gameinfo:mutators:LIST";
698
699                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
700                 s = ret_string;
701
702                 // simple, probably not good in the mutator system
703                 if(autocvar_g_grappling_hook)
704                         s = strcat(s, ":grappling_hook");
705
706                 // initialiation stuff, not good in the mutator system
707                 if(!autocvar_g_use_ammunition)
708                         s = strcat(s, ":no_use_ammunition");
709
710                 // initialiation stuff, not good in the mutator system
711                 if(autocvar_g_pickup_items == 0)
712                         s = strcat(s, ":no_pickup_items");
713                 if(autocvar_g_pickup_items > 0)
714                         s = strcat(s, ":pickup_items");
715
716                 // initialiation stuff, not good in the mutator system
717                 if(autocvar_g_weaponarena != "0")
718                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
719
720                 // TODO to mutator system
721                 if(autocvar_g_norecoil)
722                         s = strcat(s, ":norecoil");
723
724                 // TODO to mutator system
725                 if(autocvar_g_powerups == 0)
726                         s = strcat(s, ":no_powerups");
727                 if(autocvar_g_powerups > 0)
728                         s = strcat(s, ":powerups");
729
730                 GameLogEcho(s);
731                 GameLogEcho(":gameinfo:end");
732         }
733         else
734                 matchid = strzone(ftos(random()));
735
736         cvar_set("nextmap", "");
737
738         SetDefaultAlpha();
739
740         if(autocvar_g_campaign)
741                 CampaignPostInit();
742
743         Ban_LoadBans();
744
745         MapInfo_Enumerate();
746         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
747
748         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
749         {
750                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
751                 if(fd != -1)
752                 {
753                         while((s = fgets(fd)))
754                         {
755                                 l = tokenize_console(s);
756                                 if(l < 2)
757                                         continue;
758                                 if(argv(0) == "cd")
759                                 {
760                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
761                                         print("  cdtrack ", argv(2), "\n");
762                                 }
763                                 else if(argv(0) == "fog")
764                                 {
765                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
766                                         print("  \"fog\" \"", s, "\"\n");
767                                 }
768                                 else if(argv(0) == "set")
769                                 {
770                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
771                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
772                                 }
773                                 else if(argv(0) != "//")
774                                 {
775                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
776                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
777                                 }
778                         }
779                         fclose(fd);
780                 }
781         }
782
783         WeaponStats_Init();
784
785         WepSet_AddStat();
786         WepSet_AddStat_InMap();
787         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
788         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
789         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
790         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
791         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
792         Nagger_Init();
793
794         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
795         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
796         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
797         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
798         addstat(STAT_FUEL, AS_INT, ammo_fuel);
799         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
800         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
801         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
802         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
803         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
804         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
805         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
806         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
807         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
808         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
809
810         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
811         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
812
813         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
814
815         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
816
817         // items time
818         addstat(STAT_ARMOR_LARGE_TIME, AS_FLOAT, item_armor_large_time);
819         addstat(STAT_HEALTH_MEGA_TIME, AS_FLOAT, item_health_mega_time);
820         addstat(STAT_INVISIBLE_TIME, AS_FLOAT, item_invisible_time);
821         addstat(STAT_SPEED_TIME, AS_FLOAT, item_speed_time);
822         addstat(STAT_EXTRALIFE_TIME, AS_FLOAT, item_extralife_time);
823         addstat(STAT_STRENGTH_TIME, AS_FLOAT, item_strength_time);
824         addstat(STAT_SHIELD_TIME, AS_FLOAT, item_shield_time);
825         addstat(STAT_FUELREGEN_TIME, AS_FLOAT, item_fuelregen_time);
826         addstat(STAT_JETPACK_TIME, AS_FLOAT, item_jetpack_time);
827         addstat(STAT_SUPERWEAPONS_TIME, AS_FLOAT, item_superweapons_time);
828         Item_ItemsTime_Init();
829
830         // freeze attacks
831         addstat(STAT_FROZEN, AS_INT, frozen);
832         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
833
834         // physics
835         Physics_AddStats();
836
837         // new properties
838         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
839         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
840         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
841         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
842         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
843         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
844         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
845         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
846         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
847         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
848         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
849         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
850         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
851         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
852         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
853         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
854         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
855         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
856         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
857
858         // secrets
859         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
860         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
861
862         // monsters
863         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
864         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
865
866         // misc
867         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
868
869         next_pingtime = time + 5;
870
871         detect_maptype();
872
873         // set up information replies for clients and server to use
874         maplist_reply = strzone(getmaplist());
875         lsmaps_reply = strzone(getlsmaps());
876         monsterlist_reply = strzone(getmonsterlist());
877         for(int i = 0; i < 10; ++i)
878         {
879                 s = getrecords(i);
880                 if (s)
881                         records_reply[i] = strzone(s);
882         }
883         ladder_reply = strzone(getladder());
884         rankings_reply = strzone(getrankings());
885
886         // begin other init
887         ClientInit_Spawn();
888         RandomSeed_Spawn();
889         PingPLReport_Spawn();
890
891         CheatInit();
892
893         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
894
895         // fill sv_curl_serverpackages from .serverpackage files
896         if(autocvar_sv_curl_serverpackages_auto)
897         {
898                 s = "";
899                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
900                 for(int i = 0; i < n; ++i)
901                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
902                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
903                                 s = strcat(s, " ", argv(i));
904                 fd = search_begin("*-serverpackage.txt", true, false);
905                 if(fd >= 0)
906                 {
907                         j = search_getsize(fd);
908                         for(int i = 0; i < j; ++i)
909                                 s = strcat(s, " ", search_getfilename(fd, i));
910                         search_end(fd);
911                 }
912                 fd = search_begin("*.serverpackage", true, false);
913                 if(fd >= 0)
914                 {
915                         j = search_getsize(fd);
916                         for(int i = 0; i < j; ++i)
917                                 s = strcat(s, " ", search_getfilename(fd, i));
918                         search_end(fd);
919                 }
920                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
921         }
922
923         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
924         modname = "Xonotic";
925         // physics/balance/config changes that count as mod
926         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
927                 modname = cvar_string("g_mod_physics");
928         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
929                 modname = cvar_string("g_mod_balance");
930         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
931                 modname = cvar_string("g_mod_config");
932         // extra mutators that deserve to count as mod
933         MUTATOR_CALLHOOK(SetModname);
934
935         // save it for later
936         modname = strzone(modname);
937
938         WinningConditionHelper(); // set worldstatus
939
940         world_initialized = 1;
941 }
942
943 void spawnfunc_light (void)
944 {
945         //makestatic (self); // Who the f___ did that?
946         remove(self);
947 }
948
949 string GetGametype()
950 {
951         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
952 }
953
954 string GetMapname()
955 {
956         return mapname;
957 }
958
959 float Map_Count, Map_Current;
960 string Map_Current_Name;
961
962 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
963 float GetMaplistPosition()
964 {
965         float pos, idx;
966         string map;
967
968         map = GetMapname();
969         idx = autocvar_g_maplist_index;
970
971         if(idx >= 0)
972                 if(idx < Map_Count)
973                         if(map == argv(idx))
974                                 return idx;
975
976         for(pos = 0; pos < Map_Count; ++pos)
977                 if(map == argv(pos))
978                         return pos;
979
980         // resume normal maplist rotation if current map is not in g_maplist
981         return idx;
982 }
983
984 float MapHasRightSize(string map)
985 {
986         float fh;
987         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
988         if(autocvar_g_maplist_check_waypoints)
989         {
990                 dprint("checkwp "); dprint(map);
991                 if(!fexists(strcat("maps/", map, ".waypoints")))
992                 {
993                         dprint(": no waypoints\n");
994                         return false;
995                 }
996                 dprint(": has waypoints\n");
997         }
998
999         // open map size restriction file
1000         dprint("opensize "); dprint(map);
1001         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1002         if(fh >= 0)
1003         {
1004                 float mapmin, mapmax;
1005                 dprint(": ok, ");
1006                 mapmin = stof(fgets(fh));
1007                 mapmax = stof(fgets(fh));
1008                 fclose(fh);
1009                 if(player_count < mapmin)
1010                 {
1011                         dprint("not enough\n");
1012                         return false;
1013                 }
1014                 if(player_count > mapmax)
1015                 {
1016                         dprint("too many\n");
1017                         return false;
1018                 }
1019                 dprint("right size\n");
1020                 return true;
1021         }
1022         dprint(": not found\n");
1023         return true;
1024 }
1025
1026 string Map_Filename(float position)
1027 {
1028         return strcat("maps/", argv(position), ".bsp");
1029 }
1030
1031 string strwords(string s, float w)
1032 {
1033         float endpos;
1034         for(endpos = 0; w && endpos >= 0; --w)
1035                 endpos = strstrofs(s, " ", endpos + 1);
1036         if(endpos < 0)
1037                 return s;
1038         else
1039                 return substring(s, 0, endpos);
1040 }
1041
1042 float strhasword(string s, string w)
1043 {
1044         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1045 }
1046
1047 void Map_MarkAsRecent(string m)
1048 {
1049         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1050 }
1051
1052 float Map_IsRecent(string m)
1053 {
1054         return strhasword(autocvar_g_maplist_mostrecent, m);
1055 }
1056
1057 float Map_Check(float position, float pass)
1058 {
1059         string filename;
1060         string map_next;
1061         map_next = argv(position);
1062         if(pass <= 1)
1063         {
1064                 if(Map_IsRecent(map_next))
1065                         return 0;
1066         }
1067         filename = Map_Filename(position);
1068         if(MapInfo_CheckMap(map_next))
1069         {
1070                 if(pass == 2)
1071                         return 1;
1072                 if(MapHasRightSize(map_next))
1073                         return 1;
1074                 return 0;
1075         }
1076         else
1077                 dprint( "Couldn't select '", filename, "'..\n" );
1078
1079         return 0;
1080 }
1081
1082 void Map_Goto_SetStr(string nextmapname)
1083 {
1084         if(getmapname_stored != "")
1085                 strunzone(getmapname_stored);
1086         if(nextmapname == "")
1087                 getmapname_stored = "";
1088         else
1089                 getmapname_stored = strzone(nextmapname);
1090 }
1091
1092 void Map_Goto_SetFloat(float position)
1093 {
1094         cvar_set("g_maplist_index", ftos(position));
1095         Map_Goto_SetStr(argv(position));
1096 }
1097
1098 void Map_Goto(float reinit)
1099 {
1100         MapInfo_LoadMap(getmapname_stored, reinit);
1101 }
1102
1103 // return codes of map selectors:
1104 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1105 //   -2 = permanent failure
1106 float() MaplistMethod_Iterate = // usual method
1107 {
1108         float pass, i;
1109
1110         dprint("Trying MaplistMethod_Iterate\n");
1111
1112         for(pass = 1; pass <= 2; ++pass)
1113         {
1114                 for(i = 1; i < Map_Count; ++i)
1115                 {
1116                         float mapindex;
1117                         mapindex = (i + Map_Current) % Map_Count;
1118                         if(Map_Check(mapindex, pass))
1119                                 return mapindex;
1120                 }
1121         }
1122         return -1;
1123 }
1124
1125 float() MaplistMethod_Repeat = // fallback method
1126 {
1127         dprint("Trying MaplistMethod_Repeat\n");
1128
1129         if(Map_Check(Map_Current, 2))
1130                 return Map_Current;
1131         return -2;
1132 }
1133
1134 float() MaplistMethod_Random = // random map selection
1135 {
1136         float i, imax;
1137
1138         dprint("Trying MaplistMethod_Random\n");
1139
1140         imax = 42;
1141
1142         for(i = 0; i <= imax; ++i)
1143         {
1144                 float mapindex;
1145                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1146                 if(Map_Check(mapindex, 1))
1147                         return mapindex;
1148         }
1149         return -1;
1150 }
1151
1152 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1153 // the exponent sets a bias on the map selection:
1154 // the higher the exponent, the less likely "shortly repeated" same maps are
1155 {
1156         float i, j, imax, insertpos;
1157
1158         dprint("Trying MaplistMethod_Shuffle\n");
1159
1160         imax = 42;
1161
1162         for(i = 0; i <= imax; ++i)
1163         {
1164                 string newlist;
1165
1166                 // now reinsert this at another position
1167                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1168                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1169                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1170                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1171
1172                 // insert the current map there
1173                 newlist = "";
1174                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1175                         newlist = strcat(newlist, " ", argv(j));
1176                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1177                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1178                         newlist = strcat(newlist, " ", argv(j));
1179                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1180                 cvar_set("g_maplist", newlist);
1181                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1182
1183                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1184                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1185                 if(Map_Check(Map_Current, 1))
1186                         return Map_Current;
1187         }
1188         return -1;
1189 }
1190
1191 void Maplist_Init()
1192 {
1193         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194         float i;
1195         for (i = 0; i < Map_Count; ++i)
1196                 if (Map_Check(i, 2))
1197                         break;
1198         if (i == Map_Count)
1199         {
1200                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1201                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1202                 if(autocvar_g_maplist_shuffle)
1203                         ShuffleMaplist();
1204                 localcmd("\nmenu_cmd sync\n");
1205                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1206         }
1207         if(Map_Count == 0)
1208                 error("empty maplist, cannot select a new map");
1209         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1210
1211         if(Map_Current_Name)
1212                 strunzone(Map_Current_Name);
1213         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1214         // this may or may not be correct, but who cares, in the worst case a map
1215         // isn't chosen in the first pass that should have been
1216 }
1217
1218 string GetNextMap()
1219 {
1220         float nextMap;
1221
1222         Maplist_Init();
1223         nextMap = -1;
1224
1225         if(nextMap == -1)
1226                 if(autocvar_g_maplist_shuffle > 0)
1227                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1228
1229         if(nextMap == -1)
1230                 if(autocvar_g_maplist_selectrandom)
1231                         nextMap = MaplistMethod_Random();
1232
1233         if(nextMap == -1)
1234                 nextMap = MaplistMethod_Iterate();
1235
1236         if(nextMap == -1)
1237                 nextMap = MaplistMethod_Repeat();
1238
1239         if(nextMap >= 0)
1240         {
1241                 Map_Goto_SetFloat(nextMap);
1242                 return getmapname_stored;
1243         }
1244
1245         return "";
1246 }
1247
1248 float DoNextMapOverride(float reinit)
1249 {
1250         if(autocvar_g_campaign)
1251         {
1252                 CampaignPostIntermission();
1253                 alreadychangedlevel = true;
1254                 return true;
1255         }
1256         if(autocvar_quit_when_empty)
1257         {
1258                 if(player_count <= currentbots)
1259                 {
1260                         localcmd("quit\n");
1261                         alreadychangedlevel = true;
1262                         return true;
1263                 }
1264         }
1265         if(autocvar_quit_and_redirect != "")
1266         {
1267                 redirection_target = strzone(autocvar_quit_and_redirect);
1268                 alreadychangedlevel = true;
1269                 return true;
1270         }
1271         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1272         {
1273                 localcmd("restart\n");
1274                 alreadychangedlevel = true;
1275                 return true;
1276         }
1277         if(autocvar_nextmap != "")
1278         {
1279                 string m;
1280                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1281                 cvar_set("nextmap",m);
1282
1283                 if(!m || gametypevote)
1284                         return false;
1285                 if(autocvar_sv_vote_gametype)
1286                 {
1287                         Map_Goto_SetStr(m);
1288                         return false;
1289                 }
1290
1291                 if(MapInfo_CheckMap(m))
1292                 {
1293                         Map_Goto_SetStr(m);
1294                         Map_Goto(reinit);
1295                         alreadychangedlevel = true;
1296                         return true;
1297                 }
1298         }
1299         if(!reinit && autocvar_lastlevel)
1300         {
1301                 cvar_settemp_restore();
1302                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1303                 alreadychangedlevel = true;
1304                 return true;
1305         }
1306         return false;
1307 }
1308
1309 void GotoNextMap(float reinit)
1310 {
1311         //string nextmap;
1312         //float n, nummaps;
1313         //string s;
1314         if (alreadychangedlevel)
1315                 return;
1316         alreadychangedlevel = true;
1317
1318         string nextMap;
1319
1320         nextMap = GetNextMap();
1321         if(nextMap == "")
1322                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1323         Map_Goto(reinit);
1324 }
1325
1326
1327 /*
1328 ============
1329 IntermissionThink
1330
1331 When the player presses attack or jump, change to the next level
1332 ============
1333 */
1334 .float autoscreenshot;
1335 void IntermissionThink()
1336 {
1337         FixIntermissionClient(self);
1338
1339         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1340         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1341
1342         if( (server_screenshot || client_screenshot)
1343                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1344         {
1345                 self.autoscreenshot = -1;
1346                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1347                 return;
1348         }
1349
1350         if (time < intermission_exittime)
1351                 return;
1352
1353         if(!mapvote_initialized)
1354                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1355                         return;
1356
1357         MapVote_Start();
1358 }
1359
1360 /*
1361 ============
1362 FindIntermission
1363
1364 Returns the entity to view from
1365 ============
1366 */
1367 /*
1368 entity FindIntermission()
1369 {
1370         local   entity spot;
1371         local   float cyc;
1372
1373 // look for info_intermission first
1374         spot = find (world, classname, "info_intermission");
1375         if (spot)
1376         {       // pick a random one
1377                 cyc = random() * 4;
1378                 while (cyc > 1)
1379                 {
1380                         spot = find (spot, classname, "info_intermission");
1381                         if (!spot)
1382                                 spot = find (spot, classname, "info_intermission");
1383                         cyc = cyc - 1;
1384                 }
1385                 return spot;
1386         }
1387
1388 // then look for the start position
1389         spot = find (world, classname, "info_player_start");
1390         if (spot)
1391                 return spot;
1392
1393 // testinfo_player_start is only found in regioned levels
1394         spot = find (world, classname, "testplayerstart");
1395         if (spot)
1396                 return spot;
1397
1398 // then look for the start position
1399         spot = find (world, classname, "info_player_deathmatch");
1400         if (spot)
1401                 return spot;
1402
1403         //objerror ("FindIntermission: no spot");
1404         return world;
1405 }
1406 */
1407
1408 /*
1409 ===============================================================================
1410
1411 RULES
1412
1413 ===============================================================================
1414 */
1415
1416 void DumpStats(float final)
1417 {
1418         float file;
1419         string s;
1420         float to_console;
1421         float to_eventlog;
1422         float to_file;
1423         float i;
1424
1425         to_console = autocvar_sv_logscores_console;
1426         to_eventlog = autocvar_sv_eventlog;
1427         to_file = autocvar_sv_logscores_file;
1428
1429         if(!final)
1430         {
1431                 to_console = true; // always print printstats replies
1432                 to_eventlog = false; // but never print them to the event log
1433         }
1434
1435         if(to_eventlog)
1436                 if(autocvar_sv_eventlog_console)
1437                         to_console = false; // otherwise we get the output twice
1438
1439         if(final)
1440                 s = ":scores:";
1441         else
1442                 s = ":status:";
1443         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1444
1445         if(to_console)
1446                 print(s, "\n");
1447         if(to_eventlog)
1448                 GameLogEcho(s);
1449
1450         file = -1;
1451         if(to_file)
1452         {
1453                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1454                 if(file == -1)
1455                         to_file = false;
1456                 else
1457                         fputs(file, strcat(s, "\n"));
1458         }
1459
1460         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1461         if(to_console)
1462                 print(s, "\n");
1463         if(to_eventlog)
1464                 GameLogEcho(s);
1465         if(to_file)
1466                 fputs(file, strcat(s, "\n"));
1467
1468         FOR_EACH_CLIENT(other)
1469         {
1470                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1471                 {
1472                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1473                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1474                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1475                                 s = strcat(s, ftos(other.team), ":");
1476                         else
1477                                 s = strcat(s, "spectator:");
1478
1479                         if(to_console)
1480                                 print(s, other.netname, "\n");
1481                         if(to_eventlog)
1482                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1483                         if(to_file)
1484                                 fputs(file, strcat(s, other.netname, "\n"));
1485                 }
1486         }
1487
1488         if(teamplay)
1489         {
1490                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1491                 if(to_console)
1492                         print(s, "\n");
1493                 if(to_eventlog)
1494                         GameLogEcho(s);
1495                 if(to_file)
1496                         fputs(file, strcat(s, "\n"));
1497
1498                 for(i = 1; i < 16; ++i)
1499                 {
1500                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1501                         s = strcat(s, ":", ftos(i));
1502                         if(to_console)
1503                                 print(s, "\n");
1504                         if(to_eventlog)
1505                                 GameLogEcho(s);
1506                         if(to_file)
1507                                 fputs(file, strcat(s, "\n"));
1508                 }
1509         }
1510
1511         if(to_console)
1512                 print(":end\n");
1513         if(to_eventlog)
1514                 GameLogEcho(":end");
1515         if(to_file)
1516         {
1517                 fputs(file, ":end\n");
1518                 fclose(file);
1519         }
1520 }
1521
1522 void FixIntermissionClient(entity e)
1523 {
1524         string s;
1525         if(!e.autoscreenshot) // initial call
1526         {
1527                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1528                 e.health = -2342;
1529                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1530                 e.solid = SOLID_NOT;
1531                 e.movetype = MOVETYPE_NONE;
1532                 e.takedamage = DAMAGE_NO;
1533                 if(e.weaponentity)
1534                 {
1535                         e.weaponentity.effects = EF_NODRAW;
1536                         if (e.weaponentity.weaponentity)
1537                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1538                 }
1539                 if(IS_REAL_CLIENT(e))
1540                 {
1541                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1542                         s = autocvar_sv_intermission_cdtrack;
1543                         if(s != "")
1544                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1545                         msg_entity = e;
1546                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1547                 }
1548         }
1549 }
1550
1551 /*
1552 go to the next level for deathmatch
1553 only called if a time or frag limit has expired
1554 */
1555 void NextLevel()
1556 {
1557         gameover = true;
1558
1559         intermission_running = 1;
1560
1561 // enforce a wait time before allowing changelevel
1562         if(player_count > 0)
1563                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1564         else
1565                 intermission_exittime = -1;
1566
1567         /*
1568         WriteByte (MSG_ALL, SVC_CDTRACK);
1569         WriteByte (MSG_ALL, 3);
1570         WriteByte (MSG_ALL, 3);
1571         // done in FixIntermission
1572         */
1573
1574         //pos = FindIntermission ();
1575
1576         VoteReset();
1577
1578         DumpStats(true);
1579
1580         // send statistics
1581         PlayerStats_GameReport(true);
1582         WeaponStats_Shutdown();
1583
1584         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1585
1586         if(autocvar_sv_eventlog)
1587                 GameLogEcho(":gameover");
1588
1589         GameLogClose();
1590
1591         FOR_EACH_PLAYER(other) {
1592                 FixIntermissionClient(other);
1593                 if(other.winning)
1594                         bprint(other.netname, " ^7wins.\n");
1595         }
1596
1597         if(autocvar_g_campaign)
1598                 CampaignPreIntermission();
1599
1600         MUTATOR_CALLHOOK(MatchEnd);
1601
1602         localcmd("\nsv_hook_gameend\n");
1603 }
1604
1605 /*
1606 ============
1607 CheckRules_Player
1608
1609 Exit deathmatch games upon conditions
1610 ============
1611 */
1612 void CheckRules_Player()
1613 {
1614         if (gameover)   // someone else quit the game already
1615                 return;
1616
1617         if(self.deadflag == DEAD_NO)
1618                 self.play_time += frametime;
1619
1620         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1621         //   (div0: and that in CheckRules_World please)
1622 }
1623
1624
1625 float InitiateSuddenDeath()
1626 {
1627         // Check first whether normal overtimes could be added before initiating suddendeath mode
1628         // - for this timelimit_overtime needs to be >0 of course
1629         // - also check the winning condition calculated in the previous frame and only add normal overtime
1630         //   again, if at the point at which timelimit would be extended again, still no winner was found
1631         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1632         {
1633                 return 1; // need to call InitiateOvertime later
1634         }
1635         else
1636         {
1637                 if(!checkrules_suddendeathend)
1638                 {
1639                         if(autocvar_g_campaign)
1640                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1641                         else
1642                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1643                         if(g_race && !g_race_qualifying)
1644                                 race_StartCompleting();
1645                 }
1646                 return 0;
1647         }
1648 }
1649
1650 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1651 {
1652         ++checkrules_overtimesadded;
1653         //add one more overtime by simply extending the timelimit
1654         float tl;
1655         tl = autocvar_timelimit;
1656         tl += autocvar_timelimit_overtime;
1657         cvar_set("timelimit", ftos(tl));
1658
1659         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1660 }
1661
1662 float GetWinningCode(float fraglimitreached, float equality)
1663 {
1664         if(autocvar_g_campaign == 1)
1665                 if(fraglimitreached)
1666                         return WINNING_YES;
1667                 else
1668                         return WINNING_NO;
1669
1670         else
1671                 if(equality)
1672                         if(fraglimitreached)
1673                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1674                         else
1675                                 return WINNING_NEVER;
1676                 else
1677                         if(fraglimitreached)
1678                                 return WINNING_YES;
1679                         else
1680                                 return WINNING_NO;
1681 }
1682
1683 // set the .winning flag for exactly those players with a given field value
1684 void SetWinners(.float field, float value)
1685 {
1686         entity head;
1687         FOR_EACH_PLAYER(head)
1688                 head.winning = (head.(field) == value);
1689 }
1690
1691 // set the .winning flag for those players with a given field value
1692 void AddWinners(.float field, float value)
1693 {
1694         entity head;
1695         FOR_EACH_PLAYER(head)
1696                 if (head.(field) == value)
1697                         head.winning = 1;
1698 }
1699
1700 // clear the .winning flags
1701 void ClearWinners(void)
1702 {
1703         entity head;
1704         FOR_EACH_PLAYER(head)
1705                 head.winning = 0;
1706 }
1707
1708 // Onslaught winning condition:
1709 // game terminates if only one team has a working generator (or none)
1710 float WinningCondition_Onslaught()
1711 {
1712         entity head;
1713         float t1, t2, t3, t4;
1714
1715         WinningConditionHelper(); // set worldstatus
1716
1717         if(warmup_stage)
1718                 return WINNING_NO;
1719
1720         // first check if the game has ended
1721         t1 = t2 = t3 = t4 = 0;
1722         head = find(world, classname, "onslaught_generator");
1723         while (head)
1724         {
1725                 if (head.health > 0)
1726                 {
1727                         if (head.team == NUM_TEAM_1) t1 = 1;
1728                         if (head.team == NUM_TEAM_2) t2 = 1;
1729                         if (head.team == NUM_TEAM_3) t3 = 1;
1730                         if (head.team == NUM_TEAM_4) t4 = 1;
1731                 }
1732                 head = find(head, classname, "onslaught_generator");
1733         }
1734         if (t1 + t2 + t3 + t4 < 2)
1735         {
1736                 // game over, only one team remains (or none)
1737                 ClearWinners();
1738                 if (t1) SetWinners(team, NUM_TEAM_1);
1739                 if (t2) SetWinners(team, NUM_TEAM_2);
1740                 if (t3) SetWinners(team, NUM_TEAM_3);
1741                 if (t4) SetWinners(team, NUM_TEAM_4);
1742                 dprint("Have a winner, ending game.\n");
1743                 return WINNING_YES;
1744         }
1745
1746         // Two or more teams remain
1747         return WINNING_NO;
1748 }
1749
1750 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1751 // they win. Otherwise the defending team wins once the timelimit passes.
1752 void assault_new_round();
1753 float WinningCondition_Assault()
1754 {
1755         float status;
1756
1757         WinningConditionHelper(); // set worldstatus
1758
1759         status = WINNING_NO;
1760         // as the timelimit has not yet passed just assume the defending team will win
1761         if(assault_attacker_team == NUM_TEAM_1)
1762         {
1763                 SetWinners(team, NUM_TEAM_2);
1764         }
1765         else
1766         {
1767                 SetWinners(team, NUM_TEAM_1);
1768         }
1769
1770         entity ent;
1771         ent = find(world, classname, "target_assault_roundend");
1772         if(ent)
1773         {
1774                 if(ent.winning) // round end has been triggered by attacking team
1775                 {
1776                         bprint("ASSAULT: round completed...\n");
1777                         SetWinners(team, assault_attacker_team);
1778
1779                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1780
1781                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1782                         {
1783                                 status = WINNING_YES;
1784                         }
1785                         else
1786                         {
1787                                 entity oldself;
1788                                 oldself = self;
1789                                 self = ent;
1790                                 assault_new_round();
1791                                 self = oldself;
1792                         }
1793                 }
1794         }
1795
1796         return status;
1797 }
1798
1799 // LMS winning condition: game terminates if and only if there's at most one
1800 // one player who's living lives. Top two scores being equal cancels the time
1801 // limit.
1802 float WinningCondition_LMS()
1803 {
1804         entity head, head2;
1805         float have_player;
1806         float have_players;
1807         float l;
1808
1809         have_player = false;
1810         have_players = false;
1811         l = LMS_NewPlayerLives();
1812
1813         head = find(world, classname, "player");
1814         if(head)
1815                 have_player = true;
1816         head2 = find(head, classname, "player");
1817         if(head2)
1818                 have_players = true;
1819
1820         if(have_player)
1821         {
1822                 // we have at least one player
1823                 if(have_players)
1824                 {
1825                         // two or more active players - continue with the game
1826                 }
1827                 else
1828                 {
1829                         // exactly one player?
1830
1831                         ClearWinners();
1832                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1833
1834                         if(l)
1835                         {
1836                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1837                                 return WINNING_NO;
1838                         }
1839                         else
1840                         {
1841                                 // a winner!
1842                                 // and assign him his first place
1843                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1844                                 return WINNING_YES;
1845                         }
1846                 }
1847         }
1848         else
1849         {
1850                 // nobody is playing at all...
1851                 if(l)
1852                 {
1853                         // wait for players...
1854                 }
1855                 else
1856                 {
1857                         // SNAFU (maybe a draw game?)
1858                         ClearWinners();
1859                         dprint("No players, ending game.\n");
1860                         return WINNING_YES;
1861                 }
1862         }
1863
1864         // When we get here, we have at least two players who are actually LIVING,
1865         // now check if the top two players have equal score.
1866         WinningConditionHelper();
1867
1868         ClearWinners();
1869         if(WinningConditionHelper_winner)
1870                 WinningConditionHelper_winner.winning = true;
1871         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1872                 return WINNING_NEVER;
1873
1874         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1875         return WINNING_NO;
1876 }
1877
1878 void ShuffleMaplist()
1879 {
1880         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1881 }
1882
1883 float leaderfrags;
1884 float WinningCondition_Scores(float limit, float leadlimit)
1885 {
1886         float limitreached;
1887
1888         // TODO make everything use THIS winning condition (except LMS)
1889         WinningConditionHelper();
1890
1891         if(teamplay)
1892         {
1893                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1894                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1895                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1896                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1897         }
1898
1899         ClearWinners();
1900         if(WinningConditionHelper_winner)
1901                 WinningConditionHelper_winner.winning = 1;
1902         if(WinningConditionHelper_winnerteam >= 0)
1903                 SetWinners(team, WinningConditionHelper_winnerteam);
1904
1905         if(WinningConditionHelper_lowerisbetter)
1906         {
1907                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1908                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1909                 limit = -limit;
1910         }
1911
1912         if(WinningConditionHelper_zeroisworst)
1913                 leadlimit = 0; // not supported in this mode
1914
1915         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1916         // these modes always score in increments of 1, thus this makes sense
1917         {
1918                 if(leaderfrags != WinningConditionHelper_topscore)
1919                 {
1920                         leaderfrags = WinningConditionHelper_topscore;
1921
1922                         if (limit)
1923                         if (leaderfrags == limit - 1)
1924                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1925                         else if (leaderfrags == limit - 2)
1926                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1927                         else if (leaderfrags == limit - 3)
1928                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1929                 }
1930         }
1931
1932         limitreached = false;
1933         if(limit)
1934                 if(WinningConditionHelper_topscore >= limit)
1935                         limitreached = true;
1936         if(leadlimit)
1937         {
1938                 float leadlimitreached;
1939                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1940                 if(autocvar_leadlimit_and_fraglimit)
1941                         limitreached = (limitreached && leadlimitreached);
1942                 else
1943                         limitreached = (limitreached || leadlimitreached);
1944         }
1945
1946         if(limit)
1947                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1948
1949         return GetWinningCode(
1950                 WinningConditionHelper_topscore && limitreached,
1951                 WinningConditionHelper_equality
1952         );
1953 }
1954
1955 float WinningCondition_Race(float fraglimit)
1956 {
1957         float wc;
1958         entity p;
1959         float n, c;
1960
1961         n = 0;
1962         c = 0;
1963         FOR_EACH_PLAYER(p)
1964         {
1965                 ++n;
1966                 if(p.race_completed)
1967                         ++c;
1968         }
1969         if(n && (n == c))
1970                 return WINNING_YES;
1971         wc = WinningCondition_Scores(fraglimit, 0);
1972
1973         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1974         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1975         // do NOT support equality when the laps are all raced!
1976                 return WINNING_STARTSUDDENDEATHOVERTIME;
1977         else
1978                 return WINNING_NEVER;
1979 }
1980
1981 float WinningCondition_QualifyingThenRace(float limit)
1982 {
1983         float wc;
1984         wc = WinningCondition_Scores(limit, 0);
1985
1986         // NEVER initiate overtime
1987         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1988         {
1989                 return WINNING_YES;
1990         }
1991
1992         return wc;
1993 }
1994
1995 float WinningCondition_RanOutOfSpawns()
1996 {
1997         entity head;
1998
1999         if(have_team_spawns <= 0)
2000                 return WINNING_NO;
2001
2002         if(!autocvar_g_spawn_useallspawns)
2003                 return WINNING_NO;
2004
2005         if(!some_spawn_has_been_used)
2006                 return WINNING_NO;
2007
2008         team1_score = team2_score = team3_score = team4_score = 0;
2009
2010         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2011         {
2012                 if(head.team == NUM_TEAM_1)
2013                         team1_score = 1;
2014                 else if(head.team == NUM_TEAM_2)
2015                         team2_score = 1;
2016                 else if(head.team == NUM_TEAM_3)
2017                         team3_score = 1;
2018                 else if(head.team == NUM_TEAM_4)
2019                         team4_score = 1;
2020         }
2021
2022         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2023         {
2024                 if(head.team == NUM_TEAM_1)
2025                         team1_score = 1;
2026                 else if(head.team == NUM_TEAM_2)
2027                         team2_score = 1;
2028                 else if(head.team == NUM_TEAM_3)
2029                         team3_score = 1;
2030                 else if(head.team == NUM_TEAM_4)
2031                         team4_score = 1;
2032         }
2033
2034         ClearWinners();
2035         if(team1_score + team2_score + team3_score + team4_score == 0)
2036         {
2037                 checkrules_equality = true;
2038                 return WINNING_YES;
2039         }
2040         else if(team1_score + team2_score + team3_score + team4_score == 1)
2041         {
2042                 float t, i;
2043                 if(team1_score)
2044                         t = NUM_TEAM_1;
2045                 else if(team2_score)
2046                         t = NUM_TEAM_2;
2047                 else if(team3_score)
2048                         t = NUM_TEAM_3;
2049                 else // if(team4_score)
2050                         t = NUM_TEAM_4;
2051                 CheckAllowedTeams(world);
2052                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2053                 {
2054                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2055                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2056                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2057                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2058                 }
2059
2060                 AddWinners(team, t);
2061                 return WINNING_YES;
2062         }
2063         else
2064                 return WINNING_NO;
2065 }
2066
2067 /*
2068 ============
2069 CheckRules_World
2070
2071 Exit deathmatch games upon conditions
2072 ============
2073 */
2074 void CheckRules_World()
2075 {
2076         float timelimit;
2077         float fraglimit;
2078         float leadlimit;
2079
2080         VoteThink();
2081         MapVote_Think();
2082
2083         SetDefaultAlpha();
2084
2085         if (gameover)   // someone else quit the game already
2086         {
2087                 if(player_count == 0) // Nobody there? Then let's go to the next map
2088                         MapVote_Start();
2089                         // this will actually check the player count in the next frame
2090                         // again, but this shouldn't hurt
2091                 return;
2092         }
2093
2094         timelimit = autocvar_timelimit * 60;
2095         fraglimit = autocvar_fraglimit;
2096         leadlimit = autocvar_leadlimit;
2097
2098         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2099         {
2100                 if(timelimit > 0)
2101                         timelimit = 0; // timelimit is not made for warmup
2102                 if(fraglimit > 0)
2103                         fraglimit = 0; // no fraglimit for now
2104                 leadlimit = 0; // no leadlimit for now
2105         }
2106
2107         if(timelimit > 0)
2108         {
2109                 timelimit += game_starttime;
2110         }
2111         else if (timelimit < 0)
2112         {
2113                 // endmatch
2114                 NextLevel();
2115                 return;
2116         }
2117
2118         if(g_onslaught)
2119                 timelimit = 0; // ONS has its own overtime rule
2120
2121         float wantovertime;
2122         wantovertime = 0;
2123
2124         if(timelimit > game_starttime)
2125                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2126         else
2127                 game_completion_ratio = 0;
2128
2129         if(checkrules_suddendeathend)
2130         {
2131                 if(!checkrules_suddendeathwarning)
2132                 {
2133                         checkrules_suddendeathwarning = true;
2134                         if(g_race && !g_race_qualifying)
2135                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2136                         else
2137                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2138                 }
2139         }
2140         else
2141         {
2142                 if (timelimit && time >= timelimit)
2143                 {
2144                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2145                         {
2146                                 float totalplayers;
2147                                 float playerswithlaps;
2148                                 float readyplayers;
2149                                 entity head;
2150                                 totalplayers = playerswithlaps = readyplayers = 0;
2151                                 FOR_EACH_PLAYER(head)
2152                                 {
2153                                         ++totalplayers;
2154                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2155                                                 ++playerswithlaps;
2156                                         if(head.ready)
2157                                                 ++readyplayers;
2158                                 }
2159
2160                                 // at least 2 of the players have completed a lap: start the RACE
2161                                 // otherwise, the players should end the qualifying on their own
2162                                 if(readyplayers || playerswithlaps >= 2)
2163                                 {
2164                                         checkrules_suddendeathend = 0;
2165                                         ReadyRestart(); // go to race
2166                                         return;
2167                                 }
2168                                 else
2169                                         wantovertime |= InitiateSuddenDeath();
2170                         }
2171                         else
2172                                 wantovertime |= InitiateSuddenDeath();
2173                 }
2174         }
2175
2176         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2177         {
2178                 NextLevel();
2179                 return;
2180         }
2181
2182         float checkrules_status;
2183         checkrules_status = WinningCondition_RanOutOfSpawns();
2184         if(checkrules_status == WINNING_YES)
2185         {
2186                 bprint("Hey! Someone ran out of spawns!\n");
2187         }
2188         else if(g_race && !g_race_qualifying && timelimit >= 0)
2189         {
2190                 checkrules_status = WinningCondition_Race(fraglimit);
2191                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2192         }
2193         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2194         {
2195                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2196                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2197         }
2198         else if(g_assault)
2199         {
2200                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2201         }
2202         else if(g_lms)
2203         {
2204                 checkrules_status = WinningCondition_LMS();
2205         }
2206         else if (g_onslaught)
2207         {
2208                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2209         }
2210         else
2211         {
2212                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2213                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2214         }
2215
2216         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2217         {
2218                 checkrules_status = WINNING_NEVER;
2219                 checkrules_overtimesadded = -1;
2220                 wantovertime |= InitiateSuddenDeath();
2221         }
2222
2223         if(checkrules_status == WINNING_NEVER)
2224                 // equality cases! Nobody wins if the overtime ends in a draw.
2225                 ClearWinners();
2226
2227         if(wantovertime)
2228         {
2229                 if(checkrules_status == WINNING_NEVER)
2230                         InitiateOvertime();
2231                 else
2232                         checkrules_status = WINNING_YES;
2233         }
2234
2235         if(checkrules_suddendeathend)
2236                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2237                         checkrules_status = WINNING_YES;
2238
2239         if(checkrules_status == WINNING_YES)
2240         {
2241                 //print("WINNING\n");
2242                 NextLevel();
2243         }
2244 }
2245
2246 string GotoMap(string m)
2247 {
2248         m = GameTypeVote_MapInfo_FixName(m);
2249         if (!m)
2250                 return "The map you suggested is not available on this server.";
2251         if (!autocvar_sv_vote_gametype)
2252         if(!MapInfo_CheckMap(m))
2253                 return "The map you suggested does not support the current game mode.";
2254         cvar_set("nextmap", m);
2255         cvar_set("timelimit", "-1");
2256         if(mapvote_initialized || alreadychangedlevel)
2257         {
2258                 if(DoNextMapOverride(0))
2259                         return "Map switch initiated.";
2260                 else
2261                         return "Hm... no. For some reason I like THIS map more.";
2262         }
2263         else
2264                 return "Map switch will happen after scoreboard.";
2265 }
2266
2267
2268 void EndFrame()
2269 {
2270         anticheat_endframe();
2271
2272         float altime;
2273         FOR_EACH_REALCLIENT(self)
2274         {
2275                 entity e = IS_SPEC(self) ? self.enemy : self;
2276                 if(e.typehitsound)
2277                         self.typehit_time = time;
2278                 else if(e.damage_dealt)
2279                 {
2280                         self.hit_time = time;
2281                         self.damage_dealt_total += ceil(e.damage_dealt);
2282                 }
2283         }
2284         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2285         // add 1 frametime because after this, engine SV_Physics
2286         // increases time by a frametime and then networks the frame
2287         // add another frametime because client shows everything with
2288         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2289         // needed!
2290         FOR_EACH_CLIENT(self)
2291         {
2292                 self.typehitsound = false;
2293                 self.damage_dealt = 0;
2294                 antilag_record(self, altime);
2295         }
2296         FOR_EACH_MONSTER(self)
2297                 antilag_record(self, altime);
2298 }
2299
2300
2301 /*
2302  * RedirectionThink:
2303  * returns true if redirecting
2304  */
2305 float redirection_timeout;
2306 float redirection_nextthink;
2307 float RedirectionThink()
2308 {
2309         float clients_found;
2310
2311         if(redirection_target == "")
2312                 return false;
2313
2314         if(!redirection_timeout)
2315         {
2316                 cvar_set("sv_public", "-2");
2317                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2318                 if(redirection_target == "self")
2319                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2320                 else
2321                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2322         }
2323
2324         if(time < redirection_nextthink)
2325                 return true;
2326
2327         redirection_nextthink = time + 1;
2328
2329         clients_found = 0;
2330         FOR_EACH_REALCLIENT(self)
2331         {
2332                 // TODO add timer
2333                 print("Redirecting: sending connect command to ", self.netname, "\n");
2334                 if(redirection_target == "self")
2335                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2336                 else
2337                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2338                 ++clients_found;
2339         }
2340
2341         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2342
2343         if(time > redirection_timeout || clients_found == 0)
2344                 localcmd("\nwait; wait; wait; quit\n");
2345
2346         return true;
2347 }
2348
2349 void TargetMusic_RestoreGame();
2350 void RestoreGame()
2351 {
2352         // Loaded from a save game
2353         // some things then break, so let's work around them...
2354
2355         // Progs DB (capture records)
2356         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2357
2358         // Mapinfo
2359         MapInfo_Shutdown();
2360         MapInfo_Enumerate();
2361         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2362         WeaponStats_Init();
2363
2364         TargetMusic_RestoreGame();
2365 }
2366
2367 void Shutdown()
2368 {
2369         gameover = 2;
2370
2371         if(world_initialized > 0)
2372         {
2373                 world_initialized = 0;
2374                 print("Saving persistent data...\n");
2375                 Ban_SaveBans();
2376
2377                 // playerstats with unfinished match
2378                 PlayerStats_GameReport(false);
2379
2380                 if(!cheatcount_total)
2381                 {
2382                         if(autocvar_sv_db_saveasdump)
2383                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2384                         else
2385                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2386                 }
2387                 if(autocvar_developer)
2388                 {
2389                         if(autocvar_sv_db_saveasdump)
2390                                 db_dump(TemporaryDB, "server-temp.db");
2391                         else
2392                                 db_save(TemporaryDB, "server-temp.db");
2393                 }
2394                 CheatShutdown(); // must be after cheatcount check
2395                 db_close(ServerProgsDB);
2396                 db_close(TemporaryDB);
2397                 print("done!\n");
2398                 // tell the bot system the game is ending now
2399                 bot_endgame();
2400
2401                 WeaponStats_Shutdown();
2402                 MapInfo_Shutdown();
2403         }
2404         else if(world_initialized == 0)
2405         {
2406                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2407         }
2408 }