qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312                 BADCVAR("rescan_pending");
 313
 314                 // these can contain player IDs, so better hide
 315                 BADPREFIX("g_forced_team_");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_allow_fullbright");
 387                 BADCVAR("sv_checkforpacketsduringsleep");
 388                 BADCVAR("sv_timeout");
 389                 BADCVAR("welcome_message_time");
 390                 BADPREFIX("crypto_");
 391                 BADPREFIX("g_chat_");
 392                 BADPREFIX("g_ctf_captimerecord_");
 393                 BADPREFIX("g_maplist_votable_");
 394                 BADPREFIX("net_");
 395                 BADPREFIX("prvm_");
 396                 BADPREFIX("skill_");
 397                 BADPREFIX("sv_cullentities_");
 398                 BADPREFIX("sv_fraginfo_");
 399                 BADPREFIX("sv_maxidle_");
 400                 BADPREFIX("sv_vote_");
 401                 BADPREFIX("timelimit_");
 402                 BADCVAR("gameversion");
 403                 BADPREFIX("gameversion_");
 404                 BADCVAR("sv_namechangetimer");
 405
 406                 // allowed changes to server admins (please sync this to server.cfg)
 407                 // vi commands:
 408                 //   :/"impure"/,$d
 409                 //   :g!,^\/\/[^ /],d
 410                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 411                 //   :%!sort
 412                 // yes, this does contain some redundant stuff, don't really care
 413                 BADCVAR("bot_config_file");
 414                 BADCVAR("bot_number");
 415                 BADCVAR("bot_prefix");
 416                 BADCVAR("bot_suffix");
 417                 BADCVAR("capturelimit_override");
 418                 BADCVAR("fraglimit_override");
 419                 BADCVAR("gametype");
 420                 BADCVAR("g_antilag");
 421                 BADCVAR("g_balance_teams");
 422                 BADCVAR("g_balance_teams_force");
 423                 BADCVAR("g_ban_sync_trusted_servers");
 424                 BADCVAR("g_ban_sync_uri");
 425                 BADCVAR("g_ctf_capture_limit");
 426                 BADCVAR("g_ctf_ignore_frags");
 427                 BADCVAR("g_ctf_win_mode");
 428                 BADCVAR("g_domination_point_limit");
 429                 BADCVAR("g_friendlyfire");
 430                 BADCVAR("g_fullbrightitems");
 431                 BADCVAR("g_fullbrightplayers");
 432                 BADCVAR("g_keyhunt_point_limit");
 433                 BADCVAR("g_keyhunt_teams_override");
 434                 BADCVAR("g_lms_lives_override");
 435                 BADCVAR("g_maplist");
 436                 BADCVAR("g_maplist_check_waypoints");
 437                 BADCVAR("g_maplist_mostrecent_count");
 438                 BADCVAR("g_maplist_shuffle");
 439                 BADCVAR("g_maplist_votable");
 440                 BADCVAR("g_maplist_votable_abstain");
 441                 BADCVAR("g_maplist_votable_nodetail");
 442                 BADCVAR("g_maplist_votable_suggestions");
 443                 BADCVAR("g_maxplayers");
 444                 BADCVAR("g_minstagib");
 445                 BADCVAR("g_mirrordamage");
 446                 BADCVAR("g_nexball_goallimit");
 447                 BADCVAR("g_runematch_point_limit");
 448                 BADCVAR("g_start_delay");
 449                 BADCVAR("g_warmup");
 450                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 451                 BADCVAR("hostname");
 452                 BADCVAR("log_file");
 453                 BADCVAR("maxplayers");
 454                 BADCVAR("minplayers");
 455                 BADCVAR("net_address");
 456                 BADCVAR("port");
 457                 BADCVAR("rcon_password");
 458                 BADCVAR("rcon_restricted_commands");
 459                 BADCVAR("rcon_restricted_password");
 460                 BADCVAR("skill");
 461                 BADCVAR("sv_adminnick");
 462                 BADCVAR("sv_autoscreenshot");
 463                 BADCVAR("sv_autotaunt");
 464                 BADCVAR("sv_curl_defaulturl");
 465                 BADCVAR("sv_defaultcharacter");
 466                 BADCVAR("sv_defaultplayercolors");
 467                 BADCVAR("sv_defaultplayermodel");
 468                 BADCVAR("sv_defaultplayerskin");
 469                 BADCVAR("sv_maxidle");
 470                 BADCVAR("sv_maxrate");
 471                 BADCVAR("sv_motd");
 472                 BADCVAR("sv_public");
 473                 BADCVAR("sv_ready_restart");
 474                 BADCVAR("sv_status_privacy");
 475                 BADCVAR("sv_taunt");
 476                 BADCVAR("sv_vote_call");
 477                 BADCVAR("sv_vote_commands");
 478                 BADCVAR("sv_vote_majority_factor");
 479                 BADCVAR("sv_vote_master");
 480                 BADCVAR("sv_vote_master_commands");
 481                 BADCVAR("sv_vote_master_password");
 482                 BADCVAR("sv_vote_simple_majority_factor");
 483                 BADCVAR("sys_ticrate");
 484                 BADCVAR("teamplay_mode");
 485                 BADCVAR("timelimit_override");
 486                 BADPREFIX("g_powerup_");
 487                 BADPREFIX("g_warmup_");
 488                 BADPREFIX("sv_ready_restart_");
 489
 490                 if(autocvar_g_minstagib)
 491                 {
 492                         BADCVAR("g_grappling_hook");
 493                         BADCVAR("g_jetpack");
 494                 }
 495 #undef BADPREFIX
 496 #undef BADCVAR
 497
 498                 if(pureadding)
 499                 {
 500                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 501                         if(strlen(cvar_purechanges) > 16384)
 502                         {
 503                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 504                                 pureadding = 0;
 505                         }
 506                 }
 507                 ++cvar_purechanges_count;
 508                 // WARNING: this variable is used for the server list
 509                 // NEVER dare to skip this code!
 510                 // Hacks to intentionally appearing as "pure server" even though you DO have
 511                 // modified settings may be punished by removal from the server list.
 512                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 513                 // though.
 514         }
 515         buf_del(h);
 516         if(cvar_changes == "")
 517                 cvar_changes = "// this server runs at default server settings\n";
 518         else
 519                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 520         cvar_changes = strzone(cvar_changes);
 521         if(cvar_purechanges == "")
 522                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 523         else
 524                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 525         cvar_purechanges = strzone(cvar_purechanges);
 526 }
 527
 528 void detect_maptype()
 529 {
 530 #if 0
 531         vector o, v;
 532         float i;
 533
 534         for(;;)
 535         {
 536                 o = world.mins;
 537                 o_x += random() * (world.maxs_x - world.mins_x);
 538                 o_y += random() * (world.maxs_y - world.mins_y);
 539                 o_z += random() * (world.maxs_z - world.mins_z);
 540
 541                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 542                 if(trace_fraction == 1)
 543                         continue;
 544
 545                 v = trace_endpos;
 546
 547                 for(i = 0; i < 64; i += 4)
 548                 {
 549                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 550         if(trace_fraction == 1)
 551                 continue;
 552                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 553                 }
 554
 555                 break;
 556         }
 557 #endif
 558 }
 559
 560 entity randomseed;
 561 float RandomSeed_Send(entity to, float sf)
 562 {
 563         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 564         WriteShort(MSG_ENTITY, self.cnt);
 565         return TRUE;
 566 }
 567 void RandomSeed_Think()
 568 {
 569         self.cnt = bound(0, floor(random() * 65536), 65535);
 570         self.nextthink = time + 5;
 571
 572         self.SendFlags |= 1;
 573 }
 574 void RandomSeed_Spawn()
 575 {
 576         randomseed = spawn();
 577         randomseed.think = RandomSeed_Think;
 578         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 579
 580         entity oldself;
 581         oldself = self;
 582         self = randomseed;
 583         self.think(); // sets random seed and nextthink
 584         self = oldself;
 585 }
 586
 587 void spawnfunc___init_dedicated_server(void)
 588 {
 589         // handler for _init/_init map (only for dedicated server initialization)
 590
 591         world_initialized = -1; // don't complain
 592         cvar = cvar_normal;
 593         cvar_string = cvar_string_normal;
 594         cvar_set = cvar_set_normal;
 595
 596         remove = remove_unsafely;
 597
 598         entity e;
 599         e = spawn();
 600         e.think = GotoFirstMap;
 601         e.nextthink = time; // this is usually 1 at this point
 602
 603         e = spawn();
 604         e.classname = "info_player_deathmatch"; // safeguard against player joining
 605
 606         self.classname = "worldspawn"; // safeguard against various stuff ;)
 607
 608         MapInfo_Enumerate();
 609         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 610 }
 611
 612 void Map_MarkAsRecent(string m);
 613 float world_already_spawned;
 614 void RegisterWeapons();
 615 void Nagger_Init();
 616 void ClientInit_Spawn();
 617 void WeaponStats_Init();
 618 void WeaponStats_Shutdown();
 619 void spawnfunc_worldspawn (void)
 620 {
 621         float fd, l, i, j, n;
 622         string s, col;
 623
 624         cvar = cvar_normal;
 625         cvar_string = cvar_string_normal;
 626         cvar_set = cvar_set_normal;
 627
 628         if(world_already_spawned)
 629                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 630         world_already_spawned = TRUE;
 631
 632         remove = remove_safely; // during spawning, watch what you remove!
 633
 634         check_unacceptable_compiler_bugs();
 635
 636         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 637
 638         compressShortVector_init();
 639
 640         allowed_to_spawn = TRUE;
 641
 642         entity head;
 643         head = nextent(world);
 644         maxclients = 0;
 645         while(head)
 646         {
 647                 ++maxclients;
 648                 head = nextent(head);
 649         }
 650
 651         // needs to be done so early as they would still spawn
 652         RegisterWeapons();
 653
 654         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 655
 656         TemporaryDB = db_create();
 657
 658         // 0 normal
 659         lightstyle(0, "m");
 660
 661         // 1 FLICKER (first variety)
 662         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 663
 664         // 2 SLOW STRONG PULSE
 665         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 666
 667         // 3 CANDLE (first variety)
 668         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 669
 670         // 4 FAST STROBE
 671         lightstyle(4, "mamamamamama");
 672
 673         // 5 GENTLE PULSE 1
 674         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 675
 676         // 6 FLICKER (second variety)
 677         lightstyle(6, "nmonqnmomnmomomno");
 678
 679         // 7 CANDLE (second variety)
 680         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 681
 682         // 8 CANDLE (third variety)
 683         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 684
 685         // 9 SLOW STROBE (fourth variety)
 686         lightstyle(9, "aaaaaaaazzzzzzzz");
 687
 688         // 10 FLUORESCENT FLICKER
 689         lightstyle(10, "mmamammmmammamamaaamammma");
 690
 691         // 11 SLOW PULSE NOT FADE TO BLACK
 692         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 693
 694         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 695
 696         // 63 testing
 697         lightstyle(63, "a");
 698
 699         if(autocvar_g_campaign)
 700                 CampaignPreInit();
 701
 702         Map_MarkAsRecent(mapname);
 703
 704         precache_model ("null"); // we need this one before InitGameplayMode
 705         InitGameplayMode();
 706         readlevelcvars();
 707         GrappleHookInit();
 708         ElectroInit();
 709         LaserInit();
 710
 711         player_count = 0;
 712         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 713         if(bot_waypoints_for_items == 1)
 714                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 715                         bot_waypoints_for_items = 0;
 716
 717         precache();
 718
 719         WaypointSprite_Init();
 720
 721         //if (g_domination)
 722         //      dom_init();
 723
 724         GameLogInit(); // prepare everything
 725         // NOTE for matchid:
 726         // changing the logic generating it is okay. But:
 727         // it HAS to stay <= 64 chars
 728         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 729         if(autocvar_sv_eventlog)
 730         {
 731                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 732                 matchid = strzone(s);
 733
 734                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 735                 s = ":gameinfo:mutators:LIST";
 736
 737                 ret_string = s;
 738                 MUTATOR_CALLHOOK(BuildMutatorsString);
 739                 s = ret_string;
 740
 741                 // simple, probably not good in the mutator system
 742                 if(autocvar_g_grappling_hook)
 743                         s = strcat(s, ":grappling_hook");
 744
 745                 // initialiation stuff, not good in the mutator system
 746                 if(!autocvar_g_use_ammunition)
 747                         s = strcat(s, ":no_use_ammunition");
 748
 749                 // initialiation stuff, not good in the mutator system
 750                 if(!autocvar_g_pickup_items)
 751                         s = strcat(s, ":no_pickup_items");
 752
 753                 // initialiation stuff, not good in the mutator system
 754                 if(autocvar_g_weaponarena != "0")
 755                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 756
 757                 // TODO to mutator system
 758                 if(autocvar_g_norecoil)
 759                         s = strcat(s, ":norecoil");
 760
 761                 // TODO to mutator system
 762                 if(autocvar_g_midair)
 763                         s = strcat(s, ":midair");
 764
 765                 // TODO to mutator system
 766                 if(autocvar_g_minstagib)
 767                         s = strcat(s, ":minstagib");
 768
 769                 // TODO to mutator system
 770                 if(!autocvar_g_powerup_superhealth)
 771                         s = strcat(s, ":no_superhealth");
 772
 773                 // TODO to mutator system
 774                 if(!autocvar_g_powerup_strength)
 775                         s = strcat(s, ":no_strength");
 776
 777                 // TODO to mutator system
 778                 if(!autocvar_g_powerup_shield)
 779                         s = strcat(s, ":no_shield");
 780
 781                 GameLogEcho(s);
 782                 GameLogEcho(":gameinfo:end");
 783         }
 784         else
 785                 matchid = strzone(ftos(random()));
 786
 787         cvar_set("nextmap", "");
 788
 789         SetDefaultAlpha();
 790
 791         if(autocvar_g_campaign)
 792                 CampaignPostInit();
 793
 794         fteqcc_testbugs();
 795
 796         Ban_LoadBans();
 797
 798         MapInfo_Enumerate();
 799         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 800
 801         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 802         {
 803                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 804                 if(fd != -1)
 805                 {
 806                         while((s = fgets(fd)))
 807                         {
 808                                 l = tokenize_console(s);
 809                                 if(l < 2)
 810                                         continue;
 811                                 if(argv(0) == "cd")
 812                                 {
 813                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 814                                         print("  cdtrack ", argv(2), "\n");
 815                                 }
 816                                 else if(argv(0) == "fog")
 817                                 {
 818                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 819                                         print("  \"fog\" \"", s, "\"\n");
 820                                 }
 821                                 else if(argv(0) == "set")
 822                                 {
 823                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 824                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 825                                 }
 826                                 else if(argv(0) != "//")
 827                                 {
 828                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 829                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 830                                 }
 831                         }
 832                         fclose(fd);
 833                 }
 834         }
 835
 836         WeaponStats_Init();
 837
 838         addstat(STAT_WEAPONS, AS_INT, weapons);
 839         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 840         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 841         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 842         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 843         Nagger_Init();
 844
 845         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 846         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 847         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 848         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 849         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 850         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 851         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 852         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 853         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 854         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 855         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 856         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 857
 858         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 859         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 860
 861         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 862
 863         if(g_ca || g_freezetag)
 864         {
 865                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 866                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 867                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 868                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 869         }
 870         if(g_freezetag)
 871         {
 872                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 873                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 874         }
 875
 876         // g_movementspeed hack
 877         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 878         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 879         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 880         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 881
 882         // secrets
 883         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 884         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 885
 886         next_pingtime = time + 5;
 887
 888         detect_maptype();
 889
 890         lsmaps_reply = "^7Maps available: ";
 891         lsnewmaps_reply = "^7Maps without a record set: ";
 892         for(i = 0, j = 0; i < MapInfo_count; ++i)
 893         {
 894                 if(MapInfo_Get_ByID(i))
 895                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 896                         {
 897                                 if(mod(i, 2))
 898                                         col = "^2";
 899                                 else
 900                                         col = "^3";
 901                                 ++j;
 902                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 903                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 904                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 905                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 906                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 907                         }
 908         }
 909         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 910         if (!g_race && !g_cts)
 911                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 912         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 913
 914         maplist_reply = "^7Maps in list: ";
 915         n = tokenize_console(autocvar_g_maplist);
 916         for(i = 0, j = 0; i < n; ++i)
 917         {
 918                 if(MapInfo_CheckMap(argv(i)))
 919                 {
 920                         if(mod(j, 2))
 921                                 col = "^2";
 922                         else
 923                                 col = "^3";
 924                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 925                         ++j;
 926                 }
 927         }
 928         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 929         MapInfo_ClearTemps();
 930
 931         for(i = 0; i < 10; ++i)
 932         {
 933                 records_reply[i] = strzone(getrecords(i));
 934         }
 935         if(g_cts)
 936                 ladder_reply = strzone(getladder());
 937
 938         rankings_reply = strzone(getrankings());
 939
 940         ClientInit_Spawn();
 941         RandomSeed_Spawn();
 942         PingPLReport_Spawn();
 943
 944         CheatInit();
 945
 946         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 947
 948         // fill sv_curl_serverpackages from .serverpackage files
 949         if(autocvar_sv_curl_serverpackages_auto)
 950         {
 951                 s = "";
 952                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 953                 for(i = 0; i < n; ++i)
 954                         if(substring(argv(i), -14, -1) != ".serverpackage")
 955                                 s = strcat(s, " ", argv(i));
 956                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 957                 if(fd >= 0)
 958                 {
 959                         j = search_getsize(fd);
 960                         for(i = 0; i < j; ++i)
 961                                 s = strcat(s, " ", search_getfilename(fd, i));
 962                         search_end(fd);
 963                 }
 964                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 965         }
 966
 967         PlayerStats_Init();
 968
 969         world_initialized = 1;
 970 }
 971
 972 void spawnfunc_light (void)
 973 {
 974         //makestatic (self); // Who the f___ did that?
 975         remove(self);
 976 }
 977
 978 string GetGametype()
 979 {
 980         return GametypeNameFromType(game);
 981 }
 982
 983 string getmapname_stored;
 984 string GetMapname()
 985 {
 986         return mapname;
 987 }
 988
 989 float Map_Count, Map_Current;
 990 string Map_Current_Name;
 991
 992 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 993 float GetMaplistPosition()
 994 {
 995         float pos, idx;
 996         string map;
 997
 998         map = GetMapname();
 999         idx = autocvar_g_maplist_index;
1000
1001         if(idx >= 0)
1002                 if(idx < Map_Count)
1003                         if(map == argv(idx))
1004                                 return idx;
1005
1006         for(pos = 0; pos < Map_Count; ++pos)
1007                 if(map == argv(pos))
1008                         return pos;
1009
1010         // resume normal maplist rotation if current map is not in g_maplist
1011         return idx;
1012 }
1013
1014 float MapHasRightSize(string map)
1015 {
1016         float fh;
1017         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1018         if(autocvar_g_maplist_check_waypoints)
1019         {
1020                 dprint("checkwp "); dprint(map);
1021                 if(!fexists(strcat("maps/", map, ".waypoints")))
1022                 {
1023                         dprint(": no waypoints\n");
1024                         return FALSE;
1025                 }
1026                 dprint(": has waypoints\n");
1027         }
1028
1029         // open map size restriction file
1030         dprint("opensize "); dprint(map);
1031         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1032         if(fh >= 0)
1033         {
1034                 float mapmin, mapmax;
1035                 dprint(": ok, ");
1036                 mapmin = stof(fgets(fh));
1037                 mapmax = stof(fgets(fh));
1038                 fclose(fh);
1039                 if(player_count < mapmin)
1040                 {
1041                         dprint("not enough\n");
1042                         return FALSE;
1043                 }
1044                 if(player_count > mapmax)
1045                 {
1046                         dprint("too many\n");
1047                         return FALSE;
1048                 }
1049                 dprint("right size\n");
1050                 return TRUE;
1051         }
1052         dprint(": not found\n");
1053         return TRUE;
1054 }
1055
1056 string Map_Filename(float position)
1057 {
1058         return strcat("maps/", argv(position), ".bsp");
1059 }
1060
1061 string strwords(string s, float w)
1062 {
1063         float endpos;
1064         for(endpos = 0; w && endpos >= 0; --w)
1065                 endpos = strstrofs(s, " ", endpos + 1);
1066         if(endpos < 0)
1067                 return s;
1068         else
1069                 return substring(s, 0, endpos);
1070 }
1071
1072 float strhasword(string s, string w)
1073 {
1074         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1075 }
1076
1077 void Map_MarkAsRecent(string m)
1078 {
1079         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1080 }
1081
1082 float Map_IsRecent(string m)
1083 {
1084         return strhasword(autocvar_g_maplist_mostrecent, m);
1085 }
1086
1087 float Map_Check(float position, float pass)
1088 {
1089         string filename;
1090         string map_next;
1091         map_next = argv(position);
1092         if(pass <= 1)
1093         {
1094                 if(Map_IsRecent(map_next))
1095                         return 0;
1096         }
1097         filename = Map_Filename(position);
1098         if(MapInfo_CheckMap(map_next))
1099         {
1100                 if(pass == 2)
1101                         return 1;
1102                 if(MapHasRightSize(map_next))
1103                         return 1;
1104                 return 0;
1105         }
1106         else
1107                 dprint( "Couldn't select '", filename, "'..\n" );
1108
1109         return 0;
1110 }
1111
1112 void Map_Goto_SetStr(string nextmapname)
1113 {
1114         if(getmapname_stored != "")
1115                 strunzone(getmapname_stored);
1116         if(nextmapname == "")
1117                 getmapname_stored = "";
1118         else
1119                 getmapname_stored = strzone(nextmapname);
1120 }
1121
1122 void Map_Goto_SetFloat(float position)
1123 {
1124         cvar_set("g_maplist_index", ftos(position));
1125         Map_Goto_SetStr(argv(position));
1126 }
1127
1128 void GameResetCfg()
1129 {
1130         // settings persist, except...
1131         localcmd("\nsettemp_restore\n");
1132 }
1133
1134 void Map_Goto()
1135 {
1136         GameResetCfg();
1137         MapInfo_LoadMap(getmapname_stored);
1138 }
1139
1140 // return codes of map selectors:
1141 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1142 //   -2 = permanent failure
1143 float() MaplistMethod_Iterate = // usual method
1144 {
1145         float pass, i;
1146
1147         for(pass = 1; pass <= 2; ++pass)
1148         {
1149                 for(i = 1; i < Map_Count; ++i)
1150                 {
1151                         float mapindex;
1152                         mapindex = mod(i + Map_Current, Map_Count);
1153                         if(Map_Check(mapindex, pass))
1154                                 return mapindex;
1155                 }
1156         }
1157         return -1;
1158 }
1159
1160 float() MaplistMethod_Repeat = // fallback method
1161 {
1162         if(Map_Check(Map_Current, 2))
1163                 return Map_Current;
1164         return -2;
1165 }
1166
1167 float() MaplistMethod_Random = // random map selection
1168 {
1169         float i, imax;
1170
1171         imax = 42;
1172
1173         for(i = 0; i <= imax; ++i)
1174         {
1175                 float mapindex;
1176                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1177                 if(Map_Check(mapindex, 1))
1178                         return mapindex;
1179         }
1180         return -1;
1181 }
1182
1183 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1184 // the exponent sets a bias on the map selection:
1185 // the higher the exponent, the less likely "shortly repeated" same maps are
1186 {
1187         float i, j, imax, insertpos;
1188
1189         imax = 42;
1190
1191         for(i = 0; i <= imax; ++i)
1192         {
1193                 string newlist;
1194
1195                 // now reinsert this at another position
1196                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1197                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1198                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1199                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1200
1201                 // insert the current map there
1202                 newlist = "";
1203                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1204                         newlist = strcat(newlist, " ", argv(j));
1205                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1206                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1207                         newlist = strcat(newlist, " ", argv(j));
1208                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1209                 cvar_set("g_maplist", newlist);
1210                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1211
1212                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1213                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1214                 if(Map_Check(Map_Current, 1))
1215                         return Map_Current;
1216         }
1217         return -1;
1218 }
1219
1220 void Maplist_Init()
1221 {
1222         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1223         if(Map_Count == 0)
1224         {
1225                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1226                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1227                 if(autocvar_g_maplist_shuffle)
1228                         ShuffleMaplist();
1229                 localcmd("\nmenu_cmd sync\n");
1230                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1231         }
1232         if(Map_Count == 0)
1233                 error("empty maplist, cannot select a new map");
1234         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1235
1236         if(Map_Current_Name)
1237                 strunzone(Map_Current_Name);
1238         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1239         // this may or may not be correct, but who cares, in the worst case a map
1240         // isn't chosen in the first pass that should have been
1241 }
1242
1243 string GetNextMap()
1244 {
1245         float nextMap;
1246
1247         Maplist_Init();
1248         nextMap = -1;
1249
1250         if(nextMap == -1)
1251                 if(autocvar_g_maplist_shuffle > 0)
1252                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1253
1254         if(nextMap == -1)
1255                 if(autocvar_g_maplist_selectrandom)
1256                         nextMap = MaplistMethod_Random();
1257
1258         if(nextMap == -1)
1259                 nextMap = MaplistMethod_Iterate();
1260
1261         if(nextMap == -1)
1262                 nextMap = MaplistMethod_Repeat();
1263
1264         if(nextMap >= 0)
1265         {
1266                 Map_Goto_SetFloat(nextMap);
1267                 return getmapname_stored;
1268         }
1269
1270         return "";
1271 }
1272
1273 float DoNextMapOverride()
1274 {
1275         if(autocvar_g_campaign)
1276         {
1277                 CampaignPostIntermission();
1278                 alreadychangedlevel = TRUE;
1279                 return TRUE;
1280         }
1281         if(autocvar_quit_when_empty)
1282         {
1283                 if(player_count <= currentbots)
1284                 {
1285                         localcmd("quit\n");
1286                         alreadychangedlevel = TRUE;
1287                         return TRUE;
1288                 }
1289         }
1290         if(autocvar_quit_and_redirect != "")
1291         {
1292                 redirection_target = strzone(autocvar_quit_and_redirect);
1293                 alreadychangedlevel = TRUE;
1294                 return TRUE;
1295         }
1296         if (autocvar_samelevel) // if samelevel is set, stay on same level
1297         {
1298                 localcmd("restart\n");
1299                 alreadychangedlevel = TRUE;
1300                 return TRUE;
1301         }
1302         if(autocvar_nextmap != "")
1303                 if(MapInfo_CheckMap(autocvar_nextmap))
1304                 {
1305                         Map_Goto_SetStr(autocvar_nextmap);
1306                         Map_Goto();
1307                         alreadychangedlevel = TRUE;
1308                         return TRUE;
1309                 }
1310         if(autocvar_lastlevel)
1311         {
1312                 GameResetCfg();
1313                 localcmd("set lastlevel 0\ntogglemenu\n");
1314                 alreadychangedlevel = TRUE;
1315                 return TRUE;
1316         }
1317         return FALSE;
1318 }
1319
1320 void GotoNextMap()
1321 {
1322         //string nextmap;
1323         //float n, nummaps;
1324         //string s;
1325         if (alreadychangedlevel)
1326                 return;
1327         alreadychangedlevel = TRUE;
1328
1329         {
1330                 string nextMap;
1331                 float allowReset;
1332
1333                 for(allowReset = 1; allowReset >= 0; --allowReset)
1334                 {
1335                         nextMap = GetNextMap();
1336                         if(nextMap != "")
1337                                 break;
1338
1339                         if(allowReset)
1340                         {
1341                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1342                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1343                                 if(autocvar_g_maplist_shuffle)
1344                                         ShuffleMaplist();
1345                                 localcmd("\nmenu_cmd sync\n");
1346                         }
1347                         else
1348                         {
1349                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1350                         }
1351                 }
1352                 Map_Goto();
1353         }
1354 }
1355
1356
1357 /*
1358 ============
1359 IntermissionThink
1360
1361 When the player presses attack or jump, change to the next level
1362 ============
1363 */
1364 .float autoscreenshot;
1365 void() MapVote_Start;
1366 void() MapVote_Think;
1367 float mapvote_initialized;
1368 void IntermissionThink()
1369 {
1370         FixIntermissionClient(self);
1371
1372         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1373                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1374         {
1375                 self.autoscreenshot = -1;
1376                 if(clienttype(self) == CLIENTTYPE_REAL)
1377                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1378                 return;
1379         }
1380
1381         if (time < intermission_exittime)
1382                 return;
1383
1384         if(!mapvote_initialized)
1385                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1386                         return;
1387
1388         MapVote_Start();
1389 }
1390
1391 /*
1392 ============
1393 FindIntermission
1394
1395 Returns the entity to view from
1396 ============
1397 */
1398 /*
1399 entity FindIntermission()
1400 {
1401         local   entity spot;
1402         local   float cyc;
1403
1404 // look for info_intermission first
1405         spot = find (world, classname, "info_intermission");
1406         if (spot)
1407         {       // pick a random one
1408                 cyc = random() * 4;
1409                 while (cyc > 1)
1410                 {
1411                         spot = find (spot, classname, "info_intermission");
1412                         if (!spot)
1413                                 spot = find (spot, classname, "info_intermission");
1414                         cyc = cyc - 1;
1415                 }
1416                 return spot;
1417         }
1418
1419 // then look for the start position
1420         spot = find (world, classname, "info_player_start");
1421         if (spot)
1422                 return spot;
1423
1424 // testinfo_player_start is only found in regioned levels
1425         spot = find (world, classname, "testplayerstart");
1426         if (spot)
1427                 return spot;
1428
1429 // then look for the start position
1430         spot = find (world, classname, "info_player_deathmatch");
1431         if (spot)
1432                 return spot;
1433
1434         //objerror ("FindIntermission: no spot");
1435         return world;
1436 }
1437 */
1438
1439 /*
1440 ===============================================================================
1441
1442 RULES
1443
1444 ===============================================================================
1445 */
1446
1447 void DumpStats(float final)
1448 {
1449         float file;
1450         string s;
1451         float to_console;
1452         float to_eventlog;
1453         float to_file;
1454         float i;
1455
1456         to_console = autocvar_sv_logscores_console;
1457         to_eventlog = autocvar_sv_eventlog;
1458         to_file = autocvar_sv_logscores_file;
1459
1460         if(!final)
1461         {
1462                 to_console = TRUE; // always print printstats replies
1463                 to_eventlog = FALSE; // but never print them to the event log
1464         }
1465
1466         if(to_eventlog)
1467                 if(autocvar_sv_eventlog_console)
1468                         to_console = FALSE; // otherwise we get the output twice
1469
1470         if(final)
1471                 s = ":scores:";
1472         else
1473                 s = ":status:";
1474         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1475
1476         if(to_console)
1477                 print(s, "\n");
1478         if(to_eventlog)
1479                 GameLogEcho(s);
1480         if(to_file)
1481         {
1482                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1483                 if(file == -1)
1484                         to_file = FALSE;
1485                 else
1486                         fputs(file, strcat(s, "\n"));
1487         }
1488
1489         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1490         if(to_console)
1491                 print(s, "\n");
1492         if(to_eventlog)
1493                 GameLogEcho(s);
1494         if(to_file)
1495                 fputs(file, strcat(s, "\n"));
1496
1497         FOR_EACH_CLIENT(other)
1498         {
1499                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1500                 {
1501                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1502                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1503                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1504                                 s = strcat(s, ftos(other.team), ":");
1505                         else
1506                                 s = strcat(s, "spectator:");
1507
1508                         if(to_console)
1509                                 print(s, other.netname, "\n");
1510                         if(to_eventlog)
1511                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1512                         if(to_file)
1513                                 fputs(file, strcat(s, other.netname, "\n"));
1514                 }
1515         }
1516
1517         if(teamplay)
1518         {
1519                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1520                 if(to_console)
1521                         print(s, "\n");
1522                 if(to_eventlog)
1523                         GameLogEcho(s);
1524                 if(to_file)
1525                         fputs(file, strcat(s, "\n"));
1526
1527                 for(i = 1; i < 16; ++i)
1528                 {
1529                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1530                         s = strcat(s, ":", ftos(i));
1531                         if(to_console)
1532                                 print(s, "\n");
1533                         if(to_eventlog)
1534                                 GameLogEcho(s);
1535                         if(to_file)
1536                                 fputs(file, strcat(s, "\n"));
1537                 }
1538         }
1539
1540         if(to_console)
1541                 print(":end\n");
1542         if(to_eventlog)
1543                 GameLogEcho(":end");
1544         if(to_file)
1545         {
1546                 fputs(file, ":end\n");
1547                 fclose(file);
1548         }
1549 }
1550
1551 void FixIntermissionClient(entity e)
1552 {
1553         string s;
1554         if(!e.autoscreenshot) // initial call
1555         {
1556                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1557                 e.health = -2342;
1558                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1559                 e.solid = SOLID_NOT;
1560                 e.movetype = MOVETYPE_NONE;
1561                 e.takedamage = DAMAGE_NO;
1562                 if(e.weaponentity)
1563                 {
1564                         e.weaponentity.effects = EF_NODRAW;
1565                         if (e.weaponentity.weaponentity)
1566                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1567                 }
1568                 if(clienttype(e) == CLIENTTYPE_REAL)
1569                 {
1570                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1571                         s = autocvar_sv_intermission_cdtrack;
1572                         if(s != "")
1573                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1574                         msg_entity = e;
1575                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1576                 }
1577         }
1578 }
1579
1580
1581 /*
1582 go to the next level for deathmatch
1583 only called if a time or frag limit has expired
1584 */
1585 void NextLevel()
1586 {
1587         gameover = TRUE;
1588
1589         intermission_running = 1;
1590
1591 // enforce a wait time before allowing changelevel
1592         if(player_count > 0)
1593                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1594         else
1595                 intermission_exittime = -1;
1596
1597         /*
1598         WriteByte (MSG_ALL, SVC_CDTRACK);
1599         WriteByte (MSG_ALL, 3);
1600         WriteByte (MSG_ALL, 3);
1601         // done in FixIntermission
1602         */
1603
1604         //pos = FindIntermission ();
1605
1606         VoteReset();
1607
1608         DumpStats(TRUE);
1609
1610         // send statistics
1611         entity e;
1612         PlayerStats_EndMatch(1);
1613         FOR_EACH_CLIENT(e)
1614                 PlayerStats_AddGlobalInfo(e);
1615         PlayerStats_Shutdown();
1616         WeaponStats_Shutdown();
1617
1618         if(autocvar_sv_eventlog)
1619                 GameLogEcho(":gameover");
1620
1621         GameLogClose();
1622
1623         FOR_EACH_PLAYER(other) {
1624                 FixIntermissionClient(other);
1625                 if(other.winning)
1626                         bprint(other.netname, " ^7wins.\n");
1627         }
1628
1629         if(autocvar_g_campaign)
1630                 CampaignPreIntermission();
1631
1632         localcmd("\nsv_hook_gameend\n");
1633 }
1634
1635 /*
1636 ============
1637 CheckRules_Player
1638
1639 Exit deathmatch games upon conditions
1640 ============
1641 */
1642 void CheckRules_Player()
1643 {
1644         if (gameover)   // someone else quit the game already
1645                 return;
1646
1647         if(self.deadflag == DEAD_NO)
1648                 self.play_time += frametime;
1649
1650         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1651         //   (div0: and that in CheckRules_World please)
1652 }
1653
1654 float checkrules_equality;
1655 float checkrules_suddendeathwarning;
1656 float checkrules_suddendeathend;
1657 float checkrules_overtimesadded; //how many overtimes have been already added
1658
1659 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1660 float WINNING_YES = 1; // winner found
1661 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1662 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1663
1664 float InitiateSuddenDeath()
1665 {
1666         // Check first whether normal overtimes could be added before initiating suddendeath mode
1667         // - for this timelimit_overtime needs to be >0 of course
1668         // - also check the winning condition calculated in the previous frame and only add normal overtime
1669         //   again, if at the point at which timelimit would be extended again, still no winner was found
1670         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1671         {
1672                 return 1; // need to call InitiateOvertime later
1673         }
1674         else
1675         {
1676                 if(!checkrules_suddendeathend)
1677                 {
1678                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1679                         if(g_race && !g_race_qualifying)
1680                                 race_StartCompleting();
1681                 }
1682                 return 0;
1683         }
1684 }
1685
1686 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1687 {
1688         ++checkrules_overtimesadded;
1689         //add one more overtime by simply extending the timelimit
1690         float tl;
1691         tl = autocvar_timelimit;
1692         tl += autocvar_timelimit_overtime;
1693         cvar_set("timelimit", ftos(tl));
1694         string minutesPlural;
1695         if (autocvar_timelimit_overtime == 1)
1696                 minutesPlural = " ^3minute";
1697         else
1698                 minutesPlural = " ^3minutes";
1699
1700         bcenterprint(
1701                 strcat(
1702                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1703                         ftos(autocvar_timelimit_overtime),
1704                         minutesPlural,
1705                         " to the game!"
1706                 )
1707         );
1708 }
1709
1710 float GetWinningCode(float fraglimitreached, float equality)
1711 {
1712         if(autocvar_g_campaign == 1)
1713                 if(fraglimitreached)
1714                         return WINNING_YES;
1715                 else
1716                         return WINNING_NO;
1717
1718         else
1719                 if(equality)
1720                         if(fraglimitreached)
1721                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1722                         else
1723                                 return WINNING_NEVER;
1724                 else
1725                         if(fraglimitreached)
1726                                 return WINNING_YES;
1727                         else
1728                                 return WINNING_NO;
1729 }
1730
1731 // set the .winning flag for exactly those players with a given field value
1732 void SetWinners(.float field, float value)
1733 {
1734         entity head;
1735         FOR_EACH_PLAYER(head)
1736                 head.winning = (head.field == value);
1737 }
1738
1739 // set the .winning flag for those players with a given field value
1740 void AddWinners(.float field, float value)
1741 {
1742         entity head;
1743         FOR_EACH_PLAYER(head)
1744                 if(head.field == value)
1745                         head.winning = 1;
1746 }
1747
1748 // clear the .winning flags
1749 void ClearWinners(void)
1750 {
1751         entity head;
1752         FOR_EACH_PLAYER(head)
1753                 head.winning = 0;
1754 }
1755
1756 // Onslaught winning condition:
1757 // game terminates if only one team has a working generator (or none)
1758 float WinningCondition_Onslaught()
1759 {
1760         entity head;
1761         float t1, t2, t3, t4;
1762
1763         WinningConditionHelper(); // set worldstatus
1764
1765         if(inWarmupStage)
1766                 return WINNING_NO;
1767
1768         // first check if the game has ended
1769         t1 = t2 = t3 = t4 = 0;
1770         head = find(world, classname, "onslaught_generator");
1771         while (head)
1772         {
1773                 if (head.health > 0)
1774                 {
1775                         if (head.team == COLOR_TEAM1) t1 = 1;
1776                         if (head.team == COLOR_TEAM2) t2 = 1;
1777                         if (head.team == COLOR_TEAM3) t3 = 1;
1778                         if (head.team == COLOR_TEAM4) t4 = 1;
1779                 }
1780                 head = find(head, classname, "onslaught_generator");
1781         }
1782         if (t1 + t2 + t3 + t4 < 2)
1783         {
1784                 // game over, only one team remains (or none)
1785                 ClearWinners();
1786                 if (t1) SetWinners(team, COLOR_TEAM1);
1787                 if (t2) SetWinners(team, COLOR_TEAM2);
1788                 if (t3) SetWinners(team, COLOR_TEAM3);
1789                 if (t4) SetWinners(team, COLOR_TEAM4);
1790                 dprint("Have a winner, ending game.\n");
1791                 return WINNING_YES;
1792         }
1793
1794         // Two or more teams remain
1795         return WINNING_NO;
1796 }
1797
1798 float LMS_NewPlayerLives()
1799 {
1800         float fl;
1801         fl = autocvar_fraglimit;
1802         if(fl == 0)
1803                 fl = 999;
1804
1805         // first player has left the game for dying too much? Nobody else can get in.
1806         if(lms_lowest_lives < 1)
1807                 return 0;
1808
1809         if(!autocvar_g_lms_join_anytime)
1810                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1811                         return 0;
1812
1813         return bound(1, lms_lowest_lives, fl);
1814 }
1815
1816 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1817 // they win. Otherwise the defending team wins once the timelimit passes.
1818 void assault_new_round();
1819 float WinningCondition_Assault()
1820 {
1821         float status;
1822
1823         WinningConditionHelper(); // set worldstatus
1824
1825         status = WINNING_NO;
1826         // as the timelimit has not yet passed just assume the defending team will win
1827         if(assault_attacker_team == COLOR_TEAM1)
1828         {
1829                 SetWinners(team, COLOR_TEAM2);
1830         }
1831         else
1832         {
1833                 SetWinners(team, COLOR_TEAM1);
1834         }
1835
1836         entity ent;
1837         ent = find(world, classname, "target_assault_roundend");
1838         if(ent)
1839         {
1840                 if(ent.winning) // round end has been triggered by attacking team
1841                 {
1842                         bprint("ASSAULT: round completed...\n");
1843                         SetWinners(team, assault_attacker_team);
1844
1845                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1846
1847                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1848                         {
1849                                 status = WINNING_YES;
1850                         }
1851                         else
1852                         {
1853                                 entity oldself;
1854                                 oldself = self;
1855                                 self = ent;
1856                                 assault_new_round();
1857                                 self = oldself;
1858                         }
1859                 }
1860         }
1861
1862         return status;
1863 }
1864
1865 // LMS winning condition: game terminates if and only if there's at most one
1866 // one player who's living lives. Top two scores being equal cancels the time
1867 // limit.
1868 float WinningCondition_LMS()
1869 {
1870         entity head, head2;
1871         float have_player;
1872         float have_players;
1873         float l;
1874
1875         have_player = FALSE;
1876         have_players = FALSE;
1877         l = LMS_NewPlayerLives();
1878
1879         head = find(world, classname, "player");
1880         if(head)
1881                 have_player = TRUE;
1882         head2 = find(head, classname, "player");
1883         if(head2)
1884                 have_players = TRUE;
1885
1886         if(have_player)
1887         {
1888                 // we have at least one player
1889                 if(have_players)
1890                 {
1891                         // two or more active players - continue with the game
1892                 }
1893                 else
1894                 {
1895                         // exactly one player?
1896
1897                         ClearWinners();
1898                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1899
1900                         if(l)
1901                         {
1902                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1903                                 return WINNING_NO;
1904                         }
1905                         else
1906                         {
1907                                 // a winner!
1908                                 // and assign him his first place
1909                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1910                                 return WINNING_YES;
1911                         }
1912                 }
1913         }
1914         else
1915         {
1916                 // nobody is playing at all...
1917                 if(l)
1918                 {
1919                         // wait for players...
1920                 }
1921                 else
1922                 {
1923                         // SNAFU (maybe a draw game?)
1924                         ClearWinners();
1925                         dprint("No players, ending game.\n");
1926                         return WINNING_YES;
1927                 }
1928         }
1929
1930         // When we get here, we have at least two players who are actually LIVING,
1931         // now check if the top two players have equal score.
1932         WinningConditionHelper();
1933
1934         ClearWinners();
1935         if(WinningConditionHelper_winner)
1936                 WinningConditionHelper_winner.winning = TRUE;
1937         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1938                 return WINNING_NEVER;
1939
1940         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1941         return WINNING_NO;
1942 }
1943
1944 void ShuffleMaplist()
1945 {
1946         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1947 }
1948
1949 float leaderfrags;
1950 float WinningCondition_Scores(float limit, float leadlimit)
1951 {
1952         float limitreached;
1953
1954         // TODO make everything use THIS winning condition (except LMS)
1955         WinningConditionHelper();
1956
1957         if(teamplay)
1958         {
1959                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1960                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1961                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1962                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1963         }
1964
1965         ClearWinners();
1966         if(WinningConditionHelper_winner)
1967                 WinningConditionHelper_winner.winning = 1;
1968         if(WinningConditionHelper_winnerteam >= 0)
1969                 SetWinners(team, WinningConditionHelper_winnerteam);
1970
1971         if(WinningConditionHelper_lowerisbetter)
1972         {
1973                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1974                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1975                 limit = -limit;
1976         }
1977
1978         if(WinningConditionHelper_zeroisworst)
1979                 leadlimit = 0; // not supported in this mode
1980
1981         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1982         // these modes always score in increments of 1, thus this makes sense
1983         {
1984                 if(leaderfrags != WinningConditionHelper_topscore)
1985                 {
1986                         leaderfrags = WinningConditionHelper_topscore;
1987
1988                         if (limit)
1989                         if (leaderfrags == limit - 1)
1990                                 Announce("1fragleft");
1991                         else if (leaderfrags == limit - 2)
1992                                 Announce("2fragsleft");
1993                         else if (leaderfrags == limit - 3)
1994                                 Announce("3fragsleft");
1995                 }
1996         }
1997
1998         limitreached = FALSE;
1999         if(limit)
2000                 if(WinningConditionHelper_topscore >= limit)
2001                         limitreached = TRUE;
2002         if(leadlimit)
2003         {
2004                 float leadlimitreached;
2005                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2006                 if(autocvar_leadlimit_and_fraglimit)
2007                         limitreached = (limitreached && leadlimitreached);
2008                 else
2009                         limitreached = (limitreached || leadlimitreached);
2010         }
2011
2012         return GetWinningCode(
2013                 WinningConditionHelper_topscore && limitreached,
2014                 WinningConditionHelper_equality
2015         );
2016 }
2017
2018 float WinningCondition_Race(float fraglimit)
2019 {
2020         float wc;
2021         entity p;
2022         float n, c;
2023
2024         n = 0;
2025         c = 0;
2026         FOR_EACH_PLAYER(p)
2027         {
2028                 ++n;
2029                 if(p.race_completed)
2030                         ++c;
2031         }
2032         if(n && (n == c))
2033                 return WINNING_YES;
2034         wc = WinningCondition_Scores(fraglimit, 0);
2035
2036         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2037         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2038         // do NOT support equality when the laps are all raced!
2039                 return WINNING_STARTSUDDENDEATHOVERTIME;
2040         else
2041                 return WINNING_NEVER;
2042         return wc;
2043 }
2044
2045 void ReadyRestart();
2046 float WinningCondition_QualifyingThenRace(float limit)
2047 {
2048         float wc;
2049         wc = WinningCondition_Scores(limit, 0);
2050
2051         // NEVER initiate overtime
2052         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2053         {
2054                 return WINNING_YES;
2055         }
2056
2057         return wc;
2058 }
2059
2060 float WinningCondition_RanOutOfSpawns()
2061 {
2062         entity head;
2063
2064         if(have_team_spawns <= 0)
2065                 return WINNING_NO;
2066
2067         if(autocvar_g_spawn_useallspawns <= 0)
2068                 return WINNING_NO;
2069
2070         if(!some_spawn_has_been_used)
2071                 return WINNING_NO;
2072
2073         team1_score = team2_score = team3_score = team4_score = 0;
2074
2075         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2076         {
2077                 if(head.team == COLOR_TEAM1)
2078                         team1_score = 1;
2079                 else if(head.team == COLOR_TEAM2)
2080                         team2_score = 1;
2081                 else if(head.team == COLOR_TEAM3)
2082                         team3_score = 1;
2083                 else if(head.team == COLOR_TEAM4)
2084                         team4_score = 1;
2085         }
2086
2087         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2088         {
2089                 if(head.team == COLOR_TEAM1)
2090                         team1_score = 1;
2091                 else if(head.team == COLOR_TEAM2)
2092                         team2_score = 1;
2093                 else if(head.team == COLOR_TEAM3)
2094                         team3_score = 1;
2095                 else if(head.team == COLOR_TEAM4)
2096                         team4_score = 1;
2097         }
2098
2099         ClearWinners();
2100         if(team1_score + team2_score + team3_score + team4_score == 0)
2101         {
2102                 checkrules_equality = TRUE;
2103                 return WINNING_YES;
2104         }
2105         else if(team1_score + team2_score + team3_score + team4_score == 1)
2106         {
2107                 float t, i;
2108                 if(team1_score) t = COLOR_TEAM1;
2109                 if(team2_score) t = COLOR_TEAM2;
2110                 if(team3_score) t = COLOR_TEAM3;
2111                 if(team4_score) t = COLOR_TEAM4;
2112                 CheckAllowedTeams(world);
2113                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2114                 {
2115                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2116                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2117                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2118                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2119                 }
2120
2121                 AddWinners(team, t);
2122                 return WINNING_YES;
2123         }
2124         else
2125                 return WINNING_NO;
2126 }
2127
2128 /*
2129 ============
2130 CheckRules_World
2131
2132 Exit deathmatch games upon conditions
2133 ============
2134 */
2135 void CheckRules_World()
2136 {
2137         float timelimit;
2138         float fraglimit;
2139         float leadlimit;
2140
2141         VoteThink();
2142         MapVote_Think();
2143
2144         SetDefaultAlpha();
2145
2146         /*
2147         MapVote_Think should now do that part
2148         if (intermission_running)
2149                 if (time >= intermission_exittime + 60)
2150                 {
2151                         if(!DoNextMapOverride())
2152                                 GotoNextMap();
2153                         return;
2154                 }
2155         */
2156
2157         if (gameover)   // someone else quit the game already
2158         {
2159                 if(player_count == 0) // Nobody there? Then let's go to the next map
2160                         MapVote_Start();
2161                         // this will actually check the player count in the next frame
2162                         // again, but this shouldn't hurt
2163                 return;
2164         }
2165
2166         timelimit = autocvar_timelimit * 60;
2167         fraglimit = autocvar_fraglimit;
2168         leadlimit = autocvar_leadlimit;
2169
2170         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2171         {
2172                 if(timelimit > 0)
2173                         timelimit = 0; // timelimit is not made for warmup
2174                 if(fraglimit > 0)
2175                         fraglimit = 0; // no fraglimit for now
2176                 leadlimit = 0; // no leadlimit for now
2177         }
2178
2179         if(g_onslaught)
2180                 timelimit = 0; // ONS has its own overtime rule
2181
2182         if(timelimit > 0)
2183         {
2184                 timelimit += game_starttime;
2185         }
2186         else if (timelimit < 0)
2187         {
2188                 // endmatch
2189                 NextLevel();
2190                 return;
2191         }
2192
2193         float wantovertime;
2194         wantovertime = 0;
2195
2196         if(checkrules_suddendeathend)
2197         {
2198                 if(!checkrules_suddendeathwarning)
2199                 {
2200                         checkrules_suddendeathwarning = TRUE;
2201                         if(g_race && !g_race_qualifying)
2202                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2203                         else
2204                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2205                 }
2206         }
2207         else
2208         {
2209                 if (timelimit && time >= timelimit)
2210                 {
2211                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2212                         {
2213                                 float totalplayers;
2214                                 float playerswithlaps;
2215                                 float readyplayers;
2216                                 entity head;
2217                                 totalplayers = playerswithlaps = readyplayers = 0;
2218                                 FOR_EACH_PLAYER(head)
2219                                 {
2220                                         ++totalplayers;
2221                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2222                                                 ++playerswithlaps;
2223                                         if(head.ready)
2224                                                 ++readyplayers;
2225                                 }
2226
2227                                 // at least 2 of the players have completed a lap: start the RACE
2228                                 // otherwise, the players should end the qualifying on their own
2229                                 if(readyplayers || playerswithlaps >= 2)
2230                                 {
2231                                         checkrules_suddendeathend = 0;
2232                                         ReadyRestart(); // go to race
2233                                         return;
2234                                 }
2235                                 else
2236                                         wantovertime |= InitiateSuddenDeath();
2237                         }
2238                         else
2239                                 wantovertime |= InitiateSuddenDeath();
2240                 }
2241         }
2242
2243         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2244         {
2245                 NextLevel();
2246                 return;
2247         }
2248
2249         float checkrules_status;
2250         checkrules_status = WinningCondition_RanOutOfSpawns();
2251         if(checkrules_status == WINNING_YES)
2252         {
2253                 bprint("Hey! Someone ran out of spawns!\n");
2254         }
2255         else if(g_race && !g_race_qualifying && timelimit >= 0)
2256         {
2257                 checkrules_status = WinningCondition_Race(fraglimit);
2258                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2259         }
2260         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2261         {
2262                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2263                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2264         }
2265         else if(g_assault)
2266         {
2267                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2268         }
2269         else if(g_lms)
2270         {
2271                 checkrules_status = WinningCondition_LMS();
2272         }
2273         else if (g_onslaught)
2274         {
2275                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2276         }
2277         else
2278         {
2279                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2280                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2281         }
2282
2283         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2284         {
2285                 checkrules_status = WINNING_NEVER;
2286                 checkrules_overtimesadded = -1;
2287                 wantovertime |= InitiateSuddenDeath();
2288         }
2289
2290         if(checkrules_status == WINNING_NEVER)
2291                 // equality cases! Nobody wins if the overtime ends in a draw.
2292                 ClearWinners();
2293
2294         if(wantovertime)
2295         {
2296                 if(checkrules_status == WINNING_NEVER)
2297                         InitiateOvertime();
2298                 else
2299                         checkrules_status = WINNING_YES;
2300         }
2301
2302         if(checkrules_suddendeathend)
2303                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2304                         checkrules_status = WINNING_YES;
2305
2306         if(checkrules_status == WINNING_YES)
2307         {
2308                 //print("WINNING\n");
2309                 NextLevel();
2310         }
2311 }
2312
2313 float mapvote_nextthink;
2314 float mapvote_initialized;
2315 float mapvote_keeptwotime;
2316 float mapvote_timeout;
2317 string mapvote_message;
2318 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2319 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2320 float mapvote_screenshot_dirs_count;
2321
2322 float mapvote_count;
2323 float mapvote_count_real;
2324 string mapvote_maps[MAPVOTE_COUNT];
2325 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2326 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2327 float mapvote_maps_suggested[MAPVOTE_COUNT];
2328 string mapvote_suggestions[MAPVOTE_COUNT];
2329 float mapvote_suggestion_ptr;
2330 float mapvote_voters;
2331 float mapvote_votes[MAPVOTE_COUNT];
2332 float mapvote_run;
2333 float mapvote_detail;
2334 float mapvote_abstain;
2335 .float mapvote;
2336
2337 void MapVote_ClearAllVotes()
2338 {
2339         FOR_EACH_CLIENT(other)
2340                 other.mapvote = 0;
2341 }
2342
2343 string MapVote_Suggest(string m)
2344 {
2345         float i;
2346         if(m == "")
2347                 return "That's not how to use this command.";
2348         if(!autocvar_g_maplist_votable_suggestions)
2349                 return "Suggestions are not accepted on this server.";
2350         if(mapvote_initialized)
2351                 return "Can't suggest - voting is already in progress!";
2352         m = MapInfo_FixName(m);
2353         if(!m)
2354                 return "The map you suggested is not available on this server.";
2355         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2356                 if(Map_IsRecent(m))
2357                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2358
2359         if(!MapInfo_CheckMap(m))
2360                 return "The map you suggested does not support the current game mode.";
2361         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2362                 if(mapvote_suggestions[i] == m)
2363                         return "This map was already suggested.";
2364         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2365         {
2366                 i = floor(random() * mapvote_suggestion_ptr);
2367         }
2368         else
2369         {
2370                 i = mapvote_suggestion_ptr;
2371                 mapvote_suggestion_ptr += 1;
2372         }
2373         if(mapvote_suggestions[i] != "")
2374                 strunzone(mapvote_suggestions[i]);
2375         mapvote_suggestions[i] = strzone(m);
2376         if(autocvar_sv_eventlog)
2377                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2378         return strcat("Suggestion of ", m, " accepted.");
2379 }
2380
2381 void MapVote_AddVotable(string nextMap, float isSuggestion)
2382 {
2383         float j, i, o;
2384         string pakfile, mapfile;
2385
2386         if(nextMap == "")
2387                 return;
2388         for(j = 0; j < mapvote_count; ++j)
2389                 if(mapvote_maps[j] == nextMap)
2390                         return;
2391         // suggestions might be no longer valid/allowed after gametype switch!
2392         if(isSuggestion)
2393                 if(!MapInfo_CheckMap(nextMap))
2394                         return;
2395         mapvote_maps[mapvote_count] = strzone(nextMap);
2396         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2397
2398         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2399         {
2400                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2401                 pakfile = whichpack(strcat(mapfile, ".tga"));
2402                 if(pakfile == "")
2403                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2404                 if(pakfile == "")
2405                         pakfile = whichpack(strcat(mapfile, ".png"));
2406                 if(pakfile != "")
2407                         break;
2408         }
2409         if(i >= mapvote_screenshot_dirs_count)
2410                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2411         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2412                 pakfile = substring(pakfile, o, -1);
2413
2414         mapvote_maps_screenshot_dir[mapvote_count] = i;
2415         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2416
2417         mapvote_count += 1;
2418 }
2419
2420 void MapVote_Spawn();
2421 void MapVote_Init()
2422 {
2423         float i;
2424         float nmax, smax;
2425
2426         MapVote_ClearAllVotes();
2427
2428         mapvote_count = 0;
2429         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2430         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2431
2432         if(mapvote_abstain)
2433                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2434         else
2435                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2436         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2437
2438         // we need this for AddVotable, as that cycles through the screenshot dirs
2439         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2440         if(mapvote_screenshot_dirs_count == 0)
2441                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2442         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2443         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2444                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2445
2446         if(mapvote_suggestion_ptr)
2447                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2448                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2449
2450         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2451                 MapVote_AddVotable(GetNextMap(), FALSE);
2452
2453         if(mapvote_count == 0)
2454         {
2455                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2456                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2457                 if(autocvar_g_maplist_shuffle)
2458                         ShuffleMaplist();
2459                 localcmd("\nmenu_cmd sync\n");
2460                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2461                         MapVote_AddVotable(GetNextMap(), FALSE);
2462         }
2463
2464         mapvote_count_real = mapvote_count;
2465         if(mapvote_abstain)
2466                 MapVote_AddVotable("don't care", 0);
2467
2468         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2469
2470         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2471         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2472         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2473                 mapvote_keeptwotime = 0;
2474         mapvote_message = "Choose a map and press its key!";
2475
2476         MapVote_Spawn();
2477 }
2478
2479 void MapVote_SendPicture(float id)
2480 {
2481         msg_entity = self;
2482         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2483         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2484         WriteByte(MSG_ONE, id);
2485         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2486 }
2487
2488 float GameCommand_MapVote(string cmd)
2489 {
2490         if(!intermission_running)
2491                 return FALSE;
2492
2493         if(cmd == "mv_getpic")
2494         {
2495                 MapVote_SendPicture(stof(argv(1)));
2496                 return TRUE;
2497         }
2498
2499         return FALSE;
2500 }
2501
2502 float MapVote_GetMapMask()
2503 {
2504         float mask, i, power;
2505         mask = 0;
2506         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2507                 if(mapvote_maps[i] != "")
2508                         mask |= power;
2509         return mask;
2510 }
2511
2512 entity mapvote_ent;
2513 float MapVote_SendEntity(entity to, float sf)
2514 {
2515         float i;
2516
2517         if(sf & 1)
2518                 sf &~= 2; // if we send 1, we don't need to also send 2
2519
2520         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2521         WriteByte(MSG_ENTITY, sf);
2522
2523         if(sf & 1)
2524         {
2525                 // flag 1 == initialization
2526                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2527                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2528                 WriteString(MSG_ENTITY, "");
2529                 WriteByte(MSG_ENTITY, mapvote_count);
2530                 WriteByte(MSG_ENTITY, mapvote_abstain);
2531                 WriteByte(MSG_ENTITY, mapvote_detail);
2532                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2533                 if(mapvote_count <= 8)
2534                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2535                 else
2536                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2537                 for(i = 0; i < mapvote_count; ++i)
2538                         if(mapvote_maps[i] != "")
2539                         {
2540                                 if(mapvote_abstain && i == mapvote_count - 1)
2541                                 {
2542                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2543                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2544                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2545                                 }
2546                                 else
2547                                 {
2548                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2549                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2550                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2551                                 }
2552                         }
2553         }
2554
2555         if(sf & 2)
2556         {
2557                 // flag 2 == update of mask
2558                 if(mapvote_count <= 8)
2559                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2560                 else
2561                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2562         }
2563
2564         if(sf & 4)
2565         {
2566                 if(mapvote_detail)
2567                         for(i = 0; i < mapvote_count; ++i)
2568                                 if(mapvote_maps[i] != "")
2569                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2570
2571                 WriteByte(MSG_ENTITY, to.mapvote);
2572         }
2573
2574         return TRUE;
2575 }
2576
2577 void MapVote_Spawn()
2578 {
2579         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2580 }
2581
2582 void MapVote_TouchMask()
2583 {
2584         mapvote_ent.SendFlags |= 2;
2585 }
2586
2587 void MapVote_TouchVotes(entity voter)
2588 {
2589         mapvote_ent.SendFlags |= 4;
2590 }
2591
2592 float MapVote_Finished(float mappos)
2593 {
2594         string result;
2595         float i;
2596         float didntvote;
2597
2598         if(autocvar_sv_eventlog)
2599         {
2600                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2601                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2602                 didntvote = mapvote_voters;
2603                 for(i = 0; i < mapvote_count; ++i)
2604                         if(mapvote_maps[i] != "")
2605                         {
2606                                 didntvote -= mapvote_votes[i];
2607                                 if(i != mappos)
2608                                 {
2609                                         result = strcat(result, ":", mapvote_maps[i]);
2610                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2611                                 }
2612                         }
2613                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2614
2615                 GameLogEcho(result);
2616                 if(mapvote_maps_suggested[mappos])
2617                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2618         }
2619
2620         FOR_EACH_REALCLIENT(other)
2621                 FixClientCvars(other);
2622
2623         Map_Goto_SetStr(mapvote_maps[mappos]);
2624         Map_Goto();
2625         alreadychangedlevel = TRUE;
2626         return TRUE;
2627 }
2628 void MapVote_CheckRules_1()
2629 {
2630         float i;
2631
2632         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2633         {
2634                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2635                 mapvote_votes[i] = 0;
2636         }
2637
2638         mapvote_voters = 0;
2639         FOR_EACH_REALCLIENT(other)
2640         {
2641                 ++mapvote_voters;
2642                 if(other.mapvote)
2643                 {
2644                         i = other.mapvote - 1;
2645                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2646                         mapvote_votes[i] = mapvote_votes[i] + 1;
2647                 }
2648         }
2649 }
2650
2651 float MapVote_CheckRules_2()
2652 {
2653         float i;
2654         float firstPlace, secondPlace;
2655         float firstPlaceVotes, secondPlaceVotes;
2656         float mapvote_voters_real;
2657         string result;
2658
2659         if(mapvote_count_real == 1)
2660                 return MapVote_Finished(0);
2661
2662         mapvote_voters_real = mapvote_voters;
2663         if(mapvote_abstain)
2664                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2665
2666         RandomSelection_Init();
2667         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2668                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2669         firstPlace = RandomSelection_chosen_float;
2670         firstPlaceVotes = RandomSelection_best_priority;
2671         //dprint("First place: ", ftos(firstPlace), "\n");
2672         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2673
2674         RandomSelection_Init();
2675         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2676                 if(i != firstPlace)
2677                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2678         secondPlace = RandomSelection_chosen_float;
2679         secondPlaceVotes = RandomSelection_best_priority;
2680         //dprint("Second place: ", ftos(secondPlace), "\n");
2681         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2682
2683         if(firstPlace == -1)
2684                 error("No first place in map vote... WTF?");
2685
2686         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2687                 return MapVote_Finished(firstPlace);
2688
2689         if(mapvote_keeptwotime)
2690                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2691                 {
2692                         float didntvote;
2693                         MapVote_TouchMask();
2694                         mapvote_message = "Now decide between the TOP TWO!";
2695                         mapvote_keeptwotime = 0;
2696                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2697                         result = strcat(result, ":", ftos(firstPlaceVotes));
2698                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2699                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2700                         didntvote = mapvote_voters;
2701                         for(i = 0; i < mapvote_count; ++i)
2702                                 if(mapvote_maps[i] != "")
2703                                 {
2704                                         didntvote -= mapvote_votes[i];
2705                                         if(i != firstPlace)
2706                                                 if(i != secondPlace)
2707                                                 {
2708                                                         result = strcat(result, ":", mapvote_maps[i]);
2709                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2710                                                         if(i < mapvote_count_real)
2711                                                         {
2712                                                                 strunzone(mapvote_maps[i]);
2713                                                                 mapvote_maps[i] = "";
2714                                                                 strunzone(mapvote_maps_pakfile[i]);
2715                                                                 mapvote_maps_pakfile[i] = "";
2716                                                         }
2717                                                 }
2718                                 }
2719                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2720                         if(autocvar_sv_eventlog)
2721                                 GameLogEcho(result);
2722                 }
2723
2724         return FALSE;
2725 }
2726 void MapVote_Tick()
2727 {
2728         float keeptwo;
2729         float totalvotes;
2730
2731         keeptwo = mapvote_keeptwotime;
2732         MapVote_CheckRules_1(); // count
2733         if(MapVote_CheckRules_2()) // decide
2734                 return;
2735
2736         totalvotes = 0;
2737         FOR_EACH_REALCLIENT(other)
2738         {
2739                 // hide scoreboard again
2740                 if(other.health != 2342)
2741                 {
2742                         other.health = 2342;
2743                         other.impulse = 0;
2744                         if(clienttype(other) == CLIENTTYPE_REAL)
2745                         {
2746                                 msg_entity = other;
2747                                 WriteByte(MSG_ONE, SVC_FINALE);
2748                                 WriteString(MSG_ONE, "");
2749                         }
2750                 }
2751
2752                 // clear possibly invalid votes
2753                 if(mapvote_maps[other.mapvote - 1] == "")
2754                         other.mapvote = 0;
2755                 // use impulses as new vote
2756                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2757                         if(mapvote_maps[other.impulse - 1] != "")
2758                         {
2759                                 other.mapvote = other.impulse;
2760                                 MapVote_TouchVotes(other);
2761                         }
2762                 other.impulse = 0;
2763
2764                 if(other.mapvote)
2765                         ++totalvotes;
2766         }
2767
2768         MapVote_CheckRules_1(); // just count
2769 }
2770 void MapVote_Start()
2771 {
2772         if(mapvote_run)
2773                 return;
2774
2775         // wait for stats to be sent first
2776         if(!playerstats_waitforme)
2777                 return;
2778
2779         MapInfo_Enumerate();
2780         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2781                 mapvote_run = TRUE;
2782 }
2783 void MapVote_Think()
2784 {
2785         if(!mapvote_run)
2786                 return;
2787
2788         if(alreadychangedlevel)
2789                 return;
2790
2791         if(time < mapvote_nextthink)
2792                 return;
2793         //dprint("tick\n");
2794
2795         mapvote_nextthink = time + 0.5;
2796
2797         if(!mapvote_initialized)
2798         {
2799                 if(autocvar_rescan_pending == 1)
2800                 {
2801                         cvar_set("rescan_pending", "2");
2802                         localcmd("fs_rescan\nrescan_pending 3\n");
2803                         return;
2804                 }
2805                 else if(autocvar_rescan_pending == 2)
2806                 {
2807                         return;
2808                 }
2809                 else if(autocvar_rescan_pending == 3)
2810                 {
2811                         // now build missing mapinfo files
2812                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2813                                 return;
2814
2815                         // we're done, start the timer
2816                         cvar_set("rescan_pending", "0");
2817                 }
2818
2819                 mapvote_initialized = TRUE;
2820                 if(DoNextMapOverride())
2821                         return;
2822                 if(!autocvar_g_maplist_votable || player_count <= 0)
2823                 {
2824                         GotoNextMap();
2825                         return;
2826                 }
2827                 MapVote_Init();
2828         }
2829
2830         MapVote_Tick();
2831 }
2832
2833 string GotoMap(string m)
2834 {
2835         if(!MapInfo_CheckMap(m))
2836                 return "The map you chose is not available on this server.";
2837         cvar_set("nextmap", m);
2838         cvar_set("timelimit", "-1");
2839         if(mapvote_initialized || alreadychangedlevel)
2840         {
2841                 if(DoNextMapOverride())
2842                         return "Map switch initiated.";
2843                 else
2844                         return "Hm... no. For some reason I like THIS map more.";
2845         }
2846         else
2847                 return "Map switch will happen after scoreboard.";
2848 }
2849
2850
2851 void EndFrame()
2852 {
2853         float altime;
2854         FOR_EACH_REALCLIENT(self)
2855         {
2856                 if(self.classname == "spectator")
2857                 {
2858                         if(self.enemy.typehitsound)
2859                                 self.typehit_time = time;
2860                         else if(self.enemy.hitsound)
2861                                 self.hit_time = time;
2862                 }
2863                 else
2864                 {
2865                         if(self.typehitsound)
2866                                 self.typehit_time = time;
2867                         else if(self.hitsound)
2868                                 self.hit_time = time;
2869                 }
2870         }
2871         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2872         // add 1 frametime because after this, engine SV_Physics
2873         // increases time by a frametime and then networks the frame
2874         // add another frametime because client shows everything with
2875         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2876         // needed!
2877         FOR_EACH_CLIENT(self)
2878         {
2879                 self.hitsound = FALSE;
2880                 self.typehitsound = FALSE;
2881                 antilag_record(self, altime);
2882         }
2883 }
2884
2885
2886 /*
2887  * RedirectionThink:
2888  * returns TRUE if redirecting
2889  */
2890 float redirection_timeout;
2891 float redirection_nextthink;
2892 float RedirectionThink()
2893 {
2894         float clients_found;
2895
2896         if(redirection_target == "")
2897                 return FALSE;
2898
2899         if(!redirection_timeout)
2900         {
2901                 cvar_set("sv_public", "-2");
2902                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2903                 if(redirection_target == "self")
2904                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2905                 else
2906                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2907         }
2908
2909         if(time < redirection_nextthink)
2910                 return TRUE;
2911
2912         redirection_nextthink = time + 1;
2913
2914         clients_found = 0;
2915         FOR_EACH_REALCLIENT(self)
2916         {
2917                 print("Redirecting: sending connect command to ", self.netname, "\n");
2918                 if(redirection_target == "self")
2919                         stuffcmd(self, "\ndisconnect; reconnect\n");
2920                 else
2921                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2922                 ++clients_found;
2923         }
2924
2925         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2926
2927         if(time > redirection_timeout || clients_found == 0)
2928                 localcmd("\nwait; wait; wait; quit\n");
2929
2930         return TRUE;
2931 }
2932
2933 void TargetMusic_RestoreGame();
2934 void RestoreGame()
2935 {
2936         // Loaded from a save game
2937         // some things then break, so let's work around them...
2938
2939         // Progs DB (capture records)
2940         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2941
2942         // Mapinfo
2943         MapInfo_Shutdown();
2944         MapInfo_Enumerate();
2945         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2946         WeaponStats_Init();
2947
2948         TargetMusic_RestoreGame();
2949 }
2950
2951 void SV_Shutdown()
2952 {
2953         entity e;
2954
2955         if(gameover > 1) // shutting down already?
2956                 return;
2957
2958         gameover = 2; // 2 = server shutting down
2959
2960         if(world_initialized > 0)
2961         {
2962                 world_initialized = 0;
2963                 print("Saving persistent data...\n");
2964                 Ban_SaveBans();
2965
2966                 PlayerStats_EndMatch(0);
2967                 FOR_EACH_CLIENT(e)
2968                         PlayerStats_AddGlobalInfo(e);
2969                 PlayerStats_Shutdown();
2970
2971                 if(!cheatcount_total)
2972                 {
2973                         if(autocvar_sv_db_saveasdump)
2974                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2975                         else
2976                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2977                 }
2978                 if(autocvar_developer)
2979                 {
2980                         if(autocvar_sv_db_saveasdump)
2981                                 db_dump(TemporaryDB, "server-temp.db");
2982                         else
2983                                 db_save(TemporaryDB, "server-temp.db");
2984                 }
2985                 CheatShutdown(); // must be after cheatcount check
2986                 db_close(ServerProgsDB);
2987                 db_close(TemporaryDB);
2988                 print("done!\n");
2989                 // tell the bot system the game is ending now
2990                 bot_endgame();
2991
2992                 WeaponStats_Shutdown();
2993                 MapInfo_Shutdown();
2994         }
2995         else if(world_initialized == 0)
2996         {
2997                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2998         }
2999 }