qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_arena_point_leadlimit");
 307                 BADCVAR("g_balance_kill_delay");
 308                 BADCVAR("g_ca_point_leadlimit");
 309                 BADCVAR("g_ctf_captimerecord_always");
 310                 BADCVAR("g_ctf_flag_glowtrails");
 311                 BADCVAR("g_ctf_flag_pickup_verbosename");
 312                 BADCVAR("g_domination_point_leadlimit");
 313                 BADCVAR("g_forced_respawn");
 314                 BADCVAR("g_keyhunt_point_leadlimit");
 315                 BADPREFIX("g_mod_");
 316                 BADCVAR("g_nexball_goalleadlimit");
 317                 BADCVAR("leadlimit_and_fraglimit");
 318                 BADCVAR("leadlimit_override");
 319                 BADCVAR("pausable");
 320                 BADCVAR("sv_allow_fullbright");
 321                 BADCVAR("sv_checkforpacketsduringsleep");
 322                 BADCVAR("sv_fraginfo");
 323                 BADCVAR("sv_timeout");
 324                 BADPREFIX("sv_timeout_");
 325                 BADCVAR("welcome_message_time");
 326                 BADPREFIX("crypto_");
 327                 BADPREFIX("g_chat_");
 328                 BADPREFIX("g_ctf_captimerecord_");
 329                 BADPREFIX("g_maplist_votable_");
 330                 BADPREFIX("net_");
 331                 BADPREFIX("prvm_");
 332                 BADPREFIX("skill_");
 333                 BADPREFIX("sv_cullentities_");
 334                 BADPREFIX("sv_fraginfo_");
 335                 BADPREFIX("sv_maxidle_");
 336                 BADPREFIX("sv_vote_");
 337                 BADPREFIX("timelimit_");
 338                 BADCVAR("gameversion");
 339                 BADPREFIX("gameversion_");
 340                 BADCVAR("sv_namechangetimer");
 341
 342                 // allowed changes to server admins (please sync this to server.cfg)
 343                 // vi commands:
 344                 //   :/"impure"/,$d
 345                 //   :g!,^\/\/[^ /],d
 346                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 347                 //   :%!sort
 348                 // yes, this does contain some redundant stuff, don't really care
 349                 BADCVAR("bot_config_file");
 350                 BADCVAR("bot_number");
 351                 BADCVAR("bot_prefix");
 352                 BADCVAR("bot_suffix");
 353                 BADCVAR("capturelimit_override");
 354                 BADCVAR("fraglimit_override");
 355                 BADCVAR("gametype");
 356                 BADCVAR("g_antilag");
 357                 BADCVAR("g_balance_teams");
 358                 BADCVAR("g_balance_teams_prevent_imbalance");
 359                 BADCVAR("g_balance_teams_scorefactor");
 360                 BADCVAR("g_ban_sync_trusted_servers");
 361                 BADCVAR("g_ban_sync_uri");
 362                 BADCVAR("g_ctf_ignore_frags");
 363                 BADCVAR("g_domination_point_limit");
 364                 BADCVAR("g_friendlyfire");
 365                 BADCVAR("g_fullbrightitems");
 366                 BADCVAR("g_fullbrightplayers");
 367                 BADCVAR("g_keyhunt_point_limit");
 368                 BADCVAR("g_keyhunt_teams_override");
 369                 BADCVAR("g_lms_lives_override");
 370                 BADCVAR("g_maplist");
 371                 BADCVAR("g_maplist_check_waypoints");
 372                 BADCVAR("g_maplist_mostrecent_count");
 373                 BADCVAR("g_maplist_shuffle");
 374                 BADCVAR("g_maplist_votable");
 375                 BADCVAR("g_maplist_votable_abstain");
 376                 BADCVAR("g_maplist_votable_nodetail");
 377                 BADCVAR("g_maplist_votable_suggestions");
 378                 BADCVAR("g_maxplayers");
 379                 BADCVAR("g_mirrordamage");
 380                 BADCVAR("g_nexball_goallimit");
 381                 BADCVAR("g_powerups");
 382                 BADCVAR("g_start_delay");
 383                 BADCVAR("g_warmup");
 384                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 385                 BADCVAR("hostname");
 386                 BADCVAR("log_file");
 387                 BADCVAR("maxplayers");
 388                 BADCVAR("minplayers");
 389                 BADCVAR("net_address");
 390                 BADCVAR("port");
 391                 BADCVAR("rcon_password");
 392                 BADCVAR("rcon_restricted_commands");
 393                 BADCVAR("rcon_restricted_password");
 394                 BADCVAR("skill");
 395                 BADCVAR("sv_adminnick");
 396                 BADCVAR("sv_autoscreenshot");
 397                 BADCVAR("sv_autotaunt");
 398                 BADCVAR("sv_curl_defaulturl");
 399                 BADCVAR("sv_defaultcharacter");
 400                 BADCVAR("sv_defaultplayercolors");
 401                 BADCVAR("sv_defaultplayermodel");
 402                 BADCVAR("sv_defaultplayerskin");
 403                 BADCVAR("sv_maxidle");
 404                 BADCVAR("sv_maxrate");
 405                 BADCVAR("sv_motd");
 406                 BADCVAR("sv_public");
 407                 BADCVAR("sv_ready_restart");
 408                 BADCVAR("sv_status_privacy");
 409                 BADCVAR("sv_taunt");
 410                 BADCVAR("sv_vote_call");
 411                 BADCVAR("sv_vote_commands");
 412                 BADCVAR("sv_vote_majority_factor");
 413                 BADCVAR("sv_vote_master");
 414                 BADCVAR("sv_vote_master_commands");
 415                 BADCVAR("sv_vote_master_password");
 416                 BADCVAR("sv_vote_simple_majority_factor");
 417                 BADCVAR("sys_ticrate");
 418                 BADCVAR("teamplay_mode");
 419                 BADCVAR("timelimit_override");
 420                 BADCVAR("g_spawnshieldtime");
 421                 BADPREFIX("g_warmup_");
 422                 BADPREFIX("sv_ready_restart_");
 423
 424                 // mutators that announce themselves properly to the server browser
 425                 BADCVAR("g_minstagib");
 426                 BADCVAR("g_new_toys");
 427                 BADCVAR("g_nix");
 428
 429                 if(autocvar_g_minstagib)
 430                 {
 431                         BADCVAR("g_grappling_hook");
 432                         BADCVAR("g_jetpack");
 433                 }
 434 #undef BADPREFIX
 435 #undef BADCVAR
 436
 437                 if(pureadding)
 438                 {
 439                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 440                         if(strlen(cvar_purechanges) > 16384)
 441                         {
 442                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 443                                 pureadding = 0;
 444                         }
 445                 }
 446                 ++cvar_purechanges_count;
 447                 // WARNING: this variable is used for the server list
 448                 // NEVER dare to skip this code!
 449                 // Hacks to intentionally appearing as "pure server" even though you DO have
 450                 // modified settings may be punished by removal from the server list.
 451                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 452                 // though.
 453         }
 454         buf_del(h);
 455         if(cvar_changes == "")
 456                 cvar_changes = "// this server runs at default server settings\n";
 457         else
 458                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 459         cvar_changes = strzone(cvar_changes);
 460         if(cvar_purechanges == "")
 461                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 462         else
 463                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 464         cvar_purechanges = strzone(cvar_purechanges);
 465 }
 466
 467 void detect_maptype()
 468 {
 469 #if 0
 470         vector o, v;
 471         float i;
 472
 473         for(;;)
 474         {
 475                 o = world.mins;
 476                 o_x += random() * (world.maxs_x - world.mins_x);
 477                 o_y += random() * (world.maxs_y - world.mins_y);
 478                 o_z += random() * (world.maxs_z - world.mins_z);
 479
 480                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 481                 if(trace_fraction == 1)
 482                         continue;
 483
 484                 v = trace_endpos;
 485
 486                 for(i = 0; i < 64; i += 4)
 487                 {
 488                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 489         if(trace_fraction == 1)
 490                 continue;
 491                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 492                 }
 493
 494                 break;
 495         }
 496 #endif
 497 }
 498
 499 entity randomseed;
 500 float RandomSeed_Send(entity to, float sf)
 501 {
 502         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 503         WriteShort(MSG_ENTITY, self.cnt);
 504         return TRUE;
 505 }
 506 void RandomSeed_Think()
 507 {
 508         self.cnt = bound(0, floor(random() * 65536), 65535);
 509         self.nextthink = time + 5;
 510
 511         self.SendFlags |= 1;
 512 }
 513 void RandomSeed_Spawn()
 514 {
 515         randomseed = spawn();
 516         randomseed.think = RandomSeed_Think;
 517         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 518
 519         entity oldself;
 520         oldself = self;
 521         self = randomseed;
 522         self.think(); // sets random seed and nextthink
 523         self = oldself;
 524 }
 525
 526 void spawnfunc___init_dedicated_server(void)
 527 {
 528         // handler for _init/_init map (only for dedicated server initialization)
 529
 530         world_initialized = -1; // don't complain
 531         cvar = cvar_normal;
 532         cvar_string = cvar_string_normal;
 533         cvar_set = cvar_set_normal;
 534
 535         remove = remove_unsafely;
 536
 537         entity e;
 538         e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = spawn();
 543         e.classname = "info_player_deathmatch"; // safeguard against player joining
 544
 545         self.classname = "worldspawn"; // safeguard against various stuff ;)
 546
 547         // needs to be done so early because of the constants they create
 548         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 549         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 550         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 551         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 552
 553         MapInfo_Enumerate();
 554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 555 }
 556
 557 void Map_MarkAsRecent(string m);
 558 float world_already_spawned;
 559 void Nagger_Init();
 560 void ClientInit_Spawn();
 561 void WeaponStats_Init();
 562 void WeaponStats_Shutdown();
 563 void spawnfunc_worldspawn (void)
 564 {
 565         float fd, l, i, j, n;
 566         string s, col;
 567
 568         cvar = cvar_normal;
 569         cvar_string = cvar_string_normal;
 570         cvar_set = cvar_set_normal;
 571
 572         if(world_already_spawned)
 573                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 574         world_already_spawned = TRUE;
 575
 576         remove = remove_safely; // during spawning, watch what you remove!
 577
 578         check_unacceptable_compiler_bugs();
 579
 580         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 581
 582         compressShortVector_init();
 583
 584         allowed_to_spawn = TRUE;
 585
 586         entity head;
 587         head = nextent(world);
 588         maxclients = 0;
 589         while(head)
 590         {
 591                 ++maxclients;
 592                 head = nextent(head);
 593         }
 594
 595         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 596
 597         // needs to be done so early because of the constants they create
 598         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 599         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 600         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 601         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 602
 603         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 604
 605         TemporaryDB = db_create();
 606
 607         // 0 normal
 608         lightstyle(0, "m");
 609
 610         // 1 FLICKER (first variety)
 611         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 612
 613         // 2 SLOW STRONG PULSE
 614         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 615
 616         // 3 CANDLE (first variety)
 617         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 618
 619         // 4 FAST STROBE
 620         lightstyle(4, "mamamamamama");
 621
 622         // 5 GENTLE PULSE 1
 623         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 624
 625         // 6 FLICKER (second variety)
 626         lightstyle(6, "nmonqnmomnmomomno");
 627
 628         // 7 CANDLE (second variety)
 629         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 630
 631         // 8 CANDLE (third variety)
 632         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 633
 634         // 9 SLOW STROBE (fourth variety)
 635         lightstyle(9, "aaaaaaaazzzzzzzz");
 636
 637         // 10 FLUORESCENT FLICKER
 638         lightstyle(10, "mmamammmmammamamaaamammma");
 639
 640         // 11 SLOW PULSE NOT FADE TO BLACK
 641         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 642
 643         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 644
 645         // 63 testing
 646         lightstyle(63, "a");
 647
 648         if(autocvar_g_campaign)
 649                 CampaignPreInit();
 650
 651         Map_MarkAsRecent(mapname);
 652
 653         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 654
 655         precache_model ("null"); // we need this one before InitGameplayMode
 656         InitGameplayMode();
 657         readlevelcvars();
 658         GrappleHookInit();
 659         ElectroInit();
 660         LaserInit();
 661
 662         player_count = 0;
 663         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 664         if(bot_waypoints_for_items == 1)
 665                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 666                         bot_waypoints_for_items = 0;
 667
 668         precache();
 669
 670         WaypointSprite_Init();
 671
 672         GameLogInit(); // prepare everything
 673         // NOTE for matchid:
 674         // changing the logic generating it is okay. But:
 675         // it HAS to stay <= 64 chars
 676         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 677         if(autocvar_sv_eventlog)
 678         {
 679                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 680                 matchid = strzone(s);
 681
 682                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 683                 s = ":gameinfo:mutators:LIST";
 684
 685                 ret_string = s;
 686                 MUTATOR_CALLHOOK(BuildMutatorsString);
 687                 s = ret_string;
 688
 689                 // simple, probably not good in the mutator system
 690                 if(autocvar_g_grappling_hook)
 691                         s = strcat(s, ":grappling_hook");
 692
 693                 // initialiation stuff, not good in the mutator system
 694                 if(!autocvar_g_use_ammunition)
 695                         s = strcat(s, ":no_use_ammunition");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(autocvar_g_pickup_items == 0)
 699                         s = strcat(s, ":no_pickup_items");
 700                 if(autocvar_g_pickup_items > 0)
 701                         s = strcat(s, ":pickup_items");
 702
 703                 // initialiation stuff, not good in the mutator system
 704                 if(autocvar_g_weaponarena != "0")
 705                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 706
 707                 // TODO to mutator system
 708                 if(autocvar_g_norecoil)
 709                         s = strcat(s, ":norecoil");
 710
 711                 // TODO to mutator system
 712                 if(autocvar_g_midair)
 713                         s = strcat(s, ":midair");
 714
 715                 // TODO to mutator system
 716                 if(autocvar_g_minstagib)
 717                         s = strcat(s, ":minstagib");
 718
 719                 // TODO to mutator system
 720                 if(autocvar_g_powerups == 0)
 721                         s = strcat(s, ":no_powerups");
 722                 if(autocvar_g_powerups > 0)
 723                         s = strcat(s, ":powerups");
 724
 725                 GameLogEcho(s);
 726                 GameLogEcho(":gameinfo:end");
 727         }
 728         else
 729                 matchid = strzone(ftos(random()));
 730
 731         cvar_set("nextmap", "");
 732
 733         SetDefaultAlpha();
 734
 735         if(autocvar_g_campaign)
 736                 CampaignPostInit();
 737
 738         fteqcc_testbugs();
 739
 740         Ban_LoadBans();
 741
 742         MapInfo_Enumerate();
 743         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 744
 745         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 746         {
 747                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 748                 if(fd != -1)
 749                 {
 750                         while((s = fgets(fd)))
 751                         {
 752                                 l = tokenize_console(s);
 753                                 if(l < 2)
 754                                         continue;
 755                                 if(argv(0) == "cd")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  cdtrack ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) == "fog")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 763                                         print("  \"fog\" \"", s, "\"\n");
 764                                 }
 765                                 else if(argv(0) == "set")
 766                                 {
 767                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 768                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 769                                 }
 770                                 else if(argv(0) != "//")
 771                                 {
 772                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 773                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 774                                 }
 775                         }
 776                         fclose(fd);
 777                 }
 778         }
 779
 780         WeaponStats_Init();
 781
 782         WEPSET_ADDSTAT();
 783         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 784         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 785         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 786         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 787         Nagger_Init();
 788
 789         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 790         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 791         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 792         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 793         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 794         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 795         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 796         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 797         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 798         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 799         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 800         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 801         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 802
 803         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 804         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 805
 806         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 807
 808         if(g_ca || g_freezetag)
 809         {
 810                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 811                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 812                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 813                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 814         }
 815         if(g_freezetag)
 816         {
 817                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 818                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 819         }
 820
 821         // g_movementspeed hack
 822         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 823         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 824         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 825         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 826
 827         // secrets
 828         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 829         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 830
 831         // misc
 832         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 833
 834         next_pingtime = time + 5;
 835
 836         detect_maptype();
 837
 838         // set up information replies for clients and server to use
 839         lsmaps_reply = "^7Maps available: ";
 840         lsnewmaps_reply = "^7Maps without a record set: ";
 841         for(i = 0, j = 0; i < MapInfo_count; ++i)
 842         {
 843                 if(MapInfo_Get_ByID(i))
 844                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 845                         {
 846                                 if(mod(i, 2))
 847                                         col = "^2";
 848                                 else
 849                                         col = "^3";
 850
 851                                 ++j;
 852
 853                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 854
 855                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 856                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 857                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 858                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 859                         }
 860         }
 861
 862         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 863         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 864
 865         maplist_reply = "^7Maps in list: ";
 866         n = tokenize_console(autocvar_g_maplist);
 867         for(i = 0, j = 0; i < n; ++i)
 868         {
 869                 if(MapInfo_CheckMap(argv(i)))
 870                 {
 871                         if(mod(j, 2))
 872                                 col = "^2";
 873                         else
 874                                 col = "^3";
 875                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 876                         ++j;
 877                 }
 878         }
 879         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 880         MapInfo_ClearTemps();
 881
 882         for(i = 0; i < 10; ++i)
 883         {
 884                 s = getrecords(i);
 885                 if (s)
 886                         records_reply[i] = strzone(s);
 887         }
 888
 889         ladder_reply = strzone(getladder());
 890
 891         rankings_reply = strzone(getrankings());
 892
 893         // begin other init
 894         ClientInit_Spawn();
 895         RandomSeed_Spawn();
 896         PingPLReport_Spawn();
 897
 898         CheatInit();
 899
 900         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 901
 902         // fill sv_curl_serverpackages from .serverpackage files
 903         if(autocvar_sv_curl_serverpackages_auto)
 904         {
 905                 s = "";
 906                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 907                 for(i = 0; i < n; ++i)
 908                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 909                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 910                                 s = strcat(s, " ", argv(i));
 911                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 912                 if(fd >= 0)
 913                 {
 914                         j = search_getsize(fd);
 915                         for(i = 0; i < j; ++i)
 916                                 s = strcat(s, " ", search_getfilename(fd, i));
 917                         search_end(fd);
 918                 }
 919                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 920                 if(fd >= 0)
 921                 {
 922                         j = search_getsize(fd);
 923                         for(i = 0; i < j; ++i)
 924                                 s = strcat(s, " ", search_getfilename(fd, i));
 925                         search_end(fd);
 926                 }
 927                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 928         }
 929
 930         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 931         modname = "Xonotic";
 932         // physics/balance/config changes that count as mod
 933         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 934                 modname = cvar_string("g_mod_physics");
 935         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 936                 modname = cvar_string("g_mod_balance");
 937         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 938                 modname = cvar_string("g_mod_config");
 939         // weird mutators that deserve to count as mod
 940         if(autocvar_g_minstagib)
 941                 modname = "MinstaGib";
 942         // extra mutators that deserve to count as mod
 943         MUTATOR_CALLHOOK(SetModname);
 944
 945         // save it for later
 946         modname = strzone(modname);
 947
 948         WinningConditionHelper(); // set worldstatus
 949
 950         world_initialized = 1;
 951 }
 952
 953 void spawnfunc_light (void)
 954 {
 955         //makestatic (self); // Who the f___ did that?
 956         remove(self);
 957 }
 958
 959 string GetGametype()
 960 {
 961         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 962 }
 963
 964 string getmapname_stored;
 965 string GetMapname()
 966 {
 967         return mapname;
 968 }
 969
 970 float Map_Count, Map_Current;
 971 string Map_Current_Name;
 972
 973 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 974 float GetMaplistPosition()
 975 {
 976         float pos, idx;
 977         string map;
 978
 979         map = GetMapname();
 980         idx = autocvar_g_maplist_index;
 981
 982         if(idx >= 0)
 983                 if(idx < Map_Count)
 984                         if(map == argv(idx))
 985                                 return idx;
 986
 987         for(pos = 0; pos < Map_Count; ++pos)
 988                 if(map == argv(pos))
 989                         return pos;
 990
 991         // resume normal maplist rotation if current map is not in g_maplist
 992         return idx;
 993 }
 994
 995 float MapHasRightSize(string map)
 996 {
 997         float fh;
 998         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 999         if(autocvar_g_maplist_check_waypoints)
1000         {
1001                 dprint("checkwp "); dprint(map);
1002                 if(!fexists(strcat("maps/", map, ".waypoints")))
1003                 {
1004                         dprint(": no waypoints\n");
1005                         return FALSE;
1006                 }
1007                 dprint(": has waypoints\n");
1008         }
1009
1010         // open map size restriction file
1011         dprint("opensize "); dprint(map);
1012         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1013         if(fh >= 0)
1014         {
1015                 float mapmin, mapmax;
1016                 dprint(": ok, ");
1017                 mapmin = stof(fgets(fh));
1018                 mapmax = stof(fgets(fh));
1019                 fclose(fh);
1020                 if(player_count < mapmin)
1021                 {
1022                         dprint("not enough\n");
1023                         return FALSE;
1024                 }
1025                 if(player_count > mapmax)
1026                 {
1027                         dprint("too many\n");
1028                         return FALSE;
1029                 }
1030                 dprint("right size\n");
1031                 return TRUE;
1032         }
1033         dprint(": not found\n");
1034         return TRUE;
1035 }
1036
1037 string Map_Filename(float position)
1038 {
1039         return strcat("maps/", argv(position), ".bsp");
1040 }
1041
1042 string strwords(string s, float w)
1043 {
1044         float endpos;
1045         for(endpos = 0; w && endpos >= 0; --w)
1046                 endpos = strstrofs(s, " ", endpos + 1);
1047         if(endpos < 0)
1048                 return s;
1049         else
1050                 return substring(s, 0, endpos);
1051 }
1052
1053 float strhasword(string s, string w)
1054 {
1055         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1056 }
1057
1058 void Map_MarkAsRecent(string m)
1059 {
1060         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1061 }
1062
1063 float Map_IsRecent(string m)
1064 {
1065         return strhasword(autocvar_g_maplist_mostrecent, m);
1066 }
1067
1068 float Map_Check(float position, float pass)
1069 {
1070         string filename;
1071         string map_next;
1072         map_next = argv(position);
1073         if(pass <= 1)
1074         {
1075                 if(Map_IsRecent(map_next))
1076                         return 0;
1077         }
1078         filename = Map_Filename(position);
1079         if(MapInfo_CheckMap(map_next))
1080         {
1081                 if(pass == 2)
1082                         return 1;
1083                 if(MapHasRightSize(map_next))
1084                         return 1;
1085                 return 0;
1086         }
1087         else
1088                 dprint( "Couldn't select '", filename, "'..\n" );
1089
1090         return 0;
1091 }
1092
1093 void Map_Goto_SetStr(string nextmapname)
1094 {
1095         if(getmapname_stored != "")
1096                 strunzone(getmapname_stored);
1097         if(nextmapname == "")
1098                 getmapname_stored = "";
1099         else
1100                 getmapname_stored = strzone(nextmapname);
1101 }
1102
1103 void Map_Goto_SetFloat(float position)
1104 {
1105         cvar_set("g_maplist_index", ftos(position));
1106         Map_Goto_SetStr(argv(position));
1107 }
1108
1109 void Map_Goto(float reinit)
1110 {
1111         MapInfo_LoadMap(getmapname_stored, reinit);
1112 }
1113
1114 // return codes of map selectors:
1115 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1116 //   -2 = permanent failure
1117 float() MaplistMethod_Iterate = // usual method
1118 {
1119         float pass, i;
1120
1121         for(pass = 1; pass <= 2; ++pass)
1122         {
1123                 for(i = 1; i < Map_Count; ++i)
1124                 {
1125                         float mapindex;
1126                         mapindex = mod(i + Map_Current, Map_Count);
1127                         if(Map_Check(mapindex, pass))
1128                                 return mapindex;
1129                 }
1130         }
1131         return -1;
1132 }
1133
1134 float() MaplistMethod_Repeat = // fallback method
1135 {
1136         if(Map_Check(Map_Current, 2))
1137                 return Map_Current;
1138         return -2;
1139 }
1140
1141 float() MaplistMethod_Random = // random map selection
1142 {
1143         float i, imax;
1144
1145         imax = 42;
1146
1147         for(i = 0; i <= imax; ++i)
1148         {
1149                 float mapindex;
1150                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1151                 if(Map_Check(mapindex, 1))
1152                         return mapindex;
1153         }
1154         return -1;
1155 }
1156
1157 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1158 // the exponent sets a bias on the map selection:
1159 // the higher the exponent, the less likely "shortly repeated" same maps are
1160 {
1161         float i, j, imax, insertpos;
1162
1163         imax = 42;
1164
1165         for(i = 0; i <= imax; ++i)
1166         {
1167                 string newlist;
1168
1169                 // now reinsert this at another position
1170                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1171                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1172                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1173                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1174
1175                 // insert the current map there
1176                 newlist = "";
1177                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1178                         newlist = strcat(newlist, " ", argv(j));
1179                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1180                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1181                         newlist = strcat(newlist, " ", argv(j));
1182                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1183                 cvar_set("g_maplist", newlist);
1184                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1185
1186                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1187                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1188                 if(Map_Check(Map_Current, 1))
1189                         return Map_Current;
1190         }
1191         return -1;
1192 }
1193
1194 void Maplist_Init()
1195 {
1196         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1197         if(Map_Count == 0)
1198         {
1199                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1200                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1201                 if(autocvar_g_maplist_shuffle)
1202                         ShuffleMaplist();
1203                 localcmd("\nmenu_cmd sync\n");
1204                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1205         }
1206         if(Map_Count == 0)
1207                 error("empty maplist, cannot select a new map");
1208         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1209
1210         if(Map_Current_Name)
1211                 strunzone(Map_Current_Name);
1212         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1213         // this may or may not be correct, but who cares, in the worst case a map
1214         // isn't chosen in the first pass that should have been
1215 }
1216
1217 string GetNextMap()
1218 {
1219         float nextMap;
1220
1221         Maplist_Init();
1222         nextMap = -1;
1223
1224         if(nextMap == -1)
1225                 if(autocvar_g_maplist_shuffle > 0)
1226                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1227
1228         if(nextMap == -1)
1229                 if(autocvar_g_maplist_selectrandom)
1230                         nextMap = MaplistMethod_Random();
1231
1232         if(nextMap == -1)
1233                 nextMap = MaplistMethod_Iterate();
1234
1235         if(nextMap == -1)
1236                 nextMap = MaplistMethod_Repeat();
1237
1238         if(nextMap >= 0)
1239         {
1240                 Map_Goto_SetFloat(nextMap);
1241                 return getmapname_stored;
1242         }
1243
1244         return "";
1245 }
1246
1247 float DoNextMapOverride(float reinit)
1248 {
1249         if(autocvar_g_campaign)
1250         {
1251                 CampaignPostIntermission();
1252                 alreadychangedlevel = TRUE;
1253                 return TRUE;
1254         }
1255         if(autocvar_quit_when_empty)
1256         {
1257                 if(player_count <= currentbots)
1258                 {
1259                         localcmd("quit\n");
1260                         alreadychangedlevel = TRUE;
1261                         return TRUE;
1262                 }
1263         }
1264         if(autocvar_quit_and_redirect != "")
1265         {
1266                 redirection_target = strzone(autocvar_quit_and_redirect);
1267                 alreadychangedlevel = TRUE;
1268                 return TRUE;
1269         }
1270         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1271         {
1272                 localcmd("restart\n");
1273                 alreadychangedlevel = TRUE;
1274                 return TRUE;
1275         }
1276         if(autocvar_nextmap != "")
1277                 if(MapInfo_CheckMap(autocvar_nextmap))
1278                 {
1279                         Map_Goto_SetStr(autocvar_nextmap);
1280                         Map_Goto(reinit);
1281                         alreadychangedlevel = TRUE;
1282                         return TRUE;
1283                 }
1284         if(!reinit && autocvar_lastlevel)
1285         {
1286                 cvar_settemp_restore();
1287                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1288                 alreadychangedlevel = TRUE;
1289                 return TRUE;
1290         }
1291         return FALSE;
1292 }
1293
1294 void GotoNextMap(float reinit)
1295 {
1296         //string nextmap;
1297         //float n, nummaps;
1298         //string s;
1299         if (alreadychangedlevel)
1300                 return;
1301         alreadychangedlevel = TRUE;
1302
1303         {
1304                 string nextMap;
1305                 float allowReset;
1306
1307                 for(allowReset = 1; allowReset >= 0; --allowReset)
1308                 {
1309                         nextMap = GetNextMap();
1310                         if(nextMap != "")
1311                                 break;
1312
1313                         if(allowReset)
1314                         {
1315                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1316                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1317                                 if(autocvar_g_maplist_shuffle)
1318                                         ShuffleMaplist();
1319                                 localcmd("\nmenu_cmd sync\n");
1320                         }
1321                         else
1322                         {
1323                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1324                         }
1325                 }
1326                 Map_Goto(reinit);
1327         }
1328 }
1329
1330
1331 /*
1332 ============
1333 IntermissionThink
1334
1335 When the player presses attack or jump, change to the next level
1336 ============
1337 */
1338 .float autoscreenshot;
1339 void() MapVote_Start;
1340 void() MapVote_Think;
1341 float mapvote_initialized;
1342 void IntermissionThink()
1343 {
1344         FixIntermissionClient(self);
1345
1346         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1347         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1348
1349         if( (server_screenshot || client_screenshot)
1350                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1351         {
1352                 self.autoscreenshot = -1;
1353                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1354                 return;
1355         }
1356
1357         if (time < intermission_exittime)
1358                 return;
1359
1360         if(!mapvote_initialized)
1361                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1362                         return;
1363
1364         MapVote_Start();
1365 }
1366
1367 /*
1368 ============
1369 FindIntermission
1370
1371 Returns the entity to view from
1372 ============
1373 */
1374 /*
1375 entity FindIntermission()
1376 {
1377         local   entity spot;
1378         local   float cyc;
1379
1380 // look for info_intermission first
1381         spot = find (world, classname, "info_intermission");
1382         if (spot)
1383         {       // pick a random one
1384                 cyc = random() * 4;
1385                 while (cyc > 1)
1386                 {
1387                         spot = find (spot, classname, "info_intermission");
1388                         if (!spot)
1389                                 spot = find (spot, classname, "info_intermission");
1390                         cyc = cyc - 1;
1391                 }
1392                 return spot;
1393         }
1394
1395 // then look for the start position
1396         spot = find (world, classname, "info_player_start");
1397         if (spot)
1398                 return spot;
1399
1400 // testinfo_player_start is only found in regioned levels
1401         spot = find (world, classname, "testplayerstart");
1402         if (spot)
1403                 return spot;
1404
1405 // then look for the start position
1406         spot = find (world, classname, "info_player_deathmatch");
1407         if (spot)
1408                 return spot;
1409
1410         //objerror ("FindIntermission: no spot");
1411         return world;
1412 }
1413 */
1414
1415 /*
1416 ===============================================================================
1417
1418 RULES
1419
1420 ===============================================================================
1421 */
1422
1423 void DumpStats(float final)
1424 {
1425         float file;
1426         string s;
1427         float to_console;
1428         float to_eventlog;
1429         float to_file;
1430         float i;
1431
1432         to_console = autocvar_sv_logscores_console;
1433         to_eventlog = autocvar_sv_eventlog;
1434         to_file = autocvar_sv_logscores_file;
1435
1436         if(!final)
1437         {
1438                 to_console = TRUE; // always print printstats replies
1439                 to_eventlog = FALSE; // but never print them to the event log
1440         }
1441
1442         if(to_eventlog)
1443                 if(autocvar_sv_eventlog_console)
1444                         to_console = FALSE; // otherwise we get the output twice
1445
1446         if(final)
1447                 s = ":scores:";
1448         else
1449                 s = ":status:";
1450         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1451
1452         if(to_console)
1453                 print(s, "\n");
1454         if(to_eventlog)
1455                 GameLogEcho(s);
1456
1457         file = -1;
1458         if(to_file)
1459         {
1460                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1461                 if(file == -1)
1462                         to_file = FALSE;
1463                 else
1464                         fputs(file, strcat(s, "\n"));
1465         }
1466
1467         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1468         if(to_console)
1469                 print(s, "\n");
1470         if(to_eventlog)
1471                 GameLogEcho(s);
1472         if(to_file)
1473                 fputs(file, strcat(s, "\n"));
1474
1475         FOR_EACH_CLIENT(other)
1476         {
1477                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1478                 {
1479                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1480                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1481                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1482                                 s = strcat(s, ftos(other.team), ":");
1483                         else
1484                                 s = strcat(s, "spectator:");
1485
1486                         if(to_console)
1487                                 print(s, other.netname, "\n");
1488                         if(to_eventlog)
1489                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1490                         if(to_file)
1491                                 fputs(file, strcat(s, other.netname, "\n"));
1492                 }
1493         }
1494
1495         if(teamplay)
1496         {
1497                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1498                 if(to_console)
1499                         print(s, "\n");
1500                 if(to_eventlog)
1501                         GameLogEcho(s);
1502                 if(to_file)
1503                         fputs(file, strcat(s, "\n"));
1504
1505                 for(i = 1; i < 16; ++i)
1506                 {
1507                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1508                         s = strcat(s, ":", ftos(i));
1509                         if(to_console)
1510                                 print(s, "\n");
1511                         if(to_eventlog)
1512                                 GameLogEcho(s);
1513                         if(to_file)
1514                                 fputs(file, strcat(s, "\n"));
1515                 }
1516         }
1517
1518         if(to_console)
1519                 print(":end\n");
1520         if(to_eventlog)
1521                 GameLogEcho(":end");
1522         if(to_file)
1523         {
1524                 fputs(file, ":end\n");
1525                 fclose(file);
1526         }
1527 }
1528
1529 void FixIntermissionClient(entity e)
1530 {
1531         string s;
1532         if(!e.autoscreenshot) // initial call
1533         {
1534                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1535                 e.health = -2342;
1536                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1537                 e.solid = SOLID_NOT;
1538                 e.movetype = MOVETYPE_NONE;
1539                 e.takedamage = DAMAGE_NO;
1540                 if(e.weaponentity)
1541                 {
1542                         e.weaponentity.effects = EF_NODRAW;
1543                         if (e.weaponentity.weaponentity)
1544                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1545                 }
1546                 if(clienttype(e) == CLIENTTYPE_REAL)
1547                 {
1548                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1549                         s = autocvar_sv_intermission_cdtrack;
1550                         if(s != "")
1551                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1552                         msg_entity = e;
1553                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1554                 }
1555         }
1556 }
1557
1558 void minstagib_stop_countdown(entity e);
1559 /*
1560 go to the next level for deathmatch
1561 only called if a time or frag limit has expired
1562 */
1563 void NextLevel()
1564 {
1565         gameover = TRUE;
1566
1567         intermission_running = 1;
1568
1569 // enforce a wait time before allowing changelevel
1570         if(player_count > 0)
1571                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1572         else
1573                 intermission_exittime = -1;
1574
1575         /*
1576         WriteByte (MSG_ALL, SVC_CDTRACK);
1577         WriteByte (MSG_ALL, 3);
1578         WriteByte (MSG_ALL, 3);
1579         // done in FixIntermission
1580         */
1581
1582         //pos = FindIntermission ();
1583
1584         VoteReset();
1585
1586         DumpStats(TRUE);
1587
1588         // send statistics
1589         entity e;
1590         PlayerStats_EndMatch(1);
1591         FOR_EACH_CLIENT(e)
1592                 PlayerStats_AddGlobalInfo(e);
1593         PlayerStats_Shutdown();
1594         WeaponStats_Shutdown();
1595
1596         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1597
1598         if(autocvar_sv_eventlog)
1599                 GameLogEcho(":gameover");
1600
1601         GameLogClose();
1602
1603         FOR_EACH_PLAYER(other) {
1604                 minstagib_stop_countdown(other);
1605                 FixIntermissionClient(other);
1606                 if(other.winning)
1607                         bprint(other.netname, " ^7wins.\n");
1608         }
1609
1610         if(autocvar_g_campaign)
1611                 CampaignPreIntermission();
1612
1613         MUTATOR_CALLHOOK(MatchEnd);
1614
1615         localcmd("\nsv_hook_gameend\n");
1616 }
1617
1618 /*
1619 ============
1620 CheckRules_Player
1621
1622 Exit deathmatch games upon conditions
1623 ============
1624 */
1625 void CheckRules_Player()
1626 {
1627         if (gameover)   // someone else quit the game already
1628                 return;
1629
1630         if(self.deadflag == DEAD_NO)
1631                 self.play_time += frametime;
1632
1633         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1634         //   (div0: and that in CheckRules_World please)
1635 }
1636
1637 float checkrules_equality;
1638 float checkrules_suddendeathwarning;
1639 float checkrules_suddendeathend;
1640 float checkrules_overtimesadded; //how many overtimes have been already added
1641
1642 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1643 float WINNING_YES = 1; // winner found
1644 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1645 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1646
1647 float InitiateSuddenDeath()
1648 {
1649         // Check first whether normal overtimes could be added before initiating suddendeath mode
1650         // - for this timelimit_overtime needs to be >0 of course
1651         // - also check the winning condition calculated in the previous frame and only add normal overtime
1652         //   again, if at the point at which timelimit would be extended again, still no winner was found
1653         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1654         {
1655                 return 1; // need to call InitiateOvertime later
1656         }
1657         else
1658         {
1659                 if(!checkrules_suddendeathend)
1660                 {
1661                         if(autocvar_g_campaign)
1662                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1663                         else
1664                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1665                         if(g_race && !g_race_qualifying)
1666                                 race_StartCompleting();
1667                 }
1668                 return 0;
1669         }
1670 }
1671
1672 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1673 {
1674         ++checkrules_overtimesadded;
1675         //add one more overtime by simply extending the timelimit
1676         float tl;
1677         tl = autocvar_timelimit;
1678         tl += autocvar_timelimit_overtime;
1679         cvar_set("timelimit", ftos(tl));
1680
1681         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime);
1682 }
1683
1684 float GetWinningCode(float fraglimitreached, float equality)
1685 {
1686         if(autocvar_g_campaign == 1)
1687                 if(fraglimitreached)
1688                         return WINNING_YES;
1689                 else
1690                         return WINNING_NO;
1691
1692         else
1693                 if(equality)
1694                         if(fraglimitreached)
1695                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1696                         else
1697                                 return WINNING_NEVER;
1698                 else
1699                         if(fraglimitreached)
1700                                 return WINNING_YES;
1701                         else
1702                                 return WINNING_NO;
1703 }
1704
1705 // set the .winning flag for exactly those players with a given field value
1706 void SetWinners(.float field, float value)
1707 {
1708         entity head;
1709         FOR_EACH_PLAYER(head)
1710                 head.winning = (head.field == value);
1711 }
1712
1713 // set the .winning flag for those players with a given field value
1714 void AddWinners(.float field, float value)
1715 {
1716         entity head;
1717         FOR_EACH_PLAYER(head)
1718                 if(head.field == value)
1719                         head.winning = 1;
1720 }
1721
1722 // clear the .winning flags
1723 void ClearWinners(void)
1724 {
1725         entity head;
1726         FOR_EACH_PLAYER(head)
1727                 head.winning = 0;
1728 }
1729
1730 // Onslaught winning condition:
1731 // game terminates if only one team has a working generator (or none)
1732 float WinningCondition_Onslaught()
1733 {
1734         entity head;
1735         float t1, t2, t3, t4;
1736
1737         WinningConditionHelper(); // set worldstatus
1738
1739         if(inWarmupStage)
1740                 return WINNING_NO;
1741
1742         // first check if the game has ended
1743         t1 = t2 = t3 = t4 = 0;
1744         head = find(world, classname, "onslaught_generator");
1745         while (head)
1746         {
1747                 if (head.health > 0)
1748                 {
1749                         if (head.team == NUM_TEAM_1) t1 = 1;
1750                         if (head.team == NUM_TEAM_2) t2 = 1;
1751                         if (head.team == NUM_TEAM_3) t3 = 1;
1752                         if (head.team == NUM_TEAM_4) t4 = 1;
1753                 }
1754                 head = find(head, classname, "onslaught_generator");
1755         }
1756         if (t1 + t2 + t3 + t4 < 2)
1757         {
1758                 // game over, only one team remains (or none)
1759                 ClearWinners();
1760                 if (t1) SetWinners(team, NUM_TEAM_1);
1761                 if (t2) SetWinners(team, NUM_TEAM_2);
1762                 if (t3) SetWinners(team, NUM_TEAM_3);
1763                 if (t4) SetWinners(team, NUM_TEAM_4);
1764                 dprint("Have a winner, ending game.\n");
1765                 return WINNING_YES;
1766         }
1767
1768         // Two or more teams remain
1769         return WINNING_NO;
1770 }
1771
1772 float LMS_NewPlayerLives()
1773 {
1774         float fl;
1775         fl = autocvar_fraglimit;
1776         if(fl == 0)
1777                 fl = 999;
1778
1779         // first player has left the game for dying too much? Nobody else can get in.
1780         if(lms_lowest_lives < 1)
1781                 return 0;
1782
1783         if(!autocvar_g_lms_join_anytime)
1784                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1785                         return 0;
1786
1787         return bound(1, lms_lowest_lives, fl);
1788 }
1789
1790 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1791 // they win. Otherwise the defending team wins once the timelimit passes.
1792 void assault_new_round();
1793 float WinningCondition_Assault()
1794 {
1795         float status;
1796
1797         WinningConditionHelper(); // set worldstatus
1798
1799         status = WINNING_NO;
1800         // as the timelimit has not yet passed just assume the defending team will win
1801         if(assault_attacker_team == NUM_TEAM_1)
1802         {
1803                 SetWinners(team, NUM_TEAM_2);
1804         }
1805         else
1806         {
1807                 SetWinners(team, NUM_TEAM_1);
1808         }
1809
1810         entity ent;
1811         ent = find(world, classname, "target_assault_roundend");
1812         if(ent)
1813         {
1814                 if(ent.winning) // round end has been triggered by attacking team
1815                 {
1816                         bprint("ASSAULT: round completed...\n");
1817                         SetWinners(team, assault_attacker_team);
1818
1819                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1820
1821                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1822                         {
1823                                 status = WINNING_YES;
1824                         }
1825                         else
1826                         {
1827                                 entity oldself;
1828                                 oldself = self;
1829                                 self = ent;
1830                                 assault_new_round();
1831                                 self = oldself;
1832                         }
1833                 }
1834         }
1835
1836         return status;
1837 }
1838
1839 // LMS winning condition: game terminates if and only if there's at most one
1840 // one player who's living lives. Top two scores being equal cancels the time
1841 // limit.
1842 float WinningCondition_LMS()
1843 {
1844         entity head, head2;
1845         float have_player;
1846         float have_players;
1847         float l;
1848
1849         have_player = FALSE;
1850         have_players = FALSE;
1851         l = LMS_NewPlayerLives();
1852
1853         head = find(world, classname, "player");
1854         if(head)
1855                 have_player = TRUE;
1856         head2 = find(head, classname, "player");
1857         if(head2)
1858                 have_players = TRUE;
1859
1860         if(have_player)
1861         {
1862                 // we have at least one player
1863                 if(have_players)
1864                 {
1865                         // two or more active players - continue with the game
1866                 }
1867                 else
1868                 {
1869                         // exactly one player?
1870
1871                         ClearWinners();
1872                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1873
1874                         if(l)
1875                         {
1876                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1877                                 return WINNING_NO;
1878                         }
1879                         else
1880                         {
1881                                 // a winner!
1882                                 // and assign him his first place
1883                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1884                                 return WINNING_YES;
1885                         }
1886                 }
1887         }
1888         else
1889         {
1890                 // nobody is playing at all...
1891                 if(l)
1892                 {
1893                         // wait for players...
1894                 }
1895                 else
1896                 {
1897                         // SNAFU (maybe a draw game?)
1898                         ClearWinners();
1899                         dprint("No players, ending game.\n");
1900                         return WINNING_YES;
1901                 }
1902         }
1903
1904         // When we get here, we have at least two players who are actually LIVING,
1905         // now check if the top two players have equal score.
1906         WinningConditionHelper();
1907
1908         ClearWinners();
1909         if(WinningConditionHelper_winner)
1910                 WinningConditionHelper_winner.winning = TRUE;
1911         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1912                 return WINNING_NEVER;
1913
1914         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1915         return WINNING_NO;
1916 }
1917
1918 void ShuffleMaplist()
1919 {
1920         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1921 }
1922
1923 float leaderfrags;
1924 float WinningCondition_Scores(float limit, float leadlimit)
1925 {
1926         float limitreached;
1927
1928         // TODO make everything use THIS winning condition (except LMS)
1929         WinningConditionHelper();
1930
1931         if(teamplay)
1932         {
1933                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1934                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1935                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1936                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1937         }
1938
1939         ClearWinners();
1940         if(WinningConditionHelper_winner)
1941                 WinningConditionHelper_winner.winning = 1;
1942         if(WinningConditionHelper_winnerteam >= 0)
1943                 SetWinners(team, WinningConditionHelper_winnerteam);
1944
1945         if(WinningConditionHelper_lowerisbetter)
1946         {
1947                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1948                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1949                 limit = -limit;
1950         }
1951
1952         if(WinningConditionHelper_zeroisworst)
1953                 leadlimit = 0; // not supported in this mode
1954
1955         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1956         // these modes always score in increments of 1, thus this makes sense
1957         {
1958                 if(leaderfrags != WinningConditionHelper_topscore)
1959                 {
1960                         leaderfrags = WinningConditionHelper_topscore;
1961
1962                         if (limit)
1963                         if (leaderfrags == limit - 1)
1964                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1965                         else if (leaderfrags == limit - 2)
1966                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1967                         else if (leaderfrags == limit - 3)
1968                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1969                 }
1970         }
1971
1972         limitreached = FALSE;
1973         if(limit)
1974                 if(WinningConditionHelper_topscore >= limit)
1975                         limitreached = TRUE;
1976         if(leadlimit)
1977         {
1978                 float leadlimitreached;
1979                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1980                 if(autocvar_leadlimit_and_fraglimit)
1981                         limitreached = (limitreached && leadlimitreached);
1982                 else
1983                         limitreached = (limitreached || leadlimitreached);
1984         }
1985
1986         if(limit)
1987                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1988
1989         return GetWinningCode(
1990                 WinningConditionHelper_topscore && limitreached,
1991                 WinningConditionHelper_equality
1992         );
1993 }
1994
1995 float WinningCondition_Race(float fraglimit)
1996 {
1997         float wc;
1998         entity p;
1999         float n, c;
2000
2001         n = 0;
2002         c = 0;
2003         FOR_EACH_PLAYER(p)
2004         {
2005                 ++n;
2006                 if(p.race_completed)
2007                         ++c;
2008         }
2009         if(n && (n == c))
2010                 return WINNING_YES;
2011         wc = WinningCondition_Scores(fraglimit, 0);
2012
2013         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2014         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2015         // do NOT support equality when the laps are all raced!
2016                 return WINNING_STARTSUDDENDEATHOVERTIME;
2017         else
2018                 return WINNING_NEVER;
2019 }
2020
2021 float WinningCondition_QualifyingThenRace(float limit)
2022 {
2023         float wc;
2024         wc = WinningCondition_Scores(limit, 0);
2025
2026         // NEVER initiate overtime
2027         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2028         {
2029                 return WINNING_YES;
2030         }
2031
2032         return wc;
2033 }
2034
2035 float WinningCondition_RanOutOfSpawns()
2036 {
2037         entity head;
2038
2039         if(have_team_spawns <= 0)
2040                 return WINNING_NO;
2041
2042         if(autocvar_g_spawn_useallspawns <= 0)
2043                 return WINNING_NO;
2044
2045         if(!some_spawn_has_been_used)
2046                 return WINNING_NO;
2047
2048         team1_score = team2_score = team3_score = team4_score = 0;
2049
2050         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2051         {
2052                 if(head.team == NUM_TEAM_1)
2053                         team1_score = 1;
2054                 else if(head.team == NUM_TEAM_2)
2055                         team2_score = 1;
2056                 else if(head.team == NUM_TEAM_3)
2057                         team3_score = 1;
2058                 else if(head.team == NUM_TEAM_4)
2059                         team4_score = 1;
2060         }
2061
2062         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2063         {
2064                 if(head.team == NUM_TEAM_1)
2065                         team1_score = 1;
2066                 else if(head.team == NUM_TEAM_2)
2067                         team2_score = 1;
2068                 else if(head.team == NUM_TEAM_3)
2069                         team3_score = 1;
2070                 else if(head.team == NUM_TEAM_4)
2071                         team4_score = 1;
2072         }
2073
2074         ClearWinners();
2075         if(team1_score + team2_score + team3_score + team4_score == 0)
2076         {
2077                 checkrules_equality = TRUE;
2078                 return WINNING_YES;
2079         }
2080         else if(team1_score + team2_score + team3_score + team4_score == 1)
2081         {
2082                 float t, i;
2083                 if(team1_score)
2084                         t = NUM_TEAM_1;
2085                 else if(team2_score)
2086                         t = NUM_TEAM_2;
2087                 else if(team3_score)
2088                         t = NUM_TEAM_3;
2089                 else // if(team4_score)
2090                         t = NUM_TEAM_4;
2091                 CheckAllowedTeams(world);
2092                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2093                 {
2094                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2095                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2096                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2097                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2098                 }
2099
2100                 AddWinners(team, t);
2101                 return WINNING_YES;
2102         }
2103         else
2104                 return WINNING_NO;
2105 }
2106
2107 /*
2108 ============
2109 CheckRules_World
2110
2111 Exit deathmatch games upon conditions
2112 ============
2113 */
2114 void ReadyRestart();
2115 void CheckRules_World()
2116 {
2117         float timelimit;
2118         float fraglimit;
2119         float leadlimit;
2120
2121         VoteThink();
2122         MapVote_Think();
2123
2124         SetDefaultAlpha();
2125
2126         /*
2127         MapVote_Think should now do that part
2128         if (intermission_running)
2129                 if (time >= intermission_exittime + 60)
2130                 {
2131                         if(!DoNextMapOverride())
2132                                 GotoNextMap();
2133                         return;
2134                 }
2135         */
2136
2137         if (gameover)   // someone else quit the game already
2138         {
2139                 if(player_count == 0) // Nobody there? Then let's go to the next map
2140                         MapVote_Start();
2141                         // this will actually check the player count in the next frame
2142                         // again, but this shouldn't hurt
2143                 return;
2144         }
2145
2146         timelimit = autocvar_timelimit * 60;
2147         fraglimit = autocvar_fraglimit;
2148         leadlimit = autocvar_leadlimit;
2149
2150         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2151         {
2152                 if(timelimit > 0)
2153                         timelimit = 0; // timelimit is not made for warmup
2154                 if(fraglimit > 0)
2155                         fraglimit = 0; // no fraglimit for now
2156                 leadlimit = 0; // no leadlimit for now
2157         }
2158
2159         if(timelimit > 0)
2160         {
2161                 timelimit += game_starttime;
2162         }
2163         else if (timelimit < 0)
2164         {
2165                 // endmatch
2166                 NextLevel();
2167                 return;
2168         }
2169
2170         if(g_onslaught)
2171                 timelimit = 0; // ONS has its own overtime rule
2172
2173         float wantovertime;
2174         wantovertime = 0;
2175
2176         if(timelimit > game_starttime)
2177                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2178         else
2179                 game_completion_ratio = 0;
2180
2181         if(checkrules_suddendeathend)
2182         {
2183                 if(!checkrules_suddendeathwarning)
2184                 {
2185                         checkrules_suddendeathwarning = TRUE;
2186                         if(g_race && !g_race_qualifying)
2187                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2188                         else
2189                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2190                 }
2191         }
2192         else
2193         {
2194                 if (timelimit && time >= timelimit)
2195                 {
2196                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2197                         {
2198                                 float totalplayers;
2199                                 float playerswithlaps;
2200                                 float readyplayers;
2201                                 entity head;
2202                                 totalplayers = playerswithlaps = readyplayers = 0;
2203                                 FOR_EACH_PLAYER(head)
2204                                 {
2205                                         ++totalplayers;
2206                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2207                                                 ++playerswithlaps;
2208                                         if(head.ready)
2209                                                 ++readyplayers;
2210                                 }
2211
2212                                 // at least 2 of the players have completed a lap: start the RACE
2213                                 // otherwise, the players should end the qualifying on their own
2214                                 if(readyplayers || playerswithlaps >= 2)
2215                                 {
2216                                         checkrules_suddendeathend = 0;
2217                                         ReadyRestart(); // go to race
2218                                         return;
2219                                 }
2220                                 else
2221                                         wantovertime |= InitiateSuddenDeath();
2222                         }
2223                         else
2224                                 wantovertime |= InitiateSuddenDeath();
2225                 }
2226         }
2227
2228         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2229         {
2230                 NextLevel();
2231                 return;
2232         }
2233
2234         float checkrules_status;
2235         checkrules_status = WinningCondition_RanOutOfSpawns();
2236         if(checkrules_status == WINNING_YES)
2237         {
2238                 bprint("Hey! Someone ran out of spawns!\n");
2239         }
2240         else if(g_race && !g_race_qualifying && timelimit >= 0)
2241         {
2242                 checkrules_status = WinningCondition_Race(fraglimit);
2243                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2244         }
2245         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2246         {
2247                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2248                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2249         }
2250         else if(g_assault)
2251         {
2252                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2253         }
2254         else if(g_lms)
2255         {
2256                 checkrules_status = WinningCondition_LMS();
2257         }
2258         else if (g_onslaught)
2259         {
2260                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2261         }
2262         else
2263         {
2264                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2265                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2266         }
2267
2268         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2269         {
2270                 checkrules_status = WINNING_NEVER;
2271                 checkrules_overtimesadded = -1;
2272                 wantovertime |= InitiateSuddenDeath();
2273         }
2274
2275         if(checkrules_status == WINNING_NEVER)
2276                 // equality cases! Nobody wins if the overtime ends in a draw.
2277                 ClearWinners();
2278
2279         if(wantovertime)
2280         {
2281                 if(checkrules_status == WINNING_NEVER)
2282                         InitiateOvertime();
2283                 else
2284                         checkrules_status = WINNING_YES;
2285         }
2286
2287         if(checkrules_suddendeathend)
2288                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2289                         checkrules_status = WINNING_YES;
2290
2291         if(checkrules_status == WINNING_YES)
2292         {
2293                 //print("WINNING\n");
2294                 NextLevel();
2295         }
2296 }
2297
2298 float mapvote_nextthink;
2299 float mapvote_initialized;
2300 float mapvote_keeptwotime;
2301 float mapvote_timeout;
2302 string mapvote_message;
2303 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2304 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2305 float mapvote_screenshot_dirs_count;
2306
2307 float mapvote_count;
2308 float mapvote_count_real;
2309 string mapvote_maps[MAPVOTE_COUNT];
2310 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2311 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2312 float mapvote_maps_suggested[MAPVOTE_COUNT];
2313 string mapvote_suggestions[MAPVOTE_COUNT];
2314 float mapvote_suggestion_ptr;
2315 float mapvote_voters;
2316 float mapvote_selections[MAPVOTE_COUNT];
2317 float mapvote_run;
2318 float mapvote_detail;
2319 float mapvote_abstain;
2320 .float mapvote;
2321
2322 void MapVote_ClearAllVotes()
2323 {
2324         FOR_EACH_CLIENT(other)
2325                 other.mapvote = 0;
2326 }
2327
2328 string MapVote_Suggest(string m)
2329 {
2330         float i;
2331         if(m == "")
2332                 return "That's not how to use this command.";
2333         if(!autocvar_g_maplist_votable_suggestions)
2334                 return "Suggestions are not accepted on this server.";
2335         if(mapvote_initialized)
2336                 return "Can't suggest - voting is already in progress!";
2337         m = MapInfo_FixName(m);
2338         if not(m)
2339                 return "The map you suggested is not available on this server.";
2340         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2341                 if(Map_IsRecent(m))
2342                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2343
2344         if(!MapInfo_CheckMap(m))
2345                 return "The map you suggested does not support the current game mode.";
2346         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2347                 if(mapvote_suggestions[i] == m)
2348                         return "This map was already suggested.";
2349         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2350         {
2351                 i = floor(random() * mapvote_suggestion_ptr);
2352         }
2353         else
2354         {
2355                 i = mapvote_suggestion_ptr;
2356                 mapvote_suggestion_ptr += 1;
2357         }
2358         if(mapvote_suggestions[i] != "")
2359                 strunzone(mapvote_suggestions[i]);
2360         mapvote_suggestions[i] = strzone(m);
2361         if(autocvar_sv_eventlog)
2362                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2363         return strcat("Suggestion of ", m, " accepted.");
2364 }
2365
2366 void MapVote_AddVotable(string nextMap, float isSuggestion)
2367 {
2368         float j, i, o;
2369         string pakfile, mapfile;
2370
2371         if(nextMap == "")
2372                 return;
2373         for(j = 0; j < mapvote_count; ++j)
2374                 if(mapvote_maps[j] == nextMap)
2375                         return;
2376         // suggestions might be no longer valid/allowed after gametype switch!
2377         if(isSuggestion)
2378                 if(!MapInfo_CheckMap(nextMap))
2379                         return;
2380         mapvote_maps[mapvote_count] = strzone(nextMap);
2381         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2382
2383         pakfile = string_null;
2384         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2385         {
2386                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2387                 pakfile = whichpack(strcat(mapfile, ".tga"));
2388                 if(pakfile == "")
2389                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2390                 if(pakfile == "")
2391                         pakfile = whichpack(strcat(mapfile, ".png"));
2392                 if(pakfile != "")
2393                         break;
2394         }
2395         if(i >= mapvote_screenshot_dirs_count)
2396                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2397         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2398                 pakfile = substring(pakfile, o, -1);
2399
2400         mapvote_maps_screenshot_dir[mapvote_count] = i;
2401         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2402
2403         mapvote_count += 1;
2404 }
2405
2406 void MapVote_Spawn();
2407 void MapVote_Init()
2408 {
2409         float i;
2410         float nmax, smax;
2411
2412         MapVote_ClearAllVotes();
2413
2414         mapvote_count = 0;
2415         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2416         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2417
2418         if(mapvote_abstain)
2419                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2420         else
2421                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2422         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2423
2424         // we need this for AddVotable, as that cycles through the screenshot dirs
2425         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2426         if(mapvote_screenshot_dirs_count == 0)
2427                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2428         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2429         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2430                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2431
2432         if(mapvote_suggestion_ptr)
2433                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2434                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2435
2436         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2437                 MapVote_AddVotable(GetNextMap(), FALSE);
2438
2439         if(mapvote_count == 0)
2440         {
2441                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2442                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2443                 if(autocvar_g_maplist_shuffle)
2444                         ShuffleMaplist();
2445                 localcmd("\nmenu_cmd sync\n");
2446                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2447                         MapVote_AddVotable(GetNextMap(), FALSE);
2448         }
2449
2450         mapvote_count_real = mapvote_count;
2451         if(mapvote_abstain)
2452                 MapVote_AddVotable("don't care", 0);
2453
2454         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2455
2456         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2457         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2458         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2459                 mapvote_keeptwotime = 0;
2460         mapvote_message = "Choose a map and press its key!";
2461
2462         MapVote_Spawn();
2463 }
2464
2465 void MapVote_SendPicture(float id)
2466 {
2467         msg_entity = self;
2468         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2469         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2470         WriteByte(MSG_ONE, id);
2471         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2472 }
2473
2474 float MapVote_GetMapMask()
2475 {
2476         float mask, i, power;
2477         mask = 0;
2478         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2479                 if(mapvote_maps[i] != "")
2480                         mask |= power;
2481         return mask;
2482 }
2483
2484 entity mapvote_ent;
2485 float MapVote_SendEntity(entity to, float sf)
2486 {
2487         float i;
2488
2489         if(sf & 1)
2490                 sf &~= 2; // if we send 1, we don't need to also send 2
2491
2492         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2493         WriteByte(MSG_ENTITY, sf);
2494
2495         if(sf & 1)
2496         {
2497                 // flag 1 == initialization
2498                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2499                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2500                 WriteString(MSG_ENTITY, "");
2501                 WriteByte(MSG_ENTITY, mapvote_count);
2502                 WriteByte(MSG_ENTITY, mapvote_abstain);
2503                 WriteByte(MSG_ENTITY, mapvote_detail);
2504                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2505                 if(mapvote_count <= 8)
2506                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2507                 else
2508                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2509                 for(i = 0; i < mapvote_count; ++i)
2510                         if(mapvote_maps[i] != "")
2511                         {
2512                                 if(mapvote_abstain && i == mapvote_count - 1)
2513                                 {
2514                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2515                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2516                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2517                                 }
2518                                 else
2519                                 {
2520                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2521                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2522                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2523                                 }
2524                         }
2525         }
2526
2527         if(sf & 2)
2528         {
2529                 // flag 2 == update of mask
2530                 if(mapvote_count <= 8)
2531                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2532                 else
2533                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2534         }
2535
2536         if(sf & 4)
2537         {
2538                 if(mapvote_detail)
2539                         for(i = 0; i < mapvote_count; ++i)
2540                                 if(mapvote_maps[i] != "")
2541                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2542
2543                 WriteByte(MSG_ENTITY, to.mapvote);
2544         }
2545
2546         return TRUE;
2547 }
2548
2549 void MapVote_Spawn()
2550 {
2551         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2552 }
2553
2554 void MapVote_TouchMask()
2555 {
2556         mapvote_ent.SendFlags |= 2;
2557 }
2558
2559 void MapVote_TouchVotes(entity voter)
2560 {
2561         mapvote_ent.SendFlags |= 4;
2562 }
2563
2564 float MapVote_Finished(float mappos)
2565 {
2566         string result;
2567         float i;
2568         float didntvote;
2569
2570         if(autocvar_sv_eventlog)
2571         {
2572                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2573                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2574                 didntvote = mapvote_voters;
2575                 for(i = 0; i < mapvote_count; ++i)
2576                         if(mapvote_maps[i] != "")
2577                         {
2578                                 didntvote -= mapvote_selections[i];
2579                                 if(i != mappos)
2580                                 {
2581                                         result = strcat(result, ":", mapvote_maps[i]);
2582                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2583                                 }
2584                         }
2585                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2586
2587                 GameLogEcho(result);
2588                 if(mapvote_maps_suggested[mappos])
2589                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2590         }
2591
2592         FOR_EACH_REALCLIENT(other)
2593                 FixClientCvars(other);
2594
2595         Map_Goto_SetStr(mapvote_maps[mappos]);
2596         Map_Goto(0);
2597         alreadychangedlevel = TRUE;
2598         return TRUE;
2599 }
2600 void MapVote_CheckRules_1()
2601 {
2602         float i;
2603
2604         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2605         {
2606                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2607                 mapvote_selections[i] = 0;
2608         }
2609
2610         mapvote_voters = 0;
2611         FOR_EACH_REALCLIENT(other)
2612         {
2613                 ++mapvote_voters;
2614                 if(other.mapvote)
2615                 {
2616                         i = other.mapvote - 1;
2617                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2618                         mapvote_selections[i] = mapvote_selections[i] + 1;
2619                 }
2620         }
2621 }
2622
2623 float MapVote_CheckRules_2()
2624 {
2625         float i;
2626         float firstPlace, secondPlace;
2627         float firstPlaceVotes, secondPlaceVotes;
2628         float mapvote_voters_real;
2629         string result;
2630
2631         if(mapvote_count_real == 1)
2632                 return MapVote_Finished(0);
2633
2634         mapvote_voters_real = mapvote_voters;
2635         if(mapvote_abstain)
2636                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2637
2638         RandomSelection_Init();
2639         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2640                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2641         firstPlace = RandomSelection_chosen_float;
2642         firstPlaceVotes = RandomSelection_best_priority;
2643         //dprint("First place: ", ftos(firstPlace), "\n");
2644         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2645
2646         RandomSelection_Init();
2647         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2648                 if(i != firstPlace)
2649                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2650         secondPlace = RandomSelection_chosen_float;
2651         secondPlaceVotes = RandomSelection_best_priority;
2652         //dprint("Second place: ", ftos(secondPlace), "\n");
2653         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2654
2655         if(firstPlace == -1)
2656                 error("No first place in map vote... WTF?");
2657
2658         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2659                 return MapVote_Finished(firstPlace);
2660
2661         if(mapvote_keeptwotime)
2662                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2663                 {
2664                         float didntvote;
2665                         MapVote_TouchMask();
2666                         mapvote_message = "Now decide between the TOP TWO!";
2667                         mapvote_keeptwotime = 0;
2668                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2669                         result = strcat(result, ":", ftos(firstPlaceVotes));
2670                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2671                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2672                         didntvote = mapvote_voters;
2673                         for(i = 0; i < mapvote_count; ++i)
2674                                 if(mapvote_maps[i] != "")
2675                                 {
2676                                         didntvote -= mapvote_selections[i];
2677                                         if(i != firstPlace)
2678                                                 if(i != secondPlace)
2679                                                 {
2680                                                         result = strcat(result, ":", mapvote_maps[i]);
2681                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2682                                                         if(i < mapvote_count_real)
2683                                                         {
2684                                                                 strunzone(mapvote_maps[i]);
2685                                                                 mapvote_maps[i] = "";
2686                                                                 strunzone(mapvote_maps_pakfile[i]);
2687                                                                 mapvote_maps_pakfile[i] = "";
2688                                                         }
2689                                                 }
2690                                 }
2691                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2692                         if(autocvar_sv_eventlog)
2693                                 GameLogEcho(result);
2694                 }
2695
2696         return FALSE;
2697 }
2698 void MapVote_Tick()
2699 {
2700         float keeptwo;
2701         float totalvotes;
2702
2703         keeptwo = mapvote_keeptwotime;
2704         MapVote_CheckRules_1(); // count
2705         if(MapVote_CheckRules_2()) // decide
2706                 return;
2707
2708         totalvotes = 0;
2709         FOR_EACH_REALCLIENT(other)
2710         {
2711                 // hide scoreboard again
2712                 if(other.health != 2342)
2713                 {
2714                         other.health = 2342;
2715                         other.impulse = 0;
2716                         if(clienttype(other) == CLIENTTYPE_REAL)
2717                         {
2718                                 msg_entity = other;
2719                                 WriteByte(MSG_ONE, SVC_FINALE);
2720                                 WriteString(MSG_ONE, "");
2721                         }
2722                 }
2723
2724                 // clear possibly invalid votes
2725                 if(mapvote_maps[other.mapvote - 1] == "")
2726                         other.mapvote = 0;
2727                 // use impulses as new vote
2728                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2729                         if(mapvote_maps[other.impulse - 1] != "")
2730                         {
2731                                 other.mapvote = other.impulse;
2732                                 MapVote_TouchVotes(other);
2733                         }
2734                 other.impulse = 0;
2735
2736                 if(other.mapvote)
2737                         ++totalvotes;
2738         }
2739
2740         MapVote_CheckRules_1(); // just count
2741 }
2742 void MapVote_Start()
2743 {
2744         if(mapvote_run)
2745                 return;
2746
2747         // wait for stats to be sent first
2748         if(!playerstats_waitforme)
2749                 return;
2750
2751         MapInfo_Enumerate();
2752         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2753                 mapvote_run = TRUE;
2754 }
2755 void MapVote_Think()
2756 {
2757         if(!mapvote_run)
2758                 return;
2759
2760         if(alreadychangedlevel)
2761                 return;
2762
2763         if(time < mapvote_nextthink)
2764                 return;
2765         //dprint("tick\n");
2766
2767         mapvote_nextthink = time + 0.5;
2768
2769         if(!mapvote_initialized)
2770         {
2771                 if(autocvar_rescan_pending == 1)
2772                 {
2773                         cvar_set("rescan_pending", "2");
2774                         localcmd("fs_rescan\nrescan_pending 3\n");
2775                         return;
2776                 }
2777                 else if(autocvar_rescan_pending == 2)
2778                 {
2779                         return;
2780                 }
2781                 else if(autocvar_rescan_pending == 3)
2782                 {
2783                         // now build missing mapinfo files
2784                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2785                                 return;
2786
2787                         // we're done, start the timer
2788                         cvar_set("rescan_pending", "0");
2789                 }
2790
2791                 mapvote_initialized = TRUE;
2792                 if(DoNextMapOverride(0))
2793                         return;
2794                 if(!autocvar_g_maplist_votable || player_count <= 0)
2795                 {
2796                         GotoNextMap(0);
2797                         return;
2798                 }
2799                 MapVote_Init();
2800         }
2801
2802         MapVote_Tick();
2803 }
2804
2805 string GotoMap(string m)
2806 {
2807         if(!MapInfo_CheckMap(m))
2808                 return "The map you chose is not available on this server.";
2809         cvar_set("nextmap", m);
2810         cvar_set("timelimit", "-1");
2811         if(mapvote_initialized || alreadychangedlevel)
2812         {
2813                 if(DoNextMapOverride(0))
2814                         return "Map switch initiated.";
2815                 else
2816                         return "Hm... no. For some reason I like THIS map more.";
2817         }
2818         else
2819                 return "Map switch will happen after scoreboard.";
2820 }
2821
2822
2823 void EndFrame()
2824 {
2825         float altime;
2826         FOR_EACH_REALCLIENT(self)
2827         {
2828                 if(self.classname == "spectator")
2829                 {
2830                         if(self.enemy.typehitsound)
2831                                 self.typehit_time = time;
2832                         else if(self.enemy.hitsound)
2833                                 self.hit_time = time;
2834                 }
2835                 else
2836                 {
2837                         if(self.typehitsound)
2838                                 self.typehit_time = time;
2839                         else if(self.hitsound)
2840                                 self.hit_time = time;
2841                 }
2842         }
2843         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2844         // add 1 frametime because after this, engine SV_Physics
2845         // increases time by a frametime and then networks the frame
2846         // add another frametime because client shows everything with
2847         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2848         // needed!
2849         FOR_EACH_CLIENT(self)
2850         {
2851                 self.hitsound = FALSE;
2852                 self.typehitsound = FALSE;
2853                 antilag_record(self, altime);
2854         }
2855 }
2856
2857
2858 /*
2859  * RedirectionThink:
2860  * returns TRUE if redirecting
2861  */
2862 float redirection_timeout;
2863 float redirection_nextthink;
2864 float RedirectionThink()
2865 {
2866         float clients_found;
2867
2868         if(redirection_target == "")
2869                 return FALSE;
2870
2871         if(!redirection_timeout)
2872         {
2873                 cvar_set("sv_public", "-2");
2874                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2875                 if(redirection_target == "self")
2876                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2877                 else
2878                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2879         }
2880
2881         if(time < redirection_nextthink)
2882                 return TRUE;
2883
2884         redirection_nextthink = time + 1;
2885
2886         clients_found = 0;
2887         FOR_EACH_REALCLIENT(self)
2888         {
2889                 // TODO add timer
2890                 print("Redirecting: sending connect command to ", self.netname, "\n");
2891                 if(redirection_target == "self")
2892                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2893                 else
2894                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2895                 ++clients_found;
2896         }
2897
2898         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2899
2900         if(time > redirection_timeout || clients_found == 0)
2901                 localcmd("\nwait; wait; wait; quit\n");
2902
2903         return TRUE;
2904 }
2905
2906 void TargetMusic_RestoreGame();
2907 void RestoreGame()
2908 {
2909         // Loaded from a save game
2910         // some things then break, so let's work around them...
2911
2912         // Progs DB (capture records)
2913         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2914
2915         // Mapinfo
2916         MapInfo_Shutdown();
2917         MapInfo_Enumerate();
2918         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2919         WeaponStats_Init();
2920
2921         TargetMusic_RestoreGame();
2922 }
2923
2924 void Shutdown()
2925 {
2926         entity e;
2927
2928         gameover = 2;
2929
2930         if(world_initialized > 0)
2931         {
2932                 world_initialized = 0;
2933                 print("Saving persistent data...\n");
2934                 Ban_SaveBans();
2935
2936                 PlayerStats_EndMatch(0);
2937                 FOR_EACH_CLIENT(e)
2938                         PlayerStats_AddGlobalInfo(e);
2939                 PlayerStats_Shutdown();
2940
2941                 if(!cheatcount_total)
2942                 {
2943                         if(autocvar_sv_db_saveasdump)
2944                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2945                         else
2946                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2947                 }
2948                 if(autocvar_developer)
2949                 {
2950                         if(autocvar_sv_db_saveasdump)
2951                                 db_dump(TemporaryDB, "server-temp.db");
2952                         else
2953                                 db_save(TemporaryDB, "server-temp.db");
2954                 }
2955                 CheatShutdown(); // must be after cheatcount check
2956                 db_close(ServerProgsDB);
2957                 db_close(TemporaryDB);
2958                 print("done!\n");
2959                 // tell the bot system the game is ending now
2960                 bot_endgame();
2961
2962                 WeaponStats_Shutdown();
2963                 MapInfo_Shutdown();
2964         }
2965         else if(world_initialized == 0)
2966         {
2967                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2968         }
2969 }