qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include <common/net_linked.qh>
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/_mod.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications/all.qh"
  29 #include "../common/physics/player.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/_mod.qh"
  37 #include <common/weapons/_all.qh>
  38 #include "../common/state.qh"
  39
  40 const float LATENCY_THINKRATE = 10;
  41 .float latency_sum;
  42 .float latency_cnt;
  43 .float latency_time;
  44 entity pingplreport;
  45 void PingPLReport_Think(entity this)
  46 {
  47         float delta;
  48         entity e;
  49
  50         delta = 3 / maxclients;
  51         if(delta < sys_frametime)
  52                 delta = 0;
  53         this.nextthink = time + delta;
  54
  55         e = edict_num(this.cnt + 1);
  56         if(IS_REAL_CLIENT(e))
  57         {
  58                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  59                 WriteByte(MSG_BROADCAST, this.cnt);
  60                 WriteShort(MSG_BROADCAST, bound(1, e.ping, 65535));
  61                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_packetloss * 255), 255));
  62                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_movementloss * 255), 255));
  63
  64                 // record latency times for clients throughout the match so we can report it to playerstats
  65                 if(time > (e.latency_time + LATENCY_THINKRATE))
  66                 {
  67                         e.latency_sum += e.ping;
  68                         e.latency_cnt += 1;
  69                         e.latency_time = time;
  70                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  71                 }
  72         }
  73         else
  74         {
  75                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, this.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         this.cnt = (this.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = new_pure(pingplreport);
  86         setthink(pingplreport, PingPLReport_Think);
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap(entity this)
 109 {
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 this.nextthink = time;
 134         }
 135         else
 136         {
 137                 this.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213
 214                 // private
 215                 BADCVAR("developer");
 216                 BADCVAR("log_dest_udp");
 217                 BADCVAR("net_address");
 218                 BADCVAR("net_address_ipv6");
 219                 BADCVAR("port");
 220                 BADCVAR("savedgamecfg");
 221                 BADCVAR("serverconfig");
 222                 BADCVAR("sv_autoscreenshot");
 223                 BADCVAR("sv_heartbeatperiod");
 224                 BADCVAR("sv_vote_master_password");
 225                 BADCVAR("sys_colortranslation");
 226                 BADCVAR("sys_specialcharactertranslation");
 227                 BADCVAR("timeformat");
 228                 BADCVAR("timestamps");
 229                 BADCVAR("g_require_stats");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_require_stats_");
 234                 BADPREFIX("g_chat_flood_");
 235                 BADPREFIX("g_ghost_items");
 236                 BADPREFIX("g_playerstats_");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("quit_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_conquest");
 261                 BADCVAR("g_ctf");
 262                 BADCVAR("g_cts");
 263                 BADCVAR("g_dotc");
 264                 BADCVAR("g_dm");
 265                 BADCVAR("g_domination");
 266                 BADCVAR("g_domination_default_teams");
 267                 BADCVAR("g_freezetag");
 268                 BADCVAR("g_freezetag_teams");
 269                 BADCVAR("g_invasion_teams");
 270                 BADCVAR("g_jailbreak");
 271                 BADCVAR("g_jailbreak_teams");
 272                 BADCVAR("g_keepaway");
 273                 BADCVAR("g_keyhunt");
 274                 BADCVAR("g_keyhunt_teams");
 275                 BADCVAR("g_lms");
 276                 BADCVAR("g_nexball");
 277                 BADCVAR("g_onslaught");
 278                 BADCVAR("g_race");
 279                 BADCVAR("g_race_laps_limit");
 280                 BADCVAR("g_race_qualifying_timelimit");
 281                 BADCVAR("g_race_qualifying_timelimit_override");
 282                 BADCVAR("g_snafu");
 283                 BADCVAR("g_tdm");
 284                 BADCVAR("g_tdm_teams");
 285                 BADCVAR("g_vip");
 286                 BADCVAR("leadlimit");
 287                 BADCVAR("nextmap");
 288                 BADCVAR("teamplay");
 289                 BADCVAR("timelimit");
 290                 BADCVAR("g_mapinfo_ignore_warnings");
 291
 292                 // long
 293                 BADCVAR("hostname");
 294                 BADCVAR("g_maplist");
 295                 BADCVAR("g_maplist_mostrecent");
 296                 BADCVAR("sv_motd");
 297
 298                 v = cvar_string(k);
 299                 d = cvar_defstring(k);
 300                 if(v == d)
 301                         continue;
 302
 303                 if(adding)
 304                 {
 305                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 306                         if(strlen(cvar_changes) > 16384)
 307                         {
 308                                 cvar_changes = "// too many settings have been changed to show them here\n";
 309                                 adding = 0;
 310                         }
 311                 }
 312
 313                 // now check if the changes are actually gameplay relevant
 314
 315                 // does nothing gameplay relevant
 316                 BADCVAR("captureleadlimit_override");
 317                 BADCVAR("gameversion");
 318                 BADCVAR("g_allow_oldvortexbeam");
 319                 BADCVAR("g_balance_kill_delay");
 320                 BADCVAR("g_buffs_pickup_anyway");
 321                 BADCVAR("g_buffs_randomize");
 322                 BADCVAR("g_campcheck_distance");
 323                 BADCVAR("g_ca_point_leadlimit");
 324                 BADCVAR("g_ca_point_limit");
 325                 BADCVAR("g_ctf_captimerecord_always");
 326                 BADCVAR("g_ctf_flag_glowtrails");
 327                 BADCVAR("g_ctf_flag_pickup_verbosename");
 328                 BADCVAR("g_domination_point_leadlimit");
 329                 BADCVAR("g_forced_respawn");
 330                 BADCVAR("g_freezetag_point_leadlimit");
 331                 BADCVAR("g_freezetag_point_limit");
 332                 BADCVAR("g_hats");
 333                 BADCVAR("g_invasion_point_limit");
 334                 BADCVAR("g_jump_grunt");
 335                 BADCVAR("g_keyhunt_point_leadlimit");
 336                 BADCVAR("g_nexball_goalleadlimit");
 337                 BADCVAR("g_new_toys_use_pickupsound");
 338                 BADCVAR("g_physics_predictall");
 339                 BADCVAR("g_piggyback");
 340                 BADCVAR("g_playerclip_collisions");
 341                 BADCVAR("g_tdm_point_leadlimit");
 342                 BADCVAR("g_tdm_point_limit");
 343                 BADCVAR("leadlimit_and_fraglimit");
 344                 BADCVAR("leadlimit_override");
 345                 BADCVAR("pausable");
 346                 BADCVAR("sv_checkforpacketsduringsleep");
 347                 BADCVAR("sv_damagetext");
 348                 BADCVAR("sv_db_saveasdump");
 349                 BADCVAR("sv_intermission_cdtrack");
 350                 BADCVAR("sv_minigames");
 351                 BADCVAR("sv_namechangetimer");
 352                 BADCVAR("sv_precacheplayermodels");
 353                 BADCVAR("sv_stepheight");
 354                 BADCVAR("sv_timeout");
 355                 BADCVAR("sv_weapons_modeloverride");
 356                 BADPREFIX("crypto_");
 357                 BADPREFIX("gameversion_");
 358                 BADPREFIX("g_chat_");
 359                 BADPREFIX("g_ctf_captimerecord_");
 360                 BADPREFIX("g_maplist_");
 361                 BADPREFIX("g_mod_");
 362                 BADPREFIX("g_respawn_");
 363                 BADPREFIX("net_");
 364                 BADPREFIX("prvm_");
 365                 BADPREFIX("skill_");
 366                 BADPREFIX("sv_allow_");
 367                 BADPREFIX("sv_cullentities_");
 368                 BADPREFIX("sv_maxidle_");
 369                 BADPREFIX("sv_minigames_");
 370                 BADPREFIX("sv_radio_");
 371                 BADPREFIX("sv_timeout_");
 372                 BADPREFIX("sv_vote_");
 373                 BADPREFIX("timelimit_");
 374
 375                 // allowed changes to server admins (please sync this to server.cfg)
 376                 // vi commands:
 377                 //   :/"impure"/,$d
 378                 //   :g!,^\/\/[^ /],d
 379                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 380                 //   :%!sort
 381                 // yes, this does contain some redundant stuff, don't really care
 382                 BADCVAR("bot_config_file");
 383                 BADCVAR("bot_number");
 384                 BADCVAR("bot_prefix");
 385                 BADCVAR("bot_suffix");
 386                 BADCVAR("capturelimit_override");
 387                 BADCVAR("fraglimit_override");
 388                 BADCVAR("gametype");
 389                 BADCVAR("g_antilag");
 390                 BADCVAR("g_balance_teams");
 391                 BADCVAR("g_balance_teams_prevent_imbalance");
 392                 BADCVAR("g_balance_teams_scorefactor");
 393                 BADCVAR("g_ban_sync_trusted_servers");
 394                 BADCVAR("g_ban_sync_uri");
 395                 BADCVAR("g_buffs");
 396                 BADCVAR("g_ca_teams_override");
 397                 BADCVAR("g_ctf_ignore_frags");
 398                 BADCVAR("g_ctf_leaderboard");
 399                 BADCVAR("g_domination_point_limit");
 400                 BADCVAR("g_domination_teams_override");
 401                 BADCVAR("g_freezetag_teams_override");
 402                 BADCVAR("g_friendlyfire");
 403                 BADCVAR("g_fullbrightitems");
 404                 BADCVAR("g_fullbrightplayers");
 405                 BADCVAR("g_keyhunt_point_limit");
 406                 BADCVAR("g_keyhunt_teams_override");
 407                 BADCVAR("g_lms_lives_override");
 408                 BADCVAR("g_maplist");
 409                 BADCVAR("g_maxplayers");
 410                 BADCVAR("g_mirrordamage");
 411                 BADCVAR("g_nexball_goallimit");
 412                 BADCVAR("g_norecoil");
 413                 BADCVAR("g_physics_clientselect");
 414                 BADCVAR("g_pinata");
 415                 BADCVAR("g_powerups");
 416                 BADCVAR("g_spawnshieldtime");
 417                 BADCVAR("g_start_delay");
 418                 BADCVAR("g_superspectate");
 419                 BADCVAR("g_tdm_teams_override");
 420                 BADCVAR("g_warmup");
 421                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 422                 BADCVAR("hostname");
 423                 BADCVAR("log_file");
 424                 BADCVAR("maxplayers");
 425                 BADCVAR("minplayers");
 426                 BADCVAR("net_address");
 427                 BADCVAR("port");
 428                 BADCVAR("rcon_password");
 429                 BADCVAR("rcon_restricted_commands");
 430                 BADCVAR("rcon_restricted_password");
 431                 BADCVAR("skill");
 432                 BADCVAR("sv_adminnick");
 433                 BADCVAR("sv_autoscreenshot");
 434                 BADCVAR("sv_autotaunt");
 435                 BADCVAR("sv_curl_defaulturl");
 436                 BADCVAR("sv_defaultcharacter");
 437                 BADCVAR("sv_defaultcharacterskin");
 438                 BADCVAR("sv_defaultplayercolors");
 439                 BADCVAR("sv_defaultplayermodel");
 440                 BADCVAR("sv_defaultplayerskin");
 441                 BADCVAR("sv_maxidle");
 442                 BADCVAR("sv_maxrate");
 443                 BADCVAR("sv_motd");
 444                 BADCVAR("sv_public");
 445                 BADCVAR("sv_ready_restart");
 446                 BADCVAR("sv_status_privacy");
 447                 BADCVAR("sv_taunt");
 448                 BADCVAR("sv_vote_call");
 449                 BADCVAR("sv_vote_commands");
 450                 BADCVAR("sv_vote_majority_factor");
 451                 BADCVAR("sv_vote_master");
 452                 BADCVAR("sv_vote_master_commands");
 453                 BADCVAR("sv_vote_master_password");
 454                 BADCVAR("sv_vote_simple_majority_factor");
 455                 BADCVAR("teamplay_mode");
 456                 BADCVAR("timelimit_override");
 457                 BADPREFIX("g_warmup_");
 458                 BADPREFIX("sv_ready_restart_");
 459
 460                 // mutators that announce themselves properly to the server browser
 461                 BADCVAR("g_instagib");
 462                 BADCVAR("g_new_toys");
 463                 BADCVAR("g_nix");
 464                 BADCVAR("g_grappling_hook");
 465                 BADCVAR("g_jetpack");
 466
 467 #undef BADPRESUFFIX
 468 #undef BADPREFIX
 469 #undef BADCVAR
 470
 471                 if(pureadding)
 472                 {
 473                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 474                         if(strlen(cvar_purechanges) > 16384)
 475                         {
 476                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 477                                 pureadding = 0;
 478                         }
 479                 }
 480                 ++cvar_purechanges_count;
 481                 // WARNING: this variable is used for the server list
 482                 // NEVER dare to skip this code!
 483                 // Hacks to intentionally appearing as "pure server" even though you DO have
 484                 // modified settings may be punished by removal from the server list.
 485                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 486                 // though.
 487         }
 488         buf_del(h);
 489         if(cvar_changes == "")
 490                 cvar_changes = "// this server runs at default server settings\n";
 491         else
 492                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 493         cvar_changes = strzone(cvar_changes);
 494         if(cvar_purechanges == "")
 495                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 496         else
 497                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 498         cvar_purechanges = strzone(cvar_purechanges);
 499 }
 500
 501 void detect_maptype()
 502 {
 503 #if 0
 504         vector o, v;
 505         float i;
 506
 507         for (;;)
 508         {
 509                 o = world.mins;
 510                 o.x += random() * (world.maxs.x - world.mins.x);
 511                 o.y += random() * (world.maxs.y - world.mins.y);
 512                 o.z += random() * (world.maxs.z - world.mins.z);
 513
 514                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 515                 if(trace_fraction == 1)
 516                         continue;
 517
 518                 v = trace_endpos;
 519
 520                 for(i = 0; i < 64; i += 4)
 521                 {
 522                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 523         if(trace_fraction == 1)
 524                 continue;
 525                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 526                 }
 527
 528                 break;
 529         }
 530 #endif
 531 }
 532
 533 entity randomseed;
 534 bool RandomSeed_Send(entity this, entity to, int sf)
 535 {
 536         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 537         WriteShort(MSG_ENTITY, this.cnt);
 538         return true;
 539 }
 540 void RandomSeed_Think(entity this)
 541 {
 542         this.cnt = bound(0, floor(random() * 65536), 65535);
 543         this.nextthink = time + 5;
 544
 545         this.SendFlags |= 1;
 546 }
 547 void RandomSeed_Spawn()
 548 {
 549         randomseed = new_pure(randomseed);
 550         setthink(randomseed, RandomSeed_Think);
 551         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 552
 553         getthink(randomseed)(randomseed); // sets random seed and nextthink
 554 }
 555
 556 spawnfunc(__init_dedicated_server)
 557 {
 558         // handler for _init/_init map (only for dedicated server initialization)
 559
 560         world_initialized = -1; // don't complain
 561         cvar = cvar_normal;
 562         cvar_string = cvar_string_normal;
 563         cvar_set = cvar_set_normal;
 564
 565         delete_fn = remove_unsafely;
 566
 567         entity e = spawn();
 568         setthink(e, GotoFirstMap);
 569         e.nextthink = time; // this is usually 1 at this point
 570
 571         e = new(info_player_deathmatch);  // safeguard against player joining
 572
 573         this.classname = "worldspawn"; // safeguard against various stuff ;)
 574
 575         // needs to be done so early because of the constants they create
 576         static_init();
 577         static_init_late();
 578         static_init_precache();
 579
 580         IL_PUSH(g_spawnpoints, e); // just incase
 581
 582         MapInfo_Enumerate();
 583         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 584 }
 585
 586 void __init_dedicated_server_shutdown() {
 587         MapInfo_Shutdown();
 588 }
 589
 590 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override)
 591 {
 592         if(!autocvar_g_campaign)
 593         {
 594                 if(fraglimit_override >= 0) cvar_set("fraglimit", ftos(fraglimit_override));
 595                 if(timelimit_override >= 0) cvar_set("timelimit", ftos(timelimit_override));
 596                 if(leadlimit_override >= 0) cvar_set("leadlimit", ftos(leadlimit_override));
 597                 if(qualifying_override >= 0) cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 598         }
 599         limits_are_set = true;
 600 }
 601
 602 void Map_MarkAsRecent(string m);
 603 float world_already_spawned;
 604 void Nagger_Init();
 605 void ClientInit_Spawn();
 606 void WeaponStats_Init();
 607 void WeaponStats_Shutdown();
 608 spawnfunc(worldspawn)
 609 {
 610         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 611
 612     bool wantrestart = false;
 613         {
 614                 if (!server_is_dedicated)
 615                 {
 616                         // force unloading of server pk3 files when starting a listen server
 617                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 618                         // restore csqc_progname too
 619                         string expect = "csprogs.dat";
 620                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 621                         cvar_set_normal("csqc_progname", expect);
 622                 }
 623                 else
 624                 {
 625                         // Try to use versioned csprogs from pk3
 626                         // Only ever use versioned csprogs.dat files on dedicated servers;
 627                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 628                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 629                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 630                         string select = "csprogs.dat";
 631                         if (fexists(pk3csprogs)) select = pk3csprogs;
 632                         if (cvar_string_normal("csqc_progname") != select)
 633                         {
 634                                 cvar_set_normal("csqc_progname", select);
 635                                 wantrestart = true;
 636                         }
 637                         // Check for updates on startup
 638                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 639                         int sentinel = fopen("progs.txt", FILE_READ);
 640                         if (sentinel >= 0)
 641                         {
 642                                 string switchversion = fgets(sentinel);
 643                                 fclose(sentinel);
 644                                 if (switchversion != "" && switchversion != WATERMARK)
 645                                 {
 646                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 647                                         // if it doesn't exist, assume either:
 648                                         //   a) the current program was overwritten
 649                                         //   b) this is a client only update
 650                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 651                                         if (fexists(newprogs))
 652                                         {
 653                                                 cvar_set_normal("sv_progs", newprogs);
 654                                                 wantrestart = true;
 655                                         }
 656                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 657                                         if (fexists(newcsprogs))
 658                                         {
 659                                                 cvar_set_normal("csqc_progname", newcsprogs);
 660                                                 wantrestart = true;
 661                                         }
 662                                 }
 663                         }
 664                 }
 665                 if (wantrestart)
 666                 {
 667                         LOG_INFOF("Restart requested\n");
 668                         changelevel(mapname);
 669                         // let initialization continue, shutdown depends on it
 670                 }
 671         }
 672
 673         cvar = cvar_normal;
 674         cvar_string = cvar_string_normal;
 675         cvar_set = cvar_set_normal;
 676
 677         if(world_already_spawned)
 678                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 679         world_already_spawned = true;
 680
 681         delete_fn = remove_safely; // during spawning, watch what you remove!
 682
 683         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 684
 685         maxclients = 0;
 686         for (entity head = nextent(NULL); head; head = nextent(head))
 687         {
 688                 ++maxclients;
 689         }
 690
 691         // needs to be done so early because of the constants they create
 692         static_init();
 693
 694         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 695
 696         TemporaryDB = db_create();
 697
 698         // 0 normal
 699         lightstyle(0, "m");
 700
 701         // 1 FLICKER (first variety)
 702         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 703
 704         // 2 SLOW STRONG PULSE
 705         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 706
 707         // 3 CANDLE (first variety)
 708         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 709
 710         // 4 FAST STROBE
 711         lightstyle(4, "mamamamamama");
 712
 713         // 5 GENTLE PULSE 1
 714         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 715
 716         // 6 FLICKER (second variety)
 717         lightstyle(6, "nmonqnmomnmomomno");
 718
 719         // 7 CANDLE (second variety)
 720         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 721
 722         // 8 CANDLE (third variety)
 723         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 724
 725         // 9 SLOW STROBE (fourth variety)
 726         lightstyle(9, "aaaaaaaazzzzzzzz");
 727
 728         // 10 FLUORESCENT FLICKER
 729         lightstyle(10, "mmamammmmammamamaaamammma");
 730
 731         // 11 SLOW PULSE NOT FADE TO BLACK
 732         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 733
 734         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 735
 736         // 63 testing
 737         lightstyle(63, "a");
 738
 739         if(autocvar_g_campaign)
 740                 CampaignPreInit();
 741
 742         Map_MarkAsRecent(mapname);
 743
 744         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 745
 746         InitGameplayMode();
 747         static_init_late();
 748         static_init_precache();
 749         readlevelcvars();
 750         GrappleHookInit();
 751
 752         if(!limits_are_set)
 753                 SetLimits(autocvar_fraglimit_override, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
 754
 755         if(warmup_limit == 0)
 756                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 757
 758         player_count = 0;
 759         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 760         if(bot_waypoints_for_items == 1)
 761                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 762                         bot_waypoints_for_items = 0;
 763
 764         precache();
 765
 766         WaypointSprite_Init();
 767
 768         GameLogInit(); // prepare everything
 769         // NOTE for matchid:
 770         // changing the logic generating it is okay. But:
 771         // it HAS to stay <= 64 chars
 772         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 773         if(autocvar_sv_eventlog)
 774         {
 775                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 776                 matchid = strzone(s);
 777
 778                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 779                 s = ":gameinfo:mutators:LIST";
 780
 781                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 782                 s = M_ARGV(0, string);
 783
 784                 // initialiation stuff, not good in the mutator system
 785                 if(!autocvar_g_use_ammunition)
 786                         s = strcat(s, ":no_use_ammunition");
 787
 788                 // initialiation stuff, not good in the mutator system
 789                 if(autocvar_g_pickup_items == 0)
 790                         s = strcat(s, ":no_pickup_items");
 791                 if(autocvar_g_pickup_items > 0)
 792                         s = strcat(s, ":pickup_items");
 793
 794                 // initialiation stuff, not good in the mutator system
 795                 if(autocvar_g_weaponarena != "0")
 796                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 797
 798                 // TODO to mutator system
 799                 if(autocvar_g_norecoil)
 800                         s = strcat(s, ":norecoil");
 801
 802                 // TODO to mutator system
 803                 if(autocvar_g_powerups == 0)
 804                         s = strcat(s, ":no_powerups");
 805                 if(autocvar_g_powerups > 0)
 806                         s = strcat(s, ":powerups");
 807
 808                 GameLogEcho(s);
 809                 GameLogEcho(":gameinfo:end");
 810         }
 811         else
 812                 matchid = strzone(ftos(random()));
 813
 814         cvar_set("nextmap", "");
 815
 816         SetDefaultAlpha();
 817
 818         if(autocvar_g_campaign)
 819                 CampaignPostInit();
 820
 821         Ban_LoadBans();
 822
 823         MapInfo_Enumerate();
 824         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 825
 826         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 827         {
 828                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 829                 if(fd != -1)
 830                 {
 831                         string s;
 832                         while((s = fgets(fd)))
 833                         {
 834                                 int l = tokenize_console(s);
 835                                 if(l < 2)
 836                                         continue;
 837                                 if(argv(0) == "cd")
 838                                 {
 839                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 840                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 841                                 }
 842                                 else if(argv(0) == "fog")
 843                                 {
 844                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 845                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 846                                 }
 847                                 else if(argv(0) == "set")
 848                                 {
 849                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 850                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 851                                 }
 852                                 else if(argv(0) != "//")
 853                                 {
 854                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 855                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 856                                 }
 857                         }
 858                         fclose(fd);
 859                 }
 860         }
 861
 862         WeaponStats_Init();
 863
 864         Nagger_Init();
 865
 866         next_pingtime = time + 5;
 867
 868         detect_maptype();
 869
 870         // set up information replies for clients and server to use
 871         maplist_reply = strzone(getmaplist());
 872         lsmaps_reply = strzone(getlsmaps());
 873         monsterlist_reply = strzone(getmonsterlist());
 874         for(int i = 0; i < 10; ++i)
 875         {
 876                 string s = getrecords(i);
 877                 if (s)
 878                         records_reply[i] = strzone(s);
 879         }
 880         ladder_reply = strzone(getladder());
 881         rankings_reply = strzone(getrankings());
 882
 883         // begin other init
 884         ClientInit_Spawn();
 885         RandomSeed_Spawn();
 886         PingPLReport_Spawn();
 887
 888         CheatInit();
 889
 890         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 891
 892         // fill sv_curl_serverpackages from .serverpackage files
 893         if (autocvar_sv_curl_serverpackages_auto)
 894         {
 895                 string s = "csprogs-" WATERMARK ".txt";
 896                 // remove automatically managed files from the list to prevent duplicates
 897                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 898                 {
 899                         string pkg = argv(i);
 900                         if (startsWith(pkg, "csprogs-")) continue;
 901                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 902                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 903                         s = cons(s, pkg);
 904                 }
 905                 // add automatically managed files to the list
 906                 #define X(match) MACRO_BEGIN { \
 907                         int fd = search_begin(match, true, false); \
 908                         if (fd >= 0) \
 909                         { \
 910                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 911                                 { \
 912                                         s = cons(s, search_getfilename(fd, i)); \
 913                                 } \
 914                                 search_end(fd); \
 915                         } \
 916                 } MACRO_END
 917                 X("*-serverpackage.txt");
 918                 X("*.serverpackage");
 919                 #undef X
 920                 cvar_set("sv_curl_serverpackages", s);
 921         }
 922
 923         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 924         modname = "Xonotic";
 925         // physics/balance/config changes that count as mod
 926         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 927                 modname = cvar_string("g_mod_physics");
 928         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 929                 modname = cvar_string("g_mod_balance");
 930         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 931                 modname = cvar_string("g_mod_config");
 932         // extra mutators that deserve to count as mod
 933         MUTATOR_CALLHOOK(SetModname, modname);
 934         modname = M_ARGV(0, string);
 935
 936         // save it for later
 937         modname = strzone(modname);
 938
 939         WinningConditionHelper(this); // set worldstatus
 940
 941         world_initialized = 1;
 942 }
 943
 944 spawnfunc(light)
 945 {
 946         //makestatic (this); // Who the f___ did that?
 947         delete(this);
 948 }
 949
 950 string GetGametype()
 951 {
 952         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 953 }
 954
 955 string GetMapname()
 956 {
 957         return mapname;
 958 }
 959
 960 float Map_Count, Map_Current;
 961 string Map_Current_Name;
 962
 963 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 964 float GetMaplistPosition()
 965 {
 966         float pos, idx;
 967         string map;
 968
 969         map = GetMapname();
 970         idx = autocvar_g_maplist_index;
 971
 972         if(idx >= 0)
 973                 if(idx < Map_Count)
 974                         if(map == argv(idx))
 975                                 return idx;
 976
 977         for(pos = 0; pos < Map_Count; ++pos)
 978                 if(map == argv(pos))
 979                         return pos;
 980
 981         // resume normal maplist rotation if current map is not in g_maplist
 982         return idx;
 983 }
 984
 985 float MapHasRightSize(string map)
 986 {
 987         float fh;
 988         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 989         if(autocvar_g_maplist_check_waypoints)
 990         {
 991                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 992                 if(!fexists(strcat("maps/", map, ".waypoints")))
 993                 {
 994                         LOG_TRACE(": no waypoints");
 995                         return false;
 996                 }
 997                 LOG_TRACE(": has waypoints");
 998         }
 999
1000         // open map size restriction file
1001         LOG_TRACE("opensize "); LOG_TRACE(map);
1002         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1003         if(fh >= 0)
1004         {
1005                 float mapmin, mapmax;
1006                 LOG_TRACE(": ok, ");
1007                 mapmin = stof(fgets(fh));
1008                 mapmax = stof(fgets(fh));
1009                 fclose(fh);
1010                 if(player_count < mapmin)
1011                 {
1012                         LOG_TRACE("not enough");
1013                         return false;
1014                 }
1015                 if(player_count > mapmax)
1016                 {
1017                         LOG_TRACE("too many");
1018                         return false;
1019                 }
1020                 LOG_TRACE("right size");
1021                 return true;
1022         }
1023         LOG_TRACE(": not found");
1024         return true;
1025 }
1026
1027 string Map_Filename(float position)
1028 {
1029         return strcat("maps/", argv(position), ".bsp");
1030 }
1031
1032 void Map_MarkAsRecent(string m)
1033 {
1034         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1035 }
1036
1037 float Map_IsRecent(string m)
1038 {
1039         return strhasword(autocvar_g_maplist_mostrecent, m);
1040 }
1041
1042 float Map_Check(float position, float pass)
1043 {
1044         string filename;
1045         string map_next;
1046         map_next = argv(position);
1047         if(pass <= 1)
1048         {
1049                 if(Map_IsRecent(map_next))
1050                         return 0;
1051         }
1052         filename = Map_Filename(position);
1053         if(MapInfo_CheckMap(map_next))
1054         {
1055                 if(pass == 2)
1056                         return 1;
1057                 if(MapHasRightSize(map_next))
1058                         return 1;
1059                 return 0;
1060         }
1061         else
1062                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1063
1064         return 0;
1065 }
1066
1067 void Map_Goto_SetStr(string nextmapname)
1068 {
1069         if(getmapname_stored != "")
1070                 strunzone(getmapname_stored);
1071         if(nextmapname == "")
1072                 getmapname_stored = "";
1073         else
1074                 getmapname_stored = strzone(nextmapname);
1075 }
1076
1077 void Map_Goto_SetFloat(float position)
1078 {
1079         cvar_set("g_maplist_index", ftos(position));
1080         Map_Goto_SetStr(argv(position));
1081 }
1082
1083 void Map_Goto(float reinit)
1084 {
1085         MapInfo_LoadMap(getmapname_stored, reinit);
1086 }
1087
1088 // return codes of map selectors:
1089 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1090 //   -2 = permanent failure
1091 float() MaplistMethod_Iterate = // usual method
1092 {
1093         float pass, i;
1094
1095         LOG_TRACE("Trying MaplistMethod_Iterate");
1096
1097         for(pass = 1; pass <= 2; ++pass)
1098         {
1099                 for(i = 1; i < Map_Count; ++i)
1100                 {
1101                         float mapindex;
1102                         mapindex = (i + Map_Current) % Map_Count;
1103                         if(Map_Check(mapindex, pass))
1104                                 return mapindex;
1105                 }
1106         }
1107         return -1;
1108 }
1109
1110 float() MaplistMethod_Repeat = // fallback method
1111 {
1112         LOG_TRACE("Trying MaplistMethod_Repeat");
1113
1114         if(Map_Check(Map_Current, 2))
1115                 return Map_Current;
1116         return -2;
1117 }
1118
1119 float() MaplistMethod_Random = // random map selection
1120 {
1121         float i, imax;
1122
1123         LOG_TRACE("Trying MaplistMethod_Random");
1124
1125         imax = 42;
1126
1127         for(i = 0; i <= imax; ++i)
1128         {
1129                 float mapindex;
1130                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1131                 if(Map_Check(mapindex, 1))
1132                         return mapindex;
1133         }
1134         return -1;
1135 }
1136
1137 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1138 // the exponent sets a bias on the map selection:
1139 // the higher the exponent, the less likely "shortly repeated" same maps are
1140 {
1141         float i, j, imax, insertpos;
1142
1143         LOG_TRACE("Trying MaplistMethod_Shuffle");
1144
1145         imax = 42;
1146
1147         for(i = 0; i <= imax; ++i)
1148         {
1149                 string newlist;
1150
1151                 // now reinsert this at another position
1152                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1153                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1154                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1155                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1156
1157                 // insert the current map there
1158                 newlist = "";
1159                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1160                         newlist = strcat(newlist, " ", argv(j));
1161                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1162                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1163                         newlist = strcat(newlist, " ", argv(j));
1164                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1165                 cvar_set("g_maplist", newlist);
1166                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1167
1168                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1169                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1170                 if(Map_Check(Map_Current, 1))
1171                         return Map_Current;
1172         }
1173         return -1;
1174 }
1175
1176 void Maplist_Init()
1177 {
1178         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1179         float i;
1180         for (i = 0; i < Map_Count; ++i)
1181                 if (Map_Check(i, 2))
1182                         break;
1183         if (i == Map_Count)
1184         {
1185                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1186                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1187                 if(autocvar_g_maplist_shuffle)
1188                         ShuffleMaplist();
1189                 localcmd("\nmenu_cmd sync\n");
1190                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1191         }
1192         if(Map_Count == 0)
1193                 error("empty maplist, cannot select a new map");
1194         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1195
1196         if(Map_Current_Name)
1197                 strunzone(Map_Current_Name);
1198         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1199         // this may or may not be correct, but who cares, in the worst case a map
1200         // isn't chosen in the first pass that should have been
1201 }
1202
1203 string GetNextMap()
1204 {
1205         float nextMap;
1206
1207         Maplist_Init();
1208         nextMap = -1;
1209
1210         if(nextMap == -1)
1211                 if(autocvar_g_maplist_shuffle > 0)
1212                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1213
1214         if(nextMap == -1)
1215                 if(autocvar_g_maplist_selectrandom)
1216                         nextMap = MaplistMethod_Random();
1217
1218         if(nextMap == -1)
1219                 nextMap = MaplistMethod_Iterate();
1220
1221         if(nextMap == -1)
1222                 nextMap = MaplistMethod_Repeat();
1223
1224         if(nextMap >= 0)
1225         {
1226                 Map_Goto_SetFloat(nextMap);
1227                 return getmapname_stored;
1228         }
1229
1230         return "";
1231 }
1232
1233 float DoNextMapOverride(float reinit)
1234 {
1235         if(autocvar_g_campaign)
1236         {
1237                 CampaignPostIntermission();
1238                 alreadychangedlevel = true;
1239                 return true;
1240         }
1241         if(autocvar_quit_when_empty)
1242         {
1243                 if(player_count <= currentbots)
1244                 {
1245                         localcmd("quit\n");
1246                         alreadychangedlevel = true;
1247                         return true;
1248                 }
1249         }
1250         if(autocvar_quit_and_redirect != "")
1251         {
1252                 redirection_target = strzone(autocvar_quit_and_redirect);
1253                 alreadychangedlevel = true;
1254                 return true;
1255         }
1256         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1257         {
1258                 localcmd("restart\n");
1259                 alreadychangedlevel = true;
1260                 return true;
1261         }
1262         if(autocvar_nextmap != "")
1263         {
1264                 string m;
1265                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1266                 cvar_set("nextmap",m);
1267
1268                 if(!m || gametypevote)
1269                         return false;
1270                 if(autocvar_sv_vote_gametype)
1271                 {
1272                         Map_Goto_SetStr(m);
1273                         return false;
1274                 }
1275
1276                 if(MapInfo_CheckMap(m))
1277                 {
1278                         Map_Goto_SetStr(m);
1279                         Map_Goto(reinit);
1280                         alreadychangedlevel = true;
1281                         return true;
1282                 }
1283         }
1284         if(!reinit && autocvar_lastlevel)
1285         {
1286                 cvar_settemp_restore();
1287                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1288                 alreadychangedlevel = true;
1289                 return true;
1290         }
1291         return false;
1292 }
1293
1294 void GotoNextMap(float reinit)
1295 {
1296         //string nextmap;
1297         //float n, nummaps;
1298         //string s;
1299         if (alreadychangedlevel)
1300                 return;
1301         alreadychangedlevel = true;
1302
1303         string nextMap;
1304
1305         nextMap = GetNextMap();
1306         if(nextMap == "")
1307                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1308         Map_Goto(reinit);
1309 }
1310
1311
1312 /*
1313 ============
1314 IntermissionThink
1315
1316 When the player presses attack or jump, change to the next level
1317 ============
1318 */
1319 .float autoscreenshot;
1320 void IntermissionThink(entity this)
1321 {
1322         FixIntermissionClient(this);
1323
1324         float server_screenshot = (autocvar_sv_autoscreenshot && this.cvar_cl_autoscreenshot);
1325         float client_screenshot = (this.cvar_cl_autoscreenshot == 2);
1326
1327         if( (server_screenshot || client_screenshot)
1328                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1329         {
1330                 this.autoscreenshot = -1;
1331                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1332                 return;
1333         }
1334
1335         if (time < intermission_exittime)
1336                 return;
1337
1338         if(!mapvote_initialized)
1339                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1340                         return;
1341
1342         MapVote_Start();
1343 }
1344
1345 /*
1346 ============
1347 FindIntermission
1348
1349 Returns the entity to view from
1350 ============
1351 */
1352 /*
1353 entity FindIntermission()
1354 {
1355         local   entity spot;
1356         local   float cyc;
1357
1358 // look for info_intermission first
1359         spot = find(NULL, classname, "info_intermission");
1360         if (spot)
1361         {       // pick a random one
1362                 cyc = random() * 4;
1363                 while (cyc > 1)
1364                 {
1365                         spot = find(spot, classname, "info_intermission");
1366                         if (!spot)
1367                                 spot = find(spot, classname, "info_intermission");
1368                         cyc = cyc - 1;
1369                 }
1370                 return spot;
1371         }
1372
1373 // then look for the start position
1374         spot = find(NULL, classname, "info_player_start");
1375         if (spot)
1376                 return spot;
1377
1378 // testinfo_player_start is only found in regioned levels
1379         spot = find(NULL, classname, "testplayerstart");
1380         if (spot)
1381                 return spot;
1382
1383 // then look for the start position
1384         spot = find(NULL, classname, "info_player_deathmatch");
1385         if (spot)
1386                 return spot;
1387
1388         //objerror ("FindIntermission: no spot");
1389         return NULL;
1390 }
1391 */
1392
1393 /*
1394 ===============================================================================
1395
1396 RULES
1397
1398 ===============================================================================
1399 */
1400
1401 void DumpStats(float final)
1402 {
1403         float file;
1404         string s;
1405         float to_console;
1406         float to_eventlog;
1407         float to_file;
1408         float i;
1409
1410         to_console = autocvar_sv_logscores_console;
1411         to_eventlog = autocvar_sv_eventlog;
1412         to_file = autocvar_sv_logscores_file;
1413
1414         if(!final)
1415         {
1416                 to_console = true; // always print printstats replies
1417                 to_eventlog = false; // but never print them to the event log
1418         }
1419
1420         if(to_eventlog)
1421                 if(autocvar_sv_eventlog_console)
1422                         to_console = false; // otherwise we get the output twice
1423
1424         if(final)
1425                 s = ":scores:";
1426         else
1427                 s = ":status:";
1428         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1429
1430         if(to_console)
1431                 LOG_INFO(s, "\n");
1432         if(to_eventlog)
1433                 GameLogEcho(s);
1434
1435         file = -1;
1436         if(to_file)
1437         {
1438                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1439                 if(file == -1)
1440                         to_file = false;
1441                 else
1442                         fputs(file, strcat(s, "\n"));
1443         }
1444
1445         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1446         if(to_console)
1447                 LOG_INFO(s, "\n");
1448         if(to_eventlog)
1449                 GameLogEcho(s);
1450         if(to_file)
1451                 fputs(file, strcat(s, "\n"));
1452
1453         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1454                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1455                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1456                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1457                         s = strcat(s, ftos(it.team), ":");
1458                 else
1459                         s = strcat(s, "spectator:");
1460
1461                 if(to_console)
1462                         LOG_INFO(s, playername(it, false), "\n");
1463                 if(to_eventlog)
1464                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1465                 if(to_file)
1466                         fputs(file, strcat(s, playername(it, false), "\n"));
1467         ));
1468
1469         if(teamplay)
1470         {
1471                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1472                 if(to_console)
1473                         LOG_INFO(s, "\n");
1474                 if(to_eventlog)
1475                         GameLogEcho(s);
1476                 if(to_file)
1477                         fputs(file, strcat(s, "\n"));
1478
1479                 for(i = 1; i < 16; ++i)
1480                 {
1481                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1482                         s = strcat(s, ":", ftos(i));
1483                         if(to_console)
1484                                 LOG_INFO(s, "\n");
1485                         if(to_eventlog)
1486                                 GameLogEcho(s);
1487                         if(to_file)
1488                                 fputs(file, strcat(s, "\n"));
1489                 }
1490         }
1491
1492         if(to_console)
1493                 LOG_INFO(":end\n");
1494         if(to_eventlog)
1495                 GameLogEcho(":end");
1496         if(to_file)
1497         {
1498                 fputs(file, ":end\n");
1499                 fclose(file);
1500         }
1501 }
1502
1503 void FixIntermissionClient(entity e)
1504 {
1505         if(!e.autoscreenshot) // initial call
1506         {
1507                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1508                 e.health = -2342;
1509                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1510                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1511                 {
1512                     .entity weaponentity = weaponentities[slot];
1513                         if(e.(weaponentity))
1514                         {
1515                                 e.(weaponentity).effects = EF_NODRAW;
1516                                 if (e.(weaponentity).weaponchild)
1517                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1518                         }
1519                 }
1520                 if(IS_REAL_CLIENT(e))
1521                 {
1522                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1523                         RandomSelection_Init();
1524                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1525                                 RandomSelection_AddString(it, 1, 1);
1526                         ));
1527                         if (RandomSelection_chosen_string != "")
1528                         {
1529                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1530                         }
1531                         msg_entity = e;
1532                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1533                 }
1534         }
1535 }
1536
1537 /*
1538 go to the next level for deathmatch
1539 only called if a time or frag limit has expired
1540 */
1541 void NextLevel()
1542 {
1543         game_stopped = true;
1544         intermission_running = 1; // game over
1545
1546         // enforce a wait time before allowing changelevel
1547         if(player_count > 0)
1548                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1549         else
1550                 intermission_exittime = -1;
1551
1552         /*
1553         WriteByte (MSG_ALL, SVC_CDTRACK);
1554         WriteByte (MSG_ALL, 3);
1555         WriteByte (MSG_ALL, 3);
1556         // done in FixIntermission
1557         */
1558
1559         //pos = FindIntermission ();
1560
1561         VoteReset();
1562
1563         DumpStats(true);
1564
1565         // send statistics
1566         PlayerStats_GameReport(true);
1567         WeaponStats_Shutdown();
1568
1569         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1570
1571         if(autocvar_sv_eventlog)
1572                 GameLogEcho(":gameover");
1573
1574         GameLogClose();
1575
1576         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1577                 FixIntermissionClient(it);
1578                 if(it.winning)
1579                         bprint(playername(it, false), " ^7wins.\n");
1580         ));
1581
1582         target_music_kill();
1583
1584         if(autocvar_g_campaign)
1585                 CampaignPreIntermission();
1586
1587         MUTATOR_CALLHOOK(MatchEnd);
1588
1589         localcmd("\nsv_hook_gameend\n");
1590 }
1591
1592 /*
1593 ============
1594 CheckRules_Player
1595
1596 Exit deathmatch games upon conditions
1597 ============
1598 */
1599 void CheckRules_Player(entity this)
1600 {
1601         if (game_stopped) // someone else quit the game already
1602                 return;
1603
1604         if(!IS_DEAD(this))
1605                 this.play_time += frametime;
1606
1607         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1608         //   (div0: and that in CheckRules_World please)
1609 }
1610
1611
1612 float InitiateSuddenDeath()
1613 {
1614         // Check first whether normal overtimes could be added before initiating suddendeath mode
1615         // - for this timelimit_overtime needs to be >0 of course
1616         // - also check the winning condition calculated in the previous frame and only add normal overtime
1617         //   again, if at the point at which timelimit would be extended again, still no winner was found
1618         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1619         {
1620                 return 1; // need to call InitiateOvertime later
1621         }
1622         else
1623         {
1624                 if(!checkrules_suddendeathend)
1625                 {
1626                         if(autocvar_g_campaign)
1627                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1628                         else
1629                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1630                         if(g_race && !g_race_qualifying)
1631                                 race_StartCompleting();
1632                 }
1633                 return 0;
1634         }
1635 }
1636
1637 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1638 {
1639         ++checkrules_overtimesadded;
1640         //add one more overtime by simply extending the timelimit
1641         float tl;
1642         tl = autocvar_timelimit;
1643         tl += autocvar_timelimit_overtime;
1644         cvar_set("timelimit", ftos(tl));
1645
1646         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1647 }
1648
1649 float GetWinningCode(float fraglimitreached, float equality)
1650 {
1651         if(autocvar_g_campaign == 1)
1652                 if(fraglimitreached)
1653                         return WINNING_YES;
1654                 else
1655                         return WINNING_NO;
1656
1657         else
1658                 if(equality)
1659                         if(fraglimitreached)
1660                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1661                         else
1662                                 return WINNING_NEVER;
1663                 else
1664                         if(fraglimitreached)
1665                                 return WINNING_YES;
1666                         else
1667                                 return WINNING_NO;
1668 }
1669
1670 // set the .winning flag for exactly those players with a given field value
1671 void SetWinners(.float field, float value)
1672 {
1673         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1674 }
1675
1676 // set the .winning flag for those players with a given field value
1677 void AddWinners(.float field, float value)
1678 {
1679         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1680                 if(it.(field) == value)
1681                         it.winning = 1;
1682         ));
1683 }
1684
1685 // clear the .winning flags
1686 void ClearWinners()
1687 {
1688         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1689 }
1690
1691 void ShuffleMaplist()
1692 {
1693         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1694 }
1695
1696 float leaderfrags;
1697 float WinningCondition_Scores(float limit, float leadlimit)
1698 {
1699         float limitreached;
1700
1701         // TODO make everything use THIS winning condition (except LMS)
1702         WinningConditionHelper(NULL);
1703
1704         if(teamplay)
1705         {
1706                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1707                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1708                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1709                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1710         }
1711
1712         ClearWinners();
1713         if(WinningConditionHelper_winner)
1714                 WinningConditionHelper_winner.winning = 1;
1715         if(WinningConditionHelper_winnerteam >= 0)
1716                 SetWinners(team, WinningConditionHelper_winnerteam);
1717
1718         if(WinningConditionHelper_lowerisbetter)
1719         {
1720                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1721                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1722                 limit = -limit;
1723         }
1724
1725         if(WinningConditionHelper_zeroisworst)
1726                 leadlimit = 0; // not supported in this mode
1727
1728         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1729         // these modes always score in increments of 1, thus this makes sense
1730         {
1731                 if(leaderfrags != WinningConditionHelper_topscore)
1732                 {
1733                         leaderfrags = WinningConditionHelper_topscore;
1734
1735                         if (limit)
1736                         if (leaderfrags == limit - 1)
1737                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1738                         else if (leaderfrags == limit - 2)
1739                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1740                         else if (leaderfrags == limit - 3)
1741                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1742                 }
1743         }
1744
1745         limitreached = false;
1746         if(limit)
1747                 if(WinningConditionHelper_topscore >= limit)
1748                         limitreached = true;
1749         if(leadlimit)
1750         {
1751                 float leadlimitreached;
1752                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1753                 if(autocvar_leadlimit_and_fraglimit)
1754                         limitreached = (limitreached && leadlimitreached);
1755                 else
1756                         limitreached = (limitreached || leadlimitreached);
1757         }
1758
1759         if(limit)
1760                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1761
1762         return GetWinningCode(
1763                 WinningConditionHelper_topscore && limitreached,
1764                 WinningConditionHelper_equality
1765         );
1766 }
1767
1768 float WinningCondition_RanOutOfSpawns()
1769 {
1770         if(have_team_spawns <= 0)
1771                 return WINNING_NO;
1772
1773         if(!autocvar_g_spawn_useallspawns)
1774                 return WINNING_NO;
1775
1776         if(!some_spawn_has_been_used)
1777                 return WINNING_NO;
1778
1779         team1_score = team2_score = team3_score = team4_score = 0;
1780
1781         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1782                 switch(it.team)
1783                 {
1784                         case NUM_TEAM_1: team1_score = 1; break;
1785                         case NUM_TEAM_2: team2_score = 1; break;
1786                         case NUM_TEAM_3: team3_score = 1; break;
1787                         case NUM_TEAM_4: team4_score = 1; break;
1788                 }
1789         ));
1790
1791         IL_EACH(g_spawnpoints, true,
1792         {
1793                 switch(it.team)
1794                 {
1795                         case NUM_TEAM_1: team1_score = 1; break;
1796                         case NUM_TEAM_2: team2_score = 1; break;
1797                         case NUM_TEAM_3: team3_score = 1; break;
1798                         case NUM_TEAM_4: team4_score = 1; break;
1799                 }
1800         });
1801
1802         ClearWinners();
1803         if(team1_score + team2_score + team3_score + team4_score == 0)
1804         {
1805                 checkrules_equality = true;
1806                 return WINNING_YES;
1807         }
1808         else if(team1_score + team2_score + team3_score + team4_score == 1)
1809         {
1810                 float t, i;
1811                 if(team1_score)
1812                         t = NUM_TEAM_1;
1813                 else if(team2_score)
1814                         t = NUM_TEAM_2;
1815                 else if(team3_score)
1816                         t = NUM_TEAM_3;
1817                 else // if(team4_score)
1818                         t = NUM_TEAM_4;
1819                 CheckAllowedTeams(NULL);
1820                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1821                 {
1822                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1823                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1824                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1825                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1826                 }
1827
1828                 AddWinners(team, t);
1829                 return WINNING_YES;
1830         }
1831         else
1832                 return WINNING_NO;
1833 }
1834
1835 /*
1836 ============
1837 CheckRules_World
1838
1839 Exit deathmatch games upon conditions
1840 ============
1841 */
1842 void CheckRules_World()
1843 {
1844         float timelimit;
1845         float fraglimit;
1846         float leadlimit;
1847
1848         VoteThink();
1849         MapVote_Think();
1850
1851         SetDefaultAlpha();
1852
1853         if (intermission_running) // someone else quit the game already
1854         {
1855                 if(player_count == 0) // Nobody there? Then let's go to the next map
1856                         MapVote_Start();
1857                         // this will actually check the player count in the next frame
1858                         // again, but this shouldn't hurt
1859                 return;
1860         }
1861
1862         timelimit = autocvar_timelimit * 60;
1863         fraglimit = autocvar_fraglimit;
1864         leadlimit = autocvar_leadlimit;
1865
1866         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1867         {
1868                 if(timelimit > 0)
1869                         timelimit = 0; // timelimit is not made for warmup
1870                 if(fraglimit > 0)
1871                         fraglimit = 0; // no fraglimit for now
1872                 leadlimit = 0; // no leadlimit for now
1873         }
1874
1875         if(timelimit > 0)
1876         {
1877                 timelimit += game_starttime;
1878         }
1879         else if (timelimit < 0)
1880         {
1881                 // endmatch
1882                 NextLevel();
1883                 return;
1884         }
1885
1886         float wantovertime;
1887         wantovertime = 0;
1888
1889         if(timelimit > game_starttime)
1890                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1891         else
1892                 game_completion_ratio = 0;
1893
1894         if(checkrules_suddendeathend)
1895         {
1896                 if(!checkrules_suddendeathwarning)
1897                 {
1898                         checkrules_suddendeathwarning = true;
1899                         if(g_race && !g_race_qualifying)
1900                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1901                         else
1902                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1903                 }
1904         }
1905         else
1906         {
1907                 if (timelimit && time >= timelimit)
1908                 {
1909                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1910                         {
1911                                 float totalplayers;
1912                                 float playerswithlaps;
1913                                 float readyplayers;
1914                                 totalplayers = playerswithlaps = readyplayers = 0;
1915                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1916                                         ++totalplayers;
1917                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1918                                                 ++playerswithlaps;
1919                                         if(it.ready)
1920                                                 ++readyplayers;
1921                                 ));
1922
1923                                 // at least 2 of the players have completed a lap: start the RACE
1924                                 // otherwise, the players should end the qualifying on their own
1925                                 if(readyplayers || playerswithlaps >= 2)
1926                                 {
1927                                         checkrules_suddendeathend = 0;
1928                                         ReadyRestart(); // go to race
1929                                         return;
1930                                 }
1931                                 else
1932                                         wantovertime |= InitiateSuddenDeath();
1933                         }
1934                         else
1935                                 wantovertime |= InitiateSuddenDeath();
1936                 }
1937         }
1938
1939         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1940         {
1941                 NextLevel();
1942                 return;
1943         }
1944
1945         int checkrules_status = WinningCondition_RanOutOfSpawns();
1946         if(checkrules_status == WINNING_YES)
1947                 bprint("Hey! Someone ran out of spawns!\n");
1948         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1949                 checkrules_status = M_ARGV(0, float);
1950         else
1951                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1952
1953         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1954         {
1955                 checkrules_status = WINNING_NEVER;
1956                 checkrules_overtimesadded = -1;
1957                 wantovertime |= InitiateSuddenDeath();
1958         }
1959
1960         if(checkrules_status == WINNING_NEVER)
1961                 // equality cases! Nobody wins if the overtime ends in a draw.
1962                 ClearWinners();
1963
1964         if(wantovertime)
1965         {
1966                 if(checkrules_status == WINNING_NEVER)
1967                         InitiateOvertime();
1968                 else
1969                         checkrules_status = WINNING_YES;
1970         }
1971
1972         if(checkrules_suddendeathend)
1973                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1974                         checkrules_status = WINNING_YES;
1975
1976         if(checkrules_status == WINNING_YES)
1977         {
1978                 //print("WINNING\n");
1979                 NextLevel();
1980         }
1981 }
1982
1983 string GotoMap(string m)
1984 {
1985         m = GameTypeVote_MapInfo_FixName(m);
1986         if (!m)
1987                 return "The map you suggested is not available on this server.";
1988         if (!autocvar_sv_vote_gametype)
1989         if(!MapInfo_CheckMap(m))
1990                 return "The map you suggested does not support the current game mode.";
1991         cvar_set("nextmap", m);
1992         cvar_set("timelimit", "-1");
1993         if(mapvote_initialized || alreadychangedlevel)
1994         {
1995                 if(DoNextMapOverride(0))
1996                         return "Map switch initiated.";
1997                 else
1998                         return "Hm... no. For some reason I like THIS map more.";
1999         }
2000         else
2001                 return "Map switch will happen after scoreboard.";
2002 }
2003
2004 bool autocvar_sv_gameplayfix_multiplethinksperframe;
2005 void RunThink(entity this)
2006 {
2007         // don't let things stay in the past.
2008         // it is possible to start that way by a trigger with a local time.
2009         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2010                 return;
2011
2012         float oldtime = time; // do we need to save this?
2013
2014         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2015         {
2016                 time = max(oldtime, this.nextthink);
2017                 this.nextthink = 0;
2018
2019                 if(getthink(this))
2020                         getthink(this)(this);
2021                 // mods often set nextthink to time to cause a think every frame,
2022                 // we don't want to loop in that case, so exit if the new nextthink is
2023                 // <= the time the qc was told, also exit if it is past the end of the
2024                 // frame
2025                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2026                         break;
2027         }
2028
2029         time = oldtime;
2030 }
2031
2032 bool autocvar_sv_freezenonclients;
2033 bool autocvar_sv_gameplayfix_delayprojectiles;
2034 void Physics_Frame()
2035 {
2036         if(autocvar_sv_freezenonclients)
2037                 return;
2038
2039         FOREACH_ENTITY_FLOAT(pure_data, false,
2040         {
2041                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2042                         continue;
2043
2044                 //set_movetype(it, it.move_movetype);
2045                 // inline the set_movetype function, since this is called a lot
2046                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2047
2048                 if(it.move_movetype == MOVETYPE_NONE)
2049                         continue;
2050
2051                 if(it.move_qcphysics)
2052                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2053
2054                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2055                 {
2056                         // handle thinking here
2057                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2058                                 RunThink(it);
2059                 }
2060         });
2061
2062         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2063                 return;
2064
2065         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2066         {
2067                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2068                         continue;
2069                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2070         });
2071 }
2072
2073 void systems_update();
2074 void EndFrame()
2075 {
2076         anticheat_endframe();
2077
2078         Physics_Frame();
2079
2080         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2081                 entity e = IS_SPEC(it) ? it.enemy : it;
2082                 if (e.typehitsound) {
2083                         it.typehit_time = time;
2084                 } else if (e.killsound) {
2085                         it.kill_time = time;
2086                 } else if (e.damage_dealt) {
2087                         it.hit_time = time;
2088                         it.damage_dealt_total += ceil(e.damage_dealt);
2089                 }
2090         });
2091         // add 1 frametime because after this, engine SV_Physics
2092         // increases time by a frametime and then networks the frame
2093         // add another frametime because client shows everything with
2094         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2095         // needed!
2096         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2097         FOREACH_CLIENT(true, {
2098                 it.typehitsound = false;
2099                 it.damage_dealt = 0;
2100                 it.killsound = false;
2101                 antilag_record(it, CS(it), altime);
2102         });
2103         IL_EACH(g_monsters, true,
2104         {
2105                 antilag_record(it, it, altime);
2106         });
2107         systems_update();
2108         IL_ENDFRAME();
2109 }
2110
2111
2112 /*
2113  * RedirectionThink:
2114  * returns true if redirecting
2115  */
2116 float redirection_timeout;
2117 float redirection_nextthink;
2118 float RedirectionThink()
2119 {
2120         float clients_found;
2121
2122         if(redirection_target == "")
2123                 return false;
2124
2125         if(!redirection_timeout)
2126         {
2127                 cvar_set("sv_public", "-2");
2128                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2129                 if(redirection_target == "self")
2130                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2131                 else
2132                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2133         }
2134
2135         if(time < redirection_nextthink)
2136                 return true;
2137
2138         redirection_nextthink = time + 1;
2139
2140         clients_found = 0;
2141         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2142                 // TODO add timer
2143                 LOG_INFO("Redirecting: sending connect command to ", it.netname, "\n");
2144                 if(redirection_target == "self")
2145                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2146                 else
2147                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2148                 ++clients_found;
2149         ));
2150
2151         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2152
2153         if(time > redirection_timeout || clients_found == 0)
2154                 localcmd("\nwait; wait; wait; quit\n");
2155
2156         return true;
2157 }
2158
2159 void TargetMusic_RestoreGame();
2160 void RestoreGame()
2161 {
2162         // Loaded from a save game
2163         // some things then break, so let's work around them...
2164
2165         // Progs DB (capture records)
2166         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2167
2168         // Mapinfo
2169         MapInfo_Shutdown();
2170         MapInfo_Enumerate();
2171         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2172         WeaponStats_Init();
2173
2174         TargetMusic_RestoreGame();
2175 }
2176
2177 void Shutdown()
2178 {
2179         game_stopped = 2;
2180
2181         if(world_initialized > 0)
2182         {
2183                 world_initialized = 0;
2184                 LOG_TRACE("Saving persistent data...");
2185                 Ban_SaveBans();
2186
2187                 // playerstats with unfinished match
2188                 PlayerStats_GameReport(false);
2189
2190                 if(!cheatcount_total)
2191                 {
2192                         if(autocvar_sv_db_saveasdump)
2193                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2194                         else
2195                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2196                 }
2197                 if(autocvar_developer)
2198                 {
2199                         if(autocvar_sv_db_saveasdump)
2200                                 db_dump(TemporaryDB, "server-temp.db");
2201                         else
2202                                 db_save(TemporaryDB, "server-temp.db");
2203                 }
2204                 CheatShutdown(); // must be after cheatcount check
2205                 db_close(ServerProgsDB);
2206                 db_close(TemporaryDB);
2207                 LOG_TRACE("Saving persistent data... done!");
2208                 // tell the bot system the game is ending now
2209                 bot_endgame();
2210
2211                 WeaponStats_Shutdown();
2212                 MapInfo_Shutdown();
2213         }
2214         else if(world_initialized == 0)
2215         {
2216                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2217         }
2218         else
2219         {
2220                 __init_dedicated_server_shutdown();
2221         }
2222 }