qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2 #include "_all.qh"
   3
   4 #include "anticheat.qh"
   5 #include "antilag.qh"
   6 #include "bot/bot.qh"
   7 #include "campaign.qh"
   8 #include "cheats.qh"
   9 #include "cl_client.qh"
  10 #include "command/common.qh"
  11 #include "command/getreplies.qh"
  12 #include "command/sv_cmd.qh"
  13 #include "command/vote.qh"
  14 #include "g_hook.qh"
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include "mutators/mutators_include.qh"
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "teamplay.qh"
  21 #include "waypointsprites.qh"
  22 #include "weapons/weaponstats.qh"
  23 #include "../common/buffs.qh"
  24 #include "../common/constants.qh"
  25 #include "../common/deathtypes.qh"
  26 #include "../common/effects.qh"
  27 #include "../common/mapinfo.qh"
  28 #include "../common/monsters/all.qh"
  29 #include "../common/monsters/sv_monsters.qh"
  30 #include "../common/vehicles/all.qh"
  31 #include "../common/notifications.qh"
  32 #include "../common/playerstats.qh"
  33 #include "../common/stats.qh"
  34 #include "../common/teams.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/all.qh"
  37 #include "../common/weapons/all.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  58                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  59                 WriteByte(MSG_BROADCAST, self.cnt);
  60                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  62                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  63
  64                 // record latency times for clients throughout the match so we can report it to playerstats
  65                 if(time > (e.latency_time + LATENCY_THINKRATE))
  66                 {
  67                         e.latency_sum += e.ping;
  68                         e.latency_cnt += 1;
  69                         e.latency_time = time;
  70                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  71                 }
  72         }
  73         else
  74         {
  75                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  76                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  77                 WriteByte(MSG_BROADCAST, self.cnt);
  78                 WriteShort(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81         }
  82         self.cnt = (self.cnt + 1) % maxclients;
  83 }
  84 void PingPLReport_Spawn()
  85 {
  86         pingplreport = spawn();
  87         pingplreport.classname = "pingplreport";
  88         pingplreport.think = PingPLReport_Think;
  89         pingplreport.nextthink = time;
  90 }
  91
  92 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  93 string redirection_target;
  94 float world_initialized;
  95
  96 string GetGametype();
  97 void ShuffleMaplist();
  98
  99 void SetDefaultAlpha()
 100 {
 101         if(autocvar_g_running_guns)
 102         {
 103                 default_player_alpha = -1;
 104                 default_weapon_alpha = +1;
 105         }
 106         else if(g_cloaked)
 107         {
 108                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 109                 default_weapon_alpha = default_player_alpha;
 110         }
 111         else
 112         {
 113                 default_player_alpha = autocvar_g_player_alpha;
 114                 if(default_player_alpha == 0)
 115                         default_player_alpha = 1;
 116                 default_weapon_alpha = default_player_alpha;
 117         }
 118 }
 119
 120 void GotoFirstMap()
 121 {
 122         float n;
 123         if(autocvar__sv_init)
 124         {
 125                 // cvar_set("_sv_init", "0");
 126                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 127                 // to this "init" map on a dedicated server will cause no permanent
 128                 // harm
 129                 if(autocvar_g_maplist_shuffle)
 130                         ShuffleMaplist();
 131                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 132                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 133
 134                 MapInfo_Enumerate();
 135                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 136
 137                 if(!DoNextMapOverride(1))
 138                         GotoNextMap(1);
 139
 140                 return;
 141         }
 142
 143         if(time < 5)
 144         {
 145                 self.nextthink = time;
 146         }
 147         else
 148         {
 149                 self.nextthink = time + 1;
 150                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 151         }
 152 }
 153
 154 void cvar_changes_init()
 155 {
 156         float h;
 157         string k, v, d;
 158         float n, i, adding, pureadding;
 159
 160         if(cvar_changes)
 161                 strunzone(cvar_changes);
 162         cvar_changes = string_null;
 163         if(cvar_purechanges)
 164                 strunzone(cvar_purechanges);
 165         cvar_purechanges = string_null;
 166         cvar_purechanges_count = 0;
 167
 168         h = buf_create();
 169         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 170         n = buf_getsize(h);
 171
 172         adding = true;
 173         pureadding = true;
 174
 175         for(i = 0; i < n; ++i)
 176         {
 177                 k = bufstr_get(h, i);
 178
 179 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 180 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 181 #define BADCVAR(p) if(k == p) continue
 182
 183                 // general excludes and namespaces for server admin used cvars
 184                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 185
 186                 // internal
 187                 BADPREFIX("csqc_");
 188                 BADPREFIX("cvar_check_");
 189                 BADCVAR("gamecfg");
 190                 BADCVAR("g_configversion");
 191                 BADCVAR("g_maplist_index");
 192                 BADCVAR("halflifebsp");
 193                 BADCVAR("sv_mapformat_is_quake2");
 194                 BADCVAR("sv_mapformat_is_quake3");
 195                 BADPREFIX("sv_world");
 196
 197                 // client
 198                 BADPREFIX("chase_");
 199                 BADPREFIX("cl_");
 200                 BADPREFIX("con_");
 201                 BADPREFIX("scoreboard_");
 202                 BADPREFIX("g_campaign");
 203                 BADPREFIX("g_waypointsprite_");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("hud_");
 207                 BADPREFIX("m_");
 208                 BADPREFIX("menu_");
 209                 BADPREFIX("net_slist_");
 210                 BADPREFIX("r_");
 211                 BADPREFIX("sbar_");
 212                 BADPREFIX("scr_");
 213                 BADPREFIX("snd_");
 214                 BADPREFIX("show");
 215                 BADPREFIX("sensitivity");
 216                 BADPREFIX("userbind");
 217                 BADPREFIX("v_");
 218                 BADPREFIX("vid_");
 219                 BADPREFIX("crosshair");
 220                 BADCVAR("mod_q3bsp_lightmapmergepower");
 221                 BADCVAR("mod_q3bsp_nolightmaps");
 222                 BADCVAR("fov");
 223                 BADCVAR("mastervolume");
 224                 BADCVAR("volume");
 225                 BADCVAR("bgmvolume");
 226
 227                 // private
 228                 BADCVAR("developer");
 229                 BADCVAR("log_dest_udp");
 230                 BADCVAR("net_address");
 231                 BADCVAR("net_address_ipv6");
 232                 BADCVAR("port");
 233                 BADCVAR("savedgamecfg");
 234                 BADCVAR("serverconfig");
 235                 BADCVAR("sv_autoscreenshot");
 236                 BADCVAR("sv_heartbeatperiod");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timeformat");
 241                 BADCVAR("timestamps");
 242                 BADPREFIX("developer_");
 243                 BADPREFIX("g_ban_");
 244                 BADPREFIX("g_banned_list");
 245                 BADPREFIX("g_chat_flood_");
 246                 BADPREFIX("g_ghost_items");
 247                 BADPREFIX("g_playerstats_");
 248                 BADPREFIX("g_respawn_ghosts");
 249                 BADPREFIX("g_voice_flood_");
 250                 BADPREFIX("log_file");
 251                 BADPREFIX("rcon_");
 252                 BADPREFIX("sv_allowdownloads");
 253                 BADPREFIX("sv_autodemo");
 254                 BADPREFIX("sv_curl_");
 255                 BADPREFIX("sv_eventlog");
 256                 BADPREFIX("sv_logscores_");
 257                 BADPREFIX("sv_master");
 258                 BADPREFIX("sv_weaponstats_");
 259                 BADPREFIX("sv_waypointsprite_");
 260                 BADCVAR("rescan_pending");
 261
 262                 // these can contain player IDs, so better hide
 263                 BADPREFIX("g_forced_team_");
 264
 265                 // mapinfo
 266                 BADCVAR("fraglimit");
 267                 BADCVAR("g_assault");
 268                 BADCVAR("g_ca");
 269                 BADCVAR("g_ca_teams");
 270                 BADCVAR("g_ctf");
 271                 BADCVAR("g_cts");
 272                 BADCVAR("g_dm");
 273                 BADCVAR("g_domination");
 274                 BADCVAR("g_domination_default_teams");
 275                 BADCVAR("g_freezetag");
 276                 BADCVAR("g_freezetag_teams");
 277                 BADCVAR("g_invasion_teams");
 278                 BADCVAR("g_keepaway");
 279                 BADCVAR("g_keyhunt");
 280                 BADCVAR("g_keyhunt_teams");
 281                 BADCVAR("g_lms");
 282                 BADCVAR("g_nexball");
 283                 BADCVAR("g_onslaught");
 284                 BADCVAR("g_race");
 285                 BADCVAR("g_race_qualifying_timelimit");
 286                 BADCVAR("g_tdm");
 287                 BADCVAR("g_tdm_teams");
 288                 BADCVAR("leadlimit");
 289                 BADCVAR("nextmap");
 290                 BADCVAR("teamplay");
 291                 BADCVAR("timelimit");
 292
 293                 // long
 294                 BADCVAR("hostname");
 295                 BADCVAR("g_maplist");
 296                 BADCVAR("g_maplist_mostrecent");
 297                 BADCVAR("sv_motd");
 298
 299                 v = cvar_string(k);
 300                 d = cvar_defstring(k);
 301                 if(v == d)
 302                         continue;
 303
 304                 if(adding)
 305                 {
 306                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 307                         if(strlen(cvar_changes) > 16384)
 308                         {
 309                                 cvar_changes = "// too many settings have been changed to show them here\n";
 310                                 adding = 0;
 311                         }
 312                 }
 313
 314                 // now check if the changes are actually gameplay relevant
 315
 316                 // does nothing visible
 317                 BADCVAR("captureleadlimit_override");
 318                 BADCVAR("g_balance_kill_delay");
 319                 BADCVAR("g_ca_point_limit");
 320                 BADCVAR("g_ca_point_leadlimit");
 321                 BADCVAR("g_ctf_captimerecord_always");
 322                 BADCVAR("g_ctf_flag_glowtrails");
 323                 BADCVAR("g_ctf_flag_pickup_verbosename");
 324                 BADCVAR("g_domination_point_leadlimit");
 325                 BADCVAR("g_forced_respawn");
 326                 BADCVAR("g_freezetag_point_limit");
 327                 BADCVAR("g_freezetag_point_leadlimit");
 328                 BADCVAR("g_keyhunt_point_leadlimit");
 329                 BADPREFIX("g_mod_");
 330                 BADCVAR("g_invasion_point_limit");
 331                 BADCVAR("g_nexball_goalleadlimit");
 332                 BADCVAR("g_tdm_point_limit");
 333                 BADCVAR("g_tdm_point_leadlimit");
 334                 BADCVAR("leadlimit_and_fraglimit");
 335                 BADCVAR("leadlimit_override");
 336                 BADCVAR("pausable");
 337                 BADCVAR("sv_allow_fullbright");
 338                 BADCVAR("sv_checkforpacketsduringsleep");
 339                 BADCVAR("sv_timeout");
 340                 BADPREFIX("sv_timeout_");
 341                 BADPREFIX("crypto_");
 342                 BADPREFIX("g_chat_");
 343                 BADPREFIX("g_ctf_captimerecord_");
 344                 BADPREFIX("g_maplist_votable_");
 345                 BADPREFIX("net_");
 346                 BADPREFIX("prvm_");
 347                 BADPREFIX("skill_");
 348                 BADPREFIX("sv_cullentities_");
 349                 BADPREFIX("sv_maxidle_");
 350                 BADPREFIX("sv_vote_");
 351                 BADPREFIX("timelimit_");
 352                 BADCVAR("gameversion");
 353                 BADPREFIX("gameversion_");
 354                 BADCVAR("sv_namechangetimer");
 355
 356                 // allowed changes to server admins (please sync this to server.cfg)
 357                 // vi commands:
 358                 //   :/"impure"/,$d
 359                 //   :g!,^\/\/[^ /],d
 360                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 361                 //   :%!sort
 362                 // yes, this does contain some redundant stuff, don't really care
 363                 BADCVAR("bot_config_file");
 364                 BADCVAR("bot_number");
 365                 BADCVAR("bot_prefix");
 366                 BADCVAR("bot_suffix");
 367                 BADCVAR("capturelimit_override");
 368                 BADCVAR("fraglimit_override");
 369                 BADCVAR("gametype");
 370                 BADCVAR("g_antilag");
 371                 BADCVAR("g_balance_teams");
 372                 BADCVAR("g_balance_teams_prevent_imbalance");
 373                 BADCVAR("g_balance_teams_scorefactor");
 374                 BADCVAR("g_ban_sync_trusted_servers");
 375                 BADCVAR("g_ban_sync_uri");
 376                 BADCVAR("g_ca_teams_override");
 377                 BADCVAR("g_ctf_ignore_frags");
 378                 BADCVAR("g_domination_point_limit");
 379                 BADCVAR("g_domination_teams_override");
 380                 BADCVAR("g_freezetag_teams_override");
 381                 BADCVAR("g_friendlyfire");
 382                 BADCVAR("g_fullbrightitems");
 383                 BADCVAR("g_fullbrightplayers");
 384                 BADCVAR("g_keyhunt_point_limit");
 385                 BADCVAR("g_keyhunt_teams_override");
 386                 BADCVAR("g_lms_lives_override");
 387                 BADCVAR("g_maplist");
 388                 BADCVAR("g_maplist_check_waypoints");
 389                 BADCVAR("g_maplist_mostrecent_count");
 390                 BADCVAR("g_maplist_shuffle");
 391                 BADCVAR("g_maplist_votable");
 392                 BADCVAR("g_maplist_votable_abstain");
 393                 BADCVAR("g_maplist_votable_nodetail");
 394                 BADCVAR("g_maplist_votable_suggestions");
 395                 BADCVAR("g_maxplayers");
 396                 BADCVAR("g_mirrordamage");
 397                 BADCVAR("g_nexball_goallimit");
 398                 BADCVAR("g_powerups");
 399                 BADCVAR("g_start_delay");
 400                 BADCVAR("g_tdm_teams_override");
 401                 BADCVAR("g_warmup");
 402                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 403                 BADCVAR("hostname");
 404                 BADCVAR("log_file");
 405                 BADCVAR("maxplayers");
 406                 BADCVAR("minplayers");
 407                 BADCVAR("net_address");
 408                 BADCVAR("port");
 409                 BADCVAR("rcon_password");
 410                 BADCVAR("rcon_restricted_commands");
 411                 BADCVAR("rcon_restricted_password");
 412                 BADCVAR("skill");
 413                 BADCVAR("sv_adminnick");
 414                 BADCVAR("sv_autoscreenshot");
 415                 BADCVAR("sv_autotaunt");
 416                 BADCVAR("sv_curl_defaulturl");
 417                 BADCVAR("sv_defaultcharacter");
 418                 BADCVAR("sv_defaultplayercolors");
 419                 BADCVAR("sv_defaultplayermodel");
 420                 BADCVAR("sv_defaultplayerskin");
 421                 BADCVAR("sv_maxidle");
 422                 BADCVAR("sv_maxrate");
 423                 BADCVAR("sv_motd");
 424                 BADCVAR("sv_public");
 425                 BADCVAR("sv_ready_restart");
 426                 BADCVAR("sv_status_privacy");
 427                 BADCVAR("sv_taunt");
 428                 BADCVAR("sv_vote_call");
 429                 BADCVAR("sv_vote_commands");
 430                 BADCVAR("sv_vote_majority_factor");
 431                 BADCVAR("sv_vote_master");
 432                 BADCVAR("sv_vote_master_commands");
 433                 BADCVAR("sv_vote_master_password");
 434                 BADCVAR("sv_vote_simple_majority_factor");
 435                 BADCVAR("teamplay_mode");
 436                 BADCVAR("timelimit_override");
 437                 BADCVAR("g_spawnshieldtime");
 438                 BADPREFIX("g_warmup_");
 439                 BADPREFIX("sv_ready_restart_");
 440
 441                 // mutators that announce themselves properly to the server browser
 442                 BADCVAR("g_instagib");
 443                 BADCVAR("g_new_toys");
 444                 BADCVAR("g_nix");
 445                 BADCVAR("g_grappling_hook");
 446                 BADCVAR("g_jetpack");
 447
 448 #undef BADPREFIX
 449 #undef BADCVAR
 450
 451                 if(pureadding)
 452                 {
 453                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 454                         if(strlen(cvar_purechanges) > 16384)
 455                         {
 456                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 457                                 pureadding = 0;
 458                         }
 459                 }
 460                 ++cvar_purechanges_count;
 461                 // WARNING: this variable is used for the server list
 462                 // NEVER dare to skip this code!
 463                 // Hacks to intentionally appearing as "pure server" even though you DO have
 464                 // modified settings may be punished by removal from the server list.
 465                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 466                 // though.
 467         }
 468         buf_del(h);
 469         if(cvar_changes == "")
 470                 cvar_changes = "// this server runs at default server settings\n";
 471         else
 472                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 473         cvar_changes = strzone(cvar_changes);
 474         if(cvar_purechanges == "")
 475                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 476         else
 477                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 478         cvar_purechanges = strzone(cvar_purechanges);
 479 }
 480
 481 void detect_maptype()
 482 {
 483 #if 0
 484         vector o, v;
 485         float i;
 486
 487         for (;;)
 488         {
 489                 o = world.mins;
 490                 o.x += random() * (world.maxs.x - world.mins.x);
 491                 o.y += random() * (world.maxs.y - world.mins.y);
 492                 o.z += random() * (world.maxs.z - world.mins.z);
 493
 494                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 495                 if(trace_fraction == 1)
 496                         continue;
 497
 498                 v = trace_endpos;
 499
 500                 for(i = 0; i < 64; i += 4)
 501                 {
 502                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 503         if(trace_fraction == 1)
 504                 continue;
 505                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 506                 }
 507
 508                 break;
 509         }
 510 #endif
 511 }
 512
 513 entity randomseed;
 514 float RandomSeed_Send(entity to, int sf)
 515 {
 516         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 517         WriteShort(MSG_ENTITY, self.cnt);
 518         return true;
 519 }
 520 void RandomSeed_Think()
 521 {
 522         self.cnt = bound(0, floor(random() * 65536), 65535);
 523         self.nextthink = time + 5;
 524
 525         self.SendFlags |= 1;
 526 }
 527 void RandomSeed_Spawn()
 528 {
 529         randomseed = spawn();
 530         randomseed.think = RandomSeed_Think;
 531         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 532
 533         entity oldself;
 534         oldself = self;
 535         self = randomseed;
 536         self.think(); // sets random seed and nextthink
 537         self = oldself;
 538 }
 539
 540 void spawnfunc___init_dedicated_server(void)
 541 {
 542         // handler for _init/_init map (only for dedicated server initialization)
 543
 544         world_initialized = -1; // don't complain
 545         cvar = cvar_normal;
 546         cvar_string = cvar_string_normal;
 547         cvar_set = cvar_set_normal;
 548
 549         remove = remove_unsafely;
 550
 551         entity e;
 552         e = spawn();
 553         e.think = GotoFirstMap;
 554         e.nextthink = time; // this is usually 1 at this point
 555
 556         e = spawn();
 557         e.classname = "info_player_deathmatch"; // safeguard against player joining
 558
 559         self.classname = "worldspawn"; // safeguard against various stuff ;)
 560
 561         // needs to be done so early because of the constants they create
 562         static_init();
 563         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 564         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 565         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 566         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 567
 568         MapInfo_Enumerate();
 569         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 570 }
 571
 572 void Map_MarkAsRecent(string m);
 573 float world_already_spawned;
 574 void Nagger_Init();
 575 void ClientInit_Spawn();
 576 void WeaponStats_Init();
 577 void WeaponStats_Shutdown();
 578 void Physics_AddStats();
 579 void spawnfunc_worldspawn (void)
 580 {
 581         float fd, l, j, n;
 582         string s;
 583
 584         cvar = cvar_normal;
 585         cvar_string = cvar_string_normal;
 586         cvar_set = cvar_set_normal;
 587
 588         if(world_already_spawned)
 589                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 590         world_already_spawned = true;
 591
 592         remove = remove_safely; // during spawning, watch what you remove!
 593
 594         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 595
 596         compressShortVector_init();
 597
 598         entity head;
 599         head = nextent(world);
 600         maxclients = 0;
 601         while(head)
 602         {
 603                 ++maxclients;
 604                 head = nextent(head);
 605         }
 606
 607         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 608
 609         // needs to be done so early because of the constants they create
 610         static_init();
 611         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 612         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 613         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 614         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 615
 616         initialize_minigames();
 617
 618         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 619
 620         TemporaryDB = db_create();
 621
 622         // 0 normal
 623         lightstyle(0, "m");
 624
 625         // 1 FLICKER (first variety)
 626         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 627
 628         // 2 SLOW STRONG PULSE
 629         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 630
 631         // 3 CANDLE (first variety)
 632         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 633
 634         // 4 FAST STROBE
 635         lightstyle(4, "mamamamamama");
 636
 637         // 5 GENTLE PULSE 1
 638         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 639
 640         // 6 FLICKER (second variety)
 641         lightstyle(6, "nmonqnmomnmomomno");
 642
 643         // 7 CANDLE (second variety)
 644         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 645
 646         // 8 CANDLE (third variety)
 647         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 648
 649         // 9 SLOW STROBE (fourth variety)
 650         lightstyle(9, "aaaaaaaazzzzzzzz");
 651
 652         // 10 FLUORESCENT FLICKER
 653         lightstyle(10, "mmamammmmammamamaaamammma");
 654
 655         // 11 SLOW PULSE NOT FADE TO BLACK
 656         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 657
 658         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 659
 660         // 63 testing
 661         lightstyle(63, "a");
 662
 663         if(autocvar_g_campaign)
 664                 CampaignPreInit();
 665
 666         Map_MarkAsRecent(mapname);
 667
 668         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 669
 670         precache_model ("null"); // we need this one before InitGameplayMode
 671         InitGameplayMode();
 672         readlevelcvars();
 673         GrappleHookInit();
 674
 675         player_count = 0;
 676         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 677         if(bot_waypoints_for_items == 1)
 678                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 679                         bot_waypoints_for_items = 0;
 680
 681         precache();
 682
 683         WaypointSprite_Init();
 684
 685         GameLogInit(); // prepare everything
 686         // NOTE for matchid:
 687         // changing the logic generating it is okay. But:
 688         // it HAS to stay <= 64 chars
 689         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 690         if(autocvar_sv_eventlog)
 691         {
 692                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 693                 matchid = strzone(s);
 694
 695                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 696                 s = ":gameinfo:mutators:LIST";
 697
 698                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 699                 s = ret_string;
 700
 701                 // simple, probably not good in the mutator system
 702                 if(autocvar_g_grappling_hook)
 703                         s = strcat(s, ":grappling_hook");
 704
 705                 // initialiation stuff, not good in the mutator system
 706                 if(!autocvar_g_use_ammunition)
 707                         s = strcat(s, ":no_use_ammunition");
 708
 709                 // initialiation stuff, not good in the mutator system
 710                 if(autocvar_g_pickup_items == 0)
 711                         s = strcat(s, ":no_pickup_items");
 712                 if(autocvar_g_pickup_items > 0)
 713                         s = strcat(s, ":pickup_items");
 714
 715                 // initialiation stuff, not good in the mutator system
 716                 if(autocvar_g_weaponarena != "0")
 717                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 718
 719                 // TODO to mutator system
 720                 if(autocvar_g_norecoil)
 721                         s = strcat(s, ":norecoil");
 722
 723                 // TODO to mutator system
 724                 if(autocvar_g_powerups == 0)
 725                         s = strcat(s, ":no_powerups");
 726                 if(autocvar_g_powerups > 0)
 727                         s = strcat(s, ":powerups");
 728
 729                 GameLogEcho(s);
 730                 GameLogEcho(":gameinfo:end");
 731         }
 732         else
 733                 matchid = strzone(ftos(random()));
 734
 735         cvar_set("nextmap", "");
 736
 737         SetDefaultAlpha();
 738
 739         if(autocvar_g_campaign)
 740                 CampaignPostInit();
 741
 742         Ban_LoadBans();
 743
 744         MapInfo_Enumerate();
 745         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 746
 747         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 748         {
 749                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 750                 if(fd != -1)
 751                 {
 752                         while((s = fgets(fd)))
 753                         {
 754                                 l = tokenize_console(s);
 755                                 if(l < 2)
 756                                         continue;
 757                                 if(argv(0) == "cd")
 758                                 {
 759                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 760                                         print("  cdtrack ", argv(2), "\n");
 761                                 }
 762                                 else if(argv(0) == "fog")
 763                                 {
 764                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 765                                         print("  \"fog\" \"", s, "\"\n");
 766                                 }
 767                                 else if(argv(0) == "set")
 768                                 {
 769                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 770                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 771                                 }
 772                                 else if(argv(0) != "//")
 773                                 {
 774                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 775                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 776                                 }
 777                         }
 778                         fclose(fd);
 779                 }
 780         }
 781
 782         WeaponStats_Init();
 783
 784         WepSet_AddStat();
 785         WepSet_AddStat_InMap();
 786         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 787         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 788         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 789         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 790         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 791         Nagger_Init();
 792
 793         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 794         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 795         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 796         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 797         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 798         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 799         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 800         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 801         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 802         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 803         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 804         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 805         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 806         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 807         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 808
 809         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 810         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 811
 812         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 813
 814         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 815
 816         // freeze attacks
 817         addstat(STAT_FROZEN, AS_INT, frozen);
 818         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 819
 820         // physics
 821         Physics_AddStats();
 822
 823         // new properties
 824         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 825         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 826         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 827         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 828         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 829         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 830         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 831         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 832         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 833         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 834         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 835         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 836         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 837         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 838         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 839         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 840         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 841         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 842         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 843
 844         // secrets
 845         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 846         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 847
 848         // monsters
 849         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 850         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 851
 852         // misc
 853         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 854
 855         next_pingtime = time + 5;
 856
 857         detect_maptype();
 858
 859         // set up information replies for clients and server to use
 860         maplist_reply = strzone(getmaplist());
 861         lsmaps_reply = strzone(getlsmaps());
 862         monsterlist_reply = strzone(getmonsterlist());
 863         for(int i = 0; i < 10; ++i)
 864         {
 865                 s = getrecords(i);
 866                 if (s)
 867                         records_reply[i] = strzone(s);
 868         }
 869         ladder_reply = strzone(getladder());
 870         rankings_reply = strzone(getrankings());
 871
 872         // begin other init
 873         ClientInit_Spawn();
 874         RandomSeed_Spawn();
 875         PingPLReport_Spawn();
 876
 877         CheatInit();
 878
 879         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 880
 881         // fill sv_curl_serverpackages from .serverpackage files
 882         if(autocvar_sv_curl_serverpackages_auto)
 883         {
 884                 s = "";
 885                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 886                 for(int i = 0; i < n; ++i)
 887                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 888                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 889                                 s = strcat(s, " ", argv(i));
 890                 fd = search_begin("*-serverpackage.txt", true, false);
 891                 if(fd >= 0)
 892                 {
 893                         j = search_getsize(fd);
 894                         for(int i = 0; i < j; ++i)
 895                                 s = strcat(s, " ", search_getfilename(fd, i));
 896                         search_end(fd);
 897                 }
 898                 fd = search_begin("*.serverpackage", true, false);
 899                 if(fd >= 0)
 900                 {
 901                         j = search_getsize(fd);
 902                         for(int i = 0; i < j; ++i)
 903                                 s = strcat(s, " ", search_getfilename(fd, i));
 904                         search_end(fd);
 905                 }
 906                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 907         }
 908
 909         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 910         modname = "Xonotic";
 911         // physics/balance/config changes that count as mod
 912         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 913                 modname = cvar_string("g_mod_physics");
 914         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 915                 modname = cvar_string("g_mod_balance");
 916         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 917                 modname = cvar_string("g_mod_config");
 918         // extra mutators that deserve to count as mod
 919         MUTATOR_CALLHOOK(SetModname);
 920
 921         // save it for later
 922         modname = strzone(modname);
 923
 924         WinningConditionHelper(); // set worldstatus
 925
 926         world_initialized = 1;
 927 }
 928
 929 void spawnfunc_light (void)
 930 {
 931         //makestatic (self); // Who the f___ did that?
 932         remove(self);
 933 }
 934
 935 string GetGametype()
 936 {
 937         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 938 }
 939
 940 string GetMapname()
 941 {
 942         return mapname;
 943 }
 944
 945 float Map_Count, Map_Current;
 946 string Map_Current_Name;
 947
 948 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 949 float GetMaplistPosition()
 950 {
 951         float pos, idx;
 952         string map;
 953
 954         map = GetMapname();
 955         idx = autocvar_g_maplist_index;
 956
 957         if(idx >= 0)
 958                 if(idx < Map_Count)
 959                         if(map == argv(idx))
 960                                 return idx;
 961
 962         for(pos = 0; pos < Map_Count; ++pos)
 963                 if(map == argv(pos))
 964                         return pos;
 965
 966         // resume normal maplist rotation if current map is not in g_maplist
 967         return idx;
 968 }
 969
 970 float MapHasRightSize(string map)
 971 {
 972         float fh;
 973         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 974         if(autocvar_g_maplist_check_waypoints)
 975         {
 976                 dprint("checkwp "); dprint(map);
 977                 if(!fexists(strcat("maps/", map, ".waypoints")))
 978                 {
 979                         dprint(": no waypoints\n");
 980                         return false;
 981                 }
 982                 dprint(": has waypoints\n");
 983         }
 984
 985         // open map size restriction file
 986         dprint("opensize "); dprint(map);
 987         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 988         if(fh >= 0)
 989         {
 990                 float mapmin, mapmax;
 991                 dprint(": ok, ");
 992                 mapmin = stof(fgets(fh));
 993                 mapmax = stof(fgets(fh));
 994                 fclose(fh);
 995                 if(player_count < mapmin)
 996                 {
 997                         dprint("not enough\n");
 998                         return false;
 999                 }
1000                 if(player_count > mapmax)
1001                 {
1002                         dprint("too many\n");
1003                         return false;
1004                 }
1005                 dprint("right size\n");
1006                 return true;
1007         }
1008         dprint(": not found\n");
1009         return true;
1010 }
1011
1012 string Map_Filename(float position)
1013 {
1014         return strcat("maps/", argv(position), ".bsp");
1015 }
1016
1017 string strwords(string s, float w)
1018 {
1019         float endpos;
1020         for(endpos = 0; w && endpos >= 0; --w)
1021                 endpos = strstrofs(s, " ", endpos + 1);
1022         if(endpos < 0)
1023                 return s;
1024         else
1025                 return substring(s, 0, endpos);
1026 }
1027
1028 float strhasword(string s, string w)
1029 {
1030         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1031 }
1032
1033 void Map_MarkAsRecent(string m)
1034 {
1035         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1036 }
1037
1038 float Map_IsRecent(string m)
1039 {
1040         return strhasword(autocvar_g_maplist_mostrecent, m);
1041 }
1042
1043 float Map_Check(float position, float pass)
1044 {
1045         string filename;
1046         string map_next;
1047         map_next = argv(position);
1048         if(pass <= 1)
1049         {
1050                 if(Map_IsRecent(map_next))
1051                         return 0;
1052         }
1053         filename = Map_Filename(position);
1054         if(MapInfo_CheckMap(map_next))
1055         {
1056                 if(pass == 2)
1057                         return 1;
1058                 if(MapHasRightSize(map_next))
1059                         return 1;
1060                 return 0;
1061         }
1062         else
1063                 dprint( "Couldn't select '", filename, "'..\n" );
1064
1065         return 0;
1066 }
1067
1068 void Map_Goto_SetStr(string nextmapname)
1069 {
1070         if(getmapname_stored != "")
1071                 strunzone(getmapname_stored);
1072         if(nextmapname == "")
1073                 getmapname_stored = "";
1074         else
1075                 getmapname_stored = strzone(nextmapname);
1076 }
1077
1078 void Map_Goto_SetFloat(float position)
1079 {
1080         cvar_set("g_maplist_index", ftos(position));
1081         Map_Goto_SetStr(argv(position));
1082 }
1083
1084 void Map_Goto(float reinit)
1085 {
1086         MapInfo_LoadMap(getmapname_stored, reinit);
1087 }
1088
1089 // return codes of map selectors:
1090 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1091 //   -2 = permanent failure
1092 float() MaplistMethod_Iterate = // usual method
1093 {
1094         float pass, i;
1095
1096         dprint("Trying MaplistMethod_Iterate\n");
1097
1098         for(pass = 1; pass <= 2; ++pass)
1099         {
1100                 for(i = 1; i < Map_Count; ++i)
1101                 {
1102                         float mapindex;
1103                         mapindex = (i + Map_Current) % Map_Count;
1104                         if(Map_Check(mapindex, pass))
1105                                 return mapindex;
1106                 }
1107         }
1108         return -1;
1109 }
1110
1111 float() MaplistMethod_Repeat = // fallback method
1112 {
1113         dprint("Trying MaplistMethod_Repeat\n");
1114
1115         if(Map_Check(Map_Current, 2))
1116                 return Map_Current;
1117         return -2;
1118 }
1119
1120 float() MaplistMethod_Random = // random map selection
1121 {
1122         float i, imax;
1123
1124         dprint("Trying MaplistMethod_Random\n");
1125
1126         imax = 42;
1127
1128         for(i = 0; i <= imax; ++i)
1129         {
1130                 float mapindex;
1131                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1132                 if(Map_Check(mapindex, 1))
1133                         return mapindex;
1134         }
1135         return -1;
1136 }
1137
1138 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1139 // the exponent sets a bias on the map selection:
1140 // the higher the exponent, the less likely "shortly repeated" same maps are
1141 {
1142         float i, j, imax, insertpos;
1143
1144         dprint("Trying MaplistMethod_Shuffle\n");
1145
1146         imax = 42;
1147
1148         for(i = 0; i <= imax; ++i)
1149         {
1150                 string newlist;
1151
1152                 // now reinsert this at another position
1153                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1154                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1155                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1156                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1157
1158                 // insert the current map there
1159                 newlist = "";
1160                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1161                         newlist = strcat(newlist, " ", argv(j));
1162                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1163                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1164                         newlist = strcat(newlist, " ", argv(j));
1165                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1166                 cvar_set("g_maplist", newlist);
1167                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1168
1169                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1170                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1171                 if(Map_Check(Map_Current, 1))
1172                         return Map_Current;
1173         }
1174         return -1;
1175 }
1176
1177 void Maplist_Init()
1178 {
1179         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1180         float i;
1181         for (i = 0; i < Map_Count; ++i)
1182                 if (Map_Check(i, 2))
1183                         break;
1184         if (i == Map_Count)
1185         {
1186                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1187                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1188                 if(autocvar_g_maplist_shuffle)
1189                         ShuffleMaplist();
1190                 localcmd("\nmenu_cmd sync\n");
1191                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1192         }
1193         if(Map_Count == 0)
1194                 error("empty maplist, cannot select a new map");
1195         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1196
1197         if(Map_Current_Name)
1198                 strunzone(Map_Current_Name);
1199         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1200         // this may or may not be correct, but who cares, in the worst case a map
1201         // isn't chosen in the first pass that should have been
1202 }
1203
1204 string GetNextMap()
1205 {
1206         float nextMap;
1207
1208         Maplist_Init();
1209         nextMap = -1;
1210
1211         if(nextMap == -1)
1212                 if(autocvar_g_maplist_shuffle > 0)
1213                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1214
1215         if(nextMap == -1)
1216                 if(autocvar_g_maplist_selectrandom)
1217                         nextMap = MaplistMethod_Random();
1218
1219         if(nextMap == -1)
1220                 nextMap = MaplistMethod_Iterate();
1221
1222         if(nextMap == -1)
1223                 nextMap = MaplistMethod_Repeat();
1224
1225         if(nextMap >= 0)
1226         {
1227                 Map_Goto_SetFloat(nextMap);
1228                 return getmapname_stored;
1229         }
1230
1231         return "";
1232 }
1233
1234 float DoNextMapOverride(float reinit)
1235 {
1236         if(autocvar_g_campaign)
1237         {
1238                 CampaignPostIntermission();
1239                 alreadychangedlevel = true;
1240                 return true;
1241         }
1242         if(autocvar_quit_when_empty)
1243         {
1244                 if(player_count <= currentbots)
1245                 {
1246                         localcmd("quit\n");
1247                         alreadychangedlevel = true;
1248                         return true;
1249                 }
1250         }
1251         if(autocvar_quit_and_redirect != "")
1252         {
1253                 redirection_target = strzone(autocvar_quit_and_redirect);
1254                 alreadychangedlevel = true;
1255                 return true;
1256         }
1257         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1258         {
1259                 localcmd("restart\n");
1260                 alreadychangedlevel = true;
1261                 return true;
1262         }
1263         if(autocvar_nextmap != "")
1264         {
1265                 string m;
1266                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1267                 cvar_set("nextmap",m);
1268
1269                 if(!m || gametypevote)
1270                         return false;
1271                 if(autocvar_sv_vote_gametype)
1272                 {
1273                         Map_Goto_SetStr(m);
1274                         return false;
1275                 }
1276
1277                 if(MapInfo_CheckMap(m))
1278                 {
1279                         Map_Goto_SetStr(m);
1280                         Map_Goto(reinit);
1281                         alreadychangedlevel = true;
1282                         return true;
1283                 }
1284         }
1285         if(!reinit && autocvar_lastlevel)
1286         {
1287                 cvar_settemp_restore();
1288                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1289                 alreadychangedlevel = true;
1290                 return true;
1291         }
1292         return false;
1293 }
1294
1295 void GotoNextMap(float reinit)
1296 {
1297         //string nextmap;
1298         //float n, nummaps;
1299         //string s;
1300         if (alreadychangedlevel)
1301                 return;
1302         alreadychangedlevel = true;
1303
1304         string nextMap;
1305
1306         nextMap = GetNextMap();
1307         if(nextMap == "")
1308                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1309         Map_Goto(reinit);
1310 }
1311
1312
1313 /*
1314 ============
1315 IntermissionThink
1316
1317 When the player presses attack or jump, change to the next level
1318 ============
1319 */
1320 .float autoscreenshot;
1321 void IntermissionThink()
1322 {
1323         FixIntermissionClient(self);
1324
1325         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1326         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1327
1328         if( (server_screenshot || client_screenshot)
1329                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1330         {
1331                 self.autoscreenshot = -1;
1332                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1333                 return;
1334         }
1335
1336         if (time < intermission_exittime)
1337                 return;
1338
1339         if(!mapvote_initialized)
1340                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1341                         return;
1342
1343         MapVote_Start();
1344 }
1345
1346 /*
1347 ============
1348 FindIntermission
1349
1350 Returns the entity to view from
1351 ============
1352 */
1353 /*
1354 entity FindIntermission()
1355 {
1356         local   entity spot;
1357         local   float cyc;
1358
1359 // look for info_intermission first
1360         spot = find (world, classname, "info_intermission");
1361         if (spot)
1362         {       // pick a random one
1363                 cyc = random() * 4;
1364                 while (cyc > 1)
1365                 {
1366                         spot = find (spot, classname, "info_intermission");
1367                         if (!spot)
1368                                 spot = find (spot, classname, "info_intermission");
1369                         cyc = cyc - 1;
1370                 }
1371                 return spot;
1372         }
1373
1374 // then look for the start position
1375         spot = find (world, classname, "info_player_start");
1376         if (spot)
1377                 return spot;
1378
1379 // testinfo_player_start is only found in regioned levels
1380         spot = find (world, classname, "testplayerstart");
1381         if (spot)
1382                 return spot;
1383
1384 // then look for the start position
1385         spot = find (world, classname, "info_player_deathmatch");
1386         if (spot)
1387                 return spot;
1388
1389         //objerror ("FindIntermission: no spot");
1390         return world;
1391 }
1392 */
1393
1394 /*
1395 ===============================================================================
1396
1397 RULES
1398
1399 ===============================================================================
1400 */
1401
1402 void DumpStats(float final)
1403 {
1404         float file;
1405         string s;
1406         float to_console;
1407         float to_eventlog;
1408         float to_file;
1409         float i;
1410
1411         to_console = autocvar_sv_logscores_console;
1412         to_eventlog = autocvar_sv_eventlog;
1413         to_file = autocvar_sv_logscores_file;
1414
1415         if(!final)
1416         {
1417                 to_console = true; // always print printstats replies
1418                 to_eventlog = false; // but never print them to the event log
1419         }
1420
1421         if(to_eventlog)
1422                 if(autocvar_sv_eventlog_console)
1423                         to_console = false; // otherwise we get the output twice
1424
1425         if(final)
1426                 s = ":scores:";
1427         else
1428                 s = ":status:";
1429         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1430
1431         if(to_console)
1432                 print(s, "\n");
1433         if(to_eventlog)
1434                 GameLogEcho(s);
1435
1436         file = -1;
1437         if(to_file)
1438         {
1439                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1440                 if(file == -1)
1441                         to_file = false;
1442                 else
1443                         fputs(file, strcat(s, "\n"));
1444         }
1445
1446         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1447         if(to_console)
1448                 print(s, "\n");
1449         if(to_eventlog)
1450                 GameLogEcho(s);
1451         if(to_file)
1452                 fputs(file, strcat(s, "\n"));
1453
1454         FOR_EACH_CLIENT(other)
1455         {
1456                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1457                 {
1458                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1459                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1460                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1461                                 s = strcat(s, ftos(other.team), ":");
1462                         else
1463                                 s = strcat(s, "spectator:");
1464
1465                         if(to_console)
1466                                 print(s, other.netname, "\n");
1467                         if(to_eventlog)
1468                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1469                         if(to_file)
1470                                 fputs(file, strcat(s, other.netname, "\n"));
1471                 }
1472         }
1473
1474         if(teamplay)
1475         {
1476                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1477                 if(to_console)
1478                         print(s, "\n");
1479                 if(to_eventlog)
1480                         GameLogEcho(s);
1481                 if(to_file)
1482                         fputs(file, strcat(s, "\n"));
1483
1484                 for(i = 1; i < 16; ++i)
1485                 {
1486                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1487                         s = strcat(s, ":", ftos(i));
1488                         if(to_console)
1489                                 print(s, "\n");
1490                         if(to_eventlog)
1491                                 GameLogEcho(s);
1492                         if(to_file)
1493                                 fputs(file, strcat(s, "\n"));
1494                 }
1495         }
1496
1497         if(to_console)
1498                 print(":end\n");
1499         if(to_eventlog)
1500                 GameLogEcho(":end");
1501         if(to_file)
1502         {
1503                 fputs(file, ":end\n");
1504                 fclose(file);
1505         }
1506 }
1507
1508 void FixIntermissionClient(entity e)
1509 {
1510         string s;
1511         if(!e.autoscreenshot) // initial call
1512         {
1513                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1514                 e.health = -2342;
1515                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1516                 e.solid = SOLID_NOT;
1517                 e.movetype = MOVETYPE_NONE;
1518                 e.takedamage = DAMAGE_NO;
1519                 if(e.weaponentity)
1520                 {
1521                         e.weaponentity.effects = EF_NODRAW;
1522                         if (e.weaponentity.weaponentity)
1523                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1524                 }
1525                 if(IS_REAL_CLIENT(e))
1526                 {
1527                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1528                         s = autocvar_sv_intermission_cdtrack;
1529                         if(s != "")
1530                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1531                         msg_entity = e;
1532                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1533                 }
1534         }
1535 }
1536
1537 /*
1538 go to the next level for deathmatch
1539 only called if a time or frag limit has expired
1540 */
1541 void NextLevel()
1542 {
1543         gameover = true;
1544
1545         intermission_running = 1;
1546
1547 // enforce a wait time before allowing changelevel
1548         if(player_count > 0)
1549                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1550         else
1551                 intermission_exittime = -1;
1552
1553         /*
1554         WriteByte (MSG_ALL, SVC_CDTRACK);
1555         WriteByte (MSG_ALL, 3);
1556         WriteByte (MSG_ALL, 3);
1557         // done in FixIntermission
1558         */
1559
1560         //pos = FindIntermission ();
1561
1562         VoteReset();
1563
1564         DumpStats(true);
1565
1566         // send statistics
1567         PlayerStats_GameReport(true);
1568         WeaponStats_Shutdown();
1569
1570         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1571
1572         if(autocvar_sv_eventlog)
1573                 GameLogEcho(":gameover");
1574
1575         GameLogClose();
1576
1577         FOR_EACH_PLAYER(other) {
1578                 FixIntermissionClient(other);
1579                 if(other.winning)
1580                         bprint(other.netname, " ^7wins.\n");
1581         }
1582
1583         if(autocvar_g_campaign)
1584                 CampaignPreIntermission();
1585
1586         MUTATOR_CALLHOOK(MatchEnd);
1587
1588         localcmd("\nsv_hook_gameend\n");
1589 }
1590
1591 /*
1592 ============
1593 CheckRules_Player
1594
1595 Exit deathmatch games upon conditions
1596 ============
1597 */
1598 void CheckRules_Player()
1599 {
1600         if (gameover)   // someone else quit the game already
1601                 return;
1602
1603         if(self.deadflag == DEAD_NO)
1604                 self.play_time += frametime;
1605
1606         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1607         //   (div0: and that in CheckRules_World please)
1608 }
1609
1610
1611 float InitiateSuddenDeath()
1612 {
1613         // Check first whether normal overtimes could be added before initiating suddendeath mode
1614         // - for this timelimit_overtime needs to be >0 of course
1615         // - also check the winning condition calculated in the previous frame and only add normal overtime
1616         //   again, if at the point at which timelimit would be extended again, still no winner was found
1617         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1618         {
1619                 return 1; // need to call InitiateOvertime later
1620         }
1621         else
1622         {
1623                 if(!checkrules_suddendeathend)
1624                 {
1625                         if(autocvar_g_campaign)
1626                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1627                         else
1628                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1629                         if(g_race && !g_race_qualifying)
1630                                 race_StartCompleting();
1631                 }
1632                 return 0;
1633         }
1634 }
1635
1636 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1637 {
1638         ++checkrules_overtimesadded;
1639         //add one more overtime by simply extending the timelimit
1640         float tl;
1641         tl = autocvar_timelimit;
1642         tl += autocvar_timelimit_overtime;
1643         cvar_set("timelimit", ftos(tl));
1644
1645         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1646 }
1647
1648 float GetWinningCode(float fraglimitreached, float equality)
1649 {
1650         if(autocvar_g_campaign == 1)
1651                 if(fraglimitreached)
1652                         return WINNING_YES;
1653                 else
1654                         return WINNING_NO;
1655
1656         else
1657                 if(equality)
1658                         if(fraglimitreached)
1659                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1660                         else
1661                                 return WINNING_NEVER;
1662                 else
1663                         if(fraglimitreached)
1664                                 return WINNING_YES;
1665                         else
1666                                 return WINNING_NO;
1667 }
1668
1669 // set the .winning flag for exactly those players with a given field value
1670 void SetWinners(.float field, float value)
1671 {
1672         entity head;
1673         FOR_EACH_PLAYER(head)
1674                 head.winning = (head.(field) == value);
1675 }
1676
1677 // set the .winning flag for those players with a given field value
1678 void AddWinners(.float field, float value)
1679 {
1680         entity head;
1681         FOR_EACH_PLAYER(head)
1682                 if (head.(field) == value)
1683                         head.winning = 1;
1684 }
1685
1686 // clear the .winning flags
1687 void ClearWinners(void)
1688 {
1689         entity head;
1690         FOR_EACH_PLAYER(head)
1691                 head.winning = 0;
1692 }
1693
1694 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1695 // they win. Otherwise the defending team wins once the timelimit passes.
1696 void assault_new_round();
1697 float WinningCondition_Assault()
1698 {
1699         float status;
1700
1701         WinningConditionHelper(); // set worldstatus
1702
1703         status = WINNING_NO;
1704         // as the timelimit has not yet passed just assume the defending team will win
1705         if(assault_attacker_team == NUM_TEAM_1)
1706         {
1707                 SetWinners(team, NUM_TEAM_2);
1708         }
1709         else
1710         {
1711                 SetWinners(team, NUM_TEAM_1);
1712         }
1713
1714         entity ent;
1715         ent = find(world, classname, "target_assault_roundend");
1716         if(ent)
1717         {
1718                 if(ent.winning) // round end has been triggered by attacking team
1719                 {
1720                         bprint("ASSAULT: round completed...\n");
1721                         SetWinners(team, assault_attacker_team);
1722
1723                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1724
1725                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1726                         {
1727                                 status = WINNING_YES;
1728                         }
1729                         else
1730                         {
1731                                 entity oldself;
1732                                 oldself = self;
1733                                 self = ent;
1734                                 assault_new_round();
1735                                 self = oldself;
1736                         }
1737                 }
1738         }
1739
1740         return status;
1741 }
1742
1743 // LMS winning condition: game terminates if and only if there's at most one
1744 // one player who's living lives. Top two scores being equal cancels the time
1745 // limit.
1746 float WinningCondition_LMS()
1747 {
1748         entity head, head2;
1749         float have_player;
1750         float have_players;
1751         float l;
1752
1753         have_player = false;
1754         have_players = false;
1755         l = LMS_NewPlayerLives();
1756
1757         head = find(world, classname, "player");
1758         if(head)
1759                 have_player = true;
1760         head2 = find(head, classname, "player");
1761         if(head2)
1762                 have_players = true;
1763
1764         if(have_player)
1765         {
1766                 // we have at least one player
1767                 if(have_players)
1768                 {
1769                         // two or more active players - continue with the game
1770                 }
1771                 else
1772                 {
1773                         // exactly one player?
1774
1775                         ClearWinners();
1776                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1777
1778                         if(l)
1779                         {
1780                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1781                                 return WINNING_NO;
1782                         }
1783                         else
1784                         {
1785                                 // a winner!
1786                                 // and assign him his first place
1787                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1788                                 return WINNING_YES;
1789                         }
1790                 }
1791         }
1792         else
1793         {
1794                 // nobody is playing at all...
1795                 if(l)
1796                 {
1797                         // wait for players...
1798                 }
1799                 else
1800                 {
1801                         // SNAFU (maybe a draw game?)
1802                         ClearWinners();
1803                         dprint("No players, ending game.\n");
1804                         return WINNING_YES;
1805                 }
1806         }
1807
1808         // When we get here, we have at least two players who are actually LIVING,
1809         // now check if the top two players have equal score.
1810         WinningConditionHelper();
1811
1812         ClearWinners();
1813         if(WinningConditionHelper_winner)
1814                 WinningConditionHelper_winner.winning = true;
1815         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1816                 return WINNING_NEVER;
1817
1818         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1819         return WINNING_NO;
1820 }
1821
1822 void ShuffleMaplist()
1823 {
1824         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1825 }
1826
1827 float leaderfrags;
1828 float WinningCondition_Scores(float limit, float leadlimit)
1829 {
1830         float limitreached;
1831
1832         // TODO make everything use THIS winning condition (except LMS)
1833         WinningConditionHelper();
1834
1835         if(teamplay)
1836         {
1837                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1838                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1839                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1840                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1841         }
1842
1843         ClearWinners();
1844         if(WinningConditionHelper_winner)
1845                 WinningConditionHelper_winner.winning = 1;
1846         if(WinningConditionHelper_winnerteam >= 0)
1847                 SetWinners(team, WinningConditionHelper_winnerteam);
1848
1849         if(WinningConditionHelper_lowerisbetter)
1850         {
1851                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1852                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1853                 limit = -limit;
1854         }
1855
1856         if(WinningConditionHelper_zeroisworst)
1857                 leadlimit = 0; // not supported in this mode
1858
1859         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1860         // these modes always score in increments of 1, thus this makes sense
1861         {
1862                 if(leaderfrags != WinningConditionHelper_topscore)
1863                 {
1864                         leaderfrags = WinningConditionHelper_topscore;
1865
1866                         if (limit)
1867                         if (leaderfrags == limit - 1)
1868                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1869                         else if (leaderfrags == limit - 2)
1870                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1871                         else if (leaderfrags == limit - 3)
1872                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1873                 }
1874         }
1875
1876         limitreached = false;
1877         if(limit)
1878                 if(WinningConditionHelper_topscore >= limit)
1879                         limitreached = true;
1880         if(leadlimit)
1881         {
1882                 float leadlimitreached;
1883                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1884                 if(autocvar_leadlimit_and_fraglimit)
1885                         limitreached = (limitreached && leadlimitreached);
1886                 else
1887                         limitreached = (limitreached || leadlimitreached);
1888         }
1889
1890         if(limit)
1891                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1892
1893         return GetWinningCode(
1894                 WinningConditionHelper_topscore && limitreached,
1895                 WinningConditionHelper_equality
1896         );
1897 }
1898
1899 float WinningCondition_Race(float fraglimit)
1900 {
1901         float wc;
1902         entity p;
1903         float n, c;
1904
1905         n = 0;
1906         c = 0;
1907         FOR_EACH_PLAYER(p)
1908         {
1909                 ++n;
1910                 if(p.race_completed)
1911                         ++c;
1912         }
1913         if(n && (n == c))
1914                 return WINNING_YES;
1915         wc = WinningCondition_Scores(fraglimit, 0);
1916
1917         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1918         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1919         // do NOT support equality when the laps are all raced!
1920                 return WINNING_STARTSUDDENDEATHOVERTIME;
1921         else
1922                 return WINNING_NEVER;
1923 }
1924
1925 float WinningCondition_QualifyingThenRace(float limit)
1926 {
1927         float wc;
1928         wc = WinningCondition_Scores(limit, 0);
1929
1930         // NEVER initiate overtime
1931         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1932         {
1933                 return WINNING_YES;
1934         }
1935
1936         return wc;
1937 }
1938
1939 float WinningCondition_RanOutOfSpawns()
1940 {
1941         entity head;
1942
1943         if(have_team_spawns <= 0)
1944                 return WINNING_NO;
1945
1946         if(!autocvar_g_spawn_useallspawns)
1947                 return WINNING_NO;
1948
1949         if(!some_spawn_has_been_used)
1950                 return WINNING_NO;
1951
1952         team1_score = team2_score = team3_score = team4_score = 0;
1953
1954         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1955         {
1956                 if(head.team == NUM_TEAM_1)
1957                         team1_score = 1;
1958                 else if(head.team == NUM_TEAM_2)
1959                         team2_score = 1;
1960                 else if(head.team == NUM_TEAM_3)
1961                         team3_score = 1;
1962                 else if(head.team == NUM_TEAM_4)
1963                         team4_score = 1;
1964         }
1965
1966         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1967         {
1968                 if(head.team == NUM_TEAM_1)
1969                         team1_score = 1;
1970                 else if(head.team == NUM_TEAM_2)
1971                         team2_score = 1;
1972                 else if(head.team == NUM_TEAM_3)
1973                         team3_score = 1;
1974                 else if(head.team == NUM_TEAM_4)
1975                         team4_score = 1;
1976         }
1977
1978         ClearWinners();
1979         if(team1_score + team2_score + team3_score + team4_score == 0)
1980         {
1981                 checkrules_equality = true;
1982                 return WINNING_YES;
1983         }
1984         else if(team1_score + team2_score + team3_score + team4_score == 1)
1985         {
1986                 float t, i;
1987                 if(team1_score)
1988                         t = NUM_TEAM_1;
1989                 else if(team2_score)
1990                         t = NUM_TEAM_2;
1991                 else if(team3_score)
1992                         t = NUM_TEAM_3;
1993                 else // if(team4_score)
1994                         t = NUM_TEAM_4;
1995                 CheckAllowedTeams(world);
1996                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1997                 {
1998                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1999                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2000                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2001                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2002                 }
2003
2004                 AddWinners(team, t);
2005                 return WINNING_YES;
2006         }
2007         else
2008                 return WINNING_NO;
2009 }
2010
2011 /*
2012 ============
2013 CheckRules_World
2014
2015 Exit deathmatch games upon conditions
2016 ============
2017 */
2018 void CheckRules_World()
2019 {
2020         float timelimit;
2021         float fraglimit;
2022         float leadlimit;
2023
2024         VoteThink();
2025         MapVote_Think();
2026
2027         SetDefaultAlpha();
2028
2029         if (gameover)   // someone else quit the game already
2030         {
2031                 if(player_count == 0) // Nobody there? Then let's go to the next map
2032                         MapVote_Start();
2033                         // this will actually check the player count in the next frame
2034                         // again, but this shouldn't hurt
2035                 return;
2036         }
2037
2038         timelimit = autocvar_timelimit * 60;
2039         fraglimit = autocvar_fraglimit;
2040         leadlimit = autocvar_leadlimit;
2041
2042         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2043         {
2044                 if(timelimit > 0)
2045                         timelimit = 0; // timelimit is not made for warmup
2046                 if(fraglimit > 0)
2047                         fraglimit = 0; // no fraglimit for now
2048                 leadlimit = 0; // no leadlimit for now
2049         }
2050
2051         if(timelimit > 0)
2052         {
2053                 timelimit += game_starttime;
2054         }
2055         else if (timelimit < 0)
2056         {
2057                 // endmatch
2058                 NextLevel();
2059                 return;
2060         }
2061
2062         float wantovertime;
2063         wantovertime = 0;
2064
2065         if(timelimit > game_starttime)
2066                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2067         else
2068                 game_completion_ratio = 0;
2069
2070         if(checkrules_suddendeathend)
2071         {
2072                 if(!checkrules_suddendeathwarning)
2073                 {
2074                         checkrules_suddendeathwarning = true;
2075                         if(g_race && !g_race_qualifying)
2076                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2077                         else
2078                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2079                 }
2080         }
2081         else
2082         {
2083                 if (timelimit && time >= timelimit)
2084                 {
2085                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2086                         {
2087                                 float totalplayers;
2088                                 float playerswithlaps;
2089                                 float readyplayers;
2090                                 entity head;
2091                                 totalplayers = playerswithlaps = readyplayers = 0;
2092                                 FOR_EACH_PLAYER(head)
2093                                 {
2094                                         ++totalplayers;
2095                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2096                                                 ++playerswithlaps;
2097                                         if(head.ready)
2098                                                 ++readyplayers;
2099                                 }
2100
2101                                 // at least 2 of the players have completed a lap: start the RACE
2102                                 // otherwise, the players should end the qualifying on their own
2103                                 if(readyplayers || playerswithlaps >= 2)
2104                                 {
2105                                         checkrules_suddendeathend = 0;
2106                                         ReadyRestart(); // go to race
2107                                         return;
2108                                 }
2109                                 else
2110                                         wantovertime |= InitiateSuddenDeath();
2111                         }
2112                         else
2113                                 wantovertime |= InitiateSuddenDeath();
2114                 }
2115         }
2116
2117         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2118         {
2119                 NextLevel();
2120                 return;
2121         }
2122
2123         float checkrules_status;
2124         checkrules_status = WinningCondition_RanOutOfSpawns();
2125         if(checkrules_status == WINNING_YES)
2126         {
2127                 bprint("Hey! Someone ran out of spawns!\n");
2128         }
2129         else if(g_race && !g_race_qualifying && timelimit >= 0)
2130         {
2131                 checkrules_status = WinningCondition_Race(fraglimit);
2132                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2133         }
2134         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2135         {
2136                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2137                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2138         }
2139         else if(g_assault)
2140         {
2141                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2142         }
2143         else if(g_lms)
2144         {
2145                 checkrules_status = WinningCondition_LMS();
2146         }
2147         else
2148         {
2149                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2150                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2151         }
2152
2153         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2154         {
2155                 checkrules_status = WINNING_NEVER;
2156                 checkrules_overtimesadded = -1;
2157                 wantovertime |= InitiateSuddenDeath();
2158         }
2159
2160         if(checkrules_status == WINNING_NEVER)
2161                 // equality cases! Nobody wins if the overtime ends in a draw.
2162                 ClearWinners();
2163
2164         if(wantovertime)
2165         {
2166                 if(checkrules_status == WINNING_NEVER)
2167                         InitiateOvertime();
2168                 else
2169                         checkrules_status = WINNING_YES;
2170         }
2171
2172         if(checkrules_suddendeathend)
2173                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2174                         checkrules_status = WINNING_YES;
2175
2176         if(checkrules_status == WINNING_YES)
2177         {
2178                 //print("WINNING\n");
2179                 NextLevel();
2180         }
2181 }
2182
2183 string GotoMap(string m)
2184 {
2185         m = GameTypeVote_MapInfo_FixName(m);
2186         if (!m)
2187                 return "The map you suggested is not available on this server.";
2188         if (!autocvar_sv_vote_gametype)
2189         if(!MapInfo_CheckMap(m))
2190                 return "The map you suggested does not support the current game mode.";
2191         cvar_set("nextmap", m);
2192         cvar_set("timelimit", "-1");
2193         if(mapvote_initialized || alreadychangedlevel)
2194         {
2195                 if(DoNextMapOverride(0))
2196                         return "Map switch initiated.";
2197                 else
2198                         return "Hm... no. For some reason I like THIS map more.";
2199         }
2200         else
2201                 return "Map switch will happen after scoreboard.";
2202 }
2203
2204
2205 void EndFrame()
2206 {
2207         anticheat_endframe();
2208
2209         float altime;
2210         FOR_EACH_REALCLIENT(self)
2211         {
2212                 entity e = IS_SPEC(self) ? self.enemy : self;
2213                 if(e.typehitsound)
2214                         self.typehit_time = time;
2215                 else if(e.damage_dealt)
2216                 {
2217                         self.hit_time = time;
2218                         self.damage_dealt_total += ceil(e.damage_dealt);
2219                 }
2220         }
2221         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2222         // add 1 frametime because after this, engine SV_Physics
2223         // increases time by a frametime and then networks the frame
2224         // add another frametime because client shows everything with
2225         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2226         // needed!
2227         FOR_EACH_CLIENT(self)
2228         {
2229                 self.typehitsound = false;
2230                 self.damage_dealt = 0;
2231                 antilag_record(self, altime);
2232         }
2233         FOR_EACH_MONSTER(self)
2234                 antilag_record(self, altime);
2235 }
2236
2237
2238 /*
2239  * RedirectionThink:
2240  * returns true if redirecting
2241  */
2242 float redirection_timeout;
2243 float redirection_nextthink;
2244 float RedirectionThink()
2245 {
2246         float clients_found;
2247
2248         if(redirection_target == "")
2249                 return false;
2250
2251         if(!redirection_timeout)
2252         {
2253                 cvar_set("sv_public", "-2");
2254                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2255                 if(redirection_target == "self")
2256                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2257                 else
2258                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2259         }
2260
2261         if(time < redirection_nextthink)
2262                 return true;
2263
2264         redirection_nextthink = time + 1;
2265
2266         clients_found = 0;
2267         FOR_EACH_REALCLIENT(self)
2268         {
2269                 // TODO add timer
2270                 print("Redirecting: sending connect command to ", self.netname, "\n");
2271                 if(redirection_target == "self")
2272                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2273                 else
2274                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2275                 ++clients_found;
2276         }
2277
2278         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2279
2280         if(time > redirection_timeout || clients_found == 0)
2281                 localcmd("\nwait; wait; wait; quit\n");
2282
2283         return true;
2284 }
2285
2286 void TargetMusic_RestoreGame();
2287 void RestoreGame()
2288 {
2289         // Loaded from a save game
2290         // some things then break, so let's work around them...
2291
2292         // Progs DB (capture records)
2293         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2294
2295         // Mapinfo
2296         MapInfo_Shutdown();
2297         MapInfo_Enumerate();
2298         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2299         WeaponStats_Init();
2300
2301         TargetMusic_RestoreGame();
2302 }
2303
2304 void Shutdown()
2305 {
2306         gameover = 2;
2307
2308         if(world_initialized > 0)
2309         {
2310                 world_initialized = 0;
2311                 print("Saving persistent data...\n");
2312                 Ban_SaveBans();
2313
2314                 // playerstats with unfinished match
2315                 PlayerStats_GameReport(false);
2316
2317                 if(!cheatcount_total)
2318                 {
2319                         if(autocvar_sv_db_saveasdump)
2320                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2321                         else
2322                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2323                 }
2324                 if(autocvar_developer)
2325                 {
2326                         if(autocvar_sv_db_saveasdump)
2327                                 db_dump(TemporaryDB, "server-temp.db");
2328                         else
2329                                 db_save(TemporaryDB, "server-temp.db");
2330                 }
2331                 CheatShutdown(); // must be after cheatcount check
2332                 db_close(ServerProgsDB);
2333                 db_close(TemporaryDB);
2334                 print("done!\n");
2335                 // tell the bot system the game is ending now
2336                 bot_endgame();
2337
2338                 WeaponStats_Shutdown();
2339                 MapInfo_Shutdown();
2340         }
2341         else if(world_initialized == 0)
2342         {
2343                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2344         }
2345 }