qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "../common/buffs.qh"
   4
   5 #if defined(CSQC)
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "../common/constants.qh"
   9     #include "../common/stats.qh"
  10     #include "../common/teams.qh"
  11     #include "../common/util.qh"
  12     #include "../common/monsters/sv_monsters.qh"
  13     #include "../common/weapons/weapons.qh"
  14     #include "weapons/weaponstats.qh"
  15     #include "autocvars.qh"
  16     #include "constants.qh"
  17     #include "defs.qh"
  18     #include "../common/notifications.qh"
  19     #include "mutators/mutators_include.qh"
  20     #include "campaign.qh"
  21     #include "../common/mapinfo.qh"
  22     #include "command/common.qh"
  23     #include "command/vote.qh"
  24     #include "command/getreplies.qh"
  25     #include "command/sv_cmd.qh"
  26     #include "anticheat.qh"
  27     #include "cheats.qh"
  28     #include "../common/playerstats.qh"
  29     #include "g_hook.qh"
  30     #include "scores.qh"
  31     #include "mapvoting.qh"
  32     #include "ipban.qh"
  33     #include "race.qh"
  34     #include "antilag.qh"
  35 #endif
  36
  37 const float LATENCY_THINKRATE = 10;
  38 .float latency_sum;
  39 .float latency_cnt;
  40 .float latency_time;
  41 entity pingplreport;
  42 void PingPLReport_Think()
  43 {
  44         float delta;
  45         entity e;
  46
  47         delta = 3 / maxclients;
  48         if(delta < sys_frametime)
  49                 delta = 0;
  50         self.nextthink = time + delta;
  51
  52         e = edict_num(self.cnt + 1);
  53         if(IS_REAL_CLIENT(e))
  54         {
  55                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  56                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  74                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = spawn();
  85         pingplreport.classname = "pingplreport";
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void GotoNextMap(float reinit);
  96 void ShuffleMaplist();
  97 float(float reinit) DoNextMapOverride;
  98
  99 void SetDefaultAlpha()
 100 {
 101         if(autocvar_g_running_guns)
 102         {
 103                 default_player_alpha = -1;
 104                 default_weapon_alpha = +1;
 105         }
 106         else if(g_cloaked)
 107         {
 108                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 109                 default_weapon_alpha = default_player_alpha;
 110         }
 111         else
 112         {
 113                 default_player_alpha = autocvar_g_player_alpha;
 114                 if(default_player_alpha == 0)
 115                         default_player_alpha = 1;
 116                 default_weapon_alpha = default_player_alpha;
 117         }
 118 }
 119
 120 void GotoFirstMap()
 121 {
 122         float n;
 123         if(autocvar__sv_init)
 124         {
 125                 // cvar_set("_sv_init", "0");
 126                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 127                 // to this "init" map on a dedicated server will cause no permanent
 128                 // harm
 129                 if(autocvar_g_maplist_shuffle)
 130                         ShuffleMaplist();
 131                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 132                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 133
 134                 MapInfo_Enumerate();
 135                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 136
 137                 if(!DoNextMapOverride(1))
 138                         GotoNextMap(1);
 139
 140                 return;
 141         }
 142
 143         if(time < 5)
 144         {
 145                 self.nextthink = time;
 146         }
 147         else
 148         {
 149                 self.nextthink = time + 1;
 150                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 151         }
 152 }
 153
 154 void cvar_changes_init()
 155 {
 156         float h;
 157         string k, v, d;
 158         float n, i, adding, pureadding;
 159
 160         if(cvar_changes)
 161                 strunzone(cvar_changes);
 162         cvar_changes = string_null;
 163         if(cvar_purechanges)
 164                 strunzone(cvar_purechanges);
 165         cvar_purechanges = string_null;
 166         cvar_purechanges_count = 0;
 167
 168         h = buf_create();
 169         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 170         n = buf_getsize(h);
 171
 172         adding = true;
 173         pureadding = true;
 174
 175         for(i = 0; i < n; ++i)
 176         {
 177                 k = bufstr_get(h, i);
 178
 179 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 180 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 181 #define BADCVAR(p) if(k == p) continue
 182
 183                 // general excludes and namespaces for server admin used cvars
 184                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 185
 186                 // internal
 187                 BADPREFIX("csqc_");
 188                 BADPREFIX("cvar_check_");
 189                 BADCVAR("gamecfg");
 190                 BADCVAR("g_configversion");
 191                 BADCVAR("g_maplist_index");
 192                 BADCVAR("halflifebsp");
 193                 BADPREFIX("sv_world");
 194
 195                 // client
 196                 BADPREFIX("chase_");
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("scoreboard_");
 200                 BADPREFIX("g_campaign");
 201                 BADPREFIX("g_waypointsprite_");
 202                 BADPREFIX("gl_");
 203                 BADPREFIX("joy");
 204                 BADPREFIX("hud_");
 205                 BADPREFIX("m_");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("snd_");
 212                 BADPREFIX("show");
 213                 BADPREFIX("sensitivity");
 214                 BADPREFIX("userbind");
 215                 BADPREFIX("v_");
 216                 BADPREFIX("vid_");
 217                 BADPREFIX("crosshair");
 218                 BADCVAR("mod_q3bsp_lightmapmergepower");
 219                 BADCVAR("mod_q3bsp_nolightmaps");
 220                 BADCVAR("fov");
 221                 BADCVAR("mastervolume");
 222                 BADCVAR("volume");
 223                 BADCVAR("bgmvolume");
 224
 225                 // private
 226                 BADCVAR("developer");
 227                 BADCVAR("log_dest_udp");
 228                 BADCVAR("net_address");
 229                 BADCVAR("net_address_ipv6");
 230                 BADCVAR("port");
 231                 BADCVAR("savedgamecfg");
 232                 BADCVAR("serverconfig");
 233                 BADCVAR("sv_autoscreenshot");
 234                 BADCVAR("sv_heartbeatperiod");
 235                 BADCVAR("sv_vote_master_password");
 236                 BADCVAR("sys_colortranslation");
 237                 BADCVAR("sys_specialcharactertranslation");
 238                 BADCVAR("timeformat");
 239                 BADCVAR("timestamps");
 240                 BADPREFIX("developer_");
 241                 BADPREFIX("g_ban_");
 242                 BADPREFIX("g_banned_list");
 243                 BADPREFIX("g_chat_flood_");
 244                 BADPREFIX("g_ghost_items");
 245                 BADPREFIX("g_playerstats_");
 246                 BADPREFIX("g_respawn_ghosts");
 247                 BADPREFIX("g_voice_flood_");
 248                 BADPREFIX("log_file");
 249                 BADPREFIX("rcon_");
 250                 BADPREFIX("sv_allowdownloads");
 251                 BADPREFIX("sv_autodemo");
 252                 BADPREFIX("sv_curl_");
 253                 BADPREFIX("sv_eventlog");
 254                 BADPREFIX("sv_logscores_");
 255                 BADPREFIX("sv_master");
 256                 BADPREFIX("sv_weaponstats_");
 257                 BADPREFIX("sv_waypointsprite_");
 258                 BADCVAR("rescan_pending");
 259
 260                 // these can contain player IDs, so better hide
 261                 BADPREFIX("g_forced_team_");
 262
 263                 // mapinfo
 264                 BADCVAR("fraglimit");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_ctf");
 269                 BADCVAR("g_cts");
 270                 BADCVAR("g_dm");
 271                 BADCVAR("g_domination");
 272                 BADCVAR("g_domination_default_teams");
 273                 BADCVAR("g_freezetag");
 274                 BADCVAR("g_freezetag_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_qualifying_timelimit");
 283                 BADCVAR("g_tdm");
 284                 BADCVAR("g_tdm_teams");
 285                 BADCVAR("leadlimit");
 286                 BADCVAR("nextmap");
 287                 BADCVAR("teamplay");
 288                 BADCVAR("timelimit");
 289
 290                 // long
 291                 BADCVAR("hostname");
 292                 BADCVAR("g_maplist");
 293                 BADCVAR("g_maplist_mostrecent");
 294                 BADCVAR("sv_motd");
 295
 296                 v = cvar_string(k);
 297                 d = cvar_defstring(k);
 298                 if(v == d)
 299                         continue;
 300
 301                 if(adding)
 302                 {
 303                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 304                         if(strlen(cvar_changes) > 16384)
 305                         {
 306                                 cvar_changes = "// too many settings have been changed to show them here\n";
 307                                 adding = 0;
 308                         }
 309                 }
 310
 311                 // now check if the changes are actually gameplay relevant
 312
 313                 // does nothing visible
 314                 BADCVAR("captureleadlimit_override");
 315                 BADCVAR("g_balance_kill_delay");
 316                 BADCVAR("g_ca_point_leadlimit");
 317                 BADCVAR("g_ctf_captimerecord_always");
 318                 BADCVAR("g_ctf_flag_glowtrails");
 319                 BADCVAR("g_ctf_flag_pickup_verbosename");
 320                 BADCVAR("g_domination_point_leadlimit");
 321                 BADCVAR("g_forced_respawn");
 322                 BADCVAR("g_keyhunt_point_leadlimit");
 323                 BADPREFIX("g_mod_");
 324                 BADCVAR("g_nexball_goalleadlimit");
 325                 BADCVAR("leadlimit_and_fraglimit");
 326                 BADCVAR("leadlimit_override");
 327                 BADCVAR("pausable");
 328                 BADCVAR("sv_allow_fullbright");
 329                 BADCVAR("sv_checkforpacketsduringsleep");
 330                 BADCVAR("sv_fraginfo");
 331                 BADCVAR("sv_timeout");
 332                 BADPREFIX("sv_timeout_");
 333                 BADPREFIX("crypto_");
 334                 BADPREFIX("g_chat_");
 335                 BADPREFIX("g_ctf_captimerecord_");
 336                 BADPREFIX("g_maplist_votable_");
 337                 BADPREFIX("net_");
 338                 BADPREFIX("prvm_");
 339                 BADPREFIX("skill_");
 340                 BADPREFIX("sv_cullentities_");
 341                 BADPREFIX("sv_fraginfo_");
 342                 BADPREFIX("sv_maxidle_");
 343                 BADPREFIX("sv_vote_");
 344                 BADPREFIX("timelimit_");
 345                 BADCVAR("gameversion");
 346                 BADPREFIX("gameversion_");
 347                 BADCVAR("sv_namechangetimer");
 348
 349                 // allowed changes to server admins (please sync this to server.cfg)
 350                 // vi commands:
 351                 //   :/"impure"/,$d
 352                 //   :g!,^\/\/[^ /],d
 353                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 354                 //   :%!sort
 355                 // yes, this does contain some redundant stuff, don't really care
 356                 BADCVAR("bot_config_file");
 357                 BADCVAR("bot_number");
 358                 BADCVAR("bot_prefix");
 359                 BADCVAR("bot_suffix");
 360                 BADCVAR("capturelimit_override");
 361                 BADCVAR("fraglimit_override");
 362                 BADCVAR("gametype");
 363                 BADCVAR("g_antilag");
 364                 BADCVAR("g_balance_teams");
 365                 BADCVAR("g_balance_teams_prevent_imbalance");
 366                 BADCVAR("g_balance_teams_scorefactor");
 367                 BADCVAR("g_ban_sync_trusted_servers");
 368                 BADCVAR("g_ban_sync_uri");
 369                 BADCVAR("g_ca_teams_override");
 370                 BADCVAR("g_ctf_ignore_frags");
 371                 BADCVAR("g_domination_point_limit");
 372                 BADCVAR("g_freezetag_teams_override");
 373                 BADCVAR("g_friendlyfire");
 374                 BADCVAR("g_fullbrightitems");
 375                 BADCVAR("g_fullbrightplayers");
 376                 BADCVAR("g_keyhunt_point_limit");
 377                 BADCVAR("g_keyhunt_teams_override");
 378                 BADCVAR("g_lms_lives_override");
 379                 BADCVAR("g_maplist");
 380                 BADCVAR("g_maplist_check_waypoints");
 381                 BADCVAR("g_maplist_mostrecent_count");
 382                 BADCVAR("g_maplist_shuffle");
 383                 BADCVAR("g_maplist_votable");
 384                 BADCVAR("g_maplist_votable_abstain");
 385                 BADCVAR("g_maplist_votable_nodetail");
 386                 BADCVAR("g_maplist_votable_suggestions");
 387                 BADCVAR("g_maxplayers");
 388                 BADCVAR("g_mirrordamage");
 389                 BADCVAR("g_nexball_goallimit");
 390                 BADCVAR("g_powerups");
 391                 BADCVAR("g_start_delay");
 392                 BADCVAR("g_warmup");
 393                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 394                 BADCVAR("hostname");
 395                 BADCVAR("log_file");
 396                 BADCVAR("maxplayers");
 397                 BADCVAR("minplayers");
 398                 BADCVAR("net_address");
 399                 BADCVAR("port");
 400                 BADCVAR("rcon_password");
 401                 BADCVAR("rcon_restricted_commands");
 402                 BADCVAR("rcon_restricted_password");
 403                 BADCVAR("skill");
 404                 BADCVAR("sv_adminnick");
 405                 BADCVAR("sv_autoscreenshot");
 406                 BADCVAR("sv_autotaunt");
 407                 BADCVAR("sv_curl_defaulturl");
 408                 BADCVAR("sv_defaultcharacter");
 409                 BADCVAR("sv_defaultplayercolors");
 410                 BADCVAR("sv_defaultplayermodel");
 411                 BADCVAR("sv_defaultplayerskin");
 412                 BADCVAR("sv_maxidle");
 413                 BADCVAR("sv_maxrate");
 414                 BADCVAR("sv_motd");
 415                 BADCVAR("sv_public");
 416                 BADCVAR("sv_ready_restart");
 417                 BADCVAR("sv_status_privacy");
 418                 BADCVAR("sv_taunt");
 419                 BADCVAR("sv_vote_call");
 420                 BADCVAR("sv_vote_commands");
 421                 BADCVAR("sv_vote_majority_factor");
 422                 BADCVAR("sv_vote_master");
 423                 BADCVAR("sv_vote_master_commands");
 424                 BADCVAR("sv_vote_master_password");
 425                 BADCVAR("sv_vote_simple_majority_factor");
 426                 BADCVAR("teamplay_mode");
 427                 BADCVAR("timelimit_override");
 428                 BADCVAR("g_spawnshieldtime");
 429                 BADPREFIX("g_warmup_");
 430                 BADPREFIX("sv_ready_restart_");
 431
 432                 // mutators that announce themselves properly to the server browser
 433                 BADCVAR("g_instagib");
 434                 BADCVAR("g_new_toys");
 435                 BADCVAR("g_nix");
 436                 BADCVAR("g_grappling_hook");
 437                 BADCVAR("g_jetpack");
 438
 439 #undef BADPREFIX
 440 #undef BADCVAR
 441
 442                 if(pureadding)
 443                 {
 444                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 445                         if(strlen(cvar_purechanges) > 16384)
 446                         {
 447                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 448                                 pureadding = 0;
 449                         }
 450                 }
 451                 ++cvar_purechanges_count;
 452                 // WARNING: this variable is used for the server list
 453                 // NEVER dare to skip this code!
 454                 // Hacks to intentionally appearing as "pure server" even though you DO have
 455                 // modified settings may be punished by removal from the server list.
 456                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 457                 // though.
 458         }
 459         buf_del(h);
 460         if(cvar_changes == "")
 461                 cvar_changes = "// this server runs at default server settings\n";
 462         else
 463                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 464         cvar_changes = strzone(cvar_changes);
 465         if(cvar_purechanges == "")
 466                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 467         else
 468                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 469         cvar_purechanges = strzone(cvar_purechanges);
 470 }
 471
 472 void detect_maptype()
 473 {
 474 #if 0
 475         vector o, v;
 476         float i;
 477
 478         for (;;)
 479         {
 480                 o = world.mins;
 481                 o.x += random() * (world.maxs.x - world.mins.x);
 482                 o.y += random() * (world.maxs.y - world.mins.y);
 483                 o.z += random() * (world.maxs.z - world.mins.z);
 484
 485                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 486                 if(trace_fraction == 1)
 487                         continue;
 488
 489                 v = trace_endpos;
 490
 491                 for(i = 0; i < 64; i += 4)
 492                 {
 493                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 494         if(trace_fraction == 1)
 495                 continue;
 496                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 497                 }
 498
 499                 break;
 500         }
 501 #endif
 502 }
 503
 504 entity randomseed;
 505 float RandomSeed_Send(entity to, float sf)
 506 {
 507         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 508         WriteShort(MSG_ENTITY, self.cnt);
 509         return true;
 510 }
 511 void RandomSeed_Think()
 512 {
 513         self.cnt = bound(0, floor(random() * 65536), 65535);
 514         self.nextthink = time + 5;
 515
 516         self.SendFlags |= 1;
 517 }
 518 void RandomSeed_Spawn()
 519 {
 520         randomseed = spawn();
 521         randomseed.think = RandomSeed_Think;
 522         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 523
 524         entity oldself;
 525         oldself = self;
 526         self = randomseed;
 527         self.think(); // sets random seed and nextthink
 528         self = oldself;
 529 }
 530
 531 void spawnfunc___init_dedicated_server(void)
 532 {
 533         // handler for _init/_init map (only for dedicated server initialization)
 534
 535         world_initialized = -1; // don't complain
 536         cvar = cvar_normal;
 537         cvar_string = cvar_string_normal;
 538         cvar_set = cvar_set_normal;
 539
 540         remove = remove_unsafely;
 541
 542         entity e;
 543         e = spawn();
 544         e.think = GotoFirstMap;
 545         e.nextthink = time; // this is usually 1 at this point
 546
 547         e = spawn();
 548         e.classname = "info_player_deathmatch"; // safeguard against player joining
 549
 550         self.classname = "worldspawn"; // safeguard against various stuff ;)
 551
 552         // needs to be done so early because of the constants they create
 553         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 554         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 555         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 556         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 557         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 558         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 559
 560         MapInfo_Enumerate();
 561         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 562 }
 563
 564 void Map_MarkAsRecent(string m);
 565 float world_already_spawned;
 566 void Nagger_Init();
 567 void ClientInit_Spawn();
 568 void WeaponStats_Init();
 569 void WeaponStats_Shutdown();
 570 void Physics_AddStats();
 571 void spawnfunc_worldspawn (void)
 572 {
 573         float fd, l, i, j, n;
 574         string s;
 575
 576         cvar = cvar_normal;
 577         cvar_string = cvar_string_normal;
 578         cvar_set = cvar_set_normal;
 579
 580         if(world_already_spawned)
 581                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 582         world_already_spawned = true;
 583
 584         remove = remove_safely; // during spawning, watch what you remove!
 585
 586         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 587
 588         compressShortVector_init();
 589
 590         entity head;
 591         head = nextent(world);
 592         maxclients = 0;
 593         while(head)
 594         {
 595                 ++maxclients;
 596                 head = nextent(head);
 597         }
 598
 599         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 600
 601         // needs to be done so early because of the constants they create
 602         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 603         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 604         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 605         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 606         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 607         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 608
 609         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 610
 611         TemporaryDB = db_create();
 612
 613         // 0 normal
 614         lightstyle(0, "m");
 615
 616         // 1 FLICKER (first variety)
 617         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 618
 619         // 2 SLOW STRONG PULSE
 620         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 621
 622         // 3 CANDLE (first variety)
 623         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 624
 625         // 4 FAST STROBE
 626         lightstyle(4, "mamamamamama");
 627
 628         // 5 GENTLE PULSE 1
 629         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 630
 631         // 6 FLICKER (second variety)
 632         lightstyle(6, "nmonqnmomnmomomno");
 633
 634         // 7 CANDLE (second variety)
 635         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 636
 637         // 8 CANDLE (third variety)
 638         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 639
 640         // 9 SLOW STROBE (fourth variety)
 641         lightstyle(9, "aaaaaaaazzzzzzzz");
 642
 643         // 10 FLUORESCENT FLICKER
 644         lightstyle(10, "mmamammmmammamamaaamammma");
 645
 646         // 11 SLOW PULSE NOT FADE TO BLACK
 647         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 648
 649         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 650
 651         // 63 testing
 652         lightstyle(63, "a");
 653
 654         if(autocvar_g_campaign)
 655                 CampaignPreInit();
 656
 657         Map_MarkAsRecent(mapname);
 658
 659         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 660
 661         precache_model ("null"); // we need this one before InitGameplayMode
 662         InitGameplayMode();
 663         readlevelcvars();
 664         GrappleHookInit();
 665
 666         player_count = 0;
 667         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 668         if(bot_waypoints_for_items == 1)
 669                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 670                         bot_waypoints_for_items = 0;
 671
 672         precache();
 673
 674         WaypointSprite_Init();
 675
 676         GameLogInit(); // prepare everything
 677         // NOTE for matchid:
 678         // changing the logic generating it is okay. But:
 679         // it HAS to stay <= 64 chars
 680         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 681         if(autocvar_sv_eventlog)
 682         {
 683                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 684                 matchid = strzone(s);
 685
 686                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 687                 s = ":gameinfo:mutators:LIST";
 688
 689                 ret_string = s;
 690                 MUTATOR_CALLHOOK(BuildMutatorsString);
 691                 s = ret_string;
 692
 693                 // simple, probably not good in the mutator system
 694                 if(autocvar_g_grappling_hook)
 695                         s = strcat(s, ":grappling_hook");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(!autocvar_g_use_ammunition)
 699                         s = strcat(s, ":no_use_ammunition");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_pickup_items == 0)
 703                         s = strcat(s, ":no_pickup_items");
 704                 if(autocvar_g_pickup_items > 0)
 705                         s = strcat(s, ":pickup_items");
 706
 707                 // initialiation stuff, not good in the mutator system
 708                 if(autocvar_g_weaponarena != "0")
 709                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 710
 711                 // TODO to mutator system
 712                 if(autocvar_g_norecoil)
 713                         s = strcat(s, ":norecoil");
 714
 715                 // TODO to mutator system
 716                 if(autocvar_g_powerups == 0)
 717                         s = strcat(s, ":no_powerups");
 718                 if(autocvar_g_powerups > 0)
 719                         s = strcat(s, ":powerups");
 720
 721                 GameLogEcho(s);
 722                 GameLogEcho(":gameinfo:end");
 723         }
 724         else
 725                 matchid = strzone(ftos(random()));
 726
 727         cvar_set("nextmap", "");
 728
 729         SetDefaultAlpha();
 730
 731         if(autocvar_g_campaign)
 732                 CampaignPostInit();
 733
 734         Ban_LoadBans();
 735
 736         MapInfo_Enumerate();
 737         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 738
 739         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 740         {
 741                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 742                 if(fd != -1)
 743                 {
 744                         while((s = fgets(fd)))
 745                         {
 746                                 l = tokenize_console(s);
 747                                 if(l < 2)
 748                                         continue;
 749                                 if(argv(0) == "cd")
 750                                 {
 751                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 752                                         print("  cdtrack ", argv(2), "\n");
 753                                 }
 754                                 else if(argv(0) == "fog")
 755                                 {
 756                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 757                                         print("  \"fog\" \"", s, "\"\n");
 758                                 }
 759                                 else if(argv(0) == "set")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 763                                 }
 764                                 else if(argv(0) != "//")
 765                                 {
 766                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 767                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 768                                 }
 769                         }
 770                         fclose(fd);
 771                 }
 772         }
 773
 774         WeaponStats_Init();
 775
 776         WepSet_AddStat();
 777         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 778         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 779         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 780         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 781         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 782         Nagger_Init();
 783
 784         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 785         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 786         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 787         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 788         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 789         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 790         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 791         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 792         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 793         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 794         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 795         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 796         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 797         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 798         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 799
 800         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 801         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 802
 803         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 804
 805         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 806
 807         // freeze attacks
 808         addstat(STAT_FROZEN, AS_INT, frozen);
 809         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 810
 811         // physics
 812         Physics_AddStats();
 813
 814         // secrets
 815         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 816         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 817
 818         // monsters
 819         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 820         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 821
 822         // misc
 823         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 824
 825         next_pingtime = time + 5;
 826
 827         detect_maptype();
 828
 829         // set up information replies for clients and server to use
 830         maplist_reply = strzone(getmaplist());
 831         lsmaps_reply = strzone(getlsmaps());
 832         monsterlist_reply = strzone(getmonsterlist());
 833         for(i = 0; i < 10; ++i)
 834         {
 835                 s = getrecords(i);
 836                 if (s)
 837                         records_reply[i] = strzone(s);
 838         }
 839         ladder_reply = strzone(getladder());
 840         rankings_reply = strzone(getrankings());
 841
 842         // begin other init
 843         ClientInit_Spawn();
 844         RandomSeed_Spawn();
 845         PingPLReport_Spawn();
 846
 847         CheatInit();
 848
 849         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 850
 851         // fill sv_curl_serverpackages from .serverpackage files
 852         if(autocvar_sv_curl_serverpackages_auto)
 853         {
 854                 s = "";
 855                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 856                 for(i = 0; i < n; ++i)
 857                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 858                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 859                                 s = strcat(s, " ", argv(i));
 860                 fd = search_begin("*-serverpackage.txt", true, false);
 861                 if(fd >= 0)
 862                 {
 863                         j = search_getsize(fd);
 864                         for(i = 0; i < j; ++i)
 865                                 s = strcat(s, " ", search_getfilename(fd, i));
 866                         search_end(fd);
 867                 }
 868                 fd = search_begin("*.serverpackage", true, false);
 869                 if(fd >= 0)
 870                 {
 871                         j = search_getsize(fd);
 872                         for(i = 0; i < j; ++i)
 873                                 s = strcat(s, " ", search_getfilename(fd, i));
 874                         search_end(fd);
 875                 }
 876                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 877         }
 878
 879         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 880         modname = "Xonotic";
 881         // physics/balance/config changes that count as mod
 882         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 883                 modname = cvar_string("g_mod_physics");
 884         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 885                 modname = cvar_string("g_mod_balance");
 886         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 887                 modname = cvar_string("g_mod_config");
 888         // extra mutators that deserve to count as mod
 889         MUTATOR_CALLHOOK(SetModname);
 890
 891         // save it for later
 892         modname = strzone(modname);
 893
 894         WinningConditionHelper(); // set worldstatus
 895
 896         world_initialized = 1;
 897 }
 898
 899 void spawnfunc_light (void)
 900 {
 901         //makestatic (self); // Who the f___ did that?
 902         remove(self);
 903 }
 904
 905 string GetGametype()
 906 {
 907         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 908 }
 909
 910 string GetMapname()
 911 {
 912         return mapname;
 913 }
 914
 915 float Map_Count, Map_Current;
 916 string Map_Current_Name;
 917
 918 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 919 float GetMaplistPosition()
 920 {
 921         float pos, idx;
 922         string map;
 923
 924         map = GetMapname();
 925         idx = autocvar_g_maplist_index;
 926
 927         if(idx >= 0)
 928                 if(idx < Map_Count)
 929                         if(map == argv(idx))
 930                                 return idx;
 931
 932         for(pos = 0; pos < Map_Count; ++pos)
 933                 if(map == argv(pos))
 934                         return pos;
 935
 936         // resume normal maplist rotation if current map is not in g_maplist
 937         return idx;
 938 }
 939
 940 float MapHasRightSize(string map)
 941 {
 942         float fh;
 943         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 944         if(autocvar_g_maplist_check_waypoints)
 945         {
 946                 dprint("checkwp "); dprint(map);
 947                 if(!fexists(strcat("maps/", map, ".waypoints")))
 948                 {
 949                         dprint(": no waypoints\n");
 950                         return false;
 951                 }
 952                 dprint(": has waypoints\n");
 953         }
 954
 955         // open map size restriction file
 956         dprint("opensize "); dprint(map);
 957         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 958         if(fh >= 0)
 959         {
 960                 float mapmin, mapmax;
 961                 dprint(": ok, ");
 962                 mapmin = stof(fgets(fh));
 963                 mapmax = stof(fgets(fh));
 964                 fclose(fh);
 965                 if(player_count < mapmin)
 966                 {
 967                         dprint("not enough\n");
 968                         return false;
 969                 }
 970                 if(player_count > mapmax)
 971                 {
 972                         dprint("too many\n");
 973                         return false;
 974                 }
 975                 dprint("right size\n");
 976                 return true;
 977         }
 978         dprint(": not found\n");
 979         return true;
 980 }
 981
 982 string Map_Filename(float position)
 983 {
 984         return strcat("maps/", argv(position), ".bsp");
 985 }
 986
 987 string strwords(string s, float w)
 988 {
 989         float endpos;
 990         for(endpos = 0; w && endpos >= 0; --w)
 991                 endpos = strstrofs(s, " ", endpos + 1);
 992         if(endpos < 0)
 993                 return s;
 994         else
 995                 return substring(s, 0, endpos);
 996 }
 997
 998 float strhasword(string s, string w)
 999 {
1000         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1001 }
1002
1003 void Map_MarkAsRecent(string m)
1004 {
1005         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1006 }
1007
1008 float Map_IsRecent(string m)
1009 {
1010         return strhasword(autocvar_g_maplist_mostrecent, m);
1011 }
1012
1013 float Map_Check(float position, float pass)
1014 {
1015         string filename;
1016         string map_next;
1017         map_next = argv(position);
1018         if(pass <= 1)
1019         {
1020                 if(Map_IsRecent(map_next))
1021                         return 0;
1022         }
1023         filename = Map_Filename(position);
1024         if(MapInfo_CheckMap(map_next))
1025         {
1026                 if(pass == 2)
1027                         return 1;
1028                 if(MapHasRightSize(map_next))
1029                         return 1;
1030                 return 0;
1031         }
1032         else
1033                 dprint( "Couldn't select '", filename, "'..\n" );
1034
1035         return 0;
1036 }
1037
1038 void Map_Goto_SetStr(string nextmapname)
1039 {
1040         if(getmapname_stored != "")
1041                 strunzone(getmapname_stored);
1042         if(nextmapname == "")
1043                 getmapname_stored = "";
1044         else
1045                 getmapname_stored = strzone(nextmapname);
1046 }
1047
1048 void Map_Goto_SetFloat(float position)
1049 {
1050         cvar_set("g_maplist_index", ftos(position));
1051         Map_Goto_SetStr(argv(position));
1052 }
1053
1054 void Map_Goto(float reinit)
1055 {
1056         MapInfo_LoadMap(getmapname_stored, reinit);
1057 }
1058
1059 // return codes of map selectors:
1060 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1061 //   -2 = permanent failure
1062 float() MaplistMethod_Iterate = // usual method
1063 {
1064         float pass, i;
1065
1066         dprint("Trying MaplistMethod_Iterate\n");
1067
1068         for(pass = 1; pass <= 2; ++pass)
1069         {
1070                 for(i = 1; i < Map_Count; ++i)
1071                 {
1072                         float mapindex;
1073                         mapindex = (i + Map_Current) % Map_Count;
1074                         if(Map_Check(mapindex, pass))
1075                                 return mapindex;
1076                 }
1077         }
1078         return -1;
1079 }
1080
1081 float() MaplistMethod_Repeat = // fallback method
1082 {
1083         dprint("Trying MaplistMethod_Repeat\n");
1084
1085         if(Map_Check(Map_Current, 2))
1086                 return Map_Current;
1087         return -2;
1088 }
1089
1090 float() MaplistMethod_Random = // random map selection
1091 {
1092         float i, imax;
1093
1094         dprint("Trying MaplistMethod_Random\n");
1095
1096         imax = 42;
1097
1098         for(i = 0; i <= imax; ++i)
1099         {
1100                 float mapindex;
1101                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1102                 if(Map_Check(mapindex, 1))
1103                         return mapindex;
1104         }
1105         return -1;
1106 }
1107
1108 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1109 // the exponent sets a bias on the map selection:
1110 // the higher the exponent, the less likely "shortly repeated" same maps are
1111 {
1112         float i, j, imax, insertpos;
1113
1114         dprint("Trying MaplistMethod_Shuffle\n");
1115
1116         imax = 42;
1117
1118         for(i = 0; i <= imax; ++i)
1119         {
1120                 string newlist;
1121
1122                 // now reinsert this at another position
1123                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1124                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1125                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1126                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1127
1128                 // insert the current map there
1129                 newlist = "";
1130                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1131                         newlist = strcat(newlist, " ", argv(j));
1132                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1133                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1134                         newlist = strcat(newlist, " ", argv(j));
1135                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1136                 cvar_set("g_maplist", newlist);
1137                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1138
1139                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1140                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1141                 if(Map_Check(Map_Current, 1))
1142                         return Map_Current;
1143         }
1144         return -1;
1145 }
1146
1147 void Maplist_Init()
1148 {
1149         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1150         float i;
1151         for (i = 0; i < Map_Count; ++i)
1152                 if (Map_Check(i, 2))
1153                         break;
1154         if (i == Map_Count)
1155         {
1156                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1157                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1158                 if(autocvar_g_maplist_shuffle)
1159                         ShuffleMaplist();
1160                 localcmd("\nmenu_cmd sync\n");
1161                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1162         }
1163         if(Map_Count == 0)
1164                 error("empty maplist, cannot select a new map");
1165         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1166
1167         if(Map_Current_Name)
1168                 strunzone(Map_Current_Name);
1169         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1170         // this may or may not be correct, but who cares, in the worst case a map
1171         // isn't chosen in the first pass that should have been
1172 }
1173
1174 string GetNextMap()
1175 {
1176         float nextMap;
1177
1178         Maplist_Init();
1179         nextMap = -1;
1180
1181         if(nextMap == -1)
1182                 if(autocvar_g_maplist_shuffle > 0)
1183                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1184
1185         if(nextMap == -1)
1186                 if(autocvar_g_maplist_selectrandom)
1187                         nextMap = MaplistMethod_Random();
1188
1189         if(nextMap == -1)
1190                 nextMap = MaplistMethod_Iterate();
1191
1192         if(nextMap == -1)
1193                 nextMap = MaplistMethod_Repeat();
1194
1195         if(nextMap >= 0)
1196         {
1197                 Map_Goto_SetFloat(nextMap);
1198                 return getmapname_stored;
1199         }
1200
1201         return "";
1202 }
1203
1204 float DoNextMapOverride(float reinit)
1205 {
1206         if(autocvar_g_campaign)
1207         {
1208                 CampaignPostIntermission();
1209                 alreadychangedlevel = true;
1210                 return true;
1211         }
1212         if(autocvar_quit_when_empty)
1213         {
1214                 if(player_count <= currentbots)
1215                 {
1216                         localcmd("quit\n");
1217                         alreadychangedlevel = true;
1218                         return true;
1219                 }
1220         }
1221         if(autocvar_quit_and_redirect != "")
1222         {
1223                 redirection_target = strzone(autocvar_quit_and_redirect);
1224                 alreadychangedlevel = true;
1225                 return true;
1226         }
1227         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1228         {
1229                 localcmd("restart\n");
1230                 alreadychangedlevel = true;
1231                 return true;
1232         }
1233         if(autocvar_nextmap != "")
1234         {
1235                 string m;
1236                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1237                 cvar_set("nextmap",m);
1238
1239                 if(!m || gametypevote)
1240                         return false;
1241                 if(autocvar_sv_vote_gametype)
1242                 {
1243                         Map_Goto_SetStr(m);
1244                         return false;
1245                 }
1246
1247                 if(MapInfo_CheckMap(m))
1248                 {
1249                         Map_Goto_SetStr(m);
1250                         Map_Goto(reinit);
1251                         alreadychangedlevel = true;
1252                         return true;
1253                 }
1254         }
1255         if(!reinit && autocvar_lastlevel)
1256         {
1257                 cvar_settemp_restore();
1258                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1259                 alreadychangedlevel = true;
1260                 return true;
1261         }
1262         return false;
1263 }
1264
1265 void GotoNextMap(float reinit)
1266 {
1267         //string nextmap;
1268         //float n, nummaps;
1269         //string s;
1270         if (alreadychangedlevel)
1271                 return;
1272         alreadychangedlevel = true;
1273
1274         string nextMap;
1275
1276         nextMap = GetNextMap();
1277         if(nextMap == "")
1278                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1279         Map_Goto(reinit);
1280 }
1281
1282
1283 /*
1284 ============
1285 IntermissionThink
1286
1287 When the player presses attack or jump, change to the next level
1288 ============
1289 */
1290 .float autoscreenshot;
1291 void IntermissionThink()
1292 {
1293         FixIntermissionClient(self);
1294
1295         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1296         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1297
1298         if( (server_screenshot || client_screenshot)
1299                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1300         {
1301                 self.autoscreenshot = -1;
1302                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1303                 return;
1304         }
1305
1306         if (time < intermission_exittime)
1307                 return;
1308
1309         if(!mapvote_initialized)
1310                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1311                         return;
1312
1313         MapVote_Start();
1314 }
1315
1316 /*
1317 ============
1318 FindIntermission
1319
1320 Returns the entity to view from
1321 ============
1322 */
1323 /*
1324 entity FindIntermission()
1325 {
1326         local   entity spot;
1327         local   float cyc;
1328
1329 // look for info_intermission first
1330         spot = find (world, classname, "info_intermission");
1331         if (spot)
1332         {       // pick a random one
1333                 cyc = random() * 4;
1334                 while (cyc > 1)
1335                 {
1336                         spot = find (spot, classname, "info_intermission");
1337                         if (!spot)
1338                                 spot = find (spot, classname, "info_intermission");
1339                         cyc = cyc - 1;
1340                 }
1341                 return spot;
1342         }
1343
1344 // then look for the start position
1345         spot = find (world, classname, "info_player_start");
1346         if (spot)
1347                 return spot;
1348
1349 // testinfo_player_start is only found in regioned levels
1350         spot = find (world, classname, "testplayerstart");
1351         if (spot)
1352                 return spot;
1353
1354 // then look for the start position
1355         spot = find (world, classname, "info_player_deathmatch");
1356         if (spot)
1357                 return spot;
1358
1359         //objerror ("FindIntermission: no spot");
1360         return world;
1361 }
1362 */
1363
1364 /*
1365 ===============================================================================
1366
1367 RULES
1368
1369 ===============================================================================
1370 */
1371
1372 void DumpStats(float final)
1373 {
1374         float file;
1375         string s;
1376         float to_console;
1377         float to_eventlog;
1378         float to_file;
1379         float i;
1380
1381         to_console = autocvar_sv_logscores_console;
1382         to_eventlog = autocvar_sv_eventlog;
1383         to_file = autocvar_sv_logscores_file;
1384
1385         if(!final)
1386         {
1387                 to_console = true; // always print printstats replies
1388                 to_eventlog = false; // but never print them to the event log
1389         }
1390
1391         if(to_eventlog)
1392                 if(autocvar_sv_eventlog_console)
1393                         to_console = false; // otherwise we get the output twice
1394
1395         if(final)
1396                 s = ":scores:";
1397         else
1398                 s = ":status:";
1399         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1400
1401         if(to_console)
1402                 print(s, "\n");
1403         if(to_eventlog)
1404                 GameLogEcho(s);
1405
1406         file = -1;
1407         if(to_file)
1408         {
1409                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1410                 if(file == -1)
1411                         to_file = false;
1412                 else
1413                         fputs(file, strcat(s, "\n"));
1414         }
1415
1416         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1417         if(to_console)
1418                 print(s, "\n");
1419         if(to_eventlog)
1420                 GameLogEcho(s);
1421         if(to_file)
1422                 fputs(file, strcat(s, "\n"));
1423
1424         FOR_EACH_CLIENT(other)
1425         {
1426                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1427                 {
1428                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1429                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1430                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1431                                 s = strcat(s, ftos(other.team), ":");
1432                         else
1433                                 s = strcat(s, "spectator:");
1434
1435                         if(to_console)
1436                                 print(s, other.netname, "\n");
1437                         if(to_eventlog)
1438                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1439                         if(to_file)
1440                                 fputs(file, strcat(s, other.netname, "\n"));
1441                 }
1442         }
1443
1444         if(teamplay)
1445         {
1446                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1447                 if(to_console)
1448                         print(s, "\n");
1449                 if(to_eventlog)
1450                         GameLogEcho(s);
1451                 if(to_file)
1452                         fputs(file, strcat(s, "\n"));
1453
1454                 for(i = 1; i < 16; ++i)
1455                 {
1456                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1457                         s = strcat(s, ":", ftos(i));
1458                         if(to_console)
1459                                 print(s, "\n");
1460                         if(to_eventlog)
1461                                 GameLogEcho(s);
1462                         if(to_file)
1463                                 fputs(file, strcat(s, "\n"));
1464                 }
1465         }
1466
1467         if(to_console)
1468                 print(":end\n");
1469         if(to_eventlog)
1470                 GameLogEcho(":end");
1471         if(to_file)
1472         {
1473                 fputs(file, ":end\n");
1474                 fclose(file);
1475         }
1476 }
1477
1478 void FixIntermissionClient(entity e)
1479 {
1480         string s;
1481         if(!e.autoscreenshot) // initial call
1482         {
1483                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1484                 e.health = -2342;
1485                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1486                 e.solid = SOLID_NOT;
1487                 e.movetype = MOVETYPE_NONE;
1488                 e.takedamage = DAMAGE_NO;
1489                 if(e.weaponentity)
1490                 {
1491                         e.weaponentity.effects = EF_NODRAW;
1492                         if (e.weaponentity.weaponentity)
1493                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1494                 }
1495                 if(IS_REAL_CLIENT(e))
1496                 {
1497                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1498                         s = autocvar_sv_intermission_cdtrack;
1499                         if(s != "")
1500                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1501                         msg_entity = e;
1502                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1503                 }
1504         }
1505 }
1506
1507 /*
1508 go to the next level for deathmatch
1509 only called if a time or frag limit has expired
1510 */
1511 void NextLevel()
1512 {
1513         gameover = true;
1514
1515         intermission_running = 1;
1516
1517 // enforce a wait time before allowing changelevel
1518         if(player_count > 0)
1519                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1520         else
1521                 intermission_exittime = -1;
1522
1523         /*
1524         WriteByte (MSG_ALL, SVC_CDTRACK);
1525         WriteByte (MSG_ALL, 3);
1526         WriteByte (MSG_ALL, 3);
1527         // done in FixIntermission
1528         */
1529
1530         //pos = FindIntermission ();
1531
1532         VoteReset();
1533
1534         DumpStats(true);
1535
1536         // send statistics
1537         PlayerStats_GameReport(true);
1538         WeaponStats_Shutdown();
1539
1540         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1541
1542         if(autocvar_sv_eventlog)
1543                 GameLogEcho(":gameover");
1544
1545         GameLogClose();
1546
1547         FOR_EACH_PLAYER(other) {
1548                 FixIntermissionClient(other);
1549                 if(other.winning)
1550                         bprint(other.netname, " ^7wins.\n");
1551         }
1552
1553         if(autocvar_g_campaign)
1554                 CampaignPreIntermission();
1555
1556         MUTATOR_CALLHOOK(MatchEnd);
1557
1558         localcmd("\nsv_hook_gameend\n");
1559 }
1560
1561 /*
1562 ============
1563 CheckRules_Player
1564
1565 Exit deathmatch games upon conditions
1566 ============
1567 */
1568 void CheckRules_Player()
1569 {
1570         if (gameover)   // someone else quit the game already
1571                 return;
1572
1573         if(self.deadflag == DEAD_NO)
1574                 self.play_time += frametime;
1575
1576         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1577         //   (div0: and that in CheckRules_World please)
1578 }
1579
1580
1581 float InitiateSuddenDeath()
1582 {
1583         // Check first whether normal overtimes could be added before initiating suddendeath mode
1584         // - for this timelimit_overtime needs to be >0 of course
1585         // - also check the winning condition calculated in the previous frame and only add normal overtime
1586         //   again, if at the point at which timelimit would be extended again, still no winner was found
1587         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1588         {
1589                 return 1; // need to call InitiateOvertime later
1590         }
1591         else
1592         {
1593                 if(!checkrules_suddendeathend)
1594                 {
1595                         if(autocvar_g_campaign)
1596                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1597                         else
1598                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1599                         if(g_race && !g_race_qualifying)
1600                                 race_StartCompleting();
1601                 }
1602                 return 0;
1603         }
1604 }
1605
1606 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1607 {
1608         ++checkrules_overtimesadded;
1609         //add one more overtime by simply extending the timelimit
1610         float tl;
1611         tl = autocvar_timelimit;
1612         tl += autocvar_timelimit_overtime;
1613         cvar_set("timelimit", ftos(tl));
1614
1615         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1616 }
1617
1618 float GetWinningCode(float fraglimitreached, float equality)
1619 {
1620         if(autocvar_g_campaign == 1)
1621                 if(fraglimitreached)
1622                         return WINNING_YES;
1623                 else
1624                         return WINNING_NO;
1625
1626         else
1627                 if(equality)
1628                         if(fraglimitreached)
1629                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1630                         else
1631                                 return WINNING_NEVER;
1632                 else
1633                         if(fraglimitreached)
1634                                 return WINNING_YES;
1635                         else
1636                                 return WINNING_NO;
1637 }
1638
1639 // set the .winning flag for exactly those players with a given field value
1640 void SetWinners(.float field, float value)
1641 {
1642         entity head;
1643         FOR_EACH_PLAYER(head)
1644                 head.winning = (head.field == value);
1645 }
1646
1647 // set the .winning flag for those players with a given field value
1648 void AddWinners(.float field, float value)
1649 {
1650         entity head;
1651         FOR_EACH_PLAYER(head)
1652                 if(head.field == value)
1653                         head.winning = 1;
1654 }
1655
1656 // clear the .winning flags
1657 void ClearWinners(void)
1658 {
1659         entity head;
1660         FOR_EACH_PLAYER(head)
1661                 head.winning = 0;
1662 }
1663
1664 // Onslaught winning condition:
1665 // game terminates if only one team has a working generator (or none)
1666 float WinningCondition_Onslaught()
1667 {
1668         entity head;
1669         float t1, t2, t3, t4;
1670
1671         WinningConditionHelper(); // set worldstatus
1672
1673         if(warmup_stage)
1674                 return WINNING_NO;
1675
1676         // first check if the game has ended
1677         t1 = t2 = t3 = t4 = 0;
1678         head = find(world, classname, "onslaught_generator");
1679         while (head)
1680         {
1681                 if (head.health > 0)
1682                 {
1683                         if (head.team == NUM_TEAM_1) t1 = 1;
1684                         if (head.team == NUM_TEAM_2) t2 = 1;
1685                         if (head.team == NUM_TEAM_3) t3 = 1;
1686                         if (head.team == NUM_TEAM_4) t4 = 1;
1687                 }
1688                 head = find(head, classname, "onslaught_generator");
1689         }
1690         if (t1 + t2 + t3 + t4 < 2)
1691         {
1692                 // game over, only one team remains (or none)
1693                 ClearWinners();
1694                 if (t1) SetWinners(team, NUM_TEAM_1);
1695                 if (t2) SetWinners(team, NUM_TEAM_2);
1696                 if (t3) SetWinners(team, NUM_TEAM_3);
1697                 if (t4) SetWinners(team, NUM_TEAM_4);
1698                 dprint("Have a winner, ending game.\n");
1699                 return WINNING_YES;
1700         }
1701
1702         // Two or more teams remain
1703         return WINNING_NO;
1704 }
1705
1706 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1707 // they win. Otherwise the defending team wins once the timelimit passes.
1708 void assault_new_round();
1709 float WinningCondition_Assault()
1710 {
1711         float status;
1712
1713         WinningConditionHelper(); // set worldstatus
1714
1715         status = WINNING_NO;
1716         // as the timelimit has not yet passed just assume the defending team will win
1717         if(assault_attacker_team == NUM_TEAM_1)
1718         {
1719                 SetWinners(team, NUM_TEAM_2);
1720         }
1721         else
1722         {
1723                 SetWinners(team, NUM_TEAM_1);
1724         }
1725
1726         entity ent;
1727         ent = find(world, classname, "target_assault_roundend");
1728         if(ent)
1729         {
1730                 if(ent.winning) // round end has been triggered by attacking team
1731                 {
1732                         bprint("ASSAULT: round completed...\n");
1733                         SetWinners(team, assault_attacker_team);
1734
1735                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1736
1737                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1738                         {
1739                                 status = WINNING_YES;
1740                         }
1741                         else
1742                         {
1743                                 entity oldself;
1744                                 oldself = self;
1745                                 self = ent;
1746                                 assault_new_round();
1747                                 self = oldself;
1748                         }
1749                 }
1750         }
1751
1752         return status;
1753 }
1754
1755 // LMS winning condition: game terminates if and only if there's at most one
1756 // one player who's living lives. Top two scores being equal cancels the time
1757 // limit.
1758 float WinningCondition_LMS()
1759 {
1760         entity head, head2;
1761         float have_player;
1762         float have_players;
1763         float l;
1764
1765         have_player = false;
1766         have_players = false;
1767         l = LMS_NewPlayerLives();
1768
1769         head = find(world, classname, "player");
1770         if(head)
1771                 have_player = true;
1772         head2 = find(head, classname, "player");
1773         if(head2)
1774                 have_players = true;
1775
1776         if(have_player)
1777         {
1778                 // we have at least one player
1779                 if(have_players)
1780                 {
1781                         // two or more active players - continue with the game
1782                 }
1783                 else
1784                 {
1785                         // exactly one player?
1786
1787                         ClearWinners();
1788                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1789
1790                         if(l)
1791                         {
1792                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1793                                 return WINNING_NO;
1794                         }
1795                         else
1796                         {
1797                                 // a winner!
1798                                 // and assign him his first place
1799                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1800                                 return WINNING_YES;
1801                         }
1802                 }
1803         }
1804         else
1805         {
1806                 // nobody is playing at all...
1807                 if(l)
1808                 {
1809                         // wait for players...
1810                 }
1811                 else
1812                 {
1813                         // SNAFU (maybe a draw game?)
1814                         ClearWinners();
1815                         dprint("No players, ending game.\n");
1816                         return WINNING_YES;
1817                 }
1818         }
1819
1820         // When we get here, we have at least two players who are actually LIVING,
1821         // now check if the top two players have equal score.
1822         WinningConditionHelper();
1823
1824         ClearWinners();
1825         if(WinningConditionHelper_winner)
1826                 WinningConditionHelper_winner.winning = true;
1827         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1828                 return WINNING_NEVER;
1829
1830         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1831         return WINNING_NO;
1832 }
1833
1834 void ShuffleMaplist()
1835 {
1836         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1837 }
1838
1839 float leaderfrags;
1840 float WinningCondition_Scores(float limit, float leadlimit)
1841 {
1842         float limitreached;
1843
1844         // TODO make everything use THIS winning condition (except LMS)
1845         WinningConditionHelper();
1846
1847         if(teamplay)
1848         {
1849                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1850                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1851                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1852                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1853         }
1854
1855         ClearWinners();
1856         if(WinningConditionHelper_winner)
1857                 WinningConditionHelper_winner.winning = 1;
1858         if(WinningConditionHelper_winnerteam >= 0)
1859                 SetWinners(team, WinningConditionHelper_winnerteam);
1860
1861         if(WinningConditionHelper_lowerisbetter)
1862         {
1863                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1864                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1865                 limit = -limit;
1866         }
1867
1868         if(WinningConditionHelper_zeroisworst)
1869                 leadlimit = 0; // not supported in this mode
1870
1871         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1872         // these modes always score in increments of 1, thus this makes sense
1873         {
1874                 if(leaderfrags != WinningConditionHelper_topscore)
1875                 {
1876                         leaderfrags = WinningConditionHelper_topscore;
1877
1878                         if (limit)
1879                         if (leaderfrags == limit - 1)
1880                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1881                         else if (leaderfrags == limit - 2)
1882                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1883                         else if (leaderfrags == limit - 3)
1884                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1885                 }
1886         }
1887
1888         limitreached = false;
1889         if(limit)
1890                 if(WinningConditionHelper_topscore >= limit)
1891                         limitreached = true;
1892         if(leadlimit)
1893         {
1894                 float leadlimitreached;
1895                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1896                 if(autocvar_leadlimit_and_fraglimit)
1897                         limitreached = (limitreached && leadlimitreached);
1898                 else
1899                         limitreached = (limitreached || leadlimitreached);
1900         }
1901
1902         if(limit)
1903                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1904
1905         return GetWinningCode(
1906                 WinningConditionHelper_topscore && limitreached,
1907                 WinningConditionHelper_equality
1908         );
1909 }
1910
1911 float WinningCondition_Race(float fraglimit)
1912 {
1913         float wc;
1914         entity p;
1915         float n, c;
1916
1917         n = 0;
1918         c = 0;
1919         FOR_EACH_PLAYER(p)
1920         {
1921                 ++n;
1922                 if(p.race_completed)
1923                         ++c;
1924         }
1925         if(n && (n == c))
1926                 return WINNING_YES;
1927         wc = WinningCondition_Scores(fraglimit, 0);
1928
1929         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1930         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1931         // do NOT support equality when the laps are all raced!
1932                 return WINNING_STARTSUDDENDEATHOVERTIME;
1933         else
1934                 return WINNING_NEVER;
1935 }
1936
1937 float WinningCondition_QualifyingThenRace(float limit)
1938 {
1939         float wc;
1940         wc = WinningCondition_Scores(limit, 0);
1941
1942         // NEVER initiate overtime
1943         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1944         {
1945                 return WINNING_YES;
1946         }
1947
1948         return wc;
1949 }
1950
1951 float WinningCondition_RanOutOfSpawns()
1952 {
1953         entity head;
1954
1955         if(have_team_spawns <= 0)
1956                 return WINNING_NO;
1957
1958         if(autocvar_g_spawn_useallspawns <= 0)
1959                 return WINNING_NO;
1960
1961         if(!some_spawn_has_been_used)
1962                 return WINNING_NO;
1963
1964         team1_score = team2_score = team3_score = team4_score = 0;
1965
1966         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1967         {
1968                 if(head.team == NUM_TEAM_1)
1969                         team1_score = 1;
1970                 else if(head.team == NUM_TEAM_2)
1971                         team2_score = 1;
1972                 else if(head.team == NUM_TEAM_3)
1973                         team3_score = 1;
1974                 else if(head.team == NUM_TEAM_4)
1975                         team4_score = 1;
1976         }
1977
1978         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1979         {
1980                 if(head.team == NUM_TEAM_1)
1981                         team1_score = 1;
1982                 else if(head.team == NUM_TEAM_2)
1983                         team2_score = 1;
1984                 else if(head.team == NUM_TEAM_3)
1985                         team3_score = 1;
1986                 else if(head.team == NUM_TEAM_4)
1987                         team4_score = 1;
1988         }
1989
1990         ClearWinners();
1991         if(team1_score + team2_score + team3_score + team4_score == 0)
1992         {
1993                 checkrules_equality = true;
1994                 return WINNING_YES;
1995         }
1996         else if(team1_score + team2_score + team3_score + team4_score == 1)
1997         {
1998                 float t, i;
1999                 if(team1_score)
2000                         t = NUM_TEAM_1;
2001                 else if(team2_score)
2002                         t = NUM_TEAM_2;
2003                 else if(team3_score)
2004                         t = NUM_TEAM_3;
2005                 else // if(team4_score)
2006                         t = NUM_TEAM_4;
2007                 CheckAllowedTeams(world);
2008                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2009                 {
2010                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2011                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2012                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2013                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2014                 }
2015
2016                 AddWinners(team, t);
2017                 return WINNING_YES;
2018         }
2019         else
2020                 return WINNING_NO;
2021 }
2022
2023 /*
2024 ============
2025 CheckRules_World
2026
2027 Exit deathmatch games upon conditions
2028 ============
2029 */
2030 void ReadyRestart();
2031 void CheckRules_World()
2032 {
2033         float timelimit;
2034         float fraglimit;
2035         float leadlimit;
2036
2037         VoteThink();
2038         MapVote_Think();
2039
2040         SetDefaultAlpha();
2041
2042         if (gameover)   // someone else quit the game already
2043         {
2044                 if(player_count == 0) // Nobody there? Then let's go to the next map
2045                         MapVote_Start();
2046                         // this will actually check the player count in the next frame
2047                         // again, but this shouldn't hurt
2048                 return;
2049         }
2050
2051         timelimit = autocvar_timelimit * 60;
2052         fraglimit = autocvar_fraglimit;
2053         leadlimit = autocvar_leadlimit;
2054
2055         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2056         {
2057                 if(timelimit > 0)
2058                         timelimit = 0; // timelimit is not made for warmup
2059                 if(fraglimit > 0)
2060                         fraglimit = 0; // no fraglimit for now
2061                 leadlimit = 0; // no leadlimit for now
2062         }
2063
2064         if(timelimit > 0)
2065         {
2066                 timelimit += game_starttime;
2067         }
2068         else if (timelimit < 0)
2069         {
2070                 // endmatch
2071                 NextLevel();
2072                 return;
2073         }
2074
2075         if(g_onslaught)
2076                 timelimit = 0; // ONS has its own overtime rule
2077
2078         float wantovertime;
2079         wantovertime = 0;
2080
2081         if(timelimit > game_starttime)
2082                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2083         else
2084                 game_completion_ratio = 0;
2085
2086         if(checkrules_suddendeathend)
2087         {
2088                 if(!checkrules_suddendeathwarning)
2089                 {
2090                         checkrules_suddendeathwarning = true;
2091                         if(g_race && !g_race_qualifying)
2092                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2093                         else
2094                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2095                 }
2096         }
2097         else
2098         {
2099                 if (timelimit && time >= timelimit)
2100                 {
2101                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2102                         {
2103                                 float totalplayers;
2104                                 float playerswithlaps;
2105                                 float readyplayers;
2106                                 entity head;
2107                                 totalplayers = playerswithlaps = readyplayers = 0;
2108                                 FOR_EACH_PLAYER(head)
2109                                 {
2110                                         ++totalplayers;
2111                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2112                                                 ++playerswithlaps;
2113                                         if(head.ready)
2114                                                 ++readyplayers;
2115                                 }
2116
2117                                 // at least 2 of the players have completed a lap: start the RACE
2118                                 // otherwise, the players should end the qualifying on their own
2119                                 if(readyplayers || playerswithlaps >= 2)
2120                                 {
2121                                         checkrules_suddendeathend = 0;
2122                                         ReadyRestart(); // go to race
2123                                         return;
2124                                 }
2125                                 else
2126                                         wantovertime |= InitiateSuddenDeath();
2127                         }
2128                         else
2129                                 wantovertime |= InitiateSuddenDeath();
2130                 }
2131         }
2132
2133         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2134         {
2135                 NextLevel();
2136                 return;
2137         }
2138
2139         float checkrules_status;
2140         checkrules_status = WinningCondition_RanOutOfSpawns();
2141         if(checkrules_status == WINNING_YES)
2142         {
2143                 bprint("Hey! Someone ran out of spawns!\n");
2144         }
2145         else if(g_race && !g_race_qualifying && timelimit >= 0)
2146         {
2147                 checkrules_status = WinningCondition_Race(fraglimit);
2148                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2149         }
2150         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2151         {
2152                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2153                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2154         }
2155         else if(g_assault)
2156         {
2157                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2158         }
2159         else if(g_lms)
2160         {
2161                 checkrules_status = WinningCondition_LMS();
2162         }
2163         else if (g_onslaught)
2164         {
2165                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2166         }
2167         else
2168         {
2169                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2170                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2171         }
2172
2173         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2174         {
2175                 checkrules_status = WINNING_NEVER;
2176                 checkrules_overtimesadded = -1;
2177                 wantovertime |= InitiateSuddenDeath();
2178         }
2179
2180         if(checkrules_status == WINNING_NEVER)
2181                 // equality cases! Nobody wins if the overtime ends in a draw.
2182                 ClearWinners();
2183
2184         if(wantovertime)
2185         {
2186                 if(checkrules_status == WINNING_NEVER)
2187                         InitiateOvertime();
2188                 else
2189                         checkrules_status = WINNING_YES;
2190         }
2191
2192         if(checkrules_suddendeathend)
2193                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2194                         checkrules_status = WINNING_YES;
2195
2196         if(checkrules_status == WINNING_YES)
2197         {
2198                 //print("WINNING\n");
2199                 NextLevel();
2200         }
2201 }
2202
2203 string GotoMap(string m)
2204 {
2205         m = GameTypeVote_MapInfo_FixName(m);
2206         if (!m)
2207                 return "The map you suggested is not available on this server.";
2208         if (!autocvar_sv_vote_gametype)
2209         if(!MapInfo_CheckMap(m))
2210                 return "The map you suggested does not support the current game mode.";
2211         cvar_set("nextmap", m);
2212         cvar_set("timelimit", "-1");
2213         if(mapvote_initialized || alreadychangedlevel)
2214         {
2215                 if(DoNextMapOverride(0))
2216                         return "Map switch initiated.";
2217                 else
2218                         return "Hm... no. For some reason I like THIS map more.";
2219         }
2220         else
2221                 return "Map switch will happen after scoreboard.";
2222 }
2223
2224
2225 void EndFrame()
2226 {
2227         anticheat_endframe();
2228
2229         float altime;
2230         FOR_EACH_REALCLIENT(self)
2231         {
2232                 entity e = IS_SPEC(self) ? self.enemy : self;
2233                 if(e.typehitsound)
2234                         self.typehit_time = time;
2235                 else if(e.damage_dealt)
2236                 {
2237                         self.hit_time = time;
2238                         self.damage_dealt_total += ceil(e.damage_dealt);
2239                 }
2240         }
2241         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2242         // add 1 frametime because after this, engine SV_Physics
2243         // increases time by a frametime and then networks the frame
2244         // add another frametime because client shows everything with
2245         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2246         // needed!
2247         FOR_EACH_CLIENT(self)
2248         {
2249                 self.typehitsound = false;
2250                 self.damage_dealt = 0;
2251                 antilag_record(self, altime);
2252         }
2253         FOR_EACH_MONSTER(self)
2254                 antilag_record(self, altime);
2255 }
2256
2257
2258 /*
2259  * RedirectionThink:
2260  * returns true if redirecting
2261  */
2262 float redirection_timeout;
2263 float redirection_nextthink;
2264 float RedirectionThink()
2265 {
2266         float clients_found;
2267
2268         if(redirection_target == "")
2269                 return false;
2270
2271         if(!redirection_timeout)
2272         {
2273                 cvar_set("sv_public", "-2");
2274                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2275                 if(redirection_target == "self")
2276                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2277                 else
2278                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2279         }
2280
2281         if(time < redirection_nextthink)
2282                 return true;
2283
2284         redirection_nextthink = time + 1;
2285
2286         clients_found = 0;
2287         FOR_EACH_REALCLIENT(self)
2288         {
2289                 // TODO add timer
2290                 print("Redirecting: sending connect command to ", self.netname, "\n");
2291                 if(redirection_target == "self")
2292                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2293                 else
2294                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2295                 ++clients_found;
2296         }
2297
2298         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2299
2300         if(time > redirection_timeout || clients_found == 0)
2301                 localcmd("\nwait; wait; wait; quit\n");
2302
2303         return true;
2304 }
2305
2306 void TargetMusic_RestoreGame();
2307 void RestoreGame()
2308 {
2309         // Loaded from a save game
2310         // some things then break, so let's work around them...
2311
2312         // Progs DB (capture records)
2313         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2314
2315         // Mapinfo
2316         MapInfo_Shutdown();
2317         MapInfo_Enumerate();
2318         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2319         WeaponStats_Init();
2320
2321         TargetMusic_RestoreGame();
2322 }
2323
2324 void Shutdown()
2325 {
2326         gameover = 2;
2327
2328         if(world_initialized > 0)
2329         {
2330                 world_initialized = 0;
2331                 print("Saving persistent data...\n");
2332                 Ban_SaveBans();
2333
2334                 // playerstats with unfinished match
2335                 PlayerStats_GameReport(false);
2336
2337                 if(!cheatcount_total)
2338                 {
2339                         if(autocvar_sv_db_saveasdump)
2340                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2341                         else
2342                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2343                 }
2344                 if(autocvar_developer)
2345                 {
2346                         if(autocvar_sv_db_saveasdump)
2347                                 db_dump(TemporaryDB, "server-temp.db");
2348                         else
2349                                 db_save(TemporaryDB, "server-temp.db");
2350                 }
2351                 CheatShutdown(); // must be after cheatcount check
2352                 db_close(ServerProgsDB);
2353                 db_close(TemporaryDB);
2354                 print("done!\n");
2355                 // tell the bot system the game is ending now
2356                 bot_endgame();
2357
2358                 WeaponStats_Shutdown();
2359                 MapInfo_Shutdown();
2360         }
2361         else if(world_initialized == 0)
2362         {
2363                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2364         }
2365 }