qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_assault");
 257                 BADCVAR("g_ca");
 258                 BADCVAR("g_ca_teams");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_freezetag_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_leadlimit");
 308                 BADCVAR("g_ctf_captimerecord_always");
 309                 BADCVAR("g_ctf_flag_glowtrails");
 310                 BADCVAR("g_ctf_flag_pickup_verbosename");
 311                 BADCVAR("g_domination_point_leadlimit");
 312                 BADCVAR("g_forced_respawn");
 313                 BADCVAR("g_keyhunt_point_leadlimit");
 314                 BADPREFIX("g_mod_");
 315                 BADCVAR("g_nexball_goalleadlimit");
 316                 BADCVAR("leadlimit_and_fraglimit");
 317                 BADCVAR("leadlimit_override");
 318                 BADCVAR("pausable");
 319                 BADCVAR("sv_allow_fullbright");
 320                 BADCVAR("sv_checkforpacketsduringsleep");
 321                 BADCVAR("sv_fraginfo");
 322                 BADCVAR("sv_timeout");
 323                 BADPREFIX("sv_timeout_");
 324                 BADPREFIX("crypto_");
 325                 BADPREFIX("g_chat_");
 326                 BADPREFIX("g_ctf_captimerecord_");
 327                 BADPREFIX("g_maplist_votable_");
 328                 BADPREFIX("net_");
 329                 BADPREFIX("prvm_");
 330                 BADPREFIX("skill_");
 331                 BADPREFIX("sv_cullentities_");
 332                 BADPREFIX("sv_fraginfo_");
 333                 BADPREFIX("sv_maxidle_");
 334                 BADPREFIX("sv_vote_");
 335                 BADPREFIX("timelimit_");
 336                 BADCVAR("gameversion");
 337                 BADPREFIX("gameversion_");
 338                 BADCVAR("sv_namechangetimer");
 339
 340                 // allowed changes to server admins (please sync this to server.cfg)
 341                 // vi commands:
 342                 //   :/"impure"/,$d
 343                 //   :g!,^\/\/[^ /],d
 344                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 345                 //   :%!sort
 346                 // yes, this does contain some redundant stuff, don't really care
 347                 BADCVAR("bot_config_file");
 348                 BADCVAR("bot_number");
 349                 BADCVAR("bot_prefix");
 350                 BADCVAR("bot_suffix");
 351                 BADCVAR("capturelimit_override");
 352                 BADCVAR("fraglimit_override");
 353                 BADCVAR("gametype");
 354                 BADCVAR("g_antilag");
 355                 BADCVAR("g_balance_teams");
 356                 BADCVAR("g_balance_teams_prevent_imbalance");
 357                 BADCVAR("g_balance_teams_scorefactor");
 358                 BADCVAR("g_ban_sync_trusted_servers");
 359                 BADCVAR("g_ban_sync_uri");
 360                 BADCVAR("g_ca_teams_override");
 361                 BADCVAR("g_ctf_ignore_frags");
 362                 BADCVAR("g_domination_point_limit");
 363                 BADCVAR("g_freezetag_teams_override");
 364                 BADCVAR("g_friendlyfire");
 365                 BADCVAR("g_fullbrightitems");
 366                 BADCVAR("g_fullbrightplayers");
 367                 BADCVAR("g_keyhunt_point_limit");
 368                 BADCVAR("g_keyhunt_teams_override");
 369                 BADCVAR("g_lms_lives_override");
 370                 BADCVAR("g_maplist");
 371                 BADCVAR("g_maplist_check_waypoints");
 372                 BADCVAR("g_maplist_mostrecent_count");
 373                 BADCVAR("g_maplist_shuffle");
 374                 BADCVAR("g_maplist_votable");
 375                 BADCVAR("g_maplist_votable_abstain");
 376                 BADCVAR("g_maplist_votable_nodetail");
 377                 BADCVAR("g_maplist_votable_suggestions");
 378                 BADCVAR("g_maxplayers");
 379                 BADCVAR("g_mirrordamage");
 380                 BADCVAR("g_nexball_goallimit");
 381                 BADCVAR("g_powerups");
 382                 BADCVAR("g_start_delay");
 383                 BADCVAR("g_warmup");
 384                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 385                 BADCVAR("hostname");
 386                 BADCVAR("log_file");
 387                 BADCVAR("maxplayers");
 388                 BADCVAR("minplayers");
 389                 BADCVAR("net_address");
 390                 BADCVAR("port");
 391                 BADCVAR("rcon_password");
 392                 BADCVAR("rcon_restricted_commands");
 393                 BADCVAR("rcon_restricted_password");
 394                 BADCVAR("skill");
 395                 BADCVAR("sv_adminnick");
 396                 BADCVAR("sv_autoscreenshot");
 397                 BADCVAR("sv_autotaunt");
 398                 BADCVAR("sv_curl_defaulturl");
 399                 BADCVAR("sv_defaultcharacter");
 400                 BADCVAR("sv_defaultplayercolors");
 401                 BADCVAR("sv_defaultplayermodel");
 402                 BADCVAR("sv_defaultplayerskin");
 403                 BADCVAR("sv_maxidle");
 404                 BADCVAR("sv_maxrate");
 405                 BADCVAR("sv_motd");
 406                 BADCVAR("sv_public");
 407                 BADCVAR("sv_ready_restart");
 408                 BADCVAR("sv_status_privacy");
 409                 BADCVAR("sv_taunt");
 410                 BADCVAR("sv_vote_call");
 411                 BADCVAR("sv_vote_commands");
 412                 BADCVAR("sv_vote_majority_factor");
 413                 BADCVAR("sv_vote_master");
 414                 BADCVAR("sv_vote_master_commands");
 415                 BADCVAR("sv_vote_master_password");
 416                 BADCVAR("sv_vote_simple_majority_factor");
 417                 BADCVAR("teamplay_mode");
 418                 BADCVAR("timelimit_override");
 419                 BADCVAR("g_spawnshieldtime");
 420                 BADPREFIX("g_warmup_");
 421                 BADPREFIX("sv_ready_restart_");
 422
 423                 // mutators that announce themselves properly to the server browser
 424                 BADCVAR("g_minstagib");
 425                 BADCVAR("g_new_toys");
 426                 BADCVAR("g_nix");
 427                 BADCVAR("g_grappling_hook");
 428                 BADCVAR("g_jetpack");
 429
 430 #undef BADPREFIX
 431 #undef BADCVAR
 432
 433                 if(pureadding)
 434                 {
 435                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 436                         if(strlen(cvar_purechanges) > 16384)
 437                         {
 438                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 439                                 pureadding = 0;
 440                         }
 441                 }
 442                 ++cvar_purechanges_count;
 443                 // WARNING: this variable is used for the server list
 444                 // NEVER dare to skip this code!
 445                 // Hacks to intentionally appearing as "pure server" even though you DO have
 446                 // modified settings may be punished by removal from the server list.
 447                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 448                 // though.
 449         }
 450         buf_del(h);
 451         if(cvar_changes == "")
 452                 cvar_changes = "// this server runs at default server settings\n";
 453         else
 454                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 455         cvar_changes = strzone(cvar_changes);
 456         if(cvar_purechanges == "")
 457                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 458         else
 459                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 460         cvar_purechanges = strzone(cvar_purechanges);
 461 }
 462
 463 void detect_maptype()
 464 {
 465 #if 0
 466         vector o, v;
 467         float i;
 468
 469         for(;;)
 470         {
 471                 o = world.mins;
 472                 o_x += random() * (world.maxs_x - world.mins_x);
 473                 o_y += random() * (world.maxs_y - world.mins_y);
 474                 o_z += random() * (world.maxs_z - world.mins_z);
 475
 476                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 477                 if(trace_fraction == 1)
 478                         continue;
 479
 480                 v = trace_endpos;
 481
 482                 for(i = 0; i < 64; i += 4)
 483                 {
 484                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 485         if(trace_fraction == 1)
 486                 continue;
 487                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 488                 }
 489
 490                 break;
 491         }
 492 #endif
 493 }
 494
 495 entity randomseed;
 496 float RandomSeed_Send(entity to, float sf)
 497 {
 498         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 499         WriteShort(MSG_ENTITY, self.cnt);
 500         return TRUE;
 501 }
 502 void RandomSeed_Think()
 503 {
 504         self.cnt = bound(0, floor(random() * 65536), 65535);
 505         self.nextthink = time + 5;
 506
 507         self.SendFlags |= 1;
 508 }
 509 void RandomSeed_Spawn()
 510 {
 511         randomseed = spawn();
 512         randomseed.think = RandomSeed_Think;
 513         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 514
 515         entity oldself;
 516         oldself = self;
 517         self = randomseed;
 518         self.think(); // sets random seed and nextthink
 519         self = oldself;
 520 }
 521
 522 void spawnfunc___init_dedicated_server(void)
 523 {
 524         // handler for _init/_init map (only for dedicated server initialization)
 525
 526         world_initialized = -1; // don't complain
 527         cvar = cvar_normal;
 528         cvar_string = cvar_string_normal;
 529         cvar_set = cvar_set_normal;
 530
 531         remove = remove_unsafely;
 532
 533         entity e;
 534         e = spawn();
 535         e.think = GotoFirstMap;
 536         e.nextthink = time; // this is usually 1 at this point
 537
 538         e = spawn();
 539         e.classname = "info_player_deathmatch"; // safeguard against player joining
 540
 541         self.classname = "worldspawn"; // safeguard against various stuff ;)
 542
 543         // needs to be done so early because of the constants they create
 544         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 545         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 546         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 547         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 548         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 591
 592         // needs to be done so early because of the constants they create
 593         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 594         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 595         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 596         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 597         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 598
 599         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 600
 601         TemporaryDB = db_create();
 602
 603         // 0 normal
 604         lightstyle(0, "m");
 605
 606         // 1 FLICKER (first variety)
 607         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 608
 609         // 2 SLOW STRONG PULSE
 610         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 611
 612         // 3 CANDLE (first variety)
 613         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 614
 615         // 4 FAST STROBE
 616         lightstyle(4, "mamamamamama");
 617
 618         // 5 GENTLE PULSE 1
 619         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 620
 621         // 6 FLICKER (second variety)
 622         lightstyle(6, "nmonqnmomnmomomno");
 623
 624         // 7 CANDLE (second variety)
 625         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 626
 627         // 8 CANDLE (third variety)
 628         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 629
 630         // 9 SLOW STROBE (fourth variety)
 631         lightstyle(9, "aaaaaaaazzzzzzzz");
 632
 633         // 10 FLUORESCENT FLICKER
 634         lightstyle(10, "mmamammmmammamamaaamammma");
 635
 636         // 11 SLOW PULSE NOT FADE TO BLACK
 637         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 638
 639         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 640
 641         // 63 testing
 642         lightstyle(63, "a");
 643
 644         if(autocvar_g_campaign)
 645                 CampaignPreInit();
 646
 647         Map_MarkAsRecent(mapname);
 648
 649         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 650
 651         precache_model ("null"); // we need this one before InitGameplayMode
 652         InitGameplayMode();
 653         readlevelcvars();
 654         GrappleHookInit();
 655         ElectroInit();
 656         LaserInit();
 657
 658         player_count = 0;
 659         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 660         if(bot_waypoints_for_items == 1)
 661                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 662                         bot_waypoints_for_items = 0;
 663
 664         precache();
 665
 666         WaypointSprite_Init();
 667
 668         GameLogInit(); // prepare everything
 669         // NOTE for matchid:
 670         // changing the logic generating it is okay. But:
 671         // it HAS to stay <= 64 chars
 672         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 673         if(autocvar_sv_eventlog)
 674         {
 675                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 676                 matchid = strzone(s);
 677
 678                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 679                 s = ":gameinfo:mutators:LIST";
 680
 681                 ret_string = s;
 682                 MUTATOR_CALLHOOK(BuildMutatorsString);
 683                 s = ret_string;
 684
 685                 // simple, probably not good in the mutator system
 686                 if(autocvar_g_grappling_hook)
 687                         s = strcat(s, ":grappling_hook");
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(!autocvar_g_use_ammunition)
 691                         s = strcat(s, ":no_use_ammunition");
 692
 693                 // initialiation stuff, not good in the mutator system
 694                 if(autocvar_g_pickup_items == 0)
 695                         s = strcat(s, ":no_pickup_items");
 696                 if(autocvar_g_pickup_items > 0)
 697                         s = strcat(s, ":pickup_items");
 698
 699                 // initialiation stuff, not good in the mutator system
 700                 if(autocvar_g_weaponarena != "0")
 701                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 702
 703                 // TODO to mutator system
 704                 if(autocvar_g_norecoil)
 705                         s = strcat(s, ":norecoil");
 706
 707                 // TODO to mutator system
 708                 if(autocvar_g_powerups == 0)
 709                         s = strcat(s, ":no_powerups");
 710                 if(autocvar_g_powerups > 0)
 711                         s = strcat(s, ":powerups");
 712
 713                 GameLogEcho(s);
 714                 GameLogEcho(":gameinfo:end");
 715         }
 716         else
 717                 matchid = strzone(ftos(random()));
 718
 719         cvar_set("nextmap", "");
 720
 721         SetDefaultAlpha();
 722
 723         if(autocvar_g_campaign)
 724                 CampaignPostInit();
 725
 726         fteqcc_testbugs();
 727
 728         Ban_LoadBans();
 729
 730         MapInfo_Enumerate();
 731         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 732
 733         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 734         {
 735                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 736                 if(fd != -1)
 737                 {
 738                         while((s = fgets(fd)))
 739                         {
 740                                 l = tokenize_console(s);
 741                                 if(l < 2)
 742                                         continue;
 743                                 if(argv(0) == "cd")
 744                                 {
 745                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 746                                         print("  cdtrack ", argv(2), "\n");
 747                                 }
 748                                 else if(argv(0) == "fog")
 749                                 {
 750                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 751                                         print("  \"fog\" \"", s, "\"\n");
 752                                 }
 753                                 else if(argv(0) == "set")
 754                                 {
 755                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 756                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 757                                 }
 758                                 else if(argv(0) != "//")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 761                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 762                                 }
 763                         }
 764                         fclose(fd);
 765                 }
 766         }
 767
 768         WeaponStats_Init();
 769
 770         WepSet_AddStat();
 771         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 772         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 773         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 774         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 775         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 776         Nagger_Init();
 777
 778         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 779         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 780         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 781         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 782         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 783         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 784         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 785         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 786         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 787         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 788         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 789         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 790         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 791
 792         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 793         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 794
 795         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 796
 797         // freeze attacks
 798         addstat(STAT_FROZEN, AS_INT, frozen);
 799         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 800
 801         // g_movementspeed hack
 802         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 803         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 804         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 805         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 806
 807         // secrets
 808         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 809         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 810
 811         // monsters
 812         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 813         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 814
 815         // misc
 816         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 817
 818         next_pingtime = time + 5;
 819
 820         detect_maptype();
 821
 822         // set up information replies for clients and server to use
 823         maplist_reply = strzone(getmaplist());
 824         lsmaps_reply = strzone(getlsmaps());
 825         monsterlist_reply = strzone(getmonsterlist());
 826         for(i = 0; i < 10; ++i)
 827         {
 828                 s = getrecords(i);
 829                 if (s)
 830                         records_reply[i] = strzone(s);
 831         }
 832         ladder_reply = strzone(getladder());
 833         rankings_reply = strzone(getrankings());
 834
 835         // begin other init
 836         ClientInit_Spawn();
 837         RandomSeed_Spawn();
 838         PingPLReport_Spawn();
 839
 840         CheatInit();
 841
 842         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 843
 844         // fill sv_curl_serverpackages from .serverpackage files
 845         if(autocvar_sv_curl_serverpackages_auto)
 846         {
 847                 s = "";
 848                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 849                 for(i = 0; i < n; ++i)
 850                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 851                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 852                                 s = strcat(s, " ", argv(i));
 853                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 854                 if(fd >= 0)
 855                 {
 856                         j = search_getsize(fd);
 857                         for(i = 0; i < j; ++i)
 858                                 s = strcat(s, " ", search_getfilename(fd, i));
 859                         search_end(fd);
 860                 }
 861                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 862                 if(fd >= 0)
 863                 {
 864                         j = search_getsize(fd);
 865                         for(i = 0; i < j; ++i)
 866                                 s = strcat(s, " ", search_getfilename(fd, i));
 867                         search_end(fd);
 868                 }
 869                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 870         }
 871
 872         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 873         modname = "Xonotic";
 874         // physics/balance/config changes that count as mod
 875         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 876                 modname = cvar_string("g_mod_physics");
 877         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 878                 modname = cvar_string("g_mod_balance");
 879         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 880                 modname = cvar_string("g_mod_config");
 881         // extra mutators that deserve to count as mod
 882         MUTATOR_CALLHOOK(SetModname);
 883
 884         // save it for later
 885         modname = strzone(modname);
 886
 887         WinningConditionHelper(); // set worldstatus
 888
 889         world_initialized = 1;
 890 }
 891
 892 void spawnfunc_light (void)
 893 {
 894         //makestatic (self); // Who the f___ did that?
 895         remove(self);
 896 }
 897
 898 string GetGametype()
 899 {
 900         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 901 }
 902
 903 string getmapname_stored;
 904 string GetMapname()
 905 {
 906         return mapname;
 907 }
 908
 909 float Map_Count, Map_Current;
 910 string Map_Current_Name;
 911
 912 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 913 float GetMaplistPosition()
 914 {
 915         float pos, idx;
 916         string map;
 917
 918         map = GetMapname();
 919         idx = autocvar_g_maplist_index;
 920
 921         if(idx >= 0)
 922                 if(idx < Map_Count)
 923                         if(map == argv(idx))
 924                                 return idx;
 925
 926         for(pos = 0; pos < Map_Count; ++pos)
 927                 if(map == argv(pos))
 928                         return pos;
 929
 930         // resume normal maplist rotation if current map is not in g_maplist
 931         return idx;
 932 }
 933
 934 float MapHasRightSize(string map)
 935 {
 936         float fh;
 937         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 938         if(autocvar_g_maplist_check_waypoints)
 939         {
 940                 dprint("checkwp "); dprint(map);
 941                 if(!fexists(strcat("maps/", map, ".waypoints")))
 942                 {
 943                         dprint(": no waypoints\n");
 944                         return FALSE;
 945                 }
 946                 dprint(": has waypoints\n");
 947         }
 948
 949         // open map size restriction file
 950         dprint("opensize "); dprint(map);
 951         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 952         if(fh >= 0)
 953         {
 954                 float mapmin, mapmax;
 955                 dprint(": ok, ");
 956                 mapmin = stof(fgets(fh));
 957                 mapmax = stof(fgets(fh));
 958                 fclose(fh);
 959                 if(player_count < mapmin)
 960                 {
 961                         dprint("not enough\n");
 962                         return FALSE;
 963                 }
 964                 if(player_count > mapmax)
 965                 {
 966                         dprint("too many\n");
 967                         return FALSE;
 968                 }
 969                 dprint("right size\n");
 970                 return TRUE;
 971         }
 972         dprint(": not found\n");
 973         return TRUE;
 974 }
 975
 976 string Map_Filename(float position)
 977 {
 978         return strcat("maps/", argv(position), ".bsp");
 979 }
 980
 981 string strwords(string s, float w)
 982 {
 983         float endpos;
 984         for(endpos = 0; w && endpos >= 0; --w)
 985                 endpos = strstrofs(s, " ", endpos + 1);
 986         if(endpos < 0)
 987                 return s;
 988         else
 989                 return substring(s, 0, endpos);
 990 }
 991
 992 float strhasword(string s, string w)
 993 {
 994         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 995 }
 996
 997 void Map_MarkAsRecent(string m)
 998 {
 999         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1000 }
