qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_runematch");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("g_runematch_point_leadlimit");
 319                 BADCVAR("leadlimit_and_fraglimit");
 320                 BADCVAR("leadlimit_override");
 321                 BADCVAR("pausable");
 322                 BADCVAR("sv_allow_fullbright");
 323                 BADCVAR("sv_checkforpacketsduringsleep");
 324                 BADCVAR("sv_fraginfo");
 325                 BADCVAR("sv_timeout");
 326                 BADPREFIX("sv_timeout_");
 327                 BADCVAR("welcome_message_time");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_fraginfo_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_namechangetimer");
 343 #ifndef NO_LEGACY_NETWORKING
 344                 BADCVAR("sv_use_csqc_players"); // transition
 345 #endif
 346
 347                 // allowed changes to server admins (please sync this to server.cfg)
 348                 // vi commands:
 349                 //   :/"impure"/,$d
 350                 //   :g!,^\/\/[^ /],d
 351                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 352                 //   :%!sort
 353                 // yes, this does contain some redundant stuff, don't really care
 354                 BADCVAR("bot_config_file");
 355                 BADCVAR("bot_number");
 356                 BADCVAR("bot_prefix");
 357                 BADCVAR("bot_suffix");
 358                 BADCVAR("capturelimit_override");
 359                 BADCVAR("fraglimit_override");
 360                 BADCVAR("gametype");
 361                 BADCVAR("g_antilag");
 362                 BADCVAR("g_balance_teams");
 363                 BADCVAR("g_balance_teams_prevent_imbalance");
 364                 BADCVAR("g_balance_teams_scorefactor");
 365                 BADCVAR("g_ban_sync_trusted_servers");
 366                 BADCVAR("g_ban_sync_uri");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_friendlyfire");
 370                 BADCVAR("g_fullbrightitems");
 371                 BADCVAR("g_fullbrightplayers");
 372                 BADCVAR("g_keyhunt_point_limit");
 373                 BADCVAR("g_keyhunt_teams_override");
 374                 BADCVAR("g_lms_lives_override");
 375                 BADCVAR("g_maplist");
 376                 BADCVAR("g_maplist_check_waypoints");
 377                 BADCVAR("g_maplist_mostrecent_count");
 378                 BADCVAR("g_maplist_shuffle");
 379                 BADCVAR("g_maplist_votable");
 380                 BADCVAR("g_maplist_votable_abstain");
 381                 BADCVAR("g_maplist_votable_nodetail");
 382                 BADCVAR("g_maplist_votable_suggestions");
 383                 BADCVAR("g_maxplayers");
 384                 BADCVAR("g_mirrordamage");
 385                 BADCVAR("g_nexball_goallimit");
 386                 BADCVAR("g_powerups");
 387                 BADCVAR("g_runematch_point_limit");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_warmup");
 390                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 391                 BADCVAR("hostname");
 392                 BADCVAR("log_file");
 393                 BADCVAR("maxplayers");
 394                 BADCVAR("minplayers");
 395                 BADCVAR("net_address");
 396                 BADCVAR("port");
 397                 BADCVAR("rcon_password");
 398                 BADCVAR("rcon_restricted_commands");
 399                 BADCVAR("rcon_restricted_password");
 400                 BADCVAR("skill");
 401                 BADCVAR("sv_adminnick");
 402                 BADCVAR("sv_autoscreenshot");
 403                 BADCVAR("sv_autotaunt");
 404                 BADCVAR("sv_curl_defaulturl");
 405                 BADCVAR("sv_defaultcharacter");
 406                 BADCVAR("sv_defaultplayercolors");
 407                 BADCVAR("sv_defaultplayermodel");
 408                 BADCVAR("sv_defaultplayerskin");
 409                 BADCVAR("sv_maxidle");
 410                 BADCVAR("sv_maxrate");
 411                 BADCVAR("sv_motd");
 412                 BADCVAR("sv_public");
 413                 BADCVAR("sv_ready_restart");
 414                 BADCVAR("sv_status_privacy");
 415                 BADCVAR("sv_taunt");
 416                 BADCVAR("sv_vote_call");
 417                 BADCVAR("sv_vote_commands");
 418                 BADCVAR("sv_vote_majority_factor");
 419                 BADCVAR("sv_vote_master");
 420                 BADCVAR("sv_vote_master_commands");
 421                 BADCVAR("sv_vote_master_password");
 422                 BADCVAR("sv_vote_simple_majority_factor");
 423                 BADCVAR("sys_ticrate");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_minstagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434
 435                 if(autocvar_g_minstagib)
 436                 {
 437                         BADCVAR("g_grappling_hook");
 438                         BADCVAR("g_jetpack");
 439                 }
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for(;;)
 480         {
 481                 o = world.mins;
 482                 o_x += random() * (world.maxs_x - world.mins_x);
 483                 o_y += random() * (world.maxs_y - world.mins_y);
 484                 o_z += random() * (world.maxs_z - world.mins_z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return TRUE;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         // needs to be done so early because of the constants they create
 554         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 555         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 556         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 557         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 558
 559         MapInfo_Enumerate();
 560         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 561 }
 562
 563 void Map_MarkAsRecent(string m);
 564 float world_already_spawned;
 565 void Nagger_Init();
 566 void ClientInit_Spawn();
 567 void WeaponStats_Init();
 568 void WeaponStats_Shutdown();
 569 void spawnfunc_worldspawn (void)
 570 {
 571         float fd, l, i, j, n;
 572         string s, col;
 573
 574         cvar = cvar_normal;
 575         cvar_string = cvar_string_normal;
 576         cvar_set = cvar_set_normal;
 577
 578         if(world_already_spawned)
 579                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 580         world_already_spawned = TRUE;
 581
 582         remove = remove_safely; // during spawning, watch what you remove!
 583
 584         check_unacceptable_compiler_bugs();
 585
 586         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 587
 588         compressShortVector_init();
 589
 590         allowed_to_spawn = TRUE;
 591
 592         entity head;
 593         head = nextent(world);
 594         maxclients = 0;
 595         while(head)
 596         {
 597                 ++maxclients;
 598                 head = nextent(head);
 599         }
 600
 601         // needs to be done so early because of the constants they create
 602         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 603         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 604         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 605         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 606
 607         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 608
 609         TemporaryDB = db_create();
 610
 611         // 0 normal
 612         lightstyle(0, "m");
 613
 614         // 1 FLICKER (first variety)
 615         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 616
 617         // 2 SLOW STRONG PULSE
 618         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 619
 620         // 3 CANDLE (first variety)
 621         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 622
 623         // 4 FAST STROBE
 624         lightstyle(4, "mamamamamama");
 625
 626         // 5 GENTLE PULSE 1
 627         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 628
 629         // 6 FLICKER (second variety)
 630         lightstyle(6, "nmonqnmomnmomomno");
 631
 632         // 7 CANDLE (second variety)
 633         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 634
 635         // 8 CANDLE (third variety)
 636         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 637
 638         // 9 SLOW STROBE (fourth variety)
 639         lightstyle(9, "aaaaaaaazzzzzzzz");
 640
 641         // 10 FLUORESCENT FLICKER
 642         lightstyle(10, "mmamammmmammamamaaamammma");
 643
 644         // 11 SLOW PULSE NOT FADE TO BLACK
 645         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 646
 647         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 648
 649         // 63 testing
 650         lightstyle(63, "a");
 651
 652         if(autocvar_g_campaign)
 653                 CampaignPreInit();
 654
 655         Map_MarkAsRecent(mapname);
 656
 657         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 658
 659         precache_model ("null"); // we need this one before InitGameplayMode
 660         InitGameplayMode();
 661         readlevelcvars();
 662         GrappleHookInit();
 663         ElectroInit();
 664         LaserInit();
 665
 666         player_count = 0;
 667         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 668         if(bot_waypoints_for_items == 1)
 669                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 670                         bot_waypoints_for_items = 0;
 671
 672         precache();
 673
 674         WaypointSprite_Init();
 675
 676         GameLogInit(); // prepare everything
 677         // NOTE for matchid:
 678         // changing the logic generating it is okay. But:
 679         // it HAS to stay <= 64 chars
 680         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 681         if(autocvar_sv_eventlog)
 682         {
 683                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 684                 matchid = strzone(s);
 685
 686                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 687                 s = ":gameinfo:mutators:LIST";
 688
 689                 ret_string = s;
 690                 MUTATOR_CALLHOOK(BuildMutatorsString);
 691                 s = ret_string;
 692
 693                 // simple, probably not good in the mutator system
 694                 if(autocvar_g_grappling_hook)
 695                         s = strcat(s, ":grappling_hook");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(!autocvar_g_use_ammunition)
 699                         s = strcat(s, ":no_use_ammunition");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_pickup_items == 0)
 703                         s = strcat(s, ":no_pickup_items");
 704                 if(autocvar_g_pickup_items > 0)
 705                         s = strcat(s, ":pickup_items");
 706
 707                 // initialiation stuff, not good in the mutator system
 708                 if(autocvar_g_weaponarena != "0")
 709                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 710
 711                 // TODO to mutator system
 712                 if(autocvar_g_norecoil)
 713                         s = strcat(s, ":norecoil");
 714
 715                 // TODO to mutator system
 716                 if(autocvar_g_midair)
 717                         s = strcat(s, ":midair");
 718
 719                 // TODO to mutator system
 720                 if(autocvar_g_minstagib)
 721                         s = strcat(s, ":minstagib");
 722
 723                 // TODO to mutator system
 724                 if(autocvar_g_powerups == 0)
 725                         s = strcat(s, ":no_powerups");
 726                 if(autocvar_g_powerups > 0)
 727                         s = strcat(s, ":powerups");
 728
 729                 GameLogEcho(s);
 730                 GameLogEcho(":gameinfo:end");
 731         }
 732         else
 733                 matchid = strzone(ftos(random()));
 734
 735         cvar_set("nextmap", "");
 736
 737         SetDefaultAlpha();
 738
 739         if(autocvar_g_campaign)
 740                 CampaignPostInit();
 741
 742         fteqcc_testbugs();
 743
 744         Ban_LoadBans();
 745
 746         MapInfo_Enumerate();
 747         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 748
 749         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 750         {
 751                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 752                 if(fd != -1)
 753                 {
 754                         while((s = fgets(fd)))
 755                         {
 756                                 l = tokenize_console(s);
 757                                 if(l < 2)
 758                                         continue;
 759                                 if(argv(0) == "cd")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  cdtrack ", argv(2), "\n");
 763                                 }
 764                                 else if(argv(0) == "fog")
 765                                 {
 766                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 767                                         print("  \"fog\" \"", s, "\"\n");
 768                                 }
 769                                 else if(argv(0) == "set")
 770                                 {
 771                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 772                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 773                                 }
 774                                 else if(argv(0) != "//")
 775                                 {
 776                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 777                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 778                                 }
 779                         }
 780                         fclose(fd);
 781                 }
 782         }
 783
 784         WeaponStats_Init();
 785
 786         WEPSET_ADDSTAT();
 787         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 788         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 789         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 790         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 791         Nagger_Init();
 792
 793         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 794         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 795         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 796         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 797         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 798         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 799         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 800         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 801         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 802         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 803         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 804         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 805         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 806
 807         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 808         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 809
 810         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 811
 812         if(g_ca || g_freezetag)
 813         {
 814                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 815                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 816                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 817                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 818         }
 819         if(g_freezetag)
 820         {
 821                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 822                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 823         }
 824
 825         // g_movementspeed hack
 826         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 827         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 828         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 829         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 830
 831         // secrets
 832         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 833         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 834
 835         // misc
 836         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 837
 838         next_pingtime = time + 5;
 839
 840         detect_maptype();
 841
 842         // set up information replies for clients and server to use
 843         lsmaps_reply = "^7Maps available: ";
 844         lsnewmaps_reply = "^7Maps without a record set: ";
 845         for(i = 0, j = 0; i < MapInfo_count; ++i)
 846         {
 847                 if(MapInfo_Get_ByID(i))
 848                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 849                         {
 850                                 if(mod(i, 2))
 851                                         col = "^2";
 852                                 else
 853                                         col = "^3";
 854
 855                                 ++j;
 856
 857                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 858
 859                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 860                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 861                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 862                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 863                         }
 864         }
 865
 866         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 867         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 868
 869         maplist_reply = "^7Maps in list: ";
 870         n = tokenize_console(autocvar_g_maplist);
 871         for(i = 0, j = 0; i < n; ++i)
 872         {
 873                 if(MapInfo_CheckMap(argv(i)))
 874                 {
 875                         if(mod(j, 2))
 876                                 col = "^2";
 877                         else
 878                                 col = "^3";
 879                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 880                         ++j;
 881                 }
 882         }
 883         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 884         MapInfo_ClearTemps();
 885
 886         for(i = 0; i < 10; ++i)
 887         {
 888                 s = getrecords(i);
 889                 if (s)
 890                         records_reply[i] = strzone(s);
 891         }
 892
 893         ladder_reply = strzone(getladder());
 894
 895         rankings_reply = strzone(getrankings());
 896
 897         // begin other init
 898         ClientInit_Spawn();
 899         RandomSeed_Spawn();
 900         PingPLReport_Spawn();
 901
 902         CheatInit();
 903
 904         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 905
 906         // fill sv_curl_serverpackages from .serverpackage files
 907         if(autocvar_sv_curl_serverpackages_auto)
 908         {
 909                 s = "";
 910                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 911                 for(i = 0; i < n; ++i)
 912                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 913                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 914                                 s = strcat(s, " ", argv(i));
 915                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 916                 if(fd >= 0)
 917                 {
 918                         j = search_getsize(fd);
 919                         for(i = 0; i < j; ++i)
 920                                 s = strcat(s, " ", search_getfilename(fd, i));
 921                         search_end(fd);
 922                 }
 923                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 924                 if(fd >= 0)
 925                 {
 926                         j = search_getsize(fd);
 927                         for(i = 0; i < j; ++i)
 928                                 s = strcat(s, " ", search_getfilename(fd, i));
 929                         search_end(fd);
 930                 }
 931                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 932         }
 933
 934         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 935         modname = "Xonotic";
 936         // physics/balance/config changes that count as mod
 937         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 938                 modname = cvar_string("g_mod_physics");
 939         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 940                 modname = cvar_string("g_mod_balance");
 941         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 942                 modname = cvar_string("g_mod_config");
 943         // weird mutators that deserve to count as mod
 944         if(autocvar_g_minstagib)
 945                 modname = "MinstaGib";
 946         // extra mutators that deserve to count as mod
 947         MUTATOR_CALLHOOK(SetModname);
 948
 949         // save it for later
 950         modname = strzone(modname);
 951
 952         WinningConditionHelper(); // set worldstatus
 953
 954         world_initialized = 1;
 955 }
 956
 957 void spawnfunc_light (void)
 958 {
 959         //makestatic (self); // Who the f___ did that?
 960         remove(self);
 961 }
 962
 963 string GetGametype()
 964 {
 965         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 966 }
 967
 968 string getmapname_stored;
 969 string GetMapname()
 970 {
 971         return mapname;
 972 }
 973
 974 float Map_Count, Map_Current;
 975 string Map_Current_Name;
 976
 977 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 978 float GetMaplistPosition()
 979 {
 980         float pos, idx;
 981         string map;
 982
 983         map = GetMapname();
 984         idx = autocvar_g_maplist_index;
 985
 986         if(idx >= 0)
 987                 if(idx < Map_Count)
 988                         if(map == argv(idx))
 989                                 return idx;
 990
 991         for(pos = 0; pos < Map_Count; ++pos)
 992                 if(map == argv(pos))
 993                         return pos;
 994
 995         // resume normal maplist rotation if current map is not in g_maplist
 996         return idx;
 997 }
 998
 999 float MapHasRightSize(string map)
