qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("developer");
 276                 BADCVAR("g_banned_list");
 277                 BADCVAR("log_dest_udp");
 278                 BADCVAR("log_file");
 279                 BADCVAR("net_address");
 280                 BADCVAR("net_address_ipv6");
 281                 BADCVAR("port");
 282                 BADCVAR("savedgamecfg");
 283                 BADCVAR("serverconfig");
 284                 BADCVAR("sv_heartbeatperiod");
 285                 BADCVAR("sv_vote_master_password");
 286                 BADCVAR("sys_colortranslation");
 287                 BADCVAR("sys_specialcharactertranslation");
 288                 BADCVAR("timestamps");
 289                 BADPREFIX("developer_");
 290                 BADPREFIX("g_ban_");
 291                 BADPREFIX("g_chat_flood_");
 292                 BADPREFIX("g_voice_flood_");
 293                 BADPREFIX("rcon_");
 294                 BADPREFIX("settemp_");
 295                 BADPREFIX("sv_allowdownloads_");
 296                 BADPREFIX("sv_autodemo");
 297                 BADPREFIX("sv_curl_");
 298                 BADPREFIX("sv_eventlog");
 299                 BADPREFIX("sv_logscores_");
 300                 BADPREFIX("sv_master");
 301                 BADPREFIX("sv_weaponstats_");
 302
 303                 // these can contain player IDs, so better hide
 304                 BADCVAR("g_forced_team_red");
 305                 BADCVAR("g_forced_team_blue");
 306                 BADCVAR("g_forced_team_yellow");
 307                 BADCVAR("g_forced_team_pink");
 308
 309                 // mapinfo
 310                 BADCVAR("timelimit");
 311                 BADCVAR("fraglimit");
 312                 BADCVAR("leadlimit");
 313                 BADCVAR("g_tdm_teams");
 314                 BADCVAR("g_keyhunt_teams");
 315                 BADCVAR("g_domination_default_teams");
 316                 BADCVAR("g_race_qualifying_timelimit");
 317                 BADCVAR("g_lms");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_ca");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_dm");
 323                 BADCVAR("g_domination");
 324                 BADCVAR("g_keyhunt");
 325                 BADCVAR("g_keyhunt_teams");
 326                 BADCVAR("g_onslaught");
 327                 BADCVAR("g_race");
 328                 BADCVAR("g_cts");
 329                 BADCVAR("g_runematch");
 330                 BADCVAR("g_tdm");
 331                 BADCVAR("g_nexball");
 332                 BADCVAR("teamplay");
 333
 334                 // long
 335                 BADCVAR("hostname");
 336                 BADCVAR("g_maplist");
 337                 BADCVAR("g_maplist_mostrecent");
 338                 BADCVAR("sv_motd");
 339
 340                 v = cvar_string(k);
 341                 d = cvar_defstring(k);
 342                 if(v == d)
 343                         continue;
 344
 345                 if(adding)
 346                 {
 347                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 348                         if(strlen(cvar_changes) > 16384)
 349                         {
 350                                 cvar_changes = "// too many settings have been changed to show them here\n";
 351                                 adding = 0;
 352                         }
 353                 }
 354
 355                 // now check if the changes are actually gameplay relevant
 356
 357                 // does nothing visible
 358                 BADCVAR("captureleadlimit_override");
 359                 BADCVAR("g_arena_point_leadlimit");
 360                 BADCVAR("g_ca_point_leadlimit");
 361                 BADCVAR("g_ctf_capture_leadlimit");
 362                 BADCVAR("g_domination_point_leadlimit");
 363                 BADCVAR("g_keyhunt_point_leadlimit");
 364                 BADCVAR("g_nexball_goalleadlimit");
 365                 BADCVAR("g_runematch_point_leadlimit");
 366                 BADCVAR("leadlimit_and_fraglimit");
 367                 BADCVAR("leadlimit_override");
 368                 BADCVAR("sv_checkforpacketsduringsleep");
 369                 BADPREFIX("crypto_");
 370                 BADPREFIX("g_chat_");
 371                 BADPREFIX("net_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("sv_fragmessage_");
 374                 BADPREFIX("sv_vote_");
 375                 BADPREFIX("timelimit_");
 376
 377                 // allowed changes to server admins (please sync this to server.cfg)
 378                 // vi commands:
 379                 //   :/"impure"/,$d
 380                 //   :g!,^\/\/[^ /],d
 381                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 382                 //   :%!sort
 383                 // yes, this does contain some redundant stuff, don't really care
 384                 BADCVAR("bot_number");
 385                 BADCVAR("bot_prefix");
 386                 BADCVAR("bot_suffix");
 387                 BADCVAR("capturelimit_override");
 388                 BADCVAR("fraglimit_override");
 389                 BADCVAR("gametype");
 390                 BADCVAR("g_antilag");
 391                 BADCVAR("g_balance_teams");
 392                 BADCVAR("g_balance_teams_force");
 393                 BADCVAR("g_ban_sync_trusted_servers");
 394                 BADCVAR("g_ban_sync_uri");
 395                 BADCVAR("g_ctf_capture_limit");
 396                 BADCVAR("g_ctf_ignore_frags");
 397                 BADCVAR("g_ctf_win_mode");
 398                 BADCVAR("g_domination_point_limit");
 399                 BADCVAR("g_fullbrightitems");
 400                 BADCVAR("g_fullbrightplayers");
 401                 BADCVAR("g_keyhunt_point_limit");
 402                 BADCVAR("g_keyhunt_teams_override");
 403                 BADCVAR("g_lms_lives_override");
 404                 BADCVAR("g_maplist");
 405                 BADCVAR("g_maplist_check_waypoints");
 406                 BADCVAR("g_maplist_mostrecent_count");
 407                 BADCVAR("g_maplist_shuffle");
 408                 BADCVAR("g_maplist_votable");
 409                 BADCVAR("g_maplist_votable_abstain");
 410                 BADCVAR("g_maplist_votable_nodetail");
 411                 BADCVAR("g_maplist_votable_suggestions");
 412                 BADCVAR("g_minstagib");
 413                 BADCVAR("g_nexball_goallimit");
 414                 BADCVAR("g_runematch_point_limit");
 415                 BADCVAR("g_start_delay");
 416                 BADCVAR("hostname");
 417                 BADCVAR("log_file");
 418                 BADCVAR("maxplayers");
 419                 BADCVAR("minplayers");
 420                 BADCVAR("net_address");
 421                 BADCVAR("port");
 422                 BADCVAR("rcon_password");
 423                 BADCVAR("rcon_restricted_commands");
 424                 BADCVAR("rcon_restricted_password");
 425                 BADCVAR("skill");
 426                 BADCVAR("sv_adminnick");
 427                 BADCVAR("sv_autoscreenshot");
 428                 BADCVAR("sv_curl_defaulturl");
 429                 BADCVAR("sv_maxidle");
 430                 BADCVAR("sv_maxrate");
 431                 BADCVAR("sv_motd");
 432                 BADCVAR("sv_public");
 433                 BADCVAR("sv_ready_restart");
 434                 BADCVAR("sv_status_privacy");
 435                 BADCVAR("sv_vote_call");
 436                 BADCVAR("sv_vote_commands");
 437                 BADCVAR("sv_vote_majority_factor");
 438                 BADCVAR("sv_vote_master");
 439                 BADCVAR("sv_vote_master_commands");
 440                 BADCVAR("sv_vote_master_password");
 441                 BADCVAR("sv_vote_simple_majority_factor");
 442                 BADCVAR("timelimit_override");
 443
 444                 if(cvar("g_minstagib"))
 445                 {
 446                         BADCVAR("g_grappling_hook");
 447                         BADCVAR("g_jetpack");
 448                 }
 449 #undef BADPREFIX
 450 #undef BADCVAR
 451
 452                 if(pureadding)
 453                 {
 454                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 455                         if(strlen(cvar_purechanges) > 16384)
 456                         {
 457                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 458                                 pureadding = 0;
 459                         }
 460                 }
 461                 ++cvar_purechanges_count;
 462                 // WARNING: this variable is used for the server list
 463                 // NEVER dare to skip this code!
 464                 // Hacks to intentionally appearing as "pure server" even though you DO have
 465                 // modified settings may be punished by removal from the server list.
 466                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 467                 // though.
 468         }
 469         buf_del(h);
 470         if(cvar_changes == "")
 471                 cvar_changes = "// this server runs at default server settings\n";
 472         else
 473                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 474         cvar_changes = strzone(cvar_changes);
 475         if(cvar_purechanges == "")
 476                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 477         else
 478                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 479         cvar_purechanges = strzone(cvar_purechanges);
 480 }
 481
 482 void detect_maptype()
 483 {
 484 #if 0
 485         vector o, v;
 486         float i;
 487
 488         for(;;)
 489         {
 490                 o = world.mins;
 491                 o_x += random() * (world.maxs_x - world.mins_x);
 492                 o_y += random() * (world.maxs_y - world.mins_y);
 493                 o_z += random() * (world.maxs_z - world.mins_z);
 494
 495                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 496                 if(trace_fraction == 1)
 497                         continue;
 498
 499                 v = trace_endpos;
 500
 501                 for(i = 0; i < 64; i += 4)
 502                 {
 503                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 504         if(trace_fraction == 1)
 505                 continue;
 506                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 507                 }
 508
 509                 break;
 510         }
 511 #endif
 512 }
 513
 514 entity randomseed;
 515 float RandomSeed_Send(entity to, float sf)
 516 {
 517         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 518         WriteShort(MSG_ENTITY, self.cnt);
 519         return TRUE;
 520 }
 521 void RandomSeed_Think()
 522 {
 523         self.cnt = bound(0, floor(random() * 65536), 65535);
 524         self.nextthink = time + 5;
 525
 526         self.SendFlags |= 1;
 527 }
 528 void RandomSeed_Spawn()
 529 {
 530         randomseed = spawn();
 531         randomseed.think = RandomSeed_Think;
 532         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 533
 534         entity oldself;
 535         oldself = self;
 536         self = randomseed;
 537         self.think(); // sets random seed and nextthink
 538         self = oldself;
 539 }
 540
 541 void spawnfunc___init_dedicated_server(void)
 542 {
 543         // handler for _init/_init map (only for dedicated server initialization)
 544
 545         world_initialized = -1; // don't complain
 546         cvar = cvar_normal;
 547         cvar_string = cvar_string_normal;
 548         cvar_set = cvar_set_normal;
 549
 550         remove = remove_unsafely;
 551
 552         entity e;
 553         e = spawn();
 554         e.think = GotoFirstMap;
 555         e.nextthink = time; // this is usually 1 at this point
 556
 557         e = spawn();
 558         e.classname = "info_player_deathmatch"; // safeguard against player joining
 559
 560         self.classname = "worldspawn"; // safeguard against various stuff ;)
 561
 562         MapInfo_Enumerate();
 563         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 564 }
 565
 566 void Map_MarkAsRecent(string m);
 567 float world_already_spawned;
 568 void RegisterWeapons();
 569 void Nagger_Init();
 570 void ClientInit_Spawn();
 571 void WeaponStats_Init();
 572 void WeaponStats_Shutdown();
 573 void spawnfunc_worldspawn (void)
 574 {
 575         float fd, l, i, j, n;
 576         string s, col;
 577
 578         cvar = cvar_normal;
 579         cvar_string = cvar_string_normal;
 580         cvar_set = cvar_set_normal;
 581
 582         if(world_already_spawned)
 583                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 584         world_already_spawned = TRUE;
 585
 586         remove = remove_safely; // during spawning, watch what you remove!
 587
 588         check_unacceptable_compiler_bugs();
 589
 590         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 591
 592         compressShortVector_init();
 593
 594         allowed_to_spawn = TRUE;
 595
 596         local entity head;
 597         head = nextent(world);
 598         maxclients = 0;
 599         while(head)
 600         {
 601                 ++maxclients;
 602                 head = nextent(head);
 603         }
 604
 605         // needs to be done so early as they would still spawn
 606         RegisterWeapons();
 607
 608         ServerProgsDB = db_load("server.db");
 609
 610         TemporaryDB = db_create();
 611
 612         /*
 613         TODO sound pack system
 614         // initialize sound pack system
 615         soundpack = cvar_string("g_soundpack");
 616         if(soundpack != "")
 617                 soundpack = strcat(soundpack, "/");
 618         soundpack = strzone(soundpack);
 619         */
 620
 621         // 0 normal
 622         lightstyle(0, "m");
 623
 624         // 1 FLICKER (first variety)
 625         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 626
 627         // 2 SLOW STRONG PULSE
 628         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 629
 630         // 3 CANDLE (first variety)
 631         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 632
 633         // 4 FAST STROBE
 634         lightstyle(4, "mamamamamama");
 635
 636         // 5 GENTLE PULSE 1
 637         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 638
 639         // 6 FLICKER (second variety)
 640         lightstyle(6, "nmonqnmomnmomomno");
 641
 642         // 7 CANDLE (second variety)
 643         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 644
 645         // 8 CANDLE (third variety)
 646         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 647
 648         // 9 SLOW STROBE (fourth variety)
 649         lightstyle(9, "aaaaaaaazzzzzzzz");
 650
 651         // 10 FLUORESCENT FLICKER
 652         lightstyle(10, "mmamammmmammamamaaamammma");
 653
 654         // 11 SLOW PULSE NOT FADE TO BLACK
 655         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 656
 657         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 658
 659         // 63 testing
 660         lightstyle(63, "a");
 661
 662         if(cvar("g_campaign"))
 663                 CampaignPreInit();
 664
 665         Map_MarkAsRecent(mapname);
 666
 667         precache_model ("null"); // we need this one before InitGameplayMode
 668         InitGameplayMode();
 669         readlevelcvars();
 670         GrappleHookInit();
 671         ElectroInit();
 672         LaserInit();
 673
 674         player_count = 0;
 675         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 676         if(bot_waypoints_for_items == 1)
 677                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 678                         bot_waypoints_for_items = 0;
 679
 680         // for setting by mapinfo
 681         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 682         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 683
 684         precache();
 685
 686         WaypointSprite_Init();
 687
 688         //if (g_domination)
 689         //      dom_init();
 690
 691         GameLogInit(); // prepare everything
 692         if(cvar("sv_eventlog"))
 693         {
 694                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 695                 s = strcat(s, ftos(random()));
 696                 matchid = strzone(s);
 697
 698                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 699                 s = ":gameinfo:mutators:LIST";
 700
 701                 ret_string = s;
 702                 MUTATOR_CALLHOOK(BuildMutatorsString);
 703                 s = ret_string;
 704
 705                 // simple, probably not good in the mutator system
 706                 if(cvar("g_grappling_hook"))
 707                         s = strcat(s, ":grappling_hook");
 708
 709                 // initialiation stuff, not good in the mutator system
 710                 if(!cvar("g_use_ammunition"))
 711                         s = strcat(s, ":no_use_ammunition");
 712
 713                 // initialiation stuff, not good in the mutator system
 714                 if(!cvar("g_pickup_items"))
 715                         s = strcat(s, ":no_pickup_items");
 716
 717                 // initialiation stuff, not good in the mutator system
 718                 if(cvar_string("g_weaponarena") != "0")
 719                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 720
 721                 // TODO to mutator system
 722                 if(cvar("g_norecoil"))
 723                         s = strcat(s, ":norecoil");
 724
 725                 // TODO to mutator system
 726                 if(cvar("g_midair"))
 727                         s = strcat(s, ":midair");
 728
 729                 // TODO to mutator system
 730                 if(cvar("g_minstagib"))
 731                         s = strcat(s, ":minstagib");
 732
 733                 GameLogEcho(s);
 734                 GameLogEcho(":gameinfo:end");
 735         }
 736         else
 737                 matchid = strzone(ftos(random()));
 738
 739         cvar_set("nextmap", "");
 740
 741         SetDefaultAlpha();
 742
 743         if(cvar("g_campaign"))
 744                 CampaignPostInit();
 745
 746         fteqcc_testbugs();
 747
 748         Ban_LoadBans();
 749
 750         MapInfo_Enumerate();
 751         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 752
 753         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 754         {
 755                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 756                 if(fd != -1)
 757                 {
 758                         while((s = fgets(fd)))
 759                         {
 760                                 l = tokenize_console(s);
 761                                 if(l < 2)
 762                                         continue;
 763                                 if(argv(0) == "cd")
 764                                 {
 765                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 766                                         print("  cdtrack ", argv(2), "\n");
 767                                 }
 768                                 else if(argv(0) == "fog")
 769                                 {
 770                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 771                                         print("  \"fog\" \"", s, "\"\n");
 772                                 }
 773                                 else if(argv(0) == "set")
 774                                 {
 775                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 776                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 777                                 }
 778                                 else if(argv(0) != "//")
 779                                 {
 780                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 781                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 782                                 }
 783                         }
 784                         fclose(fd);
 785                 }
 786         }
 787
 788         WeaponStats_Init();
 789
 790         addstat(STAT_WEAPONS, AS_INT, weapons);
 791         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 792         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 793         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 794         Nagger_Init();
 795
 796         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 797         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 798         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 799         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 800         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 801         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 802         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 803         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 804         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 805         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 806
 807         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 808
 809         if(g_ca)
 810         {
 811                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 812                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 813         }
 814         // g_movementspeed hack
 815         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 816         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 817         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 818
 819         next_pingtime = time + 5;
 820
 821         detect_maptype();
 822
 823         lsmaps_reply = "^7Maps available: ";
 824         lsnewmaps_reply = "^7Maps without a record set: ";
 825         for(i = 0, j = 0; i < MapInfo_count; ++i)
 826         {
 827                 if(MapInfo_Get_ByID(i))
 828                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 829                         {
 830                                 if(mod(i, 2))
 831                                         col = "^2";
 832                                 else
 833                                         col = "^3";
 834                                 ++j;
 835                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 836                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 837                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 838                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 839                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 840                         }
 841         }
 842         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 843         if (!g_race && !g_cts)
 844                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 845         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 846
 847         maplist_reply = "^7Maps in list: ";
 848         n = tokenize_console(cvar_string("g_maplist"));
 849         for(i = 0, j = 0; i < n; ++i)
 850         {
 851                 if(MapInfo_CheckMap(argv(i)))
 852                 {
 853                         if(mod(j, 2))
 854                                 col = "^2";
 855                         else
 856                                 col = "^3";
 857                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 858                         ++j;
 859                 }
 860         }
 861         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 862         MapInfo_ClearTemps();
 863
 864         for(i = 0; i < 10; ++i)
 865         {
 866                 records_reply[i] = strzone(getrecords(i));
 867         }
 868         if(g_cts)
 869                 ladder_reply = strzone(getladder());
 870
 871         rankings_reply = strzone(getrankings());
 872
 873         ClientInit_Spawn();
 874         RandomSeed_Spawn();
 875         PingPLReport_Spawn();
 876
 877         CheatInit();
 878
 879         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 880
 881         // fill sv_curl_serverpackages from .serverpackage files
 882         if(cvar("sv_curl_serverpackages_auto"))
 883         {
 884                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 885                 s = "";
 886                 if(fd >= 0)
 887                 {
 888                         j = search_getsize(fd);
 889                         for(i = 0; i < j; ++i)
 890                                 s = strcat(s, " ", search_getfilename(fd, i));
 891                         search_end(fd);
 892                 }
 893                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 894         }
 895
 896         world_initialized = 1;
 897 }
 898
 899 void spawnfunc_light (void)
 900 {
 901         //makestatic (self); // Who the f___ did that?
 902         remove(self);
 903 }
 904
 905 float TryFile( string pFilename )
 906 {
 907         local float lHandle;
 908         dprint("TryFile(\"", pFilename, "\")\n");
 909         lHandle = fopen( pFilename, FILE_READ );
 910         if( lHandle != -1 ) {
 911                 fclose( lHandle );
 912                 return TRUE;
 913         } else {
 914                 return FALSE;
 915         }
 916 };
 917
 918 string GetGametype()
 919 {
 920         return GametypeNameFromType(game);
 921 }
 922
 923 string getmapname_stored;
 924 string GetMapname()
 925 {
 926         return mapname;
 927 }
 928
 929 float Map_Count, Map_Current;
 930 string Map_Current_Name;
 931
 932 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 933 float GetMaplistPosition()
 934 {
 935         float pos, idx;
 936         string map;
 937
 938         map = GetMapname();
 939         idx = cvar("g_maplist_index");
 940
 941         if(idx >= 0)
 942                 if(idx < Map_Count)
 943                         if(map == argv(idx))
 944                                 return idx;
 945
 946         for(pos = 0; pos < Map_Count; ++pos)
 947                 if(map == argv(pos))
 948                         return pos;
 949
 950         // resume normal maplist rotation if current map is not in g_maplist
 951         return idx;
 952 }
 953
 954 float MapHasRightSize(string map)
 955 {
 956         float fh;
 957         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 958         if(cvar("g_maplist_check_waypoints"))
 959         {
 960                 dprint("checkwp "); dprint(map);
 961                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 962                 if(fh < 0)
 963                 {
 964                         dprint(": no waypoints\n");
 965                         return FALSE;
 966                 }
 967                 dprint(": has waypoints\n");
 968                 fclose(fh);
 969         }
 970
 971         // open map size restriction file
 972         dprint("opensize "); dprint(map);
 973         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 974         if(fh >= 0)
 975         {
 976                 float mapmin, mapmax;
 977                 dprint(": ok, ");
 978                 mapmin = stof(fgets(fh));
 979                 mapmax = stof(fgets(fh));
 980                 fclose(fh);
 981                 if(player_count < mapmin)
 982                 {
 983                         dprint("not enough\n");
 984                         return FALSE;
 985                 }
 986                 if(player_count > mapmax)
 987                 {
 988                         dprint("too many\n");
 989                         return FALSE;
 990                 }
 991                 dprint("right size\n");
 992                 return TRUE;
 993         }
 994         dprint(": not found\n");
 995         return TRUE;
 996 }
 997
 998 string Map_Filename(float position)
 999 {
1000         return strcat("maps/", argv(position), ".bsp");
1001 }
1002
1003 string strwords(string s, float w)
1004 {
1005         float endpos;
1006         for(endpos = 0; w && endpos >= 0; --w)
1007                 endpos = strstrofs(s, " ", endpos + 1);
1008         if(endpos < 0)
1009                 return s;
1010         else
1011                 return substring(s, 0, endpos);
1012 }
1013
1014 float strhasword(string s, string w)
1015 {
1016         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1017 }
1018
1019 void Map_MarkAsRecent(string m)
1020 {
1021         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1022 }
1023
1024 float Map_IsRecent(string m)
1025 {
1026         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1027 }
1028
1029 float Map_Check(float position, float pass)
1030 {
1031         string filename;
1032         string map_next;
1033         map_next = argv(position);
1034         if(pass <= 1)
1035         {
1036                 if(Map_IsRecent(map_next))
1037                         return 0;
1038         }
1039         filename = Map_Filename(position);
1040         if(MapInfo_CheckMap(map_next))
1041         {
1042                 if(pass == 2)
1043                         return 1;
1044                 if(MapHasRightSize(map_next))
1045                         return 1;
1046                 return 0;
1047         }
1048         else
1049                 dprint( "Couldn't select '", filename, "'..\n" );
1050
1051         return 0;
1052 }
1053
1054 void Map_Goto_SetStr(string nextmapname)
1055 {
1056         if(getmapname_stored != "")
1057                 strunzone(getmapname_stored);
1058         if(nextmapname == "")
1059                 getmapname_stored = "";
1060         else
1061                 getmapname_stored = strzone(nextmapname);
1062 }
1063
1064 void Map_Goto_SetFloat(float position)
1065 {
1066         cvar_set("g_maplist_index", ftos(position));
1067         Map_Goto_SetStr(argv(position));
1068 }
1069
1070 void GameResetCfg()
1071 {
1072         // settings persist, except...
1073         localcmd("\nsettemp_restore\n");
1074 };
1075
1076 void Map_Goto()
1077 {
1078         GameResetCfg();
1079         MapInfo_LoadMap(getmapname_stored);
1080 }
1081
1082 // return codes of map selectors:
1083 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1084 //   -2 = permanent failure
1085 float() MaplistMethod_Iterate = // usual method
1086 {
1087         float pass, i;
1088
1089         for(pass = 1; pass <= 2; ++pass)
1090         {
1091                 for(i = 1; i < Map_Count; ++i)
1092                 {
1093                         float mapindex;
1094                         mapindex = mod(i + Map_Current, Map_Count);
1095                         if(Map_Check(mapindex, pass))
1096                                 return mapindex;
1097                 }
1098         }
1099         return -1;
1100 }
1101
1102 float() MaplistMethod_Repeat = // fallback method
1103 {
1104         if(Map_Check(Map_Current, 2))
1105                 return Map_Current;
1106         return -2;
1107 }
1108
1109 float() MaplistMethod_Random = // random map selection
1110 {
1111         float i, imax;
1112
1113         imax = 42;
1114
1115         for(i = 0; i <= imax; ++i)
1116         {
1117                 float mapindex;
1118                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1119                 if(Map_Check(mapindex, 1))
1120                         return mapindex;
1121         }
1122         return -1;
1123 }
1124
1125 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1126 // the exponent sets a bias on the map selection:
1127 // the higher the exponent, the less likely "shortly repeated" same maps are
1128 {
1129         float i, j, imax, insertpos;
1130
1131         imax = 42;
1132
1133         for(i = 0; i <= imax; ++i)
1134         {
1135                 string newlist;
1136
1137                 // now reinsert this at another position
1138                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1139                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1140                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1141                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1142
1143                 // insert the current map there
1144                 newlist = "";
1145                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1146                         newlist = strcat(newlist, " ", argv(j));
1147                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1148                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1149                         newlist = strcat(newlist, " ", argv(j));
1150                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1151                 cvar_set("g_maplist", newlist);
1152                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1153
1154                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1155                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1156                 if(Map_Check(Map_Current, 1))
1157                         return Map_Current;
1158         }
1159         return -1;
1160 }
1161
1162 void Maplist_Init()
1163 {
1164         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1165         if(Map_Count == 0)
1166         {
1167                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1168                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1169                 if(cvar("g_maplist_shuffle"))
1170                         ShuffleMaplist();
1171                 localcmd("\nmenu_cmd sync\n");
1172                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1173         }
1174         if(Map_Count == 0)
1175                 error("empty maplist, cannot select a new map");
1176         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1177
1178         if(Map_Current_Name)
1179                 strunzone(Map_Current_Name);
1180         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1181         // this may or may not be correct, but who cares, in the worst case a map
1182         // isn't chosen in the first pass that should have been
1183 }
1184
1185 string GetNextMap()
1186 {
1187         float nextMap;
1188
1189         Maplist_Init();
1190         nextMap = -1;
1191
1192         if(nextMap == -1)
1193                 if(cvar("g_maplist_shuffle") > 0)
1194                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1195
1196         if(nextMap == -1)
1197                 if(cvar("g_maplist_selectrandom"))
1198                         nextMap = MaplistMethod_Random();
1199
1200         if(nextMap == -1)
1201                 nextMap = MaplistMethod_Iterate();
1202
1203         if(nextMap == -1)
1204                 nextMap = MaplistMethod_Repeat();
1205
1206         if(nextMap >= 0)
1207         {
1208                 Map_Goto_SetFloat(nextMap);
1209                 return getmapname_stored;
1210         }
1211
1212         return "";
1213 };
1214
1215 float DoNextMapOverride()
1216 {
1217         if(cvar("g_campaign"))
1218         {
1219                 CampaignPostIntermission();
1220                 alreadychangedlevel = TRUE;
1221                 return TRUE;
1222         }
1223         if(cvar("quit_when_empty"))
1224         {
1225                 if(player_count <= currentbots)
1226                 {
1227                         localcmd("quit\n");
1228                         alreadychangedlevel = TRUE;
1229                         return TRUE;
1230                 }
1231         }
1232         if(cvar_string("quit_and_redirect") != "")
1233         {
1234                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1235                 alreadychangedlevel = TRUE;
1236                 return TRUE;
1237         }
1238         if (cvar("samelevel")) // if samelevel is set, stay on same level
1239         {
1240                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1241                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1242                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1243                 localcmd("restart\n");
1244                 //changelevel (mapname);
1245                 alreadychangedlevel = TRUE;
1246                 return TRUE;
1247         }
1248         if(cvar_string("nextmap") != "")
1249                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1250                 {
1251                         Map_Goto_SetStr(cvar_string("nextmap"));
1252                         Map_Goto();
1253                         alreadychangedlevel = TRUE;
1254                         return TRUE;
1255                 }
1256         if(cvar("lastlevel"))
1257         {
1258                 GameResetCfg();
1259                 localcmd("set lastlevel 0\ntogglemenu\n");
1260                 alreadychangedlevel = TRUE;
1261                 return TRUE;
1262         }
1263         return FALSE;
1264 };
1265
1266 void GotoNextMap()
1267 {
1268         //local string nextmap;
1269         //local float n, nummaps;
1270         //local string s;
1271         if (alreadychangedlevel)
1272                 return;
1273         alreadychangedlevel = TRUE;
1274
1275         {
1276                 string nextMap;
1277                 float allowReset;
1278
1279                 for(allowReset = 1; allowReset >= 0; --allowReset)
1280                 {
1281                         nextMap = GetNextMap();
1282                         if(nextMap != "")
1283                                 break;
1284
1285                         if(allowReset)
1286                         {
1287                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1288                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1289                                 if(cvar("g_maplist_shuffle"))
1290                                         ShuffleMaplist();
1291                                 localcmd("\nmenu_cmd sync\n");
1292                         }
1293                         else
1294                         {
1295                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1296                         }
1297                 }
1298                 Map_Goto();
1299         }
1300 };
1301
1302
1303 /*
1304 ============
1305 IntermissionThink
1306
1307 When the player presses attack or jump, change to the next level
1308 ============
1309 */
1310 .float autoscreenshot;
1311 void() MapVote_Start;
1312 void() MapVote_Think;
1313 float mapvote_initialized;
1314 void IntermissionThink()
1315 {
1316         FixIntermissionClient(self);
1317
1318         if(cvar("sv_autoscreenshot"))
1319         if(self.autoscreenshot > 0)
1320         if(time > self.autoscreenshot)
1321         {
1322                 self.autoscreenshot = -1;
1323                 if(clienttype(self) == CLIENTTYPE_REAL)
1324                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1325                 return;
1326         }
1327
1328         if (time < intermission_exittime)
1329                 return;
1330
1331         if(!mapvote_initialized)
1332                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1333                         return;
1334
1335         MapVote_Start();
1336 };
1337
1338 /*
1339 ============
1340 FindIntermission
1341
1342 Returns the entity to view from
1343 ============
1344 */
1345 /*
1346 entity FindIntermission()
1347 {
1348         local   entity spot;
1349         local   float cyc;
1350
1351 // look for info_intermission first
1352         spot = find (world, classname, "info_intermission");
1353         if (spot)
1354         {       // pick a random one
1355                 cyc = random() * 4;
1356                 while (cyc > 1)
1357                 {
1358                         spot = find (spot, classname, "info_intermission");
1359                         if (!spot)
1360                                 spot = find (spot, classname, "info_intermission");
1361                         cyc = cyc - 1;
1362                 }
1363                 return spot;
1364         }
1365
1366 // then look for the start position
1367         spot = find (world, classname, "info_player_start");
1368         if (spot)
1369                 return spot;
1370
1371 // testinfo_player_start is only found in regioned levels
1372         spot = find (world, classname, "testplayerstart");
1373         if (spot)
1374                 return spot;
1375
1376 // then look for the start position
1377         spot = find (world, classname, "info_player_deathmatch");
1378         if (spot)
1379                 return spot;
1380
1381         //objerror ("FindIntermission: no spot");
1382         return world;
1383 };
1384 */
1385
1386 /*
1387 ===============================================================================
1388
1389 RULES
1390
1391 ===============================================================================
1392 */
1393
1394 void DumpStats(float final)
1395 {
1396         local float file;
1397         local string s;
1398         local float to_console;
1399         local float to_eventlog;
1400         local float to_file;
1401         local float i;
1402
1403         to_console = cvar("sv_logscores_console");
1404         to_eventlog = cvar("sv_eventlog");
1405         to_file = cvar("sv_logscores_file");
1406
1407         if(!final)
1408         {
1409                 to_console = TRUE; // always print printstats replies
1410                 to_eventlog = FALSE; // but never print them to the event log
1411         }
1412
1413         if(to_eventlog)
1414                 if(cvar("sv_eventlog_console"))
1415                         to_console = FALSE; // otherwise we get the output twice
1416
1417         if(final)
1418                 s = ":scores:";
1419         else
1420                 s = ":status:";
1421         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1422
1423         if(to_console)
1424                 print(s, "\n");
1425         if(to_eventlog)
1426                 GameLogEcho(s);
1427         if(to_file)
1428         {
1429                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1430                 if(file == -1)
1431                         to_file = FALSE;
1432                 else
1433                         fputs(file, strcat(s, "\n"));
1434         }
1435
1436         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1437         if(to_console)
1438                 print(s, "\n");
1439         if(to_eventlog)
1440                 GameLogEcho(s);
1441         if(to_file)
1442                 fputs(file, strcat(s, "\n"));
1443
1444         FOR_EACH_CLIENT(other)
1445         {
1446                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1447                 {
1448                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1449                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1450                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1451                                 s = strcat(s, ftos(other.team), ":");
1452                         else
1453                                 s = strcat(s, "spectator:");
1454
1455                         if(to_console)
1456                                 print(s, other.netname, "\n");
1457                         if(to_eventlog)
1458                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1459                         if(to_file)
1460                                 fputs(file, strcat(s, other.netname, "\n"));
1461                 }
1462         }
1463
1464         if(teams_matter)
1465         {
1466                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1467                 if(to_console)
1468                         print(s, "\n");
1469                 if(to_eventlog)
1470                         GameLogEcho(s);
1471                 if(to_file)
1472                         fputs(file, strcat(s, "\n"));
1473
1474                 for(i = 1; i < 16; ++i)
1475                 {
1476                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1477                         s = strcat(s, ":", ftos(i));
1478                         if(to_console)
1479                                 print(s, "\n");
1480                         if(to_eventlog)
1481                                 GameLogEcho(s);
1482                         if(to_file)
1483                                 fputs(file, strcat(s, "\n"));
1484                 }
1485         }
1486
1487         if(to_console)
1488                 print(":end\n");
1489         if(to_eventlog)
1490                 GameLogEcho(":end");
1491         if(to_file)
1492         {
1493                 fputs(file, ":end\n");
1494                 fclose(file);
1495         }
1496 }
1497
1498 void FixIntermissionClient(entity e)
1499 {
1500         string s;
1501         if(!e.autoscreenshot) // initial call
1502         {
1503                 e.angles = e.v_angle;
1504                 e.angles_x = -e.angles_x;
1505                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1506                 e.health = -2342;
1507                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1508                 e.solid = SOLID_NOT;
1509                 e.movetype = MOVETYPE_NONE;
1510                 e.takedamage = DAMAGE_NO;
1511                 if(e.weaponentity)
1512                 {
1513                         e.weaponentity.effects = EF_NODRAW;
1514                         if (e.weaponentity.weaponentity)
1515                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1516                 }
1517                 if(clienttype(e) == CLIENTTYPE_REAL)
1518                 {
1519                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1520                         s = cvar_string("sv_intermission_cdtrack");
1521                         if(s != "")
1522                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1523                         msg_entity = e;
1524                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1525                 }
1526         }
1527
1528         //e.velocity = '0 0 0';
1529         //e.fixangle = TRUE;
1530
1531         // TODO halt weapon animation
1532 }
1533
1534
1535 /*
1536 go to the next level for deathmatch
1537 only called if a time or frag limit has expired
1538 */
1539 void NextLevel()
1540 {
1541         float i;
1542
1543         gameover = TRUE;
1544
1545         intermission_running = 1;
1546
1547 // enforce a wait time before allowing changelevel
1548         if(player_count > 0)
1549                 intermission_exittime = time + cvar("sv_mapchange_delay");
1550         else
1551                 intermission_exittime = -1;
1552
1553         /*
1554         WriteByte (MSG_ALL, SVC_CDTRACK);
1555         WriteByte (MSG_ALL, 3);
1556         WriteByte (MSG_ALL, 3);
1557         // done in FixIntermission
1558         */
1559
1560         //pos = FindIntermission ();
1561
1562         VoteReset();
1563
1564         DumpStats(TRUE);
1565
1566         if(cvar("sv_eventlog"))
1567                 GameLogEcho(":gameover");
1568
1569         GameLogClose();
1570
1571 // TO DO
1572
1573 // save the stats to a text file on the client
1574 // stuffcmd(other, log_stats "stats/file_name");
1575 // bprint stats
1576 // stuffcmd(other, log_stats "");
1577 // use a filename similar to the demo name
1578         // string file_name;
1579         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1580
1581 // write a stats parser for the menu
1582
1583         if(cvar("sv_accuracy_data_send")) {
1584                 string stats_to_send;
1585
1586                 FOR_EACH_CLIENT(other) {  // make the string to send
1587                         FixIntermissionClient(other);
1588
1589                         if(other.cvar_cl_accuracy_data_share) {
1590                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1591
1592                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1593                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1594
1595                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1596
1597                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1598                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1599
1600                                 stats_to_send = strcat(stats_to_send, "\n");
1601                         }
1602                 }
1603
1604                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1605                         Score_NicePrint(other);  // print the score
1606
1607                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1608                                 bprint(stats_to_send);
1609                 }
1610         } else { // ye olde message
1611                 FOR_EACH_PLAYER(other) {
1612                         FixIntermissionClient(other);
1613
1614                         if(other.winning)
1615                                 bprint(other.netname, " ^7wins.\n");
1616                 }
1617         }
1618
1619         if(cvar("g_campaign"))
1620                 CampaignPreIntermission();
1621
1622         localcmd("\nsv_hook_gameend\n");
1623 }
1624
1625 /*
1626 ============
1627 CheckRules_Player
1628
1629 Exit deathmatch games upon conditions
1630 ============
1631 */
1632 void CheckRules_Player()
1633 {
1634         if (gameover)   // someone else quit the game already
1635                 return;
1636
1637         if(self.deadflag == DEAD_NO)
1638                 self.play_time += frametime;
1639
1640         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1641         //   (div0: and that in CheckRules_World please)
1642 };
1643
1644 float checkrules_equality;
1645 float checkrules_suddendeathwarning;
1646 float checkrules_suddendeathend;
1647 float checkrules_overtimesadded; //how many overtimes have been already added
1648
1649 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1650 float WINNING_YES = 1; // winner found
1651 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1652 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1653
1654 float InitiateSuddenDeath()
1655 {
1656         // Check first whether normal overtimes could be added before initiating suddendeath mode
1657         // - for this timelimit_overtime needs to be >0 of course
1658         // - also check the winning condition calculated in the previous frame and only add normal overtime
1659         //   again, if at the point at which timelimit would be extended again, still no winner was found
1660         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1661         {
1662                 return 1; // need to call InitiateOvertime later
1663         }
1664         else
1665         {
1666                 if(!checkrules_suddendeathend)
1667                 {
1668                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1669                         if(g_race && !g_race_qualifying)
1670                                 race_StartCompleting();
1671                 }
1672                 return 0;
1673         }
1674 }
1675
1676 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1677 {
1678         ++checkrules_overtimesadded;
1679         //add one more overtime by simply extending the timelimit
1680         float tl;
1681         tl = cvar("timelimit");
1682         tl += cvar("timelimit_overtime");
1683         cvar_set("timelimit", ftos(tl));
1684         string minutesPlural;
1685         if (cvar("timelimit_overtime") == 1)
1686                 minutesPlural = " ^3minute";
1687         else
1688                 minutesPlural = " ^3minutes";
1689
1690         bcenterprint(
1691                 strcat(
1692                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1693                         ftos(cvar("timelimit_overtime")),
1694                         minutesPlural,
1695                         " to the game!"
1696                 )
1697         );
1698 }
1699
1700 float GetWinningCode(float fraglimitreached, float equality)
1701 {
1702         if(cvar("g_campaign") == 1)
1703                 if(fraglimitreached)
1704                         return WINNING_YES;
1705                 else
1706                         return WINNING_NO;
1707
1708         else
1709                 if(equality)
1710                         if(fraglimitreached)
1711                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1712                         else
1713                                 return WINNING_NEVER;
1714                 else
1715                         if(fraglimitreached)
1716                                 return WINNING_YES;
1717                         else
1718                                 return WINNING_NO;
1719 }
1720
1721 // set the .winning flag for exactly those players with a given field value
1722 void SetWinners(.float field, float value)
1723 {
1724         entity head;
1725         FOR_EACH_PLAYER(head)
1726                 head.winning = (head.field == value);
1727 }
1728
1729 // set the .winning flag for those players with a given field value
1730 void AddWinners(.float field, float value)
1731 {
1732         entity head;
1733         FOR_EACH_PLAYER(head)
1734                 if(head.field == value)
1735                         head.winning = 1;
1736 }
1737
1738 // clear the .winning flags
1739 void ClearWinners(void)
1740 {
1741         entity head;
1742         FOR_EACH_PLAYER(head)
1743                 head.winning = 0;
1744 }
1745
1746 // Onslaught winning condition:
1747 // game terminates if only one team has a working generator (or none)
1748 float WinningCondition_Onslaught()
1749 {
1750         entity head;
1751         local float t1, t2, t3, t4;
1752
1753         WinningConditionHelper(); // set worldstatus
1754
1755         if(inWarmupStage)
1756                 return WINNING_NO;
1757
1758         // first check if the game has ended
1759         t1 = t2 = t3 = t4 = 0;
1760         head = find(world, classname, "onslaught_generator");
1761         while (head)
1762         {
1763                 if (head.health > 0)
1764                 {
1765                         if (head.team == COLOR_TEAM1) t1 = 1;
1766                         if (head.team == COLOR_TEAM2) t2 = 1;
1767                         if (head.team == COLOR_TEAM3) t3 = 1;
1768                         if (head.team == COLOR_TEAM4) t4 = 1;
1769                 }
1770                 head = find(head, classname, "onslaught_generator");
1771         }
1772         if (t1 + t2 + t3 + t4 < 2)
1773         {
1774                 // game over, only one team remains (or none)
1775                 ClearWinners();
1776                 if (t1) SetWinners(team, COLOR_TEAM1);
1777                 if (t2) SetWinners(team, COLOR_TEAM2);
1778                 if (t3) SetWinners(team, COLOR_TEAM3);
1779                 if (t4) SetWinners(team, COLOR_TEAM4);
1780                 dprint("Have a winner, ending game.\n");
1781                 return WINNING_YES;
1782         }
1783
1784         // Two or more teams remain
1785         return WINNING_NO;
1786 }
1787
1788 float LMS_NewPlayerLives()
1789 {
1790         float fl;
1791         fl = cvar("fraglimit");
1792         if(fl == 0)
1793                 fl = 999;
1794
1795         // first player has left the game for dying too much? Nobody else can get in.
1796         if(lms_lowest_lives < 1)
1797                 return 0;
1798
1799         if(!cvar("g_lms_join_anytime"))
1800                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1801                         return 0;
1802
1803         return bound(1, lms_lowest_lives, fl);
1804 }
1805
1806 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1807 // they win. Otherwise the defending team wins once the timelimit passes.
1808 void assault_new_round();
1809 float WinningCondition_Assault()
1810 {
1811         local float status;
1812
1813         WinningConditionHelper(); // set worldstatus
1814
1815         status = WINNING_NO;
1816         // as the timelimit has not yet passed just assume the defending team will win
1817         if(assault_attacker_team == COLOR_TEAM1)
1818         {
1819                 SetWinners(team, COLOR_TEAM2);
1820         }
1821         else
1822         {
1823                 SetWinners(team, COLOR_TEAM1);
1824         }
1825
1826         local entity ent;
1827         ent = find(world, classname, "target_assault_roundend");
1828         if(ent)
1829         {
1830                 if(ent.winning) // round end has been triggered by attacking team
1831                 {
1832                         bprint("ASSAULT: round completed...\n");
1833                         SetWinners(team, assault_attacker_team);
1834
1835                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1836
1837                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1838                         {
1839                                 status = WINNING_YES;
1840                         }
1841                         else
1842                         {
1843                                 local entity oldself;
1844                                 oldself = self;
1845                                 self = ent;
1846                                 assault_new_round();
1847                                 self = oldself;
1848                         }
1849                 }
1850         }
1851
1852         return status;
1853 }
1854
1855 // LMS winning condition: game terminates if and only if there's at most one
1856 // one player who's living lives. Top two scores being equal cancels the time
1857 // limit.
1858 float WinningCondition_LMS()
1859 {
1860         entity head, head2;
1861         float have_player;
1862         float have_players;
1863         float l;
1864
1865         have_player = FALSE;
1866         have_players = FALSE;
1867         l = LMS_NewPlayerLives();
1868
1869         head = find(world, classname, "player");
1870         if(head)
1871                 have_player = TRUE;
1872         head2 = find(head, classname, "player");
1873         if(head2)
1874                 have_players = TRUE;
1875
1876         if(have_player)
1877         {
1878                 // we have at least one player
1879                 if(have_players)
1880                 {
1881                         // two or more active players - continue with the game
1882                 }
1883                 else
1884                 {
1885                         // exactly one player?
1886
1887                         ClearWinners();
1888                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1889
1890                         if(l)
1891                         {
1892                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1893                                 return WINNING_NO;
1894                         }
1895                         else
1896                         {
1897                                 // a winner!
1898                                 // and assign him his first place
1899                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1900                                 return WINNING_YES;
1901                         }
1902                 }
1903         }
1904         else
1905         {
1906                 // nobody is playing at all...
1907                 if(l)
1908                 {
1909                         // wait for players...
1910                 }
1911                 else
1912                 {
1913                         // SNAFU (maybe a draw game?)
1914                         ClearWinners();
1915                         dprint("No players, ending game.\n");
1916                         return WINNING_YES;
1917                 }
1918         }
1919
1920         // When we get here, we have at least two players who are actually LIVING,
1921         // now check if the top two players have equal score.
1922         WinningConditionHelper();
1923
1924         ClearWinners();
1925         if(WinningConditionHelper_winner)
1926                 WinningConditionHelper_winner.winning = TRUE;
1927         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1928                 return WINNING_NEVER;
1929
1930         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1931         return WINNING_NO;
1932 }
1933
1934 void ShuffleMaplist()
1935 {
1936         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1937 }
1938
1939 float leaderfrags;
1940 float WinningCondition_Scores(float limit, float leadlimit)
1941 {
1942         float limitreached;
1943
1944         // TODO make everything use THIS winning condition (except LMS)
1945         WinningConditionHelper();
1946
1947         if(teams_matter)
1948         {
1949                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1950                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1951                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1952                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1953         }
1954
1955         ClearWinners();
1956         if(WinningConditionHelper_winner)
1957                 WinningConditionHelper_winner.winning = 1;
1958         if(WinningConditionHelper_winnerteam >= 0)
1959                 SetWinners(team, WinningConditionHelper_winnerteam);
1960
1961         if(WinningConditionHelper_lowerisbetter)
1962         {
1963                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1964                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1965                 limit = -limit;
1966         }
1967
1968         if(WinningConditionHelper_zeroisworst)
1969                 leadlimit = 0; // not supported in this mode
1970
1971         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1972         // these modes always score in increments of 1, thus this makes sense
1973         {
1974                 if(leaderfrags != WinningConditionHelper_topscore)
1975                 {
1976                         leaderfrags = WinningConditionHelper_topscore;
1977
1978                         if (limit)
1979                         if (leaderfrags == limit - 1)
1980                                 Announce("1fragleft");
1981                         else if (leaderfrags == limit - 2)
1982                                 Announce("2fragsleft");
1983                         else if (leaderfrags == limit - 3)
1984                                 Announce("3fragsleft");
1985                 }
1986         }
1987
1988         limitreached = FALSE;
1989         if(limit)
1990                 if(WinningConditionHelper_topscore >= limit)
1991                         limitreached = TRUE;
1992         if(leadlimit)
1993         {
1994                 float leadlimitreached;
1995                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1996                 if(cvar("leadlimit_and_fraglimit"))
1997                         limitreached = (limitreached && leadlimitreached);
1998                 else
1999                         limitreached = (limitreached || leadlimitreached);
2000         }
2001
2002         return GetWinningCode(
2003                 WinningConditionHelper_topscore && limitreached,
2004                 WinningConditionHelper_equality
2005         );
2006 }
2007
2008 float WinningCondition_Race(float fraglimit)
2009 {
2010         float wc;
2011         entity p;
2012         float n, c;
2013
2014         n = 0;
2015         c = 0;
2016         FOR_EACH_PLAYER(p)
2017         {
2018                 ++n;
2019                 if(p.race_completed)
2020                         ++c;
2021         }
2022         if(n && (n == c))
2023                 return WINNING_YES;
2024         wc = WinningCondition_Scores(fraglimit, 0);
2025
2026         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2027         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2028         // do NOT support equality when the laps are all raced!
2029                 return WINNING_STARTSUDDENDEATHOVERTIME;
2030         else
2031                 return WINNING_NEVER;
2032         return wc;
2033 }
2034
2035 void ReadyRestart();
2036 float WinningCondition_QualifyingThenRace(float limit)
2037 {
2038         float wc;
2039         wc = WinningCondition_Scores(limit, 0);
2040
2041         // NEVER initiate overtime
2042         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2043         {
2044                 return WINNING_YES;
2045         }
2046
2047         return wc;
2048 }
2049
2050 float WinningCondition_RanOutOfSpawns()
2051 {
2052         entity head;
2053
2054         if(have_team_spawns <= 0)
2055                 return WINNING_NO;
2056
2057         if(!some_spawn_has_been_used)
2058                 return WINNING_NO;
2059
2060         team1_score = team2_score = team3_score = team4_score = 0;
2061
2062         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2063         {
2064                 if(head.team == COLOR_TEAM1)
2065                         team1_score = 1;
2066                 else if(head.team == COLOR_TEAM2)
2067                         team2_score = 1;
2068                 else if(head.team == COLOR_TEAM3)
2069                         team3_score = 1;
2070                 else if(head.team == COLOR_TEAM4)
2071                         team4_score = 1;
2072         }
2073
2074         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2075         {
2076                 if(head.team == COLOR_TEAM1)
2077                         team1_score = 1;
2078                 else if(head.team == COLOR_TEAM2)
2079                         team2_score = 1;
2080                 else if(head.team == COLOR_TEAM3)
2081                         team3_score = 1;
2082                 else if(head.team == COLOR_TEAM4)
2083                         team4_score = 1;
2084         }
2085
2086         ClearWinners();
2087         if(team1_score + team2_score + team3_score + team4_score == 0)
2088         {
2089                 checkrules_equality = TRUE;
2090                 return WINNING_YES;
2091         }
2092         else if(team1_score + team2_score + team3_score + team4_score == 1)
2093         {
2094                 float t, i;
2095                 if(team1_score) t = COLOR_TEAM1;
2096                 if(team2_score) t = COLOR_TEAM2;
2097                 if(team3_score) t = COLOR_TEAM3;
2098                 if(team4_score) t = COLOR_TEAM4;
2099                 CheckAllowedTeams(world);
2100                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2101                 {
2102                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2103                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2104                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2105                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2106                 }
2107
2108                 AddWinners(team, t);
2109                 return WINNING_YES;
2110         }
2111         else
2112                 return WINNING_NO;
2113 }
2114
2115 /*
2116 ============
2117 CheckRules_World
2118
2119 Exit deathmatch games upon conditions
2120 ============
2121 */
2122 void CheckRules_World()
2123 {
2124         float timelimit;
2125         float fraglimit;
2126         float leadlimit;
2127
2128         VoteThink();
2129         MapVote_Think();
2130
2131         SetDefaultAlpha();
2132
2133         /*
2134         MapVote_Think should now do that part
2135         if (intermission_running)
2136                 if (time >= intermission_exittime + 60)
2137                 {
2138                         if(!DoNextMapOverride())
2139                                 GotoNextMap();
2140                         return;
2141                 }
2142         */
2143
2144         if (gameover)   // someone else quit the game already
2145         {
2146                 if(player_count == 0) // Nobody there? Then let's go to the next map
2147                         MapVote_Start();
2148                         // this will actually check the player count in the next frame
2149                         // again, but this shouldn't hurt
2150                 return;
2151         }
2152
2153         timelimit = cvar("timelimit") * 60;
2154         fraglimit = cvar("fraglimit");
2155         leadlimit = cvar("leadlimit");
2156
2157         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2158         {
2159                 if(timelimit > 0)
2160                         timelimit = 0; // timelimit is not made for warmup
2161                 if(fraglimit > 0)
2162                         fraglimit = 0; // no fraglimit for now
2163                 leadlimit = 0; // no leadlimit for now
2164         }
2165
2166         if(g_onslaught)
2167                 timelimit = 0; // ONS has its own overtime rule
2168
2169         if(timelimit > 0)
2170         {
2171                 timelimit += game_starttime;
2172         }
2173         else if (timelimit < 0)
2174         {
2175                 // endmatch
2176                 NextLevel();
2177                 return;
2178         }
2179
2180         float wantovertime;
2181         wantovertime = 0;
2182
2183         if(checkrules_suddendeathend)
2184         {
2185                 if(!checkrules_suddendeathwarning)
2186                 {
2187                         checkrules_suddendeathwarning = TRUE;
2188                         if(g_race && !g_race_qualifying)
2189                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2190                         else
2191                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2192                 }
2193         }
2194         else
2195         {
2196                 if (timelimit && time >= timelimit)
2197                 {
2198                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2199                         {
2200                                 float totalplayers;
2201                                 float playerswithlaps;
2202                                 float readyplayers;
2203                                 entity head;
2204                                 totalplayers = playerswithlaps = readyplayers = 0;
2205                                 FOR_EACH_PLAYER(head)
2206                                 {
2207                                         ++totalplayers;
2208                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2209                                                 ++playerswithlaps;
2210                                         if(head.ready)
2211                                                 ++readyplayers;
2212                                 }
2213
2214                                 // at least 2 of the players have completed a lap: start the RACE
2215                                 // otherwise, the players should end the qualifying on their own
2216                                 if(readyplayers || playerswithlaps >= 2)
2217                                 {
2218                                         checkrules_suddendeathend = 0;
2219                                         ReadyRestart(); // go to race
2220                                         return;
2221                                 }
2222                                 else
2223                                         wantovertime |= InitiateSuddenDeath();
2224                         }
2225                         else
2226                                 wantovertime |= InitiateSuddenDeath();
2227                 }
2228         }
2229
2230         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2231         {
2232                 NextLevel();
2233                 return;
2234         }
2235
2236         float checkrules_status;
2237         checkrules_status = WinningCondition_RanOutOfSpawns();
2238         if(checkrules_status == WINNING_YES)
2239         {
2240                 bprint("Hey! Someone ran out of spawns!\n");
2241         }
2242         else if(g_race && !g_race_qualifying && timelimit >= 0)
2243         {
2244                 checkrules_status = WinningCondition_Race(fraglimit);
2245                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2246         }
2247         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2248         {
2249                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2250                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2251         }
2252         else if(g_assault)
2253         {
2254                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2255         }
2256         else if(g_lms)
2257         {
2258                 checkrules_status = WinningCondition_LMS();
2259         }
2260         else if (g_onslaught)
2261         {
2262                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2263         }
2264         else
2265         {
2266                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2267                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2268         }
2269
2270         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2271         {
2272                 checkrules_status = WINNING_NEVER;
2273                 checkrules_overtimesadded = -1;
2274                 wantovertime |= InitiateSuddenDeath();
2275         }
2276
2277         if(checkrules_status == WINNING_NEVER)
2278                 // equality cases! Nobody wins if the overtime ends in a draw.
2279                 ClearWinners();
2280
2281         if(wantovertime)
2282         {
2283                 if(checkrules_status == WINNING_NEVER)
2284                         InitiateOvertime();
2285                 else
2286                         checkrules_status = WINNING_YES;
2287         }
2288
2289         if(checkrules_suddendeathend)
2290                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2291                         checkrules_status = WINNING_YES;
2292
2293         if(checkrules_status == WINNING_YES)
2294         {
2295                 //print("WINNING\n");
2296                 NextLevel();
2297         }
2298 };
2299
2300 float mapvote_nextthink;
2301 float mapvote_initialized;
2302 float mapvote_keeptwotime;
2303 float mapvote_timeout;
2304 string mapvote_message;
2305 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2306 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2307 float mapvote_screenshot_dirs_count;
2308
2309 float mapvote_count;
2310 float mapvote_count_real;
2311 string mapvote_maps[MAPVOTE_COUNT];
2312 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2313 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2314 float mapvote_maps_suggested[MAPVOTE_COUNT];
2315 string mapvote_suggestions[MAPVOTE_COUNT];
2316 float mapvote_suggestion_ptr;
2317 float mapvote_maxlen;
2318 float mapvote_voters;
2319 float mapvote_votes[MAPVOTE_COUNT];
2320 float mapvote_run;
2321 float mapvote_detail;
2322 float mapvote_abstain;
2323 .float mapvote;
2324
2325 void MapVote_ClearAllVotes()
2326 {
2327         FOR_EACH_CLIENT(other)
2328                 other.mapvote = 0;
2329 }
2330
2331 string MapVote_Suggest(string m)
2332 {
2333         float i;
2334         if(m == "")
2335                 return "That's not how to use this command.";
2336         if(!cvar("g_maplist_votable_suggestions"))
2337                 return "Suggestions are not accepted on this server.";
2338         if(mapvote_initialized)
2339                 return "Can't suggest - voting is already in progress!";
2340         m = MapInfo_FixName(m);
2341         if(!m)
2342                 return "The map you suggested is not available on this server.";
2343         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2344                 if(Map_IsRecent(m))
2345                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2346
2347         if(!MapInfo_CheckMap(m))
2348                 return "The map you suggested does not support the current game mode.";
2349         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2350                 if(mapvote_suggestions[i] == m)
2351                         return "This map was already suggested.";
2352         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2353         {
2354                 i = floor(random() * mapvote_suggestion_ptr);
2355         }
2356         else
2357         {
2358                 i = mapvote_suggestion_ptr;
2359                 mapvote_suggestion_ptr += 1;
2360         }
2361         if(mapvote_suggestions[i] != "")
2362                 strunzone(mapvote_suggestions[i]);
2363         mapvote_suggestions[i] = strzone(m);
2364         if(cvar("sv_eventlog"))
2365                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2366         return strcat("Suggestion of ", m, " accepted.");
2367 }
2368
2369 void MapVote_AddVotable(string nextMap, float isSuggestion)
2370 {
2371         float j, i, o;
2372         string pakfile, mapfile;
2373
2374         if(nextMap == "")
2375                 return;
2376         for(j = 0; j < mapvote_count; ++j)
2377                 if(mapvote_maps[j] == nextMap)
2378                         return;
2379         if(strlen(nextMap) > mapvote_maxlen)
2380                 mapvote_maxlen = strlen(nextMap);
2381         mapvote_maps[mapvote_count] = strzone(nextMap);
2382         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2383
2384         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2385         {
2386                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2387                 pakfile = whichpack(strcat(mapfile, ".tga"));
2388                 if(pakfile == "")
2389                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2390                 if(pakfile == "")
2391                         pakfile = whichpack(strcat(mapfile, ".png"));
2392                 if(pakfile != "")
2393                         break;
2394         }
2395         if(i >= mapvote_screenshot_dirs_count)
2396                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2397         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2398                 pakfile = substring(pakfile, o, -1);
2399
2400         mapvote_maps_screenshot_dir[mapvote_count] = i;
2401         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2402
2403         mapvote_count += 1;
2404 }
2405
2406 void MapVote_Spawn();
2407 void MapVote_Init()
2408 {
2409         float i;
2410         float nmax, smax;
2411
2412         MapVote_ClearAllVotes();
2413
2414         mapvote_count = 0;
2415         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2416         mapvote_abstain = cvar("g_maplist_votable_abstain");
2417
2418         if(mapvote_abstain)
2419                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2420         else
2421                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2422         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2423
2424         // we need this for AddVotable, as that cycles through the screenshot dirs
2425         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2426         if(mapvote_screenshot_dirs_count == 0)
2427                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2428         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2429         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2430                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2431
2432         if(mapvote_suggestion_ptr)
2433                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2434                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2435
2436         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2437                 MapVote_AddVotable(GetNextMap(), FALSE);
2438
2439         if(mapvote_count == 0)
2440         {
2441                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2442                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2443                 if(cvar("g_maplist_shuffle"))
2444                         ShuffleMaplist();
2445                 localcmd("\nmenu_cmd sync\n");
2446                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2447                         MapVote_AddVotable(GetNextMap(), FALSE);
2448         }
2449
2450         mapvote_count_real = mapvote_count;
2451         if(mapvote_abstain)
2452                 MapVote_AddVotable("don't care", 0);
2453
2454         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2455
2456         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2457         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2458         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2459                 mapvote_keeptwotime = 0;
2460         mapvote_message = "Choose a map and press its key!";
2461
2462         MapVote_Spawn();
2463 }
2464
2465 void MapVote_SendPicture(float id)
2466 {
2467         msg_entity = self;
2468         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2469         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2470         WriteByte(MSG_ONE, id);
2471         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2472 }
2473
2474 float GameCommand_MapVote(string cmd)
2475 {
2476         if(!intermission_running)
2477                 return FALSE;
2478
2479         if(cmd == "mv_getpic")
2480         {
2481                 MapVote_SendPicture(stof(argv(1)));
2482                 return TRUE;
2483         }
2484
2485         return FALSE;
2486 }
2487
2488 float MapVote_GetMapMask()
2489 {
2490         float mask, i, power;
2491         mask = 0;
2492         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2493                 if(mapvote_maps[i] != "")
2494                         mask |= power;
2495         return mask;
2496 }
2497
2498 entity mapvote_ent;
2499 float MapVote_SendEntity(entity to, float sf)
2500 {
2501         float i;
2502
2503         if(sf & 1)
2504                 sf &~= 2; // if we send 1, we don't need to also send 2
2505
2506         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2507         WriteByte(MSG_ENTITY, sf);
2508
2509         if(sf & 1)
2510         {
2511                 // flag 1 == initialization
2512                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2513                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2514                 WriteString(MSG_ENTITY, "");
2515                 WriteByte(MSG_ENTITY, mapvote_count);
2516                 WriteByte(MSG_ENTITY, mapvote_abstain);
2517                 WriteByte(MSG_ENTITY, mapvote_detail);
2518                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2519                 if(mapvote_count <= 8)
2520                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2521                 else
2522                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2523                 for(i = 0; i < mapvote_count; ++i)
2524                         if(mapvote_maps[i] != "")
2525                         {
2526                                 if(mapvote_abstain && i == mapvote_count - 1)
2527                                 {
2528                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2529                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2530                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2531                                 }
2532                                 else
2533                                 {
2534                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2535                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2536                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2537                                 }
2538                         }
2539         }
2540
2541         if(sf & 2)
2542         {
2543                 // flag 2 == update of mask
2544                 if(mapvote_count <= 8)
2545                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2546                 else
2547                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2548         }
2549
2550         if(sf & 4)
2551         {
2552                 if(mapvote_detail)
2553                         for(i = 0; i < mapvote_count; ++i)
2554                                 if(mapvote_maps[i] != "")
2555                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2556
2557                 WriteByte(MSG_ENTITY, to.mapvote);
2558         }
2559
2560         return TRUE;
2561 }
2562
2563 void MapVote_Spawn()
2564 {
2565         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2566 }
2567
2568 void MapVote_TouchMask()
2569 {
2570         mapvote_ent.SendFlags |= 2;
2571 }
2572
2573 void MapVote_TouchVotes(entity voter)
2574 {
2575         mapvote_ent.SendFlags |= 4;
2576 }
2577
2578 float MapVote_Finished(float mappos)
2579 {
2580         string result;
2581         float i;
2582         float didntvote;
2583
2584         if(cvar("sv_eventlog"))
2585         {
2586                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2587                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2588                 didntvote = mapvote_voters;
2589                 for(i = 0; i < mapvote_count; ++i)
2590                         if(mapvote_maps[i] != "")
2591                         {
2592                                 didntvote -= mapvote_votes[i];
2593                                 if(i != mappos)
2594                                 {
2595                                         result = strcat(result, ":", mapvote_maps[i]);
2596                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2597                                 }
2598                         }
2599                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2600
2601                 GameLogEcho(result);
2602                 if(mapvote_maps_suggested[mappos])
2603                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2604         }
2605
2606         FOR_EACH_REALCLIENT(other)
2607                 FixClientCvars(other);
2608
2609         Map_Goto_SetStr(mapvote_maps[mappos]);
2610         Map_Goto();
2611         alreadychangedlevel = TRUE;
2612         return TRUE;
2613 }
2614 void MapVote_CheckRules_1()
2615 {
2616         float i;
2617
2618         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2619         {
2620                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2621                 mapvote_votes[i] = 0;
2622         }
2623
2624         mapvote_voters = 0;
2625         FOR_EACH_REALCLIENT(other)
2626         {
2627                 ++mapvote_voters;
2628                 if(other.mapvote)
2629                 {
2630                         i = other.mapvote - 1;
2631                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2632                         mapvote_votes[i] = mapvote_votes[i] + 1;
2633                 }
2634         }
2635 }
2636
2637 float MapVote_CheckRules_2()
2638 {
2639         float i;
2640         float firstPlace, secondPlace;
2641         float firstPlaceVotes, secondPlaceVotes;
2642         float mapvote_voters_real;
2643         string result;
2644
2645         if(mapvote_count_real == 1)
2646                 return MapVote_Finished(0);
2647
2648         mapvote_voters_real = mapvote_voters;
2649         if(mapvote_abstain)
2650                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2651
2652         RandomSelection_Init();
2653         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2654                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2655         firstPlace = RandomSelection_chosen_float;
2656         firstPlaceVotes = RandomSelection_best_priority;
2657         //dprint("First place: ", ftos(firstPlace), "\n");
2658         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2659
2660         RandomSelection_Init();
2661         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2662                 if(i != firstPlace)
2663                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2664         secondPlace = RandomSelection_chosen_float;
2665         secondPlaceVotes = RandomSelection_best_priority;
2666         //dprint("Second place: ", ftos(secondPlace), "\n");
2667         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2668
2669         if(firstPlace == -1)
2670                 error("No first place in map vote... WTF?");
2671
2672         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2673                 return MapVote_Finished(firstPlace);
2674
2675         if(mapvote_keeptwotime)
2676                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2677                 {
2678                         float didntvote;
2679                         MapVote_TouchMask();
2680                         mapvote_message = "Now decide between the TOP TWO!";
2681                         mapvote_keeptwotime = 0;
2682                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2683                         result = strcat(result, ":", ftos(firstPlaceVotes));
2684                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2685                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2686                         didntvote = mapvote_voters;
2687                         for(i = 0; i < mapvote_count; ++i)
2688                                 if(mapvote_maps[i] != "")
2689                                 {
2690                                         didntvote -= mapvote_votes[i];
2691                                         if(i != firstPlace)
2692                                                 if(i != secondPlace)
2693                                                 {
2694                                                         result = strcat(result, ":", mapvote_maps[i]);
2695                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2696                                                         if(i < mapvote_count_real)
2697                                                         {
2698                                                                 strunzone(mapvote_maps[i]);
2699                                                                 mapvote_maps[i] = "";
2700                                                                 strunzone(mapvote_maps_pakfile[i]);
2701                                                                 mapvote_maps_pakfile[i] = "";
2702                                                         }
2703                                                 }
2704                                 }
2705                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2706                         if(cvar("sv_eventlog"))
2707                                 GameLogEcho(result);
2708                 }
2709
2710         return FALSE;
2711 }
2712 void MapVote_Tick()
2713 {
2714         float keeptwo;
2715         float totalvotes;
2716
2717         keeptwo = mapvote_keeptwotime;
2718         MapVote_CheckRules_1(); // count
2719         if(MapVote_CheckRules_2()) // decide
2720                 return;
2721
2722         totalvotes = 0;
2723         FOR_EACH_REALCLIENT(other)
2724         {
2725                 // hide scoreboard again
2726                 if(other.health != 2342)
2727                 {
2728                         other.health = 2342;
2729                         other.impulse = 0;
2730                         if(clienttype(other) == CLIENTTYPE_REAL)
2731                         {
2732                                 msg_entity = other;
2733                                 WriteByte(MSG_ONE, SVC_FINALE);
2734                                 WriteString(MSG_ONE, "");
2735                         }
2736                 }
2737
2738                 // clear possibly invalid votes
2739                 if(mapvote_maps[other.mapvote - 1] == "")
2740                         other.mapvote = 0;
2741                 // use impulses as new vote
2742                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2743                         if(mapvote_maps[other.impulse - 1] != "")
2744                         {
2745                                 other.mapvote = other.impulse;
2746                                 MapVote_TouchVotes(other);
2747                         }
2748                 other.impulse = 0;
2749
2750                 if(other.mapvote)
2751                         ++totalvotes;
2752         }
2753
2754         MapVote_CheckRules_1(); // just count
2755 }
2756 void MapVote_Start()
2757 {
2758         if(mapvote_run)
2759                 return;
2760
2761         MapInfo_Enumerate();
2762         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2763                 mapvote_run = TRUE;
2764 }
2765 void MapVote_Think()
2766 {
2767         if(!mapvote_run)
2768                 return;
2769
2770         if(alreadychangedlevel)
2771                 return;
2772
2773         if(time < mapvote_nextthink)
2774                 return;
2775         //dprint("tick\n");
2776
2777         mapvote_nextthink = time + 0.5;
2778
2779         if(!mapvote_initialized)
2780         {
2781                 if(cvar("rescan_pending") == 1)
2782                 {
2783                         cvar_set("rescan_pending", "2");
2784                         localcmd("fs_rescan\nrescan_pending 3\n");
2785                         return;
2786                 }
2787                 else if(cvar("rescan_pending") == 2)
2788                 {
2789                         return;
2790                 }
2791                 else if(cvar("rescan_pending") == 3)
2792                 {
2793                         // now build missing mapinfo files
2794                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2795                                 return;
2796
2797                         // we're done, start the timer
2798                         cvar_set("rescan_pending", "0");
2799                 }
2800
2801                 mapvote_initialized = TRUE;
2802                 if(DoNextMapOverride())
2803                         return;
2804                 if(!cvar("g_maplist_votable") || player_count <= 0)
2805                 {
2806                         GotoNextMap();
2807                         return;
2808                 }
2809                 MapVote_Init();
2810         }
2811
2812         MapVote_Tick();
2813 };
2814
2815 string GotoMap(string m)
2816 {
2817         if(!MapInfo_CheckMap(m))
2818                 return "The map you chose is not available on this server.";
2819         cvar_set("nextmap", m);
2820         cvar_set("timelimit", "-1");
2821         if(mapvote_initialized || alreadychangedlevel)
2822         {
2823                 if(DoNextMapOverride())
2824                         return "Map switch initiated.";
2825                 else
2826                         return "Hm... no. For some reason I like THIS map more.";
2827         }
2828         else
2829                 return "Map switch will happen after scoreboard.";
2830 }
2831
2832
2833 void EndFrame()
2834 {
2835         float altime;
2836         FOR_EACH_REALCLIENT(self)
2837         {
2838                 if(self.classname == "spectator")
2839                 {
2840                         if(self.enemy.typehitsound)
2841                                 play2(self, "misc/typehit.wav");
2842                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2843                                 play2(self, "misc/hit.wav");
2844                 }
2845                 else
2846                 {
2847                         if(self.typehitsound)
2848                                 play2(self, "misc/typehit.wav");
2849                         else if(self.hitsound && self.cvar_cl_hitsound)
2850                                 play2(self, "misc/hit.wav");
2851                 }
2852         }
2853         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2854         // add 1 frametime because after this, engine SV_Physics
2855         // increases time by a frametime and then networks the frame
2856         // add another frametime because client shows everything with
2857         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2858         // needed!
2859         FOR_EACH_CLIENT(self)
2860         {
2861                 self.hitsound = FALSE;
2862                 self.typehitsound = FALSE;
2863                 antilag_record(self, altime);
2864         }
2865 }
2866
2867
2868 /*
2869  * RedirectionThink:
2870  * returns TRUE if redirecting
2871  */
2872 float redirection_timeout;
2873 float redirection_nextthink;
2874 float RedirectionThink()
2875 {
2876         float clients_found;
2877
2878         if(redirection_target == "")
2879                 return FALSE;
2880
2881         if(!redirection_timeout)
2882         {
2883                 cvar_set("sv_public", "-2");
2884                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2885                 if(redirection_target == "self")
2886                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2887                 else
2888                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2889         }
2890
2891         if(time < redirection_nextthink)
2892                 return TRUE;
2893
2894         redirection_nextthink = time + 1;
2895
2896         clients_found = 0;
2897         FOR_EACH_REALCLIENT(self)
2898         {
2899                 print("Redirecting: sending connect command to ", self.netname, "\n");
2900                 if(redirection_target == "self")
2901                         stuffcmd(self, "\ndisconnect; reconnect\n");
2902                 else
2903                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2904                 ++clients_found;
2905         }
2906
2907         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2908
2909         if(time > redirection_timeout || clients_found == 0)
2910                 localcmd("\nwait; wait; wait; quit\n");
2911
2912         return TRUE;
2913 }
2914
2915 void TargetMusic_RestoreGame();
2916 void RestoreGame()
2917 {
2918         // Loaded from a save game
2919         // some things then break, so let's work around them...
2920
2921         // Progs DB (capture records)
2922         ServerProgsDB = db_load("server.db");
2923
2924         // Mapinfo
2925         MapInfo_Shutdown();
2926         MapInfo_Enumerate();
2927         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2928         WeaponStats_Init();
2929
2930         TargetMusic_RestoreGame();
2931 }
2932
2933 void SV_Shutdown()
2934 {
2935         if(gameover > 1) // shutting down already?
2936                 return;
2937
2938         gameover = 2; // 2 = server shutting down
2939
2940         if(world_initialized > 0)
2941         {
2942                 world_initialized = 0;
2943                 print("Saving persistent data...\n");
2944                 Ban_SaveBans();
2945                 if(!cheatcount_total)
2946                 {
2947                         if(cvar("sv_db_saveasdump"))
2948                                 db_dump(ServerProgsDB, "server.db");
2949                         else
2950                                 db_save(ServerProgsDB, "server.db");
2951                 }
2952                 if(cvar("developer"))
2953                 {
2954                         if(cvar("sv_db_saveasdump"))
2955                                 db_dump(TemporaryDB, "server-temp.db");
2956                         else
2957                                 db_save(TemporaryDB, "server-temp.db");
2958                 }
2959                 CheatShutdown(); // must be after cheatcount check
2960                 db_close(ServerProgsDB);
2961                 db_close(TemporaryDB);
2962                 print("done!\n");
2963                 // tell the bot system the game is ending now
2964                 bot_endgame();
2965
2966                 WeaponStats_Shutdown();
2967                 MapInfo_Shutdown();
2968         }
2969         else if(world_initialized == 0)
2970         {
2971                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2972         }
2973 }