qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include <common/net_linked.qh>
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/_mod.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications/all.qh"
  29 #include "../common/physics/player.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/_mod.qh"
  37 #include <common/weapons/_all.qh>
  38 #include "../common/state.qh"
  39
  40 const float LATENCY_THINKRATE = 10;
  41 .float latency_sum;
  42 .float latency_cnt;
  43 .float latency_time;
  44 entity pingplreport;
  45 void PingPLReport_Think(entity this)
  46 {
  47         float delta;
  48         entity e;
  49
  50         delta = 3 / maxclients;
  51         if(delta < sys_frametime)
  52                 delta = 0;
  53         this.nextthink = time + delta;
  54
  55         e = edict_num(this.cnt + 1);
  56         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  57         {
  58                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  59                 WriteByte(MSG_BROADCAST, this.cnt);
  60                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  61                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  62                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  63
  64                 // record latency times for clients throughout the match so we can report it to playerstats
  65                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  66                 {
  67                         CS(e).latency_sum += CS(e).ping;
  68                         CS(e).latency_cnt += 1;
  69                         CS(e).latency_time = time;
  70                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  71                 }
  72         }
  73         else
  74         {
  75                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, this.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         this.cnt = (this.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = new_pure(pingplreport);
  86         setthink(pingplreport, PingPLReport_Think);
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap(entity this)
 109 {
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 this.nextthink = time;
 134         }
 135         else
 136         {
 137                 this.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213                 BADCVAR("in_pitch_min");
 214                 BADCVAR("in_pitch_max");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("net_address");
 220                 BADCVAR("net_address_ipv6");
 221                 BADCVAR("port");
 222                 BADCVAR("savedgamecfg");
 223                 BADCVAR("serverconfig");
 224                 BADCVAR("sv_autoscreenshot");
 225                 BADCVAR("sv_heartbeatperiod");
 226                 BADCVAR("sv_vote_master_password");
 227                 BADCVAR("sys_colortranslation");
 228                 BADCVAR("sys_specialcharactertranslation");
 229                 BADCVAR("timeformat");
 230                 BADCVAR("timestamps");
 231                 BADCVAR("g_require_stats");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_require_stats_");
 236                 BADPREFIX("g_chat_flood_");
 237                 BADPREFIX("g_ghost_items");
 238                 BADPREFIX("g_playerstats_");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("log_file");
 241                 BADPREFIX("quit_");
 242                 BADPREFIX("rcon_");
 243                 BADPREFIX("sv_allowdownloads");
 244                 BADPREFIX("sv_autodemo");
 245                 BADPREFIX("sv_curl_");
 246                 BADPREFIX("sv_eventlog");
 247                 BADPREFIX("sv_logscores_");
 248                 BADPREFIX("sv_master");
 249                 BADPREFIX("sv_weaponstats_");
 250                 BADPREFIX("sv_waypointsprite_");
 251                 BADCVAR("rescan_pending");
 252
 253                 // these can contain player IDs, so better hide
 254                 BADPREFIX("g_forced_team_");
 255                 BADCVAR("sv_muteban_list");
 256                 BADCVAR("sv_allow_customplayermodels_idlist");
 257                 BADCVAR("sv_allow_customplayermodels_speciallist");
 258
 259                 // mapinfo
 260                 BADCVAR("fraglimit");
 261                 BADCVAR("g_arena");
 262                 BADCVAR("g_assault");
 263                 BADCVAR("g_ca");
 264                 BADCVAR("g_ca_teams");
 265                 BADCVAR("g_conquest");
 266                 BADCVAR("g_ctf");
 267                 BADCVAR("g_cts");
 268                 BADCVAR("g_dotc");
 269                 BADCVAR("g_dm");
 270                 BADCVAR("g_domination");
 271                 BADCVAR("g_domination_default_teams");
 272                 BADCVAR("g_freezetag");
 273                 BADCVAR("g_freezetag_teams");
 274                 BADCVAR("g_invasion_teams");
 275                 BADCVAR("g_invasion_type");
 276                 BADCVAR("g_jailbreak");
 277                 BADCVAR("g_jailbreak_teams");
 278                 BADCVAR("g_keepaway");
 279                 BADCVAR("g_keyhunt");
 280                 BADCVAR("g_keyhunt_teams");
 281                 BADCVAR("g_lms");
 282                 BADCVAR("g_nexball");
 283                 BADCVAR("g_onslaught");
 284                 BADCVAR("g_race");
 285                 BADCVAR("g_race_laps_limit");
 286                 BADCVAR("g_race_qualifying_timelimit");
 287                 BADCVAR("g_race_qualifying_timelimit_override");
 288                 BADCVAR("g_runematch");
 289                 BADCVAR("g_snafu");
 290                 BADCVAR("g_tdm");
 291                 BADCVAR("g_tdm_teams");
 292                 BADCVAR("g_vip");
 293                 BADCVAR("leadlimit");
 294                 BADCVAR("nextmap");
 295                 BADCVAR("teamplay");
 296                 BADCVAR("timelimit");
 297                 BADCVAR("g_mapinfo_ignore_warnings");
 298
 299                 // long
 300                 BADCVAR("hostname");
 301                 BADCVAR("g_maplist");
 302                 BADCVAR("g_maplist_mostrecent");
 303                 BADCVAR("sv_motd");
 304
 305                 v = cvar_string(k);
 306                 d = cvar_defstring(k);
 307                 if(v == d)
 308                         continue;
 309
 310                 if(adding)
 311                 {
 312                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 313                         if(strlen(cvar_changes) > 16384)
 314                         {
 315                                 cvar_changes = "// too many settings have been changed to show them here\n";
 316                                 adding = 0;
 317                         }
 318                 }
 319
 320                 // now check if the changes are actually gameplay relevant
 321
 322                 // does nothing gameplay relevant
 323                 BADCVAR("captureleadlimit_override");
 324                 BADCVAR("condump_stripcolors");
 325                 BADCVAR("gameversion");
 326                 BADCVAR("g_allow_oldvortexbeam");
 327                 BADCVAR("g_balance_kill_delay");
 328                 BADCVAR("g_buffs_pickup_anyway");
 329                 BADCVAR("g_buffs_randomize");
 330                 BADCVAR("g_campcheck_distance");
 331                 BADCVAR("g_ca_point_leadlimit");
 332                 BADCVAR("g_ca_point_limit");
 333                 BADCVAR("g_ctf_captimerecord_always");
 334                 BADCVAR("g_ctf_flag_glowtrails");
 335                 BADCVAR("g_ctf_flag_pickup_verbosename");
 336                 BADCVAR("g_domination_point_leadlimit");
 337                 BADCVAR("g_forced_respawn");
 338                 BADCVAR("g_freezetag_point_leadlimit");
 339                 BADCVAR("g_freezetag_point_limit");
 340                 BADCVAR("g_hats");
 341                 BADCVAR("g_invasion_point_limit");
 342                 BADCVAR("g_jump_grunt");
 343                 BADCVAR("g_keyhunt_point_leadlimit");
 344                 BADCVAR("g_nexball_goalleadlimit");
 345                 BADCVAR("g_new_toys_use_pickupsound");
 346                 BADCVAR("g_physics_predictall");
 347                 BADCVAR("g_piggyback");
 348                 BADCVAR("g_playerclip_collisions");
 349                 BADCVAR("g_tdm_point_leadlimit");
 350                 BADCVAR("g_tdm_point_limit");
 351                 BADCVAR("leadlimit_and_fraglimit");
 352                 BADCVAR("leadlimit_override");
 353                 BADCVAR("pausable");
 354                 BADCVAR("sv_checkforpacketsduringsleep");
 355                 BADCVAR("sv_damagetext");
 356                 BADCVAR("sv_db_saveasdump");
 357                 BADCVAR("sv_intermission_cdtrack");
 358                 BADCVAR("sv_minigames");
 359                 BADCVAR("sv_namechangetimer");
 360                 BADCVAR("sv_precacheplayermodels");
 361                 BADCVAR("sv_stepheight");
 362                 BADCVAR("sv_timeout");
 363                 BADCVAR("sv_weapons_modeloverride");
 364                 BADPREFIX("crypto_");
 365                 BADPREFIX("gameversion_");
 366                 BADPREFIX("g_chat_");
 367                 BADPREFIX("g_ctf_captimerecord_");
 368                 BADPREFIX("g_maplist_");
 369                 BADPREFIX("g_mod_");
 370                 BADPREFIX("g_respawn_");
 371                 BADPREFIX("net_");
 372                 BADPREFIX("notification_");
 373                 BADPREFIX("prvm_");
 374                 BADPREFIX("skill_");
 375                 BADPREFIX("sv_allow_");
 376                 BADPREFIX("sv_cullentities_");
 377                 BADPREFIX("sv_maxidle_");
 378                 BADPREFIX("sv_minigames_");
 379                 BADPREFIX("sv_radio_");
 380                 BADPREFIX("sv_timeout_");
 381                 BADPREFIX("sv_vote_");
 382                 BADPREFIX("timelimit_");
 383
 384                 // allowed changes to server admins (please sync this to server.cfg)
 385                 // vi commands:
 386                 //   :/"impure"/,$d
 387                 //   :g!,^\/\/[^ /],d
 388                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 389                 //   :%!sort
 390                 // yes, this does contain some redundant stuff, don't really care
 391                 BADCVAR("bot_config_file");
 392                 BADCVAR("bot_number");
 393                 BADCVAR("bot_prefix");
 394                 BADCVAR("bot_suffix");
 395                 BADCVAR("capturelimit_override");
 396                 BADCVAR("fraglimit_override");
 397                 BADCVAR("gametype");
 398                 BADCVAR("g_antilag");
 399                 BADCVAR("g_balance_teams");
 400                 BADCVAR("g_balance_teams_prevent_imbalance");
 401                 BADCVAR("g_balance_teams_scorefactor");
 402                 BADCVAR("g_ban_sync_trusted_servers");
 403                 BADCVAR("g_ban_sync_uri");
 404                 BADCVAR("g_buffs");
 405                 BADCVAR("g_ca_teams_override");
 406                 BADCVAR("g_ctf_ignore_frags");
 407                 BADCVAR("g_ctf_leaderboard");
 408                 BADCVAR("g_domination_point_limit");
 409                 BADCVAR("g_domination_teams_override");
 410                 BADCVAR("g_freezetag_teams_override");
 411                 BADCVAR("g_friendlyfire");
 412                 BADCVAR("g_fullbrightitems");
 413                 BADCVAR("g_fullbrightplayers");
 414                 BADCVAR("g_keyhunt_point_limit");
 415                 BADCVAR("g_keyhunt_teams_override");
 416                 BADCVAR("g_lms_lives_override");
 417                 BADCVAR("g_maplist");
 418                 BADCVAR("g_maxplayers");
 419                 BADCVAR("g_mirrordamage");
 420                 BADCVAR("g_nexball_goallimit");
 421                 BADCVAR("g_norecoil");
 422                 BADCVAR("g_physics_clientselect");
 423                 BADCVAR("g_pinata");
 424                 BADCVAR("g_powerups");
 425                 BADCVAR("g_spawnshieldtime");
 426                 BADCVAR("g_start_delay");
 427                 BADCVAR("g_superspectate");
 428                 BADCVAR("g_tdm_teams_override");
 429                 BADCVAR("g_warmup");
 430                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 431                 BADCVAR("hostname");
 432                 BADCVAR("log_file");
 433                 BADCVAR("maxplayers");
 434                 BADCVAR("minplayers");
 435                 BADCVAR("net_address");
 436                 BADCVAR("port");
 437                 BADCVAR("rcon_password");
 438                 BADCVAR("rcon_restricted_commands");
 439                 BADCVAR("rcon_restricted_password");
 440                 BADCVAR("skill");
 441                 BADCVAR("sv_adminnick");
 442                 BADCVAR("sv_autoscreenshot");
 443                 BADCVAR("sv_autotaunt");
 444                 BADCVAR("sv_curl_defaulturl");
 445                 BADCVAR("sv_defaultcharacter");
 446                 BADCVAR("sv_defaultcharacterskin");
 447                 BADCVAR("sv_defaultplayercolors");
 448                 BADCVAR("sv_defaultplayermodel");
 449                 BADCVAR("sv_defaultplayerskin");
 450                 BADCVAR("sv_maxidle");
 451                 BADCVAR("sv_maxrate");
 452                 BADCVAR("sv_motd");
 453                 BADCVAR("sv_public");
 454                 BADCVAR("sv_ready_restart");
 455                 BADCVAR("sv_status_privacy");
 456                 BADCVAR("sv_taunt");
 457                 BADCVAR("sv_vote_call");
 458                 BADCVAR("sv_vote_commands");
 459                 BADCVAR("sv_vote_majority_factor");
 460                 BADCVAR("sv_vote_master");
 461                 BADCVAR("sv_vote_master_commands");
 462                 BADCVAR("sv_vote_master_password");
 463                 BADCVAR("sv_vote_simple_majority_factor");
 464                 BADCVAR("teamplay_mode");
 465                 BADCVAR("timelimit_override");
 466                 BADPREFIX("g_warmup_");
 467                 BADPREFIX("sv_info_");
 468                 BADPREFIX("sv_ready_restart_");
 469
 470                 // mutators that announce themselves properly to the server browser
 471                 BADCVAR("g_instagib");
 472                 BADCVAR("g_new_toys");
 473                 BADCVAR("g_nix");
 474                 BADCVAR("g_grappling_hook");
 475                 BADCVAR("g_jetpack");
 476
 477 #undef BADPRESUFFIX
 478 #undef BADPREFIX
 479 #undef BADCVAR
 480
 481                 if(pureadding)
 482                 {
 483                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 484                         if(strlen(cvar_purechanges) > 16384)
 485                         {
 486                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 487                                 pureadding = 0;
 488                         }
 489                 }
 490                 ++cvar_purechanges_count;
 491                 // WARNING: this variable is used for the server list
 492                 // NEVER dare to skip this code!
 493                 // Hacks to intentionally appearing as "pure server" even though you DO have
 494                 // modified settings may be punished by removal from the server list.
 495                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 496                 // though.
 497         }
 498         buf_del(h);
 499         if(cvar_changes == "")
 500                 cvar_changes = "// this server runs at default server settings\n";
 501         else
 502                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 503         cvar_changes = strzone(cvar_changes);
 504         if(cvar_purechanges == "")
 505                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 506         else
 507                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 508         cvar_purechanges = strzone(cvar_purechanges);
 509 }
 510
 511 void detect_maptype()
 512 {
 513 #if 0
 514         vector o, v;
 515         float i;
 516
 517         for (;;)
 518         {
 519                 o = world.mins;
 520                 o.x += random() * (world.maxs.x - world.mins.x);
 521                 o.y += random() * (world.maxs.y - world.mins.y);
 522                 o.z += random() * (world.maxs.z - world.mins.z);
 523
 524                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 525                 if(trace_fraction == 1)
 526                         continue;
 527
 528                 v = trace_endpos;
 529
 530                 for(i = 0; i < 64; i += 4)
 531                 {
 532                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 533         if(trace_fraction == 1)
 534                 continue;
 535                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos));
 536                 }
 537
 538                 break;
 539         }
 540 #endif
 541 }
 542
 543 entity randomseed;
 544 bool RandomSeed_Send(entity this, entity to, int sf)
 545 {
 546         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 547         WriteShort(MSG_ENTITY, this.cnt);
 548         return true;
 549 }
 550 void RandomSeed_Think(entity this)
 551 {
 552         this.cnt = bound(0, floor(random() * 65536), 65535);
 553         this.nextthink = time + 5;
 554
 555         this.SendFlags |= 1;
 556 }
 557 void RandomSeed_Spawn()
 558 {
 559         randomseed = new_pure(randomseed);
 560         setthink(randomseed, RandomSeed_Think);
 561         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 562
 563         getthink(randomseed)(randomseed); // sets random seed and nextthink
 564 }
 565
 566 spawnfunc(__init_dedicated_server)
 567 {
 568         // handler for _init/_init map (only for dedicated server initialization)
 569
 570         world_initialized = -1; // don't complain
 571         cvar = cvar_normal;
 572         cvar_string = cvar_string_normal;
 573         cvar_set = cvar_set_normal;
 574
 575         delete_fn = remove_unsafely;
 576
 577         entity e = spawn();
 578         setthink(e, GotoFirstMap);
 579         e.nextthink = time; // this is usually 1 at this point
 580
 581         e = new(info_player_deathmatch);  // safeguard against player joining
 582
 583         this.classname = "worldspawn"; // safeguard against various stuff ;)
 584
 585         // needs to be done so early because of the constants they create
 586         static_init();
 587         static_init_late();
 588         static_init_precache();
 589
 590         IL_PUSH(g_spawnpoints, e); // just incase
 591
 592         MapInfo_Enumerate();
 593         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 594 }
 595
 596 void __init_dedicated_server_shutdown() {
 597         MapInfo_Shutdown();
 598 }
 599
 600 void Map_MarkAsRecent(string m);
 601 float world_already_spawned;
 602 void Nagger_Init();
 603 void ClientInit_Spawn();
 604 void WeaponStats_Init();
 605 void WeaponStats_Shutdown();
 606 spawnfunc(worldspawn)
 607 {
 608         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 609
 610     bool wantrestart = false;
 611         {
 612                 if (!server_is_dedicated)
 613                 {
 614                         // force unloading of server pk3 files when starting a listen server
 615                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 616                         // restore csqc_progname too
 617                         string expect = "csprogs.dat";
 618                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 619                         cvar_set_normal("csqc_progname", expect);
 620                 }
 621                 else
 622                 {
 623                         // Try to use versioned csprogs from pk3
 624                         // Only ever use versioned csprogs.dat files on dedicated servers;
 625                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 626                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 627                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 628                         string select = "csprogs.dat";
 629                         if (fexists(pk3csprogs)) select = pk3csprogs;
 630                         if (cvar_string_normal("csqc_progname") != select)
 631                         {
 632                                 cvar_set_normal("csqc_progname", select);
 633                                 wantrestart = true;
 634                         }
 635                         // Check for updates on startup
 636                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 637                         int sentinel = fopen("progs.txt", FILE_READ);
 638                         if (sentinel >= 0)
 639                         {
 640                                 string switchversion = fgets(sentinel);
 641                                 fclose(sentinel);
 642                                 if (switchversion != "" && switchversion != WATERMARK)
 643                                 {
 644                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 645                                         // if it doesn't exist, assume either:
 646                                         //   a) the current program was overwritten
 647                                         //   b) this is a client only update
 648                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 649                                         if (fexists(newprogs))
 650                                         {
 651                                                 cvar_set_normal("sv_progs", newprogs);
 652                                                 wantrestart = true;
 653                                         }
 654                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 655                                         if (fexists(newcsprogs))
 656                                         {
 657                                                 cvar_set_normal("csqc_progname", newcsprogs);
 658                                                 wantrestart = true;
 659                                         }
 660                                 }
 661                         }
 662                 }
 663                 if (wantrestart)
 664                 {
 665                         LOG_INFOF("Restart requested");
 666                         changelevel(mapname);
 667                         // let initialization continue, shutdown depends on it
 668                 }
 669         }
 670
 671         cvar = cvar_normal;
 672         cvar_string = cvar_string_normal;
 673         cvar_set = cvar_set_normal;
 674
 675         if(world_already_spawned)
 676                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 677         world_already_spawned = true;
 678
 679         delete_fn = remove_safely; // during spawning, watch what you remove!
 680
 681         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 682
 683         maxclients = 0;
 684         for (entity head = nextent(NULL); head; head = nextent(head))
 685         {
 686                 ++maxclients;
 687         }
 688
 689         // needs to be done so early because of the constants they create
 690         static_init();
 691
 692         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 693
 694         TemporaryDB = db_create();
 695
 696         // 0 normal
 697         lightstyle(0, "m");
 698
 699         // 1 FLICKER (first variety)
 700         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 701
 702         // 2 SLOW STRONG PULSE
 703         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 704
 705         // 3 CANDLE (first variety)
 706         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 707
 708         // 4 FAST STROBE
 709         lightstyle(4, "mamamamamama");
 710
 711         // 5 GENTLE PULSE 1
 712         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 713
 714         // 6 FLICKER (second variety)
 715         lightstyle(6, "nmonqnmomnmomomno");
 716
 717         // 7 CANDLE (second variety)
 718         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 719
 720         // 8 CANDLE (third variety)
 721         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 722
 723         // 9 SLOW STROBE (fourth variety)
 724         lightstyle(9, "aaaaaaaazzzzzzzz");
 725
 726         // 10 FLUORESCENT FLICKER
 727         lightstyle(10, "mmamammmmammamamaaamammma");
 728
 729         // 11 SLOW PULSE NOT FADE TO BLACK
 730         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 731
 732         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 733
 734         // 63 testing
 735         lightstyle(63, "a");
 736
 737         if(autocvar_g_campaign)
 738                 CampaignPreInit();
 739
 740         Map_MarkAsRecent(mapname);
 741
 742         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 743
 744         InitGameplayMode();
 745         static_init_late();
 746         static_init_precache();
 747         readlevelcvars();
 748         GrappleHookInit();
 749
 750     GameRules_limit_fallbacks();
 751
 752         if(warmup_limit == 0)
 753                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 754
 755         player_count = 0;
 756         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 757         if(bot_waypoints_for_items == 1)
 758                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 759                         bot_waypoints_for_items = 0;
 760
 761         precache();
 762
 763         WaypointSprite_Init();
 764
 765         GameLogInit(); // prepare everything
 766         // NOTE for matchid:
 767         // changing the logic generating it is okay. But:
 768         // it HAS to stay <= 64 chars
 769         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 770         if(autocvar_sv_eventlog)
 771         {
 772                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 773                 matchid = strzone(s);
 774
 775                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 776                 s = ":gameinfo:mutators:LIST";
 777
 778                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 779                 s = M_ARGV(0, string);
 780
 781                 // initialiation stuff, not good in the mutator system
 782                 if(!autocvar_g_use_ammunition)
 783                         s = strcat(s, ":no_use_ammunition");
 784
 785                 // initialiation stuff, not good in the mutator system
 786                 if(autocvar_g_pickup_items == 0)
 787                         s = strcat(s, ":no_pickup_items");
 788                 if(autocvar_g_pickup_items > 0)
 789                         s = strcat(s, ":pickup_items");
 790
 791                 // initialiation stuff, not good in the mutator system
 792                 if(autocvar_g_weaponarena != "0")
 793                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 794
 795                 // TODO to mutator system
 796                 if(autocvar_g_norecoil)
 797                         s = strcat(s, ":norecoil");
 798
 799                 // TODO to mutator system
 800                 if(autocvar_g_powerups == 0)
 801                         s = strcat(s, ":no_powerups");
 802                 if(autocvar_g_powerups > 0)
 803                         s = strcat(s, ":powerups");
 804
 805                 GameLogEcho(s);
 806                 GameLogEcho(":gameinfo:end");
 807         }
 808         else
 809                 matchid = strzone(ftos(random()));
 810
 811         cvar_set("nextmap", "");
 812
 813         SetDefaultAlpha();
 814
 815         if(autocvar_g_campaign)
 816                 CampaignPostInit();
 817
 818         Ban_LoadBans();
 819
 820         MapInfo_Enumerate();
 821         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 822
 823         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 824         {
 825                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 826                 if(fd != -1)
 827                 {
 828                         string s;
 829                         while((s = fgets(fd)))
 830                         {
 831                                 int l = tokenize_console(s);
 832                                 if(l < 2)
 833                                         continue;
 834                                 if(argv(0) == "cd")
 835                                 {
 836                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 837                                         LOG_INFO("  cdtrack ", argv(2));
 838                                 }
 839                                 else if(argv(0) == "fog")
 840                                 {
 841                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 842                                         LOG_INFO("  \"fog\" \"", s, "\"");
 843                                 }
 844                                 else if(argv(0) == "set")
 845                                 {
 846                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 847                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 848                                 }
 849                                 else if(argv(0) != "//")
 850                                 {
 851                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 852                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 853                                 }
 854                         }
 855                         fclose(fd);
 856                 }
 857         }
 858
 859         WeaponStats_Init();
 860
 861         Nagger_Init();
 862
 863         next_pingtime = time + 5;
 864
 865         detect_maptype();
 866
 867         // set up information replies for clients and server to use
 868         maplist_reply = strzone(getmaplist());
 869         lsmaps_reply = strzone(getlsmaps());
 870         monsterlist_reply = strzone(getmonsterlist());
 871         for(int i = 0; i < 10; ++i)
 872         {
 873                 string s = getrecords(i);
 874                 if (s)
 875                         records_reply[i] = strzone(s);
 876         }
 877         ladder_reply = strzone(getladder());
 878         rankings_reply = strzone(getrankings());
 879
 880         // begin other init
 881         ClientInit_Spawn();
 882         RandomSeed_Spawn();
 883         PingPLReport_Spawn();
 884
 885         CheatInit();
 886
 887         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 888
 889         // fill sv_curl_serverpackages from .serverpackage files
 890         if (autocvar_sv_curl_serverpackages_auto)
 891         {
 892                 string s = "csprogs-" WATERMARK ".txt";
 893                 // remove automatically managed files from the list to prevent duplicates
 894                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 895                 {
 896                         string pkg = argv(i);
 897                         if (startsWith(pkg, "csprogs-")) continue;
 898                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 899                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 900                         s = cons(s, pkg);
 901                 }
 902                 // add automatically managed files to the list
 903                 #define X(match) MACRO_BEGIN { \
 904                         int fd = search_begin(match, true, false); \
 905                         if (fd >= 0) \
 906                         { \
 907                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 908                                 { \
 909                                         s = cons(s, search_getfilename(fd, i)); \
 910                                 } \
 911                                 search_end(fd); \
 912                         } \
 913                 } MACRO_END
 914                 X("*-serverpackage.txt");
 915                 X("*.serverpackage");
 916                 #undef X
 917                 cvar_set("sv_curl_serverpackages", s);
 918         }
 919
 920         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 921         modname = "Xonotic";
 922         // physics/balance/config changes that count as mod
 923         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 924                 modname = cvar_string("g_mod_physics");
 925         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 926                 modname = cvar_string("g_mod_balance");
 927         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 928                 modname = cvar_string("g_mod_config");
 929         // extra mutators that deserve to count as mod
 930         MUTATOR_CALLHOOK(SetModname, modname);
 931         modname = M_ARGV(0, string);
 932
 933         // save it for later
 934         modname = strzone(modname);
 935
 936         WinningConditionHelper(this); // set worldstatus
 937
 938         world_initialized = 1;
 939 }
 940
 941 spawnfunc(light)
 942 {
 943         //makestatic (this); // Who the f___ did that?
 944         delete(this);
 945 }
 946
 947 string GetGametype()
 948 {
 949         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 950 }
 951
 952 string GetMapname()
 953 {
 954         return mapname;
 955 }
 956
 957 float Map_Count, Map_Current;
 958 string Map_Current_Name;
 959
 960 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 961 float GetMaplistPosition()
 962 {
 963         float pos, idx;
 964         string map;
 965
 966         map = GetMapname();
 967         idx = autocvar_g_maplist_index;
 968
 969         if(idx >= 0)
 970                 if(idx < Map_Count)
 971                         if(map == argv(idx))
 972                                 return idx;
 973
 974         for(pos = 0; pos < Map_Count; ++pos)
 975                 if(map == argv(pos))
 976                         return pos;
 977
 978         // resume normal maplist rotation if current map is not in g_maplist
 979         return idx;
 980 }
 981
 982 float MapHasRightSize(string map)
 983 {
 984         float fh;
 985         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 986         if(autocvar_g_maplist_check_waypoints)
 987         {
 988                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 989                 if(!fexists(strcat("maps/", map, ".waypoints")))
 990                 {
 991                         LOG_TRACE(": no waypoints");
 992                         return false;
 993                 }
 994                 LOG_TRACE(": has waypoints");
 995         }
 996
 997         // open map size restriction file
 998         LOG_TRACE("opensize "); LOG_TRACE(map);
 999         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1000         if(fh >= 0)
1001         {
1002                 float mapmin, mapmax;
1003                 LOG_TRACE(": ok, ");
1004                 mapmin = stof(fgets(fh));
1005                 mapmax = stof(fgets(fh));
1006                 fclose(fh);
1007                 if(player_count < mapmin)
1008                 {
1009                         LOG_TRACE("not enough");
1010                         return false;
1011                 }
1012                 if(player_count > mapmax)
1013                 {
1014                         LOG_TRACE("too many");
1015                         return false;
1016                 }
1017                 LOG_TRACE("right size");
1018                 return true;
1019         }
1020         LOG_TRACE(": not found");
1021         return true;
1022 }
1023
1024 string Map_Filename(float position)
1025 {
1026         return strcat("maps/", argv(position), ".bsp");
1027 }
1028
1029 void Map_MarkAsRecent(string m)
1030 {
1031         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1032 }
1033
1034 float Map_IsRecent(string m)
1035 {
1036         return strhasword(autocvar_g_maplist_mostrecent, m);
1037 }
1038
1039 float Map_Check(float position, float pass)
1040 {
1041         string filename;
1042         string map_next;
1043         map_next = argv(position);
1044         if(pass <= 1)
1045         {
1046                 if(Map_IsRecent(map_next))
1047                         return 0;
1048         }
1049         filename = Map_Filename(position);
1050         if(MapInfo_CheckMap(map_next))
1051         {
1052                 if(pass == 2)
1053                         return 1;
1054                 if(MapHasRightSize(map_next))
1055                         return 1;
1056                 return 0;
1057         }
1058         else
1059                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1060
1061         return 0;
1062 }
1063
1064 void Map_Goto_SetStr(string nextmapname)
1065 {
1066         if(getmapname_stored != "")
1067                 strunzone(getmapname_stored);
1068         if(nextmapname == "")
1069                 getmapname_stored = "";
1070         else
1071                 getmapname_stored = strzone(nextmapname);
1072 }
1073
1074 void Map_Goto_SetFloat(float position)
1075 {
1076         cvar_set("g_maplist_index", ftos(position));
1077         Map_Goto_SetStr(argv(position));
1078 }
1079
1080 void Map_Goto(float reinit)
1081 {
1082         MapInfo_LoadMap(getmapname_stored, reinit);
1083 }
1084
1085 // return codes of map selectors:
1086 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1087 //   -2 = permanent failure
1088 float() MaplistMethod_Iterate = // usual method
1089 {
1090         float pass, i;
1091
1092         LOG_TRACE("Trying MaplistMethod_Iterate");
1093
1094         for(pass = 1; pass <= 2; ++pass)
1095         {
1096                 for(i = 1; i < Map_Count; ++i)
1097                 {
1098                         float mapindex;
1099                         mapindex = (i + Map_Current) % Map_Count;
1100                         if(Map_Check(mapindex, pass))
1101                                 return mapindex;
1102                 }
1103         }
1104         return -1;
1105 }
1106
1107 float() MaplistMethod_Repeat = // fallback method
1108 {
1109         LOG_TRACE("Trying MaplistMethod_Repeat");
1110
1111         if(Map_Check(Map_Current, 2))
1112                 return Map_Current;
1113         return -2;
1114 }
1115
1116 float() MaplistMethod_Random = // random map selection
1117 {
1118         float i, imax;
1119
1120         LOG_TRACE("Trying MaplistMethod_Random");
1121
1122         imax = 42;
1123
1124         for(i = 0; i <= imax; ++i)
1125         {
1126                 float mapindex;
1127                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1128                 if(Map_Check(mapindex, 1))
1129                         return mapindex;
1130         }
1131         return -1;
1132 }
1133
1134 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1135 // the exponent sets a bias on the map selection:
1136 // the higher the exponent, the less likely "shortly repeated" same maps are
1137 {
1138         float i, j, imax, insertpos;
1139
1140         LOG_TRACE("Trying MaplistMethod_Shuffle");
1141
1142         imax = 42;
1143
1144         for(i = 0; i <= imax; ++i)
1145         {
1146                 string newlist;
1147
1148                 // now reinsert this at another position
1149                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1150                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1151                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1152                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1153
1154                 // insert the current map there
1155                 newlist = "";
1156                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1157                         newlist = strcat(newlist, " ", argv(j));
1158                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1159                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1160                         newlist = strcat(newlist, " ", argv(j));
1161                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1162                 cvar_set("g_maplist", newlist);
1163                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1164
1165                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1166                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1167                 if(Map_Check(Map_Current, 1))
1168                         return Map_Current;
1169         }
1170         return -1;
1171 }
1172
1173 void Maplist_Init()
1174 {
1175         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1176         float i;
1177         for (i = 0; i < Map_Count; ++i)
1178                 if (Map_Check(i, 2))
1179                         break;
1180         if (i == Map_Count)
1181         {
1182                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1183                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1184                 if(autocvar_g_maplist_shuffle)
1185                         ShuffleMaplist();
1186                 localcmd("\nmenu_cmd sync\n");
1187                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1188         }
1189         if(Map_Count == 0)
1190                 error("empty maplist, cannot select a new map");
1191         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1192
1193         if(Map_Current_Name)
1194                 strunzone(Map_Current_Name);
1195         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1196         // this may or may not be correct, but who cares, in the worst case a map
1197         // isn't chosen in the first pass that should have been
1198 }
1199
1200 string GetNextMap()
1201 {
1202         float nextMap;
1203
1204         Maplist_Init();
1205         nextMap = -1;
1206
1207         if(nextMap == -1)
1208                 if(autocvar_g_maplist_shuffle > 0)
1209                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1210
1211         if(nextMap == -1)
1212                 if(autocvar_g_maplist_selectrandom)
1213                         nextMap = MaplistMethod_Random();
1214
1215         if(nextMap == -1)
1216                 nextMap = MaplistMethod_Iterate();
1217
1218         if(nextMap == -1)
1219                 nextMap = MaplistMethod_Repeat();
1220
1221         if(nextMap >= 0)
1222         {
1223                 Map_Goto_SetFloat(nextMap);
1224                 return getmapname_stored;
1225         }
1226
1227         return "";
1228 }
1229
1230 float DoNextMapOverride(float reinit)
1231 {
1232         if(autocvar_g_campaign)
1233         {
1234                 CampaignPostIntermission();
1235                 alreadychangedlevel = true;
1236                 return true;
1237         }
1238         if(autocvar_quit_when_empty)
1239         {
1240                 if(player_count <= currentbots)
1241                 {
1242                         localcmd("quit\n");
1243                         alreadychangedlevel = true;
1244                         return true;
1245                 }
1246         }
1247         if(autocvar_quit_and_redirect != "")
1248         {
1249                 redirection_target = strzone(autocvar_quit_and_redirect);
1250                 alreadychangedlevel = true;
1251                 return true;
1252         }
1253         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1254         {
1255                 localcmd("restart\n");
1256                 alreadychangedlevel = true;
1257                 return true;
1258         }
1259         if(autocvar_nextmap != "")
1260         {
1261                 string m;
1262                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1263                 cvar_set("nextmap",m);
1264
1265                 if(!m || gametypevote)
1266                         return false;
1267                 if(autocvar_sv_vote_gametype)
1268                 {
1269                         Map_Goto_SetStr(m);
1270                         return false;
1271                 }
1272
1273                 if(MapInfo_CheckMap(m))
1274                 {
1275                         Map_Goto_SetStr(m);
1276                         Map_Goto(reinit);
1277                         alreadychangedlevel = true;
1278                         return true;
1279                 }
1280         }
1281         if(!reinit && autocvar_lastlevel)
1282         {
1283                 cvar_settemp_restore();
1284                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1285                 alreadychangedlevel = true;
1286                 return true;
1287         }
1288         return false;
1289 }
1290
1291 void GotoNextMap(float reinit)
1292 {
1293         //string nextmap;
1294         //float n, nummaps;
1295         //string s;
1296         if (alreadychangedlevel)
1297                 return;
1298         alreadychangedlevel = true;
1299
1300         string nextMap;
1301
1302         nextMap = GetNextMap();
1303         if(nextMap == "")
1304                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1305         Map_Goto(reinit);
1306 }
1307
1308
1309 /*
1310 ============
1311 IntermissionThink
1312
1313 When the player presses attack or jump, change to the next level
1314 ============
1315 */
1316 .float autoscreenshot;
1317 void IntermissionThink(entity this)
1318 {
1319         FixIntermissionClient(this);
1320
1321         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1322         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1323
1324         if( (server_screenshot || client_screenshot)
1325                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1326         {
1327                 this.autoscreenshot = -1;
1328                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1329                 return;
1330         }
1331
1332         if (time < intermission_exittime)
1333                 return;
1334
1335         if(!mapvote_initialized)
1336                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1337                         return;
1338
1339         MapVote_Start();
1340 }
1341
1342 /*
1343 ============
1344 FindIntermission
1345
1346 Returns the entity to view from
1347 ============
1348 */
1349 /*
1350 entity FindIntermission()
1351 {
1352         local   entity spot;
1353         local   float cyc;
1354
1355 // look for info_intermission first
1356         spot = find(NULL, classname, "info_intermission");
1357         if (spot)
1358         {       // pick a random one
1359                 cyc = random() * 4;
1360                 while (cyc > 1)
1361                 {
1362                         spot = find(spot, classname, "info_intermission");
1363                         if (!spot)
1364                                 spot = find(spot, classname, "info_intermission");
1365                         cyc = cyc - 1;
1366                 }
1367                 return spot;
1368         }
1369
1370 // then look for the start position
1371         spot = find(NULL, classname, "info_player_start");
1372         if (spot)
1373                 return spot;
1374
1375 // testinfo_player_start is only found in regioned levels
1376         spot = find(NULL, classname, "testplayerstart");
1377         if (spot)
1378                 return spot;
1379
1380 // then look for the start position
1381         spot = find(NULL, classname, "info_player_deathmatch");
1382         if (spot)
1383                 return spot;
1384
1385         //objerror ("FindIntermission: no spot");
1386         return NULL;
1387 }
1388 */
1389
1390 /*
1391 ===============================================================================
1392
1393 RULES
1394
1395 ===============================================================================
1396 */
1397
1398 void DumpStats(float final)
1399 {
1400         float file;
1401         string s;
1402         float to_console;
1403         float to_eventlog;
1404         float to_file;
1405         float i;
1406
1407         to_console = autocvar_sv_logscores_console;
1408         to_eventlog = autocvar_sv_eventlog;
1409         to_file = autocvar_sv_logscores_file;
1410
1411         if(!final)
1412         {
1413                 to_console = true; // always print printstats replies
1414                 to_eventlog = false; // but never print them to the event log
1415         }
1416
1417         if(to_eventlog)
1418                 if(autocvar_sv_eventlog_console)
1419                         to_console = false; // otherwise we get the output twice
1420
1421         if(final)
1422                 s = ":scores:";
1423         else
1424                 s = ":status:";
1425         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1426
1427         if(to_console)
1428                 LOG_INFO(s);
1429         if(to_eventlog)
1430                 GameLogEcho(s);
1431
1432         file = -1;
1433         if(to_file)
1434         {
1435                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1436                 if(file == -1)
1437                         to_file = false;
1438                 else
1439                         fputs(file, strcat(s, "\n"));
1440         }
1441
1442         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1443         if(to_console)
1444                 LOG_INFO(s);
1445         if(to_eventlog)
1446                 GameLogEcho(s);
1447         if(to_file)
1448                 fputs(file, strcat(s, "\n"));
1449
1450         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1451                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1452                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1453                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1454                         s = strcat(s, ftos(it.team), ":");
1455                 else
1456                         s = strcat(s, "spectator:");
1457
1458                 if(to_console)
1459                         LOG_INFO(s, playername(it, false));
1460                 if(to_eventlog)
1461                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1462                 if(to_file)
1463                         fputs(file, strcat(s, playername(it, false), "\n"));
1464         });
1465
1466         if(teamplay)
1467         {
1468                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1469                 if(to_console)
1470                         LOG_INFO(s);
1471                 if(to_eventlog)
1472                         GameLogEcho(s);
1473                 if(to_file)
1474                         fputs(file, strcat(s, "\n"));
1475
1476                 for(i = 1; i < 16; ++i)
1477                 {
1478                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1479                         s = strcat(s, ":", ftos(i));
1480                         if(to_console)
1481                                 LOG_INFO(s);
1482                         if(to_eventlog)
1483                                 GameLogEcho(s);
1484                         if(to_file)
1485                                 fputs(file, strcat(s, "\n"));
1486                 }
1487         }
1488
1489         if(to_console)
1490                 LOG_INFO(":end");
1491         if(to_eventlog)
1492                 GameLogEcho(":end");
1493         if(to_file)
1494         {
1495                 fputs(file, ":end\n");
1496                 fclose(file);
1497         }
1498 }
1499
1500 void FixIntermissionClient(entity e)
1501 {
1502         if(!e.autoscreenshot) // initial call
1503         {
1504                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1505                 e.health = -2342;
1506                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1507                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1508                 {
1509                     .entity weaponentity = weaponentities[slot];
1510                         if(e.(weaponentity))
1511                         {
1512                                 e.(weaponentity).effects = EF_NODRAW;
1513                                 if (e.(weaponentity).weaponchild)
1514                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1515                         }
1516                 }
1517                 if(IS_REAL_CLIENT(e))
1518                 {
1519                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1520                         RandomSelection_Init();
1521                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1522                                 RandomSelection_AddString(it, 1, 1);
1523                         });
1524                         if (RandomSelection_chosen_string != "")
1525                         {
1526                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1527                         }
1528                         msg_entity = e;
1529                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1530                 }
1531         }
1532 }
1533
1534 /*
1535 go to the next level for deathmatch
1536 only called if a time or frag limit has expired
1537 */
1538 void NextLevel()
1539 {
1540         game_stopped = true;
1541         intermission_running = 1; // game over
1542
1543         // enforce a wait time before allowing changelevel
1544         if(player_count > 0)
1545                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1546         else
1547                 intermission_exittime = -1;
1548
1549         /*
1550         WriteByte (MSG_ALL, SVC_CDTRACK);
1551         WriteByte (MSG_ALL, 3);
1552         WriteByte (MSG_ALL, 3);
1553         // done in FixIntermission
1554         */
1555
1556         //pos = FindIntermission ();
1557
1558         VoteReset();
1559
1560         DumpStats(true);
1561
1562         // send statistics
1563         PlayerStats_GameReport(true);
1564         WeaponStats_Shutdown();
1565
1566         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1567
1568         if(autocvar_sv_eventlog)
1569                 GameLogEcho(":gameover");
1570
1571         GameLogClose();
1572
1573         FOREACH_CLIENT(IS_PLAYER(it), {
1574                 FixIntermissionClient(it);
1575                 if(it.winning)
1576                         bprint(playername(it, false), " ^7wins.\n");
1577         });
1578
1579         target_music_kill();
1580
1581         if(autocvar_g_campaign)
1582                 CampaignPreIntermission();
1583
1584         MUTATOR_CALLHOOK(MatchEnd);
1585
1586         localcmd("\nsv_hook_gameend\n");
1587 }
1588
1589
1590 float InitiateSuddenDeath()
1591 {
1592         // Check first whether normal overtimes could be added before initiating suddendeath mode
1593         // - for this timelimit_overtime needs to be >0 of course
1594         // - also check the winning condition calculated in the previous frame and only add normal overtime
1595         //   again, if at the point at which timelimit would be extended again, still no winner was found
1596         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1597         {
1598                 return 1; // need to call InitiateOvertime later
1599         }
1600         else
1601         {
1602                 if(!checkrules_suddendeathend)
1603                 {
1604                         if(autocvar_g_campaign)
1605                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1606                         else
1607                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1608                         if(g_race && !g_race_qualifying)
1609                                 race_StartCompleting();
1610                 }
1611                 return 0;
1612         }
1613 }
1614
1615 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1616 {
1617         ++checkrules_overtimesadded;
1618         //add one more overtime by simply extending the timelimit
1619         float tl;
1620         tl = autocvar_timelimit;
1621         tl += autocvar_timelimit_overtime;
1622         cvar_set("timelimit", ftos(tl));
1623
1624         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1625 }
1626
1627 float GetWinningCode(float fraglimitreached, float equality)
1628 {
1629         if(autocvar_g_campaign == 1)
1630                 if(fraglimitreached)
1631                         return WINNING_YES;
1632                 else
1633                         return WINNING_NO;
1634
1635         else
1636                 if(equality)
1637                         if(fraglimitreached)
1638                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1639                         else
1640                                 return WINNING_NEVER;
1641                 else
1642                         if(fraglimitreached)
1643                                 return WINNING_YES;
1644                         else
1645                                 return WINNING_NO;
1646 }
1647
1648 // set the .winning flag for exactly those players with a given field value
1649 void SetWinners(.float field, float value)
1650 {
1651         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1652 }
1653
1654 // set the .winning flag for those players with a given field value
1655 void AddWinners(.float field, float value)
1656 {
1657         FOREACH_CLIENT(IS_PLAYER(it), {
1658                 if(it.(field) == value)
1659                         it.winning = 1;
1660         });
1661 }
1662
1663 // clear the .winning flags
1664 void ClearWinners()
1665 {
1666         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1667 }
1668
1669 void ShuffleMaplist()
1670 {
1671         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1672 }
1673
1674 float leaderfrags;
1675 float WinningCondition_Scores(float limit, float leadlimit)
1676 {
1677         float limitreached;
1678
1679         // TODO make everything use THIS winning condition (except LMS)
1680         WinningConditionHelper(NULL);
1681
1682         if(teamplay)
1683         {
1684                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1685                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1686                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1687                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1688         }
1689
1690         ClearWinners();
1691         if(WinningConditionHelper_winner)
1692                 WinningConditionHelper_winner.winning = 1;
1693         if(WinningConditionHelper_winnerteam >= 0)
1694                 SetWinners(team, WinningConditionHelper_winnerteam);
1695
1696         if(WinningConditionHelper_lowerisbetter)
1697         {
1698                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1699                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1700                 limit = -limit;
1701         }
1702
1703         if(WinningConditionHelper_zeroisworst)
1704                 leadlimit = 0; // not supported in this mode
1705
1706         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1707         // these modes always score in increments of 1, thus this makes sense
1708         {
1709                 if(leaderfrags != WinningConditionHelper_topscore)
1710                 {
1711                         leaderfrags = WinningConditionHelper_topscore;
1712
1713                         if (limit)
1714                         if (leaderfrags == limit - 1)
1715                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1716                         else if (leaderfrags == limit - 2)
1717                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1718                         else if (leaderfrags == limit - 3)
1719                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1720                 }
1721         }
1722
1723         limitreached = false;
1724         if(limit)
1725                 if(WinningConditionHelper_topscore >= limit)
1726                         limitreached = true;
1727         if(leadlimit)
1728         {
1729                 float leadlimitreached;
1730                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1731                 if(autocvar_leadlimit_and_fraglimit)
1732                         limitreached = (limitreached && leadlimitreached);
1733                 else
1734                         limitreached = (limitreached || leadlimitreached);
1735         }
1736
1737         if(limit)
1738                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1739
1740         return GetWinningCode(
1741                 WinningConditionHelper_topscore && limitreached,
1742                 WinningConditionHelper_equality
1743         );
1744 }
1745
1746 float WinningCondition_RanOutOfSpawns()
1747 {
1748         if(have_team_spawns <= 0)
1749                 return WINNING_NO;
1750
1751         if(!autocvar_g_spawn_useallspawns)
1752                 return WINNING_NO;
1753
1754         if(!some_spawn_has_been_used)
1755                 return WINNING_NO;
1756
1757         team1_score = team2_score = team3_score = team4_score = 0;
1758
1759         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
1760                 switch(it.team)
1761                 {
1762                         case NUM_TEAM_1: team1_score = 1; break;
1763                         case NUM_TEAM_2: team2_score = 1; break;
1764                         case NUM_TEAM_3: team3_score = 1; break;
1765                         case NUM_TEAM_4: team4_score = 1; break;
1766                 }
1767         });
1768
1769         IL_EACH(g_spawnpoints, true,
1770         {
1771                 switch(it.team)
1772                 {
1773                         case NUM_TEAM_1: team1_score = 1; break;
1774                         case NUM_TEAM_2: team2_score = 1; break;
1775                         case NUM_TEAM_3: team3_score = 1; break;
1776                         case NUM_TEAM_4: team4_score = 1; break;
1777                 }
1778         });
1779
1780         ClearWinners();
1781         if(team1_score + team2_score + team3_score + team4_score == 0)
1782         {
1783                 checkrules_equality = true;
1784                 return WINNING_YES;
1785         }
1786         else if(team1_score + team2_score + team3_score + team4_score == 1)
1787         {
1788                 float t, i;
1789                 if(team1_score)
1790                         t = NUM_TEAM_1;
1791                 else if(team2_score)
1792                         t = NUM_TEAM_2;
1793                 else if(team3_score)
1794                         t = NUM_TEAM_3;
1795                 else // if(team4_score)
1796                         t = NUM_TEAM_4;
1797                 CheckAllowedTeams(NULL);
1798                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1799                 {
1800                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1801                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1802                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1803                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1804                 }
1805
1806                 AddWinners(team, t);
1807                 return WINNING_YES;
1808         }
1809         else
1810                 return WINNING_NO;
1811 }
1812
1813 /*
1814 ============
1815 CheckRules_World
1816
1817 Exit deathmatch games upon conditions
1818 ============
1819 */
1820 void CheckRules_World()
1821 {
1822         float timelimit;
1823         float fraglimit;
1824         float leadlimit;
1825
1826         VoteThink();
1827         MapVote_Think();
1828
1829         SetDefaultAlpha();
1830
1831         if (intermission_running) // someone else quit the game already
1832         {
1833                 if(player_count == 0) // Nobody there? Then let's go to the next map
1834                         MapVote_Start();
1835                         // this will actually check the player count in the next frame
1836                         // again, but this shouldn't hurt
1837                 return;
1838         }
1839
1840         timelimit = autocvar_timelimit * 60;
1841         fraglimit = autocvar_fraglimit;
1842         leadlimit = autocvar_leadlimit;
1843
1844         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1845         {
1846                 if(timelimit > 0)
1847                         timelimit = 0; // timelimit is not made for warmup
1848                 if(fraglimit > 0)
1849                         fraglimit = 0; // no fraglimit for now
1850                 leadlimit = 0; // no leadlimit for now
1851         }
1852
1853         if(timelimit > 0)
1854         {
1855                 timelimit += game_starttime;
1856         }
1857         else if (timelimit < 0)
1858         {
1859                 // endmatch
1860                 NextLevel();
1861                 return;
1862         }
1863
1864         float wantovertime;
1865         wantovertime = 0;
1866
1867         if(timelimit > game_starttime)
1868                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1869         else
1870                 game_completion_ratio = 0;
1871
1872         if(checkrules_suddendeathend)
1873         {
1874                 if(!checkrules_suddendeathwarning)
1875                 {
1876                         checkrules_suddendeathwarning = true;
1877                         if(g_race && !g_race_qualifying)
1878                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1879                         else
1880                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1881                 }
1882         }
1883         else
1884         {
1885                 if (timelimit && time >= timelimit)
1886                 {
1887                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1888                         {
1889                                 float totalplayers;
1890                                 float playerswithlaps;
1891                                 float readyplayers;
1892                                 totalplayers = playerswithlaps = readyplayers = 0;
1893                                 FOREACH_CLIENT(IS_PLAYER(it), {
1894                                         ++totalplayers;
1895                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1896                                                 ++playerswithlaps;
1897                                         if(it.ready)
1898                                                 ++readyplayers;
1899                                 });
1900
1901                                 // at least 2 of the players have completed a lap: start the RACE
1902                                 // otherwise, the players should end the qualifying on their own
1903                                 if(readyplayers || playerswithlaps >= 2)
1904                                 {
1905                                         checkrules_suddendeathend = 0;
1906                                         ReadyRestart(); // go to race
1907                                         return;
1908                                 }
1909                                 else
1910                                         wantovertime |= InitiateSuddenDeath();
1911                         }
1912                         else
1913                                 wantovertime |= InitiateSuddenDeath();
1914                 }
1915         }
1916
1917         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1918         {
1919                 NextLevel();
1920                 return;
1921         }
1922
1923         int checkrules_status = WinningCondition_RanOutOfSpawns();
1924         if(checkrules_status == WINNING_YES)
1925                 bprint("Hey! Someone ran out of spawns!\n");
1926         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1927                 checkrules_status = M_ARGV(0, float);
1928         else
1929                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1930
1931         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1932         {
1933                 checkrules_status = WINNING_NEVER;
1934                 checkrules_overtimesadded = -1;
1935                 wantovertime |= InitiateSuddenDeath();
1936         }
1937
1938         if(checkrules_status == WINNING_NEVER)
1939                 // equality cases! Nobody wins if the overtime ends in a draw.
1940                 ClearWinners();
1941
1942         if(wantovertime)
1943         {
1944                 if(checkrules_status == WINNING_NEVER)
1945                         InitiateOvertime();
1946                 else
1947                         checkrules_status = WINNING_YES;
1948         }
1949
1950         if(checkrules_suddendeathend)
1951                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1952                         checkrules_status = WINNING_YES;
1953
1954         if(checkrules_status == WINNING_YES)
1955         {
1956                 //print("WINNING\n");
1957                 NextLevel();
1958         }
1959 }
1960
1961 string GotoMap(string m)
1962 {
1963         m = GameTypeVote_MapInfo_FixName(m);
1964         if (!m)
1965                 return "The map you suggested is not available on this server.";
1966         if (!autocvar_sv_vote_gametype)
1967         if(!MapInfo_CheckMap(m))
1968                 return "The map you suggested does not support the current game mode.";
1969         cvar_set("nextmap", m);
1970         cvar_set("timelimit", "-1");
1971         if(mapvote_initialized || alreadychangedlevel)
1972         {
1973                 if(DoNextMapOverride(0))
1974                         return "Map switch initiated.";
1975                 else
1976                         return "Hm... no. For some reason I like THIS map more.";
1977         }
1978         else
1979                 return "Map switch will happen after scoreboard.";
1980 }
1981
1982 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1983 void RunThink(entity this)
1984 {
1985         // don't let things stay in the past.
1986         // it is possible to start that way by a trigger with a local time.
1987         if(this.nextthink <= 0 || this.nextthink > time + frametime)
1988                 return;
1989
1990         float oldtime = time; // do we need to save this?
1991
1992         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
1993         {
1994                 time = max(oldtime, this.nextthink);
1995                 this.nextthink = 0;
1996
1997                 if(getthink(this))
1998                         getthink(this)(this);
1999                 // mods often set nextthink to time to cause a think every frame,
2000                 // we don't want to loop in that case, so exit if the new nextthink is
2001                 // <= the time the qc was told, also exit if it is past the end of the
2002                 // frame
2003                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2004                         break;
2005         }
2006
2007         time = oldtime;
2008 }
2009
2010 bool autocvar_sv_freezenonclients;
2011 bool autocvar_sv_gameplayfix_delayprojectiles;
2012 void Physics_Frame()
2013 {
2014         if(autocvar_sv_freezenonclients)
2015                 return;
2016
2017         FOREACH_ENTITY_FLOAT(pure_data, false,
2018         {
2019                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2020                         continue;
2021
2022                 //set_movetype(it, it.move_movetype);
2023                 // inline the set_movetype function, since this is called a lot
2024                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2025
2026                 if(it.move_movetype == MOVETYPE_NONE)
2027                         continue;
2028
2029                 if(it.move_qcphysics)
2030                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2031
2032                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2033                 {
2034                         // handle thinking here
2035                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2036                                 RunThink(it);
2037                 }
2038         });
2039
2040         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2041                 return;
2042
2043         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2044         {
2045                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2046                         continue;
2047                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2048         });
2049 }
2050
2051 void systems_update();
2052 void EndFrame()
2053 {
2054         anticheat_endframe();
2055
2056         Physics_Frame();
2057
2058         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2059                 entity e = IS_SPEC(it) ? it.enemy : it;
2060                 if (e.typehitsound) {
2061                         it.typehit_time = time;
2062                 } else if (e.killsound) {
2063                         it.kill_time = time;
2064                 } else if (e.damage_dealt) {
2065                         it.hit_time = time;
2066                         it.damage_dealt_total += ceil(e.damage_dealt);
2067                 }
2068         });
2069         // add 1 frametime because after this, engine SV_Physics
2070         // increases time by a frametime and then networks the frame
2071         // add another frametime because client shows everything with
2072         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2073         // needed!
2074         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2075         FOREACH_CLIENT(true, {
2076                 it.typehitsound = false;
2077                 it.damage_dealt = 0;
2078                 it.killsound = false;
2079                 antilag_record(it, CS(it), altime);
2080         });
2081         IL_EACH(g_monsters, true,
2082         {
2083                 antilag_record(it, it, altime);
2084         });
2085         systems_update();
2086         IL_ENDFRAME();
2087 }
2088
2089
2090 /*
2091  * RedirectionThink:
2092  * returns true if redirecting
2093  */
2094 float redirection_timeout;
2095 float redirection_nextthink;
2096 float RedirectionThink()
2097 {
2098         float clients_found;
2099
2100         if(redirection_target == "")
2101                 return false;
2102
2103         if(!redirection_timeout)
2104         {
2105                 cvar_set("sv_public", "-2");
2106                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2107                 if(redirection_target == "self")
2108                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2109                 else
2110                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2111         }
2112
2113         if(time < redirection_nextthink)
2114                 return true;
2115
2116         redirection_nextthink = time + 1;
2117
2118         clients_found = 0;
2119         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2120                 // TODO add timer
2121                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2122                 if(redirection_target == "self")
2123                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2124                 else
2125                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2126                 ++clients_found;
2127         });
2128
2129         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2130
2131         if(time > redirection_timeout || clients_found == 0)
2132                 localcmd("\nwait; wait; wait; quit\n");
2133
2134         return true;
2135 }
2136
2137 void TargetMusic_RestoreGame();
2138 void RestoreGame()
2139 {
2140         // Loaded from a save game
2141         // some things then break, so let's work around them...
2142
2143         // Progs DB (capture records)
2144         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2145
2146         // Mapinfo
2147         MapInfo_Shutdown();
2148         MapInfo_Enumerate();
2149         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2150         WeaponStats_Init();
2151
2152         TargetMusic_RestoreGame();
2153 }
2154
2155 void Shutdown()
2156 {
2157         game_stopped = 2;
2158
2159         if(world_initialized > 0)
2160         {
2161                 world_initialized = 0;
2162                 LOG_TRACE("Saving persistent data...");
2163                 Ban_SaveBans();
2164
2165                 // playerstats with unfinished match
2166                 PlayerStats_GameReport(false);
2167
2168                 if(!cheatcount_total)
2169                 {
2170                         if(autocvar_sv_db_saveasdump)
2171                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2172                         else
2173                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2174                 }
2175                 if(autocvar_developer)
2176                 {
2177                         if(autocvar_sv_db_saveasdump)
2178                                 db_dump(TemporaryDB, "server-temp.db");
2179                         else
2180                                 db_save(TemporaryDB, "server-temp.db");
2181                 }
2182                 CheatShutdown(); // must be after cheatcount check
2183                 db_close(ServerProgsDB);
2184                 db_close(TemporaryDB);
2185                 LOG_TRACE("Saving persistent data... done!");
2186                 // tell the bot system the game is ending now
2187                 bot_endgame();
2188
2189                 WeaponStats_Shutdown();
2190                 MapInfo_Shutdown();
2191         }
2192         else if(world_initialized == 0)
2193         {
2194                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2195         }
2196         else
2197         {
2198                 __init_dedicated_server_shutdown();
2199         }
2200 }