qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include <common/net_linked.qh>
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/_mod.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications/all.qh"
  29 #include "../common/physics/player.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/_mod.qh"
  37 #include <common/weapons/_all.qh>
  38 #include "../common/state.qh"
  39
  40 const float LATENCY_THINKRATE = 10;
  41 .float latency_sum;
  42 .float latency_cnt;
  43 .float latency_time;
  44 entity pingplreport;
  45 void PingPLReport_Think(entity this)
  46 {
  47         float delta;
  48         entity e;
  49
  50         delta = 3 / maxclients;
  51         if(delta < sys_frametime)
  52                 delta = 0;
  53         this.nextthink = time + delta;
  54
  55         e = edict_num(this.cnt + 1);
  56         if(IS_REAL_CLIENT(e))
  57         {
  58                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  59                 WriteByte(MSG_BROADCAST, this.cnt);
  60                 WriteShort(MSG_BROADCAST, bound(1, e.ping, 65535));
  61                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_packetloss * 255), 255));
  62                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_movementloss * 255), 255));
  63
  64                 // record latency times for clients throughout the match so we can report it to playerstats
  65                 if(time > (e.latency_time + LATENCY_THINKRATE))
  66                 {
  67                         e.latency_sum += e.ping;
  68                         e.latency_cnt += 1;
  69                         e.latency_time = time;
  70                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  71                 }
  72         }
  73         else
  74         {
  75                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, this.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         this.cnt = (this.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = new_pure(pingplreport);
  86         setthink(pingplreport, PingPLReport_Think);
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap(entity this)
 109 {
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 this.nextthink = time;
 134         }
 135         else
 136         {
 137                 this.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("g_maplist_index");
 180                 BADCVAR("halflifebsp");
 181                 BADCVAR("sv_mapformat_is_quake2");
 182                 BADCVAR("sv_mapformat_is_quake3");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_voice_flood_");
 237                 BADPREFIX("log_file");
 238                 BADPREFIX("rcon_");
 239                 BADPREFIX("sv_allowdownloads");
 240                 BADPREFIX("sv_autodemo");
 241                 BADPREFIX("sv_curl_");
 242                 BADPREFIX("sv_eventlog");
 243                 BADPREFIX("sv_logscores_");
 244                 BADPREFIX("sv_master");
 245                 BADPREFIX("sv_weaponstats_");
 246                 BADPREFIX("sv_waypointsprite_");
 247                 BADCVAR("rescan_pending");
 248
 249                 // these can contain player IDs, so better hide
 250                 BADPREFIX("g_forced_team_");
 251
 252                 // mapinfo
 253                 BADCVAR("fraglimit");
 254                 BADCVAR("g_assault");
 255                 BADCVAR("g_ca");
 256                 BADCVAR("g_ca_teams");
 257                 BADCVAR("g_ctf");
 258                 BADCVAR("g_cts");
 259                 BADCVAR("g_dm");
 260                 BADCVAR("g_domination");
 261                 BADCVAR("g_domination_default_teams");
 262                 BADCVAR("g_freezetag");
 263                 BADCVAR("g_freezetag_teams");
 264                 BADCVAR("g_invasion_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_laps_limit");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_race_qualifying_timelimit_override");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing gameplay relevant
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("gameversion");
 308                 BADCVAR("g_allow_oldvortexbeam");
 309                 BADCVAR("g_balance_kill_delay");
 310                 BADCVAR("g_campcheck_distance");
 311                 BADCVAR("g_ca_point_leadlimit");
 312                 BADCVAR("g_ca_point_limit");
 313                 BADCVAR("g_ctf_captimerecord_always");
 314                 BADCVAR("g_ctf_flag_glowtrails");
 315                 BADCVAR("g_ctf_flag_pickup_verbosename");
 316                 BADCVAR("g_domination_point_leadlimit");
 317                 BADCVAR("g_forced_respawn");
 318                 BADCVAR("g_freezetag_point_leadlimit");
 319                 BADCVAR("g_freezetag_point_limit");
 320                 BADCVAR("g_hats");
 321                 BADCVAR("g_invasion_point_limit");
 322                 BADCVAR("g_keyhunt_point_leadlimit");
 323                 BADCVAR("g_nexball_goalleadlimit");
 324                 BADCVAR("g_new_toys_use_pickupsound");
 325                 BADCVAR("g_physics_predictall");
 326                 BADCVAR("g_piggyback");
 327                 BADCVAR("g_tdm_point_leadlimit");
 328                 BADCVAR("g_tdm_point_limit");
 329                 BADCVAR("leadlimit_and_fraglimit");
 330                 BADCVAR("leadlimit_override");
 331                 BADCVAR("pausable");
 332                 BADCVAR("sv_checkforpacketsduringsleep");
 333                 BADCVAR("sv_intermission_cdtrack");
 334                 BADCVAR("sv_minigames");
 335                 BADCVAR("sv_namechangetimer");
 336                 BADCVAR("sv_precacheplayermodels");
 337                 BADCVAR("sv_stepheight");
 338                 BADCVAR("sv_timeout");
 339                 BADPREFIX("crypto_");
 340                 BADPREFIX("gameversion_");
 341                 BADPREFIX("g_chat_");
 342                 BADPREFIX("g_ctf_captimerecord_");
 343                 BADPREFIX("g_maplist_votable_");
 344                 BADPREFIX("g_mod_");
 345                 BADPREFIX("g_respawn_");
 346                 BADPREFIX("net_");
 347                 BADPREFIX("prvm_");
 348                 BADPREFIX("skill_");
 349                 BADPREFIX("sv_allow_");
 350                 BADPREFIX("sv_cullentities_");
 351                 BADPREFIX("sv_maxidle_");
 352                 BADPREFIX("sv_minigames_");
 353                 BADPREFIX("sv_radio_");
 354                 BADPREFIX("sv_timeout_");
 355                 BADPREFIX("sv_vote_");
 356                 BADPREFIX("timelimit_");
 357
 358                 // allowed changes to server admins (please sync this to server.cfg)
 359                 // vi commands:
 360                 //   :/"impure"/,$d
 361                 //   :g!,^\/\/[^ /],d
 362                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 363                 //   :%!sort
 364                 // yes, this does contain some redundant stuff, don't really care
 365                 BADCVAR("bot_config_file");
 366                 BADCVAR("bot_number");
 367                 BADCVAR("bot_prefix");
 368                 BADCVAR("bot_suffix");
 369                 BADCVAR("capturelimit_override");
 370                 BADCVAR("fraglimit_override");
 371                 BADCVAR("gametype");
 372                 BADCVAR("g_antilag");
 373                 BADCVAR("g_balance_teams");
 374                 BADCVAR("g_balance_teams_prevent_imbalance");
 375                 BADCVAR("g_balance_teams_scorefactor");
 376                 BADCVAR("g_ban_sync_trusted_servers");
 377                 BADCVAR("g_ban_sync_uri");
 378                 BADCVAR("g_buffs");
 379                 BADCVAR("g_ca_teams_override");
 380                 BADCVAR("g_ctf_ignore_frags");
 381                 BADCVAR("g_domination_point_limit");
 382                 BADCVAR("g_domination_teams_override");
 383                 BADCVAR("g_freezetag_teams_override");
 384                 BADCVAR("g_friendlyfire");
 385                 BADCVAR("g_fullbrightitems");
 386                 BADCVAR("g_fullbrightplayers");
 387                 BADCVAR("g_keyhunt_point_limit");
 388                 BADCVAR("g_keyhunt_teams_override");
 389                 BADCVAR("g_lms_lives_override");
 390                 BADCVAR("g_maplist");
 391                 BADCVAR("g_maplist_check_waypoints");
 392                 BADCVAR("g_maplist_mostrecent_count");
 393                 BADCVAR("g_maplist_shuffle");
 394                 BADCVAR("g_maplist_votable");
 395                 BADCVAR("g_maplist_votable_abstain");
 396                 BADCVAR("g_maplist_votable_nodetail");
 397                 BADCVAR("g_maplist_votable_suggestions");
 398                 BADCVAR("g_maxplayers");
 399                 BADCVAR("g_mirrordamage");
 400                 BADCVAR("g_nexball_goallimit");
 401                 BADCVAR("g_norecoil");
 402                 BADCVAR("g_physics_clientselect");
 403                 BADCVAR("g_powerups");
 404                 BADCVAR("g_spawnshieldtime");
 405                 BADCVAR("g_start_delay");
 406                 BADCVAR("g_superspectate");
 407                 BADCVAR("g_tdm_teams_override");
 408                 BADCVAR("g_warmup");
 409                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 410                 BADCVAR("hostname");
 411                 BADCVAR("log_file");
 412                 BADCVAR("maxplayers");
 413                 BADCVAR("minplayers");
 414                 BADCVAR("net_address");
 415                 BADCVAR("port");
 416                 BADCVAR("rcon_password");
 417                 BADCVAR("rcon_restricted_commands");
 418                 BADCVAR("rcon_restricted_password");
 419                 BADCVAR("skill");
 420                 BADCVAR("sv_adminnick");
 421                 BADCVAR("sv_autoscreenshot");
 422                 BADCVAR("sv_autotaunt");
 423                 BADCVAR("sv_curl_defaulturl");
 424                 BADCVAR("sv_defaultcharacter");
 425                 BADCVAR("sv_defaultcharacterskin");
 426                 BADCVAR("sv_defaultplayercolors");
 427                 BADCVAR("sv_defaultplayermodel");
 428                 BADCVAR("sv_defaultplayerskin");
 429                 BADCVAR("sv_maxidle");
 430                 BADCVAR("sv_maxrate");
 431                 BADCVAR("sv_motd");
 432                 BADCVAR("sv_public");
 433                 BADCVAR("sv_ready_restart");
 434                 BADCVAR("sv_status_privacy");
 435                 BADCVAR("sv_taunt");
 436                 BADCVAR("sv_vote_call");
 437                 BADCVAR("sv_vote_commands");
 438                 BADCVAR("sv_vote_majority_factor");
 439                 BADCVAR("sv_vote_master");
 440                 BADCVAR("sv_vote_master_commands");
 441                 BADCVAR("sv_vote_master_password");
 442                 BADCVAR("sv_vote_simple_majority_factor");
 443                 BADCVAR("teamplay_mode");
 444                 BADCVAR("timelimit_override");
 445                 BADPREFIX("g_warmup_");
 446                 BADPREFIX("sv_ready_restart_");
 447
 448                 // mutators that announce themselves properly to the server browser
 449                 BADCVAR("g_instagib");
 450                 BADCVAR("g_new_toys");
 451                 BADCVAR("g_nix");
 452                 BADCVAR("g_grappling_hook");
 453                 BADCVAR("g_jetpack");
 454
 455 #undef BADPRESUFFIX
 456 #undef BADPREFIX
 457 #undef BADCVAR
 458
 459                 if(pureadding)
 460                 {
 461                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 462                         if(strlen(cvar_purechanges) > 16384)
 463                         {
 464                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 465                                 pureadding = 0;
 466                         }
 467                 }
 468                 ++cvar_purechanges_count;
 469                 // WARNING: this variable is used for the server list
 470                 // NEVER dare to skip this code!
 471                 // Hacks to intentionally appearing as "pure server" even though you DO have
 472                 // modified settings may be punished by removal from the server list.
 473                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 474                 // though.
 475         }
 476         buf_del(h);
 477         if(cvar_changes == "")
 478                 cvar_changes = "// this server runs at default server settings\n";
 479         else
 480                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 481         cvar_changes = strzone(cvar_changes);
 482         if(cvar_purechanges == "")
 483                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 484         else
 485                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 486         cvar_purechanges = strzone(cvar_purechanges);
 487 }
 488
 489 void detect_maptype()
 490 {
 491 #if 0
 492         vector o, v;
 493         float i;
 494
 495         for (;;)
 496         {
 497                 o = world.mins;
 498                 o.x += random() * (world.maxs.x - world.mins.x);
 499                 o.y += random() * (world.maxs.y - world.mins.y);
 500                 o.z += random() * (world.maxs.z - world.mins.z);
 501
 502                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 503                 if(trace_fraction == 1)
 504                         continue;
 505
 506                 v = trace_endpos;
 507
 508                 for(i = 0; i < 64; i += 4)
 509                 {
 510                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 511         if(trace_fraction == 1)
 512                 continue;
 513                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 514                 }
 515
 516                 break;
 517         }
 518 #endif
 519 }
 520
 521 entity randomseed;
 522 bool RandomSeed_Send(entity this, entity to, int sf)
 523 {
 524         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 525         WriteShort(MSG_ENTITY, this.cnt);
 526         return true;
 527 }
 528 void RandomSeed_Think(entity this)
 529 {
 530         this.cnt = bound(0, floor(random() * 65536), 65535);
 531         this.nextthink = time + 5;
 532
 533         this.SendFlags |= 1;
 534 }
 535 void RandomSeed_Spawn()
 536 {
 537         randomseed = new_pure(randomseed);
 538         setthink(randomseed, RandomSeed_Think);
 539         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 540
 541         getthink(randomseed)(randomseed); // sets random seed and nextthink
 542 }
 543
 544 spawnfunc(__init_dedicated_server)
 545 {
 546         // handler for _init/_init map (only for dedicated server initialization)
 547
 548         world_initialized = -1; // don't complain
 549         cvar = cvar_normal;
 550         cvar_string = cvar_string_normal;
 551         cvar_set = cvar_set_normal;
 552
 553         delete_fn = remove_unsafely;
 554
 555         entity e = spawn();
 556         setthink(e, GotoFirstMap);
 557         e.nextthink = time; // this is usually 1 at this point
 558
 559         e = new(info_player_deathmatch);  // safeguard against player joining
 560
 561         this.classname = "worldspawn"; // safeguard against various stuff ;)
 562
 563         // needs to be done so early because of the constants they create
 564         static_init();
 565         static_init_late();
 566         static_init_precache();
 567
 568         IL_PUSH(g_spawnpoints, e); // just incase
 569
 570         MapInfo_Enumerate();
 571         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 572 }
 573
 574 void __init_dedicated_server_shutdown() {
 575         MapInfo_Shutdown();
 576 }
 577
 578 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override)
 579 {
 580         if(!autocvar_g_campaign)
 581         {
 582                 if(fraglimit_override >= 0) cvar_set("fraglimit", ftos(fraglimit_override));
 583                 if(timelimit_override >= 0) cvar_set("timelimit", ftos(timelimit_override));
 584                 if(leadlimit_override >= 0) cvar_set("leadlimit", ftos(leadlimit_override));
 585                 if(qualifying_override >= 0) cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 586         }
 587         limits_are_set = true;
 588 }
 589
 590 void Map_MarkAsRecent(string m);
 591 float world_already_spawned;
 592 void Nagger_Init();
 593 void ClientInit_Spawn();
 594 void WeaponStats_Init();
 595 void WeaponStats_Shutdown();
 596 spawnfunc(worldspawn)
 597 {
 598         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 599
 600     bool wantrestart = false;
 601         {
 602                 if (!server_is_dedicated)
 603                 {
 604                         // force unloading of server pk3 files when starting a listen server
 605                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 606                         // restore csqc_progname too
 607                         string expect = "csprogs.dat";
 608                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 609                         cvar_set_normal("csqc_progname", expect);
 610                 }
 611                 else
 612                 {
 613                         // Try to use versioned csprogs from pk3
 614                         // Only ever use versioned csprogs.dat files on dedicated servers;
 615                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 616                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 617                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 618                         string select = "csprogs.dat";
 619                         if (fexists(pk3csprogs)) select = pk3csprogs;
 620                         if (cvar_string_normal("csqc_progname") != select)
 621                         {
 622                                 cvar_set_normal("csqc_progname", select);
 623                                 wantrestart = true;
 624                         }
 625                         // Check for updates on startup
 626                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 627                         int sentinel = fopen("progs.txt", FILE_READ);
 628                         if (sentinel >= 0)
 629                         {
 630                                 string switchversion = fgets(sentinel);
 631                                 fclose(sentinel);
 632                                 if (switchversion != "" && switchversion != WATERMARK)
 633                                 {
 634                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 635                                         // if it doesn't exist, assume either:
 636                                         //   a) the current program was overwritten
 637                                         //   b) this is a client only update
 638                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 639                                         if (fexists(newprogs))
 640                                         {
 641                                                 cvar_set_normal("sv_progs", newprogs);
 642                                                 wantrestart = true;
 643                                         }
 644                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 645                                         if (fexists(newcsprogs))
 646                                         {
 647                                                 cvar_set_normal("csqc_progname", newcsprogs);
 648                                                 wantrestart = true;
 649                                         }
 650                                 }
 651                         }
 652                 }
 653                 if (wantrestart)
 654                 {
 655                         LOG_INFOF("Restart requested\n");
 656                         changelevel(mapname);
 657                         // let initialization continue, shutdown depends on it
 658                 }
 659         }
 660
 661         cvar = cvar_normal;
 662         cvar_string = cvar_string_normal;
 663         cvar_set = cvar_set_normal;
 664
 665         if(world_already_spawned)
 666                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 667         world_already_spawned = true;
 668
 669         delete_fn = remove_safely; // during spawning, watch what you remove!
 670
 671         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 672
 673         maxclients = 0;
 674         for (entity head = nextent(NULL); head; head = nextent(head))
 675         {
 676                 ++maxclients;
 677         }
 678
 679         // needs to be done so early because of the constants they create
 680         static_init();
 681
 682         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 683
 684         TemporaryDB = db_create();
 685
 686         // 0 normal
 687         lightstyle(0, "m");
 688
 689         // 1 FLICKER (first variety)
 690         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 691
 692         // 2 SLOW STRONG PULSE
 693         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 694
 695         // 3 CANDLE (first variety)
 696         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 697
 698         // 4 FAST STROBE
 699         lightstyle(4, "mamamamamama");
 700
 701         // 5 GENTLE PULSE 1
 702         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 703
 704         // 6 FLICKER (second variety)
 705         lightstyle(6, "nmonqnmomnmomomno");
 706
 707         // 7 CANDLE (second variety)
 708         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 709
 710         // 8 CANDLE (third variety)
 711         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 712
 713         // 9 SLOW STROBE (fourth variety)
 714         lightstyle(9, "aaaaaaaazzzzzzzz");
 715
 716         // 10 FLUORESCENT FLICKER
 717         lightstyle(10, "mmamammmmammamamaaamammma");
 718
 719         // 11 SLOW PULSE NOT FADE TO BLACK
 720         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 721
 722         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 723
 724         // 63 testing
 725         lightstyle(63, "a");
 726
 727         if(autocvar_g_campaign)
 728                 CampaignPreInit();
 729
 730         Map_MarkAsRecent(mapname);
 731
 732         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 733
 734         InitGameplayMode();
 735         static_init_late();
 736         static_init_precache();
 737         readlevelcvars();
 738         GrappleHookInit();
 739
 740         if(!limits_are_set)
 741                 SetLimits(autocvar_fraglimit_override, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
 742
 743         if(warmup_limit == 0)
 744                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 745
 746         player_count = 0;
 747         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 748         if(bot_waypoints_for_items == 1)
 749                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 750                         bot_waypoints_for_items = 0;
 751
 752         precache();
 753
 754         WaypointSprite_Init();
 755
 756         GameLogInit(); // prepare everything
 757         // NOTE for matchid:
 758         // changing the logic generating it is okay. But:
 759         // it HAS to stay <= 64 chars
 760         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 761         if(autocvar_sv_eventlog)
 762         {
 763                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 764                 matchid = strzone(s);
 765
 766                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 767                 s = ":gameinfo:mutators:LIST";
 768
 769                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 770                 s = M_ARGV(0, string);
 771
 772                 // initialiation stuff, not good in the mutator system
 773                 if(!autocvar_g_use_ammunition)
 774                         s = strcat(s, ":no_use_ammunition");
 775
 776                 // initialiation stuff, not good in the mutator system
 777                 if(autocvar_g_pickup_items == 0)
 778                         s = strcat(s, ":no_pickup_items");
 779                 if(autocvar_g_pickup_items > 0)
 780                         s = strcat(s, ":pickup_items");
 781
 782                 // initialiation stuff, not good in the mutator system
 783                 if(autocvar_g_weaponarena != "0")
 784                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 785
 786                 // TODO to mutator system
 787                 if(autocvar_g_norecoil)
 788                         s = strcat(s, ":norecoil");
 789
 790                 // TODO to mutator system
 791                 if(autocvar_g_powerups == 0)
 792                         s = strcat(s, ":no_powerups");
 793                 if(autocvar_g_powerups > 0)
 794                         s = strcat(s, ":powerups");
 795
 796                 GameLogEcho(s);
 797                 GameLogEcho(":gameinfo:end");
 798         }
 799         else
 800                 matchid = strzone(ftos(random()));
 801
 802         cvar_set("nextmap", "");
 803
 804         SetDefaultAlpha();
 805
 806         if(autocvar_g_campaign)
 807                 CampaignPostInit();
 808
 809         Ban_LoadBans();
 810
 811         MapInfo_Enumerate();
 812         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 813
 814         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 815         {
 816                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 817                 if(fd != -1)
 818                 {
 819                         string s;
 820                         while((s = fgets(fd)))
 821                         {
 822                                 int l = tokenize_console(s);
 823                                 if(l < 2)
 824                                         continue;
 825                                 if(argv(0) == "cd")
 826                                 {
 827                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 828                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 829                                 }
 830                                 else if(argv(0) == "fog")
 831                                 {
 832                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 833                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 834                                 }
 835                                 else if(argv(0) == "set")
 836                                 {
 837                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 838                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 839                                 }
 840                                 else if(argv(0) != "//")
 841                                 {
 842                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 843                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 844                                 }
 845                         }
 846                         fclose(fd);
 847                 }
 848         }
 849
 850         WeaponStats_Init();
 851
 852         Nagger_Init();
 853
 854         next_pingtime = time + 5;
 855
 856         detect_maptype();
 857
 858         // set up information replies for clients and server to use
 859         maplist_reply = strzone(getmaplist());
 860         lsmaps_reply = strzone(getlsmaps());
 861         monsterlist_reply = strzone(getmonsterlist());
 862         for(int i = 0; i < 10; ++i)
 863         {
 864                 string s = getrecords(i);
 865                 if (s)
 866                         records_reply[i] = strzone(s);
 867         }
 868         ladder_reply = strzone(getladder());
 869         rankings_reply = strzone(getrankings());
 870
 871         // begin other init
 872         ClientInit_Spawn();
 873         RandomSeed_Spawn();
 874         PingPLReport_Spawn();
 875
 876         CheatInit();
 877
 878         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 879
 880         // fill sv_curl_serverpackages from .serverpackage files
 881         if (autocvar_sv_curl_serverpackages_auto)
 882         {
 883                 string s = "csprogs-" WATERMARK ".txt";
 884                 // remove automatically managed files from the list to prevent duplicates
 885                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 886                 {
 887                         string pkg = argv(i);
 888                         if (startsWith(pkg, "csprogs-")) continue;
 889                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 890                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 891                         s = cons(s, pkg);
 892                 }
 893                 // add automatically managed files to the list
 894                 #define X(match) MACRO_BEGIN { \
 895                         int fd = search_begin(match, true, false); \
 896                         if (fd >= 0) \
 897                         { \
 898                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 899                                 { \
 900                                         s = cons(s, search_getfilename(fd, i)); \
 901                                 } \
 902                                 search_end(fd); \
 903                         } \
 904                 } MACRO_END
 905                 X("*-serverpackage.txt");
 906                 X("*.serverpackage");
 907                 #undef X
 908                 cvar_set("sv_curl_serverpackages", s);
 909         }
 910
 911         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 912         modname = "Xonotic";
 913         // physics/balance/config changes that count as mod
 914         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 915                 modname = cvar_string("g_mod_physics");
 916         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 917                 modname = cvar_string("g_mod_balance");
 918         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 919                 modname = cvar_string("g_mod_config");
 920         // extra mutators that deserve to count as mod
 921         MUTATOR_CALLHOOK(SetModname, modname);
 922         modname = M_ARGV(0, string);
 923
 924         // save it for later
 925         modname = strzone(modname);
 926
 927         WinningConditionHelper(this); // set worldstatus
 928
 929         world_initialized = 1;
 930 }
 931
 932 spawnfunc(light)
 933 {
 934         //makestatic (this); // Who the f___ did that?
 935         delete(this);
 936 }
 937
 938 string GetGametype()
 939 {
 940         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 941 }
 942
 943 string GetMapname()
 944 {
 945         return mapname;
 946 }
 947
 948 float Map_Count, Map_Current;
 949 string Map_Current_Name;
 950
 951 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 952 float GetMaplistPosition()
 953 {
 954         float pos, idx;
 955         string map;
 956
 957         map = GetMapname();
 958         idx = autocvar_g_maplist_index;
 959
 960         if(idx >= 0)
 961                 if(idx < Map_Count)
 962                         if(map == argv(idx))
 963                                 return idx;
 964
 965         for(pos = 0; pos < Map_Count; ++pos)
 966                 if(map == argv(pos))
 967                         return pos;
 968
 969         // resume normal maplist rotation if current map is not in g_maplist
 970         return idx;
 971 }
 972
 973 float MapHasRightSize(string map)
 974 {
 975         float fh;
 976         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 977         if(autocvar_g_maplist_check_waypoints)
 978         {
 979                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 980                 if(!fexists(strcat("maps/", map, ".waypoints")))
 981                 {
 982                         LOG_TRACE(": no waypoints");
 983                         return false;
 984                 }
 985                 LOG_TRACE(": has waypoints");
 986         }
 987
 988         // open map size restriction file
 989         LOG_TRACE("opensize "); LOG_TRACE(map);
 990         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 991         if(fh >= 0)
 992         {
 993                 float mapmin, mapmax;
 994                 LOG_TRACE(": ok, ");
 995                 mapmin = stof(fgets(fh));
 996                 mapmax = stof(fgets(fh));
 997                 fclose(fh);
 998                 if(player_count < mapmin)
 999                 {
1000                         LOG_TRACE("not enough");
1001                         return false;
1002                 }
1003                 if(player_count > mapmax)
1004                 {
1005                         LOG_TRACE("too many");
1006                         return false;
1007                 }
1008                 LOG_TRACE("right size");
1009                 return true;
1010         }
1011         LOG_TRACE(": not found");
1012         return true;
1013 }
1014
1015 string Map_Filename(float position)
1016 {
1017         return strcat("maps/", argv(position), ".bsp");
1018 }
1019
1020 void Map_MarkAsRecent(string m)
1021 {
1022         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1023 }
1024
1025 float Map_IsRecent(string m)
1026 {
1027         return strhasword(autocvar_g_maplist_mostrecent, m);
1028 }
1029
1030 float Map_Check(float position, float pass)
1031 {
1032         string filename;
1033         string map_next;
1034         map_next = argv(position);
1035         if(pass <= 1)
1036         {
1037                 if(Map_IsRecent(map_next))
1038                         return 0;
1039         }
1040         filename = Map_Filename(position);
1041         if(MapInfo_CheckMap(map_next))
1042         {
1043                 if(pass == 2)
1044                         return 1;
1045                 if(MapHasRightSize(map_next))
1046                         return 1;
1047                 return 0;
1048         }
1049         else
1050                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1051
1052         return 0;
1053 }
1054
1055 void Map_Goto_SetStr(string nextmapname)
1056 {
1057         if(getmapname_stored != "")
1058                 strunzone(getmapname_stored);
1059         if(nextmapname == "")
1060                 getmapname_stored = "";
1061         else
1062                 getmapname_stored = strzone(nextmapname);
1063 }
1064
1065 void Map_Goto_SetFloat(float position)
1066 {
1067         cvar_set("g_maplist_index", ftos(position));
1068         Map_Goto_SetStr(argv(position));
1069 }
1070
1071 void Map_Goto(float reinit)
1072 {
1073         MapInfo_LoadMap(getmapname_stored, reinit);
1074 }
1075
1076 // return codes of map selectors:
1077 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1078 //   -2 = permanent failure
1079 float() MaplistMethod_Iterate = // usual method
1080 {
1081         float pass, i;
1082
1083         LOG_TRACE("Trying MaplistMethod_Iterate");
1084
1085         for(pass = 1; pass <= 2; ++pass)
1086         {
1087                 for(i = 1; i < Map_Count; ++i)
1088                 {
1089                         float mapindex;
1090                         mapindex = (i + Map_Current) % Map_Count;
1091                         if(Map_Check(mapindex, pass))
1092                                 return mapindex;
1093                 }
1094         }
1095         return -1;
1096 }
1097
1098 float() MaplistMethod_Repeat = // fallback method
1099 {
1100         LOG_TRACE("Trying MaplistMethod_Repeat");
1101
1102         if(Map_Check(Map_Current, 2))
1103                 return Map_Current;
1104         return -2;
1105 }
1106
1107 float() MaplistMethod_Random = // random map selection
1108 {
1109         float i, imax;
1110
1111         LOG_TRACE("Trying MaplistMethod_Random");
1112
1113         imax = 42;
1114
1115         for(i = 0; i <= imax; ++i)
1116         {
1117                 float mapindex;
1118                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1119                 if(Map_Check(mapindex, 1))
1120                         return mapindex;
1121         }
1122         return -1;
1123 }
1124
1125 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1126 // the exponent sets a bias on the map selection:
1127 // the higher the exponent, the less likely "shortly repeated" same maps are
1128 {
1129         float i, j, imax, insertpos;
1130
1131         LOG_TRACE("Trying MaplistMethod_Shuffle");
1132
1133         imax = 42;
1134
1135         for(i = 0; i <= imax; ++i)
1136         {
1137                 string newlist;
1138
1139                 // now reinsert this at another position
1140                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1141                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1142                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1143                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1144
1145                 // insert the current map there
1146                 newlist = "";
1147                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1148                         newlist = strcat(newlist, " ", argv(j));
1149                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1150                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1151                         newlist = strcat(newlist, " ", argv(j));
1152                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1153                 cvar_set("g_maplist", newlist);
1154                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1155
1156                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1157                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1158                 if(Map_Check(Map_Current, 1))
1159                         return Map_Current;
1160         }
1161         return -1;
1162 }
1163
1164 void Maplist_Init()
1165 {
1166         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1167         float i;
1168         for (i = 0; i < Map_Count; ++i)
1169                 if (Map_Check(i, 2))
1170                         break;
1171         if (i == Map_Count)
1172         {
1173                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1174                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1175                 if(autocvar_g_maplist_shuffle)
1176                         ShuffleMaplist();
1177                 localcmd("\nmenu_cmd sync\n");
1178                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1179         }
1180         if(Map_Count == 0)
1181                 error("empty maplist, cannot select a new map");
1182         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1183
1184         if(Map_Current_Name)
1185                 strunzone(Map_Current_Name);
1186         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1187         // this may or may not be correct, but who cares, in the worst case a map
1188         // isn't chosen in the first pass that should have been
1189 }
1190
1191 string GetNextMap()
1192 {
1193         float nextMap;
1194
1195         Maplist_Init();
1196         nextMap = -1;
1197
1198         if(nextMap == -1)
1199                 if(autocvar_g_maplist_shuffle > 0)
1200                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1201
1202         if(nextMap == -1)
1203                 if(autocvar_g_maplist_selectrandom)
1204                         nextMap = MaplistMethod_Random();
1205
1206         if(nextMap == -1)
1207                 nextMap = MaplistMethod_Iterate();
1208
1209         if(nextMap == -1)
1210                 nextMap = MaplistMethod_Repeat();
1211
1212         if(nextMap >= 0)
1213         {
1214                 Map_Goto_SetFloat(nextMap);
1215                 return getmapname_stored;
1216         }
1217
1218         return "";
1219 }
1220
1221 float DoNextMapOverride(float reinit)
1222 {
1223         if(autocvar_g_campaign)
1224         {
1225                 CampaignPostIntermission();
1226                 alreadychangedlevel = true;
1227                 return true;
1228         }
1229         if(autocvar_quit_when_empty)
1230         {
1231                 if(player_count <= currentbots)
1232                 {
1233                         localcmd("quit\n");
1234                         alreadychangedlevel = true;
1235                         return true;
1236                 }
1237         }
1238         if(autocvar_quit_and_redirect != "")
1239         {
1240                 redirection_target = strzone(autocvar_quit_and_redirect);
1241                 alreadychangedlevel = true;
1242                 return true;
1243         }
1244         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1245         {
1246                 localcmd("restart\n");
1247                 alreadychangedlevel = true;
1248                 return true;
1249         }
1250         if(autocvar_nextmap != "")
1251         {
1252                 string m;
1253                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1254                 cvar_set("nextmap",m);
1255
1256                 if(!m || gametypevote)
1257                         return false;
1258                 if(autocvar_sv_vote_gametype)
1259                 {
1260                         Map_Goto_SetStr(m);
1261                         return false;
1262                 }
1263
1264                 if(MapInfo_CheckMap(m))
1265                 {
1266                         Map_Goto_SetStr(m);
1267                         Map_Goto(reinit);
1268                         alreadychangedlevel = true;
1269                         return true;
1270                 }
1271         }
1272         if(!reinit && autocvar_lastlevel)
1273         {
1274                 cvar_settemp_restore();
1275                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1276                 alreadychangedlevel = true;
1277                 return true;
1278         }
1279         return false;
1280 }
1281
1282 void GotoNextMap(float reinit)
1283 {
1284         //string nextmap;
1285         //float n, nummaps;
1286         //string s;
1287         if (alreadychangedlevel)
1288                 return;
1289         alreadychangedlevel = true;
1290
1291         string nextMap;
1292
1293         nextMap = GetNextMap();
1294         if(nextMap == "")
1295                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1296         Map_Goto(reinit);
1297 }
1298
1299
1300 /*
1301 ============
1302 IntermissionThink
1303
1304 When the player presses attack or jump, change to the next level
1305 ============
1306 */
1307 .float autoscreenshot;
1308 void IntermissionThink(entity this)
1309 {
1310         FixIntermissionClient(this);
1311
1312         float server_screenshot = (autocvar_sv_autoscreenshot && this.cvar_cl_autoscreenshot);
1313         float client_screenshot = (this.cvar_cl_autoscreenshot == 2);
1314
1315         if( (server_screenshot || client_screenshot)
1316                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1317         {
1318                 this.autoscreenshot = -1;
1319                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1320                 return;
1321         }
1322
1323         if (time < intermission_exittime)
1324                 return;
1325
1326         if(!mapvote_initialized)
1327                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1328                         return;
1329
1330         MapVote_Start();
1331 }
1332
1333 /*
1334 ============
1335 FindIntermission
1336
1337 Returns the entity to view from
1338 ============
1339 */
1340 /*
1341 entity FindIntermission()
1342 {
1343         local   entity spot;
1344         local   float cyc;
1345
1346 // look for info_intermission first
1347         spot = find(NULL, classname, "info_intermission");
1348         if (spot)
1349         {       // pick a random one
1350                 cyc = random() * 4;
1351                 while (cyc > 1)
1352                 {
1353                         spot = find(spot, classname, "info_intermission");
1354                         if (!spot)
1355                                 spot = find(spot, classname, "info_intermission");
1356                         cyc = cyc - 1;
1357                 }
1358                 return spot;
1359         }
1360
1361 // then look for the start position
1362         spot = find(NULL, classname, "info_player_start");
1363         if (spot)
1364                 return spot;
1365
1366 // testinfo_player_start is only found in regioned levels
1367         spot = find(NULL, classname, "testplayerstart");
1368         if (spot)
1369                 return spot;
1370
1371 // then look for the start position
1372         spot = find(NULL, classname, "info_player_deathmatch");
1373         if (spot)
1374                 return spot;
1375
1376         //objerror ("FindIntermission: no spot");
1377         return NULL;
1378 }
1379 */
1380
1381 /*
1382 ===============================================================================
1383
1384 RULES
1385
1386 ===============================================================================
1387 */
1388
1389 void DumpStats(float final)
1390 {
1391         float file;
1392         string s;
1393         float to_console;
1394         float to_eventlog;
1395         float to_file;
1396         float i;
1397
1398         to_console = autocvar_sv_logscores_console;
1399         to_eventlog = autocvar_sv_eventlog;
1400         to_file = autocvar_sv_logscores_file;
1401
1402         if(!final)
1403         {
1404                 to_console = true; // always print printstats replies
1405                 to_eventlog = false; // but never print them to the event log
1406         }
1407
1408         if(to_eventlog)
1409                 if(autocvar_sv_eventlog_console)
1410                         to_console = false; // otherwise we get the output twice
1411
1412         if(final)
1413                 s = ":scores:";
1414         else
1415                 s = ":status:";
1416         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1417
1418         if(to_console)
1419                 LOG_INFO(s, "\n");
1420         if(to_eventlog)
1421                 GameLogEcho(s);
1422
1423         file = -1;
1424         if(to_file)
1425         {
1426                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1427                 if(file == -1)
1428                         to_file = false;
1429                 else
1430                         fputs(file, strcat(s, "\n"));
1431         }
1432
1433         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1434         if(to_console)
1435                 LOG_INFO(s, "\n");
1436         if(to_eventlog)
1437                 GameLogEcho(s);
1438         if(to_file)
1439                 fputs(file, strcat(s, "\n"));
1440
1441         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1442                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1443                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1444                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1445                         s = strcat(s, ftos(it.team), ":");
1446                 else
1447                         s = strcat(s, "spectator:");
1448
1449                 if(to_console)
1450                         LOG_INFO(s, it.netname, "\n");
1451                 if(to_eventlog)
1452                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1453                 if(to_file)
1454                         fputs(file, strcat(s, it.netname, "\n"));
1455         ));
1456
1457         if(teamplay)
1458         {
1459                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1460                 if(to_console)
1461                         LOG_INFO(s, "\n");
1462                 if(to_eventlog)
1463                         GameLogEcho(s);
1464                 if(to_file)
1465                         fputs(file, strcat(s, "\n"));
1466
1467                 for(i = 1; i < 16; ++i)
1468                 {
1469                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1470                         s = strcat(s, ":", ftos(i));
1471                         if(to_console)
1472                                 LOG_INFO(s, "\n");
1473                         if(to_eventlog)
1474                                 GameLogEcho(s);
1475                         if(to_file)
1476                                 fputs(file, strcat(s, "\n"));
1477                 }
1478         }
1479
1480         if(to_console)
1481                 LOG_INFO(":end\n");
1482         if(to_eventlog)
1483                 GameLogEcho(":end");
1484         if(to_file)
1485         {
1486                 fputs(file, ":end\n");
1487                 fclose(file);
1488         }
1489 }
1490
1491 void FixIntermissionClient(entity e)
1492 {
1493         if(!e.autoscreenshot) // initial call
1494         {
1495                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1496                 e.health = -2342;
1497                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1498                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1499                 {
1500                     .entity weaponentity = weaponentities[slot];
1501                         if(e.(weaponentity))
1502                         {
1503                                 e.(weaponentity).effects = EF_NODRAW;
1504                                 if (e.(weaponentity).weaponchild)
1505                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1506                         }
1507                 }
1508                 if(IS_REAL_CLIENT(e))
1509                 {
1510                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1511                         RandomSelection_Init();
1512                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1513                                 RandomSelection_AddString(it, 1, 1);
1514                         ));
1515                         if (RandomSelection_chosen_string != "")
1516                         {
1517                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1518                         }
1519                         msg_entity = e;
1520                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1521                 }
1522         }
1523 }
1524
1525 /*
1526 go to the next level for deathmatch
1527 only called if a time or frag limit has expired
1528 */
1529 void NextLevel()
1530 {
1531         gameover = true;
1532
1533         intermission_running = 1;
1534
1535         // enforce a wait time before allowing changelevel
1536         if(player_count > 0)
1537                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1538         else
1539                 intermission_exittime = -1;
1540
1541         /*
1542         WriteByte (MSG_ALL, SVC_CDTRACK);
1543         WriteByte (MSG_ALL, 3);
1544         WriteByte (MSG_ALL, 3);
1545         // done in FixIntermission
1546         */
1547
1548         //pos = FindIntermission ();
1549
1550         VoteReset();
1551
1552         DumpStats(true);
1553
1554         // send statistics
1555         PlayerStats_GameReport(true);
1556         WeaponStats_Shutdown();
1557
1558         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1559
1560         if(autocvar_sv_eventlog)
1561                 GameLogEcho(":gameover");
1562
1563         GameLogClose();
1564
1565         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1566                 FixIntermissionClient(it);
1567                 if(it.winning)
1568                         bprint(it.netname, " ^7wins.\n");
1569         ));
1570
1571         target_music_kill();
1572
1573         if(autocvar_g_campaign)
1574                 CampaignPreIntermission();
1575
1576         MUTATOR_CALLHOOK(MatchEnd);
1577
1578         localcmd("\nsv_hook_gameend\n");
1579 }
1580
1581 /*
1582 ============
1583 CheckRules_Player
1584
1585 Exit deathmatch games upon conditions
1586 ============
1587 */
1588 void CheckRules_Player(entity this)
1589 {
1590         if (gameover)   // someone else quit the game already
1591                 return;
1592
1593         if(!IS_DEAD(this))
1594                 this.play_time += frametime;
1595
1596         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1597         //   (div0: and that in CheckRules_World please)
1598 }
1599
1600
1601 float InitiateSuddenDeath()
1602 {
1603         // Check first whether normal overtimes could be added before initiating suddendeath mode
1604         // - for this timelimit_overtime needs to be >0 of course
1605         // - also check the winning condition calculated in the previous frame and only add normal overtime
1606         //   again, if at the point at which timelimit would be extended again, still no winner was found
1607         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1608         {
1609                 return 1; // need to call InitiateOvertime later
1610         }
1611         else
1612         {
1613                 if(!checkrules_suddendeathend)
1614                 {
1615                         if(autocvar_g_campaign)
1616                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1617                         else
1618                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1619                         if(g_race && !g_race_qualifying)
1620                                 race_StartCompleting();
1621                 }
1622                 return 0;
1623         }
1624 }
1625
1626 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1627 {
1628         ++checkrules_overtimesadded;
1629         //add one more overtime by simply extending the timelimit
1630         float tl;
1631         tl = autocvar_timelimit;
1632         tl += autocvar_timelimit_overtime;
1633         cvar_set("timelimit", ftos(tl));
1634
1635         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1636 }
1637
1638 float GetWinningCode(float fraglimitreached, float equality)
1639 {
1640         if(autocvar_g_campaign == 1)
1641                 if(fraglimitreached)
1642                         return WINNING_YES;
1643                 else
1644                         return WINNING_NO;
1645
1646         else
1647                 if(equality)
1648                         if(fraglimitreached)
1649                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1650                         else
1651                                 return WINNING_NEVER;
1652                 else
1653                         if(fraglimitreached)
1654                                 return WINNING_YES;
1655                         else
1656                                 return WINNING_NO;
1657 }
1658
1659 // set the .winning flag for exactly those players with a given field value
1660 void SetWinners(.float field, float value)
1661 {
1662         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1663 }
1664
1665 // set the .winning flag for those players with a given field value
1666 void AddWinners(.float field, float value)
1667 {
1668         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1669                 if(it.(field) == value)
1670                         it.winning = 1;
1671         ));
1672 }
1673
1674 // clear the .winning flags
1675 void ClearWinners()
1676 {
1677         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1678 }
1679
1680 void ShuffleMaplist()
1681 {
1682         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1683 }
1684
1685 float leaderfrags;
1686 float WinningCondition_Scores(float limit, float leadlimit)
1687 {
1688         float limitreached;
1689
1690         // TODO make everything use THIS winning condition (except LMS)
1691         WinningConditionHelper(NULL);
1692
1693         if(teamplay)
1694         {
1695                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1696                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1697                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1698                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1699         }
1700
1701         ClearWinners();
1702         if(WinningConditionHelper_winner)
1703                 WinningConditionHelper_winner.winning = 1;
1704         if(WinningConditionHelper_winnerteam >= 0)
1705                 SetWinners(team, WinningConditionHelper_winnerteam);
1706
1707         if(WinningConditionHelper_lowerisbetter)
1708         {
1709                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1710                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1711                 limit = -limit;
1712         }
1713
1714         if(WinningConditionHelper_zeroisworst)
1715                 leadlimit = 0; // not supported in this mode
1716
1717         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1718         // these modes always score in increments of 1, thus this makes sense
1719         {
1720                 if(leaderfrags != WinningConditionHelper_topscore)
1721                 {
1722                         leaderfrags = WinningConditionHelper_topscore;
1723
1724                         if (limit)
1725                         if (leaderfrags == limit - 1)
1726                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1727                         else if (leaderfrags == limit - 2)
1728                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1729                         else if (leaderfrags == limit - 3)
1730                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1731                 }
1732         }
1733
1734         limitreached = false;
1735         if(limit)
1736                 if(WinningConditionHelper_topscore >= limit)
1737                         limitreached = true;
1738         if(leadlimit)
1739         {
1740                 float leadlimitreached;
1741                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1742                 if(autocvar_leadlimit_and_fraglimit)
1743                         limitreached = (limitreached && leadlimitreached);
1744                 else
1745                         limitreached = (limitreached || leadlimitreached);
1746         }
1747
1748         if(limit)
1749                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1750
1751         return GetWinningCode(
1752                 WinningConditionHelper_topscore && limitreached,
1753                 WinningConditionHelper_equality
1754         );
1755 }
1756
1757 float WinningCondition_RanOutOfSpawns()
1758 {
1759         if(have_team_spawns <= 0)
1760                 return WINNING_NO;
1761
1762         if(!autocvar_g_spawn_useallspawns)
1763                 return WINNING_NO;
1764
1765         if(!some_spawn_has_been_used)
1766                 return WINNING_NO;
1767
1768         team1_score = team2_score = team3_score = team4_score = 0;
1769
1770         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1771                 switch(it.team)
1772                 {
1773                         case NUM_TEAM_1: team1_score = 1; break;
1774                         case NUM_TEAM_2: team2_score = 1; break;
1775                         case NUM_TEAM_3: team3_score = 1; break;
1776                         case NUM_TEAM_4: team4_score = 1; break;
1777                 }
1778         ));
1779
1780         IL_EACH(g_spawnpoints, true,
1781         {
1782                 switch(it.team)
1783                 {
1784                         case NUM_TEAM_1: team1_score = 1; break;
1785                         case NUM_TEAM_2: team2_score = 1; break;
1786                         case NUM_TEAM_3: team3_score = 1; break;
1787                         case NUM_TEAM_4: team4_score = 1; break;
1788                 }
1789         });
1790
1791         ClearWinners();
1792         if(team1_score + team2_score + team3_score + team4_score == 0)
1793         {
1794                 checkrules_equality = true;
1795                 return WINNING_YES;
1796         }
1797         else if(team1_score + team2_score + team3_score + team4_score == 1)
1798         {
1799                 float t, i;
1800                 if(team1_score)
1801                         t = NUM_TEAM_1;
1802                 else if(team2_score)
1803                         t = NUM_TEAM_2;
1804                 else if(team3_score)
1805                         t = NUM_TEAM_3;
1806                 else // if(team4_score)
1807                         t = NUM_TEAM_4;
1808                 CheckAllowedTeams(NULL);
1809                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1810                 {
1811                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1812                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1813                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1814                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1815                 }
1816
1817                 AddWinners(team, t);
1818                 return WINNING_YES;
1819         }
1820         else
1821                 return WINNING_NO;
1822 }
1823
1824 /*
1825 ============
1826 CheckRules_World
1827
1828 Exit deathmatch games upon conditions
1829 ============
1830 */
1831 void CheckRules_World()
1832 {
1833         float timelimit;
1834         float fraglimit;
1835         float leadlimit;
1836
1837         VoteThink();
1838         MapVote_Think();
1839
1840         SetDefaultAlpha();
1841
1842         if (intermission_running) // someone else quit the game already
1843         {
1844                 if(player_count == 0) // Nobody there? Then let's go to the next map
1845                         MapVote_Start();
1846                         // this will actually check the player count in the next frame
1847                         // again, but this shouldn't hurt
1848                 return;
1849         }
1850
1851         timelimit = autocvar_timelimit * 60;
1852         fraglimit = autocvar_fraglimit;
1853         leadlimit = autocvar_leadlimit;
1854
1855         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1856         {
1857                 if(timelimit > 0)
1858                         timelimit = 0; // timelimit is not made for warmup
1859                 if(fraglimit > 0)
1860                         fraglimit = 0; // no fraglimit for now
1861                 leadlimit = 0; // no leadlimit for now
1862         }
1863
1864         if(timelimit > 0)
1865         {
1866                 timelimit += game_starttime;
1867         }
1868         else if (timelimit < 0)
1869         {
1870                 // endmatch
1871                 NextLevel();
1872                 return;
1873         }
1874
1875         float wantovertime;
1876         wantovertime = 0;
1877
1878         if(timelimit > game_starttime)
1879                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1880         else
1881                 game_completion_ratio = 0;
1882
1883         if(checkrules_suddendeathend)
1884         {
1885                 if(!checkrules_suddendeathwarning)
1886                 {
1887                         checkrules_suddendeathwarning = true;
1888                         if(g_race && !g_race_qualifying)
1889                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1890                         else
1891                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1892                 }
1893         }
1894         else
1895         {
1896                 if (timelimit && time >= timelimit)
1897                 {
1898                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1899                         {
1900                                 float totalplayers;
1901                                 float playerswithlaps;
1902                                 float readyplayers;
1903                                 totalplayers = playerswithlaps = readyplayers = 0;
1904                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1905                                         ++totalplayers;
1906                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1907                                                 ++playerswithlaps;
1908                                         if(it.ready)
1909                                                 ++readyplayers;
1910                                 ));
1911
1912                                 // at least 2 of the players have completed a lap: start the RACE
1913                                 // otherwise, the players should end the qualifying on their own
1914                                 if(readyplayers || playerswithlaps >= 2)
1915                                 {
1916                                         checkrules_suddendeathend = 0;
1917                                         ReadyRestart(); // go to race
1918                                         return;
1919                                 }
1920                                 else
1921                                         wantovertime |= InitiateSuddenDeath();
1922                         }
1923                         else
1924                                 wantovertime |= InitiateSuddenDeath();
1925                 }
1926         }
1927
1928         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1929         {
1930                 NextLevel();
1931                 return;
1932         }
1933
1934         int checkrules_status = WinningCondition_RanOutOfSpawns();
1935         if(checkrules_status == WINNING_YES)
1936                 bprint("Hey! Someone ran out of spawns!\n");
1937         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1938                 checkrules_status = M_ARGV(0, float);
1939         else
1940                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1941
1942         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1943         {
1944                 checkrules_status = WINNING_NEVER;
1945                 checkrules_overtimesadded = -1;
1946                 wantovertime |= InitiateSuddenDeath();
1947         }
1948
1949         if(checkrules_status == WINNING_NEVER)
1950                 // equality cases! Nobody wins if the overtime ends in a draw.
1951                 ClearWinners();
1952
1953         if(wantovertime)
1954         {
1955                 if(checkrules_status == WINNING_NEVER)
1956                         InitiateOvertime();
1957                 else
1958                         checkrules_status = WINNING_YES;
1959         }
1960
1961         if(checkrules_suddendeathend)
1962                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1963                         checkrules_status = WINNING_YES;
1964
1965         if(checkrules_status == WINNING_YES)
1966         {
1967                 //print("WINNING\n");
1968                 NextLevel();
1969         }
1970 }
1971
1972 string GotoMap(string m)
1973 {
1974         m = GameTypeVote_MapInfo_FixName(m);
1975         if (!m)
1976                 return "The map you suggested is not available on this server.";
1977         if (!autocvar_sv_vote_gametype)
1978         if(!MapInfo_CheckMap(m))
1979                 return "The map you suggested does not support the current game mode.";
1980         cvar_set("nextmap", m);
1981         cvar_set("timelimit", "-1");
1982         if(mapvote_initialized || alreadychangedlevel)
1983         {
1984                 if(DoNextMapOverride(0))
1985                         return "Map switch initiated.";
1986                 else
1987                         return "Hm... no. For some reason I like THIS map more.";
1988         }
1989         else
1990                 return "Map switch will happen after scoreboard.";
1991 }
1992
1993 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1994 void RunThink(entity this)
1995 {
1996         // don't let things stay in the past.
1997         // it is possible to start that way by a trigger with a local time.
1998         if(this.nextthink <= 0 || this.nextthink > time + frametime)
1999                 return;
2000
2001         float oldtime = time; // do we need to save this?
2002
2003         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2004         {
2005                 time = max(oldtime, this.nextthink);
2006                 this.nextthink = 0;
2007
2008                 if(getthink(this))
2009                         getthink(this)(this);
2010                 // mods often set nextthink to time to cause a think every frame,
2011                 // we don't want to loop in that case, so exit if the new nextthink is
2012                 // <= the time the qc was told, also exit if it is past the end of the
2013                 // frame
2014                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2015                         break;
2016         }
2017
2018         time = oldtime;
2019 }
2020
2021 bool autocvar_sv_freezenonclients;
2022 bool autocvar_sv_gameplayfix_delayprojectiles;
2023 void Physics_Frame()
2024 {
2025         if(autocvar_sv_freezenonclients)
2026                 return;
2027
2028         FOREACH_ENTITY_FLOAT(pure_data, false,
2029         {
2030                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2031                         continue;
2032
2033                 set_movetype(it, it.move_movetype);
2034
2035                 if(it.move_movetype == MOVETYPE_NONE)
2036                         continue;
2037
2038                 if(it.move_qcphysics)
2039                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2040
2041                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2042                 {
2043                         // handle thinking here
2044                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2045                                 RunThink(it);
2046                 }
2047         });
2048
2049         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2050                 return;
2051
2052         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2053         {
2054                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2055                         continue;
2056                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2057         });
2058 }
2059
2060 void systems_update();
2061 void EndFrame()
2062 {
2063         anticheat_endframe();
2064
2065         Physics_Frame();
2066
2067         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2068                 entity e = IS_SPEC(it) ? it.enemy : it;
2069                 if (e.typehitsound) {
2070                         it.typehit_time = time;
2071                 } else if (e.damage_dealt) {
2072                         it.hit_time = time;
2073                         it.damage_dealt_total += ceil(e.damage_dealt);
2074                 }
2075         });
2076         // add 1 frametime because after this, engine SV_Physics
2077         // increases time by a frametime and then networks the frame
2078         // add another frametime because client shows everything with
2079         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2080         // needed!
2081         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2082         FOREACH_CLIENT(true, {
2083                 it.typehitsound = false;
2084                 it.damage_dealt = 0;
2085                 antilag_record(it, CS(it), altime);
2086         });
2087         IL_EACH(g_monsters, true,
2088         {
2089                 antilag_record(it, it, altime);
2090         });
2091         systems_update();
2092         IL_ENDFRAME();
2093 }
2094
2095
2096 /*
2097  * RedirectionThink:
2098  * returns true if redirecting
2099  */
2100 float redirection_timeout;
2101 float redirection_nextthink;
2102 float RedirectionThink()
2103 {
2104         float clients_found;
2105
2106         if(redirection_target == "")
2107                 return false;
2108
2109         if(!redirection_timeout)
2110         {
2111                 cvar_set("sv_public", "-2");
2112                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2113                 if(redirection_target == "self")
2114                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2115                 else
2116                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2117         }
2118
2119         if(time < redirection_nextthink)
2120                 return true;
2121
2122         redirection_nextthink = time + 1;
2123
2124         clients_found = 0;
2125         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2126                 // TODO add timer
2127                 LOG_INFO("Redirecting: sending connect command to ", it.netname, "\n");
2128                 if(redirection_target == "self")
2129                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2130                 else
2131                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2132                 ++clients_found;
2133         ));
2134
2135         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2136
2137         if(time > redirection_timeout || clients_found == 0)
2138                 localcmd("\nwait; wait; wait; quit\n");
2139
2140         return true;
2141 }
2142
2143 void TargetMusic_RestoreGame();
2144 void RestoreGame()
2145 {
2146         // Loaded from a save game
2147         // some things then break, so let's work around them...
2148
2149         // Progs DB (capture records)
2150         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2151
2152         // Mapinfo
2153         MapInfo_Shutdown();
2154         MapInfo_Enumerate();
2155         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2156         WeaponStats_Init();
2157
2158         TargetMusic_RestoreGame();
2159 }
2160
2161 void Shutdown()
2162 {
2163         gameover = 2;
2164
2165         if(world_initialized > 0)
2166         {
2167                 world_initialized = 0;
2168                 LOG_TRACE("Saving persistent data...");
2169                 Ban_SaveBans();
2170
2171                 // playerstats with unfinished match
2172                 PlayerStats_GameReport(false);
2173
2174                 if(!cheatcount_total)
2175                 {
2176                         if(autocvar_sv_db_saveasdump)
2177                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2178                         else
2179                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2180                 }
2181                 if(autocvar_developer)
2182                 {
2183                         if(autocvar_sv_db_saveasdump)
2184                                 db_dump(TemporaryDB, "server-temp.db");
2185                         else
2186                                 db_save(TemporaryDB, "server-temp.db");
2187                 }
2188                 CheatShutdown(); // must be after cheatcount check
2189                 db_close(ServerProgsDB);
2190                 db_close(TemporaryDB);
2191                 LOG_TRACE("Saving persistent data... done!");
2192                 // tell the bot system the game is ending now
2193                 bot_endgame();
2194
2195                 WeaponStats_Shutdown();
2196                 MapInfo_Shutdown();
2197         }
2198         else if(world_initialized == 0)
2199         {
2200                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2201         }
2202         else
2203         {
2204                 __init_dedicated_server_shutdown();
2205         }
2206 }