qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADCVAR("welcome_message_time");
 327                 BADPREFIX("crypto_");
 328                 BADPREFIX("g_chat_");
 329                 BADPREFIX("g_ctf_captimerecord_");
 330                 BADPREFIX("g_maplist_votable_");
 331                 BADPREFIX("net_");
 332                 BADPREFIX("prvm_");
 333                 BADPREFIX("skill_");
 334                 BADPREFIX("sv_cullentities_");
 335                 BADPREFIX("sv_fraginfo_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_namechangetimer");
 342
 343                 // allowed changes to server admins (please sync this to server.cfg)
 344                 // vi commands:
 345                 //   :/"impure"/,$d
 346                 //   :g!,^\/\/[^ /],d
 347                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 348                 //   :%!sort
 349                 // yes, this does contain some redundant stuff, don't really care
 350                 BADCVAR("bot_config_file");
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_prevent_imbalance");
 360                 BADCVAR("g_balance_teams_scorefactor");
 361                 BADCVAR("g_ban_sync_trusted_servers");
 362                 BADCVAR("g_ban_sync_uri");
 363                 BADCVAR("g_ca_teams_override");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_freezetag_teams_override");
 367                 BADCVAR("g_friendlyfire");
 368                 BADCVAR("g_fullbrightitems");
 369                 BADCVAR("g_fullbrightplayers");
 370                 BADCVAR("g_keyhunt_point_limit");
 371                 BADCVAR("g_keyhunt_teams_override");
 372                 BADCVAR("g_lms_lives_override");
 373                 BADCVAR("g_maplist");
 374                 BADCVAR("g_maplist_check_waypoints");
 375                 BADCVAR("g_maplist_mostrecent_count");
 376                 BADCVAR("g_maplist_shuffle");
 377                 BADCVAR("g_maplist_votable");
 378                 BADCVAR("g_maplist_votable_abstain");
 379                 BADCVAR("g_maplist_votable_nodetail");
 380                 BADCVAR("g_maplist_votable_suggestions");
 381                 BADCVAR("g_maxplayers");
 382                 BADCVAR("g_mirrordamage");
 383                 BADCVAR("g_nexball_goallimit");
 384                 BADCVAR("g_powerups");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("sys_ticrate");
 421                 BADCVAR("teamplay_mode");
 422                 BADCVAR("timelimit_override");
 423                 BADCVAR("g_spawnshieldtime");
 424                 BADPREFIX("g_warmup_");
 425                 BADPREFIX("sv_ready_restart_");
 426
 427                 // mutators that announce themselves properly to the server browser
 428                 BADCVAR("g_minstagib");
 429                 BADCVAR("g_new_toys");
 430                 BADCVAR("g_nix");
 431
 432                 if(autocvar_g_minstagib)
 433                 {
 434                         BADCVAR("g_grappling_hook");
 435                         BADCVAR("g_jetpack");
 436                 }
 437 #undef BADPREFIX
 438 #undef BADCVAR
 439
 440                 if(pureadding)
 441                 {
 442                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 443                         if(strlen(cvar_purechanges) > 16384)
 444                         {
 445                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 446                                 pureadding = 0;
 447                         }
 448                 }
 449                 ++cvar_purechanges_count;
 450                 // WARNING: this variable is used for the server list
 451                 // NEVER dare to skip this code!
 452                 // Hacks to intentionally appearing as "pure server" even though you DO have
 453                 // modified settings may be punished by removal from the server list.
 454                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 455                 // though.
 456         }
 457         buf_del(h);
 458         if(cvar_changes == "")
 459                 cvar_changes = "// this server runs at default server settings\n";
 460         else
 461                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 462         cvar_changes = strzone(cvar_changes);
 463         if(cvar_purechanges == "")
 464                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 465         else
 466                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 467         cvar_purechanges = strzone(cvar_purechanges);
 468 }
 469
 470 void detect_maptype()
 471 {
 472 #if 0
 473         vector o, v;
 474         float i;
 475
 476         for(;;)
 477         {
 478                 o = world.mins;
 479                 o_x += random() * (world.maxs_x - world.mins_x);
 480                 o_y += random() * (world.maxs_y - world.mins_y);
 481                 o_z += random() * (world.maxs_z - world.mins_z);
 482
 483                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 484                 if(trace_fraction == 1)
 485                         continue;
 486
 487                 v = trace_endpos;
 488
 489                 for(i = 0; i < 64; i += 4)
 490                 {
 491                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 492         if(trace_fraction == 1)
 493                 continue;
 494                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 495                 }
 496
 497                 break;
 498         }
 499 #endif
 500 }
 501
 502 entity randomseed;
 503 float RandomSeed_Send(entity to, float sf)
 504 {
 505         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 506         WriteShort(MSG_ENTITY, self.cnt);
 507         return TRUE;
 508 }
 509 void RandomSeed_Think()
 510 {
 511         self.cnt = bound(0, floor(random() * 65536), 65535);
 512         self.nextthink = time + 5;
 513
 514         self.SendFlags |= 1;
 515 }
 516 void RandomSeed_Spawn()
 517 {
 518         randomseed = spawn();
 519         randomseed.think = RandomSeed_Think;
 520         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 521
 522         entity oldself;
 523         oldself = self;
 524         self = randomseed;
 525         self.think(); // sets random seed and nextthink
 526         self = oldself;
 527 }
 528
 529 void spawnfunc___init_dedicated_server(void)
 530 {
 531         // handler for _init/_init map (only for dedicated server initialization)
 532
 533         world_initialized = -1; // don't complain
 534         cvar = cvar_normal;
 535         cvar_string = cvar_string_normal;
 536         cvar_set = cvar_set_normal;
 537
 538         remove = remove_unsafely;
 539
 540         entity e;
 541         e = spawn();
 542         e.think = GotoFirstMap;
 543         e.nextthink = time; // this is usually 1 at this point
 544
 545         e = spawn();
 546         e.classname = "info_player_deathmatch"; // safeguard against player joining
 547
 548         self.classname = "worldspawn"; // safeguard against various stuff ;)
 549
 550         // needs to be done so early because of the constants they create
 551         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 552         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 553         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 554         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 555
 556         MapInfo_Enumerate();
 557         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 558 }
 559
 560 void Map_MarkAsRecent(string m);
 561 float world_already_spawned;
 562 void Nagger_Init();
 563 void ClientInit_Spawn();
 564 void WeaponStats_Init();
 565 void WeaponStats_Shutdown();
 566 void spawnfunc_worldspawn (void)
 567 {
 568         float fd, l, i, j, n;
 569         string s, col;
 570
 571         cvar = cvar_normal;
 572         cvar_string = cvar_string_normal;
 573         cvar_set = cvar_set_normal;
 574
 575         if(world_already_spawned)
 576                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 577         world_already_spawned = TRUE;
 578
 579         remove = remove_safely; // during spawning, watch what you remove!
 580
 581         check_unacceptable_compiler_bugs();
 582
 583         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 584
 585         compressShortVector_init();
 586
 587         entity head;
 588         head = nextent(world);
 589         maxclients = 0;
 590         while(head)
 591         {
 592                 ++maxclients;
 593                 head = nextent(head);
 594         }
 595
 596         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 597
 598         // needs to be done so early because of the constants they create
 599         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 600         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 601         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 602         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 603
 604         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 605
 606         TemporaryDB = db_create();
 607
 608         // 0 normal
 609         lightstyle(0, "m");
 610
 611         // 1 FLICKER (first variety)
 612         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 613
 614         // 2 SLOW STRONG PULSE
 615         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 616
 617         // 3 CANDLE (first variety)
 618         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 619
 620         // 4 FAST STROBE
 621         lightstyle(4, "mamamamamama");
 622
 623         // 5 GENTLE PULSE 1
 624         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 625
 626         // 6 FLICKER (second variety)
 627         lightstyle(6, "nmonqnmomnmomomno");
 628
 629         // 7 CANDLE (second variety)
 630         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 631
 632         // 8 CANDLE (third variety)
 633         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 634
 635         // 9 SLOW STROBE (fourth variety)
 636         lightstyle(9, "aaaaaaaazzzzzzzz");
 637
 638         // 10 FLUORESCENT FLICKER
 639         lightstyle(10, "mmamammmmammamamaaamammma");
 640
 641         // 11 SLOW PULSE NOT FADE TO BLACK
 642         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 643
 644         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 645
 646         // 63 testing
 647         lightstyle(63, "a");
 648
 649         if(autocvar_g_campaign)
 650                 CampaignPreInit();
 651
 652         Map_MarkAsRecent(mapname);
 653
 654         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 655
 656         precache_model ("null"); // we need this one before InitGameplayMode
 657         InitGameplayMode();
 658         readlevelcvars();
 659         GrappleHookInit();
 660         ElectroInit();
 661         LaserInit();
 662
 663         player_count = 0;
 664         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 665         if(bot_waypoints_for_items == 1)
 666                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 667                         bot_waypoints_for_items = 0;
 668
 669         precache();
 670
 671         WaypointSprite_Init();
 672
 673         GameLogInit(); // prepare everything
 674         // NOTE for matchid:
 675         // changing the logic generating it is okay. But:
 676         // it HAS to stay <= 64 chars
 677         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 678         if(autocvar_sv_eventlog)
 679         {
 680                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 681                 matchid = strzone(s);
 682
 683                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 684                 s = ":gameinfo:mutators:LIST";
 685
 686                 ret_string = s;
 687                 MUTATOR_CALLHOOK(BuildMutatorsString);
 688                 s = ret_string;
 689
 690                 // simple, probably not good in the mutator system
 691                 if(autocvar_g_grappling_hook)
 692                         s = strcat(s, ":grappling_hook");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(!autocvar_g_use_ammunition)
 696                         s = strcat(s, ":no_use_ammunition");
 697
 698                 // initialiation stuff, not good in the mutator system
 699                 if(autocvar_g_pickup_items == 0)
 700                         s = strcat(s, ":no_pickup_items");
 701                 if(autocvar_g_pickup_items > 0)
 702                         s = strcat(s, ":pickup_items");
 703
 704                 // initialiation stuff, not good in the mutator system
 705                 if(autocvar_g_weaponarena != "0")
 706                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_norecoil)
 710                         s = strcat(s, ":norecoil");
 711
 712                 // TODO to mutator system
 713                 if(autocvar_g_midair)
 714                         s = strcat(s, ":midair");
 715
 716                 // TODO to mutator system
 717                 if(autocvar_g_minstagib)
 718                         s = strcat(s, ":minstagib");
 719
 720                 // TODO to mutator system
 721                 if(autocvar_g_powerups == 0)
 722                         s = strcat(s, ":no_powerups");
 723                 if(autocvar_g_powerups > 0)
 724                         s = strcat(s, ":powerups");
 725
 726                 GameLogEcho(s);
 727                 GameLogEcho(":gameinfo:end");
 728         }
 729         else
 730                 matchid = strzone(ftos(random()));
 731
 732         cvar_set("nextmap", "");
 733
 734         SetDefaultAlpha();
 735
 736         if(autocvar_g_campaign)
 737                 CampaignPostInit();
 738
 739         fteqcc_testbugs();
 740
 741         Ban_LoadBans();
 742
 743         MapInfo_Enumerate();
 744         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 745
 746         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 747         {
 748                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 749                 if(fd != -1)
 750                 {
 751                         while((s = fgets(fd)))
 752                         {
 753                                 l = tokenize_console(s);
 754                                 if(l < 2)
 755                                         continue;
 756                                 if(argv(0) == "cd")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  cdtrack ", argv(2), "\n");
 760                                 }
 761                                 else if(argv(0) == "fog")
 762                                 {
 763                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 764                                         print("  \"fog\" \"", s, "\"\n");
 765                                 }
 766                                 else if(argv(0) == "set")
 767                                 {
 768                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 769                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 770                                 }
 771                                 else if(argv(0) != "//")
 772                                 {
 773                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 774                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 775                                 }
 776                         }
 777                         fclose(fd);
 778                 }
 779         }
 780
 781         WeaponStats_Init();
 782
 783         WEPSET_ADDSTAT();
 784         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 785         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 786         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 787         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 788         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 789         Nagger_Init();
 790
 791         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 792         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 793         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 794         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 795         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 796         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 797         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 798         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 799         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 800         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 801         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 802         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 803         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 804
 805         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 806         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 807
 808         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 809
 810         // g_movementspeed hack
 811         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 812         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 813         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 814         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 815
 816         // secrets
 817         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 818         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 819
 820         // misc
 821         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 822
 823         next_pingtime = time + 5;
 824
 825         detect_maptype();
 826
 827         // set up information replies for clients and server to use
 828         lsmaps_reply = "^7Maps available: ";
 829         lsnewmaps_reply = "^7Maps without a record set: ";
 830         for(i = 0, j = 0; i < MapInfo_count; ++i)
 831         {
 832                 if(MapInfo_Get_ByID(i))
 833                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 834                         {
 835                                 if(mod(i, 2))
 836                                         col = "^2";
 837                                 else
 838                                         col = "^3";
 839
 840                                 ++j;
 841
 842                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 843
 844                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 845                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 846                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 847                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 848                         }
 849         }
 850
 851         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 852         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 853
 854         maplist_reply = "^7Maps in list: ";
 855         n = tokenize_console(autocvar_g_maplist);
 856         for(i = 0, j = 0; i < n; ++i)
 857         {
 858                 if(MapInfo_CheckMap(argv(i)))
 859                 {
 860                         if(mod(j, 2))
 861                                 col = "^2";
 862                         else
 863                                 col = "^3";
 864                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 865                         ++j;
 866                 }
 867         }
 868         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 869         MapInfo_ClearTemps();
 870
 871         for(i = 0; i < 10; ++i)
 872         {
 873                 s = getrecords(i);
 874                 if (s)
 875                         records_reply[i] = strzone(s);
 876         }
 877
 878         ladder_reply = strzone(getladder());
 879
 880         rankings_reply = strzone(getrankings());
 881
 882         // begin other init
 883         ClientInit_Spawn();
 884         RandomSeed_Spawn();
 885         PingPLReport_Spawn();
 886
 887         CheatInit();
 888
 889         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 890
 891         // fill sv_curl_serverpackages from .serverpackage files
 892         if(autocvar_sv_curl_serverpackages_auto)
 893         {
 894                 s = "";
 895                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 896                 for(i = 0; i < n; ++i)
 897                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 898                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 899                                 s = strcat(s, " ", argv(i));
 900                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 901                 if(fd >= 0)
 902                 {
 903                         j = search_getsize(fd);
 904                         for(i = 0; i < j; ++i)
 905                                 s = strcat(s, " ", search_getfilename(fd, i));
 906                         search_end(fd);
 907                 }
 908                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 909                 if(fd >= 0)
 910                 {
 911                         j = search_getsize(fd);
 912                         for(i = 0; i < j; ++i)
 913                                 s = strcat(s, " ", search_getfilename(fd, i));
 914                         search_end(fd);
 915                 }
 916                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 917         }
 918
 919         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 920         modname = "Xonotic";
 921         // physics/balance/config changes that count as mod
 922         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 923                 modname = cvar_string("g_mod_physics");
 924         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 925                 modname = cvar_string("g_mod_balance");
 926         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 927                 modname = cvar_string("g_mod_config");
 928         // weird mutators that deserve to count as mod
 929         if(autocvar_g_minstagib)
 930                 modname = "MinstaGib";
 931         // extra mutators that deserve to count as mod
 932         MUTATOR_CALLHOOK(SetModname);
 933
 934         // save it for later
 935         modname = strzone(modname);
 936
 937         WinningConditionHelper(); // set worldstatus
 938
 939         world_initialized = 1;
 940 }
 941
 942 void spawnfunc_light (void)
 943 {
 944         //makestatic (self); // Who the f___ did that?
 945         remove(self);
 946 }
 947
 948 string GetGametype()
 949 {
 950         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 951 }
 952
 953 string getmapname_stored;
 954 string GetMapname()
 955 {
 956         return mapname;
 957 }
 958
 959 float Map_Count, Map_Current;
 960 string Map_Current_Name;
 961
 962 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 963 float GetMaplistPosition()
 964 {
 965         float pos, idx;
 966         string map;
 967
 968         map = GetMapname();
 969         idx = autocvar_g_maplist_index;
 970
 971         if(idx >= 0)
 972                 if(idx < Map_Count)
 973                         if(map == argv(idx))
 974                                 return idx;
 975
 976         for(pos = 0; pos < Map_Count; ++pos)
 977                 if(map == argv(pos))
 978                         return pos;
 979
 980         // resume normal maplist rotation if current map is not in g_maplist
 981         return idx;
 982 }
 983
 984 float MapHasRightSize(string map)
 985 {
 986         float fh;
 987         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 988         if(autocvar_g_maplist_check_waypoints)
 989         {
 990                 dprint("checkwp "); dprint(map);
 991                 if(!fexists(strcat("maps/", map, ".waypoints")))
 992                 {
 993                         dprint(": no waypoints\n");
 994                         return FALSE;
 995                 }
 996                 dprint(": has waypoints\n");
 997         }
 998
 999         // open map size restriction file
1000         dprint("opensize "); dprint(map);
1001         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1002         if(fh >= 0)
1003         {
1004                 float mapmin, mapmax;
1005                 dprint(": ok, ");
1006                 mapmin = stof(fgets(fh));
1007                 mapmax = stof(fgets(fh));
1008                 fclose(fh);
1009                 if(player_count < mapmin)
1010                 {
1011                         dprint("not enough\n");
1012                         return FALSE;
1013                 }
1014                 if(player_count > mapmax)
1015                 {
1016                         dprint("too many\n");
1017                         return FALSE;
1018                 }
1019                 dprint("right size\n");
1020                 return TRUE;
1021         }
1022         dprint(": not found\n");
1023         return TRUE;
1024 }
1025
1026 string Map_Filename(float position)
1027 {
1028         return strcat("maps/", argv(position), ".bsp");
1029 }
1030
1031 string strwords(string s, float w)
1032 {
1033         float endpos;
1034         for(endpos = 0; w && endpos >= 0; --w)
1035                 endpos = strstrofs(s, " ", endpos + 1);
1036         if(endpos < 0)
1037                 return s;
1038         else
1039                 return substring(s, 0, endpos);
1040 }
1041
1042 float strhasword(string s, string w)
1043 {
1044         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1045 }
1046
1047 void Map_MarkAsRecent(string m)
1048 {
1049         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1050 }
1051
1052 float Map_IsRecent(string m)
1053 {
1054         return strhasword(autocvar_g_maplist_mostrecent, m);
1055 }
1056
1057 float Map_Check(float position, float pass)
1058 {
1059         string filename;
1060         string map_next;
1061         map_next = argv(position);
1062         if(pass <= 1)
1063         {
1064                 if(Map_IsRecent(map_next))
1065                         return 0;
1066         }
1067         filename = Map_Filename(position);
1068         if(MapInfo_CheckMap(map_next))
1069         {
1070                 if(pass == 2)
1071                         return 1;
1072                 if(MapHasRightSize(map_next))
1073                         return 1;
1074                 return 0;
1075         }
1076         else
1077                 dprint( "Couldn't select '", filename, "'..\n" );
1078
1079         return 0;
1080 }
1081
1082 void Map_Goto_SetStr(string nextmapname)
1083 {
1084         if(getmapname_stored != "")
1085                 strunzone(getmapname_stored);
1086         if(nextmapname == "")
1087                 getmapname_stored = "";
1088         else
1089                 getmapname_stored = strzone(nextmapname);
1090 }
1091
1092 void Map_Goto_SetFloat(float position)
1093 {
1094         cvar_set("g_maplist_index", ftos(position));
1095         Map_Goto_SetStr(argv(position));
1096 }
1097
1098 void Map_Goto(float reinit)
1099 {
1100         MapInfo_LoadMap(getmapname_stored, reinit);
1101 }
1102
1103 // return codes of map selectors:
1104 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1105 //   -2 = permanent failure
1106 float() MaplistMethod_Iterate = // usual method
1107 {
1108         float pass, i;
1109
1110         for(pass = 1; pass <= 2; ++pass)
1111         {
1112                 for(i = 1; i < Map_Count; ++i)
1113                 {
1114                         float mapindex;
1115                         mapindex = mod(i + Map_Current, Map_Count);
1116                         if(Map_Check(mapindex, pass))
1117                                 return mapindex;
1118                 }
1119         }
1120         return -1;
1121 }
1122
1123 float() MaplistMethod_Repeat = // fallback method
1124 {
1125         if(Map_Check(Map_Current, 2))
1126                 return Map_Current;
1127         return -2;
1128 }
1129
1130 float() MaplistMethod_Random = // random map selection
1131 {
1132         float i, imax;
1133
1134         imax = 42;
1135
1136         for(i = 0; i <= imax; ++i)
1137         {
1138                 float mapindex;
1139                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1140                 if(Map_Check(mapindex, 1))
1141                         return mapindex;
1142         }
1143         return -1;
1144 }
1145
1146 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1147 // the exponent sets a bias on the map selection:
1148 // the higher the exponent, the less likely "shortly repeated" same maps are
1149 {
1150         float i, j, imax, insertpos;
1151
1152         imax = 42;
1153
1154         for(i = 0; i <= imax; ++i)
1155         {
1156                 string newlist;
1157
1158                 // now reinsert this at another position
1159                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1160                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1161                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1162                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1163
1164                 // insert the current map there
1165                 newlist = "";
1166                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1167                         newlist = strcat(newlist, " ", argv(j));
1168                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1169                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1170                         newlist = strcat(newlist, " ", argv(j));
1171                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1172                 cvar_set("g_maplist", newlist);
1173                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1174
1175                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1176                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1177                 if(Map_Check(Map_Current, 1))
1178                         return Map_Current;
1179         }
1180         return -1;
1181 }
1182
1183 void Maplist_Init()
1184 {
1185         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1186         if(Map_Count == 0)
1187         {
1188                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1189                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1190                 if(autocvar_g_maplist_shuffle)
1191                         ShuffleMaplist();
1192                 localcmd("\nmenu_cmd sync\n");
1193                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194         }
1195         if(Map_Count == 0)
1196                 error("empty maplist, cannot select a new map");
1197         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1198
1199         if(Map_Current_Name)
1200                 strunzone(Map_Current_Name);
1201         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1202         // this may or may not be correct, but who cares, in the worst case a map
1203         // isn't chosen in the first pass that should have been
1204 }
1205
1206 string GetNextMap()
1207 {
1208         float nextMap;
1209
1210         Maplist_Init();
1211         nextMap = -1;
1212
1213         if(nextMap == -1)
1214                 if(autocvar_g_maplist_shuffle > 0)
1215                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1216
1217         if(nextMap == -1)
1218                 if(autocvar_g_maplist_selectrandom)
1219                         nextMap = MaplistMethod_Random();
1220
1221         if(nextMap == -1)
1222                 nextMap = MaplistMethod_Iterate();
1223
1224         if(nextMap == -1)
1225                 nextMap = MaplistMethod_Repeat();
1226
1227         if(nextMap >= 0)
1228         {
1229                 Map_Goto_SetFloat(nextMap);
1230                 return getmapname_stored;
1231         }
1232
1233         return "";
1234 }
1235
1236 float DoNextMapOverride(float reinit)
1237 {
1238         if(autocvar_g_campaign)
1239         {
1240                 CampaignPostIntermission();
1241                 alreadychangedlevel = TRUE;
1242                 return TRUE;
1243         }
1244         if(autocvar_quit_when_empty)
1245         {
1246                 if(player_count <= currentbots)
1247                 {
1248                         localcmd("quit\n");
1249                         alreadychangedlevel = TRUE;
1250                         return TRUE;
1251                 }
1252         }
1253         if(autocvar_quit_and_redirect != "")
1254         {
1255                 redirection_target = strzone(autocvar_quit_and_redirect);
1256                 alreadychangedlevel = TRUE;
1257                 return TRUE;
1258         }
1259         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1260         {
1261                 localcmd("restart\n");
1262                 alreadychangedlevel = TRUE;
1263                 return TRUE;
1264         }
1265         if(autocvar_nextmap != "")
1266                 if(MapInfo_CheckMap(autocvar_nextmap))
1267                 {
1268                         Map_Goto_SetStr(autocvar_nextmap);
1269                         Map_Goto(reinit);
1270                         alreadychangedlevel = TRUE;
1271                         return TRUE;
1272                 }
1273         if(!reinit && autocvar_lastlevel)
1274         {
1275                 cvar_settemp_restore();
1276                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1277                 alreadychangedlevel = TRUE;
1278                 return TRUE;
1279         }
1280         return FALSE;
1281 }
1282
1283 void GotoNextMap(float reinit)
1284 {
1285         //string nextmap;
1286         //float n, nummaps;
1287         //string s;
1288         if (alreadychangedlevel)
1289                 return;
1290         alreadychangedlevel = TRUE;
1291
1292         {
1293                 string nextMap;
1294                 float allowReset;
1295
1296                 for(allowReset = 1; allowReset >= 0; --allowReset)
1297                 {
1298                         nextMap = GetNextMap();
1299                         if(nextMap != "")
1300                                 break;
1301
1302                         if(allowReset)
1303                         {
1304                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1305                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1306                                 if(autocvar_g_maplist_shuffle)
1307                                         ShuffleMaplist();
1308                                 localcmd("\nmenu_cmd sync\n");
1309                         }
1310                         else
1311                         {
1312                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1313                         }
1314                 }
1315                 Map_Goto(reinit);
1316         }
1317 }
1318
1319
1320 /*
1321 ============
1322 IntermissionThink
1323
1324 When the player presses attack or jump, change to the next level
1325 ============
1326 */
1327 .float autoscreenshot;
1328 void() MapVote_Start;
1329 void() MapVote_Think;
1330 float mapvote_initialized;
1331 void IntermissionThink()
1332 {
1333         FixIntermissionClient(self);
1334
1335         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1336         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1337
1338         if( (server_screenshot || client_screenshot)
1339                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1340         {
1341                 self.autoscreenshot = -1;
1342                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1343                 return;
1344         }
1345
1346         if (time < intermission_exittime)
1347                 return;
1348
1349         if(!mapvote_initialized)
1350                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1351                         return;
1352
1353         MapVote_Start();
1354 }
1355
1356 /*
1357 ============
1358 FindIntermission
1359
1360 Returns the entity to view from
1361 ============
1362 */
1363 /*
1364 entity FindIntermission()
1365 {
1366         local   entity spot;
1367         local   float cyc;
1368
1369 // look for info_intermission first
1370         spot = find (world, classname, "info_intermission");
1371         if (spot)
1372         {       // pick a random one
1373                 cyc = random() * 4;
1374                 while (cyc > 1)
1375                 {
1376                         spot = find (spot, classname, "info_intermission");
1377                         if (!spot)
1378                                 spot = find (spot, classname, "info_intermission");
1379                         cyc = cyc - 1;
1380                 }
1381                 return spot;
1382         }
1383
1384 // then look for the start position
1385         spot = find (world, classname, "info_player_start");
1386         if (spot)
1387                 return spot;
1388
1389 // testinfo_player_start is only found in regioned levels
1390         spot = find (world, classname, "testplayerstart");
1391         if (spot)
1392                 return spot;
1393
1394 // then look for the start position
1395         spot = find (world, classname, "info_player_deathmatch");
1396         if (spot)
1397                 return spot;
1398
1399         //objerror ("FindIntermission: no spot");
1400         return world;
1401 }
1402 */
1403
1404 /*
1405 ===============================================================================
1406
1407 RULES
1408
1409 ===============================================================================
1410 */
1411
1412 void DumpStats(float final)
1413 {
1414         float file;
1415         string s;
1416         float to_console;
1417         float to_eventlog;
1418         float to_file;
1419         float i;
1420
1421         to_console = autocvar_sv_logscores_console;
1422         to_eventlog = autocvar_sv_eventlog;
1423         to_file = autocvar_sv_logscores_file;
1424
1425         if(!final)
1426         {
1427                 to_console = TRUE; // always print printstats replies
1428                 to_eventlog = FALSE; // but never print them to the event log
1429         }
1430
1431         if(to_eventlog)
1432                 if(autocvar_sv_eventlog_console)
1433                         to_console = FALSE; // otherwise we get the output twice
1434
1435         if(final)
1436                 s = ":scores:";
1437         else
1438                 s = ":status:";
1439         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1440
1441         if(to_console)
1442                 print(s, "\n");
1443         if(to_eventlog)
1444                 GameLogEcho(s);
1445
1446         file = -1;
1447         if(to_file)
1448         {
1449                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1450                 if(file == -1)
1451                         to_file = FALSE;
1452                 else
1453                         fputs(file, strcat(s, "\n"));
1454         }
1455
1456         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1457         if(to_console)
1458                 print(s, "\n");
1459         if(to_eventlog)
1460                 GameLogEcho(s);
1461         if(to_file)
1462                 fputs(file, strcat(s, "\n"));
1463
1464         FOR_EACH_CLIENT(other)
1465         {
1466                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1467                 {
1468                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1469                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1470                         if(other.classname == "player" || g_arena || other.caplayer == 1 || g_lms)
1471                                 s = strcat(s, ftos(other.team), ":");
1472                         else
1473                                 s = strcat(s, "spectator:");
1474
1475                         if(to_console)
1476                                 print(s, other.netname, "\n");
1477                         if(to_eventlog)
1478                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1479                         if(to_file)
1480                                 fputs(file, strcat(s, other.netname, "\n"));
1481                 }
1482         }
1483
1484         if(teamplay)
1485         {
1486                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1487                 if(to_console)
1488                         print(s, "\n");
1489                 if(to_eventlog)
1490                         GameLogEcho(s);
1491                 if(to_file)
1492                         fputs(file, strcat(s, "\n"));
1493
1494                 for(i = 1; i < 16; ++i)
1495                 {
1496                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1497                         s = strcat(s, ":", ftos(i));
1498                         if(to_console)
1499                                 print(s, "\n");
1500                         if(to_eventlog)
1501                                 GameLogEcho(s);
1502                         if(to_file)
1503                                 fputs(file, strcat(s, "\n"));
1504                 }
1505         }
1506
1507         if(to_console)
1508                 print(":end\n");
1509         if(to_eventlog)
1510                 GameLogEcho(":end");
1511         if(to_file)
1512         {
1513                 fputs(file, ":end\n");
1514                 fclose(file);
1515         }
1516 }
1517
1518 void FixIntermissionClient(entity e)
1519 {
1520         string s;
1521         if(!e.autoscreenshot) // initial call
1522         {
1523                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1524                 e.health = -2342;
1525                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1526                 e.solid = SOLID_NOT;
1527                 e.movetype = MOVETYPE_NONE;
1528                 e.takedamage = DAMAGE_NO;
1529                 if(e.weaponentity)
1530                 {
1531                         e.weaponentity.effects = EF_NODRAW;
1532                         if (e.weaponentity.weaponentity)
1533                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1534                 }
1535                 if(clienttype(e) == CLIENTTYPE_REAL)
1536                 {
1537                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1538                         s = autocvar_sv_intermission_cdtrack;
1539                         if(s != "")
1540                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1541                         msg_entity = e;
1542                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1543                 }
1544         }
1545 }
1546
1547 void minstagib_stop_countdown(entity e);
1548 /*
1549 go to the next level for deathmatch
1550 only called if a time or frag limit has expired
1551 */
1552 void NextLevel()
1553 {
1554         gameover = TRUE;
1555
1556         intermission_running = 1;
1557
1558 // enforce a wait time before allowing changelevel
1559         if(player_count > 0)
1560                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1561         else
1562                 intermission_exittime = -1;
1563
1564         /*
1565         WriteByte (MSG_ALL, SVC_CDTRACK);
1566         WriteByte (MSG_ALL, 3);
1567         WriteByte (MSG_ALL, 3);
1568         // done in FixIntermission
1569         */
1570
1571         //pos = FindIntermission ();
1572
1573         VoteReset();
1574
1575         DumpStats(TRUE);
1576
1577         // send statistics
1578         entity e;
1579         PlayerStats_EndMatch(1);
1580         FOR_EACH_CLIENT(e)
1581                 PlayerStats_AddGlobalInfo(e);
1582         PlayerStats_Shutdown();
1583         WeaponStats_Shutdown();
1584
1585         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1586
1587         if(autocvar_sv_eventlog)
1588                 GameLogEcho(":gameover");
1589
1590         GameLogClose();
1591
1592         FOR_EACH_PLAYER(other) {
1593                 minstagib_stop_countdown(other);
1594                 FixIntermissionClient(other);
1595                 if(other.winning)
1596                         bprint(other.netname, " ^7wins.\n");
1597         }
1598
1599         if(autocvar_g_campaign)
1600                 CampaignPreIntermission();
1601
1602         MUTATOR_CALLHOOK(MatchEnd);
1603
1604         localcmd("\nsv_hook_gameend\n");
1605 }
1606
1607 /*
1608 ============
1609 CheckRules_Player
1610
1611 Exit deathmatch games upon conditions
1612 ============
1613 */
1614 void CheckRules_Player()
1615 {
1616         if (gameover)   // someone else quit the game already
1617                 return;
1618
1619         if(self.deadflag == DEAD_NO)
1620                 self.play_time += frametime;
1621
1622         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1623         //   (div0: and that in CheckRules_World please)
1624 }
1625
1626 float checkrules_equality;
1627 float checkrules_suddendeathwarning;
1628 float checkrules_suddendeathend;
1629 float checkrules_overtimesadded; //how many overtimes have been already added
1630
1631 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1632 float WINNING_YES = 1; // winner found
1633 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1634 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1635
1636 float InitiateSuddenDeath()
1637 {
1638         // Check first whether normal overtimes could be added before initiating suddendeath mode
1639         // - for this timelimit_overtime needs to be >0 of course
1640         // - also check the winning condition calculated in the previous frame and only add normal overtime
1641         //   again, if at the point at which timelimit would be extended again, still no winner was found
1642         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1643         {
1644                 return 1; // need to call InitiateOvertime later
1645         }
1646         else
1647         {
1648                 if(!checkrules_suddendeathend)
1649                 {
1650                         if(autocvar_g_campaign)
1651                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1652                         else
1653                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1654                         if(g_race && !g_race_qualifying)
1655                                 race_StartCompleting();
1656                 }
1657                 return 0;
1658         }
1659 }
1660
1661 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1662 {
1663         ++checkrules_overtimesadded;
1664         //add one more overtime by simply extending the timelimit
1665         float tl;
1666         tl = autocvar_timelimit;
1667         tl += autocvar_timelimit_overtime;
1668         cvar_set("timelimit", ftos(tl));
1669
1670         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1671 }
1672
1673 float GetWinningCode(float fraglimitreached, float equality)
1674 {
1675         if(autocvar_g_campaign == 1)
1676                 if(fraglimitreached)
1677                         return WINNING_YES;
1678                 else
1679                         return WINNING_NO;
1680
1681         else
1682                 if(equality)
1683                         if(fraglimitreached)
1684                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1685                         else
1686                                 return WINNING_NEVER;
1687                 else
1688                         if(fraglimitreached)
1689                                 return WINNING_YES;
1690                         else
1691                                 return WINNING_NO;
1692 }
1693
1694 // set the .winning flag for exactly those players with a given field value
1695 void SetWinners(.float field, float value)
1696 {
1697         entity head;
1698         FOR_EACH_PLAYER(head)
1699                 head.winning = (head.field == value);
1700 }
1701
1702 // set the .winning flag for those players with a given field value
1703 void AddWinners(.float field, float value)
1704 {
1705         entity head;
1706         FOR_EACH_PLAYER(head)
1707                 if(head.field == value)
1708                         head.winning = 1;
1709 }
1710
1711 // clear the .winning flags
1712 void ClearWinners(void)
1713 {
1714         entity head;
1715         FOR_EACH_PLAYER(head)
1716                 head.winning = 0;
1717 }
1718
1719 // Onslaught winning condition:
1720 // game terminates if only one team has a working generator (or none)
1721 float WinningCondition_Onslaught()
1722 {
1723         entity head;
1724         float t1, t2, t3, t4;
1725
1726         WinningConditionHelper(); // set worldstatus
1727
1728         if(inWarmupStage)
1729                 return WINNING_NO;
1730
1731         // first check if the game has ended
1732         t1 = t2 = t3 = t4 = 0;
1733         head = find(world, classname, "onslaught_generator");
1734         while (head)
1735         {
1736                 if (head.health > 0)
1737                 {
1738                         if (head.team == NUM_TEAM_1) t1 = 1;
1739                         if (head.team == NUM_TEAM_2) t2 = 1;
1740                         if (head.team == NUM_TEAM_3) t3 = 1;
1741                         if (head.team == NUM_TEAM_4) t4 = 1;
1742                 }
1743                 head = find(head, classname, "onslaught_generator");
1744         }
1745         if (t1 + t2 + t3 + t4 < 2)
1746         {
1747                 // game over, only one team remains (or none)
1748                 ClearWinners();
1749                 if (t1) SetWinners(team, NUM_TEAM_1);
1750                 if (t2) SetWinners(team, NUM_TEAM_2);
1751                 if (t3) SetWinners(team, NUM_TEAM_3);
1752                 if (t4) SetWinners(team, NUM_TEAM_4);
1753                 dprint("Have a winner, ending game.\n");
1754                 return WINNING_YES;
1755         }
1756
1757         // Two or more teams remain
1758         return WINNING_NO;
1759 }
1760
1761 float LMS_NewPlayerLives()
1762 {
1763         float fl;
1764         fl = autocvar_fraglimit;
1765         if(fl == 0)
1766                 fl = 999;
1767
1768         // first player has left the game for dying too much? Nobody else can get in.
1769         if(lms_lowest_lives < 1)
1770                 return 0;
1771
1772         if(!autocvar_g_lms_join_anytime)
1773                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1774                         return 0;
1775
1776         return bound(1, lms_lowest_lives, fl);
1777 }
1778
1779 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1780 // they win. Otherwise the defending team wins once the timelimit passes.
1781 void assault_new_round();
1782 float WinningCondition_Assault()
1783 {
1784         float status;
1785
1786         WinningConditionHelper(); // set worldstatus
1787
1788         status = WINNING_NO;
1789         // as the timelimit has not yet passed just assume the defending team will win
1790         if(assault_attacker_team == NUM_TEAM_1)
1791         {
1792                 SetWinners(team, NUM_TEAM_2);
1793         }
1794         else
1795         {
1796                 SetWinners(team, NUM_TEAM_1);
1797         }
1798
1799         entity ent;
1800         ent = find(world, classname, "target_assault_roundend");
1801         if(ent)
1802         {
1803                 if(ent.winning) // round end has been triggered by attacking team
1804                 {
1805                         bprint("ASSAULT: round completed...\n");
1806                         SetWinners(team, assault_attacker_team);
1807
1808                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1809
1810                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1811                         {
1812                                 status = WINNING_YES;
1813                         }
1814                         else
1815                         {
1816                                 entity oldself;
1817                                 oldself = self;
1818                                 self = ent;
1819                                 assault_new_round();
1820                                 self = oldself;
1821                         }
1822                 }
1823         }
1824
1825         return status;
1826 }
1827
1828 // LMS winning condition: game terminates if and only if there's at most one
1829 // one player who's living lives. Top two scores being equal cancels the time
1830 // limit.
1831 float WinningCondition_LMS()
1832 {
1833         entity head, head2;
1834         float have_player;
1835         float have_players;
1836         float l;
1837
1838         have_player = FALSE;
1839         have_players = FALSE;
1840         l = LMS_NewPlayerLives();
1841
1842         head = find(world, classname, "player");
1843         if(head)
1844                 have_player = TRUE;
1845         head2 = find(head, classname, "player");
1846         if(head2)
1847                 have_players = TRUE;
1848
1849         if(have_player)
1850         {
1851                 // we have at least one player
1852                 if(have_players)
1853                 {
1854                         // two or more active players - continue with the game
1855                 }
1856                 else
1857                 {
1858                         // exactly one player?
1859
1860                         ClearWinners();
1861                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1862
1863                         if(l)
1864                         {
1865                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1866                                 return WINNING_NO;
1867                         }
1868                         else
1869                         {
1870                                 // a winner!
1871                                 // and assign him his first place
1872                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1873                                 return WINNING_YES;
1874                         }
1875                 }
1876         }
1877         else
1878         {
1879                 // nobody is playing at all...
1880                 if(l)
1881                 {
1882                         // wait for players...
1883                 }
1884                 else
1885                 {
1886                         // SNAFU (maybe a draw game?)
1887                         ClearWinners();
1888                         dprint("No players, ending game.\n");
1889                         return WINNING_YES;
1890                 }
1891         }
1892
1893         // When we get here, we have at least two players who are actually LIVING,
1894         // now check if the top two players have equal score.
1895         WinningConditionHelper();
1896
1897         ClearWinners();
1898         if(WinningConditionHelper_winner)
1899                 WinningConditionHelper_winner.winning = TRUE;
1900         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1901                 return WINNING_NEVER;
1902
1903         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1904         return WINNING_NO;
1905 }
1906
1907 void ShuffleMaplist()
1908 {
1909         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1910 }
1911
1912 float leaderfrags;
1913 float WinningCondition_Scores(float limit, float leadlimit)
1914 {
1915         float limitreached;
1916
1917         // TODO make everything use THIS winning condition (except LMS)
1918         WinningConditionHelper();
1919
1920         if(teamplay)
1921         {
1922                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1923                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1924                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1925                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1926         }
1927
1928         ClearWinners();
1929         if(WinningConditionHelper_winner)
1930                 WinningConditionHelper_winner.winning = 1;
1931         if(WinningConditionHelper_winnerteam >= 0)
1932                 SetWinners(team, WinningConditionHelper_winnerteam);
1933
1934         if(WinningConditionHelper_lowerisbetter)
1935         {
1936                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1937                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1938                 limit = -limit;
1939         }
1940
1941         if(WinningConditionHelper_zeroisworst)
1942                 leadlimit = 0; // not supported in this mode
1943
1944         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1945         // these modes always score in increments of 1, thus this makes sense
1946         {
1947                 if(leaderfrags != WinningConditionHelper_topscore)
1948                 {
1949                         leaderfrags = WinningConditionHelper_topscore;
1950
1951                         if (limit)
1952                         if (leaderfrags == limit - 1)
1953                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1954                         else if (leaderfrags == limit - 2)
1955                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1956                         else if (leaderfrags == limit - 3)
1957                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1958                 }
1959         }
1960
1961         limitreached = FALSE;
1962         if(limit)
1963                 if(WinningConditionHelper_topscore >= limit)
1964                         limitreached = TRUE;
1965         if(leadlimit)
1966         {
1967                 float leadlimitreached;
1968                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1969                 if(autocvar_leadlimit_and_fraglimit)
1970                         limitreached = (limitreached && leadlimitreached);
1971                 else
1972                         limitreached = (limitreached || leadlimitreached);
1973         }
1974
1975         if(limit)
1976                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1977
1978         return GetWinningCode(
1979                 WinningConditionHelper_topscore && limitreached,
1980                 WinningConditionHelper_equality
1981         );
1982 }
1983
1984 float WinningCondition_Race(float fraglimit)
1985 {
1986         float wc;
1987         entity p;
1988         float n, c;
1989
1990         n = 0;
1991         c = 0;
1992         FOR_EACH_PLAYER(p)
1993         {
1994                 ++n;
1995                 if(p.race_completed)
1996                         ++c;
1997         }
1998         if(n && (n == c))
1999                 return WINNING_YES;
2000         wc = WinningCondition_Scores(fraglimit, 0);
2001
2002         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2003         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2004         // do NOT support equality when the laps are all raced!
2005                 return WINNING_STARTSUDDENDEATHOVERTIME;
2006         else
2007                 return WINNING_NEVER;
2008 }
2009
2010 float WinningCondition_QualifyingThenRace(float limit)
2011 {
2012         float wc;
2013         wc = WinningCondition_Scores(limit, 0);
2014
2015         // NEVER initiate overtime
2016         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2017         {
2018                 return WINNING_YES;
2019         }
2020
2021         return wc;
2022 }
2023
2024 float WinningCondition_RanOutOfSpawns()
2025 {
2026         entity head;
2027
2028         if(have_team_spawns <= 0)
2029                 return WINNING_NO;
2030
2031         if(autocvar_g_spawn_useallspawns <= 0)
2032                 return WINNING_NO;
2033
2034         if(!some_spawn_has_been_used)
2035                 return WINNING_NO;
2036
2037         team1_score = team2_score = team3_score = team4_score = 0;
2038
2039         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2040         {
2041                 if(head.team == NUM_TEAM_1)
2042                         team1_score = 1;
2043                 else if(head.team == NUM_TEAM_2)
2044                         team2_score = 1;
2045                 else if(head.team == NUM_TEAM_3)
2046                         team3_score = 1;
2047                 else if(head.team == NUM_TEAM_4)
2048                         team4_score = 1;
2049         }
2050
2051         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2052         {
2053                 if(head.team == NUM_TEAM_1)
2054                         team1_score = 1;
2055                 else if(head.team == NUM_TEAM_2)
2056                         team2_score = 1;
2057                 else if(head.team == NUM_TEAM_3)
2058                         team3_score = 1;
2059                 else if(head.team == NUM_TEAM_4)
2060                         team4_score = 1;
2061         }
2062
2063         ClearWinners();
2064         if(team1_score + team2_score + team3_score + team4_score == 0)
2065         {
2066                 checkrules_equality = TRUE;
2067                 return WINNING_YES;
2068         }
2069         else if(team1_score + team2_score + team3_score + team4_score == 1)
2070         {
2071                 float t, i;
2072                 if(team1_score)
2073                         t = NUM_TEAM_1;
2074                 else if(team2_score)
2075                         t = NUM_TEAM_2;
2076                 else if(team3_score)
2077                         t = NUM_TEAM_3;
2078                 else // if(team4_score)
2079                         t = NUM_TEAM_4;
2080                 CheckAllowedTeams(world);
2081                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2082                 {
2083                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2084                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2085                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2086                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2087                 }
2088
2089                 AddWinners(team, t);
2090                 return WINNING_YES;
2091         }
2092         else
2093                 return WINNING_NO;
2094 }
2095
2096 /*
2097 ============
2098 CheckRules_World
2099
2100 Exit deathmatch games upon conditions
2101 ============
2102 */
2103 void ReadyRestart();
2104 void CheckRules_World()
2105 {
2106         float timelimit;
2107         float fraglimit;
2108         float leadlimit;
2109
2110         VoteThink();
2111         MapVote_Think();
2112
2113         SetDefaultAlpha();
2114
2115         /*
2116         MapVote_Think should now do that part
2117         if (intermission_running)
2118                 if (time >= intermission_exittime + 60)
2119                 {
2120                         if(!DoNextMapOverride())
2121                                 GotoNextMap();
2122                         return;
2123                 }
2124         */
2125
2126         if (gameover)   // someone else quit the game already
2127         {
2128                 if(player_count == 0) // Nobody there? Then let's go to the next map
2129                         MapVote_Start();
2130                         // this will actually check the player count in the next frame
2131                         // again, but this shouldn't hurt
2132                 return;
2133         }
2134
2135         timelimit = autocvar_timelimit * 60;
2136         fraglimit = autocvar_fraglimit;
2137         leadlimit = autocvar_leadlimit;
2138
2139         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2140         {
2141                 if(timelimit > 0)
2142                         timelimit = 0; // timelimit is not made for warmup
2143                 if(fraglimit > 0)
2144                         fraglimit = 0; // no fraglimit for now
2145                 leadlimit = 0; // no leadlimit for now
2146         }
2147
2148         if(timelimit > 0)
2149         {
2150                 timelimit += game_starttime;
2151         }
2152         else if (timelimit < 0)
2153         {
2154                 // endmatch
2155                 NextLevel();
2156                 return;
2157         }
2158
2159         if(g_onslaught)
2160                 timelimit = 0; // ONS has its own overtime rule
2161
2162         float wantovertime;
2163         wantovertime = 0;
2164
2165         if(timelimit > game_starttime)
2166                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2167         else
2168                 game_completion_ratio = 0;
2169
2170         if(checkrules_suddendeathend)
2171         {
2172                 if(!checkrules_suddendeathwarning)
2173                 {
2174                         checkrules_suddendeathwarning = TRUE;
2175                         if(g_race && !g_race_qualifying)
2176                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2177                         else
2178                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2179                 }
2180         }
2181         else
2182         {
2183                 if (timelimit && time >= timelimit)
2184                 {
2185                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2186                         {
2187                                 float totalplayers;
2188                                 float playerswithlaps;
2189                                 float readyplayers;
2190                                 entity head;
2191                                 totalplayers = playerswithlaps = readyplayers = 0;
2192                                 FOR_EACH_PLAYER(head)
2193                                 {
2194                                         ++totalplayers;
2195                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2196                                                 ++playerswithlaps;
2197                                         if(head.ready)
2198                                                 ++readyplayers;
2199                                 }
2200
2201                                 // at least 2 of the players have completed a lap: start the RACE
2202                                 // otherwise, the players should end the qualifying on their own
2203                                 if(readyplayers || playerswithlaps >= 2)
2204                                 {
2205                                         checkrules_suddendeathend = 0;
2206                                         ReadyRestart(); // go to race
2207                                         return;
2208                                 }
2209                                 else
2210                                         wantovertime |= InitiateSuddenDeath();
2211                         }
2212                         else
2213                                 wantovertime |= InitiateSuddenDeath();
2214                 }
2215         }
2216
2217         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2218         {
2219                 NextLevel();
2220                 return;
2221         }
2222
2223         float checkrules_status;
2224         checkrules_status = WinningCondition_RanOutOfSpawns();
2225         if(checkrules_status == WINNING_YES)
2226         {
2227                 bprint("Hey! Someone ran out of spawns!\n");
2228         }
2229         else if(g_race && !g_race_qualifying && timelimit >= 0)
2230         {
2231                 checkrules_status = WinningCondition_Race(fraglimit);
2232                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2233         }
2234         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2235         {
2236                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2237                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2238         }
2239         else if(g_assault)
2240         {
2241                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2242         }
2243         else if(g_lms)
2244         {
2245                 checkrules_status = WinningCondition_LMS();
2246         }
2247         else if (g_onslaught)
2248         {
2249                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2250         }
2251         else
2252         {
2253                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2254                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2255         }
2256
2257         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2258         {
2259                 checkrules_status = WINNING_NEVER;
2260                 checkrules_overtimesadded = -1;
2261                 wantovertime |= InitiateSuddenDeath();
2262         }
2263
2264         if(checkrules_status == WINNING_NEVER)
2265                 // equality cases! Nobody wins if the overtime ends in a draw.
2266                 ClearWinners();
2267
2268         if(wantovertime)
2269         {
2270                 if(checkrules_status == WINNING_NEVER)
2271                         InitiateOvertime();
2272                 else
2273                         checkrules_status = WINNING_YES;
2274         }
2275
2276         if(checkrules_suddendeathend)
2277                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2278                         checkrules_status = WINNING_YES;
2279
2280         if(checkrules_status == WINNING_YES)
2281         {
2282                 //print("WINNING\n");
2283                 NextLevel();
2284         }
2285 }
2286
2287 float mapvote_nextthink;
2288 float mapvote_initialized;
2289 float mapvote_keeptwotime;
2290 float mapvote_timeout;
2291 string mapvote_message;
2292 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2293 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2294 float mapvote_screenshot_dirs_count;
2295
2296 float mapvote_count;
2297 float mapvote_count_real;
2298 string mapvote_maps[MAPVOTE_COUNT];
2299 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2300 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2301 float mapvote_maps_suggested[MAPVOTE_COUNT];
2302 string mapvote_suggestions[MAPVOTE_COUNT];
2303 float mapvote_suggestion_ptr;
2304 float mapvote_voters;
2305 float mapvote_selections[MAPVOTE_COUNT];
2306 float mapvote_run;
2307 float mapvote_detail;
2308 float mapvote_abstain;
2309 .float mapvote;
2310
2311 void MapVote_ClearAllVotes()
2312 {
2313         FOR_EACH_CLIENT(other)
2314                 other.mapvote = 0;
2315 }
2316
2317 string MapVote_Suggest(string m)
2318 {
2319         float i;
2320         if(m == "")
2321                 return "That's not how to use this command.";
2322         if(!autocvar_g_maplist_votable_suggestions)
2323                 return "Suggestions are not accepted on this server.";
2324         if(mapvote_initialized)
2325                 return "Can't suggest - voting is already in progress!";
2326         m = MapInfo_FixName(m);
2327         if not(m)
2328                 return "The map you suggested is not available on this server.";
2329         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2330                 if(Map_IsRecent(m))
2331                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2332
2333         if(!MapInfo_CheckMap(m))
2334                 return "The map you suggested does not support the current game mode.";
2335         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2336                 if(mapvote_suggestions[i] == m)
2337                         return "This map was already suggested.";
2338         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2339         {
2340                 i = floor(random() * mapvote_suggestion_ptr);
2341         }
2342         else
2343         {
2344                 i = mapvote_suggestion_ptr;
2345                 mapvote_suggestion_ptr += 1;
2346         }
2347         if(mapvote_suggestions[i] != "")
2348                 strunzone(mapvote_suggestions[i]);
2349         mapvote_suggestions[i] = strzone(m);
2350         if(autocvar_sv_eventlog)
2351                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2352         return strcat("Suggestion of ", m, " accepted.");
2353 }
2354
2355 void MapVote_AddVotable(string nextMap, float isSuggestion)
2356 {
2357         float j, i, o;
2358         string pakfile, mapfile;
2359
2360         if(nextMap == "")
2361                 return;
2362         for(j = 0; j < mapvote_count; ++j)
2363                 if(mapvote_maps[j] == nextMap)
2364                         return;
2365         // suggestions might be no longer valid/allowed after gametype switch!
2366         if(isSuggestion)
2367                 if(!MapInfo_CheckMap(nextMap))
2368                         return;
2369         mapvote_maps[mapvote_count] = strzone(nextMap);
2370         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2371
2372         pakfile = string_null;
2373         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2374         {
2375                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2376                 pakfile = whichpack(strcat(mapfile, ".tga"));
2377                 if(pakfile == "")
2378                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2379                 if(pakfile == "")
2380                         pakfile = whichpack(strcat(mapfile, ".png"));
2381                 if(pakfile != "")
2382                         break;
2383         }
2384         if(i >= mapvote_screenshot_dirs_count)
2385                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2386         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2387                 pakfile = substring(pakfile, o, -1);
2388
2389         mapvote_maps_screenshot_dir[mapvote_count] = i;
2390         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2391
2392         mapvote_count += 1;
2393 }
2394
2395 void MapVote_Spawn();
2396 void MapVote_Init()
2397 {
2398         float i;
2399         float nmax, smax;
2400
2401         MapVote_ClearAllVotes();
2402
2403         mapvote_count = 0;
2404         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2405         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2406
2407         if(mapvote_abstain)
2408                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2409         else
2410                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2411         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2412
2413         // we need this for AddVotable, as that cycles through the screenshot dirs
2414         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2415         if(mapvote_screenshot_dirs_count == 0)
2416                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2417         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2418         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2419                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2420
2421         if(mapvote_suggestion_ptr)
2422                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2423                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2424
2425         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2426                 MapVote_AddVotable(GetNextMap(), FALSE);
2427
2428         if(mapvote_count == 0)
2429         {
2430                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2431                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2432                 if(autocvar_g_maplist_shuffle)
2433                         ShuffleMaplist();
2434                 localcmd("\nmenu_cmd sync\n");
2435                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2436                         MapVote_AddVotable(GetNextMap(), FALSE);
2437         }
2438
2439         mapvote_count_real = mapvote_count;
2440         if(mapvote_abstain)
2441                 MapVote_AddVotable("don't care", 0);
2442
2443         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2444
2445         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2446         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2447         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2448                 mapvote_keeptwotime = 0;
2449         mapvote_message = "Choose a map and press its key!";
2450
2451         MapVote_Spawn();
2452 }
2453
2454 void MapVote_SendPicture(float id)
2455 {
2456         msg_entity = self;
2457         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2458         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2459         WriteByte(MSG_ONE, id);
2460         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2461 }
2462
2463 float MapVote_GetMapMask()
2464 {
2465         float mask, i, power;
2466         mask = 0;
2467         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2468                 if(mapvote_maps[i] != "")
2469                         mask |= power;
2470         return mask;
2471 }
2472
2473 entity mapvote_ent;
2474 float MapVote_SendEntity(entity to, float sf)
2475 {
2476         float i;
2477
2478         if(sf & 1)
2479                 sf &~= 2; // if we send 1, we don't need to also send 2
2480
2481         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2482         WriteByte(MSG_ENTITY, sf);
2483
2484         if(sf & 1)
2485         {
2486                 // flag 1 == initialization
2487                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2488                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2489                 WriteString(MSG_ENTITY, "");
2490                 WriteByte(MSG_ENTITY, mapvote_count);
2491                 WriteByte(MSG_ENTITY, mapvote_abstain);
2492                 WriteByte(MSG_ENTITY, mapvote_detail);
2493                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2494                 if(mapvote_count <= 8)
2495                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2496                 else
2497                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2498                 for(i = 0; i < mapvote_count; ++i)
2499                         if(mapvote_maps[i] != "")
2500                         {
2501                                 if(mapvote_abstain && i == mapvote_count - 1)
2502                                 {
2503                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2504                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2505                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2506                                 }
2507                                 else
2508                                 {
2509                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2510                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2511                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2512                                 }
2513                         }
2514         }
2515
2516         if(sf & 2)
2517         {
2518                 // flag 2 == update of mask
2519                 if(mapvote_count <= 8)
2520                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2521                 else
2522                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2523         }
2524
2525         if(sf & 4)
2526         {
2527                 if(mapvote_detail)
2528                         for(i = 0; i < mapvote_count; ++i)
2529                                 if(mapvote_maps[i] != "")
2530                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2531
2532                 WriteByte(MSG_ENTITY, to.mapvote);
2533         }
2534
2535         return TRUE;
2536 }
2537
2538 void MapVote_Spawn()
2539 {
2540         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2541 }
2542
2543 void MapVote_TouchMask()
2544 {
2545         mapvote_ent.SendFlags |= 2;
2546 }
2547
2548 void MapVote_TouchVotes(entity voter)
2549 {
2550         mapvote_ent.SendFlags |= 4;
2551 }
2552
2553 float MapVote_Finished(float mappos)
2554 {
2555         string result;
2556         float i;
2557         float didntvote;
2558
2559         if(autocvar_sv_eventlog)
2560         {
2561                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2562                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2563                 didntvote = mapvote_voters;
2564                 for(i = 0; i < mapvote_count; ++i)
2565                         if(mapvote_maps[i] != "")
2566                         {
2567                                 didntvote -= mapvote_selections[i];
2568                                 if(i != mappos)
2569                                 {
2570                                         result = strcat(result, ":", mapvote_maps[i]);
2571                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2572                                 }
2573                         }
2574                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2575
2576                 GameLogEcho(result);
2577                 if(mapvote_maps_suggested[mappos])
2578                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2579         }
2580
2581         FOR_EACH_REALCLIENT(other)
2582                 FixClientCvars(other);
2583
2584         Map_Goto_SetStr(mapvote_maps[mappos]);
2585         Map_Goto(0);
2586         alreadychangedlevel = TRUE;
2587         return TRUE;
2588 }
2589 void MapVote_CheckRules_1()
2590 {
2591         float i;
2592
2593         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2594         {
2595                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2596                 mapvote_selections[i] = 0;
2597         }
2598
2599         mapvote_voters = 0;
2600         FOR_EACH_REALCLIENT(other)
2601         {
2602                 ++mapvote_voters;
2603                 if(other.mapvote)
2604                 {
2605                         i = other.mapvote - 1;
2606                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2607                         mapvote_selections[i] = mapvote_selections[i] + 1;
2608                 }
2609         }
2610 }
2611
2612 float MapVote_CheckRules_2()
2613 {
2614         float i;
2615         float firstPlace, secondPlace;
2616         float firstPlaceVotes, secondPlaceVotes;
2617         float mapvote_voters_real;
2618         string result;
2619
2620         if(mapvote_count_real == 1)
2621                 return MapVote_Finished(0);
2622
2623         mapvote_voters_real = mapvote_voters;
2624         if(mapvote_abstain)
2625                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2626
2627         RandomSelection_Init();
2628         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2629                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2630         firstPlace = RandomSelection_chosen_float;
2631         firstPlaceVotes = RandomSelection_best_priority;
2632         //dprint("First place: ", ftos(firstPlace), "\n");
2633         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2634
2635         RandomSelection_Init();
2636         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2637                 if(i != firstPlace)
2638                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2639         secondPlace = RandomSelection_chosen_float;
2640         secondPlaceVotes = RandomSelection_best_priority;
2641         //dprint("Second place: ", ftos(secondPlace), "\n");
2642         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2643
2644         if(firstPlace == -1)
2645                 error("No first place in map vote... WTF?");
2646
2647         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2648                 return MapVote_Finished(firstPlace);
2649
2650         if(mapvote_keeptwotime)
2651                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2652                 {
2653                         float didntvote;
2654                         MapVote_TouchMask();
2655                         mapvote_message = "Now decide between the TOP TWO!";
2656                         mapvote_keeptwotime = 0;
2657                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2658                         result = strcat(result, ":", ftos(firstPlaceVotes));
2659                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2660                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2661                         didntvote = mapvote_voters;
2662                         for(i = 0; i < mapvote_count; ++i)
2663                                 if(mapvote_maps[i] != "")
2664                                 {
2665                                         didntvote -= mapvote_selections[i];
2666                                         if(i != firstPlace)
2667                                                 if(i != secondPlace)
2668                                                 {
2669                                                         result = strcat(result, ":", mapvote_maps[i]);
2670                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2671                                                         if(i < mapvote_count_real)
2672                                                         {
2673                                                                 strunzone(mapvote_maps[i]);
2674                                                                 mapvote_maps[i] = "";
2675                                                                 strunzone(mapvote_maps_pakfile[i]);
2676                                                                 mapvote_maps_pakfile[i] = "";
2677                                                         }
2678                                                 }
2679                                 }
2680                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2681                         if(autocvar_sv_eventlog)
2682                                 GameLogEcho(result);
2683                 }
2684
2685         return FALSE;
2686 }
2687 void MapVote_Tick()
2688 {
2689         float keeptwo;
2690         float totalvotes;
2691
2692         keeptwo = mapvote_keeptwotime;
2693         MapVote_CheckRules_1(); // count
2694         if(MapVote_CheckRules_2()) // decide
2695                 return;
2696
2697         totalvotes = 0;
2698         FOR_EACH_REALCLIENT(other)
2699         {
2700                 // hide scoreboard again
2701                 if(other.health != 2342)
2702                 {
2703                         other.health = 2342;
2704                         other.impulse = 0;
2705                         if(clienttype(other) == CLIENTTYPE_REAL)
2706                         {
2707                                 msg_entity = other;
2708                                 WriteByte(MSG_ONE, SVC_FINALE);
2709                                 WriteString(MSG_ONE, "");
2710                         }
2711                 }
2712
2713                 // clear possibly invalid votes
2714                 if(mapvote_maps[other.mapvote - 1] == "")
2715                         other.mapvote = 0;
2716                 // use impulses as new vote
2717                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2718                         if(mapvote_maps[other.impulse - 1] != "")
2719                         {
2720                                 other.mapvote = other.impulse;
2721                                 MapVote_TouchVotes(other);
2722                         }
2723                 other.impulse = 0;
2724
2725                 if(other.mapvote)
2726                         ++totalvotes;
2727         }
2728
2729         MapVote_CheckRules_1(); // just count
2730 }
2731 void MapVote_Start()
2732 {
2733         if(mapvote_run)
2734                 return;
2735
2736         // wait for stats to be sent first
2737         if(!playerstats_waitforme)
2738                 return;
2739
2740         MapInfo_Enumerate();
2741         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2742                 mapvote_run = TRUE;
2743 }
2744 void MapVote_Think()
2745 {
2746         if(!mapvote_run)
2747                 return;
2748
2749         if(alreadychangedlevel)
2750                 return;
2751
2752         if(time < mapvote_nextthink)
2753                 return;
2754         //dprint("tick\n");
2755
2756         mapvote_nextthink = time + 0.5;
2757
2758         if(!mapvote_initialized)
2759         {
2760                 if(autocvar_rescan_pending == 1)
2761                 {
2762                         cvar_set("rescan_pending", "2");
2763                         localcmd("fs_rescan\nrescan_pending 3\n");
2764                         return;
2765                 }
2766                 else if(autocvar_rescan_pending == 2)
2767                 {
2768                         return;
2769                 }
2770                 else if(autocvar_rescan_pending == 3)
2771                 {
2772                         // now build missing mapinfo files
2773                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2774                                 return;
2775
2776                         // we're done, start the timer
2777                         cvar_set("rescan_pending", "0");
2778                 }
2779
2780                 mapvote_initialized = TRUE;
2781                 if(DoNextMapOverride(0))
2782                         return;
2783                 if(!autocvar_g_maplist_votable || player_count <= 0)
2784                 {
2785                         GotoNextMap(0);
2786                         return;
2787                 }
2788                 MapVote_Init();
2789         }
2790
2791         MapVote_Tick();
2792 }
2793
2794 string GotoMap(string m)
2795 {
2796         if(!MapInfo_CheckMap(m))
2797                 return "The map you chose is not available on this server.";
2798         cvar_set("nextmap", m);
2799         cvar_set("timelimit", "-1");
2800         if(mapvote_initialized || alreadychangedlevel)
2801         {
2802                 if(DoNextMapOverride(0))
2803                         return "Map switch initiated.";
2804                 else
2805                         return "Hm... no. For some reason I like THIS map more.";
2806         }
2807         else
2808                 return "Map switch will happen after scoreboard.";
2809 }
2810
2811
2812 void EndFrame()
2813 {
2814         float altime;
2815         FOR_EACH_REALCLIENT(self)
2816         {
2817                 if(self.classname == "spectator")
2818                 {
2819                         if(self.enemy.typehitsound)
2820                                 self.typehit_time = time;
2821                         else if(self.enemy.hitsound)
2822                                 self.hit_time = time;
2823                 }
2824                 else
2825                 {
2826                         if(self.typehitsound)
2827                                 self.typehit_time = time;
2828                         else if(self.hitsound)
2829                                 self.hit_time = time;
2830                 }
2831         }
2832         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2833         // add 1 frametime because after this, engine SV_Physics
2834         // increases time by a frametime and then networks the frame
2835         // add another frametime because client shows everything with
2836         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2837         // needed!
2838         FOR_EACH_CLIENT(self)
2839         {
2840                 self.hitsound = FALSE;
2841                 self.typehitsound = FALSE;
2842                 antilag_record(self, altime);
2843         }
2844 }
2845
2846
2847 /*
2848  * RedirectionThink:
2849  * returns TRUE if redirecting
2850  */
2851 float redirection_timeout;
2852 float redirection_nextthink;
2853 float RedirectionThink()
2854 {
2855         float clients_found;
2856
2857         if(redirection_target == "")
2858                 return FALSE;
2859
2860         if(!redirection_timeout)
2861         {
2862                 cvar_set("sv_public", "-2");
2863                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2864                 if(redirection_target == "self")
2865                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2866                 else
2867                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2868         }
2869
2870         if(time < redirection_nextthink)
2871                 return TRUE;
2872
2873         redirection_nextthink = time + 1;
2874
2875         clients_found = 0;
2876         FOR_EACH_REALCLIENT(self)
2877         {
2878                 // TODO add timer
2879                 print("Redirecting: sending connect command to ", self.netname, "\n");
2880                 if(redirection_target == "self")
2881                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2882                 else
2883                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2884                 ++clients_found;
2885         }
2886
2887         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2888
2889         if(time > redirection_timeout || clients_found == 0)
2890                 localcmd("\nwait; wait; wait; quit\n");
2891
2892         return TRUE;
2893 }
2894
2895 void TargetMusic_RestoreGame();
2896 void RestoreGame()
2897 {
2898         // Loaded from a save game
2899         // some things then break, so let's work around them...
2900
2901         // Progs DB (capture records)
2902         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2903
2904         // Mapinfo
2905         MapInfo_Shutdown();
2906         MapInfo_Enumerate();
2907         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2908         WeaponStats_Init();
2909
2910         TargetMusic_RestoreGame();
2911 }
2912
2913 void Shutdown()
2914 {
2915         entity e;
2916
2917         gameover = 2;
2918
2919         if(world_initialized > 0)
2920         {
2921                 world_initialized = 0;
2922                 print("Saving persistent data...\n");
2923                 Ban_SaveBans();
2924
2925                 PlayerStats_EndMatch(0);
2926                 FOR_EACH_CLIENT(e)
2927                         PlayerStats_AddGlobalInfo(e);
2928                 PlayerStats_Shutdown();
2929
2930                 if(!cheatcount_total)
2931                 {
2932                         if(autocvar_sv_db_saveasdump)
2933                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2934                         else
2935                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2936                 }
2937                 if(autocvar_developer)
2938                 {
2939                         if(autocvar_sv_db_saveasdump)
2940                                 db_dump(TemporaryDB, "server-temp.db");
2941                         else
2942                                 db_save(TemporaryDB, "server-temp.db");
2943                 }
2944                 CheatShutdown(); // must be after cheatcount check
2945                 db_close(ServerProgsDB);
2946                 db_close(TemporaryDB);
2947                 print("done!\n");
2948                 // tell the bot system the game is ending now
2949                 bot_endgame();
2950
2951                 WeaponStats_Shutdown();
2952                 MapInfo_Shutdown();
2953         }
2954         else if(world_initialized == 0)
2955         {
2956                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2957         }
2958 }