qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include <server/mutators/_mod.qh>
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include <common/net_linked.qh>
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/gamemodes/sv_rules.qh"
  25 #include "../common/mapinfo.qh"
  26 #include "../common/monsters/_mod.qh"
  27 #include "../common/monsters/sv_monsters.qh"
  28 #include "../common/vehicles/all.qh"
  29 #include "../common/notifications/all.qh"
  30 #include "../common/physics/player.qh"
  31 #include "../common/playerstats.qh"
  32 #include "../common/stats.qh"
  33 #include "../common/teams.qh"
  34 #include "../common/mapobjects/trigger/secret.qh"
  35 #include "../common/mapobjects/target/music.qh"
  36 #include "../common/util.qh"
  37 #include "../common/items/_mod.qh"
  38 #include <common/weapons/_all.qh>
  39 #include "../common/state.qh"
  40
  41 const float LATENCY_THINKRATE = 10;
  42 .float latency_sum;
  43 .float latency_cnt;
  44 .float latency_time;
  45 entity pingplreport;
  46 void PingPLReport_Think(entity this)
  47 {
  48         float delta;
  49         entity e;
  50
  51         delta = 3 / maxclients;
  52         if(delta < sys_frametime)
  53                 delta = 0;
  54         this.nextthink = time + delta;
  55
  56         e = edict_num(this.cnt + 1);
  57         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  58         {
  59                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  60                 WriteByte(MSG_BROADCAST, this.cnt);
  61                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  62                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  64
  65                 // record latency times for clients throughout the match so we can report it to playerstats
  66                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  67                 {
  68                         CS(e).latency_sum += CS(e).ping;
  69                         CS(e).latency_cnt += 1;
  70                         CS(e).latency_time = time;
  71                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  72                 }
  73         }
  74         else
  75         {
  76                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  77                 WriteByte(MSG_BROADCAST, this.cnt);
  78                 WriteShort(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81         }
  82         this.cnt = (this.cnt + 1) % maxclients;
  83 }
  84 void PingPLReport_Spawn()
  85 {
  86         pingplreport = new_pure(pingplreport);
  87         setthink(pingplreport, PingPLReport_Think);
  88         pingplreport.nextthink = time;
  89 }
  90
  91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  92 string redirection_target;
  93 float world_initialized;
  94
  95 void SetDefaultAlpha()
  96 {
  97         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  98         {
  99                 default_player_alpha = autocvar_g_player_alpha;
 100                 if(default_player_alpha == 0)
 101                         default_player_alpha = 1;
 102                 default_weapon_alpha = default_player_alpha;
 103         }
 104 }
 105
 106 void GotoFirstMap(entity this)
 107 {
 108         float n;
 109         if(autocvar__sv_init)
 110         {
 111                 // cvar_set("_sv_init", "0");
 112                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 113                 // to this "init" map on a dedicated server will cause no permanent
 114                 // harm
 115                 if(autocvar_g_maplist_shuffle)
 116                         ShuffleMaplist();
 117                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 118                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 119
 120                 MapInfo_Enumerate();
 121                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 122
 123                 if(!DoNextMapOverride(1))
 124                         GotoNextMap(1);
 125
 126                 return;
 127         }
 128
 129         if(time < 5)
 130         {
 131                 this.nextthink = time;
 132         }
 133         else
 134         {
 135                 this.nextthink = time + 1;
 136                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 137         }
 138 }
 139
 140 void cvar_changes_init()
 141 {
 142         float h;
 143         string k, v, d;
 144         float n, i, adding, pureadding;
 145
 146         strfree(cvar_changes);
 147         strfree(cvar_purechanges);
 148         cvar_purechanges_count = 0;
 149
 150         h = buf_create();
 151         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 152         n = buf_getsize(h);
 153
 154         adding = true;
 155         pureadding = true;
 156
 157         for(i = 0; i < n; ++i)
 158         {
 159                 k = bufstr_get(h, i);
 160
 161 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 162 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 163 #define BADCVAR(p) if(k == p) continue
 164
 165                 // general excludes and namespaces for server admin used cvars
 166                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 167
 168                 // internal
 169                 BADPREFIX("csqc_");
 170                 BADPREFIX("cvar_check_");
 171                 BADCVAR("gamecfg");
 172                 BADCVAR("g_configversion");
 173                 BADCVAR("halflifebsp");
 174                 BADCVAR("sv_mapformat_is_quake2");
 175                 BADCVAR("sv_mapformat_is_quake3");
 176                 BADPREFIX("sv_world");
 177
 178                 // client
 179                 BADPREFIX("chase_");
 180                 BADPREFIX("cl_");
 181                 BADPREFIX("con_");
 182                 BADPREFIX("scoreboard_");
 183                 BADPREFIX("g_campaign");
 184                 BADPREFIX("g_waypointsprite_");
 185                 BADPREFIX("gl_");
 186                 BADPREFIX("joy");
 187                 BADPREFIX("hud_");
 188                 BADPREFIX("m_");
 189                 BADPREFIX("menu_");
 190                 BADPREFIX("net_slist_");
 191                 BADPREFIX("r_");
 192                 BADPREFIX("sbar_");
 193                 BADPREFIX("scr_");
 194                 BADPREFIX("snd_");
 195                 BADPREFIX("show");
 196                 BADPREFIX("sensitivity");
 197                 BADPREFIX("userbind");
 198                 BADPREFIX("v_");
 199                 BADPREFIX("vid_");
 200                 BADPREFIX("crosshair");
 201                 BADCVAR("mod_q3bsp_lightmapmergepower");
 202                 BADCVAR("mod_q3bsp_nolightmaps");
 203                 BADCVAR("fov");
 204                 BADCVAR("mastervolume");
 205                 BADCVAR("volume");
 206                 BADCVAR("bgmvolume");
 207                 BADCVAR("in_pitch_min");
 208                 BADCVAR("in_pitch_max");
 209
 210                 // private
 211                 BADCVAR("developer");
 212                 BADCVAR("log_dest_udp");
 213                 BADCVAR("net_address");
 214                 BADCVAR("net_address_ipv6");
 215                 BADCVAR("port");
 216                 BADCVAR("savedgamecfg");
 217                 BADCVAR("serverconfig");
 218                 BADCVAR("sv_autoscreenshot");
 219                 BADCVAR("sv_heartbeatperiod");
 220                 BADCVAR("sv_vote_master_password");
 221                 BADCVAR("sys_colortranslation");
 222                 BADCVAR("sys_specialcharactertranslation");
 223                 BADCVAR("timeformat");
 224                 BADCVAR("timestamps");
 225                 BADCVAR("g_require_stats");
 226                 BADPREFIX("developer_");
 227                 BADPREFIX("g_ban_");
 228                 BADPREFIX("g_banned_list");
 229                 BADPREFIX("g_require_stats_");
 230                 BADPREFIX("g_chat_flood_");
 231                 BADPREFIX("g_ghost_items");
 232                 BADPREFIX("g_playerstats_");
 233                 BADPREFIX("g_voice_flood_");
 234                 BADPREFIX("log_file");
 235                 BADPREFIX("quit_");
 236                 BADPREFIX("rcon_");
 237                 BADPREFIX("sv_allowdownloads");
 238                 BADPREFIX("sv_autodemo");
 239                 BADPREFIX("sv_curl_");
 240                 BADPREFIX("sv_eventlog");
 241                 BADPREFIX("sv_logscores_");
 242                 BADPREFIX("sv_master");
 243                 BADPREFIX("sv_weaponstats_");
 244                 BADPREFIX("sv_waypointsprite_");
 245                 BADCVAR("rescan_pending");
 246
 247                 // these can contain player IDs, so better hide
 248                 BADPREFIX("g_forced_team_");
 249                 BADCVAR("sv_muteban_list");
 250                 BADCVAR("sv_voteban_list");
 251                 BADCVAR("sv_allow_customplayermodels_idlist");
 252                 BADCVAR("sv_allow_customplayermodels_speciallist");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_conquest");
 261                 BADCVAR("g_ctf");
 262                 BADCVAR("g_cts");
 263                 BADCVAR("g_dotc");
 264                 BADCVAR("g_dm");
 265                 BADCVAR("g_domination");
 266                 BADCVAR("g_domination_default_teams");
 267                 BADCVAR("g_freezetag");
 268                 BADCVAR("g_freezetag_teams");
 269                 BADCVAR("g_invasion_teams");
 270                 BADCVAR("g_invasion_type");
 271                 BADCVAR("g_jailbreak");
 272                 BADCVAR("g_jailbreak_teams");
 273                 BADCVAR("g_keepaway");
 274                 BADCVAR("g_keyhunt");
 275                 BADCVAR("g_keyhunt_teams");
 276                 BADCVAR("g_lms");
 277                 BADCVAR("g_nexball");
 278                 BADCVAR("g_onslaught");
 279                 BADCVAR("g_race");
 280                 BADCVAR("g_race_laps_limit");
 281                 BADCVAR("g_race_qualifying_timelimit");
 282                 BADCVAR("g_race_qualifying_timelimit_override");
 283                 BADCVAR("g_runematch");
 284                 BADCVAR("g_snafu");
 285                 BADCVAR("g_tdm");
 286                 BADCVAR("g_tdm_teams");
 287                 BADCVAR("g_vip");
 288                 BADCVAR("leadlimit");
 289                 BADCVAR("nextmap");
 290                 BADCVAR("teamplay");
 291                 BADCVAR("timelimit");
 292                 BADCVAR("g_mapinfo_ignore_warnings");
 293
 294                 // long
 295                 BADCVAR("hostname");
 296                 BADCVAR("g_maplist");
 297                 BADCVAR("g_maplist_mostrecent");
 298                 BADCVAR("sv_motd");
 299
 300                 v = cvar_string(k);
 301                 d = cvar_defstring(k);
 302                 if(v == d)
 303                         continue;
 304
 305                 if(adding)
 306                 {
 307                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 308                         if(strlen(cvar_changes) > 16384)
 309                         {
 310                                 cvar_changes = "// too many settings have been changed to show them here\n";
 311                                 adding = 0;
 312                         }
 313                 }
 314
 315                 // now check if the changes are actually gameplay relevant
 316
 317                 // does nothing gameplay relevant
 318                 BADCVAR("captureleadlimit_override");
 319                 BADCVAR("condump_stripcolors");
 320                 BADCVAR("gameversion");
 321                 BADCVAR("g_allow_oldvortexbeam");
 322                 BADCVAR("g_balance_kill_delay");
 323                 BADCVAR("g_buffs_pickup_anyway");
 324                 BADCVAR("g_buffs_randomize");
 325                 BADCVAR("g_campcheck_distance");
 326                 BADCVAR("g_ca_point_leadlimit");
 327                 BADCVAR("g_ca_point_limit");
 328                 BADCVAR("g_ctf_captimerecord_always");
 329                 BADCVAR("g_ctf_flag_glowtrails");
 330                 BADCVAR("g_ctf_flag_pickup_verbosename");
 331                 BADCVAR("g_domination_point_leadlimit");
 332                 BADCVAR("g_forced_respawn");
 333                 BADCVAR("g_freezetag_point_leadlimit");
 334                 BADCVAR("g_freezetag_point_limit");
 335                 BADCVAR("g_hats");
 336                 BADCVAR("g_invasion_point_limit");
 337                 BADCVAR("g_jump_grunt");
 338                 BADCVAR("g_keyhunt_point_leadlimit");
 339                 BADCVAR("g_nexball_goalleadlimit");
 340                 BADCVAR("g_new_toys_use_pickupsound");
 341                 BADCVAR("g_physics_predictall");
 342                 BADCVAR("g_piggyback");
 343                 BADCVAR("g_playerclip_collisions");
 344                 BADCVAR("g_tdm_point_leadlimit");
 345                 BADCVAR("g_tdm_point_limit");
 346                 BADCVAR("leadlimit_and_fraglimit");
 347                 BADCVAR("leadlimit_override");
 348                 BADCVAR("pausable");
 349                 BADCVAR("sv_checkforpacketsduringsleep");
 350                 BADCVAR("sv_damagetext");
 351                 BADCVAR("sv_db_saveasdump");
 352                 BADCVAR("sv_intermission_cdtrack");
 353                 BADCVAR("sv_minigames");
 354                 BADCVAR("sv_namechangetimer");
 355                 BADCVAR("sv_precacheplayermodels");
 356                 BADCVAR("sv_stepheight");
 357                 BADCVAR("sv_timeout");
 358                 BADCVAR("sv_weapons_modeloverride");
 359                 BADPREFIX("crypto_");
 360                 BADPREFIX("gameversion_");
 361                 BADPREFIX("g_chat_");
 362                 BADPREFIX("g_ctf_captimerecord_");
 363                 BADPREFIX("g_hats_");
 364                 BADPREFIX("g_maplist_");
 365                 BADPREFIX("g_mod_");
 366                 BADPREFIX("g_respawn_");
 367                 BADPREFIX("net_");
 368                 BADPREFIX("notification_");
 369                 BADPREFIX("prvm_");
 370                 BADPREFIX("skill_");
 371                 BADPREFIX("sv_allow_");
 372                 BADPREFIX("sv_cullentities_");
 373                 BADPREFIX("sv_maxidle_");
 374                 BADPREFIX("sv_minigames_");
 375                 BADPREFIX("sv_radio_");
 376                 BADPREFIX("sv_timeout_");
 377                 BADPREFIX("sv_vote_");
 378                 BADPREFIX("timelimit_");
 379
 380                 // allowed changes to server admins (please sync this to server.cfg)
 381                 // vi commands:
 382                 //   :/"impure"/,$d
 383                 //   :g!,^\/\/[^ /],d
 384                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 385                 //   :%!sort
 386                 // yes, this does contain some redundant stuff, don't really care
 387                 BADCVAR("bot_config_file");
 388                 BADCVAR("bot_number");
 389                 BADCVAR("bot_prefix");
 390                 BADCVAR("bot_suffix");
 391                 BADCVAR("capturelimit_override");
 392                 BADCVAR("fraglimit_override");
 393                 BADCVAR("gametype");
 394                 BADCVAR("g_antilag");
 395                 BADCVAR("g_balance_teams");
 396                 BADCVAR("g_balance_teams_prevent_imbalance");
 397                 BADCVAR("g_balance_teams_scorefactor");
 398                 BADCVAR("g_ban_sync_trusted_servers");
 399                 BADCVAR("g_ban_sync_uri");
 400                 BADCVAR("g_buffs");
 401                 BADCVAR("g_ca_teams_override");
 402                 BADCVAR("g_ctf_ignore_frags");
 403                 BADCVAR("g_ctf_leaderboard");
 404                 BADCVAR("g_domination_point_limit");
 405                 BADCVAR("g_domination_teams_override");
 406                 BADCVAR("g_freezetag_teams_override");
 407                 BADCVAR("g_friendlyfire");
 408                 BADCVAR("g_fullbrightitems");
 409                 BADCVAR("g_fullbrightplayers");
 410                 BADCVAR("g_keyhunt_point_limit");
 411                 BADCVAR("g_keyhunt_teams_override");
 412                 BADCVAR("g_lms_lives_override");
 413                 BADCVAR("g_maplist");
 414                 BADCVAR("g_maxplayers");
 415                 BADCVAR("g_mirrordamage");
 416                 BADCVAR("g_nexball_goallimit");
 417                 BADCVAR("g_norecoil");
 418                 BADCVAR("g_physics_clientselect");
 419                 BADCVAR("g_pinata");
 420                 BADCVAR("g_powerups");
 421                 BADCVAR("g_spawnshieldtime");
 422                 BADCVAR("g_start_delay");
 423                 BADCVAR("g_superspectate");
 424                 BADCVAR("g_tdm_teams_override");
 425                 BADCVAR("g_warmup");
 426                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 427                 BADCVAR("hostname");
 428                 BADCVAR("log_file");
 429                 BADCVAR("maxplayers");
 430                 BADCVAR("minplayers");
 431                 BADCVAR("net_address");
 432                 BADCVAR("port");
 433                 BADCVAR("rcon_password");
 434                 BADCVAR("rcon_restricted_commands");
 435                 BADCVAR("rcon_restricted_password");
 436                 BADCVAR("skill");
 437                 BADCVAR("sv_adminnick");
 438                 BADCVAR("sv_autoscreenshot");
 439                 BADCVAR("sv_autotaunt");
 440                 BADCVAR("sv_curl_defaulturl");
 441                 BADCVAR("sv_defaultcharacter");
 442                 BADCVAR("sv_defaultcharacterskin");
 443                 BADCVAR("sv_defaultplayercolors");
 444                 BADCVAR("sv_defaultplayermodel");
 445                 BADCVAR("sv_defaultplayerskin");
 446                 BADCVAR("sv_maxidle");
 447                 BADCVAR("sv_maxrate");
 448                 BADCVAR("sv_motd");
 449                 BADCVAR("sv_public");
 450                 BADCVAR("sv_ready_restart");
 451                 BADCVAR("sv_status_privacy");
 452                 BADCVAR("sv_taunt");
 453                 BADCVAR("sv_vote_call");
 454                 BADCVAR("sv_vote_commands");
 455                 BADCVAR("sv_vote_majority_factor");
 456                 BADCVAR("sv_vote_master");
 457                 BADCVAR("sv_vote_master_commands");
 458                 BADCVAR("sv_vote_master_password");
 459                 BADCVAR("sv_vote_simple_majority_factor");
 460                 BADCVAR("teamplay_mode");
 461                 BADCVAR("timelimit_override");
 462                 BADPREFIX("g_warmup_");
 463                 BADPREFIX("sv_info_");
 464                 BADPREFIX("sv_ready_restart_");
 465
 466                 // mutators that announce themselves properly to the server browser
 467                 BADCVAR("g_instagib");
 468                 BADCVAR("g_new_toys");
 469                 BADCVAR("g_nix");
 470                 BADCVAR("g_grappling_hook");
 471                 BADCVAR("g_jetpack");
 472
 473 #undef BADPRESUFFIX
 474 #undef BADPREFIX
 475 #undef BADCVAR
 476
 477                 if(pureadding)
 478                 {
 479                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 480                         if(strlen(cvar_purechanges) > 16384)
 481                         {
 482                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 483                                 pureadding = 0;
 484                         }
 485                 }
 486                 ++cvar_purechanges_count;
 487                 // WARNING: this variable is used for the server list
 488                 // NEVER dare to skip this code!
 489                 // Hacks to intentionally appearing as "pure server" even though you DO have
 490                 // modified settings may be punished by removal from the server list.
 491                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 492                 // though.
 493         }
 494         buf_del(h);
 495         if(cvar_changes == "")
 496                 cvar_changes = "// this server runs at default server settings\n";
 497         else
 498                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 499         cvar_changes = strzone(cvar_changes);
 500         if(cvar_purechanges == "")
 501                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 502         else
 503                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 504         cvar_purechanges = strzone(cvar_purechanges);
 505 }
 506
 507 entity randomseed;
 508 bool RandomSeed_Send(entity this, entity to, int sf)
 509 {
 510         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 511         WriteShort(MSG_ENTITY, this.cnt);
 512         return true;
 513 }
 514 void RandomSeed_Think(entity this)
 515 {
 516         this.cnt = bound(0, floor(random() * 65536), 65535);
 517         this.nextthink = time + 5;
 518
 519         this.SendFlags |= 1;
 520 }
 521 void RandomSeed_Spawn()
 522 {
 523         randomseed = new_pure(randomseed);
 524         setthink(randomseed, RandomSeed_Think);
 525         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 526
 527         getthink(randomseed)(randomseed); // sets random seed and nextthink
 528 }
 529
 530 spawnfunc(__init_dedicated_server)
 531 {
 532         // handler for _init/_init map (only for dedicated server initialization)
 533
 534         world_initialized = -1; // don't complain
 535         cvar = cvar_normal;
 536         cvar_string = cvar_string_normal;
 537         cvar_set = cvar_set_normal;
 538
 539         delete_fn = remove_unsafely;
 540
 541         entity e = spawn();
 542         setthink(e, GotoFirstMap);
 543         e.nextthink = time; // this is usually 1 at this point
 544
 545         e = new(info_player_deathmatch);  // safeguard against player joining
 546
 547     // assign reflectively to avoid "assignment to world" warning
 548     for (int i = 0, n = numentityfields(); i < n; ++i) {
 549         string k = entityfieldname(i);
 550         if (k == "classname") {
 551             // safeguard against various stuff ;)
 552             putentityfieldstring(i, this, "worldspawn");
 553             break;
 554         }
 555     }
 556
 557         // needs to be done so early because of the constants they create
 558         static_init();
 559         static_init_late();
 560         static_init_precache();
 561
 562         IL_PUSH(g_spawnpoints, e); // just incase
 563
 564         MapInfo_Enumerate();
 565         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 566 }
 567
 568 void __init_dedicated_server_shutdown() {
 569         MapInfo_Shutdown();
 570 }
 571
 572 STATIC_INIT_EARLY(maxclients)
 573 {
 574         maxclients = 0;
 575         for (entity head = nextent(NULL); head; head = nextent(head)) {
 576                 ++maxclients;
 577         }
 578 }
 579
 580 float world_already_spawned;
 581 spawnfunc(worldspawn)
 582 {
 583         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 584
 585     bool wantrestart = false;
 586         {
 587                 if (!server_is_dedicated)
 588                 {
 589                         // force unloading of server pk3 files when starting a listen server
 590                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 591                         // restore csqc_progname too
 592                         string expect = "csprogs.dat";
 593                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 594                         cvar_set_normal("csqc_progname", expect);
 595                 }
 596                 else
 597                 {
 598                         // Try to use versioned csprogs from pk3
 599                         // Only ever use versioned csprogs.dat files on dedicated servers;
 600                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 601                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 602                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 603                         string select = "csprogs.dat";
 604                         if (fexists(pk3csprogs)) select = pk3csprogs;
 605                         if (cvar_string_normal("csqc_progname") != select)
 606                         {
 607                                 cvar_set_normal("csqc_progname", select);
 608                                 wantrestart = true;
 609                         }
 610                         // Check for updates on startup
 611                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 612                         int sentinel = fopen("progs.txt", FILE_READ);
 613                         if (sentinel >= 0)
 614                         {
 615                                 string switchversion = fgets(sentinel);
 616                                 fclose(sentinel);
 617                                 if (switchversion != "" && switchversion != WATERMARK)
 618                                 {
 619                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 620                                         // if it doesn't exist, assume either:
 621                                         //   a) the current program was overwritten
 622                                         //   b) this is a client only update
 623                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 624                                         if (fexists(newprogs))
 625                                         {
 626                                                 cvar_set_normal("sv_progs", newprogs);
 627                                                 wantrestart = true;
 628                                         }
 629                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 630                                         if (fexists(newcsprogs))
 631                                         {
 632                                                 cvar_set_normal("csqc_progname", newcsprogs);
 633                                                 wantrestart = true;
 634                                         }
 635                                 }
 636                         }
 637                 }
 638                 if (wantrestart)
 639                 {
 640                         LOG_INFOF("Restart requested");
 641                         changelevel(mapname);
 642                         // let initialization continue, shutdown depends on it
 643                 }
 644         }
 645
 646         cvar = cvar_normal;
 647         cvar_string = cvar_string_normal;
 648         cvar_set = cvar_set_normal;
 649
 650         if(world_already_spawned)
 651                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 652         world_already_spawned = true;
 653
 654         delete_fn = remove_safely; // during spawning, watch what you remove!
 655
 656         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 657
 658         // needs to be done so early because of the constants they create
 659         static_init();
 660
 661         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 662
 663         TemporaryDB = db_create();
 664
 665         // 0 normal
 666         lightstyle(0, "m");
 667
 668         // 1 FLICKER (first variety)
 669         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 670
 671         // 2 SLOW STRONG PULSE
 672         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 673
 674         // 3 CANDLE (first variety)
 675         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 676
 677         // 4 FAST STROBE
 678         lightstyle(4, "mamamamamama");
 679
 680         // 5 GENTLE PULSE 1
 681         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 682
 683         // 6 FLICKER (second variety)
 684         lightstyle(6, "nmonqnmomnmomomno");
 685
 686         // 7 CANDLE (second variety)
 687         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 688
 689         // 8 CANDLE (third variety)
 690         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 691
 692         // 9 SLOW STROBE (fourth variety)
 693         lightstyle(9, "aaaaaaaazzzzzzzz");
 694
 695         // 10 FLUORESCENT FLICKER
 696         lightstyle(10, "mmamammmmammamamaaamammma");
 697
 698         // 11 SLOW PULSE NOT FADE TO BLACK
 699         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 700
 701         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 702
 703         // 63 testing
 704         lightstyle(63, "a");
 705
 706         if(autocvar_g_campaign)
 707                 CampaignPreInit();
 708
 709         Map_MarkAsRecent(mapname);
 710
 711         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 712
 713         InitGameplayMode();
 714         static_init_late();
 715         static_init_precache();
 716         readlevelcvars();
 717         GrappleHookInit();
 718
 719     GameRules_limit_fallbacks();
 720
 721         if(warmup_limit == 0)
 722                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 723
 724         player_count = 0;
 725         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 726         if(bot_waypoints_for_items == 1)
 727                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 728                         bot_waypoints_for_items = 0;
 729
 730         precache();
 731
 732         WaypointSprite_Init();
 733
 734         GameLogInit(); // prepare everything
 735         // NOTE for matchid:
 736         // changing the logic generating it is okay. But:
 737         // it HAS to stay <= 64 chars
 738         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 739         if(autocvar_sv_eventlog)
 740         {
 741                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 742                 matchid = strzone(s);
 743
 744                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 745                 s = ":gameinfo:mutators:LIST";
 746
 747                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 748                 s = M_ARGV(0, string);
 749
 750                 // initialiation stuff, not good in the mutator system
 751                 if(!autocvar_g_use_ammunition)
 752                         s = strcat(s, ":no_use_ammunition");
 753
 754                 // initialiation stuff, not good in the mutator system
 755                 if(autocvar_g_pickup_items == 0)
 756                         s = strcat(s, ":no_pickup_items");
 757                 if(autocvar_g_pickup_items > 0)
 758                         s = strcat(s, ":pickup_items");
 759
 760                 // initialiation stuff, not good in the mutator system
 761                 if(autocvar_g_weaponarena != "0")
 762                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 763
 764                 // TODO to mutator system
 765                 if(autocvar_g_norecoil)
 766                         s = strcat(s, ":norecoil");
 767
 768                 // TODO to mutator system
 769                 if(autocvar_g_powerups == 0)
 770                         s = strcat(s, ":no_powerups");
 771                 if(autocvar_g_powerups > 0)
 772                         s = strcat(s, ":powerups");
 773
 774                 GameLogEcho(s);
 775                 GameLogEcho(":gameinfo:end");
 776         }
 777         else
 778                 matchid = strzone(ftos(random()));
 779
 780         cvar_set("nextmap", "");
 781
 782         SetDefaultAlpha();
 783
 784         if(autocvar_g_campaign)
 785                 CampaignPostInit();
 786
 787         Ban_LoadBans();
 788
 789         MapInfo_Enumerate();
 790         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 791
 792         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 793         {
 794                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 795                 if(fd != -1)
 796                 {
 797                         string s;
 798                         while((s = fgets(fd)))
 799                         {
 800                                 int l = tokenize_console(s);
 801                                 if(l < 2)
 802                                         continue;
 803                                 if(argv(0) == "cd")
 804                                 {
 805                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 806                                         LOG_INFO("  cdtrack ", argv(2));
 807                                 }
 808                                 else if(argv(0) == "fog")
 809                                 {
 810                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 811                                         LOG_INFO("  \"fog\" \"", s, "\"");
 812                                 }
 813                                 else if(argv(0) == "set")
 814                                 {
 815                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 816                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 817                                 }
 818                                 else if(argv(0) != "//")
 819                                 {
 820                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 821                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 822                                 }
 823                         }
 824                         fclose(fd);
 825                 }
 826         }
 827
 828         WeaponStats_Init();
 829
 830         Nagger_Init();
 831
 832         next_pingtime = time + 5;
 833
 834         // set up information replies for clients and server to use
 835         maplist_reply = strzone(getmaplist());
 836         lsmaps_reply = strzone(getlsmaps());
 837         monsterlist_reply = strzone(getmonsterlist());
 838         for(int i = 0; i < 10; ++i)
 839         {
 840                 string s = getrecords(i);
 841                 if (s)
 842                         records_reply[i] = strzone(s);
 843         }
 844         ladder_reply = strzone(getladder());
 845         rankings_reply = strzone(getrankings());
 846
 847         // begin other init
 848         ClientInit_Spawn();
 849         RandomSeed_Spawn();
 850         PingPLReport_Spawn();
 851
 852         CheatInit();
 853
 854         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 855
 856         // fill sv_curl_serverpackages from .serverpackage files
 857         if (autocvar_sv_curl_serverpackages_auto)
 858         {
 859                 string s = "csprogs-" WATERMARK ".txt";
 860                 // remove automatically managed files from the list to prevent duplicates
 861                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 862                 {
 863                         string pkg = argv(i);
 864                         if (startsWith(pkg, "csprogs-")) continue;
 865                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 866                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 867                         s = cons(s, pkg);
 868                 }
 869                 // add automatically managed files to the list
 870                 #define X(match) MACRO_BEGIN { \
 871                         int fd = search_begin(match, true, false); \
 872                         if (fd >= 0) \
 873                         { \
 874                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 875                                 { \
 876                                         s = cons(s, search_getfilename(fd, i)); \
 877                                 } \
 878                                 search_end(fd); \
 879                         } \
 880                 } MACRO_END
 881                 X("*-serverpackage.txt");
 882                 X("*.serverpackage");
 883                 #undef X
 884                 cvar_set("sv_curl_serverpackages", s);
 885         }
 886
 887         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 888         modname = "Xonotic";
 889         // physics/balance/config changes that count as mod
 890         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 891                 modname = cvar_string("g_mod_physics");
 892         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 893                 modname = cvar_string("g_mod_balance");
 894         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 895                 modname = cvar_string("g_mod_config");
 896         // extra mutators that deserve to count as mod
 897         MUTATOR_CALLHOOK(SetModname, modname);
 898         modname = M_ARGV(0, string);
 899
 900         // save it for later
 901         modname = strzone(modname);
 902
 903         WinningConditionHelper(this); // set worldstatus
 904
 905         world_initialized = 1;
 906         __spawnfunc_spawn_all();
 907 }
 908
 909 spawnfunc(light)
 910 {
 911         //makestatic (this); // Who the f___ did that?
 912         delete(this);
 913 }
 914
 915 string GetGametype()
 916 {
 917         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 918 }
 919
 920 string GetMapname()
 921 {
 922         return mapname;
 923 }
 924
 925 float Map_Count, Map_Current;
 926 string Map_Current_Name;
 927
 928 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 929 float GetMaplistPosition()
 930 {
 931         float pos, idx;
 932         string map;
 933
 934         map = GetMapname();
 935         idx = autocvar_g_maplist_index;
 936
 937         if(idx >= 0)
 938                 if(idx < Map_Count)
 939                         if(map == argv(idx))
 940                                 return idx;
 941
 942         for(pos = 0; pos < Map_Count; ++pos)
 943                 if(map == argv(pos))
 944                         return pos;
 945
 946         // resume normal maplist rotation if current map is not in g_maplist
 947         return idx;
 948 }
 949
 950 bool MapHasRightSize(string map)
 951 {
 952         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 953         if(autocvar_g_maplist_check_waypoints)
 954         {
 955                 string checkwp_msg = strcat("checkwp ", map);
 956                 if(!fexists(strcat("maps/", map, ".waypoints")))
 957                 {
 958                         LOG_TRACE(checkwp_msg, ": no waypoints");
 959                         return false;
 960                 }
 961                 LOG_TRACE(checkwp_msg, ": has waypoints");
 962         }
 963
 964         // open map size restriction file
 965         string opensize_msg = strcat("opensize ", map);
 966         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 967         if(fh >= 0)
 968         {
 969                 opensize_msg = strcat(opensize_msg, ": ok, ");
 970                 int mapmin = stoi(fgets(fh));
 971                 int mapmax = stoi(fgets(fh));
 972                 fclose(fh);
 973                 if(player_count < mapmin)
 974                 {
 975                         LOG_TRACE(opensize_msg, "not enough");
 976                         return false;
 977                 }
 978                 if(mapmax && player_count > mapmax)
 979                 {
 980                         LOG_TRACE(opensize_msg, "too many");
 981                         return false;
 982                 }
 983                 LOG_TRACE(opensize_msg, "right size");
 984                 return true;
 985         }
 986         LOG_TRACE(opensize_msg, ": not found");
 987         return true;
 988 }
 989
 990 string Map_Filename(float position)
 991 {
 992         return strcat("maps/", argv(position), ".bsp");
 993 }
 994
 995 void Map_MarkAsRecent(string m)
 996 {
 997         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 998 }
 999
