Update hash
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_world.qc
1 #include "g_world.qh"
2
3 #include "anticheat.qh"
4 #include "antilag.qh"
5 #include "bot/api.qh"
6 #include "campaign.qh"
7 #include "cheats.qh"
8 #include "client.qh"
9 #include "command/common.qh"
10 #include "command/getreplies.qh"
11 #include "command/sv_cmd.qh"
12 #include "command/vote.qh"
13 #include "g_hook.qh"
14 #include "ipban.qh"
15 #include "mapvoting.qh"
16 #include <server/mutators/_mod.qh>
17 #include "race.qh"
18 #include "scores.qh"
19 #include "scores_rules.qh"
20 #include "teamplay.qh"
21 #include "weapons/weaponstats.qh"
22 #include "../common/constants.qh"
23 #include <common/net_linked.qh>
24 #include "../common/deathtypes/all.qh"
25 #include "../common/gamemodes/sv_rules.qh"
26 #include "../common/mapinfo.qh"
27 #include "../common/monsters/_mod.qh"
28 #include "../common/monsters/sv_monsters.qh"
29 #include "../common/vehicles/all.qh"
30 #include "../common/notifications/all.qh"
31 #include "../common/physics/player.qh"
32 #include "../common/playerstats.qh"
33 #include "../common/stats.qh"
34 #include "../common/teams.qh"
35 #include "../common/mapobjects/trigger/secret.qh"
36 #include "../common/mapobjects/target/music.qh"
37 #include "../common/util.qh"
38 #include "../common/items/_mod.qh"
39 #include <common/weapons/_all.qh>
40 #include "../common/state.qh"
41
42 const float LATENCY_THINKRATE = 10;
43 .float latency_sum;
44 .float latency_cnt;
45 .float latency_time;
46 entity pingplreport;
47 void PingPLReport_Think(entity this)
48 {
49         float delta;
50         entity e;
51
52         delta = 3 / maxclients;
53         if(delta < sys_frametime)
54                 delta = 0;
55         this.nextthink = time + delta;
56
57         e = edict_num(this.cnt + 1);
58         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
59         {
60                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
61                 WriteByte(MSG_BROADCAST, this.cnt);
62                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
65
66                 // record latency times for clients throughout the match so we can report it to playerstats
67                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
68                 {
69                         CS(e).latency_sum += CS(e).ping;
70                         CS(e).latency_cnt += 1;
71                         CS(e).latency_time = time;
72                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
73                 }
74         }
75         else
76         {
77                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
78                 WriteByte(MSG_BROADCAST, this.cnt);
79                 WriteShort(MSG_BROADCAST, 0);
80                 WriteByte(MSG_BROADCAST, 0);
81                 WriteByte(MSG_BROADCAST, 0);
82         }
83         this.cnt = (this.cnt + 1) % maxclients;
84 }
85 void PingPLReport_Spawn()
86 {
87         pingplreport = new_pure(pingplreport);
88         setthink(pingplreport, PingPLReport_Think);
89         pingplreport.nextthink = time;
90 }
91
92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
93 string redirection_target;
94 float world_initialized;
95
96 void SetDefaultAlpha()
97 {
98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
99         {
100                 default_player_alpha = autocvar_g_player_alpha;
101                 if(default_player_alpha == 0)
102                         default_player_alpha = 1;
103                 default_weapon_alpha = default_player_alpha;
104         }
105 }
106
107 void GotoFirstMap(entity this)
108 {
109         float n;
110         if(autocvar__sv_init)
111         {
112                 // cvar_set("_sv_init", "0");
113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
114                 // to this "init" map on a dedicated server will cause no permanent
115                 // harm
116                 if(autocvar_g_maplist_shuffle)
117                         ShuffleMaplist();
118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
120
121                 MapInfo_Enumerate();
122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
123
124                 if(!DoNextMapOverride(1))
125                         GotoNextMap(1);
126
127                 return;
128         }
129
130         if(time < 5)
131         {
132                 this.nextthink = time;
133         }
134         else
135         {
136                 this.nextthink = time + 1;
137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
138         }
139 }
140
141 void cvar_changes_init()
142 {
143         float h;
144         string k, v, d;
145         float n, i, adding, pureadding;
146
147         strfree(cvar_changes);
148         strfree(cvar_purechanges);
149         cvar_purechanges_count = 0;
150
151         h = buf_create();
152         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
153         n = buf_getsize(h);
154
155         adding = true;
156         pureadding = true;
157
158         for(i = 0; i < n; ++i)
159         {
160                 k = bufstr_get(h, i);
161
162 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
163 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
164 #define BADCVAR(p) if(k == p) continue
165
166                 // general excludes and namespaces for server admin used cvars
167                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
168
169                 // internal
170                 BADPREFIX("csqc_");
171                 BADPREFIX("cvar_check_");
172                 BADCVAR("gamecfg");
173                 BADCVAR("g_configversion");
174                 BADCVAR("halflifebsp");
175                 BADCVAR("sv_mapformat_is_quake2");
176                 BADCVAR("sv_mapformat_is_quake3");
177                 BADPREFIX("sv_world");
178
179                 // client
180                 BADPREFIX("chase_");
181                 BADPREFIX("cl_");
182                 BADPREFIX("con_");
183                 BADPREFIX("scoreboard_");
184                 BADPREFIX("g_campaign");
185                 BADPREFIX("g_waypointsprite_");
186                 BADPREFIX("gl_");
187                 BADPREFIX("joy");
188                 BADPREFIX("hud_");
189                 BADPREFIX("m_");
190                 BADPREFIX("menu_");
191                 BADPREFIX("net_slist_");
192                 BADPREFIX("r_");
193                 BADPREFIX("sbar_");
194                 BADPREFIX("scr_");
195                 BADPREFIX("snd_");
196                 BADPREFIX("show");
197                 BADPREFIX("sensitivity");
198                 BADPREFIX("userbind");
199                 BADPREFIX("v_");
200                 BADPREFIX("vid_");
201                 BADPREFIX("crosshair");
202                 BADCVAR("mod_q3bsp_lightmapmergepower");
203                 BADCVAR("mod_q3bsp_nolightmaps");
204                 BADCVAR("fov");
205                 BADCVAR("mastervolume");
206                 BADCVAR("volume");
207                 BADCVAR("bgmvolume");
208                 BADCVAR("in_pitch_min");
209                 BADCVAR("in_pitch_max");
210
211                 // private
212                 BADCVAR("developer");
213                 BADCVAR("log_dest_udp");
214                 BADCVAR("net_address");
215                 BADCVAR("net_address_ipv6");
216                 BADCVAR("port");
217                 BADCVAR("savedgamecfg");
218                 BADCVAR("serverconfig");
219                 BADCVAR("sv_autoscreenshot");
220                 BADCVAR("sv_heartbeatperiod");
221                 BADCVAR("sv_vote_master_password");
222                 BADCVAR("sys_colortranslation");
223                 BADCVAR("sys_specialcharactertranslation");
224                 BADCVAR("timeformat");
225                 BADCVAR("timestamps");
226                 BADCVAR("g_require_stats");
227                 BADPREFIX("developer_");
228                 BADPREFIX("g_ban_");
229                 BADPREFIX("g_banned_list");
230                 BADPREFIX("g_require_stats_");
231                 BADPREFIX("g_chat_flood_");
232                 BADPREFIX("g_ghost_items");
233                 BADPREFIX("g_playerstats_");
234                 BADPREFIX("g_voice_flood_");
235                 BADPREFIX("log_file");
236                 BADPREFIX("quit_");
237                 BADPREFIX("rcon_");
238                 BADPREFIX("sv_allowdownloads");
239                 BADPREFIX("sv_autodemo");
240                 BADPREFIX("sv_curl_");
241                 BADPREFIX("sv_eventlog");
242                 BADPREFIX("sv_logscores_");
243                 BADPREFIX("sv_master");
244                 BADPREFIX("sv_weaponstats_");
245                 BADPREFIX("sv_waypointsprite_");
246                 BADCVAR("rescan_pending");
247
248                 // these can contain player IDs, so better hide
249                 BADPREFIX("g_forced_team_");
250                 BADCVAR("sv_muteban_list");
251                 BADCVAR("sv_voteban_list");
252                 BADCVAR("sv_allow_customplayermodels_idlist");
253                 BADCVAR("sv_allow_customplayermodels_speciallist");
254
255                 // mapinfo
256                 BADCVAR("fraglimit");
257                 BADCVAR("g_arena");
258                 BADCVAR("g_assault");
259                 BADCVAR("g_ca");
260                 BADCVAR("g_ca_teams");
261                 BADCVAR("g_conquest");
262                 BADCVAR("g_ctf");
263                 BADCVAR("g_cts");
264                 BADCVAR("g_dotc");
265                 BADCVAR("g_dm");
266                 BADCVAR("g_domination");
267                 BADCVAR("g_domination_default_teams");
268                 BADCVAR("g_duel");
269                 BADCVAR("g_duel_not_dm_maps");
270                 BADCVAR("g_freezetag");
271                 BADCVAR("g_freezetag_teams");
272                 BADCVAR("g_invasion_teams");
273                 BADCVAR("g_invasion_type");
274                 BADCVAR("g_jailbreak");
275                 BADCVAR("g_jailbreak_teams");
276                 BADCVAR("g_keepaway");
277                 BADCVAR("g_keyhunt");
278                 BADCVAR("g_keyhunt_teams");
279                 BADCVAR("g_lms");
280                 BADCVAR("g_nexball");
281                 BADCVAR("g_onslaught");
282                 BADCVAR("g_race");
283                 BADCVAR("g_race_laps_limit");
284                 BADCVAR("g_race_qualifying_timelimit");
285                 BADCVAR("g_race_qualifying_timelimit_override");
286                 BADCVAR("g_runematch");
287                 BADCVAR("g_shootfromeye");
288                 BADCVAR("g_snafu");
289                 BADCVAR("g_tdm");
290                 BADCVAR("g_tdm_on_dm_maps");
291                 BADCVAR("g_tdm_teams");
292                 BADCVAR("g_vip");
293                 BADCVAR("leadlimit");
294                 BADCVAR("nextmap");
295                 BADCVAR("teamplay");
296                 BADCVAR("timelimit");
297                 BADCVAR("g_mapinfo_ignore_warnings");
298                 BADCVAR("g_maplist_ignore_sizes");
299                 BADCVAR("g_maplist_sizes_count_bots");
300
301                 // long
302                 BADCVAR("hostname");
303                 BADCVAR("g_maplist");
304                 BADCVAR("g_maplist_mostrecent");
305                 BADCVAR("sv_motd");
306
307                 v = cvar_string(k);
308                 d = cvar_defstring(k);
309                 if(v == d)
310                         continue;
311
312                 if(adding)
313                 {
314                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
315                         if(strlen(cvar_changes) > 16384)
316                         {
317                                 cvar_changes = "// too many settings have been changed to show them here\n";
318                                 adding = 0;
319                         }
320                 }
321
322                 // now check if the changes are actually gameplay relevant
323
324                 // does nothing gameplay relevant
325                 BADCVAR("captureleadlimit_override");
326                 BADCVAR("condump_stripcolors");
327                 BADCVAR("gameversion");
328                 BADCVAR("fs_gamedir");
329                 BADCVAR("g_allow_oldvortexbeam");
330                 BADCVAR("g_balance_kill_delay");
331                 BADCVAR("g_buffs_pickup_anyway");
332                 BADCVAR("g_buffs_randomize");
333                 BADCVAR("g_buffs_randomize_teamplay");
334                 BADCVAR("g_campcheck_distance");
335                 BADCVAR("g_ca_point_leadlimit");
336                 BADCVAR("g_ca_point_limit");
337                 BADCVAR("g_ctf_captimerecord_always");
338                 BADCVAR("g_ctf_flag_glowtrails");
339                 BADCVAR("g_ctf_dynamiclights");
340                 BADCVAR("g_ctf_flag_pickup_verbosename");
341                 BADCVAR("g_domination_point_leadlimit");
342                 BADCVAR("g_forced_respawn");
343                 BADCVAR("g_freezetag_point_leadlimit");
344                 BADCVAR("g_freezetag_point_limit");
345                 BADCVAR("g_hats");
346                 BADCVAR("g_invasion_point_limit");
347                 BADCVAR("g_jump_grunt");
348                 BADCVAR("g_keyhunt_point_leadlimit");
349                 BADCVAR("g_nexball_goalleadlimit");
350                 BADCVAR("g_new_toys_autoreplace");
351                 BADCVAR("g_new_toys_use_pickupsound");
352                 BADCVAR("g_physics_predictall");
353                 BADCVAR("g_piggyback");
354                 BADCVAR("g_playerclip_collisions");
355                 BADCVAR("g_spawn_alloweffects");
356                 BADCVAR("g_tdm_point_leadlimit");
357                 BADCVAR("g_tdm_point_limit");
358                 BADCVAR("leadlimit_and_fraglimit");
359                 BADCVAR("leadlimit_override");
360                 BADCVAR("pausable");
361                 BADCVAR("sv_checkforpacketsduringsleep");
362                 BADCVAR("sv_damagetext");
363                 BADCVAR("sv_db_saveasdump");
364                 BADCVAR("sv_intermission_cdtrack");
365                 BADCVAR("sv_mapchange_delay");
366                 BADCVAR("sv_minigames");
367                 BADCVAR("sv_namechangetimer");
368                 BADCVAR("sv_precacheplayermodels");
369                 BADCVAR("sv_stepheight");
370                 BADCVAR("sv_timeout");
371                 BADCVAR("sv_weapons_modeloverride");
372                 BADCVAR("w_prop_interval");
373                 BADPREFIX("crypto_");
374                 BADPREFIX("gameversion_");
375                 BADPREFIX("g_chat_");
376                 BADPREFIX("g_ctf_captimerecord_");
377                 BADPREFIX("g_hats_");
378                 BADPREFIX("g_maplist_");
379                 BADPREFIX("g_mod_");
380                 BADPREFIX("g_respawn_");
381                 BADPREFIX("net_");
382                 BADPREFIX("notification_");
383                 BADPREFIX("prvm_");
384                 BADPREFIX("skill_");
385                 BADPREFIX("sv_allow_");
386                 BADPREFIX("sv_cullentities_");
387                 BADPREFIX("sv_maxidle_");
388                 BADPREFIX("sv_minigames_");
389                 BADPREFIX("sv_radio_");
390                 BADPREFIX("sv_timeout_");
391                 BADPREFIX("sv_vote_");
392                 BADPREFIX("timelimit_");
393
394                 // allowed changes to server admins (please sync this to server.cfg)
395                 // vi commands:
396                 //   :/"impure"/,$d
397                 //   :g!,^\/\/[^ /],d
398                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
399                 //   :%!sort
400                 // yes, this does contain some redundant stuff, don't really care
401                 BADCVAR("bot_config_file");
402                 BADCVAR("bot_number");
403                 BADCVAR("bot_prefix");
404                 BADCVAR("bot_suffix");
405                 BADCVAR("capturelimit_override");
406                 BADCVAR("fraglimit_override");
407                 BADCVAR("gametype");
408                 BADCVAR("g_antilag");
409                 BADCVAR("g_balance_teams");
410                 BADCVAR("g_balance_teams_prevent_imbalance");
411                 BADCVAR("g_balance_teams_scorefactor");
412                 BADCVAR("g_ban_sync_trusted_servers");
413                 BADCVAR("g_ban_sync_uri");
414                 BADCVAR("g_buffs");
415                 BADCVAR("g_ca_teams_override");
416                 BADCVAR("g_ctf_fullbrightflags");
417                 BADCVAR("g_ctf_ignore_frags");
418                 BADCVAR("g_ctf_leaderboard");
419                 BADCVAR("g_domination_point_limit");
420                 BADCVAR("g_domination_teams_override");
421                 BADCVAR("g_freezetag_teams_override");
422                 BADCVAR("g_friendlyfire");
423                 BADCVAR("g_fullbrightitems");
424                 BADCVAR("g_fullbrightplayers");
425                 BADCVAR("g_keyhunt_point_limit");
426                 BADCVAR("g_keyhunt_teams_override");
427                 BADCVAR("g_lms_lives_override");
428                 BADCVAR("g_maplist");
429                 BADCVAR("g_maxplayers");
430                 BADCVAR("g_mirrordamage");
431                 BADCVAR("g_nexball_goallimit");
432                 BADCVAR("g_norecoil");
433                 BADCVAR("g_physics_clientselect");
434                 BADCVAR("g_pinata");
435                 BADCVAR("g_powerups");
436                 BADCVAR("g_player_brightness");
437                 BADCVAR("g_rocket_flying");
438                 BADCVAR("g_rocket_flying_disabledelays");
439                 BADCVAR("g_spawnshieldtime");
440                 BADCVAR("g_start_delay");
441                 BADCVAR("g_superspectate");
442                 BADCVAR("g_tdm_teams_override");
443                 BADCVAR("g_warmup");
444                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
445                 BADCVAR("hostname");
446                 BADCVAR("log_file");
447                 BADCVAR("maxplayers");
448                 BADCVAR("minplayers");
449                 BADCVAR("minplayers_per_team");
450                 BADCVAR("net_address");
451                 BADCVAR("port");
452                 BADCVAR("rcon_password");
453                 BADCVAR("rcon_restricted_commands");
454                 BADCVAR("rcon_restricted_password");
455                 BADCVAR("skill");
456                 BADCVAR("sv_adminnick");
457                 BADCVAR("sv_autoscreenshot");
458                 BADCVAR("sv_autotaunt");
459                 BADCVAR("sv_curl_defaulturl");
460                 BADCVAR("sv_defaultcharacter");
461                 BADCVAR("sv_defaultcharacterskin");
462                 BADCVAR("sv_defaultplayercolors");
463                 BADCVAR("sv_defaultplayermodel");
464                 BADCVAR("sv_defaultplayerskin");
465                 BADCVAR("sv_maxidle");
466                 BADCVAR("sv_maxrate");
467                 BADCVAR("sv_motd");
468                 BADCVAR("sv_public");
469                 BADCVAR("sv_ready_restart");
470                 BADCVAR("sv_status_privacy");
471                 BADCVAR("sv_taunt");
472                 BADCVAR("sv_vote_call");
473                 BADCVAR("sv_vote_commands");
474                 BADCVAR("sv_vote_majority_factor");
475                 BADCVAR("sv_vote_master");
476                 BADCVAR("sv_vote_master_commands");
477                 BADCVAR("sv_vote_master_password");
478                 BADCVAR("sv_vote_simple_majority_factor");
479                 BADCVAR("teamplay_mode");
480                 BADCVAR("timelimit_override");
481                 BADPREFIX("g_warmup_");
482                 BADPREFIX("sv_info_");
483                 BADPREFIX("sv_ready_restart_");
484
485                 // mutators that announce themselves properly to the server browser
486                 BADCVAR("g_instagib");
487                 BADCVAR("g_new_toys");
488                 BADCVAR("g_nix");
489                 BADCVAR("g_grappling_hook");
490                 BADCVAR("g_jetpack");
491
492                 // temporary for testing
493                 // TODO remove before 0.8.3 release
494                 BADCVAR("g_ca_weaponarena");
495                 BADCVAR("g_freezetag_weaponarena");
496                 BADCVAR("g_lms_weaponarena");
497                 BADCVAR("g_ctf_stalemate_time");
498
499                 if(cvar_string("g_mod_balance") == "Testing")
500                 {
501                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
502                         BADPREFIX("g_balance_");
503                 }
504
505 #undef BADPRESUFFIX
506 #undef BADPREFIX
507 #undef BADCVAR
508
509                 if(pureadding)
510                 {
511                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
512                         if(strlen(cvar_purechanges) > 16384)
513                         {
514                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
515                                 pureadding = 0;
516                         }
517                 }
518                 ++cvar_purechanges_count;
519                 // WARNING: this variable is used for the server list
520                 // NEVER dare to skip this code!
521                 // Hacks to intentionally appearing as "pure server" even though you DO have
522                 // modified settings may be punished by removal from the server list.
523                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
524                 // though.
525         }
526         buf_del(h);
527         if(cvar_changes == "")
528                 cvar_changes = "// this server runs at default server settings\n";
529         else
530                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
531         cvar_changes = strzone(cvar_changes);
532         if(cvar_purechanges == "")
533                 cvar_purechanges = "// this server runs at default gameplay settings\n";
534         else
535                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
536         cvar_purechanges = strzone(cvar_purechanges);
537 }
538
539 entity randomseed;
540 bool RandomSeed_Send(entity this, entity to, int sf)
541 {
542         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
543         WriteShort(MSG_ENTITY, this.cnt);
544         return true;
545 }
546 void RandomSeed_Think(entity this)
547 {
548         this.cnt = bound(0, floor(random() * 65536), 65535);
549         this.nextthink = time + 5;
550
551         this.SendFlags |= 1;
552 }
553 void RandomSeed_Spawn()
554 {
555         randomseed = new_pure(randomseed);
556         setthink(randomseed, RandomSeed_Think);
557         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
558
559         getthink(randomseed)(randomseed); // sets random seed and nextthink
560 }
561
562 spawnfunc(__init_dedicated_server)
563 {
564         // handler for _init/_init map (only for dedicated server initialization)
565
566         world_initialized = -1; // don't complain
567         cvar = cvar_normal;
568         cvar_string = cvar_string_normal;
569         cvar_set = cvar_set_normal;
570
571         delete_fn = remove_unsafely;
572
573         entity e = spawn();
574         setthink(e, GotoFirstMap);
575         e.nextthink = time; // this is usually 1 at this point
576
577         e = new(info_player_deathmatch);  // safeguard against player joining
578
579     // assign reflectively to avoid "assignment to world" warning
580     for (int i = 0, n = numentityfields(); i < n; ++i) {
581         string k = entityfieldname(i);
582         if (k == "classname") {
583             // safeguard against various stuff ;)
584             putentityfieldstring(i, this, "worldspawn");
585             break;
586         }
587     }
588
589         // needs to be done so early because of the constants they create
590         static_init();
591         static_init_late();
592         static_init_precache();
593
594         IL_PUSH(g_spawnpoints, e); // just incase
595
596         MapInfo_Enumerate();
597         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
598 }
599
600 void __init_dedicated_server_shutdown() {
601         MapInfo_Shutdown();
602 }
603
604 STATIC_INIT_EARLY(maxclients)
605 {
606         maxclients = 0;
607         for (entity head = nextent(NULL); head; head = nextent(head)) {
608                 ++maxclients;
609         }
610 }
611
612 void default_delayedinit(entity this)
613 {
614         if(!scores_initialized)
615                 ScoreRules_generic();
616 }
617
618 void InitGameplayMode()
619 {
620         VoteReset();
621
622         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
623         get_mi_min_max(1);
624         // assign reflectively to avoid "assignment to world" warning
625         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
626             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
627             if (v) {
628             putentityfieldstring(i, world, sprintf("%v", v));
629             if (++done == 2) break;
630         }
631         }
632         // currently, NetRadiant's limit is 131072 qu for each side
633         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
634         // set the distance according to map size but don't go over the limit to avoid issues with float precision
635         // in case somebody makes extremely large maps
636         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
637
638         MapInfo_LoadMapSettings(mapname);
639         GameRules_teams(false);
640
641         if (!cvar_value_issafe(world.fog))
642         {
643                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
644                 world.fog = string_null;
645         }
646         if(MapInfo_Map_fog != "")
647         {
648                 if(MapInfo_Map_fog == "none")
649                         world.fog = string_null;
650                 else
651                         world.fog = strzone(MapInfo_Map_fog);
652         }
653         clientstuff = strzone(MapInfo_Map_clientstuff);
654
655         MapInfo_ClearTemps();
656
657         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
658
659         cache_mutatormsg = strzone("");
660         cache_lastmutatormsg = strzone("");
661
662         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
663 }
664
665 void Map_MarkAsRecent(string m);
666 float world_already_spawned;
667 spawnfunc(worldspawn)
668 {
669         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
670
671         bool wantrestart = false;
672         {
673                 if (!server_is_dedicated)
674                 {
675                         // force unloading of server pk3 files when starting a listen server
676                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
677                         // restore csqc_progname too
678                         string expect = "csprogs.dat";
679                         wantrestart = cvar_string_normal("csqc_progname") != expect;
680                         cvar_set_normal("csqc_progname", expect);
681                 }
682                 else
683                 {
684                         // Try to use versioned csprogs from pk3
685                         // Only ever use versioned csprogs.dat files on dedicated servers;
686                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
687                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
688                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
689                         string select = "csprogs.dat";
690                         if (fexists(pk3csprogs)) select = pk3csprogs;
691                         if (cvar_string_normal("csqc_progname") != select)
692                         {
693                                 cvar_set_normal("csqc_progname", select);
694                                 wantrestart = true;
695                         }
696                         // Check for updates on startup
697                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
698                         int sentinel = fopen("progs.txt", FILE_READ);
699                         if (sentinel >= 0)
700                         {
701                                 string switchversion = fgets(sentinel);
702                                 fclose(sentinel);
703                                 if (switchversion != "" && switchversion != WATERMARK)
704                                 {
705                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
706                                         // if it doesn't exist, assume either:
707                                         //   a) the current program was overwritten
708                                         //   b) this is a client only update
709                                         string newprogs = sprintf("progs-%s.dat", switchversion);
710                                         if (fexists(newprogs))
711                                         {
712                                                 cvar_set_normal("sv_progs", newprogs);
713                                                 wantrestart = true;
714                                         }
715                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
716                                         if (fexists(newcsprogs))
717                                         {
718                                                 cvar_set_normal("csqc_progname", newcsprogs);
719                                                 wantrestart = true;
720                                         }
721                                 }
722                         }
723                 }
724                 if (wantrestart)
725                 {
726                         LOG_INFO("Restart requested");
727                         changelevel(mapname);
728                         // let initialization continue, shutdown depends on it
729                 }
730         }
731
732         cvar = cvar_normal;
733         cvar_string = cvar_string_normal;
734         cvar_set = cvar_set_normal;
735
736         if(world_already_spawned)
737                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
738         world_already_spawned = true;
739
740         delete_fn = remove_safely; // during spawning, watch what you remove!
741
742         cvar_changes_init(); // do this very early now so it REALLY matches the server config
743
744         // needs to be done so early because of the constants they create
745         static_init();
746
747         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
748
749         TemporaryDB = db_create();
750
751         // 0 normal
752         lightstyle(0, "m");
753
754         // 1 FLICKER (first variety)
755         lightstyle(1, "mmnmmommommnonmmonqnmmo");
756
757         // 2 SLOW STRONG PULSE
758         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
759
760         // 3 CANDLE (first variety)
761         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
762
763         // 4 FAST STROBE
764         lightstyle(4, "mamamamamama");
765
766         // 5 GENTLE PULSE 1
767         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
768
769         // 6 FLICKER (second variety)
770         lightstyle(6, "nmonqnmomnmomomno");
771
772         // 7 CANDLE (second variety)
773         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
774
775         // 8 CANDLE (third variety)
776         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
777
778         // 9 SLOW STROBE (fourth variety)
779         lightstyle(9, "aaaaaaaazzzzzzzz");
780
781         // 10 FLUORESCENT FLICKER
782         lightstyle(10, "mmamammmmammamamaaamammma");
783
784         // 11 SLOW PULSE NOT FADE TO BLACK
785         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
786
787         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
788
789         // 63 testing
790         lightstyle(63, "a");
791
792         if(autocvar_g_campaign)
793                 CampaignPreInit();
794
795         Map_MarkAsRecent(mapname);
796
797         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
798
799         InitGameplayMode();
800         static_init_late();
801         static_init_precache();
802         readlevelcvars();
803         GrappleHookInit();
804
805         GameRules_limit_fallbacks();
806
807         if(warmup_limit == 0)
808                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
809
810         player_count = 0;
811         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
812         if(bot_waypoints_for_items == 1)
813                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
814                         bot_waypoints_for_items = 0;
815
816         WaypointSprite_Init();
817
818         GameLogInit(); // prepare everything
819         // NOTE for matchid:
820         // changing the logic generating it is okay. But:
821         // it HAS to stay <= 64 chars
822         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
823         if(autocvar_sv_eventlog)
824         {
825                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
826                 matchid = strzone(s);
827
828                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
829                 s = ":gameinfo:mutators:LIST";
830
831                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
832                 s = M_ARGV(0, string);
833
834                 // initialiation stuff, not good in the mutator system
835                 if(!autocvar_g_use_ammunition)
836                         s = strcat(s, ":no_use_ammunition");
837
838                 // initialiation stuff, not good in the mutator system
839                 if(autocvar_g_pickup_items == 0)
840                         s = strcat(s, ":no_pickup_items");
841                 if(autocvar_g_pickup_items > 0)
842                         s = strcat(s, ":pickup_items");
843
844                 // initialiation stuff, not good in the mutator system
845                 if(autocvar_g_weaponarena != "0")
846                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
847
848                 // TODO to mutator system
849                 if(autocvar_g_norecoil)
850                         s = strcat(s, ":norecoil");
851
852                 // TODO to mutator system
853                 if(autocvar_g_powerups == 0)
854                         s = strcat(s, ":no_powerups");
855                 if(autocvar_g_powerups > 0)
856                         s = strcat(s, ":powerups");
857
858                 GameLogEcho(s);
859                 GameLogEcho(":gameinfo:end");
860         }
861         else
862                 matchid = strzone(ftos(random()));
863
864         cvar_set("nextmap", "");
865
866         SetDefaultAlpha();
867
868         if(autocvar_g_campaign)
869                 CampaignPostInit();
870
871         Ban_LoadBans();
872
873         MapInfo_Enumerate();
874         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
875
876         if(fexists(strcat("scripts/", mapname, ".arena")))
877                 cvar_settemp("sv_q3acompat_machineshotgunswap", "1");
878
879         if(fexists(strcat("scripts/", mapname, ".defi")))
880                 cvar_settemp("sv_q3defragcompat", "1");
881
882         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
883         {
884                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
885                 if(fd != -1)
886                 {
887                         string s;
888                         while((s = fgets(fd)))
889                         {
890                                 int l = tokenize_console(s);
891                                 if(l < 2)
892                                         continue;
893                                 if(argv(0) == "cd")
894                                 {
895                                         string trackname = argv(2);
896                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
897                                         LOG_INFO("  cdtrack ", trackname);
898                                         if (cvar_value_issafe(trackname))
899                                         {
900                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
901                                                 strcpy(clientstuff, newstuff);
902                                         }
903                                 }
904                                 else if(argv(0) == "fog")
905                                 {
906                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
907                                         LOG_INFO("  \"fog\" \"", s, "\"");
908                                 }
909                                 else if(argv(0) == "set")
910                                 {
911                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
912                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
913                                 }
914                                 else if(argv(0) != "//")
915                                 {
916                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
917                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
918                                 }
919                         }
920                         fclose(fd);
921                 }
922         }
923
924         WeaponStats_Init();
925
926         Nagger_Init();
927
928         next_pingtime = time + 5;
929
930         // set up information replies for clients and server to use
931         maplist_reply = strzone(getmaplist());
932         lsmaps_reply = strzone(getlsmaps());
933         monsterlist_reply = strzone(getmonsterlist());
934         for(int i = 0; i < 10; ++i)
935         {
936                 string s = getrecords(i);
937                 if (s)
938                         records_reply[i] = strzone(s);
939         }
940         ladder_reply = strzone(getladder());
941         rankings_reply = strzone(getrankings());
942
943         // begin other init
944         ClientInit_Spawn();
945         RandomSeed_Spawn();
946         PingPLReport_Spawn();
947
948         CheatInit();
949
950         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
951
952         // fill sv_curl_serverpackages from .serverpackage files
953         if (autocvar_sv_curl_serverpackages_auto)
954         {
955                 string s = "csprogs-" WATERMARK ".txt";
956                 // remove automatically managed files from the list to prevent duplicates
957                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
958                 {
959                         string pkg = argv(i);
960                         if (startsWith(pkg, "csprogs-")) continue;
961                         if (endsWith(pkg, "-serverpackage.txt")) continue;
962                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
963                         s = cons(s, pkg);
964                 }
965                 // add automatically managed files to the list
966                 #define X(match) MACRO_BEGIN \
967                         int fd = search_begin(match, true, false); \
968                         if (fd >= 0) \
969                         { \
970                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
971                                 { \
972                                         s = cons(s, search_getfilename(fd, i)); \
973                                 } \
974                                 search_end(fd); \
975                         } \
976                 MACRO_END
977                 X("*-serverpackage.txt");
978                 X("*.serverpackage");
979                 #undef X
980                 cvar_set("sv_curl_serverpackages", s);
981         }
982
983         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
984         modname = "Xonotic";
985         // physics/balance/config changes that count as mod
986         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
987                 modname = cvar_string("g_mod_physics");
988         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
989                 modname = cvar_string("g_mod_balance");
990         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
991                 modname = cvar_string("g_mod_config");
992         // extra mutators that deserve to count as mod
993         MUTATOR_CALLHOOK(SetModname, modname);
994         modname = M_ARGV(0, string);
995
996         // save it for later
997         modname = strzone(modname);
998
999         WinningConditionHelper(this); // set worldstatus
1000
1001         world_initialized = 1;
1002         __spawnfunc_spawn_all();
1003 }
1004
1005 spawnfunc(light)
1006 {
1007         //makestatic (this); // Who the f___ did that?
1008         delete(this);
1009 }
1010
1011 string GetGametype()
1012 {
1013         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1014 }
1015
1016 string GetMapname()
1017 {
1018         return mapname;
1019 }
1020
1021 float Map_Count, Map_Current;
1022 string Map_Current_Name;
1023
1024 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1025 int GetMaplistPosition()
1026 {
1027         string map = GetMapname();
1028         int idx = autocvar_g_maplist_index;
1029
1030         if(idx >= 0)
1031         {
1032                 if(idx < Map_Count)
1033                 {
1034                         if(map == argv(idx))
1035                         {
1036                                 return idx;
1037                         }
1038                 }
1039         }
1040
1041         for(int pos = 0; pos < Map_Count; ++pos)
1042         {
1043                 if(map == argv(pos))
1044                         return pos;
1045         }
1046
1047         // resume normal maplist rotation if current map is not in g_maplist
1048         return idx;
1049 }
1050
1051 bool MapHasRightSize(string map)
1052 {
1053         int minplayers = max(0, floor(autocvar_minplayers));
1054         if (teamplay)
1055                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1056         if (autocvar_g_maplist_check_waypoints
1057                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1058         {
1059                 string checkwp_msg = strcat("checkwp ", map);
1060                 if(!fexists(strcat("maps/", map, ".waypoints")))
1061                 {
1062                         LOG_TRACE(checkwp_msg, ": no waypoints");
1063                         return false;
1064                 }
1065                 LOG_TRACE(checkwp_msg, ": has waypoints");
1066         }
1067
1068         if(autocvar_g_maplist_ignore_sizes)
1069                 return true;
1070
1071         // open map size restriction file
1072         string opensize_msg = strcat("opensize ", map);
1073         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1074         int pcount = player_count;
1075         if(!autocvar_g_maplist_sizes_count_bots)
1076                 pcount -= currentbots;
1077         if(fh >= 0)
1078         {
1079                 opensize_msg = strcat(opensize_msg, ": ok, ");
1080                 int mapmin = stoi(fgets(fh));
1081                 int mapmax = stoi(fgets(fh));
1082                 fclose(fh);
1083                 if(pcount < mapmin)
1084                 {
1085                         LOG_TRACE(opensize_msg, "not enough");
1086                         return false;
1087                 }
1088                 if(mapmax && pcount > mapmax)
1089                 {
1090                         LOG_TRACE(opensize_msg, "too many");
1091                         return false;
1092                 }
1093                 LOG_TRACE(opensize_msg, "right size");
1094                 return true;
1095         }
1096         LOG_TRACE(opensize_msg, ": not found");
1097         return true;
1098 }
1099
1100 string Map_Filename(float position)
1101 {
1102         return strcat("maps/", argv(position), ".bsp");
1103 }
1104
1105 void Map_MarkAsRecent(string m)
1106 {
1107         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1108 }
1109
1110 float Map_IsRecent(string m)
1111 {
1112         return strhasword(autocvar_g_maplist_mostrecent, m);
1113 }
1114
1115 float Map_Check(float position, float pass)
1116 {
1117         string filename;
1118         string map_next;
1119         map_next = argv(position);
1120         if(pass <= 1)
1121         {
1122                 if(Map_IsRecent(map_next))
1123                         return 0;
1124         }
1125         filename = Map_Filename(position);
1126         if(MapInfo_CheckMap(map_next))
1127         {
1128                 if(pass == 2)
1129                         return 1;
1130                 if(MapHasRightSize(map_next))
1131                         return 1;
1132                 return 0;
1133         }
1134         else
1135                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1136
1137         return 0;
1138 }
1139
1140 void Map_Goto_SetStr(string nextmapname)
1141 {
1142         if(getmapname_stored != "")
1143                 strunzone(getmapname_stored);
1144         if(nextmapname == "")
1145                 getmapname_stored = "";
1146         else
1147                 getmapname_stored = strzone(nextmapname);
1148 }
1149
1150 void Map_Goto_SetFloat(float position)
1151 {
1152         cvar_set("g_maplist_index", ftos(position));
1153         Map_Goto_SetStr(argv(position));
1154 }
1155
1156 void Map_Goto(float reinit)
1157 {
1158         MapInfo_LoadMap(getmapname_stored, reinit);
1159 }
1160
1161 // return codes of map selectors:
1162 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1163 //   -2 = permanent failure
1164 float MaplistMethod_Iterate() // usual method
1165 {
1166         float pass, i;
1167
1168         LOG_TRACE("Trying MaplistMethod_Iterate");
1169
1170         for(pass = 1; pass <= 2; ++pass)
1171         {
1172                 for(i = 1; i < Map_Count; ++i)
1173                 {
1174                         float mapindex;
1175                         mapindex = (i + Map_Current) % Map_Count;
1176                         if(Map_Check(mapindex, pass))
1177                                 return mapindex;
1178                 }
1179         }
1180         return -1;
1181 }
1182
1183 float MaplistMethod_Repeat() // fallback method
1184 {
1185         LOG_TRACE("Trying MaplistMethod_Repeat");
1186
1187         if(Map_Check(Map_Current, 2))
1188                 return Map_Current;
1189         return -2;
1190 }
1191
1192 float MaplistMethod_Random() // random map selection
1193 {
1194         float i, imax;
1195
1196         LOG_TRACE("Trying MaplistMethod_Random");
1197
1198         imax = 42;
1199
1200         for(i = 0; i <= imax; ++i)
1201         {
1202                 float mapindex;
1203                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1204                 if(Map_Check(mapindex, 1))
1205                         return mapindex;
1206         }
1207         return -1;
1208 }
1209
1210 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1211 // the exponent sets a bias on the map selection:
1212 // the higher the exponent, the less likely "shortly repeated" same maps are
1213 {
1214         float i, j, imax, insertpos;
1215
1216         LOG_TRACE("Trying MaplistMethod_Shuffle");
1217
1218         imax = 42;
1219
1220         for(i = 0; i <= imax; ++i)
1221         {
1222                 string newlist;
1223
1224                 // now reinsert this at another position
1225                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1226                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1227                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1228                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1229
1230                 // insert the current map there
1231                 newlist = "";
1232                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1233                         newlist = strcat(newlist, " ", argv(j));
1234                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1235                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1236                         newlist = strcat(newlist, " ", argv(j));
1237                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1238                 cvar_set("g_maplist", newlist);
1239                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1240
1241                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1242                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1243                 if(Map_Check(Map_Current, 1))
1244                         return Map_Current;
1245         }
1246         return -1;
1247 }
1248
1249 void Maplist_Init()
1250 {
1251         float i = Map_Count = 0;
1252         if(autocvar_g_maplist != "")
1253         {
1254                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1255                 for (i = 0; i < Map_Count; ++i)
1256                 {
1257                         if (Map_Check(i, 2))
1258                                 break;
1259                 }
1260         }
1261
1262         if (i == Map_Count)
1263         {
1264                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1265                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1266                 if(autocvar_g_maplist_shuffle)
1267                         ShuffleMaplist();
1268                 if(!server_is_dedicated)
1269                         localcmd("\nmenu_cmd sync\n");
1270                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1271         }
1272         if(Map_Count == 0)
1273                 error("empty maplist, cannot select a new map");
1274         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1275
1276         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1277         // this may or may not be correct, but who cares, in the worst case a map
1278         // isn't chosen in the first pass that should have been
1279 }
1280
1281 string GetNextMap()
1282 {
1283         Maplist_Init();
1284         float nextMap = -1;
1285
1286         if(nextMap == -1)
1287                 if(autocvar_g_maplist_shuffle > 0)
1288                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1289
1290         if(nextMap == -1)
1291                 if(autocvar_g_maplist_selectrandom)
1292                         nextMap = MaplistMethod_Random();
1293
1294         if(nextMap == -1)
1295                 nextMap = MaplistMethod_Iterate();
1296
1297         if(nextMap == -1)
1298                 nextMap = MaplistMethod_Repeat();
1299
1300         if(nextMap >= 0)
1301         {
1302                 Map_Goto_SetFloat(nextMap);
1303                 return getmapname_stored;
1304         }
1305
1306         return "";
1307 }
1308
1309 float DoNextMapOverride(float reinit)
1310 {
1311         if(autocvar_g_campaign)
1312         {
1313                 CampaignPostIntermission();
1314                 alreadychangedlevel = true;
1315                 return true;
1316         }
1317         if(autocvar_quit_when_empty)
1318         {
1319                 if(player_count <= currentbots)
1320                 {
1321                         localcmd("quit\n");
1322                         alreadychangedlevel = true;
1323                         return true;
1324                 }
1325         }
1326         if(autocvar_quit_and_redirect != "")
1327         {
1328                 redirection_target = strzone(autocvar_quit_and_redirect);
1329                 alreadychangedlevel = true;
1330                 return true;
1331         }
1332         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1333         {
1334                 localcmd("restart\n");
1335                 alreadychangedlevel = true;
1336                 return true;
1337         }
1338         if(autocvar_nextmap != "")
1339         {
1340                 string m;
1341                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1342                 cvar_set("nextmap",m);
1343
1344                 if(!m || gametypevote)
1345                         return false;
1346                 if(autocvar_sv_vote_gametype)
1347                 {
1348                         Map_Goto_SetStr(m);
1349                         return false;
1350                 }
1351
1352                 if(MapInfo_CheckMap(m))
1353                 {
1354                         Map_Goto_SetStr(m);
1355                         Map_Goto(reinit);
1356                         alreadychangedlevel = true;
1357                         return true;
1358                 }
1359         }
1360         if(!reinit && autocvar_lastlevel)
1361         {
1362                 cvar_settemp_restore();
1363                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1364                 alreadychangedlevel = true;
1365                 return true;
1366         }
1367         return false;
1368 }
1369
1370 void GotoNextMap(float reinit)
1371 {
1372         //string nextmap;
1373         //float n, nummaps;
1374         //string s;
1375         if (alreadychangedlevel)
1376                 return;
1377         alreadychangedlevel = true;
1378
1379         string nextMap = GetNextMap();
1380         if(nextMap == "")
1381                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1382         Map_Goto(reinit);
1383 }
1384
1385
1386 /*
1387 ============
1388 IntermissionThink
1389
1390 When the player presses attack or jump, change to the next level
1391 ============
1392 */
1393 .float autoscreenshot;
1394 void IntermissionThink(entity this)
1395 {
1396         FixIntermissionClient(this);
1397
1398         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1399         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1400
1401         if( (server_screenshot || client_screenshot)
1402                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1403         {
1404                 this.autoscreenshot = -1;
1405                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1406                 return;
1407         }
1408
1409         if (time < intermission_exittime)
1410                 return;
1411
1412         if(!mapvote_initialized)
1413                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1414                         return;
1415
1416         MapVote_Start();
1417 }
1418
1419 /*
1420 ===============================================================================
1421
1422 RULES
1423
1424 ===============================================================================
1425 */
1426
1427 void DumpStats(float final)
1428 {
1429         float file;
1430         string s;
1431         float to_console;
1432         float to_eventlog;
1433         float to_file;
1434         float i;
1435
1436         to_console = autocvar_sv_logscores_console;
1437         to_eventlog = autocvar_sv_eventlog;
1438         to_file = autocvar_sv_logscores_file;
1439
1440         if(!final)
1441         {
1442                 to_console = true; // always print printstats replies
1443                 to_eventlog = false; // but never print them to the event log
1444         }
1445
1446         if(to_eventlog)
1447                 if(autocvar_sv_eventlog_console)
1448                         to_console = false; // otherwise we get the output twice
1449
1450         if(final)
1451                 s = ":scores:";
1452         else
1453                 s = ":status:";
1454         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1455
1456         if(to_console)
1457                 LOG_INFO(s);
1458         if(to_eventlog)
1459                 GameLogEcho(s);
1460
1461         file = -1;
1462         if(to_file)
1463         {
1464                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1465                 if(file == -1)
1466                         to_file = false;
1467                 else
1468                         fputs(file, strcat(s, "\n"));
1469         }
1470
1471         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1472         if(to_console)
1473                 LOG_INFO(s);
1474         if(to_eventlog)
1475                 GameLogEcho(s);
1476         if(to_file)
1477                 fputs(file, strcat(s, "\n"));
1478
1479         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1480                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1481                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1482                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1483                         s = strcat(s, ftos(it.team), ":");
1484                 else
1485                         s = strcat(s, "spectator:");
1486
1487                 if(to_console)
1488                         LOG_INFO(s, playername(it, false));
1489                 if(to_eventlog)
1490                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1491                 if(to_file)
1492                         fputs(file, strcat(s, playername(it, false), "\n"));
1493         });
1494
1495         if(teamplay)
1496         {
1497                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1498                 if(to_console)
1499                         LOG_INFO(s);
1500                 if(to_eventlog)
1501                         GameLogEcho(s);
1502                 if(to_file)
1503                         fputs(file, strcat(s, "\n"));
1504
1505                 for(i = 1; i < 16; ++i)
1506                 {
1507                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1508                         s = strcat(s, ":", ftos(i));
1509                         if(to_console)
1510                                 LOG_INFO(s);
1511                         if(to_eventlog)
1512                                 GameLogEcho(s);
1513                         if(to_file)
1514                                 fputs(file, strcat(s, "\n"));
1515                 }
1516         }
1517
1518         if(to_console)
1519                 LOG_INFO(":end");
1520         if(to_eventlog)
1521                 GameLogEcho(":end");
1522         if(to_file)
1523         {
1524                 fputs(file, ":end\n");
1525                 fclose(file);
1526         }
1527 }
1528
1529 void FixIntermissionClient(entity e)
1530 {
1531         if(!e.autoscreenshot) // initial call
1532         {
1533                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1534                 SetResourceExplicit(e, RES_HEALTH, -2342);
1535                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1536                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1537                 {
1538                     .entity weaponentity = weaponentities[slot];
1539                         if(e.(weaponentity))
1540                         {
1541                                 e.(weaponentity).effects = EF_NODRAW;
1542                                 if (e.(weaponentity).weaponchild)
1543                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1544                         }
1545                 }
1546                 if(IS_REAL_CLIENT(e))
1547                 {
1548                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1549                         RandomSelection_Init();
1550                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1551                                 RandomSelection_AddString(it, 1, 1);
1552                         });
1553                         if (RandomSelection_chosen_string != "")
1554                         {
1555                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1556                         }
1557                         msg_entity = e;
1558                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1559                 }
1560         }
1561 }
1562
1563 /*
1564 go to the next level for deathmatch
1565 only called if a time or frag limit has expired
1566 */
1567 void NextLevel()
1568 {
1569         game_stopped = true;
1570         intermission_running = 1; // game over
1571
1572         // enforce a wait time before allowing changelevel
1573         if(player_count > 0)
1574                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1575         else
1576                 intermission_exittime = -1;
1577
1578         /*
1579         WriteByte (MSG_ALL, SVC_CDTRACK);
1580         WriteByte (MSG_ALL, 3);
1581         WriteByte (MSG_ALL, 3);
1582         // done in FixIntermission
1583         */
1584
1585         //pos = FindIntermission ();
1586
1587         VoteReset();
1588
1589         DumpStats(true);
1590
1591         // send statistics
1592         PlayerStats_GameReport(true);
1593         WeaponStats_Shutdown();
1594
1595         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1596
1597         if(autocvar_sv_eventlog)
1598                 GameLogEcho(":gameover");
1599
1600         GameLogClose();
1601
1602         FOREACH_CLIENT(IS_PLAYER(it), {
1603                 FixIntermissionClient(it);
1604                 if(it.winning)
1605                         bprint(playername(it, false), " ^7wins.\n");
1606         });
1607
1608         target_music_kill();
1609
1610         if(autocvar_g_campaign)
1611                 CampaignPreIntermission();
1612
1613         MUTATOR_CALLHOOK(MatchEnd);
1614
1615         localcmd("\nsv_hook_gameend\n");
1616 }
1617
1618
1619 float InitiateSuddenDeath()
1620 {
1621         // Check first whether normal overtimes could be added before initiating suddendeath mode
1622         // - for this timelimit_overtime needs to be >0 of course
1623         // - also check the winning condition calculated in the previous frame and only add normal overtime
1624         //   again, if at the point at which timelimit would be extended again, still no winner was found
1625         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1626                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1627                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1628         {
1629                 return 1; // need to call InitiateOvertime later
1630         }
1631         else
1632         {
1633                 if(!checkrules_suddendeathend)
1634                 {
1635                         if(autocvar_g_campaign)
1636                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1637                         else
1638                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1639                         if(g_race && !g_race_qualifying)
1640                                 race_StartCompleting();
1641                 }
1642                 return 0;
1643         }
1644 }
1645
1646 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1647 {
1648         ++checkrules_overtimesadded;
1649         //add one more overtime by simply extending the timelimit
1650         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1651         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1652 }
1653
1654 float GetWinningCode(float fraglimitreached, float equality)
1655 {
1656         if(autocvar_g_campaign == 1)
1657         {
1658                 if(fraglimitreached)
1659                         return WINNING_YES;
1660                 else
1661                         return WINNING_NO;
1662         }
1663         else
1664         {
1665                 if(equality)
1666                 {
1667                         if(fraglimitreached)
1668                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1669                         else
1670                                 return WINNING_NEVER;
1671                 }
1672                 else
1673                 {
1674                         if(fraglimitreached)
1675                                 return WINNING_YES;
1676                         else
1677                                 return WINNING_NO;
1678                 }
1679         }
1680 }
1681
1682 // set the .winning flag for exactly those players with a given field value
1683 void SetWinners(.float field, float value)
1684 {
1685         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1686 }
1687
1688 // set the .winning flag for those players with a given field value
1689 void AddWinners(.float field, float value)
1690 {
1691         FOREACH_CLIENT(IS_PLAYER(it), {
1692                 if(it.(field) == value)
1693                         it.winning = 1;
1694         });
1695 }
1696
1697 // clear the .winning flags
1698 void ClearWinners()
1699 {
1700         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1701 }
1702
1703 void ShuffleMaplist()
1704 {
1705         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1706 }
1707
1708 float leaderscore;
1709 float secondscore;
1710 int fragsleft_last;
1711 float WinningCondition_Scores(float limit, float leadlimit)
1712 {
1713         float limitreached;
1714
1715         // TODO make everything use THIS winning condition (except LMS)
1716         WinningConditionHelper(NULL);
1717
1718         if(teamplay)
1719         {
1720                 for (int i = 1; i < 5; ++i)
1721                 {
1722                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1723                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1724                 }
1725         }
1726
1727         ClearWinners();
1728         if(WinningConditionHelper_winner)
1729                 WinningConditionHelper_winner.winning = 1;
1730         if(WinningConditionHelper_winnerteam >= 0)
1731                 SetWinners(team, WinningConditionHelper_winnerteam);
1732
1733         if(WinningConditionHelper_lowerisbetter)
1734         {
1735                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1736                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1737                 limit = -limit;
1738         }
1739
1740         if(WinningConditionHelper_zeroisworst)
1741                 leadlimit = 0; // not supported in this mode
1742
1743         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1744         // these modes always score in increments of 1, thus this makes sense
1745         {
1746                 if (leaderscore != WinningConditionHelper_topscore ||
1747                         secondscore != WinningConditionHelper_secondscore)
1748                 {
1749                         int fragsleft = 0, leadingfragsleft = 0;
1750
1751                         leaderscore = WinningConditionHelper_topscore;
1752                         secondscore = WinningConditionHelper_secondscore;
1753
1754                         if (limit)
1755                                 fragsleft = limit - leaderscore;
1756                         if (leadlimit)
1757                                 leadingfragsleft = secondscore + leadlimit - leaderscore;
1758
1759                         if (autocvar_leadlimit_and_fraglimit && leadlimit)
1760                         {
1761                                 if (limit)
1762                                         fragsleft = max(leadingfragsleft, fragsleft);
1763                         }
1764                         else if (leadlimit)
1765                         {
1766                                 if (limit)
1767                                         fragsleft = min(fragsleft, leadingfragsleft);
1768                                 else
1769                                         fragsleft = leadingfragsleft;
1770                         }
1771
1772                         if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1773                         {
1774                                 if (fragsleft == 1)
1775                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1776                                 else if (fragsleft == 2)
1777                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1778                                 else if (fragsleft == 3)
1779                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1780
1781                                 fragsleft_last = fragsleft;
1782                         }
1783                 }
1784         }
1785
1786         limitreached = false;
1787         if (limit && WinningConditionHelper_topscore >= limit)
1788                 limitreached = true;
1789         if(leadlimit)
1790         {
1791                 float leadlimitreached;
1792                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1793                 if(autocvar_leadlimit_and_fraglimit)
1794                         limitreached = (limitreached && leadlimitreached);
1795                 else
1796                         limitreached = (limitreached || leadlimitreached);
1797         }
1798
1799         if(limit)
1800                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1801
1802         return GetWinningCode(
1803                 WinningConditionHelper_topscore && limitreached,
1804                 WinningConditionHelper_equality
1805         );
1806 }
1807
1808 float WinningCondition_RanOutOfSpawns()
1809 {
1810         if(have_team_spawns <= 0)
1811                 return WINNING_NO;
1812
1813         if(!autocvar_g_spawn_useallspawns)
1814                 return WINNING_NO;
1815
1816         if(!some_spawn_has_been_used)
1817                 return WINNING_NO;
1818
1819         for (int i = 1; i < 5; ++i)
1820         {
1821                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1822         }
1823
1824         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1825         {
1826                 if (Team_IsValidTeam(it.team))
1827                 {
1828                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1829                 }
1830         });
1831
1832         IL_EACH(g_spawnpoints, true,
1833         {
1834                 if (Team_IsValidTeam(it.team))
1835                 {
1836                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1837                 }
1838         });
1839
1840         ClearWinners();
1841         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1842         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1843         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1844         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1845         if(team1_score + team2_score + team3_score + team4_score == 0)
1846         {
1847                 checkrules_equality = true;
1848                 return WINNING_YES;
1849         }
1850         else if(team1_score + team2_score + team3_score + team4_score == 1)
1851         {
1852                 float t, i;
1853                 if(team1_score)
1854                         t = 1;
1855                 else if(team2_score)
1856                         t = 2;
1857                 else if(team3_score)
1858                         t = 3;
1859                 else // if(team4_score)
1860                         t = 4;
1861                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1862                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1863                 {
1864                         for (int j = 1; j <= NUM_TEAMS; ++j)
1865                         {
1866                                 if (t == j)
1867                                 {
1868                                         continue;
1869                                 }
1870                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1871                                 {
1872                                         continue;
1873                                 }
1874                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1875                         }
1876                 }
1877
1878                 AddWinners(team, t);
1879                 return WINNING_YES;
1880         }
1881         else
1882                 return WINNING_NO;
1883 }
1884
1885 /*
1886 ============
1887 CheckRules_World
1888
1889 Exit deathmatch games upon conditions
1890 ============
1891 */
1892 void CheckRules_World()
1893 {
1894         float timelimit;
1895         float fraglimit;
1896         float leadlimit;
1897
1898         VoteThink();
1899         MapVote_Think();
1900
1901         SetDefaultAlpha();
1902
1903         if (intermission_running) // someone else quit the game already
1904         {
1905                 if(player_count == 0) // Nobody there? Then let's go to the next map
1906                         MapVote_Start();
1907                         // this will actually check the player count in the next frame
1908                         // again, but this shouldn't hurt
1909                 return;
1910         }
1911
1912         timelimit = autocvar_timelimit * 60;
1913         fraglimit = autocvar_fraglimit;
1914         leadlimit = autocvar_leadlimit;
1915
1916         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1917         {
1918                 if(timelimit > 0)
1919                         timelimit = 0; // timelimit is not made for warmup
1920                 if(fraglimit > 0)
1921                         fraglimit = 0; // no fraglimit for now
1922                 leadlimit = 0; // no leadlimit for now
1923         }
1924
1925         if(timelimit > 0)
1926         {
1927                 timelimit += game_starttime;
1928         }
1929         else if (timelimit < 0)
1930         {
1931                 // endmatch
1932                 NextLevel();
1933                 return;
1934         }
1935
1936         float wantovertime;
1937         wantovertime = 0;
1938
1939         if(timelimit > game_starttime)
1940                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1941         else
1942                 game_completion_ratio = 0;
1943
1944         if(checkrules_suddendeathend)
1945         {
1946                 if(!checkrules_suddendeathwarning)
1947                 {
1948                         checkrules_suddendeathwarning = true;
1949                         if(g_race && !g_race_qualifying)
1950                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1951                         else
1952                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1953                 }
1954         }
1955         else
1956         {
1957                 if (timelimit && time >= timelimit)
1958                 {
1959                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1960                         {
1961                                 float totalplayers;
1962                                 float playerswithlaps;
1963                                 float readyplayers;
1964                                 totalplayers = playerswithlaps = readyplayers = 0;
1965                                 FOREACH_CLIENT(IS_PLAYER(it), {
1966                                         ++totalplayers;
1967                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1968                                                 ++playerswithlaps;
1969                                         if(it.ready)
1970                                                 ++readyplayers;
1971                                 });
1972
1973                                 // at least 2 of the players have completed a lap: start the RACE
1974                                 // otherwise, the players should end the qualifying on their own
1975                                 if(readyplayers || playerswithlaps >= 2)
1976                                 {
1977                                         checkrules_suddendeathend = 0;
1978                                         ReadyRestart(); // go to race
1979                                         return;
1980                                 }
1981                                 else
1982                                         wantovertime |= InitiateSuddenDeath();
1983                         }
1984                         else
1985                                 wantovertime |= InitiateSuddenDeath();
1986                 }
1987         }
1988
1989         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1990         {
1991                 NextLevel();
1992                 return;
1993         }
1994
1995         int checkrules_status = WinningCondition_RanOutOfSpawns();
1996         if(checkrules_status == WINNING_YES)
1997                 bprint("Hey! Someone ran out of spawns!\n");
1998         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1999                 checkrules_status = M_ARGV(0, float);
2000         else
2001                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2002
2003         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2004         {
2005                 checkrules_status = WINNING_NEVER;
2006                 checkrules_overtimesadded = -1;
2007                 wantovertime |= InitiateSuddenDeath();
2008         }
2009
2010         if(checkrules_status == WINNING_NEVER)
2011                 // equality cases! Nobody wins if the overtime ends in a draw.
2012                 ClearWinners();
2013
2014         if(wantovertime)
2015         {
2016                 if(checkrules_status == WINNING_NEVER)
2017                         InitiateOvertime();
2018                 else
2019                         checkrules_status = WINNING_YES;
2020         }
2021
2022         if(checkrules_suddendeathend)
2023                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2024                         checkrules_status = WINNING_YES;
2025
2026         if(checkrules_status == WINNING_YES)
2027         {
2028                 //print("WINNING\n");
2029                 NextLevel();
2030         }
2031 }
2032
2033 string GotoMap(string m)
2034 {
2035         m = GameTypeVote_MapInfo_FixName(m);
2036         if (!m)
2037                 return "The map you suggested is not available on this server.";
2038         if (!autocvar_sv_vote_gametype)
2039         if(!MapInfo_CheckMap(m))
2040                 return "The map you suggested does not support the current game mode.";
2041         cvar_set("nextmap", m);
2042         cvar_set("timelimit", "-1");
2043         if(mapvote_initialized || alreadychangedlevel)
2044         {
2045                 if(DoNextMapOverride(0))
2046                         return "Map switch initiated.";
2047                 else
2048                         return "Hm... no. For some reason I like THIS map more.";
2049         }
2050         else
2051                 return "Map switch will happen after scoreboard.";
2052 }
2053
2054 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2055 void RunThink(entity this)
2056 {
2057         // don't let things stay in the past.
2058         // it is possible to start that way by a trigger with a local time.
2059         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2060                 return;
2061
2062         float oldtime = time; // do we need to save this?
2063
2064         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2065         {
2066                 time = max(oldtime, this.nextthink);
2067                 this.nextthink = 0;
2068
2069                 if(getthink(this))
2070                         getthink(this)(this);
2071                 // mods often set nextthink to time to cause a think every frame,
2072                 // we don't want to loop in that case, so exit if the new nextthink is
2073                 // <= the time the qc was told, also exit if it is past the end of the
2074                 // frame
2075                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2076                         break;
2077         }
2078
2079         time = oldtime;
2080 }
2081
2082 bool autocvar_sv_freezenonclients;
2083 bool autocvar_sv_gameplayfix_delayprojectiles = false;
2084 void Physics_Frame()
2085 {
2086         if(autocvar_sv_freezenonclients)
2087                 return;
2088
2089         IL_EACH(g_moveables, true,
2090         {
2091                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2092                         continue;
2093
2094                 //set_movetype(it, it.move_movetype);
2095                 // inline the set_movetype function, since this is called a lot
2096                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2097
2098                 if(it.move_movetype == MOVETYPE_NONE)
2099                         continue;
2100
2101                 if(it.move_qcphysics)
2102                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2103
2104                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2105                 {
2106                         // handle thinking here
2107                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2108                                 RunThink(it);
2109                 }
2110         });
2111
2112         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2113                 return;
2114
2115         IL_EACH(g_moveables, it.move_qcphysics,
2116         {
2117                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2118                         continue;
2119                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2120         });
2121 }
2122
2123 void systems_update();
2124 void EndFrame()
2125 {
2126         anticheat_endframe();
2127
2128         Physics_Frame();
2129
2130         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2131                 entity e = IS_SPEC(it) ? it.enemy : it;
2132                 if (e.typehitsound) {
2133                         STAT(TYPEHIT_TIME, it) = time;
2134                 } else if (e.killsound) {
2135                         STAT(KILL_TIME, it) = time;
2136                 } else if (e.damage_dealt) {
2137                         STAT(HIT_TIME, it) = time;
2138                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2139                 }
2140         });
2141         // add 1 frametime because after this, engine SV_Physics
2142         // increases time by a frametime and then networks the frame
2143         // add another frametime because client shows everything with
2144         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2145         // needed!
2146         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2147         FOREACH_CLIENT(true, {
2148                 it.typehitsound = false;
2149                 it.damage_dealt = 0;
2150                 it.killsound = false;
2151                 antilag_record(it, CS(it), altime);
2152         });
2153         IL_EACH(g_monsters, true,
2154         {
2155                 antilag_record(it, it, altime);
2156         });
2157         IL_EACH(g_projectiles, it.classname == "nade",
2158         {
2159                 antilag_record(it, it, altime);
2160         });
2161         systems_update();
2162         IL_ENDFRAME();
2163 }
2164
2165
2166 /*
2167  * RedirectionThink:
2168  * returns true if redirecting
2169  */
2170 float redirection_timeout;
2171 float redirection_nextthink;
2172 float RedirectionThink()
2173 {
2174         float clients_found;
2175
2176         if(redirection_target == "")
2177                 return false;
2178
2179         if(!redirection_timeout)
2180         {
2181                 cvar_set("sv_public", "-2");
2182                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2183                 if(redirection_target == "self")
2184                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2185                 else
2186                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2187         }
2188
2189         if(time < redirection_nextthink)
2190                 return true;
2191
2192         redirection_nextthink = time + 1;
2193
2194         clients_found = 0;
2195         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2196                 // TODO add timer
2197                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2198                 if(redirection_target == "self")
2199                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2200                 else
2201                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2202                 ++clients_found;
2203         });
2204
2205         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2206
2207         if(time > redirection_timeout || clients_found == 0)
2208                 localcmd("\nwait; wait; wait; quit\n");
2209
2210         return true;
2211 }
2212
2213 void RestoreGame()
2214 {
2215         // Loaded from a save game
2216         // some things then break, so let's work around them...
2217
2218         // Progs DB (capture records)
2219         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2220
2221         // Mapinfo
2222         MapInfo_Shutdown();
2223         MapInfo_Enumerate();
2224         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2225         WeaponStats_Init();
2226
2227         TargetMusic_RestoreGame();
2228 }
2229
2230 void Shutdown()
2231 {
2232         game_stopped = 2;
2233
2234         if(world_initialized > 0)
2235         {
2236                 world_initialized = 0;
2237                 LOG_TRACE("Saving persistent data...");
2238                 Ban_SaveBans();
2239
2240                 // playerstats with unfinished match
2241                 PlayerStats_GameReport(false);
2242
2243                 if(!cheatcount_total)
2244                 {
2245                         if(autocvar_sv_db_saveasdump)
2246                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2247                         else
2248                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2249                 }
2250                 if(autocvar_developer > 0)
2251                 {
2252                         if(autocvar_sv_db_saveasdump)
2253                                 db_dump(TemporaryDB, "server-temp.db");
2254                         else
2255                                 db_save(TemporaryDB, "server-temp.db");
2256                 }
2257                 CheatShutdown(); // must be after cheatcount check
2258                 db_close(ServerProgsDB);
2259                 db_close(TemporaryDB);
2260                 LOG_TRACE("Saving persistent data... done!");
2261                 // tell the bot system the game is ending now
2262                 bot_endgame();
2263
2264                 WeaponStats_Shutdown();
2265                 MapInfo_Shutdown();
2266         }
2267         else if(world_initialized == 0)
2268         {
2269                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2270         }
2271         else
2272         {
2273                 __init_dedicated_server_shutdown();
2274         }
2275 }