1001
1002 float Map_IsRecent(string m)
1003 {
1004         return strhasword(autocvar_g_maplist_mostrecent, m);
1005 }
1006
1007 float Map_Check(float position, float pass)
1008 {
1009         string filename;
1010         string map_next;
1011         map_next = argv(position);
1012         if(pass <= 1)
1013         {
1014                 if(Map_IsRecent(map_next))
1015                         return 0;
1016         }
1017         filename = Map_Filename(position);
1018         if(MapInfo_CheckMap(map_next))
1019         {
1020                 if(pass == 2)
1021                         return 1;
1022                 if(MapHasRightSize(map_next))
1023                         return 1;
1024                 return 0;
1025         }
1026         else
1027                 dprint( "Couldn't select '", filename, "'..\n" );
1028
1029         return 0;
1030 }
1031
1032 void Map_Goto_SetStr(string nextmapname)
1033 {
1034         if(getmapname_stored != "")
1035                 strunzone(getmapname_stored);
1036         if(nextmapname == "")
1037                 getmapname_stored = "";
1038         else
1039                 getmapname_stored = strzone(nextmapname);
1040 }
1041
1042 void Map_Goto_SetFloat(float position)
1043 {
1044         cvar_set("g_maplist_index", ftos(position));
1045         Map_Goto_SetStr(argv(position));
1046 }
1047
1048 void Map_Goto(float reinit)
1049 {
1050         MapInfo_LoadMap(getmapname_stored, reinit);
1051 }
1052
1053 // return codes of map selectors:
1054 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1055 //   -2 = permanent failure
1056 float() MaplistMethod_Iterate = // usual method
1057 {
1058         float pass, i;
1059
1060         dprint("Trying MaplistMethod_Iterate\n");
1061
1062         for(pass = 1; pass <= 2; ++pass)
1063         {
1064                 for(i = 1; i < Map_Count; ++i)
1065                 {
1066                         float mapindex;
1067                         mapindex = mod(i + Map_Current, Map_Count);
1068                         if(Map_Check(mapindex, pass))
1069                                 return mapindex;
1070                 }
1071         }
1072         return -1;
1073 }
1074
1075 float() MaplistMethod_Repeat = // fallback method
1076 {
1077         dprint("Trying MaplistMethod_Repeat\n");
1078
1079         if(Map_Check(Map_Current, 2))
1080                 return Map_Current;
1081         return -2;
1082 }
1083
1084 float() MaplistMethod_Random = // random map selection
1085 {
1086         float i, imax;
1087
1088         dprint("Trying MaplistMethod_Random\n");
1089
1090         imax = 42;
1091
1092         for(i = 0; i <= imax; ++i)
1093         {
1094                 float mapindex;
1095                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1096                 if(Map_Check(mapindex, 1))
1097                         return mapindex;
1098         }
1099         return -1;
1100 }
1101
1102 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1103 // the exponent sets a bias on the map selection:
1104 // the higher the exponent, the less likely "shortly repeated" same maps are
1105 {
1106         float i, j, imax, insertpos;
1107
1108         dprint("Trying MaplistMethod_Shuffle\n");
1109
1110         imax = 42;
1111
1112         for(i = 0; i <= imax; ++i)
1113         {
1114                 string newlist;
1115
1116                 // now reinsert this at another position
1117                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1118                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1119                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1120                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1121
1122                 // insert the current map there
1123                 newlist = "";
1124                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1125                         newlist = strcat(newlist, " ", argv(j));
1126                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1127                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1128                         newlist = strcat(newlist, " ", argv(j));
1129                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1130                 cvar_set("g_maplist", newlist);
1131                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1132
1133                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1134                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1135                 if(Map_Check(Map_Current, 1))
1136                         return Map_Current;
1137         }
1138         return -1;
1139 }
1140
1141 void Maplist_Init()
1142 {
1143         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1144         float i;
1145         for (i = 0; i < Map_Count; ++i)
1146                 if (Map_Check(i, 2))
1147                         break;
1148         if (i == Map_Count)
1149         {
1150                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1151                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1152                 if(autocvar_g_maplist_shuffle)
1153                         ShuffleMaplist();
1154                 localcmd("\nmenu_cmd sync\n");
1155                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1156         }
1157         if(Map_Count == 0)
1158                 error("empty maplist, cannot select a new map");
1159         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1160
1161         if(Map_Current_Name)
1162                 strunzone(Map_Current_Name);
1163         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1164         // this may or may not be correct, but who cares, in the worst case a map
1165         // isn't chosen in the first pass that should have been
1166 }
1167
1168 string GetNextMap()
1169 {
1170         float nextMap;
1171
1172         Maplist_Init();
1173         nextMap = -1;
1174
1175         if(nextMap == -1)
1176                 if(autocvar_g_maplist_shuffle > 0)
1177                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1178
1179         if(nextMap == -1)
1180                 if(autocvar_g_maplist_selectrandom)
1181                         nextMap = MaplistMethod_Random();
1182
1183         if(nextMap == -1)
1184                 nextMap = MaplistMethod_Iterate();
1185
1186         if(nextMap == -1)
1187                 nextMap = MaplistMethod_Repeat();
1188
1189         if(nextMap >= 0)
1190         {
1191                 Map_Goto_SetFloat(nextMap);
1192                 return getmapname_stored;
1193         }
1194
1195         return "";
1196 }
1197
1198 float DoNextMapOverride(float reinit)
1199 {
1200         if(autocvar_g_campaign)
1201         {
1202                 CampaignPostIntermission();
1203                 alreadychangedlevel = TRUE;
1204                 return TRUE;
1205         }
1206         if(autocvar_quit_when_empty)
1207         {
1208                 if(player_count <= currentbots)
1209                 {
1210                         localcmd("quit\n");
1211                         alreadychangedlevel = TRUE;
1212                         return TRUE;
1213                 }
1214         }
1215         if(autocvar_quit_and_redirect != "")
1216         {
1217                 redirection_target = strzone(autocvar_quit_and_redirect);
1218                 alreadychangedlevel = TRUE;
1219                 return TRUE;
1220         }
1221         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1222         {
1223                 localcmd("restart\n");
1224                 alreadychangedlevel = TRUE;
1225                 return TRUE;
1226         }
1227         if(autocvar_nextmap != "")
1228                 if(MapInfo_CheckMap(autocvar_nextmap))
1229                 {
1230                         Map_Goto_SetStr(autocvar_nextmap);
1231                         Map_Goto(reinit);
1232                         alreadychangedlevel = TRUE;
1233                         return TRUE;
1234                 }
1235         if(!reinit && autocvar_lastlevel)
1236         {
1237                 cvar_settemp_restore();
1238                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1239                 alreadychangedlevel = TRUE;
1240                 return TRUE;
1241         }
1242         return FALSE;
1243 }
1244
1245 void GotoNextMap(float reinit)
1246 {
1247         //string nextmap;
1248         //float n, nummaps;
1249         //string s;
1250         if (alreadychangedlevel)
1251                 return;
1252         alreadychangedlevel = TRUE;
1253
1254         string nextMap;
1255
1256         nextMap = GetNextMap();
1257         if(nextMap == "")
1258                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1259         Map_Goto(reinit);
1260 }
1261
1262
1263 /*
1264 ============
1265 IntermissionThink
1266
1267 When the player presses attack or jump, change to the next level
1268 ============
1269 */
1270 .float autoscreenshot;
1271 void() MapVote_Start;
1272 void() MapVote_Think;
1273 float mapvote_initialized;
1274 void IntermissionThink()
1275 {
1276         FixIntermissionClient(self);
1277
1278         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1279         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1280
1281         if( (server_screenshot || client_screenshot)
1282                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1283         {
1284                 self.autoscreenshot = -1;
1285                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1286                 return;
1287         }
1288
1289         if (time < intermission_exittime)
1290                 return;
1291
1292         if(!mapvote_initialized)
1293                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1294                         return;
1295
1296         MapVote_Start();
1297 }
1298
1299 /*
1300 ============
1301 FindIntermission
1302
1303 Returns the entity to view from
1304 ============
1305 */
1306 /*
1307 entity FindIntermission()
1308 {
1309         local   entity spot;
1310         local   float cyc;
1311
1312 // look for info_intermission first
1313         spot = find (world, classname, "info_intermission");
1314         if (spot)
1315         {       // pick a random one
1316                 cyc = random() * 4;
1317                 while (cyc > 1)
1318                 {
1319                         spot = find (spot, classname, "info_intermission");
1320                         if (!spot)
1321                                 spot = find (spot, classname, "info_intermission");
1322                         cyc = cyc - 1;
1323                 }
1324                 return spot;
1325         }
1326
1327 // then look for the start position
1328         spot = find (world, classname, "info_player_start");
1329         if (spot)
1330                 return spot;
1331
1332 // testinfo_player_start is only found in regioned levels
1333         spot = find (world, classname, "testplayerstart");
1334         if (spot)
1335                 return spot;
1336
1337 // then look for the start position
1338         spot = find (world, classname, "info_player_deathmatch");
1339         if (spot)
1340                 return spot;
1341
1342         //objerror ("FindIntermission: no spot");
1343         return world;
1344 }
1345 */
1346
1347 /*
1348 ===============================================================================
1349
1350 RULES
1351
1352 ===============================================================================
1353 */
1354
1355 void DumpStats(float final)
1356 {
1357         float file;
1358         string s;
1359         float to_console;
1360         float to_eventlog;
1361         float to_file;
1362         float i;
1363
1364         to_console = autocvar_sv_logscores_console;
1365         to_eventlog = autocvar_sv_eventlog;
1366         to_file = autocvar_sv_logscores_file;
1367
1368         if(!final)
1369         {
1370                 to_console = TRUE; // always print printstats replies
1371                 to_eventlog = FALSE; // but never print them to the event log
1372         }
1373
1374         if(to_eventlog)
1375                 if(autocvar_sv_eventlog_console)
1376                         to_console = FALSE; // otherwise we get the output twice
1377
1378         if(final)
1379                 s = ":scores:";
1380         else
1381                 s = ":status:";
1382         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1383
1384         if(to_console)
1385                 print(s, "\n");
1386         if(to_eventlog)
1387                 GameLogEcho(s);
1388
1389         file = -1;
1390         if(to_file)
1391         {
1392                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1393                 if(file == -1)
1394                         to_file = FALSE;
1395                 else
1396                         fputs(file, strcat(s, "\n"));
1397         }
1398
1399         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1400         if(to_console)
1401                 print(s, "\n");
1402         if(to_eventlog)
1403                 GameLogEcho(s);
1404         if(to_file)
1405                 fputs(file, strcat(s, "\n"));
1406
1407         FOR_EACH_CLIENT(other)
1408         {
1409                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1410                 {
1411                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1412                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1413                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1414                                 s = strcat(s, ftos(other.team), ":");
1415                         else
1416                                 s = strcat(s, "spectator:");
1417
1418                         if(to_console)
1419                                 print(s, other.netname, "\n");
1420                         if(to_eventlog)
1421                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1422                         if(to_file)
1423                                 fputs(file, strcat(s, other.netname, "\n"));
1424                 }
1425         }
1426
1427         if(teamplay)
1428         {
1429                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1430                 if(to_console)
1431                         print(s, "\n");
1432                 if(to_eventlog)
1433                         GameLogEcho(s);
1434                 if(to_file)
1435                         fputs(file, strcat(s, "\n"));
1436
1437                 for(i = 1; i < 16; ++i)
1438                 {
1439                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1440                         s = strcat(s, ":", ftos(i));
1441                         if(to_console)
1442                                 print(s, "\n");
1443                         if(to_eventlog)
1444                                 GameLogEcho(s);
1445                         if(to_file)
1446                                 fputs(file, strcat(s, "\n"));
1447                 }
1448         }
1449
1450         if(to_console)
1451                 print(":end\n");
1452         if(to_eventlog)
1453                 GameLogEcho(":end");
1454         if(to_file)
1455         {
1456                 fputs(file, ":end\n");
1457                 fclose(file);
1458         }
1459 }
1460
1461 void FixIntermissionClient(entity e)
1462 {
1463         string s;
1464         if(!e.autoscreenshot) // initial call
1465         {
1466                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1467                 e.health = -2342;
1468                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1469                 e.solid = SOLID_NOT;
1470                 e.movetype = MOVETYPE_NONE;
1471                 e.takedamage = DAMAGE_NO;
1472                 if(e.weaponentity)
1473                 {
1474                         e.weaponentity.effects = EF_NODRAW;
1475                         if (e.weaponentity.weaponentity)
1476                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1477                 }
1478                 if(IS_REAL_CLIENT(e))
1479                 {
1480                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1481                         s = autocvar_sv_intermission_cdtrack;
1482                         if(s != "")
1483                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1484                         msg_entity = e;
1485                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1486                 }
1487         }
1488 }
1489
1490 /*
1491 go to the next level for deathmatch
1492 only called if a time or frag limit has expired
1493 */
1494 void NextLevel()
1495 {
1496         gameover = TRUE;
1497
1498         intermission_running = 1;
1499
1500 // enforce a wait time before allowing changelevel
1501         if(player_count > 0)
1502                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1503         else
1504                 intermission_exittime = -1;
1505
1506         /*
1507         WriteByte (MSG_ALL, SVC_CDTRACK);
1508         WriteByte (MSG_ALL, 3);
1509         WriteByte (MSG_ALL, 3);
1510         // done in FixIntermission
1511         */
1512
1513         //pos = FindIntermission ();
1514
1515         VoteReset();
1516
1517         DumpStats(TRUE);
1518
1519         // send statistics
1520         entity e;
1521         PlayerStats_EndMatch(1);
1522         FOR_EACH_CLIENT(e)
1523                 PlayerStats_AddGlobalInfo(e);
1524         PlayerStats_Shutdown();
1525         WeaponStats_Shutdown();
1526
1527         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1528
1529         if(autocvar_sv_eventlog)
1530                 GameLogEcho(":gameover");
1531
1532         GameLogClose();
1533
1534         FOR_EACH_PLAYER(other) {
1535                 FixIntermissionClient(other);
1536                 if(other.winning)
1537                         bprint(other.netname, " ^7wins.\n");
1538         }
1539
1540         if(autocvar_g_campaign)
1541                 CampaignPreIntermission();
1542
1543         MUTATOR_CALLHOOK(MatchEnd);
1544
1545         localcmd("\nsv_hook_gameend\n");
1546 }
1547
1548 /*
1549 ============
1550 CheckRules_Player
1551
1552 Exit deathmatch games upon conditions
1553 ============
1554 */
1555 void CheckRules_Player()
1556 {
1557         if (gameover)   // someone else quit the game already
1558                 return;
1559
1560         if(self.deadflag == DEAD_NO)
1561                 self.play_time += frametime;
1562
1563         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1564         //   (div0: and that in CheckRules_World please)
1565 }
1566
1567 float checkrules_equality;
1568 float checkrules_suddendeathwarning;
1569 float checkrules_suddendeathend;
1570 float checkrules_overtimesadded; //how many overtimes have been already added
1571
1572 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1573 const float WINNING_YES = 1; // winner found
1574 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1575 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1576
1577 float InitiateSuddenDeath()
1578 {
1579         // Check first whether normal overtimes could be added before initiating suddendeath mode
1580         // - for this timelimit_overtime needs to be >0 of course
1581         // - also check the winning condition calculated in the previous frame and only add normal overtime
1582         //   again, if at the point at which timelimit would be extended again, still no winner was found
1583         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1584         {
1585                 return 1; // need to call InitiateOvertime later
1586         }
1587         else
1588         {
1589                 if(!checkrules_suddendeathend)
1590                 {
1591                         if(autocvar_g_campaign)
1592                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1593                         else
1594                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1595                         if(g_race && !g_race_qualifying)
1596                                 race_StartCompleting();
1597                 }
1598                 return 0;
1599         }
1600 }
1601
1602 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1603 {
1604         ++checkrules_overtimesadded;
1605         //add one more overtime by simply extending the timelimit
1606         float tl;
1607         tl = autocvar_timelimit;
1608         tl += autocvar_timelimit_overtime;
1609         cvar_set("timelimit", ftos(tl));
1610
1611         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1612 }
1613
1614 float GetWinningCode(float fraglimitreached, float equality)
1615 {
1616         if(autocvar_g_campaign == 1)
1617                 if(fraglimitreached)
1618                         return WINNING_YES;
1619                 else
1620                         return WINNING_NO;
1621
1622         else
1623                 if(equality)
1624                         if(fraglimitreached)
1625                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1626                         else
1627                                 return WINNING_NEVER;
1628                 else
1629                         if(fraglimitreached)
1630                                 return WINNING_YES;
1631                         else
1632                                 return WINNING_NO;
1633 }
1634
1635 // set the .winning flag for exactly those players with a given field value
1636 void SetWinners(.float field, float value)
1637 {
1638         entity head;
1639         FOR_EACH_PLAYER(head)
1640                 head.winning = (head.field == value);
1641 }
1642
1643 // set the .winning flag for those players with a given field value
1644 void AddWinners(.float field, float value)
1645 {
1646         entity head;
1647         FOR_EACH_PLAYER(head)
1648                 if(head.field == value)
1649                         head.winning = 1;
1650 }
1651
1652 // clear the .winning flags
1653 void ClearWinners(void)
1654 {
1655         entity head;
1656         FOR_EACH_PLAYER(head)
1657                 head.winning = 0;
1658 }
1659
1660 // Onslaught winning condition:
1661 // game terminates if only one team has a working generator (or none)
1662 float WinningCondition_Onslaught()
1663 {
1664         entity head;
1665         float t1, t2, t3, t4;
1666
1667         WinningConditionHelper(); // set worldstatus
1668
1669         if(warmup_stage)
1670                 return WINNING_NO;
1671
1672         // first check if the game has ended
1673         t1 = t2 = t3 = t4 = 0;
1674         head = find(world, classname, "onslaught_generator");
1675         while (head)
1676         {
1677                 if (head.health > 0)
1678                 {
1679                         if (head.team == NUM_TEAM_1) t1 = 1;
1680                         if (head.team == NUM_TEAM_2) t2 = 1;
1681                         if (head.team == NUM_TEAM_3) t3 = 1;
1682                         if (head.team == NUM_TEAM_4) t4 = 1;
1683                 }
1684                 head = find(head, classname, "onslaught_generator");
1685         }
1686         if (t1 + t2 + t3 + t4 < 2)
1687         {
1688                 // game over, only one team remains (or none)
1689                 ClearWinners();
1690                 if (t1) SetWinners(team, NUM_TEAM_1);
1691                 if (t2) SetWinners(team, NUM_TEAM_2);
1692                 if (t3) SetWinners(team, NUM_TEAM_3);
1693                 if (t4) SetWinners(team, NUM_TEAM_4);
1694                 dprint("Have a winner, ending game.\n");
1695                 return WINNING_YES;
1696         }
1697
1698         // Two or more teams remain
1699         return WINNING_NO;
1700 }
1701
1702 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1703 // they win. Otherwise the defending team wins once the timelimit passes.
1704 void assault_new_round();
1705 float WinningCondition_Assault()
1706 {
1707         float status;
1708
1709         WinningConditionHelper(); // set worldstatus
1710
1711         status = WINNING_NO;
1712         // as the timelimit has not yet passed just assume the defending team will win
1713         if(assault_attacker_team == NUM_TEAM_1)
1714         {
1715                 SetWinners(team, NUM_TEAM_2);
1716         }
1717         else
1718         {
1719                 SetWinners(team, NUM_TEAM_1);
1720         }
1721
1722         entity ent;
1723         ent = find(world, classname, "target_assault_roundend");
1724         if(ent)
1725         {
1726                 if(ent.winning) // round end has been triggered by attacking team
1727                 {
1728                         bprint("ASSAULT: round completed...\n");
1729                         SetWinners(team, assault_attacker_team);
1730
1731                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1732
1733                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1734                         {
1735                                 status = WINNING_YES;
1736                         }
1737                         else
1738                         {
1739                                 entity oldself;
1740                                 oldself = self;
1741                                 self = ent;
1742                                 assault_new_round();
1743                                 self = oldself;
1744                         }
1745                 }
1746         }
1747
1748         return status;
1749 }
1750
1751 // LMS winning condition: game terminates if and only if there's at most one
1752 // one player who's living lives. Top two scores being equal cancels the time
1753 // limit.
1754 float WinningCondition_LMS()
1755 {
1756         entity head, head2;
1757         float have_player;
1758         float have_players;
1759         float l;
1760
1761         have_player = FALSE;
1762         have_players = FALSE;
1763         l = LMS_NewPlayerLives();
1764
1765         head = find(world, classname, "player");
1766         if(head)
1767                 have_player = TRUE;
1768         head2 = find(head, classname, "player");
1769         if(head2)
1770                 have_players = TRUE;
1771
1772         if(have_player)
1773         {
1774                 // we have at least one player
1775                 if(have_players)
1776                 {
1777                         // two or more active players - continue with the game
1778                 }
1779                 else
1780                 {
1781                         // exactly one player?
1782
1783                         ClearWinners();
1784                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1785
1786                         if(l)
1787                         {
1788                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1789                                 return WINNING_NO;
1790                         }
1791                         else
1792                         {
1793                                 // a winner!
1794                                 // and assign him his first place
1795                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1796                                 return WINNING_YES;
1797                         }
1798                 }
1799         }
1800         else
1801         {
1802                 // nobody is playing at all...
1803                 if(l)
1804                 {
1805                         // wait for players...
1806                 }
1807                 else
1808                 {
1809                         // SNAFU (maybe a draw game?)
1810                         ClearWinners();
1811                         dprint("No players, ending game.\n");
1812                         return WINNING_YES;
1813                 }
1814         }
1815
1816         // When we get here, we have at least two players who are actually LIVING,
1817         // now check if the top two players have equal score.
1818         WinningConditionHelper();
1819
1820         ClearWinners();
1821         if(WinningConditionHelper_winner)
1822                 WinningConditionHelper_winner.winning = TRUE;
1823         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1824                 return WINNING_NEVER;
1825
1826         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1827         return WINNING_NO;
1828 }
1829
1830 void ShuffleMaplist()
1831 {
1832         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1833 }
1834
1835 float leaderfrags;
1836 float WinningCondition_Scores(float limit, float leadlimit)
1837 {
1838         float limitreached;
1839
1840         // TODO make everything use THIS winning condition (except LMS)
1841         WinningConditionHelper();
1842
1843         if(teamplay)
1844         {
1845                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1846                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1847                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1848                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1849         }
1850
1851         ClearWinners();
1852         if(WinningConditionHelper_winner)
1853                 WinningConditionHelper_winner.winning = 1;
1854         if(WinningConditionHelper_winnerteam >= 0)
1855                 SetWinners(team, WinningConditionHelper_winnerteam);
1856
1857         if(WinningConditionHelper_lowerisbetter)
1858         {
1859                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1860                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1861                 limit = -limit;
1862         }
1863
1864         if(WinningConditionHelper_zeroisworst)
1865                 leadlimit = 0; // not supported in this mode
1866
1867         if(g_dm || g_tdm || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1868         // these modes always score in increments of 1, thus this makes sense
1869         {
1870                 if(leaderfrags != WinningConditionHelper_topscore)
1871                 {
1872                         leaderfrags = WinningConditionHelper_topscore;
1873
1874                         if (limit)
1875                         if (leaderfrags == limit - 1)
1876                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1877                         else if (leaderfrags == limit - 2)
1878                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1879                         else if (leaderfrags == limit - 3)
1880                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1881                 }
1882         }
1883
1884         limitreached = FALSE;
1885         if(limit)
1886                 if(WinningConditionHelper_topscore >= limit)
1887                         limitreached = TRUE;
1888         if(leadlimit)
1889         {
1890                 float leadlimitreached;
1891                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1892                 if(autocvar_leadlimit_and_fraglimit)
1893                         limitreached = (limitreached && leadlimitreached);
1894                 else
1895                         limitreached = (limitreached || leadlimitreached);
1896         }
1897
1898         if(limit)
1899                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1900
1901         return GetWinningCode(
1902                 WinningConditionHelper_topscore && limitreached,
1903                 WinningConditionHelper_equality
1904         );
1905 }
1906
1907 float WinningCondition_Race(float fraglimit)
1908 {
1909         float wc;
1910         entity p;
1911         float n, c;
1912
1913         n = 0;
1914         c = 0;
1915         FOR_EACH_PLAYER(p)
1916         {
1917                 ++n;
1918                 if(p.race_completed)
1919                         ++c;
1920         }
1921         if(n && (n == c))
1922                 return WINNING_YES;
1923         wc = WinningCondition_Scores(fraglimit, 0);
1924
1925         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1926         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1927         // do NOT support equality when the laps are all raced!
1928                 return WINNING_STARTSUDDENDEATHOVERTIME;
1929         else
1930                 return WINNING_NEVER;
1931 }
1932
1933 float WinningCondition_QualifyingThenRace(float limit)
1934 {
1935         float wc;
1936         wc = WinningCondition_Scores(limit, 0);
1937
1938         // NEVER initiate overtime
1939         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1940         {
1941                 return WINNING_YES;
1942         }
1943
1944         return wc;
1945 }
1946
1947 float WinningCondition_RanOutOfSpawns()
1948 {
1949         entity head;
1950
1951         if(have_team_spawns <= 0)
1952                 return WINNING_NO;
1953
1954         if(autocvar_g_spawn_useallspawns <= 0)
1955                 return WINNING_NO;
1956
1957         if(!some_spawn_has_been_used)
1958                 return WINNING_NO;
1959
1960         team1_score = team2_score = team3_score = team4_score = 0;
1961
1962         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1963         {
1964                 if(head.team == NUM_TEAM_1)
1965                         team1_score = 1;
1966                 else if(head.team == NUM_TEAM_2)
1967                         team2_score = 1;
1968                 else if(head.team == NUM_TEAM_3)
1969                         team3_score = 1;
1970                 else if(head.team == NUM_TEAM_4)
1971                         team4_score = 1;
1972         }
1973
1974         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1975         {
1976                 if(head.team == NUM_TEAM_1)
1977                         team1_score = 1;
1978                 else if(head.team == NUM_TEAM_2)
1979                         team2_score = 1;
1980                 else if(head.team == NUM_TEAM_3)
1981                         team3_score = 1;
1982                 else if(head.team == NUM_TEAM_4)
1983                         team4_score = 1;
1984         }
1985
1986         ClearWinners();
1987         if(team1_score + team2_score + team3_score + team4_score == 0)
1988         {
1989                 checkrules_equality = TRUE;
1990                 return WINNING_YES;
1991         }
1992         else if(team1_score + team2_score + team3_score + team4_score == 1)
1993         {
1994                 float t, i;
1995                 if(team1_score)
1996                         t = NUM_TEAM_1;
1997                 else if(team2_score)
1998                         t = NUM_TEAM_2;
1999                 else if(team3_score)
2000                         t = NUM_TEAM_3;
2001                 else // if(team4_score)
2002                         t = NUM_TEAM_4;
2003                 CheckAllowedTeams(world);
2004                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2005                 {
2006                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2007                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2008                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2009                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2010                 }
2011
2012                 AddWinners(team, t);
2013                 return WINNING_YES;
2014         }
2015         else
2016                 return WINNING_NO;
2017 }
2018
2019 /*
2020 ============
2021 CheckRules_World
2022
2023 Exit deathmatch games upon conditions
2024 ============
2025 */
2026 void ReadyRestart();
2027 void CheckRules_World()
2028 {
2029         float timelimit;
2030         float fraglimit;
2031         float leadlimit;
2032
2033         VoteThink();
2034         MapVote_Think();
2035
2036         SetDefaultAlpha();
2037
2038         /*
2039         MapVote_Think should now do that part
2040         if (intermission_running)
2041                 if (time >= intermission_exittime + 60)
2042                 {
2043                         if(!DoNextMapOverride())
2044                                 GotoNextMap();
2045                         return;
2046                 }
2047         */
2048
2049         if (gameover)   // someone else quit the game already
2050         {
2051                 if(player_count == 0) // Nobody there? Then let's go to the next map
2052                         MapVote_Start();
2053                         // this will actually check the player count in the next frame
2054                         // again, but this shouldn't hurt
2055                 return;
2056         }
2057
2058         timelimit = autocvar_timelimit * 60;
2059         fraglimit = autocvar_fraglimit;
2060         leadlimit = autocvar_leadlimit;
2061
2062         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2063         {
2064                 if(timelimit > 0)
2065                         timelimit = 0; // timelimit is not made for warmup
2066                 if(fraglimit > 0)
2067                         fraglimit = 0; // no fraglimit for now
2068                 leadlimit = 0; // no leadlimit for now
2069         }
2070
2071         if(timelimit > 0)
2072         {
2073                 timelimit += game_starttime;
2074         }
2075         else if (timelimit < 0)
2076         {
2077                 // endmatch
2078                 NextLevel();
2079                 return;
2080         }
2081
2082         if(g_onslaught)
2083                 timelimit = 0; // ONS has its own overtime rule
2084
2085         float wantovertime;
2086         wantovertime = 0;
2087
2088         if(timelimit > game_starttime)
2089                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2090         else
2091                 game_completion_ratio = 0;
2092
2093         if(checkrules_suddendeathend)
2094         {
2095                 if(!checkrules_suddendeathwarning)
2096                 {
2097                         checkrules_suddendeathwarning = TRUE;
2098                         if(g_race && !g_race_qualifying)
2099                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2100                         else
2101                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2102                 }
2103         }
2104         else
2105         {
2106                 if (timelimit && time >= timelimit)
2107                 {
2108                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2109                         {
2110                                 float totalplayers;
2111                                 float playerswithlaps;
2112                                 float readyplayers;
2113                                 entity head;
2114                                 totalplayers = playerswithlaps = readyplayers = 0;
2115                                 FOR_EACH_PLAYER(head)
2116                                 {
2117                                         ++totalplayers;
2118                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2119                                                 ++playerswithlaps;
2120                                         if(head.ready)
2121                                                 ++readyplayers;
2122                                 }
2123
2124                                 // at least 2 of the players have completed a lap: start the RACE
2125                                 // otherwise, the players should end the qualifying on their own
2126                                 if(readyplayers || playerswithlaps >= 2)
2127                                 {
2128                                         checkrules_suddendeathend = 0;
2129                                         ReadyRestart(); // go to race
2130                                         return;
2131                                 }
2132                                 else
2133                                         wantovertime |= InitiateSuddenDeath();
2134                         }
2135                         else
2136                                 wantovertime |= InitiateSuddenDeath();
2137                 }
2138         }
2139
2140         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2141         {
2142                 NextLevel();
2143                 return;
2144         }
2145
2146         float checkrules_status;
2147         checkrules_status = WinningCondition_RanOutOfSpawns();
2148         if(checkrules_status == WINNING_YES)
2149         {
2150                 bprint("Hey! Someone ran out of spawns!\n");
2151         }
2152         else if(g_race && !g_race_qualifying && timelimit >= 0)
2153         {
2154                 checkrules_status = WinningCondition_Race(fraglimit);
2155                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2156         }
2157         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2158         {
2159                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2160                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2161         }
2162         else if(g_assault)
2163         {
2164                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2165         }
2166         else if(g_lms)
2167         {
2168                 checkrules_status = WinningCondition_LMS();
2169         }
2170         else if (g_onslaught)
2171         {
2172                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2173         }
2174         else
2175         {
2176                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2177                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2178         }
2179
2180         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2181         {
2182                 checkrules_status = WINNING_NEVER;
2183                 checkrules_overtimesadded = -1;
2184                 wantovertime |= InitiateSuddenDeath();
2185         }
2186
2187         if(checkrules_status == WINNING_NEVER)
2188                 // equality cases! Nobody wins if the overtime ends in a draw.
2189                 ClearWinners();
2190
2191         if(wantovertime)
2192         {
2193                 if(checkrules_status == WINNING_NEVER)
2194                         InitiateOvertime();
2195                 else
2196                         checkrules_status = WINNING_YES;
2197         }
2198
2199         if(checkrules_suddendeathend)
2200                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2201                         checkrules_status = WINNING_YES;
2202
2203         if(checkrules_status == WINNING_YES)
2204         {
2205                 //print("WINNING\n");
2206                 NextLevel();
2207         }
2208 }
2209
2210 float mapvote_nextthink;
2211 float mapvote_initialized;
2212 float mapvote_keeptwotime;
2213 float mapvote_timeout;
2214 string mapvote_message;
2215 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2216 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2217 float mapvote_screenshot_dirs_count;
2218
2219 float mapvote_count;
2220 float mapvote_count_real;
2221 string mapvote_maps[MAPVOTE_COUNT];
2222 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2223 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2224 float mapvote_maps_suggested[MAPVOTE_COUNT];
2225 string mapvote_suggestions[MAPVOTE_COUNT];
2226 float mapvote_suggestion_ptr;
2227 float mapvote_voters;
2228 float mapvote_selections[MAPVOTE_COUNT];
2229 float mapvote_run;
2230 float mapvote_detail;
2231 float mapvote_abstain;
2232 .float mapvote;
2233
2234 void MapVote_ClearAllVotes()
2235 {
2236         FOR_EACH_CLIENT(other)
2237                 other.mapvote = 0;
2238 }
2239
2240 string MapVote_Suggest(string m)
2241 {
2242         float i;
2243         if(m == "")
2244                 return "That's not how to use this command.";
2245         if(!autocvar_g_maplist_votable_suggestions)
2246                 return "Suggestions are not accepted on this server.";
2247         if(mapvote_initialized)
2248                 return "Can't suggest - voting is already in progress!";
2249         m = MapInfo_FixName(m);
2250         if (!m)
2251                 return "The map you suggested is not available on this server.";
2252         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2253                 if(Map_IsRecent(m))
2254                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2255
2256         if(!MapInfo_CheckMap(m))
2257                 return "The map you suggested does not support the current game mode.";
2258         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2259                 if(mapvote_suggestions[i] == m)
2260                         return "This map was already suggested.";
2261         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2262         {
2263                 i = floor(random() * mapvote_suggestion_ptr);
2264         }
2265         else
2266         {
2267                 i = mapvote_suggestion_ptr;
2268                 mapvote_suggestion_ptr += 1;
2269         }
2270         if(mapvote_suggestions[i] != "")
2271                 strunzone(mapvote_suggestions[i]);
2272         mapvote_suggestions[i] = strzone(m);
2273         if(autocvar_sv_eventlog)
2274                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2275         return strcat("Suggestion of ", m, " accepted.");
2276 }
2277
2278 void MapVote_AddVotable(string nextMap, float isSuggestion)
2279 {
2280         float j, i, o;
2281         string pakfile, mapfile;
2282
2283         if(nextMap == "")
2284                 return;
2285         for(j = 0; j < mapvote_count; ++j)
2286                 if(mapvote_maps[j] == nextMap)
2287                         return;
2288         // suggestions might be no longer valid/allowed after gametype switch!
2289         if(isSuggestion)
2290                 if(!MapInfo_CheckMap(nextMap))
2291                         return;
2292         mapvote_maps[mapvote_count] = strzone(nextMap);
2293         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2294
2295         pakfile = string_null;
2296         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2297         {
2298                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2299                 pakfile = whichpack(strcat(mapfile, ".tga"));
2300                 if(pakfile == "")
2301                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2302                 if(pakfile == "")
2303                         pakfile = whichpack(strcat(mapfile, ".png"));
2304                 if(pakfile != "")
2305                         break;
2306         }
2307         if(i >= mapvote_screenshot_dirs_count)
2308                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2309         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2310                 pakfile = substring(pakfile, o, -1);
2311
2312         mapvote_maps_screenshot_dir[mapvote_count] = i;
2313         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2314
2315         mapvote_count += 1;
2316 }
2317
2318 void MapVote_Spawn();
2319 void MapVote_Init()
2320 {
2321         float i;
2322         float nmax, smax;
2323
2324         MapVote_ClearAllVotes();
2325
2326         mapvote_count = 0;
2327         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2328         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2329
2330         if(mapvote_abstain)
2331                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2332         else
2333                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2334         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2335
2336         // we need this for AddVotable, as that cycles through the screenshot dirs
2337         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2338         if(mapvote_screenshot_dirs_count == 0)
2339                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2340         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2341         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2342                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2343
2344         if(mapvote_suggestion_ptr)
2345                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2346                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2347
2348         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2349                 MapVote_AddVotable(GetNextMap(), FALSE);
2350
2351         if(mapvote_count == 0)
2352         {
2353                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2354                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2355                 if(autocvar_g_maplist_shuffle)
2356                         ShuffleMaplist();
2357                 localcmd("\nmenu_cmd sync\n");
2358                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2359                         MapVote_AddVotable(GetNextMap(), FALSE);
2360         }
2361
2362         mapvote_count_real = mapvote_count;
2363         if(mapvote_abstain)
2364                 MapVote_AddVotable("don't care", 0);
2365
2366         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2367
2368         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2369         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2370         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2371                 mapvote_keeptwotime = 0;
2372         mapvote_message = "Choose a map and press its key!";
2373
2374         MapVote_Spawn();
2375 }
2376
2377 void MapVote_SendPicture(float id)
2378 {
2379         msg_entity = self;
2380         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2381         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2382         WriteByte(MSG_ONE, id);
2383         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2384 }
2385
2386 float MapVote_GetMapMask()
2387 {
2388         float mask, i, power;
2389         mask = 0;
2390         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2391                 if(mapvote_maps[i] != "")
2392                         mask |= power;
2393         return mask;
2394 }
2395
2396 entity mapvote_ent;
2397 float MapVote_SendEntity(entity to, float sf)
2398 {
2399         float i;
2400
2401         if(sf & 1)
2402                 sf &= ~2; // if we send 1, we don't need to also send 2
2403
2404         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2405         WriteByte(MSG_ENTITY, sf);
2406
2407         if(sf & 1)
2408         {
2409                 // flag 1 == initialization
2410                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2411                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2412                 WriteString(MSG_ENTITY, "");
2413                 WriteByte(MSG_ENTITY, mapvote_count);
2414                 WriteByte(MSG_ENTITY, mapvote_abstain);
2415                 WriteByte(MSG_ENTITY, mapvote_detail);
2416                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2417                 if(mapvote_count <= 8)
2418                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2419                 else
2420                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2421                 for(i = 0; i < mapvote_count; ++i)
2422                         if(mapvote_maps[i] != "")
2423                         {
2424                                 if(mapvote_abstain && i == mapvote_count - 1)
2425                                 {
2426                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2427                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2428                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2429                                 }
2430                                 else
2431                                 {
2432                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2433                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2434                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2435                                 }
2436                         }
2437         }
2438
2439         if(sf & 2)
2440         {
2441                 // flag 2 == update of mask
2442                 if(mapvote_count <= 8)
2443                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2444                 else
2445                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2446         }
2447
2448         if(sf & 4)
2449         {
2450                 if(mapvote_detail)
2451                         for(i = 0; i < mapvote_count; ++i)
2452                                 if(mapvote_maps[i] != "")
2453                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2454
2455                 WriteByte(MSG_ENTITY, to.mapvote);
2456         }
2457
2458         return TRUE;
2459 }
2460
2461 void MapVote_Spawn()
2462 {
2463         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2464 }
2465
2466 void MapVote_TouchMask()
2467 {
2468         mapvote_ent.SendFlags |= 2;
2469 }
2470
2471 void MapVote_TouchVotes(entity voter)
2472 {
2473         mapvote_ent.SendFlags |= 4;
2474 }
2475
2476 float MapVote_Finished(float mappos)
2477 {
2478         string result;
2479         float i;
2480         float didntvote;
2481
2482         if(autocvar_sv_eventlog)
2483         {
2484                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2485                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2486                 didntvote = mapvote_voters;
2487                 for(i = 0; i < mapvote_count; ++i)
2488                         if(mapvote_maps[i] != "")
2489                         {
2490                                 didntvote -= mapvote_selections[i];
2491                                 if(i != mappos)
2492                                 {
2493                                         result = strcat(result, ":", mapvote_maps[i]);
2494                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2495                                 }
2496                         }
2497                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2498
2499                 GameLogEcho(result);
2500                 if(mapvote_maps_suggested[mappos])
2501                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2502         }
2503
2504         FOR_EACH_REALCLIENT(other)
2505                 FixClientCvars(other);
2506
2507         Map_Goto_SetStr(mapvote_maps[mappos]);
2508         Map_Goto(0);
2509         alreadychangedlevel = TRUE;
2510         return TRUE;
2511 }
2512 void MapVote_CheckRules_1()
2513 {
2514         float i;
2515
2516         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2517         {
2518                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2519                 mapvote_selections[i] = 0;
2520         }
2521
2522         mapvote_voters = 0;
2523         FOR_EACH_REALCLIENT(other)
2524         {
2525                 ++mapvote_voters;
2526                 if(other.mapvote)
2527                 {
2528                         i = other.mapvote - 1;
2529                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2530                         mapvote_selections[i] = mapvote_selections[i] + 1;
2531                 }
2532         }
2533 }
2534
2535 float MapVote_CheckRules_2()
2536 {
2537         float i;
2538         float firstPlace, secondPlace;
2539         float firstPlaceVotes, secondPlaceVotes;
2540         float mapvote_voters_real;
2541         string result;
2542
2543         if(mapvote_count_real == 1)
2544                 return MapVote_Finished(0);
2545
2546         mapvote_voters_real = mapvote_voters;
2547         if(mapvote_abstain)
2548                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2549
2550         RandomSelection_Init();
2551         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2552                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2553         firstPlace = RandomSelection_chosen_float;
2554         firstPlaceVotes = RandomSelection_best_priority;
2555         //dprint("First place: ", ftos(firstPlace), "\n");
2556         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2557
2558         RandomSelection_Init();
2559         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2560                 if(i != firstPlace)
2561                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2562         secondPlace = RandomSelection_chosen_float;
2563         secondPlaceVotes = RandomSelection_best_priority;
2564         //dprint("Second place: ", ftos(secondPlace), "\n");
2565         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2566
2567         if(firstPlace == -1)
2568                 error("No first place in map vote... WTF?");
2569
2570         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2571                 return MapVote_Finished(firstPlace);
2572
2573         if(mapvote_keeptwotime)
2574                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2575                 {
2576                         float didntvote;
2577                         MapVote_TouchMask();
2578                         mapvote_message = "Now decide between the TOP TWO!";
2579                         mapvote_keeptwotime = 0;
2580                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2581                         result = strcat(result, ":", ftos(firstPlaceVotes));
2582                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2583                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2584                         didntvote = mapvote_voters;
2585                         for(i = 0; i < mapvote_count; ++i)
2586                                 if(mapvote_maps[i] != "")
2587                                 {
2588                                         didntvote -= mapvote_selections[i];
2589                                         if(i != firstPlace)
2590                                                 if(i != secondPlace)
2591                                                 {
2592                                                         result = strcat(result, ":", mapvote_maps[i]);
2593                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2594                                                         if(i < mapvote_count_real)
2595                                                         {
2596                                                                 strunzone(mapvote_maps[i]);
2597                                                                 mapvote_maps[i] = "";
2598                                                                 strunzone(mapvote_maps_pakfile[i]);
2599                                                                 mapvote_maps_pakfile[i] = "";
2600                                                         }
2601                                                 }
2602                                 }
2603                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2604                         if(autocvar_sv_eventlog)
2605                                 GameLogEcho(result);
2606                 }
2607
2608         return FALSE;
2609 }
2610 void MapVote_Tick()
2611 {
2612         float keeptwo;
2613         float totalvotes;
2614
2615         keeptwo = mapvote_keeptwotime;
2616         MapVote_CheckRules_1(); // count
2617         if(MapVote_CheckRules_2()) // decide
2618                 return;
2619
2620         totalvotes = 0;
2621         FOR_EACH_REALCLIENT(other)
2622         {
2623                 // hide scoreboard again
2624                 if(other.health != 2342)
2625                 {
2626                         other.health = 2342;
2627                         other.impulse = 0;
2628                         if(IS_REAL_CLIENT(other))
2629                         {
2630                                 msg_entity = other;
2631                                 WriteByte(MSG_ONE, SVC_FINALE);
2632                                 WriteString(MSG_ONE, "");
2633                         }
2634                 }
2635
2636                 // clear possibly invalid votes
2637                 if(mapvote_maps[other.mapvote - 1] == "")
2638                         other.mapvote = 0;
2639                 // use impulses as new vote
2640                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2641                         if(mapvote_maps[other.impulse - 1] != "")
2642                         {
2643                                 other.mapvote = other.impulse;
2644                                 MapVote_TouchVotes(other);
2645                         }
2646                 other.impulse = 0;
2647
2648                 if(other.mapvote)
2649                         ++totalvotes;
2650         }
2651
2652         MapVote_CheckRules_1(); // just count
2653 }
2654 void MapVote_Start()
2655 {
2656         if(mapvote_run)
2657                 return;
2658
2659         // wait for stats to be sent first
2660         if(!playerstats_waitforme)
2661                 return;
2662
2663         MapInfo_Enumerate();
2664         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2665                 mapvote_run = TRUE;
2666 }
2667 void MapVote_Think()
2668 {
2669         if(!mapvote_run)
2670                 return;
2671
2672         if(alreadychangedlevel)
2673                 return;
2674
2675         if(time < mapvote_nextthink)
2676                 return;
2677         //dprint("tick\n");
2678
2679         mapvote_nextthink = time + 0.5;
2680
2681         if(!mapvote_initialized)
2682         {
2683                 if(autocvar_rescan_pending == 1)
2684                 {
2685                         cvar_set("rescan_pending", "2");
2686                         localcmd("fs_rescan\nrescan_pending 3\n");
2687                         return;
2688                 }
2689                 else if(autocvar_rescan_pending == 2)
2690                 {
2691                         return;
2692                 }
2693                 else if(autocvar_rescan_pending == 3)
2694                 {
2695                         // now build missing mapinfo files
2696                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2697                                 return;
2698
2699                         // we're done, start the timer
2700                         cvar_set("rescan_pending", "0");
2701                 }
2702
2703                 mapvote_initialized = TRUE;
2704                 if(DoNextMapOverride(0))
2705                         return;
2706                 if(!autocvar_g_maplist_votable || player_count <= 0)
2707                 {
2708                         GotoNextMap(0);
2709                         return;
2710                 }
2711                 MapVote_Init();
2712         }
2713
2714         MapVote_Tick();
2715 }
2716
2717 string GotoMap(string m)
2718 {
2719         if(!MapInfo_CheckMap(m))
2720                 return "The map you chose is not available on this server.";
2721         cvar_set("nextmap", m);
2722         cvar_set("timelimit", "-1");
2723         if(mapvote_initialized || alreadychangedlevel)
2724         {
2725                 if(DoNextMapOverride(0))
2726                         return "Map switch initiated.";
2727                 else
2728                         return "Hm... no. For some reason I like THIS map more.";
2729         }
2730         else
2731                 return "Map switch will happen after scoreboard.";
2732 }
2733
2734
2735 void EndFrame()
2736 {
2737         float altime;
2738         FOR_EACH_REALCLIENT(self)
2739         {
2740                 if(IS_SPEC(self))
2741                 {
2742                         if(self.enemy.typehitsound)
2743                                 self.typehit_time = time;
2744                         else if(self.enemy.hitsound)
2745                                 self.hit_time = time;
2746                 }
2747                 else
2748                 {
2749                         if(self.typehitsound)
2750                                 self.typehit_time = time;
2751                         else if(self.hitsound)
2752                                 self.hit_time = time;
2753                 }
2754         }
2755         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2756         // add 1 frametime because after this, engine SV_Physics
2757         // increases time by a frametime and then networks the frame
2758         // add another frametime because client shows everything with
2759         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2760         // needed!
2761         FOR_EACH_CLIENT(self)
2762         {
2763                 self.hitsound = FALSE;
2764                 self.typehitsound = FALSE;
2765                 antilag_record(self, altime);
2766         }
2767 }
2768
2769
2770 /*
2771  * RedirectionThink:
2772  * returns TRUE if redirecting
2773  */
2774 float redirection_timeout;
2775 float redirection_nextthink;
2776 float RedirectionThink()
2777 {
2778         float clients_found;
2779
2780         if(redirection_target == "")
2781                 return FALSE;
2782
2783         if(!redirection_timeout)
2784         {
2785                 cvar_set("sv_public", "-2");
2786                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2787                 if(redirection_target == "self")
2788                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2789                 else
2790                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2791         }
2792
2793         if(time < redirection_nextthink)
2794                 return TRUE;
2795
2796         redirection_nextthink = time + 1;
2797
2798         clients_found = 0;
2799         FOR_EACH_REALCLIENT(self)
2800         {
2801                 // TODO add timer
2802                 print("Redirecting: sending connect command to ", self.netname, "\n");
2803                 if(redirection_target == "self")
2804                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2805                 else
2806                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2807                 ++clients_found;
2808         }
2809
2810         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2811
2812         if(time > redirection_timeout || clients_found == 0)
2813                 localcmd("\nwait; wait; wait; quit\n");
2814
2815         return TRUE;
2816 }
2817
2818 void TargetMusic_RestoreGame();
2819 void RestoreGame()
2820 {
2821         // Loaded from a save game
2822         // some things then break, so let's work around them...
2823
2824         // Progs DB (capture records)
2825         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2826
2827         // Mapinfo
2828         MapInfo_Shutdown();
2829         MapInfo_Enumerate();
2830         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2831         WeaponStats_Init();
2832
2833         TargetMusic_RestoreGame();
2834 }
2835
2836 void Shutdown()
2837 {
2838         entity e;
2839
2840         gameover = 2;
2841
2842         if(world_initialized > 0)
2843         {
2844                 world_initialized = 0;
2845                 print("Saving persistent data...\n");
2846                 Ban_SaveBans();
2847
2848                 PlayerStats_EndMatch(0);
2849                 FOR_EACH_CLIENT(e)
2850                         PlayerStats_AddGlobalInfo(e);
2851                 PlayerStats_Shutdown();
2852
2853                 if(!cheatcount_total)
2854                 {
2855                         if(autocvar_sv_db_saveasdump)
2856                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2857                         else
2858                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2859                 }
2860                 if(autocvar_developer)
2861                 {
2862                         if(autocvar_sv_db_saveasdump)
2863                                 db_dump(TemporaryDB, "server-temp.db");
2864                         else
2865                                 db_save(TemporaryDB, "server-temp.db");
2866                 }
2867                 CheatShutdown(); // must be after cheatcount check
2868                 db_close(ServerProgsDB);
2869                 db_close(TemporaryDB);
2870                 print("done!\n");
2871                 // tell the bot system the game is ending now
2872                 bot_endgame();
2873
2874                 WeaponStats_Shutdown();
2875                 MapInfo_Shutdown();
2876         }
2877         else if(world_initialized == 0)
2878         {
2879                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2880         }
2881 }