1000 float Map_IsRecent(string m)
1001 {
1002         return strhasword(autocvar_g_maplist_mostrecent, m);
1003 }
1004
1005 float Map_Check(float position, float pass)
1006 {
1007         string filename;
1008         string map_next;
1009         map_next = argv(position);
1010         if(pass <= 1)
1011         {
1012                 if(Map_IsRecent(map_next))
1013                         return 0;
1014         }
1015         filename = Map_Filename(position);
1016         if(MapInfo_CheckMap(map_next))
1017         {
1018                 if(pass == 2)
1019                         return 1;
1020                 if(MapHasRightSize(map_next))
1021                         return 1;
1022                 return 0;
1023         }
1024         else
1025                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1026
1027         return 0;
1028 }
1029
1030 void Map_Goto_SetStr(string nextmapname)
1031 {
1032         if(getmapname_stored != "")
1033                 strunzone(getmapname_stored);
1034         if(nextmapname == "")
1035                 getmapname_stored = "";
1036         else
1037                 getmapname_stored = strzone(nextmapname);
1038 }
1039
1040 void Map_Goto_SetFloat(float position)
1041 {
1042         cvar_set("g_maplist_index", ftos(position));
1043         Map_Goto_SetStr(argv(position));
1044 }
1045
1046 void Map_Goto(float reinit)
1047 {
1048         MapInfo_LoadMap(getmapname_stored, reinit);
1049 }
1050
1051 // return codes of map selectors:
1052 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1053 //   -2 = permanent failure
1054 float MaplistMethod_Iterate() // usual method
1055 {
1056         float pass, i;
1057
1058         LOG_TRACE("Trying MaplistMethod_Iterate");
1059
1060         for(pass = 1; pass <= 2; ++pass)
1061         {
1062                 for(i = 1; i < Map_Count; ++i)
1063                 {
1064                         float mapindex;
1065                         mapindex = (i + Map_Current) % Map_Count;
1066                         if(Map_Check(mapindex, pass))
1067                                 return mapindex;
1068                 }
1069         }
1070         return -1;
1071 }
1072
1073 float MaplistMethod_Repeat() // fallback method
1074 {
1075         LOG_TRACE("Trying MaplistMethod_Repeat");
1076
1077         if(Map_Check(Map_Current, 2))
1078                 return Map_Current;
1079         return -2;
1080 }
1081
1082 float MaplistMethod_Random() // random map selection
1083 {
1084         float i, imax;
1085
1086         LOG_TRACE("Trying MaplistMethod_Random");
1087
1088         imax = 42;
1089
1090         for(i = 0; i <= imax; ++i)
1091         {
1092                 float mapindex;
1093                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1094                 if(Map_Check(mapindex, 1))
1095                         return mapindex;
1096         }
1097         return -1;
1098 }
1099
1100 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1101 // the exponent sets a bias on the map selection:
1102 // the higher the exponent, the less likely "shortly repeated" same maps are
1103 {
1104         float i, j, imax, insertpos;
1105
1106         LOG_TRACE("Trying MaplistMethod_Shuffle");
1107
1108         imax = 42;
1109
1110         for(i = 0; i <= imax; ++i)
1111         {
1112                 string newlist;
1113
1114                 // now reinsert this at another position
1115                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1116                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1117                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1118                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1119
1120                 // insert the current map there
1121                 newlist = "";
1122                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1123                         newlist = strcat(newlist, " ", argv(j));
1124                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1125                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1126                         newlist = strcat(newlist, " ", argv(j));
1127                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1128                 cvar_set("g_maplist", newlist);
1129                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1130
1131                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1132                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1133                 if(Map_Check(Map_Current, 1))
1134                         return Map_Current;
1135         }
1136         return -1;
1137 }
1138
1139 void Maplist_Init()
1140 {
1141         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1142         float i;
1143         for (i = 0; i < Map_Count; ++i)
1144                 if (Map_Check(i, 2))
1145                         break;
1146         if (i == Map_Count)
1147         {
1148                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1149                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1150                 if(autocvar_g_maplist_shuffle)
1151                         ShuffleMaplist();
1152                 localcmd("\nmenu_cmd sync\n");
1153                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1154         }
1155         if(Map_Count == 0)
1156                 error("empty maplist, cannot select a new map");
1157         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1158
1159         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1160         // this may or may not be correct, but who cares, in the worst case a map
1161         // isn't chosen in the first pass that should have been
1162 }
1163
1164 string GetNextMap()
1165 {
1166         float nextMap;
1167
1168         Maplist_Init();
1169         nextMap = -1;
1170
1171         if(nextMap == -1)
1172                 if(autocvar_g_maplist_shuffle > 0)
1173                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1174
1175         if(nextMap == -1)
1176                 if(autocvar_g_maplist_selectrandom)
1177                         nextMap = MaplistMethod_Random();
1178
1179         if(nextMap == -1)
1180                 nextMap = MaplistMethod_Iterate();
1181
1182         if(nextMap == -1)
1183                 nextMap = MaplistMethod_Repeat();
1184
1185         if(nextMap >= 0)
1186         {
1187                 Map_Goto_SetFloat(nextMap);
1188                 return getmapname_stored;
1189         }
1190
1191         return "";
1192 }
1193
1194 float DoNextMapOverride(float reinit)
1195 {
1196         if(autocvar_g_campaign)
1197         {
1198                 CampaignPostIntermission();
1199                 alreadychangedlevel = true;
1200                 return true;
1201         }
1202         if(autocvar_quit_when_empty)
1203         {
1204                 if(player_count <= currentbots)
1205                 {
1206                         localcmd("quit\n");
1207                         alreadychangedlevel = true;
1208                         return true;
1209                 }
1210         }
1211         if(autocvar_quit_and_redirect != "")
1212         {
1213                 redirection_target = strzone(autocvar_quit_and_redirect);
1214                 alreadychangedlevel = true;
1215                 return true;
1216         }
1217         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1218         {
1219                 localcmd("restart\n");
1220                 alreadychangedlevel = true;
1221                 return true;
1222         }
1223         if(autocvar_nextmap != "")
1224         {
1225                 string m;
1226                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1227                 cvar_set("nextmap",m);
1228
1229                 if(!m || gametypevote)
1230                         return false;
1231                 if(autocvar_sv_vote_gametype)
1232                 {
1233                         Map_Goto_SetStr(m);
1234                         return false;
1235                 }
1236
1237                 if(MapInfo_CheckMap(m))
1238                 {
1239                         Map_Goto_SetStr(m);
1240                         Map_Goto(reinit);
1241                         alreadychangedlevel = true;
1242                         return true;
1243                 }
1244         }
1245         if(!reinit && autocvar_lastlevel)
1246         {
1247                 cvar_settemp_restore();
1248                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1249                 alreadychangedlevel = true;
1250                 return true;
1251         }
1252         return false;
1253 }
1254
1255 void GotoNextMap(float reinit)
1256 {
1257         //string nextmap;
1258         //float n, nummaps;
1259         //string s;
1260         if (alreadychangedlevel)
1261                 return;
1262         alreadychangedlevel = true;
1263
1264         string nextMap;
1265
1266         nextMap = GetNextMap();
1267         if(nextMap == "")
1268                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1269         Map_Goto(reinit);
1270 }
1271
1272
1273 /*
1274 ============
1275 IntermissionThink
1276
1277 When the player presses attack or jump, change to the next level
1278 ============
1279 */
1280 .float autoscreenshot;
1281 void IntermissionThink(entity this)
1282 {
1283         FixIntermissionClient(this);
1284
1285         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1286         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1287
1288         if( (server_screenshot || client_screenshot)
1289                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1290         {
1291                 this.autoscreenshot = -1;
1292                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1293                 return;
1294         }
1295
1296         if (time < intermission_exittime)
1297                 return;
1298
1299         if(!mapvote_initialized)
1300                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1301                         return;
1302
1303         MapVote_Start();
1304 }
1305
1306 /*
1307 ============
1308 FindIntermission
1309
1310 Returns the entity to view from
1311 ============
1312 */
1313 /*
1314 entity FindIntermission()
1315 {
1316         local   entity spot;
1317         local   float cyc;
1318
1319 // look for info_intermission first
1320         spot = find(NULL, classname, "info_intermission");
1321         if (spot)
1322         {       // pick a random one
1323                 cyc = random() * 4;
1324                 while (cyc > 1)
1325                 {
1326                         spot = find(spot, classname, "info_intermission");
1327                         if (!spot)
1328                                 spot = find(spot, classname, "info_intermission");
1329                         cyc = cyc - 1;
1330                 }
1331                 return spot;
1332         }
1333
1334 // then look for the start position
1335         spot = find(NULL, classname, "info_player_start");
1336         if (spot)
1337                 return spot;
1338
1339 // testinfo_player_start is only found in regioned levels
1340         spot = find(NULL, classname, "testplayerstart");
1341         if (spot)
1342                 return spot;
1343
1344 // then look for the start position
1345         spot = find(NULL, classname, "info_player_deathmatch");
1346         if (spot)
1347                 return spot;
1348
1349         //objerror ("FindIntermission: no spot");
1350         return NULL;
1351 }
1352 */
1353
1354 /*
1355 ===============================================================================
1356
1357 RULES
1358
1359 ===============================================================================
1360 */
1361
1362 void DumpStats(float final)
1363 {
1364         float file;
1365         string s;
1366         float to_console;
1367         float to_eventlog;
1368         float to_file;
1369         float i;
1370
1371         to_console = autocvar_sv_logscores_console;
1372         to_eventlog = autocvar_sv_eventlog;
1373         to_file = autocvar_sv_logscores_file;
1374
1375         if(!final)
1376         {
1377                 to_console = true; // always print printstats replies
1378                 to_eventlog = false; // but never print them to the event log
1379         }
1380
1381         if(to_eventlog)
1382                 if(autocvar_sv_eventlog_console)
1383                         to_console = false; // otherwise we get the output twice
1384
1385         if(final)
1386                 s = ":scores:";
1387         else
1388                 s = ":status:";
1389         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1390
1391         if(to_console)
1392                 LOG_INFO(s);
1393         if(to_eventlog)
1394                 GameLogEcho(s);
1395
1396         file = -1;
1397         if(to_file)
1398         {
1399                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1400                 if(file == -1)
1401                         to_file = false;
1402                 else
1403                         fputs(file, strcat(s, "\n"));
1404         }
1405
1406         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1407         if(to_console)
1408                 LOG_INFO(s);
1409         if(to_eventlog)
1410                 GameLogEcho(s);
1411         if(to_file)
1412                 fputs(file, strcat(s, "\n"));
1413
1414         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1415                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1416                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1417                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1418                         s = strcat(s, ftos(it.team), ":");
1419                 else
1420                         s = strcat(s, "spectator:");
1421
1422                 if(to_console)
1423                         LOG_INFO(s, playername(it, false));
1424                 if(to_eventlog)
1425                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1426                 if(to_file)
1427                         fputs(file, strcat(s, playername(it, false), "\n"));
1428         });
1429
1430         if(teamplay)
1431         {
1432                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1433                 if(to_console)
1434                         LOG_INFO(s);
1435                 if(to_eventlog)
1436                         GameLogEcho(s);
1437                 if(to_file)
1438                         fputs(file, strcat(s, "\n"));
1439
1440                 for(i = 1; i < 16; ++i)
1441                 {
1442                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1443                         s = strcat(s, ":", ftos(i));
1444                         if(to_console)
1445                                 LOG_INFO(s);
1446                         if(to_eventlog)
1447                                 GameLogEcho(s);
1448                         if(to_file)
1449                                 fputs(file, strcat(s, "\n"));
1450                 }
1451         }
1452
1453         if(to_console)
1454                 LOG_INFO(":end");
1455         if(to_eventlog)
1456                 GameLogEcho(":end");
1457         if(to_file)
1458         {
1459                 fputs(file, ":end\n");
1460                 fclose(file);
1461         }
1462 }
1463
1464 void FixIntermissionClient(entity e)
1465 {
1466         if(!e.autoscreenshot) // initial call
1467         {
1468                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1469                 e.health = -2342;
1470                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1471                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1472                 {
1473                     .entity weaponentity = weaponentities[slot];
1474                         if(e.(weaponentity))
1475                         {
1476                                 e.(weaponentity).effects = EF_NODRAW;
1477                                 if (e.(weaponentity).weaponchild)
1478                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1479                         }
1480                 }
1481                 if(IS_REAL_CLIENT(e))
1482                 {
1483                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1484                         RandomSelection_Init();
1485                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1486                                 RandomSelection_AddString(it, 1, 1);
1487                         });
1488                         if (RandomSelection_chosen_string != "")
1489                         {
1490                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1491                         }
1492                         msg_entity = e;
1493                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1494                 }
1495         }
1496 }
1497
1498 /*
1499 go to the next level for deathmatch
1500 only called if a time or frag limit has expired
1501 */
1502 void NextLevel()
1503 {
1504         game_stopped = true;
1505         intermission_running = 1; // game over
1506
1507         // enforce a wait time before allowing changelevel
1508         if(player_count > 0)
1509                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1510         else
1511                 intermission_exittime = -1;
1512
1513         /*
1514         WriteByte (MSG_ALL, SVC_CDTRACK);
1515         WriteByte (MSG_ALL, 3);
1516         WriteByte (MSG_ALL, 3);
1517         // done in FixIntermission
1518         */
1519
1520         //pos = FindIntermission ();
1521
1522         VoteReset();
1523
1524         DumpStats(true);
1525
1526         // send statistics
1527         PlayerStats_GameReport(true);
1528         WeaponStats_Shutdown();
1529
1530         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1531
1532         if(autocvar_sv_eventlog)
1533                 GameLogEcho(":gameover");
1534
1535         GameLogClose();
1536
1537         FOREACH_CLIENT(IS_PLAYER(it), {
1538                 FixIntermissionClient(it);
1539                 if(it.winning)
1540                         bprint(playername(it, false), " ^7wins.\n");
1541         });
1542
1543         target_music_kill();
1544
1545         if(autocvar_g_campaign)
1546                 CampaignPreIntermission();
1547
1548         MUTATOR_CALLHOOK(MatchEnd);
1549
1550         localcmd("\nsv_hook_gameend\n");
1551 }
1552
1553
1554 float InitiateSuddenDeath()
1555 {
1556         // Check first whether normal overtimes could be added before initiating suddendeath mode
1557         // - for this timelimit_overtime needs to be >0 of course
1558         // - also check the winning condition calculated in the previous frame and only add normal overtime
1559         //   again, if at the point at which timelimit would be extended again, still no winner was found
1560         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1561         {
1562                 return 1; // need to call InitiateOvertime later
1563         }
1564         else
1565         {
1566                 if(!checkrules_suddendeathend)
1567                 {
1568                         if(autocvar_g_campaign)
1569                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1570                         else
1571                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1572                         if(g_race && !g_race_qualifying)
1573                                 race_StartCompleting();
1574                 }
1575                 return 0;
1576         }
1577 }
1578
1579 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1580 {
1581         ++checkrules_overtimesadded;
1582         //add one more overtime by simply extending the timelimit
1583         float tl;
1584         tl = autocvar_timelimit;
1585         tl += autocvar_timelimit_overtime;
1586         cvar_set("timelimit", ftos(tl));
1587
1588         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1589 }
1590
1591 float GetWinningCode(float fraglimitreached, float equality)
1592 {
1593         if(autocvar_g_campaign == 1)
1594                 if(fraglimitreached)
1595                         return WINNING_YES;
1596                 else
1597                         return WINNING_NO;
1598
1599         else
1600                 if(equality)
1601                         if(fraglimitreached)
1602                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1603                         else
1604                                 return WINNING_NEVER;
1605                 else
1606                         if(fraglimitreached)
1607                                 return WINNING_YES;
1608                         else
1609                                 return WINNING_NO;
1610 }
1611
1612 // set the .winning flag for exactly those players with a given field value
1613 void SetWinners(.float field, float value)
1614 {
1615         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1616 }
1617
1618 // set the .winning flag for those players with a given field value
1619 void AddWinners(.float field, float value)
1620 {
1621         FOREACH_CLIENT(IS_PLAYER(it), {
1622                 if(it.(field) == value)
1623                         it.winning = 1;
1624         });
1625 }
1626
1627 // clear the .winning flags
1628 void ClearWinners()
1629 {
1630         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1631 }
1632
1633 void ShuffleMaplist()
1634 {
1635         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1636 }
1637
1638 float leaderfrags;
1639 float WinningCondition_Scores(float limit, float leadlimit)
1640 {
1641         float limitreached;
1642
1643         // TODO make everything use THIS winning condition (except LMS)
1644         WinningConditionHelper(NULL);
1645
1646         if(teamplay)
1647         {
1648                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1649                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1650                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1651                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1652         }
1653
1654         ClearWinners();
1655         if(WinningConditionHelper_winner)
1656                 WinningConditionHelper_winner.winning = 1;
1657         if(WinningConditionHelper_winnerteam >= 0)
1658                 SetWinners(team, WinningConditionHelper_winnerteam);
1659
1660         if(WinningConditionHelper_lowerisbetter)
1661         {
1662                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1663                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1664                 limit = -limit;
1665         }
1666
1667         if(WinningConditionHelper_zeroisworst)
1668                 leadlimit = 0; // not supported in this mode
1669
1670         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1671         // these modes always score in increments of 1, thus this makes sense
1672         {
1673                 if(leaderfrags != WinningConditionHelper_topscore)
1674                 {
1675                         leaderfrags = WinningConditionHelper_topscore;
1676
1677                         if (limit)
1678                         if (leaderfrags == limit - 1)
1679                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1680                         else if (leaderfrags == limit - 2)
1681                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1682                         else if (leaderfrags == limit - 3)
1683                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1684                 }
1685         }
1686
1687         limitreached = false;
1688         if(limit)
1689                 if(WinningConditionHelper_topscore >= limit)
1690                         limitreached = true;
1691         if(leadlimit)
1692         {
1693                 float leadlimitreached;
1694                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1695                 if(autocvar_leadlimit_and_fraglimit)
1696                         limitreached = (limitreached && leadlimitreached);
1697                 else
1698                         limitreached = (limitreached || leadlimitreached);
1699         }
1700
1701         if(limit)
1702                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1703
1704         return GetWinningCode(
1705                 WinningConditionHelper_topscore && limitreached,
1706                 WinningConditionHelper_equality
1707         );
1708 }
1709
1710 float WinningCondition_RanOutOfSpawns()
1711 {
1712         if(have_team_spawns <= 0)
1713                 return WINNING_NO;
1714
1715         if(!autocvar_g_spawn_useallspawns)
1716                 return WINNING_NO;
1717
1718         if(!some_spawn_has_been_used)
1719                 return WINNING_NO;
1720
1721         team1_score = team2_score = team3_score = team4_score = 0;
1722
1723         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
1724                 switch(it.team)
1725                 {
1726                         case NUM_TEAM_1: team1_score = 1; break;
1727                         case NUM_TEAM_2: team2_score = 1; break;
1728                         case NUM_TEAM_3: team3_score = 1; break;
1729                         case NUM_TEAM_4: team4_score = 1; break;
1730                 }
1731         });
1732
1733         IL_EACH(g_spawnpoints, true,
1734         {
1735                 switch(it.team)
1736                 {
1737                         case NUM_TEAM_1: team1_score = 1; break;
1738                         case NUM_TEAM_2: team2_score = 1; break;
1739                         case NUM_TEAM_3: team3_score = 1; break;
1740                         case NUM_TEAM_4: team4_score = 1; break;
1741                 }
1742         });
1743
1744         ClearWinners();
1745         if(team1_score + team2_score + team3_score + team4_score == 0)
1746         {
1747                 checkrules_equality = true;
1748                 return WINNING_YES;
1749         }
1750         else if(team1_score + team2_score + team3_score + team4_score == 1)
1751         {
1752                 float t, i;
1753                 if(team1_score)
1754                         t = NUM_TEAM_1;
1755                 else if(team2_score)
1756                         t = NUM_TEAM_2;
1757                 else if(team3_score)
1758                         t = NUM_TEAM_3;
1759                 else // if(team4_score)
1760                         t = NUM_TEAM_4;
1761                 CheckAllowedTeams(NULL);
1762                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1763                 {
1764                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1765                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1766                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1767                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1768                 }
1769
1770                 AddWinners(team, t);
1771                 return WINNING_YES;
1772         }
1773         else
1774                 return WINNING_NO;
1775 }
1776
1777 /*
1778 ============
1779 CheckRules_World
1780
1781 Exit deathmatch games upon conditions
1782 ============
1783 */
1784 void CheckRules_World()
1785 {
1786         float timelimit;
1787         float fraglimit;
1788         float leadlimit;
1789
1790         VoteThink();
1791         MapVote_Think();
1792
1793         SetDefaultAlpha();
1794
1795         if (intermission_running) // someone else quit the game already
1796         {
1797                 if(player_count == 0) // Nobody there? Then let's go to the next map
1798                         MapVote_Start();
1799                         // this will actually check the player count in the next frame
1800                         // again, but this shouldn't hurt
1801                 return;
1802         }
1803
1804         timelimit = autocvar_timelimit * 60;
1805         fraglimit = autocvar_fraglimit;
1806         leadlimit = autocvar_leadlimit;
1807
1808         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1809         {
1810                 if(timelimit > 0)
1811                         timelimit = 0; // timelimit is not made for warmup
1812                 if(fraglimit > 0)
1813                         fraglimit = 0; // no fraglimit for now
1814                 leadlimit = 0; // no leadlimit for now
1815         }
1816
1817         if(timelimit > 0)
1818         {
1819                 timelimit += game_starttime;
1820         }
1821         else if (timelimit < 0)
1822         {
1823                 // endmatch
1824                 NextLevel();
1825                 return;
1826         }
1827
1828         float wantovertime;
1829         wantovertime = 0;
1830
1831         if(timelimit > game_starttime)
1832                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1833         else
1834                 game_completion_ratio = 0;
1835
1836         if(checkrules_suddendeathend)
1837         {
1838                 if(!checkrules_suddendeathwarning)
1839                 {
1840                         checkrules_suddendeathwarning = true;
1841                         if(g_race && !g_race_qualifying)
1842                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1843                         else
1844                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1845                 }
1846         }
1847         else
1848         {
1849                 if (timelimit && time >= timelimit)
1850                 {
1851                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1852                         {
1853                                 float totalplayers;
1854                                 float playerswithlaps;
1855                                 float readyplayers;
1856                                 totalplayers = playerswithlaps = readyplayers = 0;
1857                                 FOREACH_CLIENT(IS_PLAYER(it), {
1858                                         ++totalplayers;
1859                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1860                                                 ++playerswithlaps;
1861                                         if(it.ready)
1862                                                 ++readyplayers;
1863                                 });
1864
1865                                 // at least 2 of the players have completed a lap: start the RACE
1866                                 // otherwise, the players should end the qualifying on their own
1867                                 if(readyplayers || playerswithlaps >= 2)
1868                                 {
1869                                         checkrules_suddendeathend = 0;
1870                                         ReadyRestart(); // go to race
1871                                         return;
1872                                 }
1873                                 else
1874                                         wantovertime |= InitiateSuddenDeath();
1875                         }
1876                         else
1877                                 wantovertime |= InitiateSuddenDeath();
1878                 }
1879         }
1880
1881         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1882         {
1883                 NextLevel();
1884                 return;
1885         }
1886
1887         int checkrules_status = WinningCondition_RanOutOfSpawns();
1888         if(checkrules_status == WINNING_YES)
1889                 bprint("Hey! Someone ran out of spawns!\n");
1890         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1891                 checkrules_status = M_ARGV(0, float);
1892         else
1893                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1894
1895         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1896         {
1897                 checkrules_status = WINNING_NEVER;
1898                 checkrules_overtimesadded = -1;
1899                 wantovertime |= InitiateSuddenDeath();
1900         }
1901
1902         if(checkrules_status == WINNING_NEVER)
1903                 // equality cases! Nobody wins if the overtime ends in a draw.
1904                 ClearWinners();
1905
1906         if(wantovertime)
1907         {
1908                 if(checkrules_status == WINNING_NEVER)
1909                         InitiateOvertime();
1910                 else
1911                         checkrules_status = WINNING_YES;
1912         }
1913
1914         if(checkrules_suddendeathend)
1915                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1916                         checkrules_status = WINNING_YES;
1917
1918         if(checkrules_status == WINNING_YES)
1919         {
1920                 //print("WINNING\n");
1921                 NextLevel();
1922         }
1923 }
1924
1925 string GotoMap(string m)
1926 {
1927         m = GameTypeVote_MapInfo_FixName(m);
1928         if (!m)
1929                 return "The map you suggested is not available on this server.";
1930         if (!autocvar_sv_vote_gametype)
1931         if(!MapInfo_CheckMap(m))
1932                 return "The map you suggested does not support the current game mode.";
1933         cvar_set("nextmap", m);
1934         cvar_set("timelimit", "-1");
1935         if(mapvote_initialized || alreadychangedlevel)
1936         {
1937                 if(DoNextMapOverride(0))
1938                         return "Map switch initiated.";
1939                 else
1940                         return "Hm... no. For some reason I like THIS map more.";
1941         }
1942         else
1943                 return "Map switch will happen after scoreboard.";
1944 }
1945
1946 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1947 void RunThink(entity this)
1948 {
1949         // don't let things stay in the past.
1950         // it is possible to start that way by a trigger with a local time.
1951         if(this.nextthink <= 0 || this.nextthink > time + frametime)
1952                 return;
1953
1954         float oldtime = time; // do we need to save this?
1955
1956         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
1957         {
1958                 time = max(oldtime, this.nextthink);
1959                 this.nextthink = 0;
1960
1961                 if(getthink(this))
1962                         getthink(this)(this);
1963                 // mods often set nextthink to time to cause a think every frame,
1964                 // we don't want to loop in that case, so exit if the new nextthink is
1965                 // <= the time the qc was told, also exit if it is past the end of the
1966                 // frame
1967                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
1968                         break;
1969         }
1970
1971         time = oldtime;
1972 }
1973
1974 bool autocvar_sv_freezenonclients;
1975 bool autocvar_sv_gameplayfix_delayprojectiles;
1976 void Physics_Frame()
1977 {
1978         if(autocvar_sv_freezenonclients)
1979                 return;
1980
1981         FOREACH_ENTITY_FLOAT(pure_data, false,
1982         {
1983                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
1984                         continue;
1985
1986                 //set_movetype(it, it.move_movetype);
1987                 // inline the set_movetype function, since this is called a lot
1988                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
1989
1990                 if(it.move_movetype == MOVETYPE_NONE)
1991                         continue;
1992
1993                 if(it.move_qcphysics)
1994                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
1995
1996                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
1997                 {
1998                         // handle thinking here
1999                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2000                                 RunThink(it);
2001                 }
2002         });
2003
2004         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2005                 return;
2006
2007         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2008         {
2009                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2010                         continue;
2011                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2012         });
2013 }
2014
2015 void systems_update();
2016 void EndFrame()
2017 {
2018         anticheat_endframe();
2019
2020         Physics_Frame();
2021
2022         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2023                 entity e = IS_SPEC(it) ? it.enemy : it;
2024                 if (e.typehitsound) {
2025                         STAT(TYPEHIT_TIME, it) = time;
2026                 } else if (e.killsound) {
2027                         STAT(KILL_TIME, it) = time;
2028                 } else if (e.damage_dealt) {
2029                         STAT(HIT_TIME, it) = time;
2030                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2031                 }
2032         });
2033         // add 1 frametime because after this, engine SV_Physics
2034         // increases time by a frametime and then networks the frame
2035         // add another frametime because client shows everything with
2036         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2037         // needed!
2038         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2039         FOREACH_CLIENT(true, {
2040                 it.typehitsound = false;
2041                 it.damage_dealt = 0;
2042                 it.killsound = false;
2043                 antilag_record(it, CS(it), altime);
2044         });
2045         IL_EACH(g_monsters, true,
2046         {
2047                 antilag_record(it, it, altime);
2048         });
2049         IL_EACH(g_projectiles, it.classname == "nade",
2050         {
2051                 antilag_record(it, it, altime);
2052         });
2053         systems_update();
2054         IL_ENDFRAME();
2055 }
2056
2057
2058 /*
2059  * RedirectionThink:
2060  * returns true if redirecting
2061  */
2062 float redirection_timeout;
2063 float redirection_nextthink;
2064 float RedirectionThink()
2065 {
2066         float clients_found;
2067
2068         if(redirection_target == "")
2069                 return false;
2070
2071         if(!redirection_timeout)
2072         {
2073                 cvar_set("sv_public", "-2");
2074                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2075                 if(redirection_target == "self")
2076                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2077                 else
2078                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2079         }
2080
2081         if(time < redirection_nextthink)
2082                 return true;
2083
2084         redirection_nextthink = time + 1;
2085
2086         clients_found = 0;
2087         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2088                 // TODO add timer
2089                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2090                 if(redirection_target == "self")
2091                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2092                 else
2093                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2094                 ++clients_found;
2095         });
2096
2097         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2098
2099         if(time > redirection_timeout || clients_found == 0)
2100                 localcmd("\nwait; wait; wait; quit\n");
2101
2102         return true;
2103 }
2104
2105 void RestoreGame()
2106 {
2107         // Loaded from a save game
2108         // some things then break, so let's work around them...
2109
2110         // Progs DB (capture records)
2111         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2112
2113         // Mapinfo
2114         MapInfo_Shutdown();
2115         MapInfo_Enumerate();
2116         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2117         WeaponStats_Init();
2118
2119         TargetMusic_RestoreGame();
2120 }
2121
2122 void Shutdown()
2123 {
2124         game_stopped = 2;
2125
2126         if(world_initialized > 0)
2127         {
2128                 world_initialized = 0;
2129                 LOG_TRACE("Saving persistent data...");
2130                 Ban_SaveBans();
2131
2132                 // playerstats with unfinished match
2133                 PlayerStats_GameReport(false);
2134
2135                 if(!cheatcount_total)
2136                 {
2137                         if(autocvar_sv_db_saveasdump)
2138                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2139                         else
2140                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2141                 }
2142                 if(autocvar_developer)
2143                 {
2144                         if(autocvar_sv_db_saveasdump)
2145                                 db_dump(TemporaryDB, "server-temp.db");
2146                         else
2147                                 db_save(TemporaryDB, "server-temp.db");
2148                 }
2149                 CheatShutdown(); // must be after cheatcount check
2150                 db_close(ServerProgsDB);
2151                 db_close(TemporaryDB);
2152                 LOG_TRACE("Saving persistent data... done!");
2153                 // tell the bot system the game is ending now
2154                 bot_endgame();
2155
2156                 WeaponStats_Shutdown();
2157                 MapInfo_Shutdown();
2158         }
2159         else if(world_initialized == 0)
2160         {
2161                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2162         }
2163         else
2164         {
2165                 __init_dedicated_server_shutdown();
2166         }
2167 }