qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2 #include "_all.qh"
   3
   4 #include "anticheat.qh"
   5 #include "antilag.qh"
   6 #include "bot/bot.qh"
   7 #include "campaign.qh"
   8 #include "cheats.qh"
   9 #include "cl_client.qh"
  10 #include "command/common.qh"
  11 #include "command/getreplies.qh"
  12 #include "command/sv_cmd.qh"
  13 #include "command/vote.qh"
  14 #include "g_hook.qh"
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include "mutators/mutators_include.qh"
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "teamplay.qh"
  21 #include "waypointsprites.qh"
  22 #include "weapons/weaponstats.qh"
  23 #include "../common/buffs.qh"
  24 #include "../common/constants.qh"
  25 #include "../common/deathtypes.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/all.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/notifications.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/util.qh"
  34 #include "../common/items/all.qh"
  35 #include "../common/weapons/all.qh"
  36
  37 const float LATENCY_THINKRATE = 10;
  38 .float latency_sum;
  39 .float latency_cnt;
  40 .float latency_time;
  41 entity pingplreport;
  42 void PingPLReport_Think()
  43 {
  44         float delta;
  45         entity e;
  46
  47         delta = 3 / maxclients;
  48         if(delta < sys_frametime)
  49                 delta = 0;
  50         self.nextthink = time + delta;
  51
  52         e = edict_num(self.cnt + 1);
  53         if(IS_REAL_CLIENT(e))
  54         {
  55                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  56                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  74                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = spawn();
  85         pingplreport.classname = "pingplreport";
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if(autocvar_g_running_guns)
 100         {
 101                 default_player_alpha = -1;
 102                 default_weapon_alpha = +1;
 103         }
 104         else if(g_cloaked)
 105         {
 106                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 107                 default_weapon_alpha = default_player_alpha;
 108         }
 109         else
 110         {
 111                 default_player_alpha = autocvar_g_player_alpha;
 112                 if(default_player_alpha == 0)
 113                         default_player_alpha = 1;
 114                 default_weapon_alpha = default_player_alpha;
 115         }
 116 }
 117
 118 void GotoFirstMap()
 119 {
 120         float n;
 121         if(autocvar__sv_init)
 122         {
 123                 // cvar_set("_sv_init", "0");
 124                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 125                 // to this "init" map on a dedicated server will cause no permanent
 126                 // harm
 127                 if(autocvar_g_maplist_shuffle)
 128                         ShuffleMaplist();
 129                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 130                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 131
 132                 MapInfo_Enumerate();
 133                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 134
 135                 if(!DoNextMapOverride(1))
 136                         GotoNextMap(1);
 137
 138                 return;
 139         }
 140
 141         if(time < 5)
 142         {
 143                 self.nextthink = time;
 144         }
 145         else
 146         {
 147                 self.nextthink = time + 1;
 148                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 149         }
 150 }
 151
 152 void cvar_changes_init()
 153 {
 154         float h;
 155         string k, v, d;
 156         float n, i, adding, pureadding;
 157
 158         if(cvar_changes)
 159                 strunzone(cvar_changes);
 160         cvar_changes = string_null;
 161         if(cvar_purechanges)
 162                 strunzone(cvar_purechanges);
 163         cvar_purechanges = string_null;
 164         cvar_purechanges_count = 0;
 165
 166         h = buf_create();
 167         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 168         n = buf_getsize(h);
 169
 170         adding = true;
 171         pureadding = true;
 172
 173         for(i = 0; i < n; ++i)
 174         {
 175                 k = bufstr_get(h, i);
 176
 177 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 178 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 179 #define BADCVAR(p) if(k == p) continue
 180
 181                 // general excludes and namespaces for server admin used cvars
 182                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 183
 184                 // internal
 185                 BADPREFIX("csqc_");
 186                 BADPREFIX("cvar_check_");
 187                 BADCVAR("gamecfg");
 188                 BADCVAR("g_configversion");
 189                 BADCVAR("g_maplist_index");
 190                 BADCVAR("halflifebsp");
 191                 BADCVAR("sv_mapformat_is_quake2");
 192                 BADCVAR("sv_mapformat_is_quake3");
 193                 BADPREFIX("sv_world");
 194
 195                 // client
 196                 BADPREFIX("chase_");
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("scoreboard_");
 200                 BADPREFIX("g_campaign");
 201                 BADPREFIX("g_waypointsprite_");
 202                 BADPREFIX("gl_");
 203                 BADPREFIX("joy");
 204                 BADPREFIX("hud_");
 205                 BADPREFIX("m_");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("snd_");
 212                 BADPREFIX("show");
 213                 BADPREFIX("sensitivity");
 214                 BADPREFIX("userbind");
 215                 BADPREFIX("v_");
 216                 BADPREFIX("vid_");
 217                 BADPREFIX("crosshair");
 218                 BADCVAR("mod_q3bsp_lightmapmergepower");
 219                 BADCVAR("mod_q3bsp_nolightmaps");
 220                 BADCVAR("fov");
 221                 BADCVAR("mastervolume");
 222                 BADCVAR("volume");
 223                 BADCVAR("bgmvolume");
 224
 225                 // private
 226                 BADCVAR("developer");
 227                 BADCVAR("log_dest_udp");
 228                 BADCVAR("net_address");
 229                 BADCVAR("net_address_ipv6");
 230                 BADCVAR("port");
 231                 BADCVAR("savedgamecfg");
 232                 BADCVAR("serverconfig");
 233                 BADCVAR("sv_autoscreenshot");
 234                 BADCVAR("sv_heartbeatperiod");
 235                 BADCVAR("sv_vote_master_password");
 236                 BADCVAR("sys_colortranslation");
 237                 BADCVAR("sys_specialcharactertranslation");
 238                 BADCVAR("timeformat");
 239                 BADCVAR("timestamps");
 240                 BADPREFIX("developer_");
 241                 BADPREFIX("g_ban_");
 242                 BADPREFIX("g_banned_list");
 243                 BADPREFIX("g_chat_flood_");
 244                 BADPREFIX("g_ghost_items");
 245                 BADPREFIX("g_playerstats_");
 246                 BADPREFIX("g_respawn_ghosts");
 247                 BADPREFIX("g_voice_flood_");
 248                 BADPREFIX("log_file");
 249                 BADPREFIX("rcon_");
 250                 BADPREFIX("sv_allowdownloads");
 251                 BADPREFIX("sv_autodemo");
 252                 BADPREFIX("sv_curl_");
 253                 BADPREFIX("sv_eventlog");
 254                 BADPREFIX("sv_logscores_");
 255                 BADPREFIX("sv_master");
 256                 BADPREFIX("sv_weaponstats_");
 257                 BADPREFIX("sv_waypointsprite_");
 258                 BADCVAR("rescan_pending");
 259
 260                 // these can contain player IDs, so better hide
 261                 BADPREFIX("g_forced_team_");
 262
 263                 // mapinfo
 264                 BADCVAR("fraglimit");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_ctf");
 269                 BADCVAR("g_cts");
 270                 BADCVAR("g_dm");
 271                 BADCVAR("g_domination");
 272                 BADCVAR("g_domination_default_teams");
 273                 BADCVAR("g_freezetag");
 274                 BADCVAR("g_freezetag_teams");
 275                 BADCVAR("g_invasion_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_tdm");
 285                 BADCVAR("g_tdm_teams");
 286                 BADCVAR("leadlimit");
 287                 BADCVAR("nextmap");
 288                 BADCVAR("teamplay");
 289                 BADCVAR("timelimit");
 290
 291                 // long
 292                 BADCVAR("hostname");
 293                 BADCVAR("g_maplist");
 294                 BADCVAR("g_maplist_mostrecent");
 295                 BADCVAR("sv_motd");
 296
 297                 v = cvar_string(k);
 298                 d = cvar_defstring(k);
 299                 if(v == d)
 300                         continue;
 301
 302                 if(adding)
 303                 {
 304                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 305                         if(strlen(cvar_changes) > 16384)
 306                         {
 307                                 cvar_changes = "// too many settings have been changed to show them here\n";
 308                                 adding = 0;
 309                         }
 310                 }
 311
 312                 // now check if the changes are actually gameplay relevant
 313
 314                 // does nothing visible
 315                 BADCVAR("captureleadlimit_override");
 316                 BADCVAR("g_balance_kill_delay");
 317                 BADCVAR("g_ca_point_limit");
 318                 BADCVAR("g_ca_point_leadlimit");
 319                 BADCVAR("g_ctf_captimerecord_always");
 320                 BADCVAR("g_ctf_flag_glowtrails");
 321                 BADCVAR("g_ctf_flag_pickup_verbosename");
 322                 BADCVAR("g_domination_point_leadlimit");
 323                 BADCVAR("g_forced_respawn");
 324                 BADCVAR("g_freezetag_point_limit");
 325                 BADCVAR("g_freezetag_point_leadlimit");
 326                 BADCVAR("g_keyhunt_point_leadlimit");
 327                 BADPREFIX("g_mod_");
 328                 BADCVAR("g_invasion_point_limit");
 329                 BADCVAR("g_nexball_goalleadlimit");
 330                 BADCVAR("g_tdm_point_limit");
 331                 BADCVAR("g_tdm_point_leadlimit");
 332                 BADCVAR("leadlimit_and_fraglimit");
 333                 BADCVAR("leadlimit_override");
 334                 BADCVAR("pausable");
 335                 BADCVAR("sv_allow_fullbright");
 336                 BADCVAR("sv_checkforpacketsduringsleep");
 337                 BADCVAR("sv_fraginfo");
 338                 BADCVAR("sv_timeout");
 339                 BADPREFIX("sv_timeout_");
 340                 BADPREFIX("crypto_");
 341                 BADPREFIX("g_chat_");
 342                 BADPREFIX("g_ctf_captimerecord_");
 343                 BADPREFIX("g_maplist_votable_");
 344                 BADPREFIX("net_");
 345                 BADPREFIX("prvm_");
 346                 BADPREFIX("skill_");
 347                 BADPREFIX("sv_cullentities_");
 348                 BADPREFIX("sv_fraginfo_");
 349                 BADPREFIX("sv_maxidle_");
 350                 BADPREFIX("sv_vote_");
 351                 BADPREFIX("timelimit_");
 352                 BADCVAR("gameversion");
 353                 BADPREFIX("gameversion_");
 354                 BADCVAR("sv_namechangetimer");
 355
 356                 // allowed changes to server admins (please sync this to server.cfg)
 357                 // vi commands:
 358                 //   :/"impure"/,$d
 359                 //   :g!,^\/\/[^ /],d
 360                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 361                 //   :%!sort
 362                 // yes, this does contain some redundant stuff, don't really care
 363                 BADCVAR("bot_config_file");
 364                 BADCVAR("bot_number");
 365                 BADCVAR("bot_prefix");
 366                 BADCVAR("bot_suffix");
 367                 BADCVAR("capturelimit_override");
 368                 BADCVAR("fraglimit_override");
 369                 BADCVAR("gametype");
 370                 BADCVAR("g_antilag");
 371                 BADCVAR("g_balance_teams");
 372                 BADCVAR("g_balance_teams_prevent_imbalance");
 373                 BADCVAR("g_balance_teams_scorefactor");
 374                 BADCVAR("g_ban_sync_trusted_servers");
 375                 BADCVAR("g_ban_sync_uri");
 376                 BADCVAR("g_ca_teams_override");
 377                 BADCVAR("g_ctf_ignore_frags");
 378                 BADCVAR("g_domination_point_limit");
 379                 BADCVAR("g_domination_teams_override");
 380                 BADCVAR("g_freezetag_teams_override");
 381                 BADCVAR("g_friendlyfire");
 382                 BADCVAR("g_fullbrightitems");
 383                 BADCVAR("g_fullbrightplayers");
 384                 BADCVAR("g_keyhunt_point_limit");
 385                 BADCVAR("g_keyhunt_teams_override");
 386                 BADCVAR("g_lms_lives_override");
 387                 BADCVAR("g_maplist");
 388                 BADCVAR("g_maplist_check_waypoints");
 389                 BADCVAR("g_maplist_mostrecent_count");
 390                 BADCVAR("g_maplist_shuffle");
 391                 BADCVAR("g_maplist_votable");
 392                 BADCVAR("g_maplist_votable_abstain");
 393                 BADCVAR("g_maplist_votable_nodetail");
 394                 BADCVAR("g_maplist_votable_suggestions");
 395                 BADCVAR("g_maxplayers");
 396                 BADCVAR("g_mirrordamage");
 397                 BADCVAR("g_nexball_goallimit");
 398                 BADCVAR("g_powerups");
 399                 BADCVAR("g_start_delay");
 400                 BADCVAR("g_tdm_teams_override");
 401                 BADCVAR("g_warmup");
 402                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 403                 BADCVAR("hostname");
 404                 BADCVAR("log_file");
 405                 BADCVAR("maxplayers");
 406                 BADCVAR("minplayers");
 407                 BADCVAR("net_address");
 408                 BADCVAR("port");
 409                 BADCVAR("rcon_password");
 410                 BADCVAR("rcon_restricted_commands");
 411                 BADCVAR("rcon_restricted_password");
 412                 BADCVAR("skill");
 413                 BADCVAR("sv_adminnick");
 414                 BADCVAR("sv_autoscreenshot");
 415                 BADCVAR("sv_autotaunt");
 416                 BADCVAR("sv_curl_defaulturl");
 417                 BADCVAR("sv_defaultcharacter");
 418                 BADCVAR("sv_defaultplayercolors");
 419                 BADCVAR("sv_defaultplayermodel");
 420                 BADCVAR("sv_defaultplayerskin");
 421                 BADCVAR("sv_maxidle");
 422                 BADCVAR("sv_maxrate");
 423                 BADCVAR("sv_motd");
 424                 BADCVAR("sv_public");
 425                 BADCVAR("sv_ready_restart");
 426                 BADCVAR("sv_status_privacy");
 427                 BADCVAR("sv_taunt");
 428                 BADCVAR("sv_vote_call");
 429                 BADCVAR("sv_vote_commands");
 430                 BADCVAR("sv_vote_majority_factor");
 431                 BADCVAR("sv_vote_master");
 432                 BADCVAR("sv_vote_master_commands");
 433                 BADCVAR("sv_vote_master_password");
 434                 BADCVAR("sv_vote_simple_majority_factor");
 435                 BADCVAR("teamplay_mode");
 436                 BADCVAR("timelimit_override");
 437                 BADCVAR("g_spawnshieldtime");
 438                 BADPREFIX("g_warmup_");
 439                 BADPREFIX("sv_ready_restart_");
 440
 441                 // mutators that announce themselves properly to the server browser
 442                 BADCVAR("g_instagib");
 443                 BADCVAR("g_new_toys");
 444                 BADCVAR("g_nix");
 445                 BADCVAR("g_grappling_hook");
 446                 BADCVAR("g_jetpack");
 447
 448 #undef BADPREFIX
 449 #undef BADCVAR
 450
 451                 if(pureadding)
 452                 {
 453                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 454                         if(strlen(cvar_purechanges) > 16384)
 455                         {
 456                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 457                                 pureadding = 0;
 458                         }
 459                 }
 460                 ++cvar_purechanges_count;
 461                 // WARNING: this variable is used for the server list
 462                 // NEVER dare to skip this code!
 463                 // Hacks to intentionally appearing as "pure server" even though you DO have
 464                 // modified settings may be punished by removal from the server list.
 465                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 466                 // though.
 467         }
 468         buf_del(h);
 469         if(cvar_changes == "")
 470                 cvar_changes = "// this server runs at default server settings\n";
 471         else
 472                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 473         cvar_changes = strzone(cvar_changes);
 474         if(cvar_purechanges == "")
 475                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 476         else
 477                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 478         cvar_purechanges = strzone(cvar_purechanges);
 479 }
 480
 481 void detect_maptype()
 482 {
 483 #if 0
 484         vector o, v;
 485         float i;
 486
 487         for (;;)
 488         {
 489                 o = world.mins;
 490                 o.x += random() * (world.maxs.x - world.mins.x);
 491                 o.y += random() * (world.maxs.y - world.mins.y);
 492                 o.z += random() * (world.maxs.z - world.mins.z);
 493
 494                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 495                 if(trace_fraction == 1)
 496                         continue;
 497
 498                 v = trace_endpos;
 499
 500                 for(i = 0; i < 64; i += 4)
 501                 {
 502                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 503         if(trace_fraction == 1)
 504                 continue;
 505                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 506                 }
 507
 508                 break;
 509         }
 510 #endif
 511 }
 512
 513 entity randomseed;
 514 float RandomSeed_Send(entity to, int sf)
 515 {
 516         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 517         WriteShort(MSG_ENTITY, self.cnt);
 518         return true;
 519 }
 520 void RandomSeed_Think()
 521 {
 522         self.cnt = bound(0, floor(random() * 65536), 65535);
 523         self.nextthink = time + 5;
 524
 525         self.SendFlags |= 1;
 526 }
 527 void RandomSeed_Spawn()
 528 {
 529         randomseed = spawn();
 530         randomseed.think = RandomSeed_Think;
 531         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 532
 533         entity oldself;
 534         oldself = self;
 535         self = randomseed;
 536         self.think(); // sets random seed and nextthink
 537         self = oldself;
 538 }
 539
 540 void spawnfunc___init_dedicated_server(void)
 541 {
 542         // handler for _init/_init map (only for dedicated server initialization)
 543
 544         world_initialized = -1; // don't complain
 545         cvar = cvar_normal;
 546         cvar_string = cvar_string_normal;
 547         cvar_set = cvar_set_normal;
 548
 549         remove = remove_unsafely;
 550
 551         entity e;
 552         e = spawn();
 553         e.think = GotoFirstMap;
 554         e.nextthink = time; // this is usually 1 at this point
 555
 556         e = spawn();
 557         e.classname = "info_player_deathmatch"; // safeguard against player joining
 558
 559         self.classname = "worldspawn"; // safeguard against various stuff ;)
 560
 561         // needs to be done so early because of the constants they create
 562         static_init();
 563         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 564         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 565         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 566
 567         MapInfo_Enumerate();
 568         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 569 }
 570
 571 void Map_MarkAsRecent(string m);
 572 float world_already_spawned;
 573 void Nagger_Init();
 574 void Item_ItemsTime_Init();
 575 void ClientInit_Spawn();
 576 void WeaponStats_Init();
 577 void WeaponStats_Shutdown();
 578 void Physics_AddStats();
 579 void spawnfunc_worldspawn (void)
 580 {
 581         float fd, l, j, n;
 582         string s;
 583
 584         cvar = cvar_normal;
 585         cvar_string = cvar_string_normal;
 586         cvar_set = cvar_set_normal;
 587
 588         if(world_already_spawned)
 589                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 590         world_already_spawned = true;
 591
 592         remove = remove_safely; // during spawning, watch what you remove!
 593
 594         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 595
 596         compressShortVector_init();
 597
 598         entity head;
 599         head = nextent(world);
 600         maxclients = 0;
 601         while(head)
 602         {
 603                 ++maxclients;
 604                 head = nextent(head);
 605         }
 606
 607         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 608
 609         // needs to be done so early because of the constants they create
 610         static_init();
 611         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 612         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 613         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 614
 615         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 616
 617         TemporaryDB = db_create();
 618
 619         // 0 normal
 620         lightstyle(0, "m");
 621
 622         // 1 FLICKER (first variety)
 623         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 624
 625         // 2 SLOW STRONG PULSE
 626         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 627
 628         // 3 CANDLE (first variety)
 629         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 630
 631         // 4 FAST STROBE
 632         lightstyle(4, "mamamamamama");
 633
 634         // 5 GENTLE PULSE 1
 635         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 636
 637         // 6 FLICKER (second variety)
 638         lightstyle(6, "nmonqnmomnmomomno");
 639
 640         // 7 CANDLE (second variety)
 641         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 642
 643         // 8 CANDLE (third variety)
 644         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 645
 646         // 9 SLOW STROBE (fourth variety)
 647         lightstyle(9, "aaaaaaaazzzzzzzz");
 648
 649         // 10 FLUORESCENT FLICKER
 650         lightstyle(10, "mmamammmmammamamaaamammma");
 651
 652         // 11 SLOW PULSE NOT FADE TO BLACK
 653         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 654
 655         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 656
 657         // 63 testing
 658         lightstyle(63, "a");
 659
 660         if(autocvar_g_campaign)
 661                 CampaignPreInit();
 662
 663         Map_MarkAsRecent(mapname);
 664
 665         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 666
 667         precache_model ("null"); // we need this one before InitGameplayMode
 668         InitGameplayMode();
 669         readlevelcvars();
 670         GrappleHookInit();
 671
 672         player_count = 0;
 673         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 674         if(bot_waypoints_for_items == 1)
 675                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 676                         bot_waypoints_for_items = 0;
 677
 678         precache();
 679
 680         WaypointSprite_Init();
 681
 682         GameLogInit(); // prepare everything
 683         // NOTE for matchid:
 684         // changing the logic generating it is okay. But:
 685         // it HAS to stay <= 64 chars
 686         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 687         if(autocvar_sv_eventlog)
 688         {
 689                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 690                 matchid = strzone(s);
 691
 692                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 693                 s = ":gameinfo:mutators:LIST";
 694
 695                 ret_string = s;
 696                 MUTATOR_CALLHOOK(BuildMutatorsString);
 697                 s = ret_string;
 698
 699                 // simple, probably not good in the mutator system
 700                 if(autocvar_g_grappling_hook)
 701                         s = strcat(s, ":grappling_hook");
 702
 703                 // initialiation stuff, not good in the mutator system
 704                 if(!autocvar_g_use_ammunition)
 705                         s = strcat(s, ":no_use_ammunition");
 706
 707                 // initialiation stuff, not good in the mutator system
 708                 if(autocvar_g_pickup_items == 0)
 709                         s = strcat(s, ":no_pickup_items");
 710                 if(autocvar_g_pickup_items > 0)
 711                         s = strcat(s, ":pickup_items");
 712
 713                 // initialiation stuff, not good in the mutator system
 714                 if(autocvar_g_weaponarena != "0")
 715                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 716
 717                 // TODO to mutator system
 718                 if(autocvar_g_norecoil)
 719                         s = strcat(s, ":norecoil");
 720
 721                 // TODO to mutator system
 722                 if(autocvar_g_powerups == 0)
 723                         s = strcat(s, ":no_powerups");
 724                 if(autocvar_g_powerups > 0)
 725                         s = strcat(s, ":powerups");
 726
 727                 GameLogEcho(s);
 728                 GameLogEcho(":gameinfo:end");
 729         }
 730         else
 731                 matchid = strzone(ftos(random()));
 732
 733         cvar_set("nextmap", "");
 734
 735         SetDefaultAlpha();
 736
 737         if(autocvar_g_campaign)
 738                 CampaignPostInit();
 739
 740         Ban_LoadBans();
 741
 742         MapInfo_Enumerate();
 743         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 744
 745         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 746         {
 747                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 748                 if(fd != -1)
 749                 {
 750                         while((s = fgets(fd)))
 751                         {
 752                                 l = tokenize_console(s);
 753                                 if(l < 2)
 754                                         continue;
 755                                 if(argv(0) == "cd")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  cdtrack ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) == "fog")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 763                                         print("  \"fog\" \"", s, "\"\n");
 764                                 }
 765                                 else if(argv(0) == "set")
 766                                 {
 767                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 768                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 769                                 }
 770                                 else if(argv(0) != "//")
 771                                 {
 772                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 773                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 774                                 }
 775                         }
 776                         fclose(fd);
 777                 }
 778         }
 779
 780         WeaponStats_Init();
 781
 782         WepSet_AddStat();
 783         WepSet_AddStat_InMap();
 784         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 785         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 786         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 787         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 788         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 789         Nagger_Init();
 790
 791         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 792         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 793         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 794         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 795         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 796         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 797         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 798         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 799         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 800         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 801         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 802         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 803         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 804         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 805         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 806
 807         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 808         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 809
 810         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 811
 812         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 813
 814         // items time
 815         addstat(STAT_ARMOR_LARGE_TIME, AS_FLOAT, item_armor_large_time);
 816         addstat(STAT_HEALTH_MEGA_TIME, AS_FLOAT, item_health_mega_time);
 817         addstat(STAT_INVISIBLE_TIME, AS_FLOAT, item_invisible_time);
 818         addstat(STAT_SPEED_TIME, AS_FLOAT, item_speed_time);
 819         addstat(STAT_EXTRALIFE_TIME, AS_FLOAT, item_extralife_time);
 820         addstat(STAT_STRENGTH_TIME, AS_FLOAT, item_strength_time);
 821         addstat(STAT_SHIELD_TIME, AS_FLOAT, item_shield_time);
 822         addstat(STAT_FUELREGEN_TIME, AS_FLOAT, item_fuelregen_time);
 823         addstat(STAT_JETPACK_TIME, AS_FLOAT, item_jetpack_time);
 824         addstat(STAT_SUPERWEAPONS_TIME, AS_FLOAT, item_superweapons_time);
 825         Item_ItemsTime_Init();
 826
 827         // freeze attacks
 828         addstat(STAT_FROZEN, AS_INT, frozen);
 829         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 830
 831         // physics
 832         Physics_AddStats();
 833
 834         // new properties
 835         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 836         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 837         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 838         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 839         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 840         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 841         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 842         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 843         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 844         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 845         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 846         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 847         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 848         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 849         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 850         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 851         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 852         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 853         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 854
 855         // secrets
 856         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 857         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 858
 859         // monsters
 860         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 861         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 862
 863         // misc
 864         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 865
 866         next_pingtime = time + 5;
 867
 868         detect_maptype();
 869
 870         // set up information replies for clients and server to use
 871         maplist_reply = strzone(getmaplist());
 872         lsmaps_reply = strzone(getlsmaps());
 873         monsterlist_reply = strzone(getmonsterlist());
 874         for(int i = 0; i < 10; ++i)
 875         {
 876                 s = getrecords(i);
 877                 if (s)
 878                         records_reply[i] = strzone(s);
 879         }
 880         ladder_reply = strzone(getladder());
 881         rankings_reply = strzone(getrankings());
 882
 883         // begin other init
 884         ClientInit_Spawn();
 885         RandomSeed_Spawn();
 886         PingPLReport_Spawn();
 887
 888         CheatInit();
 889
 890         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 891
 892         // fill sv_curl_serverpackages from .serverpackage files
 893         if(autocvar_sv_curl_serverpackages_auto)
 894         {
 895                 s = "";
 896                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 897                 for(int i = 0; i < n; ++i)
 898                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 899                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 900                                 s = strcat(s, " ", argv(i));
 901                 fd = search_begin("*-serverpackage.txt", true, false);
 902                 if(fd >= 0)
 903                 {
 904                         j = search_getsize(fd);
 905                         for(int i = 0; i < j; ++i)
 906                                 s = strcat(s, " ", search_getfilename(fd, i));
 907                         search_end(fd);
 908                 }
 909                 fd = search_begin("*.serverpackage", true, false);
 910                 if(fd >= 0)
 911                 {
 912                         j = search_getsize(fd);
 913                         for(int i = 0; i < j; ++i)
 914                                 s = strcat(s, " ", search_getfilename(fd, i));
 915                         search_end(fd);
 916                 }
 917                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 918         }
 919
 920         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 921         modname = "Xonotic";
 922         // physics/balance/config changes that count as mod
 923         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 924                 modname = cvar_string("g_mod_physics");
 925         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 926                 modname = cvar_string("g_mod_balance");
 927         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 928                 modname = cvar_string("g_mod_config");
 929         // extra mutators that deserve to count as mod
 930         MUTATOR_CALLHOOK(SetModname);
 931
 932         // save it for later
 933         modname = strzone(modname);
 934
 935         WinningConditionHelper(); // set worldstatus
 936
 937         world_initialized = 1;
 938 }
 939
 940 void spawnfunc_light (void)
 941 {
 942         //makestatic (self); // Who the f___ did that?
 943         remove(self);
 944 }
 945
 946 string GetGametype()
 947 {
 948         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 949 }
 950
 951 string GetMapname()
 952 {
 953         return mapname;
 954 }
 955
 956 float Map_Count, Map_Current;
 957 string Map_Current_Name;
 958
 959 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 960 float GetMaplistPosition()
 961 {
 962         float pos, idx;
 963         string map;
 964
 965         map = GetMapname();
 966         idx = autocvar_g_maplist_index;
 967
 968         if(idx >= 0)
 969                 if(idx < Map_Count)
 970                         if(map == argv(idx))
 971                                 return idx;
 972
 973         for(pos = 0; pos < Map_Count; ++pos)
 974                 if(map == argv(pos))
 975                         return pos;
 976
 977         // resume normal maplist rotation if current map is not in g_maplist
 978         return idx;
 979 }
 980
 981 float MapHasRightSize(string map)
 982 {
 983         float fh;
 984         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 985         if(autocvar_g_maplist_check_waypoints)
 986         {
 987                 dprint("checkwp "); dprint(map);
 988                 if(!fexists(strcat("maps/", map, ".waypoints")))
 989                 {
 990                         dprint(": no waypoints\n");
 991                         return false;
 992                 }
 993                 dprint(": has waypoints\n");
 994         }
 995
 996         // open map size restriction file
 997         dprint("opensize "); dprint(map);
 998         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 999         if(fh >= 0)
1000         {
1001                 float mapmin, mapmax;
1002                 dprint(": ok, ");
1003                 mapmin = stof(fgets(fh));
1004                 mapmax = stof(fgets(fh));
1005                 fclose(fh);
1006                 if(player_count < mapmin)
1007                 {
1008                         dprint("not enough\n");
1009                         return false;
1010                 }
1011                 if(player_count > mapmax)
1012                 {
1013                         dprint("too many\n");
1014                         return false;
1015                 }
1016                 dprint("right size\n");
1017                 return true;
1018         }
1019         dprint(": not found\n");
1020         return true;
1021 }
1022
1023 string Map_Filename(float position)
1024 {
1025         return strcat("maps/", argv(position), ".bsp");
1026 }
1027
1028 string strwords(string s, float w)
1029 {
1030         float endpos;
1031         for(endpos = 0; w && endpos >= 0; --w)
1032                 endpos = strstrofs(s, " ", endpos + 1);
1033         if(endpos < 0)
1034                 return s;
1035         else
1036                 return substring(s, 0, endpos);
1037 }
1038
1039 float strhasword(string s, string w)
1040 {
1041         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1042 }
1043
1044 void Map_MarkAsRecent(string m)
1045 {
1046         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1047 }
1048
1049 float Map_IsRecent(string m)
1050 {
1051         return strhasword(autocvar_g_maplist_mostrecent, m);
1052 }
1053
1054 float Map_Check(float position, float pass)
1055 {
1056         string filename;
1057         string map_next;
1058         map_next = argv(position);
1059         if(pass <= 1)
1060         {
1061                 if(Map_IsRecent(map_next))
1062                         return 0;
1063         }
1064         filename = Map_Filename(position);
1065         if(MapInfo_CheckMap(map_next))
1066         {
1067                 if(pass == 2)
1068                         return 1;
1069                 if(MapHasRightSize(map_next))
1070                         return 1;
1071                 return 0;
1072         }
1073         else
1074                 dprint( "Couldn't select '", filename, "'..\n" );
1075
1076         return 0;
1077 }
1078
1079 void Map_Goto_SetStr(string nextmapname)
1080 {
1081         if(getmapname_stored != "")
1082                 strunzone(getmapname_stored);
1083         if(nextmapname == "")
1084                 getmapname_stored = "";
1085         else
1086                 getmapname_stored = strzone(nextmapname);
1087 }
1088
1089 void Map_Goto_SetFloat(float position)
1090 {
1091         cvar_set("g_maplist_index", ftos(position));
1092         Map_Goto_SetStr(argv(position));
1093 }
1094
1095 void Map_Goto(float reinit)
1096 {
1097         MapInfo_LoadMap(getmapname_stored, reinit);
1098 }
1099
1100 // return codes of map selectors:
1101 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1102 //   -2 = permanent failure
1103 float() MaplistMethod_Iterate = // usual method
1104 {
1105         float pass, i;
1106
1107         dprint("Trying MaplistMethod_Iterate\n");
1108
1109         for(pass = 1; pass <= 2; ++pass)
1110         {
1111                 for(i = 1; i < Map_Count; ++i)
1112                 {
1113                         float mapindex;
1114                         mapindex = (i + Map_Current) % Map_Count;
1115                         if(Map_Check(mapindex, pass))
1116                                 return mapindex;
1117                 }
1118         }
1119         return -1;
1120 }
1121
1122 float() MaplistMethod_Repeat = // fallback method
1123 {
1124         dprint("Trying MaplistMethod_Repeat\n");
1125
1126         if(Map_Check(Map_Current, 2))
1127                 return Map_Current;
1128         return -2;
1129 }
1130
1131 float() MaplistMethod_Random = // random map selection
1132 {
1133         float i, imax;
1134
1135         dprint("Trying MaplistMethod_Random\n");
1136
1137         imax = 42;
1138
1139         for(i = 0; i <= imax; ++i)
1140         {
1141                 float mapindex;
1142                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1143                 if(Map_Check(mapindex, 1))
1144                         return mapindex;
1145         }
1146         return -1;
1147 }
1148
1149 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1150 // the exponent sets a bias on the map selection:
1151 // the higher the exponent, the less likely "shortly repeated" same maps are
1152 {
1153         float i, j, imax, insertpos;
1154
1155         dprint("Trying MaplistMethod_Shuffle\n");
1156
1157         imax = 42;
1158
1159         for(i = 0; i <= imax; ++i)
1160         {
1161                 string newlist;
1162
1163                 // now reinsert this at another position
1164                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1165                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1166                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1167                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1168
1169                 // insert the current map there
1170                 newlist = "";
1171                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1172                         newlist = strcat(newlist, " ", argv(j));
1173                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1174                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1175                         newlist = strcat(newlist, " ", argv(j));
1176                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1177                 cvar_set("g_maplist", newlist);
1178                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1179
1180                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1181                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1182                 if(Map_Check(Map_Current, 1))
1183                         return Map_Current;
1184         }
1185         return -1;
1186 }
1187
1188 void Maplist_Init()
1189 {
1190         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1191         float i;
1192         for (i = 0; i < Map_Count; ++i)
1193                 if (Map_Check(i, 2))
1194                         break;
1195         if (i == Map_Count)
1196         {
1197                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1198                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1199                 if(autocvar_g_maplist_shuffle)
1200                         ShuffleMaplist();
1201                 localcmd("\nmenu_cmd sync\n");
1202                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1203         }
1204         if(Map_Count == 0)
1205                 error("empty maplist, cannot select a new map");
1206         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1207
1208         if(Map_Current_Name)
1209                 strunzone(Map_Current_Name);
1210         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1211         // this may or may not be correct, but who cares, in the worst case a map
1212         // isn't chosen in the first pass that should have been
1213 }
1214
1215 string GetNextMap()
1216 {
1217         float nextMap;
1218
1219         Maplist_Init();
1220         nextMap = -1;
1221
1222         if(nextMap == -1)
1223                 if(autocvar_g_maplist_shuffle > 0)
1224                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1225
1226         if(nextMap == -1)
1227                 if(autocvar_g_maplist_selectrandom)
1228                         nextMap = MaplistMethod_Random();
1229
1230         if(nextMap == -1)
1231                 nextMap = MaplistMethod_Iterate();
1232
1233         if(nextMap == -1)
1234                 nextMap = MaplistMethod_Repeat();
1235
1236         if(nextMap >= 0)
1237         {
1238                 Map_Goto_SetFloat(nextMap);
1239                 return getmapname_stored;
1240         }
1241
1242         return "";
1243 }
1244
1245 float DoNextMapOverride(float reinit)
1246 {
1247         if(autocvar_g_campaign)
1248         {
1249                 CampaignPostIntermission();
1250                 alreadychangedlevel = true;
1251                 return true;
1252         }
1253         if(autocvar_quit_when_empty)
1254         {
1255                 if(player_count <= currentbots)
1256                 {
1257                         localcmd("quit\n");
1258                         alreadychangedlevel = true;
1259                         return true;
1260                 }
1261         }
1262         if(autocvar_quit_and_redirect != "")
1263         {
1264                 redirection_target = strzone(autocvar_quit_and_redirect);
1265                 alreadychangedlevel = true;
1266                 return true;
1267         }
1268         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1269         {
1270                 localcmd("restart\n");
1271                 alreadychangedlevel = true;
1272                 return true;
1273         }
1274         if(autocvar_nextmap != "")
1275         {
1276                 string m;
1277                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1278                 cvar_set("nextmap",m);
1279
1280                 if(!m || gametypevote)
1281                         return false;
1282                 if(autocvar_sv_vote_gametype)
1283                 {
1284                         Map_Goto_SetStr(m);
1285                         return false;
1286                 }
1287
1288                 if(MapInfo_CheckMap(m))
1289                 {
1290                         Map_Goto_SetStr(m);
1291                         Map_Goto(reinit);
1292                         alreadychangedlevel = true;
1293                         return true;
1294                 }
1295         }
1296         if(!reinit && autocvar_lastlevel)
1297         {
1298                 cvar_settemp_restore();
1299                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1300                 alreadychangedlevel = true;
1301                 return true;
1302         }
1303         return false;
1304 }
1305
1306 void GotoNextMap(float reinit)
1307 {
1308         //string nextmap;
1309         //float n, nummaps;
1310         //string s;
1311         if (alreadychangedlevel)
1312                 return;
1313         alreadychangedlevel = true;
1314
1315         string nextMap;
1316
1317         nextMap = GetNextMap();
1318         if(nextMap == "")
1319                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1320         Map_Goto(reinit);
1321 }
1322
1323
1324 /*
1325 ============
1326 IntermissionThink
1327
1328 When the player presses attack or jump, change to the next level
1329 ============
1330 */
1331 .float autoscreenshot;
1332 void IntermissionThink()
1333 {
1334         FixIntermissionClient(self);
1335
1336         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1337         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1338
1339         if( (server_screenshot || client_screenshot)
1340                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1341         {
1342                 self.autoscreenshot = -1;
1343                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1344                 return;
1345         }
1346
1347         if (time < intermission_exittime)
1348                 return;
1349
1350         if(!mapvote_initialized)
1351                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1352                         return;
1353
1354         MapVote_Start();
1355 }
1356
1357 /*
1358 ============
1359 FindIntermission
1360
1361 Returns the entity to view from
1362 ============
1363 */
1364 /*
1365 entity FindIntermission()
1366 {
1367         local   entity spot;
1368         local   float cyc;
1369
1370 // look for info_intermission first
1371         spot = find (world, classname, "info_intermission");
1372         if (spot)
1373         {       // pick a random one
1374                 cyc = random() * 4;
1375                 while (cyc > 1)
1376                 {
1377                         spot = find (spot, classname, "info_intermission");
1378                         if (!spot)
1379                                 spot = find (spot, classname, "info_intermission");
1380                         cyc = cyc - 1;
1381                 }
1382                 return spot;
1383         }
1384
1385 // then look for the start position
1386         spot = find (world, classname, "info_player_start");
1387         if (spot)
1388                 return spot;
1389
1390 // testinfo_player_start is only found in regioned levels
1391         spot = find (world, classname, "testplayerstart");
1392         if (spot)
1393                 return spot;
1394
1395 // then look for the start position
1396         spot = find (world, classname, "info_player_deathmatch");
1397         if (spot)
1398                 return spot;
1399
1400         //objerror ("FindIntermission: no spot");
1401         return world;
1402 }
1403 */
1404
1405 /*
1406 ===============================================================================
1407
1408 RULES
1409
1410 ===============================================================================
1411 */
1412
1413 void DumpStats(float final)
1414 {
1415         float file;
1416         string s;
1417         float to_console;
1418         float to_eventlog;
1419         float to_file;
1420         float i;
1421
1422         to_console = autocvar_sv_logscores_console;
1423         to_eventlog = autocvar_sv_eventlog;
1424         to_file = autocvar_sv_logscores_file;
1425
1426         if(!final)
1427         {
1428                 to_console = true; // always print printstats replies
1429                 to_eventlog = false; // but never print them to the event log
1430         }
1431
1432         if(to_eventlog)
1433                 if(autocvar_sv_eventlog_console)
1434                         to_console = false; // otherwise we get the output twice
1435
1436         if(final)
1437                 s = ":scores:";
1438         else
1439                 s = ":status:";
1440         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1441
1442         if(to_console)
1443                 print(s, "\n");
1444         if(to_eventlog)
1445                 GameLogEcho(s);
1446
1447         file = -1;
1448         if(to_file)
1449         {
1450                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1451                 if(file == -1)
1452                         to_file = false;
1453                 else
1454                         fputs(file, strcat(s, "\n"));
1455         }
1456
1457         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1458         if(to_console)
1459                 print(s, "\n");
1460         if(to_eventlog)
1461                 GameLogEcho(s);
1462         if(to_file)
1463                 fputs(file, strcat(s, "\n"));
1464
1465         FOR_EACH_CLIENT(other)
1466         {
1467                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1468                 {
1469                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1470                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1471                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1472                                 s = strcat(s, ftos(other.team), ":");
1473                         else
1474                                 s = strcat(s, "spectator:");
1475
1476                         if(to_console)
1477                                 print(s, other.netname, "\n");
1478                         if(to_eventlog)
1479                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1480                         if(to_file)
1481                                 fputs(file, strcat(s, other.netname, "\n"));
1482                 }
1483         }
1484
1485         if(teamplay)
1486         {
1487                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1488                 if(to_console)
1489                         print(s, "\n");
1490                 if(to_eventlog)
1491                         GameLogEcho(s);
1492                 if(to_file)
1493                         fputs(file, strcat(s, "\n"));
1494
1495                 for(i = 1; i < 16; ++i)
1496                 {
1497                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1498                         s = strcat(s, ":", ftos(i));
1499                         if(to_console)
1500                                 print(s, "\n");
1501                         if(to_eventlog)
1502                                 GameLogEcho(s);
1503                         if(to_file)
1504                                 fputs(file, strcat(s, "\n"));
1505                 }
1506         }
1507
1508         if(to_console)
1509                 print(":end\n");
1510         if(to_eventlog)
1511                 GameLogEcho(":end");
1512         if(to_file)
1513         {
1514                 fputs(file, ":end\n");
1515                 fclose(file);
1516         }
1517 }
1518
1519 void FixIntermissionClient(entity e)
1520 {
1521         string s;
1522         if(!e.autoscreenshot) // initial call
1523         {
1524                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1525                 e.health = -2342;
1526                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1527                 e.solid = SOLID_NOT;
1528                 e.movetype = MOVETYPE_NONE;
1529                 e.takedamage = DAMAGE_NO;
1530                 if(e.weaponentity)
1531                 {
1532                         e.weaponentity.effects = EF_NODRAW;
1533                         if (e.weaponentity.weaponentity)
1534                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1535                 }
1536                 if(IS_REAL_CLIENT(e))
1537                 {
1538                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1539                         s = autocvar_sv_intermission_cdtrack;
1540                         if(s != "")
1541                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1542                         msg_entity = e;
1543                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1544                 }
1545         }
1546 }
1547
1548 /*
1549 go to the next level for deathmatch
1550 only called if a time or frag limit has expired
1551 */
1552 void NextLevel()
1553 {
1554         gameover = true;
1555
1556         intermission_running = 1;
1557
1558 // enforce a wait time before allowing changelevel
1559         if(player_count > 0)
1560                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1561         else
1562                 intermission_exittime = -1;
1563
1564         /*
1565         WriteByte (MSG_ALL, SVC_CDTRACK);
1566         WriteByte (MSG_ALL, 3);
1567         WriteByte (MSG_ALL, 3);
1568         // done in FixIntermission
1569         */
1570
1571         //pos = FindIntermission ();
1572
1573         VoteReset();
1574
1575         DumpStats(true);
1576
1577         // send statistics
1578         PlayerStats_GameReport(true);
1579         WeaponStats_Shutdown();
1580
1581         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1582
1583         if(autocvar_sv_eventlog)
1584                 GameLogEcho(":gameover");
1585
1586         GameLogClose();
1587
1588         FOR_EACH_PLAYER(other) {
1589                 FixIntermissionClient(other);
1590                 if(other.winning)
1591                         bprint(other.netname, " ^7wins.\n");
1592         }
1593
1594         if(autocvar_g_campaign)
1595                 CampaignPreIntermission();
1596
1597         MUTATOR_CALLHOOK(MatchEnd);
1598
1599         localcmd("\nsv_hook_gameend\n");
1600 }
1601
1602 /*
1603 ============
1604 CheckRules_Player
1605
1606 Exit deathmatch games upon conditions
1607 ============
1608 */
1609 void CheckRules_Player()
1610 {
1611         if (gameover)   // someone else quit the game already
1612                 return;
1613
1614         if(self.deadflag == DEAD_NO)
1615                 self.play_time += frametime;
1616
1617         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1618         //   (div0: and that in CheckRules_World please)
1619 }
1620
1621
1622 float InitiateSuddenDeath()
1623 {
1624         // Check first whether normal overtimes could be added before initiating suddendeath mode
1625         // - for this timelimit_overtime needs to be >0 of course
1626         // - also check the winning condition calculated in the previous frame and only add normal overtime
1627         //   again, if at the point at which timelimit would be extended again, still no winner was found
1628         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1629         {
1630                 return 1; // need to call InitiateOvertime later
1631         }
1632         else
1633         {
1634                 if(!checkrules_suddendeathend)
1635                 {
1636                         if(autocvar_g_campaign)
1637                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1638                         else
1639                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1640                         if(g_race && !g_race_qualifying)
1641                                 race_StartCompleting();
1642                 }
1643                 return 0;
1644         }
1645 }
1646
1647 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1648 {
1649         ++checkrules_overtimesadded;
1650         //add one more overtime by simply extending the timelimit
1651         float tl;
1652         tl = autocvar_timelimit;
1653         tl += autocvar_timelimit_overtime;
1654         cvar_set("timelimit", ftos(tl));
1655
1656         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1657 }
1658
1659 float GetWinningCode(float fraglimitreached, float equality)
1660 {
1661         if(autocvar_g_campaign == 1)
1662                 if(fraglimitreached)
1663                         return WINNING_YES;
1664                 else
1665                         return WINNING_NO;
1666
1667         else
1668                 if(equality)
1669                         if(fraglimitreached)
1670                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1671                         else
1672                                 return WINNING_NEVER;
1673                 else
1674                         if(fraglimitreached)
1675                                 return WINNING_YES;
1676                         else
1677                                 return WINNING_NO;
1678 }
1679
1680 // set the .winning flag for exactly those players with a given field value
1681 void SetWinners(.float field, float value)
1682 {
1683         entity head;
1684         FOR_EACH_PLAYER(head)
1685                 head.winning = (head.(field) == value);
1686 }
1687
1688 // set the .winning flag for those players with a given field value
1689 void AddWinners(.float field, float value)
1690 {
1691         entity head;
1692         FOR_EACH_PLAYER(head)
1693                 if (head.(field) == value)
1694                         head.winning = 1;
1695 }
1696
1697 // clear the .winning flags
1698 void ClearWinners(void)
1699 {
1700         entity head;
1701         FOR_EACH_PLAYER(head)
1702                 head.winning = 0;
1703 }
1704
1705 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1706 // they win. Otherwise the defending team wins once the timelimit passes.
1707 void assault_new_round();
1708 float WinningCondition_Assault()
1709 {
1710         float status;
1711
1712         WinningConditionHelper(); // set worldstatus
1713
1714         status = WINNING_NO;
1715         // as the timelimit has not yet passed just assume the defending team will win
1716         if(assault_attacker_team == NUM_TEAM_1)
1717         {
1718                 SetWinners(team, NUM_TEAM_2);
1719         }
1720         else
1721         {
1722                 SetWinners(team, NUM_TEAM_1);
1723         }
1724
1725         entity ent;
1726         ent = find(world, classname, "target_assault_roundend");
1727         if(ent)
1728         {
1729                 if(ent.winning) // round end has been triggered by attacking team
1730                 {
1731                         bprint("ASSAULT: round completed...\n");
1732                         SetWinners(team, assault_attacker_team);
1733
1734                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1735
1736                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1737                         {
1738                                 status = WINNING_YES;
1739                         }
1740                         else
1741                         {
1742                                 entity oldself;
1743                                 oldself = self;
1744                                 self = ent;
1745                                 assault_new_round();
1746                                 self = oldself;
1747                         }
1748                 }
1749         }
1750
1751         return status;
1752 }
1753
1754 // LMS winning condition: game terminates if and only if there's at most one
1755 // one player who's living lives. Top two scores being equal cancels the time
1756 // limit.
1757 float WinningCondition_LMS()
1758 {
1759         entity head, head2;
1760         float have_player;
1761         float have_players;
1762         float l;
1763
1764         have_player = false;
1765         have_players = false;
1766         l = LMS_NewPlayerLives();
1767
1768         head = find(world, classname, "player");
1769         if(head)
1770                 have_player = true;
1771         head2 = find(head, classname, "player");
1772         if(head2)
1773                 have_players = true;
1774
1775         if(have_player)
1776         {
1777                 // we have at least one player
1778                 if(have_players)
1779                 {
1780                         // two or more active players - continue with the game
1781                 }
1782                 else
1783                 {
1784                         // exactly one player?
1785
1786                         ClearWinners();
1787                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1788
1789                         if(l)
1790                         {
1791                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1792                                 return WINNING_NO;
1793                         }
1794                         else
1795                         {
1796                                 // a winner!
1797                                 // and assign him his first place
1798                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1799                                 return WINNING_YES;
1800                         }
1801                 }
1802         }
1803         else
1804         {
1805                 // nobody is playing at all...
1806                 if(l)
1807                 {
1808                         // wait for players...
1809                 }
1810                 else
1811                 {
1812                         // SNAFU (maybe a draw game?)
1813                         ClearWinners();
1814                         dprint("No players, ending game.\n");
1815                         return WINNING_YES;
1816                 }
1817         }
1818
1819         // When we get here, we have at least two players who are actually LIVING,
1820         // now check if the top two players have equal score.
1821         WinningConditionHelper();
1822
1823         ClearWinners();
1824         if(WinningConditionHelper_winner)
1825                 WinningConditionHelper_winner.winning = true;
1826         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1827                 return WINNING_NEVER;
1828
1829         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1830         return WINNING_NO;
1831 }
1832
1833 void ShuffleMaplist()
1834 {
1835         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1836 }
1837
1838 float leaderfrags;
1839 float WinningCondition_Scores(float limit, float leadlimit)
1840 {
1841         float limitreached;
1842
1843         // TODO make everything use THIS winning condition (except LMS)
1844         WinningConditionHelper();
1845
1846         if(teamplay)
1847         {
1848                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1849                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1850                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1851                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1852         }
1853
1854         ClearWinners();
1855         if(WinningConditionHelper_winner)
1856                 WinningConditionHelper_winner.winning = 1;
1857         if(WinningConditionHelper_winnerteam >= 0)
1858                 SetWinners(team, WinningConditionHelper_winnerteam);
1859
1860         if(WinningConditionHelper_lowerisbetter)
1861         {
1862                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1863                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1864                 limit = -limit;
1865         }
1866
1867         if(WinningConditionHelper_zeroisworst)
1868                 leadlimit = 0; // not supported in this mode
1869
1870         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1871         // these modes always score in increments of 1, thus this makes sense
1872         {
1873                 if(leaderfrags != WinningConditionHelper_topscore)
1874                 {
1875                         leaderfrags = WinningConditionHelper_topscore;
1876
1877                         if (limit)
1878                         if (leaderfrags == limit - 1)
1879                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1880                         else if (leaderfrags == limit - 2)
1881                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1882                         else if (leaderfrags == limit - 3)
1883                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1884                 }
1885         }
1886
1887         limitreached = false;
1888         if(limit)
1889                 if(WinningConditionHelper_topscore >= limit)
1890                         limitreached = true;
1891         if(leadlimit)
1892         {
1893                 float leadlimitreached;
1894                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1895                 if(autocvar_leadlimit_and_fraglimit)
1896                         limitreached = (limitreached && leadlimitreached);
1897                 else
1898                         limitreached = (limitreached || leadlimitreached);
1899         }
1900
1901         if(limit)
1902                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1903
1904         return GetWinningCode(
1905                 WinningConditionHelper_topscore && limitreached,
1906                 WinningConditionHelper_equality
1907         );
1908 }
1909
1910 float WinningCondition_Race(float fraglimit)
1911 {
1912         float wc;
1913         entity p;
1914         float n, c;
1915
1916         n = 0;
1917         c = 0;
1918         FOR_EACH_PLAYER(p)
1919         {
1920                 ++n;
1921                 if(p.race_completed)
1922                         ++c;
1923         }
1924         if(n && (n == c))
1925                 return WINNING_YES;
1926         wc = WinningCondition_Scores(fraglimit, 0);
1927
1928         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1929         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1930         // do NOT support equality when the laps are all raced!
1931                 return WINNING_STARTSUDDENDEATHOVERTIME;
1932         else
1933                 return WINNING_NEVER;
1934 }
1935
1936 float WinningCondition_QualifyingThenRace(float limit)
1937 {
1938         float wc;
1939         wc = WinningCondition_Scores(limit, 0);
1940
1941         // NEVER initiate overtime
1942         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1943         {
1944                 return WINNING_YES;
1945         }
1946
1947         return wc;
1948 }
1949
1950 float WinningCondition_RanOutOfSpawns()
1951 {
1952         entity head;
1953
1954         if(have_team_spawns <= 0)
1955                 return WINNING_NO;
1956
1957         if(!autocvar_g_spawn_useallspawns)
1958                 return WINNING_NO;
1959
1960         if(!some_spawn_has_been_used)
1961                 return WINNING_NO;
1962
1963         team1_score = team2_score = team3_score = team4_score = 0;
1964
1965         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1966         {
1967                 if(head.team == NUM_TEAM_1)
1968                         team1_score = 1;
1969                 else if(head.team == NUM_TEAM_2)
1970                         team2_score = 1;
1971                 else if(head.team == NUM_TEAM_3)
1972                         team3_score = 1;
1973                 else if(head.team == NUM_TEAM_4)
1974                         team4_score = 1;
1975         }
1976
1977         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1978         {
1979                 if(head.team == NUM_TEAM_1)
1980                         team1_score = 1;
1981                 else if(head.team == NUM_TEAM_2)
1982                         team2_score = 1;
1983                 else if(head.team == NUM_TEAM_3)
1984                         team3_score = 1;
1985                 else if(head.team == NUM_TEAM_4)
1986                         team4_score = 1;
1987         }
1988
1989         ClearWinners();
1990         if(team1_score + team2_score + team3_score + team4_score == 0)
1991         {
1992                 checkrules_equality = true;
1993                 return WINNING_YES;
1994         }
1995         else if(team1_score + team2_score + team3_score + team4_score == 1)
1996         {
1997                 float t, i;
1998                 if(team1_score)
1999                         t = NUM_TEAM_1;
2000                 else if(team2_score)
2001                         t = NUM_TEAM_2;
2002                 else if(team3_score)
2003                         t = NUM_TEAM_3;
2004                 else // if(team4_score)
2005                         t = NUM_TEAM_4;
2006                 CheckAllowedTeams(world);
2007                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2008                 {
2009                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2010                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2011                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2012                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2013                 }
2014
2015                 AddWinners(team, t);
2016                 return WINNING_YES;
2017         }
2018         else
2019                 return WINNING_NO;
2020 }
2021
2022 /*
2023 ============
2024 CheckRules_World
2025
2026 Exit deathmatch games upon conditions
2027 ============
2028 */
2029 void CheckRules_World()
2030 {
2031         float timelimit;
2032         float fraglimit;
2033         float leadlimit;
2034
2035         VoteThink();
2036         MapVote_Think();
2037
2038         SetDefaultAlpha();
2039
2040         if (gameover)   // someone else quit the game already
2041         {
2042                 if(player_count == 0) // Nobody there? Then let's go to the next map
2043                         MapVote_Start();
2044                         // this will actually check the player count in the next frame
2045                         // again, but this shouldn't hurt
2046                 return;
2047         }
2048
2049         timelimit = autocvar_timelimit * 60;
2050         fraglimit = autocvar_fraglimit;
2051         leadlimit = autocvar_leadlimit;
2052
2053         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2054         {
2055                 if(timelimit > 0)
2056                         timelimit = 0; // timelimit is not made for warmup
2057                 if(fraglimit > 0)
2058                         fraglimit = 0; // no fraglimit for now
2059                 leadlimit = 0; // no leadlimit for now
2060         }
2061
2062         if(timelimit > 0)
2063         {
2064                 timelimit += game_starttime;
2065         }
2066         else if (timelimit < 0)
2067         {
2068                 // endmatch
2069                 NextLevel();
2070                 return;
2071         }
2072
2073         float wantovertime;
2074         wantovertime = 0;
2075
2076         if(timelimit > game_starttime)
2077                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2078         else
2079                 game_completion_ratio = 0;
2080
2081         if(checkrules_suddendeathend)
2082         {
2083                 if(!checkrules_suddendeathwarning)
2084                 {
2085                         checkrules_suddendeathwarning = true;
2086                         if(g_race && !g_race_qualifying)
2087                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2088                         else
2089                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2090                 }
2091         }
2092         else
2093         {
2094                 if (timelimit && time >= timelimit)
2095                 {
2096                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2097                         {
2098                                 float totalplayers;
2099                                 float playerswithlaps;
2100                                 float readyplayers;
2101                                 entity head;
2102                                 totalplayers = playerswithlaps = readyplayers = 0;
2103                                 FOR_EACH_PLAYER(head)
2104                                 {
2105                                         ++totalplayers;
2106                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2107                                                 ++playerswithlaps;
2108                                         if(head.ready)
2109                                                 ++readyplayers;
2110                                 }
2111
2112                                 // at least 2 of the players have completed a lap: start the RACE
2113                                 // otherwise, the players should end the qualifying on their own
2114                                 if(readyplayers || playerswithlaps >= 2)
2115                                 {
2116                                         checkrules_suddendeathend = 0;
2117                                         ReadyRestart(); // go to race
2118                                         return;
2119                                 }
2120                                 else
2121                                         wantovertime |= InitiateSuddenDeath();
2122                         }
2123                         else
2124                                 wantovertime |= InitiateSuddenDeath();
2125                 }
2126         }
2127
2128         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2129         {
2130                 NextLevel();
2131                 return;
2132         }
2133
2134         float checkrules_status;
2135         checkrules_status = WinningCondition_RanOutOfSpawns();
2136         if(checkrules_status == WINNING_YES)
2137         {
2138                 bprint("Hey! Someone ran out of spawns!\n");
2139         }
2140         else if(g_race && !g_race_qualifying && timelimit >= 0)
2141         {
2142                 checkrules_status = WinningCondition_Race(fraglimit);
2143                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2144         }
2145         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2146         {
2147                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2148                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2149         }
2150         else if(g_assault)
2151         {
2152                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2153         }
2154         else if(g_lms)
2155         {
2156                 checkrules_status = WinningCondition_LMS();
2157         }
2158         else
2159         {
2160                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2161                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2162         }
2163
2164         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2165         {
2166                 checkrules_status = WINNING_NEVER;
2167                 checkrules_overtimesadded = -1;
2168                 wantovertime |= InitiateSuddenDeath();
2169         }
2170
2171         if(checkrules_status == WINNING_NEVER)
2172                 // equality cases! Nobody wins if the overtime ends in a draw.
2173                 ClearWinners();
2174
2175         if(wantovertime)
2176         {
2177                 if(checkrules_status == WINNING_NEVER)
2178                         InitiateOvertime();
2179                 else
2180                         checkrules_status = WINNING_YES;
2181         }
2182
2183         if(checkrules_suddendeathend)
2184                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2185                         checkrules_status = WINNING_YES;
2186
2187         if(checkrules_status == WINNING_YES)
2188         {
2189                 //print("WINNING\n");
2190                 NextLevel();
2191         }
2192 }
2193
2194 string GotoMap(string m)
2195 {
2196         m = GameTypeVote_MapInfo_FixName(m);
2197         if (!m)
2198                 return "The map you suggested is not available on this server.";
2199         if (!autocvar_sv_vote_gametype)
2200         if(!MapInfo_CheckMap(m))
2201                 return "The map you suggested does not support the current game mode.";
2202         cvar_set("nextmap", m);
2203         cvar_set("timelimit", "-1");
2204         if(mapvote_initialized || alreadychangedlevel)
2205         {
2206                 if(DoNextMapOverride(0))
2207                         return "Map switch initiated.";
2208                 else
2209                         return "Hm... no. For some reason I like THIS map more.";
2210         }
2211         else
2212                 return "Map switch will happen after scoreboard.";
2213 }
2214
2215
2216 void EndFrame()
2217 {
2218         anticheat_endframe();
2219
2220         float altime;
2221         FOR_EACH_REALCLIENT(self)
2222         {
2223                 entity e = IS_SPEC(self) ? self.enemy : self;
2224                 if(e.typehitsound)
2225                         self.typehit_time = time;
2226                 else if(e.damage_dealt)
2227                 {
2228                         self.hit_time = time;
2229                         self.damage_dealt_total += ceil(e.damage_dealt);
2230                 }
2231         }
2232         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2233         // add 1 frametime because after this, engine SV_Physics
2234         // increases time by a frametime and then networks the frame
2235         // add another frametime because client shows everything with
2236         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2237         // needed!
2238         FOR_EACH_CLIENT(self)
2239         {
2240                 self.typehitsound = false;
2241                 self.damage_dealt = 0;
2242                 antilag_record(self, altime);
2243         }
2244         FOR_EACH_MONSTER(self)
2245                 antilag_record(self, altime);
2246 }
2247
2248
2249 /*
2250  * RedirectionThink:
2251  * returns true if redirecting
2252  */
2253 float redirection_timeout;
2254 float redirection_nextthink;
2255 float RedirectionThink()
2256 {
2257         float clients_found;
2258
2259         if(redirection_target == "")
2260                 return false;
2261
2262         if(!redirection_timeout)
2263         {
2264                 cvar_set("sv_public", "-2");
2265                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2266                 if(redirection_target == "self")
2267                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2268                 else
2269                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2270         }
2271
2272         if(time < redirection_nextthink)
2273                 return true;
2274
2275         redirection_nextthink = time + 1;
2276
2277         clients_found = 0;
2278         FOR_EACH_REALCLIENT(self)
2279         {
2280                 // TODO add timer
2281                 print("Redirecting: sending connect command to ", self.netname, "\n");
2282                 if(redirection_target == "self")
2283                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2284                 else
2285                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2286                 ++clients_found;
2287         }
2288
2289         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2290
2291         if(time > redirection_timeout || clients_found == 0)
2292                 localcmd("\nwait; wait; wait; quit\n");
2293
2294         return true;
2295 }
2296
2297 void TargetMusic_RestoreGame();
2298 void RestoreGame()
2299 {
2300         // Loaded from a save game
2301         // some things then break, so let's work around them...
2302
2303         // Progs DB (capture records)
2304         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2305
2306         // Mapinfo
2307         MapInfo_Shutdown();
2308         MapInfo_Enumerate();
2309         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2310         WeaponStats_Init();
2311
2312         TargetMusic_RestoreGame();
2313 }
2314
2315 void Shutdown()
2316 {
2317         gameover = 2;
2318
2319         if(world_initialized > 0)
2320         {
2321                 world_initialized = 0;
2322                 print("Saving persistent data...\n");
2323                 Ban_SaveBans();
2324
2325                 // playerstats with unfinished match
2326                 PlayerStats_GameReport(false);
2327
2328                 if(!cheatcount_total)
2329                 {
2330                         if(autocvar_sv_db_saveasdump)
2331                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2332                         else
2333                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2334                 }
2335                 if(autocvar_developer)
2336                 {
2337                         if(autocvar_sv_db_saveasdump)
2338                                 db_dump(TemporaryDB, "server-temp.db");
2339                         else
2340                                 db_save(TemporaryDB, "server-temp.db");
2341                 }
2342                 CheatShutdown(); // must be after cheatcount check
2343                 db_close(ServerProgsDB);
2344                 db_close(TemporaryDB);
2345                 print("done!\n");
2346                 // tell the bot system the game is ending now
2347                 bot_endgame();
2348
2349                 WeaponStats_Shutdown();
2350                 MapInfo_Shutdown();
2351         }
2352         else if(world_initialized == 0)
2353         {
2354                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2355         }
2356 }