1000 {
1001         float fh;
1002         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1003         if(autocvar_g_maplist_check_waypoints)
1004         {
1005                 dprint("checkwp "); dprint(map);
1006                 if(!fexists(strcat("maps/", map, ".waypoints")))
1007                 {
1008                         dprint(": no waypoints\n");
1009                         return FALSE;
1010                 }
1011                 dprint(": has waypoints\n");
1012         }
1013
1014         // open map size restriction file
1015         dprint("opensize "); dprint(map);
1016         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1017         if(fh >= 0)
1018         {
1019                 float mapmin, mapmax;
1020                 dprint(": ok, ");
1021                 mapmin = stof(fgets(fh));
1022                 mapmax = stof(fgets(fh));
1023                 fclose(fh);
1024                 if(player_count < mapmin)
1025                 {
1026                         dprint("not enough\n");
1027                         return FALSE;
1028                 }
1029                 if(player_count > mapmax)
1030                 {
1031                         dprint("too many\n");
1032                         return FALSE;
1033                 }
1034                 dprint("right size\n");
1035                 return TRUE;
1036         }
1037         dprint(": not found\n");
1038         return TRUE;
1039 }
1040
1041 string Map_Filename(float position)
1042 {
1043         return strcat("maps/", argv(position), ".bsp");
1044 }
1045
1046 string strwords(string s, float w)
1047 {
1048         float endpos;
1049         for(endpos = 0; w && endpos >= 0; --w)
1050                 endpos = strstrofs(s, " ", endpos + 1);
1051         if(endpos < 0)
1052                 return s;
1053         else
1054                 return substring(s, 0, endpos);
1055 }
1056
1057 float strhasword(string s, string w)
1058 {
1059         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1060 }
1061
1062 void Map_MarkAsRecent(string m)
1063 {
1064         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1065 }
1066
1067 float Map_IsRecent(string m)
1068 {
1069         return strhasword(autocvar_g_maplist_mostrecent, m);
1070 }
1071
1072 float Map_Check(float position, float pass)
1073 {
1074         string filename;
1075         string map_next;
1076         map_next = argv(position);
1077         if(pass <= 1)
1078         {
1079                 if(Map_IsRecent(map_next))
1080                         return 0;
1081         }
1082         filename = Map_Filename(position);
1083         if(MapInfo_CheckMap(map_next))
1084         {
1085                 if(pass == 2)
1086                         return 1;
1087                 if(MapHasRightSize(map_next))
1088                         return 1;
1089                 return 0;
1090         }
1091         else
1092                 dprint( "Couldn't select '", filename, "'..\n" );
1093
1094         return 0;
1095 }
1096
1097 void Map_Goto_SetStr(string nextmapname)
1098 {
1099         if(getmapname_stored != "")
1100                 strunzone(getmapname_stored);
1101         if(nextmapname == "")
1102                 getmapname_stored = "";
1103         else
1104                 getmapname_stored = strzone(nextmapname);
1105 }
1106
1107 void Map_Goto_SetFloat(float position)
1108 {
1109         cvar_set("g_maplist_index", ftos(position));
1110         Map_Goto_SetStr(argv(position));
1111 }
1112
1113 void Map_Goto(float reinit)
1114 {
1115         MapInfo_LoadMap(getmapname_stored, reinit);
1116 }
1117
1118 // return codes of map selectors:
1119 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1120 //   -2 = permanent failure
1121 float() MaplistMethod_Iterate = // usual method
1122 {
1123         float pass, i;
1124
1125         for(pass = 1; pass <= 2; ++pass)
1126         {
1127                 for(i = 1; i < Map_Count; ++i)
1128                 {
1129                         float mapindex;
1130                         mapindex = mod(i + Map_Current, Map_Count);
1131                         if(Map_Check(mapindex, pass))
1132                                 return mapindex;
1133                 }
1134         }
1135         return -1;
1136 }
1137
1138 float() MaplistMethod_Repeat = // fallback method
1139 {
1140         if(Map_Check(Map_Current, 2))
1141                 return Map_Current;
1142         return -2;
1143 }
1144
1145 float() MaplistMethod_Random = // random map selection
1146 {
1147         float i, imax;
1148
1149         imax = 42;
1150
1151         for(i = 0; i <= imax; ++i)
1152         {
1153                 float mapindex;
1154                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1155                 if(Map_Check(mapindex, 1))
1156                         return mapindex;
1157         }
1158         return -1;
1159 }
1160
1161 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1162 // the exponent sets a bias on the map selection:
1163 // the higher the exponent, the less likely "shortly repeated" same maps are
1164 {
1165         float i, j, imax, insertpos;
1166
1167         imax = 42;
1168
1169         for(i = 0; i <= imax; ++i)
1170         {
1171                 string newlist;
1172
1173                 // now reinsert this at another position
1174                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1175                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1176                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1177                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1178
1179                 // insert the current map there
1180                 newlist = "";
1181                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1182                         newlist = strcat(newlist, " ", argv(j));
1183                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1184                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1185                         newlist = strcat(newlist, " ", argv(j));
1186                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1187                 cvar_set("g_maplist", newlist);
1188                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1189
1190                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1191                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1192                 if(Map_Check(Map_Current, 1))
1193                         return Map_Current;
1194         }
1195         return -1;
1196 }
1197
1198 void Maplist_Init()
1199 {
1200         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1201         if(Map_Count == 0)
1202         {
1203                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1204                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1205                 if(autocvar_g_maplist_shuffle)
1206                         ShuffleMaplist();
1207                 localcmd("\nmenu_cmd sync\n");
1208                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1209         }
1210         if(Map_Count == 0)
1211                 error("empty maplist, cannot select a new map");
1212         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1213
1214         if(Map_Current_Name)
1215                 strunzone(Map_Current_Name);
1216         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1217         // this may or may not be correct, but who cares, in the worst case a map
1218         // isn't chosen in the first pass that should have been
1219 }
1220
1221 string GetNextMap()
1222 {
1223         float nextMap;
1224
1225         Maplist_Init();
1226         nextMap = -1;
1227
1228         if(nextMap == -1)
1229                 if(autocvar_g_maplist_shuffle > 0)
1230                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1231
1232         if(nextMap == -1)
1233                 if(autocvar_g_maplist_selectrandom)
1234                         nextMap = MaplistMethod_Random();
1235
1236         if(nextMap == -1)
1237                 nextMap = MaplistMethod_Iterate();
1238
1239         if(nextMap == -1)
1240                 nextMap = MaplistMethod_Repeat();
1241
1242         if(nextMap >= 0)
1243         {
1244                 Map_Goto_SetFloat(nextMap);
1245                 return getmapname_stored;
1246         }
1247
1248         return "";
1249 }
1250
1251 float DoNextMapOverride(float reinit)
1252 {
1253         if(autocvar_g_campaign)
1254         {
1255                 CampaignPostIntermission();
1256                 alreadychangedlevel = TRUE;
1257                 return TRUE;
1258         }
1259         if(autocvar_quit_when_empty)
1260         {
1261                 if(player_count <= currentbots)
1262                 {
1263                         localcmd("quit\n");
1264                         alreadychangedlevel = TRUE;
1265                         return TRUE;
1266                 }
1267         }
1268         if(autocvar_quit_and_redirect != "")
1269         {
1270                 redirection_target = strzone(autocvar_quit_and_redirect);
1271                 alreadychangedlevel = TRUE;
1272                 return TRUE;
1273         }
1274         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1275         {
1276                 localcmd("restart\n");
1277                 alreadychangedlevel = TRUE;
1278                 return TRUE;
1279         }
1280         if(autocvar_nextmap != "")
1281                 if(MapInfo_CheckMap(autocvar_nextmap))
1282                 {
1283                         Map_Goto_SetStr(autocvar_nextmap);
1284                         Map_Goto(reinit);
1285                         alreadychangedlevel = TRUE;
1286                         return TRUE;
1287                 }
1288         if(!reinit && autocvar_lastlevel)
1289         {
1290                 cvar_settemp_restore();
1291                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1292                 alreadychangedlevel = TRUE;
1293                 return TRUE;
1294         }
1295         return FALSE;
1296 }
1297
1298 void GotoNextMap(float reinit)
1299 {
1300         //string nextmap;
1301         //float n, nummaps;
1302         //string s;
1303         if (alreadychangedlevel)
1304                 return;
1305         alreadychangedlevel = TRUE;
1306
1307         {
1308                 string nextMap;
1309                 float allowReset;
1310
1311                 for(allowReset = 1; allowReset >= 0; --allowReset)
1312                 {
1313                         nextMap = GetNextMap();
1314                         if(nextMap != "")
1315                                 break;
1316
1317                         if(allowReset)
1318                         {
1319                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1320                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1321                                 if(autocvar_g_maplist_shuffle)
1322                                         ShuffleMaplist();
1323                                 localcmd("\nmenu_cmd sync\n");
1324                         }
1325                         else
1326                         {
1327                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1328                         }
1329                 }
1330                 Map_Goto(reinit);
1331         }
1332 }
1333
1334
1335 /*
1336 ============
1337 IntermissionThink
1338
1339 When the player presses attack or jump, change to the next level
1340 ============
1341 */
1342 .float autoscreenshot;
1343 void() MapVote_Start;
1344 void() MapVote_Think;
1345 float mapvote_initialized;
1346 void IntermissionThink()
1347 {
1348         FixIntermissionClient(self);
1349
1350         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1351         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1352
1353         if( (server_screenshot || client_screenshot)
1354                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1355         {
1356                 self.autoscreenshot = -1;
1357                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1358                 return;
1359         }
1360
1361         if (time < intermission_exittime)
1362                 return;
1363
1364         if(!mapvote_initialized)
1365                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1366                         return;
1367
1368         MapVote_Start();
1369 }
1370
1371 /*
1372 ============
1373 FindIntermission
1374
1375 Returns the entity to view from
1376 ============
1377 */
1378 /*
1379 entity FindIntermission()
1380 {
1381         local   entity spot;
1382         local   float cyc;
1383
1384 // look for info_intermission first
1385         spot = find (world, classname, "info_intermission");
1386         if (spot)
1387         {       // pick a random one
1388                 cyc = random() * 4;
1389                 while (cyc > 1)
1390                 {
1391                         spot = find (spot, classname, "info_intermission");
1392                         if (!spot)
1393                                 spot = find (spot, classname, "info_intermission");
1394                         cyc = cyc - 1;
1395                 }
1396                 return spot;
1397         }
1398
1399 // then look for the start position
1400         spot = find (world, classname, "info_player_start");
1401         if (spot)
1402                 return spot;
1403
1404 // testinfo_player_start is only found in regioned levels
1405         spot = find (world, classname, "testplayerstart");
1406         if (spot)
1407                 return spot;
1408
1409 // then look for the start position
1410         spot = find (world, classname, "info_player_deathmatch");
1411         if (spot)
1412                 return spot;
1413
1414         //objerror ("FindIntermission: no spot");
1415         return world;
1416 }
1417 */
1418
1419 /*
1420 ===============================================================================
1421
1422 RULES
1423
1424 ===============================================================================
1425 */
1426
1427 void DumpStats(float final)
1428 {
1429         float file;
1430         string s;
1431         float to_console;
1432         float to_eventlog;
1433         float to_file;
1434         float i;
1435
1436         to_console = autocvar_sv_logscores_console;
1437         to_eventlog = autocvar_sv_eventlog;
1438         to_file = autocvar_sv_logscores_file;
1439
1440         if(!final)
1441         {
1442                 to_console = TRUE; // always print printstats replies
1443                 to_eventlog = FALSE; // but never print them to the event log
1444         }
1445
1446         if(to_eventlog)
1447                 if(autocvar_sv_eventlog_console)
1448                         to_console = FALSE; // otherwise we get the output twice
1449
1450         if(final)
1451                 s = ":scores:";
1452         else
1453                 s = ":status:";
1454         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1455
1456         if(to_console)
1457                 print(s, "\n");
1458         if(to_eventlog)
1459                 GameLogEcho(s);
1460
1461         file = -1;
1462         if(to_file)
1463         {
1464                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1465                 if(file == -1)
1466                         to_file = FALSE;
1467                 else
1468                         fputs(file, strcat(s, "\n"));
1469         }
1470
1471         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1472         if(to_console)
1473                 print(s, "\n");
1474         if(to_eventlog)
1475                 GameLogEcho(s);
1476         if(to_file)
1477                 fputs(file, strcat(s, "\n"));
1478
1479         FOR_EACH_CLIENT(other)
1480         {
1481                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1482                 {
1483                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1484                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1485                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1486                                 s = strcat(s, ftos(other.team), ":");
1487                         else
1488                                 s = strcat(s, "spectator:");
1489
1490                         if(to_console)
1491                                 print(s, other.netname, "\n");
1492                         if(to_eventlog)
1493                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1494                         if(to_file)
1495                                 fputs(file, strcat(s, other.netname, "\n"));
1496                 }
1497         }
1498
1499         if(teamplay)
1500         {
1501                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1502                 if(to_console)
1503                         print(s, "\n");
1504                 if(to_eventlog)
1505                         GameLogEcho(s);
1506                 if(to_file)
1507                         fputs(file, strcat(s, "\n"));
1508
1509                 for(i = 1; i < 16; ++i)
1510                 {
1511                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1512                         s = strcat(s, ":", ftos(i));
1513                         if(to_console)
1514                                 print(s, "\n");
1515                         if(to_eventlog)
1516                                 GameLogEcho(s);
1517                         if(to_file)
1518                                 fputs(file, strcat(s, "\n"));
1519                 }
1520         }
1521
1522         if(to_console)
1523                 print(":end\n");
1524         if(to_eventlog)
1525                 GameLogEcho(":end");
1526         if(to_file)
1527         {
1528                 fputs(file, ":end\n");
1529                 fclose(file);
1530         }
1531 }
1532
1533 void FixIntermissionClient(entity e)
1534 {
1535         string s;
1536         if(!e.autoscreenshot) // initial call
1537         {
1538                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1539                 e.health = -2342;
1540                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1541                 e.solid = SOLID_NOT;
1542                 e.movetype = MOVETYPE_NONE;
1543                 e.takedamage = DAMAGE_NO;
1544                 if(e.weaponentity)
1545                 {
1546                         e.weaponentity.effects = EF_NODRAW;
1547                         if (e.weaponentity.weaponentity)
1548                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1549                 }
1550                 if(clienttype(e) == CLIENTTYPE_REAL)
1551                 {
1552                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1553                         s = autocvar_sv_intermission_cdtrack;
1554                         if(s != "")
1555                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1556                         msg_entity = e;
1557                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1558                 }
1559         }
1560 }
1561
1562 void minstagib_stop_countdown(entity e);
1563 /*
1564 go to the next level for deathmatch
1565 only called if a time or frag limit has expired
1566 */
1567 void NextLevel()
1568 {
1569         gameover = TRUE;
1570
1571         intermission_running = 1;
1572
1573 // enforce a wait time before allowing changelevel
1574         if(player_count > 0)
1575                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1576         else
1577                 intermission_exittime = -1;
1578
1579         /*
1580         WriteByte (MSG_ALL, SVC_CDTRACK);
1581         WriteByte (MSG_ALL, 3);
1582         WriteByte (MSG_ALL, 3);
1583         // done in FixIntermission
1584         */
1585
1586         //pos = FindIntermission ();
1587
1588         VoteReset();
1589
1590         DumpStats(TRUE);
1591
1592         // send statistics
1593         entity e;
1594         PlayerStats_EndMatch(1);
1595         FOR_EACH_CLIENT(e)
1596                 PlayerStats_AddGlobalInfo(e);
1597         PlayerStats_Shutdown();
1598         WeaponStats_Shutdown();
1599
1600         if(autocvar_sv_eventlog)
1601                 GameLogEcho(":gameover");
1602
1603         GameLogClose();
1604
1605         FOR_EACH_PLAYER(other) {
1606                 minstagib_stop_countdown(other);
1607                 FixIntermissionClient(other);
1608                 if(other.winning)
1609                         bprint(other.netname, " ^7wins.\n");
1610         }
1611
1612         if(autocvar_g_campaign)
1613                 CampaignPreIntermission();
1614
1615         MUTATOR_CALLHOOK(MatchEnd);
1616
1617         localcmd("\nsv_hook_gameend\n");
1618 }
1619
1620 /*
1621 ============
1622 CheckRules_Player
1623
1624 Exit deathmatch games upon conditions
1625 ============
1626 */
1627 void CheckRules_Player()
1628 {
1629         if (gameover)   // someone else quit the game already
1630                 return;
1631
1632         if(self.deadflag == DEAD_NO)
1633                 self.play_time += frametime;
1634
1635         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1636         //   (div0: and that in CheckRules_World please)
1637 }
1638
1639 float checkrules_equality;
1640 float checkrules_suddendeathwarning;
1641 float checkrules_suddendeathend;
1642 float checkrules_overtimesadded; //how many overtimes have been already added
1643
1644 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1645 float WINNING_YES = 1; // winner found
1646 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1647 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1648
1649 float InitiateSuddenDeath()
1650 {
1651         // Check first whether normal overtimes could be added before initiating suddendeath mode
1652         // - for this timelimit_overtime needs to be >0 of course
1653         // - also check the winning condition calculated in the previous frame and only add normal overtime
1654         //   again, if at the point at which timelimit would be extended again, still no winner was found
1655         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1656         {
1657                 return 1; // need to call InitiateOvertime later
1658         }
1659         else
1660         {
1661                 if(!checkrules_suddendeathend)
1662                 {
1663                         if(autocvar_g_campaign)
1664                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1665                         else
1666                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1667                         if(g_race && !g_race_qualifying)
1668                                 race_StartCompleting();
1669                 }
1670                 return 0;
1671         }
1672 }
1673
1674 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1675 {
1676         ++checkrules_overtimesadded;
1677         //add one more overtime by simply extending the timelimit
1678         float tl;
1679         tl = autocvar_timelimit;
1680         tl += autocvar_timelimit_overtime;
1681         cvar_set("timelimit", ftos(tl));
1682         string minutesPlural;
1683         if (autocvar_timelimit_overtime == 1)
1684                 minutesPlural = " ^3minute";
1685         else
1686                 minutesPlural = " ^3minutes";
1687
1688         bcenterprint(
1689                 strcat(
1690                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1691                         ftos(autocvar_timelimit_overtime),
1692                         minutesPlural,
1693                         " to the game!"
1694                 )
1695         );
1696 }
1697
1698 float GetWinningCode(float fraglimitreached, float equality)
1699 {
1700         if(autocvar_g_campaign == 1)
1701                 if(fraglimitreached)
1702                         return WINNING_YES;
1703                 else
1704                         return WINNING_NO;
1705
1706         else
1707                 if(equality)
1708                         if(fraglimitreached)
1709                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1710                         else
1711                                 return WINNING_NEVER;
1712                 else
1713                         if(fraglimitreached)
1714                                 return WINNING_YES;
1715                         else
1716                                 return WINNING_NO;
1717 }
1718
1719 // set the .winning flag for exactly those players with a given field value
1720 void SetWinners(.float field, float value)
1721 {
1722         entity head;
1723         FOR_EACH_PLAYER(head)
1724                 head.winning = (head.field == value);
1725 }
1726
1727 // set the .winning flag for those players with a given field value
1728 void AddWinners(.float field, float value)
1729 {
1730         entity head;
1731         FOR_EACH_PLAYER(head)
1732                 if(head.field == value)
1733                         head.winning = 1;
1734 }
1735
1736 // clear the .winning flags
1737 void ClearWinners(void)
1738 {
1739         entity head;
1740         FOR_EACH_PLAYER(head)
1741                 head.winning = 0;
1742 }
1743
1744 // Onslaught winning condition:
1745 // game terminates if only one team has a working generator (or none)
1746 float WinningCondition_Onslaught()
1747 {
1748         entity head;
1749         float t1, t2, t3, t4;
1750
1751         WinningConditionHelper(); // set worldstatus
1752
1753         if(inWarmupStage)
1754                 return WINNING_NO;
1755
1756         // first check if the game has ended
1757         t1 = t2 = t3 = t4 = 0;
1758         head = find(world, classname, "onslaught_generator");
1759         while (head)
1760         {
1761                 if (head.health > 0)
1762                 {
1763                         if (head.team == FL_TEAM_1) t1 = 1;
1764                         if (head.team == FL_TEAM_2) t2 = 1;
1765                         if (head.team == FL_TEAM_3) t3 = 1;
1766                         if (head.team == FL_TEAM_4) t4 = 1;
1767                 }
1768                 head = find(head, classname, "onslaught_generator");
1769         }
1770         if (t1 + t2 + t3 + t4 < 2)
1771         {
1772                 // game over, only one team remains (or none)
1773                 ClearWinners();
1774                 if (t1) SetWinners(team, FL_TEAM_1);
1775                 if (t2) SetWinners(team, FL_TEAM_2);
1776                 if (t3) SetWinners(team, FL_TEAM_3);
1777                 if (t4) SetWinners(team, FL_TEAM_4);
1778                 dprint("Have a winner, ending game.\n");
1779                 return WINNING_YES;
1780         }
1781
1782         // Two or more teams remain
1783         return WINNING_NO;
1784 }
1785
1786 float LMS_NewPlayerLives()
1787 {
1788         float fl;
1789         fl = autocvar_fraglimit;
1790         if(fl == 0)
1791                 fl = 999;
1792
1793         // first player has left the game for dying too much? Nobody else can get in.
1794         if(lms_lowest_lives < 1)
1795                 return 0;
1796
1797         if(!autocvar_g_lms_join_anytime)
1798                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1799                         return 0;
1800
1801         return bound(1, lms_lowest_lives, fl);
1802 }
1803
1804 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1805 // they win. Otherwise the defending team wins once the timelimit passes.
1806 void assault_new_round();
1807 float WinningCondition_Assault()
1808 {
1809         float status;
1810
1811         WinningConditionHelper(); // set worldstatus
1812
1813         status = WINNING_NO;
1814         // as the timelimit has not yet passed just assume the defending team will win
1815         if(assault_attacker_team == FL_TEAM_1)
1816         {
1817                 SetWinners(team, FL_TEAM_2);
1818         }
1819         else
1820         {
1821                 SetWinners(team, FL_TEAM_1);
1822         }
1823
1824         entity ent;
1825         ent = find(world, classname, "target_assault_roundend");
1826         if(ent)
1827         {
1828                 if(ent.winning) // round end has been triggered by attacking team
1829                 {
1830                         bprint("ASSAULT: round completed...\n");
1831                         SetWinners(team, assault_attacker_team);
1832
1833                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1834
1835                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1836                         {
1837                                 status = WINNING_YES;
1838                         }
1839                         else
1840                         {
1841                                 entity oldself;
1842                                 oldself = self;
1843                                 self = ent;
1844                                 assault_new_round();
1845                                 self = oldself;
1846                         }
1847                 }
1848         }
1849
1850         return status;
1851 }
1852
1853 // LMS winning condition: game terminates if and only if there's at most one
1854 // one player who's living lives. Top two scores being equal cancels the time
1855 // limit.
1856 float WinningCondition_LMS()
1857 {
1858         entity head, head2;
1859         float have_player;
1860         float have_players;
1861         float l;
1862
1863         have_player = FALSE;
1864         have_players = FALSE;
1865         l = LMS_NewPlayerLives();
1866
1867         head = find(world, classname, "player");
1868         if(head)
1869                 have_player = TRUE;
1870         head2 = find(head, classname, "player");
1871         if(head2)
1872                 have_players = TRUE;
1873
1874         if(have_player)
1875         {
1876                 // we have at least one player
1877                 if(have_players)
1878                 {
1879                         // two or more active players - continue with the game
1880                 }
1881                 else
1882                 {
1883                         // exactly one player?
1884
1885                         ClearWinners();
1886                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1887
1888                         if(l)
1889                         {
1890                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1891                                 return WINNING_NO;
1892                         }
1893                         else
1894                         {
1895                                 // a winner!
1896                                 // and assign him his first place
1897                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1898                                 return WINNING_YES;
1899                         }
1900                 }
1901         }
1902         else
1903         {
1904                 // nobody is playing at all...
1905                 if(l)
1906                 {
1907                         // wait for players...
1908                 }
1909                 else
1910                 {
1911                         // SNAFU (maybe a draw game?)
1912                         ClearWinners();
1913                         dprint("No players, ending game.\n");
1914                         return WINNING_YES;
1915                 }
1916         }
1917
1918         // When we get here, we have at least two players who are actually LIVING,
1919         // now check if the top two players have equal score.
1920         WinningConditionHelper();
1921
1922         ClearWinners();
1923         if(WinningConditionHelper_winner)
1924                 WinningConditionHelper_winner.winning = TRUE;
1925         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1926                 return WINNING_NEVER;
1927
1928         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1929         return WINNING_NO;
1930 }
1931
1932 void ShuffleMaplist()
1933 {
1934         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1935 }
1936
1937 float leaderfrags;
1938 float WinningCondition_Scores(float limit, float leadlimit)
1939 {
1940         float limitreached;
1941
1942         // TODO make everything use THIS winning condition (except LMS)
1943         WinningConditionHelper();
1944
1945         if(teamplay)
1946         {
1947                 team1_score = TeamScore_GetCompareValue(FL_TEAM_1);
1948                 team2_score = TeamScore_GetCompareValue(FL_TEAM_2);
1949                 team3_score = TeamScore_GetCompareValue(FL_TEAM_3);
1950                 team4_score = TeamScore_GetCompareValue(FL_TEAM_4);
1951         }
1952
1953         ClearWinners();
1954         if(WinningConditionHelper_winner)
1955                 WinningConditionHelper_winner.winning = 1;
1956         if(WinningConditionHelper_winnerteam >= 0)
1957                 SetWinners(team, WinningConditionHelper_winnerteam);
1958
1959         if(WinningConditionHelper_lowerisbetter)
1960         {
1961                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1962                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1963                 limit = -limit;
1964         }
1965
1966         if(WinningConditionHelper_zeroisworst)
1967                 leadlimit = 0; // not supported in this mode
1968
1969         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1970         // these modes always score in increments of 1, thus this makes sense
1971         {
1972                 if(leaderfrags != WinningConditionHelper_topscore)
1973                 {
1974                         leaderfrags = WinningConditionHelper_topscore;
1975
1976                         if (limit)
1977                         if (leaderfrags == limit - 1)
1978                                 Announce("1fragleft");
1979                         else if (leaderfrags == limit - 2)
1980                                 Announce("2fragsleft");
1981                         else if (leaderfrags == limit - 3)
1982                                 Announce("3fragsleft");
1983                 }
1984         }
1985
1986         limitreached = FALSE;
1987         if(limit)
1988                 if(WinningConditionHelper_topscore >= limit)
1989                         limitreached = TRUE;
1990         if(leadlimit)
1991         {
1992                 float leadlimitreached;
1993                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1994                 if(autocvar_leadlimit_and_fraglimit)
1995                         limitreached = (limitreached && leadlimitreached);
1996                 else
1997                         limitreached = (limitreached || leadlimitreached);
1998         }
1999
2000         if(limit)
2001                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
2002
2003         return GetWinningCode(
2004                 WinningConditionHelper_topscore && limitreached,
2005                 WinningConditionHelper_equality
2006         );
2007 }
2008
2009 float WinningCondition_Race(float fraglimit)
2010 {
2011         float wc;
2012         entity p;
2013         float n, c;
2014
2015         n = 0;
2016         c = 0;
2017         FOR_EACH_PLAYER(p)
2018         {
2019                 ++n;
2020                 if(p.race_completed)
2021                         ++c;
2022         }
2023         if(n && (n == c))
2024                 return WINNING_YES;
2025         wc = WinningCondition_Scores(fraglimit, 0);
2026
2027         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2028         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2029         // do NOT support equality when the laps are all raced!
2030                 return WINNING_STARTSUDDENDEATHOVERTIME;
2031         else
2032                 return WINNING_NEVER;
2033 }
2034
2035 float WinningCondition_QualifyingThenRace(float limit)
2036 {
2037         float wc;
2038         wc = WinningCondition_Scores(limit, 0);
2039
2040         // NEVER initiate overtime
2041         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2042         {
2043                 return WINNING_YES;
2044         }
2045
2046         return wc;
2047 }
2048
2049 float WinningCondition_RanOutOfSpawns()
2050 {
2051         entity head;
2052
2053         if(have_team_spawns <= 0)
2054                 return WINNING_NO;
2055
2056         if(autocvar_g_spawn_useallspawns <= 0)
2057                 return WINNING_NO;
2058
2059         if(!some_spawn_has_been_used)
2060                 return WINNING_NO;
2061
2062         team1_score = team2_score = team3_score = team4_score = 0;
2063
2064         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2065         {
2066                 if(head.team == FL_TEAM_1)
2067                         team1_score = 1;
2068                 else if(head.team == FL_TEAM_2)
2069                         team2_score = 1;
2070                 else if(head.team == FL_TEAM_3)
2071                         team3_score = 1;
2072                 else if(head.team == FL_TEAM_4)
2073                         team4_score = 1;
2074         }
2075
2076         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2077         {
2078                 if(head.team == FL_TEAM_1)
2079                         team1_score = 1;
2080                 else if(head.team == FL_TEAM_2)
2081                         team2_score = 1;
2082                 else if(head.team == FL_TEAM_3)
2083                         team3_score = 1;
2084                 else if(head.team == FL_TEAM_4)
2085                         team4_score = 1;
2086         }
2087
2088         ClearWinners();
2089         if(team1_score + team2_score + team3_score + team4_score == 0)
2090         {
2091                 checkrules_equality = TRUE;
2092                 return WINNING_YES;
2093         }
2094         else if(team1_score + team2_score + team3_score + team4_score == 1)
2095         {
2096                 float t, i;
2097                 if(team1_score)
2098                         t = FL_TEAM_1;
2099                 else if(team2_score)
2100                         t = FL_TEAM_2;
2101                 else if(team3_score)
2102                         t = FL_TEAM_3;
2103                 else // if(team4_score)
2104                         t = FL_TEAM_4;
2105                 CheckAllowedTeams(world);
2106                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2107                 {
2108                         if(t != FL_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(FL_TEAM_1, i, -1000);
2109                         if(t != FL_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(FL_TEAM_2, i, -1000);
2110                         if(t != FL_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(FL_TEAM_3, i, -1000);
2111                         if(t != FL_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(FL_TEAM_4, i, -1000);
2112                 }
2113
2114                 AddWinners(team, t);
2115                 return WINNING_YES;
2116         }
2117         else
2118                 return WINNING_NO;
2119 }
2120
2121 /*
2122 ============
2123 CheckRules_World
2124
2125 Exit deathmatch games upon conditions
2126 ============
2127 */
2128 void ReadyRestart();
2129 void CheckRules_World()
2130 {
2131         float timelimit;
2132         float fraglimit;
2133         float leadlimit;
2134
2135         VoteThink();
2136         MapVote_Think();
2137
2138         SetDefaultAlpha();
2139
2140         /*
2141         MapVote_Think should now do that part
2142         if (intermission_running)
2143                 if (time >= intermission_exittime + 60)
2144                 {
2145                         if(!DoNextMapOverride())
2146                                 GotoNextMap();
2147                         return;
2148                 }
2149         */
2150
2151         if (gameover)   // someone else quit the game already
2152         {
2153                 if(player_count == 0) // Nobody there? Then let's go to the next map
2154                         MapVote_Start();
2155                         // this will actually check the player count in the next frame
2156                         // again, but this shouldn't hurt
2157                 return;
2158         }
2159
2160         timelimit = autocvar_timelimit * 60;
2161         fraglimit = autocvar_fraglimit;
2162         leadlimit = autocvar_leadlimit;
2163
2164         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2165         {
2166                 if(timelimit > 0)
2167                         timelimit = 0; // timelimit is not made for warmup
2168                 if(fraglimit > 0)
2169                         fraglimit = 0; // no fraglimit for now
2170                 leadlimit = 0; // no leadlimit for now
2171         }
2172
2173         if(timelimit > 0)
2174         {
2175                 timelimit += game_starttime;
2176         }
2177         else if (timelimit < 0)
2178         {
2179                 // endmatch
2180                 NextLevel();
2181                 return;
2182         }
2183
2184         if(g_onslaught)
2185                 timelimit = 0; // ONS has its own overtime rule
2186
2187         float wantovertime;
2188         wantovertime = 0;
2189
2190         if(timelimit > game_starttime)
2191                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2192         else
2193                 game_completion_ratio = 0;
2194
2195         if(checkrules_suddendeathend)
2196         {
2197                 if(!checkrules_suddendeathwarning)
2198                 {
2199                         checkrules_suddendeathwarning = TRUE;
2200                         if(g_race && !g_race_qualifying)
2201                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2202                         else
2203                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2204                 }
2205         }
2206         else
2207         {
2208                 if (timelimit && time >= timelimit)
2209                 {
2210                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2211                         {
2212                                 float totalplayers;
2213                                 float playerswithlaps;
2214                                 float readyplayers;
2215                                 entity head;
2216                                 totalplayers = playerswithlaps = readyplayers = 0;
2217                                 FOR_EACH_PLAYER(head)
2218                                 {
2219                                         ++totalplayers;
2220                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2221                                                 ++playerswithlaps;
2222                                         if(head.ready)
2223                                                 ++readyplayers;
2224                                 }
2225
2226                                 // at least 2 of the players have completed a lap: start the RACE
2227                                 // otherwise, the players should end the qualifying on their own
2228                                 if(readyplayers || playerswithlaps >= 2)
2229                                 {
2230                                         checkrules_suddendeathend = 0;
2231                                         ReadyRestart(); // go to race
2232                                         return;
2233                                 }
2234                                 else
2235                                         wantovertime |= InitiateSuddenDeath();
2236                         }
2237                         else
2238                                 wantovertime |= InitiateSuddenDeath();
2239                 }
2240         }
2241
2242         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2243         {
2244                 NextLevel();
2245                 return;
2246         }
2247
2248         float checkrules_status;
2249         checkrules_status = WinningCondition_RanOutOfSpawns();
2250         if(checkrules_status == WINNING_YES)
2251         {
2252                 bprint("Hey! Someone ran out of spawns!\n");
2253         }
2254         else if(g_race && !g_race_qualifying && timelimit >= 0)
2255         {
2256                 checkrules_status = WinningCondition_Race(fraglimit);
2257                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2258         }
2259         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2260         {
2261                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2262                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2263         }
2264         else if(g_assault)
2265         {
2266                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2267         }
2268         else if(g_lms)
2269         {
2270                 checkrules_status = WinningCondition_LMS();
2271         }
2272         else if (g_onslaught)
2273         {
2274                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2275         }
2276         else
2277         {
2278                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2279                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2280         }
2281
2282         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2283         {
2284                 checkrules_status = WINNING_NEVER;
2285                 checkrules_overtimesadded = -1;
2286                 wantovertime |= InitiateSuddenDeath();
2287         }
2288
2289         if(checkrules_status == WINNING_NEVER)
2290                 // equality cases! Nobody wins if the overtime ends in a draw.
2291                 ClearWinners();
2292
2293         if(wantovertime)
2294         {
2295                 if(checkrules_status == WINNING_NEVER)
2296                         InitiateOvertime();
2297                 else
2298                         checkrules_status = WINNING_YES;
2299         }
2300
2301         if(checkrules_suddendeathend)
2302                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2303                         checkrules_status = WINNING_YES;
2304
2305         if(checkrules_status == WINNING_YES)
2306         {
2307                 //print("WINNING\n");
2308                 NextLevel();
2309         }
2310 }
2311
2312 float mapvote_nextthink;
2313 float mapvote_initialized;
2314 float mapvote_keeptwotime;
2315 float mapvote_timeout;
2316 string mapvote_message;
2317 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2318 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2319 float mapvote_screenshot_dirs_count;
2320
2321 float mapvote_count;
2322 float mapvote_count_real;
2323 string mapvote_maps[MAPVOTE_COUNT];
2324 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2325 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2326 float mapvote_maps_suggested[MAPVOTE_COUNT];
2327 string mapvote_suggestions[MAPVOTE_COUNT];
2328 float mapvote_suggestion_ptr;
2329 float mapvote_voters;
2330 float mapvote_selections[MAPVOTE_COUNT];
2331 float mapvote_run;
2332 float mapvote_detail;
2333 float mapvote_abstain;
2334 .float mapvote;
2335
2336 void MapVote_ClearAllVotes()
2337 {
2338         FOR_EACH_CLIENT(other)
2339                 other.mapvote = 0;
2340 }
2341
2342 string MapVote_Suggest(string m)
2343 {
2344         float i;
2345         if(m == "")
2346                 return "That's not how to use this command.";
2347         if(!autocvar_g_maplist_votable_suggestions)
2348                 return "Suggestions are not accepted on this server.";
2349         if(mapvote_initialized)
2350                 return "Can't suggest - voting is already in progress!";
2351         m = MapInfo_FixName(m);
2352         if not(m)
2353                 return "The map you suggested is not available on this server.";
2354         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2355                 if(Map_IsRecent(m))
2356                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2357
2358         if(!MapInfo_CheckMap(m))
2359                 return "The map you suggested does not support the current game mode.";
2360         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2361                 if(mapvote_suggestions[i] == m)
2362                         return "This map was already suggested.";
2363         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2364         {
2365                 i = floor(random() * mapvote_suggestion_ptr);
2366         }
2367         else
2368         {
2369                 i = mapvote_suggestion_ptr;
2370                 mapvote_suggestion_ptr += 1;
2371         }
2372         if(mapvote_suggestions[i] != "")
2373                 strunzone(mapvote_suggestions[i]);
2374         mapvote_suggestions[i] = strzone(m);
2375         if(autocvar_sv_eventlog)
2376                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2377         return strcat("Suggestion of ", m, " accepted.");
2378 }
2379
2380 void MapVote_AddVotable(string nextMap, float isSuggestion)
2381 {
2382         float j, i, o;
2383         string pakfile, mapfile;
2384
2385         if(nextMap == "")
2386                 return;
2387         for(j = 0; j < mapvote_count; ++j)
2388                 if(mapvote_maps[j] == nextMap)
2389                         return;
2390         // suggestions might be no longer valid/allowed after gametype switch!
2391         if(isSuggestion)
2392                 if(!MapInfo_CheckMap(nextMap))
2393                         return;
2394         mapvote_maps[mapvote_count] = strzone(nextMap);
2395         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2396
2397         pakfile = string_null;
2398         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2399         {
2400                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2401                 pakfile = whichpack(strcat(mapfile, ".tga"));
2402                 if(pakfile == "")
2403                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2404                 if(pakfile == "")
2405                         pakfile = whichpack(strcat(mapfile, ".png"));
2406                 if(pakfile != "")
2407                         break;
2408         }
2409         if(i >= mapvote_screenshot_dirs_count)
2410                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2411         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2412                 pakfile = substring(pakfile, o, -1);
2413
2414         mapvote_maps_screenshot_dir[mapvote_count] = i;
2415         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2416
2417         mapvote_count += 1;
2418 }
2419
2420 void MapVote_Spawn();
2421 void MapVote_Init()
2422 {
2423         float i;
2424         float nmax, smax;
2425
2426         MapVote_ClearAllVotes();
2427
2428         mapvote_count = 0;
2429         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2430         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2431
2432         if(mapvote_abstain)
2433                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2434         else
2435                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2436         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2437
2438         // we need this for AddVotable, as that cycles through the screenshot dirs
2439         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2440         if(mapvote_screenshot_dirs_count == 0)
2441                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2442         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2443         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2444                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2445
2446         if(mapvote_suggestion_ptr)
2447                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2448                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2449
2450         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2451                 MapVote_AddVotable(GetNextMap(), FALSE);
2452
2453         if(mapvote_count == 0)
2454         {
2455                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2456                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2457                 if(autocvar_g_maplist_shuffle)
2458                         ShuffleMaplist();
2459                 localcmd("\nmenu_cmd sync\n");
2460                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2461                         MapVote_AddVotable(GetNextMap(), FALSE);
2462         }
2463
2464         mapvote_count_real = mapvote_count;
2465         if(mapvote_abstain)
2466                 MapVote_AddVotable("don't care", 0);
2467
2468         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2469
2470         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2471         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2472         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2473                 mapvote_keeptwotime = 0;
2474         mapvote_message = "Choose a map and press its key!";
2475
2476         MapVote_Spawn();
2477 }
2478
2479 void MapVote_SendPicture(float id)
2480 {
2481         msg_entity = self;
2482         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2483         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2484         WriteByte(MSG_ONE, id);
2485         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2486 }
2487
2488 float MapVote_GetMapMask()
2489 {
2490         float mask, i, power;
2491         mask = 0;
2492         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2493                 if(mapvote_maps[i] != "")
2494                         mask |= power;
2495         return mask;
2496 }
2497
2498 entity mapvote_ent;
2499 float MapVote_SendEntity(entity to, float sf)
2500 {
2501         float i;
2502
2503         if(sf & 1)
2504                 sf &~= 2; // if we send 1, we don't need to also send 2
2505
2506         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2507         WriteByte(MSG_ENTITY, sf);
2508
2509         if(sf & 1)
2510         {
2511                 // flag 1 == initialization
2512                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2513                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2514                 WriteString(MSG_ENTITY, "");
2515                 WriteByte(MSG_ENTITY, mapvote_count);
2516                 WriteByte(MSG_ENTITY, mapvote_abstain);
2517                 WriteByte(MSG_ENTITY, mapvote_detail);
2518                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2519                 if(mapvote_count <= 8)
2520                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2521                 else
2522                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2523                 for(i = 0; i < mapvote_count; ++i)
2524                         if(mapvote_maps[i] != "")
2525                         {
2526                                 if(mapvote_abstain && i == mapvote_count - 1)
2527                                 {
2528                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2529                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2530                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2531                                 }
2532                                 else
2533                                 {
2534                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2535                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2536                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2537                                 }
2538                         }
2539         }
2540
2541         if(sf & 2)
2542         {
2543                 // flag 2 == update of mask
2544                 if(mapvote_count <= 8)
2545                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2546                 else
2547                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2548         }
2549
2550         if(sf & 4)
2551         {
2552                 if(mapvote_detail)
2553                         for(i = 0; i < mapvote_count; ++i)
2554                                 if(mapvote_maps[i] != "")
2555                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2556
2557                 WriteByte(MSG_ENTITY, to.mapvote);
2558         }
2559
2560         return TRUE;
2561 }
2562
2563 void MapVote_Spawn()
2564 {
2565         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2566 }
2567
2568 void MapVote_TouchMask()
2569 {
2570         mapvote_ent.SendFlags |= 2;
2571 }
2572
2573 void MapVote_TouchVotes(entity voter)
2574 {
2575         mapvote_ent.SendFlags |= 4;
2576 }
2577
2578 float MapVote_Finished(float mappos)
2579 {
2580         string result;
2581         float i;
2582         float didntvote;
2583
2584         if(autocvar_sv_eventlog)
2585         {
2586                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2587                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2588                 didntvote = mapvote_voters;
2589                 for(i = 0; i < mapvote_count; ++i)
2590                         if(mapvote_maps[i] != "")
2591                         {
2592                                 didntvote -= mapvote_selections[i];
2593                                 if(i != mappos)
2594                                 {
2595                                         result = strcat(result, ":", mapvote_maps[i]);
2596                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2597                                 }
2598                         }
2599                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2600
2601                 GameLogEcho(result);
2602                 if(mapvote_maps_suggested[mappos])
2603                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2604         }
2605
2606         FOR_EACH_REALCLIENT(other)
2607                 FixClientCvars(other);
2608
2609         Map_Goto_SetStr(mapvote_maps[mappos]);
2610         Map_Goto(0);
2611         alreadychangedlevel = TRUE;
2612         return TRUE;
2613 }
2614 void MapVote_CheckRules_1()
2615 {
2616         float i;
2617
2618         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2619         {
2620                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2621                 mapvote_selections[i] = 0;
2622         }
2623
2624         mapvote_voters = 0;
2625         FOR_EACH_REALCLIENT(other)
2626         {
2627                 ++mapvote_voters;
2628                 if(other.mapvote)
2629                 {
2630                         i = other.mapvote - 1;
2631                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2632                         mapvote_selections[i] = mapvote_selections[i] + 1;
2633                 }
2634         }
2635 }
2636
2637 float MapVote_CheckRules_2()
2638 {
2639         float i;
2640         float firstPlace, secondPlace;
2641         float firstPlaceVotes, secondPlaceVotes;
2642         float mapvote_voters_real;
2643         string result;
2644
2645         if(mapvote_count_real == 1)
2646                 return MapVote_Finished(0);
2647
2648         mapvote_voters_real = mapvote_voters;
2649         if(mapvote_abstain)
2650                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2651
2652         RandomSelection_Init();
2653         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2654                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2655         firstPlace = RandomSelection_chosen_float;
2656         firstPlaceVotes = RandomSelection_best_priority;
2657         //dprint("First place: ", ftos(firstPlace), "\n");
2658         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2659
2660         RandomSelection_Init();
2661         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2662                 if(i != firstPlace)
2663                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2664         secondPlace = RandomSelection_chosen_float;
2665         secondPlaceVotes = RandomSelection_best_priority;
2666         //dprint("Second place: ", ftos(secondPlace), "\n");
2667         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2668
2669         if(firstPlace == -1)
2670                 error("No first place in map vote... WTF?");
2671
2672         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2673                 return MapVote_Finished(firstPlace);
2674
2675         if(mapvote_keeptwotime)
2676                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2677                 {
2678                         float didntvote;
2679                         MapVote_TouchMask();
2680                         mapvote_message = "Now decide between the TOP TWO!";
2681                         mapvote_keeptwotime = 0;
2682                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2683                         result = strcat(result, ":", ftos(firstPlaceVotes));
2684                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2685                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2686                         didntvote = mapvote_voters;
2687                         for(i = 0; i < mapvote_count; ++i)
2688                                 if(mapvote_maps[i] != "")
2689                                 {
2690                                         didntvote -= mapvote_selections[i];
2691                                         if(i != firstPlace)
2692                                                 if(i != secondPlace)
2693                                                 {
2694                                                         result = strcat(result, ":", mapvote_maps[i]);
2695                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2696                                                         if(i < mapvote_count_real)
2697                                                         {
2698                                                                 strunzone(mapvote_maps[i]);
2699                                                                 mapvote_maps[i] = "";
2700                                                                 strunzone(mapvote_maps_pakfile[i]);
2701                                                                 mapvote_maps_pakfile[i] = "";
2702                                                         }
2703                                                 }
2704                                 }
2705                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2706                         if(autocvar_sv_eventlog)
2707                                 GameLogEcho(result);
2708                 }
2709
2710         return FALSE;
2711 }
2712 void MapVote_Tick()
2713 {
2714         float keeptwo;
2715         float totalvotes;
2716
2717         keeptwo = mapvote_keeptwotime;
2718         MapVote_CheckRules_1(); // count
2719         if(MapVote_CheckRules_2()) // decide
2720                 return;
2721
2722         totalvotes = 0;
2723         FOR_EACH_REALCLIENT(other)
2724         {
2725                 // hide scoreboard again
2726                 if(other.health != 2342)
2727                 {
2728                         other.health = 2342;
2729                         other.impulse = 0;
2730                         if(clienttype(other) == CLIENTTYPE_REAL)
2731                         {
2732                                 msg_entity = other;
2733                                 WriteByte(MSG_ONE, SVC_FINALE);
2734                                 WriteString(MSG_ONE, "");
2735                         }
2736                 }
2737
2738                 // clear possibly invalid votes
2739                 if(mapvote_maps[other.mapvote - 1] == "")
2740                         other.mapvote = 0;
2741                 // use impulses as new vote
2742                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2743                         if(mapvote_maps[other.impulse - 1] != "")
2744                         {
2745                                 other.mapvote = other.impulse;
2746                                 MapVote_TouchVotes(other);
2747                         }
2748                 other.impulse = 0;
2749
2750                 if(other.mapvote)
2751                         ++totalvotes;
2752         }
2753
2754         MapVote_CheckRules_1(); // just count
2755 }
2756 void MapVote_Start()
2757 {
2758         if(mapvote_run)
2759                 return;
2760
2761         // wait for stats to be sent first
2762         if(!playerstats_waitforme)
2763                 return;
2764
2765         MapInfo_Enumerate();
2766         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2767                 mapvote_run = TRUE;
2768 }
2769 void MapVote_Think()
2770 {
2771         if(!mapvote_run)
2772                 return;
2773
2774         if(alreadychangedlevel)
2775                 return;
2776
2777         if(time < mapvote_nextthink)
2778                 return;
2779         //dprint("tick\n");
2780
2781         mapvote_nextthink = time + 0.5;
2782
2783         if(!mapvote_initialized)
2784         {
2785                 if(autocvar_rescan_pending == 1)
2786                 {
2787                         cvar_set("rescan_pending", "2");
2788                         localcmd("fs_rescan\nrescan_pending 3\n");
2789                         return;
2790                 }
2791                 else if(autocvar_rescan_pending == 2)
2792                 {
2793                         return;
2794                 }
2795                 else if(autocvar_rescan_pending == 3)
2796                 {
2797                         // now build missing mapinfo files
2798                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2799                                 return;
2800
2801                         // we're done, start the timer
2802                         cvar_set("rescan_pending", "0");
2803                 }
2804
2805                 mapvote_initialized = TRUE;
2806                 if(DoNextMapOverride(0))
2807                         return;
2808                 if(!autocvar_g_maplist_votable || player_count <= 0)
2809                 {
2810                         GotoNextMap(0);
2811                         return;
2812                 }
2813                 MapVote_Init();
2814         }
2815
2816         MapVote_Tick();
2817 }
2818
2819 string GotoMap(string m)
2820 {
2821         if(!MapInfo_CheckMap(m))
2822                 return "The map you chose is not available on this server.";
2823         cvar_set("nextmap", m);
2824         cvar_set("timelimit", "-1");
2825         if(mapvote_initialized || alreadychangedlevel)
2826         {
2827                 if(DoNextMapOverride(0))
2828                         return "Map switch initiated.";
2829                 else
2830                         return "Hm... no. For some reason I like THIS map more.";
2831         }
2832         else
2833                 return "Map switch will happen after scoreboard.";
2834 }
2835
2836
2837 void EndFrame()
2838 {
2839         float altime;
2840         FOR_EACH_REALCLIENT(self)
2841         {
2842                 if(self.classname == "spectator")
2843                 {
2844                         if(self.enemy.typehitsound)
2845                                 self.typehit_time = time;
2846                         else if(self.enemy.hitsound)
2847                                 self.hit_time = time;
2848                 }
2849                 else
2850                 {
2851                         if(self.typehitsound)
2852                                 self.typehit_time = time;
2853                         else if(self.hitsound)
2854                                 self.hit_time = time;
2855                 }
2856         }
2857         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2858         // add 1 frametime because after this, engine SV_Physics
2859         // increases time by a frametime and then networks the frame
2860         // add another frametime because client shows everything with
2861         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2862         // needed!
2863         FOR_EACH_CLIENT(self)
2864         {
2865                 self.hitsound = FALSE;
2866                 self.typehitsound = FALSE;
2867                 antilag_record(self, altime);
2868         }
2869 }
2870
2871
2872 /*
2873  * RedirectionThink:
2874  * returns TRUE if redirecting
2875  */
2876 float redirection_timeout;
2877 float redirection_nextthink;
2878 float RedirectionThink()
2879 {
2880         float clients_found;
2881
2882         if(redirection_target == "")
2883                 return FALSE;
2884
2885         if(!redirection_timeout)
2886         {
2887                 cvar_set("sv_public", "-2");
2888                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2889                 if(redirection_target == "self")
2890                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2891                 else
2892                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2893         }
2894
2895         if(time < redirection_nextthink)
2896                 return TRUE;
2897
2898         redirection_nextthink = time + 1;
2899
2900         clients_found = 0;
2901         FOR_EACH_REALCLIENT(self)
2902         {
2903                 // TODO add timer
2904                 print("Redirecting: sending connect command to ", self.netname, "\n");
2905                 if(redirection_target == "self")
2906                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2907                 else
2908                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2909                 ++clients_found;
2910         }
2911
2912         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2913
2914         if(time > redirection_timeout || clients_found == 0)
2915                 localcmd("\nwait; wait; wait; quit\n");
2916
2917         return TRUE;
2918 }
2919
2920 void TargetMusic_RestoreGame();
2921 void RestoreGame()
2922 {
2923         // Loaded from a save game
2924         // some things then break, so let's work around them...
2925
2926         // Progs DB (capture records)
2927         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2928
2929         // Mapinfo
2930         MapInfo_Shutdown();
2931         MapInfo_Enumerate();
2932         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2933         WeaponStats_Init();
2934
2935         TargetMusic_RestoreGame();
2936 }
2937
2938 void Shutdown()
2939 {
2940         entity e;
2941
2942         gameover = 2;
2943
2944         if(world_initialized > 0)
2945         {
2946                 world_initialized = 0;
2947                 print("Saving persistent data...\n");
2948                 Ban_SaveBans();
2949
2950                 PlayerStats_EndMatch(0);
2951                 FOR_EACH_CLIENT(e)
2952                         PlayerStats_AddGlobalInfo(e);
2953                 PlayerStats_Shutdown();
2954
2955                 if(!cheatcount_total)
2956                 {
2957                         if(autocvar_sv_db_saveasdump)
2958                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2959                         else
2960                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2961                 }
2962                 if(autocvar_developer)
2963                 {
2964                         if(autocvar_sv_db_saveasdump)
2965                                 db_dump(TemporaryDB, "server-temp.db");
2966                         else
2967                                 db_save(TemporaryDB, "server-temp.db");
2968                 }
2969                 CheatShutdown(); // must be after cheatcount check
2970                 db_close(ServerProgsDB);
2971                 db_close(TemporaryDB);
2972                 print("done!\n");
2973                 // tell the bot system the game is ending now
2974                 bot_endgame();
2975
2976                 WeaponStats_Shutdown();
2977                 MapInfo_Shutdown();
2978         }
2979         else if(world_initialized == 0)
2980         {
2981                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2982         }
2983 }