qcsrc/server/g_world.qc

   1 const float LATENCY_THINKRATE = 10;
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = (self.cnt + 1) % maxclients;
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void GotoFirstMap()
  85 {
  86         float n;
  87         if(autocvar__sv_init)
  88         {
  89                 // cvar_set("_sv_init", "0");
  90                 // we do NOT set this to 0 any more, so someone "accidentally" changing
  91                 // to this "init" map on a dedicated server will cause no permanent
  92                 // harm
  93                 if(autocvar_g_maplist_shuffle)
  94                         ShuffleMaplist();
  95                 n = tokenizebyseparator(autocvar_g_maplist, " ");
  96                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
  97
  98                 MapInfo_Enumerate();
  99                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 100
 101                 if(!DoNextMapOverride(1))
 102                         GotoNextMap(1);
 103
 104                 return;
 105         }
 106
 107         if(time < 5)
 108         {
 109                 self.nextthink = time;
 110         }
 111         else
 112         {
 113                 self.nextthink = time + 1;
 114                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 115         }
 116 }
 117
 118 void cvar_changes_init()
 119 {
 120         float h;
 121         string k, v, d;
 122         float n, i, adding, pureadding;
 123
 124         if(cvar_changes)
 125                 strunzone(cvar_changes);
 126         cvar_changes = string_null;
 127         if(cvar_purechanges)
 128                 strunzone(cvar_purechanges);
 129         cvar_purechanges = string_null;
 130         cvar_purechanges_count = 0;
 131
 132         h = buf_create();
 133         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 134         n = buf_getsize(h);
 135
 136         adding = TRUE;
 137         pureadding = TRUE;
 138
 139         for(i = 0; i < n; ++i)
 140         {
 141                 k = bufstr_get(h, i);
 142
 143 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 144 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 145 #define BADCVAR(p) if(k == p) continue
 146
 147                 // general excludes and namespaces for server admin used cvars
 148                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 149
 150                 // internal
 151                 BADPREFIX("csqc_");
 152                 BADPREFIX("cvar_check_");
 153                 BADCVAR("gamecfg");
 154                 BADCVAR("g_configversion");
 155                 BADCVAR("g_maplist_index");
 156                 BADCVAR("halflifebsp");
 157                 BADPREFIX("sv_world");
 158
 159                 // client
 160                 BADPREFIX("chase_");
 161                 BADPREFIX("cl_");
 162                 BADPREFIX("con_");
 163                 BADPREFIX("scoreboard_");
 164                 BADPREFIX("g_campaign");
 165                 BADPREFIX("g_waypointsprite_");
 166                 BADPREFIX("gl_");
 167                 BADPREFIX("joy");
 168                 BADPREFIX("hud_");
 169                 BADPREFIX("m_");
 170                 BADPREFIX("menu_");
 171                 BADPREFIX("net_slist_");
 172                 BADPREFIX("r_");
 173                 BADPREFIX("sbar_");
 174                 BADPREFIX("scr_");
 175                 BADPREFIX("snd_");
 176                 BADPREFIX("show");
 177                 BADPREFIX("sensitivity");
 178                 BADPREFIX("userbind");
 179                 BADPREFIX("v_");
 180                 BADPREFIX("vid_");
 181                 BADPREFIX("crosshair");
 182                 BADCVAR("mod_q3bsp_lightmapmergepower");
 183                 BADCVAR("mod_q3bsp_nolightmaps");
 184                 BADCVAR("fov");
 185                 BADCVAR("mastervolume");
 186                 BADCVAR("volume");
 187                 BADCVAR("bgmvolume");
 188
 189                 // private
 190                 BADCVAR("developer");
 191                 BADCVAR("log_dest_udp");
 192                 BADCVAR("net_address");
 193                 BADCVAR("net_address_ipv6");
 194                 BADCVAR("port");
 195                 BADCVAR("savedgamecfg");
 196                 BADCVAR("serverconfig");
 197                 BADCVAR("sv_autoscreenshot");
 198                 BADCVAR("sv_heartbeatperiod");
 199                 BADCVAR("sv_vote_master_password");
 200                 BADCVAR("sys_colortranslation");
 201                 BADCVAR("sys_specialcharactertranslation");
 202                 BADCVAR("timeformat");
 203                 BADCVAR("timestamps");
 204                 BADPREFIX("developer_");
 205                 BADPREFIX("g_ban_");
 206                 BADPREFIX("g_banned_list");
 207                 BADPREFIX("g_chat_flood_");
 208                 BADPREFIX("g_ghost_items");
 209                 BADPREFIX("g_playerstats_");
 210                 BADPREFIX("g_respawn_ghosts");
 211                 BADPREFIX("g_voice_flood_");
 212                 BADPREFIX("log_file");
 213                 BADPREFIX("rcon_");
 214                 BADPREFIX("sv_allowdownloads");
 215                 BADPREFIX("sv_autodemo");
 216                 BADPREFIX("sv_curl_");
 217                 BADPREFIX("sv_eventlog");
 218                 BADPREFIX("sv_logscores_");
 219                 BADPREFIX("sv_master");
 220                 BADPREFIX("sv_weaponstats_");
 221                 BADPREFIX("sv_waypointsprite_");
 222                 BADCVAR("rescan_pending");
 223
 224                 // these can contain player IDs, so better hide
 225                 BADPREFIX("g_forced_team_");
 226
 227                 // mapinfo
 228                 BADCVAR("fraglimit");
 229                 BADCVAR("g_assault");
 230                 BADCVAR("g_ca");
 231                 BADCVAR("g_ca_teams");
 232                 BADCVAR("g_ctf");
 233                 BADCVAR("g_cts");
 234                 BADCVAR("g_dm");
 235                 BADCVAR("g_domination");
 236                 BADCVAR("g_domination_default_teams");
 237                 BADCVAR("g_freezetag");
 238                 BADCVAR("g_freezetag_teams");
 239                 BADCVAR("g_keepaway");
 240                 BADCVAR("g_keyhunt");
 241                 BADCVAR("g_keyhunt_teams");
 242                 BADCVAR("g_lms");
 243                 BADCVAR("g_nexball");
 244                 BADCVAR("g_onslaught");
 245                 BADCVAR("g_race");
 246                 BADCVAR("g_race_qualifying_timelimit");
 247                 BADCVAR("g_tdm");
 248                 BADCVAR("g_tdm_teams");
 249                 BADCVAR("leadlimit");
 250                 BADCVAR("nextmap");
 251                 BADCVAR("teamplay");
 252                 BADCVAR("timelimit");
 253
 254                 // long
 255                 BADCVAR("hostname");
 256                 BADCVAR("g_maplist");
 257                 BADCVAR("g_maplist_mostrecent");
 258                 BADCVAR("sv_motd");
 259
 260                 v = cvar_string(k);
 261                 d = cvar_defstring(k);
 262                 if(v == d)
 263                         continue;
 264
 265                 if(adding)
 266                 {
 267                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 268                         if(strlen(cvar_changes) > 16384)
 269                         {
 270                                 cvar_changes = "// too many settings have been changed to show them here\n";
 271                                 adding = 0;
 272                         }
 273                 }
 274
 275                 // now check if the changes are actually gameplay relevant
 276
 277                 // does nothing visible
 278                 BADCVAR("captureleadlimit_override");
 279                 BADCVAR("g_balance_kill_delay");
 280                 BADCVAR("g_ca_point_leadlimit");
 281                 BADCVAR("g_ctf_captimerecord_always");
 282                 BADCVAR("g_ctf_flag_glowtrails");
 283                 BADCVAR("g_ctf_flag_pickup_verbosename");
 284                 BADCVAR("g_domination_point_leadlimit");
 285                 BADCVAR("g_forced_respawn");
 286                 BADCVAR("g_keyhunt_point_leadlimit");
 287                 BADPREFIX("g_mod_");
 288                 BADCVAR("g_nexball_goalleadlimit");
 289                 BADCVAR("leadlimit_and_fraglimit");
 290                 BADCVAR("leadlimit_override");
 291                 BADCVAR("pausable");
 292                 BADCVAR("sv_allow_fullbright");
 293                 BADCVAR("sv_checkforpacketsduringsleep");
 294                 BADCVAR("sv_fraginfo");
 295                 BADCVAR("sv_timeout");
 296                 BADPREFIX("sv_timeout_");
 297                 BADPREFIX("crypto_");
 298                 BADPREFIX("g_chat_");
 299                 BADPREFIX("g_ctf_captimerecord_");
 300                 BADPREFIX("g_maplist_votable_");
 301                 BADPREFIX("net_");
 302                 BADPREFIX("prvm_");
 303                 BADPREFIX("skill_");
 304                 BADPREFIX("sv_cullentities_");
 305                 BADPREFIX("sv_fraginfo_");
 306                 BADPREFIX("sv_maxidle_");
 307                 BADPREFIX("sv_vote_");
 308                 BADPREFIX("timelimit_");
 309                 BADCVAR("gameversion");
 310                 BADPREFIX("gameversion_");
 311                 BADCVAR("sv_namechangetimer");
 312
 313                 // allowed changes to server admins (please sync this to server.cfg)
 314                 // vi commands:
 315                 //   :/"impure"/,$d
 316                 //   :g!,^\/\/[^ /],d
 317                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 318                 //   :%!sort
 319                 // yes, this does contain some redundant stuff, don't really care
 320                 BADCVAR("bot_config_file");
 321                 BADCVAR("bot_number");
 322                 BADCVAR("bot_prefix");
 323                 BADCVAR("bot_suffix");
 324                 BADCVAR("capturelimit_override");
 325                 BADCVAR("fraglimit_override");
 326                 BADCVAR("gametype");
 327                 BADCVAR("g_antilag");
 328                 BADCVAR("g_balance_teams");
 329                 BADCVAR("g_balance_teams_prevent_imbalance");
 330                 BADCVAR("g_balance_teams_scorefactor");
 331                 BADCVAR("g_ban_sync_trusted_servers");
 332                 BADCVAR("g_ban_sync_uri");
 333                 BADCVAR("g_ca_teams_override");
 334                 BADCVAR("g_ctf_ignore_frags");
 335                 BADCVAR("g_domination_point_limit");
 336                 BADCVAR("g_freezetag_teams_override");
 337                 BADCVAR("g_friendlyfire");
 338                 BADCVAR("g_fullbrightitems");
 339                 BADCVAR("g_fullbrightplayers");
 340                 BADCVAR("g_keyhunt_point_limit");
 341                 BADCVAR("g_keyhunt_teams_override");
 342                 BADCVAR("g_lms_lives_override");
 343                 BADCVAR("g_maplist");
 344                 BADCVAR("g_maplist_check_waypoints");
 345                 BADCVAR("g_maplist_mostrecent_count");
 346                 BADCVAR("g_maplist_shuffle");
 347                 BADCVAR("g_maplist_votable");
 348                 BADCVAR("g_maplist_votable_abstain");
 349                 BADCVAR("g_maplist_votable_nodetail");
 350                 BADCVAR("g_maplist_votable_suggestions");
 351                 BADCVAR("g_maxplayers");
 352                 BADCVAR("g_mirrordamage");
 353                 BADCVAR("g_nexball_goallimit");
 354                 BADCVAR("g_powerups");
 355                 BADCVAR("g_start_delay");
 356                 BADCVAR("g_warmup");
 357                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 358                 BADCVAR("hostname");
 359                 BADCVAR("log_file");
 360                 BADCVAR("maxplayers");
 361                 BADCVAR("minplayers");
 362                 BADCVAR("net_address");
 363                 BADCVAR("port");
 364                 BADCVAR("rcon_password");
 365                 BADCVAR("rcon_restricted_commands");
 366                 BADCVAR("rcon_restricted_password");
 367                 BADCVAR("skill");
 368                 BADCVAR("sv_adminnick");
 369                 BADCVAR("sv_autoscreenshot");
 370                 BADCVAR("sv_autotaunt");
 371                 BADCVAR("sv_curl_defaulturl");
 372                 BADCVAR("sv_defaultcharacter");
 373                 BADCVAR("sv_defaultplayercolors");
 374                 BADCVAR("sv_defaultplayermodel");
 375                 BADCVAR("sv_defaultplayerskin");
 376                 BADCVAR("sv_maxidle");
 377                 BADCVAR("sv_maxrate");
 378                 BADCVAR("sv_motd");
 379                 BADCVAR("sv_public");
 380                 BADCVAR("sv_ready_restart");
 381                 BADCVAR("sv_status_privacy");
 382                 BADCVAR("sv_taunt");
 383                 BADCVAR("sv_vote_call");
 384                 BADCVAR("sv_vote_commands");
 385                 BADCVAR("sv_vote_majority_factor");
 386                 BADCVAR("sv_vote_master");
 387                 BADCVAR("sv_vote_master_commands");
 388                 BADCVAR("sv_vote_master_password");
 389                 BADCVAR("sv_vote_simple_majority_factor");
 390                 BADCVAR("teamplay_mode");
 391                 BADCVAR("timelimit_override");
 392                 BADCVAR("g_spawnshieldtime");
 393                 BADPREFIX("g_warmup_");
 394                 BADPREFIX("sv_ready_restart_");
 395
 396                 // mutators that announce themselves properly to the server browser
 397                 BADCVAR("g_instagib");
 398                 BADCVAR("g_new_toys");
 399                 BADCVAR("g_nix");
 400                 BADCVAR("g_grappling_hook");
 401                 BADCVAR("g_jetpack");
 402
 403 #undef BADPREFIX
 404 #undef BADCVAR
 405
 406                 if(pureadding)
 407                 {
 408                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 409                         if(strlen(cvar_purechanges) > 16384)
 410                         {
 411                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 412                                 pureadding = 0;
 413                         }
 414                 }
 415                 ++cvar_purechanges_count;
 416                 // WARNING: this variable is used for the server list
 417                 // NEVER dare to skip this code!
 418                 // Hacks to intentionally appearing as "pure server" even though you DO have
 419                 // modified settings may be punished by removal from the server list.
 420                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 421                 // though.
 422         }
 423         buf_del(h);
 424         if(cvar_changes == "")
 425                 cvar_changes = "// this server runs at default server settings\n";
 426         else
 427                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 428         cvar_changes = strzone(cvar_changes);
 429         if(cvar_purechanges == "")
 430                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 431         else
 432                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 433         cvar_purechanges = strzone(cvar_purechanges);
 434 }
 435
 436 void detect_maptype()
 437 {
 438 #if 0
 439         vector o, v;
 440         float i;
 441
 442         for(0;;)
 443         {
 444                 o = world.mins;
 445                 o.x += random() * (world.maxs.x - world.mins.x);
 446                 o.y += random() * (world.maxs.y - world.mins.y);
 447                 o.z += random() * (world.maxs.z - world.mins.z);
 448
 449                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 450                 if(trace_fraction == 1)
 451                         continue;
 452
 453                 v = trace_endpos;
 454
 455                 for(i = 0; i < 64; i += 4)
 456                 {
 457                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 458         if(trace_fraction == 1)
 459                 continue;
 460                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 461                 }
 462
 463                 break;
 464         }
 465 #endif
 466 }
 467
 468 entity randomseed;
 469 float RandomSeed_Send(entity to, float sf)
 470 {
 471         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 472         WriteShort(MSG_ENTITY, self.cnt);
 473         return TRUE;
 474 }
 475 void RandomSeed_Think()
 476 {
 477         self.cnt = bound(0, floor(random() * 65536), 65535);
 478         self.nextthink = time + 5;
 479
 480         self.SendFlags |= 1;
 481 }
 482 void RandomSeed_Spawn()
 483 {
 484         randomseed = spawn();
 485         randomseed.think = RandomSeed_Think;
 486         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 487
 488         entity oldself;
 489         oldself = self;
 490         self = randomseed;
 491         self.think(); // sets random seed and nextthink
 492         self = oldself;
 493 }
 494
 495 void spawnfunc___init_dedicated_server(void)
 496 {
 497         // handler for _init/_init map (only for dedicated server initialization)
 498
 499         world_initialized = -1; // don't complain
 500         cvar = cvar_normal;
 501         cvar_string = cvar_string_normal;
 502         cvar_set = cvar_set_normal;
 503
 504         remove = remove_unsafely;
 505
 506         entity e;
 507         e = spawn();
 508         e.think = GotoFirstMap;
 509         e.nextthink = time; // this is usually 1 at this point
 510
 511         e = spawn();
 512         e.classname = "info_player_deathmatch"; // safeguard against player joining
 513
 514         self.classname = "worldspawn"; // safeguard against various stuff ;)
 515
 516         // needs to be done so early because of the constants they create
 517         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 518         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 519         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 520         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 521         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 522         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 523
 524         MapInfo_Enumerate();
 525         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 526 }
 527
 528 void Map_MarkAsRecent(string m);
 529 float world_already_spawned;
 530 void Nagger_Init();
 531 void ClientInit_Spawn();
 532 void WeaponStats_Init();
 533 void WeaponStats_Shutdown();
 534 void spawnfunc_worldspawn (void)
 535 {
 536         float fd, l, i, j, n;
 537         string s;
 538
 539         cvar = cvar_normal;
 540         cvar_string = cvar_string_normal;
 541         cvar_set = cvar_set_normal;
 542
 543         if(world_already_spawned)
 544                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 545         world_already_spawned = TRUE;
 546
 547         remove = remove_safely; // during spawning, watch what you remove!
 548
 549         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 550
 551         compressShortVector_init();
 552
 553         entity head;
 554         head = nextent(world);
 555         maxclients = 0;
 556         while(head)
 557         {
 558                 ++maxclients;
 559                 head = nextent(head);
 560         }
 561
 562         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 563
 564         // needs to be done so early because of the constants they create
 565         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 566         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 567         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 568         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 569         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 570         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 571
 572         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 573
 574         TemporaryDB = db_create();
 575
 576         // 0 normal
 577         lightstyle(0, "m");
 578
 579         // 1 FLICKER (first variety)
 580         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 581
 582         // 2 SLOW STRONG PULSE
 583         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 584
 585         // 3 CANDLE (first variety)
 586         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 587
 588         // 4 FAST STROBE
 589         lightstyle(4, "mamamamamama");
 590
 591         // 5 GENTLE PULSE 1
 592         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 593
 594         // 6 FLICKER (second variety)
 595         lightstyle(6, "nmonqnmomnmomomno");
 596
 597         // 7 CANDLE (second variety)
 598         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 599
 600         // 8 CANDLE (third variety)
 601         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 602
 603         // 9 SLOW STROBE (fourth variety)
 604         lightstyle(9, "aaaaaaaazzzzzzzz");
 605
 606         // 10 FLUORESCENT FLICKER
 607         lightstyle(10, "mmamammmmammamamaaamammma");
 608
 609         // 11 SLOW PULSE NOT FADE TO BLACK
 610         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 611
 612         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 613
 614         // 63 testing
 615         lightstyle(63, "a");
 616
 617         if(autocvar_g_campaign)
 618                 CampaignPreInit();
 619
 620         Map_MarkAsRecent(mapname);
 621
 622         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 623
 624         precache_model ("null"); // we need this one before InitGameplayMode
 625         InitGameplayMode();
 626         readlevelcvars();
 627         GrappleHookInit();
 628
 629         player_count = 0;
 630         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 631         if(bot_waypoints_for_items == 1)
 632                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 633                         bot_waypoints_for_items = 0;
 634
 635         precache();
 636
 637         WaypointSprite_Init();
 638
 639         GameLogInit(); // prepare everything
 640         // NOTE for matchid:
 641         // changing the logic generating it is okay. But:
 642         // it HAS to stay <= 64 chars
 643         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 644         if(autocvar_sv_eventlog)
 645         {
 646                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 647                 matchid = strzone(s);
 648
 649                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 650                 s = ":gameinfo:mutators:LIST";
 651
 652                 ret_string = s;
 653                 MUTATOR_CALLHOOK(BuildMutatorsString);
 654                 s = ret_string;
 655
 656                 // simple, probably not good in the mutator system
 657                 if(autocvar_g_grappling_hook)
 658                         s = strcat(s, ":grappling_hook");
 659
 660                 // initialiation stuff, not good in the mutator system
 661                 if(!autocvar_g_use_ammunition)
 662                         s = strcat(s, ":no_use_ammunition");
 663
 664                 // initialiation stuff, not good in the mutator system
 665                 if(autocvar_g_pickup_items == 0)
 666                         s = strcat(s, ":no_pickup_items");
 667                 if(autocvar_g_pickup_items > 0)
 668                         s = strcat(s, ":pickup_items");
 669
 670                 // initialiation stuff, not good in the mutator system
 671                 if(autocvar_g_weaponarena != "0")
 672                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 673
 674                 // TODO to mutator system
 675                 if(autocvar_g_norecoil)
 676                         s = strcat(s, ":norecoil");
 677
 678                 // TODO to mutator system
 679                 if(autocvar_g_powerups == 0)
 680                         s = strcat(s, ":no_powerups");
 681                 if(autocvar_g_powerups > 0)
 682                         s = strcat(s, ":powerups");
 683
 684                 GameLogEcho(s);
 685                 GameLogEcho(":gameinfo:end");
 686         }
 687         else
 688                 matchid = strzone(ftos(random()));
 689
 690         cvar_set("nextmap", "");
 691
 692         SetDefaultAlpha();
 693
 694         if(autocvar_g_campaign)
 695                 CampaignPostInit();
 696
 697         Ban_LoadBans();
 698
 699         MapInfo_Enumerate();
 700         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 701
 702         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 703         {
 704                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 705                 if(fd != -1)
 706                 {
 707                         while((s = fgets(fd)))
 708                         {
 709                                 l = tokenize_console(s);
 710                                 if(l < 2)
 711                                         continue;
 712                                 if(argv(0) == "cd")
 713                                 {
 714                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 715                                         print("  cdtrack ", argv(2), "\n");
 716                                 }
 717                                 else if(argv(0) == "fog")
 718                                 {
 719                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 720                                         print("  \"fog\" \"", s, "\"\n");
 721                                 }
 722                                 else if(argv(0) == "set")
 723                                 {
 724                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 725                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 726                                 }
 727                                 else if(argv(0) != "//")
 728                                 {
 729                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 730                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 731                                 }
 732                         }
 733                         fclose(fd);
 734                 }
 735         }
 736
 737         WeaponStats_Init();
 738
 739         WepSet_AddStat();
 740         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 741         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 742         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 743         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 744         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 745         Nagger_Init();
 746
 747         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 748         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 749         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 750         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 751         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 752         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 753         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 754         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 755         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 756         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 757         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 758         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 759         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 760         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 761         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 762
 763         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 764         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 765
 766         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 767
 768         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 769
 770         // freeze attacks
 771         addstat(STAT_FROZEN, AS_INT, frozen);
 772         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 773
 774         // g_movementspeed hack
 775         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 776         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 777         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 778         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 779
 780         // secrets
 781         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 782         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 783
 784         // monsters
 785         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 786         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 787
 788         // misc
 789         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 790
 791         next_pingtime = time + 5;
 792
 793         detect_maptype();
 794
 795         // set up information replies for clients and server to use
 796         maplist_reply = strzone(getmaplist());
 797         lsmaps_reply = strzone(getlsmaps());
 798         monsterlist_reply = strzone(getmonsterlist());
 799         for(i = 0; i < 10; ++i)
 800         {
 801                 s = getrecords(i);
 802                 if (s)
 803                         records_reply[i] = strzone(s);
 804         }
 805         ladder_reply = strzone(getladder());
 806         rankings_reply = strzone(getrankings());
 807
 808         // begin other init
 809         ClientInit_Spawn();
 810         RandomSeed_Spawn();
 811         PingPLReport_Spawn();
 812
 813         CheatInit();
 814
 815         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 816
 817         // fill sv_curl_serverpackages from .serverpackage files
 818         if(autocvar_sv_curl_serverpackages_auto)
 819         {
 820                 s = "";
 821                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 822                 for(i = 0; i < n; ++i)
 823                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 824                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 825                                 s = strcat(s, " ", argv(i));
 826                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 827                 if(fd >= 0)
 828                 {
 829                         j = search_getsize(fd);
 830                         for(i = 0; i < j; ++i)
 831                                 s = strcat(s, " ", search_getfilename(fd, i));
 832                         search_end(fd);
 833                 }
 834                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 835                 if(fd >= 0)
 836                 {
 837                         j = search_getsize(fd);
 838                         for(i = 0; i < j; ++i)
 839                                 s = strcat(s, " ", search_getfilename(fd, i));
 840                         search_end(fd);
 841                 }
 842                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 843         }
 844
 845         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 846         modname = "Xonotic";
 847         // physics/balance/config changes that count as mod
 848         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 849                 modname = cvar_string("g_mod_physics");
 850         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 851                 modname = cvar_string("g_mod_balance");
 852         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 853                 modname = cvar_string("g_mod_config");
 854         // extra mutators that deserve to count as mod
 855         MUTATOR_CALLHOOK(SetModname);
 856
 857         // save it for later
 858         modname = strzone(modname);
 859
 860         WinningConditionHelper(); // set worldstatus
 861
 862         world_initialized = 1;
 863 }
 864
 865 void spawnfunc_light (void)
 866 {
 867         //makestatic (self); // Who the f___ did that?
 868         remove(self);
 869 }
 870
 871 string GetGametype()
 872 {
 873         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 874 }
 875
 876 string GetMapname()
 877 {
 878         return mapname;
 879 }
 880
 881 float Map_Count, Map_Current;
 882 string Map_Current_Name;
 883
 884 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 885 float GetMaplistPosition()
 886 {
 887         float pos, idx;
 888         string map;
 889
 890         map = GetMapname();
 891         idx = autocvar_g_maplist_index;
 892
 893         if(idx >= 0)
 894                 if(idx < Map_Count)
 895                         if(map == argv(idx))
 896                                 return idx;
 897
 898         for(pos = 0; pos < Map_Count; ++pos)
 899                 if(map == argv(pos))
 900                         return pos;
 901
 902         // resume normal maplist rotation if current map is not in g_maplist
 903         return idx;
 904 }
 905
 906 float MapHasRightSize(string map)
 907 {
 908         float fh;
 909         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 910         if(autocvar_g_maplist_check_waypoints)
 911         {
 912                 dprint("checkwp "); dprint(map);
 913                 if(!fexists(strcat("maps/", map, ".waypoints")))
 914                 {
 915                         dprint(": no waypoints\n");
 916                         return FALSE;
 917                 }
 918                 dprint(": has waypoints\n");
 919         }
 920
 921         // open map size restriction file
 922         dprint("opensize "); dprint(map);
 923         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 924         if(fh >= 0)
 925         {
 926                 float mapmin, mapmax;
 927                 dprint(": ok, ");
 928                 mapmin = stof(fgets(fh));
 929                 mapmax = stof(fgets(fh));
 930                 fclose(fh);
 931                 if(player_count < mapmin)
 932                 {
 933                         dprint("not enough\n");
 934                         return FALSE;
 935                 }
 936                 if(player_count > mapmax)
 937                 {
 938                         dprint("too many\n");
 939                         return FALSE;
 940                 }
 941                 dprint("right size\n");
 942                 return TRUE;
 943         }
 944         dprint(": not found\n");
 945         return TRUE;
 946 }
 947
 948 string Map_Filename(float position)
 949 {
 950         return strcat("maps/", argv(position), ".bsp");
 951 }
 952
 953 string strwords(string s, float w)
 954 {
 955         float endpos;
 956         for(endpos = 0; w && endpos >= 0; --w)
 957                 endpos = strstrofs(s, " ", endpos + 1);
 958         if(endpos < 0)
 959                 return s;
 960         else
 961                 return substring(s, 0, endpos);
 962 }
 963
 964 float strhasword(string s, string w)
 965 {
 966         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 967 }
 968
 969 void Map_MarkAsRecent(string m)
 970 {
 971         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 972 }
 973
 974 float Map_IsRecent(string m)
 975 {
 976         return strhasword(autocvar_g_maplist_mostrecent, m);
 977 }
 978
 979 float Map_Check(float position, float pass)
 980 {
 981         string filename;
 982         string map_next;
 983         map_next = argv(position);
 984         if(pass <= 1)
 985         {
 986                 if(Map_IsRecent(map_next))
 987                         return 0;
 988         }
 989         filename = Map_Filename(position);
 990         if(MapInfo_CheckMap(map_next))
 991         {
 992                 if(pass == 2)
 993                         return 1;
 994                 if(MapHasRightSize(map_next))
 995                         return 1;
 996                 return 0;
 997         }
 998         else
 999                 dprint( "Couldn't select '", filename, "'..\n" );
1000
1001         return 0;
1002 }
1003
1004 void Map_Goto_SetStr(string nextmapname)
1005 {
1006         if(getmapname_stored != "")
1007                 strunzone(getmapname_stored);
1008         if(nextmapname == "")
1009                 getmapname_stored = "";
1010         else
1011                 getmapname_stored = strzone(nextmapname);
1012 }
1013
1014 void Map_Goto_SetFloat(float position)
1015 {
1016         cvar_set("g_maplist_index", ftos(position));
1017         Map_Goto_SetStr(argv(position));
1018 }
1019
1020 void Map_Goto(float reinit)
1021 {
1022         MapInfo_LoadMap(getmapname_stored, reinit);
1023 }
1024
1025 // return codes of map selectors:
1026 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1027 //   -2 = permanent failure
1028 float() MaplistMethod_Iterate = // usual method
1029 {
1030         float pass, i;
1031
1032         dprint("Trying MaplistMethod_Iterate\n");
1033
1034         for(pass = 1; pass <= 2; ++pass)
1035         {
1036                 for(i = 1; i < Map_Count; ++i)
1037                 {
1038                         float mapindex;
1039                         mapindex = (i + Map_Current) % Map_Count;
1040                         if(Map_Check(mapindex, pass))
1041                                 return mapindex;
1042                 }
1043         }
1044         return -1;
1045 }
1046
1047 float() MaplistMethod_Repeat = // fallback method
1048 {
1049         dprint("Trying MaplistMethod_Repeat\n");
1050
1051         if(Map_Check(Map_Current, 2))
1052                 return Map_Current;
1053         return -2;
1054 }
1055
1056 float() MaplistMethod_Random = // random map selection
1057 {
1058         float i, imax;
1059
1060         dprint("Trying MaplistMethod_Random\n");
1061
1062         imax = 42;
1063
1064         for(i = 0; i <= imax; ++i)
1065         {
1066                 float mapindex;
1067                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1068                 if(Map_Check(mapindex, 1))
1069                         return mapindex;
1070         }
1071         return -1;
1072 }
1073
1074 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1075 // the exponent sets a bias on the map selection:
1076 // the higher the exponent, the less likely "shortly repeated" same maps are
1077 {
1078         float i, j, imax, insertpos;
1079
1080         dprint("Trying MaplistMethod_Shuffle\n");
1081
1082         imax = 42;
1083
1084         for(i = 0; i <= imax; ++i)
1085         {
1086                 string newlist;
1087
1088                 // now reinsert this at another position
1089                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1090                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1091                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1092                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1093
1094                 // insert the current map there
1095                 newlist = "";
1096                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1097                         newlist = strcat(newlist, " ", argv(j));
1098                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1099                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1100                         newlist = strcat(newlist, " ", argv(j));
1101                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1102                 cvar_set("g_maplist", newlist);
1103                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1104
1105                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1106                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1107                 if(Map_Check(Map_Current, 1))
1108                         return Map_Current;
1109         }
1110         return -1;
1111 }
1112
1113 void Maplist_Init()
1114 {
1115         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1116         float i;
1117         for (i = 0; i < Map_Count; ++i)
1118                 if (Map_Check(i, 2))
1119                         break;
1120         if (i == Map_Count)
1121         {
1122                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1123                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1124                 if(autocvar_g_maplist_shuffle)
1125                         ShuffleMaplist();
1126                 localcmd("\nmenu_cmd sync\n");
1127                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1128         }
1129         if(Map_Count == 0)
1130                 error("empty maplist, cannot select a new map");
1131         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1132
1133         if(Map_Current_Name)
1134                 strunzone(Map_Current_Name);
1135         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1136         // this may or may not be correct, but who cares, in the worst case a map
1137         // isn't chosen in the first pass that should have been
1138 }
1139
1140 string GetNextMap()
1141 {
1142         float nextMap;
1143
1144         Maplist_Init();
1145         nextMap = -1;
1146
1147         if(nextMap == -1)
1148                 if(autocvar_g_maplist_shuffle > 0)
1149                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1150
1151         if(nextMap == -1)
1152                 if(autocvar_g_maplist_selectrandom)
1153                         nextMap = MaplistMethod_Random();
1154
1155         if(nextMap == -1)
1156                 nextMap = MaplistMethod_Iterate();
1157
1158         if(nextMap == -1)
1159                 nextMap = MaplistMethod_Repeat();
1160
1161         if(nextMap >= 0)
1162         {
1163                 Map_Goto_SetFloat(nextMap);
1164                 return getmapname_stored;
1165         }
1166
1167         return "";
1168 }
1169
1170 float DoNextMapOverride(float reinit)
1171 {
1172         if(autocvar_g_campaign)
1173         {
1174                 CampaignPostIntermission();
1175                 alreadychangedlevel = TRUE;
1176                 return TRUE;
1177         }
1178         if(autocvar_quit_when_empty)
1179         {
1180                 if(player_count <= currentbots)
1181                 {
1182                         localcmd("quit\n");
1183                         alreadychangedlevel = TRUE;
1184                         return TRUE;
1185                 }
1186         }
1187         if(autocvar_quit_and_redirect != "")
1188         {
1189                 redirection_target = strzone(autocvar_quit_and_redirect);
1190                 alreadychangedlevel = TRUE;
1191                 return TRUE;
1192         }
1193         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1194         {
1195                 localcmd("restart\n");
1196                 alreadychangedlevel = TRUE;
1197                 return TRUE;
1198         }
1199         if(autocvar_nextmap != "")
1200         {
1201                 string m;
1202                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1203                 cvar_set("nextmap",m);
1204
1205                 if(!m || gametypevote)
1206                         return FALSE;
1207                 if(autocvar_sv_vote_gametype)
1208                 {
1209                         Map_Goto_SetStr(m);
1210                         return FALSE;
1211                 }
1212
1213                 if(MapInfo_CheckMap(m))
1214                 {
1215                         Map_Goto_SetStr(m);
1216                         Map_Goto(reinit);
1217                         alreadychangedlevel = TRUE;
1218                         return TRUE;
1219                 }
1220         }
1221         if(!reinit && autocvar_lastlevel)
1222         {
1223                 cvar_settemp_restore();
1224                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1225                 alreadychangedlevel = TRUE;
1226                 return TRUE;
1227         }
1228         return FALSE;
1229 }
1230
1231 void GotoNextMap(float reinit)
1232 {
1233         //string nextmap;
1234         //float n, nummaps;
1235         //string s;
1236         if (alreadychangedlevel)
1237                 return;
1238         alreadychangedlevel = TRUE;
1239
1240         string nextMap;
1241
1242         nextMap = GetNextMap();
1243         if(nextMap == "")
1244                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1245         Map_Goto(reinit);
1246 }
1247
1248
1249 /*
1250 ============
1251 IntermissionThink
1252
1253 When the player presses attack or jump, change to the next level
1254 ============
1255 */
1256 .float autoscreenshot;
1257 void IntermissionThink()
1258 {
1259         FixIntermissionClient(self);
1260
1261         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1262         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1263
1264         if( (server_screenshot || client_screenshot)
1265                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1266         {
1267                 self.autoscreenshot = -1;
1268                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1269                 return;
1270         }
1271
1272         if (time < intermission_exittime)
1273                 return;
1274
1275         if(!mapvote_initialized)
1276                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1277                         return;
1278
1279         MapVote_Start();
1280 }
1281
1282 /*
1283 ============
1284 FindIntermission
1285
1286 Returns the entity to view from
1287 ============
1288 */
1289 /*
1290 entity FindIntermission()
1291 {
1292         local   entity spot;
1293         local   float cyc;
1294
1295 // look for info_intermission first
1296         spot = find (world, classname, "info_intermission");
1297         if (spot)
1298         {       // pick a random one
1299                 cyc = random() * 4;
1300                 while (cyc > 1)
1301                 {
1302                         spot = find (spot, classname, "info_intermission");
1303                         if (!spot)
1304                                 spot = find (spot, classname, "info_intermission");
1305                         cyc = cyc - 1;
1306                 }
1307                 return spot;
1308         }
1309
1310 // then look for the start position
1311         spot = find (world, classname, "info_player_start");
1312         if (spot)
1313                 return spot;
1314
1315 // testinfo_player_start is only found in regioned levels
1316         spot = find (world, classname, "testplayerstart");
1317         if (spot)
1318                 return spot;
1319
1320 // then look for the start position
1321         spot = find (world, classname, "info_player_deathmatch");
1322         if (spot)
1323                 return spot;
1324
1325         //objerror ("FindIntermission: no spot");
1326         return world;
1327 }
1328 */
1329
1330 /*
1331 ===============================================================================
1332
1333 RULES
1334
1335 ===============================================================================
1336 */
1337
1338 void DumpStats(float final)
1339 {
1340         float file;
1341         string s;
1342         float to_console;
1343         float to_eventlog;
1344         float to_file;
1345         float i;
1346
1347         to_console = autocvar_sv_logscores_console;
1348         to_eventlog = autocvar_sv_eventlog;
1349         to_file = autocvar_sv_logscores_file;
1350
1351         if(!final)
1352         {
1353                 to_console = TRUE; // always print printstats replies
1354                 to_eventlog = FALSE; // but never print them to the event log
1355         }
1356
1357         if(to_eventlog)
1358                 if(autocvar_sv_eventlog_console)
1359                         to_console = FALSE; // otherwise we get the output twice
1360
1361         if(final)
1362                 s = ":scores:";
1363         else
1364                 s = ":status:";
1365         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1366
1367         if(to_console)
1368                 print(s, "\n");
1369         if(to_eventlog)
1370                 GameLogEcho(s);
1371
1372         file = -1;
1373         if(to_file)
1374         {
1375                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1376                 if(file == -1)
1377                         to_file = FALSE;
1378                 else
1379                         fputs(file, strcat(s, "\n"));
1380         }
1381
1382         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1383         if(to_console)
1384                 print(s, "\n");
1385         if(to_eventlog)
1386                 GameLogEcho(s);
1387         if(to_file)
1388                 fputs(file, strcat(s, "\n"));
1389
1390         FOR_EACH_CLIENT(other)
1391         {
1392                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1393                 {
1394                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1395                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1396                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1397                                 s = strcat(s, ftos(other.team), ":");
1398                         else
1399                                 s = strcat(s, "spectator:");
1400
1401                         if(to_console)
1402                                 print(s, other.netname, "\n");
1403                         if(to_eventlog)
1404                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1405                         if(to_file)
1406                                 fputs(file, strcat(s, other.netname, "\n"));
1407                 }
1408         }
1409
1410         if(teamplay)
1411         {
1412                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1413                 if(to_console)
1414                         print(s, "\n");
1415                 if(to_eventlog)
1416                         GameLogEcho(s);
1417                 if(to_file)
1418                         fputs(file, strcat(s, "\n"));
1419
1420                 for(i = 1; i < 16; ++i)
1421                 {
1422                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1423                         s = strcat(s, ":", ftos(i));
1424                         if(to_console)
1425                                 print(s, "\n");
1426                         if(to_eventlog)
1427                                 GameLogEcho(s);
1428                         if(to_file)
1429                                 fputs(file, strcat(s, "\n"));
1430                 }
1431         }
1432
1433         if(to_console)
1434                 print(":end\n");
1435         if(to_eventlog)
1436                 GameLogEcho(":end");
1437         if(to_file)
1438         {
1439                 fputs(file, ":end\n");
1440                 fclose(file);
1441         }
1442 }
1443
1444 void FixIntermissionClient(entity e)
1445 {
1446         string s;
1447         if(!e.autoscreenshot) // initial call
1448         {
1449                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1450                 e.health = -2342;
1451                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1452                 e.solid = SOLID_NOT;
1453                 e.movetype = MOVETYPE_NONE;
1454                 e.takedamage = DAMAGE_NO;
1455                 if(e.weaponentity)
1456                 {
1457                         e.weaponentity.effects = EF_NODRAW;
1458                         if (e.weaponentity.weaponentity)
1459                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1460                 }
1461                 if(IS_REAL_CLIENT(e))
1462                 {
1463                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1464                         s = autocvar_sv_intermission_cdtrack;
1465                         if(s != "")
1466                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1467                         msg_entity = e;
1468                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1469                 }
1470         }
1471 }
1472
1473 /*
1474 go to the next level for deathmatch
1475 only called if a time or frag limit has expired
1476 */
1477 void NextLevel()
1478 {
1479         gameover = TRUE;
1480
1481         intermission_running = 1;
1482
1483 // enforce a wait time before allowing changelevel
1484         if(player_count > 0)
1485                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1486         else
1487                 intermission_exittime = -1;
1488
1489         /*
1490         WriteByte (MSG_ALL, SVC_CDTRACK);
1491         WriteByte (MSG_ALL, 3);
1492         WriteByte (MSG_ALL, 3);
1493         // done in FixIntermission
1494         */
1495
1496         //pos = FindIntermission ();
1497
1498         VoteReset();
1499
1500         DumpStats(TRUE);
1501
1502         // send statistics
1503         PlayerStats_GameReport(TRUE);
1504         WeaponStats_Shutdown();
1505
1506         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1507
1508         if(autocvar_sv_eventlog)
1509                 GameLogEcho(":gameover");
1510
1511         GameLogClose();
1512
1513         FOR_EACH_PLAYER(other) {
1514                 FixIntermissionClient(other);
1515                 if(other.winning)
1516                         bprint(other.netname, " ^7wins.\n");
1517         }
1518
1519         if(autocvar_g_campaign)
1520                 CampaignPreIntermission();
1521
1522         MUTATOR_CALLHOOK(MatchEnd);
1523
1524         localcmd("\nsv_hook_gameend\n");
1525 }
1526
1527 /*
1528 ============
1529 CheckRules_Player
1530
1531 Exit deathmatch games upon conditions
1532 ============
1533 */
1534 void CheckRules_Player()
1535 {
1536         if (gameover)   // someone else quit the game already
1537                 return;
1538
1539         if(self.deadflag == DEAD_NO)
1540                 self.play_time += frametime;
1541
1542         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1543         //   (div0: and that in CheckRules_World please)
1544 }
1545
1546 float checkrules_equality;
1547 float checkrules_suddendeathwarning;
1548 float checkrules_suddendeathend;
1549 float checkrules_overtimesadded; //how many overtimes have been already added
1550
1551 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1552 const float WINNING_YES = 1; // winner found
1553 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1554 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1555
1556 float InitiateSuddenDeath()
1557 {
1558         // Check first whether normal overtimes could be added before initiating suddendeath mode
1559         // - for this timelimit_overtime needs to be >0 of course
1560         // - also check the winning condition calculated in the previous frame and only add normal overtime
1561         //   again, if at the point at which timelimit would be extended again, still no winner was found
1562         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1563         {
1564                 return 1; // need to call InitiateOvertime later
1565         }
1566         else
1567         {
1568                 if(!checkrules_suddendeathend)
1569                 {
1570                         if(autocvar_g_campaign)
1571                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1572                         else
1573                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1574                         if(g_race && !g_race_qualifying)
1575                                 race_StartCompleting();
1576                 }
1577                 return 0;
1578         }
1579 }
1580
1581 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1582 {
1583         ++checkrules_overtimesadded;
1584         //add one more overtime by simply extending the timelimit
1585         float tl;
1586         tl = autocvar_timelimit;
1587         tl += autocvar_timelimit_overtime;
1588         cvar_set("timelimit", ftos(tl));
1589
1590         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1591 }
1592
1593 float GetWinningCode(float fraglimitreached, float equality)
1594 {
1595         if(autocvar_g_campaign == 1)
1596                 if(fraglimitreached)
1597                         return WINNING_YES;
1598                 else
1599                         return WINNING_NO;
1600
1601         else
1602                 if(equality)
1603                         if(fraglimitreached)
1604                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1605                         else
1606                                 return WINNING_NEVER;
1607                 else
1608                         if(fraglimitreached)
1609                                 return WINNING_YES;
1610                         else
1611                                 return WINNING_NO;
1612 }
1613
1614 // set the .winning flag for exactly those players with a given field value
1615 void SetWinners(.float field, float value)
1616 {
1617         entity head;
1618         FOR_EACH_PLAYER(head)
1619                 head.winning = (head.field == value);
1620 }
1621
1622 // set the .winning flag for those players with a given field value
1623 void AddWinners(.float field, float value)
1624 {
1625         entity head;
1626         FOR_EACH_PLAYER(head)
1627                 if(head.field == value)
1628                         head.winning = 1;
1629 }
1630
1631 // clear the .winning flags
1632 void ClearWinners(void)
1633 {
1634         entity head;
1635         FOR_EACH_PLAYER(head)
1636                 head.winning = 0;
1637 }
1638
1639 // Onslaught winning condition:
1640 // game terminates if only one team has a working generator (or none)
1641 float WinningCondition_Onslaught()
1642 {
1643         entity head;
1644         float t1, t2, t3, t4;
1645
1646         WinningConditionHelper(); // set worldstatus
1647
1648         if(warmup_stage)
1649                 return WINNING_NO;
1650
1651         // first check if the game has ended
1652         t1 = t2 = t3 = t4 = 0;
1653         head = find(world, classname, "onslaught_generator");
1654         while (head)
1655         {
1656                 if (head.health > 0)
1657                 {
1658                         if (head.team == NUM_TEAM_1) t1 = 1;
1659                         if (head.team == NUM_TEAM_2) t2 = 1;
1660                         if (head.team == NUM_TEAM_3) t3 = 1;
1661                         if (head.team == NUM_TEAM_4) t4 = 1;
1662                 }
1663                 head = find(head, classname, "onslaught_generator");
1664         }
1665         if (t1 + t2 + t3 + t4 < 2)
1666         {
1667                 // game over, only one team remains (or none)
1668                 ClearWinners();
1669                 if (t1) SetWinners(team, NUM_TEAM_1);
1670                 if (t2) SetWinners(team, NUM_TEAM_2);
1671                 if (t3) SetWinners(team, NUM_TEAM_3);
1672                 if (t4) SetWinners(team, NUM_TEAM_4);
1673                 dprint("Have a winner, ending game.\n");
1674                 return WINNING_YES;
1675         }
1676
1677         // Two or more teams remain
1678         return WINNING_NO;
1679 }
1680
1681 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1682 // they win. Otherwise the defending team wins once the timelimit passes.
1683 void assault_new_round();
1684 float WinningCondition_Assault()
1685 {
1686         float status;
1687
1688         WinningConditionHelper(); // set worldstatus
1689
1690         status = WINNING_NO;
1691         // as the timelimit has not yet passed just assume the defending team will win
1692         if(assault_attacker_team == NUM_TEAM_1)
1693         {
1694                 SetWinners(team, NUM_TEAM_2);
1695         }
1696         else
1697         {
1698                 SetWinners(team, NUM_TEAM_1);
1699         }
1700
1701         entity ent;
1702         ent = find(world, classname, "target_assault_roundend");
1703         if(ent)
1704         {
1705                 if(ent.winning) // round end has been triggered by attacking team
1706                 {
1707                         bprint("ASSAULT: round completed...\n");
1708                         SetWinners(team, assault_attacker_team);
1709
1710                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1711
1712                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1713                         {
1714                                 status = WINNING_YES;
1715                         }
1716                         else
1717                         {
1718                                 entity oldself;
1719                                 oldself = self;
1720                                 self = ent;
1721                                 assault_new_round();
1722                                 self = oldself;
1723                         }
1724                 }
1725         }
1726
1727         return status;
1728 }
1729
1730 // LMS winning condition: game terminates if and only if there's at most one
1731 // one player who's living lives. Top two scores being equal cancels the time
1732 // limit.
1733 float WinningCondition_LMS()
1734 {
1735         entity head, head2;
1736         float have_player;
1737         float have_players;
1738         float l;
1739
1740         have_player = FALSE;
1741         have_players = FALSE;
1742         l = LMS_NewPlayerLives();
1743
1744         head = find(world, classname, "player");
1745         if(head)
1746                 have_player = TRUE;
1747         head2 = find(head, classname, "player");
1748         if(head2)
1749                 have_players = TRUE;
1750
1751         if(have_player)
1752         {
1753                 // we have at least one player
1754                 if(have_players)
1755                 {
1756                         // two or more active players - continue with the game
1757                 }
1758                 else
1759                 {
1760                         // exactly one player?
1761
1762                         ClearWinners();
1763                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1764
1765                         if(l)
1766                         {
1767                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1768                                 return WINNING_NO;
1769                         }
1770                         else
1771                         {
1772                                 // a winner!
1773                                 // and assign him his first place
1774                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1775                                 return WINNING_YES;
1776                         }
1777                 }
1778         }
1779         else
1780         {
1781                 // nobody is playing at all...
1782                 if(l)
1783                 {
1784                         // wait for players...
1785                 }
1786                 else
1787                 {
1788                         // SNAFU (maybe a draw game?)
1789                         ClearWinners();
1790                         dprint("No players, ending game.\n");
1791                         return WINNING_YES;
1792                 }
1793         }
1794
1795         // When we get here, we have at least two players who are actually LIVING,
1796         // now check if the top two players have equal score.
1797         WinningConditionHelper();
1798
1799         ClearWinners();
1800         if(WinningConditionHelper_winner)
1801                 WinningConditionHelper_winner.winning = TRUE;
1802         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1803                 return WINNING_NEVER;
1804
1805         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1806         return WINNING_NO;
1807 }
1808
1809 void ShuffleMaplist()
1810 {
1811         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1812 }
1813
1814 float leaderfrags;
1815 float WinningCondition_Scores(float limit, float leadlimit)
1816 {
1817         float limitreached;
1818
1819         // TODO make everything use THIS winning condition (except LMS)
1820         WinningConditionHelper();
1821
1822         if(teamplay)
1823         {
1824                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1825                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1826                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1827                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1828         }
1829
1830         ClearWinners();
1831         if(WinningConditionHelper_winner)
1832                 WinningConditionHelper_winner.winning = 1;
1833         if(WinningConditionHelper_winnerteam >= 0)
1834                 SetWinners(team, WinningConditionHelper_winnerteam);
1835
1836         if(WinningConditionHelper_lowerisbetter)
1837         {
1838                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1839                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1840                 limit = -limit;
1841         }
1842
1843         if(WinningConditionHelper_zeroisworst)
1844                 leadlimit = 0; // not supported in this mode
1845
1846         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1847         // these modes always score in increments of 1, thus this makes sense
1848         {
1849                 if(leaderfrags != WinningConditionHelper_topscore)
1850                 {
1851                         leaderfrags = WinningConditionHelper_topscore;
1852
1853                         if (limit)
1854                         if (leaderfrags == limit - 1)
1855                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1856                         else if (leaderfrags == limit - 2)
1857                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1858                         else if (leaderfrags == limit - 3)
1859                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1860                 }
1861         }
1862
1863         limitreached = FALSE;
1864         if(limit)
1865                 if(WinningConditionHelper_topscore >= limit)
1866                         limitreached = TRUE;
1867         if(leadlimit)
1868         {
1869                 float leadlimitreached;
1870                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1871                 if(autocvar_leadlimit_and_fraglimit)
1872                         limitreached = (limitreached && leadlimitreached);
1873                 else
1874                         limitreached = (limitreached || leadlimitreached);
1875         }
1876
1877         if(limit)
1878                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1879
1880         return GetWinningCode(
1881                 WinningConditionHelper_topscore && limitreached,
1882                 WinningConditionHelper_equality
1883         );
1884 }
1885
1886 float WinningCondition_Race(float fraglimit)
1887 {
1888         float wc;
1889         entity p;
1890         float n, c;
1891
1892         n = 0;
1893         c = 0;
1894         FOR_EACH_PLAYER(p)
1895         {
1896                 ++n;
1897                 if(p.race_completed)
1898                         ++c;
1899         }
1900         if(n && (n == c))
1901                 return WINNING_YES;
1902         wc = WinningCondition_Scores(fraglimit, 0);
1903
1904         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1905         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1906         // do NOT support equality when the laps are all raced!
1907                 return WINNING_STARTSUDDENDEATHOVERTIME;
1908         else
1909                 return WINNING_NEVER;
1910 }
1911
1912 float WinningCondition_QualifyingThenRace(float limit)
1913 {
1914         float wc;
1915         wc = WinningCondition_Scores(limit, 0);
1916
1917         // NEVER initiate overtime
1918         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1919         {
1920                 return WINNING_YES;
1921         }
1922
1923         return wc;
1924 }
1925
1926 float WinningCondition_RanOutOfSpawns()
1927 {
1928         entity head;
1929
1930         if(have_team_spawns <= 0)
1931                 return WINNING_NO;
1932
1933         if(autocvar_g_spawn_useallspawns <= 0)
1934                 return WINNING_NO;
1935
1936         if(!some_spawn_has_been_used)
1937                 return WINNING_NO;
1938
1939         team1_score = team2_score = team3_score = team4_score = 0;
1940
1941         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1942         {
1943                 if(head.team == NUM_TEAM_1)
1944                         team1_score = 1;
1945                 else if(head.team == NUM_TEAM_2)
1946                         team2_score = 1;
1947                 else if(head.team == NUM_TEAM_3)
1948                         team3_score = 1;
1949                 else if(head.team == NUM_TEAM_4)
1950                         team4_score = 1;
1951         }
1952
1953         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1954         {
1955                 if(head.team == NUM_TEAM_1)
1956                         team1_score = 1;
1957                 else if(head.team == NUM_TEAM_2)
1958                         team2_score = 1;
1959                 else if(head.team == NUM_TEAM_3)
1960                         team3_score = 1;
1961                 else if(head.team == NUM_TEAM_4)
1962                         team4_score = 1;
1963         }
1964
1965         ClearWinners();
1966         if(team1_score + team2_score + team3_score + team4_score == 0)
1967         {
1968                 checkrules_equality = TRUE;
1969                 return WINNING_YES;
1970         }
1971         else if(team1_score + team2_score + team3_score + team4_score == 1)
1972         {
1973                 float t, i;
1974                 if(team1_score)
1975                         t = NUM_TEAM_1;
1976                 else if(team2_score)
1977                         t = NUM_TEAM_2;
1978                 else if(team3_score)
1979                         t = NUM_TEAM_3;
1980                 else // if(team4_score)
1981                         t = NUM_TEAM_4;
1982                 CheckAllowedTeams(world);
1983                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1984                 {
1985                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1986                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1987                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1988                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1989                 }
1990
1991                 AddWinners(team, t);
1992                 return WINNING_YES;
1993         }
1994         else
1995                 return WINNING_NO;
1996 }
1997
1998 /*
1999 ============
2000 CheckRules_World
2001
2002 Exit deathmatch games upon conditions
2003 ============
2004 */
2005 void ReadyRestart();
2006 void CheckRules_World()
2007 {
2008         float timelimit;
2009         float fraglimit;
2010         float leadlimit;
2011
2012         VoteThink();
2013         MapVote_Think();
2014
2015         SetDefaultAlpha();
2016
2017         if (gameover)   // someone else quit the game already
2018         {
2019                 if(player_count == 0) // Nobody there? Then let's go to the next map
2020                         MapVote_Start();
2021                         // this will actually check the player count in the next frame
2022                         // again, but this shouldn't hurt
2023                 return;
2024         }
2025
2026         timelimit = autocvar_timelimit * 60;
2027         fraglimit = autocvar_fraglimit;
2028         leadlimit = autocvar_leadlimit;
2029
2030         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2031         {
2032                 if(timelimit > 0)
2033                         timelimit = 0; // timelimit is not made for warmup
2034                 if(fraglimit > 0)
2035                         fraglimit = 0; // no fraglimit for now
2036                 leadlimit = 0; // no leadlimit for now
2037         }
2038
2039         if(timelimit > 0)
2040         {
2041                 timelimit += game_starttime;
2042         }
2043         else if (timelimit < 0)
2044         {
2045                 // endmatch
2046                 NextLevel();
2047                 return;
2048         }
2049
2050         if(g_onslaught)
2051                 timelimit = 0; // ONS has its own overtime rule
2052
2053         float wantovertime;
2054         wantovertime = 0;
2055
2056         if(timelimit > game_starttime)
2057                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2058         else
2059                 game_completion_ratio = 0;
2060
2061         if(checkrules_suddendeathend)
2062         {
2063                 if(!checkrules_suddendeathwarning)
2064                 {
2065                         checkrules_suddendeathwarning = TRUE;
2066                         if(g_race && !g_race_qualifying)
2067                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2068                         else
2069                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2070                 }
2071         }
2072         else
2073         {
2074                 if (timelimit && time >= timelimit)
2075                 {
2076                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2077                         {
2078                                 float totalplayers;
2079                                 float playerswithlaps;
2080                                 float readyplayers;
2081                                 entity head;
2082                                 totalplayers = playerswithlaps = readyplayers = 0;
2083                                 FOR_EACH_PLAYER(head)
2084                                 {
2085                                         ++totalplayers;
2086                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2087                                                 ++playerswithlaps;
2088                                         if(head.ready)
2089                                                 ++readyplayers;
2090                                 }
2091
2092                                 // at least 2 of the players have completed a lap: start the RACE
2093                                 // otherwise, the players should end the qualifying on their own
2094                                 if(readyplayers || playerswithlaps >= 2)
2095                                 {
2096                                         checkrules_suddendeathend = 0;
2097                                         ReadyRestart(); // go to race
2098                                         return;
2099                                 }
2100                                 else
2101                                         wantovertime |= InitiateSuddenDeath();
2102                         }
2103                         else
2104                                 wantovertime |= InitiateSuddenDeath();
2105                 }
2106         }
2107
2108         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2109         {
2110                 NextLevel();
2111                 return;
2112         }
2113
2114         float checkrules_status;
2115         checkrules_status = WinningCondition_RanOutOfSpawns();
2116         if(checkrules_status == WINNING_YES)
2117         {
2118                 bprint("Hey! Someone ran out of spawns!\n");
2119         }
2120         else if(g_race && !g_race_qualifying && timelimit >= 0)
2121         {
2122                 checkrules_status = WinningCondition_Race(fraglimit);
2123                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2124         }
2125         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2126         {
2127                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2128                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2129         }
2130         else if(g_assault)
2131         {
2132                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2133         }
2134         else if(g_lms)
2135         {
2136                 checkrules_status = WinningCondition_LMS();
2137         }
2138         else if (g_onslaught)
2139         {
2140                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2141         }
2142         else
2143         {
2144                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2145                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2146         }
2147
2148         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2149         {
2150                 checkrules_status = WINNING_NEVER;
2151                 checkrules_overtimesadded = -1;
2152                 wantovertime |= InitiateSuddenDeath();
2153         }
2154
2155         if(checkrules_status == WINNING_NEVER)
2156                 // equality cases! Nobody wins if the overtime ends in a draw.
2157                 ClearWinners();
2158
2159         if(wantovertime)
2160         {
2161                 if(checkrules_status == WINNING_NEVER)
2162                         InitiateOvertime();
2163                 else
2164                         checkrules_status = WINNING_YES;
2165         }
2166
2167         if(checkrules_suddendeathend)
2168                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2169                         checkrules_status = WINNING_YES;
2170
2171         if(checkrules_status == WINNING_YES)
2172         {
2173                 //print("WINNING\n");
2174                 NextLevel();
2175         }
2176 }
2177
2178 string GotoMap(string m)
2179 {
2180         m = GameTypeVote_MapInfo_FixName(m);
2181         if (!m)
2182                 return "The map you suggested is not available on this server.";
2183         if (!autocvar_sv_vote_gametype)
2184         if(!MapInfo_CheckMap(m))
2185                 return "The map you suggested does not support the current game mode.";
2186         cvar_set("nextmap", m);
2187         cvar_set("timelimit", "-1");
2188         if(mapvote_initialized || alreadychangedlevel)
2189         {
2190                 if(DoNextMapOverride(0))
2191                         return "Map switch initiated.";
2192                 else
2193                         return "Hm... no. For some reason I like THIS map more.";
2194         }
2195         else
2196                 return "Map switch will happen after scoreboard.";
2197 }
2198
2199
2200 void EndFrame()
2201 {
2202         anticheat_endframe();
2203
2204         float altime;
2205         FOR_EACH_REALCLIENT(self)
2206         {
2207                 entity e = IS_SPEC(self) ? self.enemy : self;
2208                 if(e.typehitsound)
2209                         self.typehit_time = time;
2210                 else if(e.damage_dealt)
2211                 {
2212                         self.hit_time = time;
2213                         self.damage_dealt_total += ceil(e.damage_dealt);
2214                 }
2215         }
2216         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2217         // add 1 frametime because after this, engine SV_Physics
2218         // increases time by a frametime and then networks the frame
2219         // add another frametime because client shows everything with
2220         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2221         // needed!
2222         FOR_EACH_CLIENT(self)
2223         {
2224                 self.typehitsound = FALSE;
2225                 self.damage_dealt = 0;
2226                 antilag_record(self, altime);
2227         }
2228         FOR_EACH_MONSTER(self)
2229                 antilag_record(self, altime);
2230 }
2231
2232
2233 /*
2234  * RedirectionThink:
2235  * returns TRUE if redirecting
2236  */
2237 float redirection_timeout;
2238 float redirection_nextthink;
2239 float RedirectionThink()
2240 {
2241         float clients_found;
2242
2243         if(redirection_target == "")
2244                 return FALSE;
2245
2246         if(!redirection_timeout)
2247         {
2248                 cvar_set("sv_public", "-2");
2249                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2250                 if(redirection_target == "self")
2251                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2252                 else
2253                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2254         }
2255
2256         if(time < redirection_nextthink)
2257                 return TRUE;
2258
2259         redirection_nextthink = time + 1;
2260
2261         clients_found = 0;
2262         FOR_EACH_REALCLIENT(self)
2263         {
2264                 // TODO add timer
2265                 print("Redirecting: sending connect command to ", self.netname, "\n");
2266                 if(redirection_target == "self")
2267                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2268                 else
2269                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2270                 ++clients_found;
2271         }
2272
2273         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2274
2275         if(time > redirection_timeout || clients_found == 0)
2276                 localcmd("\nwait; wait; wait; quit\n");
2277
2278         return TRUE;
2279 }
2280
2281 void TargetMusic_RestoreGame();
2282 void RestoreGame()
2283 {
2284         // Loaded from a save game
2285         // some things then break, so let's work around them...
2286
2287         // Progs DB (capture records)
2288         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2289
2290         // Mapinfo
2291         MapInfo_Shutdown();
2292         MapInfo_Enumerate();
2293         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2294         WeaponStats_Init();
2295
2296         TargetMusic_RestoreGame();
2297 }
2298
2299 void Shutdown()
2300 {
2301         gameover = 2;
2302
2303         if(world_initialized > 0)
2304         {
2305                 world_initialized = 0;
2306                 print("Saving persistent data...\n");
2307                 Ban_SaveBans();
2308
2309                 // playerstats with unfinished match
2310                 PlayerStats_GameReport(FALSE);
2311
2312                 if(!cheatcount_total)
2313                 {
2314                         if(autocvar_sv_db_saveasdump)
2315                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2316                         else
2317                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2318                 }
2319                 if(autocvar_developer)
2320                 {
2321                         if(autocvar_sv_db_saveasdump)
2322                                 db_dump(TemporaryDB, "server-temp.db");
2323                         else
2324                                 db_save(TemporaryDB, "server-temp.db");
2325                 }
2326                 CheatShutdown(); // must be after cheatcount check
2327                 db_close(ServerProgsDB);
2328                 db_close(TemporaryDB);
2329                 print("done!\n");
2330                 // tell the bot system the game is ending now
2331                 bot_endgame();
2332
2333                 WeaponStats_Shutdown();
2334                 MapInfo_Shutdown();
2335         }
2336         else if(world_initialized == 0)
2337         {
2338                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2339         }
2340 }