qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include <server/mutators/_mod.qh>
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "scores_rules.qh"
  20 #include "teamplay.qh"
  21 #include "weapons/weaponstats.qh"
  22 #include "../common/constants.qh"
  23 #include <common/net_linked.qh>
  24 #include "../common/deathtypes/all.qh"
  25 #include "../common/gamemodes/sv_rules.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/_mod.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/vehicles/all.qh"
  30 #include "../common/notifications/all.qh"
  31 #include "../common/physics/player.qh"
  32 #include "../common/playerstats.qh"
  33 #include "../common/stats.qh"
  34 #include "../common/teams.qh"
  35 #include "../common/mapobjects/trigger/secret.qh"
  36 #include "../common/mapobjects/target/music.qh"
  37 #include "../common/util.qh"
  38 #include "../common/items/_mod.qh"
  39 #include <common/weapons/_all.qh>
  40 #include "../common/state.qh"
  41
  42 const float LATENCY_THINKRATE = 10;
  43 .float latency_sum;
  44 .float latency_cnt;
  45 .float latency_time;
  46 entity pingplreport;
  47 void PingPLReport_Think(entity this)
  48 {
  49         float delta;
  50         entity e;
  51
  52         delta = 3 / maxclients;
  53         if(delta < sys_frametime)
  54                 delta = 0;
  55         this.nextthink = time + delta;
  56
  57         e = edict_num(this.cnt + 1);
  58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  59         {
  60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  61                 WriteByte(MSG_BROADCAST, this.cnt);
  62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  65
  66                 // record latency times for clients throughout the match so we can report it to playerstats
  67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  68                 {
  69                         CS(e).latency_sum += CS(e).ping;
  70                         CS(e).latency_cnt += 1;
  71                         CS(e).latency_time = time;
  72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  73                 }
  74         }
  75         else
  76         {
  77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  78                 WriteByte(MSG_BROADCAST, this.cnt);
  79                 WriteShort(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82         }
  83         this.cnt = (this.cnt + 1) % maxclients;
  84 }
  85 void PingPLReport_Spawn()
  86 {
  87         pingplreport = new_pure(pingplreport);
  88         setthink(pingplreport, PingPLReport_Think);
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         strfree(cvar_changes);
 148         strfree(cvar_purechanges);
 149         cvar_purechanges_count = 0;
 150
 151         h = buf_create();
 152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 153         n = buf_getsize(h);
 154
 155         adding = true;
 156         pureadding = true;
 157
 158         for(i = 0; i < n; ++i)
 159         {
 160                 k = bufstr_get(h, i);
 161
 162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 164 #define BADCVAR(p) if(k == p) continue
 165
 166                 // general excludes and namespaces for server admin used cvars
 167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 168
 169                 // internal
 170                 BADPREFIX("csqc_");
 171                 BADPREFIX("cvar_check_");
 172                 BADCVAR("gamecfg");
 173                 BADCVAR("g_configversion");
 174                 BADCVAR("halflifebsp");
 175                 BADCVAR("sv_mapformat_is_quake2");
 176                 BADCVAR("sv_mapformat_is_quake3");
 177                 BADPREFIX("sv_world");
 178
 179                 // client
 180                 BADPREFIX("chase_");
 181                 BADPREFIX("cl_");
 182                 BADPREFIX("con_");
 183                 BADPREFIX("scoreboard_");
 184                 BADPREFIX("g_campaign");
 185                 BADPREFIX("g_waypointsprite_");
 186                 BADPREFIX("gl_");
 187                 BADPREFIX("joy");
 188                 BADPREFIX("hud_");
 189                 BADPREFIX("m_");
 190                 BADPREFIX("menu_");
 191                 BADPREFIX("net_slist_");
 192                 BADPREFIX("r_");
 193                 BADPREFIX("sbar_");
 194                 BADPREFIX("scr_");
 195                 BADPREFIX("snd_");
 196                 BADPREFIX("show");
 197                 BADPREFIX("sensitivity");
 198                 BADPREFIX("userbind");
 199                 BADPREFIX("v_");
 200                 BADPREFIX("vid_");
 201                 BADPREFIX("crosshair");
 202                 BADCVAR("mod_q3bsp_lightmapmergepower");
 203                 BADCVAR("mod_q3bsp_nolightmaps");
 204                 BADCVAR("fov");
 205                 BADCVAR("mastervolume");
 206                 BADCVAR("volume");
 207                 BADCVAR("bgmvolume");
 208                 BADCVAR("in_pitch_min");
 209                 BADCVAR("in_pitch_max");
 210
 211                 // private
 212                 BADCVAR("developer");
 213                 BADCVAR("log_dest_udp");
 214                 BADCVAR("net_address");
 215                 BADCVAR("net_address_ipv6");
 216                 BADCVAR("port");
 217                 BADCVAR("savedgamecfg");
 218                 BADCVAR("serverconfig");
 219                 BADCVAR("sv_autoscreenshot");
 220                 BADCVAR("sv_heartbeatperiod");
 221                 BADCVAR("sv_vote_master_password");
 222                 BADCVAR("sys_colortranslation");
 223                 BADCVAR("sys_specialcharactertranslation");
 224                 BADCVAR("timeformat");
 225                 BADCVAR("timestamps");
 226                 BADCVAR("g_require_stats");
 227                 BADPREFIX("developer_");
 228                 BADPREFIX("g_ban_");
 229                 BADPREFIX("g_banned_list");
 230                 BADPREFIX("g_require_stats_");
 231                 BADPREFIX("g_chat_flood_");
 232                 BADPREFIX("g_ghost_items");
 233                 BADPREFIX("g_playerstats_");
 234                 BADPREFIX("g_voice_flood_");
 235                 BADPREFIX("log_file");
 236                 BADPREFIX("quit_");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250                 BADCVAR("sv_muteban_list");
 251                 BADCVAR("sv_voteban_list");
 252                 BADCVAR("sv_allow_customplayermodels_idlist");
 253                 BADCVAR("sv_allow_customplayermodels_speciallist");
 254
 255                 // mapinfo
 256                 BADCVAR("fraglimit");
 257                 BADCVAR("g_arena");
 258                 BADCVAR("g_assault");
 259                 BADCVAR("g_ca");
 260                 BADCVAR("g_ca_teams");
 261                 BADCVAR("g_conquest");
 262                 BADCVAR("g_ctf");
 263                 BADCVAR("g_cts");
 264                 BADCVAR("g_dotc");
 265                 BADCVAR("g_dm");
 266                 BADCVAR("g_domination");
 267                 BADCVAR("g_domination_default_teams");
 268                 BADCVAR("g_duel");
 269                 BADCVAR("g_duel_not_dm_maps");
 270                 BADCVAR("g_freezetag");
 271                 BADCVAR("g_freezetag_teams");
 272                 BADCVAR("g_invasion_teams");
 273                 BADCVAR("g_invasion_type");
 274                 BADCVAR("g_jailbreak");
 275                 BADCVAR("g_jailbreak_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_laps_limit");
 284                 BADCVAR("g_race_qualifying_timelimit");
 285                 BADCVAR("g_race_qualifying_timelimit_override");
 286                 BADCVAR("g_runematch");
 287                 BADCVAR("g_shootfromeye");
 288                 BADCVAR("g_snafu");
 289                 BADCVAR("g_tdm");
 290                 BADCVAR("g_tdm_on_dm_maps");
 291                 BADCVAR("g_tdm_teams");
 292                 BADCVAR("g_vip");
 293                 BADCVAR("leadlimit");
 294                 BADCVAR("nextmap");
 295                 BADCVAR("teamplay");
 296                 BADCVAR("timelimit");
 297                 BADCVAR("g_mapinfo_ignore_warnings");
 298                 BADCVAR("g_maplist_ignore_sizes");
 299                 BADCVAR("g_maplist_sizes_count_bots");
 300
 301                 // long
 302                 BADCVAR("hostname");
 303                 BADCVAR("g_maplist");
 304                 BADCVAR("g_maplist_mostrecent");
 305                 BADCVAR("sv_motd");
 306
 307                 v = cvar_string(k);
 308                 d = cvar_defstring(k);
 309                 if(v == d)
 310                         continue;
 311
 312                 if(adding)
 313                 {
 314                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 315                         if(strlen(cvar_changes) > 16384)
 316                         {
 317                                 cvar_changes = "// too many settings have been changed to show them here\n";
 318                                 adding = 0;
 319                         }
 320                 }
 321
 322                 // now check if the changes are actually gameplay relevant
 323
 324                 // does nothing gameplay relevant
 325                 BADCVAR("captureleadlimit_override");
 326                 BADCVAR("condump_stripcolors");
 327                 BADCVAR("gameversion");
 328                 BADCVAR("fs_gamedir");
 329                 BADCVAR("g_allow_oldvortexbeam");
 330                 BADCVAR("g_balance_kill_delay");
 331                 BADCVAR("g_buffs_pickup_anyway");
 332                 BADCVAR("g_buffs_randomize");
 333                 BADCVAR("g_buffs_randomize_teamplay");
 334                 BADCVAR("g_campcheck_distance");
 335                 BADCVAR("g_ca_point_leadlimit");
 336                 BADCVAR("g_ca_point_limit");
 337                 BADCVAR("g_ctf_captimerecord_always");
 338                 BADCVAR("g_ctf_flag_glowtrails");
 339                 BADCVAR("g_ctf_dynamiclights");
 340                 BADCVAR("g_ctf_flag_pickup_verbosename");
 341                 BADCVAR("g_domination_point_leadlimit");
 342                 BADCVAR("g_forced_respawn");
 343                 BADCVAR("g_freezetag_point_leadlimit");
 344                 BADCVAR("g_freezetag_point_limit");
 345                 BADCVAR("g_hats");
 346                 BADCVAR("g_invasion_point_limit");
 347                 BADCVAR("g_jump_grunt");
 348                 BADCVAR("g_keyhunt_point_leadlimit");
 349                 BADCVAR("g_nexball_goalleadlimit");
 350                 BADCVAR("g_new_toys_autoreplace");
 351                 BADCVAR("g_new_toys_use_pickupsound");
 352                 BADCVAR("g_physics_predictall");
 353                 BADCVAR("g_piggyback");
 354                 BADCVAR("g_playerclip_collisions");
 355                 BADCVAR("g_spawn_alloweffects");
 356                 BADCVAR("g_tdm_point_leadlimit");
 357                 BADCVAR("g_tdm_point_limit");
 358                 BADCVAR("leadlimit_and_fraglimit");
 359                 BADCVAR("leadlimit_override");
 360                 BADCVAR("pausable");
 361                 BADCVAR("sv_checkforpacketsduringsleep");
 362                 BADCVAR("sv_damagetext");
 363                 BADCVAR("sv_db_saveasdump");
 364                 BADCVAR("sv_intermission_cdtrack");
 365                 BADCVAR("sv_mapchange_delay");
 366                 BADCVAR("sv_minigames");
 367                 BADCVAR("sv_namechangetimer");
 368                 BADCVAR("sv_precacheplayermodels");
 369                 BADCVAR("sv_stepheight");
 370                 BADCVAR("sv_timeout");
 371                 BADCVAR("sv_weapons_modeloverride");
 372                 BADCVAR("w_prop_interval");
 373                 BADPREFIX("crypto_");
 374                 BADPREFIX("gameversion_");
 375                 BADPREFIX("g_chat_");
 376                 BADPREFIX("g_ctf_captimerecord_");
 377                 BADPREFIX("g_hats_");
 378                 BADPREFIX("g_maplist_");
 379                 BADPREFIX("g_mod_");
 380                 BADPREFIX("g_respawn_");
 381                 BADPREFIX("net_");
 382                 BADPREFIX("notification_");
 383                 BADPREFIX("prvm_");
 384                 BADPREFIX("skill_");
 385                 BADPREFIX("sv_allow_");
 386                 BADPREFIX("sv_cullentities_");
 387                 BADPREFIX("sv_maxidle_");
 388                 BADPREFIX("sv_minigames_");
 389                 BADPREFIX("sv_radio_");
 390                 BADPREFIX("sv_timeout_");
 391                 BADPREFIX("sv_vote_");
 392                 BADPREFIX("timelimit_");
 393
 394                 // allowed changes to server admins (please sync this to server.cfg)
 395                 // vi commands:
 396                 //   :/"impure"/,$d
 397                 //   :g!,^\/\/[^ /],d
 398                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 399                 //   :%!sort
 400                 // yes, this does contain some redundant stuff, don't really care
 401                 BADPREFIX("bot_ai_");
 402                 BADCVAR("bot_config_file");
 403                 BADCVAR("bot_number");
 404                 BADCVAR("bot_prefix");
 405                 BADCVAR("bot_suffix");
 406                 BADCVAR("capturelimit_override");
 407                 BADCVAR("fraglimit_override");
 408                 BADCVAR("gametype");
 409                 BADCVAR("g_antilag");
 410                 BADCVAR("g_balance_teams");
 411                 BADCVAR("g_balance_teams_prevent_imbalance");
 412                 BADCVAR("g_balance_teams_scorefactor");
 413                 BADCVAR("g_ban_sync_trusted_servers");
 414                 BADCVAR("g_ban_sync_uri");
 415                 BADCVAR("g_buffs");
 416                 BADCVAR("g_ca_teams_override");
 417                 BADCVAR("g_ctf_fullbrightflags");
 418                 BADCVAR("g_ctf_ignore_frags");
 419                 BADCVAR("g_ctf_leaderboard");
 420                 BADCVAR("g_domination_point_limit");
 421                 BADCVAR("g_domination_teams_override");
 422                 BADCVAR("g_freezetag_teams_override");
 423                 BADCVAR("g_friendlyfire");
 424                 BADCVAR("g_fullbrightitems");
 425                 BADCVAR("g_fullbrightplayers");
 426                 BADCVAR("g_keyhunt_point_limit");
 427                 BADCVAR("g_keyhunt_teams_override");
 428                 BADCVAR("g_lms_lives_override");
 429                 BADCVAR("g_maplist");
 430                 BADCVAR("g_maxplayers");
 431                 BADCVAR("g_mirrordamage");
 432                 BADCVAR("g_nexball_goallimit");
 433                 BADCVAR("g_norecoil");
 434                 BADCVAR("g_physics_clientselect");
 435                 BADCVAR("g_pinata");
 436                 BADCVAR("g_powerups");
 437                 BADCVAR("g_player_brightness");
 438                 BADCVAR("g_rocket_flying");
 439                 BADCVAR("g_rocket_flying_disabledelays");
 440                 BADCVAR("g_spawnshieldtime");
 441                 BADCVAR("g_start_delay");
 442                 BADCVAR("g_superspectate");
 443                 BADCVAR("g_tdm_teams_override");
 444                 BADCVAR("g_warmup");
 445                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 446                 BADCVAR("hostname");
 447                 BADCVAR("log_file");
 448                 BADCVAR("maxplayers");
 449                 BADCVAR("minplayers");
 450                 BADCVAR("minplayers_per_team");
 451                 BADCVAR("net_address");
 452                 BADCVAR("port");
 453                 BADCVAR("rcon_password");
 454                 BADCVAR("rcon_restricted_commands");
 455                 BADCVAR("rcon_restricted_password");
 456                 BADCVAR("skill");
 457                 BADCVAR("sv_adminnick");
 458                 BADCVAR("sv_autoscreenshot");
 459                 BADCVAR("sv_autotaunt");
 460                 BADCVAR("sv_curl_defaulturl");
 461                 BADCVAR("sv_defaultcharacter");
 462                 BADCVAR("sv_defaultcharacterskin");
 463                 BADCVAR("sv_defaultplayercolors");
 464                 BADCVAR("sv_defaultplayermodel");
 465                 BADCVAR("sv_defaultplayerskin");
 466                 BADCVAR("sv_maxidle");
 467                 BADCVAR("sv_maxrate");
 468                 BADCVAR("sv_motd");
 469                 BADCVAR("sv_public");
 470                 BADCVAR("sv_ready_restart");
 471                 BADCVAR("sv_status_privacy");
 472                 BADCVAR("sv_taunt");
 473                 BADCVAR("sv_vote_call");
 474                 BADCVAR("sv_vote_commands");
 475                 BADCVAR("sv_vote_majority_factor");
 476                 BADCVAR("sv_vote_master");
 477                 BADCVAR("sv_vote_master_commands");
 478                 BADCVAR("sv_vote_master_password");
 479                 BADCVAR("sv_vote_simple_majority_factor");
 480                 BADCVAR("teamplay_mode");
 481                 BADCVAR("timelimit_override");
 482                 BADPREFIX("g_warmup_");
 483                 BADPREFIX("sv_info_");
 484                 BADPREFIX("sv_ready_restart_");
 485
 486                 // mutators that announce themselves properly to the server browser
 487                 BADCVAR("g_instagib");
 488                 BADCVAR("g_new_toys");
 489                 BADCVAR("g_nix");
 490                 BADCVAR("g_grappling_hook");
 491                 BADCVAR("g_jetpack");
 492
 493                 // temporary for testing
 494                 // TODO remove before 0.8.3 release
 495                 BADCVAR("g_ca_weaponarena");
 496                 BADCVAR("g_freezetag_weaponarena");
 497                 BADCVAR("g_lms_weaponarena");
 498                 BADCVAR("g_ctf_stalemate_time");
 499
 500                 if(cvar_string("g_mod_balance") == "Testing")
 501                 {
 502                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
 503                         BADPREFIX("g_balance_");
 504                 }
 505
 506 #undef BADPRESUFFIX
 507 #undef BADPREFIX
 508 #undef BADCVAR
 509
 510                 if(pureadding)
 511                 {
 512                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 513                         if(strlen(cvar_purechanges) > 16384)
 514                         {
 515                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 516                                 pureadding = 0;
 517                         }
 518                 }
 519                 ++cvar_purechanges_count;
 520                 // WARNING: this variable is used for the server list
 521                 // NEVER dare to skip this code!
 522                 // Hacks to intentionally appearing as "pure server" even though you DO have
 523                 // modified settings may be punished by removal from the server list.
 524                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 525                 // though.
 526         }
 527         buf_del(h);
 528         if(cvar_changes == "")
 529                 cvar_changes = "// this server runs at default server settings\n";
 530         else
 531                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 532         cvar_changes = strzone(cvar_changes);
 533         if(cvar_purechanges == "")
 534                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 535         else
 536                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 537         cvar_purechanges = strzone(cvar_purechanges);
 538 }
 539
 540 entity randomseed;
 541 bool RandomSeed_Send(entity this, entity to, int sf)
 542 {
 543         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 544         WriteShort(MSG_ENTITY, this.cnt);
 545         return true;
 546 }
 547 void RandomSeed_Think(entity this)
 548 {
 549         this.cnt = bound(0, floor(random() * 65536), 65535);
 550         this.nextthink = time + 5;
 551
 552         this.SendFlags |= 1;
 553 }
 554 void RandomSeed_Spawn()
 555 {
 556         randomseed = new_pure(randomseed);
 557         setthink(randomseed, RandomSeed_Think);
 558         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 559
 560         getthink(randomseed)(randomseed); // sets random seed and nextthink
 561 }
 562
 563 spawnfunc(__init_dedicated_server)
 564 {
 565         // handler for _init/_init map (only for dedicated server initialization)
 566
 567         world_initialized = -1; // don't complain
 568         cvar = cvar_normal;
 569         cvar_string = cvar_string_normal;
 570         cvar_set = cvar_set_normal;
 571
 572         delete_fn = remove_unsafely;
 573
 574         entity e = spawn();
 575         setthink(e, GotoFirstMap);
 576         e.nextthink = time; // this is usually 1 at this point
 577
 578         e = new(info_player_deathmatch);  // safeguard against player joining
 579
 580     // assign reflectively to avoid "assignment to world" warning
 581     for (int i = 0, n = numentityfields(); i < n; ++i) {
 582         string k = entityfieldname(i);
 583         if (k == "classname") {
 584             // safeguard against various stuff ;)
 585             putentityfieldstring(i, this, "worldspawn");
 586             break;
 587         }
 588     }
 589
 590         // needs to be done so early because of the constants they create
 591         static_init();
 592         static_init_late();
 593         static_init_precache();
 594
 595         IL_PUSH(g_spawnpoints, e); // just incase
 596
 597         MapInfo_Enumerate();
 598         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 599 }
 600
 601 void __init_dedicated_server_shutdown() {
 602         MapInfo_Shutdown();
 603 }
 604
 605 STATIC_INIT_EARLY(maxclients)
 606 {
 607         maxclients = 0;
 608         for (entity head = nextent(NULL); head; head = nextent(head)) {
 609                 ++maxclients;
 610         }
 611 }
 612
 613 void default_delayedinit(entity this)
 614 {
 615         if(!scores_initialized)
 616                 ScoreRules_generic();
 617 }
 618
 619 void InitGameplayMode()
 620 {
 621         VoteReset();
 622
 623         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 624         get_mi_min_max(1);
 625         // assign reflectively to avoid "assignment to world" warning
 626         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 627             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 628             if (v) {
 629             putentityfieldstring(i, world, sprintf("%v", v));
 630             if (++done == 2) break;
 631         }
 632         }
 633         // currently, NetRadiant's limit is 131072 qu for each side
 634         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 635         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 636         // in case somebody makes extremely large maps
 637         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 638
 639         MapInfo_LoadMapSettings(mapname);
 640         GameRules_teams(false);
 641
 642         if (!cvar_value_issafe(world.fog))
 643         {
 644                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 645                 world.fog = string_null;
 646         }
 647         if(MapInfo_Map_fog != "")
 648         {
 649                 if(MapInfo_Map_fog == "none")
 650                         world.fog = string_null;
 651                 else
 652                         world.fog = strzone(MapInfo_Map_fog);
 653         }
 654         clientstuff = strzone(MapInfo_Map_clientstuff);
 655
 656         MapInfo_ClearTemps();
 657
 658         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 659
 660         cache_mutatormsg = strzone("");
 661         cache_lastmutatormsg = strzone("");
 662
 663         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 664 }
 665
 666 void Map_MarkAsRecent(string m);
 667 float world_already_spawned;
 668 spawnfunc(worldspawn)
 669 {
 670         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 671
 672         bool wantrestart = false;
 673         {
 674                 if (!server_is_dedicated)
 675                 {
 676                         // force unloading of server pk3 files when starting a listen server
 677                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 678                         // restore csqc_progname too
 679                         string expect = "csprogs.dat";
 680                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 681                         cvar_set_normal("csqc_progname", expect);
 682                 }
 683                 else
 684                 {
 685                         // Try to use versioned csprogs from pk3
 686                         // Only ever use versioned csprogs.dat files on dedicated servers;
 687                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 688                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 689                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 690                         string select = "csprogs.dat";
 691                         if (fexists(pk3csprogs)) select = pk3csprogs;
 692                         if (cvar_string_normal("csqc_progname") != select)
 693                         {
 694                                 cvar_set_normal("csqc_progname", select);
 695                                 wantrestart = true;
 696                         }
 697                         // Check for updates on startup
 698                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 699                         int sentinel = fopen("progs.txt", FILE_READ);
 700                         if (sentinel >= 0)
 701                         {
 702                                 string switchversion = fgets(sentinel);
 703                                 fclose(sentinel);
 704                                 if (switchversion != "" && switchversion != WATERMARK)
 705                                 {
 706                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 707                                         // if it doesn't exist, assume either:
 708                                         //   a) the current program was overwritten
 709                                         //   b) this is a client only update
 710                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 711                                         if (fexists(newprogs))
 712                                         {
 713                                                 cvar_set_normal("sv_progs", newprogs);
 714                                                 wantrestart = true;
 715                                         }
 716                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 717                                         if (fexists(newcsprogs))
 718                                         {
 719                                                 cvar_set_normal("csqc_progname", newcsprogs);
 720                                                 wantrestart = true;
 721                                         }
 722                                 }
 723                         }
 724                 }
 725                 if (wantrestart)
 726                 {
 727                         LOG_INFO("Restart requested");
 728                         changelevel(mapname);
 729                         // let initialization continue, shutdown depends on it
 730                 }
 731         }
 732
 733         cvar = cvar_normal;
 734         cvar_string = cvar_string_normal;
 735         cvar_set = cvar_set_normal;
 736
 737         if(world_already_spawned)
 738                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 739         world_already_spawned = true;
 740
 741         delete_fn = remove_safely; // during spawning, watch what you remove!
 742
 743         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 744
 745         // needs to be done so early because of the constants they create
 746         static_init();
 747
 748         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 749
 750         TemporaryDB = db_create();
 751
 752         // 0 normal
 753         lightstyle(0, "m");
 754
 755         // 1 FLICKER (first variety)
 756         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 757
 758         // 2 SLOW STRONG PULSE
 759         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 760
 761         // 3 CANDLE (first variety)
 762         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 763
 764         // 4 FAST STROBE
 765         lightstyle(4, "mamamamamama");
 766
 767         // 5 GENTLE PULSE 1
 768         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 769
 770         // 6 FLICKER (second variety)
 771         lightstyle(6, "nmonqnmomnmomomno");
 772
 773         // 7 CANDLE (second variety)
 774         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 775
 776         // 8 CANDLE (third variety)
 777         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 778
 779         // 9 SLOW STROBE (fourth variety)
 780         lightstyle(9, "aaaaaaaazzzzzzzz");
 781
 782         // 10 FLUORESCENT FLICKER
 783         lightstyle(10, "mmamammmmammamamaaamammma");
 784
 785         // 11 SLOW PULSE NOT FADE TO BLACK
 786         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 787
 788         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 789
 790         // 63 testing
 791         lightstyle(63, "a");
 792
 793         if(autocvar_g_campaign)
 794                 CampaignPreInit();
 795
 796         Map_MarkAsRecent(mapname);
 797
 798         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 799
 800         InitGameplayMode();
 801         static_init_late();
 802         static_init_precache();
 803         readlevelcvars();
 804         GrappleHookInit();
 805
 806         GameRules_limit_fallbacks();
 807
 808         if(warmup_limit == 0)
 809                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 810
 811         player_count = 0;
 812         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 813         if(bot_waypoints_for_items == 1)
 814                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 815                         bot_waypoints_for_items = 0;
 816
 817         WaypointSprite_Init();
 818
 819         GameLogInit(); // prepare everything
 820         // NOTE for matchid:
 821         // changing the logic generating it is okay. But:
 822         // it HAS to stay <= 64 chars
 823         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 824         if(autocvar_sv_eventlog)
 825         {
 826                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 827                 matchid = strzone(s);
 828
 829                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 830                 s = ":gameinfo:mutators:LIST";
 831
 832                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 833                 s = M_ARGV(0, string);
 834
 835                 // initialiation stuff, not good in the mutator system
 836                 if(!autocvar_g_use_ammunition)
 837                         s = strcat(s, ":no_use_ammunition");
 838
 839                 // initialiation stuff, not good in the mutator system
 840                 if(autocvar_g_pickup_items == 0)
 841                         s = strcat(s, ":no_pickup_items");
 842                 if(autocvar_g_pickup_items > 0)
 843                         s = strcat(s, ":pickup_items");
 844
 845                 // initialiation stuff, not good in the mutator system
 846                 if(autocvar_g_weaponarena != "0")
 847                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 848
 849                 // TODO to mutator system
 850                 if(autocvar_g_norecoil)
 851                         s = strcat(s, ":norecoil");
 852
 853                 // TODO to mutator system
 854                 if(autocvar_g_powerups == 0)
 855                         s = strcat(s, ":no_powerups");
 856                 if(autocvar_g_powerups > 0)
 857                         s = strcat(s, ":powerups");
 858
 859                 GameLogEcho(s);
 860                 GameLogEcho(":gameinfo:end");
 861         }
 862         else
 863                 matchid = strzone(ftos(random()));
 864
 865         cvar_set("nextmap", "");
 866
 867         SetDefaultAlpha();
 868
 869         if(autocvar_g_campaign)
 870                 CampaignPostInit();
 871
 872         Ban_LoadBans();
 873
 874         MapInfo_Enumerate();
 875         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 876
 877         if(fexists(strcat("scripts/", mapname, ".arena")))
 878                 cvar_settemp("sv_q3acompat_machineshotgunswap", "1");
 879
 880         if(fexists(strcat("scripts/", mapname, ".defi")))
 881                 cvar_settemp("sv_q3defragcompat", "1");
 882
 883         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 884         {
 885                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 886                 if(fd != -1)
 887                 {
 888                         string s;
 889                         while((s = fgets(fd)))
 890                         {
 891                                 int l = tokenize_console(s);
 892                                 if(l < 2)
 893                                         continue;
 894                                 if(argv(0) == "cd")
 895                                 {
 896                                         string trackname = argv(2);
 897                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 898                                         LOG_INFO("  cdtrack ", trackname);
 899                                         if (cvar_value_issafe(trackname))
 900                                         {
 901                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 902                                                 strcpy(clientstuff, newstuff);
 903                                         }
 904                                 }
 905                                 else if(argv(0) == "fog")
 906                                 {
 907                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 908                                         LOG_INFO("  \"fog\" \"", s, "\"");
 909                                 }
 910                                 else if(argv(0) == "set")
 911                                 {
 912                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 913                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 914                                 }
 915                                 else if(argv(0) != "//")
 916                                 {
 917                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 918                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 919                                 }
 920                         }
 921                         fclose(fd);
 922                 }
 923         }
 924
 925         WeaponStats_Init();
 926
 927         Nagger_Init();
 928
 929         next_pingtime = time + 5;
 930
 931         // set up information replies for clients and server to use
 932         maplist_reply = strzone(getmaplist());
 933         lsmaps_reply = strzone(getlsmaps());
 934         monsterlist_reply = strzone(getmonsterlist());
 935         for(int i = 0; i < 10; ++i)
 936         {
 937                 string s = getrecords(i);
 938                 if (s)
 939                         records_reply[i] = strzone(s);
 940         }
 941         ladder_reply = strzone(getladder());
 942         rankings_reply = strzone(getrankings());
 943
 944         // begin other init
 945         ClientInit_Spawn();
 946         RandomSeed_Spawn();
 947         PingPLReport_Spawn();
 948
 949         CheatInit();
 950
 951         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 952
 953         // fill sv_curl_serverpackages from .serverpackage files
 954         if (autocvar_sv_curl_serverpackages_auto)
 955         {
 956                 string s = "csprogs-" WATERMARK ".txt";
 957                 // remove automatically managed files from the list to prevent duplicates
 958                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 959                 {
 960                         string pkg = argv(i);
 961                         if (startsWith(pkg, "csprogs-")) continue;
 962                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 963                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 964                         s = cons(s, pkg);
 965                 }
 966                 // add automatically managed files to the list
 967                 #define X(match) MACRO_BEGIN \
 968                         int fd = search_begin(match, true, false); \
 969                         if (fd >= 0) \
 970                         { \
 971                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 972                                 { \
 973                                         s = cons(s, search_getfilename(fd, i)); \
 974                                 } \
 975                                 search_end(fd); \
 976                         } \
 977                 MACRO_END
 978                 X("*-serverpackage.txt");
 979                 X("*.serverpackage");
 980                 #undef X
 981                 cvar_set("sv_curl_serverpackages", s);
 982         }
 983
 984         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 985         modname = "Xonotic";
 986         // physics/balance/config changes that count as mod
 987         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 988                 modname = cvar_string("g_mod_physics");
 989         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
 990                 modname = cvar_string("g_mod_balance");
 991         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 992                 modname = cvar_string("g_mod_config");
 993         // extra mutators that deserve to count as mod
 994         MUTATOR_CALLHOOK(SetModname, modname);
 995         modname = M_ARGV(0, string);
 996
 997         // save it for later
 998         modname = strzone(modname);
 999
1000         WinningConditionHelper(this); // set worldstatus
1001
1002         world_initialized = 1;
1003         __spawnfunc_spawn_all();
1004 }
1005
1006 spawnfunc(light)
1007 {
1008         //makestatic (this); // Who the f___ did that?
1009         delete(this);
1010 }
1011
1012 string GetGametype()
1013 {
1014         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1015 }
1016
1017 string GetMapname()
1018 {
1019         return mapname;
1020 }
1021
1022 float Map_Count, Map_Current;
1023 string Map_Current_Name;
1024
1025 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1026 int GetMaplistPosition()
1027 {
1028         string map = GetMapname();
1029         int idx = autocvar_g_maplist_index;
1030
1031         if(idx >= 0)
1032         {
1033                 if(idx < Map_Count)
1034                 {
1035                         if(map == argv(idx))
1036                         {
1037                                 return idx;
1038                         }
1039                 }
1040         }
1041
1042         for(int pos = 0; pos < Map_Count; ++pos)
1043         {
1044                 if(map == argv(pos))
1045                         return pos;
1046         }
1047
1048         // resume normal maplist rotation if current map is not in g_maplist
1049         return idx;
1050 }
1051
1052 bool MapHasRightSize(string map)
1053 {
1054         int minplayers = max(0, floor(autocvar_minplayers));
1055         if (teamplay)
1056                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1057         if (autocvar_g_maplist_check_waypoints
1058                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1059         {
1060                 string checkwp_msg = strcat("checkwp ", map);
1061                 if(!fexists(strcat("maps/", map, ".waypoints")))
1062                 {
1063                         LOG_TRACE(checkwp_msg, ": no waypoints");
1064                         return false;
1065                 }
1066                 LOG_TRACE(checkwp_msg, ": has waypoints");
1067         }
1068
1069         if(autocvar_g_maplist_ignore_sizes)
1070                 return true;
1071
1072         // open map size restriction file
1073         string opensize_msg = strcat("opensize ", map);
1074         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1075         int pcount = player_count;
1076         if(!autocvar_g_maplist_sizes_count_bots)
1077                 pcount -= currentbots;
1078         if(fh >= 0)
1079         {
1080                 opensize_msg = strcat(opensize_msg, ": ok, ");
1081                 int mapmin = stoi(fgets(fh));
1082                 int mapmax = stoi(fgets(fh));
1083                 fclose(fh);
1084                 if(pcount < mapmin)
1085                 {
1086                         LOG_TRACE(opensize_msg, "not enough");
1087                         return false;
1088                 }
1089                 if(mapmax && pcount > mapmax)
1090                 {
1091                         LOG_TRACE(opensize_msg, "too many");
1092                         return false;
1093                 }
1094                 LOG_TRACE(opensize_msg, "right size");
1095                 return true;
1096         }
1097         LOG_TRACE(opensize_msg, ": not found");
1098         return true;
1099 }
1100
1101 string Map_Filename(float position)
1102 {
1103         return strcat("maps/", argv(position), ".bsp");
1104 }
1105
1106 void Map_MarkAsRecent(string m)
1107 {
1108         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1109 }
1110
1111 float Map_IsRecent(string m)
1112 {
1113         return strhasword(autocvar_g_maplist_mostrecent, m);
1114 }
1115
1116 float Map_Check(float position, float pass)
1117 {
1118         string filename;
1119         string map_next;
1120         map_next = argv(position);
1121         if(pass <= 1)
1122         {
1123                 if(Map_IsRecent(map_next))
1124                         return 0;
1125         }
1126         filename = Map_Filename(position);
1127         if(MapInfo_CheckMap(map_next))
1128         {
1129                 if(pass == 2)
1130                         return 1;
1131                 if(MapHasRightSize(map_next))
1132                         return 1;
1133                 return 0;
1134         }
1135         else
1136                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1137
1138         return 0;
1139 }
1140
1141 void Map_Goto_SetStr(string nextmapname)
1142 {
1143         if(getmapname_stored != "")
1144                 strunzone(getmapname_stored);
1145         if(nextmapname == "")
1146                 getmapname_stored = "";
1147         else
1148                 getmapname_stored = strzone(nextmapname);
1149 }
1150
1151 void Map_Goto_SetFloat(float position)
1152 {
1153         cvar_set("g_maplist_index", ftos(position));
1154         Map_Goto_SetStr(argv(position));
1155 }
1156
1157 void Map_Goto(float reinit)
1158 {
1159         MapInfo_LoadMap(getmapname_stored, reinit);
1160 }
1161
1162 // return codes of map selectors:
1163 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1164 //   -2 = permanent failure
1165 float MaplistMethod_Iterate() // usual method
1166 {
1167         float pass, i;
1168
1169         LOG_TRACE("Trying MaplistMethod_Iterate");
1170
1171         for(pass = 1; pass <= 2; ++pass)
1172         {
1173                 for(i = 1; i < Map_Count; ++i)
1174                 {
1175                         float mapindex;
1176                         mapindex = (i + Map_Current) % Map_Count;
1177                         if(Map_Check(mapindex, pass))
1178                                 return mapindex;
1179                 }
1180         }
1181         return -1;
1182 }
1183
1184 float MaplistMethod_Repeat() // fallback method
1185 {
1186         LOG_TRACE("Trying MaplistMethod_Repeat");
1187
1188         if(Map_Check(Map_Current, 2))
1189                 return Map_Current;
1190         return -2;
1191 }
1192
1193 float MaplistMethod_Random() // random map selection
1194 {
1195         float i, imax;
1196
1197         LOG_TRACE("Trying MaplistMethod_Random");
1198
1199         imax = 42;
1200
1201         for(i = 0; i <= imax; ++i)
1202         {
1203                 float mapindex;
1204                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1205                 if(Map_Check(mapindex, 1))
1206                         return mapindex;
1207         }
1208         return -1;
1209 }
1210
1211 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1212 // the exponent sets a bias on the map selection:
1213 // the higher the exponent, the less likely "shortly repeated" same maps are
1214 {
1215         float i, j, imax, insertpos;
1216
1217         LOG_TRACE("Trying MaplistMethod_Shuffle");
1218
1219         imax = 42;
1220
1221         for(i = 0; i <= imax; ++i)
1222         {
1223                 string newlist;
1224
1225                 // now reinsert this at another position
1226                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1227                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1228                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1229                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1230
1231                 // insert the current map there
1232                 newlist = "";
1233                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1234                         newlist = strcat(newlist, " ", argv(j));
1235                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1236                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1237                         newlist = strcat(newlist, " ", argv(j));
1238                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1239                 cvar_set("g_maplist", newlist);
1240                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1241
1242                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1243                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1244                 if(Map_Check(Map_Current, 1))
1245                         return Map_Current;
1246         }
1247         return -1;
1248 }
1249
1250 void Maplist_Init()
1251 {
1252         float i = Map_Count = 0;
1253         if(autocvar_g_maplist != "")
1254         {
1255                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1256                 for (i = 0; i < Map_Count; ++i)
1257                 {
1258                         if (Map_Check(i, 2))
1259                                 break;
1260                 }
1261         }
1262
1263         if (i == Map_Count)
1264         {
1265                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1266                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1267                 if(autocvar_g_maplist_shuffle)
1268                         ShuffleMaplist();
1269                 if(!server_is_dedicated)
1270                         localcmd("\nmenu_cmd sync\n");
1271                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1272         }
1273         if(Map_Count == 0)
1274                 error("empty maplist, cannot select a new map");
1275         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1276
1277         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1278         // this may or may not be correct, but who cares, in the worst case a map
1279         // isn't chosen in the first pass that should have been
1280 }
1281
1282 string GetNextMap()
1283 {
1284         Maplist_Init();
1285         float nextMap = -1;
1286
1287         if(nextMap == -1)
1288                 if(autocvar_g_maplist_shuffle > 0)
1289                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1290
1291         if(nextMap == -1)
1292                 if(autocvar_g_maplist_selectrandom)
1293                         nextMap = MaplistMethod_Random();
1294
1295         if(nextMap == -1)
1296                 nextMap = MaplistMethod_Iterate();
1297
1298         if(nextMap == -1)
1299                 nextMap = MaplistMethod_Repeat();
1300
1301         if(nextMap >= 0)
1302         {
1303                 Map_Goto_SetFloat(nextMap);
1304                 return getmapname_stored;
1305         }
1306
1307         return "";
1308 }
1309
1310 float DoNextMapOverride(float reinit)
1311 {
1312         if(autocvar_g_campaign)
1313         {
1314                 CampaignPostIntermission();
1315                 alreadychangedlevel = true;
1316                 return true;
1317         }
1318         if(autocvar_quit_when_empty)
1319         {
1320                 if(player_count <= currentbots)
1321                 {
1322                         localcmd("quit\n");
1323                         alreadychangedlevel = true;
1324                         return true;
1325                 }
1326         }
1327         if(autocvar_quit_and_redirect != "")
1328         {
1329                 redirection_target = strzone(autocvar_quit_and_redirect);
1330                 alreadychangedlevel = true;
1331                 return true;
1332         }
1333         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1334         {
1335                 localcmd("restart\n");
1336                 alreadychangedlevel = true;
1337                 return true;
1338         }
1339         if(autocvar_nextmap != "")
1340         {
1341                 string m;
1342                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1343                 cvar_set("nextmap",m);
1344
1345                 if(!m || gametypevote)
1346                         return false;
1347                 if(autocvar_sv_vote_gametype)
1348                 {
1349                         Map_Goto_SetStr(m);
1350                         return false;
1351                 }
1352
1353                 if(MapInfo_CheckMap(m))
1354                 {
1355                         Map_Goto_SetStr(m);
1356                         Map_Goto(reinit);
1357                         alreadychangedlevel = true;
1358                         return true;
1359                 }
1360         }
1361         if(!reinit && autocvar_lastlevel)
1362         {
1363                 cvar_settemp_restore();
1364                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1365                 alreadychangedlevel = true;
1366                 return true;
1367         }
1368         return false;
1369 }
1370
1371 void GotoNextMap(float reinit)
1372 {
1373         //string nextmap;
1374         //float n, nummaps;
1375         //string s;
1376         if (alreadychangedlevel)
1377                 return;
1378         alreadychangedlevel = true;
1379
1380         string nextMap = GetNextMap();
1381         if(nextMap == "")
1382                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1383         Map_Goto(reinit);
1384 }
1385
1386
1387 /*
1388 ============
1389 IntermissionThink
1390
1391 When the player presses attack or jump, change to the next level
1392 ============
1393 */
1394 .float autoscreenshot;
1395 void IntermissionThink(entity this)
1396 {
1397         FixIntermissionClient(this);
1398
1399         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1400         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1401
1402         if( (server_screenshot || client_screenshot)
1403                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1404         {
1405                 this.autoscreenshot = -1;
1406                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1407                 return;
1408         }
1409
1410         if (time < intermission_exittime)
1411                 return;
1412
1413         if(!mapvote_initialized)
1414                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1415                         return;
1416
1417         MapVote_Start();
1418 }
1419
1420 /*
1421 ===============================================================================
1422
1423 RULES
1424
1425 ===============================================================================
1426 */
1427
1428 void DumpStats(float final)
1429 {
1430         float file;
1431         string s;
1432         float to_console;
1433         float to_eventlog;
1434         float to_file;
1435         float i;
1436
1437         to_console = autocvar_sv_logscores_console;
1438         to_eventlog = autocvar_sv_eventlog;
1439         to_file = autocvar_sv_logscores_file;
1440
1441         if(!final)
1442         {
1443                 to_console = true; // always print printstats replies
1444                 to_eventlog = false; // but never print them to the event log
1445         }
1446
1447         if(to_eventlog)
1448                 if(autocvar_sv_eventlog_console)
1449                         to_console = false; // otherwise we get the output twice
1450
1451         if(final)
1452                 s = ":scores:";
1453         else
1454                 s = ":status:";
1455         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1456
1457         if(to_console)
1458                 LOG_INFO(s);
1459         if(to_eventlog)
1460                 GameLogEcho(s);
1461
1462         file = -1;
1463         if(to_file)
1464         {
1465                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1466                 if(file == -1)
1467                         to_file = false;
1468                 else
1469                         fputs(file, strcat(s, "\n"));
1470         }
1471
1472         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1473         if(to_console)
1474                 LOG_INFO(s);
1475         if(to_eventlog)
1476                 GameLogEcho(s);
1477         if(to_file)
1478                 fputs(file, strcat(s, "\n"));
1479
1480         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1481                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1482                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1483                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1484                         s = strcat(s, ftos(it.team), ":");
1485                 else
1486                         s = strcat(s, "spectator:");
1487
1488                 if(to_console)
1489                         LOG_INFO(s, playername(it, false));
1490                 if(to_eventlog)
1491                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1492                 if(to_file)
1493                         fputs(file, strcat(s, playername(it, false), "\n"));
1494         });
1495
1496         if(teamplay)
1497         {
1498                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1499                 if(to_console)
1500                         LOG_INFO(s);
1501                 if(to_eventlog)
1502                         GameLogEcho(s);
1503                 if(to_file)
1504                         fputs(file, strcat(s, "\n"));
1505
1506                 for(i = 1; i < 16; ++i)
1507                 {
1508                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1509                         s = strcat(s, ":", ftos(i));
1510                         if(to_console)
1511                                 LOG_INFO(s);
1512                         if(to_eventlog)
1513                                 GameLogEcho(s);
1514                         if(to_file)
1515                                 fputs(file, strcat(s, "\n"));
1516                 }
1517         }
1518
1519         if(to_console)
1520                 LOG_INFO(":end");
1521         if(to_eventlog)
1522                 GameLogEcho(":end");
1523         if(to_file)
1524         {
1525                 fputs(file, ":end\n");
1526                 fclose(file);
1527         }
1528 }
1529
1530 void FixIntermissionClient(entity e)
1531 {
1532         if(!e.autoscreenshot) // initial call
1533         {
1534                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1535                 SetResourceExplicit(e, RES_HEALTH, -2342);
1536                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1537                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1538                 {
1539                     .entity weaponentity = weaponentities[slot];
1540                         if(e.(weaponentity))
1541                         {
1542                                 e.(weaponentity).effects = EF_NODRAW;
1543                                 if (e.(weaponentity).weaponchild)
1544                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1545                         }
1546                 }
1547                 if(IS_REAL_CLIENT(e))
1548                 {
1549                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1550                         RandomSelection_Init();
1551                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1552                                 RandomSelection_AddString(it, 1, 1);
1553                         });
1554                         if (RandomSelection_chosen_string != "")
1555                         {
1556                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1557                         }
1558                         msg_entity = e;
1559                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1560                 }
1561         }
1562 }
1563
1564 /*
1565 go to the next level for deathmatch
1566 only called if a time or frag limit has expired
1567 */
1568 void NextLevel()
1569 {
1570         game_stopped = true;
1571         intermission_running = 1; // game over
1572
1573         // enforce a wait time before allowing changelevel
1574         if(player_count > 0)
1575                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1576         else
1577                 intermission_exittime = -1;
1578
1579         /*
1580         WriteByte (MSG_ALL, SVC_CDTRACK);
1581         WriteByte (MSG_ALL, 3);
1582         WriteByte (MSG_ALL, 3);
1583         // done in FixIntermission
1584         */
1585
1586         //pos = FindIntermission ();
1587
1588         VoteReset();
1589
1590         DumpStats(true);
1591
1592         // send statistics
1593         PlayerStats_GameReport(true);
1594         WeaponStats_Shutdown();
1595
1596         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1597
1598         if(autocvar_sv_eventlog)
1599                 GameLogEcho(":gameover");
1600
1601         GameLogClose();
1602
1603         FOREACH_CLIENT(IS_PLAYER(it), {
1604                 FixIntermissionClient(it);
1605                 if(it.winning)
1606                         bprint(playername(it, false), " ^7wins.\n");
1607         });
1608
1609         target_music_kill();
1610
1611         if(autocvar_g_campaign)
1612                 CampaignPreIntermission();
1613
1614         MUTATOR_CALLHOOK(MatchEnd);
1615
1616         localcmd("\nsv_hook_gameend\n");
1617 }
1618
1619
1620 float InitiateSuddenDeath()
1621 {
1622         // Check first whether normal overtimes could be added before initiating suddendeath mode
1623         // - for this timelimit_overtime needs to be >0 of course
1624         // - also check the winning condition calculated in the previous frame and only add normal overtime
1625         //   again, if at the point at which timelimit would be extended again, still no winner was found
1626         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1627                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1628                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1629         {
1630                 return 1; // need to call InitiateOvertime later
1631         }
1632         else
1633         {
1634                 if(!checkrules_suddendeathend)
1635                 {
1636                         if(autocvar_g_campaign)
1637                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1638                         else
1639                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1640                         if(g_race && !g_race_qualifying)
1641                                 race_StartCompleting();
1642                 }
1643                 return 0;
1644         }
1645 }
1646
1647 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1648 {
1649         ++checkrules_overtimesadded;
1650         //add one more overtime by simply extending the timelimit
1651         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1652         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1653 }
1654
1655 float GetWinningCode(float fraglimitreached, float equality)
1656 {
1657         if(autocvar_g_campaign == 1)
1658         {
1659                 if(fraglimitreached)
1660                         return WINNING_YES;
1661                 else
1662                         return WINNING_NO;
1663         }
1664         else
1665         {
1666                 if(equality)
1667                 {
1668                         if(fraglimitreached)
1669                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1670                         else
1671                                 return WINNING_NEVER;
1672                 }
1673                 else
1674                 {
1675                         if(fraglimitreached)
1676                                 return WINNING_YES;
1677                         else
1678                                 return WINNING_NO;
1679                 }
1680         }
1681 }
1682
1683 // set the .winning flag for exactly those players with a given field value
1684 void SetWinners(.float field, float value)
1685 {
1686         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1687 }
1688
1689 // set the .winning flag for those players with a given field value
1690 void AddWinners(.float field, float value)
1691 {
1692         FOREACH_CLIENT(IS_PLAYER(it), {
1693                 if(it.(field) == value)
1694                         it.winning = 1;
1695         });
1696 }
1697
1698 // clear the .winning flags
1699 void ClearWinners()
1700 {
1701         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1702 }
1703
1704 void ShuffleMaplist()
1705 {
1706         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1707 }
1708
1709 int fragsleft_last;
1710 float WinningCondition_Scores(float limit, float leadlimit)
1711 {
1712         // TODO make everything use THIS winning condition (except LMS)
1713         WinningConditionHelper(NULL);
1714
1715         if(teamplay)
1716         {
1717                 for (int i = 1; i < 5; ++i)
1718                 {
1719                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1720                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1721                 }
1722         }
1723
1724         ClearWinners();
1725         if(WinningConditionHelper_winner)
1726                 WinningConditionHelper_winner.winning = 1;
1727         if(WinningConditionHelper_winnerteam >= 0)
1728                 SetWinners(team, WinningConditionHelper_winnerteam);
1729
1730         if(WinningConditionHelper_lowerisbetter)
1731         {
1732                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1733                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1734                 limit = -limit;
1735         }
1736
1737         if(WinningConditionHelper_zeroisworst)
1738                 leadlimit = 0; // not supported in this mode
1739
1740         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1741         {
1742                 float fragsleft = FLOAT_MAX, leadingfragsleft = FLOAT_MAX;
1743                 if (limit)
1744                         fragsleft = limit - WinningConditionHelper_topscore;
1745                 if (leadlimit)
1746                         leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1747
1748                 if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1749                         fragsleft = max(fragsleft, leadingfragsleft);
1750                 else
1751                         fragsleft = min(fragsleft, leadingfragsleft);
1752
1753                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1754                 {
1755                         if (fragsleft == 1)
1756                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1757                         else if (fragsleft == 2)
1758                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1759                         else if (fragsleft == 3)
1760                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1761
1762                         fragsleft_last = fragsleft;
1763                 }
1764         }
1765
1766         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1767         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1768
1769         bool limit_reached;
1770         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1771         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1772                 limit_reached = (fraglimit_reached && leadlimit_reached);
1773         else
1774                 limit_reached = (fraglimit_reached || leadlimit_reached);
1775
1776         return GetWinningCode(
1777                 WinningConditionHelper_topscore && limit_reached,
1778                 WinningConditionHelper_equality
1779         );
1780 }
1781
1782 float WinningCondition_RanOutOfSpawns()
1783 {
1784         if(have_team_spawns <= 0)
1785                 return WINNING_NO;
1786
1787         if(!autocvar_g_spawn_useallspawns)
1788                 return WINNING_NO;
1789
1790         if(!some_spawn_has_been_used)
1791                 return WINNING_NO;
1792
1793         for (int i = 1; i < 5; ++i)
1794         {
1795                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1796         }
1797
1798         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1799         {
1800                 if (Team_IsValidTeam(it.team))
1801                 {
1802                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1803                 }
1804         });
1805
1806         IL_EACH(g_spawnpoints, true,
1807         {
1808                 if (Team_IsValidTeam(it.team))
1809                 {
1810                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1811                 }
1812         });
1813
1814         ClearWinners();
1815         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1816         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1817         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1818         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1819         if(team1_score + team2_score + team3_score + team4_score == 0)
1820         {
1821                 checkrules_equality = true;
1822                 return WINNING_YES;
1823         }
1824         else if(team1_score + team2_score + team3_score + team4_score == 1)
1825         {
1826                 float t, i;
1827                 if(team1_score)
1828                         t = 1;
1829                 else if(team2_score)
1830                         t = 2;
1831                 else if(team3_score)
1832                         t = 3;
1833                 else // if(team4_score)
1834                         t = 4;
1835                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1836                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1837                 {
1838                         for (int j = 1; j <= NUM_TEAMS; ++j)
1839                         {
1840                                 if (t == j)
1841                                 {
1842                                         continue;
1843                                 }
1844                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1845                                 {
1846                                         continue;
1847                                 }
1848                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1849                         }
1850                 }
1851
1852                 AddWinners(team, t);
1853                 return WINNING_YES;
1854         }
1855         else
1856                 return WINNING_NO;
1857 }
1858
1859 /*
1860 ============
1861 CheckRules_World
1862
1863 Exit deathmatch games upon conditions
1864 ============
1865 */
1866 void CheckRules_World()
1867 {
1868         VoteThink();
1869         MapVote_Think();
1870
1871         SetDefaultAlpha();
1872
1873         if (intermission_running) // someone else quit the game already
1874         {
1875                 if(player_count == 0) // Nobody there? Then let's go to the next map
1876                         MapVote_Start();
1877                         // this will actually check the player count in the next frame
1878                         // again, but this shouldn't hurt
1879                 return;
1880         }
1881
1882         float timelimit = autocvar_timelimit * 60;
1883         float fraglimit = autocvar_fraglimit;
1884         float leadlimit = autocvar_leadlimit;
1885         if (leadlimit < 0) leadlimit = 0;
1886
1887         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1888         {
1889                 if(timelimit > 0)
1890                         timelimit = 0; // timelimit is not made for warmup
1891                 if(fraglimit > 0)
1892                         fraglimit = 0; // no fraglimit for now
1893                 leadlimit = 0; // no leadlimit for now
1894         }
1895
1896         if(timelimit > 0)
1897         {
1898                 timelimit += game_starttime;
1899         }
1900         else if (timelimit < 0)
1901         {
1902                 // endmatch
1903                 NextLevel();
1904                 return;
1905         }
1906
1907         float wantovertime;
1908         wantovertime = 0;
1909
1910         if(checkrules_suddendeathend)
1911         {
1912                 if(!checkrules_suddendeathwarning)
1913                 {
1914                         checkrules_suddendeathwarning = true;
1915                         if(g_race && !g_race_qualifying)
1916                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1917                         else
1918                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1919                 }
1920         }
1921         else
1922         {
1923                 if (timelimit && time >= timelimit)
1924                 {
1925                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1926                         {
1927                                 float totalplayers;
1928                                 float playerswithlaps;
1929                                 float readyplayers;
1930                                 totalplayers = playerswithlaps = readyplayers = 0;
1931                                 FOREACH_CLIENT(IS_PLAYER(it), {
1932                                         ++totalplayers;
1933                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1934                                                 ++playerswithlaps;
1935                                         if(it.ready)
1936                                                 ++readyplayers;
1937                                 });
1938
1939                                 // at least 2 of the players have completed a lap: start the RACE
1940                                 // otherwise, the players should end the qualifying on their own
1941                                 if(readyplayers || playerswithlaps >= 2)
1942                                 {
1943                                         checkrules_suddendeathend = 0;
1944                                         ReadyRestart(); // go to race
1945                                         return;
1946                                 }
1947                                 else
1948                                         wantovertime |= InitiateSuddenDeath();
1949                         }
1950                         else
1951                                 wantovertime |= InitiateSuddenDeath();
1952                 }
1953         }
1954
1955         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1956         {
1957                 NextLevel();
1958                 return;
1959         }
1960
1961         int checkrules_status = WinningCondition_RanOutOfSpawns();
1962         if(checkrules_status == WINNING_YES)
1963                 bprint("Hey! Someone ran out of spawns!\n");
1964         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1965                 checkrules_status = M_ARGV(0, float);
1966         else
1967                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1968
1969         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1970         {
1971                 checkrules_status = WINNING_NEVER;
1972                 checkrules_overtimesadded = -1;
1973                 wantovertime |= InitiateSuddenDeath();
1974         }
1975
1976         if(checkrules_status == WINNING_NEVER)
1977                 // equality cases! Nobody wins if the overtime ends in a draw.
1978                 ClearWinners();
1979
1980         if(wantovertime)
1981         {
1982                 if(checkrules_status == WINNING_NEVER)
1983                         InitiateOvertime();
1984                 else
1985                         checkrules_status = WINNING_YES;
1986         }
1987
1988         if(checkrules_suddendeathend)
1989                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1990                         checkrules_status = WINNING_YES;
1991
1992         if(checkrules_status == WINNING_YES)
1993         {
1994                 //print("WINNING\n");
1995                 NextLevel();
1996         }
1997 }
1998
1999 string GotoMap(string m)
2000 {
2001         m = GameTypeVote_MapInfo_FixName(m);
2002         if (!m)
2003                 return "The map you suggested is not available on this server.";
2004         if (!autocvar_sv_vote_gametype)
2005         if(!MapInfo_CheckMap(m))
2006                 return "The map you suggested does not support the current game mode.";
2007         cvar_set("nextmap", m);
2008         cvar_set("timelimit", "-1");
2009         if(mapvote_initialized || alreadychangedlevel)
2010         {
2011                 if(DoNextMapOverride(0))
2012                         return "Map switch initiated.";
2013                 else
2014                         return "Hm... no. For some reason I like THIS map more.";
2015         }
2016         else
2017                 return "Map switch will happen after scoreboard.";
2018 }
2019
2020 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2021 void RunThink(entity this)
2022 {
2023         // don't let things stay in the past.
2024         // it is possible to start that way by a trigger with a local time.
2025         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2026                 return;
2027
2028         float oldtime = time; // do we need to save this?
2029
2030         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2031         {
2032                 time = max(oldtime, this.nextthink);
2033                 this.nextthink = 0;
2034
2035                 if(getthink(this))
2036                         getthink(this)(this);
2037                 // mods often set nextthink to time to cause a think every frame,
2038                 // we don't want to loop in that case, so exit if the new nextthink is
2039                 // <= the time the qc was told, also exit if it is past the end of the
2040                 // frame
2041                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2042                         break;
2043         }
2044
2045         time = oldtime;
2046 }
2047
2048 bool autocvar_sv_freezenonclients;
2049 bool autocvar_sv_gameplayfix_delayprojectiles = false;
2050 void Physics_Frame()
2051 {
2052         if(autocvar_sv_freezenonclients)
2053                 return;
2054
2055         IL_EACH(g_moveables, true,
2056         {
2057                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2058                         continue;
2059
2060                 //set_movetype(it, it.move_movetype);
2061                 // inline the set_movetype function, since this is called a lot
2062                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2063
2064                 if(it.move_movetype == MOVETYPE_NONE)
2065                         continue;
2066
2067                 if(it.move_qcphysics)
2068                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2069
2070                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2071                 {
2072                         // handle thinking here
2073                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2074                                 RunThink(it);
2075                 }
2076         });
2077
2078         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2079                 return;
2080
2081         IL_EACH(g_moveables, it.move_qcphysics,
2082         {
2083                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2084                         continue;
2085                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2086         });
2087 }
2088
2089 void systems_update();
2090 void EndFrame()
2091 {
2092         anticheat_endframe();
2093
2094         Physics_Frame();
2095
2096         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2097                 entity e = IS_SPEC(it) ? it.enemy : it;
2098                 if (e.typehitsound) {
2099                         STAT(TYPEHIT_TIME, it) = time;
2100                 } else if (e.killsound) {
2101                         STAT(KILL_TIME, it) = time;
2102                 } else if (e.damage_dealt) {
2103                         STAT(HIT_TIME, it) = time;
2104                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2105                 }
2106         });
2107         // add 1 frametime because after this, engine SV_Physics
2108         // increases time by a frametime and then networks the frame
2109         // add another frametime because client shows everything with
2110         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2111         // needed!
2112         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2113         FOREACH_CLIENT(true, {
2114                 it.typehitsound = false;
2115                 it.damage_dealt = 0;
2116                 it.killsound = false;
2117                 antilag_record(it, CS(it), altime);
2118         });
2119         IL_EACH(g_monsters, true,
2120         {
2121                 antilag_record(it, it, altime);
2122         });
2123         IL_EACH(g_projectiles, it.classname == "nade",
2124         {
2125                 antilag_record(it, it, altime);
2126         });
2127         systems_update();
2128         IL_ENDFRAME();
2129 }
2130
2131
2132 /*
2133  * RedirectionThink:
2134  * returns true if redirecting
2135  */
2136 float redirection_timeout;
2137 float redirection_nextthink;
2138 float RedirectionThink()
2139 {
2140         float clients_found;
2141
2142         if(redirection_target == "")
2143                 return false;
2144
2145         if(!redirection_timeout)
2146         {
2147                 cvar_set("sv_public", "-2");
2148                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2149                 if(redirection_target == "self")
2150                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2151                 else
2152                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2153         }
2154
2155         if(time < redirection_nextthink)
2156                 return true;
2157
2158         redirection_nextthink = time + 1;
2159
2160         clients_found = 0;
2161         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2162                 // TODO add timer
2163                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2164                 if(redirection_target == "self")
2165                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2166                 else
2167                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2168                 ++clients_found;
2169         });
2170
2171         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2172
2173         if(time > redirection_timeout || clients_found == 0)
2174                 localcmd("\nwait; wait; wait; quit\n");
2175
2176         return true;
2177 }
2178
2179 void RestoreGame()
2180 {
2181         // Loaded from a save game
2182         // some things then break, so let's work around them...
2183
2184         // Progs DB (capture records)
2185         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2186
2187         // Mapinfo
2188         MapInfo_Shutdown();
2189         MapInfo_Enumerate();
2190         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2191         WeaponStats_Init();
2192
2193         TargetMusic_RestoreGame();
2194 }
2195
2196 void Shutdown()
2197 {
2198         game_stopped = 2;
2199
2200         if(world_initialized > 0)
2201         {
2202                 world_initialized = 0;
2203                 LOG_TRACE("Saving persistent data...");
2204                 Ban_SaveBans();
2205
2206                 // playerstats with unfinished match
2207                 PlayerStats_GameReport(false);
2208
2209                 if(!cheatcount_total)
2210                 {
2211                         if(autocvar_sv_db_saveasdump)
2212                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2213                         else
2214                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2215                 }
2216                 if(autocvar_developer > 0)
2217                 {
2218                         if(autocvar_sv_db_saveasdump)
2219                                 db_dump(TemporaryDB, "server-temp.db");
2220                         else
2221                                 db_save(TemporaryDB, "server-temp.db");
2222                 }
2223                 CheatShutdown(); // must be after cheatcount check
2224                 db_close(ServerProgsDB);
2225                 db_close(TemporaryDB);
2226                 LOG_TRACE("Saving persistent data... done!");
2227                 // tell the bot system the game is ending now
2228                 bot_endgame();
2229
2230                 WeaponStats_Shutdown();
2231                 MapInfo_Shutdown();
2232         }
2233         else if(world_initialized == 0)
2234         {
2235                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2236         }
2237         else
2238         {
2239                 __init_dedicated_server_shutdown();
2240         }
2241 }