qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_runematch");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("g_runematch_point_leadlimit");
 319                 BADCVAR("leadlimit_and_fraglimit");
 320                 BADCVAR("leadlimit_override");
 321                 BADCVAR("pausable");
 322                 BADCVAR("sv_allow_fullbright");
 323                 BADCVAR("sv_checkforpacketsduringsleep");
 324                 BADCVAR("sv_fraginfo");
 325                 BADCVAR("sv_timeout");
 326                 BADPREFIX("sv_timeout_");
 327                 BADCVAR("welcome_message_time");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_fraginfo_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_namechangetimer");
 343 #ifndef NO_LEGACY_NETWORKING
 344                 BADCVAR("sv_use_csqc_players"); // transition
 345 #endif
 346
 347                 // allowed changes to server admins (please sync this to server.cfg)
 348                 // vi commands:
 349                 //   :/"impure"/,$d
 350                 //   :g!,^\/\/[^ /],d
 351                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 352                 //   :%!sort
 353                 // yes, this does contain some redundant stuff, don't really care
 354                 BADCVAR("bot_config_file");
 355                 BADCVAR("bot_number");
 356                 BADCVAR("bot_prefix");
 357                 BADCVAR("bot_suffix");
 358                 BADCVAR("capturelimit_override");
 359                 BADCVAR("fraglimit_override");
 360                 BADCVAR("gametype");
 361                 BADCVAR("g_antilag");
 362                 BADCVAR("g_balance_teams");
 363                 BADCVAR("g_balance_teams_prevent_imbalance");
 364                 BADCVAR("g_balance_teams_scorefactor");
 365                 BADCVAR("g_ban_sync_trusted_servers");
 366                 BADCVAR("g_ban_sync_uri");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_friendlyfire");
 370                 BADCVAR("g_fullbrightitems");
 371                 BADCVAR("g_fullbrightplayers");
 372                 BADCVAR("g_keyhunt_point_limit");
 373                 BADCVAR("g_keyhunt_teams_override");
 374                 BADCVAR("g_lms_lives_override");
 375                 BADCVAR("g_maplist");
 376                 BADCVAR("g_maplist_check_waypoints");
 377                 BADCVAR("g_maplist_mostrecent_count");
 378                 BADCVAR("g_maplist_shuffle");
 379                 BADCVAR("g_maplist_votable");
 380                 BADCVAR("g_maplist_votable_abstain");
 381                 BADCVAR("g_maplist_votable_nodetail");
 382                 BADCVAR("g_maplist_votable_suggestions");
 383                 BADCVAR("g_maxplayers");
 384                 BADCVAR("g_mirrordamage");
 385                 BADCVAR("g_nexball_goallimit");
 386                 BADCVAR("g_powerups");
 387                 BADCVAR("g_runematch_point_limit");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_warmup");
 390                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 391                 BADCVAR("hostname");
 392                 BADCVAR("log_file");
 393                 BADCVAR("maxplayers");
 394                 BADCVAR("minplayers");
 395                 BADCVAR("net_address");
 396                 BADCVAR("port");
 397                 BADCVAR("rcon_password");
 398                 BADCVAR("rcon_restricted_commands");
 399                 BADCVAR("rcon_restricted_password");
 400                 BADCVAR("skill");
 401                 BADCVAR("sv_adminnick");
 402                 BADCVAR("sv_autoscreenshot");
 403                 BADCVAR("sv_autotaunt");
 404                 BADCVAR("sv_curl_defaulturl");
 405                 BADCVAR("sv_defaultcharacter");
 406                 BADCVAR("sv_defaultplayercolors");
 407                 BADCVAR("sv_defaultplayermodel");
 408                 BADCVAR("sv_defaultplayerskin");
 409                 BADCVAR("sv_maxidle");
 410                 BADCVAR("sv_maxrate");
 411                 BADCVAR("sv_motd");
 412                 BADCVAR("sv_public");
 413                 BADCVAR("sv_ready_restart");
 414                 BADCVAR("sv_status_privacy");
 415                 BADCVAR("sv_taunt");
 416                 BADCVAR("sv_vote_call");
 417                 BADCVAR("sv_vote_commands");
 418                 BADCVAR("sv_vote_majority_factor");
 419                 BADCVAR("sv_vote_master");
 420                 BADCVAR("sv_vote_master_commands");
 421                 BADCVAR("sv_vote_master_password");
 422                 BADCVAR("sv_vote_simple_majority_factor");
 423                 BADCVAR("sys_ticrate");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_minstagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434
 435                 if(autocvar_g_minstagib)
 436                 {
 437                         BADCVAR("g_grappling_hook");
 438                         BADCVAR("g_jetpack");
 439                 }
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for(;;)
 480         {
 481                 o = world.mins;
 482                 o_x += random() * (world.maxs_x - world.mins_x);
 483                 o_y += random() * (world.maxs_y - world.mins_y);
 484                 o_z += random() * (world.maxs_z - world.mins_z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return TRUE;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         // needs to be done so early because of the constants they create
 554         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 555         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 556
 557         MapInfo_Enumerate();
 558         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 559 }
 560
 561 void Map_MarkAsRecent(string m);
 562 float world_already_spawned;
 563 void Nagger_Init();
 564 void ClientInit_Spawn();
 565 void WeaponStats_Init();
 566 void WeaponStats_Shutdown();
 567 void spawnfunc_worldspawn (void)
 568 {
 569         float fd, l, i, j, n;
 570         string s, col;
 571
 572         cvar = cvar_normal;
 573         cvar_string = cvar_string_normal;
 574         cvar_set = cvar_set_normal;
 575
 576         if(world_already_spawned)
 577                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 578         world_already_spawned = TRUE;
 579
 580         remove = remove_safely; // during spawning, watch what you remove!
 581
 582         check_unacceptable_compiler_bugs();
 583
 584         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 585
 586         compressShortVector_init();
 587
 588         allowed_to_spawn = TRUE;
 589
 590         entity head;
 591         head = nextent(world);
 592         maxclients = 0;
 593         while(head)
 594         {
 595                 ++maxclients;
 596                 head = nextent(head);
 597         }
 598
 599         // needs to be done so early because of the constants they create
 600         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 601         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 602
 603         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 604
 605         TemporaryDB = db_create();
 606
 607         // 0 normal
 608         lightstyle(0, "m");
 609
 610         // 1 FLICKER (first variety)
 611         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 612
 613         // 2 SLOW STRONG PULSE
 614         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 615
 616         // 3 CANDLE (first variety)
 617         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 618
 619         // 4 FAST STROBE
 620         lightstyle(4, "mamamamamama");
 621
 622         // 5 GENTLE PULSE 1
 623         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 624
 625         // 6 FLICKER (second variety)
 626         lightstyle(6, "nmonqnmomnmomomno");
 627
 628         // 7 CANDLE (second variety)
 629         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 630
 631         // 8 CANDLE (third variety)
 632         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 633
 634         // 9 SLOW STROBE (fourth variety)
 635         lightstyle(9, "aaaaaaaazzzzzzzz");
 636
 637         // 10 FLUORESCENT FLICKER
 638         lightstyle(10, "mmamammmmammamamaaamammma");
 639
 640         // 11 SLOW PULSE NOT FADE TO BLACK
 641         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 642
 643         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 644
 645         // 63 testing
 646         lightstyle(63, "a");
 647
 648         if(autocvar_g_campaign)
 649                 CampaignPreInit();
 650
 651         Map_MarkAsRecent(mapname);
 652
 653         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 654
 655         precache_model ("null"); // we need this one before InitGameplayMode
 656         InitGameplayMode();
 657         readlevelcvars();
 658         GrappleHookInit();
 659         ElectroInit();
 660         LaserInit();
 661
 662         player_count = 0;
 663         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 664         if(bot_waypoints_for_items == 1)
 665                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 666                         bot_waypoints_for_items = 0;
 667
 668         precache();
 669
 670         WaypointSprite_Init();
 671
 672         //if (g_domination)
 673         //      dom_init();
 674
 675         GameLogInit(); // prepare everything
 676         // NOTE for matchid:
 677         // changing the logic generating it is okay. But:
 678         // it HAS to stay <= 64 chars
 679         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 680         if(autocvar_sv_eventlog)
 681         {
 682                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 683                 matchid = strzone(s);
 684
 685                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 686                 s = ":gameinfo:mutators:LIST";
 687
 688                 ret_string = s;
 689                 MUTATOR_CALLHOOK(BuildMutatorsString);
 690                 s = ret_string;
 691
 692                 // simple, probably not good in the mutator system
 693                 if(autocvar_g_grappling_hook)
 694                         s = strcat(s, ":grappling_hook");
 695
 696                 // initialiation stuff, not good in the mutator system
 697                 if(!autocvar_g_use_ammunition)
 698                         s = strcat(s, ":no_use_ammunition");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_pickup_items == 0)
 702                         s = strcat(s, ":no_pickup_items");
 703                 if(autocvar_g_pickup_items > 0)
 704                         s = strcat(s, ":pickup_items");
 705
 706                 // initialiation stuff, not good in the mutator system
 707                 if(autocvar_g_weaponarena != "0")
 708                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 709
 710                 // TODO to mutator system
 711                 if(autocvar_g_norecoil)
 712                         s = strcat(s, ":norecoil");
 713
 714                 // TODO to mutator system
 715                 if(autocvar_g_midair)
 716                         s = strcat(s, ":midair");
 717
 718                 // TODO to mutator system
 719                 if(autocvar_g_minstagib)
 720                         s = strcat(s, ":minstagib");
 721
 722                 // TODO to mutator system
 723                 if(autocvar_g_powerups == 0)
 724                         s = strcat(s, ":no_powerups");
 725                 if(autocvar_g_powerups > 0)
 726                         s = strcat(s, ":powerups");
 727
 728                 GameLogEcho(s);
 729                 GameLogEcho(":gameinfo:end");
 730         }
 731         else
 732                 matchid = strzone(ftos(random()));
 733
 734         cvar_set("nextmap", "");
 735
 736         SetDefaultAlpha();
 737
 738         if(autocvar_g_campaign)
 739                 CampaignPostInit();
 740
 741         fteqcc_testbugs();
 742
 743         Ban_LoadBans();
 744
 745         MapInfo_Enumerate();
 746         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 747
 748         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 749         {
 750                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 751                 if(fd != -1)
 752                 {
 753                         while((s = fgets(fd)))
 754                         {
 755                                 l = tokenize_console(s);
 756                                 if(l < 2)
 757                                         continue;
 758                                 if(argv(0) == "cd")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 761                                         print("  cdtrack ", argv(2), "\n");
 762                                 }
 763                                 else if(argv(0) == "fog")
 764                                 {
 765                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 766                                         print("  \"fog\" \"", s, "\"\n");
 767                                 }
 768                                 else if(argv(0) == "set")
 769                                 {
 770                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 771                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 772                                 }
 773                                 else if(argv(0) != "//")
 774                                 {
 775                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 776                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 777                                 }
 778                         }
 779                         fclose(fd);
 780                 }
 781         }
 782
 783         WeaponStats_Init();
 784
 785         WEPSET_ADDSTAT();
 786         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 787         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 788         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 789         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 790         Nagger_Init();
 791
 792         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 793         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 794         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 795         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 796         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 797         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 798         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 799         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 800         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 801         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 802         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 803         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 804         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 805
 806         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 807         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 808
 809         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 810
 811         if(g_ca || g_freezetag)
 812         {
 813                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 814                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 815                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 816                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 817         }
 818         if(g_freezetag)
 819         {
 820                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 821                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 822         }
 823
 824         // g_movementspeed hack
 825         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 826         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 827         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 828         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 829
 830         // secrets
 831         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 832         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 833
 834         // misc
 835         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 836
 837         next_pingtime = time + 5;
 838
 839         detect_maptype();
 840
 841         // set up information replies for clients and server to use
 842         lsmaps_reply = "^7Maps available: ";
 843         lsnewmaps_reply = "^7Maps without a record set: ";
 844         for(i = 0, j = 0; i < MapInfo_count; ++i)
 845         {
 846                 if(MapInfo_Get_ByID(i))
 847                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 848                         {
 849                                 if(mod(i, 2))
 850                                         col = "^2";
 851                                 else
 852                                         col = "^3";
 853
 854                                 ++j;
 855
 856                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 857
 858                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 859                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 860                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 861                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 862                         }
 863         }
 864
 865         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 866         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 867
 868         maplist_reply = "^7Maps in list: ";
 869         n = tokenize_console(autocvar_g_maplist);
 870         for(i = 0, j = 0; i < n; ++i)
 871         {
 872                 if(MapInfo_CheckMap(argv(i)))
 873                 {
 874                         if(mod(j, 2))
 875                                 col = "^2";
 876                         else
 877                                 col = "^3";
 878                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 879                         ++j;
 880                 }
 881         }
 882         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 883         MapInfo_ClearTemps();
 884
 885         for(i = 0; i < 10; ++i)
 886         {
 887                 s = getrecords(i);
 888                 if (s)
 889                         records_reply[i] = strzone(s);
 890         }
 891
 892         ladder_reply = strzone(getladder());
 893
 894         rankings_reply = strzone(getrankings());
 895
 896         // begin other init
 897         ClientInit_Spawn();
 898         RandomSeed_Spawn();
 899         PingPLReport_Spawn();
 900
 901         CheatInit();
 902
 903         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 904
 905         // fill sv_curl_serverpackages from .serverpackage files
 906         if(autocvar_sv_curl_serverpackages_auto)
 907         {
 908                 s = "";
 909                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 910                 for(i = 0; i < n; ++i)
 911                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 912                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 913                                 s = strcat(s, " ", argv(i));
 914                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 915                 if(fd >= 0)
 916                 {
 917                         j = search_getsize(fd);
 918                         for(i = 0; i < j; ++i)
 919                                 s = strcat(s, " ", search_getfilename(fd, i));
 920                         search_end(fd);
 921                 }
 922                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 923                 if(fd >= 0)
 924                 {
 925                         j = search_getsize(fd);
 926                         for(i = 0; i < j; ++i)
 927                                 s = strcat(s, " ", search_getfilename(fd, i));
 928                         search_end(fd);
 929                 }
 930                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 931         }
 932
 933         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 934         modname = "Xonotic";
 935         // physics/balance/config changes that count as mod
 936         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 937                 modname = cvar_string("g_mod_physics");
 938         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 939                 modname = cvar_string("g_mod_balance");
 940         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 941                 modname = cvar_string("g_mod_config");
 942         // weird mutators that deserve to count as mod
 943         if(autocvar_g_minstagib)
 944                 modname = "MinstaGib";
 945         // extra mutators that deserve to count as mod
 946         MUTATOR_CALLHOOK(SetModname);
 947         // weird game types that deserve to count as mod
 948         if(g_cts)
 949                 modname = "CTS";
 950         // save it for later
 951         modname = strzone(modname);
 952
 953         WinningConditionHelper(); // set worldstatus
 954
 955         world_initialized = 1;
 956 }
 957
 958 void spawnfunc_light (void)
 959 {
 960         //makestatic (self); // Who the f___ did that?
 961         remove(self);
 962 }
 963
 964 string GetGametype()
 965 {
 966         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 967 }
 968
 969 string getmapname_stored;
 970 string GetMapname()
 971 {
 972         return mapname;
 973 }
 974
 975 float Map_Count, Map_Current;
 976 string Map_Current_Name;
 977
 978 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 979 float GetMaplistPosition()
 980 {
 981         float pos, idx;
 982         string map;
 983
 984         map = GetMapname();
 985         idx = autocvar_g_maplist_index;
 986
 987         if(idx >= 0)
 988                 if(idx < Map_Count)
 989                         if(map == argv(idx))
 990                                 return idx;
 991
 992         for(pos = 0; pos < Map_Count; ++pos)
 993                 if(map == argv(pos))
 994                         return pos;
 995
 996         // resume normal maplist rotation if current map is not in g_maplist
 997         return idx;
 998 }
 999
