qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_assault");
 257                 BADCVAR("g_ca");
 258                 BADCVAR("g_ca_teams");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_freezetag_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_leadlimit");
 308                 BADCVAR("g_ctf_captimerecord_always");
 309                 BADCVAR("g_ctf_flag_glowtrails");
 310                 BADCVAR("g_ctf_flag_pickup_verbosename");
 311                 BADCVAR("g_domination_point_leadlimit");
 312                 BADCVAR("g_forced_respawn");
 313                 BADCVAR("g_keyhunt_point_leadlimit");
 314                 BADPREFIX("g_mod_");
 315                 BADCVAR("g_nexball_goalleadlimit");
 316                 BADCVAR("leadlimit_and_fraglimit");
 317                 BADCVAR("leadlimit_override");
 318                 BADCVAR("pausable");
 319                 BADCVAR("sv_allow_fullbright");
 320                 BADCVAR("sv_checkforpacketsduringsleep");
 321                 BADCVAR("sv_fraginfo");
 322                 BADCVAR("sv_timeout");
 323                 BADPREFIX("sv_timeout_");
 324                 BADPREFIX("crypto_");
 325                 BADPREFIX("g_chat_");
 326                 BADPREFIX("g_ctf_captimerecord_");
 327                 BADPREFIX("g_maplist_votable_");
 328                 BADPREFIX("net_");
 329                 BADPREFIX("prvm_");
 330                 BADPREFIX("skill_");
 331                 BADPREFIX("sv_cullentities_");
 332                 BADPREFIX("sv_fraginfo_");
 333                 BADPREFIX("sv_maxidle_");
 334                 BADPREFIX("sv_vote_");
 335                 BADPREFIX("timelimit_");
 336                 BADCVAR("gameversion");
 337                 BADPREFIX("gameversion_");
 338                 BADCVAR("sv_namechangetimer");
 339
 340                 // allowed changes to server admins (please sync this to server.cfg)
 341                 // vi commands:
 342                 //   :/"impure"/,$d
 343                 //   :g!,^\/\/[^ /],d
 344                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 345                 //   :%!sort
 346                 // yes, this does contain some redundant stuff, don't really care
 347                 BADCVAR("bot_config_file");
 348                 BADCVAR("bot_number");
 349                 BADCVAR("bot_prefix");
 350                 BADCVAR("bot_suffix");
 351                 BADCVAR("capturelimit_override");
 352                 BADCVAR("fraglimit_override");
 353                 BADCVAR("gametype");
 354                 BADCVAR("g_antilag");
 355                 BADCVAR("g_balance_teams");
 356                 BADCVAR("g_balance_teams_prevent_imbalance");
 357                 BADCVAR("g_balance_teams_scorefactor");
 358                 BADCVAR("g_ban_sync_trusted_servers");
 359                 BADCVAR("g_ban_sync_uri");
 360                 BADCVAR("g_ca_teams_override");
 361                 BADCVAR("g_ctf_ignore_frags");
 362                 BADCVAR("g_domination_point_limit");
 363                 BADCVAR("g_freezetag_teams_override");
 364                 BADCVAR("g_friendlyfire");
 365                 BADCVAR("g_fullbrightitems");
 366                 BADCVAR("g_fullbrightplayers");
 367                 BADCVAR("g_keyhunt_point_limit");
 368                 BADCVAR("g_keyhunt_teams_override");
 369                 BADCVAR("g_lms_lives_override");
 370                 BADCVAR("g_maplist");
 371                 BADCVAR("g_maplist_check_waypoints");
 372                 BADCVAR("g_maplist_mostrecent_count");
 373                 BADCVAR("g_maplist_shuffle");
 374                 BADCVAR("g_maplist_votable");
 375                 BADCVAR("g_maplist_votable_abstain");
 376                 BADCVAR("g_maplist_votable_nodetail");
 377                 BADCVAR("g_maplist_votable_suggestions");
 378                 BADCVAR("g_maxplayers");
 379                 BADCVAR("g_mirrordamage");
 380                 BADCVAR("g_nexball_goallimit");
 381                 BADCVAR("g_powerups");
 382                 BADCVAR("g_start_delay");
 383                 BADCVAR("g_warmup");
 384                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 385                 BADCVAR("hostname");
 386                 BADCVAR("log_file");
 387                 BADCVAR("maxplayers");
 388                 BADCVAR("minplayers");
 389                 BADCVAR("net_address");
 390                 BADCVAR("port");
 391                 BADCVAR("rcon_password");
 392                 BADCVAR("rcon_restricted_commands");
 393                 BADCVAR("rcon_restricted_password");
 394                 BADCVAR("skill");
 395                 BADCVAR("sv_adminnick");
 396                 BADCVAR("sv_autoscreenshot");
 397                 BADCVAR("sv_autotaunt");
 398                 BADCVAR("sv_curl_defaulturl");
 399                 BADCVAR("sv_defaultcharacter");
 400                 BADCVAR("sv_defaultplayercolors");
 401                 BADCVAR("sv_defaultplayermodel");
 402                 BADCVAR("sv_defaultplayerskin");
 403                 BADCVAR("sv_maxidle");
 404                 BADCVAR("sv_maxrate");
 405                 BADCVAR("sv_motd");
 406                 BADCVAR("sv_public");
 407                 BADCVAR("sv_ready_restart");
 408                 BADCVAR("sv_status_privacy");
 409                 BADCVAR("sv_taunt");
 410                 BADCVAR("sv_vote_call");
 411                 BADCVAR("sv_vote_commands");
 412                 BADCVAR("sv_vote_majority_factor");
 413                 BADCVAR("sv_vote_master");
 414                 BADCVAR("sv_vote_master_commands");
 415                 BADCVAR("sv_vote_master_password");
 416                 BADCVAR("sv_vote_simple_majority_factor");
 417                 BADCVAR("teamplay_mode");
 418                 BADCVAR("timelimit_override");
 419                 BADCVAR("g_spawnshieldtime");
 420                 BADPREFIX("g_warmup_");
 421                 BADPREFIX("sv_ready_restart_");
 422
 423                 // mutators that announce themselves properly to the server browser
 424                 BADCVAR("g_minstagib");
 425                 BADCVAR("g_new_toys");
 426                 BADCVAR("g_nix");
 427                 BADCVAR("g_grappling_hook");
 428                 BADCVAR("g_jetpack");
 429
 430 #undef BADPREFIX
 431 #undef BADCVAR
 432
 433                 if(pureadding)
 434                 {
 435                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 436                         if(strlen(cvar_purechanges) > 16384)
 437                         {
 438                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 439                                 pureadding = 0;
 440                         }
 441                 }
 442                 ++cvar_purechanges_count;
 443                 // WARNING: this variable is used for the server list
 444                 // NEVER dare to skip this code!
 445                 // Hacks to intentionally appearing as "pure server" even though you DO have
 446                 // modified settings may be punished by removal from the server list.
 447                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 448                 // though.
 449         }
 450         buf_del(h);
 451         if(cvar_changes == "")
 452                 cvar_changes = "// this server runs at default server settings\n";
 453         else
 454                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 455         cvar_changes = strzone(cvar_changes);
 456         if(cvar_purechanges == "")
 457                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 458         else
 459                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 460         cvar_purechanges = strzone(cvar_purechanges);
 461 }
 462
 463 void detect_maptype()
 464 {
 465 #if 0
 466         vector o, v;
 467         float i;
 468
 469         for(;;)
 470         {
 471                 o = world.mins;
 472                 o_x += random() * (world.maxs_x - world.mins_x);
 473                 o_y += random() * (world.maxs_y - world.mins_y);
 474                 o_z += random() * (world.maxs_z - world.mins_z);
 475
 476                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 477                 if(trace_fraction == 1)
 478                         continue;
 479
 480                 v = trace_endpos;
 481
 482                 for(i = 0; i < 64; i += 4)
 483                 {
 484                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 485         if(trace_fraction == 1)
 486                 continue;
 487                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 488                 }
 489
 490                 break;
 491         }
 492 #endif
 493 }
 494
 495 entity randomseed;
 496 float RandomSeed_Send(entity to, float sf)
 497 {
 498         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 499         WriteShort(MSG_ENTITY, self.cnt);
 500         return TRUE;
 501 }
 502 void RandomSeed_Think()
 503 {
 504         self.cnt = bound(0, floor(random() * 65536), 65535);
 505         self.nextthink = time + 5;
 506
 507         self.SendFlags |= 1;
 508 }
 509 void RandomSeed_Spawn()
 510 {
 511         randomseed = spawn();
 512         randomseed.think = RandomSeed_Think;
 513         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 514
 515         entity oldself;
 516         oldself = self;
 517         self = randomseed;
 518         self.think(); // sets random seed and nextthink
 519         self = oldself;
 520 }
 521
 522 void spawnfunc___init_dedicated_server(void)
 523 {
 524         // handler for _init/_init map (only for dedicated server initialization)
 525
 526         world_initialized = -1; // don't complain
 527         cvar = cvar_normal;
 528         cvar_string = cvar_string_normal;
 529         cvar_set = cvar_set_normal;
 530
 531         remove = remove_unsafely;
 532
 533         entity e;
 534         e = spawn();
 535         e.think = GotoFirstMap;
 536         e.nextthink = time; // this is usually 1 at this point
 537
 538         e = spawn();
 539         e.classname = "info_player_deathmatch"; // safeguard against player joining
 540
 541         self.classname = "worldspawn"; // safeguard against various stuff ;)
 542
 543         // needs to be done so early because of the constants they create
 544         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 545         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 546         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 547         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 548         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 549         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 550
 551         MapInfo_Enumerate();
 552         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 553 }
 554
 555 void Map_MarkAsRecent(string m);
 556 float world_already_spawned;
 557 void Nagger_Init();
 558 void ClientInit_Spawn();
 559 void WeaponStats_Init();
 560 void WeaponStats_Shutdown();
 561 void spawnfunc_worldspawn (void)
 562 {
 563         float fd, l, i, j, n;
 564         string s;
 565
 566         cvar = cvar_normal;
 567         cvar_string = cvar_string_normal;
 568         cvar_set = cvar_set_normal;
 569
 570         if(world_already_spawned)
 571                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 572         world_already_spawned = TRUE;
 573
 574         remove = remove_safely; // during spawning, watch what you remove!
 575
 576         check_unacceptable_compiler_bugs();
 577
 578         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 579
 580         compressShortVector_init();
 581
 582         entity head;
 583         head = nextent(world);
 584         maxclients = 0;
 585         while(head)
 586         {
 587                 ++maxclients;
 588                 head = nextent(head);
 589         }
 590
 591         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 592
 593         // needs to be done so early because of the constants they create
 594         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 595         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 596         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 597         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 599         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 600
 601         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 602
 603         TemporaryDB = db_create();
 604
 605         // 0 normal
 606         lightstyle(0, "m");
 607
 608         // 1 FLICKER (first variety)
 609         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 610
 611         // 2 SLOW STRONG PULSE
 612         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 613
 614         // 3 CANDLE (first variety)
 615         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 616
 617         // 4 FAST STROBE
 618         lightstyle(4, "mamamamamama");
 619
 620         // 5 GENTLE PULSE 1
 621         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 622
 623         // 6 FLICKER (second variety)
 624         lightstyle(6, "nmonqnmomnmomomno");
 625
 626         // 7 CANDLE (second variety)
 627         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 628
 629         // 8 CANDLE (third variety)
 630         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 631
 632         // 9 SLOW STROBE (fourth variety)
 633         lightstyle(9, "aaaaaaaazzzzzzzz");
 634
 635         // 10 FLUORESCENT FLICKER
 636         lightstyle(10, "mmamammmmammamamaaamammma");
 637
 638         // 11 SLOW PULSE NOT FADE TO BLACK
 639         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 640
 641         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 642
 643         // 63 testing
 644         lightstyle(63, "a");
 645
 646         if(autocvar_g_campaign)
 647                 CampaignPreInit();
 648
 649         Map_MarkAsRecent(mapname);
 650
 651         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 652
 653         precache_model ("null"); // we need this one before InitGameplayMode
 654         InitGameplayMode();
 655         readlevelcvars();
 656         GrappleHookInit();
 657         ElectroInit();
 658         LaserInit();
 659
 660         player_count = 0;
 661         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 662         if(bot_waypoints_for_items == 1)
 663                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 664                         bot_waypoints_for_items = 0;
 665
 666         precache();
 667
 668         WaypointSprite_Init();
 669
 670         GameLogInit(); // prepare everything
 671         // NOTE for matchid:
 672         // changing the logic generating it is okay. But:
 673         // it HAS to stay <= 64 chars
 674         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 675         if(autocvar_sv_eventlog)
 676         {
 677                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 678                 matchid = strzone(s);
 679
 680                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 681                 s = ":gameinfo:mutators:LIST";
 682
 683                 ret_string = s;
 684                 MUTATOR_CALLHOOK(BuildMutatorsString);
 685                 s = ret_string;
 686
 687                 // simple, probably not good in the mutator system
 688                 if(autocvar_g_grappling_hook)
 689                         s = strcat(s, ":grappling_hook");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(!autocvar_g_use_ammunition)
 693                         s = strcat(s, ":no_use_ammunition");
 694
 695                 // initialiation stuff, not good in the mutator system
 696                 if(autocvar_g_pickup_items == 0)
 697                         s = strcat(s, ":no_pickup_items");
 698                 if(autocvar_g_pickup_items > 0)
 699                         s = strcat(s, ":pickup_items");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_weaponarena != "0")
 703                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_norecoil)
 707                         s = strcat(s, ":norecoil");
 708
 709                 // TODO to mutator system
 710                 if(autocvar_g_powerups == 0)
 711                         s = strcat(s, ":no_powerups");
 712                 if(autocvar_g_powerups > 0)
 713                         s = strcat(s, ":powerups");
 714
 715                 GameLogEcho(s);
 716                 GameLogEcho(":gameinfo:end");
 717         }
 718         else
 719                 matchid = strzone(ftos(random()));
 720
 721         cvar_set("nextmap", "");
 722
 723         SetDefaultAlpha();
 724
 725         if(autocvar_g_campaign)
 726                 CampaignPostInit();
 727
 728         fteqcc_testbugs();
 729
 730         Ban_LoadBans();
 731
 732         MapInfo_Enumerate();
 733         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 734
 735         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 736         {
 737                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 738                 if(fd != -1)
 739                 {
 740                         while((s = fgets(fd)))
 741                         {
 742                                 l = tokenize_console(s);
 743                                 if(l < 2)
 744                                         continue;
 745                                 if(argv(0) == "cd")
 746                                 {
 747                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 748                                         print("  cdtrack ", argv(2), "\n");
 749                                 }
 750                                 else if(argv(0) == "fog")
 751                                 {
 752                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 753                                         print("  \"fog\" \"", s, "\"\n");
 754                                 }
 755                                 else if(argv(0) == "set")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) != "//")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 763                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 764                                 }
 765                         }
 766                         fclose(fd);
 767                 }
 768         }
 769
 770         WeaponStats_Init();
 771
 772         WepSet_AddStat();
 773         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 774         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 775         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 776         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 777         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 778         Nagger_Init();
 779
 780         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 781         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 782         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 783         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 784         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 785         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 786         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 787         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 788         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 789         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 790         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 791         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 792         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 793
 794         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 795         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 796
 797         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 798
 799         // g_movementspeed hack
 800         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 801         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 802         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 803         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 804
 805         // secrets
 806         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 807         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 808
 809         // monsters
 810         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 811         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 812
 813         // misc
 814         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 815
 816         next_pingtime = time + 5;
 817
 818         detect_maptype();
 819
 820         // set up information replies for clients and server to use
 821         maplist_reply = strzone(getmaplist());
 822         lsmaps_reply = strzone(getlsmaps());
 823         monsterlist_reply = strzone(getmonsterlist());
 824         for(i = 0; i < 10; ++i)
 825         {
 826                 s = getrecords(i);
 827                 if (s)
 828                         records_reply[i] = strzone(s);
 829         }
 830         ladder_reply = strzone(getladder());
 831         rankings_reply = strzone(getrankings());
 832
 833         // begin other init
 834         ClientInit_Spawn();
 835         RandomSeed_Spawn();
 836         PingPLReport_Spawn();
 837
 838         CheatInit();
 839
 840         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 841
 842         // fill sv_curl_serverpackages from .serverpackage files
 843         if(autocvar_sv_curl_serverpackages_auto)
 844         {
 845                 s = "";
 846                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 847                 for(i = 0; i < n; ++i)
 848                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 849                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 850                                 s = strcat(s, " ", argv(i));
 851                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 852                 if(fd >= 0)
 853                 {
 854                         j = search_getsize(fd);
 855                         for(i = 0; i < j; ++i)
 856                                 s = strcat(s, " ", search_getfilename(fd, i));
 857                         search_end(fd);
 858                 }
 859                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 860                 if(fd >= 0)
 861                 {
 862                         j = search_getsize(fd);
 863                         for(i = 0; i < j; ++i)
 864                                 s = strcat(s, " ", search_getfilename(fd, i));
 865                         search_end(fd);
 866                 }
 867                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 868         }
 869
 870         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 871         modname = "Xonotic";
 872         // physics/balance/config changes that count as mod
 873         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 874                 modname = cvar_string("g_mod_physics");
 875         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 876                 modname = cvar_string("g_mod_balance");
 877         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 878                 modname = cvar_string("g_mod_config");
 879         // extra mutators that deserve to count as mod
 880         MUTATOR_CALLHOOK(SetModname);
 881
 882         // save it for later
 883         modname = strzone(modname);
 884
 885         WinningConditionHelper(); // set worldstatus
 886
 887         world_initialized = 1;
 888 }
 889
 890 void spawnfunc_light (void)
 891 {
 892         //makestatic (self); // Who the f___ did that?
 893         remove(self);
 894 }
 895
 896 string GetGametype()
 897 {
 898         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 899 }
 900
 901 string getmapname_stored;
 902 string GetMapname()
 903 {
 904         return mapname;
 905 }
 906
 907 float Map_Count, Map_Current;
 908 string Map_Current_Name;
 909
 910 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 911 float GetMaplistPosition()
 912 {
 913         float pos, idx;
 914         string map;
 915
 916         map = GetMapname();
 917         idx = autocvar_g_maplist_index;
 918
 919         if(idx >= 0)
 920                 if(idx < Map_Count)
 921                         if(map == argv(idx))
 922                                 return idx;
 923
 924         for(pos = 0; pos < Map_Count; ++pos)
 925                 if(map == argv(pos))
 926                         return pos;
 927
 928         // resume normal maplist rotation if current map is not in g_maplist
 929         return idx;
 930 }
 931
 932 float MapHasRightSize(string map)
 933 {
 934         float fh;
 935         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 936         if(autocvar_g_maplist_check_waypoints)
 937         {
 938                 dprint("checkwp "); dprint(map);
 939                 if(!fexists(strcat("maps/", map, ".waypoints")))
 940                 {
 941                         dprint(": no waypoints\n");
 942                         return FALSE;
 943                 }
 944                 dprint(": has waypoints\n");
 945         }
 946
 947         // open map size restriction file
 948         dprint("opensize "); dprint(map);
 949         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 950         if(fh >= 0)
 951         {
 952                 float mapmin, mapmax;
 953                 dprint(": ok, ");
 954                 mapmin = stof(fgets(fh));
 955                 mapmax = stof(fgets(fh));
 956                 fclose(fh);
 957                 if(player_count < mapmin)
 958                 {
 959                         dprint("not enough\n");
 960                         return FALSE;
 961                 }
 962                 if(player_count > mapmax)
 963                 {
 964                         dprint("too many\n");
 965                         return FALSE;
 966                 }
 967                 dprint("right size\n");
 968                 return TRUE;
 969         }
 970         dprint(": not found\n");
 971         return TRUE;
 972 }
 973
 974 string Map_Filename(float position)
 975 {
 976         return strcat("maps/", argv(position), ".bsp");
 977 }
 978
 979 string strwords(string s, float w)
 980 {
 981         float endpos;
 982         for(endpos = 0; w && endpos >= 0; --w)
 983                 endpos = strstrofs(s, " ", endpos + 1);
 984         if(endpos < 0)
 985                 return s;
 986         else
 987                 return substring(s, 0, endpos);
 988 }
 989
 990 float strhasword(string s, string w)
 991 {
 992         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 993 }
 994
 995 void Map_MarkAsRecent(string m)
 996 {
 997         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 998 }
 999
