another try
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 entity pingplreport;
2 void PingPLReport_Think()
3 {
4         float delta;
5         entity e;
6
7         delta = 3 / maxclients;
8         if(delta < sys_frametime)
9                 delta = 0;
10         self.nextthink = time + delta;
11
12         e = edict_num(self.cnt + 1);
13         if(clienttype(e) == CLIENTTYPE_REAL)
14         {
15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
17                 WriteByte(MSG_BROADCAST, self.cnt);
18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
21         }
22         else
23         {
24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
26                 WriteByte(MSG_BROADCAST, self.cnt);
27                 WriteShort(MSG_BROADCAST, 0);
28                 WriteByte(MSG_BROADCAST, 0);
29                 WriteByte(MSG_BROADCAST, 0);
30         }
31         self.cnt = mod(self.cnt + 1, maxclients);
32 }
33 void PingPLReport_Spawn()
34 {
35         pingplreport = spawn();
36         pingplreport.classname = "pingplreport";
37         pingplreport.think = PingPLReport_Think;
38         pingplreport.nextthink = time;
39 }
40
41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
42 string redirection_target;
43 float world_initialized;
44
45 string GetMapname();
46 string GetGametype();
47 void GotoNextMap();
48 void ShuffleMaplist()
49 float() DoNextMapOverride;
50
51 void SetDefaultAlpha()
52 {
53         if(cvar("g_running_guns"))
54         {
55                 default_player_alpha = -1;
56                 default_weapon_alpha = +1;
57         }
58         else if(g_cloaked)
59         {
60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
61                 default_weapon_alpha = default_player_alpha;
62         }
63         else
64         {
65                 default_player_alpha = cvar("g_player_alpha");
66                 if(default_player_alpha == 0)
67                         default_player_alpha = 1;
68                 default_weapon_alpha = default_player_alpha;
69         }
70 }
71
72 void fteqcc_testbugs()
73 {
74         float a, b;
75
76         if(!cvar("developer_fteqccbugs"))
77                 return;
78
79         dprint("*** fteqcc test: checking for bugs...\n");
80
81         a = 1;
82         b = 5;
83         if(sqrt(a) - sqrt(b - a) == 0)
84                 dprint("*** fteqcc test: found same-function-twice bug\n");
85         else
86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
87
88         world.cnt = -10;
89         world.enemy = world;
90         world.enemy.cnt += 10;
91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
92                 dprint("*** fteqcc test: found += bug\n");
93         else
94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
95         world.cnt = 0;
96 }
97
98 /**
99  * Takes care of pausing and unpausing the game.
100  * Centerprints the information about an upcoming or active timeout to all active
101  * players. Also plays reminder sounds.
102  */
103 void timeoutHandler_Think() {
104         local string timeStr;
105         local entity plr;
106         if (timeoutStatus == 1) {
107                 if (remainingLeadTime > 0) {
108                         //centerprint the information to every player
109                         timeStr = getTimeoutText(0);
110                         FOR_EACH_REALCLIENT(plr) {
111                                 if(plr.classname == "player") {
112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
113                                 }
114                         }
115                         remainingLeadTime -= 1;
116                         //think again in 1 second:
117                         self.nextthink = time + 1;
118                 }
119                 else {
120                         //now pause the game:
121                         timeoutStatus = 2;
122                         //reset all the flood variables
123                         FOR_EACH_CLIENT(plr) {
124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
125                         }
126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
128                         FOR_EACH_REALPLAYER(plr) {
129                                 plr.lastV_angle = plr.v_angle;
130                         }
131                         self.nextthink = time;
132                 }
133         }
134         else if (timeoutStatus == 2) {
135                 if (remainingTimeoutTime > 0) {
136                         timeStr = getTimeoutText(0);
137                         FOR_EACH_REALCLIENT(plr) {
138                                 if(plr.classname == "player") {
139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
140                                 }
141                         }
142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
143                                 Announce("prepareforbattle");
144                         }
145                         remainingTimeoutTime -= 1;
146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
147                 }
148                 else {
149                         //unpause the game again
150                         remainingTimeoutTime = timeoutStatus = 0;
151                         cvar_set("slowmo", ftos(orig_slowmo));
152                         //and unlock the fixed view again once there is no timeout active anymore
153                         FOR_EACH_REALPLAYER(plr) {
154                                 plr.fixangle = FALSE;
155                         }
156                         //get rid of the countdown message
157                         FOR_EACH_REALCLIENT(plr) {
158                                 if(plr.classname == "player") {
159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
160                                 }
161                         }
162                         remove(self);
163                         return;
164                 }
165
166         }
167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
168                 FOR_EACH_REALCLIENT(plr) {
169                         if(plr.classname == "player") {
170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
171                         }
172                 }
173                 remove(self);
174                 return;
175         }
176 }
177
178 void GotoFirstMap()
179 {
180         float n;
181         if(cvar("_sv_init"))
182         {
183                 // cvar_set("_sv_init", "0");
184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
185                 // to this "init" map on a dedicated server will cause no permanent
186                 // harm
187                 if(cvar("g_maplist_shuffle"))
188                         ShuffleMaplist();
189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
191
192                 MapInfo_Enumerate();
193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
194
195                 if(!DoNextMapOverride())
196                         GotoNextMap();
197
198                 return;
199         }
200
201         if(time < 5)
202         {
203                 self.nextthink = time;
204         }
205         else
206         {
207                 self.nextthink = time + 1;
208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
209         }
210 }
211
212 void cvar_changes_init()
213 {
214         float h;
215         string k, v, d;
216         float n, i, adding, pureadding;
217
218         if(cvar_changes)
219                 strunzone(cvar_changes);
220         cvar_changes = string_null;
221         if(cvar_purechanges)
222                 strunzone(cvar_purechanges);
223         cvar_purechanges = string_null;
224         cvar_purechanges_count = 0;
225
226         h = buf_create();
227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
228         n = buf_getsize(h);
229
230         adding = TRUE;
231         pureadding = TRUE;
232
233         for(i = 0; i < n; ++i)
234         {
235                 k = bufstr_get(h, i);
236
237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
238 #define BADCVAR(p) if(k == p) continue
239                 // internal
240                 BADPREFIX("csqc_");
241                 BADPREFIX("cvar_check_");
242                 BADCVAR("gamecfg");
243                 BADCVAR("g_configversion");
244                 BADCVAR("g_maplist_index");
245                 BADCVAR("halflifebsp");
246                 BADPREFIX("sv_world");
247
248                 // client
249                 BADPREFIX("chase_");
250                 BADPREFIX("cl_");
251                 BADPREFIX("con_");
252                 BADPREFIX("scoreboard_");
253                 BADPREFIX("g_campaign");
254                 BADPREFIX("gl_");
255                 BADPREFIX("joy");
256                 BADPREFIX("hud_");
257                 BADPREFIX("menu_");
258                 BADPREFIX("net_slist_");
259                 BADPREFIX("r_");
260                 BADPREFIX("sbar_");
261                 BADPREFIX("scr_");
262                 BADPREFIX("snd_");
263                 BADPREFIX("userbind");
264                 BADPREFIX("v_");
265                 BADPREFIX("vid_");
266                 BADPREFIX("crosshair");
267                 BADCVAR("mod_q3bsp_lightmapmergepower");
268                 BADCVAR("mod_q3bsp_nolightmaps");
269                 BADCVAR("fov");
270                 BADCVAR("mastervolume");
271                 BADCVAR("volume");
272                 BADCVAR("bgmvolume");
273
274                 // private
275                 BADCVAR("developer");
276                 BADCVAR("g_banned_list");
277                 BADCVAR("log_dest_udp");
278                 BADCVAR("log_file");
279                 BADCVAR("net_address");
280                 BADCVAR("net_address_ipv6");
281                 BADCVAR("port");
282                 BADCVAR("savedgamecfg");
283                 BADCVAR("serverconfig");
284                 BADCVAR("sv_heartbeatperiod");
285                 BADCVAR("sv_vote_master_password");
286                 BADCVAR("sys_colortranslation");
287                 BADCVAR("sys_specialcharactertranslation");
288                 BADCVAR("timestamps");
289                 BADPREFIX("developer_");
290                 BADPREFIX("g_ban_");
291                 BADPREFIX("g_chat_flood_");
292                 BADPREFIX("g_voice_flood_");
293                 BADPREFIX("rcon_");
294                 BADPREFIX("settemp_");
295                 BADPREFIX("sv_allowdownloads_");
296                 BADPREFIX("sv_autodemo");
297                 BADPREFIX("sv_curl_");
298                 BADPREFIX("sv_eventlog");
299                 BADPREFIX("sv_logscores_");
300                 BADPREFIX("sv_master");
301                 BADPREFIX("sv_weaponstats_");
302
303                 // these can contain player IDs, so better hide
304                 BADCVAR("g_forced_team_red");
305                 BADCVAR("g_forced_team_blue");
306                 BADCVAR("g_forced_team_yellow");
307                 BADCVAR("g_forced_team_pink");
308
309                 // mapinfo
310                 BADCVAR("timelimit");
311                 BADCVAR("fraglimit");
312                 BADCVAR("leadlimit");
313                 BADCVAR("g_tdm_teams");
314                 BADCVAR("g_keyhunt_teams");
315                 BADCVAR("g_domination_default_teams");
316                 BADCVAR("g_race_qualifying_timelimit");
317                 BADCVAR("g_lms");
318                 BADCVAR("g_arena");
319                 BADCVAR("g_ca");
320                 BADCVAR("g_assault");
321                 BADCVAR("g_ctf");
322                 BADCVAR("g_dm");
323                 BADCVAR("g_domination");
324                 BADCVAR("g_keyhunt");
325                 BADCVAR("g_keyhunt_teams");
326                 BADCVAR("g_onslaught");
327                 BADCVAR("g_race");
328                 BADCVAR("g_cts");
329                 BADCVAR("g_runematch");
330                 BADCVAR("g_tdm");
331                 BADCVAR("g_nexball");
332                 BADCVAR("teamplay");
333
334                 // long
335                 BADCVAR("hostname");
336                 BADCVAR("g_maplist");
337                 BADCVAR("g_maplist_mostrecent");
338                 BADCVAR("sv_motd");
339
340                 v = cvar_string(k);
341                 d = cvar_defstring(k);
342                 if(v == d)
343                         continue;
344
345                 if(adding)
346                 {
347                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
348                         if(strlen(cvar_changes) > 16384)
349                         {
350                                 cvar_changes = "// too many settings have been changed to show them here\n";
351                                 adding = 0;
352                         }
353                 }
354
355                 // now check if the changes are actually gameplay relevant
356
357                 // does nothing visible
358                 BADCVAR("captureleadlimit_override");
359                 BADCVAR("g_arena_point_leadlimit");
360                 BADCVAR("g_ca_point_leadlimit");
361                 BADCVAR("g_ctf_capture_leadlimit");
362                 BADCVAR("g_domination_point_leadlimit");
363                 BADCVAR("g_keyhunt_point_leadlimit");
364                 BADCVAR("g_nexball_goalleadlimit");
365                 BADCVAR("g_runematch_point_leadlimit");
366                 BADCVAR("leadlimit_and_fraglimit");
367                 BADCVAR("leadlimit_override");
368                 BADCVAR("sv_checkforpacketsduringsleep");
369                 BADPREFIX("crypto_");
370                 BADPREFIX("g_chat_");
371                 BADPREFIX("net_");
372                 BADPREFIX("prvm_");
373                 BADPREFIX("sv_fragmessage_");
374                 BADPREFIX("sv_vote_");
375                 BADPREFIX("timelimit_");
376
377                 // allowed changes to server admins (please sync this to server.cfg)
378                 // vi commands:
379                 //   :/"impure"/,$d
380                 //   :g!,^\/\/[^ /],d
381                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
382                 //   :%!sort
383                 // yes, this does contain some redundant stuff, don't really care
384                 BADCVAR("bot_number");
385                 BADCVAR("bot_prefix");
386                 BADCVAR("bot_suffix");
387                 BADCVAR("capturelimit_override");
388                 BADCVAR("fraglimit_override");
389                 BADCVAR("gametype");
390                 BADCVAR("g_antilag");
391                 BADCVAR("g_balance_teams");
392                 BADCVAR("g_balance_teams_force");
393                 BADCVAR("g_ban_sync_trusted_servers");
394                 BADCVAR("g_ban_sync_uri");
395                 BADCVAR("g_ctf_capture_limit");
396                 BADCVAR("g_ctf_ignore_frags");
397                 BADCVAR("g_ctf_win_mode");
398                 BADCVAR("g_domination_point_limit");
399                 BADCVAR("g_fullbrightitems");
400                 BADCVAR("g_fullbrightplayers");
401                 BADCVAR("g_keyhunt_point_limit");
402                 BADCVAR("g_keyhunt_teams_override");
403                 BADCVAR("g_lms_lives_override");
404                 BADCVAR("g_maplist");
405                 BADCVAR("g_maplist_check_waypoints");
406                 BADCVAR("g_maplist_mostrecent_count");
407                 BADCVAR("g_maplist_shuffle");
408                 BADCVAR("g_maplist_votable");
409                 BADCVAR("g_maplist_votable_abstain");
410                 BADCVAR("g_maplist_votable_nodetail");
411                 BADCVAR("g_maplist_votable_suggestions");
412                 BADCVAR("g_minstagib");
413                 BADCVAR("g_nexball_goallimit");
414                 BADCVAR("g_runematch_point_limit");
415                 BADCVAR("g_start_delay");
416                 BADCVAR("hostname");
417                 BADCVAR("log_file");
418                 BADCVAR("maxplayers");
419                 BADCVAR("minplayers");
420                 BADCVAR("net_address");
421                 BADCVAR("port");
422                 BADCVAR("rcon_password");
423                 BADCVAR("rcon_restricted_commands");
424                 BADCVAR("rcon_restricted_password");
425                 BADCVAR("skill");
426                 BADCVAR("sv_adminnick");
427                 BADCVAR("sv_autoscreenshot");
428                 BADCVAR("sv_curl_defaulturl");
429                 BADCVAR("sv_defaultcharacter");
430                 BADCVAR("sv_defaultplayermodel");
431                 BADCVAR("sv_defaultplayerskin");
432                 BADCVAR("sv_maxidle");
433                 BADCVAR("sv_maxrate");
434                 BADCVAR("sv_motd");
435                 BADCVAR("sv_public");
436                 BADCVAR("sv_ready_restart");
437                 BADCVAR("sv_status_privacy");
438                 BADCVAR("sv_vote_call");
439                 BADCVAR("sv_vote_commands");
440                 BADCVAR("sv_vote_majority_factor");
441                 BADCVAR("sv_vote_master");
442                 BADCVAR("sv_vote_master_commands");
443                 BADCVAR("sv_vote_master_password");
444                 BADCVAR("sv_vote_simple_majority_factor");
445                 BADCVAR("timelimit_override");
446
447                 if(cvar("g_minstagib"))
448                 {
449                         BADCVAR("g_grappling_hook");
450                         BADCVAR("g_jetpack");
451                 }
452 #undef BADPREFIX
453 #undef BADCVAR
454
455                 if(pureadding)
456                 {
457                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
458                         if(strlen(cvar_purechanges) > 16384)
459                         {
460                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
461                                 pureadding = 0;
462                         }
463                 }
464                 ++cvar_purechanges_count;
465                 // WARNING: this variable is used for the server list
466                 // NEVER dare to skip this code!
467                 // Hacks to intentionally appearing as "pure server" even though you DO have
468                 // modified settings may be punished by removal from the server list.
469                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
470                 // though.
471         }
472         buf_del(h);
473         if(cvar_changes == "")
474                 cvar_changes = "// this server runs at default server settings\n";
475         else
476                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
477         cvar_changes = strzone(cvar_changes);
478         if(cvar_purechanges == "")
479                 cvar_purechanges = "// this server runs at default gameplay settings\n";
480         else
481                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
482         cvar_purechanges = strzone(cvar_purechanges);
483 }
484
485 void detect_maptype()
486 {
487 #if 0
488         vector o, v;
489         float i;
490
491         for(;;)
492         {
493                 o = world.mins;
494                 o_x += random() * (world.maxs_x - world.mins_x);
495                 o_y += random() * (world.maxs_y - world.mins_y);
496                 o_z += random() * (world.maxs_z - world.mins_z);
497
498                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
499                 if(trace_fraction == 1)
500                         continue;
501
502                 v = trace_endpos;
503
504                 for(i = 0; i < 64; i += 4)
505                 {
506                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
507         if(trace_fraction == 1)
508                 continue;
509                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
510                 }
511
512                 break;
513         }
514 #endif
515 }
516
517 entity randomseed;
518 float RandomSeed_Send(entity to, float sf)
519 {
520         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
521         WriteShort(MSG_ENTITY, self.cnt);
522         return TRUE;
523 }
524 void RandomSeed_Think()
525 {
526         self.cnt = bound(0, floor(random() * 65536), 65535);
527         self.nextthink = time + 5;
528
529         self.SendFlags |= 1;
530 }
531 void RandomSeed_Spawn()
532 {
533         randomseed = spawn();
534         randomseed.think = RandomSeed_Think;
535         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
536
537         entity oldself;
538         oldself = self;
539         self = randomseed;
540         self.think(); // sets random seed and nextthink
541         self = oldself;
542 }
543
544 void spawnfunc___init_dedicated_server(void)
545 {
546         // handler for _init/_init map (only for dedicated server initialization)
547
548         world_initialized = -1; // don't complain
549         cvar = cvar_normal;
550         cvar_string = cvar_string_normal;
551         cvar_set = cvar_set_normal;
552
553         remove = remove_unsafely;
554
555         entity e;
556         e = spawn();
557         e.think = GotoFirstMap;
558         e.nextthink = time; // this is usually 1 at this point
559
560         e = spawn();
561         e.classname = "info_player_deathmatch"; // safeguard against player joining
562
563         self.classname = "worldspawn"; // safeguard against various stuff ;)
564
565         MapInfo_Enumerate();
566         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
567 }
568
569 void Map_MarkAsRecent(string m);
570 float world_already_spawned;
571 void RegisterWeapons();
572 void Nagger_Init();
573 void ClientInit_Spawn();
574 void WeaponStats_Init();
575 void WeaponStats_Shutdown();
576 void spawnfunc_worldspawn (void)
577 {
578         float fd, l, i, j, n;
579         string s, col;
580
581         cvar = cvar_normal;
582         cvar_string = cvar_string_normal;
583         cvar_set = cvar_set_normal;
584
585         if(world_already_spawned)
586                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
587         world_already_spawned = TRUE;
588
589         remove = remove_safely; // during spawning, watch what you remove!
590
591         check_unacceptable_compiler_bugs();
592
593         cvar_changes_init(); // do this very early now so it REALLY matches the server config
594
595         compressShortVector_init();
596
597         allowed_to_spawn = TRUE;
598
599         local entity head;
600         head = nextent(world);
601         maxclients = 0;
602         while(head)
603         {
604                 ++maxclients;
605                 head = nextent(head);
606         }
607
608         // needs to be done so early as they would still spawn
609         RegisterWeapons();
610
611         ServerProgsDB = db_load("server.db");
612
613         TemporaryDB = db_create();
614
615         /*
616         TODO sound pack system
617         // initialize sound pack system
618         soundpack = cvar_string("g_soundpack");
619         if(soundpack != "")
620                 soundpack = strcat(soundpack, "/");
621         soundpack = strzone(soundpack);
622         */
623
624         // 0 normal
625         lightstyle(0, "m");
626
627         // 1 FLICKER (first variety)
628         lightstyle(1, "mmnmmommommnonmmonqnmmo");
629
630         // 2 SLOW STRONG PULSE
631         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
632
633         // 3 CANDLE (first variety)
634         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
635
636         // 4 FAST STROBE
637         lightstyle(4, "mamamamamama");
638
639         // 5 GENTLE PULSE 1
640         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
641
642         // 6 FLICKER (second variety)
643         lightstyle(6, "nmonqnmomnmomomno");
644
645         // 7 CANDLE (second variety)
646         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
647
648         // 8 CANDLE (third variety)
649         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
650
651         // 9 SLOW STROBE (fourth variety)
652         lightstyle(9, "aaaaaaaazzzzzzzz");
653
654         // 10 FLUORESCENT FLICKER
655         lightstyle(10, "mmamammmmammamamaaamammma");
656
657         // 11 SLOW PULSE NOT FADE TO BLACK
658         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
659
660         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
661
662         // 63 testing
663         lightstyle(63, "a");
664
665         if(cvar("g_campaign"))
666                 CampaignPreInit();
667
668         Map_MarkAsRecent(mapname);
669
670         precache_model ("null"); // we need this one before InitGameplayMode
671         InitGameplayMode();
672         readlevelcvars();
673         GrappleHookInit();
674         ElectroInit();
675         LaserInit();
676
677         player_count = 0;
678         bot_waypoints_for_items = cvar("g_waypoints_for_items");
679         if(bot_waypoints_for_items == 1)
680                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
681                         bot_waypoints_for_items = 0;
682
683         // for setting by mapinfo
684         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
685         cvar_set("sv_q3acompat_machineshotgunswap", "0");
686
687         precache();
688
689         WaypointSprite_Init();
690
691         //if (g_domination)
692         //      dom_init();
693
694         GameLogInit(); // prepare everything
695         if(cvar("sv_eventlog"))
696         {
697                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
698                 s = strcat(s, ftos(random()));
699                 matchid = strzone(s);
700
701                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
702                 s = ":gameinfo:mutators:LIST";
703
704                 ret_string = s;
705                 MUTATOR_CALLHOOK(BuildMutatorsString);
706                 s = ret_string;
707
708                 // simple, probably not good in the mutator system
709                 if(cvar("g_grappling_hook"))
710                         s = strcat(s, ":grappling_hook");
711
712                 // initialiation stuff, not good in the mutator system
713                 if(!cvar("g_use_ammunition"))
714                         s = strcat(s, ":no_use_ammunition");
715
716                 // initialiation stuff, not good in the mutator system
717                 if(!cvar("g_pickup_items"))
718                         s = strcat(s, ":no_pickup_items");
719
720                 // initialiation stuff, not good in the mutator system
721                 if(cvar_string("g_weaponarena") != "0")
722                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
723
724                 // TODO to mutator system
725                 if(cvar("g_norecoil"))
726                         s = strcat(s, ":norecoil");
727
728                 // TODO to mutator system
729                 if(cvar("g_midair"))
730                         s = strcat(s, ":midair");
731
732                 // TODO to mutator system
733                 if(cvar("g_minstagib"))
734                         s = strcat(s, ":minstagib");
735
736                 GameLogEcho(s);
737                 GameLogEcho(":gameinfo:end");
738         }
739         else
740                 matchid = strzone(ftos(random()));
741
742         cvar_set("nextmap", "");
743
744         SetDefaultAlpha();
745
746         if(cvar("g_campaign"))
747                 CampaignPostInit();
748
749         fteqcc_testbugs();
750
751         Ban_LoadBans();
752
753         MapInfo_Enumerate();
754         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
755
756         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
757         {
758                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
759                 if(fd != -1)
760                 {
761                         while((s = fgets(fd)))
762                         {
763                                 l = tokenize_console(s);
764                                 if(l < 2)
765                                         continue;
766                                 if(argv(0) == "cd")
767                                 {
768                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
769                                         print("  cdtrack ", argv(2), "\n");
770                                 }
771                                 else if(argv(0) == "fog")
772                                 {
773                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
774                                         print("  \"fog\" \"", s, "\"\n");
775                                 }
776                                 else if(argv(0) == "set")
777                                 {
778                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
779                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
780                                 }
781                                 else if(argv(0) != "//")
782                                 {
783                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
784                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
785                                 }
786                         }
787                         fclose(fd);
788                 }
789         }
790
791         WeaponStats_Init();
792
793         addstat(STAT_WEAPONS, AS_INT, weapons);
794         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
795         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
796         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
797         Nagger_Init();
798
799         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
800         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
801         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
802         addstat(STAT_FUEL, AS_INT, ammo_fuel);
803         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
804         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
805         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
806         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
807         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
808         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
809
810         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
811
812         if(g_ca)
813         {
814                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
815                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
816         }
817         // g_movementspeed hack
818         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
819         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
820         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
821
822         next_pingtime = time + 5;
823
824         detect_maptype();
825
826         lsmaps_reply = "^7Maps available: ";
827         lsnewmaps_reply = "^7Maps without a record set: ";
828         for(i = 0, j = 0; i < MapInfo_count; ++i)
829         {
830                 if(MapInfo_Get_ByID(i))
831                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
832                         {
833                                 if(mod(i, 2))
834                                         col = "^2";
835                                 else
836                                         col = "^3";
837                                 ++j;
838                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
839                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
840                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
841                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
842                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
843                         }
844         }
845         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
846         if (!g_race && !g_cts)
847                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
848         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
849
850         maplist_reply = "^7Maps in list: ";
851         n = tokenize_console(cvar_string("g_maplist"));
852         for(i = 0, j = 0; i < n; ++i)
853         {
854                 if(MapInfo_CheckMap(argv(i)))
855                 {
856                         if(mod(j, 2))
857                                 col = "^2";
858                         else
859                                 col = "^3";
860                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
861                         ++j;
862                 }
863         }
864         maplist_reply = strzone(strcat(maplist_reply, "\n"));
865         MapInfo_ClearTemps();
866
867         for(i = 0; i < 10; ++i)
868         {
869                 records_reply[i] = strzone(getrecords(i));
870         }
871         if(g_cts)
872                 ladder_reply = strzone(getladder());
873
874         rankings_reply = strzone(getrankings());
875
876         ClientInit_Spawn();
877         RandomSeed_Spawn();
878         PingPLReport_Spawn();
879
880         CheatInit();
881
882         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
883
884         // fill sv_curl_serverpackages from .serverpackage files
885         if(cvar("sv_curl_serverpackages_auto"))
886         {
887                 fd = search_begin("*.serverpackage", TRUE, FALSE);
888                 s = "";
889                 if(fd >= 0)
890                 {
891                         j = search_getsize(fd);
892                         for(i = 0; i < j; ++i)
893                                 s = strcat(s, " ", search_getfilename(fd, i));
894                         search_end(fd);
895                 }
896                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
897         }
898
899         world_initialized = 1;
900 }
901
902 void spawnfunc_light (void)
903 {
904         //makestatic (self); // Who the f___ did that?
905         remove(self);
906 }
907
908 float TryFile( string pFilename )
909 {
910         local float lHandle;
911         dprint("TryFile(\"", pFilename, "\")\n");
912         lHandle = fopen( pFilename, FILE_READ );
913         if( lHandle != -1 ) {
914                 fclose( lHandle );
915                 return TRUE;
916         } else {
917                 return FALSE;
918         }
919 };
920
921 string GetGametype()
922 {
923         return GametypeNameFromType(game);
924 }
925
926 string getmapname_stored;
927 string GetMapname()
928 {
929         return mapname;
930 }
931
932 float Map_Count, Map_Current;
933 string Map_Current_Name;
934
935 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
936 float GetMaplistPosition()
937 {
938         float pos, idx;
939         string map;
940
941         map = GetMapname();
942         idx = cvar("g_maplist_index");
943
944         if(idx >= 0)
945                 if(idx < Map_Count)
946                         if(map == argv(idx))
947                                 return idx;
948
949         for(pos = 0; pos < Map_Count; ++pos)
950                 if(map == argv(pos))
951                         return pos;
952
953         // resume normal maplist rotation if current map is not in g_maplist
954         return idx;
955 }
956
957 float MapHasRightSize(string map)
958 {
959         float fh;
960         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
961         if(cvar("g_maplist_check_waypoints"))
962         {
963                 dprint("checkwp "); dprint(map);
964                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
965                 if(fh < 0)
966                 {
967                         dprint(": no waypoints\n");
968                         return FALSE;
969                 }
970                 dprint(": has waypoints\n");
971                 fclose(fh);
972         }
973
974         // open map size restriction file
975         dprint("opensize "); dprint(map);
976         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
977         if(fh >= 0)
978         {
979                 float mapmin, mapmax;
980                 dprint(": ok, ");
981                 mapmin = stof(fgets(fh));
982                 mapmax = stof(fgets(fh));
983                 fclose(fh);
984                 if(player_count < mapmin)
985                 {
986                         dprint("not enough\n");
987                         return FALSE;
988                 }
989                 if(player_count > mapmax)
990                 {
991                         dprint("too many\n");
992                         return FALSE;
993                 }
994                 dprint("right size\n");
995                 return TRUE;
996         }
997         dprint(": not found\n");
998         return TRUE;
999 }
1000
1001 string Map_Filename(float position)
1002 {
1003         return strcat("maps/", argv(position), ".bsp");
1004 }
1005
1006 string strwords(string s, float w)
1007 {
1008         float endpos;
1009         for(endpos = 0; w && endpos >= 0; --w)
1010                 endpos = strstrofs(s, " ", endpos + 1);
1011         if(endpos < 0)
1012                 return s;
1013         else
1014                 return substring(s, 0, endpos);
1015 }
1016
1017 float strhasword(string s, string w)
1018 {
1019         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1020 }
1021
1022 void Map_MarkAsRecent(string m)
1023 {
1024         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1025 }
1026
1027 float Map_IsRecent(string m)
1028 {
1029         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1030 }
1031
1032 float Map_Check(float position, float pass)
1033 {
1034         string filename;
1035         string map_next;
1036         map_next = argv(position);
1037         if(pass <= 1)
1038         {
1039                 if(Map_IsRecent(map_next))
1040                         return 0;
1041         }
1042         filename = Map_Filename(position);
1043         if(MapInfo_CheckMap(map_next))
1044         {
1045                 if(pass == 2)
1046                         return 1;
1047                 if(MapHasRightSize(map_next))
1048                         return 1;
1049                 return 0;
1050         }
1051         else
1052                 dprint( "Couldn't select '", filename, "'..\n" );
1053
1054         return 0;
1055 }
1056
1057 void Map_Goto_SetStr(string nextmapname)
1058 {
1059         if(getmapname_stored != "")
1060                 strunzone(getmapname_stored);
1061         if(nextmapname == "")
1062                 getmapname_stored = "";
1063         else
1064                 getmapname_stored = strzone(nextmapname);
1065 }
1066
1067 void Map_Goto_SetFloat(float position)
1068 {
1069         cvar_set("g_maplist_index", ftos(position));
1070         Map_Goto_SetStr(argv(position));
1071 }
1072
1073 void GameResetCfg()
1074 {
1075         // settings persist, except...
1076         localcmd("\nsettemp_restore\n");
1077 };
1078
1079 void Map_Goto()
1080 {
1081         GameResetCfg();
1082         MapInfo_LoadMap(getmapname_stored);
1083 }
1084
1085 // return codes of map selectors:
1086 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1087 //   -2 = permanent failure
1088 float() MaplistMethod_Iterate = // usual method
1089 {
1090         float pass, i;
1091
1092         for(pass = 1; pass <= 2; ++pass)
1093         {
1094                 for(i = 1; i < Map_Count; ++i)
1095                 {
1096                         float mapindex;
1097                         mapindex = mod(i + Map_Current, Map_Count);
1098                         if(Map_Check(mapindex, pass))
1099                                 return mapindex;
1100                 }
1101         }
1102         return -1;
1103 }
1104
1105 float() MaplistMethod_Repeat = // fallback method
1106 {
1107         if(Map_Check(Map_Current, 2))
1108                 return Map_Current;
1109         return -2;
1110 }
1111
1112 float() MaplistMethod_Random = // random map selection
1113 {
1114         float i, imax;
1115
1116         imax = 42;
1117
1118         for(i = 0; i <= imax; ++i)
1119         {
1120                 float mapindex;
1121                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1122                 if(Map_Check(mapindex, 1))
1123                         return mapindex;
1124         }
1125         return -1;
1126 }
1127
1128 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1129 // the exponent sets a bias on the map selection:
1130 // the higher the exponent, the less likely "shortly repeated" same maps are
1131 {
1132         float i, j, imax, insertpos;
1133
1134         imax = 42;
1135
1136         for(i = 0; i <= imax; ++i)
1137         {
1138                 string newlist;
1139
1140                 // now reinsert this at another position
1141                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1142                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1143                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1144                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1145
1146                 // insert the current map there
1147                 newlist = "";
1148                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1149                         newlist = strcat(newlist, " ", argv(j));
1150                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1151                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1152                         newlist = strcat(newlist, " ", argv(j));
1153                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1154                 cvar_set("g_maplist", newlist);
1155                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1156
1157                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1158                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1159                 if(Map_Check(Map_Current, 1))
1160                         return Map_Current;
1161         }
1162         return -1;
1163 }
1164
1165 void Maplist_Init()
1166 {
1167         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1168         if(Map_Count == 0)
1169         {
1170                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1171                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1172                 if(cvar("g_maplist_shuffle"))
1173                         ShuffleMaplist();
1174                 localcmd("\nmenu_cmd sync\n");
1175                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1176         }
1177         if(Map_Count == 0)
1178                 error("empty maplist, cannot select a new map");
1179         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1180
1181         if(Map_Current_Name)
1182                 strunzone(Map_Current_Name);
1183         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1184         // this may or may not be correct, but who cares, in the worst case a map
1185         // isn't chosen in the first pass that should have been
1186 }
1187
1188 string GetNextMap()
1189 {
1190         float nextMap;
1191
1192         Maplist_Init();
1193         nextMap = -1;
1194
1195         if(nextMap == -1)
1196                 if(cvar("g_maplist_shuffle") > 0)
1197                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1198
1199         if(nextMap == -1)
1200                 if(cvar("g_maplist_selectrandom"))
1201                         nextMap = MaplistMethod_Random();
1202
1203         if(nextMap == -1)
1204                 nextMap = MaplistMethod_Iterate();
1205
1206         if(nextMap == -1)
1207                 nextMap = MaplistMethod_Repeat();
1208
1209         if(nextMap >= 0)
1210         {
1211                 Map_Goto_SetFloat(nextMap);
1212                 return getmapname_stored;
1213         }
1214
1215         return "";
1216 };
1217
1218 float DoNextMapOverride()
1219 {
1220         if(cvar("g_campaign"))
1221         {
1222                 CampaignPostIntermission();
1223                 alreadychangedlevel = TRUE;
1224                 return TRUE;
1225         }
1226         if(cvar("quit_when_empty"))
1227         {
1228                 if(player_count <= currentbots)
1229                 {
1230                         localcmd("quit\n");
1231                         alreadychangedlevel = TRUE;
1232                         return TRUE;
1233                 }
1234         }
1235         if(cvar_string("quit_and_redirect") != "")
1236         {
1237                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1238                 alreadychangedlevel = TRUE;
1239                 return TRUE;
1240         }
1241         if (cvar("samelevel")) // if samelevel is set, stay on same level
1242         {
1243                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1244                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1245                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1246                 localcmd("restart\n");
1247                 //changelevel (mapname);
1248                 alreadychangedlevel = TRUE;
1249                 return TRUE;
1250         }
1251         if(cvar_string("nextmap") != "")
1252                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1253                 {
1254                         Map_Goto_SetStr(cvar_string("nextmap"));
1255                         Map_Goto();
1256                         alreadychangedlevel = TRUE;
1257                         return TRUE;
1258                 }
1259         if(cvar("lastlevel"))
1260         {
1261                 GameResetCfg();
1262                 localcmd("set lastlevel 0\ntogglemenu\n");
1263                 alreadychangedlevel = TRUE;
1264                 return TRUE;
1265         }
1266         return FALSE;
1267 };
1268
1269 void GotoNextMap()
1270 {
1271         //local string nextmap;
1272         //local float n, nummaps;
1273         //local string s;
1274         if (alreadychangedlevel)
1275                 return;
1276         alreadychangedlevel = TRUE;
1277
1278         {
1279                 string nextMap;
1280                 float allowReset;
1281
1282                 for(allowReset = 1; allowReset >= 0; --allowReset)
1283                 {
1284                         nextMap = GetNextMap();
1285                         if(nextMap != "")
1286                                 break;
1287
1288                         if(allowReset)
1289                         {
1290                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1291                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1292                                 if(cvar("g_maplist_shuffle"))
1293                                         ShuffleMaplist();
1294                                 localcmd("\nmenu_cmd sync\n");
1295                         }
1296                         else
1297                         {
1298                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1299                         }
1300                 }
1301                 Map_Goto();
1302         }
1303 };
1304
1305
1306 /*
1307 ============
1308 IntermissionThink
1309
1310 When the player presses attack or jump, change to the next level
1311 ============
1312 */
1313 .float autoscreenshot;
1314 void() MapVote_Start;
1315 void() MapVote_Think;
1316 float mapvote_initialized;
1317 void IntermissionThink()
1318 {
1319         FixIntermissionClient(self);
1320
1321         if(cvar("sv_autoscreenshot"))
1322         if(self.autoscreenshot > 0)
1323         if(time > self.autoscreenshot)
1324         {
1325                 self.autoscreenshot = -1;
1326                 if(clienttype(self) == CLIENTTYPE_REAL)
1327                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1328                 return;
1329         }
1330
1331         if (time < intermission_exittime)
1332                 return;
1333
1334         if(!mapvote_initialized)
1335                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1336                         return;
1337
1338         MapVote_Start();
1339 };
1340
1341 /*
1342 ============
1343 FindIntermission
1344
1345 Returns the entity to view from
1346 ============
1347 */
1348 /*
1349 entity FindIntermission()
1350 {
1351         local   entity spot;
1352         local   float cyc;
1353
1354 // look for info_intermission first
1355         spot = find (world, classname, "info_intermission");
1356         if (spot)
1357         {       // pick a random one
1358                 cyc = random() * 4;
1359                 while (cyc > 1)
1360                 {
1361                         spot = find (spot, classname, "info_intermission");
1362                         if (!spot)
1363                                 spot = find (spot, classname, "info_intermission");
1364                         cyc = cyc - 1;
1365                 }
1366                 return spot;
1367         }
1368
1369 // then look for the start position
1370         spot = find (world, classname, "info_player_start");
1371         if (spot)
1372                 return spot;
1373
1374 // testinfo_player_start is only found in regioned levels
1375         spot = find (world, classname, "testplayerstart");
1376         if (spot)
1377                 return spot;
1378
1379 // then look for the start position
1380         spot = find (world, classname, "info_player_deathmatch");
1381         if (spot)
1382                 return spot;
1383
1384         //objerror ("FindIntermission: no spot");
1385         return world;
1386 };
1387 */
1388
1389 /*
1390 ===============================================================================
1391
1392 RULES
1393
1394 ===============================================================================
1395 */
1396
1397 void DumpStats(float final)
1398 {
1399         local float file;
1400         local string s;
1401         local float to_console;
1402         local float to_eventlog;
1403         local float to_file;
1404         local float i;
1405
1406         to_console = cvar("sv_logscores_console");
1407         to_eventlog = cvar("sv_eventlog");
1408         to_file = cvar("sv_logscores_file");
1409
1410         if(!final)
1411         {
1412                 to_console = TRUE; // always print printstats replies
1413                 to_eventlog = FALSE; // but never print them to the event log
1414         }
1415
1416         if(to_eventlog)
1417                 if(cvar("sv_eventlog_console"))
1418                         to_console = FALSE; // otherwise we get the output twice
1419
1420         if(final)
1421                 s = ":scores:";
1422         else
1423                 s = ":status:";
1424         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1425
1426         if(to_console)
1427                 print(s, "\n");
1428         if(to_eventlog)
1429                 GameLogEcho(s);
1430         if(to_file)
1431         {
1432                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1433                 if(file == -1)
1434                         to_file = FALSE;
1435                 else
1436                         fputs(file, strcat(s, "\n"));
1437         }
1438
1439         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1440         if(to_console)
1441                 print(s, "\n");
1442         if(to_eventlog)
1443                 GameLogEcho(s);
1444         if(to_file)
1445                 fputs(file, strcat(s, "\n"));
1446
1447         FOR_EACH_CLIENT(other)
1448         {
1449                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1450                 {
1451                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1452                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1453                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1454                                 s = strcat(s, ftos(other.team), ":");
1455                         else
1456                                 s = strcat(s, "spectator:");
1457
1458                         if(to_console)
1459                                 print(s, other.netname, "\n");
1460                         if(to_eventlog)
1461                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1462                         if(to_file)
1463                                 fputs(file, strcat(s, other.netname, "\n"));
1464                 }
1465         }
1466
1467         if(teams_matter)
1468         {
1469                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1470                 if(to_console)
1471                         print(s, "\n");
1472                 if(to_eventlog)
1473                         GameLogEcho(s);
1474                 if(to_file)
1475                         fputs(file, strcat(s, "\n"));
1476
1477                 for(i = 1; i < 16; ++i)
1478                 {
1479                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1480                         s = strcat(s, ":", ftos(i));
1481                         if(to_console)
1482                                 print(s, "\n");
1483                         if(to_eventlog)
1484                                 GameLogEcho(s);
1485                         if(to_file)
1486                                 fputs(file, strcat(s, "\n"));
1487                 }
1488         }
1489
1490         if(to_console)
1491                 print(":end\n");
1492         if(to_eventlog)
1493                 GameLogEcho(":end");
1494         if(to_file)
1495         {
1496                 fputs(file, ":end\n");
1497                 fclose(file);
1498         }
1499 }
1500
1501 void FixIntermissionClient(entity e)
1502 {
1503         string s;
1504         if(!e.autoscreenshot) // initial call
1505         {
1506                 e.angles = e.v_angle;
1507                 e.angles_x = -e.angles_x;
1508                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1509                 e.health = -2342;
1510                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1511                 e.solid = SOLID_NOT;
1512                 e.movetype = MOVETYPE_NONE;
1513                 e.takedamage = DAMAGE_NO;
1514                 if(e.weaponentity)
1515                 {
1516                         e.weaponentity.effects = EF_NODRAW;
1517                         if (e.weaponentity.weaponentity)
1518                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1519                 }
1520                 if(clienttype(e) == CLIENTTYPE_REAL)
1521                 {
1522                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1523                         s = cvar_string("sv_intermission_cdtrack");
1524                         if(s != "")
1525                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1526                         msg_entity = e;
1527                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1528                 }
1529         }
1530
1531         //e.velocity = '0 0 0';
1532         //e.fixangle = TRUE;
1533
1534         // TODO halt weapon animation
1535 }
1536
1537
1538 /*
1539 go to the next level for deathmatch
1540 only called if a time or frag limit has expired
1541 */
1542 void NextLevel()
1543 {
1544         float i;
1545
1546         gameover = TRUE;
1547
1548         intermission_running = 1;
1549
1550 // enforce a wait time before allowing changelevel
1551         if(player_count > 0)
1552                 intermission_exittime = time + cvar("sv_mapchange_delay");
1553         else
1554                 intermission_exittime = -1;
1555
1556         /*
1557         WriteByte (MSG_ALL, SVC_CDTRACK);
1558         WriteByte (MSG_ALL, 3);
1559         WriteByte (MSG_ALL, 3);
1560         // done in FixIntermission
1561         */
1562
1563         //pos = FindIntermission ();
1564
1565         VoteReset();
1566
1567         DumpStats(TRUE);
1568
1569         if(cvar("sv_eventlog"))
1570                 GameLogEcho(":gameover");
1571
1572         GameLogClose();
1573
1574 // TO DO
1575
1576 // save the stats to a text file on the client
1577 // stuffcmd(other, log_stats "stats/file_name");
1578 // bprint stats
1579 // stuffcmd(other, log_stats "");
1580 // use a filename similar to the demo name
1581         // string file_name;
1582         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1583
1584 // write a stats parser for the menu
1585
1586         if(cvar("sv_accuracy_data_send")) {
1587                 string stats_to_send;
1588
1589                 FOR_EACH_CLIENT(other) {  // make the string to send
1590                         FixIntermissionClient(other);
1591
1592                         if(other.cvar_cl_accuracy_data_share) {
1593                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1594
1595                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1596                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1597
1598                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1599
1600                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1601                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1602
1603                                 stats_to_send = strcat(stats_to_send, "\n");
1604                         }
1605                 }
1606
1607                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1608                         Score_NicePrint(other);  // print the score
1609
1610                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1611                                 bprint(stats_to_send);
1612                 }
1613         } else { // ye olde message
1614                 FOR_EACH_PLAYER(other) {
1615                         FixIntermissionClient(other);
1616
1617                         if(other.winning)
1618                                 bprint(other.netname, " ^7wins.\n");
1619                 }
1620         }
1621
1622         if(cvar("g_campaign"))
1623                 CampaignPreIntermission();
1624
1625         localcmd("\nsv_hook_gameend\n");
1626 }
1627
1628 /*
1629 ============
1630 CheckRules_Player
1631
1632 Exit deathmatch games upon conditions
1633 ============
1634 */
1635 void CheckRules_Player()
1636 {
1637         if (gameover)   // someone else quit the game already
1638                 return;
1639
1640         if(self.deadflag == DEAD_NO)
1641                 self.play_time += frametime;
1642
1643         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1644         //   (div0: and that in CheckRules_World please)
1645 };
1646
1647 float checkrules_equality;
1648 float checkrules_suddendeathwarning;
1649 float checkrules_suddendeathend;
1650 float checkrules_overtimesadded; //how many overtimes have been already added
1651
1652 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1653 float WINNING_YES = 1; // winner found
1654 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1655 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1656
1657 float InitiateSuddenDeath()
1658 {
1659         // Check first whether normal overtimes could be added before initiating suddendeath mode
1660         // - for this timelimit_overtime needs to be >0 of course
1661         // - also check the winning condition calculated in the previous frame and only add normal overtime
1662         //   again, if at the point at which timelimit would be extended again, still no winner was found
1663         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1664         {
1665                 return 1; // need to call InitiateOvertime later
1666         }
1667         else
1668         {
1669                 if(!checkrules_suddendeathend)
1670                 {
1671                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1672                         if(g_race && !g_race_qualifying)
1673                                 race_StartCompleting();
1674                 }
1675                 return 0;
1676         }
1677 }
1678
1679 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1680 {
1681         ++checkrules_overtimesadded;
1682         //add one more overtime by simply extending the timelimit
1683         float tl;
1684         tl = cvar("timelimit");
1685         tl += cvar("timelimit_overtime");
1686         cvar_set("timelimit", ftos(tl));
1687         string minutesPlural;
1688         if (cvar("timelimit_overtime") == 1)
1689                 minutesPlural = " ^3minute";
1690         else
1691                 minutesPlural = " ^3minutes";
1692
1693         bcenterprint(
1694                 strcat(
1695                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1696                         ftos(cvar("timelimit_overtime")),
1697                         minutesPlural,
1698                         " to the game!"
1699                 )
1700         );
1701 }
1702
1703 float GetWinningCode(float fraglimitreached, float equality)
1704 {
1705         if(cvar("g_campaign") == 1)
1706                 if(fraglimitreached)
1707                         return WINNING_YES;
1708                 else
1709                         return WINNING_NO;
1710
1711         else
1712                 if(equality)
1713                         if(fraglimitreached)
1714                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1715                         else
1716                                 return WINNING_NEVER;
1717                 else
1718                         if(fraglimitreached)
1719                                 return WINNING_YES;
1720                         else
1721                                 return WINNING_NO;
1722 }
1723
1724 // set the .winning flag for exactly those players with a given field value
1725 void SetWinners(.float field, float value)
1726 {
1727         entity head;
1728         FOR_EACH_PLAYER(head)
1729                 head.winning = (head.field == value);
1730 }
1731
1732 // set the .winning flag for those players with a given field value
1733 void AddWinners(.float field, float value)
1734 {
1735         entity head;
1736         FOR_EACH_PLAYER(head)
1737                 if(head.field == value)
1738                         head.winning = 1;
1739 }
1740
1741 // clear the .winning flags
1742 void ClearWinners(void)
1743 {
1744         entity head;
1745         FOR_EACH_PLAYER(head)
1746                 head.winning = 0;
1747 }
1748
1749 // Onslaught winning condition:
1750 // game terminates if only one team has a working generator (or none)
1751 float WinningCondition_Onslaught()
1752 {
1753         entity head;
1754         local float t1, t2, t3, t4;
1755
1756         WinningConditionHelper(); // set worldstatus
1757
1758         if(inWarmupStage)
1759                 return WINNING_NO;
1760
1761         // first check if the game has ended
1762         t1 = t2 = t3 = t4 = 0;
1763         head = find(world, classname, "onslaught_generator");
1764         while (head)
1765         {
1766                 if (head.health > 0)
1767                 {
1768                         if (head.team == COLOR_TEAM1) t1 = 1;
1769                         if (head.team == COLOR_TEAM2) t2 = 1;
1770                         if (head.team == COLOR_TEAM3) t3 = 1;
1771                         if (head.team == COLOR_TEAM4) t4 = 1;
1772                 }
1773                 head = find(head, classname, "onslaught_generator");
1774         }
1775         if (t1 + t2 + t3 + t4 < 2)
1776         {
1777                 // game over, only one team remains (or none)
1778                 ClearWinners();
1779                 if (t1) SetWinners(team, COLOR_TEAM1);
1780                 if (t2) SetWinners(team, COLOR_TEAM2);
1781                 if (t3) SetWinners(team, COLOR_TEAM3);
1782                 if (t4) SetWinners(team, COLOR_TEAM4);
1783                 dprint("Have a winner, ending game.\n");
1784                 return WINNING_YES;
1785         }
1786
1787         // Two or more teams remain
1788         return WINNING_NO;
1789 }
1790
1791 float LMS_NewPlayerLives()
1792 {
1793         float fl;
1794         fl = cvar("fraglimit");
1795         if(fl == 0)
1796                 fl = 999;
1797
1798         // first player has left the game for dying too much? Nobody else can get in.
1799         if(lms_lowest_lives < 1)
1800                 return 0;
1801
1802         if(!cvar("g_lms_join_anytime"))
1803                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1804                         return 0;
1805
1806         return bound(1, lms_lowest_lives, fl);
1807 }
1808
1809 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1810 // they win. Otherwise the defending team wins once the timelimit passes.
1811 void assault_new_round();
1812 float WinningCondition_Assault()
1813 {
1814         local float status;
1815
1816         WinningConditionHelper(); // set worldstatus
1817
1818         status = WINNING_NO;
1819         // as the timelimit has not yet passed just assume the defending team will win
1820         if(assault_attacker_team == COLOR_TEAM1)
1821         {
1822                 SetWinners(team, COLOR_TEAM2);
1823         }
1824         else
1825         {
1826                 SetWinners(team, COLOR_TEAM1);
1827         }
1828
1829         local entity ent;
1830         ent = find(world, classname, "target_assault_roundend");
1831         if(ent)
1832         {
1833                 if(ent.winning) // round end has been triggered by attacking team
1834                 {
1835                         bprint("ASSAULT: round completed...\n");
1836                         SetWinners(team, assault_attacker_team);
1837
1838                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1839
1840                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1841                         {
1842                                 status = WINNING_YES;
1843                         }
1844                         else
1845                         {
1846                                 local entity oldself;
1847                                 oldself = self;
1848                                 self = ent;
1849                                 assault_new_round();
1850                                 self = oldself;
1851                         }
1852                 }
1853         }
1854
1855         return status;
1856 }
1857
1858 // LMS winning condition: game terminates if and only if there's at most one
1859 // one player who's living lives. Top two scores being equal cancels the time
1860 // limit.
1861 float WinningCondition_LMS()
1862 {
1863         entity head, head2;
1864         float have_player;
1865         float have_players;
1866         float l;
1867
1868         have_player = FALSE;
1869         have_players = FALSE;
1870         l = LMS_NewPlayerLives();
1871
1872         head = find(world, classname, "player");
1873         if(head)
1874                 have_player = TRUE;
1875         head2 = find(head, classname, "player");
1876         if(head2)
1877                 have_players = TRUE;
1878
1879         if(have_player)
1880         {
1881                 // we have at least one player
1882                 if(have_players)
1883                 {
1884                         // two or more active players - continue with the game
1885                 }
1886                 else
1887                 {
1888                         // exactly one player?
1889
1890                         ClearWinners();
1891                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1892
1893                         if(l)
1894                         {
1895                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1896                                 return WINNING_NO;
1897                         }
1898                         else
1899                         {
1900                                 // a winner!
1901                                 // and assign him his first place
1902                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1903                                 return WINNING_YES;
1904                         }
1905                 }
1906         }
1907         else
1908         {
1909                 // nobody is playing at all...
1910                 if(l)
1911                 {
1912                         // wait for players...
1913                 }
1914                 else
1915                 {
1916                         // SNAFU (maybe a draw game?)
1917                         ClearWinners();
1918                         dprint("No players, ending game.\n");
1919                         return WINNING_YES;
1920                 }
1921         }
1922
1923         // When we get here, we have at least two players who are actually LIVING,
1924         // now check if the top two players have equal score.
1925         WinningConditionHelper();
1926
1927         ClearWinners();
1928         if(WinningConditionHelper_winner)
1929                 WinningConditionHelper_winner.winning = TRUE;
1930         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1931                 return WINNING_NEVER;
1932
1933         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1934         return WINNING_NO;
1935 }
1936
1937 void ShuffleMaplist()
1938 {
1939         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1940 }
1941
1942 float leaderfrags;
1943 float WinningCondition_Scores(float limit, float leadlimit)
1944 {
1945         float limitreached;
1946
1947         // TODO make everything use THIS winning condition (except LMS)
1948         WinningConditionHelper();
1949
1950         if(teams_matter)
1951         {
1952                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1953                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1954                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1955                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1956         }
1957
1958         ClearWinners();
1959         if(WinningConditionHelper_winner)
1960                 WinningConditionHelper_winner.winning = 1;
1961         if(WinningConditionHelper_winnerteam >= 0)
1962                 SetWinners(team, WinningConditionHelper_winnerteam);
1963
1964         if(WinningConditionHelper_lowerisbetter)
1965         {
1966                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1967                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1968                 limit = -limit;
1969         }
1970
1971         if(WinningConditionHelper_zeroisworst)
1972                 leadlimit = 0; // not supported in this mode
1973
1974         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1975         // these modes always score in increments of 1, thus this makes sense
1976         {
1977                 if(leaderfrags != WinningConditionHelper_topscore)
1978                 {
1979                         leaderfrags = WinningConditionHelper_topscore;
1980
1981                         if (limit)
1982                         if (leaderfrags == limit - 1)
1983                                 Announce("1fragleft");
1984                         else if (leaderfrags == limit - 2)
1985                                 Announce("2fragsleft");
1986                         else if (leaderfrags == limit - 3)
1987                                 Announce("3fragsleft");
1988                 }
1989         }
1990
1991         limitreached = FALSE;
1992         if(limit)
1993                 if(WinningConditionHelper_topscore >= limit)
1994                         limitreached = TRUE;
1995         if(leadlimit)
1996         {
1997                 float leadlimitreached;
1998                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1999                 if(cvar("leadlimit_and_fraglimit"))
2000                         limitreached = (limitreached && leadlimitreached);
2001                 else
2002                         limitreached = (limitreached || leadlimitreached);
2003         }
2004
2005         return GetWinningCode(
2006                 WinningConditionHelper_topscore && limitreached,
2007                 WinningConditionHelper_equality
2008         );
2009 }
2010
2011 float WinningCondition_Race(float fraglimit)
2012 {
2013         float wc;
2014         entity p;
2015         float n, c;
2016
2017         n = 0;
2018         c = 0;
2019         FOR_EACH_PLAYER(p)
2020         {
2021                 ++n;
2022                 if(p.race_completed)
2023                         ++c;
2024         }
2025         if(n && (n == c))
2026                 return WINNING_YES;
2027         wc = WinningCondition_Scores(fraglimit, 0);
2028
2029         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2030         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2031         // do NOT support equality when the laps are all raced!
2032                 return WINNING_STARTSUDDENDEATHOVERTIME;
2033         else
2034                 return WINNING_NEVER;
2035         return wc;
2036 }
2037
2038 void ReadyRestart();
2039 float WinningCondition_QualifyingThenRace(float limit)
2040 {
2041         float wc;
2042         wc = WinningCondition_Scores(limit, 0);
2043
2044         // NEVER initiate overtime
2045         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2046         {
2047                 return WINNING_YES;
2048         }
2049
2050         return wc;
2051 }
2052
2053 float WinningCondition_RanOutOfSpawns()
2054 {
2055         entity head;
2056
2057         if(have_team_spawns <= 0)
2058                 return WINNING_NO;
2059
2060         if(!some_spawn_has_been_used)
2061                 return WINNING_NO;
2062
2063         team1_score = team2_score = team3_score = team4_score = 0;
2064
2065         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2066         {
2067                 if(head.team == COLOR_TEAM1)
2068                         team1_score = 1;
2069                 else if(head.team == COLOR_TEAM2)
2070                         team2_score = 1;
2071                 else if(head.team == COLOR_TEAM3)
2072                         team3_score = 1;
2073                 else if(head.team == COLOR_TEAM4)
2074                         team4_score = 1;
2075         }
2076
2077         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2078         {
2079                 if(head.team == COLOR_TEAM1)
2080                         team1_score = 1;
2081                 else if(head.team == COLOR_TEAM2)
2082                         team2_score = 1;
2083                 else if(head.team == COLOR_TEAM3)
2084                         team3_score = 1;
2085                 else if(head.team == COLOR_TEAM4)
2086                         team4_score = 1;
2087         }
2088
2089         ClearWinners();
2090         if(team1_score + team2_score + team3_score + team4_score == 0)
2091         {
2092                 checkrules_equality = TRUE;
2093                 return WINNING_YES;
2094         }
2095         else if(team1_score + team2_score + team3_score + team4_score == 1)
2096         {
2097                 float t, i;
2098                 if(team1_score) t = COLOR_TEAM1;
2099                 if(team2_score) t = COLOR_TEAM2;
2100                 if(team3_score) t = COLOR_TEAM3;
2101                 if(team4_score) t = COLOR_TEAM4;
2102                 CheckAllowedTeams(world);
2103                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2104                 {
2105                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2106                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2107                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2108                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2109                 }
2110
2111                 AddWinners(team, t);
2112                 return WINNING_YES;
2113         }
2114         else
2115                 return WINNING_NO;
2116 }
2117
2118 /*
2119 ============
2120 CheckRules_World
2121
2122 Exit deathmatch games upon conditions
2123 ============
2124 */
2125 void CheckRules_World()
2126 {
2127         float timelimit;
2128         float fraglimit;
2129         float leadlimit;
2130
2131         VoteThink();
2132         MapVote_Think();
2133
2134         SetDefaultAlpha();
2135
2136         /*
2137         MapVote_Think should now do that part
2138         if (intermission_running)
2139                 if (time >= intermission_exittime + 60)
2140                 {
2141                         if(!DoNextMapOverride())
2142                                 GotoNextMap();
2143                         return;
2144                 }
2145         */
2146
2147         if (gameover)   // someone else quit the game already
2148         {
2149                 if(player_count == 0) // Nobody there? Then let's go to the next map
2150                         MapVote_Start();
2151                         // this will actually check the player count in the next frame
2152                         // again, but this shouldn't hurt
2153                 return;
2154         }
2155
2156         timelimit = cvar("timelimit") * 60;
2157         fraglimit = cvar("fraglimit");
2158         leadlimit = cvar("leadlimit");
2159
2160         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2161         {
2162                 if(timelimit > 0)
2163                         timelimit = 0; // timelimit is not made for warmup
2164                 if(fraglimit > 0)
2165                         fraglimit = 0; // no fraglimit for now
2166                 leadlimit = 0; // no leadlimit for now
2167         }
2168
2169         if(g_onslaught)
2170                 timelimit = 0; // ONS has its own overtime rule
2171
2172         if(timelimit > 0)
2173         {
2174                 timelimit += game_starttime;
2175         }
2176         else if (timelimit < 0)
2177         {
2178                 // endmatch
2179                 NextLevel();
2180                 return;
2181         }
2182
2183         float wantovertime;
2184         wantovertime = 0;
2185
2186         if(checkrules_suddendeathend)
2187         {
2188                 if(!checkrules_suddendeathwarning)
2189                 {
2190                         checkrules_suddendeathwarning = TRUE;
2191                         if(g_race && !g_race_qualifying)
2192                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2193                         else
2194                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2195                 }
2196         }
2197         else
2198         {
2199                 if (timelimit && time >= timelimit)
2200                 {
2201                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2202                         {
2203                                 float totalplayers;
2204                                 float playerswithlaps;
2205                                 float readyplayers;
2206                                 entity head;
2207                                 totalplayers = playerswithlaps = readyplayers = 0;
2208                                 FOR_EACH_PLAYER(head)
2209                                 {
2210                                         ++totalplayers;
2211                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2212                                                 ++playerswithlaps;
2213                                         if(head.ready)
2214                                                 ++readyplayers;
2215                                 }
2216
2217                                 // at least 2 of the players have completed a lap: start the RACE
2218                                 // otherwise, the players should end the qualifying on their own
2219                                 if(readyplayers || playerswithlaps >= 2)
2220                                 {
2221                                         checkrules_suddendeathend = 0;
2222                                         ReadyRestart(); // go to race
2223                                         return;
2224                                 }
2225                                 else
2226                                         wantovertime |= InitiateSuddenDeath();
2227                         }
2228                         else
2229                                 wantovertime |= InitiateSuddenDeath();
2230                 }
2231         }
2232
2233         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2234         {
2235                 NextLevel();
2236                 return;
2237         }
2238
2239         float checkrules_status;
2240         checkrules_status = WinningCondition_RanOutOfSpawns();
2241         if(checkrules_status == WINNING_YES)
2242         {
2243                 bprint("Hey! Someone ran out of spawns!\n");
2244         }
2245         else if(g_race && !g_race_qualifying && timelimit >= 0)
2246         {
2247                 checkrules_status = WinningCondition_Race(fraglimit);
2248                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2249         }
2250         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2251         {
2252                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2253                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2254         }
2255         else if(g_assault)
2256         {
2257                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2258         }
2259         else if(g_lms)
2260         {
2261                 checkrules_status = WinningCondition_LMS();
2262         }
2263         else if (g_onslaught)
2264         {
2265                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2266         }
2267         else
2268         {
2269                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2270                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2271         }
2272
2273         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2274         {
2275                 checkrules_status = WINNING_NEVER;
2276                 checkrules_overtimesadded = -1;
2277                 wantovertime |= InitiateSuddenDeath();
2278         }
2279
2280         if(checkrules_status == WINNING_NEVER)
2281                 // equality cases! Nobody wins if the overtime ends in a draw.
2282                 ClearWinners();
2283
2284         if(wantovertime)
2285         {
2286                 if(checkrules_status == WINNING_NEVER)
2287                         InitiateOvertime();
2288                 else
2289                         checkrules_status = WINNING_YES;
2290         }
2291
2292         if(checkrules_suddendeathend)
2293                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2294                         checkrules_status = WINNING_YES;
2295
2296         if(checkrules_status == WINNING_YES)
2297         {
2298                 //print("WINNING\n");
2299                 NextLevel();
2300         }
2301 };
2302
2303 float mapvote_nextthink;
2304 float mapvote_initialized;
2305 float mapvote_keeptwotime;
2306 float mapvote_timeout;
2307 string mapvote_message;
2308 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2309 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2310 float mapvote_screenshot_dirs_count;
2311
2312 float mapvote_count;
2313 float mapvote_count_real;
2314 string mapvote_maps[MAPVOTE_COUNT];
2315 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2316 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2317 float mapvote_maps_suggested[MAPVOTE_COUNT];
2318 string mapvote_suggestions[MAPVOTE_COUNT];
2319 float mapvote_suggestion_ptr;
2320 float mapvote_maxlen;
2321 float mapvote_voters;
2322 float mapvote_votes[MAPVOTE_COUNT];
2323 float mapvote_run;
2324 float mapvote_detail;
2325 float mapvote_abstain;
2326 .float mapvote;
2327
2328 void MapVote_ClearAllVotes()
2329 {
2330         FOR_EACH_CLIENT(other)
2331                 other.mapvote = 0;
2332 }
2333
2334 string MapVote_Suggest(string m)
2335 {
2336         float i;
2337         if(m == "")
2338                 return "That's not how to use this command.";
2339         if(!cvar("g_maplist_votable_suggestions"))
2340                 return "Suggestions are not accepted on this server.";
2341         if(mapvote_initialized)
2342                 return "Can't suggest - voting is already in progress!";
2343         m = MapInfo_FixName(m);
2344         if(!m)
2345                 return "The map you suggested is not available on this server.";
2346         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2347                 if(Map_IsRecent(m))
2348                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2349
2350         if(!MapInfo_CheckMap(m))
2351                 return "The map you suggested does not support the current game mode.";
2352         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2353                 if(mapvote_suggestions[i] == m)
2354                         return "This map was already suggested.";
2355         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2356         {
2357                 i = floor(random() * mapvote_suggestion_ptr);
2358         }
2359         else
2360         {
2361                 i = mapvote_suggestion_ptr;
2362                 mapvote_suggestion_ptr += 1;
2363         }
2364         if(mapvote_suggestions[i] != "")
2365                 strunzone(mapvote_suggestions[i]);
2366         mapvote_suggestions[i] = strzone(m);
2367         if(cvar("sv_eventlog"))
2368                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2369         return strcat("Suggestion of ", m, " accepted.");
2370 }
2371
2372 void MapVote_AddVotable(string nextMap, float isSuggestion)
2373 {
2374         float j, i, o;
2375         string pakfile, mapfile;
2376
2377         if(nextMap == "")
2378                 return;
2379         for(j = 0; j < mapvote_count; ++j)
2380                 if(mapvote_maps[j] == nextMap)
2381                         return;
2382         if(strlen(nextMap) > mapvote_maxlen)
2383                 mapvote_maxlen = strlen(nextMap);
2384         mapvote_maps[mapvote_count] = strzone(nextMap);
2385         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2386
2387         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2388         {
2389                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2390                 pakfile = whichpack(strcat(mapfile, ".tga"));
2391                 if(pakfile == "")
2392                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2393                 if(pakfile == "")
2394                         pakfile = whichpack(strcat(mapfile, ".png"));
2395                 if(pakfile != "")
2396                         break;
2397         }
2398         if(i >= mapvote_screenshot_dirs_count)
2399                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2400         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2401                 pakfile = substring(pakfile, o, -1);
2402
2403         mapvote_maps_screenshot_dir[mapvote_count] = i;
2404         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2405
2406         mapvote_count += 1;
2407 }
2408
2409 void MapVote_Spawn();
2410 void MapVote_Init()
2411 {
2412         float i;
2413         float nmax, smax;
2414
2415         MapVote_ClearAllVotes();
2416
2417         mapvote_count = 0;
2418         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2419         mapvote_abstain = cvar("g_maplist_votable_abstain");
2420
2421         if(mapvote_abstain)
2422                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2423         else
2424                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2425         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2426
2427         // we need this for AddVotable, as that cycles through the screenshot dirs
2428         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2429         if(mapvote_screenshot_dirs_count == 0)
2430                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2431         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2432         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2433                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2434
2435         if(mapvote_suggestion_ptr)
2436                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2437                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2438
2439         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2440                 MapVote_AddVotable(GetNextMap(), FALSE);
2441
2442         if(mapvote_count == 0)
2443         {
2444                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2445                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2446                 if(cvar("g_maplist_shuffle"))
2447                         ShuffleMaplist();
2448                 localcmd("\nmenu_cmd sync\n");
2449                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2450                         MapVote_AddVotable(GetNextMap(), FALSE);
2451         }
2452
2453         mapvote_count_real = mapvote_count;
2454         if(mapvote_abstain)
2455                 MapVote_AddVotable("don't care", 0);
2456
2457         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2458
2459         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2460         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2461         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2462                 mapvote_keeptwotime = 0;
2463         mapvote_message = "Choose a map and press its key!";
2464
2465         MapVote_Spawn();
2466 }
2467
2468 void MapVote_SendPicture(float id)
2469 {
2470         msg_entity = self;
2471         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2472         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2473         WriteByte(MSG_ONE, id);
2474         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2475 }
2476
2477 float GameCommand_MapVote(string cmd)
2478 {
2479         if(!intermission_running)
2480                 return FALSE;
2481
2482         if(cmd == "mv_getpic")
2483         {
2484                 MapVote_SendPicture(stof(argv(1)));
2485                 return TRUE;
2486         }
2487
2488         return FALSE;
2489 }
2490
2491 float MapVote_GetMapMask()
2492 {
2493         float mask, i, power;
2494         mask = 0;
2495         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2496                 if(mapvote_maps[i] != "")
2497                         mask |= power;
2498         return mask;
2499 }
2500
2501 entity mapvote_ent;
2502 float MapVote_SendEntity(entity to, float sf)
2503 {
2504         float i;
2505
2506         if(sf & 1)
2507                 sf &~= 2; // if we send 1, we don't need to also send 2
2508
2509         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2510         WriteByte(MSG_ENTITY, sf);
2511
2512         if(sf & 1)
2513         {
2514                 // flag 1 == initialization
2515                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2516                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2517                 WriteString(MSG_ENTITY, "");
2518                 WriteByte(MSG_ENTITY, mapvote_count);
2519                 WriteByte(MSG_ENTITY, mapvote_abstain);
2520                 WriteByte(MSG_ENTITY, mapvote_detail);
2521                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2522                 if(mapvote_count <= 8)
2523                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2524                 else
2525                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2526                 for(i = 0; i < mapvote_count; ++i)
2527                         if(mapvote_maps[i] != "")
2528                         {
2529                                 if(mapvote_abstain && i == mapvote_count - 1)
2530                                 {
2531                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2532                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2533                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2534                                 }
2535                                 else
2536                                 {
2537                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2538                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2539                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2540                                 }
2541                         }
2542         }
2543
2544         if(sf & 2)
2545         {
2546                 // flag 2 == update of mask
2547                 if(mapvote_count <= 8)
2548                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2549                 else
2550                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2551         }
2552
2553         if(sf & 4)
2554         {
2555                 if(mapvote_detail)
2556                         for(i = 0; i < mapvote_count; ++i)
2557                                 if(mapvote_maps[i] != "")
2558                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2559
2560                 WriteByte(MSG_ENTITY, to.mapvote);
2561         }
2562
2563         return TRUE;
2564 }
2565
2566 void MapVote_Spawn()
2567 {
2568         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2569 }
2570
2571 void MapVote_TouchMask()
2572 {
2573         mapvote_ent.SendFlags |= 2;
2574 }
2575
2576 void MapVote_TouchVotes(entity voter)
2577 {
2578         mapvote_ent.SendFlags |= 4;
2579 }
2580
2581 float MapVote_Finished(float mappos)
2582 {
2583         string result;
2584         float i;
2585         float didntvote;
2586
2587         if(cvar("sv_eventlog"))
2588         {
2589                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2590                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2591                 didntvote = mapvote_voters;
2592                 for(i = 0; i < mapvote_count; ++i)
2593                         if(mapvote_maps[i] != "")
2594                         {
2595                                 didntvote -= mapvote_votes[i];
2596                                 if(i != mappos)
2597                                 {
2598                                         result = strcat(result, ":", mapvote_maps[i]);
2599                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2600                                 }
2601                         }
2602                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2603
2604                 GameLogEcho(result);
2605                 if(mapvote_maps_suggested[mappos])
2606                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2607         }
2608
2609         FOR_EACH_REALCLIENT(other)
2610                 FixClientCvars(other);
2611
2612         Map_Goto_SetStr(mapvote_maps[mappos]);
2613         Map_Goto();
2614         alreadychangedlevel = TRUE;
2615         return TRUE;
2616 }
2617 void MapVote_CheckRules_1()
2618 {
2619         float i;
2620
2621         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2622         {
2623                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2624                 mapvote_votes[i] = 0;
2625         }
2626
2627         mapvote_voters = 0;
2628         FOR_EACH_REALCLIENT(other)
2629         {
2630                 ++mapvote_voters;
2631                 if(other.mapvote)
2632                 {
2633                         i = other.mapvote - 1;
2634                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2635                         mapvote_votes[i] = mapvote_votes[i] + 1;
2636                 }
2637         }
2638 }
2639
2640 float MapVote_CheckRules_2()
2641 {
2642         float i;
2643         float firstPlace, secondPlace;
2644         float firstPlaceVotes, secondPlaceVotes;
2645         float mapvote_voters_real;
2646         string result;
2647
2648         if(mapvote_count_real == 1)
2649                 return MapVote_Finished(0);
2650
2651         mapvote_voters_real = mapvote_voters;
2652         if(mapvote_abstain)
2653                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2654
2655         RandomSelection_Init();
2656         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2657                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2658         firstPlace = RandomSelection_chosen_float;
2659         firstPlaceVotes = RandomSelection_best_priority;
2660         //dprint("First place: ", ftos(firstPlace), "\n");
2661         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2662
2663         RandomSelection_Init();
2664         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2665                 if(i != firstPlace)
2666                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2667         secondPlace = RandomSelection_chosen_float;
2668         secondPlaceVotes = RandomSelection_best_priority;
2669         //dprint("Second place: ", ftos(secondPlace), "\n");
2670         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2671
2672         if(firstPlace == -1)
2673                 error("No first place in map vote... WTF?");
2674
2675         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2676                 return MapVote_Finished(firstPlace);
2677
2678         if(mapvote_keeptwotime)
2679                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2680                 {
2681                         float didntvote;
2682                         MapVote_TouchMask();
2683                         mapvote_message = "Now decide between the TOP TWO!";
2684                         mapvote_keeptwotime = 0;
2685                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2686                         result = strcat(result, ":", ftos(firstPlaceVotes));
2687                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2688                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2689                         didntvote = mapvote_voters;
2690                         for(i = 0; i < mapvote_count; ++i)
2691                                 if(mapvote_maps[i] != "")
2692                                 {
2693                                         didntvote -= mapvote_votes[i];
2694                                         if(i != firstPlace)
2695                                                 if(i != secondPlace)
2696                                                 {
2697                                                         result = strcat(result, ":", mapvote_maps[i]);
2698                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2699                                                         if(i < mapvote_count_real)
2700                                                         {
2701                                                                 strunzone(mapvote_maps[i]);
2702                                                                 mapvote_maps[i] = "";
2703                                                                 strunzone(mapvote_maps_pakfile[i]);
2704                                                                 mapvote_maps_pakfile[i] = "";
2705                                                         }
2706                                                 }
2707                                 }
2708                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2709                         if(cvar("sv_eventlog"))
2710                                 GameLogEcho(result);
2711                 }
2712
2713         return FALSE;
2714 }
2715 void MapVote_Tick()
2716 {
2717         float keeptwo;
2718         float totalvotes;
2719
2720         keeptwo = mapvote_keeptwotime;
2721         MapVote_CheckRules_1(); // count
2722         if(MapVote_CheckRules_2()) // decide
2723                 return;
2724
2725         totalvotes = 0;
2726         FOR_EACH_REALCLIENT(other)
2727         {
2728                 // hide scoreboard again
2729                 if(other.health != 2342)
2730                 {
2731                         other.health = 2342;
2732                         other.impulse = 0;
2733                         if(clienttype(other) == CLIENTTYPE_REAL)
2734                         {
2735                                 msg_entity = other;
2736                                 WriteByte(MSG_ONE, SVC_FINALE);
2737                                 WriteString(MSG_ONE, "");
2738                         }
2739                 }
2740
2741                 // clear possibly invalid votes
2742                 if(mapvote_maps[other.mapvote - 1] == "")
2743                         other.mapvote = 0;
2744                 // use impulses as new vote
2745                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2746                         if(mapvote_maps[other.impulse - 1] != "")
2747                         {
2748                                 other.mapvote = other.impulse;
2749                                 MapVote_TouchVotes(other);
2750                         }
2751                 other.impulse = 0;
2752
2753                 if(other.mapvote)
2754                         ++totalvotes;
2755         }
2756
2757         MapVote_CheckRules_1(); // just count
2758 }
2759 void MapVote_Start()
2760 {
2761         if(mapvote_run)
2762                 return;
2763
2764         MapInfo_Enumerate();
2765         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2766                 mapvote_run = TRUE;
2767 }
2768 void MapVote_Think()
2769 {
2770         if(!mapvote_run)
2771                 return;
2772
2773         if(alreadychangedlevel)
2774                 return;
2775
2776         if(time < mapvote_nextthink)
2777                 return;
2778         //dprint("tick\n");
2779
2780         mapvote_nextthink = time + 0.5;
2781
2782         if(!mapvote_initialized)
2783         {
2784                 if(cvar("rescan_pending") == 1)
2785                 {
2786                         cvar_set("rescan_pending", "2");
2787                         localcmd("fs_rescan\nrescan_pending 3\n");
2788                         return;
2789                 }
2790                 else if(cvar("rescan_pending") == 2)
2791                 {
2792                         return;
2793                 }
2794                 else if(cvar("rescan_pending") == 3)
2795                 {
2796                         // now build missing mapinfo files
2797                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2798                                 return;
2799
2800                         // we're done, start the timer
2801                         cvar_set("rescan_pending", "0");
2802                 }
2803
2804                 mapvote_initialized = TRUE;
2805                 if(DoNextMapOverride())
2806                         return;
2807                 if(!cvar("g_maplist_votable") || player_count <= 0)
2808                 {
2809                         GotoNextMap();
2810                         return;
2811                 }
2812                 MapVote_Init();
2813         }
2814
2815         MapVote_Tick();
2816 };
2817
2818 string GotoMap(string m)
2819 {
2820         if(!MapInfo_CheckMap(m))
2821                 return "The map you chose is not available on this server.";
2822         cvar_set("nextmap", m);
2823         cvar_set("timelimit", "-1");
2824         if(mapvote_initialized || alreadychangedlevel)
2825         {
2826                 if(DoNextMapOverride())
2827                         return "Map switch initiated.";
2828                 else
2829                         return "Hm... no. For some reason I like THIS map more.";
2830         }
2831         else
2832                 return "Map switch will happen after scoreboard.";
2833 }
2834
2835
2836 void EndFrame()
2837 {
2838         float altime;
2839         FOR_EACH_REALCLIENT(self)
2840         {
2841                 if(self.classname == "spectator")
2842                 {
2843                         if(self.enemy.typehitsound)
2844                                 play2(self, "misc/typehit.wav");
2845                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2846                                 play2(self, "misc/hit.wav");
2847                 }
2848                 else
2849                 {
2850                         if(self.typehitsound)
2851                                 play2(self, "misc/typehit.wav");
2852                         else if(self.hitsound && self.cvar_cl_hitsound)
2853                                 play2(self, "misc/hit.wav");
2854                 }
2855         }
2856         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2857         // add 1 frametime because after this, engine SV_Physics
2858         // increases time by a frametime and then networks the frame
2859         // add another frametime because client shows everything with
2860         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2861         // needed!
2862         FOR_EACH_CLIENT(self)
2863         {
2864                 self.hitsound = FALSE;
2865                 self.typehitsound = FALSE;
2866                 antilag_record(self, altime);
2867         }
2868 }
2869
2870
2871 /*
2872  * RedirectionThink:
2873  * returns TRUE if redirecting
2874  */
2875 float redirection_timeout;
2876 float redirection_nextthink;
2877 float RedirectionThink()
2878 {
2879         float clients_found;
2880
2881         if(redirection_target == "")
2882                 return FALSE;
2883
2884         if(!redirection_timeout)
2885         {
2886                 cvar_set("sv_public", "-2");
2887                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2888                 if(redirection_target == "self")
2889                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2890                 else
2891                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2892         }
2893
2894         if(time < redirection_nextthink)
2895                 return TRUE;
2896
2897         redirection_nextthink = time + 1;
2898
2899         clients_found = 0;
2900         FOR_EACH_REALCLIENT(self)
2901         {
2902                 print("Redirecting: sending connect command to ", self.netname, "\n");
2903                 if(redirection_target == "self")
2904                         stuffcmd(self, "\ndisconnect; reconnect\n");
2905                 else
2906                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2907                 ++clients_found;
2908         }
2909
2910         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2911
2912         if(time > redirection_timeout || clients_found == 0)
2913                 localcmd("\nwait; wait; wait; quit\n");
2914
2915         return TRUE;
2916 }
2917
2918 void TargetMusic_RestoreGame();
2919 void RestoreGame()
2920 {
2921         // Loaded from a save game
2922         // some things then break, so let's work around them...
2923
2924         // Progs DB (capture records)
2925         ServerProgsDB = db_load("server.db");
2926
2927         // Mapinfo
2928         MapInfo_Shutdown();
2929         MapInfo_Enumerate();
2930         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2931         WeaponStats_Init();
2932
2933         TargetMusic_RestoreGame();
2934 }
2935
2936 void SV_Shutdown()
2937 {
2938         if(gameover > 1) // shutting down already?
2939                 return;
2940
2941         gameover = 2; // 2 = server shutting down
2942
2943         if(world_initialized > 0)
2944         {
2945                 world_initialized = 0;
2946                 print("Saving persistent data...\n");
2947                 Ban_SaveBans();
2948                 if(!cheatcount_total)
2949                 {
2950                         if(cvar("sv_db_saveasdump"))
2951                                 db_dump(ServerProgsDB, "server.db");
2952                         else
2953                                 db_save(ServerProgsDB, "server.db");
2954                 }
2955                 if(cvar("developer"))
2956                 {
2957                         if(cvar("sv_db_saveasdump"))
2958                                 db_dump(TemporaryDB, "server-temp.db");
2959                         else
2960                                 db_save(TemporaryDB, "server-temp.db");
2961                 }
2962                 CheatShutdown(); // must be after cheatcount check
2963                 db_close(ServerProgsDB);
2964                 db_close(TemporaryDB);
2965                 print("done!\n");
2966                 // tell the bot system the game is ending now
2967                 bot_endgame();
2968
2969                 WeaponStats_Shutdown();
2970                 MapInfo_Shutdown();
2971         }
2972         else if(world_initialized == 0)
2973         {
2974                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2975         }
2976 }