qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_assault");
 257                 BADCVAR("g_ca");
 258                 BADCVAR("g_ca_teams");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_freezetag_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_leadlimit");
 308                 BADCVAR("g_ctf_captimerecord_always");
 309                 BADCVAR("g_ctf_flag_glowtrails");
 310                 BADCVAR("g_ctf_flag_pickup_verbosename");
 311                 BADCVAR("g_domination_point_leadlimit");
 312                 BADCVAR("g_forced_respawn");
 313                 BADCVAR("g_keyhunt_point_leadlimit");
 314                 BADPREFIX("g_mod_");
 315                 BADCVAR("g_nexball_goalleadlimit");
 316                 BADCVAR("leadlimit_and_fraglimit");
 317                 BADCVAR("leadlimit_override");
 318                 BADCVAR("pausable");
 319                 BADCVAR("sv_allow_fullbright");
 320                 BADCVAR("sv_checkforpacketsduringsleep");
 321                 BADCVAR("sv_fraginfo");
 322                 BADCVAR("sv_timeout");
 323                 BADPREFIX("sv_timeout_");
 324                 BADPREFIX("crypto_");
 325                 BADPREFIX("g_chat_");
 326                 BADPREFIX("g_ctf_captimerecord_");
 327                 BADPREFIX("g_maplist_votable_");
 328                 BADPREFIX("net_");
 329                 BADPREFIX("prvm_");
 330                 BADPREFIX("skill_");
 331                 BADPREFIX("sv_cullentities_");
 332                 BADPREFIX("sv_fraginfo_");
 333                 BADPREFIX("sv_maxidle_");
 334                 BADPREFIX("sv_vote_");
 335                 BADPREFIX("timelimit_");
 336                 BADCVAR("gameversion");
 337                 BADPREFIX("gameversion_");
 338                 BADCVAR("sv_namechangetimer");
 339
 340                 // allowed changes to server admins (please sync this to server.cfg)
 341                 // vi commands:
 342                 //   :/"impure"/,$d
 343                 //   :g!,^\/\/[^ /],d
 344                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 345                 //   :%!sort
 346                 // yes, this does contain some redundant stuff, don't really care
 347                 BADCVAR("bot_config_file");
 348                 BADCVAR("bot_number");
 349                 BADCVAR("bot_prefix");
 350                 BADCVAR("bot_suffix");
 351                 BADCVAR("capturelimit_override");
 352                 BADCVAR("fraglimit_override");
 353                 BADCVAR("gametype");
 354                 BADCVAR("g_antilag");
 355                 BADCVAR("g_balance_teams");
 356                 BADCVAR("g_balance_teams_prevent_imbalance");
 357                 BADCVAR("g_balance_teams_scorefactor");
 358                 BADCVAR("g_ban_sync_trusted_servers");
 359                 BADCVAR("g_ban_sync_uri");
 360                 BADCVAR("g_ca_teams_override");
 361                 BADCVAR("g_ctf_ignore_frags");
 362                 BADCVAR("g_domination_point_limit");
 363                 BADCVAR("g_freezetag_teams_override");
 364                 BADCVAR("g_friendlyfire");
 365                 BADCVAR("g_fullbrightitems");
 366                 BADCVAR("g_fullbrightplayers");
 367                 BADCVAR("g_keyhunt_point_limit");
 368                 BADCVAR("g_keyhunt_teams_override");
 369                 BADCVAR("g_lms_lives_override");
 370                 BADCVAR("g_maplist");
 371                 BADCVAR("g_maplist_check_waypoints");
 372                 BADCVAR("g_maplist_mostrecent_count");
 373                 BADCVAR("g_maplist_shuffle");
 374                 BADCVAR("g_maplist_votable");
 375                 BADCVAR("g_maplist_votable_abstain");
 376                 BADCVAR("g_maplist_votable_nodetail");
 377                 BADCVAR("g_maplist_votable_suggestions");
 378                 BADCVAR("g_maxplayers");
 379                 BADCVAR("g_mirrordamage");
 380                 BADCVAR("g_nexball_goallimit");
 381                 BADCVAR("g_powerups");
 382                 BADCVAR("g_start_delay");
 383                 BADCVAR("g_warmup");
 384                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 385                 BADCVAR("hostname");
 386                 BADCVAR("log_file");
 387                 BADCVAR("maxplayers");
 388                 BADCVAR("minplayers");
 389                 BADCVAR("net_address");
 390                 BADCVAR("port");
 391                 BADCVAR("rcon_password");
 392                 BADCVAR("rcon_restricted_commands");
 393                 BADCVAR("rcon_restricted_password");
 394                 BADCVAR("skill");
 395                 BADCVAR("sv_adminnick");
 396                 BADCVAR("sv_autoscreenshot");
 397                 BADCVAR("sv_autotaunt");
 398                 BADCVAR("sv_curl_defaulturl");
 399                 BADCVAR("sv_defaultcharacter");
 400                 BADCVAR("sv_defaultplayercolors");
 401                 BADCVAR("sv_defaultplayermodel");
 402                 BADCVAR("sv_defaultplayerskin");
 403                 BADCVAR("sv_maxidle");
 404                 BADCVAR("sv_maxrate");
 405                 BADCVAR("sv_motd");
 406                 BADCVAR("sv_public");
 407                 BADCVAR("sv_ready_restart");
 408                 BADCVAR("sv_status_privacy");
 409                 BADCVAR("sv_taunt");
 410                 BADCVAR("sv_vote_call");
 411                 BADCVAR("sv_vote_commands");
 412                 BADCVAR("sv_vote_majority_factor");
 413                 BADCVAR("sv_vote_master");
 414                 BADCVAR("sv_vote_master_commands");
 415                 BADCVAR("sv_vote_master_password");
 416                 BADCVAR("sv_vote_simple_majority_factor");
 417                 BADCVAR("teamplay_mode");
 418                 BADCVAR("timelimit_override");
 419                 BADCVAR("g_spawnshieldtime");
 420                 BADPREFIX("g_warmup_");
 421                 BADPREFIX("sv_ready_restart_");
 422
 423                 // mutators that announce themselves properly to the server browser
 424                 BADCVAR("g_minstagib");
 425                 BADCVAR("g_new_toys");
 426                 BADCVAR("g_nix");
 427                 BADCVAR("g_grappling_hook");
 428                 BADCVAR("g_jetpack");
 429
 430 #undef BADPREFIX
 431 #undef BADCVAR
 432
 433                 if(pureadding)
 434                 {
 435                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 436                         if(strlen(cvar_purechanges) > 16384)
 437                         {
 438                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 439                                 pureadding = 0;
 440                         }
 441                 }
 442                 ++cvar_purechanges_count;
 443                 // WARNING: this variable is used for the server list
 444                 // NEVER dare to skip this code!
 445                 // Hacks to intentionally appearing as "pure server" even though you DO have
 446                 // modified settings may be punished by removal from the server list.
 447                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 448                 // though.
 449         }
 450         buf_del(h);
 451         if(cvar_changes == "")
 452                 cvar_changes = "// this server runs at default server settings\n";
 453         else
 454                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 455         cvar_changes = strzone(cvar_changes);
 456         if(cvar_purechanges == "")
 457                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 458         else
 459                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 460         cvar_purechanges = strzone(cvar_purechanges);
 461 }
 462
 463 void detect_maptype()
 464 {
 465 #if 0
 466         vector o, v;
 467         float i;
 468
 469         for(;;)
 470         {
 471                 o = world.mins;
 472                 o_x += random() * (world.maxs_x - world.mins_x);
 473                 o_y += random() * (world.maxs_y - world.mins_y);
 474                 o_z += random() * (world.maxs_z - world.mins_z);
 475
 476                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 477                 if(trace_fraction == 1)
 478                         continue;
 479
 480                 v = trace_endpos;
 481
 482                 for(i = 0; i < 64; i += 4)
 483                 {
 484                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 485         if(trace_fraction == 1)
 486                 continue;
 487                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 488                 }
 489
 490                 break;
 491         }
 492 #endif
 493 }
 494
 495 entity randomseed;
 496 float RandomSeed_Send(entity to, float sf)
 497 {
 498         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 499         WriteShort(MSG_ENTITY, self.cnt);
 500         return TRUE;
 501 }
 502 void RandomSeed_Think()
 503 {
 504         self.cnt = bound(0, floor(random() * 65536), 65535);
 505         self.nextthink = time + 5;
 506
 507         self.SendFlags |= 1;
 508 }
 509 void RandomSeed_Spawn()
 510 {
 511         randomseed = spawn();
 512         randomseed.think = RandomSeed_Think;
 513         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 514
 515         entity oldself;
 516         oldself = self;
 517         self = randomseed;
 518         self.think(); // sets random seed and nextthink
 519         self = oldself;
 520 }
 521
 522 void spawnfunc___init_dedicated_server(void)
 523 {
 524         // handler for _init/_init map (only for dedicated server initialization)
 525
 526         world_initialized = -1; // don't complain
 527         cvar = cvar_normal;
 528         cvar_string = cvar_string_normal;
 529         cvar_set = cvar_set_normal;
 530
 531         remove = remove_unsafely;
 532
 533         entity e;
 534         e = spawn();
 535         e.think = GotoFirstMap;
 536         e.nextthink = time; // this is usually 1 at this point
 537
 538         e = spawn();
 539         e.classname = "info_player_deathmatch"; // safeguard against player joining
 540
 541         self.classname = "worldspawn"; // safeguard against various stuff ;)
 542
 543         // needs to be done so early because of the constants they create
 544         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 545         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 546         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 547         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 548
 549         MapInfo_Enumerate();
 550         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 551 }
 552
 553 void Map_MarkAsRecent(string m);
 554 float world_already_spawned;
 555 void Nagger_Init();
 556 void ClientInit_Spawn();
 557 void WeaponStats_Init();
 558 void WeaponStats_Shutdown();
 559 void spawnfunc_worldspawn (void)
 560 {
 561         float fd, l, i, j, n;
 562         string s;
 563
 564         cvar = cvar_normal;
 565         cvar_string = cvar_string_normal;
 566         cvar_set = cvar_set_normal;
 567
 568         if(world_already_spawned)
 569                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 570         world_already_spawned = TRUE;
 571
 572         remove = remove_safely; // during spawning, watch what you remove!
 573
 574         check_unacceptable_compiler_bugs();
 575
 576         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 577
 578         compressShortVector_init();
 579
 580         entity head;
 581         head = nextent(world);
 582         maxclients = 0;
 583         while(head)
 584         {
 585                 ++maxclients;
 586                 head = nextent(head);
 587         }
 588
 589         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 590
 591         // needs to be done so early because of the constants they create
 592         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 593         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 594         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 595         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 596
 597         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 598
 599         TemporaryDB = db_create();
 600
 601         // 0 normal
 602         lightstyle(0, "m");
 603
 604         // 1 FLICKER (first variety)
 605         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 606
 607         // 2 SLOW STRONG PULSE
 608         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 609
 610         // 3 CANDLE (first variety)
 611         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 612
 613         // 4 FAST STROBE
 614         lightstyle(4, "mamamamamama");
 615
 616         // 5 GENTLE PULSE 1
 617         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 618
 619         // 6 FLICKER (second variety)
 620         lightstyle(6, "nmonqnmomnmomomno");
 621
 622         // 7 CANDLE (second variety)
 623         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 624
 625         // 8 CANDLE (third variety)
 626         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 627
 628         // 9 SLOW STROBE (fourth variety)
 629         lightstyle(9, "aaaaaaaazzzzzzzz");
 630
 631         // 10 FLUORESCENT FLICKER
 632         lightstyle(10, "mmamammmmammamamaaamammma");
 633
 634         // 11 SLOW PULSE NOT FADE TO BLACK
 635         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 636
 637         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 638
 639         // 63 testing
 640         lightstyle(63, "a");
 641
 642         if(autocvar_g_campaign)
 643                 CampaignPreInit();
 644
 645         Map_MarkAsRecent(mapname);
 646
 647         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 648
 649         precache_model ("null"); // we need this one before InitGameplayMode
 650         InitGameplayMode();
 651         readlevelcvars();
 652         GrappleHookInit();
 653         ArcInit();
 654         ElectroInit();
 655
 656         player_count = 0;
 657         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 658         if(bot_waypoints_for_items == 1)
 659                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 660                         bot_waypoints_for_items = 0;
 661
 662         precache();
 663
 664         WaypointSprite_Init();
 665
 666         GameLogInit(); // prepare everything
 667         // NOTE for matchid:
 668         // changing the logic generating it is okay. But:
 669         // it HAS to stay <= 64 chars
 670         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 671         if(autocvar_sv_eventlog)
 672         {
 673                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 674                 matchid = strzone(s);
 675
 676                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 677                 s = ":gameinfo:mutators:LIST";
 678
 679                 ret_string = s;
 680                 MUTATOR_CALLHOOK(BuildMutatorsString);
 681                 s = ret_string;
 682
 683                 // simple, probably not good in the mutator system
 684                 if(autocvar_g_grappling_hook)
 685                         s = strcat(s, ":grappling_hook");
 686
 687                 // initialiation stuff, not good in the mutator system
 688                 if(!autocvar_g_use_ammunition)
 689                         s = strcat(s, ":no_use_ammunition");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(autocvar_g_pickup_items == 0)
 693                         s = strcat(s, ":no_pickup_items");
 694                 if(autocvar_g_pickup_items > 0)
 695                         s = strcat(s, ":pickup_items");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(autocvar_g_weaponarena != "0")
 699                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 700
 701                 // TODO to mutator system
 702                 if(autocvar_g_norecoil)
 703                         s = strcat(s, ":norecoil");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_powerups == 0)
 707                         s = strcat(s, ":no_powerups");
 708                 if(autocvar_g_powerups > 0)
 709                         s = strcat(s, ":powerups");
 710
 711                 GameLogEcho(s);
 712                 GameLogEcho(":gameinfo:end");
 713         }
 714         else
 715                 matchid = strzone(ftos(random()));
 716
 717         cvar_set("nextmap", "");
 718
 719         SetDefaultAlpha();
 720
 721         if(autocvar_g_campaign)
 722                 CampaignPostInit();
 723
 724         fteqcc_testbugs();
 725
 726         Ban_LoadBans();
 727
 728         MapInfo_Enumerate();
 729         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 730
 731         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 732         {
 733                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 734                 if(fd != -1)
 735                 {
 736                         while((s = fgets(fd)))
 737                         {
 738                                 l = tokenize_console(s);
 739                                 if(l < 2)
 740                                         continue;
 741                                 if(argv(0) == "cd")
 742                                 {
 743                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 744                                         print("  cdtrack ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) == "fog")
 747                                 {
 748                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 749                                         print("  \"fog\" \"", s, "\"\n");
 750                                 }
 751                                 else if(argv(0) == "set")
 752                                 {
 753                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 754                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 755                                 }
 756                                 else if(argv(0) != "//")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 760                                 }
 761                         }
 762                         fclose(fd);
 763                 }
 764         }
 765
 766         WeaponStats_Init();
 767
 768         WepSet_AddStat();
 769         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 770         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 771         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 772         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 773         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 774         Nagger_Init();
 775
 776         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 777         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 778         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 779         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 780         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 781         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 782         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 783         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 784         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 785         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 786         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 787         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 788         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 789
 790         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 791         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 792
 793         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 794
 795         // g_movementspeed hack
 796         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 797         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 798         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 799         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 800
 801         // secrets
 802         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 803         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 804
 805         // misc
 806         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 807
 808         next_pingtime = time + 5;
 809
 810         detect_maptype();
 811
 812         // set up information replies for clients and server to use
 813         maplist_reply = strzone(getmaplist());
 814         lsmaps_reply = strzone(getlsmaps());
 815         for(i = 0; i < 10; ++i)
 816         {
 817                 s = getrecords(i);
 818                 if (s)
 819                         records_reply[i] = strzone(s);
 820         }
 821         ladder_reply = strzone(getladder());
 822         rankings_reply = strzone(getrankings());
 823
 824         // begin other init
 825         ClientInit_Spawn();
 826         RandomSeed_Spawn();
 827         PingPLReport_Spawn();
 828
 829         CheatInit();
 830
 831         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 832
 833         // fill sv_curl_serverpackages from .serverpackage files
 834         if(autocvar_sv_curl_serverpackages_auto)
 835         {
 836                 s = "";
 837                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 838                 for(i = 0; i < n; ++i)
 839                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 840                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 841                                 s = strcat(s, " ", argv(i));
 842                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 843                 if(fd >= 0)
 844                 {
 845                         j = search_getsize(fd);
 846                         for(i = 0; i < j; ++i)
 847                                 s = strcat(s, " ", search_getfilename(fd, i));
 848                         search_end(fd);
 849                 }
 850                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 851                 if(fd >= 0)
 852                 {
 853                         j = search_getsize(fd);
 854                         for(i = 0; i < j; ++i)
 855                                 s = strcat(s, " ", search_getfilename(fd, i));
 856                         search_end(fd);
 857                 }
 858                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 859         }
 860
 861         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 862         modname = "Xonotic";
 863         // physics/balance/config changes that count as mod
 864         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 865                 modname = cvar_string("g_mod_physics");
 866         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 867                 modname = cvar_string("g_mod_balance");
 868         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 869                 modname = cvar_string("g_mod_config");
 870         // extra mutators that deserve to count as mod
 871         MUTATOR_CALLHOOK(SetModname);
 872
 873         // save it for later
 874         modname = strzone(modname);
 875
 876         WinningConditionHelper(); // set worldstatus
 877
 878         world_initialized = 1;
 879 }
 880
 881 void spawnfunc_light (void)
 882 {
 883         //makestatic (self); // Who the f___ did that?
 884         remove(self);
 885 }
 886
 887 string GetGametype()
 888 {
 889         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 890 }
 891
 892 string getmapname_stored;
 893 string GetMapname()
 894 {
 895         return mapname;
 896 }
 897
 898 float Map_Count, Map_Current;
 899 string Map_Current_Name;
 900
 901 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 902 float GetMaplistPosition()
 903 {
 904         float pos, idx;
 905         string map;
 906
 907         map = GetMapname();
 908         idx = autocvar_g_maplist_index;
 909
 910         if(idx >= 0)
 911                 if(idx < Map_Count)
 912                         if(map == argv(idx))
 913                                 return idx;
 914
 915         for(pos = 0; pos < Map_Count; ++pos)
 916                 if(map == argv(pos))
 917                         return pos;
 918
 919         // resume normal maplist rotation if current map is not in g_maplist
 920         return idx;
 921 }
 922
 923 float MapHasRightSize(string map)
 924 {
 925         float fh;
 926         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 927         if(autocvar_g_maplist_check_waypoints)
 928         {
 929                 dprint("checkwp "); dprint(map);
 930                 if(!fexists(strcat("maps/", map, ".waypoints")))
 931                 {
 932                         dprint(": no waypoints\n");
 933                         return FALSE;
 934                 }
 935                 dprint(": has waypoints\n");
 936         }
 937
 938         // open map size restriction file
 939         dprint("opensize "); dprint(map);
 940         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 941         if(fh >= 0)
 942         {
 943                 float mapmin, mapmax;
 944                 dprint(": ok, ");
 945                 mapmin = stof(fgets(fh));
 946                 mapmax = stof(fgets(fh));
 947                 fclose(fh);
 948                 if(player_count < mapmin)
 949                 {
 950                         dprint("not enough\n");
 951                         return FALSE;
 952                 }
 953                 if(player_count > mapmax)
 954                 {
 955                         dprint("too many\n");
 956                         return FALSE;
 957                 }
 958                 dprint("right size\n");
 959                 return TRUE;
 960         }
 961         dprint(": not found\n");
 962         return TRUE;
 963 }
 964
 965 string Map_Filename(float position)
 966 {
 967         return strcat("maps/", argv(position), ".bsp");
 968 }
 969
 970 string strwords(string s, float w)
 971 {
 972         float endpos;
 973         for(endpos = 0; w && endpos >= 0; --w)
 974                 endpos = strstrofs(s, " ", endpos + 1);
 975         if(endpos < 0)
 976                 return s;
 977         else
 978                 return substring(s, 0, endpos);
 979 }
 980
 981 float strhasword(string s, string w)
 982 {
 983         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 984 }
 985
 986 void Map_MarkAsRecent(string m)
 987 {
 988         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 989 }
 990
 991 float Map_IsRecent(string m)
 992 {
 993         return strhasword(autocvar_g_maplist_mostrecent, m);
 994 }
 995
 996 float Map_Check(float position, float pass)
 997 {
 998         string filename;
 999         string map_next;
1000         map_next = argv(position);
1001         if(pass <= 1)
1002         {
1003                 if(Map_IsRecent(map_next))
1004                         return 0;
1005         }
1006         filename = Map_Filename(position);
1007         if(MapInfo_CheckMap(map_next))
1008         {
1009                 if(pass == 2)
1010                         return 1;
1011                 if(MapHasRightSize(map_next))
1012                         return 1;
1013                 return 0;
1014         }
1015         else
1016                 dprint( "Couldn't select '", filename, "'..\n" );
1017
1018         return 0;
1019 }
1020
1021 void Map_Goto_SetStr(string nextmapname)
1022 {
1023         if(getmapname_stored != "")
1024                 strunzone(getmapname_stored);
1025         if(nextmapname == "")
1026                 getmapname_stored = "";
1027         else
1028                 getmapname_stored = strzone(nextmapname);
1029 }
1030
1031 void Map_Goto_SetFloat(float position)
1032 {
1033         cvar_set("g_maplist_index", ftos(position));
1034         Map_Goto_SetStr(argv(position));
1035 }
1036
1037 void Map_Goto(float reinit)
1038 {
1039         MapInfo_LoadMap(getmapname_stored, reinit);
1040 }
1041
1042 // return codes of map selectors:
1043 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1044 //   -2 = permanent failure
1045 float() MaplistMethod_Iterate = // usual method
1046 {
1047         float pass, i;
1048
1049         dprint("Trying MaplistMethod_Iterate\n");
1050
1051         for(pass = 1; pass <= 2; ++pass)
1052         {
1053                 for(i = 1; i < Map_Count; ++i)
1054                 {
1055                         float mapindex;
1056                         mapindex = mod(i + Map_Current, Map_Count);
1057                         if(Map_Check(mapindex, pass))
1058                                 return mapindex;
1059                 }
1060         }
1061         return -1;
1062 }
1063
1064 float() MaplistMethod_Repeat = // fallback method
1065 {
1066         dprint("Trying MaplistMethod_Repeat\n");
1067
1068         if(Map_Check(Map_Current, 2))
1069                 return Map_Current;
1070         return -2;
1071 }
1072
1073 float() MaplistMethod_Random = // random map selection
1074 {
1075         float i, imax;
1076
1077         dprint("Trying MaplistMethod_Random\n");
1078
1079         imax = 42;
1080
1081         for(i = 0; i <= imax; ++i)
1082         {
1083                 float mapindex;
1084                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1085                 if(Map_Check(mapindex, 1))
1086                         return mapindex;
1087         }
1088         return -1;
1089 }
1090
1091 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1092 // the exponent sets a bias on the map selection:
1093 // the higher the exponent, the less likely "shortly repeated" same maps are
1094 {
1095         float i, j, imax, insertpos;
1096
1097         dprint("Trying MaplistMethod_Shuffle\n");
1098
1099         imax = 42;
1100
1101         for(i = 0; i <= imax; ++i)
1102         {
1103                 string newlist;
1104
1105                 // now reinsert this at another position
1106                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1107                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1108                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1109                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1110
1111                 // insert the current map there
1112                 newlist = "";
1113                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1114                         newlist = strcat(newlist, " ", argv(j));
1115                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1116                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1117                         newlist = strcat(newlist, " ", argv(j));
1118                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1119                 cvar_set("g_maplist", newlist);
1120                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1121
1122                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1123                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1124                 if(Map_Check(Map_Current, 1))
1125                         return Map_Current;
1126         }
1127         return -1;
1128 }
1129
1130 void Maplist_Init()
1131 {
1132         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1133         float i;
1134         for (i = 0; i < Map_Count; ++i)
1135                 if (Map_Check(i, 2))
1136                         break;
1137         if (i == Map_Count)
1138         {
1139                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1140                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1141                 if(autocvar_g_maplist_shuffle)
1142                         ShuffleMaplist();
1143                 localcmd("\nmenu_cmd sync\n");
1144                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1145         }
1146         if(Map_Count == 0)
1147                 error("empty maplist, cannot select a new map");
1148         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1149
1150         if(Map_Current_Name)
1151                 strunzone(Map_Current_Name);
1152         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1153         // this may or may not be correct, but who cares, in the worst case a map
1154         // isn't chosen in the first pass that should have been
1155 }
1156
1157 string GetNextMap()
1158 {
1159         float nextMap;
1160
1161         Maplist_Init();
1162         nextMap = -1;
1163
1164         if(nextMap == -1)
1165                 if(autocvar_g_maplist_shuffle > 0)
1166                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1167
1168         if(nextMap == -1)
1169                 if(autocvar_g_maplist_selectrandom)
1170                         nextMap = MaplistMethod_Random();
1171
1172         if(nextMap == -1)
1173                 nextMap = MaplistMethod_Iterate();
1174
1175         if(nextMap == -1)
1176                 nextMap = MaplistMethod_Repeat();
1177
1178         if(nextMap >= 0)
1179         {
1180                 Map_Goto_SetFloat(nextMap);
1181                 return getmapname_stored;
1182         }
1183
1184         return "";
1185 }
1186
1187 float DoNextMapOverride(float reinit)
1188 {
1189         if(autocvar_g_campaign)
1190         {
1191                 CampaignPostIntermission();
1192                 alreadychangedlevel = TRUE;
1193                 return TRUE;
1194         }
1195         if(autocvar_quit_when_empty)
1196         {
1197                 if(player_count <= currentbots)
1198                 {
1199                         localcmd("quit\n");
1200                         alreadychangedlevel = TRUE;
1201                         return TRUE;
1202                 }
1203         }
1204         if(autocvar_quit_and_redirect != "")
1205         {
1206                 redirection_target = strzone(autocvar_quit_and_redirect);
1207                 alreadychangedlevel = TRUE;
1208                 return TRUE;
1209         }
1210         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1211         {
1212                 localcmd("restart\n");
1213                 alreadychangedlevel = TRUE;
1214                 return TRUE;
1215         }
1216         if(autocvar_nextmap != "")
1217                 if(MapInfo_CheckMap(autocvar_nextmap))
1218                 {
1219                         Map_Goto_SetStr(autocvar_nextmap);
1220                         Map_Goto(reinit);
1221                         alreadychangedlevel = TRUE;
1222                         return TRUE;
1223                 }
1224         if(!reinit && autocvar_lastlevel)
1225         {
1226                 cvar_settemp_restore();
1227                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1228                 alreadychangedlevel = TRUE;
1229                 return TRUE;
1230         }
1231         return FALSE;
1232 }
1233
1234 void GotoNextMap(float reinit)
1235 {
1236         //string nextmap;
1237         //float n, nummaps;
1238         //string s;
1239         if (alreadychangedlevel)
1240                 return;
1241         alreadychangedlevel = TRUE;
1242
1243         string nextMap;
1244
1245         nextMap = GetNextMap();
1246         if(nextMap == "")
1247                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1248         Map_Goto(reinit);
1249 }
1250
1251
1252 /*
1253 ============
1254 IntermissionThink
1255
1256 When the player presses attack or jump, change to the next level
1257 ============
1258 */
1259 .float autoscreenshot;
1260 void() MapVote_Start;
1261 void() MapVote_Think;
1262 float mapvote_initialized;
1263 void IntermissionThink()
1264 {
1265         FixIntermissionClient(self);
1266
1267         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1268         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1269
1270         if( (server_screenshot || client_screenshot)
1271                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1272         {
1273                 self.autoscreenshot = -1;
1274                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1275                 return;
1276         }
1277
1278         if (time < intermission_exittime)
1279                 return;
1280
1281         if(!mapvote_initialized)
1282                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1283                         return;
1284
1285         MapVote_Start();
1286 }
1287
1288 /*
1289 ============
1290 FindIntermission
1291
1292 Returns the entity to view from
1293 ============
1294 */
1295 /*
1296 entity FindIntermission()
1297 {
1298         local   entity spot;
1299         local   float cyc;
1300
1301 // look for info_intermission first
1302         spot = find (world, classname, "info_intermission");
1303         if (spot)
1304         {       // pick a random one
1305                 cyc = random() * 4;
1306                 while (cyc > 1)
1307                 {
1308                         spot = find (spot, classname, "info_intermission");
1309                         if (!spot)
1310                                 spot = find (spot, classname, "info_intermission");
1311                         cyc = cyc - 1;
1312                 }
1313                 return spot;
1314         }
1315
1316 // then look for the start position
1317         spot = find (world, classname, "info_player_start");
1318         if (spot)
1319                 return spot;
1320
1321 // testinfo_player_start is only found in regioned levels
1322         spot = find (world, classname, "testplayerstart");
1323         if (spot)
1324                 return spot;
1325
1326 // then look for the start position
1327         spot = find (world, classname, "info_player_deathmatch");
1328         if (spot)
1329                 return spot;
1330
1331         //objerror ("FindIntermission: no spot");
1332         return world;
1333 }
1334 */
1335
1336 /*
1337 ===============================================================================
1338
1339 RULES
1340
1341 ===============================================================================
1342 */
1343
1344 void DumpStats(float final)
1345 {
1346         float file;
1347         string s;
1348         float to_console;
1349         float to_eventlog;
1350         float to_file;
1351         float i;
1352
1353         to_console = autocvar_sv_logscores_console;
1354         to_eventlog = autocvar_sv_eventlog;
1355         to_file = autocvar_sv_logscores_file;
1356
1357         if(!final)
1358         {
1359                 to_console = TRUE; // always print printstats replies
1360                 to_eventlog = FALSE; // but never print them to the event log
1361         }
1362
1363         if(to_eventlog)
1364                 if(autocvar_sv_eventlog_console)
1365                         to_console = FALSE; // otherwise we get the output twice
1366
1367         if(final)
1368                 s = ":scores:";
1369         else
1370                 s = ":status:";
1371         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1372
1373         if(to_console)
1374                 print(s, "\n");
1375         if(to_eventlog)
1376                 GameLogEcho(s);
1377
1378         file = -1;
1379         if(to_file)
1380         {
1381                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1382                 if(file == -1)
1383                         to_file = FALSE;
1384                 else
1385                         fputs(file, strcat(s, "\n"));
1386         }
1387
1388         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1389         if(to_console)
1390                 print(s, "\n");
1391         if(to_eventlog)
1392                 GameLogEcho(s);
1393         if(to_file)
1394                 fputs(file, strcat(s, "\n"));
1395
1396         FOR_EACH_CLIENT(other)
1397         {
1398                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1399                 {
1400                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1401                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1402                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1403                                 s = strcat(s, ftos(other.team), ":");
1404                         else
1405                                 s = strcat(s, "spectator:");
1406
1407                         if(to_console)
1408                                 print(s, other.netname, "\n");
1409                         if(to_eventlog)
1410                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1411                         if(to_file)
1412                                 fputs(file, strcat(s, other.netname, "\n"));
1413                 }
1414         }
1415
1416         if(teamplay)
1417         {
1418                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1419                 if(to_console)
1420                         print(s, "\n");
1421                 if(to_eventlog)
1422                         GameLogEcho(s);
1423                 if(to_file)
1424                         fputs(file, strcat(s, "\n"));
1425
1426                 for(i = 1; i < 16; ++i)
1427                 {
1428                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1429                         s = strcat(s, ":", ftos(i));
1430                         if(to_console)
1431                                 print(s, "\n");
1432                         if(to_eventlog)
1433                                 GameLogEcho(s);
1434                         if(to_file)
1435                                 fputs(file, strcat(s, "\n"));
1436                 }
1437         }
1438
1439         if(to_console)
1440                 print(":end\n");
1441         if(to_eventlog)
1442                 GameLogEcho(":end");
1443         if(to_file)
1444         {
1445                 fputs(file, ":end\n");
1446                 fclose(file);
1447         }
1448 }
1449
1450 void FixIntermissionClient(entity e)
1451 {
1452         string s;
1453         if(!e.autoscreenshot) // initial call
1454         {
1455                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1456                 e.health = -2342;
1457                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1458                 e.solid = SOLID_NOT;
1459                 e.movetype = MOVETYPE_NONE;
1460                 e.takedamage = DAMAGE_NO;
1461                 if(e.weaponentity)
1462                 {
1463                         e.weaponentity.effects = EF_NODRAW;
1464                         if (e.weaponentity.weaponentity)
1465                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1466                 }
1467                 if(IS_REAL_CLIENT(e))
1468                 {
1469                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1470                         s = autocvar_sv_intermission_cdtrack;
1471                         if(s != "")
1472                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1473                         msg_entity = e;
1474                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1475                 }
1476         }
1477 }
1478
1479 /*
1480 go to the next level for deathmatch
1481 only called if a time or frag limit has expired
1482 */
1483 void NextLevel()
1484 {
1485         gameover = TRUE;
1486
1487         intermission_running = 1;
1488
1489 // enforce a wait time before allowing changelevel
1490         if(player_count > 0)
1491                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1492         else
1493                 intermission_exittime = -1;
1494
1495         /*
1496         WriteByte (MSG_ALL, SVC_CDTRACK);
1497         WriteByte (MSG_ALL, 3);
1498         WriteByte (MSG_ALL, 3);
1499         // done in FixIntermission
1500         */
1501
1502         //pos = FindIntermission ();
1503
1504         VoteReset();
1505
1506         DumpStats(TRUE);
1507
1508         // send statistics
1509         entity e;
1510         PlayerStats_EndMatch(1);
1511         FOR_EACH_CLIENT(e)
1512                 PlayerStats_AddGlobalInfo(e);
1513         PlayerStats_Shutdown();
1514         WeaponStats_Shutdown();
1515
1516         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1517
1518         if(autocvar_sv_eventlog)
1519                 GameLogEcho(":gameover");
1520
1521         GameLogClose();
1522
1523         FOR_EACH_PLAYER(other) {
1524                 FixIntermissionClient(other);
1525                 if(other.winning)
1526                         bprint(other.netname, " ^7wins.\n");
1527         }
1528
1529         if(autocvar_g_campaign)
1530                 CampaignPreIntermission();
1531
1532         MUTATOR_CALLHOOK(MatchEnd);
1533
1534         localcmd("\nsv_hook_gameend\n");
1535 }
1536
1537 /*
1538 ============
1539 CheckRules_Player
1540
1541 Exit deathmatch games upon conditions
1542 ============
1543 */
1544 void CheckRules_Player()
1545 {
1546         if (gameover)   // someone else quit the game already
1547                 return;
1548
1549         if(self.deadflag == DEAD_NO)
1550                 self.play_time += frametime;
1551
1552         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1553         //   (div0: and that in CheckRules_World please)
1554 }
1555
1556 float checkrules_equality;
1557 float checkrules_suddendeathwarning;
1558 float checkrules_suddendeathend;
1559 float checkrules_overtimesadded; //how many overtimes have been already added
1560
1561 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1562 const float WINNING_YES = 1; // winner found
1563 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1564 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1565
1566 float InitiateSuddenDeath()
1567 {
1568         // Check first whether normal overtimes could be added before initiating suddendeath mode
1569         // - for this timelimit_overtime needs to be >0 of course
1570         // - also check the winning condition calculated in the previous frame and only add normal overtime
1571         //   again, if at the point at which timelimit would be extended again, still no winner was found
1572         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1573         {
1574                 return 1; // need to call InitiateOvertime later
1575         }
1576         else
1577         {
1578                 if(!checkrules_suddendeathend)
1579                 {
1580                         if(autocvar_g_campaign)
1581                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1582                         else
1583                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1584                         if(g_race && !g_race_qualifying)
1585                                 race_StartCompleting();
1586                 }
1587                 return 0;
1588         }
1589 }
1590
1591 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1592 {
1593         ++checkrules_overtimesadded;
1594         //add one more overtime by simply extending the timelimit
1595         float tl;
1596         tl = autocvar_timelimit;
1597         tl += autocvar_timelimit_overtime;
1598         cvar_set("timelimit", ftos(tl));
1599
1600         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1601 }
1602
1603 float GetWinningCode(float fraglimitreached, float equality)
1604 {
1605         if(autocvar_g_campaign == 1)
1606                 if(fraglimitreached)
1607                         return WINNING_YES;
1608                 else
1609                         return WINNING_NO;
1610
1611         else
1612                 if(equality)
1613                         if(fraglimitreached)
1614                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1615                         else
1616                                 return WINNING_NEVER;
1617                 else
1618                         if(fraglimitreached)
1619                                 return WINNING_YES;
1620                         else
1621                                 return WINNING_NO;
1622 }
1623
1624 // set the .winning flag for exactly those players with a given field value
1625 void SetWinners(.float field, float value)
1626 {
1627         entity head;
1628         FOR_EACH_PLAYER(head)
1629                 head.winning = (head.field == value);
1630 }
1631
1632 // set the .winning flag for those players with a given field value
1633 void AddWinners(.float field, float value)
1634 {
1635         entity head;
1636         FOR_EACH_PLAYER(head)
1637                 if(head.field == value)
1638                         head.winning = 1;
1639 }
1640
1641 // clear the .winning flags
1642 void ClearWinners(void)
1643 {
1644         entity head;
1645         FOR_EACH_PLAYER(head)
1646                 head.winning = 0;
1647 }
1648
1649 // Onslaught winning condition:
1650 // game terminates if only one team has a working generator (or none)
1651 float WinningCondition_Onslaught()
1652 {
1653         entity head;
1654         float t1, t2, t3, t4;
1655
1656         WinningConditionHelper(); // set worldstatus
1657
1658         if(warmup_stage)
1659                 return WINNING_NO;
1660
1661         // first check if the game has ended
1662         t1 = t2 = t3 = t4 = 0;
1663         head = find(world, classname, "onslaught_generator");
1664         while (head)
1665         {
1666                 if (head.health > 0)
1667                 {
1668                         if (head.team == NUM_TEAM_1) t1 = 1;
1669                         if (head.team == NUM_TEAM_2) t2 = 1;
1670                         if (head.team == NUM_TEAM_3) t3 = 1;
1671                         if (head.team == NUM_TEAM_4) t4 = 1;
1672                 }
1673                 head = find(head, classname, "onslaught_generator");
1674         }
1675         if (t1 + t2 + t3 + t4 < 2)
1676         {
1677                 // game over, only one team remains (or none)
1678                 ClearWinners();
1679                 if (t1) SetWinners(team, NUM_TEAM_1);
1680                 if (t2) SetWinners(team, NUM_TEAM_2);
1681                 if (t3) SetWinners(team, NUM_TEAM_3);
1682                 if (t4) SetWinners(team, NUM_TEAM_4);
1683                 dprint("Have a winner, ending game.\n");
1684                 return WINNING_YES;
1685         }
1686
1687         // Two or more teams remain
1688         return WINNING_NO;
1689 }
1690
1691 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1692 // they win. Otherwise the defending team wins once the timelimit passes.
1693 void assault_new_round();
1694 float WinningCondition_Assault()
1695 {
1696         float status;
1697
1698         WinningConditionHelper(); // set worldstatus
1699
1700         status = WINNING_NO;
1701         // as the timelimit has not yet passed just assume the defending team will win
1702         if(assault_attacker_team == NUM_TEAM_1)
1703         {
1704                 SetWinners(team, NUM_TEAM_2);
1705         }
1706         else
1707         {
1708                 SetWinners(team, NUM_TEAM_1);
1709         }
1710
1711         entity ent;
1712         ent = find(world, classname, "target_assault_roundend");
1713         if(ent)
1714         {
1715                 if(ent.winning) // round end has been triggered by attacking team
1716                 {
1717                         bprint("ASSAULT: round completed...\n");
1718                         SetWinners(team, assault_attacker_team);
1719
1720                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1721
1722                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1723                         {
1724                                 status = WINNING_YES;
1725                         }
1726                         else
1727                         {
1728                                 entity oldself;
1729                                 oldself = self;
1730                                 self = ent;
1731                                 assault_new_round();
1732                                 self = oldself;
1733                         }
1734                 }
1735         }
1736
1737         return status;
1738 }
1739
1740 // LMS winning condition: game terminates if and only if there's at most one
1741 // one player who's living lives. Top two scores being equal cancels the time
1742 // limit.
1743 float WinningCondition_LMS()
1744 {
1745         entity head, head2;
1746         float have_player;
1747         float have_players;
1748         float l;
1749
1750         have_player = FALSE;
1751         have_players = FALSE;
1752         l = LMS_NewPlayerLives();
1753
1754         head = find(world, classname, "player");
1755         if(head)
1756                 have_player = TRUE;
1757         head2 = find(head, classname, "player");
1758         if(head2)
1759                 have_players = TRUE;
1760
1761         if(have_player)
1762         {
1763                 // we have at least one player
1764                 if(have_players)
1765                 {
1766                         // two or more active players - continue with the game
1767                 }
1768                 else
1769                 {
1770                         // exactly one player?
1771
1772                         ClearWinners();
1773                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1774
1775                         if(l)
1776                         {
1777                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1778                                 return WINNING_NO;
1779                         }
1780                         else
1781                         {
1782                                 // a winner!
1783                                 // and assign him his first place
1784                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1785                                 return WINNING_YES;
1786                         }
1787                 }
1788         }
1789         else
1790         {
1791                 // nobody is playing at all...
1792                 if(l)
1793                 {
1794                         // wait for players...
1795                 }
1796                 else
1797                 {
1798                         // SNAFU (maybe a draw game?)
1799                         ClearWinners();
1800                         dprint("No players, ending game.\n");
1801                         return WINNING_YES;
1802                 }
1803         }
1804
1805         // When we get here, we have at least two players who are actually LIVING,
1806         // now check if the top two players have equal score.
1807         WinningConditionHelper();
1808
1809         ClearWinners();
1810         if(WinningConditionHelper_winner)
1811                 WinningConditionHelper_winner.winning = TRUE;
1812         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1813                 return WINNING_NEVER;
1814
1815         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1816         return WINNING_NO;
1817 }
1818
1819 void ShuffleMaplist()
1820 {
1821         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1822 }
1823
1824 float leaderfrags;
1825 float WinningCondition_Scores(float limit, float leadlimit)
1826 {
1827         float limitreached;
1828
1829         // TODO make everything use THIS winning condition (except LMS)
1830         WinningConditionHelper();
1831
1832         if(teamplay)
1833         {
1834                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1835                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1836                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1837                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1838         }
1839
1840         ClearWinners();
1841         if(WinningConditionHelper_winner)
1842                 WinningConditionHelper_winner.winning = 1;
1843         if(WinningConditionHelper_winnerteam >= 0)
1844                 SetWinners(team, WinningConditionHelper_winnerteam);
1845
1846         if(WinningConditionHelper_lowerisbetter)
1847         {
1848                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1849                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1850                 limit = -limit;
1851         }
1852
1853         if(WinningConditionHelper_zeroisworst)
1854                 leadlimit = 0; // not supported in this mode
1855
1856         if(g_dm || g_tdm || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1857         // these modes always score in increments of 1, thus this makes sense
1858         {
1859                 if(leaderfrags != WinningConditionHelper_topscore)
1860                 {
1861                         leaderfrags = WinningConditionHelper_topscore;
1862
1863                         if (limit)
1864                         if (leaderfrags == limit - 1)
1865                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1866                         else if (leaderfrags == limit - 2)
1867                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1868                         else if (leaderfrags == limit - 3)
1869                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1870                 }
1871         }
1872
1873         limitreached = FALSE;
1874         if(limit)
1875                 if(WinningConditionHelper_topscore >= limit)
1876                         limitreached = TRUE;
1877         if(leadlimit)
1878         {
1879                 float leadlimitreached;
1880                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1881                 if(autocvar_leadlimit_and_fraglimit)
1882                         limitreached = (limitreached && leadlimitreached);
1883                 else
1884                         limitreached = (limitreached || leadlimitreached);
1885         }
1886
1887         if(limit)
1888                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1889
1890         return GetWinningCode(
1891                 WinningConditionHelper_topscore && limitreached,
1892                 WinningConditionHelper_equality
1893         );
1894 }
1895
1896 float WinningCondition_Race(float fraglimit)
1897 {
1898         float wc;
1899         entity p;
1900         float n, c;
1901
1902         n = 0;
1903         c = 0;
1904         FOR_EACH_PLAYER(p)
1905         {
1906                 ++n;
1907                 if(p.race_completed)
1908                         ++c;
1909         }
1910         if(n && (n == c))
1911                 return WINNING_YES;
1912         wc = WinningCondition_Scores(fraglimit, 0);
1913
1914         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1915         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1916         // do NOT support equality when the laps are all raced!
1917                 return WINNING_STARTSUDDENDEATHOVERTIME;
1918         else
1919                 return WINNING_NEVER;
1920 }
1921
1922 float WinningCondition_QualifyingThenRace(float limit)
1923 {
1924         float wc;
1925         wc = WinningCondition_Scores(limit, 0);
1926
1927         // NEVER initiate overtime
1928         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1929         {
1930                 return WINNING_YES;
1931         }
1932
1933         return wc;
1934 }
1935
1936 float WinningCondition_RanOutOfSpawns()
1937 {
1938         entity head;
1939
1940         if(have_team_spawns <= 0)
1941                 return WINNING_NO;
1942
1943         if(autocvar_g_spawn_useallspawns <= 0)
1944                 return WINNING_NO;
1945
1946         if(!some_spawn_has_been_used)
1947                 return WINNING_NO;
1948
1949         team1_score = team2_score = team3_score = team4_score = 0;
1950
1951         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1952         {
1953                 if(head.team == NUM_TEAM_1)
1954                         team1_score = 1;
1955                 else if(head.team == NUM_TEAM_2)
1956                         team2_score = 1;
1957                 else if(head.team == NUM_TEAM_3)
1958                         team3_score = 1;
1959                 else if(head.team == NUM_TEAM_4)
1960                         team4_score = 1;
1961         }
1962
1963         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1964         {
1965                 if(head.team == NUM_TEAM_1)
1966                         team1_score = 1;
1967                 else if(head.team == NUM_TEAM_2)
1968                         team2_score = 1;
1969                 else if(head.team == NUM_TEAM_3)
1970                         team3_score = 1;
1971                 else if(head.team == NUM_TEAM_4)
1972                         team4_score = 1;
1973         }
1974
1975         ClearWinners();
1976         if(team1_score + team2_score + team3_score + team4_score == 0)
1977         {
1978                 checkrules_equality = TRUE;
1979                 return WINNING_YES;
1980         }
1981         else if(team1_score + team2_score + team3_score + team4_score == 1)
1982         {
1983                 float t, i;
1984                 if(team1_score)
1985                         t = NUM_TEAM_1;
1986                 else if(team2_score)
1987                         t = NUM_TEAM_2;
1988                 else if(team3_score)
1989                         t = NUM_TEAM_3;
1990                 else // if(team4_score)
1991                         t = NUM_TEAM_4;
1992                 CheckAllowedTeams(world);
1993                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1994                 {
1995                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1996                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1997                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1998                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1999                 }
2000
2001                 AddWinners(team, t);
2002                 return WINNING_YES;
2003         }
2004         else
2005                 return WINNING_NO;
2006 }
2007
2008 /*
2009 ============
2010 CheckRules_World
2011
2012 Exit deathmatch games upon conditions
2013 ============
2014 */
2015 void ReadyRestart();
2016 void CheckRules_World()
2017 {
2018         float timelimit;
2019         float fraglimit;
2020         float leadlimit;
2021
2022         VoteThink();
2023         MapVote_Think();
2024
2025         SetDefaultAlpha();
2026
2027         /*
2028         MapVote_Think should now do that part
2029         if (intermission_running)
2030                 if (time >= intermission_exittime + 60)
2031                 {
2032                         if(!DoNextMapOverride())
2033                                 GotoNextMap();
2034                         return;
2035                 }
2036         */
2037
2038         if (gameover)   // someone else quit the game already
2039         {
2040                 if(player_count == 0) // Nobody there? Then let's go to the next map
2041                         MapVote_Start();
2042                         // this will actually check the player count in the next frame
2043                         // again, but this shouldn't hurt
2044                 return;
2045         }
2046
2047         timelimit = autocvar_timelimit * 60;
2048         fraglimit = autocvar_fraglimit;
2049         leadlimit = autocvar_leadlimit;
2050
2051         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2052         {
2053                 if(timelimit > 0)
2054                         timelimit = 0; // timelimit is not made for warmup
2055                 if(fraglimit > 0)
2056                         fraglimit = 0; // no fraglimit for now
2057                 leadlimit = 0; // no leadlimit for now
2058         }
2059
2060         if(timelimit > 0)
2061         {
2062                 timelimit += game_starttime;
2063         }
2064         else if (timelimit < 0)
2065         {
2066                 // endmatch
2067                 NextLevel();
2068                 return;
2069         }
2070
2071         if(g_onslaught)
2072                 timelimit = 0; // ONS has its own overtime rule
2073
2074         float wantovertime;
2075         wantovertime = 0;
2076
2077         if(timelimit > game_starttime)
2078                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2079         else
2080                 game_completion_ratio = 0;
2081
2082         if(checkrules_suddendeathend)
2083         {
2084                 if(!checkrules_suddendeathwarning)
2085                 {
2086                         checkrules_suddendeathwarning = TRUE;
2087                         if(g_race && !g_race_qualifying)
2088                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2089                         else
2090                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2091                 }
2092         }
2093         else
2094         {
2095                 if (timelimit && time >= timelimit)
2096                 {
2097                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2098                         {
2099                                 float totalplayers;
2100                                 float playerswithlaps;
2101                                 float readyplayers;
2102                                 entity head;
2103                                 totalplayers = playerswithlaps = readyplayers = 0;
2104                                 FOR_EACH_PLAYER(head)
2105                                 {
2106                                         ++totalplayers;
2107                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2108                                                 ++playerswithlaps;
2109                                         if(head.ready)
2110                                                 ++readyplayers;
2111                                 }
2112
2113                                 // at least 2 of the players have completed a lap: start the RACE
2114                                 // otherwise, the players should end the qualifying on their own
2115                                 if(readyplayers || playerswithlaps >= 2)
2116                                 {
2117                                         checkrules_suddendeathend = 0;
2118                                         ReadyRestart(); // go to race
2119                                         return;
2120                                 }
2121                                 else
2122                                         wantovertime |= InitiateSuddenDeath();
2123                         }
2124                         else
2125                                 wantovertime |= InitiateSuddenDeath();
2126                 }
2127         }
2128
2129         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2130         {
2131                 NextLevel();
2132                 return;
2133         }
2134
2135         float checkrules_status;
2136         checkrules_status = WinningCondition_RanOutOfSpawns();
2137         if(checkrules_status == WINNING_YES)
2138         {
2139                 bprint("Hey! Someone ran out of spawns!\n");
2140         }
2141         else if(g_race && !g_race_qualifying && timelimit >= 0)
2142         {
2143                 checkrules_status = WinningCondition_Race(fraglimit);
2144                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2145         }
2146         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2147         {
2148                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2149                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2150         }
2151         else if(g_assault)
2152         {
2153                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2154         }
2155         else if(g_lms)
2156         {
2157                 checkrules_status = WinningCondition_LMS();
2158         }
2159         else if (g_onslaught)
2160         {
2161                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2162         }
2163         else
2164         {
2165                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2166                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2167         }
2168
2169         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2170         {
2171                 checkrules_status = WINNING_NEVER;
2172                 checkrules_overtimesadded = -1;
2173                 wantovertime |= InitiateSuddenDeath();
2174         }
2175
2176         if(checkrules_status == WINNING_NEVER)
2177                 // equality cases! Nobody wins if the overtime ends in a draw.
2178                 ClearWinners();
2179
2180         if(wantovertime)
2181         {
2182                 if(checkrules_status == WINNING_NEVER)
2183                         InitiateOvertime();
2184                 else
2185                         checkrules_status = WINNING_YES;
2186         }
2187
2188         if(checkrules_suddendeathend)
2189                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2190                         checkrules_status = WINNING_YES;
2191
2192         if(checkrules_status == WINNING_YES)
2193         {
2194                 //print("WINNING\n");
2195                 NextLevel();
2196         }
2197 }
2198
2199 float mapvote_nextthink;
2200 float mapvote_initialized;
2201 float mapvote_keeptwotime;
2202 float mapvote_timeout;
2203 string mapvote_message;
2204 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2205 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2206 float mapvote_screenshot_dirs_count;
2207
2208 float mapvote_count;
2209 float mapvote_count_real;
2210 string mapvote_maps[MAPVOTE_COUNT];
2211 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2212 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2213 float mapvote_maps_suggested[MAPVOTE_COUNT];
2214 string mapvote_suggestions[MAPVOTE_COUNT];
2215 float mapvote_suggestion_ptr;
2216 float mapvote_voters;
2217 float mapvote_selections[MAPVOTE_COUNT];
2218 float mapvote_run;
2219 float mapvote_detail;
2220 float mapvote_abstain;
2221 .float mapvote;
2222
2223 void MapVote_ClearAllVotes()
2224 {
2225         FOR_EACH_CLIENT(other)
2226                 other.mapvote = 0;
2227 }
2228
2229 string MapVote_Suggest(string m)
2230 {
2231         float i;
2232         if(m == "")
2233                 return "That's not how to use this command.";
2234         if(!autocvar_g_maplist_votable_suggestions)
2235                 return "Suggestions are not accepted on this server.";
2236         if(mapvote_initialized)
2237                 return "Can't suggest - voting is already in progress!";
2238         m = MapInfo_FixName(m);
2239         if (!m)
2240                 return "The map you suggested is not available on this server.";
2241         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2242                 if(Map_IsRecent(m))
2243                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2244
2245         if(!MapInfo_CheckMap(m))
2246                 return "The map you suggested does not support the current game mode.";
2247         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2248                 if(mapvote_suggestions[i] == m)
2249                         return "This map was already suggested.";
2250         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2251         {
2252                 i = floor(random() * mapvote_suggestion_ptr);
2253         }
2254         else
2255         {
2256                 i = mapvote_suggestion_ptr;
2257                 mapvote_suggestion_ptr += 1;
2258         }
2259         if(mapvote_suggestions[i] != "")
2260                 strunzone(mapvote_suggestions[i]);
2261         mapvote_suggestions[i] = strzone(m);
2262         if(autocvar_sv_eventlog)
2263                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2264         return strcat("Suggestion of ", m, " accepted.");
2265 }
2266
2267 void MapVote_AddVotable(string nextMap, float isSuggestion)
2268 {
2269         float j, i, o;
2270         string pakfile, mapfile;
2271
2272         if(nextMap == "")
2273                 return;
2274         for(j = 0; j < mapvote_count; ++j)
2275                 if(mapvote_maps[j] == nextMap)
2276                         return;
2277         // suggestions might be no longer valid/allowed after gametype switch!
2278         if(isSuggestion)
2279                 if(!MapInfo_CheckMap(nextMap))
2280                         return;
2281         mapvote_maps[mapvote_count] = strzone(nextMap);
2282         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2283
2284         pakfile = string_null;
2285         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2286         {
2287                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2288                 pakfile = whichpack(strcat(mapfile, ".tga"));
2289                 if(pakfile == "")
2290                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2291                 if(pakfile == "")
2292                         pakfile = whichpack(strcat(mapfile, ".png"));
2293                 if(pakfile != "")
2294                         break;
2295         }
2296         if(i >= mapvote_screenshot_dirs_count)
2297                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2298         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2299                 pakfile = substring(pakfile, o, -1);
2300
2301         mapvote_maps_screenshot_dir[mapvote_count] = i;
2302         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2303
2304         mapvote_count += 1;
2305 }
2306
2307 void MapVote_Spawn();
2308 void MapVote_Init()
2309 {
2310         float i;
2311         float nmax, smax;
2312
2313         MapVote_ClearAllVotes();
2314
2315         mapvote_count = 0;
2316         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2317         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2318
2319         if(mapvote_abstain)
2320                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2321         else
2322                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2323         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2324
2325         // we need this for AddVotable, as that cycles through the screenshot dirs
2326         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2327         if(mapvote_screenshot_dirs_count == 0)
2328                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2329         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2330         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2331                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2332
2333         if(mapvote_suggestion_ptr)
2334                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2335                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2336
2337         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2338                 MapVote_AddVotable(GetNextMap(), FALSE);
2339
2340         if(mapvote_count == 0)
2341         {
2342                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2343                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2344                 if(autocvar_g_maplist_shuffle)
2345                         ShuffleMaplist();
2346                 localcmd("\nmenu_cmd sync\n");
2347                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2348                         MapVote_AddVotable(GetNextMap(), FALSE);
2349         }
2350
2351         mapvote_count_real = mapvote_count;
2352         if(mapvote_abstain)
2353                 MapVote_AddVotable("don't care", 0);
2354
2355         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2356
2357         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2358         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2359         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2360                 mapvote_keeptwotime = 0;
2361         mapvote_message = "Choose a map and press its key!";
2362
2363         MapVote_Spawn();
2364 }
2365
2366 void MapVote_SendPicture(float id)
2367 {
2368         msg_entity = self;
2369         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2370         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2371         WriteByte(MSG_ONE, id);
2372         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2373 }
2374
2375 float MapVote_GetMapMask()
2376 {
2377         float mask, i, power;
2378         mask = 0;
2379         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2380                 if(mapvote_maps[i] != "")
2381                         mask |= power;
2382         return mask;
2383 }
2384
2385 entity mapvote_ent;
2386 float MapVote_SendEntity(entity to, float sf)
2387 {
2388         float i;
2389
2390         if(sf & 1)
2391                 sf &= ~2; // if we send 1, we don't need to also send 2
2392
2393         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2394         WriteByte(MSG_ENTITY, sf);
2395
2396         if(sf & 1)
2397         {
2398                 // flag 1 == initialization
2399                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2400                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2401                 WriteString(MSG_ENTITY, "");
2402                 WriteByte(MSG_ENTITY, mapvote_count);
2403                 WriteByte(MSG_ENTITY, mapvote_abstain);
2404                 WriteByte(MSG_ENTITY, mapvote_detail);
2405                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2406                 if(mapvote_count <= 8)
2407                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2408                 else
2409                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2410                 for(i = 0; i < mapvote_count; ++i)
2411                         if(mapvote_maps[i] != "")
2412                         {
2413                                 if(mapvote_abstain && i == mapvote_count - 1)
2414                                 {
2415                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2416                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2417                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2418                                 }
2419                                 else
2420                                 {
2421                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2422                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2423                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2424                                 }
2425                         }
2426         }
2427
2428         if(sf & 2)
2429         {
2430                 // flag 2 == update of mask
2431                 if(mapvote_count <= 8)
2432                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2433                 else
2434                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2435         }
2436
2437         if(sf & 4)
2438         {
2439                 if(mapvote_detail)
2440                         for(i = 0; i < mapvote_count; ++i)
2441                                 if(mapvote_maps[i] != "")
2442                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2443
2444                 WriteByte(MSG_ENTITY, to.mapvote);
2445         }
2446
2447         return TRUE;
2448 }
2449
2450 void MapVote_Spawn()
2451 {
2452         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2453 }
2454
2455 void MapVote_TouchMask()
2456 {
2457         mapvote_ent.SendFlags |= 2;
2458 }
2459
2460 void MapVote_TouchVotes(entity voter)
2461 {
2462         mapvote_ent.SendFlags |= 4;
2463 }
2464
2465 float MapVote_Finished(float mappos)
2466 {
2467         string result;
2468         float i;
2469         float didntvote;
2470
2471         if(autocvar_sv_eventlog)
2472         {
2473                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2474                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2475                 didntvote = mapvote_voters;
2476                 for(i = 0; i < mapvote_count; ++i)
2477                         if(mapvote_maps[i] != "")
2478                         {
2479                                 didntvote -= mapvote_selections[i];
2480                                 if(i != mappos)
2481                                 {
2482                                         result = strcat(result, ":", mapvote_maps[i]);
2483                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2484                                 }
2485                         }
2486                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2487
2488                 GameLogEcho(result);
2489                 if(mapvote_maps_suggested[mappos])
2490                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2491         }
2492
2493         FOR_EACH_REALCLIENT(other)
2494                 FixClientCvars(other);
2495
2496         Map_Goto_SetStr(mapvote_maps[mappos]);
2497         Map_Goto(0);
2498         alreadychangedlevel = TRUE;
2499         return TRUE;
2500 }
2501 void MapVote_CheckRules_1()
2502 {
2503         float i;
2504
2505         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2506         {
2507                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2508                 mapvote_selections[i] = 0;
2509         }
2510
2511         mapvote_voters = 0;
2512         FOR_EACH_REALCLIENT(other)
2513         {
2514                 ++mapvote_voters;
2515                 if(other.mapvote)
2516                 {
2517                         i = other.mapvote - 1;
2518                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2519                         mapvote_selections[i] = mapvote_selections[i] + 1;
2520                 }
2521         }
2522 }
2523
2524 float MapVote_CheckRules_2()
2525 {
2526         float i;
2527         float firstPlace, secondPlace;
2528         float firstPlaceVotes, secondPlaceVotes;
2529         float mapvote_voters_real;
2530         string result;
2531
2532         if(mapvote_count_real == 1)
2533                 return MapVote_Finished(0);
2534
2535         mapvote_voters_real = mapvote_voters;
2536         if(mapvote_abstain)
2537                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2538
2539         RandomSelection_Init();
2540         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2541                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2542         firstPlace = RandomSelection_chosen_float;
2543         firstPlaceVotes = RandomSelection_best_priority;
2544         //dprint("First place: ", ftos(firstPlace), "\n");
2545         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2546
2547         RandomSelection_Init();
2548         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2549                 if(i != firstPlace)
2550                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2551         secondPlace = RandomSelection_chosen_float;
2552         secondPlaceVotes = RandomSelection_best_priority;
2553         //dprint("Second place: ", ftos(secondPlace), "\n");
2554         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2555
2556         if(firstPlace == -1)
2557                 error("No first place in map vote... WTF?");
2558
2559         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2560                 return MapVote_Finished(firstPlace);
2561
2562         if(mapvote_keeptwotime)
2563                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2564                 {
2565                         float didntvote;
2566                         MapVote_TouchMask();
2567                         mapvote_message = "Now decide between the TOP TWO!";
2568                         mapvote_keeptwotime = 0;
2569                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2570                         result = strcat(result, ":", ftos(firstPlaceVotes));
2571                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2572                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2573                         didntvote = mapvote_voters;
2574                         for(i = 0; i < mapvote_count; ++i)
2575                                 if(mapvote_maps[i] != "")
2576                                 {
2577                                         didntvote -= mapvote_selections[i];
2578                                         if(i != firstPlace)
2579                                                 if(i != secondPlace)
2580                                                 {
2581                                                         result = strcat(result, ":", mapvote_maps[i]);
2582                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2583                                                         if(i < mapvote_count_real)
2584                                                         {
2585                                                                 strunzone(mapvote_maps[i]);
2586                                                                 mapvote_maps[i] = "";
2587                                                                 strunzone(mapvote_maps_pakfile[i]);
2588                                                                 mapvote_maps_pakfile[i] = "";
2589                                                         }
2590                                                 }
2591                                 }
2592                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2593                         if(autocvar_sv_eventlog)
2594                                 GameLogEcho(result);
2595                 }
2596
2597         return FALSE;
2598 }
2599 void MapVote_Tick()
2600 {
2601         float keeptwo;
2602         float totalvotes;
2603
2604         keeptwo = mapvote_keeptwotime;
2605         MapVote_CheckRules_1(); // count
2606         if(MapVote_CheckRules_2()) // decide
2607                 return;
2608
2609         totalvotes = 0;
2610         FOR_EACH_REALCLIENT(other)
2611         {
2612                 // hide scoreboard again
2613                 if(other.health != 2342)
2614                 {
2615                         other.health = 2342;
2616                         other.impulse = 0;
2617                         if(IS_REAL_CLIENT(other))
2618                         {
2619                                 msg_entity = other;
2620                                 WriteByte(MSG_ONE, SVC_FINALE);
2621                                 WriteString(MSG_ONE, "");
2622                         }
2623                 }
2624
2625                 // clear possibly invalid votes
2626                 if(mapvote_maps[other.mapvote - 1] == "")
2627                         other.mapvote = 0;
2628                 // use impulses as new vote
2629                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2630                         if(mapvote_maps[other.impulse - 1] != "")
2631                         {
2632                                 other.mapvote = other.impulse;
2633                                 MapVote_TouchVotes(other);
2634                         }
2635                 other.impulse = 0;
2636
2637                 if(other.mapvote)
2638                         ++totalvotes;
2639         }
2640
2641         MapVote_CheckRules_1(); // just count
2642 }
2643 void MapVote_Start()
2644 {
2645         if(mapvote_run)
2646                 return;
2647
2648         // wait for stats to be sent first
2649         if(!playerstats_waitforme)
2650                 return;
2651
2652         MapInfo_Enumerate();
2653         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2654                 mapvote_run = TRUE;
2655 }
2656 void MapVote_Think()
2657 {
2658         if(!mapvote_run)
2659                 return;
2660
2661         if(alreadychangedlevel)
2662                 return;
2663
2664         if(time < mapvote_nextthink)
2665                 return;
2666         //dprint("tick\n");
2667
2668         mapvote_nextthink = time + 0.5;
2669
2670         if(!mapvote_initialized)
2671         {
2672                 if(autocvar_rescan_pending == 1)
2673                 {
2674                         cvar_set("rescan_pending", "2");
2675                         localcmd("fs_rescan\nrescan_pending 3\n");
2676                         return;
2677                 }
2678                 else if(autocvar_rescan_pending == 2)
2679                 {
2680                         return;
2681                 }
2682                 else if(autocvar_rescan_pending == 3)
2683                 {
2684                         // now build missing mapinfo files
2685                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2686                                 return;
2687
2688                         // we're done, start the timer
2689                         cvar_set("rescan_pending", "0");
2690                 }
2691
2692                 mapvote_initialized = TRUE;
2693                 if(DoNextMapOverride(0))
2694                         return;
2695                 if(!autocvar_g_maplist_votable || player_count <= 0)
2696                 {
2697                         GotoNextMap(0);
2698                         return;
2699                 }
2700                 MapVote_Init();
2701         }
2702
2703         MapVote_Tick();
2704 }
2705
2706 string GotoMap(string m)
2707 {
2708         if(!MapInfo_CheckMap(m))
2709                 return "The map you chose is not available on this server.";
2710         cvar_set("nextmap", m);
2711         cvar_set("timelimit", "-1");
2712         if(mapvote_initialized || alreadychangedlevel)
2713         {
2714                 if(DoNextMapOverride(0))
2715                         return "Map switch initiated.";
2716                 else
2717                         return "Hm... no. For some reason I like THIS map more.";
2718         }
2719         else
2720                 return "Map switch will happen after scoreboard.";
2721 }
2722
2723
2724 void EndFrame()
2725 {
2726         float altime;
2727         FOR_EACH_REALCLIENT(self)
2728         {
2729                 if(IS_SPEC(self))
2730                 {
2731                         if(self.enemy.typehitsound)
2732                                 self.typehit_time = time;
2733                         else if(self.enemy.hitsound)
2734                                 self.hit_time = time;
2735                 }
2736                 else
2737                 {
2738                         if(self.typehitsound)
2739                                 self.typehit_time = time;
2740                         else if(self.hitsound)
2741                                 self.hit_time = time;
2742                 }
2743         }
2744         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2745         // add 1 frametime because after this, engine SV_Physics
2746         // increases time by a frametime and then networks the frame
2747         // add another frametime because client shows everything with
2748         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2749         // needed!
2750         FOR_EACH_CLIENT(self)
2751         {
2752                 self.hitsound = FALSE;
2753                 self.typehitsound = FALSE;
2754                 antilag_record(self, altime);
2755         }
2756 }
2757
2758
2759 /*
2760  * RedirectionThink:
2761  * returns TRUE if redirecting
2762  */
2763 float redirection_timeout;
2764 float redirection_nextthink;
2765 float RedirectionThink()
2766 {
2767         float clients_found;
2768
2769         if(redirection_target == "")
2770                 return FALSE;
2771
2772         if(!redirection_timeout)
2773         {
2774                 cvar_set("sv_public", "-2");
2775                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2776                 if(redirection_target == "self")
2777                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2778                 else
2779                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2780         }
2781
2782         if(time < redirection_nextthink)
2783                 return TRUE;
2784
2785         redirection_nextthink = time + 1;
2786
2787         clients_found = 0;
2788         FOR_EACH_REALCLIENT(self)
2789         {
2790                 // TODO add timer
2791                 print("Redirecting: sending connect command to ", self.netname, "\n");
2792                 if(redirection_target == "self")
2793                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2794                 else
2795                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2796                 ++clients_found;
2797         }
2798
2799         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2800
2801         if(time > redirection_timeout || clients_found == 0)
2802                 localcmd("\nwait; wait; wait; quit\n");
2803
2804         return TRUE;
2805 }
2806
2807 void TargetMusic_RestoreGame();
2808 void RestoreGame()
2809 {
2810         // Loaded from a save game
2811         // some things then break, so let's work around them...
2812
2813         // Progs DB (capture records)
2814         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2815
2816         // Mapinfo
2817         MapInfo_Shutdown();
2818         MapInfo_Enumerate();
2819         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2820         WeaponStats_Init();
2821
2822         TargetMusic_RestoreGame();
2823 }
2824
2825 void Shutdown()
2826 {
2827         entity e;
2828
2829         gameover = 2;
2830
2831         if(world_initialized > 0)
2832         {
2833                 world_initialized = 0;
2834                 print("Saving persistent data...\n");
2835                 Ban_SaveBans();
2836
2837                 PlayerStats_EndMatch(0);
2838                 FOR_EACH_CLIENT(e)
2839                         PlayerStats_AddGlobalInfo(e);
2840                 PlayerStats_Shutdown();
2841
2842                 if(!cheatcount_total)
2843                 {
2844                         if(autocvar_sv_db_saveasdump)
2845                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2846                         else
2847                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2848                 }
2849                 if(autocvar_developer)
2850                 {
2851                         if(autocvar_sv_db_saveasdump)
2852                                 db_dump(TemporaryDB, "server-temp.db");
2853                         else
2854                                 db_save(TemporaryDB, "server-temp.db");
2855                 }
2856                 CheatShutdown(); // must be after cheatcount check
2857                 db_close(ServerProgsDB);
2858                 db_close(TemporaryDB);
2859                 print("done!\n");
2860                 // tell the bot system the game is ending now
2861                 bot_endgame();
2862
2863                 WeaponStats_Shutdown();
2864                 MapInfo_Shutdown();
2865         }
2866         else if(world_initialized == 0)
2867         {
2868                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2869         }
2870 }