1000 float Map_IsRecent(string m)
1001 {
1002         return strhasword(autocvar_g_maplist_mostrecent, m);
1003 }
1004
1005 float Map_Check(float position, float pass)
1006 {
1007         string filename;
1008         string map_next;
1009         map_next = argv(position);
1010         if(pass <= 1)
1011         {
1012                 if(Map_IsRecent(map_next))
1013                         return 0;
1014         }
1015         filename = Map_Filename(position);
1016         if(MapInfo_CheckMap(map_next))
1017         {
1018                 if(pass == 2)
1019                         return 1;
1020                 if(MapHasRightSize(map_next))
1021                         return 1;
1022                 return 0;
1023         }
1024         else
1025                 dprint( "Couldn't select '", filename, "'..\n" );
1026
1027         return 0;
1028 }
1029
1030 void Map_Goto_SetStr(string nextmapname)
1031 {
1032         if(getmapname_stored != "")
1033                 strunzone(getmapname_stored);
1034         if(nextmapname == "")
1035                 getmapname_stored = "";
1036         else
1037                 getmapname_stored = strzone(nextmapname);
1038 }
1039
1040 void Map_Goto_SetFloat(float position)
1041 {
1042         cvar_set("g_maplist_index", ftos(position));
1043         Map_Goto_SetStr(argv(position));
1044 }
1045
1046 void Map_Goto(float reinit)
1047 {
1048         MapInfo_LoadMap(getmapname_stored, reinit);
1049 }
1050
1051 // return codes of map selectors:
1052 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1053 //   -2 = permanent failure
1054 float() MaplistMethod_Iterate = // usual method
1055 {
1056         float pass, i;
1057
1058         dprint("Trying MaplistMethod_Iterate\n");
1059
1060         for(pass = 1; pass <= 2; ++pass)
1061         {
1062                 for(i = 1; i < Map_Count; ++i)
1063                 {
1064                         float mapindex;
1065                         mapindex = mod(i + Map_Current, Map_Count);
1066                         if(Map_Check(mapindex, pass))
1067                                 return mapindex;
1068                 }
1069         }
1070         return -1;
1071 }
1072
1073 float() MaplistMethod_Repeat = // fallback method
1074 {
1075         dprint("Trying MaplistMethod_Repeat\n");
1076
1077         if(Map_Check(Map_Current, 2))
1078                 return Map_Current;
1079         return -2;
1080 }
1081
1082 float() MaplistMethod_Random = // random map selection
1083 {
1084         float i, imax;
1085
1086         dprint("Trying MaplistMethod_Random\n");
1087
1088         imax = 42;
1089
1090         for(i = 0; i <= imax; ++i)
1091         {
1092                 float mapindex;
1093                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1094                 if(Map_Check(mapindex, 1))
1095                         return mapindex;
1096         }
1097         return -1;
1098 }
1099
1100 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1101 // the exponent sets a bias on the map selection:
1102 // the higher the exponent, the less likely "shortly repeated" same maps are
1103 {
1104         float i, j, imax, insertpos;
1105
1106         dprint("Trying MaplistMethod_Shuffle\n");
1107
1108         imax = 42;
1109
1110         for(i = 0; i <= imax; ++i)
1111         {
1112                 string newlist;
1113
1114                 // now reinsert this at another position
1115                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1116                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1117                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1118                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1119
1120                 // insert the current map there
1121                 newlist = "";
1122                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1123                         newlist = strcat(newlist, " ", argv(j));
1124                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1125                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1126                         newlist = strcat(newlist, " ", argv(j));
1127                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1128                 cvar_set("g_maplist", newlist);
1129                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1130
1131                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1132                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1133                 if(Map_Check(Map_Current, 1))
1134                         return Map_Current;
1135         }
1136         return -1;
1137 }
1138
1139 void Maplist_Init()
1140 {
1141         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1142         float i;
1143         for (i = 0; i < Map_Count; ++i)
1144                 if (Map_Check(i, 2))
1145                         break;
1146         if (i == Map_Count)
1147         {
1148                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1149                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1150                 if(autocvar_g_maplist_shuffle)
1151                         ShuffleMaplist();
1152                 localcmd("\nmenu_cmd sync\n");
1153                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1154         }
1155         if(Map_Count == 0)
1156                 error("empty maplist, cannot select a new map");
1157         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1158
1159         if(Map_Current_Name)
1160                 strunzone(Map_Current_Name);
1161         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1162         // this may or may not be correct, but who cares, in the worst case a map
1163         // isn't chosen in the first pass that should have been
1164 }
1165
1166 string GetNextMap()
1167 {
1168         float nextMap;
1169
1170         Maplist_Init();
1171         nextMap = -1;
1172
1173         if(nextMap == -1)
1174                 if(autocvar_g_maplist_shuffle > 0)
1175                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1176
1177         if(nextMap == -1)
1178                 if(autocvar_g_maplist_selectrandom)
1179                         nextMap = MaplistMethod_Random();
1180
1181         if(nextMap == -1)
1182                 nextMap = MaplistMethod_Iterate();
1183
1184         if(nextMap == -1)
1185                 nextMap = MaplistMethod_Repeat();
1186
1187         if(nextMap >= 0)
1188         {
1189                 Map_Goto_SetFloat(nextMap);
1190                 return getmapname_stored;
1191         }
1192
1193         return "";
1194 }
1195
1196 float DoNextMapOverride(float reinit)
1197 {
1198         if(autocvar_g_campaign)
1199         {
1200                 CampaignPostIntermission();
1201                 alreadychangedlevel = TRUE;
1202                 return TRUE;
1203         }
1204         if(autocvar_quit_when_empty)
1205         {
1206                 if(player_count <= currentbots)
1207                 {
1208                         localcmd("quit\n");
1209                         alreadychangedlevel = TRUE;
1210                         return TRUE;
1211                 }
1212         }
1213         if(autocvar_quit_and_redirect != "")
1214         {
1215                 redirection_target = strzone(autocvar_quit_and_redirect);
1216                 alreadychangedlevel = TRUE;
1217                 return TRUE;
1218         }
1219         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1220         {
1221                 localcmd("restart\n");
1222                 alreadychangedlevel = TRUE;
1223                 return TRUE;
1224         }
1225         if(autocvar_nextmap != "")
1226                 if(MapInfo_CheckMap(autocvar_nextmap))
1227                 {
1228                         Map_Goto_SetStr(autocvar_nextmap);
1229                         Map_Goto(reinit);
1230                         alreadychangedlevel = TRUE;
1231                         return TRUE;
1232                 }
1233         if(!reinit && autocvar_lastlevel)
1234         {
1235                 cvar_settemp_restore();
1236                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1237                 alreadychangedlevel = TRUE;
1238                 return TRUE;
1239         }
1240         return FALSE;
1241 }
1242
1243 void GotoNextMap(float reinit)
1244 {
1245         //string nextmap;
1246         //float n, nummaps;
1247         //string s;
1248         if (alreadychangedlevel)
1249                 return;
1250         alreadychangedlevel = TRUE;
1251
1252         string nextMap;
1253
1254         nextMap = GetNextMap();
1255         if(nextMap == "")
1256                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1257         Map_Goto(reinit);
1258 }
1259
1260
1261 /*
1262 ============
1263 IntermissionThink
1264
1265 When the player presses attack or jump, change to the next level
1266 ============
1267 */
1268 .float autoscreenshot;
1269 void() MapVote_Start;
1270 void() MapVote_Think;
1271 float mapvote_initialized;
1272 void IntermissionThink()
1273 {
1274         FixIntermissionClient(self);
1275
1276         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1277         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1278
1279         if( (server_screenshot || client_screenshot)
1280                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1281         {
1282                 self.autoscreenshot = -1;
1283                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1284                 return;
1285         }
1286
1287         if (time < intermission_exittime)
1288                 return;
1289
1290         if(!mapvote_initialized)
1291                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1292                         return;
1293
1294         MapVote_Start();
1295 }
1296
1297 /*
1298 ============
1299 FindIntermission
1300
1301 Returns the entity to view from
1302 ============
1303 */
1304 /*
1305 entity FindIntermission()
1306 {
1307         local   entity spot;
1308         local   float cyc;
1309
1310 // look for info_intermission first
1311         spot = find (world, classname, "info_intermission");
1312         if (spot)
1313         {       // pick a random one
1314                 cyc = random() * 4;
1315                 while (cyc > 1)
1316                 {
1317                         spot = find (spot, classname, "info_intermission");
1318                         if (!spot)
1319                                 spot = find (spot, classname, "info_intermission");
1320                         cyc = cyc - 1;
1321                 }
1322                 return spot;
1323         }
1324
1325 // then look for the start position
1326         spot = find (world, classname, "info_player_start");
1327         if (spot)
1328                 return spot;
1329
1330 // testinfo_player_start is only found in regioned levels
1331         spot = find (world, classname, "testplayerstart");
1332         if (spot)
1333                 return spot;
1334
1335 // then look for the start position
1336         spot = find (world, classname, "info_player_deathmatch");
1337         if (spot)
1338                 return spot;
1339
1340         //objerror ("FindIntermission: no spot");
1341         return world;
1342 }
1343 */
1344
1345 /*
1346 ===============================================================================
1347
1348 RULES
1349
1350 ===============================================================================
1351 */
1352
1353 void DumpStats(float final)
1354 {
1355         float file;
1356         string s;
1357         float to_console;
1358         float to_eventlog;
1359         float to_file;
1360         float i;
1361
1362         to_console = autocvar_sv_logscores_console;
1363         to_eventlog = autocvar_sv_eventlog;
1364         to_file = autocvar_sv_logscores_file;
1365
1366         if(!final)
1367         {
1368                 to_console = TRUE; // always print printstats replies
1369                 to_eventlog = FALSE; // but never print them to the event log
1370         }
1371
1372         if(to_eventlog)
1373                 if(autocvar_sv_eventlog_console)
1374                         to_console = FALSE; // otherwise we get the output twice
1375
1376         if(final)
1377                 s = ":scores:";
1378         else
1379                 s = ":status:";
1380         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1381
1382         if(to_console)
1383                 print(s, "\n");
1384         if(to_eventlog)
1385                 GameLogEcho(s);
1386
1387         file = -1;
1388         if(to_file)
1389         {
1390                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1391                 if(file == -1)
1392                         to_file = FALSE;
1393                 else
1394                         fputs(file, strcat(s, "\n"));
1395         }
1396
1397         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1398         if(to_console)
1399                 print(s, "\n");
1400         if(to_eventlog)
1401                 GameLogEcho(s);
1402         if(to_file)
1403                 fputs(file, strcat(s, "\n"));
1404
1405         FOR_EACH_CLIENT(other)
1406         {
1407                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1408                 {
1409                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1410                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1411                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1412                                 s = strcat(s, ftos(other.team), ":");
1413                         else
1414                                 s = strcat(s, "spectator:");
1415
1416                         if(to_console)
1417                                 print(s, other.netname, "\n");
1418                         if(to_eventlog)
1419                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1420                         if(to_file)
1421                                 fputs(file, strcat(s, other.netname, "\n"));
1422                 }
1423         }
1424
1425         if(teamplay)
1426         {
1427                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1428                 if(to_console)
1429                         print(s, "\n");
1430                 if(to_eventlog)
1431                         GameLogEcho(s);
1432                 if(to_file)
1433                         fputs(file, strcat(s, "\n"));
1434
1435                 for(i = 1; i < 16; ++i)
1436                 {
1437                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1438                         s = strcat(s, ":", ftos(i));
1439                         if(to_console)
1440                                 print(s, "\n");
1441                         if(to_eventlog)
1442                                 GameLogEcho(s);
1443                         if(to_file)
1444                                 fputs(file, strcat(s, "\n"));
1445                 }
1446         }
1447
1448         if(to_console)
1449                 print(":end\n");
1450         if(to_eventlog)
1451                 GameLogEcho(":end");
1452         if(to_file)
1453         {
1454                 fputs(file, ":end\n");
1455                 fclose(file);
1456         }
1457 }
1458
1459 void FixIntermissionClient(entity e)
1460 {
1461         string s;
1462         if(!e.autoscreenshot) // initial call
1463         {
1464                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1465                 e.health = -2342;
1466                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1467                 e.solid = SOLID_NOT;
1468                 e.movetype = MOVETYPE_NONE;
1469                 e.takedamage = DAMAGE_NO;
1470                 if(e.weaponentity)
1471                 {
1472                         e.weaponentity.effects = EF_NODRAW;
1473                         if (e.weaponentity.weaponentity)
1474                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1475                 }
1476                 if(IS_REAL_CLIENT(e))
1477                 {
1478                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1479                         s = autocvar_sv_intermission_cdtrack;
1480                         if(s != "")
1481                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1482                         msg_entity = e;
1483                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1484                 }
1485         }
1486 }
1487
1488 /*
1489 go to the next level for deathmatch
1490 only called if a time or frag limit has expired
1491 */
1492 void NextLevel()
1493 {
1494         gameover = TRUE;
1495
1496         intermission_running = 1;
1497
1498 // enforce a wait time before allowing changelevel
1499         if(player_count > 0)
1500                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1501         else
1502                 intermission_exittime = -1;
1503
1504         /*
1505         WriteByte (MSG_ALL, SVC_CDTRACK);
1506         WriteByte (MSG_ALL, 3);
1507         WriteByte (MSG_ALL, 3);
1508         // done in FixIntermission
1509         */
1510
1511         //pos = FindIntermission ();
1512
1513         VoteReset();
1514
1515         DumpStats(TRUE);
1516
1517         // send statistics
1518         entity e;
1519         PlayerStats_EndMatch(1);
1520         FOR_EACH_CLIENT(e)
1521                 PlayerStats_AddGlobalInfo(e);
1522         PlayerStats_Shutdown();
1523         WeaponStats_Shutdown();
1524
1525         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1526
1527         if(autocvar_sv_eventlog)
1528                 GameLogEcho(":gameover");
1529
1530         GameLogClose();
1531
1532         FOR_EACH_PLAYER(other) {
1533                 FixIntermissionClient(other);
1534                 if(other.winning)
1535                         bprint(other.netname, " ^7wins.\n");
1536         }
1537
1538         if(autocvar_g_campaign)
1539                 CampaignPreIntermission();
1540
1541         MUTATOR_CALLHOOK(MatchEnd);
1542
1543         localcmd("\nsv_hook_gameend\n");
1544 }
1545
1546 /*
1547 ============
1548 CheckRules_Player
1549
1550 Exit deathmatch games upon conditions
1551 ============
1552 */
1553 void CheckRules_Player()
1554 {
1555         if (gameover)   // someone else quit the game already
1556                 return;
1557
1558         if(self.deadflag == DEAD_NO)
1559                 self.play_time += frametime;
1560
1561         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1562         //   (div0: and that in CheckRules_World please)
1563 }
1564
1565 float checkrules_equality;
1566 float checkrules_suddendeathwarning;
1567 float checkrules_suddendeathend;
1568 float checkrules_overtimesadded; //how many overtimes have been already added
1569
1570 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1571 const float WINNING_YES = 1; // winner found
1572 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1573 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1574
1575 float InitiateSuddenDeath()
1576 {
1577         // Check first whether normal overtimes could be added before initiating suddendeath mode
1578         // - for this timelimit_overtime needs to be >0 of course
1579         // - also check the winning condition calculated in the previous frame and only add normal overtime
1580         //   again, if at the point at which timelimit would be extended again, still no winner was found
1581         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1582         {
1583                 return 1; // need to call InitiateOvertime later
1584         }
1585         else
1586         {
1587                 if(!checkrules_suddendeathend)
1588                 {
1589                         if(autocvar_g_campaign)
1590                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1591                         else
1592                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1593                         if(g_race && !g_race_qualifying)
1594                                 race_StartCompleting();
1595                 }
1596                 return 0;
1597         }
1598 }
1599
1600 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1601 {
1602         ++checkrules_overtimesadded;
1603         //add one more overtime by simply extending the timelimit
1604         float tl;
1605         tl = autocvar_timelimit;
1606         tl += autocvar_timelimit_overtime;
1607         cvar_set("timelimit", ftos(tl));
1608
1609         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1610 }
1611
1612 float GetWinningCode(float fraglimitreached, float equality)
1613 {
1614         if(autocvar_g_campaign == 1)
1615                 if(fraglimitreached)
1616                         return WINNING_YES;
1617                 else
1618                         return WINNING_NO;
1619
1620         else
1621                 if(equality)
1622                         if(fraglimitreached)
1623                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1624                         else
1625                                 return WINNING_NEVER;
1626                 else
1627                         if(fraglimitreached)
1628                                 return WINNING_YES;
1629                         else
1630                                 return WINNING_NO;
1631 }
1632
1633 // set the .winning flag for exactly those players with a given field value
1634 void SetWinners(.float field, float value)
1635 {
1636         entity head;
1637         FOR_EACH_PLAYER(head)
1638                 head.winning = (head.field == value);
1639 }
1640
1641 // set the .winning flag for those players with a given field value
1642 void AddWinners(.float field, float value)
1643 {
1644         entity head;
1645         FOR_EACH_PLAYER(head)
1646                 if(head.field == value)
1647                         head.winning = 1;
1648 }
1649
1650 // clear the .winning flags
1651 void ClearWinners(void)
1652 {
1653         entity head;
1654         FOR_EACH_PLAYER(head)
1655                 head.winning = 0;
1656 }
1657
1658 // Onslaught winning condition:
1659 // game terminates if only one team has a working generator (or none)
1660 float WinningCondition_Onslaught()
1661 {
1662         entity head;
1663         float t1, t2, t3, t4;
1664
1665         WinningConditionHelper(); // set worldstatus
1666
1667         if(warmup_stage)
1668                 return WINNING_NO;
1669
1670         // first check if the game has ended
1671         t1 = t2 = t3 = t4 = 0;
1672         head = find(world, classname, "onslaught_generator");
1673         while (head)
1674         {
1675                 if (head.health > 0)
1676                 {
1677                         if (head.team == NUM_TEAM_1) t1 = 1;
1678                         if (head.team == NUM_TEAM_2) t2 = 1;
1679                         if (head.team == NUM_TEAM_3) t3 = 1;
1680                         if (head.team == NUM_TEAM_4) t4 = 1;
1681                 }
1682                 head = find(head, classname, "onslaught_generator");
1683         }
1684         if (t1 + t2 + t3 + t4 < 2)
1685         {
1686                 // game over, only one team remains (or none)
1687                 ClearWinners();
1688                 if (t1) SetWinners(team, NUM_TEAM_1);
1689                 if (t2) SetWinners(team, NUM_TEAM_2);
1690                 if (t3) SetWinners(team, NUM_TEAM_3);
1691                 if (t4) SetWinners(team, NUM_TEAM_4);
1692                 dprint("Have a winner, ending game.\n");
1693                 return WINNING_YES;
1694         }
1695
1696         // Two or more teams remain
1697         return WINNING_NO;
1698 }
1699
1700 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1701 // they win. Otherwise the defending team wins once the timelimit passes.
1702 void assault_new_round();
1703 float WinningCondition_Assault()
1704 {
1705         float status;
1706
1707         WinningConditionHelper(); // set worldstatus
1708
1709         status = WINNING_NO;
1710         // as the timelimit has not yet passed just assume the defending team will win
1711         if(assault_attacker_team == NUM_TEAM_1)
1712         {
1713                 SetWinners(team, NUM_TEAM_2);
1714         }
1715         else
1716         {
1717                 SetWinners(team, NUM_TEAM_1);
1718         }
1719
1720         entity ent;
1721         ent = find(world, classname, "target_assault_roundend");
1722         if(ent)
1723         {
1724                 if(ent.winning) // round end has been triggered by attacking team
1725                 {
1726                         bprint("ASSAULT: round completed...\n");
1727                         SetWinners(team, assault_attacker_team);
1728
1729                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1730
1731                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1732                         {
1733                                 status = WINNING_YES;
1734                         }
1735                         else
1736                         {
1737                                 entity oldself;
1738                                 oldself = self;
1739                                 self = ent;
1740                                 assault_new_round();
1741                                 self = oldself;
1742                         }
1743                 }
1744         }
1745
1746         return status;
1747 }
1748
1749 // LMS winning condition: game terminates if and only if there's at most one
1750 // one player who's living lives. Top two scores being equal cancels the time
1751 // limit.
1752 float WinningCondition_LMS()
1753 {
1754         entity head, head2;
1755         float have_player;
1756         float have_players;
1757         float l;
1758
1759         have_player = FALSE;
1760         have_players = FALSE;
1761         l = LMS_NewPlayerLives();
1762
1763         head = find(world, classname, "player");
1764         if(head)
1765                 have_player = TRUE;
1766         head2 = find(head, classname, "player");
1767         if(head2)
1768                 have_players = TRUE;
1769
1770         if(have_player)
1771         {
1772                 // we have at least one player
1773                 if(have_players)
1774                 {
1775                         // two or more active players - continue with the game
1776                 }
1777                 else
1778                 {
1779                         // exactly one player?
1780
1781                         ClearWinners();
1782                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1783
1784                         if(l)
1785                         {
1786                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1787                                 return WINNING_NO;
1788                         }
1789                         else
1790                         {
1791                                 // a winner!
1792                                 // and assign him his first place
1793                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1794                                 return WINNING_YES;
1795                         }
1796                 }
1797         }
1798         else
1799         {
1800                 // nobody is playing at all...
1801                 if(l)
1802                 {
1803                         // wait for players...
1804                 }
1805                 else
1806                 {
1807                         // SNAFU (maybe a draw game?)
1808                         ClearWinners();
1809                         dprint("No players, ending game.\n");
1810                         return WINNING_YES;
1811                 }
1812         }
1813
1814         // When we get here, we have at least two players who are actually LIVING,
1815         // now check if the top two players have equal score.
1816         WinningConditionHelper();
1817
1818         ClearWinners();
1819         if(WinningConditionHelper_winner)
1820                 WinningConditionHelper_winner.winning = TRUE;
1821         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1822                 return WINNING_NEVER;
1823
1824         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1825         return WINNING_NO;
1826 }
1827
1828 void ShuffleMaplist()
1829 {
1830         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1831 }
1832
1833 float leaderfrags;
1834 float WinningCondition_Scores(float limit, float leadlimit)
1835 {
1836         float limitreached;
1837
1838         // TODO make everything use THIS winning condition (except LMS)
1839         WinningConditionHelper();
1840
1841         if(teamplay)
1842         {
1843                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1844                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1845                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1846                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1847         }
1848
1849         ClearWinners();
1850         if(WinningConditionHelper_winner)
1851                 WinningConditionHelper_winner.winning = 1;
1852         if(WinningConditionHelper_winnerteam >= 0)
1853                 SetWinners(team, WinningConditionHelper_winnerteam);
1854
1855         if(WinningConditionHelper_lowerisbetter)
1856         {
1857                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1858                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1859                 limit = -limit;
1860         }
1861
1862         if(WinningConditionHelper_zeroisworst)
1863                 leadlimit = 0; // not supported in this mode
1864
1865         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1866         // these modes always score in increments of 1, thus this makes sense
1867         {
1868                 if(leaderfrags != WinningConditionHelper_topscore)
1869                 {
1870                         leaderfrags = WinningConditionHelper_topscore;
1871
1872                         if (limit)
1873                         if (leaderfrags == limit - 1)
1874                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1875                         else if (leaderfrags == limit - 2)
1876                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1877                         else if (leaderfrags == limit - 3)
1878                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1879                 }
1880         }
1881
1882         limitreached = FALSE;
1883         if(limit)
1884                 if(WinningConditionHelper_topscore >= limit)
1885                         limitreached = TRUE;
1886         if(leadlimit)
1887         {
1888                 float leadlimitreached;
1889                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1890                 if(autocvar_leadlimit_and_fraglimit)
1891                         limitreached = (limitreached && leadlimitreached);
1892                 else
1893                         limitreached = (limitreached || leadlimitreached);
1894         }
1895
1896         if(limit)
1897                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1898
1899         return GetWinningCode(
1900                 WinningConditionHelper_topscore && limitreached,
1901                 WinningConditionHelper_equality
1902         );
1903 }
1904
1905 float WinningCondition_Race(float fraglimit)
1906 {
1907         float wc;
1908         entity p;
1909         float n, c;
1910
1911         n = 0;
1912         c = 0;
1913         FOR_EACH_PLAYER(p)
1914         {
1915                 ++n;
1916                 if(p.race_completed)
1917                         ++c;
1918         }
1919         if(n && (n == c))
1920                 return WINNING_YES;
1921         wc = WinningCondition_Scores(fraglimit, 0);
1922
1923         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1924         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1925         // do NOT support equality when the laps are all raced!
1926                 return WINNING_STARTSUDDENDEATHOVERTIME;
1927         else
1928                 return WINNING_NEVER;
1929 }
1930
1931 float WinningCondition_QualifyingThenRace(float limit)
1932 {
1933         float wc;
1934         wc = WinningCondition_Scores(limit, 0);
1935
1936         // NEVER initiate overtime
1937         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1938         {
1939                 return WINNING_YES;
1940         }
1941
1942         return wc;
1943 }
1944
1945 float WinningCondition_RanOutOfSpawns()
1946 {
1947         entity head;
1948
1949         if(have_team_spawns <= 0)
1950                 return WINNING_NO;
1951
1952         if(autocvar_g_spawn_useallspawns <= 0)
1953                 return WINNING_NO;
1954
1955         if(!some_spawn_has_been_used)
1956                 return WINNING_NO;
1957
1958         team1_score = team2_score = team3_score = team4_score = 0;
1959
1960         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1961         {
1962                 if(head.team == NUM_TEAM_1)
1963                         team1_score = 1;
1964                 else if(head.team == NUM_TEAM_2)
1965                         team2_score = 1;
1966                 else if(head.team == NUM_TEAM_3)
1967                         team3_score = 1;
1968                 else if(head.team == NUM_TEAM_4)
1969                         team4_score = 1;
1970         }
1971
1972         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1973         {
1974                 if(head.team == NUM_TEAM_1)
1975                         team1_score = 1;
1976                 else if(head.team == NUM_TEAM_2)
1977                         team2_score = 1;
1978                 else if(head.team == NUM_TEAM_3)
1979                         team3_score = 1;
1980                 else if(head.team == NUM_TEAM_4)
1981                         team4_score = 1;
1982         }
1983
1984         ClearWinners();
1985         if(team1_score + team2_score + team3_score + team4_score == 0)
1986         {
1987                 checkrules_equality = TRUE;
1988                 return WINNING_YES;
1989         }
1990         else if(team1_score + team2_score + team3_score + team4_score == 1)
1991         {
1992                 float t, i;
1993                 if(team1_score)
1994                         t = NUM_TEAM_1;
1995                 else if(team2_score)
1996                         t = NUM_TEAM_2;
1997                 else if(team3_score)
1998                         t = NUM_TEAM_3;
1999                 else // if(team4_score)
2000                         t = NUM_TEAM_4;
2001                 CheckAllowedTeams(world);
2002                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2003                 {
2004                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2005                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2006                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2007                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2008                 }
2009
2010                 AddWinners(team, t);
2011                 return WINNING_YES;
2012         }
2013         else
2014                 return WINNING_NO;
2015 }
2016
2017 /*
2018 ============
2019 CheckRules_World
2020
2021 Exit deathmatch games upon conditions
2022 ============
2023 */
2024 void ReadyRestart();
2025 void CheckRules_World()
2026 {
2027         float timelimit;
2028         float fraglimit;
2029         float leadlimit;
2030
2031         VoteThink();
2032         MapVote_Think();
2033
2034         SetDefaultAlpha();
2035
2036         /*
2037         MapVote_Think should now do that part
2038         if (intermission_running)
2039                 if (time >= intermission_exittime + 60)
2040                 {
2041                         if(!DoNextMapOverride())
2042                                 GotoNextMap();
2043                         return;
2044                 }
2045         */
2046
2047         if (gameover)   // someone else quit the game already
2048         {
2049                 if(player_count == 0) // Nobody there? Then let's go to the next map
2050                         MapVote_Start();
2051                         // this will actually check the player count in the next frame
2052                         // again, but this shouldn't hurt
2053                 return;
2054         }
2055
2056         timelimit = autocvar_timelimit * 60;
2057         fraglimit = autocvar_fraglimit;
2058         leadlimit = autocvar_leadlimit;
2059
2060         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2061         {
2062                 if(timelimit > 0)
2063                         timelimit = 0; // timelimit is not made for warmup
2064                 if(fraglimit > 0)
2065                         fraglimit = 0; // no fraglimit for now
2066                 leadlimit = 0; // no leadlimit for now
2067         }
2068
2069         if(timelimit > 0)
2070         {
2071                 timelimit += game_starttime;
2072         }
2073         else if (timelimit < 0)
2074         {
2075                 // endmatch
2076                 NextLevel();
2077                 return;
2078         }
2079
2080         if(g_onslaught)
2081                 timelimit = 0; // ONS has its own overtime rule
2082
2083         float wantovertime;
2084         wantovertime = 0;
2085
2086         if(timelimit > game_starttime)
2087                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2088         else
2089                 game_completion_ratio = 0;
2090
2091         if(checkrules_suddendeathend)
2092         {
2093                 if(!checkrules_suddendeathwarning)
2094                 {
2095                         checkrules_suddendeathwarning = TRUE;
2096                         if(g_race && !g_race_qualifying)
2097                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2098                         else
2099                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2100                 }
2101         }
2102         else
2103         {
2104                 if (timelimit && time >= timelimit)
2105                 {
2106                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2107                         {
2108                                 float totalplayers;
2109                                 float playerswithlaps;
2110                                 float readyplayers;
2111                                 entity head;
2112                                 totalplayers = playerswithlaps = readyplayers = 0;
2113                                 FOR_EACH_PLAYER(head)
2114                                 {
2115                                         ++totalplayers;
2116                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2117                                                 ++playerswithlaps;
2118                                         if(head.ready)
2119                                                 ++readyplayers;
2120                                 }
2121
2122                                 // at least 2 of the players have completed a lap: start the RACE
2123                                 // otherwise, the players should end the qualifying on their own
2124                                 if(readyplayers || playerswithlaps >= 2)
2125                                 {
2126                                         checkrules_suddendeathend = 0;
2127                                         ReadyRestart(); // go to race
2128                                         return;
2129                                 }
2130                                 else
2131                                         wantovertime |= InitiateSuddenDeath();
2132                         }
2133                         else
2134                                 wantovertime |= InitiateSuddenDeath();
2135                 }
2136         }
2137
2138         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2139         {
2140                 NextLevel();
2141                 return;
2142         }
2143
2144         float checkrules_status;
2145         checkrules_status = WinningCondition_RanOutOfSpawns();
2146         if(checkrules_status == WINNING_YES)
2147         {
2148                 bprint("Hey! Someone ran out of spawns!\n");
2149         }
2150         else if(g_race && !g_race_qualifying && timelimit >= 0)
2151         {
2152                 checkrules_status = WinningCondition_Race(fraglimit);
2153                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2154         }
2155         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2156         {
2157                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2158                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2159         }
2160         else if(g_assault)
2161         {
2162                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2163         }
2164         else if(g_lms)
2165         {
2166                 checkrules_status = WinningCondition_LMS();
2167         }
2168         else if (g_onslaught)
2169         {
2170                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2171         }
2172         else
2173         {
2174                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2175                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2176         }
2177
2178         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2179         {
2180                 checkrules_status = WINNING_NEVER;
2181                 checkrules_overtimesadded = -1;
2182                 wantovertime |= InitiateSuddenDeath();
2183         }
2184
2185         if(checkrules_status == WINNING_NEVER)
2186                 // equality cases! Nobody wins if the overtime ends in a draw.
2187                 ClearWinners();
2188
2189         if(wantovertime)
2190         {
2191                 if(checkrules_status == WINNING_NEVER)
2192                         InitiateOvertime();
2193                 else
2194                         checkrules_status = WINNING_YES;
2195         }
2196
2197         if(checkrules_suddendeathend)
2198                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2199                         checkrules_status = WINNING_YES;
2200
2201         if(checkrules_status == WINNING_YES)
2202         {
2203                 //print("WINNING\n");
2204                 NextLevel();
2205         }
2206 }
2207
2208 float mapvote_nextthink;
2209 float mapvote_initialized;
2210 float mapvote_keeptwotime;
2211 float mapvote_timeout;
2212 string mapvote_message;
2213 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2214 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2215 float mapvote_screenshot_dirs_count;
2216
2217 float mapvote_count;
2218 float mapvote_count_real;
2219 string mapvote_maps[MAPVOTE_COUNT];
2220 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2221 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2222 float mapvote_maps_suggested[MAPVOTE_COUNT];
2223 string mapvote_suggestions[MAPVOTE_COUNT];
2224 float mapvote_suggestion_ptr;
2225 float mapvote_voters;
2226 float mapvote_selections[MAPVOTE_COUNT];
2227 float mapvote_run;
2228 float mapvote_detail;
2229 float mapvote_abstain;
2230 .float mapvote;
2231
2232 void MapVote_ClearAllVotes()
2233 {
2234         FOR_EACH_CLIENT(other)
2235                 other.mapvote = 0;
2236 }
2237
2238 string MapVote_Suggest(string m)
2239 {
2240         float i;
2241         if(m == "")
2242                 return "That's not how to use this command.";
2243         if(!autocvar_g_maplist_votable_suggestions)
2244                 return "Suggestions are not accepted on this server.";
2245         if(mapvote_initialized)
2246                 return "Can't suggest - voting is already in progress!";
2247         m = MapInfo_FixName(m);
2248         if (!m)
2249                 return "The map you suggested is not available on this server.";
2250         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2251                 if(Map_IsRecent(m))
2252                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2253
2254         if(!MapInfo_CheckMap(m))
2255                 return "The map you suggested does not support the current game mode.";
2256         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2257                 if(mapvote_suggestions[i] == m)
2258                         return "This map was already suggested.";
2259         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2260         {
2261                 i = floor(random() * mapvote_suggestion_ptr);
2262         }
2263         else
2264         {
2265                 i = mapvote_suggestion_ptr;
2266                 mapvote_suggestion_ptr += 1;
2267         }
2268         if(mapvote_suggestions[i] != "")
2269                 strunzone(mapvote_suggestions[i]);
2270         mapvote_suggestions[i] = strzone(m);
2271         if(autocvar_sv_eventlog)
2272                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2273         return strcat("Suggestion of ", m, " accepted.");
2274 }
2275
2276 void MapVote_AddVotable(string nextMap, float isSuggestion)
2277 {
2278         float j, i, o;
2279         string pakfile, mapfile;
2280
2281         if(nextMap == "")
2282                 return;
2283         for(j = 0; j < mapvote_count; ++j)
2284                 if(mapvote_maps[j] == nextMap)
2285                         return;
2286         // suggestions might be no longer valid/allowed after gametype switch!
2287         if(isSuggestion)
2288                 if(!MapInfo_CheckMap(nextMap))
2289                         return;
2290         mapvote_maps[mapvote_count] = strzone(nextMap);
2291         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2292
2293         pakfile = string_null;
2294         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2295         {
2296                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2297                 pakfile = whichpack(strcat(mapfile, ".tga"));
2298                 if(pakfile == "")
2299                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2300                 if(pakfile == "")
2301                         pakfile = whichpack(strcat(mapfile, ".png"));
2302                 if(pakfile != "")
2303                         break;
2304         }
2305         if(i >= mapvote_screenshot_dirs_count)
2306                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2307         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2308                 pakfile = substring(pakfile, o, -1);
2309
2310         mapvote_maps_screenshot_dir[mapvote_count] = i;
2311         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2312
2313         mapvote_count += 1;
2314 }
2315
2316 void MapVote_Spawn();
2317 void MapVote_Init()
2318 {
2319         float i;
2320         float nmax, smax;
2321
2322         MapVote_ClearAllVotes();
2323
2324         mapvote_count = 0;
2325         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2326         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2327
2328         if(mapvote_abstain)
2329                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2330         else
2331                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2332         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2333
2334         // we need this for AddVotable, as that cycles through the screenshot dirs
2335         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2336         if(mapvote_screenshot_dirs_count == 0)
2337                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2338         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2339         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2340                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2341
2342         if(mapvote_suggestion_ptr)
2343                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2344                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2345
2346         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2347                 MapVote_AddVotable(GetNextMap(), FALSE);
2348
2349         if(mapvote_count == 0)
2350         {
2351                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2352                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2353                 if(autocvar_g_maplist_shuffle)
2354                         ShuffleMaplist();
2355                 localcmd("\nmenu_cmd sync\n");
2356                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2357                         MapVote_AddVotable(GetNextMap(), FALSE);
2358         }
2359
2360         mapvote_count_real = mapvote_count;
2361         if(mapvote_abstain)
2362                 MapVote_AddVotable("don't care", 0);
2363
2364         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2365
2366         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2367         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2368         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2369                 mapvote_keeptwotime = 0;
2370         mapvote_message = "Choose a map and press its key!";
2371
2372         MapVote_Spawn();
2373 }
2374
2375 void MapVote_SendPicture(float id)
2376 {
2377         msg_entity = self;
2378         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2379         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2380         WriteByte(MSG_ONE, id);
2381         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2382 }
2383
2384 float MapVote_GetMapMask()
2385 {
2386         float mask, i, power;
2387         mask = 0;
2388         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2389                 if(mapvote_maps[i] != "")
2390                         mask |= power;
2391         return mask;
2392 }
2393
2394 entity mapvote_ent;
2395 float MapVote_SendEntity(entity to, float sf)
2396 {
2397         float i;
2398
2399         if(sf & 1)
2400                 sf &= ~2; // if we send 1, we don't need to also send 2
2401
2402         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2403         WriteByte(MSG_ENTITY, sf);
2404
2405         if(sf & 1)
2406         {
2407                 // flag 1 == initialization
2408                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2409                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2410                 WriteString(MSG_ENTITY, "");
2411                 WriteByte(MSG_ENTITY, mapvote_count);
2412                 WriteByte(MSG_ENTITY, mapvote_abstain);
2413                 WriteByte(MSG_ENTITY, mapvote_detail);
2414                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2415                 if(mapvote_count <= 8)
2416                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2417                 else
2418                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2419                 for(i = 0; i < mapvote_count; ++i)
2420                         if(mapvote_maps[i] != "")
2421                         {
2422                                 if(mapvote_abstain && i == mapvote_count - 1)
2423                                 {
2424                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2425                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2426                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2427                                 }
2428                                 else
2429                                 {
2430                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2431                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2432                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2433                                 }
2434                         }
2435         }
2436
2437         if(sf & 2)
2438         {
2439                 // flag 2 == update of mask
2440                 if(mapvote_count <= 8)
2441                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2442                 else
2443                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2444         }
2445
2446         if(sf & 4)
2447         {
2448                 if(mapvote_detail)
2449                         for(i = 0; i < mapvote_count; ++i)
2450                                 if(mapvote_maps[i] != "")
2451                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2452
2453                 WriteByte(MSG_ENTITY, to.mapvote);
2454         }
2455
2456         return TRUE;
2457 }
2458
2459 void MapVote_Spawn()
2460 {
2461         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2462 }
2463
2464 void MapVote_TouchMask()
2465 {
2466         mapvote_ent.SendFlags |= 2;
2467 }
2468
2469 void MapVote_TouchVotes(entity voter)
2470 {
2471         mapvote_ent.SendFlags |= 4;
2472 }
2473
2474 float MapVote_Finished(float mappos)
2475 {
2476         string result;
2477         float i;
2478         float didntvote;
2479
2480         if(autocvar_sv_eventlog)
2481         {
2482                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2483                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2484                 didntvote = mapvote_voters;
2485                 for(i = 0; i < mapvote_count; ++i)
2486                         if(mapvote_maps[i] != "")
2487                         {
2488                                 didntvote -= mapvote_selections[i];
2489                                 if(i != mappos)
2490                                 {
2491                                         result = strcat(result, ":", mapvote_maps[i]);
2492                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2493                                 }
2494                         }
2495                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2496
2497                 GameLogEcho(result);
2498                 if(mapvote_maps_suggested[mappos])
2499                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2500         }
2501
2502         FOR_EACH_REALCLIENT(other)
2503                 FixClientCvars(other);
2504
2505         Map_Goto_SetStr(mapvote_maps[mappos]);
2506         Map_Goto(0);
2507         alreadychangedlevel = TRUE;
2508         return TRUE;
2509 }
2510 void MapVote_CheckRules_1()
2511 {
2512         float i;
2513
2514         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2515         {
2516                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2517                 mapvote_selections[i] = 0;
2518         }
2519
2520         mapvote_voters = 0;
2521         FOR_EACH_REALCLIENT(other)
2522         {
2523                 ++mapvote_voters;
2524                 if(other.mapvote)
2525                 {
2526                         i = other.mapvote - 1;
2527                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2528                         mapvote_selections[i] = mapvote_selections[i] + 1;
2529                 }
2530         }
2531 }
2532
2533 float MapVote_CheckRules_2()
2534 {
2535         float i;
2536         float firstPlace, secondPlace;
2537         float firstPlaceVotes, secondPlaceVotes;
2538         float mapvote_voters_real;
2539         string result;
2540
2541         if(mapvote_count_real == 1)
2542                 return MapVote_Finished(0);
2543
2544         mapvote_voters_real = mapvote_voters;
2545         if(mapvote_abstain)
2546                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2547
2548         RandomSelection_Init();
2549         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2550                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2551         firstPlace = RandomSelection_chosen_float;
2552         firstPlaceVotes = RandomSelection_best_priority;
2553         //dprint("First place: ", ftos(firstPlace), "\n");
2554         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2555
2556         RandomSelection_Init();
2557         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2558                 if(i != firstPlace)
2559                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2560         secondPlace = RandomSelection_chosen_float;
2561         secondPlaceVotes = RandomSelection_best_priority;
2562         //dprint("Second place: ", ftos(secondPlace), "\n");
2563         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2564
2565         if(firstPlace == -1)
2566                 error("No first place in map vote... WTF?");
2567
2568         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2569                 return MapVote_Finished(firstPlace);
2570
2571         if(mapvote_keeptwotime)
2572                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2573                 {
2574                         float didntvote;
2575                         MapVote_TouchMask();
2576                         mapvote_message = "Now decide between the TOP TWO!";
2577                         mapvote_keeptwotime = 0;
2578                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2579                         result = strcat(result, ":", ftos(firstPlaceVotes));
2580                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2581                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2582                         didntvote = mapvote_voters;
2583                         for(i = 0; i < mapvote_count; ++i)
2584                                 if(mapvote_maps[i] != "")
2585                                 {
2586                                         didntvote -= mapvote_selections[i];
2587                                         if(i != firstPlace)
2588                                                 if(i != secondPlace)
2589                                                 {
2590                                                         result = strcat(result, ":", mapvote_maps[i]);
2591                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2592                                                         if(i < mapvote_count_real)
2593                                                         {
2594                                                                 strunzone(mapvote_maps[i]);
2595                                                                 mapvote_maps[i] = "";
2596                                                                 strunzone(mapvote_maps_pakfile[i]);
2597                                                                 mapvote_maps_pakfile[i] = "";
2598                                                         }
2599                                                 }
2600                                 }
2601                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2602                         if(autocvar_sv_eventlog)
2603                                 GameLogEcho(result);
2604                 }
2605
2606         return FALSE;
2607 }
2608 void MapVote_Tick()
2609 {
2610         float keeptwo;
2611         float totalvotes;
2612
2613         keeptwo = mapvote_keeptwotime;
2614         MapVote_CheckRules_1(); // count
2615         if(MapVote_CheckRules_2()) // decide
2616                 return;
2617
2618         totalvotes = 0;
2619         FOR_EACH_REALCLIENT(other)
2620         {
2621                 // hide scoreboard again
2622                 if(other.health != 2342)
2623                 {
2624                         other.health = 2342;
2625                         other.impulse = 0;
2626                         if(IS_REAL_CLIENT(other))
2627                         {
2628                                 msg_entity = other;
2629                                 WriteByte(MSG_ONE, SVC_FINALE);
2630                                 WriteString(MSG_ONE, "");
2631                         }
2632                 }
2633
2634                 // clear possibly invalid votes
2635                 if(mapvote_maps[other.mapvote - 1] == "")
2636                         other.mapvote = 0;
2637                 // use impulses as new vote
2638                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2639                         if(mapvote_maps[other.impulse - 1] != "")
2640                         {
2641                                 other.mapvote = other.impulse;
2642                                 MapVote_TouchVotes(other);
2643                         }
2644                 other.impulse = 0;
2645
2646                 if(other.mapvote)
2647                         ++totalvotes;
2648         }
2649
2650         MapVote_CheckRules_1(); // just count
2651 }
2652 void MapVote_Start()
2653 {
2654         if(mapvote_run)
2655                 return;
2656
2657         // wait for stats to be sent first
2658         if(!playerstats_waitforme)
2659                 return;
2660
2661         MapInfo_Enumerate();
2662         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2663                 mapvote_run = TRUE;
2664 }
2665 void MapVote_Think()
2666 {
2667         if(!mapvote_run)
2668                 return;
2669
2670         if(alreadychangedlevel)
2671                 return;
2672
2673         if(time < mapvote_nextthink)
2674                 return;
2675         //dprint("tick\n");
2676
2677         mapvote_nextthink = time + 0.5;
2678
2679         if(!mapvote_initialized)
2680         {
2681                 if(autocvar_rescan_pending == 1)
2682                 {
2683                         cvar_set("rescan_pending", "2");
2684                         localcmd("fs_rescan\nrescan_pending 3\n");
2685                         return;
2686                 }
2687                 else if(autocvar_rescan_pending == 2)
2688                 {
2689                         return;
2690                 }
2691                 else if(autocvar_rescan_pending == 3)
2692                 {
2693                         // now build missing mapinfo files
2694                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2695                                 return;
2696
2697                         // we're done, start the timer
2698                         cvar_set("rescan_pending", "0");
2699                 }
2700
2701                 mapvote_initialized = TRUE;
2702                 if(DoNextMapOverride(0))
2703                         return;
2704                 if(!autocvar_g_maplist_votable || player_count <= 0)
2705                 {
2706                         GotoNextMap(0);
2707                         return;
2708                 }
2709                 MapVote_Init();
2710         }
2711
2712         MapVote_Tick();
2713 }
2714
2715 string GotoMap(string m)
2716 {
2717         if(!MapInfo_CheckMap(m))
2718                 return "The map you chose is not available on this server.";
2719         cvar_set("nextmap", m);
2720         cvar_set("timelimit", "-1");
2721         if(mapvote_initialized || alreadychangedlevel)
2722         {
2723                 if(DoNextMapOverride(0))
2724                         return "Map switch initiated.";
2725                 else
2726                         return "Hm... no. For some reason I like THIS map more.";
2727         }
2728         else
2729                 return "Map switch will happen after scoreboard.";
2730 }
2731
2732
2733 void EndFrame()
2734 {
2735         float altime;
2736         FOR_EACH_REALCLIENT(self)
2737         {
2738                 if(IS_SPEC(self))
2739                 {
2740                         if(self.enemy.typehitsound)
2741                                 self.typehit_time = time;
2742                         else if(self.enemy.hitsound)
2743                                 self.hit_time = time;
2744                 }
2745                 else
2746                 {
2747                         if(self.typehitsound)
2748                                 self.typehit_time = time;
2749                         else if(self.hitsound)
2750                                 self.hit_time = time;
2751                 }
2752         }
2753         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2754         // add 1 frametime because after this, engine SV_Physics
2755         // increases time by a frametime and then networks the frame
2756         // add another frametime because client shows everything with
2757         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2758         // needed!
2759         FOR_EACH_CLIENT(self)
2760         {
2761                 self.hitsound = FALSE;
2762                 self.typehitsound = FALSE;
2763                 antilag_record(self, altime);
2764         }
2765 }
2766
2767
2768 /*
2769  * RedirectionThink:
2770  * returns TRUE if redirecting
2771  */
2772 float redirection_timeout;
2773 float redirection_nextthink;
2774 float RedirectionThink()
2775 {
2776         float clients_found;
2777
2778         if(redirection_target == "")
2779                 return FALSE;
2780
2781         if(!redirection_timeout)
2782         {
2783                 cvar_set("sv_public", "-2");
2784                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2785                 if(redirection_target == "self")
2786                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2787                 else
2788                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2789         }
2790
2791         if(time < redirection_nextthink)
2792                 return TRUE;
2793
2794         redirection_nextthink = time + 1;
2795
2796         clients_found = 0;
2797         FOR_EACH_REALCLIENT(self)
2798         {
2799                 // TODO add timer
2800                 print("Redirecting: sending connect command to ", self.netname, "\n");
2801                 if(redirection_target == "self")
2802                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2803                 else
2804                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2805                 ++clients_found;
2806         }
2807
2808         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2809
2810         if(time > redirection_timeout || clients_found == 0)
2811                 localcmd("\nwait; wait; wait; quit\n");
2812
2813         return TRUE;
2814 }
2815
2816 void TargetMusic_RestoreGame();
2817 void RestoreGame()
2818 {
2819         // Loaded from a save game
2820         // some things then break, so let's work around them...
2821
2822         // Progs DB (capture records)
2823         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2824
2825         // Mapinfo
2826         MapInfo_Shutdown();
2827         MapInfo_Enumerate();
2828         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2829         WeaponStats_Init();
2830
2831         TargetMusic_RestoreGame();
2832 }
2833
2834 void Shutdown()
2835 {
2836         entity e;
2837
2838         gameover = 2;
2839
2840         if(world_initialized > 0)
2841         {
2842                 world_initialized = 0;
2843                 print("Saving persistent data...\n");
2844                 Ban_SaveBans();
2845
2846                 PlayerStats_EndMatch(0);
2847                 FOR_EACH_CLIENT(e)
2848                         PlayerStats_AddGlobalInfo(e);
2849                 PlayerStats_Shutdown();
2850
2851                 if(!cheatcount_total)
2852                 {
2853                         if(autocvar_sv_db_saveasdump)
2854                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2855                         else
2856                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2857                 }
2858                 if(autocvar_developer)
2859                 {
2860                         if(autocvar_sv_db_saveasdump)
2861                                 db_dump(TemporaryDB, "server-temp.db");
2862                         else
2863                                 db_save(TemporaryDB, "server-temp.db");
2864                 }
2865                 CheatShutdown(); // must be after cheatcount check
2866                 db_close(ServerProgsDB);
2867                 db_close(TemporaryDB);
2868                 print("done!\n");
2869                 // tell the bot system the game is ending now
2870                 bot_endgame();
2871
2872                 WeaponStats_Shutdown();
2873                 MapInfo_Shutdown();
2874         }
2875         else if(world_initialized == 0)
2876         {
2877                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2878         }
2879 }