qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_runematch");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("g_runematch_point_leadlimit");
 319                 BADCVAR("leadlimit_and_fraglimit");
 320                 BADCVAR("leadlimit_override");
 321                 BADCVAR("pausable");
 322                 BADCVAR("sv_allow_fullbright");
 323                 BADCVAR("sv_checkforpacketsduringsleep");
 324                 BADCVAR("sv_fraginfo");
 325                 BADCVAR("sv_timeout");
 326                 BADPREFIX("sv_timeout_");
 327                 BADCVAR("welcome_message_time");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_fraginfo_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_namechangetimer");
 343 #ifndef NO_LEGACY_NETWORKING
 344                 BADCVAR("sv_use_csqc_players"); // transition
 345 #endif
 346
 347                 // allowed changes to server admins (please sync this to server.cfg)
 348                 // vi commands:
 349                 //   :/"impure"/,$d
 350                 //   :g!,^\/\/[^ /],d
 351                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 352                 //   :%!sort
 353                 // yes, this does contain some redundant stuff, don't really care
 354                 BADCVAR("bot_config_file");
 355                 BADCVAR("bot_number");
 356                 BADCVAR("bot_prefix");
 357                 BADCVAR("bot_suffix");
 358                 BADCVAR("capturelimit_override");
 359                 BADCVAR("fraglimit_override");
 360                 BADCVAR("gametype");
 361                 BADCVAR("g_antilag");
 362                 BADCVAR("g_balance_teams");
 363                 BADCVAR("g_balance_teams_prevent_imbalance");
 364                 BADCVAR("g_balance_teams_scorefactor");
 365                 BADCVAR("g_ban_sync_trusted_servers");
 366                 BADCVAR("g_ban_sync_uri");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_friendlyfire");
 370                 BADCVAR("g_fullbrightitems");
 371                 BADCVAR("g_fullbrightplayers");
 372                 BADCVAR("g_keyhunt_point_limit");
 373                 BADCVAR("g_keyhunt_teams_override");
 374                 BADCVAR("g_lms_lives_override");
 375                 BADCVAR("g_maplist");
 376                 BADCVAR("g_maplist_check_waypoints");
 377                 BADCVAR("g_maplist_mostrecent_count");
 378                 BADCVAR("g_maplist_shuffle");
 379                 BADCVAR("g_maplist_votable");
 380                 BADCVAR("g_maplist_votable_abstain");
 381                 BADCVAR("g_maplist_votable_nodetail");
 382                 BADCVAR("g_maplist_votable_suggestions");
 383                 BADCVAR("g_maxplayers");
 384                 BADCVAR("g_mirrordamage");
 385                 BADCVAR("g_nexball_goallimit");
 386                 BADCVAR("g_powerups");
 387                 BADCVAR("g_runematch_point_limit");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_warmup");
 390                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 391                 BADCVAR("hostname");
 392                 BADCVAR("log_file");
 393                 BADCVAR("maxplayers");
 394                 BADCVAR("minplayers");
 395                 BADCVAR("net_address");
 396                 BADCVAR("port");
 397                 BADCVAR("rcon_password");
 398                 BADCVAR("rcon_restricted_commands");
 399                 BADCVAR("rcon_restricted_password");
 400                 BADCVAR("skill");
 401                 BADCVAR("sv_adminnick");
 402                 BADCVAR("sv_autoscreenshot");
 403                 BADCVAR("sv_autotaunt");
 404                 BADCVAR("sv_curl_defaulturl");
 405                 BADCVAR("sv_defaultcharacter");
 406                 BADCVAR("sv_defaultplayercolors");
 407                 BADCVAR("sv_defaultplayermodel");
 408                 BADCVAR("sv_defaultplayerskin");
 409                 BADCVAR("sv_maxidle");
 410                 BADCVAR("sv_maxrate");
 411                 BADCVAR("sv_motd");
 412                 BADCVAR("sv_public");
 413                 BADCVAR("sv_ready_restart");
 414                 BADCVAR("sv_status_privacy");
 415                 BADCVAR("sv_taunt");
 416                 BADCVAR("sv_vote_call");
 417                 BADCVAR("sv_vote_commands");
 418                 BADCVAR("sv_vote_majority_factor");
 419                 BADCVAR("sv_vote_master");
 420                 BADCVAR("sv_vote_master_commands");
 421                 BADCVAR("sv_vote_master_password");
 422                 BADCVAR("sv_vote_simple_majority_factor");
 423                 BADCVAR("sys_ticrate");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_minstagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434
 435                 if(autocvar_g_minstagib)
 436                 {
 437                         BADCVAR("g_grappling_hook");
 438                         BADCVAR("g_jetpack");
 439                 }
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for(;;)
 480         {
 481                 o = world.mins;
 482                 o_x += random() * (world.maxs_x - world.mins_x);
 483                 o_y += random() * (world.maxs_y - world.mins_y);
 484                 o_z += random() * (world.maxs_z - world.mins_z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return TRUE;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         // needs to be done so early because of the constants they create
 554         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 555         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 556
 557         MapInfo_Enumerate();
 558         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 559 }
 560
 561 void Map_MarkAsRecent(string m);
 562 float world_already_spawned;
 563 void Nagger_Init();
 564 void ClientInit_Spawn();
 565 void WeaponStats_Init();
 566 void WeaponStats_Shutdown();
 567 void spawnfunc_worldspawn (void)
 568 {
 569         float fd, l, i, j, n;
 570         string s, col;
 571
 572         cvar = cvar_normal;
 573         cvar_string = cvar_string_normal;
 574         cvar_set = cvar_set_normal;
 575
 576         if(world_already_spawned)
 577                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 578         world_already_spawned = TRUE;
 579
 580         remove = remove_safely; // during spawning, watch what you remove!
 581
 582         check_unacceptable_compiler_bugs();
 583
 584         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 585
 586         compressShortVector_init();
 587
 588         allowed_to_spawn = TRUE;
 589
 590         entity head;
 591         head = nextent(world);
 592         maxclients = 0;
 593         while(head)
 594         {
 595                 ++maxclients;
 596                 head = nextent(head);
 597         }
 598
 599         // needs to be done so early because of the constants they create
 600         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 601         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 602
 603         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 604
 605         TemporaryDB = db_create();
 606
 607         // 0 normal
 608         lightstyle(0, "m");
 609
 610         // 1 FLICKER (first variety)
 611         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 612
 613         // 2 SLOW STRONG PULSE
 614         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 615
 616         // 3 CANDLE (first variety)
 617         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 618
 619         // 4 FAST STROBE
 620         lightstyle(4, "mamamamamama");
 621
 622         // 5 GENTLE PULSE 1
 623         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 624
 625         // 6 FLICKER (second variety)
 626         lightstyle(6, "nmonqnmomnmomomno");
 627
 628         // 7 CANDLE (second variety)
 629         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 630
 631         // 8 CANDLE (third variety)
 632         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 633
 634         // 9 SLOW STROBE (fourth variety)
 635         lightstyle(9, "aaaaaaaazzzzzzzz");
 636
 637         // 10 FLUORESCENT FLICKER
 638         lightstyle(10, "mmamammmmammamamaaamammma");
 639
 640         // 11 SLOW PULSE NOT FADE TO BLACK
 641         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 642
 643         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 644
 645         // 63 testing
 646         lightstyle(63, "a");
 647
 648         if(autocvar_g_campaign)
 649                 CampaignPreInit();
 650
 651         Map_MarkAsRecent(mapname);
 652
 653         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 654
 655         precache_model ("null"); // we need this one before InitGameplayMode
 656         InitGameplayMode();
 657         readlevelcvars();
 658         GrappleHookInit();
 659         ElectroInit();
 660         LaserInit();
 661
 662         player_count = 0;
 663         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 664         if(bot_waypoints_for_items == 1)
 665                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 666                         bot_waypoints_for_items = 0;
 667
 668         precache();
 669
 670         WaypointSprite_Init();
 671
 672         GameLogInit(); // prepare everything
 673         // NOTE for matchid:
 674         // changing the logic generating it is okay. But:
 675         // it HAS to stay <= 64 chars
 676         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 677         if(autocvar_sv_eventlog)
 678         {
 679                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 680                 matchid = strzone(s);
 681
 682                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 683                 s = ":gameinfo:mutators:LIST";
 684
 685                 ret_string = s;
 686                 MUTATOR_CALLHOOK(BuildMutatorsString);
 687                 s = ret_string;
 688
 689                 // simple, probably not good in the mutator system
 690                 if(autocvar_g_grappling_hook)
 691                         s = strcat(s, ":grappling_hook");
 692
 693                 // initialiation stuff, not good in the mutator system
 694                 if(!autocvar_g_use_ammunition)
 695                         s = strcat(s, ":no_use_ammunition");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(autocvar_g_pickup_items == 0)
 699                         s = strcat(s, ":no_pickup_items");
 700                 if(autocvar_g_pickup_items > 0)
 701                         s = strcat(s, ":pickup_items");
 702
 703                 // initialiation stuff, not good in the mutator system
 704                 if(autocvar_g_weaponarena != "0")
 705                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 706
 707                 // TODO to mutator system
 708                 if(autocvar_g_norecoil)
 709                         s = strcat(s, ":norecoil");
 710
 711                 // TODO to mutator system
 712                 if(autocvar_g_midair)
 713                         s = strcat(s, ":midair");
 714
 715                 // TODO to mutator system
 716                 if(autocvar_g_minstagib)
 717                         s = strcat(s, ":minstagib");
 718
 719                 // TODO to mutator system
 720                 if(autocvar_g_powerups == 0)
 721                         s = strcat(s, ":no_powerups");
 722                 if(autocvar_g_powerups > 0)
 723                         s = strcat(s, ":powerups");
 724
 725                 GameLogEcho(s);
 726                 GameLogEcho(":gameinfo:end");
 727         }
 728         else
 729                 matchid = strzone(ftos(random()));
 730
 731         cvar_set("nextmap", "");
 732
 733         SetDefaultAlpha();
 734
 735         if(autocvar_g_campaign)
 736                 CampaignPostInit();
 737
 738         fteqcc_testbugs();
 739
 740         Ban_LoadBans();
 741
 742         MapInfo_Enumerate();
 743         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 744
 745         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 746         {
 747                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 748                 if(fd != -1)
 749                 {
 750                         while((s = fgets(fd)))
 751                         {
 752                                 l = tokenize_console(s);
 753                                 if(l < 2)
 754                                         continue;
 755                                 if(argv(0) == "cd")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  cdtrack ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) == "fog")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 763                                         print("  \"fog\" \"", s, "\"\n");
 764                                 }
 765                                 else if(argv(0) == "set")
 766                                 {
 767                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 768                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 769                                 }
 770                                 else if(argv(0) != "//")
 771                                 {
 772                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 773                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 774                                 }
 775                         }
 776                         fclose(fd);
 777                 }
 778         }
 779
 780         WeaponStats_Init();
 781
 782         WEPSET_ADDSTAT();
 783         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 784         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 785         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 786         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 787         Nagger_Init();
 788
 789         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 790         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 791         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 792         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 793         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 794         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 795         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 796         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 797         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 798         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 799         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 800         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 801         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 802
 803         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 804         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 805
 806         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 807
 808         if(g_ca || g_freezetag)
 809         {
 810                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 811                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 812                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 813                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 814         }
 815         if(g_freezetag)
 816         {
 817                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 818                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 819         }
 820
 821         // g_movementspeed hack
 822         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 823         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 824         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 825         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 826
 827         // secrets
 828         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 829         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 830
 831         // misc
 832         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 833
 834         next_pingtime = time + 5;
 835
 836         detect_maptype();
 837
 838         // set up information replies for clients and server to use
 839         lsmaps_reply = "^7Maps available: ";
 840         lsnewmaps_reply = "^7Maps without a record set: ";
 841         for(i = 0, j = 0; i < MapInfo_count; ++i)
 842         {
 843                 if(MapInfo_Get_ByID(i))
 844                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 845                         {
 846                                 if(mod(i, 2))
 847                                         col = "^2";
 848                                 else
 849                                         col = "^3";
 850
 851                                 ++j;
 852
 853                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 854
 855                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 856                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 857                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 858                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 859                         }
 860         }
 861
 862         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 863         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 864
 865         maplist_reply = "^7Maps in list: ";
 866         n = tokenize_console(autocvar_g_maplist);
 867         for(i = 0, j = 0; i < n; ++i)
 868         {
 869                 if(MapInfo_CheckMap(argv(i)))
 870                 {
 871                         if(mod(j, 2))
 872                                 col = "^2";
 873                         else
 874                                 col = "^3";
 875                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 876                         ++j;
 877                 }
 878         }
 879         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 880         MapInfo_ClearTemps();
 881
 882         for(i = 0; i < 10; ++i)
 883         {
 884                 s = getrecords(i);
 885                 if (s)
 886                         records_reply[i] = strzone(s);
 887         }
 888
 889         ladder_reply = strzone(getladder());
 890
 891         rankings_reply = strzone(getrankings());
 892
 893         // begin other init
 894         ClientInit_Spawn();
 895         RandomSeed_Spawn();
 896         PingPLReport_Spawn();
 897
 898         CheatInit();
 899
 900         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 901
 902         // fill sv_curl_serverpackages from .serverpackage files
 903         if(autocvar_sv_curl_serverpackages_auto)
 904         {
 905                 s = "";
 906                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 907                 for(i = 0; i < n; ++i)
 908                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 909                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 910                                 s = strcat(s, " ", argv(i));
 911                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 912                 if(fd >= 0)
 913                 {
 914                         j = search_getsize(fd);
 915                         for(i = 0; i < j; ++i)
 916                                 s = strcat(s, " ", search_getfilename(fd, i));
 917                         search_end(fd);
 918                 }
 919                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 920                 if(fd >= 0)
 921                 {
 922                         j = search_getsize(fd);
 923                         for(i = 0; i < j; ++i)
 924                                 s = strcat(s, " ", search_getfilename(fd, i));
 925                         search_end(fd);
 926                 }
 927                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 928         }
 929
 930         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 931         modname = "Xonotic";
 932         // physics/balance/config changes that count as mod
 933         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 934                 modname = cvar_string("g_mod_physics");
 935         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 936                 modname = cvar_string("g_mod_balance");
 937         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 938                 modname = cvar_string("g_mod_config");
 939         // weird mutators that deserve to count as mod
 940         if(autocvar_g_minstagib)
 941                 modname = "MinstaGib";
 942         // extra mutators that deserve to count as mod
 943         MUTATOR_CALLHOOK(SetModname);
 944
 945         // save it for later
 946         modname = strzone(modname);
 947
 948         WinningConditionHelper(); // set worldstatus
 949
 950         world_initialized = 1;
 951 }
 952
 953 void spawnfunc_light (void)
 954 {
 955         //makestatic (self); // Who the f___ did that?
 956         remove(self);
 957 }
 958
 959 string GetGametype()
 960 {
 961         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 962 }
 963
 964 string getmapname_stored;
 965 string GetMapname()
 966 {
 967         return mapname;
 968 }
 969
 970 float Map_Count, Map_Current;
 971 string Map_Current_Name;
 972
 973 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 974 float GetMaplistPosition()
 975 {
 976         float pos, idx;
 977         string map;
 978
 979         map = GetMapname();
 980         idx = autocvar_g_maplist_index;
 981
 982         if(idx >= 0)
 983                 if(idx < Map_Count)
 984                         if(map == argv(idx))
 985                                 return idx;
 986
 987         for(pos = 0; pos < Map_Count; ++pos)
 988                 if(map == argv(pos))
 989                         return pos;
 990
 991         // resume normal maplist rotation if current map is not in g_maplist
 992         return idx;
 993 }
 994
 995 float MapHasRightSize(string map)
 996 {
 997         float fh;
 998         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 999         if(autocvar_g_maplist_check_waypoints)
1000         {
1001                 dprint("checkwp "); dprint(map);
1002                 if(!fexists(strcat("maps/", map, ".waypoints")))
1003                 {
1004                         dprint(": no waypoints\n");
1005                         return FALSE;
1006                 }
1007                 dprint(": has waypoints\n");
1008         }
1009
1010         // open map size restriction file
1011         dprint("opensize "); dprint(map);
1012         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1013         if(fh >= 0)
1014         {
1015                 float mapmin, mapmax;
1016                 dprint(": ok, ");
1017                 mapmin = stof(fgets(fh));
1018                 mapmax = stof(fgets(fh));
1019                 fclose(fh);
1020                 if(player_count < mapmin)
1021                 {
1022                         dprint("not enough\n");
1023                         return FALSE;
1024                 }
1025                 if(player_count > mapmax)
1026                 {
1027                         dprint("too many\n");
1028                         return FALSE;
1029                 }
1030                 dprint("right size\n");
1031                 return TRUE;
1032         }
1033         dprint(": not found\n");
1034         return TRUE;
1035 }
1036
1037 string Map_Filename(float position)
1038 {
1039         return strcat("maps/", argv(position), ".bsp");
1040 }
1041
1042 string strwords(string s, float w)
1043 {
1044         float endpos;
1045         for(endpos = 0; w && endpos >= 0; --w)
1046                 endpos = strstrofs(s, " ", endpos + 1);
1047         if(endpos < 0)
1048                 return s;
1049         else
1050                 return substring(s, 0, endpos);
1051 }
1052
1053 float strhasword(string s, string w)
1054 {
1055         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1056 }
1057
1058 void Map_MarkAsRecent(string m)
1059 {
1060         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1061 }
1062
1063 float Map_IsRecent(string m)
1064 {
1065         return strhasword(autocvar_g_maplist_mostrecent, m);
1066 }
1067
1068 float Map_Check(float position, float pass)
1069 {
1070         string filename;
1071         string map_next;
1072         map_next = argv(position);
1073         if(pass <= 1)
1074         {
1075                 if(Map_IsRecent(map_next))
1076                         return 0;
1077         }
1078         filename = Map_Filename(position);
1079         if(MapInfo_CheckMap(map_next))
1080         {
1081                 if(pass == 2)
1082                         return 1;
1083                 if(MapHasRightSize(map_next))
1084                         return 1;
1085                 return 0;
1086         }
1087         else
1088                 dprint( "Couldn't select '", filename, "'..\n" );
1089
1090         return 0;
1091 }
1092
1093 void Map_Goto_SetStr(string nextmapname)
1094 {
1095         if(getmapname_stored != "")
1096                 strunzone(getmapname_stored);
1097         if(nextmapname == "")
1098                 getmapname_stored = "";
1099         else
1100                 getmapname_stored = strzone(nextmapname);
1101 }
1102
1103 void Map_Goto_SetFloat(float position)
1104 {
1105         cvar_set("g_maplist_index", ftos(position));
1106         Map_Goto_SetStr(argv(position));
1107 }
1108
1109 void Map_Goto(float reinit)
1110 {
1111         MapInfo_LoadMap(getmapname_stored, reinit);
1112 }
1113
1114 // return codes of map selectors:
1115 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1116 //   -2 = permanent failure
1117 float() MaplistMethod_Iterate = // usual method
1118 {
1119         float pass, i;
1120
1121         for(pass = 1; pass <= 2; ++pass)
1122         {
1123                 for(i = 1; i < Map_Count; ++i)
1124                 {
1125                         float mapindex;
1126                         mapindex = mod(i + Map_Current, Map_Count);
1127                         if(Map_Check(mapindex, pass))
1128                                 return mapindex;
1129                 }
1130         }
1131         return -1;
1132 }
1133
1134 float() MaplistMethod_Repeat = // fallback method
1135 {
1136         if(Map_Check(Map_Current, 2))
1137                 return Map_Current;
1138         return -2;
1139 }
1140
1141 float() MaplistMethod_Random = // random map selection
1142 {
1143         float i, imax;
1144
1145         imax = 42;
1146
1147         for(i = 0; i <= imax; ++i)
1148         {
1149                 float mapindex;
1150                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1151                 if(Map_Check(mapindex, 1))
1152                         return mapindex;
1153         }
1154         return -1;
1155 }
1156
1157 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1158 // the exponent sets a bias on the map selection:
1159 // the higher the exponent, the less likely "shortly repeated" same maps are
1160 {
1161         float i, j, imax, insertpos;
1162
1163         imax = 42;
1164
1165         for(i = 0; i <= imax; ++i)
1166         {
1167                 string newlist;
1168
1169                 // now reinsert this at another position
1170                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1171                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1172                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1173                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1174
1175                 // insert the current map there
1176                 newlist = "";
1177                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1178                         newlist = strcat(newlist, " ", argv(j));
1179                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1180                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1181                         newlist = strcat(newlist, " ", argv(j));
1182                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1183                 cvar_set("g_maplist", newlist);
1184                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1185
1186                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1187                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1188                 if(Map_Check(Map_Current, 1))
1189                         return Map_Current;
1190         }
1191         return -1;
1192 }
1193
1194 void Maplist_Init()
1195 {
1196         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1197         if(Map_Count == 0)
1198         {
1199                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1200                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1201                 if(autocvar_g_maplist_shuffle)
1202                         ShuffleMaplist();
1203                 localcmd("\nmenu_cmd sync\n");
1204                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1205         }
1206         if(Map_Count == 0)
1207                 error("empty maplist, cannot select a new map");
1208         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1209
1210         if(Map_Current_Name)
1211                 strunzone(Map_Current_Name);
1212         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1213         // this may or may not be correct, but who cares, in the worst case a map
1214         // isn't chosen in the first pass that should have been
1215 }
1216
1217 string GetNextMap()
1218 {
1219         float nextMap;
1220
1221         Maplist_Init();
1222         nextMap = -1;
1223
1224         if(nextMap == -1)
1225                 if(autocvar_g_maplist_shuffle > 0)
1226                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1227
1228         if(nextMap == -1)
1229                 if(autocvar_g_maplist_selectrandom)
1230                         nextMap = MaplistMethod_Random();
1231
1232         if(nextMap == -1)
1233                 nextMap = MaplistMethod_Iterate();
1234
1235         if(nextMap == -1)
1236                 nextMap = MaplistMethod_Repeat();
1237
1238         if(nextMap >= 0)
1239         {
1240                 Map_Goto_SetFloat(nextMap);
1241                 return getmapname_stored;
1242         }
1243
1244         return "";
1245 }
1246
1247 float DoNextMapOverride(float reinit)
1248 {
1249         if(autocvar_g_campaign)
1250         {
1251                 CampaignPostIntermission();
1252                 alreadychangedlevel = TRUE;
1253                 return TRUE;
1254         }
1255         if(autocvar_quit_when_empty)
1256         {
1257                 if(player_count <= currentbots)
1258                 {
1259                         localcmd("quit\n");
1260                         alreadychangedlevel = TRUE;
1261                         return TRUE;
1262                 }
1263         }
1264         if(autocvar_quit_and_redirect != "")
1265         {
1266                 redirection_target = strzone(autocvar_quit_and_redirect);
1267                 alreadychangedlevel = TRUE;
1268                 return TRUE;
1269         }
1270         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1271         {
1272                 localcmd("restart\n");
1273                 alreadychangedlevel = TRUE;
1274                 return TRUE;
1275         }
1276         if(autocvar_nextmap != "")
1277                 if(MapInfo_CheckMap(autocvar_nextmap))
1278                 {
1279                         Map_Goto_SetStr(autocvar_nextmap);
1280                         Map_Goto(reinit);
1281                         alreadychangedlevel = TRUE;
1282                         return TRUE;
1283                 }
1284         if(!reinit && autocvar_lastlevel)
1285         {
1286                 cvar_settemp_restore();
1287                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1288                 alreadychangedlevel = TRUE;
1289                 return TRUE;
1290         }
1291         return FALSE;
1292 }
1293
1294 void GotoNextMap(float reinit)
1295 {
1296         //string nextmap;
1297         //float n, nummaps;
1298         //string s;
1299         if (alreadychangedlevel)
1300                 return;
1301         alreadychangedlevel = TRUE;
1302
1303         {
1304                 string nextMap;
1305                 float allowReset;
1306
1307                 for(allowReset = 1; allowReset >= 0; --allowReset)
1308                 {
1309                         nextMap = GetNextMap();
1310                         if(nextMap != "")
1311                                 break;
1312
1313                         if(allowReset)
1314                         {
1315                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1316                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1317                                 if(autocvar_g_maplist_shuffle)
1318                                         ShuffleMaplist();
1319                                 localcmd("\nmenu_cmd sync\n");
1320                         }
1321                         else
1322                         {
1323                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1324                         }
1325                 }
1326                 Map_Goto(reinit);
1327         }
1328 }
1329
1330
1331 /*
1332 ============
1333 IntermissionThink
1334
1335 When the player presses attack or jump, change to the next level
1336 ============
1337 */
1338 .float autoscreenshot;
1339 void() MapVote_Start;
1340 void() MapVote_Think;
1341 float mapvote_initialized;
1342 void IntermissionThink()
1343 {
1344         FixIntermissionClient(self);
1345
1346         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1347         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1348
1349         if( (server_screenshot || client_screenshot)
1350                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1351         {
1352                 self.autoscreenshot = -1;
1353                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1354                 return;
1355         }
1356
1357         if (time < intermission_exittime)
1358                 return;
1359
1360         if(!mapvote_initialized)
1361                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1362                         return;
1363
1364         MapVote_Start();
1365 }
1366
1367 /*
1368 ============
1369 FindIntermission
1370
1371 Returns the entity to view from
1372 ============
1373 */
1374 /*
1375 entity FindIntermission()
1376 {
1377         local   entity spot;
1378         local   float cyc;
1379
1380 // look for info_intermission first
1381         spot = find (world, classname, "info_intermission");
1382         if (spot)
1383         {       // pick a random one
1384                 cyc = random() * 4;
1385                 while (cyc > 1)
1386                 {
1387                         spot = find (spot, classname, "info_intermission");
1388                         if (!spot)
1389                                 spot = find (spot, classname, "info_intermission");
1390                         cyc = cyc - 1;
1391                 }
1392                 return spot;
1393         }
1394
1395 // then look for the start position
1396         spot = find (world, classname, "info_player_start");
1397         if (spot)
1398                 return spot;
1399
1400 // testinfo_player_start is only found in regioned levels
1401         spot = find (world, classname, "testplayerstart");
1402         if (spot)
1403                 return spot;
1404
1405 // then look for the start position
1406         spot = find (world, classname, "info_player_deathmatch");
1407         if (spot)
1408                 return spot;
1409
1410         //objerror ("FindIntermission: no spot");
1411         return world;
1412 }
1413 */
1414
1415 /*
1416 ===============================================================================
1417
1418 RULES
1419
1420 ===============================================================================
1421 */
1422
1423 void DumpStats(float final)
1424 {
1425         float file;
1426         string s;
1427         float to_console;
1428         float to_eventlog;
1429         float to_file;
1430         float i;
1431
1432         to_console = autocvar_sv_logscores_console;
1433         to_eventlog = autocvar_sv_eventlog;
1434         to_file = autocvar_sv_logscores_file;
1435
1436         if(!final)
1437         {
1438                 to_console = TRUE; // always print printstats replies
1439                 to_eventlog = FALSE; // but never print them to the event log
1440         }
1441
1442         if(to_eventlog)
1443                 if(autocvar_sv_eventlog_console)
1444                         to_console = FALSE; // otherwise we get the output twice
1445
1446         if(final)
1447                 s = ":scores:";
1448         else
1449                 s = ":status:";
1450         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1451
1452         if(to_console)
1453                 print(s, "\n");
1454         if(to_eventlog)
1455                 GameLogEcho(s);
1456
1457         file = -1;
1458         if(to_file)
1459         {
1460                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1461                 if(file == -1)
1462                         to_file = FALSE;
1463                 else
1464                         fputs(file, strcat(s, "\n"));
1465         }
1466
1467         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1468         if(to_console)
1469                 print(s, "\n");
1470         if(to_eventlog)
1471                 GameLogEcho(s);
1472         if(to_file)
1473                 fputs(file, strcat(s, "\n"));
1474
1475         FOR_EACH_CLIENT(other)
1476         {
1477                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1478                 {
1479                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1480                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1481                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1482                                 s = strcat(s, ftos(other.team), ":");
1483                         else
1484                                 s = strcat(s, "spectator:");
1485
1486                         if(to_console)
1487                                 print(s, other.netname, "\n");
1488                         if(to_eventlog)
1489                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1490                         if(to_file)
1491                                 fputs(file, strcat(s, other.netname, "\n"));
1492                 }
1493         }
1494
1495         if(teamplay)
1496         {
1497                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1498                 if(to_console)
1499                         print(s, "\n");
1500                 if(to_eventlog)
1501                         GameLogEcho(s);
1502                 if(to_file)
1503                         fputs(file, strcat(s, "\n"));
1504
1505                 for(i = 1; i < 16; ++i)
1506                 {
1507                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1508                         s = strcat(s, ":", ftos(i));
1509                         if(to_console)
1510                                 print(s, "\n");
1511                         if(to_eventlog)
1512                                 GameLogEcho(s);
1513                         if(to_file)
1514                                 fputs(file, strcat(s, "\n"));
1515                 }
1516         }
1517
1518         if(to_console)
1519                 print(":end\n");
1520         if(to_eventlog)
1521                 GameLogEcho(":end");
1522         if(to_file)
1523         {
1524                 fputs(file, ":end\n");
1525                 fclose(file);
1526         }
1527 }
1528
1529 void FixIntermissionClient(entity e)
1530 {
1531         string s;
1532         if(!e.autoscreenshot) // initial call
1533         {
1534                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1535                 e.health = -2342;
1536                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1537                 e.solid = SOLID_NOT;
1538                 e.movetype = MOVETYPE_NONE;
1539                 e.takedamage = DAMAGE_NO;
1540                 if(e.weaponentity)
1541                 {
1542                         e.weaponentity.effects = EF_NODRAW;
1543                         if (e.weaponentity.weaponentity)
1544                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1545                 }
1546                 if(clienttype(e) == CLIENTTYPE_REAL)
1547                 {
1548                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1549                         s = autocvar_sv_intermission_cdtrack;
1550                         if(s != "")
1551                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1552                         msg_entity = e;
1553                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1554                 }
1555         }
1556 }
1557
1558 void minstagib_stop_countdown(entity e);
1559 /*
1560 go to the next level for deathmatch
1561 only called if a time or frag limit has expired
1562 */
1563 void NextLevel()
1564 {
1565         gameover = TRUE;
1566
1567         intermission_running = 1;
1568
1569 // enforce a wait time before allowing changelevel
1570         if(player_count > 0)
1571                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1572         else
1573                 intermission_exittime = -1;
1574
1575         /*
1576         WriteByte (MSG_ALL, SVC_CDTRACK);
1577         WriteByte (MSG_ALL, 3);
1578         WriteByte (MSG_ALL, 3);
1579         // done in FixIntermission
1580         */
1581
1582         //pos = FindIntermission ();
1583
1584         VoteReset();
1585
1586         DumpStats(TRUE);
1587
1588         // send statistics
1589         entity e;
1590         PlayerStats_EndMatch(1);
1591         FOR_EACH_CLIENT(e)
1592                 PlayerStats_AddGlobalInfo(e);
1593         PlayerStats_Shutdown();
1594         WeaponStats_Shutdown();
1595
1596         if(autocvar_sv_eventlog)
1597                 GameLogEcho(":gameover");
1598
1599         GameLogClose();
1600
1601         FOR_EACH_PLAYER(other) {
1602                 minstagib_stop_countdown(other);
1603                 FixIntermissionClient(other);
1604                 if(other.winning)
1605                         bprint(other.netname, " ^7wins.\n");
1606         }
1607
1608         if(autocvar_g_campaign)
1609                 CampaignPreIntermission();
1610
1611         MUTATOR_CALLHOOK(MatchEnd);
1612
1613         localcmd("\nsv_hook_gameend\n");
1614 }
1615
1616 /*
1617 ============
1618 CheckRules_Player
1619
1620 Exit deathmatch games upon conditions
1621 ============
1622 */
1623 void CheckRules_Player()
1624 {
1625         if (gameover)   // someone else quit the game already
1626                 return;
1627
1628         if(self.deadflag == DEAD_NO)
1629                 self.play_time += frametime;
1630
1631         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1632         //   (div0: and that in CheckRules_World please)
1633 }
1634
1635 float checkrules_equality;
1636 float checkrules_suddendeathwarning;
1637 float checkrules_suddendeathend;
1638 float checkrules_overtimesadded; //how many overtimes have been already added
1639
1640 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1641 float WINNING_YES = 1; // winner found
1642 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1643 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1644
1645 float InitiateSuddenDeath()
1646 {
1647         // Check first whether normal overtimes could be added before initiating suddendeath mode
1648         // - for this timelimit_overtime needs to be >0 of course
1649         // - also check the winning condition calculated in the previous frame and only add normal overtime
1650         //   again, if at the point at which timelimit would be extended again, still no winner was found
1651         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1652         {
1653                 return 1; // need to call InitiateOvertime later
1654         }
1655         else
1656         {
1657                 if(!checkrules_suddendeathend)
1658                 {
1659                         if(autocvar_g_campaign)
1660                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1661                         else
1662                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1663                         if(g_race && !g_race_qualifying)
1664                                 race_StartCompleting();
1665                 }
1666                 return 0;
1667         }
1668 }
1669
1670 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1671 {
1672         ++checkrules_overtimesadded;
1673         //add one more overtime by simply extending the timelimit
1674         float tl;
1675         tl = autocvar_timelimit;
1676         tl += autocvar_timelimit_overtime;
1677         cvar_set("timelimit", ftos(tl));
1678         string minutesPlural;
1679         if (autocvar_timelimit_overtime == 1)
1680                 minutesPlural = " ^3minute";
1681         else
1682                 minutesPlural = " ^3minutes";
1683
1684         bcenterprint(
1685                 strcat(
1686                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1687                         ftos(autocvar_timelimit_overtime),
1688                         minutesPlural,
1689                         " to the game!"
1690                 )
1691         );
1692 }
1693
1694 float GetWinningCode(float fraglimitreached, float equality)
1695 {
1696         if(autocvar_g_campaign == 1)
1697                 if(fraglimitreached)
1698                         return WINNING_YES;
1699                 else
1700                         return WINNING_NO;
1701
1702         else
1703                 if(equality)
1704                         if(fraglimitreached)
1705                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1706                         else
1707                                 return WINNING_NEVER;
1708                 else
1709                         if(fraglimitreached)
1710                                 return WINNING_YES;
1711                         else
1712                                 return WINNING_NO;
1713 }
1714
1715 // set the .winning flag for exactly those players with a given field value
1716 void SetWinners(.float field, float value)
1717 {
1718         entity head;
1719         FOR_EACH_PLAYER(head)
1720                 head.winning = (head.field == value);
1721 }
1722
1723 // set the .winning flag for those players with a given field value
1724 void AddWinners(.float field, float value)
1725 {
1726         entity head;
1727         FOR_EACH_PLAYER(head)
1728                 if(head.field == value)
1729                         head.winning = 1;
1730 }
1731
1732 // clear the .winning flags
1733 void ClearWinners(void)
1734 {
1735         entity head;
1736         FOR_EACH_PLAYER(head)
1737                 head.winning = 0;
1738 }
1739
1740 // Onslaught winning condition:
1741 // game terminates if only one team has a working generator (or none)
1742 float WinningCondition_Onslaught()
1743 {
1744         entity head;
1745         float t1, t2, t3, t4;
1746
1747         WinningConditionHelper(); // set worldstatus
1748
1749         if(inWarmupStage)
1750                 return WINNING_NO;
1751
1752         // first check if the game has ended
1753         t1 = t2 = t3 = t4 = 0;
1754         head = find(world, classname, "onslaught_generator");
1755         while (head)
1756         {
1757                 if (head.health > 0)
1758                 {
1759                         if (head.team == COLOR_TEAM1) t1 = 1;
1760                         if (head.team == COLOR_TEAM2) t2 = 1;
1761                         if (head.team == COLOR_TEAM3) t3 = 1;
1762                         if (head.team == COLOR_TEAM4) t4 = 1;
1763                 }
1764                 head = find(head, classname, "onslaught_generator");
1765         }
1766         if (t1 + t2 + t3 + t4 < 2)
1767         {
1768                 // game over, only one team remains (or none)
1769                 ClearWinners();
1770                 if (t1) SetWinners(team, COLOR_TEAM1);
1771                 if (t2) SetWinners(team, COLOR_TEAM2);
1772                 if (t3) SetWinners(team, COLOR_TEAM3);
1773                 if (t4) SetWinners(team, COLOR_TEAM4);
1774                 dprint("Have a winner, ending game.\n");
1775                 return WINNING_YES;
1776         }
1777
1778         // Two or more teams remain
1779         return WINNING_NO;
1780 }
1781
1782 float LMS_NewPlayerLives()
1783 {
1784         float fl;
1785         fl = autocvar_fraglimit;
1786         if(fl == 0)
1787                 fl = 999;
1788
1789         // first player has left the game for dying too much? Nobody else can get in.
1790         if(lms_lowest_lives < 1)
1791                 return 0;
1792
1793         if(!autocvar_g_lms_join_anytime)
1794                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1795                         return 0;
1796
1797         return bound(1, lms_lowest_lives, fl);
1798 }
1799
1800 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1801 // they win. Otherwise the defending team wins once the timelimit passes.
1802 void assault_new_round();
1803 float WinningCondition_Assault()
1804 {
1805         float status;
1806
1807         WinningConditionHelper(); // set worldstatus
1808
1809         status = WINNING_NO;
1810         // as the timelimit has not yet passed just assume the defending team will win
1811         if(assault_attacker_team == COLOR_TEAM1)
1812         {
1813                 SetWinners(team, COLOR_TEAM2);
1814         }
1815         else
1816         {
1817                 SetWinners(team, COLOR_TEAM1);
1818         }
1819
1820         entity ent;
1821         ent = find(world, classname, "target_assault_roundend");
1822         if(ent)
1823         {
1824                 if(ent.winning) // round end has been triggered by attacking team
1825                 {
1826                         bprint("ASSAULT: round completed...\n");
1827                         SetWinners(team, assault_attacker_team);
1828
1829                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1830
1831                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1832                         {
1833                                 status = WINNING_YES;
1834                         }
1835                         else
1836                         {
1837                                 entity oldself;
1838                                 oldself = self;
1839                                 self = ent;
1840                                 assault_new_round();
1841                                 self = oldself;
1842                         }
1843                 }
1844         }
1845
1846         return status;
1847 }
1848
1849 // LMS winning condition: game terminates if and only if there's at most one
1850 // one player who's living lives. Top two scores being equal cancels the time
1851 // limit.
1852 float WinningCondition_LMS()
1853 {
1854         entity head, head2;
1855         float have_player;
1856         float have_players;
1857         float l;
1858
1859         have_player = FALSE;
1860         have_players = FALSE;
1861         l = LMS_NewPlayerLives();
1862
1863         head = find(world, classname, "player");
1864         if(head)
1865                 have_player = TRUE;
1866         head2 = find(head, classname, "player");
1867         if(head2)
1868                 have_players = TRUE;
1869
1870         if(have_player)
1871         {
1872                 // we have at least one player
1873                 if(have_players)
1874                 {
1875                         // two or more active players - continue with the game
1876                 }
1877                 else
1878                 {
1879                         // exactly one player?
1880
1881                         ClearWinners();
1882                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1883
1884                         if(l)
1885                         {
1886                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1887                                 return WINNING_NO;
1888                         }
1889                         else
1890                         {
1891                                 // a winner!
1892                                 // and assign him his first place
1893                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1894                                 return WINNING_YES;
1895                         }
1896                 }
1897         }
1898         else
1899         {
1900                 // nobody is playing at all...
1901                 if(l)
1902                 {
1903                         // wait for players...
1904                 }
1905                 else
1906                 {
1907                         // SNAFU (maybe a draw game?)
1908                         ClearWinners();
1909                         dprint("No players, ending game.\n");
1910                         return WINNING_YES;
1911                 }
1912         }
1913
1914         // When we get here, we have at least two players who are actually LIVING,
1915         // now check if the top two players have equal score.
1916         WinningConditionHelper();
1917
1918         ClearWinners();
1919         if(WinningConditionHelper_winner)
1920                 WinningConditionHelper_winner.winning = TRUE;
1921         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1922                 return WINNING_NEVER;
1923
1924         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1925         return WINNING_NO;
1926 }
1927
1928 void ShuffleMaplist()
1929 {
1930         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1931 }
1932
1933 float leaderfrags;
1934 float WinningCondition_Scores(float limit, float leadlimit)
1935 {
1936         float limitreached;
1937
1938         // TODO make everything use THIS winning condition (except LMS)
1939         WinningConditionHelper();
1940
1941         if(teamplay)
1942         {
1943                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1944                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1945                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1946                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1947         }
1948
1949         ClearWinners();
1950         if(WinningConditionHelper_winner)
1951                 WinningConditionHelper_winner.winning = 1;
1952         if(WinningConditionHelper_winnerteam >= 0)
1953                 SetWinners(team, WinningConditionHelper_winnerteam);
1954
1955         if(WinningConditionHelper_lowerisbetter)
1956         {
1957                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1958                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1959                 limit = -limit;
1960         }
1961
1962         if(WinningConditionHelper_zeroisworst)
1963                 leadlimit = 0; // not supported in this mode
1964
1965         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1966         // these modes always score in increments of 1, thus this makes sense
1967         {
1968                 if(leaderfrags != WinningConditionHelper_topscore)
1969                 {
1970                         leaderfrags = WinningConditionHelper_topscore;
1971
1972                         if (limit)
1973                         if (leaderfrags == limit - 1)
1974                                 Announce("1fragleft");
1975                         else if (leaderfrags == limit - 2)
1976                                 Announce("2fragsleft");
1977                         else if (leaderfrags == limit - 3)
1978                                 Announce("3fragsleft");
1979                 }
1980         }
1981
1982         limitreached = FALSE;
1983         if(limit)
1984                 if(WinningConditionHelper_topscore >= limit)
1985                         limitreached = TRUE;
1986         if(leadlimit)
1987         {
1988                 float leadlimitreached;
1989                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1990                 if(autocvar_leadlimit_and_fraglimit)
1991                         limitreached = (limitreached && leadlimitreached);
1992                 else
1993                         limitreached = (limitreached || leadlimitreached);
1994         }
1995
1996         if(limit)
1997                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1998
1999         return GetWinningCode(
2000                 WinningConditionHelper_topscore && limitreached,
2001                 WinningConditionHelper_equality
2002         );
2003 }
2004
2005 float WinningCondition_Race(float fraglimit)
2006 {
2007         float wc;
2008         entity p;
2009         float n, c;
2010
2011         n = 0;
2012         c = 0;
2013         FOR_EACH_PLAYER(p)
2014         {
2015                 ++n;
2016                 if(p.race_completed)
2017                         ++c;
2018         }
2019         if(n && (n == c))
2020                 return WINNING_YES;
2021         wc = WinningCondition_Scores(fraglimit, 0);
2022
2023         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2024         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2025         // do NOT support equality when the laps are all raced!
2026                 return WINNING_STARTSUDDENDEATHOVERTIME;
2027         else
2028                 return WINNING_NEVER;
2029 }
2030
2031 float WinningCondition_QualifyingThenRace(float limit)
2032 {
2033         float wc;
2034         wc = WinningCondition_Scores(limit, 0);
2035
2036         // NEVER initiate overtime
2037         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2038         {
2039                 return WINNING_YES;
2040         }
2041
2042         return wc;
2043 }
2044
2045 float WinningCondition_RanOutOfSpawns()
2046 {
2047         entity head;
2048
2049         if(have_team_spawns <= 0)
2050                 return WINNING_NO;
2051
2052         if(autocvar_g_spawn_useallspawns <= 0)
2053                 return WINNING_NO;
2054
2055         if(!some_spawn_has_been_used)
2056                 return WINNING_NO;
2057
2058         team1_score = team2_score = team3_score = team4_score = 0;
2059
2060         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2061         {
2062                 if(head.team == COLOR_TEAM1)
2063                         team1_score = 1;
2064                 else if(head.team == COLOR_TEAM2)
2065                         team2_score = 1;
2066                 else if(head.team == COLOR_TEAM3)
2067                         team3_score = 1;
2068                 else if(head.team == COLOR_TEAM4)
2069                         team4_score = 1;
2070         }
2071
2072         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2073         {
2074                 if(head.team == COLOR_TEAM1)
2075                         team1_score = 1;
2076                 else if(head.team == COLOR_TEAM2)
2077                         team2_score = 1;
2078                 else if(head.team == COLOR_TEAM3)
2079                         team3_score = 1;
2080                 else if(head.team == COLOR_TEAM4)
2081                         team4_score = 1;
2082         }
2083
2084         ClearWinners();
2085         if(team1_score + team2_score + team3_score + team4_score == 0)
2086         {
2087                 checkrules_equality = TRUE;
2088                 return WINNING_YES;
2089         }
2090         else if(team1_score + team2_score + team3_score + team4_score == 1)
2091         {
2092                 float t, i;
2093                 if(team1_score)
2094                         t = COLOR_TEAM1;
2095                 else if(team2_score)
2096                         t = COLOR_TEAM2;
2097                 else if(team3_score)
2098                         t = COLOR_TEAM3;
2099                 else // if(team4_score)
2100                         t = COLOR_TEAM4;
2101                 CheckAllowedTeams(world);
2102                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2103                 {
2104                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2105                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2106                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2107                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2108                 }
2109
2110                 AddWinners(team, t);
2111                 return WINNING_YES;
2112         }
2113         else
2114                 return WINNING_NO;
2115 }
2116
2117 /*
2118 ============
2119 CheckRules_World
2120
2121 Exit deathmatch games upon conditions
2122 ============
2123 */
2124 void ReadyRestart();
2125 void CheckRules_World()
2126 {
2127         float timelimit;
2128         float fraglimit;
2129         float leadlimit;
2130
2131         VoteThink();
2132         MapVote_Think();
2133
2134         SetDefaultAlpha();
2135
2136         /*
2137         MapVote_Think should now do that part
2138         if (intermission_running)
2139                 if (time >= intermission_exittime + 60)
2140                 {
2141                         if(!DoNextMapOverride())
2142                                 GotoNextMap();
2143                         return;
2144                 }
2145         */
2146
2147         if (gameover)   // someone else quit the game already
2148         {
2149                 if(player_count == 0) // Nobody there? Then let's go to the next map
2150                         MapVote_Start();
2151                         // this will actually check the player count in the next frame
2152                         // again, but this shouldn't hurt
2153                 return;
2154         }
2155
2156         timelimit = autocvar_timelimit * 60;
2157         fraglimit = autocvar_fraglimit;
2158         leadlimit = autocvar_leadlimit;
2159
2160         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2161         {
2162                 if(timelimit > 0)
2163                         timelimit = 0; // timelimit is not made for warmup
2164                 if(fraglimit > 0)
2165                         fraglimit = 0; // no fraglimit for now
2166                 leadlimit = 0; // no leadlimit for now
2167         }
2168
2169         if(timelimit > 0)
2170         {
2171                 timelimit += game_starttime;
2172         }
2173         else if (timelimit < 0)
2174         {
2175                 // endmatch
2176                 NextLevel();
2177                 return;
2178         }
2179
2180         if(g_onslaught)
2181                 timelimit = 0; // ONS has its own overtime rule
2182
2183         float wantovertime;
2184         wantovertime = 0;
2185
2186         if(timelimit > game_starttime)
2187                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2188         else
2189                 game_completion_ratio = 0;
2190
2191         if(checkrules_suddendeathend)
2192         {
2193                 if(!checkrules_suddendeathwarning)
2194                 {
2195                         checkrules_suddendeathwarning = TRUE;
2196                         if(g_race && !g_race_qualifying)
2197                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2198                         else
2199                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2200                 }
2201         }
2202         else
2203         {
2204                 if (timelimit && time >= timelimit)
2205                 {
2206                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2207                         {
2208                                 float totalplayers;
2209                                 float playerswithlaps;
2210                                 float readyplayers;
2211                                 entity head;
2212                                 totalplayers = playerswithlaps = readyplayers = 0;
2213                                 FOR_EACH_PLAYER(head)
2214                                 {
2215                                         ++totalplayers;
2216                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2217                                                 ++playerswithlaps;
2218                                         if(head.ready)
2219                                                 ++readyplayers;
2220                                 }
2221
2222                                 // at least 2 of the players have completed a lap: start the RACE
2223                                 // otherwise, the players should end the qualifying on their own
2224                                 if(readyplayers || playerswithlaps >= 2)
2225                                 {
2226                                         checkrules_suddendeathend = 0;
2227                                         ReadyRestart(); // go to race
2228                                         return;
2229                                 }
2230                                 else
2231                                         wantovertime |= InitiateSuddenDeath();
2232                         }
2233                         else
2234                                 wantovertime |= InitiateSuddenDeath();
2235                 }
2236         }
2237
2238         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2239         {
2240                 NextLevel();
2241                 return;
2242         }
2243
2244         float checkrules_status;
2245         checkrules_status = WinningCondition_RanOutOfSpawns();
2246         if(checkrules_status == WINNING_YES)
2247         {
2248                 bprint("Hey! Someone ran out of spawns!\n");
2249         }
2250         else if(g_race && !g_race_qualifying && timelimit >= 0)
2251         {
2252                 checkrules_status = WinningCondition_Race(fraglimit);
2253                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2254         }
2255         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2256         {
2257                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2258                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2259         }
2260         else if(g_assault)
2261         {
2262                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2263         }
2264         else if(g_lms)
2265         {
2266                 checkrules_status = WinningCondition_LMS();
2267         }
2268         else if (g_onslaught)
2269         {
2270                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2271         }
2272         else
2273         {
2274                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2275                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2276         }
2277
2278         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2279         {
2280                 checkrules_status = WINNING_NEVER;
2281                 checkrules_overtimesadded = -1;
2282                 wantovertime |= InitiateSuddenDeath();
2283         }
2284
2285         if(checkrules_status == WINNING_NEVER)
2286                 // equality cases! Nobody wins if the overtime ends in a draw.
2287                 ClearWinners();
2288
2289         if(wantovertime)
2290         {
2291                 if(checkrules_status == WINNING_NEVER)
2292                         InitiateOvertime();
2293                 else
2294                         checkrules_status = WINNING_YES;
2295         }
2296
2297         if(checkrules_suddendeathend)
2298                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2299                         checkrules_status = WINNING_YES;
2300
2301         if(checkrules_status == WINNING_YES)
2302         {
2303                 //print("WINNING\n");
2304                 NextLevel();
2305         }
2306 }
2307
2308 float mapvote_nextthink;
2309 float mapvote_initialized;
2310 float mapvote_keeptwotime;
2311 float mapvote_timeout;
2312 string mapvote_message;
2313 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2314 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2315 float mapvote_screenshot_dirs_count;
2316
2317 float mapvote_count;
2318 float mapvote_count_real;
2319 string mapvote_maps[MAPVOTE_COUNT];
2320 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2321 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2322 float mapvote_maps_suggested[MAPVOTE_COUNT];
2323 string mapvote_suggestions[MAPVOTE_COUNT];
2324 float mapvote_suggestion_ptr;
2325 float mapvote_voters;
2326 float mapvote_selections[MAPVOTE_COUNT];
2327 float mapvote_run;
2328 float mapvote_detail;
2329 float mapvote_abstain;
2330 .float mapvote;
2331
2332 void MapVote_ClearAllVotes()
2333 {
2334         FOR_EACH_CLIENT(other)
2335                 other.mapvote = 0;
2336 }
2337
2338 string MapVote_Suggest(string m)
2339 {
2340         float i;
2341         if(m == "")
2342                 return "That's not how to use this command.";
2343         if(!autocvar_g_maplist_votable_suggestions)
2344                 return "Suggestions are not accepted on this server.";
2345         if(mapvote_initialized)
2346                 return "Can't suggest - voting is already in progress!";
2347         m = MapInfo_FixName(m);
2348         if not(m)
2349                 return "The map you suggested is not available on this server.";
2350         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2351                 if(Map_IsRecent(m))
2352                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2353
2354         if(!MapInfo_CheckMap(m))
2355                 return "The map you suggested does not support the current game mode.";
2356         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2357                 if(mapvote_suggestions[i] == m)
2358                         return "This map was already suggested.";
2359         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2360         {
2361                 i = floor(random() * mapvote_suggestion_ptr);
2362         }
2363         else
2364         {
2365                 i = mapvote_suggestion_ptr;
2366                 mapvote_suggestion_ptr += 1;
2367         }
2368         if(mapvote_suggestions[i] != "")
2369                 strunzone(mapvote_suggestions[i]);
2370         mapvote_suggestions[i] = strzone(m);
2371         if(autocvar_sv_eventlog)
2372                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2373         return strcat("Suggestion of ", m, " accepted.");
2374 }
2375
2376 void MapVote_AddVotable(string nextMap, float isSuggestion)
2377 {
2378         float j, i, o;
2379         string pakfile, mapfile;
2380
2381         if(nextMap == "")
2382                 return;
2383         for(j = 0; j < mapvote_count; ++j)
2384                 if(mapvote_maps[j] == nextMap)
2385                         return;
2386         // suggestions might be no longer valid/allowed after gametype switch!
2387         if(isSuggestion)
2388                 if(!MapInfo_CheckMap(nextMap))
2389                         return;
2390         mapvote_maps[mapvote_count] = strzone(nextMap);
2391         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2392
2393         pakfile = string_null;
2394         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2395         {
2396                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2397                 pakfile = whichpack(strcat(mapfile, ".tga"));
2398                 if(pakfile == "")
2399                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2400                 if(pakfile == "")
2401                         pakfile = whichpack(strcat(mapfile, ".png"));
2402                 if(pakfile != "")
2403                         break;
2404         }
2405         if(i >= mapvote_screenshot_dirs_count)
2406                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2407         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2408                 pakfile = substring(pakfile, o, -1);
2409
2410         mapvote_maps_screenshot_dir[mapvote_count] = i;
2411         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2412
2413         mapvote_count += 1;
2414 }
2415
2416 void MapVote_Spawn();
2417 void MapVote_Init()
2418 {
2419         float i;
2420         float nmax, smax;
2421
2422         MapVote_ClearAllVotes();
2423
2424         mapvote_count = 0;
2425         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2426         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2427
2428         if(mapvote_abstain)
2429                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2430         else
2431                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2432         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2433
2434         // we need this for AddVotable, as that cycles through the screenshot dirs
2435         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2436         if(mapvote_screenshot_dirs_count == 0)
2437                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2438         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2439         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2440                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2441
2442         if(mapvote_suggestion_ptr)
2443                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2444                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2445
2446         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2447                 MapVote_AddVotable(GetNextMap(), FALSE);
2448
2449         if(mapvote_count == 0)
2450         {
2451                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2452                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2453                 if(autocvar_g_maplist_shuffle)
2454                         ShuffleMaplist();
2455                 localcmd("\nmenu_cmd sync\n");
2456                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2457                         MapVote_AddVotable(GetNextMap(), FALSE);
2458         }
2459
2460         mapvote_count_real = mapvote_count;
2461         if(mapvote_abstain)
2462                 MapVote_AddVotable("don't care", 0);
2463
2464         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2465
2466         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2467         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2468         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2469                 mapvote_keeptwotime = 0;
2470         mapvote_message = "Choose a map and press its key!";
2471
2472         MapVote_Spawn();
2473 }
2474
2475 void MapVote_SendPicture(float id)
2476 {
2477         msg_entity = self;
2478         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2479         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2480         WriteByte(MSG_ONE, id);
2481         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2482 }
2483
2484 float MapVote_GetMapMask()
2485 {
2486         float mask, i, power;
2487         mask = 0;
2488         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2489                 if(mapvote_maps[i] != "")
2490                         mask |= power;
2491         return mask;
2492 }
2493
2494 entity mapvote_ent;
2495 float MapVote_SendEntity(entity to, float sf)
2496 {
2497         float i;
2498
2499         if(sf & 1)
2500                 sf &~= 2; // if we send 1, we don't need to also send 2
2501
2502         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2503         WriteByte(MSG_ENTITY, sf);
2504
2505         if(sf & 1)
2506         {
2507                 // flag 1 == initialization
2508                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2509                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2510                 WriteString(MSG_ENTITY, "");
2511                 WriteByte(MSG_ENTITY, mapvote_count);
2512                 WriteByte(MSG_ENTITY, mapvote_abstain);
2513                 WriteByte(MSG_ENTITY, mapvote_detail);
2514                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2515                 if(mapvote_count <= 8)
2516                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2517                 else
2518                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2519                 for(i = 0; i < mapvote_count; ++i)
2520                         if(mapvote_maps[i] != "")
2521                         {
2522                                 if(mapvote_abstain && i == mapvote_count - 1)
2523                                 {
2524                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2525                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2526                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2527                                 }
2528                                 else
2529                                 {
2530                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2531                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2532                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2533                                 }
2534                         }
2535         }
2536
2537         if(sf & 2)
2538         {
2539                 // flag 2 == update of mask
2540                 if(mapvote_count <= 8)
2541                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2542                 else
2543                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2544         }
2545
2546         if(sf & 4)
2547         {
2548                 if(mapvote_detail)
2549                         for(i = 0; i < mapvote_count; ++i)
2550                                 if(mapvote_maps[i] != "")
2551                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2552
2553                 WriteByte(MSG_ENTITY, to.mapvote);
2554         }
2555
2556         return TRUE;
2557 }
2558
2559 void MapVote_Spawn()
2560 {
2561         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2562 }
2563
2564 void MapVote_TouchMask()
2565 {
2566         mapvote_ent.SendFlags |= 2;
2567 }
2568
2569 void MapVote_TouchVotes(entity voter)
2570 {
2571         mapvote_ent.SendFlags |= 4;
2572 }
2573
2574 float MapVote_Finished(float mappos)
2575 {
2576         string result;
2577         float i;
2578         float didntvote;
2579
2580         if(autocvar_sv_eventlog)
2581         {
2582                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2583                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2584                 didntvote = mapvote_voters;
2585                 for(i = 0; i < mapvote_count; ++i)
2586                         if(mapvote_maps[i] != "")
2587                         {
2588                                 didntvote -= mapvote_selections[i];
2589                                 if(i != mappos)
2590                                 {
2591                                         result = strcat(result, ":", mapvote_maps[i]);
2592                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2593                                 }
2594                         }
2595                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2596
2597                 GameLogEcho(result);
2598                 if(mapvote_maps_suggested[mappos])
2599                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2600         }
2601
2602         FOR_EACH_REALCLIENT(other)
2603                 FixClientCvars(other);
2604
2605         Map_Goto_SetStr(mapvote_maps[mappos]);
2606         Map_Goto(0);
2607         alreadychangedlevel = TRUE;
2608         return TRUE;
2609 }
2610 void MapVote_CheckRules_1()
2611 {
2612         float i;
2613
2614         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2615         {
2616                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2617                 mapvote_selections[i] = 0;
2618         }
2619
2620         mapvote_voters = 0;
2621         FOR_EACH_REALCLIENT(other)
2622         {
2623                 ++mapvote_voters;
2624                 if(other.mapvote)
2625                 {
2626                         i = other.mapvote - 1;
2627                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2628                         mapvote_selections[i] = mapvote_selections[i] + 1;
2629                 }
2630         }
2631 }
2632
2633 float MapVote_CheckRules_2()
2634 {
2635         float i;
2636         float firstPlace, secondPlace;
2637         float firstPlaceVotes, secondPlaceVotes;
2638         float mapvote_voters_real;
2639         string result;
2640
2641         if(mapvote_count_real == 1)
2642                 return MapVote_Finished(0);
2643
2644         mapvote_voters_real = mapvote_voters;
2645         if(mapvote_abstain)
2646                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2647
2648         RandomSelection_Init();
2649         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2650                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2651         firstPlace = RandomSelection_chosen_float;
2652         firstPlaceVotes = RandomSelection_best_priority;
2653         //dprint("First place: ", ftos(firstPlace), "\n");
2654         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2655
2656         RandomSelection_Init();
2657         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2658                 if(i != firstPlace)
2659                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2660         secondPlace = RandomSelection_chosen_float;
2661         secondPlaceVotes = RandomSelection_best_priority;
2662         //dprint("Second place: ", ftos(secondPlace), "\n");
2663         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2664
2665         if(firstPlace == -1)
2666                 error("No first place in map vote... WTF?");
2667
2668         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2669                 return MapVote_Finished(firstPlace);
2670
2671         if(mapvote_keeptwotime)
2672                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2673                 {
2674                         float didntvote;
2675                         MapVote_TouchMask();
2676                         mapvote_message = "Now decide between the TOP TWO!";
2677                         mapvote_keeptwotime = 0;
2678                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2679                         result = strcat(result, ":", ftos(firstPlaceVotes));
2680                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2681                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2682                         didntvote = mapvote_voters;
2683                         for(i = 0; i < mapvote_count; ++i)
2684                                 if(mapvote_maps[i] != "")
2685                                 {
2686                                         didntvote -= mapvote_selections[i];
2687                                         if(i != firstPlace)
2688                                                 if(i != secondPlace)
2689                                                 {
2690                                                         result = strcat(result, ":", mapvote_maps[i]);
2691                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2692                                                         if(i < mapvote_count_real)
2693                                                         {
2694                                                                 strunzone(mapvote_maps[i]);
2695                                                                 mapvote_maps[i] = "";
2696                                                                 strunzone(mapvote_maps_pakfile[i]);
2697                                                                 mapvote_maps_pakfile[i] = "";
2698                                                         }
2699                                                 }
2700                                 }
2701                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2702                         if(autocvar_sv_eventlog)
2703                                 GameLogEcho(result);
2704                 }
2705
2706         return FALSE;
2707 }
2708 void MapVote_Tick()
2709 {
2710         float keeptwo;
2711         float totalvotes;
2712
2713         keeptwo = mapvote_keeptwotime;
2714         MapVote_CheckRules_1(); // count
2715         if(MapVote_CheckRules_2()) // decide
2716                 return;
2717
2718         totalvotes = 0;
2719         FOR_EACH_REALCLIENT(other)
2720         {
2721                 // hide scoreboard again
2722                 if(other.health != 2342)
2723                 {
2724                         other.health = 2342;
2725                         other.impulse = 0;
2726                         if(clienttype(other) == CLIENTTYPE_REAL)
2727                         {
2728                                 msg_entity = other;
2729                                 WriteByte(MSG_ONE, SVC_FINALE);
2730                                 WriteString(MSG_ONE, "");
2731                         }
2732                 }
2733
2734                 // clear possibly invalid votes
2735                 if(mapvote_maps[other.mapvote - 1] == "")
2736                         other.mapvote = 0;
2737                 // use impulses as new vote
2738                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2739                         if(mapvote_maps[other.impulse - 1] != "")
2740                         {
2741                                 other.mapvote = other.impulse;
2742                                 MapVote_TouchVotes(other);
2743                         }
2744                 other.impulse = 0;
2745
2746                 if(other.mapvote)
2747                         ++totalvotes;
2748         }
2749
2750         MapVote_CheckRules_1(); // just count
2751 }
2752 void MapVote_Start()
2753 {
2754         if(mapvote_run)
2755                 return;
2756
2757         // wait for stats to be sent first
2758         if(!playerstats_waitforme)
2759                 return;
2760
2761         MapInfo_Enumerate();
2762         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2763                 mapvote_run = TRUE;
2764 }
2765 void MapVote_Think()
2766 {
2767         if(!mapvote_run)
2768                 return;
2769
2770         if(alreadychangedlevel)
2771                 return;
2772
2773         if(time < mapvote_nextthink)
2774                 return;
2775         //dprint("tick\n");
2776
2777         mapvote_nextthink = time + 0.5;
2778
2779         if(!mapvote_initialized)
2780         {
2781                 if(autocvar_rescan_pending == 1)
2782                 {
2783                         cvar_set("rescan_pending", "2");
2784                         localcmd("fs_rescan\nrescan_pending 3\n");
2785                         return;
2786                 }
2787                 else if(autocvar_rescan_pending == 2)
2788                 {
2789                         return;
2790                 }
2791                 else if(autocvar_rescan_pending == 3)
2792                 {
2793                         // now build missing mapinfo files
2794                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2795                                 return;
2796
2797                         // we're done, start the timer
2798                         cvar_set("rescan_pending", "0");
2799                 }
2800
2801                 mapvote_initialized = TRUE;
2802                 if(DoNextMapOverride(0))
2803                         return;
2804                 if(!autocvar_g_maplist_votable || player_count <= 0)
2805                 {
2806                         GotoNextMap(0);
2807                         return;
2808                 }
2809                 MapVote_Init();
2810         }
2811
2812         MapVote_Tick();
2813 }
2814
2815 string GotoMap(string m)
2816 {
2817         if(!MapInfo_CheckMap(m))
2818                 return "The map you chose is not available on this server.";
2819         cvar_set("nextmap", m);
2820         cvar_set("timelimit", "-1");
2821         if(mapvote_initialized || alreadychangedlevel)
2822         {
2823                 if(DoNextMapOverride(0))
2824                         return "Map switch initiated.";
2825                 else
2826                         return "Hm... no. For some reason I like THIS map more.";
2827         }
2828         else
2829                 return "Map switch will happen after scoreboard.";
2830 }
2831
2832
2833 void EndFrame()
2834 {
2835         float altime;
2836         FOR_EACH_REALCLIENT(self)
2837         {
2838                 if(self.classname == "spectator")
2839                 {
2840                         if(self.enemy.typehitsound)
2841                                 self.typehit_time = time;
2842                         else if(self.enemy.hitsound)
2843                                 self.hit_time = time;
2844                 }
2845                 else
2846                 {
2847                         if(self.typehitsound)
2848                                 self.typehit_time = time;
2849                         else if(self.hitsound)
2850                                 self.hit_time = time;
2851                 }
2852         }
2853         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2854         // add 1 frametime because after this, engine SV_Physics
2855         // increases time by a frametime and then networks the frame
2856         // add another frametime because client shows everything with
2857         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2858         // needed!
2859         FOR_EACH_CLIENT(self)
2860         {
2861                 self.hitsound = FALSE;
2862                 self.typehitsound = FALSE;
2863                 antilag_record(self, altime);
2864         }
2865 }
2866
2867
2868 /*
2869  * RedirectionThink:
2870  * returns TRUE if redirecting
2871  */
2872 float redirection_timeout;
2873 float redirection_nextthink;
2874 float RedirectionThink()
2875 {
2876         float clients_found;
2877
2878         if(redirection_target == "")
2879                 return FALSE;
2880
2881         if(!redirection_timeout)
2882         {
2883                 cvar_set("sv_public", "-2");
2884                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2885                 if(redirection_target == "self")
2886                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2887                 else
2888                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2889         }
2890
2891         if(time < redirection_nextthink)
2892                 return TRUE;
2893
2894         redirection_nextthink = time + 1;
2895
2896         clients_found = 0;
2897         FOR_EACH_REALCLIENT(self)
2898         {
2899                 // TODO add timer
2900                 print("Redirecting: sending connect command to ", self.netname, "\n");
2901                 if(redirection_target == "self")
2902                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2903                 else
2904                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2905                 ++clients_found;
2906         }
2907
2908         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2909
2910         if(time > redirection_timeout || clients_found == 0)
2911                 localcmd("\nwait; wait; wait; quit\n");
2912
2913         return TRUE;
2914 }
2915
2916 void TargetMusic_RestoreGame();
2917 void RestoreGame()
2918 {
2919         // Loaded from a save game
2920         // some things then break, so let's work around them...
2921
2922         // Progs DB (capture records)
2923         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2924
2925         // Mapinfo
2926         MapInfo_Shutdown();
2927         MapInfo_Enumerate();
2928         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2929         WeaponStats_Init();
2930
2931         TargetMusic_RestoreGame();
2932 }
2933
2934 void Shutdown()
2935 {
2936         entity e;
2937
2938         gameover = 2;
2939
2940         if(world_initialized > 0)
2941         {
2942                 world_initialized = 0;
2943                 print("Saving persistent data...\n");
2944                 Ban_SaveBans();
2945
2946                 PlayerStats_EndMatch(0);
2947                 FOR_EACH_CLIENT(e)
2948                         PlayerStats_AddGlobalInfo(e);
2949                 PlayerStats_Shutdown();
2950
2951                 if(!cheatcount_total)
2952                 {
2953                         if(autocvar_sv_db_saveasdump)
2954                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2955                         else
2956                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2957                 }
2958                 if(autocvar_developer)
2959                 {
2960                         if(autocvar_sv_db_saveasdump)
2961                                 db_dump(TemporaryDB, "server-temp.db");
2962                         else
2963                                 db_save(TemporaryDB, "server-temp.db");
2964                 }
2965                 CheatShutdown(); // must be after cheatcount check
2966                 db_close(ServerProgsDB);
2967                 db_close(TemporaryDB);
2968                 print("done!\n");
2969                 // tell the bot system the game is ending now
2970                 bot_endgame();
2971
2972                 WeaponStats_Shutdown();
2973                 MapInfo_Shutdown();
2974         }
2975         else if(world_initialized == 0)
2976         {
2977                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2978         }
2979 }