1000 float MapHasRightSize(string map)
1001 {
1002         float fh;
1003         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1004         if(autocvar_g_maplist_check_waypoints)
1005         {
1006                 dprint("checkwp "); dprint(map);
1007                 if(!fexists(strcat("maps/", map, ".waypoints")))
1008                 {
1009                         dprint(": no waypoints\n");
1010                         return FALSE;
1011                 }
1012                 dprint(": has waypoints\n");
1013         }
1014
1015         // open map size restriction file
1016         dprint("opensize "); dprint(map);
1017         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1018         if(fh >= 0)
1019         {
1020                 float mapmin, mapmax;
1021                 dprint(": ok, ");
1022                 mapmin = stof(fgets(fh));
1023                 mapmax = stof(fgets(fh));
1024                 fclose(fh);
1025                 if(player_count < mapmin)
1026                 {
1027                         dprint("not enough\n");
1028                         return FALSE;
1029                 }
1030                 if(player_count > mapmax)
1031                 {
1032                         dprint("too many\n");
1033                         return FALSE;
1034                 }
1035                 dprint("right size\n");
1036                 return TRUE;
1037         }
1038         dprint(": not found\n");
1039         return TRUE;
1040 }
1041
1042 string Map_Filename(float position)
1043 {
1044         return strcat("maps/", argv(position), ".bsp");
1045 }
1046
1047 string strwords(string s, float w)
1048 {
1049         float endpos;
1050         for(endpos = 0; w && endpos >= 0; --w)
1051                 endpos = strstrofs(s, " ", endpos + 1);
1052         if(endpos < 0)
1053                 return s;
1054         else
1055                 return substring(s, 0, endpos);
1056 }
1057
1058 float strhasword(string s, string w)
1059 {
1060         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1061 }
1062
1063 void Map_MarkAsRecent(string m)
1064 {
1065         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1066 }
1067
1068 float Map_IsRecent(string m)
1069 {
1070         return strhasword(autocvar_g_maplist_mostrecent, m);
1071 }
1072
1073 float Map_Check(float position, float pass)
1074 {
1075         string filename;
1076         string map_next;
1077         map_next = argv(position);
1078         if(pass <= 1)
1079         {
1080                 if(Map_IsRecent(map_next))
1081                         return 0;
1082         }
1083         filename = Map_Filename(position);
1084         if(MapInfo_CheckMap(map_next))
1085         {
1086                 if(pass == 2)
1087                         return 1;
1088                 if(MapHasRightSize(map_next))
1089                         return 1;
1090                 return 0;
1091         }
1092         else
1093                 dprint( "Couldn't select '", filename, "'..\n" );
1094
1095         return 0;
1096 }
1097
1098 void Map_Goto_SetStr(string nextmapname)
1099 {
1100         if(getmapname_stored != "")
1101                 strunzone(getmapname_stored);
1102         if(nextmapname == "")
1103                 getmapname_stored = "";
1104         else
1105                 getmapname_stored = strzone(nextmapname);
1106 }
1107
1108 void Map_Goto_SetFloat(float position)
1109 {
1110         cvar_set("g_maplist_index", ftos(position));
1111         Map_Goto_SetStr(argv(position));
1112 }
1113
1114 void Map_Goto(float reinit)
1115 {
1116         MapInfo_LoadMap(getmapname_stored, reinit);
1117 }
1118
1119 // return codes of map selectors:
1120 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1121 //   -2 = permanent failure
1122 float() MaplistMethod_Iterate = // usual method
1123 {
1124         float pass, i;
1125
1126         for(pass = 1; pass <= 2; ++pass)
1127         {
1128                 for(i = 1; i < Map_Count; ++i)
1129                 {
1130                         float mapindex;
1131                         mapindex = mod(i + Map_Current, Map_Count);
1132                         if(Map_Check(mapindex, pass))
1133                                 return mapindex;
1134                 }
1135         }
1136         return -1;
1137 }
1138
1139 float() MaplistMethod_Repeat = // fallback method
1140 {
1141         if(Map_Check(Map_Current, 2))
1142                 return Map_Current;
1143         return -2;
1144 }
1145
1146 float() MaplistMethod_Random = // random map selection
1147 {
1148         float i, imax;
1149
1150         imax = 42;
1151
1152         for(i = 0; i <= imax; ++i)
1153         {
1154                 float mapindex;
1155                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1156                 if(Map_Check(mapindex, 1))
1157                         return mapindex;
1158         }
1159         return -1;
1160 }
1161
1162 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1163 // the exponent sets a bias on the map selection:
1164 // the higher the exponent, the less likely "shortly repeated" same maps are
1165 {
1166         float i, j, imax, insertpos;
1167
1168         imax = 42;
1169
1170         for(i = 0; i <= imax; ++i)
1171         {
1172                 string newlist;
1173
1174                 // now reinsert this at another position
1175                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1176                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1177                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1178                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1179
1180                 // insert the current map there
1181                 newlist = "";
1182                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1183                         newlist = strcat(newlist, " ", argv(j));
1184                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1185                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1186                         newlist = strcat(newlist, " ", argv(j));
1187                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1188                 cvar_set("g_maplist", newlist);
1189                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1190
1191                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1192                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1193                 if(Map_Check(Map_Current, 1))
1194                         return Map_Current;
1195         }
1196         return -1;
1197 }
1198
1199 void Maplist_Init()
1200 {
1201         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1202         if(Map_Count == 0)
1203         {
1204                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1205                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1206                 if(autocvar_g_maplist_shuffle)
1207                         ShuffleMaplist();
1208                 localcmd("\nmenu_cmd sync\n");
1209                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1210         }
1211         if(Map_Count == 0)
1212                 error("empty maplist, cannot select a new map");
1213         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1214
1215         if(Map_Current_Name)
1216                 strunzone(Map_Current_Name);
1217         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1218         // this may or may not be correct, but who cares, in the worst case a map
1219         // isn't chosen in the first pass that should have been
1220 }
1221
1222 string GetNextMap()
1223 {
1224         float nextMap;
1225
1226         Maplist_Init();
1227         nextMap = -1;
1228
1229         if(nextMap == -1)
1230                 if(autocvar_g_maplist_shuffle > 0)
1231                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1232
1233         if(nextMap == -1)
1234                 if(autocvar_g_maplist_selectrandom)
1235                         nextMap = MaplistMethod_Random();
1236
1237         if(nextMap == -1)
1238                 nextMap = MaplistMethod_Iterate();
1239
1240         if(nextMap == -1)
1241                 nextMap = MaplistMethod_Repeat();
1242
1243         if(nextMap >= 0)
1244         {
1245                 Map_Goto_SetFloat(nextMap);
1246                 return getmapname_stored;
1247         }
1248
1249         return "";
1250 }
1251
1252 float DoNextMapOverride(float reinit)
1253 {
1254         if(autocvar_g_campaign)
1255         {
1256                 CampaignPostIntermission();
1257                 alreadychangedlevel = TRUE;
1258                 return TRUE;
1259         }
1260         if(autocvar_quit_when_empty)
1261         {
1262                 if(player_count <= currentbots)
1263                 {
1264                         localcmd("quit\n");
1265                         alreadychangedlevel = TRUE;
1266                         return TRUE;
1267                 }
1268         }
1269         if(autocvar_quit_and_redirect != "")
1270         {
1271                 redirection_target = strzone(autocvar_quit_and_redirect);
1272                 alreadychangedlevel = TRUE;
1273                 return TRUE;
1274         }
1275         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1276         {
1277                 localcmd("restart\n");
1278                 alreadychangedlevel = TRUE;
1279                 return TRUE;
1280         }
1281         if(autocvar_nextmap != "")
1282                 if(MapInfo_CheckMap(autocvar_nextmap))
1283                 {
1284                         Map_Goto_SetStr(autocvar_nextmap);
1285                         Map_Goto(reinit);
1286                         alreadychangedlevel = TRUE;
1287                         return TRUE;
1288                 }
1289         if(!reinit && autocvar_lastlevel)
1290         {
1291                 cvar_settemp_restore();
1292                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1293                 alreadychangedlevel = TRUE;
1294                 return TRUE;
1295         }
1296         return FALSE;
1297 }
1298
1299 void GotoNextMap(float reinit)
1300 {
1301         //string nextmap;
1302         //float n, nummaps;
1303         //string s;
1304         if (alreadychangedlevel)
1305                 return;
1306         alreadychangedlevel = TRUE;
1307
1308         {
1309                 string nextMap;
1310                 float allowReset;
1311
1312                 for(allowReset = 1; allowReset >= 0; --allowReset)
1313                 {
1314                         nextMap = GetNextMap();
1315                         if(nextMap != "")
1316                                 break;
1317
1318                         if(allowReset)
1319                         {
1320                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1321                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1322                                 if(autocvar_g_maplist_shuffle)
1323                                         ShuffleMaplist();
1324                                 localcmd("\nmenu_cmd sync\n");
1325                         }
1326                         else
1327                         {
1328                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1329                         }
1330                 }
1331                 Map_Goto(reinit);
1332         }
1333 }
1334
1335
1336 /*
1337 ============
1338 IntermissionThink
1339
1340 When the player presses attack or jump, change to the next level
1341 ============
1342 */
1343 .float autoscreenshot;
1344 void() MapVote_Start;
1345 void() MapVote_Think;
1346 float mapvote_initialized;
1347 void IntermissionThink()
1348 {
1349         FixIntermissionClient(self);
1350
1351         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1352         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1353
1354         if( (server_screenshot || client_screenshot)
1355                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1356         {
1357                 self.autoscreenshot = -1;
1358                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1359                 return;
1360         }
1361
1362         if (time < intermission_exittime)
1363                 return;
1364
1365         if(!mapvote_initialized)
1366                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1367                         return;
1368
1369         MapVote_Start();
1370 }
1371
1372 /*
1373 ============
1374 FindIntermission
1375
1376 Returns the entity to view from
1377 ============
1378 */
1379 /*
1380 entity FindIntermission()
1381 {
1382         local   entity spot;
1383         local   float cyc;
1384
1385 // look for info_intermission first
1386         spot = find (world, classname, "info_intermission");
1387         if (spot)
1388         {       // pick a random one
1389                 cyc = random() * 4;
1390                 while (cyc > 1)
1391                 {
1392                         spot = find (spot, classname, "info_intermission");
1393                         if (!spot)
1394                                 spot = find (spot, classname, "info_intermission");
1395                         cyc = cyc - 1;
1396                 }
1397                 return spot;
1398         }
1399
1400 // then look for the start position
1401         spot = find (world, classname, "info_player_start");
1402         if (spot)
1403                 return spot;
1404
1405 // testinfo_player_start is only found in regioned levels
1406         spot = find (world, classname, "testplayerstart");
1407         if (spot)
1408                 return spot;
1409
1410 // then look for the start position
1411         spot = find (world, classname, "info_player_deathmatch");
1412         if (spot)
1413                 return spot;
1414
1415         //objerror ("FindIntermission: no spot");
1416         return world;
1417 }
1418 */
1419
1420 /*
1421 ===============================================================================
1422
1423 RULES
1424
1425 ===============================================================================
1426 */
1427
1428 void DumpStats(float final)
1429 {
1430         float file;
1431         string s;
1432         float to_console;
1433         float to_eventlog;
1434         float to_file;
1435         float i;
1436
1437         to_console = autocvar_sv_logscores_console;
1438         to_eventlog = autocvar_sv_eventlog;
1439         to_file = autocvar_sv_logscores_file;
1440
1441         if(!final)
1442         {
1443                 to_console = TRUE; // always print printstats replies
1444                 to_eventlog = FALSE; // but never print them to the event log
1445         }
1446
1447         if(to_eventlog)
1448                 if(autocvar_sv_eventlog_console)
1449                         to_console = FALSE; // otherwise we get the output twice
1450
1451         if(final)
1452                 s = ":scores:";
1453         else
1454                 s = ":status:";
1455         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1456
1457         if(to_console)
1458                 print(s, "\n");
1459         if(to_eventlog)
1460                 GameLogEcho(s);
1461
1462         file = -1;
1463         if(to_file)
1464         {
1465                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1466                 if(file == -1)
1467                         to_file = FALSE;
1468                 else
1469                         fputs(file, strcat(s, "\n"));
1470         }
1471
1472         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1473         if(to_console)
1474                 print(s, "\n");
1475         if(to_eventlog)
1476                 GameLogEcho(s);
1477         if(to_file)
1478                 fputs(file, strcat(s, "\n"));
1479
1480         FOR_EACH_CLIENT(other)
1481         {
1482                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1483                 {
1484                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1485                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1486                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1487                                 s = strcat(s, ftos(other.team), ":");
1488                         else
1489                                 s = strcat(s, "spectator:");
1490
1491                         if(to_console)
1492                                 print(s, other.netname, "\n");
1493                         if(to_eventlog)
1494                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1495                         if(to_file)
1496                                 fputs(file, strcat(s, other.netname, "\n"));
1497                 }
1498         }
1499
1500         if(teamplay)
1501         {
1502                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1503                 if(to_console)
1504                         print(s, "\n");
1505                 if(to_eventlog)
1506                         GameLogEcho(s);
1507                 if(to_file)
1508                         fputs(file, strcat(s, "\n"));
1509
1510                 for(i = 1; i < 16; ++i)
1511                 {
1512                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1513                         s = strcat(s, ":", ftos(i));
1514                         if(to_console)
1515                                 print(s, "\n");
1516                         if(to_eventlog)
1517                                 GameLogEcho(s);
1518                         if(to_file)
1519                                 fputs(file, strcat(s, "\n"));
1520                 }
1521         }
1522
1523         if(to_console)
1524                 print(":end\n");
1525         if(to_eventlog)
1526                 GameLogEcho(":end");
1527         if(to_file)
1528         {
1529                 fputs(file, ":end\n");
1530                 fclose(file);
1531         }
1532 }
1533
1534 void FixIntermissionClient(entity e)
1535 {
1536         string s;
1537         if(!e.autoscreenshot) // initial call
1538         {
1539                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1540                 e.health = -2342;
1541                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1542                 e.solid = SOLID_NOT;
1543                 e.movetype = MOVETYPE_NONE;
1544                 e.takedamage = DAMAGE_NO;
1545                 if(e.weaponentity)
1546                 {
1547                         e.weaponentity.effects = EF_NODRAW;
1548                         if (e.weaponentity.weaponentity)
1549                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1550                 }
1551                 if(clienttype(e) == CLIENTTYPE_REAL)
1552                 {
1553                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1554                         s = autocvar_sv_intermission_cdtrack;
1555                         if(s != "")
1556                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1557                         msg_entity = e;
1558                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1559                 }
1560         }
1561 }
1562
1563 void minstagib_stop_countdown(entity e);
1564 /*
1565 go to the next level for deathmatch
1566 only called if a time or frag limit has expired
1567 */
1568 void NextLevel()
1569 {
1570         gameover = TRUE;
1571
1572         intermission_running = 1;
1573
1574 // enforce a wait time before allowing changelevel
1575         if(player_count > 0)
1576                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1577         else
1578                 intermission_exittime = -1;
1579
1580         /*
1581         WriteByte (MSG_ALL, SVC_CDTRACK);
1582         WriteByte (MSG_ALL, 3);
1583         WriteByte (MSG_ALL, 3);
1584         // done in FixIntermission
1585         */
1586
1587         //pos = FindIntermission ();
1588
1589         VoteReset();
1590
1591         DumpStats(TRUE);
1592
1593         // send statistics
1594         entity e;
1595         PlayerStats_EndMatch(1);
1596         FOR_EACH_CLIENT(e)
1597                 PlayerStats_AddGlobalInfo(e);
1598         PlayerStats_Shutdown();
1599         WeaponStats_Shutdown();
1600
1601         if(autocvar_sv_eventlog)
1602                 GameLogEcho(":gameover");
1603
1604         GameLogClose();
1605
1606         FOR_EACH_PLAYER(other) {
1607                 minstagib_stop_countdown(other);
1608                 FixIntermissionClient(other);
1609                 if(other.winning)
1610                         bprint(other.netname, " ^7wins.\n");
1611         }
1612
1613         if(autocvar_g_campaign)
1614                 CampaignPreIntermission();
1615
1616         MUTATOR_CALLHOOK(MatchEnd);
1617
1618         localcmd("\nsv_hook_gameend\n");
1619 }
1620
1621 /*
1622 ============
1623 CheckRules_Player
1624
1625 Exit deathmatch games upon conditions
1626 ============
1627 */
1628 void CheckRules_Player()
1629 {
1630         if (gameover)   // someone else quit the game already
1631                 return;
1632
1633         if(self.deadflag == DEAD_NO)
1634                 self.play_time += frametime;
1635
1636         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1637         //   (div0: and that in CheckRules_World please)
1638 }
1639
1640 float checkrules_equality;
1641 float checkrules_suddendeathwarning;
1642 float checkrules_suddendeathend;
1643 float checkrules_overtimesadded; //how many overtimes have been already added
1644
1645 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1646 float WINNING_YES = 1; // winner found
1647 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1648 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1649
1650 float InitiateSuddenDeath()
1651 {
1652         // Check first whether normal overtimes could be added before initiating suddendeath mode
1653         // - for this timelimit_overtime needs to be >0 of course
1654         // - also check the winning condition calculated in the previous frame and only add normal overtime
1655         //   again, if at the point at which timelimit would be extended again, still no winner was found
1656         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1657         {
1658                 return 1; // need to call InitiateOvertime later
1659         }
1660         else
1661         {
1662                 if(!checkrules_suddendeathend)
1663                 {
1664                         if(autocvar_g_campaign)
1665                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1666                         else
1667                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1668                         if(g_race && !g_race_qualifying)
1669                                 race_StartCompleting();
1670                 }
1671                 return 0;
1672         }
1673 }
1674
1675 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1676 {
1677         ++checkrules_overtimesadded;
1678         //add one more overtime by simply extending the timelimit
1679         float tl;
1680         tl = autocvar_timelimit;
1681         tl += autocvar_timelimit_overtime;
1682         cvar_set("timelimit", ftos(tl));
1683         string minutesPlural;
1684         if (autocvar_timelimit_overtime == 1)
1685                 minutesPlural = " ^3minute";
1686         else
1687                 minutesPlural = " ^3minutes";
1688
1689         bcenterprint(
1690                 strcat(
1691                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1692                         ftos(autocvar_timelimit_overtime),
1693                         minutesPlural,
1694                         " to the game!"
1695                 )
1696         );
1697 }
1698
1699 float GetWinningCode(float fraglimitreached, float equality)
1700 {
1701         if(autocvar_g_campaign == 1)
1702                 if(fraglimitreached)
1703                         return WINNING_YES;
1704                 else
1705                         return WINNING_NO;
1706
1707         else
1708                 if(equality)
1709                         if(fraglimitreached)
1710                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1711                         else
1712                                 return WINNING_NEVER;
1713                 else
1714                         if(fraglimitreached)
1715                                 return WINNING_YES;
1716                         else
1717                                 return WINNING_NO;
1718 }
1719
1720 // set the .winning flag for exactly those players with a given field value
1721 void SetWinners(.float field, float value)
1722 {
1723         entity head;
1724         FOR_EACH_PLAYER(head)
1725                 head.winning = (head.field == value);
1726 }
1727
1728 // set the .winning flag for those players with a given field value
1729 void AddWinners(.float field, float value)
1730 {
1731         entity head;
1732         FOR_EACH_PLAYER(head)
1733                 if(head.field == value)
1734                         head.winning = 1;
1735 }
1736
1737 // clear the .winning flags
1738 void ClearWinners(void)
1739 {
1740         entity head;
1741         FOR_EACH_PLAYER(head)
1742                 head.winning = 0;
1743 }
1744
1745 // Onslaught winning condition:
1746 // game terminates if only one team has a working generator (or none)
1747 float WinningCondition_Onslaught()
1748 {
1749         entity head;
1750         float t1, t2, t3, t4;
1751
1752         WinningConditionHelper(); // set worldstatus
1753
1754         if(inWarmupStage)
1755                 return WINNING_NO;
1756
1757         // first check if the game has ended
1758         t1 = t2 = t3 = t4 = 0;
1759         head = find(world, classname, "onslaught_generator");
1760         while (head)
1761         {
1762                 if (head.health > 0)
1763                 {
1764                         if (head.team == COLOR_TEAM1) t1 = 1;
1765                         if (head.team == COLOR_TEAM2) t2 = 1;
1766                         if (head.team == COLOR_TEAM3) t3 = 1;
1767                         if (head.team == COLOR_TEAM4) t4 = 1;
1768                 }
1769                 head = find(head, classname, "onslaught_generator");
1770         }
1771         if (t1 + t2 + t3 + t4 < 2)
1772         {
1773                 // game over, only one team remains (or none)
1774                 ClearWinners();
1775                 if (t1) SetWinners(team, COLOR_TEAM1);
1776                 if (t2) SetWinners(team, COLOR_TEAM2);
1777                 if (t3) SetWinners(team, COLOR_TEAM3);
1778                 if (t4) SetWinners(team, COLOR_TEAM4);
1779                 dprint("Have a winner, ending game.\n");
1780                 return WINNING_YES;
1781         }
1782
1783         // Two or more teams remain
1784         return WINNING_NO;
1785 }
1786
1787 float LMS_NewPlayerLives()
1788 {
1789         float fl;
1790         fl = autocvar_fraglimit;
1791         if(fl == 0)
1792                 fl = 999;
1793
1794         // first player has left the game for dying too much? Nobody else can get in.
1795         if(lms_lowest_lives < 1)
1796                 return 0;
1797
1798         if(!autocvar_g_lms_join_anytime)
1799                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1800                         return 0;
1801
1802         return bound(1, lms_lowest_lives, fl);
1803 }
1804
1805 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1806 // they win. Otherwise the defending team wins once the timelimit passes.
1807 void assault_new_round();
1808 float WinningCondition_Assault()
1809 {
1810         float status;
1811
1812         WinningConditionHelper(); // set worldstatus
1813
1814         status = WINNING_NO;
1815         // as the timelimit has not yet passed just assume the defending team will win
1816         if(assault_attacker_team == COLOR_TEAM1)
1817         {
1818                 SetWinners(team, COLOR_TEAM2);
1819         }
1820         else
1821         {
1822                 SetWinners(team, COLOR_TEAM1);
1823         }
1824
1825         entity ent;
1826         ent = find(world, classname, "target_assault_roundend");
1827         if(ent)
1828         {
1829                 if(ent.winning) // round end has been triggered by attacking team
1830                 {
1831                         bprint("ASSAULT: round completed...\n");
1832                         SetWinners(team, assault_attacker_team);
1833
1834                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1835
1836                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1837                         {
1838                                 status = WINNING_YES;
1839                         }
1840                         else
1841                         {
1842                                 entity oldself;
1843                                 oldself = self;
1844                                 self = ent;
1845                                 assault_new_round();
1846                                 self = oldself;
1847                         }
1848                 }
1849         }
1850
1851         return status;
1852 }
1853
1854 // LMS winning condition: game terminates if and only if there's at most one
1855 // one player who's living lives. Top two scores being equal cancels the time
1856 // limit.
1857 float WinningCondition_LMS()
1858 {
1859         entity head, head2;
1860         float have_player;
1861         float have_players;
1862         float l;
1863
1864         have_player = FALSE;
1865         have_players = FALSE;
1866         l = LMS_NewPlayerLives();
1867
1868         head = find(world, classname, "player");
1869         if(head)
1870                 have_player = TRUE;
1871         head2 = find(head, classname, "player");
1872         if(head2)
1873                 have_players = TRUE;
1874
1875         if(have_player)
1876         {
1877                 // we have at least one player
1878                 if(have_players)
1879                 {
1880                         // two or more active players - continue with the game
1881                 }
1882                 else
1883                 {
1884                         // exactly one player?
1885
1886                         ClearWinners();
1887                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1888
1889                         if(l)
1890                         {
1891                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1892                                 return WINNING_NO;
1893                         }
1894                         else
1895                         {
1896                                 // a winner!
1897                                 // and assign him his first place
1898                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1899                                 return WINNING_YES;
1900                         }
1901                 }
1902         }
1903         else
1904         {
1905                 // nobody is playing at all...
1906                 if(l)
1907                 {
1908                         // wait for players...
1909                 }
1910                 else
1911                 {
1912                         // SNAFU (maybe a draw game?)
1913                         ClearWinners();
1914                         dprint("No players, ending game.\n");
1915                         return WINNING_YES;
1916                 }
1917         }
1918
1919         // When we get here, we have at least two players who are actually LIVING,
1920         // now check if the top two players have equal score.
1921         WinningConditionHelper();
1922
1923         ClearWinners();
1924         if(WinningConditionHelper_winner)
1925                 WinningConditionHelper_winner.winning = TRUE;
1926         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1927                 return WINNING_NEVER;
1928
1929         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1930         return WINNING_NO;
1931 }
1932
1933 void ShuffleMaplist()
1934 {
1935         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1936 }
1937
1938 float leaderfrags;
1939 float WinningCondition_Scores(float limit, float leadlimit)
1940 {
1941         float limitreached;
1942
1943         // TODO make everything use THIS winning condition (except LMS)
1944         WinningConditionHelper();
1945
1946         if(teamplay)
1947         {
1948                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1949                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1950                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1951                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1952         }
1953
1954         ClearWinners();
1955         if(WinningConditionHelper_winner)
1956                 WinningConditionHelper_winner.winning = 1;
1957         if(WinningConditionHelper_winnerteam >= 0)
1958                 SetWinners(team, WinningConditionHelper_winnerteam);
1959
1960         if(WinningConditionHelper_lowerisbetter)
1961         {
1962                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1963                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1964                 limit = -limit;
1965         }
1966
1967         if(WinningConditionHelper_zeroisworst)
1968                 leadlimit = 0; // not supported in this mode
1969
1970         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1971         // these modes always score in increments of 1, thus this makes sense
1972         {
1973                 if(leaderfrags != WinningConditionHelper_topscore)
1974                 {
1975                         leaderfrags = WinningConditionHelper_topscore;
1976
1977                         if (limit)
1978                         if (leaderfrags == limit - 1)
1979                                 Announce("1fragleft");
1980                         else if (leaderfrags == limit - 2)
1981                                 Announce("2fragsleft");
1982                         else if (leaderfrags == limit - 3)
1983                                 Announce("3fragsleft");
1984                 }
1985         }
1986
1987         limitreached = FALSE;
1988         if(limit)
1989                 if(WinningConditionHelper_topscore >= limit)
1990                         limitreached = TRUE;
1991         if(leadlimit)
1992         {
1993                 float leadlimitreached;
1994                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1995                 if(autocvar_leadlimit_and_fraglimit)
1996                         limitreached = (limitreached && leadlimitreached);
1997                 else
1998                         limitreached = (limitreached || leadlimitreached);
1999         }
2000
2001         if(limit)
2002                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
2003
2004         return GetWinningCode(
2005                 WinningConditionHelper_topscore && limitreached,
2006                 WinningConditionHelper_equality
2007         );
2008 }
2009
2010 float WinningCondition_Race(float fraglimit)
2011 {
2012         float wc;
2013         entity p;
2014         float n, c;
2015
2016         n = 0;
2017         c = 0;
2018         FOR_EACH_PLAYER(p)
2019         {
2020                 ++n;
2021                 if(p.race_completed)
2022                         ++c;
2023         }
2024         if(n && (n == c))
2025                 return WINNING_YES;
2026         wc = WinningCondition_Scores(fraglimit, 0);
2027
2028         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2029         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2030         // do NOT support equality when the laps are all raced!
2031                 return WINNING_STARTSUDDENDEATHOVERTIME;
2032         else
2033                 return WINNING_NEVER;
2034 }
2035
2036 float WinningCondition_QualifyingThenRace(float limit)
2037 {
2038         float wc;
2039         wc = WinningCondition_Scores(limit, 0);
2040
2041         // NEVER initiate overtime
2042         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2043         {
2044                 return WINNING_YES;
2045         }
2046
2047         return wc;
2048 }
2049
2050 float WinningCondition_RanOutOfSpawns()
2051 {
2052         entity head;
2053
2054         if(have_team_spawns <= 0)
2055                 return WINNING_NO;
2056
2057         if(autocvar_g_spawn_useallspawns <= 0)
2058                 return WINNING_NO;
2059
2060         if(!some_spawn_has_been_used)
2061                 return WINNING_NO;
2062
2063         team1_score = team2_score = team3_score = team4_score = 0;
2064
2065         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2066         {
2067                 if(head.team == COLOR_TEAM1)
2068                         team1_score = 1;
2069                 else if(head.team == COLOR_TEAM2)
2070                         team2_score = 1;
2071                 else if(head.team == COLOR_TEAM3)
2072                         team3_score = 1;
2073                 else if(head.team == COLOR_TEAM4)
2074                         team4_score = 1;
2075         }
2076
2077         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2078         {
2079                 if(head.team == COLOR_TEAM1)
2080                         team1_score = 1;
2081                 else if(head.team == COLOR_TEAM2)
2082                         team2_score = 1;
2083                 else if(head.team == COLOR_TEAM3)
2084                         team3_score = 1;
2085                 else if(head.team == COLOR_TEAM4)
2086                         team4_score = 1;
2087         }
2088
2089         ClearWinners();
2090         if(team1_score + team2_score + team3_score + team4_score == 0)
2091         {
2092                 checkrules_equality = TRUE;
2093                 return WINNING_YES;
2094         }
2095         else if(team1_score + team2_score + team3_score + team4_score == 1)
2096         {
2097                 float t, i;
2098                 if(team1_score)
2099                         t = COLOR_TEAM1;
2100                 else if(team2_score)
2101                         t = COLOR_TEAM2;
2102                 else if(team3_score)
2103                         t = COLOR_TEAM3;
2104                 else // if(team4_score)
2105                         t = COLOR_TEAM4;
2106                 CheckAllowedTeams(world);
2107                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2108                 {
2109                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2110                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2111                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2112                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2113                 }
2114
2115                 AddWinners(team, t);
2116                 return WINNING_YES;
2117         }
2118         else
2119                 return WINNING_NO;
2120 }
2121
2122 /*
2123 ============
2124 CheckRules_World
2125
2126 Exit deathmatch games upon conditions
2127 ============
2128 */
2129 void ReadyRestart();
2130 void CheckRules_World()
2131 {
2132         float timelimit;
2133         float fraglimit;
2134         float leadlimit;
2135
2136         VoteThink();
2137         MapVote_Think();
2138
2139         SetDefaultAlpha();
2140
2141         /*
2142         MapVote_Think should now do that part
2143         if (intermission_running)
2144                 if (time >= intermission_exittime + 60)
2145                 {
2146                         if(!DoNextMapOverride())
2147                                 GotoNextMap();
2148                         return;
2149                 }
2150         */
2151
2152         if (gameover)   // someone else quit the game already
2153         {
2154                 if(player_count == 0) // Nobody there? Then let's go to the next map
2155                         MapVote_Start();
2156                         // this will actually check the player count in the next frame
2157                         // again, but this shouldn't hurt
2158                 return;
2159         }
2160
2161         timelimit = autocvar_timelimit * 60;
2162         fraglimit = autocvar_fraglimit;
2163         leadlimit = autocvar_leadlimit;
2164
2165         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2166         {
2167                 if(timelimit > 0)
2168                         timelimit = 0; // timelimit is not made for warmup
2169                 if(fraglimit > 0)
2170                         fraglimit = 0; // no fraglimit for now
2171                 leadlimit = 0; // no leadlimit for now
2172         }
2173
2174         if(timelimit > 0)
2175         {
2176                 timelimit += game_starttime;
2177         }
2178         else if (timelimit < 0)
2179         {
2180                 // endmatch
2181                 NextLevel();
2182                 return;
2183         }
2184
2185         if(g_onslaught)
2186                 timelimit = 0; // ONS has its own overtime rule
2187
2188         float wantovertime;
2189         wantovertime = 0;
2190
2191         if(timelimit > game_starttime)
2192                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2193         else
2194                 game_completion_ratio = 0;
2195
2196         if(checkrules_suddendeathend)
2197         {
2198                 if(!checkrules_suddendeathwarning)
2199                 {
2200                         checkrules_suddendeathwarning = TRUE;
2201                         if(g_race && !g_race_qualifying)
2202                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2203                         else
2204                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2205                 }
2206         }
2207         else
2208         {
2209                 if (timelimit && time >= timelimit)
2210                 {
2211                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2212                         {
2213                                 float totalplayers;
2214                                 float playerswithlaps;
2215                                 float readyplayers;
2216                                 entity head;
2217                                 totalplayers = playerswithlaps = readyplayers = 0;
2218                                 FOR_EACH_PLAYER(head)
2219                                 {
2220                                         ++totalplayers;
2221                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2222                                                 ++playerswithlaps;
2223                                         if(head.ready)
2224                                                 ++readyplayers;
2225                                 }
2226
2227                                 // at least 2 of the players have completed a lap: start the RACE
2228                                 // otherwise, the players should end the qualifying on their own
2229                                 if(readyplayers || playerswithlaps >= 2)
2230                                 {
2231                                         checkrules_suddendeathend = 0;
2232                                         ReadyRestart(); // go to race
2233                                         return;
2234                                 }
2235                                 else
2236                                         wantovertime |= InitiateSuddenDeath();
2237                         }
2238                         else
2239                                 wantovertime |= InitiateSuddenDeath();
2240                 }
2241         }
2242
2243         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2244         {
2245                 NextLevel();
2246                 return;
2247         }
2248
2249         float checkrules_status;
2250         checkrules_status = WinningCondition_RanOutOfSpawns();
2251         if(checkrules_status == WINNING_YES)
2252         {
2253                 bprint("Hey! Someone ran out of spawns!\n");
2254         }
2255         else if(g_race && !g_race_qualifying && timelimit >= 0)
2256         {
2257                 checkrules_status = WinningCondition_Race(fraglimit);
2258                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2259         }
2260         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2261         {
2262                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2263                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2264         }
2265         else if(g_assault)
2266         {
2267                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2268         }
2269         else if(g_lms)
2270         {
2271                 checkrules_status = WinningCondition_LMS();
2272         }
2273         else if (g_onslaught)
2274         {
2275                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2276         }
2277         else
2278         {
2279                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2280                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2281         }
2282
2283         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2284         {
2285                 checkrules_status = WINNING_NEVER;
2286                 checkrules_overtimesadded = -1;
2287                 wantovertime |= InitiateSuddenDeath();
2288         }
2289
2290         if(checkrules_status == WINNING_NEVER)
2291                 // equality cases! Nobody wins if the overtime ends in a draw.
2292                 ClearWinners();
2293
2294         if(wantovertime)
2295         {
2296                 if(checkrules_status == WINNING_NEVER)
2297                         InitiateOvertime();
2298                 else
2299                         checkrules_status = WINNING_YES;
2300         }
2301
2302         if(checkrules_suddendeathend)
2303                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2304                         checkrules_status = WINNING_YES;
2305
2306         if(checkrules_status == WINNING_YES)
2307         {
2308                 //print("WINNING\n");
2309                 NextLevel();
2310         }
2311 }
2312
2313 float mapvote_nextthink;
2314 float mapvote_initialized;
2315 float mapvote_keeptwotime;
2316 float mapvote_timeout;
2317 string mapvote_message;
2318 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2319 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2320 float mapvote_screenshot_dirs_count;
2321
2322 float mapvote_count;
2323 float mapvote_count_real;
2324 string mapvote_maps[MAPVOTE_COUNT];
2325 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2326 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2327 float mapvote_maps_suggested[MAPVOTE_COUNT];
2328 string mapvote_suggestions[MAPVOTE_COUNT];
2329 float mapvote_suggestion_ptr;
2330 float mapvote_voters;
2331 float mapvote_selections[MAPVOTE_COUNT];
2332 float mapvote_run;
2333 float mapvote_detail;
2334 float mapvote_abstain;
2335 .float mapvote;
2336
2337 void MapVote_ClearAllVotes()
2338 {
2339         FOR_EACH_CLIENT(other)
2340                 other.mapvote = 0;
2341 }
2342
2343 string MapVote_Suggest(string m)
2344 {
2345         float i;
2346         if(m == "")
2347                 return "That's not how to use this command.";
2348         if(!autocvar_g_maplist_votable_suggestions)
2349                 return "Suggestions are not accepted on this server.";
2350         if(mapvote_initialized)
2351                 return "Can't suggest - voting is already in progress!";
2352         m = MapInfo_FixName(m);
2353         if not(m)
2354                 return "The map you suggested is not available on this server.";
2355         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2356                 if(Map_IsRecent(m))
2357                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2358
2359         if(!MapInfo_CheckMap(m))
2360                 return "The map you suggested does not support the current game mode.";
2361         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2362                 if(mapvote_suggestions[i] == m)
2363                         return "This map was already suggested.";
2364         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2365         {
2366                 i = floor(random() * mapvote_suggestion_ptr);
2367         }
2368         else
2369         {
2370                 i = mapvote_suggestion_ptr;
2371                 mapvote_suggestion_ptr += 1;
2372         }
2373         if(mapvote_suggestions[i] != "")
2374                 strunzone(mapvote_suggestions[i]);
2375         mapvote_suggestions[i] = strzone(m);
2376         if(autocvar_sv_eventlog)
2377                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2378         return strcat("Suggestion of ", m, " accepted.");
2379 }
2380
2381 void MapVote_AddVotable(string nextMap, float isSuggestion)
2382 {
2383         float j, i, o;
2384         string pakfile, mapfile;
2385
2386         if(nextMap == "")
2387                 return;
2388         for(j = 0; j < mapvote_count; ++j)
2389                 if(mapvote_maps[j] == nextMap)
2390                         return;
2391         // suggestions might be no longer valid/allowed after gametype switch!
2392         if(isSuggestion)
2393                 if(!MapInfo_CheckMap(nextMap))
2394                         return;
2395         mapvote_maps[mapvote_count] = strzone(nextMap);
2396         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2397
2398         pakfile = string_null;
2399         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2400         {
2401                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2402                 pakfile = whichpack(strcat(mapfile, ".tga"));
2403                 if(pakfile == "")
2404                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2405                 if(pakfile == "")
2406                         pakfile = whichpack(strcat(mapfile, ".png"));
2407                 if(pakfile != "")
2408                         break;
2409         }
2410         if(i >= mapvote_screenshot_dirs_count)
2411                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2412         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2413                 pakfile = substring(pakfile, o, -1);
2414
2415         mapvote_maps_screenshot_dir[mapvote_count] = i;
2416         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2417
2418         mapvote_count += 1;
2419 }
2420
2421 void MapVote_Spawn();
2422 void MapVote_Init()
2423 {
2424         float i;
2425         float nmax, smax;
2426
2427         MapVote_ClearAllVotes();
2428
2429         mapvote_count = 0;
2430         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2431         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2432
2433         if(mapvote_abstain)
2434                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2435         else
2436                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2437         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2438
2439         // we need this for AddVotable, as that cycles through the screenshot dirs
2440         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2441         if(mapvote_screenshot_dirs_count == 0)
2442                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2443         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2444         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2445                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2446
2447         if(mapvote_suggestion_ptr)
2448                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2449                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2450
2451         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2452                 MapVote_AddVotable(GetNextMap(), FALSE);
2453
2454         if(mapvote_count == 0)
2455         {
2456                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2457                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2458                 if(autocvar_g_maplist_shuffle)
2459                         ShuffleMaplist();
2460                 localcmd("\nmenu_cmd sync\n");
2461                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2462                         MapVote_AddVotable(GetNextMap(), FALSE);
2463         }
2464
2465         mapvote_count_real = mapvote_count;
2466         if(mapvote_abstain)
2467                 MapVote_AddVotable("don't care", 0);
2468
2469         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2470
2471         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2472         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2473         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2474                 mapvote_keeptwotime = 0;
2475         mapvote_message = "Choose a map and press its key!";
2476
2477         MapVote_Spawn();
2478 }
2479
2480 void MapVote_SendPicture(float id)
2481 {
2482         msg_entity = self;
2483         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2484         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2485         WriteByte(MSG_ONE, id);
2486         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2487 }
2488
2489 float MapVote_GetMapMask()
2490 {
2491         float mask, i, power;
2492         mask = 0;
2493         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2494                 if(mapvote_maps[i] != "")
2495                         mask |= power;
2496         return mask;
2497 }
2498
2499 entity mapvote_ent;
2500 float MapVote_SendEntity(entity to, float sf)
2501 {
2502         float i;
2503
2504         if(sf & 1)
2505                 sf &~= 2; // if we send 1, we don't need to also send 2
2506
2507         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2508         WriteByte(MSG_ENTITY, sf);
2509
2510         if(sf & 1)
2511         {
2512                 // flag 1 == initialization
2513                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2514                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2515                 WriteString(MSG_ENTITY, "");
2516                 WriteByte(MSG_ENTITY, mapvote_count);
2517                 WriteByte(MSG_ENTITY, mapvote_abstain);
2518                 WriteByte(MSG_ENTITY, mapvote_detail);
2519                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2520                 if(mapvote_count <= 8)
2521                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2522                 else
2523                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2524                 for(i = 0; i < mapvote_count; ++i)
2525                         if(mapvote_maps[i] != "")
2526                         {
2527                                 if(mapvote_abstain && i == mapvote_count - 1)
2528                                 {
2529                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2530                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2531                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2532                                 }
2533                                 else
2534                                 {
2535                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2536                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2537                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2538                                 }
2539                         }
2540         }
2541
2542         if(sf & 2)
2543         {
2544                 // flag 2 == update of mask
2545                 if(mapvote_count <= 8)
2546                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2547                 else
2548                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2549         }
2550
2551         if(sf & 4)
2552         {
2553                 if(mapvote_detail)
2554                         for(i = 0; i < mapvote_count; ++i)
2555                                 if(mapvote_maps[i] != "")
2556                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2557
2558                 WriteByte(MSG_ENTITY, to.mapvote);
2559         }
2560
2561         return TRUE;
2562 }
2563
2564 void MapVote_Spawn()
2565 {
2566         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2567 }
2568
2569 void MapVote_TouchMask()
2570 {
2571         mapvote_ent.SendFlags |= 2;
2572 }
2573
2574 void MapVote_TouchVotes(entity voter)
2575 {
2576         mapvote_ent.SendFlags |= 4;
2577 }
2578
2579 float MapVote_Finished(float mappos)
2580 {
2581         string result;
2582         float i;
2583         float didntvote;
2584
2585         if(autocvar_sv_eventlog)
2586         {
2587                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2588                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2589                 didntvote = mapvote_voters;
2590                 for(i = 0; i < mapvote_count; ++i)
2591                         if(mapvote_maps[i] != "")
2592                         {
2593                                 didntvote -= mapvote_selections[i];
2594                                 if(i != mappos)
2595                                 {
2596                                         result = strcat(result, ":", mapvote_maps[i]);
2597                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2598                                 }
2599                         }
2600                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2601
2602                 GameLogEcho(result);
2603                 if(mapvote_maps_suggested[mappos])
2604                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2605         }
2606
2607         FOR_EACH_REALCLIENT(other)
2608                 FixClientCvars(other);
2609
2610         Map_Goto_SetStr(mapvote_maps[mappos]);
2611         Map_Goto(0);
2612         alreadychangedlevel = TRUE;
2613         return TRUE;
2614 }
2615 void MapVote_CheckRules_1()
2616 {
2617         float i;
2618
2619         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2620         {
2621                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2622                 mapvote_selections[i] = 0;
2623         }
2624
2625         mapvote_voters = 0;
2626         FOR_EACH_REALCLIENT(other)
2627         {
2628                 ++mapvote_voters;
2629                 if(other.mapvote)
2630                 {
2631                         i = other.mapvote - 1;
2632                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2633                         mapvote_selections[i] = mapvote_selections[i] + 1;
2634                 }
2635         }
2636 }
2637
2638 float MapVote_CheckRules_2()
2639 {
2640         float i;
2641         float firstPlace, secondPlace;
2642         float firstPlaceVotes, secondPlaceVotes;
2643         float mapvote_voters_real;
2644         string result;
2645
2646         if(mapvote_count_real == 1)
2647                 return MapVote_Finished(0);
2648
2649         mapvote_voters_real = mapvote_voters;
2650         if(mapvote_abstain)
2651                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2652
2653         RandomSelection_Init();
2654         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2655                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2656         firstPlace = RandomSelection_chosen_float;
2657         firstPlaceVotes = RandomSelection_best_priority;
2658         //dprint("First place: ", ftos(firstPlace), "\n");
2659         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2660
2661         RandomSelection_Init();
2662         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2663                 if(i != firstPlace)
2664                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2665         secondPlace = RandomSelection_chosen_float;
2666         secondPlaceVotes = RandomSelection_best_priority;
2667         //dprint("Second place: ", ftos(secondPlace), "\n");
2668         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2669
2670         if(firstPlace == -1)
2671                 error("No first place in map vote... WTF?");
2672
2673         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2674                 return MapVote_Finished(firstPlace);
2675
2676         if(mapvote_keeptwotime)
2677                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2678                 {
2679                         float didntvote;
2680                         MapVote_TouchMask();
2681                         mapvote_message = "Now decide between the TOP TWO!";
2682                         mapvote_keeptwotime = 0;
2683                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2684                         result = strcat(result, ":", ftos(firstPlaceVotes));
2685                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2686                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2687                         didntvote = mapvote_voters;
2688                         for(i = 0; i < mapvote_count; ++i)
2689                                 if(mapvote_maps[i] != "")
2690                                 {
2691                                         didntvote -= mapvote_selections[i];
2692                                         if(i != firstPlace)
2693                                                 if(i != secondPlace)
2694                                                 {
2695                                                         result = strcat(result, ":", mapvote_maps[i]);
2696                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2697                                                         if(i < mapvote_count_real)
2698                                                         {
2699                                                                 strunzone(mapvote_maps[i]);
2700                                                                 mapvote_maps[i] = "";
2701                                                                 strunzone(mapvote_maps_pakfile[i]);
2702                                                                 mapvote_maps_pakfile[i] = "";
2703                                                         }
2704                                                 }
2705                                 }
2706                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2707                         if(autocvar_sv_eventlog)
2708                                 GameLogEcho(result);
2709                 }
2710
2711         return FALSE;
2712 }
2713 void MapVote_Tick()
2714 {
2715         float keeptwo;
2716         float totalvotes;
2717
2718         keeptwo = mapvote_keeptwotime;
2719         MapVote_CheckRules_1(); // count
2720         if(MapVote_CheckRules_2()) // decide
2721                 return;
2722
2723         totalvotes = 0;
2724         FOR_EACH_REALCLIENT(other)
2725         {
2726                 // hide scoreboard again
2727                 if(other.health != 2342)
2728                 {
2729                         other.health = 2342;
2730                         other.impulse = 0;
2731                         if(clienttype(other) == CLIENTTYPE_REAL)
2732                         {
2733                                 msg_entity = other;
2734                                 WriteByte(MSG_ONE, SVC_FINALE);
2735                                 WriteString(MSG_ONE, "");
2736                         }
2737                 }
2738
2739                 // clear possibly invalid votes
2740                 if(mapvote_maps[other.mapvote - 1] == "")
2741                         other.mapvote = 0;
2742                 // use impulses as new vote
2743                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2744                         if(mapvote_maps[other.impulse - 1] != "")
2745                         {
2746                                 other.mapvote = other.impulse;
2747                                 MapVote_TouchVotes(other);
2748                         }
2749                 other.impulse = 0;
2750
2751                 if(other.mapvote)
2752                         ++totalvotes;
2753         }
2754
2755         MapVote_CheckRules_1(); // just count
2756 }
2757 void MapVote_Start()
2758 {
2759         if(mapvote_run)
2760                 return;
2761
2762         // wait for stats to be sent first
2763         if(!playerstats_waitforme)
2764                 return;
2765
2766         MapInfo_Enumerate();
2767         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2768                 mapvote_run = TRUE;
2769 }
2770 void MapVote_Think()
2771 {
2772         if(!mapvote_run)
2773                 return;
2774
2775         if(alreadychangedlevel)
2776                 return;
2777
2778         if(time < mapvote_nextthink)
2779                 return;
2780         //dprint("tick\n");
2781
2782         mapvote_nextthink = time + 0.5;
2783
2784         if(!mapvote_initialized)
2785         {
2786                 if(autocvar_rescan_pending == 1)
2787                 {
2788                         cvar_set("rescan_pending", "2");
2789                         localcmd("fs_rescan\nrescan_pending 3\n");
2790                         return;
2791                 }
2792                 else if(autocvar_rescan_pending == 2)
2793                 {
2794                         return;
2795                 }
2796                 else if(autocvar_rescan_pending == 3)
2797                 {
2798                         // now build missing mapinfo files
2799                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2800                                 return;
2801
2802                         // we're done, start the timer
2803                         cvar_set("rescan_pending", "0");
2804                 }
2805
2806                 mapvote_initialized = TRUE;
2807                 if(DoNextMapOverride(0))
2808                         return;
2809                 if(!autocvar_g_maplist_votable || player_count <= 0)
2810                 {
2811                         GotoNextMap(0);
2812                         return;
2813                 }
2814                 MapVote_Init();
2815         }
2816
2817         MapVote_Tick();
2818 }
2819
2820 string GotoMap(string m)
2821 {
2822         if(!MapInfo_CheckMap(m))
2823                 return "The map you chose is not available on this server.";
2824         cvar_set("nextmap", m);
2825         cvar_set("timelimit", "-1");
2826         if(mapvote_initialized || alreadychangedlevel)
2827         {
2828                 if(DoNextMapOverride(0))
2829                         return "Map switch initiated.";
2830                 else
2831                         return "Hm... no. For some reason I like THIS map more.";
2832         }
2833         else
2834                 return "Map switch will happen after scoreboard.";
2835 }
2836
2837
2838 void EndFrame()
2839 {
2840         float altime;
2841         FOR_EACH_REALCLIENT(self)
2842         {
2843                 if(self.classname == "spectator")
2844                 {
2845                         if(self.enemy.typehitsound)
2846                                 self.typehit_time = time;
2847                         else if(self.enemy.hitsound)
2848                                 self.hit_time = time;
2849                 }
2850                 else
2851                 {
2852                         if(self.typehitsound)
2853                                 self.typehit_time = time;
2854                         else if(self.hitsound)
2855                                 self.hit_time = time;
2856                 }
2857         }
2858         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2859         // add 1 frametime because after this, engine SV_Physics
2860         // increases time by a frametime and then networks the frame
2861         // add another frametime because client shows everything with
2862         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2863         // needed!
2864         FOR_EACH_CLIENT(self)
2865         {
2866                 self.hitsound = FALSE;
2867                 self.typehitsound = FALSE;
2868                 antilag_record(self, altime);
2869         }
2870 }
2871
2872
2873 /*
2874  * RedirectionThink:
2875  * returns TRUE if redirecting
2876  */
2877 float redirection_timeout;
2878 float redirection_nextthink;
2879 float RedirectionThink()
2880 {
2881         float clients_found;
2882
2883         if(redirection_target == "")
2884                 return FALSE;
2885
2886         if(!redirection_timeout)
2887         {
2888                 cvar_set("sv_public", "-2");
2889                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2890                 if(redirection_target == "self")
2891                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2892                 else
2893                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2894         }
2895
2896         if(time < redirection_nextthink)
2897                 return TRUE;
2898
2899         redirection_nextthink = time + 1;
2900
2901         clients_found = 0;
2902         FOR_EACH_REALCLIENT(self)
2903         {
2904                 // TODO add timer
2905                 print("Redirecting: sending connect command to ", self.netname, "\n");
2906                 if(redirection_target == "self")
2907                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2908                 else
2909                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2910                 ++clients_found;
2911         }
2912
2913         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2914
2915         if(time > redirection_timeout || clients_found == 0)
2916                 localcmd("\nwait; wait; wait; quit\n");
2917
2918         return TRUE;
2919 }
2920
2921 void TargetMusic_RestoreGame();
2922 void RestoreGame()
2923 {
2924         // Loaded from a save game
2925         // some things then break, so let's work around them...
2926
2927         // Progs DB (capture records)
2928         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2929
2930         // Mapinfo
2931         MapInfo_Shutdown();
2932         MapInfo_Enumerate();
2933         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2934         WeaponStats_Init();
2935
2936         TargetMusic_RestoreGame();
2937 }
2938
2939 void Shutdown()
2940 {
2941         entity e;
2942
2943         gameover = 2;
2944
2945         if(world_initialized > 0)
2946         {
2947                 world_initialized = 0;
2948                 print("Saving persistent data...\n");
2949                 Ban_SaveBans();
2950
2951                 PlayerStats_EndMatch(0);
2952                 FOR_EACH_CLIENT(e)
2953                         PlayerStats_AddGlobalInfo(e);
2954                 PlayerStats_Shutdown();
2955
2956                 if(!cheatcount_total)
2957                 {
2958                         if(autocvar_sv_db_saveasdump)
2959                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2960                         else
2961                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2962                 }
2963                 if(autocvar_developer)
2964                 {
2965                         if(autocvar_sv_db_saveasdump)
2966                                 db_dump(TemporaryDB, "server-temp.db");
2967                         else
2968                                 db_save(TemporaryDB, "server-temp.db");
2969                 }
2970                 CheatShutdown(); // must be after cheatcount check
2971                 db_close(ServerProgsDB);
2972                 db_close(TemporaryDB);
2973                 print("done!\n");
2974                 // tell the bot system the game is ending now
2975                 bot_endgame();
2976
2977                 WeaponStats_Shutdown();
2978                 MapInfo_Shutdown();
2979         }
2980         else if(world_initialized == 0)
2981         {
2982                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2983         }
2984 }